CyteKit/WebViewController.mm

   1 #include "CyteKit/UCPlatform.h"
   2 #include "CyteKit/WebViewController.h"
   3
   4 #include "CyteKit/MFMailComposeViewController-MailToURL.h"
   5
   6 #include "iPhonePrivate.h"
   7
   8 #include "CyteKit/IndirectDelegate.h"
   9 #include "CyteKit/Localize.h"
  10 #include "CyteKit/WebViewController.h"
  11 #include "CyteKit/PerlCompatibleRegEx.hpp"
  12 #include "CyteKit/WebThreadLocked.hpp"
  13
  14 //#include <QuartzCore/CALayer.h>
  15 // XXX: fix the minimum requirement
  16 extern NSString * const kCAFilterNearest;
  17
  18 #include <WebCore/WebCoreThread.h>
  19
  20 #import <WebKit/WebKitErrors.h>
  21 #import <WebKit/WebPreferences.h>
  22
  23 #include <WebKit/DOMCSSPrimitiveValue.h>
  24 #include <WebKit/DOMCSSStyleDeclaration.h>
  25 #include <WebKit/DOMDocument.h>
  26 #include <WebKit/DOMHTMLBodyElement.h>
  27 #include <WebKit/DOMRGBColor.h>
  28
  29 #include <dlfcn.h>
  30 #include <objc/runtime.h>
  31
  32 #define ForSaurik 0
  33 #define DefaultTimeout_ 120.0
  34
  35 #define ShowInternals 0
  36 #define LogBrowser 0
  37 #define LogMessages 0
  38
  39 #define lprintf(args...) fprintf(stderr, args)
  40
  41 JSValueRef (*$JSObjectCallAsFunction)(JSContextRef, JSObjectRef, JSObjectRef, size_t, const JSValueRef[], JSValueRef *);
  42
  43 // XXX: centralize these special class things to some file or mechanism?
  44 static Class $MFMailComposeViewController;
  45
  46 float CYScrollViewDecelerationRateNormal;
  47
  48 @interface WebView (Apple)
  49 - (void) _setLayoutInterval:(float)interval;
  50 - (void) _setAllowsMessaging:(BOOL)allows;
  51 @end
  52
  53 @interface WebFrame (Cydia)
  54 - (void) cydia$updateHeight;
  55 @end
  56
  57 @implementation WebFrame (Cydia)
  58
  59 - (NSString *) description {
  60     return [NSString stringWithFormat:@"<%s: %p, %@>", class_getName([self class]), self, [[[([self provisionalDataSource] ?: [self dataSource]) request] URL] absoluteString]];
  61 }
  62
  63 - (void) cydia$updateHeight {
  64     [[[self frameElement] style]
  65         setProperty:@"height"
  66         value:[NSString stringWithFormat:@"%dpx",
  67             [[[self DOMDocument] body] scrollHeight]]
  68         priority:nil];
  69 }
  70
  71 @end
  72
  73 /* Indirect Delegate {{{ */
  74 @implementation IndirectDelegate
  75
  76 - (id) delegate {
  77     return delegate_;
  78 }
  79
  80 - (void) setDelegate:(id)delegate {
  81     delegate_ = delegate;
  82 }
  83
  84 - (id) initWithDelegate:(id)delegate {
  85     delegate_ = delegate;
  86     return self;
  87 }
  88
  89 - (IMP) methodForSelector:(SEL)sel {
  90     if (IMP method = [super methodForSelector:sel])
  91         return method;
  92     fprintf(stderr, "methodForSelector:[%s] == NULL\n", sel_getName(sel));
  93     return NULL;
  94 }
  95
  96 - (BOOL) respondsToSelector:(SEL)sel {
  97     if ([super respondsToSelector:sel])
  98         return YES;
  99
 100     // XXX: WebThreadCreateNSInvocation returns nil
 101
 102 #if ShowInternals
 103     fprintf(stderr, "[%s]R?%s\n", class_getName(self->isa), sel_getName(sel));
 104 #endif
 105
 106     return delegate_ == nil ? NO : [delegate_ respondsToSelector:sel];
 107 }
 108
 109 - (NSMethodSignature *) methodSignatureForSelector:(SEL)sel {
 110     if (NSMethodSignature *method = [super methodSignatureForSelector:sel])
 111         return method;
 112
 113 #if ShowInternals
 114     fprintf(stderr, "[%s]S?%s\n", class_getName(self->isa), sel_getName(sel));
 115 #endif
 116
 117     if (delegate_ != nil)
 118         if (NSMethodSignature *sig = [delegate_ methodSignatureForSelector:sel])
 119             return sig;
 120
 121     // XXX: I fucking hate Apple so very very bad
 122     return [NSMethodSignature signatureWithObjCTypes:"v@:"];
 123 }
 124
 125 - (void) forwardInvocation:(NSInvocation *)inv {
 126     SEL sel = [inv selector];
 127     if (delegate_ != nil && [delegate_ respondsToSelector:sel])
 128         [inv invokeWithTarget:delegate_];
 129 }
 130
 131 @end
 132 /* }}} */
 133
 134 @implementation CyteWebViewController
 135
 136 #if ShowInternals
 137 #include "CyteKit/UCInternal.h"
 138 #endif
 139
 140 + (void) _initialize {
 141     [WebPreferences _setInitialDefaultTextEncodingToSystemEncoding];
 142
 143     void *js(NULL);
 144     if (js == NULL)
 145         js = dlopen("/System/Library/Frameworks/JavaScriptCore.framework/JavaScriptCore", RTLD_GLOBAL | RTLD_LAZY);
 146     if (js == NULL)
 147         js = dlopen("/System/Library/PrivateFrameworks/JavaScriptCore.framework/JavaScriptCore", RTLD_GLOBAL | RTLD_LAZY);
 148     if (js != NULL)
 149         $JSObjectCallAsFunction = reinterpret_cast<JSValueRef (*)(JSContextRef, JSObjectRef, JSObjectRef, size_t, const JSValueRef[], JSValueRef *)>(dlsym(js, "JSObjectCallAsFunction"));
 150
 151     dlopen("/System/Library/Frameworks/MessageUI.framework/MessageUI", RTLD_GLOBAL | RTLD_LAZY);
 152     $MFMailComposeViewController = objc_getClass("MFMailComposeViewController");
 153
 154     if (float *_UIScrollViewDecelerationRateNormal = reinterpret_cast<float *>(dlsym(RTLD_DEFAULT, "UIScrollViewDecelerationRateNormal")))
 155         CYScrollViewDecelerationRateNormal = *_UIScrollViewDecelerationRateNormal;
 156     else // XXX: this actually might be fast on some older systems: we should look into this
 157         CYScrollViewDecelerationRateNormal = 0.998;
 158 }
 159
 160 - (bool) retainsNetworkActivityIndicator {
 161     return true;
 162 }
 163
 164 - (void) releaseNetworkActivityIndicator {
 165     if ([loading_ count] != 0) {
 166         [loading_ removeAllObjects];
 167
 168         if ([self retainsNetworkActivityIndicator])
 169             [delegate_ releaseNetworkActivityIndicator];
 170     }
 171 }
 172
 173 - (void) dealloc {
 174 #if LogBrowser
 175     NSLog(@"[CyteWebViewController dealloc]");
 176 #endif
 177
 178     [self releaseNetworkActivityIndicator];
 179
 180     [super dealloc];
 181 }
 182
 183 - (NSString *) description {
 184     return [NSString stringWithFormat:@"<%s: %p, %@>", class_getName([self class]), self, [[request_ URL] absoluteString]];
 185 }
 186
 187 - (CyteWebView *) webView {
 188     return (CyteWebView *) [self view];
 189 }
 190
 191 - (NSURL *) URLWithURL:(NSURL *)url {
 192     return url;
 193 }
 194
 195 - (NSURLRequest *) requestWithURL:(NSURL *)url cachePolicy:(NSURLRequestCachePolicy)policy referrer:(NSString *)referrer {
 196     NSMutableURLRequest *request([NSMutableURLRequest
 197         requestWithURL:[self URLWithURL:url]
 198         cachePolicy:policy
 199         timeoutInterval:DefaultTimeout_
 200     ]);
 201
 202     [request setValue:referrer forHTTPHeaderField:@"Referer"];
 203
 204     return request;
 205 }
 206
 207 - (void) setRequest:(NSURLRequest *)request {
 208     _assert(request_ == nil);
 209     request_ = request;
 210 }
 211
 212 - (void) setURL:(NSURL *)url {
 213     [self setURL:url withReferrer:nil];
 214 }
 215
 216 - (void) setURL:(NSURL *)url withReferrer:(NSString *)referrer {
 217     [self setRequest:[self requestWithURL:url cachePolicy:NSURLRequestUseProtocolCachePolicy referrer:referrer]];
 218 }
 219
 220 - (void) loadURL:(NSURL *)url cachePolicy:(NSURLRequestCachePolicy)policy {
 221     [self loadRequest:[self requestWithURL:url cachePolicy:policy referrer:nil]];
 222 }
 223
 224 - (void) loadURL:(NSURL *)url {
 225     [self loadURL:url cachePolicy:NSURLRequestUseProtocolCachePolicy];
 226 }
 227
 228 - (void) loadRequest:(NSURLRequest *)request {
 229 #if LogBrowser
 230     NSLog(@"loadRequest:%@", request);
 231 #endif
 232
 233     error_ = false;
 234     ready_ = true;
 235
 236     WebThreadLocked lock;
 237     [[self webView] loadRequest:request];
 238 }
 239
 240 - (void) reloadURLWithCache:(BOOL)cache {
 241     if (request_ == nil)
 242         return;
 243
 244     NSMutableURLRequest *request([request_ mutableCopy]);
 245     [request setCachePolicy:(cache ? NSURLRequestUseProtocolCachePolicy : NSURLRequestReloadIgnoringLocalCacheData)];
 246
 247     request_ = request;
 248
 249     if (cache || [request_ HTTPBody] == nil && [request_ HTTPBodyStream] == nil)
 250         [self loadRequest:request_];
 251     else {
 252         UIAlertView *alert = [[[UIAlertView alloc]
 253             initWithTitle:UCLocalize("RESUBMIT_FORM")
 254             message:nil
 255             delegate:self
 256             cancelButtonTitle:UCLocalize("CANCEL")
 257             otherButtonTitles:
 258                 UCLocalize("SUBMIT"),
 259             nil
 260         ] autorelease];
 261
 262         [alert setContext:@"submit"];
 263         [alert show];
 264     }
 265 }
 266
 267 - (void) reloadData {
 268     [super reloadData];
 269
 270     if (ready_)
 271         [self dispatchEvent:@"CydiaReloadData"];
 272     else
 273         [self reloadURLWithCache:YES];
 274 }
 275
 276 - (void) setButtonImage:(NSString *)button withStyle:(NSString *)style toFunction:(id)function {
 277     custom_ = button;
 278     style_ = style;
 279     function_ = function;
 280
 281     [self performSelectorOnMainThread:@selector(applyRightButton) withObject:nil waitUntilDone:NO];
 282 }
 283
 284 - (void) setButtonTitle:(NSString *)button withStyle:(NSString *)style toFunction:(id)function {
 285     custom_ = button;
 286     style_ = style;
 287     function_ = function;
 288
 289     [self performSelectorOnMainThread:@selector(applyRightButton) withObject:nil waitUntilDone:NO];
 290 }
 291
 292 - (void) removeButton {
 293     custom_ = [NSNull null];
 294     [self performSelectorOnMainThread:@selector(applyRightButton) withObject:nil waitUntilDone:NO];
 295 }
 296
 297 - (void) scrollToBottomAnimated:(NSNumber *)animated {
 298     CGSize size([scroller_ contentSize]);
 299     CGPoint offset([scroller_ contentOffset]);
 300     CGRect frame([scroller_ frame]);
 301
 302     if (size.height - offset.y < frame.size.height + 20.f) {
 303         CGRect rect = {{0, size.height-1}, {size.width, 1}};
 304         [scroller_ scrollRectToVisible:rect animated:[animated boolValue]];
 305     }
 306 }
 307
 308 - (void) _setViewportWidth {
 309     [[[self webView] _documentView] setViewportSize:CGSizeMake(width_, UIWebViewGrowsAndShrinksToFitHeight) forDocumentTypes:0x10];
 310 }
 311
 312 - (void) setViewportWidth:(float)width {
 313     width_ = width != 0 ? width : [[self class] defaultWidth];
 314     [self _setViewportWidth];
 315 }
 316
 317 - (void) _setViewportWidthOnMainThread:(NSNumber *)width {
 318     [self setViewportWidth:[width floatValue]];
 319 }
 320
 321 - (void) setViewportWidthOnMainThread:(float)width {
 322     [self performSelectorOnMainThread:@selector(_setViewportWidthOnMainThread:) withObject:[NSNumber numberWithFloat:width] waitUntilDone:NO];
 323 }
 324
 325 - (void) webViewUpdateViewSettings:(UIWebView *)view {
 326     [self _setViewportWidth];
 327 }
 328
 329 - (void) mailComposeController:(MFMailComposeViewController*)controller didFinishWithResult:(MFMailComposeResult)result error:(NSError*)error {
 330     [self dismissModalViewControllerAnimated:YES];
 331 }
 332
 333 - (void) _setupMail:(MFMailComposeViewController *)controller {
 334 }
 335
 336 - (void) _openMailToURL:(NSURL *)url {
 337     if ($MFMailComposeViewController != nil && [$MFMailComposeViewController canSendMail]) {
 338         MFMailComposeViewController *controller([[[$MFMailComposeViewController alloc] init] autorelease]);
 339         [controller setMailComposeDelegate:self];
 340
 341         [controller setMailToURL:url];
 342
 343         [self _setupMail:controller];
 344
 345         [self presentModalViewController:controller animated:YES];
 346         return;
 347     }
 348
 349     UIApplication *app([UIApplication sharedApplication]);
 350     if ([app respondsToSelector:@selector(openURL:asPanel:)])
 351         [app openURL:url asPanel:YES];
 352     else
 353         [app openURL:url];
 354 }
 355
 356 - (bool) _allowJavaScriptPanel {
 357     return true;
 358 }
 359
 360 - (bool) allowsNavigationAction {
 361     return allowsNavigationAction_;
 362 }
 363
 364 - (void) setAllowsNavigationAction:(bool)value {
 365     allowsNavigationAction_ = value;
 366 }
 367
 368 - (void) setAllowsNavigationActionByNumber:(NSNumber *)value {
 369     [self setAllowsNavigationAction:[value boolValue]];
 370 }
 371
 372 - (void) popViewControllerWithNumber:(NSNumber *)value {
 373     UINavigationController *navigation([self navigationController]);
 374     if ([navigation topViewController] == self)
 375         [navigation popViewControllerAnimated:[value boolValue]];
 376 }
 377
 378 - (void) _didFailWithError:(NSError *)error forFrame:(WebFrame *)frame {
 379     NSValue *object([NSValue valueWithNonretainedObject:frame]);
 380     if (![loading_ containsObject:object])
 381         return;
 382     [loading_ removeObject:object];
 383
 384     [self _didFinishLoading];
 385
 386     if ([[error domain] isEqualToString:NSURLErrorDomain] && [error code] == NSURLErrorCancelled)
 387         return;
 388
 389     if ([[error domain] isEqualToString:WebKitErrorDomain] && [error code] == WebKitErrorFrameLoadInterruptedByPolicyChange) {
 390         request_ = nil;
 391         return;
 392     }
 393
 394     if ([frame parentFrame] == nil) {
 395         [self loadURL:[NSURL URLWithString:[NSString stringWithFormat:@"%@?%@",
 396             [[NSURL fileURLWithPath:[[NSBundle mainBundle] pathForResource:@"error" ofType:@"html"]] absoluteString],
 397             [[error localizedDescription] stringByAddingPercentEscapes]
 398         ]]];
 399
 400         error_ = true;
 401     }
 402 }
 403
 404 - (void) pushRequest:(NSURLRequest *)request forAction:(NSDictionary *)action asPop:(bool)pop {
 405     WebFrame *frame(nil);
 406     if (NSDictionary *WebActionElement = [action objectForKey:@"WebActionElementKey"])
 407         frame = [WebActionElement objectForKey:@"WebElementFrame"];
 408     if (frame == nil)
 409         frame = [[[[self webView] _documentView] webView] mainFrame];
 410
 411     WebDataSource *source([frame provisionalDataSource] ?: [frame dataSource]);
 412     NSString *referrer([request valueForHTTPHeaderField:@"Referer"] ?: [[[source request] URL] absoluteString]);
 413
 414     NSURL *url([request URL]);
 415
 416     // XXX: filter to internal usage?
 417     CyteViewController *page([delegate_ pageForURL:url forExternal:NO withReferrer:referrer]);
 418
 419     if (page == nil) {
 420         CyteWebViewController *browser([[[class_ alloc] init] autorelease]);
 421         [browser setRequest:request];
 422         page = browser;
 423     }
 424
 425     [page setDelegate:delegate_];
 426
 427     if (!pop) {
 428         [[self navigationItem] setTitle:title_];
 429
 430         [[self navigationController] pushViewController:page animated:YES];
 431     } else {
 432         UINavigationController *navigation([[[UINavigationController alloc] initWithRootViewController:page] autorelease]);
 433
 434         [navigation setDelegate:delegate_];
 435
 436         [[page navigationItem] setLeftBarButtonItem:[[[UIBarButtonItem alloc]
 437             initWithTitle:UCLocalize("CLOSE")
 438             style:UIBarButtonItemStylePlain
 439             target:page
 440             action:@selector(close)
 441         ] autorelease]];
 442
 443         [[self navigationController] presentModalViewController:navigation animated:YES];
 444     }
 445 }
 446
 447 // CyteWebViewDelegate {{{
 448 - (void) webView:(WebView *)view addMessageToConsole:(NSDictionary *)message {
 449 #if LogMessages
 450     static Pcre irritating("^(?"
 451         ":" "The page at .* displayed insecure content from .*\\."
 452         "|" "Unsafe JavaScript attempt to access frame with URL .* from frame with URL .*\\. Domains, protocols and ports must match\\."
 453     ")\\n$");
 454
 455     if (NSString *data = [message objectForKey:@"message"])
 456         if (irritating(data))
 457             return;
 458
 459     NSLog(@"addMessageToConsole:%@", message);
 460 #endif
 461 }
 462
 463 - (void) webView:(WebView *)view decidePolicyForNavigationAction:(NSDictionary *)action request:(NSURLRequest *)request frame:(WebFrame *)frame decisionListener:(id<WebPolicyDecisionListener>)listener {
 464 #if LogBrowser
 465     NSLog(@"decidePolicyForNavigationAction:%@ request:%@ %@ frame:%@", action, request, [request allHTTPHeaderFields], frame);
 466 #endif
 467
 468     if ([frame parentFrame] == nil) {
 469         if (!error_) {
 470             NSURL *url(request == nil ? nil : [request URL]);
 471
 472             if (request_ != nil && ![[request_ URL] isEqual:url] && ![self allowsNavigationAction]) {
 473                 if (url != nil)
 474                     [self pushRequest:request forAction:action asPop:NO];
 475                 [listener ignore];
 476             }
 477         }
 478     }
 479 }
 480
 481 - (void) webView:(WebView *)view didDecidePolicy:(CYWebPolicyDecision)decision forNavigationAction:(NSDictionary *)action request:(NSURLRequest *)request frame:(WebFrame *)frame {
 482 #if LogBrowser
 483     NSLog(@"didDecidePolicy:%u forNavigationAction:%@ request:%@ frame:%@", decision, action, request, [request allHTTPHeaderFields], frame);
 484 #endif
 485
 486     if ([frame parentFrame] == nil) {
 487         switch (decision) {
 488             case CYWebPolicyDecisionIgnore:
 489                 if ([[request_ URL] isEqual:[request URL]])
 490                     request_ = nil;
 491             break;
 492
 493             case CYWebPolicyDecisionUse:
 494                 if (!error_)
 495                     request_ = request;
 496             break;
 497
 498             default:
 499             break;
 500         }
 501     }
 502 }
 503
 504 - (void) webView:(WebView *)view decidePolicyForNewWindowAction:(NSDictionary *)action request:(NSURLRequest *)request newFrameName:(NSString *)name decisionListener:(id<WebPolicyDecisionListener>)listener {
 505 #if LogBrowser
 506     NSLog(@"decidePolicyForNewWindowAction:%@ request:%@ %@ newFrameName:%@", action, request, [request allHTTPHeaderFields], name);
 507 #endif
 508
 509     NSURL *url([request URL]);
 510     if (url == nil)
 511         return;
 512
 513     if ([name isEqualToString:@"_open"])
 514         [delegate_ openURL:url];
 515     else {
 516         NSString *scheme([[url scheme] lowercaseString]);
 517         if ([scheme isEqualToString:@"mailto"])
 518             [self _openMailToURL:url];
 519         else
 520             [self pushRequest:request forAction:action asPop:[name isEqualToString:@"_popup"]];
 521     }
 522
 523     [listener ignore];
 524 }
 525
 526 - (void) webView:(WebView *)view didClearWindowObject:(WebScriptObject *)window forFrame:(WebFrame *)frame {
 527 #if LogBrowser
 528     NSLog(@"didClearWindowObject:%@ forFrame:%@", window, frame);
 529 #endif
 530 }
 531
 532 - (void) webView:(WebView *)view didCommitLoadForFrame:(WebFrame *)frame {
 533 #if LogBrowser
 534     NSLog(@"didCommitLoadForFrame:%@", frame);
 535 #endif
 536
 537     if ([frame parentFrame] == nil) {
 538         loaded_ = true;
 539     }
 540 }
 541
 542 - (void) webView:(WebView *)view didFailLoadWithError:(NSError *)error forFrame:(WebFrame *)frame {
 543 #if LogBrowser
 544     NSLog(@"didFailLoadWithError:%@ forFrame:%@", error, frame);
 545 #endif
 546
 547     [self _didFailWithError:error forFrame:frame];
 548 }
 549
 550 - (void) webView:(WebView *)view didFailProvisionalLoadWithError:(NSError *)error forFrame:(WebFrame *)frame {
 551 #if LogBrowser
 552     NSLog(@"didFailProvisionalLoadWithError:%@ forFrame:%@", error, frame);
 553 #endif
 554
 555     [self _didFailWithError:error forFrame:frame];
 556 }
 557
 558 - (void) webView:(WebView *)view didFinishLoadForFrame:(WebFrame *)frame {
 559     NSValue *object([NSValue valueWithNonretainedObject:frame]);
 560     if (![loading_ containsObject:object])
 561         return;
 562     [loading_ removeObject:object];
 563
 564     if ([frame parentFrame] == nil) {
 565         if (DOMDocument *document = [frame DOMDocument])
 566             if (DOMNodeList *bodies = [document getElementsByTagName:@"body"])
 567                 for (DOMHTMLBodyElement *body in (id) bodies) {
 568                     DOMCSSStyleDeclaration *style([document getComputedStyle:body pseudoElement:nil]);
 569
 570                     UIColor *uic(nil);
 571
 572                     if (DOMCSSPrimitiveValue *color = static_cast<DOMCSSPrimitiveValue *>([style getPropertyCSSValue:@"background-color"])) {
 573                         if ([color primitiveType] == DOM_CSS_RGBCOLOR) {
 574                             DOMRGBColor *rgb([color getRGBColorValue]);
 575
 576                             float red([[rgb red] getFloatValue:DOM_CSS_NUMBER]);
 577                             float green([[rgb green] getFloatValue:DOM_CSS_NUMBER]);
 578                             float blue([[rgb blue] getFloatValue:DOM_CSS_NUMBER]);
 579                             float alpha([[rgb alpha] getFloatValue:DOM_CSS_NUMBER]);
 580
 581                             uic = [UIColor
 582                                 colorWithRed:(red / 255)
 583                                 green:(green / 255)
 584                                 blue:(blue / 255)
 585                                 alpha:alpha
 586                             ];
 587                         }
 588                     }
 589
 590                     [scroller_ setBackgroundColor:uic];
 591                     break;
 592                 }
 593     }
 594
 595     [self _didFinishLoading];
 596 }
 597
 598 - (void) webView:(WebView *)view didReceiveTitle:(NSString *)title forFrame:(WebFrame *)frame {
 599     if ([frame parentFrame] != nil)
 600         return;
 601
 602     title_ = title;
 603
 604     [[self navigationItem] setTitle:title_];
 605 }
 606
 607 - (void) webView:(WebView *)view didStartProvisionalLoadForFrame:(WebFrame *)frame {
 608 #if LogBrowser
 609     NSLog(@"didStartProvisionalLoadForFrame:%@", frame);
 610 #endif
 611
 612     [loading_ addObject:[NSValue valueWithNonretainedObject:frame]];
 613
 614     if ([frame parentFrame] == nil) {
 615         title_ = nil;
 616         custom_ = nil;
 617         style_ = nil;
 618         function_ = nil;
 619
 620         [registered_ removeAllObjects];
 621         timer_ = nil;
 622
 623         allowsNavigationAction_ = true;
 624
 625         [self setHidesNavigationBar:NO];
 626         [self setScrollAlwaysBounceVertical:true];
 627         [self setScrollIndicatorStyle:UIScrollViewIndicatorStyleDefault];
 628
 629         // XXX: do we still need to do this?
 630         [[self navigationItem] setTitle:nil];
 631     }
 632
 633     [self _didStartLoading];
 634 }
 635
 636 - (NSURLRequest *) webView:(WebView *)view resource:(id)identifier willSendRequest:(NSURLRequest *)request redirectResponse:(NSURLResponse *)response fromDataSource:(WebDataSource *)source {
 637 #if LogBrowser
 638     NSLog(@"resource:%@ willSendRequest:%@ redirectResponse:%@ fromDataSource:%@", identifier, request, response, source);
 639 #endif
 640
 641     return request;
 642 }
 643
 644 - (bool) webView:(WebView *)view shouldRunJavaScriptAlertPanelWithMessage:(NSString *)message initiatedByFrame:(WebFrame *)frame {
 645     return [self _allowJavaScriptPanel];
 646 }
 647
 648 - (bool) webView:(WebView *)view shouldRunJavaScriptConfirmPanelWithMessage:(NSString *)message initiatedByFrame:(WebFrame *)frame {
 649     return [self _allowJavaScriptPanel];
 650 }
 651
 652 - (bool) webView:(WebView *)view shouldRunJavaScriptTextInputPanelWithPrompt:(NSString *)prompt defaultText:(NSString *)text initiatedByFrame:(WebFrame *)frame {
 653     return [self _allowJavaScriptPanel];
 654 }
 655
 656 - (void) webViewClose:(WebView *)view {
 657     [self close];
 658 }
 659 // }}}
 660
 661 - (void) close {
 662     [[[self navigationController] parentOrPresentingViewController] dismissModalViewControllerAnimated:YES];
 663 }
 664
 665 - (void) alertView:(UIAlertView *)alert clickedButtonAtIndex:(NSInteger)button {
 666     NSString *context([alert context]);
 667
 668     if ([context isEqualToString:@"sensitive"]) {
 669         switch (button) {
 670             case 1:
 671                 sensitive_ = [NSNumber numberWithBool:YES];
 672             break;
 673
 674             case 2:
 675                 sensitive_ = [NSNumber numberWithBool:NO];
 676             break;
 677         }
 678
 679         [alert dismissWithClickedButtonIndex:-1 animated:YES];
 680     } else if ([context isEqualToString:@"challenge"]) {
 681         id<NSURLAuthenticationChallengeSender> sender([challenge_ sender]);
 682
 683         switch (button) {
 684             case 1: {
 685                 NSString *username([[alert textFieldAtIndex:0] text]);
 686                 NSString *password([[alert textFieldAtIndex:1] text]);
 687
 688                 NSURLCredential *credential([NSURLCredential credentialWithUser:username password:password persistence:NSURLCredentialPersistenceForSession]);
 689
 690                 [sender useCredential:credential forAuthenticationChallenge:challenge_];
 691             } break;
 692
 693             case 2:
 694                 [sender cancelAuthenticationChallenge:challenge_];
 695             break;
 696
 697             _nodefault
 698         }
 699
 700         challenge_ = nil;
 701
 702         [alert dismissWithClickedButtonIndex:-1 animated:YES];
 703     } else if ([context isEqualToString:@"submit"]) {
 704         if (button == [alert cancelButtonIndex]) {
 705         } else if (button == [alert firstOtherButtonIndex]) {
 706             if (request_ != nil) {
 707                 WebThreadLocked lock;
 708                 [[self webView] loadRequest:request_];
 709             }
 710         }
 711
 712         [alert dismissWithClickedButtonIndex:-1 animated:YES];
 713     }
 714 }
 715
 716 - (UIBarButtonItemStyle) rightButtonStyle {
 717     if (style_ == nil) normal:
 718         return UIBarButtonItemStylePlain;
 719     else if ([style_ isEqualToString:@"Normal"])
 720         return UIBarButtonItemStylePlain;
 721     else if ([style_ isEqualToString:@"Highlighted"])
 722         return UIBarButtonItemStyleDone;
 723     else goto normal;
 724 }
 725
 726 - (UIBarButtonItem *) customButton {
 727     if (custom_ == nil)
 728         return nil;
 729     else if ((/*clang:*/id) custom_ == [NSNull null])
 730         return (UIBarButtonItem *) [NSNull null];
 731
 732     return [[[UIBarButtonItem alloc]
 733         initWithTitle:static_cast<NSString *>(custom_.operator NSObject *())
 734         style:[self rightButtonStyle]
 735         target:self
 736         action:@selector(customButtonClicked)
 737     ] autorelease];
 738 }
 739
 740 - (UIBarButtonItem *) leftButton {
 741     UINavigationItem *item([self navigationItem]);
 742     if ([item backBarButtonItem] != nil && ![item hidesBackButton])
 743         return nil;
 744
 745     if (UINavigationController *navigation = [self navigationController])
 746         if ([[navigation parentOrPresentingViewController] modalViewController] == navigation)
 747             return [[[UIBarButtonItem alloc]
 748                 initWithTitle:UCLocalize("CLOSE")
 749                 style:UIBarButtonItemStylePlain
 750                 target:self
 751                 action:@selector(close)
 752             ] autorelease];
 753
 754     return nil;
 755 }
 756
 757 - (void) applyLeftButton {
 758     [[self navigationItem] setLeftBarButtonItem:[self leftButton]];
 759 }
 760
 761 - (UIBarButtonItem *) rightButton {
 762     return reloaditem_;
 763 }
 764
 765 - (void) applyLoadingTitle {
 766     [[self navigationItem] setTitle:UCLocalize("LOADING")];
 767 }
 768
 769 - (void) layoutRightButton {
 770     [[loadingitem_ view] addSubview:indicator_];
 771     [[loadingitem_ view] bringSubviewToFront:indicator_];
 772 }
 773
 774 - (void) applyRightButton {
 775     if ([self isLoading]) {
 776         [[self navigationItem] setRightBarButtonItem:loadingitem_ animated:YES];
 777         [self performSelector:@selector(layoutRightButton) withObject:nil afterDelay:0];
 778
 779         [indicator_ startAnimating];
 780         [self applyLoadingTitle];
 781     } else {
 782         [indicator_ stopAnimating];
 783
 784         UIBarButtonItem *button([self customButton]);
 785         if (button == nil)
 786             button = [self rightButton];
 787         else if (button == (UIBarButtonItem *) [NSNull null])
 788             button = nil;
 789
 790         [[self navigationItem] setRightBarButtonItem:button animated:YES];
 791     }
 792 }
 793
 794 - (void) didStartLoading {
 795     // Overridden in subclasses.
 796 }
 797
 798 - (void) _didStartLoading {
 799     [self applyRightButton];
 800
 801     if ([loading_ count] != 1)
 802         return;
 803
 804     if ([self retainsNetworkActivityIndicator])
 805         [delegate_ retainNetworkActivityIndicator];
 806
 807     [self didStartLoading];
 808 }
 809
 810 - (void) didFinishLoading {
 811     // Overridden in subclasses.
 812 }
 813
 814 - (void) _didFinishLoading {
 815     if ([loading_ count] != 0)
 816         return;
 817
 818     [self applyRightButton];
 819     [[self navigationItem] setTitle:title_];
 820
 821     if ([self retainsNetworkActivityIndicator])
 822         [delegate_ releaseNetworkActivityIndicator];
 823
 824     [self didFinishLoading];
 825 }
 826
 827 - (bool) isLoading {
 828     return [loading_ count] != 0;
 829 }
 830
 831 - (id) initWithWidth:(float)width ofClass:(Class)_class {
 832     if ((self = [super init]) != nil) {
 833         width_ = width;
 834         class_ = _class;
 835
 836         allowsNavigationAction_ = true;
 837
 838         loading_ = [NSMutableSet setWithCapacity:5];
 839         registered_ = [NSMutableSet setWithCapacity:5];
 840         indirect_ = [[[IndirectDelegate alloc] initWithDelegate:self] autorelease];
 841
 842         reloaditem_ = [[[UIBarButtonItem alloc]
 843             initWithTitle:UCLocalize("RELOAD")
 844             style:[self rightButtonStyle]
 845             target:self
 846             action:@selector(reloadButtonClicked)
 847         ] autorelease];
 848
 849         loadingitem_ = [[[UIBarButtonItem alloc]
 850             initWithTitle:(kCFCoreFoundationVersionNumber >= 800 ? @"       " : @" ")
 851             style:UIBarButtonItemStylePlain
 852             target:self
 853             action:@selector(reloadButtonClicked)
 854         ] autorelease];
 855
 856         UIActivityIndicatorViewStyle style;
 857         float left;
 858         if (kCFCoreFoundationVersionNumber >= 800) {
 859             style = UIActivityIndicatorViewStyleGray;
 860             left = 7;
 861         } else {
 862             style = UIActivityIndicatorViewStyleWhite;
 863             left = 15;
 864         }
 865
 866         indicator_ = [[[UIActivityIndicatorView alloc] initWithActivityIndicatorStyle:style] autorelease];
 867         [indicator_ setFrame:CGRectMake(left, 5, [indicator_ frame].size.width, [indicator_ frame].size.height)];
 868         [indicator_ setAutoresizingMask:UIViewAutoresizingFlexibleLeftMargin];
 869
 870         [self applyLeftButton];
 871         [self applyRightButton];
 872     } return self;
 873 }
 874
 875 - (NSString *) applicationNameForUserAgent {
 876     return nil;
 877 }
 878
 879 - (void) loadView {
 880     CGRect bounds([[UIScreen mainScreen] applicationFrame]);
 881
 882     webview_ = [[[CyteWebView alloc] initWithFrame:bounds] autorelease];
 883     [webview_ setDelegate:self];
 884     [self setView:webview_];
 885
 886     if ([webview_ respondsToSelector:@selector(setDataDetectorTypes:)])
 887         [webview_ setDataDetectorTypes:UIDataDetectorTypeAutomatic];
 888     else
 889         [webview_ setDetectsPhoneNumbers:NO];
 890
 891     [webview_ setScalesPageToFit:YES];
 892
 893     UIWebDocumentView *document([webview_ _documentView]);
 894
 895     // XXX: I think this improves scrolling; the hardcoded-ness sucks
 896     [document setTileSize:CGSizeMake(320, 500)];
 897
 898     WebView *webview([document webView]);
 899     WebPreferences *preferences([webview preferences]);
 900
 901     // XXX: I have no clue if I actually /want/ this modification
 902     if ([webview respondsToSelector:@selector(_setLayoutInterval:)])
 903         [webview _setLayoutInterval:0];
 904     else if ([preferences respondsToSelector:@selector(_setLayoutInterval:)])
 905         [preferences _setLayoutInterval:0];
 906
 907     [preferences setCacheModel:WebCacheModelDocumentBrowser];
 908     [preferences setJavaScriptCanOpenWindowsAutomatically:YES];
 909
 910     if ([preferences respondsToSelector:@selector(setOfflineWebApplicationCacheEnabled:)])
 911         [preferences setOfflineWebApplicationCacheEnabled:YES];
 912
 913     if (NSString *agent = [self applicationNameForUserAgent])
 914         [webview setApplicationNameForUserAgent:agent];
 915
 916     if ([webview respondsToSelector:@selector(setShouldUpdateWhileOffscreen:)])
 917         [webview setShouldUpdateWhileOffscreen:NO];
 918
 919 #if LogMessages
 920     if ([document respondsToSelector:@selector(setAllowsMessaging:)])
 921         [document setAllowsMessaging:YES];
 922     if ([webview respondsToSelector:@selector(_setAllowsMessaging:)])
 923         [webview _setAllowsMessaging:YES];
 924 #endif
 925
 926     if ([webview_ respondsToSelector:@selector(_scrollView)]) {
 927         scroller_ = [webview_ _scrollView];
 928
 929         [scroller_ setDirectionalLockEnabled:YES];
 930         [scroller_ setDecelerationRate:CYScrollViewDecelerationRateNormal];
 931         [scroller_ setDelaysContentTouches:NO];
 932
 933         [scroller_ setCanCancelContentTouches:YES];
 934     } else if ([webview_ respondsToSelector:@selector(_scroller)]) {
 935         UIScroller *scroller([webview_ _scroller]);
 936         scroller_ = (UIScrollView *) scroller;
 937
 938         [scroller setDirectionalScrolling:YES];
 939         // XXX: we might be better off /not/ setting this on older systems
 940         [scroller setScrollDecelerationFactor:CYScrollViewDecelerationRateNormal]; /* 0.989324 */
 941         [scroller setScrollHysteresis:0]; /* 8 */
 942
 943         [scroller setThumbDetectionEnabled:NO];
 944
 945         // use NO with UIApplicationUseLegacyEvents(YES)
 946         [scroller setEventMode:YES];
 947
 948         // XXX: this is handled by setBounces, right?
 949         //[scroller setAllowsRubberBanding:YES];
 950     }
 951
 952     [scroller_ setFixedBackgroundPattern:YES];
 953     [scroller_ setBackgroundColor:[UIColor groupTableViewBackgroundColor]];
 954     [scroller_ setClipsSubviews:YES];
 955
 956     [scroller_ setBounces:YES];
 957     [scroller_ setScrollingEnabled:YES];
 958     [scroller_ setShowBackgroundShadow:NO];
 959
 960     [self setViewportWidth:width_];
 961
 962     [webview_ setAutoresizingMask:(UIViewAutoresizingFlexibleWidth | UIViewAutoresizingFlexibleHeight)];
 963
 964     ready_ = false;
 965 }
 966
 967 - (void) releaseSubviews {
 968     webview_ = nil;
 969     scroller_ = nil;
 970
 971     [self releaseNetworkActivityIndicator];
 972
 973     [super releaseSubviews];
 974 }
 975
 976 - (id) initWithWidth:(float)width {
 977     return [self initWithWidth:width ofClass:[self class]];
 978 }
 979
 980 - (id) init {
 981     return [self initWithWidth:0];
 982 }
 983
 984 - (id) initWithURL:(NSURL *)url {
 985     if ((self = [self init]) != nil) {
 986         [self setURL:url];
 987     } return self;
 988 }
 989
 990 - (id) initWithRequest:(NSURLRequest *)request {
 991     if ((self = [self init]) != nil) {
 992         [self setRequest:request];
 993     } return self;
 994 }
 995
 996 - (void) callFunction:(WebScriptObject *)function {
 997     WebThreadLocked lock;
 998
 999     WebView *webview([[[self webView] _documentView] webView]);
1000     WebFrame *frame([webview mainFrame]);
1001
1002     JSGlobalContextRef context([frame globalContext]);
1003     JSObjectRef object([function JSObject]);
1004     if ($JSObjectCallAsFunction != NULL)
1005         ($JSObjectCallAsFunction)(context, object, NULL, 0, NULL, NULL);
1006 }
1007
1008 - (void) reloadButtonClicked {
1009     [self reloadURLWithCache:NO];
1010 }
1011
1012 - (void) _customButtonClicked {
1013     [self reloadButtonClicked];
1014 }
1015
1016 - (void) customButtonClicked {
1017 #if !AlwaysReload
1018     if (function_ != nil)
1019         [self callFunction:function_];
1020     else
1021 #endif
1022     [self _customButtonClicked];
1023 }
1024
1025 + (float) defaultWidth {
1026     return 980;
1027 }
1028
1029 - (void) setNavigationBarStyle:(NSString *)name {
1030     UIBarStyle style;
1031     if ([name isEqualToString:@"Black"])
1032         style = UIBarStyleBlack;
1033     else
1034         style = UIBarStyleDefault;
1035
1036     [[[self navigationController] navigationBar] setBarStyle:style];
1037 }
1038
1039 - (void) setNavigationBarTintColor:(UIColor *)color {
1040     [[[self navigationController] navigationBar] setTintColor:color];
1041 }
1042
1043 - (void) setBadgeValue:(id)value {
1044     [[[self navigationController] tabBarItem] setBadgeValue:value];
1045 }
1046
1047 - (void) setHidesBackButton:(bool)value {
1048     [[self navigationItem] setHidesBackButton:value];
1049     [self applyLeftButton];
1050 }
1051
1052 - (void) setHidesBackButtonByNumber:(NSNumber *)value {
1053     [self setHidesBackButton:[value boolValue]];
1054 }
1055
1056 - (void) dispatchEvent:(NSString *)event {
1057     [[self webView] dispatchEvent:event];
1058 }
1059
1060 - (bool) hidesNavigationBar {
1061     return hidesNavigationBar_;
1062 }
1063
1064 - (void) _setHidesNavigationBar:(bool)value animated:(bool)animated {
1065     if (visible_)
1066         [[self navigationController] setNavigationBarHidden:(value && [self hidesNavigationBar]) animated:animated];
1067 }
1068
1069 - (void) setHidesNavigationBar:(bool)value {
1070     if (hidesNavigationBar_ != value) {
1071         hidesNavigationBar_ = value;
1072         [self _setHidesNavigationBar:YES animated:YES];
1073     }
1074 }
1075
1076 - (void) setHidesNavigationBarByNumber:(NSNumber *)value {
1077     [self setHidesNavigationBar:[value boolValue]];
1078 }
1079
1080 - (void) setScrollAlwaysBounceVertical:(bool)value {
1081     if ([webview_ respondsToSelector:@selector(_scrollView)]) {
1082         UIScrollView *scroller([webview_ _scrollView]);
1083         [scroller setAlwaysBounceVertical:value];
1084     } else if ([webview_ respondsToSelector:@selector(_scroller)]) {
1085         //UIScroller *scroller([webview_ _scroller]);
1086         // XXX: I am sad here.
1087     } else return;
1088 }
1089
1090 - (void) setScrollAlwaysBounceVerticalNumber:(NSNumber *)value {
1091     [self setScrollAlwaysBounceVertical:[value boolValue]];
1092 }
1093
1094 - (void) setScrollIndicatorStyle:(UIScrollViewIndicatorStyle)style {
1095     if ([webview_ respondsToSelector:@selector(_scrollView)]) {
1096         UIScrollView *scroller([webview_ _scrollView]);
1097         [scroller setIndicatorStyle:style];
1098     } else if ([webview_ respondsToSelector:@selector(_scroller)]) {
1099         UIScroller *scroller([webview_ _scroller]);
1100         [scroller setScrollerIndicatorStyle:style];
1101     } else return;
1102 }
1103
1104 - (void) setScrollIndicatorStyleWithName:(NSString *)style {
1105     UIScrollViewIndicatorStyle value;
1106
1107     if (false);
1108     else if ([style isEqualToString:@"default"])
1109         value = UIScrollViewIndicatorStyleDefault;
1110     else if ([style isEqualToString:@"black"])
1111         value = UIScrollViewIndicatorStyleBlack;
1112     else if ([style isEqualToString:@"white"])
1113         value = UIScrollViewIndicatorStyleWhite;
1114     else return;
1115
1116     [self setScrollIndicatorStyle:value];
1117 }
1118
1119 - (void) viewWillAppear:(BOOL)animated {
1120     visible_ = true;
1121
1122     if ([self hidesNavigationBar])
1123         [self _setHidesNavigationBar:YES animated:animated];
1124
1125     // XXX: why isn't this evern called automatically?
1126     [[self webView] setNeedsLayout];
1127
1128     [self dispatchEvent:@"CydiaViewWillAppear"];
1129     [super viewWillAppear:animated];
1130 }
1131
1132 - (void) viewDidAppear:(BOOL)animated {
1133     [super viewDidAppear:animated];
1134     [self dispatchEvent:@"CydiaViewDidAppear"];
1135 }
1136
1137 - (void) viewWillDisappear:(BOOL)animated {
1138     [self dispatchEvent:@"CydiaViewWillDisappear"];
1139     [super viewWillDisappear:animated];
1140
1141     if ([self hidesNavigationBar])
1142         [self _setHidesNavigationBar:NO animated:animated];
1143
1144     visible_ = false;
1145 }
1146
1147 - (void) viewDidDisappear:(BOOL)animated {
1148     [super viewDidDisappear:animated];
1149     [self dispatchEvent:@"CydiaViewDidDisappear"];
1150 }
1151
1152 - (void) updateHeights:(NSTimer *)timer {
1153     for (WebFrame *frame in (id) registered_)
1154         [frame cydia$updateHeight];
1155 }
1156
1157 - (void) registerFrame:(WebFrame *)frame {
1158     [registered_ addObject:frame];
1159
1160     if (timer_ == nil)
1161         timer_ = [NSTimer scheduledTimerWithTimeInterval:0.2 target:self selector:@selector(updateHeights:) userInfo:nil repeats:YES];
1162 }
1163
1164 @end