UICaboodle/BrowserView.mm

   1 #include <UIKit/UIKit.h>
   2 #include "iPhonePrivate.h"
   3
   4 #include "UCPlatform.h"
   5
   6 #include <UICaboodle/BrowserView.h>
   7 #include <UICaboodle/UCLocalize.h>
   8
   9 //#include <QuartzCore/CALayer.h>
  10 // XXX: fix the minimum requirement
  11 extern NSString * const kCAFilterNearest;
  12
  13 #include <WebCore/WebCoreThread.h>
  14
  15 #include <WebKit/WebPolicyDelegate.h>
  16 #include <WebKit/WebPreferences.h>
  17
  18 #include <WebKit/DOMCSSPrimitiveValue.h>
  19 #include <WebKit/DOMCSSStyleDeclaration.h>
  20 #include <WebKit/DOMDocument.h>
  21 #include <WebKit/DOMHTMLBodyElement.h>
  22 #include <WebKit/DOMRGBColor.h>
  23
  24 //#include <WebCore/Page.h>
  25 //#include <WebCore/Settings.h>
  26
  27 #include "substrate.h"
  28
  29 #define ForSaurik 0
  30 #define DefaultTimeout_ 120.0
  31
  32 #define ShowInternals 0
  33 #define LogBrowser 0
  34 #define LogMessages 0
  35
  36 #define lprintf(args...) fprintf(stderr, args)
  37
  38 // WebThreadLocked {{{
  39 struct WebThreadLocked {
  40     _finline WebThreadLocked() {
  41         WebThreadLock();
  42     }
  43
  44     _finline ~WebThreadLocked() {
  45         WebThreadUnlock();
  46     }
  47 };
  48 // }}}
  49
  50 template <typename Type_>
  51 static inline void CYRelease(Type_ &value) {
  52     if (value != nil) {
  53         [value release];
  54         value = nil;
  55     }
  56 }
  57
  58 float CYScrollViewDecelerationRateNormal;
  59
  60 @interface WebView (Apple)
  61 - (void) _setLayoutInterval:(float)interval;
  62 - (void) _setAllowsMessaging:(BOOL)allows;
  63 @end
  64
  65 @interface WebPreferences (Apple)
  66 + (void) _setInitialDefaultTextEncodingToSystemEncoding;
  67 - (void) _setLayoutInterval:(NSInteger)interval;
  68 - (void) setOfflineWebApplicationCacheEnabled:(BOOL)enabled;
  69 @end
  70
  71 /* Indirect Delegate {{{ */
  72 @interface IndirectDelegate : NSObject <
  73     HookProtocol
  74 > {
  75     _transient volatile id delegate_;
  76 }
  77
  78 - (void) setDelegate:(id)delegate;
  79 - (id) initWithDelegate:(id)delegate;
  80 @end
  81
  82 @implementation IndirectDelegate
  83
  84 - (void) setDelegate:(id)delegate {
  85     delegate_ = delegate;
  86 }
  87
  88 - (id) initWithDelegate:(id)delegate {
  89     delegate_ = delegate;
  90     return self;
  91 }
  92
  93 - (void) didDismissModalViewController {
  94     if (delegate_ != nil)
  95         return [delegate_ didDismissModalViewController];
  96 }
  97
  98 - (IMP) methodForSelector:(SEL)sel {
  99     if (IMP method = [super methodForSelector:sel])
 100         return method;
 101     fprintf(stderr, "methodForSelector:[%s] == NULL\n", sel_getName(sel));
 102     return NULL;
 103 }
 104
 105 - (BOOL) respondsToSelector:(SEL)sel {
 106     if ([super respondsToSelector:sel])
 107         return YES;
 108
 109     // XXX: WebThreadCreateNSInvocation returns nil
 110
 111 #if ShowInternals
 112     fprintf(stderr, "[%s]R?%s\n", class_getName(self->isa), sel_getName(sel));
 113 #endif
 114
 115     return delegate_ == nil ? NO : [delegate_ respondsToSelector:sel];
 116 }
 117
 118 - (NSMethodSignature *) methodSignatureForSelector:(SEL)sel {
 119     if (NSMethodSignature *method = [super methodSignatureForSelector:sel])
 120         return method;
 121
 122 #if ShowInternals
 123     fprintf(stderr, "[%s]S?%s\n", class_getName(self->isa), sel_getName(sel));
 124 #endif
 125
 126     if (delegate_ != nil)
 127         if (NSMethodSignature *sig = [delegate_ methodSignatureForSelector:sel])
 128             return sig;
 129
 130     // XXX: I fucking hate Apple so very very bad
 131     return [NSMethodSignature signatureWithObjCTypes:"v@:"];
 132 }
 133
 134 - (void) forwardInvocation:(NSInvocation *)inv {
 135     SEL sel = [inv selector];
 136     if (delegate_ != nil && [delegate_ respondsToSelector:sel])
 137         [inv invokeWithTarget:delegate_];
 138 }
 139
 140 @end
 141 /* }}} */
 142
 143 @implementation WebScriptObject (UICaboodle)
 144
 145 - (NSUInteger) count {
 146     id length([self valueForKey:@"length"]);
 147     if ([length respondsToSelector:@selector(intValue)])
 148         return [length intValue];
 149     else
 150         return 0;
 151 }
 152
 153 - (id) objectAtIndex:(unsigned)index {
 154     return [self webScriptValueAtIndex:index];
 155 }
 156
 157 @end
 158
 159 // CYWebPolicyDecision* {{{
 160 enum CYWebPolicyDecision {
 161     CYWebPolicyDecisionUnknown,
 162     CYWebPolicyDecisionDownload,
 163     CYWebPolicyDecisionIgnore,
 164     CYWebPolicyDecisionUse,
 165 };
 166
 167 @interface CYWebPolicyDecisionMediator : NSObject <
 168     WebPolicyDecisionListener
 169 > {
 170     id<WebPolicyDecisionListener> listener_;
 171     CYWebPolicyDecision decision_;
 172 }
 173
 174 - (id) initWithListener:(id<WebPolicyDecisionListener>)listener;
 175
 176 - (CYWebPolicyDecision) decision;
 177 - (bool) decided;
 178 - (bool) decide;
 179
 180 @end
 181
 182 @implementation CYWebPolicyDecisionMediator
 183
 184 - (id) initWithListener:(id<WebPolicyDecisionListener>)listener {
 185     if ((self = [super init]) != nil) {
 186         listener_ = listener;
 187     } return self;
 188 }
 189
 190 - (CYWebPolicyDecision) decision {
 191     return decision_;
 192 }
 193
 194 - (bool) decided {
 195     return decision_ != CYWebPolicyDecisionUnknown;
 196 }
 197
 198 - (bool) decide {
 199     switch (decision_) {
 200         case CYWebPolicyDecisionUnknown:
 201         default:
 202             NSLog(@"CYWebPolicyDecisionUnknown");
 203             return false;
 204
 205         case CYWebPolicyDecisionDownload: [listener_ download]; break;
 206         case CYWebPolicyDecisionIgnore: [listener_ ignore]; break;
 207         case CYWebPolicyDecisionUse: [listener_ use]; break;
 208     }
 209
 210     return true;
 211 }
 212
 213 - (void) download {
 214     decision_ = CYWebPolicyDecisionDownload;
 215 }
 216
 217 - (void) ignore {
 218     decision_ = CYWebPolicyDecisionIgnore;
 219 }
 220
 221 - (void) use {
 222     decision_ = CYWebPolicyDecisionUse;
 223 }
 224
 225 @end
 226 // }}}
 227
 228 @implementation CYWebView : UIWebView
 229
 230 #if ShowInternals
 231 #include "UICaboodle/UCInternal.h"
 232 #endif
 233
 234 - (id) initWithFrame:(CGRect)frame {
 235     if ((self = [super initWithFrame:frame]) != nil) {
 236     } return self;
 237 }
 238
 239 - (void) dealloc {
 240     [super dealloc];
 241 }
 242
 243 - (id<CYWebViewDelegate>) delegate {
 244     return (id<CYWebViewDelegate>) [super delegate];
 245 }
 246
 247 /*- (WebView *) webView:(WebView *)view createWebViewWithRequest:(NSURLRequest *)request {
 248     id<CYWebViewDelegate> delegate([self delegate]);
 249     WebView *created(nil);
 250     if (created == nil && [delegate respondsToSelector:@selector(webView:createWebViewWithRequest:)])
 251         created = [delegate webView:view createWebViewWithRequest:request];
 252     if (created == nil && [UIWebView instancesRespondToSelector:@selector(webView:createWebViewWithRequest:)])
 253         created = [super webView:view createWebViewWithRequest:request];
 254     return created;
 255 }*/
 256
 257 // webView:addMessageToConsole: (X.Xx) {{{
 258 static void $UIWebViewWebViewDelegate$webView$addMessageToConsole$(UIWebViewWebViewDelegate *self, SEL sel, WebView *view, NSDictionary *message) {
 259     UIWebView *uiWebView(MSHookIvar<UIWebView *>(self, "uiWebView"));
 260     if ([uiWebView respondsToSelector:@selector(webView:addMessageToConsole:)])
 261         [uiWebView webView:view addMessageToConsole:message];
 262 }
 263
 264 - (void) webView:(WebView *)view addMessageToConsole:(NSDictionary *)message {
 265     id<CYWebViewDelegate> delegate([self delegate]);
 266     if ([delegate respondsToSelector:@selector(webView:addMessageToConsole:)])
 267         [delegate webView:view addMessageToConsole:message];
 268     if ([UIWebView instancesRespondToSelector:@selector(webView:addMessageToConsole:)])
 269         [super webView:view addMessageToConsole:message];
 270 }
 271 // }}}
 272 // webView:decidePolicyForNavigationAction:request:frame:decisionListener: (2.0+) {{{
 273 - (void) webView:(WebView *)view decidePolicyForNavigationAction:(NSDictionary *)action request:(NSURLRequest *)request frame:(WebFrame *)frame decisionListener:(id<WebPolicyDecisionListener>)listener {
 274     id<CYWebViewDelegate> delegate([self delegate]);
 275     CYWebPolicyDecisionMediator *mediator([[[CYWebPolicyDecisionMediator alloc] initWithListener:listener] autorelease]);
 276     if (![mediator decided] && [delegate respondsToSelector:@selector(webView:decidePolicyForNavigationAction:request:frame:decisionListener:)])
 277         [delegate webView:view decidePolicyForNavigationAction:action request:request frame:frame decisionListener:mediator];
 278     if (![mediator decided] && [UIWebView instancesRespondToSelector:@selector(webView:decidePolicyForNavigationAction:request:frame:decisionListener:)])
 279         [super webView:view decidePolicyForNavigationAction:action request:request frame:frame decisionListener:mediator];
 280     [mediator decide];
 281 }
 282 // }}}
 283 // webView:decidePolicyForNewWindowAction:request:newFrameName:decisionListener: (3.0+) {{{
 284 static void $UIWebViewWebViewDelegate$webView$decidePolicyForNewWindowAction$request$newFrameName$decisionListener$(UIWebViewWebViewDelegate *self, SEL sel, WebView *view, NSDictionary *action, NSURLRequest *request, NSString *frame, id<WebPolicyDecisionListener> listener) {
 285     UIWebView *uiWebView(MSHookIvar<UIWebView *>(self, "uiWebView"));
 286     if ([uiWebView respondsToSelector:@selector(webView:decidePolicyForNewWindowAction:request:newFrameName:decisionListener:)])
 287         [uiWebView webView:view decidePolicyForNewWindowAction:action request:request newFrameName:frame decisionListener:listener];
 288 }
 289
 290 - (void) webView:(WebView *)view decidePolicyForNewWindowAction:(NSDictionary *)action request:(NSURLRequest *)request newFrameName:(NSString *)frame decisionListener:(id<WebPolicyDecisionListener>)listener {
 291     id<CYWebViewDelegate> delegate([self delegate]);
 292     CYWebPolicyDecisionMediator *mediator([[[CYWebPolicyDecisionMediator alloc] initWithListener:listener] autorelease]);
 293     if (![mediator decided] && [delegate respondsToSelector:@selector(webView:decidePolicyForNewWindowAction:request:newFrameName:decisionListener:)])
 294         [delegate webView:view decidePolicyForNewWindowAction:action request:request newFrameName:frame decisionListener:mediator];
 295     if (![mediator decided] && [UIWebView instancesRespondToSelector:@selector(webView:decidePolicyForNewWindowAction:request:newFrameName:decisionListener:)])
 296         [super webView:view decidePolicyForNewWindowAction:action request:request newFrameName:frame decisionListener:mediator];
 297     [mediator decide];
 298 }
 299 // }}}
 300 // webView:didClearWindowObject:forFrame: (3.2+) {{{
 301 static void $UIWebViewWebViewDelegate$webView$didClearWindowObject$forFrame$(UIWebViewWebViewDelegate *self, SEL sel, WebView *view, WebScriptObject *window, WebFrame *frame) {
 302     UIWebView *uiWebView(MSHookIvar<UIWebView *>(self, "uiWebView"));
 303     if ([uiWebView respondsToSelector:@selector(webView:didClearWindowObject:forFrame:)])
 304         [uiWebView webView:view didClearWindowObject:window forFrame:frame];
 305 }
 306
 307 - (void) webView:(WebView *)view didClearWindowObject:(WebScriptObject *)window forFrame:(WebFrame *)frame {
 308     id<CYWebViewDelegate> delegate([self delegate]);
 309     if ([delegate respondsToSelector:@selector(webView:didClearWindowObject:forFrame:)])
 310         [delegate webView:view didClearWindowObject:window forFrame:frame];
 311     if ([UIWebView instancesRespondToSelector:@selector(webView:didClearWindowObject:forFrame:)])
 312         [super webView:view didClearWindowObject:window forFrame:frame];
 313 }
 314 // }}}
 315 // webView:didFailLoadWithError:forFrame: (2.0+) {{{
 316 - (void) webView:(WebView *)view didFailLoadWithError:(NSError *)error forFrame:(WebFrame *)frame {
 317     id<CYWebViewDelegate> delegate([self delegate]);
 318     if ([delegate respondsToSelector:@selector(webView:didFailLoadWithError:forFrame:)])
 319         [delegate webView:view didFailLoadWithError:error forFrame:frame];
 320     if ([UIWebView instancesRespondToSelector:@selector(webView:didFailLoadWithError:forFrame:)])
 321         [super webView:view didFailLoadWithError:error forFrame:frame];
 322 }
 323 // }}}
 324 // webView:didFailProvisionalLoadWithError:forFrame: (2.0+) {{{
 325 - (void) webView:(WebView *)view didFailProvisionalLoadWithError:(NSError *)error forFrame:(WebFrame *)frame {
 326     id<CYWebViewDelegate> delegate([self delegate]);
 327     if ([delegate respondsToSelector:@selector(webView:didFailProvisionalLoadWithError:forFrame:)])
 328         [delegate webView:view didFailProvisionalLoadWithError:error forFrame:frame];
 329     if ([UIWebView instancesRespondToSelector:@selector(webView:didFailProvisionalLoadWithError:forFrame:)])
 330         [super webView:view didFailProvisionalLoadWithError:error forFrame:frame];
 331 }
 332 // }}}
 333 // webView:didFinishLoadForFrame: (2.0+) {{{
 334 - (void) webView:(WebView *)view didFinishLoadForFrame:(WebFrame *)frame {
 335     id<CYWebViewDelegate> delegate([self delegate]);
 336     if ([delegate respondsToSelector:@selector(webView:didFinishLoadForFrame:)])
 337         [delegate webView:view didFinishLoadForFrame:frame];
 338     if ([UIWebView instancesRespondToSelector:@selector(webView:didFinishLoadForFrame:)])
 339         [super webView:view didFinishLoadForFrame:frame];
 340 }
 341 // }}}
 342 // webView:didReceiveTitle:forFrame: (3.2+) {{{
 343 static void $UIWebViewWebViewDelegate$webView$didReceiveTitle$forFrame$(UIWebViewWebViewDelegate *self, SEL sel, WebView *view, NSString *title, WebFrame *frame) {
 344     UIWebView *uiWebView(MSHookIvar<UIWebView *>(self, "uiWebView"));
 345     if ([uiWebView respondsToSelector:@selector(webView:didReceiveTitle:forFrame:)])
 346         [uiWebView webView:view didReceiveTitle:title forFrame:frame];
 347 }
 348
 349 - (void) webView:(WebView *)view didReceiveTitle:(NSString *)title forFrame:(WebFrame *)frame {
 350     id<CYWebViewDelegate> delegate([self delegate]);
 351     if ([delegate respondsToSelector:@selector(webView:didReceiveTitle:forFrame:)])
 352         [delegate webView:view didReceiveTitle:title forFrame:frame];
 353     if ([UIWebView instancesRespondToSelector:@selector(webView:didReceiveTitle:forFrame:)])
 354         [super webView:view didReceiveTitle:title forFrame:frame];
 355 }
 356 // }}}
 357 // webView:didStartProvisionalLoadForFrame: (2.0+) {{{
 358 - (void) webView:(WebView *)view didStartProvisionalLoadForFrame:(WebFrame *)frame {
 359     id<CYWebViewDelegate> delegate([self delegate]);
 360     if ([delegate respondsToSelector:@selector(webView:didStartProvisionalLoadForFrame:)])
 361         [delegate webView:view didStartProvisionalLoadForFrame:frame];
 362     if ([UIWebView instancesRespondToSelector:@selector(webView:didStartProvisionalLoadForFrame:)])
 363         [super webView:view didStartProvisionalLoadForFrame:frame];
 364 }
 365 // }}}
 366 // webView:resource:willSendRequest:redirectResponse:fromDataSource: (3.2+) {{{
 367 static NSURLRequest *$UIWebViewWebViewDelegate$webView$resource$willSendRequest$redirectResponse$fromDataSource$(UIWebViewWebViewDelegate *self, SEL sel, WebView *view, id identifier, NSURLRequest *request, NSURLResponse *response, WebDataSource *source) {
 368     UIWebView *uiWebView(MSHookIvar<UIWebView *>(self, "uiWebView"));
 369     if ([uiWebView respondsToSelector:@selector(webView:resource:willSendRequest:redirectResponse:fromDataSource:)])
 370         request = [uiWebView webView:view resource:identifier willSendRequest:request redirectResponse:response fromDataSource:source];
 371     return request;
 372 }
 373
 374 - (NSURLRequest *) webView:(WebView *)view resource:(id)identifier willSendRequest:(NSURLRequest *)request redirectResponse:(NSURLResponse *)response fromDataSource:(WebDataSource *)source {
 375     id<CYWebViewDelegate> delegate([self delegate]);
 376     if ([UIWebView instancesRespondToSelector:@selector(webView:resource:willSendRequest:redirectResponse:fromDataSource:)])
 377         request = [super webView:view resource:identifier willSendRequest:request redirectResponse:response fromDataSource:source];
 378     if ([delegate respondsToSelector:@selector(webView:resource:willSendRequest:redirectResponse:fromDataSource:)])
 379         request = [delegate webView:view resource:identifier willSendRequest:request redirectResponse:response fromDataSource:source];
 380     return request;
 381 }
 382 // }}}
 383 // webView:runJavaScriptAlertPanelWithMessage:initiatedByFrame: (2.1+) {{{
 384 - (void) webView:(WebView *)view runJavaScriptAlertPanelWithMessage:(NSString *)message initiatedByFrame:(WebFrame *)frame {
 385     id<CYWebViewDelegate> delegate([self delegate]);
 386     if ([UIWebView instancesRespondToSelector:@selector(webView:runJavaScriptAlertPanelWithMessage:initiatedByFrame:)])
 387         if (
 388             ![delegate respondsToSelector:@selector(webView:shouldRunJavaScriptAlertPanelWithMessage:initiatedByFrame:)] ||
 389             [delegate webView:view shouldRunJavaScriptAlertPanelWithMessage:message initiatedByFrame:frame]
 390         )
 391             [super webView:view runJavaScriptAlertPanelWithMessage:message initiatedByFrame:frame];
 392 }
 393 // }}}
 394 // webView:runJavaScriptConfirmPanelWithMessage:initiatedByFrame: (2.1+) {{{
 395 - (BOOL) webView:(WebView *)view runJavaScriptConfirmPanelWithMessage:(NSString *)message initiatedByFrame:(WebFrame *)frame {
 396     id<CYWebViewDelegate> delegate([self delegate]);
 397     if ([UIWebView instancesRespondToSelector:@selector(webView:runJavaScriptConfirmPanelWithMessage:initiatedByFrame:)])
 398         if (
 399             ![delegate respondsToSelector:@selector(webView:shouldRunJavaScriptConfirmPanelWithMessage:initiatedByFrame:)] ||
 400             [delegate webView:view shouldRunJavaScriptConfirmPanelWithMessage:message initiatedByFrame:frame]
 401         )
 402             return [super webView:view runJavaScriptConfirmPanelWithMessage:message initiatedByFrame:frame];
 403     return NO;
 404 }
 405 // }}}
 406 // webView:runJavaScriptTextInputPanelWithPrompt:defaultText:initiatedByFrame: (2.1+) {{{
 407 - (NSString *) webView:(WebView *)view runJavaScriptTextInputPanelWithPrompt:(NSString *)prompt defaultText:(NSString *)text initiatedByFrame:(WebFrame *)frame {
 408     id<CYWebViewDelegate> delegate([self delegate]);
 409     if ([UIWebView instancesRespondToSelector:@selector(webView:runJavaScriptTextInputPanelWithPrompt:defaultText:initiatedByFrame:)])
 410         if (
 411             ![delegate respondsToSelector:@selector(webView:shouldRunJavaScriptTextInputPanelWithPrompt:defaultText:initiatedByFrame:)] ||
 412             [delegate webView:view shouldRunJavaScriptTextInputPanelWithPrompt:prompt defaultText:text initiatedByFrame:frame]
 413         )
 414             return [super webView:view runJavaScriptTextInputPanelWithPrompt:prompt defaultText:text initiatedByFrame:frame];
 415     return nil;
 416 }
 417 // }}}
 418 // webViewClose: (3.2+) {{{
 419 static void $UIWebViewWebViewDelegate$webViewClose$(UIWebViewWebViewDelegate *self, SEL sel, WebView *view) {
 420     UIWebView *uiWebView(MSHookIvar<UIWebView *>(self, "uiWebView"));
 421     if ([uiWebView respondsToSelector:@selector(webViewClose:)])
 422         [uiWebView webViewClose:view];
 423 }
 424
 425 - (void) webViewClose:(WebView *)view {
 426     id<CYWebViewDelegate> delegate([self delegate]);
 427     if ([delegate respondsToSelector:@selector(webViewClose:)])
 428         [delegate webViewClose:view];
 429     if ([UIWebView instancesRespondToSelector:@selector(webViewClose:)])
 430         [super webViewClose:view];
 431 }
 432 // }}}
 433
 434 - (void) _updateViewSettings {
 435     [super _updateViewSettings];
 436
 437     id<CYWebViewDelegate> delegate([self delegate]);
 438     if ([delegate respondsToSelector:@selector(webViewUpdateViewSettings:)])
 439         [delegate webViewUpdateViewSettings:self];
 440 }
 441
 442 + (void) initialize {
 443     if (Class $UIWebViewWebViewDelegate = objc_getClass("UIWebViewWebViewDelegate")) {
 444         class_addMethod($UIWebViewWebViewDelegate, @selector(webView:addMessageToConsole:), (IMP) &$UIWebViewWebViewDelegate$webView$addMessageToConsole$, "v16@0:4@8@12");
 445         class_addMethod($UIWebViewWebViewDelegate, @selector(webView:decidePolicyForNewWindowAction:request:newFrameName:decisionListener:), (IMP) &$UIWebViewWebViewDelegate$webView$decidePolicyForNewWindowAction$request$newFrameName$decisionListener$, "v28@0:4@8@12@16@20@24");
 446         class_addMethod($UIWebViewWebViewDelegate, @selector(webView:didClearWindowObject:forFrame:), (IMP) &$UIWebViewWebViewDelegate$webView$didClearWindowObject$forFrame$, "v20@0:4@8@12@16");
 447         class_addMethod($UIWebViewWebViewDelegate, @selector(webView:didReceiveTitle:forFrame:), (IMP) &$UIWebViewWebViewDelegate$webView$didReceiveTitle$forFrame$, "v20@0:4@8@12@16");
 448         class_addMethod($UIWebViewWebViewDelegate, @selector(webView:resource:willSendRequest:redirectResponse:fromDataSource:), (IMP) &$UIWebViewWebViewDelegate$webView$resource$willSendRequest$redirectResponse$fromDataSource$, "@28@0:4@8@12@16@20@24");
 449         class_addMethod($UIWebViewWebViewDelegate, @selector(webViewClose:), (IMP) &$UIWebViewWebViewDelegate$webViewClose$, "v12@0:4@8");
 450     }
 451 }
 452
 453 @end
 454
 455 @implementation BrowserController
 456
 457 #if ShowInternals
 458 #include "UICaboodle/UCInternal.h"
 459 #endif
 460
 461 + (void) _initialize {
 462     [WebPreferences _setInitialDefaultTextEncodingToSystemEncoding];
 463
 464     if (float *_UIScrollViewDecelerationRateNormal = reinterpret_cast<float *>(dlsym(RTLD_DEFAULT, "UIScrollViewDecelerationRateNormal")))
 465         CYScrollViewDecelerationRateNormal = *_UIScrollViewDecelerationRateNormal;
 466     else // XXX: this actually might be fast on some older systems: we should look into this
 467         CYScrollViewDecelerationRateNormal = 0.998;
 468 }
 469
 470 - (void) dealloc {
 471 #if LogBrowser
 472     NSLog(@"[BrowserController dealloc]");
 473 #endif
 474
 475     [webview_ setDelegate:nil];
 476
 477     [indirect_ setDelegate:nil];
 478     [indirect_ release];
 479
 480     if (challenge_ != nil)
 481         [challenge_ release];
 482
 483     if (request_ != nil)
 484         [request_ release];
 485
 486     if (custom_ != nil)
 487         [custom_ release];
 488     if (style_ != nil)
 489         [style_ release];
 490
 491     if (function_ != nil)
 492         [function_ release];
 493     if (closer_ != nil)
 494         [closer_ release];
 495
 496     if (title_ != nil)
 497         [title_ release];
 498
 499     if ([loading_ count] != 0)
 500         [delegate_ releaseNetworkActivityIndicator];
 501     [loading_ release];
 502
 503     [reloaditem_ release];
 504     [loadingitem_ release];
 505
 506     [indicator_ release];
 507
 508     [super dealloc];
 509 }
 510
 511 - (void) setURL:(NSURL *)url {
 512     _assert(request_ == nil);
 513
 514     request_ = [[NSURLRequest
 515         requestWithURL:url
 516         cachePolicy:NSURLRequestUseProtocolCachePolicy
 517         timeoutInterval:DefaultTimeout_
 518     ] retain];
 519 }
 520
 521 - (void) loadURL:(NSURL *)url cachePolicy:(NSURLRequestCachePolicy)policy {
 522     [self loadRequest:[NSURLRequest
 523         requestWithURL:url
 524         cachePolicy:policy
 525         timeoutInterval:DefaultTimeout_
 526     ]];
 527 }
 528
 529 - (void) loadURL:(NSURL *)url {
 530     [self loadURL:url cachePolicy:NSURLRequestUseProtocolCachePolicy];
 531 }
 532
 533 - (void) loadRequest:(NSURLRequest *)request {
 534 #if LogBrowser
 535     NSLog(@"loadRequest:%@", request);
 536 #endif
 537
 538     error_ = false;
 539
 540     WebThreadLocked lock;
 541     [webview_ loadRequest:request];
 542 }
 543
 544 - (void) reloadURL {
 545     if (request_ == nil)
 546         return;
 547
 548     if ([request_ HTTPBody] == nil && [request_ HTTPBodyStream] == nil)
 549         [self loadRequest:request_];
 550     else {
 551         UIAlertView *alert = [[[UIAlertView alloc]
 552             initWithTitle:UCLocalize("RESUBMIT_FORM")
 553             message:nil
 554             delegate:self
 555             cancelButtonTitle:UCLocalize("CANCEL")
 556             otherButtonTitles:
 557                 UCLocalize("SUBMIT"),
 558             nil
 559         ] autorelease];
 560
 561         [alert setContext:@"submit"];
 562         [alert show];
 563     }
 564 }
 565
 566 - (void) reloadData {
 567     [super reloadData];
 568     [self reloadURL];
 569 }
 570
 571 - (void) setButtonImage:(NSString *)button withStyle:(NSString *)style toFunction:(id)function {
 572     if (custom_ != nil)
 573         [custom_ autorelease];
 574     if (button == nil)
 575         custom_ = nil;
 576     else
 577         custom_ = [[UIImage imageWithData:[NSData dataWithContentsOfURL:[NSURL URLWithString:button]]] retain];
 578
 579     if (style_ != nil)
 580         [style_ autorelease];
 581     if (style == nil)
 582         style_ = nil;
 583     else
 584         style_ = [style retain];
 585
 586     if (function_ != nil)
 587         [function_ autorelease];
 588     if (function == nil)
 589         function_ = nil;
 590     else
 591         function_ = [function retain];
 592
 593     [self applyRightButton];
 594 }
 595
 596 - (void) setButtonTitle:(NSString *)button withStyle:(NSString *)style toFunction:(id)function {
 597     if (custom_ != nil)
 598         [custom_ autorelease];
 599     if (button == nil)
 600         custom_ = nil;
 601     else
 602         custom_ = [button retain];
 603
 604     if (style_ != nil)
 605         [style_ autorelease];
 606     if (style == nil)
 607         style_ = nil;
 608     else
 609         style_ = [style retain];
 610
 611     if (function_ != nil)
 612         [function_ autorelease];
 613     if (function == nil)
 614         function_ = nil;
 615     else
 616         function_ = [function retain];
 617
 618     [self applyRightButton];
 619 }
 620
 621 - (void) setPopupHook:(id)function {
 622     if (closer_ != nil)
 623         [closer_ autorelease];
 624     if (function == nil)
 625         closer_ = nil;
 626     else
 627         closer_ = [function retain];
 628 }
 629
 630 - (void) _setViewportWidth {
 631     [[webview_ _documentView] setViewportSize:CGSizeMake(width_, UIWebViewGrowsAndShrinksToFitHeight) forDocumentTypes:0x10];
 632 }
 633
 634 - (void) setViewportWidth:(float)width {
 635     width_ = width != 0 ? width : [[self class] defaultWidth];
 636     [self _setViewportWidth];
 637 }
 638
 639 - (void) webViewUpdateViewSettings:(UIWebView *)view {
 640     [self _setViewportWidth];
 641 }
 642
 643 - (void) _openMailToURL:(NSURL *)url {
 644     [[UIApplication sharedApplication] openURL:url];// asPanel:YES];
 645 }
 646
 647 - (bool) _allowJavaScriptPanel {
 648     return true;
 649 }
 650
 651 - (void) _didFailWithError:(NSError *)error forFrame:(WebFrame *)frame {
 652     [loading_ removeObject:[NSValue valueWithNonretainedObject:frame]];
 653     [self _didFinishLoading];
 654
 655     if ([error code] == NSURLErrorCancelled)
 656         return;
 657
 658     if ([frame parentFrame] == nil) {
 659         [self loadURL:[NSURL URLWithString:[NSString stringWithFormat:@"%@?%@",
 660             [[NSURL fileURLWithPath:[[NSBundle mainBundle] pathForResource:@"error" ofType:@"html"]] absoluteString],
 661             [[error localizedDescription] stringByAddingPercentEscapes]
 662         ]]];
 663
 664         error_ = true;
 665     }
 666 }
 667
 668 // CYWebViewDelegate {{{
 669 - (void) webView:(WebView *)view addMessageToConsole:(NSDictionary *)message {
 670 #if LogMessages
 671     NSLog(@"addMessageToConsole:%@", message);
 672 #endif
 673 }
 674
 675 - (void) webView:(WebView *)view decidePolicyForNavigationAction:(NSDictionary *)action request:(NSURLRequest *)request frame:(WebFrame *)frame decisionListener:(id<WebPolicyDecisionListener>)listener {
 676 #if LogBrowser
 677     NSLog(@"decidePolicyForNavigationAction:%@ request:%@ frame:%@", action, request, frame);
 678 #endif
 679
 680     if ([frame parentFrame] == nil) {
 681         if (!error_) {
 682             if (request_ != nil)
 683                 [request_ autorelease];
 684             if (request == nil)
 685                 request_ = nil;
 686             else
 687                 request_ = [request retain];
 688         }
 689     }
 690 }
 691
 692 - (void) webView:(WebView *)view decidePolicyForNewWindowAction:(NSDictionary *)action request:(NSURLRequest *)request newFrameName:(NSString *)frame decisionListener:(id<WebPolicyDecisionListener>)listener {
 693 #if LogBrowser
 694     NSLog(@"decidePolicyForNewWindowAction:%@ request:%@ newFrameName:%@", action, request, frame);
 695 #endif
 696
 697     NSURL *url([request URL]);
 698     if (url == nil)
 699         return;
 700
 701     if ([frame isEqualToString:@"_open"])
 702         [delegate_ openURL:url];
 703
 704     NSString *scheme([[url scheme] lowercaseString]);
 705     if ([scheme isEqualToString:@"mailto"])
 706         [self _openMailToURL:url];
 707
 708     CYViewController *page([delegate_ pageForURL:url]);
 709
 710     if (page == nil) {
 711         BrowserController *browser([[[class_ alloc] init] autorelease]);
 712         [browser loadRequest:request];
 713         page = browser;
 714     }
 715
 716     [page setDelegate:delegate_];
 717
 718     if (![frame isEqualToString:@"_popup"]) {
 719         [[self navigationItem] setTitle:title_];
 720
 721         [[self navigationController] pushViewController:page animated:YES];
 722     } else {
 723         UCNavigationController *navigation([[[UCNavigationController alloc] initWithRootViewController:page] autorelease]);
 724
 725         [navigation setHook:indirect_];
 726         [navigation setDelegate:delegate_];
 727
 728         [[page navigationItem] setLeftBarButtonItem:[[[UIBarButtonItem alloc]
 729             initWithTitle:UCLocalize("CLOSE")
 730             style:UIBarButtonItemStylePlain
 731             target:page
 732             action:@selector(close)
 733         ] autorelease]];
 734
 735         [[self navigationController] presentModalViewController:navigation animated:YES];
 736     }
 737
 738     [listener ignore];
 739 }
 740
 741 - (void) webView:(WebView *)view didClearWindowObject:(WebScriptObject *)window forFrame:(WebFrame *)frame {
 742 }
 743
 744 - (void) webView:(WebView *)view didFailLoadWithError:(NSError *)error forFrame:(WebFrame *)frame {
 745 #if LogBrowser
 746     NSLog(@"didFailLoadWithError:%@ forFrame:%@", error, frame);
 747 #endif
 748
 749     [self _didFailWithError:error forFrame:frame];
 750 }
 751
 752 - (void) webView:(WebView *)view didFailProvisionalLoadWithError:(NSError *)error forFrame:(WebFrame *)frame {
 753 #if LogBrowser
 754     NSLog(@"didFailProvisionalLoadWithError:%@ forFrame:%@", error, frame);
 755 #endif
 756
 757     [self _didFailWithError:error forFrame:frame];
 758 }
 759
 760 - (void) webView:(WebView *)view didFinishLoadForFrame:(WebFrame *)frame {
 761     [loading_ removeObject:[NSValue valueWithNonretainedObject:frame]];
 762
 763     if ([frame parentFrame] == nil) {
 764         if (DOMDocument *document = [frame DOMDocument])
 765             if (DOMNodeList<NSFastEnumeration> *bodies = [document getElementsByTagName:@"body"])
 766                 for (DOMHTMLBodyElement *body in (id) bodies) {
 767                     DOMCSSStyleDeclaration *style([document getComputedStyle:body pseudoElement:nil]);
 768
 769                     bool colored(false);
 770
 771                     if (DOMCSSPrimitiveValue *color = static_cast<DOMCSSPrimitiveValue *>([style getPropertyCSSValue:@"background-color"])) {
 772                         if ([color primitiveType] == DOM_CSS_RGBCOLOR) {
 773                             DOMRGBColor *rgb([color getRGBColorValue]);
 774
 775                             float red([[rgb red] getFloatValue:DOM_CSS_NUMBER]);
 776                             float green([[rgb green] getFloatValue:DOM_CSS_NUMBER]);
 777                             float blue([[rgb blue] getFloatValue:DOM_CSS_NUMBER]);
 778                             float alpha([[rgb alpha] getFloatValue:DOM_CSS_NUMBER]);
 779
 780                             UIColor *uic(nil);
 781
 782                             if (red == 0xc7 && green == 0xce && blue == 0xd5)
 783                                 uic = [UIColor groupTableViewBackgroundColor];
 784                             else if (alpha != 0)
 785                                 uic = [UIColor
 786                                     colorWithRed:(red / 255)
 787                                     green:(green / 255)
 788                                     blue:(blue / 255)
 789                                     alpha:alpha
 790                                 ];
 791
 792                             if (uic != nil) {
 793                                 colored = true;
 794                                 [scroller_ setBackgroundColor:uic];
 795                             }
 796                         }
 797                     }
 798
 799                     if (!colored)
 800                         [scroller_ setBackgroundColor:[UIColor groupTableViewBackgroundColor]];
 801                     break;
 802                 }
 803     }
 804
 805     [self _didFinishLoading];
 806 }
 807
 808 - (void) webView:(WebView *)view didReceiveTitle:(NSString *)title forFrame:(WebFrame *)frame {
 809     if ([frame parentFrame] != nil)
 810         return;
 811
 812     if (title_ != nil)
 813         [title_ autorelease];
 814     title_ = [title retain];
 815
 816     [[self navigationItem] setTitle:title_];
 817 }
 818
 819 - (void) webView:(WebView *)view didStartProvisionalLoadForFrame:(WebFrame *)frame {
 820     [loading_ addObject:[NSValue valueWithNonretainedObject:frame]];
 821
 822     if ([frame parentFrame] == nil) {
 823         CYRelease(title_);
 824         CYRelease(custom_);
 825         CYRelease(style_);
 826         CYRelease(function_);
 827         CYRelease(closer_);
 828
 829         // XXX: do we still need to do this?
 830         [[self navigationItem] setTitle:nil];
 831     }
 832
 833     [self _didStartLoading];
 834 }
 835
 836 - (NSURLRequest *) webView:(WebView *)view resource:(id)identifier willSendRequest:(NSURLRequest *)request redirectResponse:(NSURLResponse *)response fromDataSource:(WebDataSource *)source {
 837 #if LogBrowser
 838     NSLog(@"resource:%@ willSendRequest:%@ redirectResponse:%@ fromDataSource:%@", identifier, request, response, source);
 839 #endif
 840
 841     return request;
 842 }
 843
 844 - (bool) webView:(WebView *)view shouldRunJavaScriptAlertPanelWithMessage:(NSString *)message initiatedByFrame:(WebFrame *)frame {
 845     return [self _allowJavaScriptPanel];
 846 }
 847
 848 - (bool) webView:(WebView *)view shouldRunJavaScriptConfirmPanelWithMessage:(NSString *)message initiatedByFrame:(WebFrame *)frame {
 849     return [self _allowJavaScriptPanel];
 850 }
 851
 852 - (bool) webView:(WebView *)view shouldRunJavaScriptTextInputPanelWithPrompt:(NSString *)prompt defaultText:(NSString *)text initiatedByFrame:(WebFrame *)frame {
 853     return [self _allowJavaScriptPanel];
 854 }
 855
 856 - (void) webViewClose:(WebView *)view {
 857     [self close];
 858 }
 859 // }}}
 860
 861 - (void) close {
 862     [[self navigationController] dismissModalViewControllerAnimated:YES];
 863 }
 864
 865 - (void) alertView:(UIAlertView *)alert clickedButtonAtIndex:(NSInteger)button {
 866     NSString *context([alert context]);
 867
 868     if ([context isEqualToString:@"sensitive"]) {
 869         switch (button) {
 870             case 1:
 871                 sensitive_ = [NSNumber numberWithBool:YES];
 872             break;
 873
 874             case 2:
 875                 sensitive_ = [NSNumber numberWithBool:NO];
 876             break;
 877         }
 878
 879         [alert dismissWithClickedButtonIndex:-1 animated:YES];
 880     } else if ([context isEqualToString:@"challenge"]) {
 881         id<NSURLAuthenticationChallengeSender> sender([challenge_ sender]);
 882
 883         switch (button) {
 884             case 1: {
 885                 NSString *username([[alert textFieldAtIndex:0] text]);
 886                 NSString *password([[alert textFieldAtIndex:1] text]);
 887
 888                 NSURLCredential *credential([NSURLCredential credentialWithUser:username password:password persistence:NSURLCredentialPersistenceForSession]);
 889
 890                 [sender useCredential:credential forAuthenticationChallenge:challenge_];
 891             } break;
 892
 893             case 2:
 894                 [sender cancelAuthenticationChallenge:challenge_];
 895             break;
 896
 897             _nodefault
 898         }
 899
 900         [challenge_ release];
 901         challenge_ = nil;
 902
 903         [alert dismissWithClickedButtonIndex:-1 animated:YES];
 904     } else if ([context isEqualToString:@"submit"]) {
 905         if (button == [alert cancelButtonIndex]) {
 906         } else if (button == [alert firstOtherButtonIndex]) {
 907             if (request_ != nil) {
 908                 WebThreadLocked lock;
 909                 [webview_ loadRequest:request_];
 910             }
 911         }
 912
 913         [alert dismissWithClickedButtonIndex:-1 animated:YES];
 914     }
 915 }
 916
 917 - (UIBarButtonItemStyle) rightButtonStyle {
 918     if (style_ == nil) normal:
 919         return UIBarButtonItemStylePlain;
 920     else if ([style_ isEqualToString:@"Normal"])
 921         return UIBarButtonItemStylePlain;
 922     else if ([style_ isEqualToString:@"Highlighted"])
 923         return UIBarButtonItemStyleDone;
 924     else goto normal;
 925 }
 926
 927 - (UIBarButtonItem *) customButton {
 928     return [[[UIBarButtonItem alloc]
 929         initWithTitle:custom_
 930         style:[self rightButtonStyle]
 931         target:self
 932         action:@selector(customButtonClicked)
 933     ] autorelease];
 934 }
 935
 936 - (UIBarButtonItem *) rightButton {
 937     return reloaditem_;
 938 }
 939
 940 - (void) applyLoadingTitle {
 941     [[self navigationItem] setTitle:UCLocalize("LOADING")];
 942 }
 943
 944 - (void) layoutRightButton {
 945     [[loadingitem_ view] addSubview:indicator_];
 946     [[loadingitem_ view] bringSubviewToFront:indicator_];
 947 }
 948
 949 - (void) applyRightButton {
 950     if ([self isLoading]) {
 951         [[self navigationItem] setRightBarButtonItem:loadingitem_ animated:YES];
 952         [self performSelector:@selector(layoutRightButton) withObject:nil afterDelay:0];
 953
 954         [indicator_ startAnimating];
 955         [self applyLoadingTitle];
 956     } else {
 957         [indicator_ stopAnimating];
 958
 959         [[self navigationItem] setRightBarButtonItem:(
 960             custom_ != nil ? [self customButton] : [self rightButton]
 961         ) animated:YES];
 962     }
 963 }
 964
 965 - (void) didStartLoading {
 966     // Overridden in subclasses.
 967 }
 968
 969 - (void) _didStartLoading {
 970     [self applyRightButton];
 971
 972     if ([loading_ count] != 1)
 973         return;
 974
 975     [delegate_ retainNetworkActivityIndicator];
 976     [self didStartLoading];
 977 }
 978
 979 - (void) didFinishLoading {
 980     // Overridden in subclasses.
 981 }
 982
 983 - (void) _didFinishLoading {
 984     if ([loading_ count] != 0)
 985         return;
 986
 987     [self applyRightButton];
 988     [[self navigationItem] setTitle:title_];
 989
 990     [delegate_ releaseNetworkActivityIndicator];
 991     [self didFinishLoading];
 992 }
 993
 994 - (bool) isLoading {
 995     return [loading_ count] != 0;
 996 }
 997
 998 - (id) initWithWidth:(float)width ofClass:(Class)_class {
 999     if ((self = [super init]) != nil) {
1000         class_ = _class;
1001         loading_ = [[NSMutableSet alloc] initWithCapacity:5];
1002
1003         indirect_ = [[IndirectDelegate alloc] initWithDelegate:self];
1004
1005         webview_ = [[[CYWebView alloc] initWithFrame:[[self view] bounds]] autorelease];
1006         [webview_ setDelegate:self];
1007         [self setView:webview_];
1008
1009         if ([webview_ respondsToSelector:@selector(setDataDetectorTypes:)])
1010             [webview_ setDataDetectorTypes:UIDataDetectorTypeAutomatic];
1011         else
1012             [webview_ setDetectsPhoneNumbers:NO];
1013
1014         [webview_ setScalesPageToFit:YES];
1015
1016         UIWebDocumentView *document([webview_ _documentView]);
1017
1018         // XXX: I think this improves scrolling; the hardcoded-ness sucks
1019         [document setTileSize:CGSizeMake(320, 500)];
1020
1021         [document setBackgroundColor:[UIColor clearColor]];
1022
1023         // XXX: this is terribly (too?) expensive
1024         [document setDrawsBackground:NO];
1025
1026         WebView *webview([document webView]);
1027         WebPreferences *preferences([webview preferences]);
1028
1029         // XXX: I have no clue if I actually /want/ this modification
1030         if ([webview respondsToSelector:@selector(_setLayoutInterval:)])
1031             [webview _setLayoutInterval:0];
1032         else if ([preferences respondsToSelector:@selector(_setLayoutInterval:)])
1033             [preferences _setLayoutInterval:0];
1034
1035         [preferences setCacheModel:WebCacheModelDocumentBrowser];
1036         [preferences setOfflineWebApplicationCacheEnabled:YES];
1037
1038 #if LogMessages
1039         if ([document respondsToSelector:@selector(setAllowsMessaging:)])
1040             [document setAllowsMessaging:YES];
1041         if ([webview respondsToSelector:@selector(_setAllowsMessaging:)])
1042             [webview _setAllowsMessaging:YES];
1043 #endif
1044
1045         if ([webview_ respondsToSelector:@selector(_scrollView)]) {
1046             scroller_ = [webview_ _scrollView];
1047
1048             [scroller_ setDirectionalLockEnabled:YES];
1049             [scroller_ setDecelerationRate:CYScrollViewDecelerationRateNormal];
1050             [scroller_ setDelaysContentTouches:NO];
1051
1052             [scroller_ setCanCancelContentTouches:YES];
1053         } else if ([webview_ respondsToSelector:@selector(_scroller)]) {
1054             UIScroller *scroller([webview_ _scroller]);
1055             scroller_ = (UIScrollView *) scroller;
1056
1057             [scroller setDirectionalScrolling:YES];
1058             // XXX: we might be better off /not/ setting this on older systems
1059             [scroller setScrollDecelerationFactor:CYScrollViewDecelerationRateNormal]; /* 0.989324 */
1060             [scroller setScrollHysteresis:0]; /* 8 */
1061
1062             [scroller setThumbDetectionEnabled:NO];
1063
1064             // use NO with UIApplicationUseLegacyEvents(YES)
1065             [scroller setEventMode:YES];
1066
1067             // XXX: this is handled by setBounces, right?
1068             //[scroller setAllowsRubberBanding:YES];
1069         }
1070
1071         [scroller_ setFixedBackgroundPattern:YES];
1072         [scroller_ setBackgroundColor:[UIColor groupTableViewBackgroundColor]];
1073         [scroller_ setClipsSubviews:YES];
1074
1075         [scroller_ setBounces:YES];
1076         [scroller_ setScrollingEnabled:YES];
1077         [scroller_ setShowBackgroundShadow:NO];
1078
1079         [self setViewportWidth:width];
1080
1081         reloaditem_ = [[UIBarButtonItem alloc]
1082             initWithTitle:UCLocalize("RELOAD")
1083             style:[self rightButtonStyle]
1084             target:self
1085             action:@selector(reloadButtonClicked)
1086         ];
1087
1088         loadingitem_ = [[UIBarButtonItem alloc]
1089             initWithTitle:@" "
1090             style:UIBarButtonItemStylePlain
1091             target:self
1092             action:@selector(reloadButtonClicked)
1093         ];
1094
1095         indicator_ = [[UIActivityIndicatorView alloc] initWithActivityIndicatorStyle:UIActivityIndicatorViewStyleWhite];
1096         [indicator_ setFrame:CGRectMake(15, 5, [indicator_ frame].size.width, [indicator_ frame].size.height)];
1097
1098         [webview_ setAutoresizingMask:(UIViewAutoresizingFlexibleWidth | UIViewAutoresizingFlexibleHeight)];
1099         [indicator_ setAutoresizingMask:UIViewAutoresizingFlexibleLeftMargin];
1100     } return self;
1101 }
1102
1103 - (id) initWithWidth:(float)width {
1104     return [self initWithWidth:width ofClass:[self class]];
1105 }
1106
1107 - (id) init {
1108     return [self initWithWidth:0];
1109 }
1110
1111 - (id) initWithURL:(NSURL *)url {
1112     if ((self = [self init]) != nil) {
1113         [self setURL:url];
1114     } return self;
1115 }
1116
1117 - (void) didDismissModalViewController {
1118     if (closer_ != nil)
1119         [self callFunction:closer_];
1120 }
1121
1122 - (void) callFunction:(WebScriptObject *)function {
1123     WebThreadLocked lock;
1124
1125     WebView *webview([[webview_ _documentView] webView]);
1126     WebFrame *frame([webview mainFrame]);
1127     WebPreferences *preferences([webview preferences]);
1128
1129     bool maybe([preferences javaScriptCanOpenWindowsAutomatically]);
1130     [preferences setJavaScriptCanOpenWindowsAutomatically:NO];
1131
1132     /*id _private(MSHookIvar<id>(webview, "_private"));
1133     WebCore::Page *page(_private == nil ? NULL : MSHookIvar<WebCore::Page *>(_private, "page"));
1134     WebCore::Settings *settings(page == NULL ? NULL : page->settings());
1135
1136     bool no;
1137     if (settings == NULL)
1138         no = 0;
1139     else {
1140         no = settings->JavaScriptCanOpenWindowsAutomatically();
1141         settings->setJavaScriptCanOpenWindowsAutomatically(true);
1142     }*/
1143
1144     if (UIWindow *window = [[self view] window])
1145         if (UIResponder *responder = [window firstResponder])
1146             [responder resignFirstResponder];
1147
1148     JSObjectRef object([function JSObject]);
1149     JSGlobalContextRef context([frame globalContext]);
1150     JSObjectCallAsFunction(context, object, NULL, 0, NULL, NULL);
1151
1152     /*if (settings != NULL)
1153         settings->setJavaScriptCanOpenWindowsAutomatically(no);*/
1154
1155     [preferences setJavaScriptCanOpenWindowsAutomatically:maybe];
1156 }
1157
1158 - (void) reloadButtonClicked {
1159     [self reloadURL];
1160 }
1161
1162 - (void) _customButtonClicked {
1163     [self reloadButtonClicked];
1164 }
1165
1166 - (void) customButtonClicked {
1167 #if !AlwaysReload
1168     if (function_ != nil)
1169         [self callFunction:function_];
1170     else
1171 #endif
1172     [self _customButtonClicked];
1173 }
1174
1175 + (float) defaultWidth {
1176     return 980;
1177 }
1178
1179 - (void) dispatchEvent:(NSString *)event {
1180     WebThreadLocked lock;
1181
1182     NSString *script([NSString stringWithFormat:@
1183         "(function() {"
1184             "var event = this.document.createEvent('Events');"
1185             "event.initEvent('%@', false, false);"
1186             "this.document.dispatchEvent(event);"
1187         "})();"
1188     , event]);
1189
1190     NSMutableArray *frames([NSMutableArray arrayWithObjects:
1191         [[[webview_ _documentView] webView] mainFrame]
1192     , nil]);
1193
1194     while (WebFrame *frame = [frames lastObject]) {
1195         WebScriptObject *object([frame windowObject]);
1196         [object evaluateWebScript:script];
1197         [frames removeLastObject];
1198         [frames addObjectsFromArray:[frame childFrames]];
1199     }
1200 }
1201
1202 - (void) viewWillAppear:(BOOL)animated {
1203     [self dispatchEvent:@"CydiaViewWillAppear"];
1204     [super viewWillAppear:animated];
1205 }
1206
1207 - (void) viewDidAppear:(BOOL)animated {
1208     [self dispatchEvent:@"CydiaViewDidAppear"];
1209     [super viewDidAppear:animated];
1210 }
1211
1212 - (void) viewWillDisappear:(BOOL)animated {
1213     [self dispatchEvent:@"CydiaViewWillDisappear"];
1214     [super viewWillDisappear:animated];
1215 }
1216
1217 - (void) viewDidDisappear:(BOOL)animated {
1218     [self dispatchEvent:@"CydiaViewDidDisappear"];
1219     [super viewDidDisappear:animated];
1220 }
1221
1222 @end