UICaboodle/BrowserView.mm

   1 #include <UIKit/UIKit.h>
   2 #include "iPhonePrivate.h"
   3
   4 #include "UCPlatform.h"
   5
   6 #include <UICaboodle/BrowserView.h>
   7 #include <UICaboodle/UCLocalize.h>
   8
   9 //#include <QuartzCore/CALayer.h>
  10 // XXX: fix the minimum requirement
  11 extern NSString * const kCAFilterNearest;
  12
  13 #include <WebCore/WebCoreThread.h>
  14
  15 #include <WebKit/WebPolicyDelegate.h>
  16 #include <WebKit/WebPreferences.h>
  17
  18 #include <WebKit/DOMCSSPrimitiveValue.h>
  19 #include <WebKit/DOMCSSStyleDeclaration.h>
  20 #include <WebKit/DOMDocument.h>
  21 #include <WebKit/DOMHTMLBodyElement.h>
  22 #include <WebKit/DOMRGBColor.h>
  23
  24 //#include <WebCore/Page.h>
  25 //#include <WebCore/Settings.h>
  26
  27 #include "substrate.h"
  28
  29 #define ForSaurik 0
  30 #define DefaultTimeout_ 120.0
  31
  32 #define ShowInternals 0
  33 #define LogBrowser 0
  34 #define LogMessages 0
  35
  36 #define lprintf(args...) fprintf(stderr, args)
  37
  38 // WebThreadLocked {{{
  39 struct WebThreadLocked {
  40     _finline WebThreadLocked() {
  41         WebThreadLock();
  42     }
  43
  44     _finline ~WebThreadLocked() {
  45         WebThreadUnlock();
  46     }
  47 };
  48 // }}}
  49
  50 template <typename Type_>
  51 static inline void CYRelease(Type_ &value) {
  52     if (value != nil) {
  53         [value release];
  54         value = nil;
  55     }
  56 }
  57
  58 float CYScrollViewDecelerationRateNormal;
  59
  60 @interface WebView (Apple)
  61 - (void) _setLayoutInterval:(float)interval;
  62 - (void) _setAllowsMessaging:(BOOL)allows;
  63 @end
  64
  65 @interface WebPreferences (Apple)
  66 + (void) _setInitialDefaultTextEncodingToSystemEncoding;
  67 - (void) _setLayoutInterval:(NSInteger)interval;
  68 - (void) setOfflineWebApplicationCacheEnabled:(BOOL)enabled;
  69 @end
  70
  71 /* Indirect Delegate {{{ */
  72 @interface IndirectDelegate : NSObject <
  73     HookProtocol
  74 > {
  75     _transient volatile id delegate_;
  76 }
  77
  78 - (void) setDelegate:(id)delegate;
  79 - (id) initWithDelegate:(id)delegate;
  80 @end
  81
  82 @implementation IndirectDelegate
  83
  84 - (void) setDelegate:(id)delegate {
  85     delegate_ = delegate;
  86 }
  87
  88 - (id) initWithDelegate:(id)delegate {
  89     delegate_ = delegate;
  90     return self;
  91 }
  92
  93 - (void) didDismissModalViewController {
  94     if (delegate_ != nil)
  95         return [delegate_ didDismissModalViewController];
  96 }
  97
  98 - (IMP) methodForSelector:(SEL)sel {
  99     if (IMP method = [super methodForSelector:sel])
 100         return method;
 101     fprintf(stderr, "methodForSelector:[%s] == NULL\n", sel_getName(sel));
 102     return NULL;
 103 }
 104
 105 - (BOOL) respondsToSelector:(SEL)sel {
 106     if ([super respondsToSelector:sel])
 107         return YES;
 108
 109     // XXX: WebThreadCreateNSInvocation returns nil
 110
 111 #if ShowInternals
 112     fprintf(stderr, "[%s]R?%s\n", class_getName(self->isa), sel_getName(sel));
 113 #endif
 114
 115     return delegate_ == nil ? NO : [delegate_ respondsToSelector:sel];
 116 }
 117
 118 - (NSMethodSignature *) methodSignatureForSelector:(SEL)sel {
 119     if (NSMethodSignature *method = [super methodSignatureForSelector:sel])
 120         return method;
 121
 122 #if ShowInternals
 123     fprintf(stderr, "[%s]S?%s\n", class_getName(self->isa), sel_getName(sel));
 124 #endif
 125
 126     if (delegate_ != nil)
 127         if (NSMethodSignature *sig = [delegate_ methodSignatureForSelector:sel])
 128             return sig;
 129
 130     // XXX: I fucking hate Apple so very very bad
 131     return [NSMethodSignature signatureWithObjCTypes:"v@:"];
 132 }
 133
 134 - (void) forwardInvocation:(NSInvocation *)inv {
 135     SEL sel = [inv selector];
 136     if (delegate_ != nil && [delegate_ respondsToSelector:sel])
 137         [inv invokeWithTarget:delegate_];
 138 }
 139
 140 @end
 141 /* }}} */
 142
 143 @implementation WebScriptObject (UICaboodle)
 144
 145 - (NSUInteger) count {
 146     id length([self valueForKey:@"length"]);
 147     if ([length respondsToSelector:@selector(intValue)])
 148         return [length intValue];
 149     else
 150         return 0;
 151 }
 152
 153 - (id) objectAtIndex:(unsigned)index {
 154     return [self webScriptValueAtIndex:index];
 155 }
 156
 157 @end
 158
 159 // CYWebPolicyDecision* {{{
 160 enum CYWebPolicyDecision {
 161     CYWebPolicyDecisionUnknown,
 162     CYWebPolicyDecisionDownload,
 163     CYWebPolicyDecisionIgnore,
 164     CYWebPolicyDecisionUse,
 165 };
 166
 167 @interface CYWebPolicyDecisionMediator : NSObject <
 168     WebPolicyDecisionListener
 169 > {
 170     id<WebPolicyDecisionListener> listener_;
 171     CYWebPolicyDecision decision_;
 172 }
 173
 174 - (id) initWithListener:(id<WebPolicyDecisionListener>)listener;
 175
 176 - (CYWebPolicyDecision) decision;
 177 - (bool) decided;
 178 - (bool) decide;
 179
 180 @end
 181
 182 @implementation CYWebPolicyDecisionMediator
 183
 184 - (id) initWithListener:(id<WebPolicyDecisionListener>)listener {
 185     if ((self = [super init]) != nil) {
 186         listener_ = listener;
 187     } return self;
 188 }
 189
 190 - (CYWebPolicyDecision) decision {
 191     return decision_;
 192 }
 193
 194 - (bool) decided {
 195     return decision_ != CYWebPolicyDecisionUnknown;
 196 }
 197
 198 - (bool) decide {
 199     switch (decision_) {
 200         case CYWebPolicyDecisionUnknown:
 201         default:
 202             NSLog(@"CYWebPolicyDecisionUnknown");
 203             return false;
 204
 205         case CYWebPolicyDecisionDownload: [listener_ download]; break;
 206         case CYWebPolicyDecisionIgnore: [listener_ ignore]; break;
 207         case CYWebPolicyDecisionUse: [listener_ use]; break;
 208     }
 209
 210     return true;
 211 }
 212
 213 - (void) download {
 214     decision_ = CYWebPolicyDecisionDownload;
 215 }
 216
 217 - (void) ignore {
 218     decision_ = CYWebPolicyDecisionIgnore;
 219 }
 220
 221 - (void) use {
 222     decision_ = CYWebPolicyDecisionUse;
 223 }
 224
 225 @end
 226 // }}}
 227
 228 @implementation CYWebView : UIWebView
 229
 230 #if ShowInternals
 231 #include "UICaboodle/UCInternal.h"
 232 #endif
 233
 234 - (id) initWithFrame:(CGRect)frame {
 235     if ((self = [super initWithFrame:frame]) != nil) {
 236     } return self;
 237 }
 238
 239 - (void) dealloc {
 240     [super dealloc];
 241 }
 242
 243 - (id<CYWebViewDelegate>) delegate {
 244     return (id<CYWebViewDelegate>) [super delegate];
 245 }
 246
 247 /*- (WebView *) webView:(WebView *)view createWebViewWithRequest:(NSURLRequest *)request {
 248     id<CYWebViewDelegate> delegate([self delegate]);
 249     WebView *created(nil);
 250     if (created == nil && [delegate respondsToSelector:@selector(webView:createWebViewWithRequest:)])
 251         created = [delegate webView:view createWebViewWithRequest:request];
 252     if (created == nil && [UIWebView instancesRespondToSelector:@selector(webView:createWebViewWithRequest:)])
 253         created = [super webView:view createWebViewWithRequest:request];
 254     return created;
 255 }*/
 256
 257 // webView:addMessageToConsole: (X.Xx) {{{
 258 static void $UIWebViewWebViewDelegate$webView$addMessageToConsole$(UIWebViewWebViewDelegate *self, SEL sel, WebView *view, NSDictionary *message) {
 259     UIWebView *uiWebView(MSHookIvar<UIWebView *>(self, "uiWebView"));
 260     if ([uiWebView respondsToSelector:@selector(webView:addMessageToConsole:)])
 261         [uiWebView webView:view addMessageToConsole:message];
 262 }
 263
 264 - (void) webView:(WebView *)view addMessageToConsole:(NSDictionary *)message {
 265     id<CYWebViewDelegate> delegate([self delegate]);
 266     if ([delegate respondsToSelector:@selector(webView:addMessageToConsole:)])
 267         [delegate webView:view addMessageToConsole:message];
 268     if ([UIWebView instancesRespondToSelector:@selector(webView:addMessageToConsole:)])
 269         [super webView:view addMessageToConsole:message];
 270 }
 271 // }}}
 272 // webView:decidePolicyForNavigationAction:request:frame:decisionListener: (2.0+) {{{
 273 - (void) webView:(WebView *)view decidePolicyForNavigationAction:(NSDictionary *)action request:(NSURLRequest *)request frame:(WebFrame *)frame decisionListener:(id<WebPolicyDecisionListener>)listener {
 274     id<CYWebViewDelegate> delegate([self delegate]);
 275     CYWebPolicyDecisionMediator *mediator([[[CYWebPolicyDecisionMediator alloc] initWithListener:listener] autorelease]);
 276     if (![mediator decided] && [delegate respondsToSelector:@selector(webView:decidePolicyForNavigationAction:request:frame:decisionListener:)])
 277         [delegate webView:view decidePolicyForNavigationAction:action request:request frame:frame decisionListener:mediator];
 278     if (![mediator decided] && [UIWebView instancesRespondToSelector:@selector(webView:decidePolicyForNavigationAction:request:frame:decisionListener:)])
 279         [super webView:view decidePolicyForNavigationAction:action request:request frame:frame decisionListener:mediator];
 280     [mediator decide];
 281 }
 282 // }}}
 283 // webView:decidePolicyForNewWindowAction:request:newFrameName:decisionListener: (3.0+) {{{
 284 static void $UIWebViewWebViewDelegate$webView$decidePolicyForNewWindowAction$request$newFrameName$decisionListener$(UIWebViewWebViewDelegate *self, SEL sel, WebView *view, NSDictionary *action, NSURLRequest *request, NSString *frame, id<WebPolicyDecisionListener> listener) {
 285     UIWebView *uiWebView(MSHookIvar<UIWebView *>(self, "uiWebView"));
 286     if ([uiWebView respondsToSelector:@selector(webView:decidePolicyForNewWindowAction:request:newFrameName:decisionListener:)])
 287         [uiWebView webView:view decidePolicyForNewWindowAction:action request:request newFrameName:frame decisionListener:listener];
 288 }
 289
 290 - (void) webView:(WebView *)view decidePolicyForNewWindowAction:(NSDictionary *)action request:(NSURLRequest *)request newFrameName:(NSString *)frame decisionListener:(id<WebPolicyDecisionListener>)listener {
 291     id<CYWebViewDelegate> delegate([self delegate]);
 292     CYWebPolicyDecisionMediator *mediator([[[CYWebPolicyDecisionMediator alloc] initWithListener:listener] autorelease]);
 293     if (![mediator decided] && [delegate respondsToSelector:@selector(webView:decidePolicyForNewWindowAction:request:newFrameName:decisionListener:)])
 294         [delegate webView:view decidePolicyForNewWindowAction:action request:request newFrameName:frame decisionListener:mediator];
 295     if (![mediator decided] && [UIWebView instancesRespondToSelector:@selector(webView:decidePolicyForNewWindowAction:request:newFrameName:decisionListener:)])
 296         [super webView:view decidePolicyForNewWindowAction:action request:request newFrameName:frame decisionListener:mediator];
 297     [mediator decide];
 298 }
 299 // }}}
 300 // webView:didClearWindowObject:forFrame: (3.2+) {{{
 301 static void $UIWebViewWebViewDelegate$webView$didClearWindowObject$forFrame$(UIWebViewWebViewDelegate *self, SEL sel, WebView *view, WebScriptObject *window, WebFrame *frame) {
 302     UIWebView *uiWebView(MSHookIvar<UIWebView *>(self, "uiWebView"));
 303     if ([uiWebView respondsToSelector:@selector(webView:didClearWindowObject:forFrame:)])
 304         [uiWebView webView:view didClearWindowObject:window forFrame:frame];
 305 }
 306
 307 - (void) webView:(WebView *)view didClearWindowObject:(WebScriptObject *)window forFrame:(WebFrame *)frame {
 308     id<CYWebViewDelegate> delegate([self delegate]);
 309     if ([delegate respondsToSelector:@selector(webView:didClearWindowObject:forFrame:)])
 310         [delegate webView:view didClearWindowObject:window forFrame:frame];
 311     if ([UIWebView instancesRespondToSelector:@selector(webView:didClearWindowObject:forFrame:)])
 312         [super webView:view didClearWindowObject:window forFrame:frame];
 313 }
 314 // }}}
 315 // webView:didFailLoadWithError:forFrame: (2.0+) {{{
 316 - (void) webView:(WebView *)view didFailLoadWithError:(NSError *)error forFrame:(WebFrame *)frame {
 317     id<CYWebViewDelegate> delegate([self delegate]);
 318     if ([delegate respondsToSelector:@selector(webView:didFailLoadWithError:forFrame:)])
 319         [delegate webView:view didFailLoadWithError:error forFrame:frame];
 320     if ([UIWebView instancesRespondToSelector:@selector(webView:didFailLoadWithError:forFrame:)])
 321         [super webView:view didFailLoadWithError:error forFrame:frame];
 322 }
 323 // }}}
 324 // webView:didFailProvisionalLoadWithError:forFrame: (2.0+) {{{
 325 - (void) webView:(WebView *)view didFailProvisionalLoadWithError:(NSError *)error forFrame:(WebFrame *)frame {
 326     id<CYWebViewDelegate> delegate([self delegate]);
 327     if ([delegate respondsToSelector:@selector(webView:didFailProvisionalLoadWithError:forFrame:)])
 328         [delegate webView:view didFailProvisionalLoadWithError:error forFrame:frame];
 329     if ([UIWebView instancesRespondToSelector:@selector(webView:didFailProvisionalLoadWithError:forFrame:)])
 330         [super webView:view didFailProvisionalLoadWithError:error forFrame:frame];
 331 }
 332 // }}}
 333 // webView:didFinishLoadForFrame: (2.0+) {{{
 334 - (void) webView:(WebView *)view didFinishLoadForFrame:(WebFrame *)frame {
 335     id<CYWebViewDelegate> delegate([self delegate]);
 336     if ([delegate respondsToSelector:@selector(webView:didFinishLoadForFrame:)])
 337         [delegate webView:view didFinishLoadForFrame:frame];
 338     if ([UIWebView instancesRespondToSelector:@selector(webView:didFinishLoadForFrame:)])
 339         [super webView:view didFinishLoadForFrame:frame];
 340 }
 341 // }}}
 342 // webView:didReceiveTitle:forFrame: (3.2+) {{{
 343 static void $UIWebViewWebViewDelegate$webView$didReceiveTitle$forFrame$(UIWebViewWebViewDelegate *self, SEL sel, WebView *view, NSString *title, WebFrame *frame) {
 344     UIWebView *uiWebView(MSHookIvar<UIWebView *>(self, "uiWebView"));
 345     if ([uiWebView respondsToSelector:@selector(webView:didReceiveTitle:forFrame:)])
 346         [uiWebView webView:view didReceiveTitle:title forFrame:frame];
 347 }
 348
 349 - (void) webView:(WebView *)view didReceiveTitle:(NSString *)title forFrame:(WebFrame *)frame {
 350     id<CYWebViewDelegate> delegate([self delegate]);
 351     if ([delegate respondsToSelector:@selector(webView:didReceiveTitle:forFrame:)])
 352         [delegate webView:view didReceiveTitle:title forFrame:frame];
 353     if ([UIWebView instancesRespondToSelector:@selector(webView:didReceiveTitle:forFrame:)])
 354         [super webView:view didReceiveTitle:title forFrame:frame];
 355 }
 356 // }}}
 357 // webView:didStartProvisionalLoadForFrame: (2.0+) {{{
 358 - (void) webView:(WebView *)view didStartProvisionalLoadForFrame:(WebFrame *)frame {
 359     id<CYWebViewDelegate> delegate([self delegate]);
 360     if ([delegate respondsToSelector:@selector(webView:didStartProvisionalLoadForFrame:)])
 361         [delegate webView:view didStartProvisionalLoadForFrame:frame];
 362     if ([UIWebView instancesRespondToSelector:@selector(webView:didStartProvisionalLoadForFrame:)])
 363         [super webView:view didStartProvisionalLoadForFrame:frame];
 364 }
 365 // }}}
 366 // webView:resource:willSendRequest:redirectResponse:fromDataSource: (3.2+) {{{
 367 static NSURLRequest *$UIWebViewWebViewDelegate$webView$resource$willSendRequest$redirectResponse$fromDataSource$(UIWebViewWebViewDelegate *self, SEL sel, WebView *view, id identifier, NSURLRequest *request, NSURLResponse *response, WebDataSource *source) {
 368     UIWebView *uiWebView(MSHookIvar<UIWebView *>(self, "uiWebView"));
 369     if ([uiWebView respondsToSelector:@selector(webView:resource:willSendRequest:redirectResponse:fromDataSource:)])
 370         request = [uiWebView webView:view resource:identifier willSendRequest:request redirectResponse:response fromDataSource:source];
 371     return request;
 372 }
 373
 374 - (NSURLRequest *) webView:(WebView *)view resource:(id)identifier willSendRequest:(NSURLRequest *)request redirectResponse:(NSURLResponse *)response fromDataSource:(WebDataSource *)source {
 375     id<CYWebViewDelegate> delegate([self delegate]);
 376     if ([UIWebView instancesRespondToSelector:@selector(webView:resource:willSendRequest:redirectResponse:fromDataSource:)])
 377         request = [super webView:view resource:identifier willSendRequest:request redirectResponse:response fromDataSource:source];
 378     if ([delegate respondsToSelector:@selector(webView:resource:willSendRequest:redirectResponse:fromDataSource:)])
 379         request = [delegate webView:view resource:identifier willSendRequest:request redirectResponse:response fromDataSource:source];
 380     return request;
 381 }
 382 // }}}
 383 // webView:runJavaScriptAlertPanelWithMessage:initiatedByFrame: (2.1+) {{{
 384 - (void) webView:(WebView *)view runJavaScriptAlertPanelWithMessage:(NSString *)message initiatedByFrame:(WebFrame *)frame {
 385     id<CYWebViewDelegate> delegate([self delegate]);
 386     if ([UIWebView instancesRespondToSelector:@selector(webView:runJavaScriptAlertPanelWithMessage:initiatedByFrame:)])
 387         if (
 388             ![delegate respondsToSelector:@selector(webView:shouldRunJavaScriptAlertPanelWithMessage:initiatedByFrame:)] ||
 389             [delegate webView:view shouldRunJavaScriptAlertPanelWithMessage:message initiatedByFrame:frame]
 390         )
 391             [super webView:view runJavaScriptAlertPanelWithMessage:message initiatedByFrame:frame];
 392 }
 393 // }}}
 394 // webView:runJavaScriptConfirmPanelWithMessage:initiatedByFrame: (2.1+) {{{
 395 - (BOOL) webView:(WebView *)view runJavaScriptConfirmPanelWithMessage:(NSString *)message initiatedByFrame:(WebFrame *)frame {
 396     id<CYWebViewDelegate> delegate([self delegate]);
 397     if ([UIWebView instancesRespondToSelector:@selector(webView:runJavaScriptConfirmPanelWithMessage:initiatedByFrame:)])
 398         if (
 399             ![delegate respondsToSelector:@selector(webView:shouldRunJavaScriptConfirmPanelWithMessage:initiatedByFrame:)] ||
 400             [delegate webView:view shouldRunJavaScriptConfirmPanelWithMessage:message initiatedByFrame:frame]
 401         )
 402             return [super webView:view runJavaScriptConfirmPanelWithMessage:message initiatedByFrame:frame];
 403     return NO;
 404 }
 405 // }}}
 406 // webView:runJavaScriptTextInputPanelWithPrompt:defaultText:initiatedByFrame: (2.1+) {{{
 407 - (NSString *) webView:(WebView *)view runJavaScriptTextInputPanelWithPrompt:(NSString *)prompt defaultText:(NSString *)text initiatedByFrame:(WebFrame *)frame {
 408     id<CYWebViewDelegate> delegate([self delegate]);
 409     if ([UIWebView instancesRespondToSelector:@selector(webView:runJavaScriptTextInputPanelWithPrompt:defaultText:initiatedByFrame:)])
 410         if (
 411             ![delegate respondsToSelector:@selector(webView:shouldRunJavaScriptTextInputPanelWithPrompt:defaultText:initiatedByFrame:)] ||
 412             [delegate webView:view shouldRunJavaScriptTextInputPanelWithPrompt:prompt defaultText:text initiatedByFrame:frame]
 413         )
 414             return [super webView:view runJavaScriptTextInputPanelWithPrompt:prompt defaultText:text initiatedByFrame:frame];
 415     return nil;
 416 }
 417 // }}}
 418 // webViewClose: (3.2+) {{{
 419 static void $UIWebViewWebViewDelegate$webViewClose$(UIWebViewWebViewDelegate *self, SEL sel, WebView *view) {
 420     UIWebView *uiWebView(MSHookIvar<UIWebView *>(self, "uiWebView"));
 421     if ([uiWebView respondsToSelector:@selector(webViewClose:)])
 422         [uiWebView webViewClose:view];
 423 }
 424
 425 - (void) webViewClose:(WebView *)view {
 426     id<CYWebViewDelegate> delegate([self delegate]);
 427     if ([delegate respondsToSelector:@selector(webViewClose:)])
 428         [delegate webViewClose:view];
 429     if ([UIWebView instancesRespondToSelector:@selector(webViewClose:)])
 430         [super webViewClose:view];
 431 }
 432 // }}}
 433
 434 - (void) _updateViewSettings {
 435     [super _updateViewSettings];
 436
 437     id<CYWebViewDelegate> delegate([self delegate]);
 438     if ([delegate respondsToSelector:@selector(webViewUpdateViewSettings:)])
 439         [delegate webViewUpdateViewSettings:self];
 440 }
 441
 442 + (void) initialize {
 443     if (Class $UIWebViewWebViewDelegate = objc_getClass("UIWebViewWebViewDelegate")) {
 444         class_addMethod($UIWebViewWebViewDelegate, @selector(webView:addMessageToConsole:), (IMP) &$UIWebViewWebViewDelegate$webView$addMessageToConsole$, "v16@0:4@8@12");
 445         class_addMethod($UIWebViewWebViewDelegate, @selector(webView:decidePolicyForNewWindowAction:request:newFrameName:decisionListener:), (IMP) &$UIWebViewWebViewDelegate$webView$decidePolicyForNewWindowAction$request$newFrameName$decisionListener$, "v28@0:4@8@12@16@20@24");
 446         class_addMethod($UIWebViewWebViewDelegate, @selector(webView:didClearWindowObject:forFrame:), (IMP) &$UIWebViewWebViewDelegate$webView$didClearWindowObject$forFrame$, "v20@0:4@8@12@16");
 447         class_addMethod($UIWebViewWebViewDelegate, @selector(webView:didReceiveTitle:forFrame:), (IMP) &$UIWebViewWebViewDelegate$webView$didReceiveTitle$forFrame$, "v20@0:4@8@12@16");
 448         class_addMethod($UIWebViewWebViewDelegate, @selector(webView:resource:willSendRequest:redirectResponse:fromDataSource:), (IMP) &$UIWebViewWebViewDelegate$webView$resource$willSendRequest$redirectResponse$fromDataSource$, "@28@0:4@8@12@16@20@24");
 449         class_addMethod($UIWebViewWebViewDelegate, @selector(webViewClose:), (IMP) &$UIWebViewWebViewDelegate$webViewClose$, "v12@0:4@8");
 450     }
 451 }
 452
 453 @end
 454
 455 @implementation BrowserController
 456
 457 #if ShowInternals
 458 #include "UICaboodle/UCInternal.h"
 459 #endif
 460
 461 + (void) _initialize {
 462     [WebPreferences _setInitialDefaultTextEncodingToSystemEncoding];
 463
 464     if (float *_UIScrollViewDecelerationRateNormal = reinterpret_cast<float *>(dlsym(RTLD_DEFAULT, "UIScrollViewDecelerationRateNormal")))
 465         CYScrollViewDecelerationRateNormal = *_UIScrollViewDecelerationRateNormal;
 466     else // XXX: this actually might be fast on some older systems: we should look into this
 467         CYScrollViewDecelerationRateNormal = 0.998;
 468 }
 469
 470 - (void) dealloc {
 471 #if LogBrowser
 472     NSLog(@"[BrowserController dealloc]");
 473 #endif
 474
 475     [webview_ setDelegate:nil];
 476
 477     [indirect_ setDelegate:nil];
 478     [indirect_ release];
 479
 480     if (challenge_ != nil)
 481         [challenge_ release];
 482
 483     if (closer_ != nil)
 484         [closer_ release];
 485
 486     if (title_ != nil)
 487         [title_ release];
 488
 489     if ([loading_ count] != 0)
 490         [delegate_ releaseNetworkActivityIndicator];
 491     [loading_ release];
 492
 493     [reloaditem_ release];
 494     [loadingitem_ release];
 495
 496     [indicator_ release];
 497
 498     [super dealloc];
 499 }
 500
 501 - (void) setURL:(NSURL *)url {
 502     _assert(request_ == nil);
 503
 504     request_ = [NSURLRequest
 505         requestWithURL:url
 506         cachePolicy:NSURLRequestUseProtocolCachePolicy
 507         timeoutInterval:DefaultTimeout_
 508     ];
 509 }
 510
 511 - (void) loadURL:(NSURL *)url cachePolicy:(NSURLRequestCachePolicy)policy {
 512     [self loadRequest:[NSURLRequest
 513         requestWithURL:url
 514         cachePolicy:policy
 515         timeoutInterval:DefaultTimeout_
 516     ]];
 517 }
 518
 519 - (void) loadURL:(NSURL *)url {
 520     [self loadURL:url cachePolicy:NSURLRequestUseProtocolCachePolicy];
 521 }
 522
 523 - (void) loadRequest:(NSURLRequest *)request {
 524 #if LogBrowser
 525     NSLog(@"loadRequest:%@", request);
 526 #endif
 527
 528     error_ = false;
 529
 530     WebThreadLocked lock;
 531     [webview_ loadRequest:request];
 532 }
 533
 534 - (void) reloadURLWithCache:(BOOL)cache {
 535     if (request_ == nil)
 536         return;
 537
 538     NSMutableURLRequest *request([request_ mutableCopy]);
 539     [request setCachePolicy:(cache ? NSURLRequestUseProtocolCachePolicy : NSURLRequestReloadIgnoringLocalCacheData)];
 540
 541     request_ = request;
 542
 543     if ([request_ HTTPBody] == nil && [request_ HTTPBodyStream] == nil)
 544         [self loadRequest:request_];
 545     else {
 546         UIAlertView *alert = [[[UIAlertView alloc]
 547             initWithTitle:UCLocalize("RESUBMIT_FORM")
 548             message:nil
 549             delegate:self
 550             cancelButtonTitle:UCLocalize("CANCEL")
 551             otherButtonTitles:
 552                 UCLocalize("SUBMIT"),
 553             nil
 554         ] autorelease];
 555
 556         [alert setContext:@"submit"];
 557         [alert show];
 558     }
 559 }
 560
 561 - (void) reloadURL {
 562     [self reloadURLWithCache:YES];
 563 }
 564
 565 - (void) reloadData {
 566     [super reloadData];
 567     [self reloadURLWithCache:YES];
 568 }
 569
 570 - (void) setButtonImage:(NSString *)button withStyle:(NSString *)style toFunction:(id)function {
 571     custom_ = button;
 572     style_ = style;
 573     function_ = function;
 574
 575     [self performSelectorOnMainThread:@selector(applyRightButton) withObject:nil waitUntilDone:NO];
 576 }
 577
 578 - (void) setButtonTitle:(NSString *)button withStyle:(NSString *)style toFunction:(id)function {
 579     custom_ = button;
 580     style_ = style;
 581     function_ = function;
 582
 583     [self performSelectorOnMainThread:@selector(applyRightButton) withObject:nil waitUntilDone:NO];
 584 }
 585
 586 - (void) removeButton {
 587     custom_ = [NSNull null];
 588     [self performSelectorOnMainThread:@selector(applyRightButton) withObject:nil waitUntilDone:NO];
 589 }
 590
 591 - (void) setPopupHook:(id)function {
 592     if (closer_ != nil)
 593         [closer_ autorelease];
 594     if (function == nil)
 595         closer_ = nil;
 596     else
 597         closer_ = [function retain];
 598 }
 599
 600 - (void) scrollToBottomAnimated:(NSNumber *)animated {
 601     CGSize size([scroller_ contentSize]);
 602     CGPoint offset([scroller_ contentOffset]);
 603     CGRect frame([scroller_ frame]);
 604
 605     if (size.height - offset.y < frame.size.height + 20.f) {
 606         CGRect rect = {{0, size.height-1}, {size.width, 1}};
 607         [scroller_ scrollRectToVisible:rect animated:[animated boolValue]];
 608     }
 609 }
 610
 611 - (void) _setViewportWidth {
 612     [[webview_ _documentView] setViewportSize:CGSizeMake(width_, UIWebViewGrowsAndShrinksToFitHeight) forDocumentTypes:0x10];
 613 }
 614
 615 - (void) setViewportWidth:(float)width {
 616     width_ = width != 0 ? width : [[self class] defaultWidth];
 617     [self _setViewportWidth];
 618 }
 619
 620 - (void) _setViewportWidthOnMainThread:(NSNumber *)width {
 621     [self setViewportWidth:[width floatValue]];
 622 }
 623
 624 - (void) setViewportWidthOnMainThread:(float)width {
 625     [self performSelectorOnMainThread:@selector(_setViewportWidthOnMainThread:) withObject:[NSNumber numberWithFloat:width] waitUntilDone:NO];
 626 }
 627
 628 - (void) webViewUpdateViewSettings:(UIWebView *)view {
 629     [self _setViewportWidth];
 630 }
 631
 632 - (void) _openMailToURL:(NSURL *)url {
 633     [[UIApplication sharedApplication] openURL:url];// asPanel:YES];
 634 }
 635
 636 - (bool) _allowJavaScriptPanel {
 637     return true;
 638 }
 639
 640 - (bool) allowsNavigationAction {
 641     return allowsNavigationAction_;
 642 }
 643
 644 - (void) setAllowsNavigationAction:(bool)value {
 645     allowsNavigationAction_ = value;
 646 }
 647
 648 - (void) setAllowsNavigationActionByNumber:(NSNumber *)value {
 649     [self setAllowsNavigationAction:[value boolValue]];
 650 }
 651
 652 - (void) _didFailWithError:(NSError *)error forFrame:(WebFrame *)frame {
 653     [loading_ removeObject:[NSValue valueWithNonretainedObject:frame]];
 654     [self _didFinishLoading];
 655
 656     if ([error code] == NSURLErrorCancelled)
 657         return;
 658
 659     if ([frame parentFrame] == nil) {
 660         [self loadURL:[NSURL URLWithString:[NSString stringWithFormat:@"%@?%@",
 661             [[NSURL fileURLWithPath:[[NSBundle mainBundle] pathForResource:@"error" ofType:@"html"]] absoluteString],
 662             [[error localizedDescription] stringByAddingPercentEscapes]
 663         ]]];
 664
 665         error_ = true;
 666     }
 667 }
 668
 669 - (void) pushRequest:(NSURLRequest *)request asPop:(bool)pop {
 670     NSURL *url([request URL]);
 671
 672     // XXX: filter to internal usage?
 673     CYViewController *page([delegate_ pageForURL:url forExternal:NO]);
 674
 675     if (page == nil) {
 676         BrowserController *browser([[[class_ alloc] init] autorelease]);
 677         [browser loadRequest:request];
 678         page = browser;
 679     }
 680
 681     [page setDelegate:delegate_];
 682
 683     if (!pop) {
 684         [[self navigationItem] setTitle:title_];
 685
 686         [[self navigationController] pushViewController:page animated:YES];
 687     } else {
 688         UCNavigationController *navigation([[[UCNavigationController alloc] initWithRootViewController:page] autorelease]);
 689
 690         [navigation setHook:indirect_];
 691         [navigation setDelegate:delegate_];
 692
 693         [[page navigationItem] setLeftBarButtonItem:[[[UIBarButtonItem alloc]
 694             initWithTitle:UCLocalize("CLOSE")
 695             style:UIBarButtonItemStylePlain
 696             target:page
 697             action:@selector(close)
 698         ] autorelease]];
 699
 700         [[self navigationController] presentModalViewController:navigation animated:YES];
 701     }
 702 }
 703
 704 // CYWebViewDelegate {{{
 705 - (void) webView:(WebView *)view addMessageToConsole:(NSDictionary *)message {
 706 #if LogMessages
 707     NSLog(@"addMessageToConsole:%@", message);
 708 #endif
 709 }
 710
 711 - (void) webView:(WebView *)view decidePolicyForNavigationAction:(NSDictionary *)action request:(NSURLRequest *)request frame:(WebFrame *)frame decisionListener:(id<WebPolicyDecisionListener>)listener {
 712 #if LogBrowser
 713     NSLog(@"decidePolicyForNavigationAction:%@ request:%@ frame:%@", action, request, frame);
 714 #endif
 715
 716     if ([frame parentFrame] == nil) {
 717         if (!error_) {
 718             NSURL *url(request == nil ? nil : [request URL]);
 719
 720             if (request_ == nil || [self allowsNavigationAction] || [[request_ URL] isEqual:url])
 721                 request_ = request;
 722             else {
 723                 if (url != nil)
 724                     [self pushRequest:request asPop:NO];
 725                 [listener ignore];
 726             }
 727         }
 728     }
 729 }
 730
 731 - (void) webView:(WebView *)view decidePolicyForNewWindowAction:(NSDictionary *)action request:(NSURLRequest *)request newFrameName:(NSString *)frame decisionListener:(id<WebPolicyDecisionListener>)listener {
 732 #if LogBrowser
 733     NSLog(@"decidePolicyForNewWindowAction:%@ request:%@ newFrameName:%@", action, request, frame);
 734 #endif
 735
 736     NSURL *url([request URL]);
 737     if (url == nil)
 738         return;
 739
 740     if ([frame isEqualToString:@"_open"])
 741         [delegate_ openURL:url];
 742     else {
 743         NSString *scheme([[url scheme] lowercaseString]);
 744         if ([scheme isEqualToString:@"mailto"])
 745             [self _openMailToURL:url];
 746         else
 747             [self pushRequest:request asPop:[frame isEqualToString:@"_popup"]];
 748     }
 749
 750     [listener ignore];
 751 }
 752
 753 - (void) webView:(WebView *)view didClearWindowObject:(WebScriptObject *)window forFrame:(WebFrame *)frame {
 754 }
 755
 756 - (void) webView:(WebView *)view didFailLoadWithError:(NSError *)error forFrame:(WebFrame *)frame {
 757 #if LogBrowser
 758     NSLog(@"didFailLoadWithError:%@ forFrame:%@", error, frame);
 759 #endif
 760
 761     [self _didFailWithError:error forFrame:frame];
 762 }
 763
 764 - (void) webView:(WebView *)view didFailProvisionalLoadWithError:(NSError *)error forFrame:(WebFrame *)frame {
 765 #if LogBrowser
 766     NSLog(@"didFailProvisionalLoadWithError:%@ forFrame:%@", error, frame);
 767 #endif
 768
 769     [self _didFailWithError:error forFrame:frame];
 770 }
 771
 772 - (void) webView:(WebView *)view didFinishLoadForFrame:(WebFrame *)frame {
 773     [loading_ removeObject:[NSValue valueWithNonretainedObject:frame]];
 774
 775     if ([frame parentFrame] == nil) {
 776         if (DOMDocument *document = [frame DOMDocument])
 777             if (DOMNodeList<NSFastEnumeration> *bodies = [document getElementsByTagName:@"body"])
 778                 for (DOMHTMLBodyElement *body in (id) bodies) {
 779                     DOMCSSStyleDeclaration *style([document getComputedStyle:body pseudoElement:nil]);
 780
 781                     UIColor *uic(nil);
 782
 783                     if (DOMCSSPrimitiveValue *color = static_cast<DOMCSSPrimitiveValue *>([style getPropertyCSSValue:@"background-color"])) {
 784                         if ([color primitiveType] == DOM_CSS_RGBCOLOR) {
 785                             DOMRGBColor *rgb([color getRGBColorValue]);
 786
 787                             float red([[rgb red] getFloatValue:DOM_CSS_NUMBER]);
 788                             float green([[rgb green] getFloatValue:DOM_CSS_NUMBER]);
 789                             float blue([[rgb blue] getFloatValue:DOM_CSS_NUMBER]);
 790                             float alpha([[rgb alpha] getFloatValue:DOM_CSS_NUMBER]);
 791
 792                             if (red == 0xc7 && green == 0xce && blue == 0xd5)
 793                                 uic = [UIColor pinStripeColor];
 794                             else if (alpha != 0)
 795                                 uic = [UIColor
 796                                     colorWithRed:(red / 255)
 797                                     green:(green / 255)
 798                                     blue:(blue / 255)
 799                                     alpha:alpha
 800                                 ];
 801                         }
 802                     }
 803
 804                     [scroller_ setBackgroundColor:(uic ?: [UIColor clearColor])];
 805                     break;
 806                 }
 807     }
 808
 809     [self _didFinishLoading];
 810 }
 811
 812 - (void) webView:(WebView *)view didReceiveTitle:(NSString *)title forFrame:(WebFrame *)frame {
 813     if ([frame parentFrame] != nil)
 814         return;
 815
 816     if (title_ != nil)
 817         [title_ autorelease];
 818     title_ = [title retain];
 819
 820     [[self navigationItem] setTitle:title_];
 821 }
 822
 823 - (void) webView:(WebView *)view didStartProvisionalLoadForFrame:(WebFrame *)frame {
 824     [loading_ addObject:[NSValue valueWithNonretainedObject:frame]];
 825
 826     if ([frame parentFrame] == nil) {
 827         CYRelease(title_);
 828         custom_ = nil;
 829         style_ = nil;
 830         function_ = nil;
 831         CYRelease(closer_);
 832
 833         [self setHidesNavigationBar:NO];
 834
 835         // XXX: do we still need to do this?
 836         [[self navigationItem] setTitle:nil];
 837     }
 838
 839     [self _didStartLoading];
 840 }
 841
 842 - (NSURLRequest *) webView:(WebView *)view resource:(id)identifier willSendRequest:(NSURLRequest *)request redirectResponse:(NSURLResponse *)response fromDataSource:(WebDataSource *)source {
 843 #if LogBrowser
 844     NSLog(@"resource:%@ willSendRequest:%@ redirectResponse:%@ fromDataSource:%@", identifier, request, response, source);
 845 #endif
 846
 847     return request;
 848 }
 849
 850 - (bool) webView:(WebView *)view shouldRunJavaScriptAlertPanelWithMessage:(NSString *)message initiatedByFrame:(WebFrame *)frame {
 851     return [self _allowJavaScriptPanel];
 852 }
 853
 854 - (bool) webView:(WebView *)view shouldRunJavaScriptConfirmPanelWithMessage:(NSString *)message initiatedByFrame:(WebFrame *)frame {
 855     return [self _allowJavaScriptPanel];
 856 }
 857
 858 - (bool) webView:(WebView *)view shouldRunJavaScriptTextInputPanelWithPrompt:(NSString *)prompt defaultText:(NSString *)text initiatedByFrame:(WebFrame *)frame {
 859     return [self _allowJavaScriptPanel];
 860 }
 861
 862 - (void) webViewClose:(WebView *)view {
 863     [self close];
 864 }
 865 // }}}
 866
 867 - (void) close {
 868     [[self navigationController] dismissModalViewControllerAnimated:YES];
 869 }
 870
 871 - (void) alertView:(UIAlertView *)alert clickedButtonAtIndex:(NSInteger)button {
 872     NSString *context([alert context]);
 873
 874     if ([context isEqualToString:@"sensitive"]) {
 875         switch (button) {
 876             case 1:
 877                 sensitive_ = [NSNumber numberWithBool:YES];
 878             break;
 879
 880             case 2:
 881                 sensitive_ = [NSNumber numberWithBool:NO];
 882             break;
 883         }
 884
 885         [alert dismissWithClickedButtonIndex:-1 animated:YES];
 886     } else if ([context isEqualToString:@"challenge"]) {
 887         id<NSURLAuthenticationChallengeSender> sender([challenge_ sender]);
 888
 889         switch (button) {
 890             case 1: {
 891                 NSString *username([[alert textFieldAtIndex:0] text]);
 892                 NSString *password([[alert textFieldAtIndex:1] text]);
 893
 894                 NSURLCredential *credential([NSURLCredential credentialWithUser:username password:password persistence:NSURLCredentialPersistenceForSession]);
 895
 896                 [sender useCredential:credential forAuthenticationChallenge:challenge_];
 897             } break;
 898
 899             case 2:
 900                 [sender cancelAuthenticationChallenge:challenge_];
 901             break;
 902
 903             _nodefault
 904         }
 905
 906         [challenge_ release];
 907         challenge_ = nil;
 908
 909         [alert dismissWithClickedButtonIndex:-1 animated:YES];
 910     } else if ([context isEqualToString:@"submit"]) {
 911         if (button == [alert cancelButtonIndex]) {
 912         } else if (button == [alert firstOtherButtonIndex]) {
 913             if (request_ != nil) {
 914                 WebThreadLocked lock;
 915                 [webview_ loadRequest:request_];
 916             }
 917         }
 918
 919         [alert dismissWithClickedButtonIndex:-1 animated:YES];
 920     }
 921 }
 922
 923 - (UIBarButtonItemStyle) rightButtonStyle {
 924     if (style_ == nil) normal:
 925         return UIBarButtonItemStylePlain;
 926     else if ([style_ isEqualToString:@"Normal"])
 927         return UIBarButtonItemStylePlain;
 928     else if ([style_ isEqualToString:@"Highlighted"])
 929         return UIBarButtonItemStyleDone;
 930     else goto normal;
 931 }
 932
 933 - (UIBarButtonItem *) customButton {
 934     return custom_ == [NSNull null] ? nil : [[[UIBarButtonItem alloc]
 935         initWithTitle:static_cast<NSString *>(custom_.operator NSObject *())
 936         style:[self rightButtonStyle]
 937         target:self
 938         action:@selector(customButtonClicked)
 939     ] autorelease];
 940 }
 941
 942 - (UIBarButtonItem *) rightButton {
 943     return reloaditem_;
 944 }
 945
 946 - (void) applyLoadingTitle {
 947     [[self navigationItem] setTitle:UCLocalize("LOADING")];
 948 }
 949
 950 - (void) layoutRightButton {
 951     [[loadingitem_ view] addSubview:indicator_];
 952     [[loadingitem_ view] bringSubviewToFront:indicator_];
 953 }
 954
 955 - (void) applyRightButton {
 956     if ([self isLoading]) {
 957         [[self navigationItem] setRightBarButtonItem:loadingitem_ animated:YES];
 958         [self performSelector:@selector(layoutRightButton) withObject:nil afterDelay:0];
 959
 960         [indicator_ startAnimating];
 961         [self applyLoadingTitle];
 962     } else {
 963         [indicator_ stopAnimating];
 964
 965         [[self navigationItem] setRightBarButtonItem:(
 966             custom_ != nil ? [self customButton] : [self rightButton]
 967         ) animated:YES];
 968     }
 969 }
 970
 971 - (void) didStartLoading {
 972     // Overridden in subclasses.
 973 }
 974
 975 - (void) _didStartLoading {
 976     [self applyRightButton];
 977
 978     if ([loading_ count] != 1)
 979         return;
 980
 981     [delegate_ retainNetworkActivityIndicator];
 982     [self didStartLoading];
 983 }
 984
 985 - (void) didFinishLoading {
 986     // Overridden in subclasses.
 987 }
 988
 989 - (void) _didFinishLoading {
 990     if ([loading_ count] != 0)
 991         return;
 992
 993     [self applyRightButton];
 994     [[self navigationItem] setTitle:title_];
 995
 996     [delegate_ releaseNetworkActivityIndicator];
 997     [self didFinishLoading];
 998 }
 999
1000 - (bool) isLoading {
1001     return [loading_ count] != 0;
1002 }
1003
1004 - (id) initWithWidth:(float)width ofClass:(Class)_class {
1005     if ((self = [super init]) != nil) {
1006         allowsNavigationAction_ = true;
1007
1008         class_ = _class;
1009         loading_ = [[NSMutableSet alloc] initWithCapacity:5];
1010
1011         indirect_ = [[IndirectDelegate alloc] initWithDelegate:self];
1012
1013         CGRect bounds([[self view] bounds]);
1014
1015         webview_ = [[[CYWebView alloc] initWithFrame:bounds] autorelease];
1016         [webview_ setDelegate:self];
1017         [self setView:webview_];
1018
1019         if ([webview_ respondsToSelector:@selector(setDataDetectorTypes:)])
1020             [webview_ setDataDetectorTypes:UIDataDetectorTypeAutomatic];
1021         else
1022             [webview_ setDetectsPhoneNumbers:NO];
1023
1024         [webview_ setScalesPageToFit:YES];
1025
1026         UIWebDocumentView *document([webview_ _documentView]);
1027
1028         // XXX: I think this improves scrolling; the hardcoded-ness sucks
1029         [document setTileSize:CGSizeMake(320, 500)];
1030
1031         [document setBackgroundColor:[UIColor clearColor]];
1032
1033         // XXX: this is terribly (too?) expensive
1034         [document setDrawsBackground:NO];
1035
1036         WebView *webview([document webView]);
1037         WebPreferences *preferences([webview preferences]);
1038
1039         // XXX: I have no clue if I actually /want/ this modification
1040         if ([webview respondsToSelector:@selector(_setLayoutInterval:)])
1041             [webview _setLayoutInterval:0];
1042         else if ([preferences respondsToSelector:@selector(_setLayoutInterval:)])
1043             [preferences _setLayoutInterval:0];
1044
1045         [preferences setCacheModel:WebCacheModelDocumentBrowser];
1046         [preferences setOfflineWebApplicationCacheEnabled:YES];
1047
1048 #if LogMessages
1049         if ([document respondsToSelector:@selector(setAllowsMessaging:)])
1050             [document setAllowsMessaging:YES];
1051         if ([webview respondsToSelector:@selector(_setAllowsMessaging:)])
1052             [webview _setAllowsMessaging:YES];
1053 #endif
1054
1055         if ([webview_ respondsToSelector:@selector(_scrollView)]) {
1056             scroller_ = [webview_ _scrollView];
1057
1058             [scroller_ setDirectionalLockEnabled:YES];
1059             [scroller_ setDecelerationRate:CYScrollViewDecelerationRateNormal];
1060             [scroller_ setDelaysContentTouches:NO];
1061
1062             [scroller_ setCanCancelContentTouches:YES];
1063         } else if ([webview_ respondsToSelector:@selector(_scroller)]) {
1064             UIScroller *scroller([webview_ _scroller]);
1065             scroller_ = (UIScrollView *) scroller;
1066
1067             [scroller setDirectionalScrolling:YES];
1068             // XXX: we might be better off /not/ setting this on older systems
1069             [scroller setScrollDecelerationFactor:CYScrollViewDecelerationRateNormal]; /* 0.989324 */
1070             [scroller setScrollHysteresis:0]; /* 8 */
1071
1072             [scroller setThumbDetectionEnabled:NO];
1073
1074             // use NO with UIApplicationUseLegacyEvents(YES)
1075             [scroller setEventMode:YES];
1076
1077             // XXX: this is handled by setBounces, right?
1078             //[scroller setAllowsRubberBanding:YES];
1079         }
1080
1081         [scroller_ setFixedBackgroundPattern:YES];
1082         [scroller_ setBackgroundColor:[UIColor clearColor]];
1083         [scroller_ setClipsSubviews:YES];
1084
1085         [scroller_ setBounces:YES];
1086         [scroller_ setScrollingEnabled:YES];
1087         [scroller_ setShowBackgroundShadow:NO];
1088
1089         [self setViewportWidth:width];
1090
1091         reloaditem_ = [[UIBarButtonItem alloc]
1092             initWithTitle:UCLocalize("RELOAD")
1093             style:[self rightButtonStyle]
1094             target:self
1095             action:@selector(reloadButtonClicked)
1096         ];
1097
1098         loadingitem_ = [[UIBarButtonItem alloc]
1099             initWithTitle:@" "
1100             style:UIBarButtonItemStylePlain
1101             target:self
1102             action:@selector(reloadButtonClicked)
1103         ];
1104
1105         indicator_ = [[UIActivityIndicatorView alloc] initWithActivityIndicatorStyle:UIActivityIndicatorViewStyleWhite];
1106         [indicator_ setFrame:CGRectMake(15, 5, [indicator_ frame].size.width, [indicator_ frame].size.height)];
1107
1108         UITableView *table([[[UITableView alloc] initWithFrame:bounds style:UITableViewStyleGrouped] autorelease]);
1109         [webview_ insertSubview:table atIndex:0];
1110
1111         [table setAutoresizingMask:(UIViewAutoresizingFlexibleWidth | UIViewAutoresizingFlexibleHeight)];
1112         [webview_ setAutoresizingMask:(UIViewAutoresizingFlexibleWidth | UIViewAutoresizingFlexibleHeight)];
1113         [indicator_ setAutoresizingMask:UIViewAutoresizingFlexibleLeftMargin];
1114     } return self;
1115 }
1116
1117 - (id) initWithWidth:(float)width {
1118     return [self initWithWidth:width ofClass:[self class]];
1119 }
1120
1121 - (id) init {
1122     return [self initWithWidth:0];
1123 }
1124
1125 - (id) initWithURL:(NSURL *)url {
1126     if ((self = [self init]) != nil) {
1127         [self setURL:url];
1128     } return self;
1129 }
1130
1131 - (void) didDismissModalViewController {
1132     if (closer_ != nil)
1133         [self callFunction:closer_];
1134 }
1135
1136 - (void) callFunction:(WebScriptObject *)function {
1137     WebThreadLocked lock;
1138
1139     WebView *webview([[webview_ _documentView] webView]);
1140     WebFrame *frame([webview mainFrame]);
1141     WebPreferences *preferences([webview preferences]);
1142
1143     bool maybe([preferences javaScriptCanOpenWindowsAutomatically]);
1144     [preferences setJavaScriptCanOpenWindowsAutomatically:NO];
1145
1146     /*id _private(MSHookIvar<id>(webview, "_private"));
1147     WebCore::Page *page(_private == nil ? NULL : MSHookIvar<WebCore::Page *>(_private, "page"));
1148     WebCore::Settings *settings(page == NULL ? NULL : page->settings());
1149
1150     bool no;
1151     if (settings == NULL)
1152         no = 0;
1153     else {
1154         no = settings->JavaScriptCanOpenWindowsAutomatically();
1155         settings->setJavaScriptCanOpenWindowsAutomatically(true);
1156     }*/
1157
1158     if (UIWindow *window = [[self view] window])
1159         if (UIResponder *responder = [window firstResponder])
1160             [responder resignFirstResponder];
1161
1162     JSObjectRef object([function JSObject]);
1163     JSGlobalContextRef context([frame globalContext]);
1164     JSObjectCallAsFunction(context, object, NULL, 0, NULL, NULL);
1165
1166     /*if (settings != NULL)
1167         settings->setJavaScriptCanOpenWindowsAutomatically(no);*/
1168
1169     [preferences setJavaScriptCanOpenWindowsAutomatically:maybe];
1170 }
1171
1172 - (void) reloadButtonClicked {
1173     [self reloadURLWithCache:YES];
1174 }
1175
1176 - (void) _customButtonClicked {
1177     [self reloadButtonClicked];
1178 }
1179
1180 - (void) customButtonClicked {
1181 #if !AlwaysReload
1182     if (function_ != nil)
1183         [self callFunction:function_];
1184     else
1185 #endif
1186     [self _customButtonClicked];
1187 }
1188
1189 + (float) defaultWidth {
1190     return 980;
1191 }
1192
1193 - (void) setNavigationBarStyle:(NSString *)name {
1194     UIBarStyle style;
1195     if ([name isEqualToString:@"Black"])
1196         style = UIBarStyleBlack;
1197     else
1198         style = UIBarStyleDefault;
1199
1200     [[[self navigationController] navigationBar] setBarStyle:style];
1201 }
1202
1203 - (void) setNavigationBarTintColor:(UIColor *)color {
1204     [[[self navigationController] navigationBar] setTintColor:color];
1205 }
1206
1207 - (void) setHidesBackButton:(bool)value {
1208     [[self navigationItem] setHidesBackButton:value];
1209 }
1210
1211 - (void) setHidesBackButtonByNumber:(NSNumber *)value {
1212     [self setHidesBackButton:[value boolValue]];
1213 }
1214
1215 - (void) dispatchEvent:(NSString *)event {
1216     WebThreadLocked lock;
1217
1218     NSString *script([NSString stringWithFormat:@
1219         "(function() {"
1220             "var event = this.document.createEvent('Events');"
1221             "event.initEvent('%@', false, false);"
1222             "this.document.dispatchEvent(event);"
1223         "})();"
1224     , event]);
1225
1226     NSMutableArray *frames([NSMutableArray arrayWithObjects:
1227         [[[webview_ _documentView] webView] mainFrame]
1228     , nil]);
1229
1230     while (WebFrame *frame = [frames lastObject]) {
1231         WebScriptObject *object([frame windowObject]);
1232         [object evaluateWebScript:script];
1233         [frames removeLastObject];
1234         [frames addObjectsFromArray:[frame childFrames]];
1235     }
1236 }
1237
1238 - (bool) hidesNavigationBar {
1239     return hidesNavigationBar_;
1240 }
1241
1242 - (void) _setHidesNavigationBar:(bool)value animated:(bool)animated {
1243     if (visible_)
1244         [[self navigationController] setNavigationBarHidden:(value && [self hidesNavigationBar]) animated:animated];
1245 }
1246
1247 - (void) setHidesNavigationBar:(bool)value {
1248     if (hidesNavigationBar_ != value) {
1249         hidesNavigationBar_ = value;
1250         [self _setHidesNavigationBar:YES animated:YES];
1251     }
1252 }
1253
1254 - (void) setHidesNavigationBarByNumber:(NSNumber *)value {
1255     [self setHidesNavigationBar:[value boolValue]];
1256 }
1257
1258 - (void) viewWillAppear:(BOOL)animated {
1259     visible_ = true;
1260
1261     if ([self hidesNavigationBar])
1262         [self _setHidesNavigationBar:YES animated:animated];
1263
1264     [self dispatchEvent:@"CydiaViewWillAppear"];
1265     [super viewWillAppear:animated];
1266 }
1267
1268 - (void) viewDidAppear:(BOOL)animated {
1269     [super viewDidAppear:animated];
1270     [self dispatchEvent:@"CydiaViewDidAppear"];
1271 }
1272
1273 - (void) viewWillDisappear:(BOOL)animated {
1274     [self dispatchEvent:@"CydiaViewWillDisappear"];
1275     [super viewWillDisappear:animated];
1276
1277     if ([self hidesNavigationBar])
1278         [self _setHidesNavigationBar:NO animated:animated];
1279
1280     visible_ = false;
1281 }
1282
1283 - (void) viewDidDisappear:(BOOL)animated {
1284     [super viewDidDisappear:animated];
1285     [self dispatchEvent:@"CydiaViewDidDisappear"];
1286 }
1287
1288 @end