MobileCydia.mm

   1 /* Cydia - iPhone UIKit Front-End for Debian APT
   2  * Copyright (C) 2008-2015  Jay Freeman (saurik)
   3 */
   4
   5 /* GNU General Public License, Version 3 {{{ */
   6 /*
   7  * Cydia is free software: you can redistribute it and/or modify
   8  * it under the terms of the GNU General Public License as published
   9  * by the Free Software Foundation, either version 3 of the License,
  10  * or (at your option) any later version.
  11  *
  12  * Cydia is distributed in the hope that it will be useful, but
  13  * WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with Cydia.  If not, see <http://www.gnu.org/licenses/>.
  19 **/
  20 /* }}} */
  21
  22 // XXX: wtf/FastMalloc.h... wtf?
  23 #define USE_SYSTEM_MALLOC 1
  24
  25 /* #include Directives {{{ */
  26 #include "CyteKit/UCPlatform.h"
  27 #include "CyteKit/Localize.h"
  28
  29 #include <unicode/ustring.h>
  30 #include <unicode/utrans.h>
  31
  32 #include <objc/objc.h>
  33 #include <objc/runtime.h>
  34
  35 #include <CoreGraphics/CoreGraphics.h>
  36 #include <Foundation/Foundation.h>
  37
  38 #if 0
  39 #define DEPLOYMENT_TARGET_MACOSX 1
  40 #define CF_BUILDING_CF 1
  41 #include <CoreFoundation/CFInternal.h>
  42 #endif
  43
  44 #include <CoreFoundation/CFUniChar.h>
  45
  46 #include <SystemConfiguration/SystemConfiguration.h>
  47
  48 #include <UIKit/UIKit.h>
  49 #include "iPhonePrivate.h"
  50
  51 #include <IOKit/IOKitLib.h>
  52
  53 #include <QuartzCore/CALayer.h>
  54
  55 #include <WebCore/WebCoreThread.h>
  56 #include <WebKit/DOMHTMLIFrameElement.h>
  57
  58 #include <algorithm>
  59 #include <fstream>
  60 #include <iomanip>
  61 #include <set>
  62 #include <sstream>
  63 #include <string>
  64
  65 #include "fdstream.hpp"
  66
  67 #undef ABS
  68
  69 #include "apt.h"
  70 #include <apt-pkg/acquire.h>
  71 #include <apt-pkg/acquire-item.h>
  72 #include <apt-pkg/algorithms.h>
  73 #include <apt-pkg/cachefile.h>
  74 #include <apt-pkg/clean.h>
  75 #include <apt-pkg/configuration.h>
  76 #include <apt-pkg/debindexfile.h>
  77 #include <apt-pkg/debmetaindex.h>
  78 #include <apt-pkg/error.h>
  79 #include <apt-pkg/init.h>
  80 #include <apt-pkg/mmap.h>
  81 #include <apt-pkg/pkgrecords.h>
  82 #include <apt-pkg/sha1.h>
  83 #include <apt-pkg/sourcelist.h>
  84 #include <apt-pkg/sptr.h>
  85 #include <apt-pkg/strutl.h>
  86 #include <apt-pkg/tagfile.h>
  87
  88 #include <sys/types.h>
  89 #include <sys/stat.h>
  90 #include <sys/sysctl.h>
  91 #include <sys/param.h>
  92 #include <sys/mount.h>
  93 #include <sys/reboot.h>
  94
  95 #include <dirent.h>
  96 #include <fcntl.h>
  97 #include <notify.h>
  98 #include <dlfcn.h>
  99
 100 extern "C" {
 101 #include <mach-o/nlist.h>
 102 }
 103
 104 #include <cstdio>
 105 #include <cstdlib>
 106 #include <cstring>
 107
 108 #include <errno.h>
 109
 110 #include <Cytore.hpp>
 111 #include "Sources.h"
 112
 113 #include "Substrate.hpp"
 114 #include "Menes/Menes.h"
 115
 116 #include "CyteKit/IndirectDelegate.h"
 117 #include "CyteKit/RegEx.hpp"
 118 #include "CyteKit/TableViewCell.h"
 119 #include "CyteKit/TabBarController.h"
 120 #include "CyteKit/WebScriptObject-Cyte.h"
 121 #include "CyteKit/WebViewController.h"
 122 #include "CyteKit/WebViewTableViewCell.h"
 123 #include "CyteKit/stringWithUTF8Bytes.h"
 124
 125 #include "Cydia/MIMEAddress.h"
 126 #include "Cydia/LoadingViewController.h"
 127 #include "Cydia/ProgressEvent.h"
 128
 129 #include "SDURLCache/SDURLCache.h"
 130 /* }}} */
 131
 132 /* Profiler {{{ */
 133 struct timeval _ltv;
 134 bool _itv;
 135
 136 #define _timestamp ({ \
 137     struct timeval tv; \
 138     gettimeofday(&tv, NULL); \
 139     tv.tv_sec * 1000000 + tv.tv_usec; \
 140 })
 141
 142 typedef std::vector<class ProfileTime *> TimeList;
 143 TimeList times_;
 144
 145 class ProfileTime {
 146   private:
 147     const char *name_;
 148     uint64_t total_;
 149     uint64_t count_;
 150
 151   public:
 152     ProfileTime(const char *name) :
 153         name_(name),
 154         total_(0)
 155     {
 156         times_.push_back(this);
 157     }
 158
 159     void AddTime(uint64_t time) {
 160         total_ += time;
 161         ++count_;
 162     }
 163
 164     void Print() {
 165         if (total_ != 0)
 166             std::cerr << std::setw(7) << count_ << ", " << std::setw(8) << total_ << " : " << name_ << std::endl;
 167         total_ = 0;
 168         count_ = 0;
 169     }
 170 };
 171
 172 class ProfileTimer {
 173   private:
 174     ProfileTime &time_;
 175     uint64_t start_;
 176
 177   public:
 178     ProfileTimer(ProfileTime &time) :
 179         time_(time),
 180         start_(_timestamp)
 181     {
 182     }
 183
 184     ~ProfileTimer() {
 185         time_.AddTime(_timestamp - start_);
 186     }
 187 };
 188
 189 void PrintTimes() {
 190     for (TimeList::const_iterator i(times_.begin()); i != times_.end(); ++i)
 191         (*i)->Print();
 192     std::cerr << "========" << std::endl;
 193 }
 194
 195 #define _profile(name) { \
 196     static ProfileTime name(#name); \
 197     ProfileTimer _ ## name(name);
 198
 199 #define _end }
 200 /* }}} */
 201
 202 // XXX: I hate clang. Apple: please get over your petty hatred of GPL and fix your gcc fork
 203 #define synchronized(lock) \
 204     synchronized(static_cast<NSObject *>(lock))
 205
 206 extern NSString *Cydia_;
 207
 208 #define lprintf(args...) fprintf(stderr, args)
 209
 210 #define ForRelease 1
 211 #define TraceLogging (1 && !ForRelease)
 212 #define HistogramInsertionSort (0 && !ForRelease)
 213 #define ProfileTimes (0 && !ForRelease)
 214 #define ForSaurik (0 && !ForRelease)
 215 #define LogBrowser (0 && !ForRelease)
 216 #define TrackResize (0 && !ForRelease)
 217 #define ManualRefresh (1 && !ForRelease)
 218 #define ShowInternals (0 && !ForRelease)
 219 #define AlwaysReload (0 && !ForRelease)
 220
 221 #if !TraceLogging
 222 #undef _trace
 223 #define _trace(args...)
 224 #endif
 225
 226 #if !ProfileTimes
 227 #undef _profile
 228 #define _profile(name) {
 229 #undef _end
 230 #define _end }
 231 #define PrintTimes() do {} while (false)
 232 #endif
 233
 234 // Hash Functions/Structures {{{
 235 extern "C" uint32_t hashlittle(const void *key, size_t length, uint32_t initval = 0);
 236
 237 union SplitHash {
 238     uint32_t u32;
 239     uint16_t u16[2];
 240 };
 241 // }}}
 242
 243 @implementation NSDictionary (Cydia)
 244 - (id) invokeUndefinedMethodFromWebScript:(NSString *)name withArguments:(NSArray *)arguments {
 245     if (false);
 246     else if ([name isEqualToString:@"get"])
 247         return [self objectForKey:[arguments objectAtIndex:0]];
 248     else if ([name isEqualToString:@"keys"])
 249         return [self allKeys];
 250     return nil;
 251 } @end
 252
 253 static NSString *Colon_;
 254 NSString *Elision_;
 255 static NSString *Error_;
 256 static NSString *Warning_;
 257
 258 static NSString *Cache_;
 259 #define Cache(file) \
 260     [NSString stringWithFormat:@"%@/%s", Cache_, file]
 261
 262 static void (*$SBSSetInterceptsMenuButtonForever)(bool);
 263 static NSData *(*$SBSCopyIconImagePNGDataForDisplayIdentifier)(NSString *);
 264
 265 static CFStringRef (*$MGCopyAnswer)(CFStringRef);
 266
 267 static NSString *UniqueIdentifier(UIDevice *device = nil) {
 268     if (kCFCoreFoundationVersionNumber < 800) // iOS 7.x
 269         return [device ?: [UIDevice currentDevice] uniqueIdentifier];
 270     else
 271         return [(id)$MGCopyAnswer(CFSTR("UniqueDeviceID")) autorelease];
 272 }
 273
 274 static bool IsReachable(const char *name) {
 275     SCNetworkReachabilityFlags flags; {
 276         SCNetworkReachabilityRef reachability(SCNetworkReachabilityCreateWithName(kCFAllocatorDefault, name));
 277         SCNetworkReachabilityGetFlags(reachability, &flags);
 278         CFRelease(reachability);
 279     }
 280
 281     // XXX: this elaborate mess is what Apple is using to determine this? :(
 282     // XXX: do we care if the user has to intervene? maybe that's ok?
 283     return
 284         (flags & kSCNetworkReachabilityFlagsReachable) != 0 && (
 285             (flags & kSCNetworkReachabilityFlagsConnectionRequired) == 0 || (
 286                 (flags & kSCNetworkReachabilityFlagsConnectionOnDemand) != 0 ||
 287                 (flags & kSCNetworkReachabilityFlagsConnectionOnTraffic) != 0
 288             ) && (flags & kSCNetworkReachabilityFlagsInterventionRequired) == 0 ||
 289             (flags & kSCNetworkReachabilityFlagsIsWWAN) != 0
 290         )
 291     ;
 292 }
 293
 294 static const NSUInteger UIViewAutoresizingFlexibleBoth(UIViewAutoresizingFlexibleWidth | UIViewAutoresizingFlexibleHeight);
 295
 296 static _finline NSString *CydiaURL(NSString *path) {
 297     char page[26];
 298     page[0] = 'h'; page[1] = 't'; page[2] = 't'; page[3] = 'p'; page[4] = 's';
 299     page[5] = ':'; page[6] = '/'; page[7] = '/'; page[8] = 'c'; page[9] = 'y';
 300     page[10] = 'd'; page[11] = 'i'; page[12] = 'a'; page[13] = '.'; page[14] = 's';
 301     page[15] = 'a'; page[16] = 'u'; page[17] = 'r'; page[18] = 'i'; page[19] = 'k';
 302     page[20] = '.'; page[21] = 'c'; page[22] = 'o'; page[23] = 'm'; page[24] = '/';
 303     page[25] = '\0';
 304     return [[NSString stringWithUTF8String:page] stringByAppendingString:path];
 305 }
 306
 307 static NSString *ShellEscape(NSString *value) {
 308     return [NSString stringWithFormat:@"'%@'", [value stringByReplacingOccurrencesOfString:@"'" withString:@"'\\''"]];
 309 }
 310
 311 static _finline void UpdateExternalStatus(uint64_t newStatus) {
 312     int notify_token;
 313     if (notify_register_check("com.saurik.Cydia.status", &notify_token) == NOTIFY_STATUS_OK) {
 314         notify_set_state(notify_token, newStatus);
 315         notify_cancel(notify_token);
 316     }
 317     notify_post("com.saurik.Cydia.status");
 318 }
 319
 320 static CGFloat CYStatusBarHeight() {
 321     CGSize size([[UIApplication sharedApplication] statusBarFrame].size);
 322     return UIInterfaceOrientationIsPortrait([[UIApplication sharedApplication] statusBarOrientation]) ? size.height : size.width;
 323 }
 324
 325 /* NSForcedOrderingSearch doesn't work on the iPhone */
 326 static const NSStringCompareOptions MatchCompareOptions_ = NSLiteralSearch | NSCaseInsensitiveSearch;
 327 static const NSStringCompareOptions LaxCompareOptions_ = NSNumericSearch | NSDiacriticInsensitiveSearch | NSWidthInsensitiveSearch | NSCaseInsensitiveSearch;
 328 static const CFStringCompareFlags LaxCompareFlags_ = kCFCompareNumerically | kCFCompareWidthInsensitive | kCFCompareForcedOrdering;
 329
 330 /* Insertion Sort {{{ */
 331
 332 CFIndex SKBSearch_(const void *element, CFIndex elementSize, const void *list, CFIndex count, CFComparatorFunction comparator, void *context) {
 333     const char *ptr = (const char *)list;
 334     while (0 < count) {
 335         CFIndex half = count / 2;
 336         const char *probe = ptr + elementSize * half;
 337         CFComparisonResult cr = comparator(element, probe, context);
 338     if (0 == cr) return (probe - (const char *)list) / elementSize;
 339         ptr = (cr < 0) ? ptr : probe + elementSize;
 340         count = (cr < 0) ? half : (half + (count & 1) - 1);
 341     }
 342     return (ptr - (const char *)list) / elementSize;
 343 }
 344
 345 CFIndex CFBSearch_(const void *element, CFIndex elementSize, const void *list, CFIndex count, CFComparatorFunction comparator, void *context) {
 346     const char *ptr = (const char *)list;
 347     while (0 < count) {
 348         CFIndex half = count / 2;
 349         const char *probe = ptr + elementSize * half;
 350         CFComparisonResult cr = comparator(element, probe, context);
 351     if (0 == cr) return (probe - (const char *)list) / elementSize;
 352         ptr = (cr < 0) ? ptr : probe + elementSize;
 353         count = (cr < 0) ? half : (half + (count & 1) - 1);
 354     }
 355     return (ptr - (const char *)list) / elementSize;
 356 }
 357
 358 void CFArrayInsertionSortValues(CFMutableArrayRef array, CFRange range, CFComparatorFunction comparator, void *context) {
 359     if (range.length == 0)
 360         return;
 361     const void **values(new const void *[range.length]);
 362     CFArrayGetValues(array, range, values);
 363
 364 #if HistogramInsertionSort > 0
 365     uint32_t total(0), *offsets(new uint32_t[range.length]);
 366 #endif
 367
 368     for (CFIndex index(1); index != range.length; ++index) {
 369         const void *value(values[index]);
 370         //CFIndex correct(SKBSearch_(&value, sizeof(const void *), values, index, comparator, context));
 371         CFIndex correct(index);
 372         while (comparator(value, values[correct - 1], context) == kCFCompareLessThan) {
 373 #if HistogramInsertionSort > 1
 374             NSLog(@"%@ < %@", value, values[correct - 1]);
 375 #endif
 376             if (--correct == 0)
 377                 break;
 378         }
 379         if (correct != index) {
 380             size_t offset(index - correct);
 381 #if HistogramInsertionSort
 382             total += offset;
 383             ++offsets[offset];
 384             if (offset > 10)
 385                 NSLog(@"Heavy Insertion Displacement: %u = %@", offset, value);
 386 #endif
 387             memmove(values + correct + 1, values + correct, sizeof(const void *) * offset);
 388             values[correct] = value;
 389         }
 390     }
 391
 392     CFArrayReplaceValues(array, range, values, range.length);
 393     delete [] values;
 394
 395 #if HistogramInsertionSort > 0
 396     for (CFIndex index(0); index != range.length; ++index)
 397         if (offsets[index] != 0)
 398             NSLog(@"Insertion Displacement [%u]: %u", index, offsets[index]);
 399     NSLog(@"Average Insertion Displacement: %f", double(total) / range.length);
 400     delete [] offsets;
 401 #endif
 402 }
 403
 404 /* }}} */
 405
 406 /* Apple Bug Fixes {{{ */
 407 @implementation UIWebDocumentView (Cydia)
 408
 409 - (void) _setScrollerOffset:(CGPoint)offset {
 410     UIScroller *scroller([self _scroller]);
 411
 412     CGSize size([scroller contentSize]);
 413     CGSize bounds([scroller bounds].size);
 414
 415     CGPoint max;
 416     max.x = size.width - bounds.width;
 417     max.y = size.height - bounds.height;
 418
 419     // wtf Apple?!
 420     if (max.x < 0)
 421         max.x = 0;
 422     if (max.y < 0)
 423         max.y = 0;
 424
 425     offset.x = offset.x < 0 ? 0 : offset.x > max.x ? max.x : offset.x;
 426     offset.y = offset.y < 0 ? 0 : offset.y > max.y ? max.y : offset.y;
 427
 428     [scroller setOffset:offset];
 429 }
 430
 431 @end
 432 /* }}} */
 433
 434 NSUInteger DOMNodeList$countByEnumeratingWithState$objects$count$(DOMNodeList *self, SEL sel, NSFastEnumerationState *state, id *objects, NSUInteger count) {
 435     size_t length([self length] - state->state);
 436     if (length <= 0)
 437         return 0;
 438     else if (length > count)
 439         length = count;
 440     for (size_t i(0); i != length; ++i)
 441         objects[i] = [self item:state->state++];
 442     state->itemsPtr = objects;
 443     state->mutationsPtr = (unsigned long *) self;
 444     return length;
 445 }
 446
 447 /* Cydia NSString Additions {{{ */
 448 @interface NSString (Cydia)
 449 - (NSComparisonResult) compareByPath:(NSString *)other;
 450 - (NSString *) stringByAddingPercentEscapesIncludingReserved;
 451 @end
 452
 453 @implementation NSString (Cydia)
 454
 455 - (NSComparisonResult) compareByPath:(NSString *)other {
 456     NSString *prefix = [self commonPrefixWithString:other options:0];
 457     size_t length = [prefix length];
 458
 459     NSRange lrange = NSMakeRange(length, [self length] - length);
 460     NSRange rrange = NSMakeRange(length, [other length] - length);
 461
 462     lrange = [self rangeOfString:@"/" options:0 range:lrange];
 463     rrange = [other rangeOfString:@"/" options:0 range:rrange];
 464
 465     NSComparisonResult value;
 466
 467     if (lrange.location == NSNotFound && rrange.location == NSNotFound)
 468         value = NSOrderedSame;
 469     else if (lrange.location == NSNotFound)
 470         value = NSOrderedAscending;
 471     else if (rrange.location == NSNotFound)
 472         value = NSOrderedDescending;
 473     else
 474         value = NSOrderedSame;
 475
 476     NSString *lpath = lrange.location == NSNotFound ? [self substringFromIndex:length] :
 477         [self substringWithRange:NSMakeRange(length, lrange.location - length)];
 478     NSString *rpath = rrange.location == NSNotFound ? [other substringFromIndex:length] :
 479         [other substringWithRange:NSMakeRange(length, rrange.location - length)];
 480
 481     NSComparisonResult result = [lpath compare:rpath];
 482     return result == NSOrderedSame ? value : result;
 483 }
 484
 485 - (NSString *) stringByAddingPercentEscapesIncludingReserved {
 486     return [(id)CFURLCreateStringByAddingPercentEscapes(
 487         kCFAllocatorDefault,
 488         (CFStringRef) self,
 489         NULL,
 490         CFSTR(";/?:@&=+$,"),
 491         kCFStringEncodingUTF8
 492     ) autorelease];
 493 }
 494
 495 @end
 496 /* }}} */
 497
 498 /* C++ NSString Wrapper Cache {{{ */
 499 static _finline CFStringRef CYStringCreate(const char *data, size_t size) {
 500     return size == 0 ? NULL :
 501         CFStringCreateWithBytesNoCopy(kCFAllocatorDefault, reinterpret_cast<const uint8_t *>(data), size, kCFStringEncodingUTF8, NO, kCFAllocatorNull) ?:
 502         CFStringCreateWithBytesNoCopy(kCFAllocatorDefault, reinterpret_cast<const uint8_t *>(data), size, kCFStringEncodingISOLatin1, NO, kCFAllocatorNull);
 503 }
 504
 505 static _finline CFStringRef CYStringCreate(const std::string &data) {
 506     return CYStringCreate(data.data(), data.size());
 507 }
 508
 509 static _finline CFStringRef CYStringCreate(const char *data) {
 510     return CYStringCreate(data, strlen(data));
 511 }
 512
 513 class CYString {
 514   private:
 515     char *data_;
 516     size_t size_;
 517     CFStringRef cache_;
 518
 519     _finline void clear_() {
 520         if (cache_ != NULL) {
 521             CFRelease(cache_);
 522             cache_ = NULL;
 523         }
 524     }
 525
 526   public:
 527     _finline bool empty() const {
 528         return size_ == 0;
 529     }
 530
 531     _finline size_t size() const {
 532         return size_;
 533     }
 534
 535     _finline char *data() const {
 536         return data_;
 537     }
 538
 539     _finline void clear() {
 540         size_ = 0;
 541         clear_();
 542     }
 543
 544     _finline CYString() :
 545         data_(0),
 546         size_(0),
 547         cache_(NULL)
 548     {
 549     }
 550
 551     _finline ~CYString() {
 552         clear_();
 553     }
 554
 555     void operator =(const CYString &rhs) {
 556         data_ = rhs.data_;
 557         size_ = rhs.size_;
 558
 559         if (rhs.cache_ == nil)
 560             cache_ = NULL;
 561         else
 562             cache_ = reinterpret_cast<CFStringRef>(CFRetain(rhs.cache_));
 563     }
 564
 565     void copy(CYPool *pool) {
 566         char *temp(pool->malloc<char>(size_ + 1));
 567         memcpy(temp, data_, size_);
 568         temp[size_] = '\0';
 569         data_ = temp;
 570     }
 571
 572     void set(CYPool *pool, const char *data, size_t size) {
 573         if (size == 0)
 574             clear();
 575         else {
 576             clear_();
 577
 578             data_ = const_cast<char *>(data);
 579             size_ = size;
 580
 581             if (pool != NULL)
 582                 copy(pool);
 583         }
 584     }
 585
 586     _finline void set(CYPool *pool, const char *data) {
 587         set(pool, data, data == NULL ? 0 : strlen(data));
 588     }
 589
 590     _finline void set(CYPool *pool, const std::string &rhs) {
 591         set(pool, rhs.data(), rhs.size());
 592     }
 593
 594     bool operator ==(const CYString &rhs) const {
 595         return size_ == rhs.size_ && memcmp(data_, rhs.data_, size_) == 0;
 596     }
 597
 598     _finline operator CFStringRef() {
 599         if (cache_ == NULL)
 600             cache_ = CYStringCreate(data_, size_);
 601         return cache_;
 602     }
 603
 604     _finline operator id() {
 605         return (NSString *) static_cast<CFStringRef>(*this);
 606     }
 607
 608     _finline operator const char *() {
 609         return reinterpret_cast<const char *>(data_);
 610     }
 611 };
 612 /* }}} */
 613 /* C++ NSString Algorithm Adapters {{{ */
 614 extern "C" {
 615     CF_EXPORT CFHashCode CFStringHashNSString(CFStringRef str);
 616 }
 617
 618 struct NSStringMapHash :
 619     std::unary_function<NSString *, size_t>
 620 {
 621     _finline size_t operator ()(NSString *value) const {
 622         return CFStringHashNSString((CFStringRef) value);
 623     }
 624 };
 625
 626 struct NSStringMapLess :
 627     std::binary_function<NSString *, NSString *, bool>
 628 {
 629     _finline bool operator ()(NSString *lhs, NSString *rhs) const {
 630         return [lhs compare:rhs] == NSOrderedAscending;
 631     }
 632 };
 633
 634 struct NSStringMapEqual :
 635     std::binary_function<NSString *, NSString *, bool>
 636 {
 637     _finline bool operator ()(NSString *lhs, NSString *rhs) const {
 638         return CFStringCompare((CFStringRef) lhs, (CFStringRef) rhs, 0) == kCFCompareEqualTo;
 639         //CFEqual((CFTypeRef) lhs, (CFTypeRef) rhs);
 640         //[lhs isEqualToString:rhs];
 641     }
 642 };
 643 /* }}} */
 644
 645 /* CoreGraphics Primitives {{{ */
 646 class CYColor {
 647   private:
 648     CGColorRef color_;
 649
 650     static CGColorRef Create_(CGColorSpaceRef space, float red, float green, float blue, float alpha) {
 651         CGFloat color[] = {red, green, blue, alpha};
 652         return CGColorCreate(space, color);
 653     }
 654
 655   public:
 656     CYColor() :
 657         color_(NULL)
 658     {
 659     }
 660
 661     CYColor(CGColorSpaceRef space, float red, float green, float blue, float alpha) :
 662         color_(Create_(space, red, green, blue, alpha))
 663     {
 664         Set(space, red, green, blue, alpha);
 665     }
 666
 667     void Clear() {
 668         if (color_ != NULL)
 669             CGColorRelease(color_);
 670     }
 671
 672     ~CYColor() {
 673         Clear();
 674     }
 675
 676     void Set(CGColorSpaceRef space, float red, float green, float blue, float alpha) {
 677         Clear();
 678         color_ = Create_(space, red, green, blue, alpha);
 679     }
 680
 681     operator CGColorRef() {
 682         return color_;
 683     }
 684 };
 685 /* }}} */
 686
 687 /* Random Global Variables {{{ */
 688 static int PulseInterval_ = 500000;
 689
 690 static const NSString *UI_;
 691
 692 static int Finish_;
 693 static bool RestartSubstrate_;
 694 static NSArray *Finishes_;
 695
 696 #define SpringBoard_ "/System/Library/LaunchDaemons/com.apple.SpringBoard.plist"
 697 #define NotifyConfig_ "/etc/notify.conf"
 698
 699 static bool Queuing_;
 700
 701 static CYColor Blue_;
 702 static CYColor Blueish_;
 703 static CYColor Black_;
 704 static CYColor Folder_;
 705 static CYColor Off_;
 706 static CYColor White_;
 707 static CYColor Gray_;
 708 static CYColor Green_;
 709 static CYColor Purple_;
 710 static CYColor Purplish_;
 711
 712 static UIColor *InstallingColor_;
 713 static UIColor *RemovingColor_;
 714
 715 static NSString *App_;
 716
 717 static BOOL Advanced_;
 718 static BOOL Ignored_;
 719
 720 static _H<UIFont> Font12_;
 721 static _H<UIFont> Font12Bold_;
 722 static _H<UIFont> Font14_;
 723 static _H<UIFont> Font18_;
 724 static _H<UIFont> Font18Bold_;
 725 static _H<UIFont> Font22Bold_;
 726
 727 static const char *Machine_ = NULL;
 728 static _H<NSString> System_;
 729 static NSString *SerialNumber_ = nil;
 730 static NSString *ChipID_ = nil;
 731 static NSString *BBSNum_ = nil;
 732 static _H<NSString> UniqueID_;
 733 static _H<NSString> UserAgent_;
 734 static _H<NSString> Product_;
 735 static _H<NSString> Safari_;
 736
 737 static _H<NSLocale> CollationLocale_;
 738 static _H<NSArray> CollationThumbs_;
 739 static std::vector<NSInteger> CollationOffset_;
 740 static _H<NSArray> CollationTitles_;
 741 static _H<NSArray> CollationStarts_;
 742 static UTransliterator *CollationTransl_;
 743 //static Function<NSString *, NSString *> CollationModify_;
 744
 745 typedef std::basic_string<UChar> ustring;
 746 static ustring CollationString_;
 747
 748 #define CUC const ustring &str(*reinterpret_cast<const ustring *>(rep))
 749 #define UC ustring &str(*reinterpret_cast<ustring *>(rep))
 750 static struct UReplaceableCallbacks CollationUCalls_ = {
 751     .length = [](const UReplaceable *rep) -> int32_t { CUC;
 752         return str.size();
 753     },
 754
 755     .charAt = [](const UReplaceable *rep, int32_t offset) -> UChar { CUC;
 756         //fprintf(stderr, "charAt(%d) : %d\n", offset, str.size());
 757         if (offset >= str.size())
 758             return 0xffff;
 759         return str[offset];
 760     },
 761
 762     .char32At = [](const UReplaceable *rep, int32_t offset) -> UChar32 { CUC;
 763         //fprintf(stderr, "char32At(%d) : %d\n", offset, str.size());
 764         if (offset >= str.size())
 765             return 0xffff;
 766         UChar32 c;
 767         U16_GET(str.data(), 0, offset, str.size(), c);
 768         return c;
 769     },
 770
 771     .replace = [](UReplaceable *rep, int32_t start, int32_t limit, const UChar *text, int32_t length) -> void { UC;
 772         //fprintf(stderr, "replace(%d, %d, %d) : %d\n", start, limit, length, str.size());
 773         str.replace(start, limit - start, text, length);
 774     },
 775
 776     .extract = [](UReplaceable *rep, int32_t start, int32_t limit, UChar *dst) -> void { UC;
 777         //fprintf(stderr, "extract(%d, %d) : %d\n", start, limit, str.size());
 778         str.copy(dst, limit - start, start);
 779     },
 780
 781     .copy = [](UReplaceable *rep, int32_t start, int32_t limit, int32_t dest) -> void { UC;
 782         //fprintf(stderr, "copy(%d, %d, %d) : %d\n", start, limit, dest, str.size());
 783         str.replace(dest, 0, str, start, limit - start);
 784     },
 785 };
 786
 787 static CFLocaleRef Locale_;
 788 static NSArray *Languages_;
 789 static CGColorSpaceRef space_;
 790
 791 #define CacheState_ "/var/mobile/Library/Caches/com.saurik.Cydia/CacheState.plist"
 792 #define SavedState_ "/var/mobile/Library/Caches/com.saurik.Cydia/SavedState.plist"
 793
 794 static NSDictionary *SectionMap_;
 795 static _H<NSDate> Backgrounded_;
 796 static _transient NSMutableDictionary *Values_;
 797 static _transient NSMutableDictionary *Sections_;
 798 _H<NSMutableDictionary> Sources_;
 799 static _transient NSNumber *Version_;
 800 static time_t now_;
 801
 802 bool IsWildcat_;
 803 CGFloat ScreenScale_;
 804 static NSString *Idiom_;
 805 static _H<NSString> Firmware_;
 806 static NSString *Major_;
 807
 808 static _H<NSMutableDictionary> SessionData_;
 809 static _H<NSObject> HostConfig_;
 810 static _H<NSMutableSet> BridgedHosts_;
 811 static _H<NSMutableSet> InsecureHosts_;
 812 static _H<NSMutableSet> PipelinedHosts_;
 813 static _H<NSMutableSet> CachedURLs_;
 814
 815 static NSString *kCydiaProgressEventTypeError = @"Error";
 816 static NSString *kCydiaProgressEventTypeInformation = @"Information";
 817 static NSString *kCydiaProgressEventTypeStatus = @"Status";
 818 static NSString *kCydiaProgressEventTypeWarning = @"Warning";
 819 /* }}} */
 820
 821 /* Display Helpers {{{ */
 822 inline float Interpolate(float begin, float end, float fraction) {
 823     return (end - begin) * fraction + begin;
 824 }
 825
 826 static inline double Retina(double value) {
 827     value *= ScreenScale_;
 828     value = round(value);
 829     value /= ScreenScale_;
 830     return value;
 831 }
 832
 833 static inline CGRect Retina(CGRect value) {
 834     value.origin.x *= ScreenScale_;
 835     value.origin.y *= ScreenScale_;
 836     value.size.width *= ScreenScale_;
 837     value.size.height *= ScreenScale_;
 838     value = CGRectIntegral(value);
 839     value.origin.x /= ScreenScale_;
 840     value.origin.y /= ScreenScale_;
 841     value.size.width /= ScreenScale_;
 842     value.size.height /= ScreenScale_;
 843     return value;
 844 }
 845
 846 static _finline const char *StripVersion_(const char *version) {
 847     const char *colon(strchr(version, ':'));
 848     return colon == NULL ? version : colon + 1;
 849 }
 850
 851 NSString *LocalizeSection(NSString *section) {
 852     static RegEx title_r("(.*?) \\((.*)\\)");
 853     if (title_r(section)) {
 854         NSString *parent(title_r[1]);
 855         NSString *child(title_r[2]);
 856
 857         return [NSString stringWithFormat:UCLocalize("PARENTHETICAL"),
 858             LocalizeSection(parent),
 859             LocalizeSection(child)
 860         ];
 861     }
 862
 863     return [[NSBundle mainBundle] localizedStringForKey:section value:nil table:@"Sections"];
 864 }
 865
 866 NSString *Simplify(NSString *title) {
 867     const char *data = [title UTF8String];
 868     size_t size = [title lengthOfBytesUsingEncoding:NSUTF8StringEncoding];
 869
 870     static RegEx square_r("\\[(.*)\\]");
 871     if (square_r(data, size))
 872         return Simplify(square_r[1]);
 873
 874     static RegEx paren_r("\\((.*)\\)");
 875     if (paren_r(data, size))
 876         return Simplify(paren_r[1]);
 877
 878     static RegEx title_r("(.*?) \\((.*)\\)");
 879     if (title_r(data, size))
 880         return Simplify(title_r[1]);
 881
 882     return title;
 883 }
 884 /* }}} */
 885
 886 bool isSectionVisible(NSString *section) {
 887     NSDictionary *metadata([Sections_ objectForKey:(section ?: @"")]);
 888     NSNumber *hidden(metadata == nil ? nil : [metadata objectForKey:@"Hidden"]);
 889     return hidden == nil || ![hidden boolValue];
 890 }
 891
 892 static NSObject *CYIOGetValue(const char *path, NSString *property) {
 893     io_registry_entry_t entry(IORegistryEntryFromPath(kIOMasterPortDefault, path));
 894     if (entry == MACH_PORT_NULL)
 895         return nil;
 896
 897     CFTypeRef value(IORegistryEntryCreateCFProperty(entry, (CFStringRef) property, kCFAllocatorDefault, 0));
 898     IOObjectRelease(entry);
 899
 900     if (value == NULL)
 901         return nil;
 902     return [(id) value autorelease];
 903 }
 904
 905 static NSString *CYHex(NSData *data, bool reverse = false) {
 906     if (data == nil)
 907         return nil;
 908
 909     size_t length([data length]);
 910     uint8_t bytes[length];
 911     [data getBytes:bytes];
 912
 913     char string[length * 2 + 1];
 914     for (size_t i(0); i != length; ++i)
 915         sprintf(string + i * 2, "%.2x", bytes[reverse ? length - i - 1 : i]);
 916
 917     return [NSString stringWithUTF8String:string];
 918 }
 919
 920 static NSString *VerifySource(NSString *href) {
 921     static RegEx href_r("(http(s?)://|file:///)[^# ]*");
 922     if (!href_r(href)) {
 923         [[[[UIAlertView alloc]
 924             initWithTitle:[NSString stringWithFormat:Colon_, Error_, UCLocalize("INVALID_URL")]
 925             message:UCLocalize("INVALID_URL_EX")
 926             delegate:nil
 927             cancelButtonTitle:UCLocalize("OK")
 928             otherButtonTitles:nil
 929         ] autorelease] show];
 930
 931         return nil;
 932     }
 933
 934     if (![href hasSuffix:@"/"])
 935         href = [href stringByAppendingString:@"/"];
 936     return href;
 937 }
 938
 939 @class Cydia;
 940
 941 /* Delegate Prototypes {{{ */
 942 @class Package;
 943 @class Source;
 944 @class CydiaProgressEvent;
 945
 946 @protocol DatabaseDelegate
 947 - (void) repairWithSelector:(SEL)selector;
 948 - (void) setConfigurationData:(NSString *)data;
 949 - (void) addProgressEventOnMainThread:(CydiaProgressEvent *)event forTask:(NSString *)task;
 950 @end
 951
 952 @class CYPackageController;
 953
 954 @protocol SourceDelegate
 955 - (void) setFetch:(NSNumber *)fetch;
 956 @end
 957
 958 @protocol FetchDelegate
 959 - (bool) isSourceCancelled;
 960 - (void) startSourceFetch:(NSString *)uri;
 961 - (void) stopSourceFetch:(NSString *)uri;
 962 @end
 963
 964 @protocol CydiaDelegate
 965 - (void) returnToCydia;
 966 - (void) saveState;
 967 - (void) retainNetworkActivityIndicator;
 968 - (void) releaseNetworkActivityIndicator;
 969 - (void) clearPackage:(Package *)package;
 970 - (void) installPackage:(Package *)package;
 971 - (void) installPackages:(NSArray *)packages;
 972 - (void) removePackage:(Package *)package;
 973 - (void) beginUpdate;
 974 - (BOOL) updating;
 975 - (bool) requestUpdate;
 976 - (void) distUpgrade;
 977 - (void) loadData;
 978 - (void) updateData;
 979 - (void) _saveConfig;
 980 - (void) syncData;
 981 - (void) addSource:(NSDictionary *)source;
 982 - (BOOL) addTrivialSource:(NSString *)href;
 983 - (UIProgressHUD *) addProgressHUD;
 984 - (void) removeProgressHUD:(UIProgressHUD *)hud;
 985 - (void) showActionSheet:(UIActionSheet *)sheet fromItem:(UIBarButtonItem *)item;
 986 - (void) reloadDataWithInvocation:(NSInvocation *)invocation;
 987 @end
 988 /* }}} */
 989
 990 /* CancelStatus {{{ */
 991 class CancelStatus :
 992     public pkgAcquireStatus
 993 {
 994   private:
 995     bool cancelled_;
 996
 997   public:
 998     CancelStatus() :
 999         cancelled_(false)
1000     {
1001     }
1002
1003     virtual bool MediaChange(std::string media, std::string drive) {
1004         return false;
1005     }
1006
1007     virtual void IMSHit(pkgAcquire::ItemDesc &desc) {
1008         Done(desc);
1009     }
1010
1011     virtual bool Pulse_(pkgAcquire *Owner) = 0;
1012
1013     virtual bool Pulse(pkgAcquire *Owner) {
1014         if (pkgAcquireStatus::Pulse(Owner) && Pulse_(Owner))
1015             return true;
1016         else {
1017             cancelled_ = true;
1018             return false;
1019         }
1020     }
1021
1022     _finline bool WasCancelled() const {
1023         return cancelled_;
1024     }
1025 };
1026 /* }}} */
1027 /* DelegateStatus {{{ */
1028 class CydiaStatus :
1029     public CancelStatus
1030 {
1031   private:
1032     _transient NSObject<ProgressDelegate> *delegate_;
1033
1034   public:
1035     CydiaStatus() :
1036         delegate_(nil)
1037     {
1038     }
1039
1040     void setDelegate(NSObject<ProgressDelegate> *delegate) {
1041         delegate_ = delegate;
1042     }
1043
1044     virtual void Fetch(pkgAcquire::ItemDesc &desc) {
1045         NSString *name([NSString stringWithUTF8String:desc.ShortDesc.c_str()]);
1046         CydiaProgressEvent *event([CydiaProgressEvent eventWithMessage:[NSString stringWithFormat:UCLocalize("DOWNLOADING_"), name] ofType:kCydiaProgressEventTypeStatus forItemDesc:desc]);
1047         [delegate_ performSelectorOnMainThread:@selector(addProgressEvent:) withObject:event waitUntilDone:YES];
1048     }
1049
1050     virtual void Done(pkgAcquire::ItemDesc &desc) {
1051         NSString *name([NSString stringWithUTF8String:desc.ShortDesc.c_str()]);
1052         CydiaProgressEvent *event([CydiaProgressEvent eventWithMessage:[NSString stringWithFormat:Colon_, UCLocalize("DONE"), name] ofType:kCydiaProgressEventTypeStatus forItemDesc:desc]);
1053         [delegate_ performSelectorOnMainThread:@selector(addProgressEvent:) withObject:event waitUntilDone:YES];
1054     }
1055
1056     virtual void Fail(pkgAcquire::ItemDesc &desc) {
1057         if (
1058             desc.Owner->Status == pkgAcquire::Item::StatIdle ||
1059             desc.Owner->Status == pkgAcquire::Item::StatDone
1060         )
1061             return;
1062
1063         std::string &error(desc.Owner->ErrorText);
1064         if (error.empty())
1065             return;
1066
1067         CydiaProgressEvent *event([CydiaProgressEvent eventWithMessage:[NSString stringWithUTF8String:error.c_str()] ofType:kCydiaProgressEventTypeError forItemDesc:desc]);
1068         [delegate_ performSelectorOnMainThread:@selector(addProgressEvent:) withObject:event waitUntilDone:YES];
1069     }
1070
1071     virtual bool Pulse_(pkgAcquire *Owner) {
1072         double percent(
1073             double(CurrentBytes + CurrentItems) /
1074             double(TotalBytes + TotalItems)
1075         );
1076
1077         [delegate_ performSelectorOnMainThread:@selector(setProgressStatus:) withObject:[NSDictionary dictionaryWithObjectsAndKeys:
1078             [NSNumber numberWithDouble:percent], @"Percent",
1079
1080             [NSNumber numberWithDouble:CurrentBytes], @"Current",
1081             [NSNumber numberWithDouble:TotalBytes], @"Total",
1082             [NSNumber numberWithDouble:CurrentCPS], @"Speed",
1083         nil] waitUntilDone:YES];
1084
1085         return ![delegate_ isProgressCancelled];
1086     }
1087
1088     virtual void Start() {
1089         pkgAcquireStatus::Start();
1090         [delegate_ performSelectorOnMainThread:@selector(setProgressCancellable:) withObject:[NSNumber numberWithBool:YES] waitUntilDone:YES];
1091     }
1092
1093     virtual void Stop() {
1094         pkgAcquireStatus::Stop();
1095         [delegate_ performSelectorOnMainThread:@selector(setProgressCancellable:) withObject:[NSNumber numberWithBool:NO] waitUntilDone:YES];
1096         [delegate_ performSelectorOnMainThread:@selector(setProgressStatus:) withObject:nil waitUntilDone:YES];
1097     }
1098 };
1099 /* }}} */
1100 /* Database Interface {{{ */
1101 typedef std::map< unsigned long, _H<Source> > SourceMap;
1102
1103 @interface Database : NSObject {
1104     NSZone *zone_;
1105     CYPool pool_;
1106
1107     unsigned era_;
1108     _H<NSDate> delock_;
1109
1110     pkgCacheFile cache_;
1111     pkgDepCache::Policy *policy_;
1112     pkgRecords *records_;
1113     pkgProblemResolver *resolver_;
1114     pkgAcquire *fetcher_;
1115     FileFd *lock_;
1116     SPtr<pkgPackageManager> manager_;
1117     pkgSourceList *list_;
1118
1119     SourceMap sourceMap_;
1120     _H<NSMutableArray> sourceList_;
1121
1122     CFMutableArrayRef packages_;
1123
1124     _transient NSObject<DatabaseDelegate> *delegate_;
1125     _transient NSObject<ProgressDelegate> *progress_;
1126
1127     CydiaStatus status_;
1128
1129     int cydiafd_;
1130     int statusfd_;
1131     FILE *input_;
1132
1133     std::map<const char *, _H<NSString> > sections_;
1134 }
1135
1136 + (Database *) sharedInstance;
1137 - (unsigned) era;
1138
1139 - (void) _readCydia:(NSNumber *)fd;
1140 - (void) _readStatus:(NSNumber *)fd;
1141 - (void) _readOutput:(NSNumber *)fd;
1142
1143 - (FILE *) input;
1144
1145 - (Package *) packageWithName:(NSString *)name;
1146
1147 - (pkgCacheFile &) cache;
1148 - (pkgDepCache::Policy *) policy;
1149 - (pkgRecords *) records;
1150 - (pkgProblemResolver *) resolver;
1151 - (pkgAcquire &) fetcher;
1152 - (pkgSourceList &) list;
1153 - (NSArray *) packages;
1154 - (NSArray *) sources;
1155 - (Source *) sourceWithKey:(NSString *)key;
1156 - (void) reloadDataWithInvocation:(NSInvocation *)invocation;
1157
1158 - (void) configure;
1159 - (bool) prepare;
1160 - (void) perform;
1161 - (bool) upgrade;
1162 - (void) update;
1163
1164 - (void) updateWithStatus:(CancelStatus &)status;
1165
1166 - (void) setDelegate:(NSObject<DatabaseDelegate> *)delegate;
1167
1168 - (void) setProgressDelegate:(NSObject<ProgressDelegate> *)delegate;
1169 - (NSObject<ProgressDelegate> *) progressDelegate;
1170
1171 - (Source *) getSource:(pkgCache::PkgFileIterator)file;
1172 - (void) setFetch:(bool)fetch forURI:(const char *)uri;
1173 - (void) resetFetch;
1174
1175 - (NSString *) mappedSectionForPointer:(const char *)pointer;
1176
1177 @end
1178 /* }}} */
1179 /* SourceStatus {{{ */
1180 class SourceStatus :
1181     public CancelStatus
1182 {
1183   private:
1184     _transient NSObject<FetchDelegate> *delegate_;
1185     _transient Database *database_;
1186     std::set<std::string> fetches_;
1187
1188   public:
1189     SourceStatus(NSObject<FetchDelegate> *delegate, Database *database) :
1190         delegate_(delegate),
1191         database_(database)
1192     {
1193     }
1194
1195     void Set(bool fetch, const std::string &uri) {
1196         if (fetch) {
1197             if (!fetches_.insert(uri).second)
1198                 return;
1199         } else {
1200             if (fetches_.erase(uri) == 0)
1201                 return;
1202         }
1203
1204         //printf("Set(%s, %s)\n", fetch ? "true" : "false", uri.c_str());
1205         [database_ setFetch:fetch forURI:uri.c_str()];
1206     }
1207
1208     _finline void Set(bool fetch, pkgAcquire::Item *item) {
1209         /*unsigned long ID(fetch ? 1 : 0);
1210         if (item->ID == ID)
1211             return;
1212         item->ID = ID;*/
1213         Set(fetch, item->DescURI());
1214     }
1215
1216     void Log(const char *tag, pkgAcquire::Item *item) {
1217         //printf("%s(%s) S:%u Q:%u\n", tag, item->DescURI().c_str(), item->Status, item->QueueCounter);
1218     }
1219
1220     virtual void Fetch(pkgAcquire::ItemDesc &desc) {
1221         Log("Fetch", desc.Owner);
1222         Set(true, desc.Owner);
1223     }
1224
1225     virtual void Done(pkgAcquire::ItemDesc &desc) {
1226         Log("Done", desc.Owner);
1227         Set(false, desc.Owner);
1228     }
1229
1230     virtual void Fail(pkgAcquire::ItemDesc &desc) {
1231         Log("Fail", desc.Owner);
1232         Set(false, desc.Owner);
1233     }
1234
1235     virtual bool Pulse_(pkgAcquire *Owner) {
1236         std::set<std::string> fetches;
1237         for (pkgAcquire::ItemCIterator item(Owner->ItemsBegin()); item != Owner->ItemsEnd(); ++item) {
1238             bool fetch;
1239             if ((*item)->QueueCounter == 0)
1240                 fetch = false;
1241             else switch ((*item)->Status) {
1242                 case pkgAcquire::Item::StatFetching:
1243                     fetches.insert((*item)->DescURI());
1244                     fetch = true;
1245                 break;
1246
1247                 default:
1248                     fetch = false;
1249                 break;
1250             }
1251
1252             Log(fetch ? "Pulse<true>" : "Pulse<false>", *item);
1253             Set(fetch, *item);
1254         }
1255
1256         std::vector<std::string> stops;
1257         std::set_difference(fetches_.begin(), fetches_.end(), fetches.begin(), fetches.end(), std::back_insert_iterator<std::vector<std::string>>(stops));
1258         for (std::vector<std::string>::const_iterator stop(stops.begin()); stop != stops.end(); ++stop) {
1259             //printf("Stop(%s)\n", stop->c_str());
1260             Set(false, *stop);
1261         }
1262
1263         return ![delegate_ isSourceCancelled];
1264     }
1265
1266     virtual void Stop() {
1267         pkgAcquireStatus::Stop();
1268         [database_ resetFetch];
1269     }
1270 };
1271 /* }}} */
1272 /* ProgressEvent Implementation {{{ */
1273 @implementation CydiaProgressEvent
1274
1275 + (CydiaProgressEvent *) eventWithMessage:(NSString *)message ofType:(NSString *)type {
1276     return [[[CydiaProgressEvent alloc] initWithMessage:message ofType:type] autorelease];
1277 }
1278
1279 + (CydiaProgressEvent *) eventWithMessage:(NSString *)message ofType:(NSString *)type forPackage:(NSString *)package {
1280     CydiaProgressEvent *event([self eventWithMessage:message ofType:type]);
1281     [event setPackage:package];
1282     return event;
1283 }
1284
1285 + (CydiaProgressEvent *) eventWithMessage:(NSString *)message ofType:(NSString *)type forItemDesc:(pkgAcquire::ItemDesc &)desc {
1286     CydiaProgressEvent *event([self eventWithMessage:message ofType:type]);
1287
1288     NSString *description([NSString stringWithUTF8String:desc.Description.c_str()]);
1289     NSArray *fields([description componentsSeparatedByString:@" "]);
1290     [event setItem:fields];
1291
1292     if ([fields count] > 3) {
1293         [event setPackage:[fields objectAtIndex:2]];
1294         [event setVersion:[fields objectAtIndex:3]];
1295     }
1296
1297     [event setURL:[NSString stringWithUTF8String:desc.URI.c_str()]];
1298
1299     return event;
1300 }
1301
1302 + (NSArray *) _attributeKeys {
1303     return [NSArray arrayWithObjects:
1304         @"item",
1305         @"message",
1306         @"package",
1307         @"type",
1308         @"url",
1309         @"version",
1310     nil];
1311 }
1312
1313 - (NSArray *) attributeKeys {
1314     return [[self class] _attributeKeys];
1315 }
1316
1317 + (BOOL) isKeyExcludedFromWebScript:(const char *)name {
1318     return ![[self _attributeKeys] containsObject:[NSString stringWithUTF8String:name]] && [super isKeyExcludedFromWebScript:name];
1319 }
1320
1321 - (id) initWithMessage:(NSString *)message ofType:(NSString *)type {
1322     if ((self = [super init]) != nil) {
1323         message_ = message;
1324         type_ = type;
1325     } return self;
1326 }
1327
1328 - (NSString *) message {
1329     return message_;
1330 }
1331
1332 - (NSString *) type {
1333     return type_;
1334 }
1335
1336 - (NSArray *) item {
1337     return (id) item_ ?: [NSNull null];
1338 }
1339
1340 - (void) setItem:(NSArray *)item {
1341     item_ = item;
1342 }
1343
1344 - (NSString *) package {
1345     return (id) package_ ?: [NSNull null];
1346 }
1347
1348 - (void) setPackage:(NSString *)package {
1349     package_ = package;
1350 }
1351
1352 - (NSString *) url {
1353     return (id) url_ ?: [NSNull null];
1354 }
1355
1356 - (void) setURL:(NSString *)url {
1357     url_ = url;
1358 }
1359
1360 - (void) setVersion:(NSString *)version {
1361     version_ = version;
1362 }
1363
1364 - (NSString *) version {
1365     return (id) version_ ?: [NSNull null];
1366 }
1367
1368 - (NSString *) compound:(NSString *)value {
1369     if (value != nil) {
1370         NSString *mode(nil); {
1371             NSString *type([self type]);
1372             if ([type isEqualToString:kCydiaProgressEventTypeError])
1373                 mode = UCLocalize("ERROR");
1374             else if ([type isEqualToString:kCydiaProgressEventTypeWarning])
1375                 mode = UCLocalize("WARNING");
1376         }
1377
1378         if (mode != nil)
1379             value = [NSString stringWithFormat:UCLocalize("COLON_DELIMITED"), mode, value];
1380     }
1381
1382     return value;
1383 }
1384
1385 - (NSString *) compoundMessage {
1386     return [self compound:[self message]];
1387 }
1388
1389 - (NSString *) compoundTitle {
1390     NSString *title;
1391
1392     if (package_ == nil)
1393         title = nil;
1394     else if (Package *package = [[Database sharedInstance] packageWithName:package_])
1395         title = [package name];
1396     else
1397         title = package_;
1398
1399     return [self compound:title];
1400 }
1401
1402 @end
1403 /* }}} */
1404
1405 // Cytore Definitions {{{
1406 struct PackageValue :
1407     Cytore::Block
1408 {
1409     Cytore::Offset<PackageValue> next_;
1410
1411     uint32_t index_ : 23;
1412     uint32_t subscribed_ : 1;
1413     uint32_t : 8;
1414
1415     int32_t first_;
1416     int32_t last_;
1417
1418     uint16_t vhash_;
1419     uint16_t nhash_;
1420
1421     char version_[8];
1422     char name_[];
1423 };
1424
1425 struct MetaValue :
1426     Cytore::Block
1427 {
1428     uint32_t active_;
1429     Cytore::Offset<PackageValue> packages_[1 << 16];
1430 };
1431
1432 static Cytore::File<MetaValue> MetaFile_;
1433 // }}}
1434 // Cytore Helper Functions {{{
1435 static PackageValue *PackageFind(const char *name, size_t length, bool *fail = NULL) {
1436     SplitHash nhash = { hashlittle(name, length) };
1437
1438     PackageValue *metadata;
1439
1440     Cytore::Offset<PackageValue> *offset(&MetaFile_->packages_[nhash.u16[0]]);
1441     for (;; offset = &metadata->next_) { if (offset->IsNull()) {
1442         *offset = MetaFile_.New<PackageValue>(length + 1);
1443         metadata = &MetaFile_.Get(*offset);
1444
1445         if (metadata == NULL) {
1446             if (fail != NULL)
1447                 *fail = true;
1448
1449             metadata = new PackageValue();
1450             memset(metadata, 0, sizeof(*metadata));
1451         }
1452
1453         memcpy(metadata->name_, name, length);
1454         metadata->name_[length] = '\0';
1455         metadata->nhash_ = nhash.u16[1];
1456     } else {
1457         metadata = &MetaFile_.Get(*offset);
1458         if (metadata->nhash_ != nhash.u16[1])
1459             continue;
1460         if (strncmp(metadata->name_, name, length) != 0)
1461             continue;
1462         if (metadata->name_[length] != '\0')
1463             continue;
1464     } break; }
1465
1466     return metadata;
1467 }
1468
1469 static void PackageImport(const void *key, const void *value, void *context) {
1470     bool &fail(*reinterpret_cast<bool *>(context));
1471
1472     char buffer[1024];
1473     if (!CFStringGetCString((CFStringRef) key, buffer, sizeof(buffer), kCFStringEncodingUTF8)) {
1474         NSLog(@"failed to import package %@", key);
1475         return;
1476     }
1477
1478     PackageValue *metadata(PackageFind(buffer, strlen(buffer), &fail));
1479     NSDictionary *package((NSDictionary *) value);
1480
1481     if (NSNumber *subscribed = [package objectForKey:@"IsSubscribed"])
1482         if ([subscribed boolValue] && !metadata->subscribed_)
1483             metadata->subscribed_ = true;
1484
1485     if (NSDate *date = [package objectForKey:@"FirstSeen"]) {
1486         time_t time([date timeIntervalSince1970]);
1487         if (metadata->first_ > time || metadata->first_ == 0)
1488             metadata->first_ = time;
1489     }
1490
1491     NSDate *date([package objectForKey:@"LastSeen"]);
1492     NSString *version([package objectForKey:@"LastVersion"]);
1493
1494     if (date != nil && version != nil) {
1495         time_t time([date timeIntervalSince1970]);
1496         if (metadata->last_ < time || metadata->last_ == 0)
1497             if (CFStringGetCString((CFStringRef) version, buffer, sizeof(buffer), kCFStringEncodingUTF8)) {
1498                 size_t length(strlen(buffer));
1499                 uint16_t vhash(hashlittle(buffer, length));
1500
1501                 size_t capped(std::min<size_t>(8, length));
1502                 char *latest(buffer + length - capped);
1503
1504                 strncpy(metadata->version_, latest, sizeof(metadata->version_));
1505                 metadata->vhash_ = vhash;
1506
1507                 metadata->last_ = time;
1508             }
1509     }
1510 }
1511 // }}}
1512
1513 static NSDate *GetStatusDate() {
1514     return [[[NSFileManager defaultManager] attributesOfItemAtPath:@"/var/lib/dpkg/status" error:NULL] fileModificationDate];
1515 }
1516
1517 static void SaveConfig(NSObject *lock) {
1518     @synchronized (lock) {
1519         _trace();
1520         MetaFile_.Sync();
1521         _trace();
1522     }
1523
1524     CFPreferencesSetMultiple((CFDictionaryRef) [NSDictionary dictionaryWithObjectsAndKeys:
1525         Values_, @"CydiaValues",
1526         Sections_, @"CydiaSections",
1527         (id) Sources_, @"CydiaSources",
1528         Version_, @"CydiaVersion",
1529     nil], NULL, CFSTR("com.saurik.Cydia"), kCFPreferencesCurrentUser, kCFPreferencesCurrentHost);
1530
1531     if (!CFPreferencesAppSynchronize(CFSTR("com.saurik.Cydia")))
1532         NSLog(@"CFPreferencesAppSynchronize(com.saurik.Cydia) == false");
1533
1534     CydiaWriteSources();
1535 }
1536
1537 /* Source Class {{{ */
1538 @interface Source : NSObject {
1539     unsigned era_;
1540     Database *database_;
1541     metaIndex *index_;
1542
1543     CYString depiction_;
1544     CYString description_;
1545     CYString label_;
1546     CYString origin_;
1547     CYString support_;
1548
1549     CYString uri_;
1550     CYString distribution_;
1551     CYString type_;
1552     CYString base_;
1553     CYString version_;
1554
1555     _H<NSString> host_;
1556     _H<NSString> authority_;
1557
1558     CYString defaultIcon_;
1559
1560     _H<NSMutableDictionary> record_;
1561     BOOL trusted_;
1562
1563     std::set<std::string> fetches_;
1564     std::set<std::string> files_;
1565     _transient NSObject<SourceDelegate> *delegate_;
1566 }
1567
1568 - (Source *) initWithMetaIndex:(metaIndex *)index forDatabase:(Database *)database inPool:(CYPool *)pool;
1569
1570 - (NSComparisonResult) compareByName:(Source *)source;
1571
1572 - (NSString *) depictionForPackage:(NSString *)package;
1573 - (NSString *) supportForPackage:(NSString *)package;
1574
1575 - (metaIndex *) metaIndex;
1576 - (NSDictionary *) record;
1577 - (BOOL) trusted;
1578
1579 - (NSString *) rooturi;
1580 - (NSString *) distribution;
1581 - (NSString *) type;
1582
1583 - (NSString *) key;
1584 - (NSString *) host;
1585
1586 - (NSString *) name;
1587 - (NSString *) shortDescription;
1588 - (NSString *) label;
1589 - (NSString *) origin;
1590 - (NSString *) version;
1591
1592 - (NSString *) defaultIcon;
1593 - (NSURL *) iconURL;
1594
1595 - (void) setFetch:(bool)fetch forURI:(const char *)uri;
1596 - (void) resetFetch;
1597
1598 @end
1599
1600 @implementation Source
1601
1602 + (NSString *) webScriptNameForSelector:(SEL)selector {
1603     if (false);
1604     else if (selector == @selector(addSection:))
1605         return @"addSection";
1606     else if (selector == @selector(getField:))
1607         return @"getField";
1608     else if (selector == @selector(removeSection:))
1609         return @"removeSection";
1610     else if (selector == @selector(remove))
1611         return @"remove";
1612     else
1613         return nil;
1614 }
1615
1616 + (BOOL) isSelectorExcludedFromWebScript:(SEL)selector {
1617     return [self webScriptNameForSelector:selector] == nil;
1618 }
1619
1620 + (NSArray *) _attributeKeys {
1621     return [NSArray arrayWithObjects:
1622         @"baseuri",
1623         @"distribution",
1624         @"host",
1625         @"key",
1626         @"iconuri",
1627         @"label",
1628         @"name",
1629         @"origin",
1630         @"rooturi",
1631         @"sections",
1632         @"shortDescription",
1633         @"trusted",
1634         @"type",
1635         @"version",
1636     nil];
1637 }
1638
1639 - (NSArray *) attributeKeys {
1640     return [[self class] _attributeKeys];
1641 }
1642
1643 + (BOOL) isKeyExcludedFromWebScript:(const char *)name {
1644     return ![[self _attributeKeys] containsObject:[NSString stringWithUTF8String:name]] && [super isKeyExcludedFromWebScript:name];
1645 }
1646
1647 - (metaIndex *) metaIndex {
1648     return index_;
1649 }
1650
1651 - (void) setMetaIndex:(metaIndex *)index inPool:(CYPool *)pool {
1652     trusted_ = index->IsTrusted();
1653
1654     uri_.set(pool, index->GetURI());
1655     distribution_.set(pool, index->GetDist());
1656     type_.set(pool, index->GetType());
1657
1658     debReleaseIndex *dindex(dynamic_cast<debReleaseIndex *>(index));
1659     if (dindex != NULL) {
1660         std::string file(dindex->MetaIndexURI(""));
1661         base_.set(pool, file);
1662
1663         pkgAcquire acquire;
1664         _profile(Source$setMetaIndex$GetIndexes)
1665         dindex->GetIndexes(&acquire, true);
1666         _end
1667         _profile(Source$setMetaIndex$DescURI)
1668         for (pkgAcquire::ItemIterator item(acquire.ItemsBegin()); item != acquire.ItemsEnd(); item++) {
1669             std::string file((*item)->DescURI());
1670             files_.insert(file);
1671             if (file.length() < sizeof("Packages.bz2") || file.substr(file.length() - sizeof("Packages.bz2")) != "/Packages.bz2")
1672                 continue;
1673             file = file.substr(0, file.length() - 4);
1674             files_.insert(file);
1675             files_.insert(file + ".gz");
1676             files_.insert(file + "Index");
1677         }
1678         _end
1679
1680         FileFd fd;
1681         if (!fd.Open(dindex->MetaIndexFile("Release"), FileFd::ReadOnly))
1682             _error->Discard();
1683         else {
1684             pkgTagFile tags(&fd);
1685
1686             pkgTagSection section;
1687             tags.Step(section);
1688
1689             struct {
1690                 const char *name_;
1691                 CYString *value_;
1692             } names[] = {
1693                 {"default-icon", &defaultIcon_},
1694                 {"depiction", &depiction_},
1695                 {"description", &description_},
1696                 {"label", &label_},
1697                 {"origin", &origin_},
1698                 {"support", &support_},
1699                 {"version", &version_},
1700             };
1701
1702             for (size_t i(0); i != sizeof(names) / sizeof(names[0]); ++i) {
1703                 const char *start, *end;
1704
1705                 if (section.Find(names[i].name_, start, end)) {
1706                     CYString &value(*names[i].value_);
1707                     value.set(pool, start, end - start);
1708                 }
1709             }
1710         }
1711     }
1712
1713     record_ = [Sources_ objectForKey:[self key]];
1714
1715     NSURL *url([NSURL URLWithString:uri_]);
1716
1717     host_ = [url host];
1718     if (host_ != nil)
1719         host_ = [host_ lowercaseString];
1720
1721     if (host_ != nil)
1722         authority_ = host_;
1723     else
1724         authority_ = [url path];
1725 }
1726
1727 - (Source *) initWithMetaIndex:(metaIndex *)index forDatabase:(Database *)database inPool:(CYPool *)pool {
1728     if ((self = [super init]) != nil) {
1729         era_ = [database era];
1730         database_ = database;
1731         index_ = index;
1732
1733         _profile(Source$initWithMetaIndex$setMetaIndex)
1734         [self setMetaIndex:index inPool:pool];
1735         _end
1736     } return self;
1737 }
1738
1739 - (NSString *) getField:(NSString *)name {
1740 @synchronized (database_) {
1741     if ([database_ era] != era_ || index_ == NULL)
1742         return nil;
1743
1744     debReleaseIndex *dindex(dynamic_cast<debReleaseIndex *>(index_));
1745     if (dindex == NULL)
1746         return nil;
1747
1748     FileFd fd;
1749     if (!fd.Open(dindex->MetaIndexFile("Release"), FileFd::ReadOnly)) {
1750          _error->Discard();
1751          return nil;
1752     }
1753
1754     pkgTagFile tags(&fd);
1755
1756     pkgTagSection section;
1757     tags.Step(section);
1758
1759     const char *start, *end;
1760     if (!section.Find([name UTF8String], start, end))
1761         return (NSString *) [NSNull null];
1762
1763     return [NSString stringWithString:[(NSString *) CYStringCreate(start, end - start) autorelease]];
1764 } }
1765
1766 - (NSComparisonResult) compareByName:(Source *)source {
1767     NSString *lhs = [self name];
1768     NSString *rhs = [source name];
1769
1770     if ([lhs length] != 0 && [rhs length] != 0) {
1771         unichar lhc = [lhs characterAtIndex:0];
1772         unichar rhc = [rhs characterAtIndex:0];
1773
1774         if (isalpha(lhc) && !isalpha(rhc))
1775             return NSOrderedAscending;
1776         else if (!isalpha(lhc) && isalpha(rhc))
1777             return NSOrderedDescending;
1778     }
1779
1780     return [lhs compare:rhs options:LaxCompareOptions_];
1781 }
1782
1783 - (NSString *) depictionForPackage:(NSString *)package {
1784     return depiction_.empty() ? nil : [static_cast<id>(depiction_) stringByReplacingOccurrencesOfString:@"*" withString:package];
1785 }
1786
1787 - (NSString *) supportForPackage:(NSString *)package {
1788     return support_.empty() ? nil : [static_cast<id>(support_) stringByReplacingOccurrencesOfString:@"*" withString:package];
1789 }
1790
1791 - (NSArray *) sections {
1792     return record_ == nil ? (id) [NSNull null] : [record_ objectForKey:@"Sections"] ?: [NSArray array];
1793 }
1794
1795 - (void) _addSection:(NSString *)section {
1796     if (record_ == nil)
1797         return;
1798     else if (NSMutableArray *sections = [record_ objectForKey:@"Sections"]) {
1799         if (![sections containsObject:section])
1800             [sections addObject:section];
1801     } else
1802         [record_ setObject:[NSMutableArray arrayWithObject:section] forKey:@"Sections"];
1803 }
1804
1805 - (bool) addSection:(NSString *)section {
1806     if (record_ == nil)
1807         return false;
1808
1809     [self performSelectorOnMainThread:@selector(_addSection:) withObject:section waitUntilDone:NO];
1810     return true;
1811 }
1812
1813 - (void) _removeSection:(NSString *)section {
1814     if (record_ == nil)
1815         return;
1816
1817     if (NSMutableArray *sections = [record_ objectForKey:@"Sections"])
1818         if ([sections containsObject:section])
1819             [sections removeObject:section];
1820 }
1821
1822 - (bool) removeSection:(NSString *)section {
1823     if (record_ == nil)
1824         return false;
1825
1826     [self performSelectorOnMainThread:@selector(_removeSection:) withObject:section waitUntilDone:NO];
1827     return true;
1828 }
1829
1830 - (void) _remove {
1831     [Sources_ removeObjectForKey:[self key]];
1832 }
1833
1834 - (bool) remove {
1835     bool value(record_ != nil);
1836     [self performSelectorOnMainThread:@selector(_remove) withObject:nil waitUntilDone:NO];
1837     return value;
1838 }
1839
1840 - (NSDictionary *) record {
1841     return record_;
1842 }
1843
1844 - (BOOL) trusted {
1845     return trusted_;
1846 }
1847
1848 - (NSString *) rooturi {
1849     return uri_;
1850 }
1851
1852 - (NSString *) distribution {
1853     return distribution_;
1854 }
1855
1856 - (NSString *) type {
1857     return type_;
1858 }
1859
1860 - (NSString *) baseuri {
1861     return base_.empty() ? nil : (id) base_;
1862 }
1863
1864 - (NSString *) iconuri {
1865     if (NSString *base = [self baseuri])
1866         return [base stringByAppendingString:@"CydiaIcon.png"];
1867
1868     return nil;
1869 }
1870
1871 - (NSURL *) iconURL {
1872     if (NSString *uri = [self iconuri])
1873         return [NSURL URLWithString:uri];
1874     return nil;
1875 }
1876
1877 - (NSString *) key {
1878     return [NSString stringWithFormat:@"%@:%@:%@", (NSString *) type_, (NSString *) uri_, (NSString *) distribution_];
1879 }
1880
1881 - (NSString *) host {
1882     return host_;
1883 }
1884
1885 - (NSString *) name {
1886     return origin_.empty() ? (id) authority_ : origin_;
1887 }
1888
1889 - (NSString *) shortDescription {
1890     return description_;
1891 }
1892
1893 - (NSString *) label {
1894     return label_.empty() ? (id) authority_ : label_;
1895 }
1896
1897 - (NSString *) origin {
1898     return origin_;
1899 }
1900
1901 - (NSString *) version {
1902     return version_;
1903 }
1904
1905 - (NSString *) defaultIcon {
1906     return defaultIcon_;
1907 }
1908
1909 - (void) setDelegate:(NSObject<SourceDelegate> *)delegate {
1910     delegate_ = delegate;
1911 }
1912
1913 - (bool) fetch {
1914     return !fetches_.empty();
1915 }
1916
1917 - (void) setFetch:(bool)fetch forURI:(const char *)uri {
1918     if (!fetch) {
1919         if (fetches_.erase(uri) == 0)
1920             return;
1921     } else if (files_.find(uri) == files_.end())
1922         return;
1923     else if (!fetches_.insert(uri).second)
1924         return;
1925
1926     [delegate_ performSelectorOnMainThread:@selector(setFetch:) withObject:[NSNumber numberWithBool:[self fetch]] waitUntilDone:NO];
1927 }
1928
1929 - (void) resetFetch {
1930     fetches_.clear();
1931     [delegate_ performSelectorOnMainThread:@selector(setFetch:) withObject:[NSNumber numberWithBool:NO] waitUntilDone:NO];
1932 }
1933
1934 @end
1935 /* }}} */
1936 /* CydiaOperation Class {{{ */
1937 @interface CydiaOperation : NSObject {
1938     _H<NSString> operator_;
1939     _H<NSString> value_;
1940 }
1941
1942 - (NSString *) operator;
1943 - (NSString *) value;
1944
1945 @end
1946
1947 @implementation CydiaOperation
1948
1949 - (id) initWithOperator:(const char *)_operator value:(const char *)value {
1950     if ((self = [super init]) != nil) {
1951         operator_ = [NSString stringWithUTF8String:_operator];
1952         value_ = [NSString stringWithUTF8String:value];
1953     } return self;
1954 }
1955
1956 + (NSArray *) _attributeKeys {
1957     return [NSArray arrayWithObjects:
1958         @"operator",
1959         @"value",
1960     nil];
1961 }
1962
1963 - (NSArray *) attributeKeys {
1964     return [[self class] _attributeKeys];
1965 }
1966
1967 + (BOOL) isKeyExcludedFromWebScript:(const char *)name {
1968     return ![[self _attributeKeys] containsObject:[NSString stringWithUTF8String:name]] && [super isKeyExcludedFromWebScript:name];
1969 }
1970
1971 - (NSString *) operator {
1972     return operator_;
1973 }
1974
1975 - (NSString *) value {
1976     return value_;
1977 }
1978
1979 @end
1980 /* }}} */
1981 /* CydiaClause Class {{{ */
1982 @interface CydiaClause : NSObject {
1983     _H<NSString> package_;
1984     _H<CydiaOperation> version_;
1985 }
1986
1987 - (NSString *) package;
1988 - (CydiaOperation *) version;
1989
1990 @end
1991
1992 @implementation CydiaClause
1993
1994 - (id) initWithIterator:(pkgCache::DepIterator &)dep {
1995     if ((self = [super init]) != nil) {
1996         package_ = [NSString stringWithUTF8String:dep.TargetPkg().Name()];
1997
1998         if (const char *version = dep.TargetVer())
1999             version_ = [[[CydiaOperation alloc] initWithOperator:dep.CompType() value:version] autorelease];
2000         else
2001             version_ = (id) [NSNull null];
2002     } return self;
2003 }
2004
2005 + (NSArray *) _attributeKeys {
2006     return [NSArray arrayWithObjects:
2007         @"package",
2008         @"version",
2009     nil];
2010 }
2011
2012 - (NSArray *) attributeKeys {
2013     return [[self class] _attributeKeys];
2014 }
2015
2016 + (BOOL) isKeyExcludedFromWebScript:(const char *)name {
2017     return ![[self _attributeKeys] containsObject:[NSString stringWithUTF8String:name]] && [super isKeyExcludedFromWebScript:name];
2018 }
2019
2020 - (NSString *) package {
2021     return package_;
2022 }
2023
2024 - (CydiaOperation *) version {
2025     return version_;
2026 }
2027
2028 @end
2029 /* }}} */
2030 /* CydiaRelation Class {{{ */
2031 @interface CydiaRelation : NSObject {
2032     _H<NSString> relationship_;
2033     _H<NSMutableArray> clauses_;
2034 }
2035
2036 - (NSString *) relationship;
2037 - (NSArray *) clauses;
2038
2039 @end
2040
2041 @implementation CydiaRelation
2042
2043 - (id) initWithIterator:(pkgCache::DepIterator &)dep {
2044     if ((self = [super init]) != nil) {
2045         relationship_ = [NSString stringWithUTF8String:dep.DepType()];
2046         clauses_ = [NSMutableArray arrayWithCapacity:8];
2047
2048         pkgCache::DepIterator start;
2049         pkgCache::DepIterator end;
2050         dep.GlobOr(start, end); // ++dep
2051
2052         _forever {
2053             [clauses_ addObject:[[[CydiaClause alloc] initWithIterator:start] autorelease]];
2054
2055             // yes, seriously. (wtf?)
2056             if (start == end)
2057                 break;
2058             ++start;
2059         }
2060     } return self;
2061 }
2062
2063 + (NSArray *) _attributeKeys {
2064     return [NSArray arrayWithObjects:
2065         @"clauses",
2066         @"relationship",
2067     nil];
2068 }
2069
2070 - (NSArray *) attributeKeys {
2071     return [[self class] _attributeKeys];
2072 }
2073
2074 + (BOOL) isKeyExcludedFromWebScript:(const char *)name {
2075     return ![[self _attributeKeys] containsObject:[NSString stringWithUTF8String:name]] && [super isKeyExcludedFromWebScript:name];
2076 }
2077
2078 - (NSString *) relationship {
2079     return relationship_;
2080 }
2081
2082 - (NSArray *) clauses {
2083     return clauses_;
2084 }
2085
2086 - (void) addClause:(CydiaClause *)clause {
2087     [clauses_ addObject:clause];
2088 }
2089
2090 @end
2091 /* }}} */
2092 /* Package Class {{{ */
2093 struct ParsedPackage {
2094     CYString md5sum_;
2095     CYString tagline_;
2096
2097     CYString architecture_;
2098     CYString icon_;
2099
2100     CYString depiction_;
2101     CYString homepage_;
2102     CYString author_;
2103
2104     CYString support_;
2105 };
2106
2107 @interface Package : NSObject {
2108     uint32_t era_ : 25;
2109     @public uint32_t role_ : 3;
2110     uint32_t essential_ : 1;
2111     uint32_t obsolete_ : 1;
2112     uint32_t ignored_ : 1;
2113     uint32_t pooled_ : 1;
2114
2115     CYPool *pool_;
2116
2117     uint32_t rank_;
2118
2119     _transient Database *database_;
2120
2121     pkgCache::VerIterator version_;
2122     pkgCache::PkgIterator iterator_;
2123     pkgCache::VerFileIterator file_;
2124
2125     CYString id_;
2126     CYString name_;
2127     CYString transform_;
2128
2129     CYString latest_;
2130     CYString installed_;
2131     time_t upgraded_;
2132
2133     const char *section_;
2134     _transient NSString *section$_;
2135
2136     _H<Source> source_;
2137
2138     PackageValue *metadata_;
2139     ParsedPackage *parsed_;
2140
2141     _H<NSMutableArray> tags_;
2142 }
2143
2144 - (Package *) initWithVersion:(pkgCache::VerIterator)version withZone:(NSZone *)zone inPool:(CYPool *)pool database:(Database *)database;
2145 + (Package *) packageWithIterator:(pkgCache::PkgIterator)iterator withZone:(NSZone *)zone inPool:(CYPool *)pool database:(Database *)database;
2146
2147 - (pkgCache::PkgIterator) iterator;
2148 - (void) parse;
2149
2150 - (NSString *) section;
2151 - (NSString *) simpleSection;
2152
2153 - (NSString *) longSection;
2154 - (NSString *) shortSection;
2155
2156 - (NSString *) uri;
2157
2158 - (MIMEAddress *) maintainer;
2159 - (size_t) size;
2160 - (NSString *) longDescription;
2161 - (NSString *) shortDescription;
2162 - (unichar) index;
2163
2164 - (PackageValue *) metadata;
2165 - (time_t) seen;
2166
2167 - (bool) subscribed;
2168 - (bool) setSubscribed:(bool)subscribed;
2169
2170 - (BOOL) ignored;
2171
2172 - (NSString *) latest;
2173 - (NSString *) installed;
2174 - (BOOL) uninstalled;
2175
2176 - (BOOL) upgradableAndEssential:(BOOL)essential;
2177 - (BOOL) essential;
2178 - (BOOL) broken;
2179 - (BOOL) unfiltered;
2180 - (BOOL) visible;
2181
2182 - (BOOL) half;
2183 - (BOOL) halfConfigured;
2184 - (BOOL) halfInstalled;
2185 - (BOOL) hasMode;
2186 - (NSString *) mode;
2187
2188 - (NSString *) id;
2189 - (NSString *) name;
2190 - (UIImage *) icon;
2191 - (NSString *) homepage;
2192 - (NSString *) depiction;
2193 - (MIMEAddress *) author;
2194
2195 - (NSString *) support;
2196
2197 - (NSArray *) files;
2198 - (NSArray *) warnings;
2199 - (NSArray *) applications;
2200
2201 - (Source *) source;
2202
2203 - (uint32_t) rank;
2204 - (BOOL) matches:(NSArray *)query;
2205
2206 - (BOOL) hasTag:(NSString *)tag;
2207 - (NSString *) primaryPurpose;
2208 - (NSArray *) purposes;
2209 - (bool) isCommercial;
2210
2211 - (void) setIndex:(size_t)index;
2212
2213 - (CYString &) cyname;
2214
2215 - (uint32_t) compareBySection:(NSArray *)sections;
2216
2217 - (void) install;
2218 - (void) remove;
2219
2220 @end
2221
2222 uint32_t PackageChangesRadix(Package *self, void *) {
2223     union {
2224         uint32_t key;
2225
2226         struct {
2227             uint32_t timestamp : 30;
2228             uint32_t ignored : 1;
2229             uint32_t upgradable : 1;
2230         } bits;
2231     } value;
2232
2233     bool upgradable([self upgradableAndEssential:YES]);
2234     value.bits.upgradable = upgradable ? 1 : 0;
2235
2236     if (upgradable) {
2237         value.bits.timestamp = 0;
2238         value.bits.ignored = [self ignored] ? 0 : 1;
2239         value.bits.upgradable = 1;
2240     } else {
2241         value.bits.timestamp = [self seen] >> 2;
2242         value.bits.ignored = 0;
2243         value.bits.upgradable = 0;
2244     }
2245
2246     return _not(uint32_t) - value.key;
2247 }
2248
2249 CYString &(*PackageName)(Package *self, SEL sel);
2250
2251 uint32_t PackagePrefixRadix(Package *self, void *context) {
2252     size_t offset(reinterpret_cast<size_t>(context));
2253     CYString &name(PackageName(self, @selector(cyname)));
2254
2255     size_t size(name.size());
2256     if (size == 0)
2257         return 0;
2258     char *text(name.data());
2259
2260     size_t zeros;
2261     if (!isdigit(text[0]))
2262         zeros = 0;
2263     else {
2264         size_t digits(1);
2265         while (size != digits && isdigit(text[digits]))
2266             if (++digits == 4)
2267                 break;
2268         zeros = 4 - digits;
2269     }
2270
2271     uint8_t data[4];
2272
2273     if (offset == 0 && zeros != 0) {
2274         memset(data, '0', zeros);
2275         memcpy(data + zeros, text, 4 - zeros);
2276     } else {
2277         /* XXX: there's some danger here if you request a non-zero offset < 4 and it gets zero padded */
2278         if (size <= offset - zeros)
2279             return 0;
2280
2281         text += offset - zeros;
2282         size -= offset - zeros;
2283
2284         if (size >= 4)
2285             memcpy(data, text, 4);
2286         else {
2287             memcpy(data, text, size);
2288             memset(data + size, 0, 4 - size);
2289         }
2290
2291         for (size_t i(0); i != 4; ++i)
2292             if (isalpha(data[i]))
2293                 data[i] |= 0x20;
2294     }
2295
2296     if (offset == 0)
2297         if (data[0] == '@')
2298             data[0] = 0x7f;
2299         else
2300             data[0] = (data[0] & 0x1f) | "\x80\x00\xc0\x40"[data[0] >> 6];
2301
2302     /* XXX: ntohl may be more honest */
2303     return OSSwapInt32(*reinterpret_cast<uint32_t *>(data));
2304 }
2305
2306 CFComparisonResult StringNameCompare(CFStringRef lhn, CFStringRef rhn, size_t length) {
2307     _profile(PackageNameCompare)
2308         if (lhn == NULL)
2309             return rhn == NULL ? kCFCompareEqualTo : kCFCompareLessThan;
2310         else if (rhn == NULL)
2311             return kCFCompareGreaterThan;
2312
2313         CFIndex length(CFStringGetLength(lhn));
2314
2315         _profile(PackageNameCompare$NumbersLast)
2316             if (length != 0 && CFStringGetLength(rhn) != 0) {
2317                 UniChar lhc(CFStringGetCharacterAtIndex(lhn, 0));
2318                 UniChar rhc(CFStringGetCharacterAtIndex(rhn, 0));
2319                 bool lha(CFUniCharIsMemberOf(lhc, kCFUniCharLetterCharacterSet));
2320                 if (lha != CFUniCharIsMemberOf(rhc, kCFUniCharLetterCharacterSet))
2321                     return lha ? kCFCompareLessThan : kCFCompareGreaterThan;
2322             }
2323         _end
2324
2325         _profile(PackageNameCompare$Compare)
2326             return CFStringCompareWithOptionsAndLocale(lhn, rhn, CFRangeMake(0, length), LaxCompareFlags_, (CFLocaleRef) (id) CollationLocale_);
2327         _end
2328     _end
2329 }
2330
2331 _finline CFComparisonResult StringNameCompare(NSString *lhn, NSString*rhn, size_t length) {
2332     return StringNameCompare((CFStringRef) lhn, (CFStringRef) rhn, length);
2333 }
2334
2335 CFComparisonResult PackageNameCompare(Package *lhs, Package *rhs, void *arg) {
2336     CYString &lhn(PackageName(lhs, @selector(cyname)));
2337     NSString *rhn(PackageName(rhs, @selector(cyname)));
2338     return StringNameCompare(lhn, rhn, lhn.size());
2339 }
2340
2341 CFComparisonResult PackageNameCompare_(Package **lhs, Package **rhs, void *arg) {
2342     return PackageNameCompare(*lhs, *rhs, arg);
2343 }
2344
2345 struct PackageNameOrdering :
2346     std::binary_function<Package *, Package *, bool>
2347 {
2348     _finline bool operator ()(Package *lhs, Package *rhs) const {
2349         return PackageNameCompare(lhs, rhs, NULL) == kCFCompareLessThan;
2350     }
2351 };
2352
2353 @implementation Package
2354
2355 - (NSString *) description {
2356     return [NSString stringWithFormat:@"<Package:%@>", static_cast<NSString *>(name_)];
2357 }
2358
2359 - (void) dealloc {
2360     if (!pooled_)
2361         delete pool_;
2362     if (parsed_ != NULL)
2363         delete parsed_;
2364     [super dealloc];
2365 }
2366
2367 + (NSString *) webScriptNameForSelector:(SEL)selector {
2368     if (false);
2369     else if (selector == @selector(clear))
2370         return @"clear";
2371     else if (selector == @selector(getField:))
2372         return @"getField";
2373     else if (selector == @selector(getRecord))
2374         return @"getRecord";
2375     else if (selector == @selector(hasTag:))
2376         return @"hasTag";
2377     else if (selector == @selector(install))
2378         return @"install";
2379     else if (selector == @selector(remove))
2380         return @"remove";
2381     else
2382         return nil;
2383 }
2384
2385 + (BOOL) isSelectorExcludedFromWebScript:(SEL)selector {
2386     return [self webScriptNameForSelector:selector] == nil;
2387 }
2388
2389 + (NSArray *) _attributeKeys {
2390     return [NSArray arrayWithObjects:
2391         @"applications",
2392         @"architecture",
2393         @"author",
2394         @"depiction",
2395         @"essential",
2396         @"homepage",
2397         @"icon",
2398         @"id",
2399         @"installed",
2400         @"latest",
2401         @"longDescription",
2402         @"longSection",
2403         @"maintainer",
2404         @"md5sum",
2405         @"mode",
2406         @"name",
2407         @"purposes",
2408         @"relations",
2409         @"section",
2410         @"selection",
2411         @"shortDescription",
2412         @"shortSection",
2413         @"simpleSection",
2414         @"size",
2415         @"source",
2416         @"state",
2417         @"support",
2418         @"tags",
2419         @"upgraded",
2420         @"warnings",
2421     nil];
2422 }
2423
2424 - (NSArray *) attributeKeys {
2425     return [[self class] _attributeKeys];
2426 }
2427
2428 + (BOOL) isKeyExcludedFromWebScript:(const char *)name {
2429     return ![[self _attributeKeys] containsObject:[NSString stringWithUTF8String:name]] && [super isKeyExcludedFromWebScript:name];
2430 }
2431
2432 - (NSArray *) relations {
2433 @synchronized (database_) {
2434     NSMutableArray *relations([NSMutableArray arrayWithCapacity:16]);
2435     for (pkgCache::DepIterator dep(version_.DependsList()); !dep.end(); ++dep)
2436         [relations addObject:[[[CydiaRelation alloc] initWithIterator:dep] autorelease]];
2437     return relations;
2438 } }
2439
2440 - (NSString *) architecture {
2441     [self parse];
2442 @synchronized (database_) {
2443     return parsed_->architecture_.empty() ? [NSNull null] : (id) parsed_->architecture_;
2444 } }
2445
2446 - (NSString *) getField:(NSString *)name {
2447 @synchronized (database_) {
2448     if ([database_ era] != era_ || file_.end())
2449         return nil;
2450
2451     pkgRecords::Parser &parser([database_ records]->Lookup(file_));
2452
2453     const char *start, *end;
2454     if (!parser.Find([name UTF8String], start, end))
2455         return (NSString *) [NSNull null];
2456
2457     return [NSString stringWithString:[(NSString *) CYStringCreate(start, end - start) autorelease]];
2458 } }
2459
2460 - (NSString *) getRecord {
2461 @synchronized (database_) {
2462     if ([database_ era] != era_ || file_.end())
2463         return nil;
2464
2465     pkgRecords::Parser &parser([database_ records]->Lookup(file_));
2466
2467     const char *start, *end;
2468     parser.GetRec(start, end);
2469
2470     return [NSString stringWithString:[(NSString *) CYStringCreate(start, end - start) autorelease]];
2471 } }
2472
2473 - (void) parse {
2474     if (parsed_ != NULL)
2475         return;
2476 @synchronized (database_) {
2477     if ([database_ era] != era_ || file_.end())
2478         return;
2479
2480     ParsedPackage *parsed(new ParsedPackage);
2481     parsed_ = parsed;
2482
2483     _profile(Package$parse)
2484         pkgRecords::Parser *parser;
2485
2486         _profile(Package$parse$Lookup)
2487             parser = &[database_ records]->Lookup(file_);
2488         _end
2489
2490         CYString bugs;
2491         CYString website;
2492
2493         _profile(Package$parse$Find)
2494             struct {
2495                 const char *name_;
2496                 CYString *value_;
2497             } names[] = {
2498                 {"architecture", &parsed->architecture_},
2499                 {"icon", &parsed->icon_},
2500                 {"depiction", &parsed->depiction_},
2501                 {"homepage", &parsed->homepage_},
2502                 {"website", &website},
2503                 {"bugs", &bugs},
2504                 {"support", &parsed->support_},
2505                 {"author", &parsed->author_},
2506                 {"md5sum", &parsed->md5sum_},
2507             };
2508
2509             for (size_t i(0); i != sizeof(names) / sizeof(names[0]); ++i) {
2510                 const char *start, *end;
2511
2512                 if (parser->Find(names[i].name_, start, end)) {
2513                     CYString &value(*names[i].value_);
2514                     _profile(Package$parse$Value)
2515                         value.set(pool_, start, end - start);
2516                     _end
2517                 }
2518             }
2519         _end
2520
2521         _profile(Package$parse$Tagline)
2522             parsed->tagline_.set(pool_, parser->ShortDesc());
2523         _end
2524
2525         _profile(Package$parse$Retain)
2526             if (parsed->homepage_.empty())
2527                 parsed->homepage_ = website;
2528             if (parsed->homepage_ == parsed->depiction_)
2529                 parsed->homepage_.clear();
2530             if (parsed->support_.empty())
2531                 parsed->support_ = bugs;
2532         _end
2533     _end
2534 } }
2535
2536 - (Package *) initWithVersion:(pkgCache::VerIterator)version withZone:(NSZone *)zone inPool:(CYPool *)pool database:(Database *)database {
2537     if ((self = [super init]) != nil) {
2538     _profile(Package$initWithVersion)
2539         if (pool == NULL)
2540             pool_ = new CYPool();
2541         else {
2542             pool_ = pool;
2543             pooled_ = true;
2544         }
2545
2546         database_ = database;
2547         era_ = [database era];
2548
2549         version_ = version;
2550
2551         pkgCache::PkgIterator iterator(version_.ParentPkg());
2552         iterator_ = iterator;
2553
2554         _profile(Package$initWithVersion$Version)
2555             file_ = version_.FileList();
2556         _end
2557
2558         _profile(Package$initWithVersion$Cache)
2559             name_.set(NULL, version_.Display());
2560
2561             latest_.set(NULL, StripVersion_(version_.VerStr()));
2562
2563             pkgCache::VerIterator current(iterator.CurrentVer());
2564             if (!current.end())
2565                 installed_.set(NULL, StripVersion_(current.VerStr()));
2566         _end
2567
2568         _profile(Package$initWithVersion$Transliterate) do {
2569             if (CollationTransl_ == NULL)
2570                 break;
2571             if (name_.empty())
2572                 break;
2573
2574             _profile(Package$initWithVersion$Transliterate$utf8)
2575             const uint8_t *data(reinterpret_cast<const uint8_t *>(name_.data()));
2576             for (size_t i(0), e(name_.size()); i != e; ++i)
2577                 if (data[i] >= 0x80)
2578                     goto extended;
2579             break; extended:;
2580             _end
2581
2582             UErrorCode code(U_ZERO_ERROR);
2583             int32_t length;
2584
2585             _profile(Package$initWithVersion$Transliterate$u_strFromUTF8WithSub)
2586             CollationString_.resize(name_.size());
2587             u_strFromUTF8WithSub(&CollationString_[0], CollationString_.size(), &length, name_.data(), name_.size(), 0xfffd, NULL, &code);
2588             if (!U_SUCCESS(code))
2589                 break;
2590             CollationString_.resize(length);
2591             _end
2592
2593             _profile(Package$initWithVersion$Transliterate$utrans_trans)
2594             length = CollationString_.size();
2595             utrans_trans(CollationTransl_, reinterpret_cast<UReplaceable *>(&CollationString_), &CollationUCalls_, 0, &length, &code);
2596             if (!U_SUCCESS(code))
2597                 break;
2598             _assert(CollationString_.size() == length);
2599             _end
2600
2601             _profile(Package$initWithVersion$Transliterate$u_strToUTF8WithSub$preflight)
2602             u_strToUTF8WithSub(NULL, 0, &length, CollationString_.data(), CollationString_.size(), 0xfffd, NULL, &code);
2603             if (code == U_BUFFER_OVERFLOW_ERROR)
2604                 code = U_ZERO_ERROR;
2605             else if (!U_SUCCESS(code))
2606                 break;
2607             _end
2608
2609             char *transform;
2610             _profile(Package$initWithVersion$Transliterate$apr_palloc)
2611             transform = pool_->malloc<char>(length);
2612             _end
2613             _profile(Package$initWithVersion$Transliterate$u_strToUTF8WithSub$transform)
2614             u_strToUTF8WithSub(transform, length, NULL, CollationString_.data(), CollationString_.size(), 0xfffd, NULL, &code);
2615             if (!U_SUCCESS(code))
2616                 break;
2617             _end
2618
2619             transform_.set(NULL, transform, length);
2620         } while (false); _end
2621
2622         _profile(Package$initWithVersion$Tags)
2623 #ifdef __arm64__
2624             pkgCache::TagIterator tag(version_.TagList());
2625 #else
2626             pkgCache::TagIterator tag(iterator.TagList());
2627 #endif
2628             if (!tag.end()) {
2629                 tags_ = [NSMutableArray arrayWithCapacity:8];
2630
2631                 goto tag; for (; !tag.end(); ++tag) tag: {
2632                     const char *name(tag.Name());
2633                     NSString *string((NSString *) CYStringCreate(name));
2634                     if (string == nil)
2635                         continue;
2636
2637                     [tags_ addObject:[string autorelease]];
2638
2639                     if (role_ == 0 && strncmp(name, "role::", 6) == 0 /*&& strcmp(name, "role::leaper") != 0*/) {
2640                         if (strcmp(name + 6, "enduser") == 0)
2641                             role_ = 1;
2642                         else if (strcmp(name + 6, "hacker") == 0)
2643                             role_ = 2;
2644                         else if (strcmp(name + 6, "developer") == 0)
2645                             role_ = 3;
2646                         else if (strcmp(name + 6, "cydia") == 0)
2647                             role_ = 7;
2648                         else
2649                             role_ = 4;
2650                     }
2651
2652                     if (strncmp(name, "cydia::", 7) == 0) {
2653                         if (strcmp(name + 7, "essential") == 0)
2654                             essential_ = true;
2655                         else if (strcmp(name + 7, "obsolete") == 0)
2656                             obsolete_ = true;
2657                     }
2658                 }
2659             }
2660         _end
2661
2662         _profile(Package$initWithVersion$Metadata)
2663             const char *mixed(iterator.Name());
2664             size_t size(strlen(mixed));
2665             static const size_t prefix(sizeof("/var/lib/dpkg/info/") - 1);
2666             char lower[prefix + size + 5 + 1];
2667
2668             for (size_t i(0); i != size; ++i)
2669                 lower[prefix + i] = mixed[i] | 0x20;
2670
2671             if (!installed_.empty()) {
2672                 memcpy(lower, "/var/lib/dpkg/info/", prefix);
2673                 memcpy(lower + prefix + size, ".list", 6);
2674                 struct stat info;
2675                 if (stat(lower, &info) != -1)
2676                     upgraded_ = info.st_birthtime;
2677             }
2678
2679             PackageValue *metadata(PackageFind(lower + prefix, size));
2680             metadata_ = metadata;
2681
2682             id_.set(NULL, metadata->name_, size);
2683
2684             const char *latest(version_.VerStr());
2685             size_t length(strlen(latest));
2686
2687             uint16_t vhash(hashlittle(latest, length));
2688
2689             size_t capped(std::min<size_t>(8, length));
2690             latest = latest + length - capped;
2691
2692             if (metadata->first_ == 0)
2693                 metadata->first_ = now_;
2694
2695             if (metadata->vhash_ != vhash || strncmp(metadata->version_, latest, sizeof(metadata->version_)) != 0) {
2696                 strncpy(metadata->version_, latest, sizeof(metadata->version_));
2697                 metadata->vhash_ = vhash;
2698                 metadata->last_ = now_;
2699             } else if (metadata->last_ == 0)
2700                 metadata->last_ = metadata->first_;
2701         _end
2702
2703         _profile(Package$initWithVersion$Section)
2704             section_ = version_.Section();
2705         _end
2706
2707         _profile(Package$initWithVersion$Flags)
2708             essential_ |= ((iterator->Flags & pkgCache::Flag::Essential) == 0 ? NO : YES);
2709             ignored_ = iterator->SelectedState == pkgCache::State::Hold;
2710         _end
2711     _end } return self;
2712 }
2713
2714 + (Package *) packageWithIterator:(pkgCache::PkgIterator)iterator withZone:(NSZone *)zone inPool:(CYPool *)pool database:(Database *)database {
2715     pkgCache::VerIterator version;
2716
2717     _profile(Package$packageWithIterator$GetCandidateVer)
2718         version = [database policy]->GetCandidateVer(iterator);
2719     _end
2720
2721     if (version.end())
2722         return nil;
2723
2724     Package *package;
2725
2726     _profile(Package$packageWithIterator$Allocate)
2727         package = [Package allocWithZone:zone];
2728     _end
2729
2730     _profile(Package$packageWithIterator$Initialize)
2731         package = [package
2732             initWithVersion:version
2733             withZone:zone
2734             inPool:pool
2735             database:database
2736         ];
2737     _end
2738
2739     _profile(Package$packageWithIterator$Autorelease)
2740         package = [package autorelease];
2741     _end
2742
2743     return package;
2744 }
2745
2746 - (pkgCache::PkgIterator) iterator {
2747     return iterator_;
2748 }
2749
2750 - (NSArray *) downgrades {
2751     NSMutableArray *versions([NSMutableArray arrayWithCapacity:4]);
2752
2753     for (auto version(iterator_.VersionList()); !version.end(); ++version) {
2754         if (version == version_)
2755             continue;
2756         Package *package([[[Package allocWithZone:NULL] initWithVersion:version withZone:NULL inPool:NULL database:database_] autorelease]);
2757         if ([package source] == nil)
2758             continue;
2759         [versions addObject:package];
2760     }
2761
2762     return versions;
2763 }
2764
2765 - (NSString *) section {
2766     if (section$_ == nil) {
2767         if (section_ == NULL)
2768             return nil;
2769
2770         _profile(Package$section$mappedSectionForPointer)
2771             section$_ = [database_ mappedSectionForPointer:section_];
2772         _end
2773     } return section$_;
2774 }
2775
2776 - (NSString *) simpleSection {
2777     if (NSString *section = [self section])
2778         return Simplify(section);
2779     else
2780         return nil;
2781 }
2782
2783 - (NSString *) longSection {
2784     if (NSString *section = [self section])
2785         return LocalizeSection(section);
2786     else
2787         return nil;
2788 }
2789
2790 - (NSString *) shortSection {
2791     return [[NSBundle mainBundle] localizedStringForKey:[self simpleSection] value:nil table:@"Sections"];
2792 }
2793
2794 - (NSString *) uri {
2795     return nil;
2796 #if 0
2797     pkgIndexFile *index;
2798     pkgCache::PkgFileIterator file(file_.File());
2799     if (![database_ list].FindIndex(file, index))
2800         return nil;
2801     return [NSString stringWithUTF8String:iterator_->Path];
2802     //return [NSString stringWithUTF8String:file.Site()];
2803     //return [NSString stringWithUTF8String:index->ArchiveURI(file.FileName()).c_str()];
2804 #endif
2805 }
2806
2807 - (MIMEAddress *) maintainer {
2808 @synchronized (database_) {
2809     if ([database_ era] != era_ || file_.end())
2810         return nil;
2811
2812     pkgRecords::Parser *parser = &[database_ records]->Lookup(file_);
2813     const std::string &maintainer(parser->Maintainer());
2814     return maintainer.empty() ? nil : [MIMEAddress addressWithString:[NSString stringWithUTF8String:maintainer.c_str()]];
2815 } }
2816
2817 - (NSString *) md5sum {
2818     return parsed_ == NULL ? nil : (id) parsed_->md5sum_;
2819 }
2820
2821 - (size_t) size {
2822 @synchronized (database_) {
2823     if ([database_ era] != era_ || version_.end())
2824         return 0;
2825
2826     return version_->InstalledSize;
2827 } }
2828
2829 - (NSString *) longDescription {
2830 @synchronized (database_) {
2831     if ([database_ era] != era_ || file_.end())
2832         return nil;
2833
2834     pkgRecords::Parser *parser = &[database_ records]->Lookup(file_);
2835     NSString *description([NSString stringWithUTF8String:parser->LongDesc().c_str()]);
2836
2837     NSArray *lines = [description componentsSeparatedByString:@"\n"];
2838     NSMutableArray *trimmed = [NSMutableArray arrayWithCapacity:([lines count] - 1)];
2839     if ([lines count] < 2)
2840         return nil;
2841
2842     NSCharacterSet *whitespace = [NSCharacterSet whitespaceCharacterSet];
2843     for (size_t i(1), e([lines count]); i != e; ++i) {
2844         NSString *trim = [[lines objectAtIndex:i] stringByTrimmingCharactersInSet:whitespace];
2845         [trimmed addObject:trim];
2846     }
2847
2848     return [trimmed componentsJoinedByString:@"\n"];
2849 } }
2850
2851 - (NSString *) shortDescription {
2852     if (parsed_ != NULL)
2853         return static_cast<NSString *>(parsed_->tagline_);
2854
2855 @synchronized (database_) {
2856     pkgRecords::Parser &parser([database_ records]->Lookup(file_));
2857     std::string value(parser.ShortDesc());
2858     if (value.empty())
2859         return nil;
2860     if (value.size() > 200)
2861         value.resize(200);
2862     return [(id) CYStringCreate(value) autorelease];
2863 } }
2864
2865 - (unichar) index {
2866     _profile(Package$index)
2867         CFStringRef name((CFStringRef) [self name]);
2868         if (CFStringGetLength(name) == 0)
2869             return '#';
2870         UniChar character(CFStringGetCharacterAtIndex(name, 0));
2871         if (!CFUniCharIsMemberOf(character, kCFUniCharLetterCharacterSet))
2872             return '#';
2873         return toupper(character);
2874     _end
2875 }
2876
2877 - (PackageValue *) metadata {
2878     return metadata_;
2879 }
2880
2881 - (time_t) seen {
2882     PackageValue *metadata([self metadata]);
2883     return metadata->subscribed_ ? metadata->last_ : metadata->first_;
2884 }
2885
2886 - (bool) subscribed {
2887     return [self metadata]->subscribed_;
2888 }
2889
2890 - (bool) setSubscribed:(bool)subscribed {
2891     PackageValue *metadata([self metadata]);
2892     if (metadata->subscribed_ == subscribed)
2893         return false;
2894     metadata->subscribed_ = subscribed;
2895     return true;
2896 }
2897
2898 - (BOOL) ignored {
2899     return ignored_;
2900 }
2901
2902 - (NSString *) latest {
2903     return latest_;
2904 }
2905
2906 - (NSString *) installed {
2907     return installed_;
2908 }
2909
2910 - (BOOL) uninstalled {
2911     return installed_.empty();
2912 }
2913
2914 - (BOOL) upgradableAndEssential:(BOOL)essential {
2915     _profile(Package$upgradableAndEssential)
2916         pkgCache::VerIterator current(iterator_.CurrentVer());
2917         if (current.end())
2918             return essential && essential_;
2919         else
2920             return version_ != current;
2921     _end
2922 }
2923
2924 - (BOOL) essential {
2925     return essential_;
2926 }
2927
2928 - (BOOL) broken {
2929     return [database_ cache][iterator_].InstBroken();
2930 }
2931
2932 - (BOOL) unfiltered {
2933     _profile(Package$unfiltered$obsolete)
2934         if (_unlikely(obsolete_))
2935             return false;
2936     _end
2937
2938     _profile(Package$unfiltered$role)
2939         if (_unlikely(role_ > 3))
2940             return false;
2941     _end
2942
2943     return true;
2944 }
2945
2946 - (BOOL) visible {
2947     if (![self unfiltered])
2948         return false;
2949
2950     NSString *section;
2951
2952     _profile(Package$visible$section)
2953         section = [self section];
2954     _end
2955
2956     _profile(Package$visible$isSectionVisible)
2957         if (!isSectionVisible(section))
2958             return false;
2959     _end
2960
2961     return true;
2962 }
2963
2964 - (BOOL) half {
2965     unsigned char current(iterator_->CurrentState);
2966     return current == pkgCache::State::HalfConfigured || current == pkgCache::State::HalfInstalled;
2967 }
2968
2969 - (BOOL) halfConfigured {
2970     return iterator_->CurrentState == pkgCache::State::HalfConfigured;
2971 }
2972
2973 - (BOOL) halfInstalled {
2974     return iterator_->CurrentState == pkgCache::State::HalfInstalled;
2975 }
2976
2977 - (BOOL) hasMode {
2978 @synchronized (database_) {
2979     if ([database_ era] != era_ || iterator_.end())
2980         return NO;
2981
2982     pkgDepCache::StateCache &state([database_ cache][iterator_]);
2983     return state.Mode != pkgDepCache::ModeKeep;
2984 } }
2985
2986 - (NSString *) mode {
2987 @synchronized (database_) {
2988     if ([database_ era] != era_ || iterator_.end())
2989         return nil;
2990
2991     pkgDepCache::StateCache &state([database_ cache][iterator_]);
2992
2993     switch (state.Mode) {
2994         case pkgDepCache::ModeDelete:
2995             if ((state.iFlags & pkgDepCache::Purge) != 0)
2996                 return @"PURGE";
2997             else
2998                 return @"REMOVE";
2999         case pkgDepCache::ModeKeep:
3000             if ((state.iFlags & pkgDepCache::ReInstall) != 0)
3001                 return @"REINSTALL";
3002             /*else if ((state.iFlags & pkgDepCache::AutoKept) != 0)
3003                 return nil;*/
3004             else
3005                 return nil;
3006         case pkgDepCache::ModeInstall:
3007             /*if ((state.iFlags & pkgDepCache::ReInstall) != 0)
3008                 return @"REINSTALL";
3009             else*/ switch (state.Status) {
3010                 case -1:
3011                     return @"DOWNGRADE";
3012                 case 0:
3013                     return @"INSTALL";
3014                 case 1:
3015                     return @"UPGRADE";
3016                 case 2:
3017                     return @"NEW_INSTALL";
3018                 _nodefault
3019             }
3020         _nodefault
3021     }
3022 } }
3023
3024 - (NSString *) id {
3025     return id_;
3026 }
3027
3028 - (NSString *) name {
3029     return name_.empty() ? id_ : name_;
3030 }
3031
3032 - (UIImage *) icon {
3033     NSString *section = [self simpleSection];
3034
3035     UIImage *icon(nil);
3036     if (parsed_ != NULL)
3037         if (NSString *href = parsed_->icon_)
3038             if ([href hasPrefix:@"file:///"])
3039                 icon = [UIImage imageAtPath:[[href substringFromIndex:7] stringByReplacingPercentEscapesUsingEncoding:NSUTF8StringEncoding]];
3040     if (icon == nil) if (section != nil)
3041         icon = [UIImage imageAtPath:[NSString stringWithFormat:@"%@/Sections/%@.png", App_, [section stringByReplacingOccurrencesOfString:@" " withString:@"_"]]];
3042     if (icon == nil) if (Source *source = [self source]) if (NSString *dicon = [source defaultIcon])
3043         if ([dicon hasPrefix:@"file:///"])
3044             icon = [UIImage imageAtPath:[[dicon substringFromIndex:7] stringByReplacingPercentEscapesUsingEncoding:NSUTF8StringEncoding]];
3045     if (icon == nil)
3046         icon = [UIImage imageNamed:@"unknown.png"];
3047     return icon;
3048 }
3049
3050 - (NSString *) homepage {
3051     return parsed_ == NULL ? nil : static_cast<NSString *>(parsed_->homepage_);
3052 }
3053
3054 - (NSString *) depiction {
3055     return parsed_ != NULL && !parsed_->depiction_.empty() ? parsed_->depiction_ : [[self source] depictionForPackage:id_];
3056 }
3057
3058 - (MIMEAddress *) author {
3059     return parsed_ == NULL || parsed_->author_.empty() ? nil : [MIMEAddress addressWithString:parsed_->author_];
3060 }
3061
3062 - (NSString *) support {
3063     return parsed_ != NULL && !parsed_->support_.empty() ? parsed_->support_ : [[self source] supportForPackage:id_];
3064 }
3065
3066 - (NSArray *) files {
3067     NSString *path = [NSString stringWithFormat:@"/var/lib/dpkg/info/%@.list", static_cast<NSString *>(id_)];
3068     NSMutableArray *files = [NSMutableArray arrayWithCapacity:128];
3069
3070     std::ifstream fin;
3071     fin.open([path UTF8String]);
3072     if (!fin.is_open())
3073         return nil;
3074
3075     std::string line;
3076     while (std::getline(fin, line))
3077         [files addObject:[NSString stringWithUTF8String:line.c_str()]];
3078
3079     return files;
3080 }
3081
3082 - (NSString *) state {
3083 @synchronized (database_) {
3084     if ([database_ era] != era_ || file_.end())
3085         return nil;
3086
3087     switch (iterator_->CurrentState) {
3088         case pkgCache::State::NotInstalled:
3089             return @"NotInstalled";
3090         case pkgCache::State::UnPacked:
3091             return @"UnPacked";
3092         case pkgCache::State::HalfConfigured:
3093             return @"HalfConfigured";
3094         case pkgCache::State::HalfInstalled:
3095             return @"HalfInstalled";
3096         case pkgCache::State::ConfigFiles:
3097             return @"ConfigFiles";
3098         case pkgCache::State::Installed:
3099             return @"Installed";
3100         case pkgCache::State::TriggersAwaited:
3101             return @"TriggersAwaited";
3102         case pkgCache::State::TriggersPending:
3103             return @"TriggersPending";
3104     }
3105
3106     return (NSString *) [NSNull null];
3107 } }
3108
3109 - (NSString *) selection {
3110 @synchronized (database_) {
3111     if ([database_ era] != era_ || file_.end())
3112         return nil;
3113
3114     switch (iterator_->SelectedState) {
3115         case pkgCache::State::Unknown:
3116             return @"Unknown";
3117         case pkgCache::State::Install:
3118             return @"Install";
3119         case pkgCache::State::Hold:
3120             return @"Hold";
3121         case pkgCache::State::DeInstall:
3122             return @"DeInstall";
3123         case pkgCache::State::Purge:
3124             return @"Purge";
3125     }
3126
3127     return (NSString *) [NSNull null];
3128 } }
3129
3130 - (NSArray *) warnings {
3131 @synchronized (database_) {
3132     if ([database_ era] != era_ || file_.end())
3133         return nil;
3134
3135     NSMutableArray *warnings([NSMutableArray arrayWithCapacity:4]);
3136     const char *name(iterator_.Name());
3137
3138     size_t length(strlen(name));
3139     if (length < 2) invalid:
3140         [warnings addObject:UCLocalize("ILLEGAL_PACKAGE_IDENTIFIER")];
3141     else for (size_t i(0); i != length; ++i)
3142         if (
3143             /* XXX: technically this is not allowed */
3144             (name[i] < 'A' || name[i] > 'Z') &&
3145             (name[i] < 'a' || name[i] > 'z') &&
3146             (name[i] < '0' || name[i] > '9') &&
3147             (i == 0 || name[i] != '+' && name[i] != '-' && name[i] != '.')
3148         ) goto invalid;
3149
3150     if (strcmp(name, "cydia") != 0) {
3151         bool cydia = false;
3152         bool user = false;
3153         bool _private = false;
3154         bool stash = false;
3155         bool dbstash = false;
3156         bool dsstore = false;
3157
3158         bool repository = [[self section] isEqualToString:@"Repositories"];
3159
3160         if (NSArray *files = [self files])
3161             for (NSString *file in files)
3162                 if (!cydia && [file isEqualToString:@"/Applications/Cydia.app"])
3163                     cydia = true;
3164                 else if (!user && [file isEqualToString:@"/User"])
3165                     user = true;
3166                 else if (!_private && [file isEqualToString:@"/private"])
3167                     _private = true;
3168                 else if (!stash && [file isEqualToString:@"/var/stash"])
3169                     stash = true;
3170                 else if (!dbstash && [file isEqualToString:@"/var/db/stash"])
3171                     dbstash = true;
3172                 else if (!dsstore && [file hasSuffix:@"/.DS_Store"])
3173                     dsstore = true;
3174
3175         /* XXX: this is not sensitive enough. only some folders are valid. */
3176         if (cydia && !repository)
3177             [warnings addObject:[NSString stringWithFormat:UCLocalize("FILES_INSTALLED_TO"), @"Cydia.app"]];
3178         if (user)
3179             [warnings addObject:[NSString stringWithFormat:UCLocalize("FILES_INSTALLED_TO"), @"/User"]];
3180         if (_private)
3181             [warnings addObject:[NSString stringWithFormat:UCLocalize("FILES_INSTALLED_TO"), @"/private"]];
3182         if (stash)
3183             [warnings addObject:[NSString stringWithFormat:UCLocalize("FILES_INSTALLED_TO"), @"/var/stash"]];
3184         if (dbstash)
3185             [warnings addObject:[NSString stringWithFormat:UCLocalize("FILES_INSTALLED_TO"), @"/var/db/stash"]];
3186         if (dsstore)
3187             [warnings addObject:[NSString stringWithFormat:UCLocalize("FILES_INSTALLED_TO"), @".DS_Store"]];
3188     }
3189
3190     return [warnings count] == 0 ? nil : warnings;
3191 } }
3192
3193 - (NSArray *) applications {
3194     NSString *me([[NSBundle mainBundle] bundleIdentifier]);
3195
3196     NSMutableArray *applications([NSMutableArray arrayWithCapacity:2]);
3197
3198     static RegEx application_r("/Applications/(.*)\\.app/Info.plist");
3199     if (NSArray *files = [self files])
3200         for (NSString *file in files)
3201             if (application_r(file)) {
3202                 NSDictionary *info([NSDictionary dictionaryWithContentsOfFile:file]);
3203                 if (info == nil)
3204                     continue;
3205                 NSString *id([info objectForKey:@"CFBundleIdentifier"]);
3206                 if (id == nil || [id isEqualToString:me])
3207                     continue;
3208
3209                 NSString *display([info objectForKey:@"CFBundleDisplayName"]);
3210                 if (display == nil)
3211                     display = application_r[1];
3212
3213                 NSString *bundle([file stringByDeletingLastPathComponent]);
3214                 NSString *icon([info objectForKey:@"CFBundleIconFile"]);
3215                 // XXX: maybe this should check if this is really a string, not just for length
3216                 if (icon == nil || ![icon respondsToSelector:@selector(length)] || [icon length] == 0)
3217                     icon = @"icon.png";
3218                 NSURL *url([NSURL fileURLWithPath:[bundle stringByAppendingPathComponent:icon]]);
3219
3220                 NSMutableArray *application([NSMutableArray arrayWithCapacity:2]);
3221                 [applications addObject:application];
3222
3223                 [application addObject:id];
3224                 [application addObject:display];
3225                 [application addObject:url];
3226             }
3227
3228     return [applications count] == 0 ? nil : applications;
3229 }
3230
3231 - (Source *) source {
3232     if (source_ == nil) {
3233         @synchronized (database_) {
3234             if ([database_ era] != era_ || file_.end())
3235                 source_ = (Source *) [NSNull null];
3236             else
3237                 source_ = [database_ getSource:file_.File()] ?: (Source *) [NSNull null];
3238         }
3239     }
3240
3241     return source_ == (Source *) [NSNull null] ? nil : source_;
3242 }
3243
3244 - (time_t) upgraded {
3245     return upgraded_;
3246 }
3247
3248 - (uint32_t) recent {
3249     return std::numeric_limits<uint32_t>::max() - upgraded_;
3250 }
3251
3252 - (uint32_t) rank {
3253     return rank_;
3254 }
3255
3256 - (BOOL) matches:(NSArray *)query {
3257     if (query == nil || [query count] == 0)
3258         return NO;
3259
3260     rank_ = 0;
3261
3262     NSString *string;
3263     NSRange range;
3264     NSUInteger length;
3265
3266     string = [self name];
3267     length = [string length];
3268
3269     if (length != 0)
3270     for (NSString *term in query) {
3271         range = [string rangeOfString:term options:MatchCompareOptions_];
3272         if (range.location != NSNotFound)
3273             rank_ -= 6 * 1000000 / length;
3274     }
3275
3276     if (rank_ == 0) {
3277         string = [self id];
3278         length = [string length];
3279
3280         if (length != 0)
3281         for (NSString *term in query) {
3282             range = [string rangeOfString:term options:MatchCompareOptions_];
3283             if (range.location != NSNotFound)
3284                 rank_ -= 6 * 1000000 / length;
3285         }
3286     }
3287
3288     string = [self shortDescription];
3289     length = [string length];
3290     NSUInteger stop(std::min<NSUInteger>(length, 200));
3291
3292     if (length != 0)
3293     for (NSString *term in query) {
3294         range = [string rangeOfString:term options:MatchCompareOptions_ range:NSMakeRange(0, stop)];
3295         if (range.location != NSNotFound)
3296             rank_ -= 2 * 100000;
3297     }
3298
3299     return rank_ != 0;
3300 }
3301
3302 - (NSArray *) tags {
3303     return tags_;
3304 }
3305
3306 - (BOOL) hasTag:(NSString *)tag {
3307     return tags_ == nil ? NO : [tags_ containsObject:tag];
3308 }
3309
3310 - (NSString *) primaryPurpose {
3311     for (NSString *tag in (NSArray *) tags_)
3312         if ([tag hasPrefix:@"purpose::"])
3313             return [tag substringFromIndex:9];
3314     return nil;
3315 }
3316
3317 - (NSArray *) purposes {
3318     NSMutableArray *purposes([NSMutableArray arrayWithCapacity:2]);
3319     for (NSString *tag in (NSArray *) tags_)
3320         if ([tag hasPrefix:@"purpose::"])
3321             [purposes addObject:[tag substringFromIndex:9]];
3322     return [purposes count] == 0 ? nil : purposes;
3323 }
3324
3325 - (bool) isCommercial {
3326     return [self hasTag:@"cydia::commercial"];
3327 }
3328
3329 - (void) setIndex:(size_t)index {
3330     if (metadata_->index_ != index)
3331         metadata_->index_ = index;
3332 }
3333
3334 - (CYString &) cyname {
3335     return !transform_.empty() ? transform_ : !name_.empty() ? name_ : id_;
3336 }
3337
3338 - (uint32_t) compareBySection:(NSArray *)sections {
3339     NSString *section([self section]);
3340     for (size_t i(0), e([sections count]); i != e; ++i) {
3341         if ([section isEqualToString:[[sections objectAtIndex:i] name]])
3342             return i;
3343     }
3344
3345     return _not(uint32_t);
3346 }
3347
3348 - (void) clear {
3349 @synchronized (database_) {
3350     if ([database_ era] != era_ || file_.end())
3351         return;
3352
3353     pkgProblemResolver *resolver = [database_ resolver];
3354     resolver->Clear(iterator_);
3355
3356     pkgCacheFile &cache([database_ cache]);
3357     cache->SetReInstall(iterator_, false);
3358     cache->MarkKeep(iterator_, false);
3359 } }
3360
3361 - (void) install {
3362 @synchronized (database_) {
3363     if ([database_ era] != era_ || file_.end())
3364         return;
3365
3366     pkgProblemResolver *resolver = [database_ resolver];
3367     resolver->Clear(iterator_);
3368     resolver->Protect(iterator_);
3369
3370     pkgCacheFile &cache([database_ cache]);
3371     cache->SetCandidateVersion(version_);
3372     cache->SetReInstall(iterator_, false);
3373     cache->MarkInstall(iterator_, false);
3374
3375     pkgDepCache::StateCache &state((*cache)[iterator_]);
3376     if (!state.Install())
3377         cache->SetReInstall(iterator_, true);
3378 } }
3379
3380 - (void) remove {
3381 @synchronized (database_) {
3382     if ([database_ era] != era_ || file_.end())
3383         return;
3384
3385     pkgProblemResolver *resolver = [database_ resolver];
3386     resolver->Clear(iterator_);
3387     resolver->Remove(iterator_);
3388     resolver->Protect(iterator_);
3389
3390     pkgCacheFile &cache([database_ cache]);
3391     cache->SetReInstall(iterator_, false);
3392     cache->MarkDelete(iterator_, true);
3393 } }
3394
3395 @end
3396 /* }}} */
3397 /* Section Class {{{ */
3398 @interface Section : NSObject {
3399     _H<NSString> name_;
3400     size_t row_;
3401     size_t count_;
3402     _H<NSString> localized_;
3403 }
3404
3405 - (NSComparisonResult) compareByLocalized:(Section *)section;
3406 - (Section *) initWithName:(NSString *)name localized:(NSString *)localized;
3407 - (Section *) initWithName:(NSString *)name localize:(BOOL)localize;
3408 - (Section *) initWithName:(NSString *)name row:(size_t)row localize:(BOOL)localize;
3409
3410 - (NSString *) name;
3411 - (void) setName:(NSString *)name;
3412
3413 - (size_t) row;
3414 - (size_t) count;
3415
3416 - (void) addToRow;
3417 - (void) addToCount;
3418
3419 - (void) setCount:(size_t)count;
3420 - (NSString *) localized;
3421
3422 @end
3423
3424 @implementation Section
3425
3426 - (NSComparisonResult) compareByLocalized:(Section *)section {
3427     NSString *lhs(localized_);
3428     NSString *rhs([section localized]);
3429
3430     /*if ([lhs length] != 0 && [rhs length] != 0) {
3431         unichar lhc = [lhs characterAtIndex:0];
3432         unichar rhc = [rhs characterAtIndex:0];
3433
3434         if (isalpha(lhc) && !isalpha(rhc))
3435             return NSOrderedAscending;
3436         else if (!isalpha(lhc) && isalpha(rhc))
3437             return NSOrderedDescending;
3438     }*/
3439
3440     return [lhs compare:rhs options:LaxCompareOptions_];
3441 }
3442
3443 - (Section *) initWithName:(NSString *)name localized:(NSString *)localized {
3444     if ((self = [self initWithName:name localize:NO]) != nil) {
3445         if (localized != nil)
3446             localized_ = localized;
3447     } return self;
3448 }
3449
3450 - (Section *) initWithName:(NSString *)name localize:(BOOL)localize {
3451     return [self initWithName:name row:0 localize:localize];
3452 }
3453
3454 - (Section *) initWithName:(NSString *)name row:(size_t)row localize:(BOOL)localize {
3455     if ((self = [super init]) != nil) {
3456         name_ = name;
3457         row_ = row;
3458         if (localize)
3459             localized_ = LocalizeSection(name_);
3460     } return self;
3461 }
3462
3463 - (NSString *) name {
3464     return name_;
3465 }
3466
3467 - (void) setName:(NSString *)name {
3468     name_ = name;
3469 }
3470
3471 - (size_t) row {
3472     return row_;
3473 }
3474
3475 - (size_t) count {
3476     return count_;
3477 }
3478
3479 - (void) addToRow {
3480     ++row_;
3481 }
3482
3483 - (void) addToCount {
3484     ++count_;
3485 }
3486
3487 - (void) setCount:(size_t)count {
3488     count_ = count;
3489 }
3490
3491 - (NSString *) localized {
3492     return localized_;
3493 }
3494
3495 @end
3496 /* }}} */
3497
3498 class CydiaLogCleaner :
3499     public pkgArchiveCleaner
3500 {
3501   protected:
3502     virtual void Erase(const char *File, std::string Pkg, std::string Ver, struct stat &St) {
3503         unlink(File);
3504     }
3505 };
3506
3507 /* Database Implementation {{{ */
3508 @implementation Database
3509
3510 + (Database *) sharedInstance {
3511     static _H<Database> instance;
3512     if (instance == nil)
3513         instance = [[[Database alloc] init] autorelease];
3514     return instance;
3515 }
3516
3517 - (unsigned) era {
3518     return era_;
3519 }
3520
3521 - (void) releasePackages {
3522     CFArrayApplyFunction(packages_, CFRangeMake(0, CFArrayGetCount(packages_)), reinterpret_cast<CFArrayApplierFunction>(&CFRelease), NULL);
3523     CFArrayRemoveAllValues(packages_);
3524 }
3525
3526 - (void) dealloc {
3527     // XXX: actually implement this thing
3528     _assert(false);
3529     [self releasePackages];
3530     NSRecycleZone(zone_);
3531     [super dealloc];
3532 }
3533
3534 - (void) _readCydia:(NSNumber *)fd {
3535     boost::fdistream is([fd intValue]);
3536     std::string line;
3537
3538     static RegEx finish_r("finish:([^:]*)");
3539
3540     while (std::getline(is, line)) {
3541         NSAutoreleasePool *pool([[NSAutoreleasePool alloc] init]);
3542
3543         const char *data(line.c_str());
3544         size_t size = line.size();
3545         lprintf("C:%s\n", data);
3546
3547         if (finish_r(data, size)) {
3548             NSString *finish = finish_r[1];
3549             int index = [Finishes_ indexOfObject:finish];
3550             if (index != INT_MAX && index > Finish_)
3551                 Finish_ = index;
3552         }
3553
3554         [pool release];
3555     }
3556
3557     _assume(false);
3558 }
3559
3560 - (void) _readStatus:(NSNumber *)fd {
3561     boost::fdistream is([fd intValue]);
3562     std::string line;
3563
3564     static RegEx conffile_r("status: [^ ]* : conffile-prompt : (.*?) *");
3565     static RegEx pmstatus_r("([^:]*):([^:]*):([^:]*):(.*)");
3566
3567     while (std::getline(is, line)) {
3568         NSAutoreleasePool *pool([[NSAutoreleasePool alloc] init]);
3569
3570         const char *data(line.c_str());
3571         size_t size(line.size());
3572         lprintf("S:%s\n", data);
3573
3574         if (conffile_r(data, size)) {
3575             // status: /fail : conffile-prompt : '/fail' '/fail.dpkg-new' 1 1
3576             [delegate_ performSelectorOnMainThread:@selector(setConfigurationData:) withObject:conffile_r[1] waitUntilDone:YES];
3577         } else if (strncmp(data, "status: ", 8) == 0) {
3578             // status: <package>: {unpacked,half-configured,installed}
3579             CydiaProgressEvent *event([CydiaProgressEvent eventWithMessage:[NSString stringWithUTF8String:(data + 8)] ofType:kCydiaProgressEventTypeStatus]);
3580             [progress_ performSelectorOnMainThread:@selector(addProgressEvent:) withObject:event waitUntilDone:YES];
3581         } else if (strncmp(data, "processing: ", 12) == 0) {
3582             // processing: configure: config-test
3583             CydiaProgressEvent *event([CydiaProgressEvent eventWithMessage:[NSString stringWithUTF8String:(data + 12)] ofType:kCydiaProgressEventTypeStatus]);
3584             [progress_ performSelectorOnMainThread:@selector(addProgressEvent:) withObject:event waitUntilDone:YES];
3585         } else if (pmstatus_r(data, size)) {
3586             std::string type([pmstatus_r[1] UTF8String]);
3587
3588             NSString *package = pmstatus_r[2];
3589             if ([package isEqualToString:@"dpkg-exec"])
3590                 package = nil;
3591
3592             float percent([pmstatus_r[3] floatValue]);
3593             [progress_ performSelectorOnMainThread:@selector(setProgressPercent:) withObject:[NSNumber numberWithFloat:(percent / 100)] waitUntilDone:YES];
3594
3595             NSString *string = pmstatus_r[4];
3596
3597             if (type == "pmerror") {
3598                 CydiaProgressEvent *event([CydiaProgressEvent eventWithMessage:string ofType:kCydiaProgressEventTypeError forPackage:package]);
3599                 [progress_ performSelectorOnMainThread:@selector(addProgressEvent:) withObject:event waitUntilDone:YES];
3600             } else if (type == "pmstatus") {
3601                 CydiaProgressEvent *event([CydiaProgressEvent eventWithMessage:string ofType:kCydiaProgressEventTypeStatus forPackage:package]);
3602                 [progress_ performSelectorOnMainThread:@selector(addProgressEvent:) withObject:event waitUntilDone:YES];
3603             } else if (type == "pmconffile")
3604                 [delegate_ performSelectorOnMainThread:@selector(setConfigurationData:) withObject:string waitUntilDone:YES];
3605             else
3606                 lprintf("E:unknown pmstatus\n");
3607         } else
3608             lprintf("E:unknown status\n");
3609
3610         [pool release];
3611     }
3612
3613     _assume(false);
3614 }
3615
3616 - (void) _readOutput:(NSNumber *)fd {
3617     boost::fdistream is([fd intValue]);
3618     std::string line;
3619
3620     while (std::getline(is, line)) {
3621         NSAutoreleasePool *pool([[NSAutoreleasePool alloc] init]);
3622
3623         lprintf("O:%s\n", line.c_str());
3624
3625         CydiaProgressEvent *event([CydiaProgressEvent eventWithMessage:[NSString stringWithUTF8String:line.c_str()] ofType:kCydiaProgressEventTypeInformation]);
3626         [progress_ performSelectorOnMainThread:@selector(addProgressEvent:) withObject:event waitUntilDone:YES];
3627
3628         [pool release];
3629     }
3630
3631     _assume(false);
3632 }
3633
3634 - (FILE *) input {
3635     return input_;
3636 }
3637
3638 - (Package *) packageWithName:(NSString *)name {
3639     if (name == nil)
3640         return nil;
3641 @synchronized (self) {
3642     if (static_cast<pkgDepCache *>(cache_) == NULL)
3643         return nil;
3644     pkgCache::PkgIterator iterator(cache_->FindPkg([name UTF8String]
3645 #ifdef __arm64__
3646         , "any"
3647 #endif
3648     ));
3649     return iterator.end() ? nil : [Package packageWithIterator:iterator withZone:NULL inPool:NULL database:self];
3650 } }
3651
3652 - (id) init {
3653     if ((self = [super init]) != nil) {
3654         policy_ = NULL;
3655         records_ = NULL;
3656         resolver_ = NULL;
3657         fetcher_ = NULL;
3658         lock_ = NULL;
3659
3660         zone_ = NSCreateZone(1024 * 1024, 256 * 1024, NO);
3661
3662         size_t capacity(MetaFile_->active_);
3663         if (capacity == 0)
3664             capacity = 16384;
3665         else
3666             capacity += 1024;
3667
3668         packages_ = CFArrayCreateMutable(kCFAllocatorDefault, capacity, NULL);
3669         sourceList_ = [NSMutableArray arrayWithCapacity:16];
3670
3671         int fds[2];
3672
3673         _assert(pipe(fds) != -1);
3674         cydiafd_ = fds[1];
3675
3676         _config->Set("APT::Keep-Fds::", cydiafd_);
3677         setenv("CYDIA", [[[[NSNumber numberWithInt:cydiafd_] stringValue] stringByAppendingString:@" 1"] UTF8String], _not(int));
3678
3679         [NSThread
3680             detachNewThreadSelector:@selector(_readCydia:)
3681             toTarget:self
3682             withObject:[NSNumber numberWithInt:fds[0]]
3683         ];
3684
3685         _assert(pipe(fds) != -1);
3686         statusfd_ = fds[1];
3687
3688         [NSThread
3689             detachNewThreadSelector:@selector(_readStatus:)
3690             toTarget:self
3691             withObject:[NSNumber numberWithInt:fds[0]]
3692         ];
3693
3694         _assert(pipe(fds) != -1);
3695         _assert(dup2(fds[0], 0) != -1);
3696         _assert(close(fds[0]) != -1);
3697
3698         input_ = fdopen(fds[1], "a");
3699
3700         _assert(pipe(fds) != -1);
3701         _assert(dup2(fds[1], 1) != -1);
3702         _assert(close(fds[1]) != -1);
3703
3704         [NSThread
3705             detachNewThreadSelector:@selector(_readOutput:)
3706             toTarget:self
3707             withObject:[NSNumber numberWithInt:fds[0]]
3708         ];
3709     } return self;
3710 }
3711
3712 - (pkgCacheFile &) cache {
3713     return cache_;
3714 }
3715
3716 - (pkgDepCache::Policy *) policy {
3717     return policy_;
3718 }
3719
3720 - (pkgRecords *) records {
3721     return records_;
3722 }
3723
3724 - (pkgProblemResolver *) resolver {
3725     return resolver_;
3726 }
3727
3728 - (pkgAcquire &) fetcher {
3729     return *fetcher_;
3730 }
3731
3732 - (pkgSourceList &) list {
3733     return *list_;
3734 }
3735
3736 - (NSArray *) packages {
3737     return (NSArray *) packages_;
3738 }
3739
3740 - (NSArray *) sources {
3741     return sourceList_;
3742 }
3743
3744 - (Source *) sourceWithKey:(NSString *)key {
3745     for (Source *source in [self sources]) {
3746         if ([[source key] isEqualToString:key])
3747             return source;
3748     } return nil;
3749 }
3750
3751 - (bool) popErrorWithTitle:(NSString *)title {
3752     bool fatal(false);
3753
3754     while (!_error->empty()) {
3755         std::string error;
3756         bool warning(!_error->PopMessage(error));
3757         if (!warning)
3758             fatal = true;
3759
3760         for (;;) {
3761             size_t size(error.size());
3762             if (size == 0 || error[size - 1] != '\n')
3763                 break;
3764             error.resize(size - 1);
3765         }
3766
3767         lprintf("%c:[%s]\n", warning ? 'W' : 'E', error.c_str());
3768
3769         static RegEx no_pubkey("GPG error:.* NO_PUBKEY .*");
3770         if (warning && no_pubkey(error.c_str()))
3771             continue;
3772
3773         [delegate_ addProgressEventOnMainThread:[CydiaProgressEvent eventWithMessage:[NSString stringWithUTF8String:error.c_str()] ofType:(warning ? kCydiaProgressEventTypeWarning : kCydiaProgressEventTypeError)] forTask:title];
3774     }
3775
3776     return fatal;
3777 }
3778
3779 - (bool) popErrorWithTitle:(NSString *)title forOperation:(bool)success {
3780     return [self popErrorWithTitle:title] || !success;
3781 }
3782
3783 - (bool) popErrorWithTitle:(NSString *)title forReadList:(pkgSourceList &)list {
3784     if ([self popErrorWithTitle:title forOperation:list.ReadMainList()])
3785         return true;
3786     return false;
3787
3788     list.Reset();
3789
3790     bool error(false);
3791
3792     if (access("/etc/apt/sources.list", F_OK) == 0)
3793         error |= [self popErrorWithTitle:title forOperation:list.ReadAppend("/etc/apt/sources.list")];
3794
3795     std::string base("/etc/apt/sources.list.d");
3796     if (DIR *sources = opendir(base.c_str())) {
3797         while (dirent *source = readdir(sources))
3798             if (source->d_name[0] != '.' && source->d_namlen > 5 && strcmp(source->d_name + source->d_namlen - 5, ".list") == 0 && strcmp(source->d_name, "cydia.list") != 0)
3799                 error |= [self popErrorWithTitle:title forOperation:list.ReadAppend((base + "/" + source->d_name).c_str())];
3800         closedir(sources);
3801     }
3802
3803     error |= [self popErrorWithTitle:title forOperation:list.ReadAppend(SOURCES_LIST)];
3804
3805     return error;
3806 }
3807
3808 - (void) reloadDataWithInvocation:(NSInvocation *)invocation {
3809 @synchronized (self) {
3810     ++era_;
3811
3812     [self releasePackages];
3813
3814     sourceMap_.clear();
3815     [sourceList_ removeAllObjects];
3816
3817     _error->Discard();
3818
3819     delete list_;
3820     list_ = NULL;
3821     manager_ = NULL;
3822     delete lock_;
3823     lock_ = NULL;
3824     delete fetcher_;
3825     fetcher_ = NULL;
3826     delete resolver_;
3827     resolver_ = NULL;
3828     delete records_;
3829     records_ = NULL;
3830     delete policy_;
3831     policy_ = NULL;
3832
3833     cache_.Close();
3834
3835     pool_.~CYPool();
3836     new (&pool_) CYPool();
3837
3838     NSRecycleZone(zone_);
3839     zone_ = NSCreateZone(1024 * 1024, 256 * 1024, NO);
3840
3841     int chk(creat("/tmp/cydia.chk", 0644));
3842     if (chk != -1)
3843         close(chk);
3844
3845     if (invocation != nil)
3846         [invocation invoke];
3847
3848     NSString *title(UCLocalize("DATABASE"));
3849
3850     list_ = new pkgSourceList();
3851     _profile(reloadDataWithInvocation$ReadMainList)
3852     if ([self popErrorWithTitle:title forReadList:*list_])
3853         return;
3854     _end
3855
3856     _profile(reloadDataWithInvocation$Source$initWithMetaIndex)
3857     for (pkgSourceList::const_iterator source = list_->begin(); source != list_->end(); ++source) {
3858         Source *object([[[Source alloc] initWithMetaIndex:*source forDatabase:self inPool:&pool_] autorelease]);
3859         [sourceList_ addObject:object];
3860     }
3861     _end
3862
3863     _trace();
3864     OpProgress progress;
3865     bool opened;
3866   open:
3867     delock_ = GetStatusDate();
3868     _profile(reloadDataWithInvocation$pkgCacheFile)
3869         opened = cache_.Open(progress, false);
3870     _end
3871     if (!opened) {
3872         // XXX: this block should probably be merged with popError: in some way
3873         while (!_error->empty()) {
3874             std::string error;
3875             bool warning(!_error->PopMessage(error));
3876
3877             lprintf("cache_.Open():[%s]\n", error.c_str());
3878
3879             [delegate_ addProgressEventOnMainThread:[CydiaProgressEvent eventWithMessage:[NSString stringWithUTF8String:error.c_str()] ofType:(warning ? kCydiaProgressEventTypeWarning : kCydiaProgressEventTypeError)] forTask:title];
3880
3881             SEL repair(NULL);
3882             if (false);
3883             else if (error == "dpkg was interrupted, you must manually run 'dpkg --configure -a' to correct the problem. ")
3884                 repair = @selector(configure);
3885             //else if (error == "The package lists or status file could not be parsed or opened.")
3886             //    repair = @selector(update);
3887             // else if (error == "Could not get lock /var/lib/dpkg/lock - open (35 Resource temporarily unavailable)")
3888             // else if (error == "Could not open lock file /var/lib/dpkg/lock - open (13 Permission denied)")
3889             // else if (error == "Malformed Status line")
3890             // else if (error == "The list of sources could not be read.")
3891
3892             if (repair != NULL) {
3893                 _error->Discard();
3894                 [delegate_ repairWithSelector:repair];
3895                 goto open;
3896             }
3897         }
3898
3899         return;
3900     } else if ([self popErrorWithTitle:title forOperation:true])
3901         return;
3902     _trace();
3903
3904     unlink("/tmp/cydia.chk");
3905
3906     now_ = [[NSDate date] timeIntervalSince1970];
3907
3908     policy_ = new pkgDepCache::Policy();
3909     records_ = new pkgRecords(cache_);
3910     resolver_ = new pkgProblemResolver(cache_);
3911     fetcher_ = new pkgAcquire(&status_);
3912     lock_ = NULL;
3913
3914     if (cache_->DelCount() != 0 || cache_->InstCount() != 0) {
3915         [delegate_ addProgressEventOnMainThread:[CydiaProgressEvent eventWithMessage:UCLocalize("COUNTS_NONZERO_EX") ofType:kCydiaProgressEventTypeError] forTask:title];
3916         return;
3917     }
3918
3919     _profile(reloadDataWithInvocation$pkgApplyStatus)
3920     if ([self popErrorWithTitle:title forOperation:pkgApplyStatus(cache_)])
3921         return;
3922     _end
3923
3924     if (cache_->BrokenCount() != 0) {
3925         _profile(pkgApplyStatus$pkgFixBroken)
3926         if ([self popErrorWithTitle:title forOperation:pkgFixBroken(cache_)])
3927             return;
3928         _end
3929
3930         if (cache_->BrokenCount() != 0) {
3931             [delegate_ addProgressEventOnMainThread:[CydiaProgressEvent eventWithMessage:UCLocalize("STILL_BROKEN_EX") ofType:kCydiaProgressEventTypeError] forTask:title];
3932             return;
3933         }
3934
3935         _profile(pkgApplyStatus$pkgMinimizeUpgrade)
3936         if ([self popErrorWithTitle:title forOperation:pkgMinimizeUpgrade(cache_)])
3937             return;
3938         _end
3939     }
3940
3941     for (Source *object in (id) sourceList_) {
3942         metaIndex *source([object metaIndex]);
3943         std::vector<pkgIndexFile *> *indices = source->GetIndexFiles();
3944         for (std::vector<pkgIndexFile *>::const_iterator index = indices->begin(); index != indices->end(); ++index)
3945             // XXX: this could be more intelligent
3946             if (dynamic_cast<debPackagesIndex *>(*index) != NULL) {
3947                 pkgCache::PkgFileIterator cached((*index)->FindInCache(cache_));
3948                 if (!cached.end())
3949                     sourceMap_[cached->ID] = object;
3950             }
3951     }
3952
3953     {
3954         /*std::vector<Package *> packages;
3955         packages.reserve(std::max(10000U, [packages_ count] + 1000));
3956         packages_ = nil;*/
3957
3958         _profile(reloadDataWithInvocation$packageWithIterator)
3959         for (pkgCache::PkgIterator iterator = cache_->PkgBegin(); !iterator.end(); ++iterator)
3960             if (Package *package = [Package packageWithIterator:iterator withZone:zone_ inPool:&pool_ database:self])
3961                 //packages.push_back(package);
3962                 CFArrayAppendValue(packages_, CFRetain(package));
3963         _end
3964
3965
3966         /*if (packages.empty())
3967             packages_ = [[NSArray alloc] init];
3968         else
3969             packages_ = [[NSArray alloc] initWithObjects:&packages.front() count:packages.size()];
3970         _trace();*/
3971
3972         _profile(reloadDataWithInvocation$radix$8)
3973         [(NSMutableArray *) packages_ radixSortUsingFunction:reinterpret_cast<MenesRadixSortFunction>(&PackagePrefixRadix) withContext:reinterpret_cast<void *>(8)];
3974         _end
3975
3976         _profile(reloadDataWithInvocation$radix$4)
3977         [(NSMutableArray *) packages_ radixSortUsingFunction:reinterpret_cast<MenesRadixSortFunction>(&PackagePrefixRadix) withContext:reinterpret_cast<void *>(4)];
3978         _end
3979
3980         _profile(reloadDataWithInvocation$radix$0)
3981         [(NSMutableArray *) packages_ radixSortUsingFunction:reinterpret_cast<MenesRadixSortFunction>(&PackagePrefixRadix) withContext:reinterpret_cast<void *>(0)];
3982         _end
3983
3984         _profile(reloadDataWithInvocation$insertion)
3985         CFArrayInsertionSortValues(packages_, CFRangeMake(0, CFArrayGetCount(packages_)), reinterpret_cast<CFComparatorFunction>(&PackageNameCompare), NULL);
3986         _end
3987
3988         /*_profile(reloadDataWithInvocation$CFQSortArray)
3989         CFQSortArray(&packages.front(), packages.size(), sizeof(packages.front()), reinterpret_cast<CFComparatorFunction>(&PackageNameCompare_), NULL);
3990         _end*/
3991
3992         /*_profile(reloadDataWithInvocation$stdsort)
3993         std::sort(packages.begin(), packages.end(), PackageNameOrdering());
3994         _end*/
3995
3996         /*_profile(reloadDataWithInvocation$CFArraySortValues)
3997         CFArraySortValues((CFMutableArrayRef) packages_, CFRangeMake(0, [packages_ count]), reinterpret_cast<CFComparatorFunction>(&PackageNameCompare), NULL);
3998         _end*/
3999
4000         /*_profile(reloadDataWithInvocation$sortUsingFunction)
4001         [packages_ sortUsingFunction:reinterpret_cast<NSComparisonResult (*)(id, id, void *)>(&PackageNameCompare) context:NULL];
4002         _end*/
4003
4004
4005         size_t count(CFArrayGetCount(packages_));
4006         MetaFile_->active_ = count;
4007         for (size_t index(0); index != count; ++index)
4008             [(Package *) CFArrayGetValueAtIndex(packages_, index) setIndex:index];
4009     }
4010 } }
4011
4012 - (void) clear {
4013 @synchronized (self) {
4014     delete resolver_;
4015     resolver_ = new pkgProblemResolver(cache_);
4016
4017     for (pkgCache::PkgIterator iterator(cache_->PkgBegin()); !iterator.end(); ++iterator)
4018         if (!cache_[iterator].Keep())
4019             cache_->MarkKeep(iterator, false);
4020         else if ((cache_[iterator].iFlags & pkgDepCache::ReInstall) != 0)
4021             cache_->SetReInstall(iterator, false);
4022 } }
4023
4024 - (void) configure {
4025     NSString *dpkg = [NSString stringWithFormat:@"/usr/libexec/cydo --configure -a --status-fd %u", statusfd_];
4026     _trace();
4027     system([dpkg UTF8String]);
4028     _trace();
4029 }
4030
4031 - (bool) clean {
4032 @synchronized (self) {
4033     // XXX: I don't remember this condition
4034     if (lock_ != NULL)
4035         return false;
4036
4037     FileFd Lock;
4038     Lock.Fd(GetLock(_config->FindDir("Dir::Cache::Archives") + "lock"));
4039
4040     NSString *title(UCLocalize("CLEAN_ARCHIVES"));
4041
4042     if ([self popErrorWithTitle:title])
4043         return false;
4044
4045     pkgAcquire fetcher;
4046     fetcher.Clean(_config->FindDir("Dir::Cache::Archives"));
4047
4048     CydiaLogCleaner cleaner;
4049     if ([self popErrorWithTitle:title forOperation:cleaner.Go(_config->FindDir("Dir::Cache::Archives") + "partial/", cache_)])
4050         return false;
4051
4052     return true;
4053 } }
4054
4055 - (bool) prepare {
4056     fetcher_->Shutdown();
4057
4058     pkgRecords records(cache_);
4059
4060     lock_ = new FileFd();
4061     lock_->Fd(GetLock(_config->FindDir("Dir::Cache::Archives") + "lock"));
4062
4063     NSString *title(UCLocalize("PREPARE_ARCHIVES"));
4064
4065     if ([self popErrorWithTitle:title])
4066         return false;
4067
4068     pkgSourceList list;
4069     if ([self popErrorWithTitle:title forReadList:list])
4070         return false;
4071
4072     manager_ = (_system->CreatePM(cache_));
4073     if ([self popErrorWithTitle:title forOperation:manager_->GetArchives(fetcher_, &list, &records)])
4074         return false;
4075
4076     return true;
4077 }
4078
4079 - (void) perform {
4080     bool substrate(RestartSubstrate_);
4081     RestartSubstrate_ = false;
4082
4083     NSString *title(UCLocalize("PERFORM_SELECTIONS"));
4084
4085     NSMutableArray *before = [NSMutableArray arrayWithCapacity:16]; {
4086         pkgSourceList list;
4087         if ([self popErrorWithTitle:title forReadList:list])
4088             return;
4089         for (pkgSourceList::const_iterator source = list.begin(); source != list.end(); ++source)
4090             [before addObject:[NSString stringWithUTF8String:(*source)->GetURI().c_str()]];
4091     }
4092
4093     [delegate_ performSelectorOnMainThread:@selector(retainNetworkActivityIndicator) withObject:nil waitUntilDone:YES];
4094
4095     if (fetcher_->Run(PulseInterval_) != pkgAcquire::Continue) {
4096         _trace();
4097         [self popErrorWithTitle:title];
4098         return;
4099     }
4100
4101     bool failed = false;
4102     for (pkgAcquire::ItemIterator item = fetcher_->ItemsBegin(); item != fetcher_->ItemsEnd(); item++) {
4103         if ((*item)->Status == pkgAcquire::Item::StatDone && (*item)->Complete)
4104             continue;
4105         if ((*item)->Status == pkgAcquire::Item::StatIdle)
4106             continue;
4107
4108         std::string uri = (*item)->DescURI();
4109         std::string error = (*item)->ErrorText;
4110
4111         lprintf("pAf:%s:%s\n", uri.c_str(), error.c_str());
4112         failed = true;
4113
4114         CydiaProgressEvent *event([CydiaProgressEvent eventWithMessage:[NSString stringWithUTF8String:error.c_str()] ofType:kCydiaProgressEventTypeError]);
4115         [delegate_ addProgressEventOnMainThread:event forTask:title];
4116     }
4117
4118     [delegate_ performSelectorOnMainThread:@selector(releaseNetworkActivityIndicator) withObject:nil waitUntilDone:YES];
4119
4120     if (failed) {
4121         _trace();
4122         return;
4123     }
4124
4125     if (substrate)
4126         RestartSubstrate_ = true;
4127
4128     if (![delock_ isEqual:GetStatusDate()]) {
4129         [delegate_ addProgressEventOnMainThread:[CydiaProgressEvent eventWithMessage:UCLocalize("DPKG_LOCKED") ofType:kCydiaProgressEventTypeError] forTask:title];
4130         return;
4131     }
4132
4133     delock_ = nil;
4134
4135     pkgPackageManager::OrderResult result(manager_->DoInstall(statusfd_));
4136
4137     NSString *oextended(@"/var/lib/apt/extended_states");
4138     NSString *nextended(Cache("extended_states"));
4139
4140     struct stat info;
4141     if (stat([nextended UTF8String], &info) != -1 && (info.st_mode & S_IFMT) == S_IFREG)
4142         system([[NSString stringWithFormat:@"/usr/libexec/cydia/cydo /bin/cp --remove-destination %@ %@", ShellEscape(nextended), ShellEscape(oextended)] UTF8String]);
4143
4144     unlink([nextended UTF8String]);
4145     symlink([oextended UTF8String], [nextended UTF8String]);
4146
4147     if ([self popErrorWithTitle:title])
4148         return;
4149
4150     if (result == pkgPackageManager::Failed) {
4151         _trace();
4152         return;
4153     }
4154
4155     if (result != pkgPackageManager::Completed) {
4156         _trace();
4157         return;
4158     }
4159
4160     NSMutableArray *after = [NSMutableArray arrayWithCapacity:16]; {
4161         pkgSourceList list;
4162         if ([self popErrorWithTitle:title forReadList:list])
4163             return;
4164         for (pkgSourceList::const_iterator source = list.begin(); source != list.end(); ++source)
4165             [after addObject:[NSString stringWithUTF8String:(*source)->GetURI().c_str()]];
4166     }
4167
4168     if (![before isEqualToArray:after])
4169         [self update];
4170 }
4171
4172 - (bool) delocked {
4173     return ![delock_ isEqual:GetStatusDate()];
4174 }
4175
4176 - (bool) upgrade {
4177     NSString *title(UCLocalize("UPGRADE"));
4178     if ([self popErrorWithTitle:title forOperation:pkgDistUpgrade(cache_)])
4179         return false;
4180     return true;
4181 }
4182
4183 - (void) update {
4184     [self updateWithStatus:status_];
4185 }
4186
4187 - (void) updateWithStatus:(CancelStatus &)status {
4188     NSString *title(UCLocalize("REFRESHING_DATA"));
4189
4190     pkgSourceList list;
4191     if ([self popErrorWithTitle:title forReadList:list])
4192         return;
4193
4194     FileFd lock;
4195     lock.Fd(GetLock(_config->FindDir("Dir::State::Lists") + "lock"));
4196     if ([self popErrorWithTitle:title])
4197         return;
4198
4199     [delegate_ performSelectorOnMainThread:@selector(retainNetworkActivityIndicator) withObject:nil waitUntilDone:YES];
4200
4201     bool success(ListUpdate(status, list, PulseInterval_));
4202     if (status.WasCancelled())
4203         _error->Discard();
4204     else {
4205         [self popErrorWithTitle:title forOperation:success];
4206
4207         [[NSDictionary dictionaryWithObjectsAndKeys:
4208             [NSDate date], @"LastUpdate",
4209         nil] writeToFile:@ CacheState_ atomically:YES];
4210     }
4211
4212     [delegate_ performSelectorOnMainThread:@selector(releaseNetworkActivityIndicator) withObject:nil waitUntilDone:YES];
4213 }
4214
4215 - (void) setDelegate:(NSObject<DatabaseDelegate> *)delegate {
4216     delegate_ = delegate;
4217 }
4218
4219 - (void) setProgressDelegate:(NSObject<ProgressDelegate> *)delegate {
4220     progress_ = delegate;
4221     status_.setDelegate(delegate);
4222 }
4223
4224 - (NSObject<ProgressDelegate> *) progressDelegate {
4225     return progress_;
4226 }
4227
4228 - (Source *) getSource:(pkgCache::PkgFileIterator)file {
4229     SourceMap::const_iterator i(sourceMap_.find(file->ID));
4230     return i == sourceMap_.end() ? nil : i->second;
4231 }
4232
4233 - (void) setFetch:(bool)fetch forURI:(const char *)uri {
4234     for (Source *source in (id) sourceList_)
4235         [source setFetch:fetch forURI:uri];
4236 }
4237
4238 - (void) resetFetch {
4239     for (Source *source in (id) sourceList_)
4240         [source resetFetch];
4241 }
4242
4243 - (NSString *) mappedSectionForPointer:(const char *)section {
4244     _H<NSString> *mapped;
4245
4246     _profile(Database$mappedSectionForPointer$Cache)
4247         mapped = &sections_[section];
4248     _end
4249
4250     if (*mapped == NULL) {
4251         size_t length(strlen(section));
4252         char spaced[length + 1];
4253
4254         _profile(Database$mappedSectionForPointer$Replace)
4255             for (size_t index(0); index != length; ++index)
4256                 spaced[index] = section[index] == '_' ? ' ' : section[index];
4257             spaced[length] = '\0';
4258         _end
4259
4260         NSString *string;
4261
4262         _profile(Database$mappedSectionForPointer$stringWithUTF8String)
4263             string = [NSString stringWithUTF8String:spaced];
4264         _end
4265
4266         _profile(Database$mappedSectionForPointer$Map)
4267             string = [SectionMap_ objectForKey:string] ?: string;
4268         _end
4269
4270         *mapped = string;
4271     } return *mapped;
4272 }
4273
4274 @end
4275 /* }}} */
4276
4277 static _H<NSMutableSet> Diversions_;
4278
4279 @interface Diversion : NSObject {
4280     RegEx pattern_;
4281     _H<NSString> key_;
4282     _H<NSString> format_;
4283 }
4284
4285 @end
4286
4287 @implementation Diversion
4288
4289 - (id) initWithFrom:(NSString *)from to:(NSString *)to {
4290     if ((self = [super init]) != nil) {
4291         pattern_ = [from UTF8String];
4292         key_ = from;
4293         format_ = to;
4294     } return self;
4295 }
4296
4297 - (NSString *) divert:(NSString *)url {
4298     return !pattern_(url) ? nil : pattern_->*format_;
4299 }
4300
4301 + (NSURL *) divertURL:(NSURL *)url {
4302   divert:
4303     NSString *href([url absoluteString]);
4304
4305     for (Diversion *diversion in (id) Diversions_)
4306         if (NSString *diverted = [diversion divert:href]) {
4307 #if !ForRelease
4308             NSLog(@"div: %@", diverted);
4309 #endif
4310             url = [NSURL URLWithString:diverted];
4311             goto divert;
4312         }
4313
4314     return url;
4315 }
4316
4317 - (NSString *) key {
4318     return key_;
4319 }
4320
4321 - (NSUInteger) hash {
4322     return [key_ hash];
4323 }
4324
4325 - (BOOL) isEqual:(Diversion *)object {
4326     return self == object || [self class] == [object class] && [key_ isEqual:[object key]];
4327 }
4328
4329 @end
4330
4331 @interface CydiaObject : NSObject {
4332     _H<CyteWebViewController> indirect_;
4333     _transient id delegate_;
4334 }
4335
4336 - (id) initWithDelegate:(IndirectDelegate *)indirect;
4337
4338 @end
4339
4340 @class CydiaObject;
4341
4342 @interface CydiaWebViewController : CyteWebViewController {
4343     _H<CydiaObject> cydia_;
4344 }
4345
4346 + (void) addDiversion:(Diversion *)diversion;
4347 + (NSURLRequest *) requestWithHeaders:(NSURLRequest *)request;
4348 + (void) didClearWindowObject:(WebScriptObject *)window forFrame:(WebFrame *)frame withCydia:(CydiaObject *)cydia;
4349 - (void) setDelegate:(id)delegate;
4350
4351 @end
4352
4353 /* Web Scripting {{{ */
4354 @implementation CydiaObject
4355
4356 - (id) initWithDelegate:(IndirectDelegate *)indirect {
4357     if ((self = [super init]) != nil) {
4358         indirect_ = (CyteWebViewController *) indirect;
4359     } return self;
4360 }
4361
4362 - (void) setDelegate:(id)delegate {
4363     delegate_ = delegate;
4364 }
4365
4366 + (NSArray *) _attributeKeys {
4367     return [NSArray arrayWithObjects:
4368         @"bittage",
4369         @"bbsnum",
4370         @"build",
4371         @"cells",
4372         @"coreFoundationVersionNumber",
4373         @"device",
4374         @"ecid",
4375         @"firmware",
4376         @"hostname",
4377         @"idiom",
4378         @"mcc",
4379         @"mnc",
4380         @"model",
4381         @"operator",
4382         @"role",
4383         @"serial",
4384         @"version",
4385     nil];
4386 }
4387
4388 - (NSArray *) attributeKeys {
4389     return [[self class] _attributeKeys];
4390 }
4391
4392 + (BOOL) isKeyExcludedFromWebScript:(const char *)name {
4393     return ![[self _attributeKeys] containsObject:[NSString stringWithUTF8String:name]] && [super isKeyExcludedFromWebScript:name];
4394 }
4395
4396 - (NSString *) version {
4397     return Cydia_;
4398 }
4399
4400 - (unsigned) bittage {
4401 #if 0
4402 #elif defined(__arm64__)
4403     return 64;
4404 #elif defined(__arm__)
4405     return 32;
4406 #else
4407     return 0;
4408 #endif
4409 }
4410
4411 - (NSString *) build {
4412     return System_;
4413 }
4414
4415 - (NSString *) coreFoundationVersionNumber {
4416     return [NSString stringWithFormat:@"%.2f", kCFCoreFoundationVersionNumber];
4417 }
4418
4419 - (NSString *) device {
4420     return UniqueIdentifier();
4421 }
4422
4423 - (NSString *) firmware {
4424     return [[UIDevice currentDevice] systemVersion];
4425 }
4426
4427 - (NSString *) hostname {
4428     return [[UIDevice currentDevice] name];
4429 }
4430
4431 - (NSString *) idiom {
4432     return (id) Idiom_ ?: [NSNull null];
4433 }
4434
4435 - (NSArray *) cells {
4436     auto *$_CTServerConnectionCreate(reinterpret_cast<id (*)(void *, void *, void *)>(dlsym(RTLD_DEFAULT, "_CTServerConnectionCreate")));
4437     if ($_CTServerConnectionCreate == NULL)
4438         return nil;
4439
4440     struct CTResult { int flag; int error; };
4441     auto *$_CTServerConnectionCellMonitorCopyCellInfo(reinterpret_cast<CTResult (*)(CFTypeRef, void *, CFArrayRef *)>(dlsym(RTLD_DEFAULT, "_CTServerConnectionCellMonitorCopyCellInfo")));
4442     if ($_CTServerConnectionCellMonitorCopyCellInfo == NULL)
4443         return nil;
4444
4445     _H<const void> connection($_CTServerConnectionCreate(NULL, NULL, NULL), true);
4446     if (connection == nil)
4447         return nil;
4448
4449     int count(0);
4450     CFArrayRef cells(NULL);
4451     auto result($_CTServerConnectionCellMonitorCopyCellInfo(connection, &count, &cells));
4452     if (result.flag != 0)
4453         return nil;
4454
4455     return [(NSArray *) cells autorelease];
4456 }
4457
4458 - (NSString *) mcc {
4459     if (CFStringRef (*$CTSIMSupportCopyMobileSubscriberCountryCode)(CFAllocatorRef) = reinterpret_cast<CFStringRef (*)(CFAllocatorRef)>(dlsym(RTLD_DEFAULT, "CTSIMSupportCopyMobileSubscriberCountryCode")))
4460         return [(NSString *) (*$CTSIMSupportCopyMobileSubscriberCountryCode)(kCFAllocatorDefault) autorelease];
4461     return nil;
4462 }
4463
4464 - (NSString *) mnc {
4465     if (CFStringRef (*$CTSIMSupportCopyMobileSubscriberNetworkCode)(CFAllocatorRef) = reinterpret_cast<CFStringRef (*)(CFAllocatorRef)>(dlsym(RTLD_DEFAULT, "CTSIMSupportCopyMobileSubscriberNetworkCode")))
4466         return [(NSString *) (*$CTSIMSupportCopyMobileSubscriberNetworkCode)(kCFAllocatorDefault) autorelease];
4467     return nil;
4468 }
4469
4470 - (NSString *) operator {
4471     if (CFStringRef (*$CTRegistrationCopyOperatorName)(CFAllocatorRef) = reinterpret_cast<CFStringRef (*)(CFAllocatorRef)>(dlsym(RTLD_DEFAULT, "CTRegistrationCopyOperatorName")))
4472         return [(NSString *) (*$CTRegistrationCopyOperatorName)(kCFAllocatorDefault) autorelease];
4473     return nil;
4474 }
4475
4476 - (NSString *) bbsnum {
4477     return (id) BBSNum_ ?: [NSNull null];
4478 }
4479
4480 - (NSString *) ecid {
4481     return (id) ChipID_ ?: [NSNull null];
4482 }
4483
4484 - (NSString *) serial {
4485     return SerialNumber_;
4486 }
4487
4488 - (NSString *) role {
4489     return (id) [NSNull null];
4490 }
4491
4492 - (NSString *) model {
4493     return [NSString stringWithUTF8String:Machine_];
4494 }
4495
4496 + (NSString *) webScriptNameForSelector:(SEL)selector {
4497     if (false);
4498     else if (selector == @selector(addBridgedHost:))
4499         return @"addBridgedHost";
4500     else if (selector == @selector(addInsecureHost:))
4501         return @"addInsecureHost";
4502     else if (selector == @selector(addInternalRedirect::))
4503         return @"addInternalRedirect";
4504     else if (selector == @selector(addPipelinedHost:scheme:))
4505         return @"addPipelinedHost";
4506     else if (selector == @selector(addSource:::))
4507         return @"addSource";
4508     else if (selector == @selector(addTrivialSource:))
4509         return @"addTrivialSource";
4510     else if (selector == @selector(close))
4511         return @"close";
4512     else if (selector == @selector(du:))
4513         return @"du";
4514     else if (selector == @selector(stringWithFormat:arguments:))
4515         return @"format";
4516     else if (selector == @selector(getAllSources))
4517         return @"getAllSources";
4518     else if (selector == @selector(getApplicationInfo:value:))
4519         return @"getApplicationInfoValue";
4520     else if (selector == @selector(getDisplayIdentifiers))
4521         return @"getDisplayIdentifiers";
4522     else if (selector == @selector(getLocalizedNameForDisplayIdentifier:))
4523         return @"getLocalizedNameForDisplayIdentifier";
4524     else if (selector == @selector(getKernelNumber:))
4525         return @"getKernelNumber";
4526     else if (selector == @selector(getKernelString:))
4527         return @"getKernelString";
4528     else if (selector == @selector(getInstalledPackages))
4529         return @"getInstalledPackages";
4530     else if (selector == @selector(getIORegistryEntry::))
4531         return @"getIORegistryEntry";
4532     else if (selector == @selector(getLocaleIdentifier))
4533         return @"getLocaleIdentifier";
4534     else if (selector == @selector(getPreferredLanguages))
4535         return @"getPreferredLanguages";
4536     else if (selector == @selector(getPackageById:))
4537         return @"getPackageById";
4538     else if (selector == @selector(getMetadataKeys))
4539         return @"getMetadataKeys";
4540     else if (selector == @selector(getMetadataValue:))
4541         return @"getMetadataValue";
4542     else if (selector == @selector(getSessionValue:))
4543         return @"getSessionValue";
4544     else if (selector == @selector(installPackages:))
4545         return @"installPackages";
4546     else if (selector == @selector(isReachable:))
4547         return @"isReachable";
4548     else if (selector == @selector(localizedStringForKey:value:table:))
4549         return @"localize";
4550     else if (selector == @selector(popViewController:))
4551         return @"popViewController";
4552     else if (selector == @selector(refreshSources))
4553         return @"refreshSources";
4554     else if (selector == @selector(registerFrame:))
4555         return @"registerFrame";
4556     else if (selector == @selector(removeButton))
4557         return @"removeButton";
4558     else if (selector == @selector(saveConfig))
4559         return @"saveConfig";
4560     else if (selector == @selector(setMetadataValue::))
4561         return @"setMetadataValue";
4562     else if (selector == @selector(setSessionValue::))
4563         return @"setSessionValue";
4564     else if (selector == @selector(substitutePackageNames:))
4565         return @"substitutePackageNames";
4566     else if (selector == @selector(scrollToBottom:))
4567         return @"scrollToBottom";
4568     else if (selector == @selector(setAllowsNavigationAction:))
4569         return @"setAllowsNavigationAction";
4570     else if (selector == @selector(setBadgeValue:))
4571         return @"setBadgeValue";
4572     else if (selector == @selector(setButtonImage:withStyle:toFunction:))
4573         return @"setButtonImage";
4574     else if (selector == @selector(setButtonTitle:withStyle:toFunction:))
4575         return @"setButtonTitle";
4576     else if (selector == @selector(setHidesBackButton:))
4577         return @"setHidesBackButton";
4578     else if (selector == @selector(setHidesNavigationBar:))
4579         return @"setHidesNavigationBar";
4580     else if (selector == @selector(setNavigationBarStyle:))
4581         return @"setNavigationBarStyle";
4582     else if (selector == @selector(setNavigationBarTintRed:green:blue:alpha:))
4583         return @"setNavigationBarTintColor";
4584     else if (selector == @selector(setPasteboardString:))
4585         return @"setPasteboardString";
4586     else if (selector == @selector(setPasteboardURL:))
4587         return @"setPasteboardURL";
4588     else if (selector == @selector(setScrollAlwaysBounceVertical:))
4589         return @"setScrollAlwaysBounceVertical";
4590     else if (selector == @selector(setScrollIndicatorStyle:))
4591         return @"setScrollIndicatorStyle";
4592     else if (selector == @selector(setToken:))
4593         return @"setToken";
4594     else if (selector == @selector(setViewportWidth:))
4595         return @"setViewportWidth";
4596     else if (selector == @selector(statfs:))
4597         return @"statfs";
4598     else if (selector == @selector(supports:))
4599         return @"supports";
4600     else if (selector == @selector(unload))
4601         return @"unload";
4602     else
4603         return nil;
4604 }
4605
4606 + (BOOL) isSelectorExcludedFromWebScript:(SEL)selector {
4607     return [self webScriptNameForSelector:selector] == nil;
4608 }
4609
4610 - (BOOL) supports:(NSString *)feature {
4611     return [feature isEqualToString:@"window.open"];
4612 }
4613
4614 - (void) unload {
4615     [delegate_ performSelectorOnMainThread:@selector(unloadData) withObject:nil waitUntilDone:NO];
4616 }
4617
4618 - (void) setScrollAlwaysBounceVertical:(NSNumber *)value {
4619     [indirect_ performSelectorOnMainThread:@selector(setScrollAlwaysBounceVerticalNumber:) withObject:value waitUntilDone:NO];
4620 }
4621
4622 - (void) setScrollIndicatorStyle:(NSString *)style {
4623     [indirect_ performSelectorOnMainThread:@selector(setScrollIndicatorStyleWithName:) withObject:style waitUntilDone:NO];
4624 }
4625
4626 - (void) addInternalRedirect:(NSString *)from :(NSString *)to {
4627     [CydiaWebViewController performSelectorOnMainThread:@selector(addDiversion:) withObject:[[[Diversion alloc] initWithFrom:from to:to] autorelease] waitUntilDone:NO];
4628 }
4629
4630 - (NSDictionary *) getApplicationInfo:(NSString *)display value:(NSString *)key {
4631     char path[1024];
4632     if (SBBundlePathForDisplayIdentifier(SBSSpringBoardServerPort(), [display UTF8String], path) != 0)
4633         return (id) [NSNull null];
4634     NSDictionary *info([NSDictionary dictionaryWithContentsOfFile:[[NSString stringWithUTF8String:path] stringByAppendingString:@"/Info.plist"]]);
4635     if (info == nil)
4636         return (id) [NSNull null];
4637     return [info objectForKey:key];
4638 }
4639
4640 - (NSArray *) getDisplayIdentifiers {
4641     return SBSCopyApplicationDisplayIdentifiers(false, false);
4642 }
4643
4644 - (NSString *) getLocalizedNameForDisplayIdentifier:(NSString *)identifier {
4645     return [SBSCopyLocalizedApplicationNameForDisplayIdentifier(identifier) autorelease] ?: (id) [NSNull null];
4646 }
4647
4648 - (NSNumber *) getKernelNumber:(NSString *)name {
4649     const char *string([name UTF8String]);
4650
4651     size_t size;
4652     if (sysctlbyname(string, NULL, &size, NULL, 0) == -1)
4653         return (id) [NSNull null];
4654
4655     if (size != sizeof(int))
4656         return (id) [NSNull null];
4657
4658     int value;
4659     if (sysctlbyname(string, &value, &size, NULL, 0) == -1)
4660         return (id) [NSNull null];
4661
4662     return [NSNumber numberWithInt:value];
4663 }
4664
4665 - (NSString *) getKernelString:(NSString *)name {
4666     const char *string([name UTF8String]);
4667
4668     size_t size;
4669     if (sysctlbyname(string, NULL, &size, NULL, 0) == -1)
4670         return (id) [NSNull null];
4671
4672     char value[size + 1];
4673     if (sysctlbyname(string, value, &size, NULL, 0) == -1)
4674         return (id) [NSNull null];
4675
4676     // XXX: just in case you request something ludicrous
4677     value[size] = '\0';
4678
4679     return [NSString stringWithCString:value];
4680 }
4681
4682 - (NSObject *) getIORegistryEntry:(NSString *)path :(NSString *)entry {
4683     NSObject *value(CYIOGetValue([path UTF8String], entry));
4684
4685     if (value != nil)
4686         if ([value isKindOfClass:[NSData class]])
4687             value = CYHex((NSData *) value);
4688
4689     return value;
4690 }
4691
4692 - (NSArray *) getMetadataKeys {
4693 @synchronized (Values_) {
4694     return [Values_ allKeys];
4695 } }
4696
4697 - (void) registerFrame:(DOMHTMLIFrameElement *)iframe {
4698     WebFrame *frame([iframe contentFrame]);
4699     [indirect_ registerFrame:frame];
4700 }
4701
4702 - (id) getMetadataValue:(NSString *)key {
4703 @synchronized (Values_) {
4704     return [Values_ objectForKey:key];
4705 } }
4706
4707 - (void) setMetadataValue:(NSString *)key :(NSString *)value {
4708 @synchronized (Values_) {
4709     if (value == nil || value == (id) [WebUndefined undefined] || value == (id) [NSNull null])
4710         [Values_ removeObjectForKey:key];
4711     else
4712         [Values_ setObject:value forKey:key];
4713 } }
4714
4715 - (id) getSessionValue:(NSString *)key {
4716 @synchronized (SessionData_) {
4717     return [SessionData_ objectForKey:key];
4718 } }
4719
4720 - (void) setSessionValue:(NSString *)key :(NSString *)value {
4721 @synchronized (SessionData_) {
4722     if (value == (id) [WebUndefined undefined])
4723         [SessionData_ removeObjectForKey:key];
4724     else
4725         [SessionData_ setObject:value forKey:key];
4726 } }
4727
4728 - (void) addBridgedHost:(NSString *)host {
4729 @synchronized (HostConfig_) {
4730     [BridgedHosts_ addObject:host];
4731 } }
4732
4733 - (void) addInsecureHost:(NSString *)host {
4734 @synchronized (HostConfig_) {
4735     [InsecureHosts_ addObject:host];
4736 } }
4737
4738 - (void) addPipelinedHost:(NSString *)host scheme:(NSString *)scheme {
4739 @synchronized (HostConfig_) {
4740     if (scheme != (id) [WebUndefined undefined])
4741         host = [NSString stringWithFormat:@"%@:%@", [scheme lowercaseString], host];
4742
4743     [PipelinedHosts_ addObject:host];
4744 } }
4745
4746 - (void) popViewController:(NSNumber *)value {
4747     if (value == (id) [WebUndefined undefined])
4748         value = [NSNumber numberWithBool:YES];
4749     [indirect_ performSelectorOnMainThread:@selector(popViewControllerWithNumber:) withObject:value waitUntilDone:NO];
4750 }
4751
4752 - (void) addSource:(NSString *)href :(NSString *)distribution :(WebScriptObject *)sections {
4753     NSMutableArray *array([NSMutableArray arrayWithCapacity:[sections count]]);
4754
4755     for (NSString *section in sections)
4756         [array addObject:section];
4757
4758     [delegate_ performSelectorOnMainThread:@selector(addSource:) withObject:[NSMutableDictionary dictionaryWithObjectsAndKeys:
4759         @"deb", @"Type",
4760         href, @"URI",
4761         distribution, @"Distribution",
4762         array, @"Sections",
4763     nil] waitUntilDone:NO];
4764 }
4765
4766 - (BOOL) addTrivialSource:(NSString *)href {
4767     href = VerifySource(href);
4768     if (href == nil)
4769         return NO;
4770     [delegate_ performSelectorOnMainThread:@selector(addTrivialSource:) withObject:href waitUntilDone:NO];
4771     return YES;
4772 }
4773
4774 - (void) refreshSources {
4775     [delegate_ performSelectorOnMainThread:@selector(syncData) withObject:nil waitUntilDone:NO];
4776 }
4777
4778 - (void) saveConfig {
4779     [delegate_ performSelectorOnMainThread:@selector(_saveConfig) withObject:nil waitUntilDone:NO];
4780 }
4781
4782 - (NSArray *) getAllSources {
4783     return [[Database sharedInstance] sources];
4784 }
4785
4786 - (NSArray *) getInstalledPackages {
4787     Database *database([Database sharedInstance]);
4788 @synchronized (database) {
4789     NSArray *packages([database packages]);
4790     NSMutableArray *installed([NSMutableArray arrayWithCapacity:1024]);
4791     for (Package *package in packages)
4792         if (![package uninstalled])
4793             [installed addObject:package];
4794     return installed;
4795 } }
4796
4797 - (Package *) getPackageById:(NSString *)id {
4798     if (Package *package = [[Database sharedInstance] packageWithName:id]) {
4799         [package parse];
4800         return package;
4801     } else
4802         return (Package *) [NSNull null];
4803 }
4804
4805 - (NSString *) getLocaleIdentifier {
4806     return Locale_ == NULL ? (NSString *) [NSNull null] : (NSString *) CFLocaleGetIdentifier(Locale_);
4807 }
4808
4809 - (NSArray *) getPreferredLanguages {
4810     return Languages_;
4811 }
4812
4813 - (NSArray *) statfs:(NSString *)path {
4814     struct statfs stat;
4815
4816     if (path == nil || statfs([path UTF8String], &stat) == -1)
4817         return nil;
4818
4819     return [NSArray arrayWithObjects:
4820         [NSNumber numberWithUnsignedLong:stat.f_bsize],
4821         [NSNumber numberWithUnsignedLong:stat.f_blocks],
4822         [NSNumber numberWithUnsignedLong:stat.f_bfree],
4823     nil];
4824 }
4825
4826 - (NSNumber *) du:(NSString *)path {
4827     NSNumber *value(nil);
4828
4829     FILE *du(popen([[NSString stringWithFormat:@"/usr/libexec/cydia/cydo /usr/libexec/cydia/du -ks %@", ShellEscape(path)] UTF8String], "r"));
4830     if (du != NULL) {
4831         char line[1024];
4832         while (fgets(line, sizeof(line), du) != NULL) {
4833             size_t length(strlen(line));
4834             while (length != 0 && line[length - 1] == '\n')
4835                 line[--length] = '\0';
4836             if (char *tab = strchr(line, '\t')) {
4837                 *tab = '\0';
4838                 value = [NSNumber numberWithUnsignedLong:strtoul(line, NULL, 0)];
4839             }
4840         }
4841         pclose(du);
4842     }
4843
4844     return value;
4845 }
4846
4847 - (void) close {
4848     [indirect_ performSelectorOnMainThread:@selector(close) withObject:nil waitUntilDone:NO];
4849 }
4850
4851 - (NSNumber *) isReachable:(NSString *)name {
4852     return [NSNumber numberWithBool:IsReachable([name UTF8String])];
4853 }
4854
4855 - (void) installPackages:(NSArray *)packages {
4856     [delegate_ performSelectorOnMainThread:@selector(installPackages:) withObject:packages waitUntilDone:NO];
4857 }
4858
4859 - (NSString *) substitutePackageNames:(NSString *)message {
4860     NSMutableArray *words([[[message componentsSeparatedByString:@" "] mutableCopy] autorelease]);
4861     for (size_t i(0), e([words count]); i != e; ++i) {
4862         NSString *word([words objectAtIndex:i]);
4863         if (Package *package = [[Database sharedInstance] packageWithName:word])
4864             [words replaceObjectAtIndex:i withObject:[package name]];
4865     }
4866
4867     return [words componentsJoinedByString:@" "];
4868 }
4869
4870 - (void) removeButton {
4871     [indirect_ removeButton];
4872 }
4873
4874 - (void) setButtonImage:(NSString *)button withStyle:(NSString *)style toFunction:(id)function {
4875     [indirect_ setButtonImage:button withStyle:style toFunction:function];
4876 }
4877
4878 - (void) setButtonTitle:(NSString *)button withStyle:(NSString *)style toFunction:(id)function {
4879     [indirect_ setButtonTitle:button withStyle:style toFunction:function];
4880 }
4881
4882 - (void) setBadgeValue:(id)value {
4883     [indirect_ performSelectorOnMainThread:@selector(setBadgeValue:) withObject:value waitUntilDone:NO];
4884 }
4885
4886 - (void) setAllowsNavigationAction:(NSString *)value {
4887     [indirect_ performSelectorOnMainThread:@selector(setAllowsNavigationActionByNumber:) withObject:value waitUntilDone:NO];
4888 }
4889
4890 - (void) setHidesBackButton:(NSString *)value {
4891     [indirect_ performSelectorOnMainThread:@selector(setHidesBackButtonByNumber:) withObject:value waitUntilDone:NO];
4892 }
4893
4894 - (void) setHidesNavigationBar:(NSString *)value {
4895     [indirect_ performSelectorOnMainThread:@selector(setHidesNavigationBarByNumber:) withObject:value waitUntilDone:NO];
4896 }
4897
4898 - (void) setNavigationBarStyle:(NSString *)value {
4899     [indirect_ performSelectorOnMainThread:@selector(setNavigationBarStyle:) withObject:value waitUntilDone:NO];
4900 }
4901
4902 - (void) setNavigationBarTintRed:(NSNumber *)red green:(NSNumber *)green blue:(NSNumber *)blue alpha:(NSNumber *)alpha {
4903     float opacity(alpha == (id) [WebUndefined undefined] ? 1 : [alpha floatValue]);
4904     UIColor *color([UIColor colorWithRed:[red floatValue] green:[green floatValue] blue:[blue floatValue] alpha:opacity]);
4905     [indirect_ performSelectorOnMainThread:@selector(setNavigationBarTintColor:) withObject:color waitUntilDone:NO];
4906 }
4907
4908 - (void) setPasteboardString:(NSString *)value {
4909     [[objc_getClass("UIPasteboard") generalPasteboard] setString:value];
4910 }
4911
4912 - (void) setPasteboardURL:(NSString *)value {
4913     [[objc_getClass("UIPasteboard") generalPasteboard] setURL:[NSURL URLWithString:value]];
4914 }
4915
4916 - (void) setToken:(NSString *)token {
4917     // XXX: the website expects this :/
4918 }
4919
4920 - (void) scrollToBottom:(NSNumber *)animated {
4921     [indirect_ performSelectorOnMainThread:@selector(scrollToBottomAnimated:) withObject:animated waitUntilDone:NO];
4922 }
4923
4924 - (void) setViewportWidth:(float)width {
4925     [indirect_ setViewportWidthOnMainThread:width];
4926 }
4927
4928 - (NSString *) stringWithFormat:(NSString *)format arguments:(WebScriptObject *)arguments {
4929     //NSLog(@"SWF:\"%@\" A:%@", format, [arguments description]);
4930     unsigned count([arguments count]);
4931     id values[count];
4932     for (unsigned i(0); i != count; ++i)
4933         values[i] = [arguments objectAtIndex:i];
4934     return [[[NSString alloc] initWithFormat:format arguments:reinterpret_cast<va_list>(values)] autorelease];
4935 }
4936
4937 - (NSString *) localizedStringForKey:(NSString *)key value:(NSString *)value table:(NSString *)table {
4938     if (reinterpret_cast<id>(value) == [WebUndefined undefined])
4939         value = nil;
4940     if (reinterpret_cast<id>(table) == [WebUndefined undefined])
4941         table = nil;
4942     return [[NSBundle mainBundle] localizedStringForKey:key value:value table:table];
4943 }
4944
4945 @end
4946 /* }}} */
4947
4948 @interface NSURL (CydiaSecure)
4949 @end
4950
4951 @implementation NSURL (CydiaSecure)
4952
4953 - (bool) isCydiaSecure {
4954     if ([[[self scheme] lowercaseString] isEqualToString:@"https"])
4955         return true;
4956
4957     @synchronized (HostConfig_) {
4958         if ([InsecureHosts_ containsObject:[self host]])
4959             return true;
4960     }
4961
4962     return false;
4963 }
4964
4965 @end
4966
4967 /* Cydia Browser Controller {{{ */
4968 @implementation CydiaWebViewController
4969
4970 - (NSURL *) navigationURL {
4971     return request_ == nil ? nil : [NSURL URLWithString:[NSString stringWithFormat:@"cydia://url/%@", [[request_ URL] absoluteString]]];
4972 }
4973
4974 + (void) _initialize {
4975     [super _initialize];
4976
4977     Diversions_ = [NSMutableSet setWithCapacity:0];
4978 }
4979
4980 + (void) addDiversion:(Diversion *)diversion {
4981     [Diversions_ addObject:diversion];
4982 }
4983
4984 - (void) webView:(WebView *)view didClearWindowObject:(WebScriptObject *)window forFrame:(WebFrame *)frame {
4985     [super webView:view didClearWindowObject:window forFrame:frame];
4986     [CydiaWebViewController didClearWindowObject:window forFrame:frame withCydia:cydia_];
4987 }
4988
4989 + (void) didClearWindowObject:(WebScriptObject *)window forFrame:(WebFrame *)frame withCydia:(CydiaObject *)cydia {
4990     WebDataSource *source([frame dataSource]);
4991     NSURLResponse *response([source response]);
4992     NSURL *url([response URL]);
4993     NSString *scheme([[url scheme] lowercaseString]);
4994
4995     bool bridged(false);
4996
4997     @synchronized (HostConfig_) {
4998         if ([scheme isEqualToString:@"file"])
4999             bridged = true;
5000         else if ([scheme isEqualToString:@"https"])
5001             if ([BridgedHosts_ containsObject:[url host]])
5002                 bridged = true;
5003     }
5004
5005     if (bridged)
5006         [window setValue:cydia forKey:@"cydia"];
5007 }
5008
5009 - (void) _setupMail:(MFMailComposeViewController *)controller {
5010     [controller addAttachmentData:[NSData dataWithContentsOfFile:@"/tmp/cydia.log"] mimeType:@"text/plain" fileName:@"cydia.log"];
5011
5012     system("/usr/bin/dpkg -l >/tmp/dpkgl.log");
5013     [controller addAttachmentData:[NSData dataWithContentsOfFile:@"/tmp/dpkgl.log"] mimeType:@"text/plain" fileName:@"dpkgl.log"];
5014 }
5015
5016 - (NSURL *) URLWithURL:(NSURL *)url {
5017     return [Diversion divertURL:url];
5018 }
5019
5020 - (NSURLRequest *) webView:(WebView *)view resource:(id)resource willSendRequest:(NSURLRequest *)request redirectResponse:(NSURLResponse *)response fromDataSource:(WebDataSource *)source {
5021     return [CydiaWebViewController requestWithHeaders:[super webView:view resource:resource willSendRequest:request redirectResponse:response fromDataSource:source]];
5022 }
5023
5024 - (NSURLRequest *) webThreadWebView:(WebView *)view resource:(id)resource willSendRequest:(NSURLRequest *)request redirectResponse:(NSURLResponse *)response fromDataSource:(WebDataSource *)source {
5025     return [CydiaWebViewController requestWithHeaders:[super webThreadWebView:view resource:resource willSendRequest:request redirectResponse:response fromDataSource:source]];
5026 }
5027
5028 + (NSURLRequest *) requestWithHeaders:(NSURLRequest *)request {
5029     NSMutableURLRequest *copy([[request mutableCopy] autorelease]);
5030
5031     NSURL *url([copy URL]);
5032     NSString *href([url absoluteString]);
5033     NSString *host([url host]);
5034
5035     if ([href hasPrefix:@"https://cydia.saurik.com/TSS/"]) {
5036         if (NSString *agent = [copy valueForHTTPHeaderField:@"X-User-Agent"]) {
5037             [copy setValue:agent forHTTPHeaderField:@"User-Agent"];
5038             [copy setValue:nil forHTTPHeaderField:@"X-User-Agent"];
5039         }
5040
5041         [copy setValue:nil forHTTPHeaderField:@"Referer"];
5042         [copy setValue:nil forHTTPHeaderField:@"Origin"];
5043
5044         [copy setURL:[NSURL URLWithString:[@"http://gs.apple.com/TSS/" stringByAppendingString:[href substringFromIndex:29]]]];
5045         return copy;
5046     }
5047
5048     if ([copy valueForHTTPHeaderField:@"X-Cydia-Cf"] == nil)
5049         [copy setValue:[NSString stringWithFormat:@"%.2f", kCFCoreFoundationVersionNumber] forHTTPHeaderField:@"X-Cydia-Cf"];
5050     if (Machine_ != NULL && [copy valueForHTTPHeaderField:@"X-Machine"] == nil)
5051         [copy setValue:[NSString stringWithUTF8String:Machine_] forHTTPHeaderField:@"X-Machine"];
5052
5053     bool bridged; @synchronized (HostConfig_) {
5054         bridged = [BridgedHosts_ containsObject:host];
5055     }
5056
5057     if ([url isCydiaSecure] && bridged && UniqueID_ != nil && [copy valueForHTTPHeaderField:@"X-Cydia-Id"] == nil)
5058         [copy setValue:UniqueID_ forHTTPHeaderField:@"X-Cydia-Id"];
5059
5060     return copy;
5061 }
5062
5063 - (void) setDelegate:(id)delegate {
5064     [super setDelegate:delegate];
5065     [cydia_ setDelegate:delegate];
5066 }
5067
5068 - (NSString *) applicationNameForUserAgent {
5069     return UserAgent_;
5070 }
5071
5072 - (id) init {
5073     if ((self = [super initWithWidth:0 ofClass:[CydiaWebViewController class]]) != nil) {
5074         cydia_ = [[[CydiaObject alloc] initWithDelegate:indirect_] autorelease];
5075     } return self;
5076 }
5077
5078 @end
5079
5080 @interface AppCacheController : CydiaWebViewController {
5081 }
5082
5083 @end
5084
5085 @implementation AppCacheController
5086
5087 - (void) didReceiveMemoryWarning {
5088     // XXX: this doesn't work
5089 }
5090
5091 - (bool) retainsNetworkActivityIndicator {
5092     return false;
5093 }
5094
5095 @end
5096 /* }}} */
5097
5098 // CydiaScript {{{
5099 @interface NSObject (CydiaScript)
5100 - (id) Cydia$webScriptObjectInContext:(WebScriptObject *)context;
5101 @end
5102
5103 @implementation NSObject (CydiaScript)
5104
5105 - (id) Cydia$webScriptObjectInContext:(WebScriptObject *)context {
5106     return self;
5107 }
5108
5109 @end
5110
5111 @implementation NSArray (CydiaScript)
5112
5113 - (id) Cydia$webScriptObjectInContext:(WebScriptObject *)context {
5114     WebScriptObject *object([context evaluateWebScript:@"[]"]);
5115     for (size_t i(0), e([self count]); i != e; ++i)
5116         [object setWebScriptValueAtIndex:i value:[[self objectAtIndex:i] Cydia$webScriptObjectInContext:context]];
5117     return object;
5118 }
5119
5120 @end
5121
5122 @implementation NSDictionary (CydiaScript)
5123
5124 - (id) Cydia$webScriptObjectInContext:(WebScriptObject *)context {
5125     WebScriptObject *object([context evaluateWebScript:@"({})"]);
5126     for (id i in self)
5127         [object setValue:[[self objectForKey:i] Cydia$webScriptObjectInContext:context] forKey:i];
5128     return object;
5129 }
5130
5131 @end
5132 // }}}
5133
5134 /* Confirmation Controller {{{ */
5135 bool DepSubstrate(const pkgCache::VerIterator &iterator) {
5136     if (!iterator.end())
5137         for (pkgCache::DepIterator dep(iterator.DependsList()); !dep.end(); ++dep) {
5138             if (dep->Type != pkgCache::Dep::Depends && dep->Type != pkgCache::Dep::PreDepends)
5139                 continue;
5140             pkgCache::PkgIterator package(dep.TargetPkg());
5141             if (package.end())
5142                 continue;
5143             if (strcmp(package.Name(), "mobilesubstrate") == 0)
5144                 return true;
5145         }
5146
5147     return false;
5148 }
5149
5150 @protocol ConfirmationControllerDelegate
5151 - (void) cancelAndClear:(bool)clear;
5152 - (void) confirmWithNavigationController:(UINavigationController *)navigation;
5153 - (void) queue;
5154 @end
5155
5156 @interface ConfirmationController : CydiaWebViewController {
5157     _transient Database *database_;
5158
5159     _H<UIAlertView> essential_;
5160
5161     _H<NSDictionary> changes_;
5162     _H<NSMutableArray> issues_;
5163     _H<NSDictionary> sizes_;
5164
5165     BOOL substrate_;
5166 }
5167
5168 - (id) initWithDatabase:(Database *)database;
5169
5170 @end
5171
5172 @implementation ConfirmationController
5173
5174 - (void) complete {
5175     if (substrate_)
5176         RestartSubstrate_ = true;
5177     [delegate_ confirmWithNavigationController:[self navigationController]];
5178 }
5179
5180 - (void) alertView:(UIAlertView *)alert clickedButtonAtIndex:(NSInteger)button {
5181     NSString *context([alert context]);
5182
5183     if ([context isEqualToString:@"remove"]) {
5184         if (button == [alert cancelButtonIndex])
5185             [self _doContinue];
5186         else if (button == [alert firstOtherButtonIndex]) {
5187             [self performSelector:@selector(complete) withObject:nil afterDelay:0];
5188         }
5189
5190         [alert dismissWithClickedButtonIndex:-1 animated:YES];
5191     } else if ([context isEqualToString:@"unable"]) {
5192         [self dismissModalViewControllerAnimated:YES];
5193         [alert dismissWithClickedButtonIndex:-1 animated:YES];
5194     } else {
5195         [super alertView:alert clickedButtonAtIndex:button];
5196     }
5197 }
5198
5199 - (void) _doContinue {
5200     [delegate_ cancelAndClear:NO];
5201     [self dismissModalViewControllerAnimated:YES];
5202 }
5203
5204 - (id) invokeDefaultMethodWithArguments:(NSArray *)args {
5205     [self performSelectorOnMainThread:@selector(_doContinue) withObject:nil waitUntilDone:NO];
5206     return nil;
5207 }
5208
5209 - (void) webView:(WebView *)view didClearWindowObject:(WebScriptObject *)window forFrame:(WebFrame *)frame {
5210     [super webView:view didClearWindowObject:window forFrame:frame];
5211
5212     [window setValue:[[NSDictionary dictionaryWithObjectsAndKeys:
5213         (id) changes_, @"changes",
5214         (id) issues_, @"issues",
5215         (id) sizes_, @"sizes",
5216         self, @"queue",
5217     nil] Cydia$webScriptObjectInContext:window] forKey:@"cydiaConfirm"];
5218 }
5219
5220 - (id) initWithDatabase:(Database *)database {
5221     if ((self = [super init]) != nil) {
5222         database_ = database;
5223
5224         NSMutableArray *installs([NSMutableArray arrayWithCapacity:16]);
5225         NSMutableArray *reinstalls([NSMutableArray arrayWithCapacity:16]);
5226         NSMutableArray *upgrades([NSMutableArray arrayWithCapacity:16]);
5227         NSMutableArray *downgrades([NSMutableArray arrayWithCapacity:16]);
5228         NSMutableArray *removes([NSMutableArray arrayWithCapacity:16]);
5229
5230         bool remove(false);
5231
5232         pkgCacheFile &cache([database_ cache]);
5233         NSArray *packages([database_ packages]);
5234         pkgDepCache::Policy *policy([database_ policy]);
5235
5236         issues_ = [NSMutableArray arrayWithCapacity:4];
5237
5238         for (Package *package in packages) {
5239             pkgCache::PkgIterator iterator([package iterator]);
5240             NSString *name([package id]);
5241
5242             if ([package broken]) {
5243                 NSMutableArray *reasons([NSMutableArray arrayWithCapacity:4]);
5244
5245                 [issues_ addObject:[NSDictionary dictionaryWithObjectsAndKeys:
5246                     name, @"package",
5247                     reasons, @"reasons",
5248                 nil]];
5249
5250                 pkgCache::VerIterator ver(cache[iterator].InstVerIter(cache));
5251                 if (ver.end())
5252                     continue;
5253
5254                 for (pkgCache::DepIterator dep(ver.DependsList()); !dep.end(); ) {
5255                     pkgCache::DepIterator start;
5256                     pkgCache::DepIterator end;
5257                     dep.GlobOr(start, end); // ++dep
5258
5259                     if (!cache->IsImportantDep(end))
5260                         continue;
5261                     if ((cache[end] & pkgDepCache::DepGInstall) != 0)
5262                         continue;
5263
5264                     NSMutableArray *clauses([NSMutableArray arrayWithCapacity:4]);
5265
5266                     [reasons addObject:[NSDictionary dictionaryWithObjectsAndKeys:
5267                         [NSString stringWithUTF8String:start.DepType()], @"relationship",
5268                         clauses, @"clauses",
5269                     nil]];
5270
5271                     _forever {
5272                         NSString *reason, *installed((NSString *) [WebUndefined undefined]);
5273
5274                         pkgCache::PkgIterator target(start.TargetPkg());
5275                         if (target->ProvidesList != 0)
5276                             reason = @"missing";
5277                         else {
5278                             pkgCache::VerIterator ver(cache[target].InstVerIter(cache));
5279                             if (!ver.end()) {
5280                                 reason = @"installed";
5281                                 installed = [NSString stringWithUTF8String:ver.VerStr()];
5282                             } else if (!cache[target].CandidateVerIter(cache).end())
5283                                 reason = @"uninstalled";
5284                             else if (target->ProvidesList == 0)
5285                                 reason = @"uninstallable";
5286                             else
5287                                 reason = @"virtual";
5288                         }
5289
5290                         NSDictionary *version(start.TargetVer() == 0 ? (NSDictionary *) [NSNull null] : [NSDictionary dictionaryWithObjectsAndKeys:
5291                             [NSString stringWithUTF8String:start.CompType()], @"operator",
5292                             [NSString stringWithUTF8String:start.TargetVer()], @"value",
5293                         nil]);
5294
5295                         [clauses addObject:[NSDictionary dictionaryWithObjectsAndKeys:
5296                             [NSString stringWithUTF8String:start.TargetPkg().Name()], @"package",
5297                             version, @"version",
5298                             reason, @"reason",
5299                             installed, @"installed",
5300                         nil]];
5301
5302                         // yes, seriously. (wtf?)
5303                         if (start == end)
5304                             break;
5305                         ++start;
5306                     }
5307                 }
5308             }
5309
5310             pkgDepCache::StateCache &state(cache[iterator]);
5311
5312             static RegEx special_r("(firmware|gsc\\..*|cy\\+.*)");
5313
5314             if (state.NewInstall())
5315                 [installs addObject:name];
5316             // XXX: else if (state.Install())
5317             else if (!state.Delete() && (state.iFlags & pkgDepCache::ReInstall) == pkgDepCache::ReInstall)
5318                 [reinstalls addObject:name];
5319             // XXX: move before previous if
5320             else if (state.Upgrade())
5321                 [upgrades addObject:name];
5322             else if (state.Downgrade())
5323                 [downgrades addObject:name];
5324             else if (!state.Delete())
5325                 // XXX: _assert(state.Keep());
5326                 continue;
5327             else if (special_r(name))
5328                 [issues_ addObject:[NSDictionary dictionaryWithObjectsAndKeys:
5329                     [NSNull null], @"package",
5330                     [NSArray arrayWithObjects:
5331                         [NSDictionary dictionaryWithObjectsAndKeys:
5332                             @"Conflicts", @"relationship",
5333                             [NSArray arrayWithObjects:
5334                                 [NSDictionary dictionaryWithObjectsAndKeys:
5335                                     name, @"package",
5336                                     [NSNull null], @"version",
5337                                     @"installed", @"reason",
5338                                 nil],
5339                             nil], @"clauses",
5340                         nil],
5341                     nil], @"reasons",
5342                 nil]];
5343             else {
5344                 if ([package essential])
5345                     remove = true;
5346                 [removes addObject:name];
5347             }
5348
5349             substrate_ |= DepSubstrate(policy->GetCandidateVer(iterator));
5350             substrate_ |= DepSubstrate(iterator.CurrentVer());
5351         }
5352
5353         if (!remove)
5354             essential_ = nil;
5355         else if (Advanced_) {
5356             NSString *parenthetical(UCLocalize("PARENTHETICAL"));
5357
5358             essential_ = [[[UIAlertView alloc]
5359                 initWithTitle:UCLocalize("REMOVING_ESSENTIALS")
5360                 message:UCLocalize("REMOVING_ESSENTIALS_EX")
5361                 delegate:self
5362                 cancelButtonTitle:[NSString stringWithFormat:parenthetical, UCLocalize("CANCEL_OPERATION"), UCLocalize("SAFE")]
5363                 otherButtonTitles:
5364                     [NSString stringWithFormat:parenthetical, UCLocalize("FORCE_REMOVAL"), UCLocalize("UNSAFE")],
5365                 nil
5366             ] autorelease];
5367
5368             [essential_ setContext:@"remove"];
5369             [essential_ setNumberOfRows:2];
5370         } else {
5371             essential_ = [[[UIAlertView alloc]
5372                 initWithTitle:UCLocalize("UNABLE_TO_COMPLY")
5373                 message:UCLocalize("UNABLE_TO_COMPLY_EX")
5374                 delegate:self
5375                 cancelButtonTitle:UCLocalize("OKAY")
5376                 otherButtonTitles:nil
5377             ] autorelease];
5378
5379             [essential_ setContext:@"unable"];
5380         }
5381
5382         changes_ = [NSDictionary dictionaryWithObjectsAndKeys:
5383             installs, @"installs",
5384             reinstalls, @"reinstalls",
5385             upgrades, @"upgrades",
5386             downgrades, @"downgrades",
5387             removes, @"removes",
5388         nil];
5389
5390         sizes_ = [NSDictionary dictionaryWithObjectsAndKeys:
5391             [NSNumber numberWithInteger:[database_ fetcher].FetchNeeded()], @"downloading",
5392             [NSNumber numberWithInteger:[database_ fetcher].PartialPresent()], @"resuming",
5393         nil];
5394
5395         [self setURL:[NSURL URLWithString:[NSString stringWithFormat:@"%@/#!/confirm/", UI_]]];
5396     } return self;
5397 }
5398
5399 - (UIBarButtonItem *) leftButton {
5400     return [[[UIBarButtonItem alloc]
5401         initWithTitle:UCLocalize("CANCEL")
5402         style:UIBarButtonItemStylePlain
5403         target:self
5404         action:@selector(cancelButtonClicked)
5405     ] autorelease];
5406 }
5407
5408 #if !AlwaysReload
5409 - (void) applyRightButton {
5410     if ([issues_ count] == 0 && ![self isLoading])
5411         [[self navigationItem] setRightBarButtonItem:[[[UIBarButtonItem alloc]
5412             initWithTitle:UCLocalize("CONFIRM")
5413             style:UIBarButtonItemStyleDone
5414             target:self
5415             action:@selector(confirmButtonClicked)
5416         ] autorelease]];
5417     else
5418         [[self navigationItem] setRightBarButtonItem:nil];
5419 }
5420 #endif
5421
5422 - (void) cancelButtonClicked {
5423     [delegate_ cancelAndClear:YES];
5424     [self dismissModalViewControllerAnimated:YES];
5425 }
5426
5427 #if !AlwaysReload
5428 - (void) confirmButtonClicked {
5429     if (essential_ != nil)
5430         [essential_ show];
5431     else
5432         [self complete];
5433 }
5434 #endif
5435
5436 @end
5437 /* }}} */
5438
5439 /* Progress Data {{{ */
5440 @interface CydiaProgressData : NSObject {
5441     _transient id delegate_;
5442
5443     bool running_;
5444     float percent_;
5445
5446     float current_;
5447     float total_;
5448     float speed_;
5449
5450     _H<NSMutableArray> events_;
5451     _H<NSString> title_;
5452
5453     _H<NSString> status_;
5454     _H<NSString> finish_;
5455 }
5456
5457 @end
5458
5459 @implementation CydiaProgressData
5460
5461 + (NSArray *) _attributeKeys {
5462     return [NSArray arrayWithObjects:
5463         @"current",
5464         @"events",
5465         @"finish",
5466         @"percent",
5467         @"running",
5468         @"speed",
5469         @"title",
5470         @"total",
5471     nil];
5472 }
5473
5474 - (NSArray *) attributeKeys {
5475     return [[self class] _attributeKeys];
5476 }
5477
5478 + (BOOL) isKeyExcludedFromWebScript:(const char *)name {
5479     return ![[self _attributeKeys] containsObject:[NSString stringWithUTF8String:name]] && [super isKeyExcludedFromWebScript:name];
5480 }
5481
5482 - (id) init {
5483     if ((self = [super init]) != nil) {
5484         events_ = [NSMutableArray arrayWithCapacity:32];
5485     } return self;
5486 }
5487
5488 - (id) delegate {
5489     return delegate_;
5490 }
5491
5492 - (void) setDelegate:(id)delegate {
5493     delegate_ = delegate;
5494 }
5495
5496 - (void) setPercent:(float)value {
5497     percent_ = value;
5498 }
5499
5500 - (NSNumber *) percent {
5501     return [NSNumber numberWithFloat:percent_];
5502 }
5503
5504 - (void) setCurrent:(float)value {
5505     current_ = value;
5506 }
5507
5508 - (NSNumber *) current {
5509     return [NSNumber numberWithFloat:current_];
5510 }
5511
5512 - (void) setTotal:(float)value {
5513     total_ = value;
5514 }
5515
5516 - (NSNumber *) total {
5517     return [NSNumber numberWithFloat:total_];
5518 }
5519
5520 - (void) setSpeed:(float)value {
5521     speed_ = value;
5522 }
5523
5524 - (NSNumber *) speed {
5525     return [NSNumber numberWithFloat:speed_];
5526 }
5527
5528 - (NSArray *) events {
5529     return events_;
5530 }
5531
5532 - (void) removeAllEvents {
5533     [events_ removeAllObjects];
5534 }
5535
5536 - (void) addEvent:(CydiaProgressEvent *)event {
5537     [events_ addObject:event];
5538 }
5539
5540 - (void) setTitle:(NSString *)text {
5541     title_ = text;
5542 }
5543
5544 - (NSString *) title {
5545     return title_;
5546 }
5547
5548 - (void) setFinish:(NSString *)text {
5549     finish_ = text;
5550 }
5551
5552 - (NSString *) finish {
5553     return (id) finish_ ?: [NSNull null];
5554 }
5555
5556 - (void) setRunning:(bool)running {
5557     running_ = running;
5558 }
5559
5560 - (NSNumber *) running {
5561     return running_ ? (NSNumber *) kCFBooleanTrue : (NSNumber *) kCFBooleanFalse;
5562 }
5563
5564 @end
5565 /* }}} */
5566 /* Progress Controller {{{ */
5567 @interface ProgressController : CydiaWebViewController <
5568     ProgressDelegate
5569 > {
5570     _transient Database *database_;
5571     _H<CydiaProgressData, 1> progress_;
5572     unsigned cancel_;
5573 }
5574
5575 - (id) initWithDatabase:(Database *)database delegate:(id)delegate;
5576
5577 - (void) invoke:(NSInvocation *)invocation withTitle:(NSString *)title;
5578
5579 - (void) setTitle:(NSString *)title;
5580 - (void) setCancellable:(bool)cancellable;
5581
5582 @end
5583
5584 @implementation ProgressController
5585
5586 - (void) dealloc {
5587     [database_ setProgressDelegate:nil];
5588     [super dealloc];
5589 }
5590
5591 - (UIBarButtonItem *) leftButton {
5592     return cancel_ == 1 ? [[[UIBarButtonItem alloc]
5593         initWithTitle:UCLocalize("CANCEL")
5594         style:UIBarButtonItemStylePlain
5595         target:self
5596         action:@selector(cancel)
5597     ] autorelease] : nil;
5598 }
5599
5600 - (void) updateCancel {
5601     [super applyLeftButton];
5602 }
5603
5604 - (id) initWithDatabase:(Database *)database delegate:(id)delegate {
5605     if ((self = [super init]) != nil) {
5606         database_ = database;
5607         delegate_ = delegate;
5608
5609         [database_ setProgressDelegate:self];
5610
5611         progress_ = [[[CydiaProgressData alloc] init] autorelease];
5612         [progress_ setDelegate:self];
5613
5614         [self setURL:[NSURL URLWithString:[NSString stringWithFormat:@"%@/#!/progress/", UI_]]];
5615
5616         [scroller_ setBackgroundColor:[UIColor blackColor]];
5617
5618         [[self navigationItem] setHidesBackButton:YES];
5619
5620         [self updateCancel];
5621     } return self;
5622 }
5623
5624 - (void) webView:(WebView *)view didClearWindowObject:(WebScriptObject *)window forFrame:(WebFrame *)frame {
5625     [super webView:view didClearWindowObject:window forFrame:frame];
5626     [window setValue:progress_ forKey:@"cydiaProgress"];
5627 }
5628
5629 - (void) updateProgress {
5630     [self dispatchEvent:@"CydiaProgressUpdate"];
5631 }
5632
5633 - (void) viewWillAppear:(BOOL)animated {
5634     [[[self navigationController] navigationBar] setBarStyle:UIBarStyleBlack];
5635     [super viewWillAppear:animated];
5636 }
5637
5638 - (void) close {
5639     UpdateExternalStatus(0);
5640
5641     if (Finish_ > 1)
5642         [delegate_ saveState];
5643
5644     switch (Finish_) {
5645         case 0:
5646             [delegate_ returnToCydia];
5647         break;
5648
5649         case 1:
5650             [delegate_ terminateWithSuccess];
5651             /*if ([delegate_ respondsToSelector:@selector(suspendWithAnimation:)])
5652                 [delegate_ suspendWithAnimation:YES];
5653             else
5654                 [delegate_ suspend];*/
5655         break;
5656
5657         case 2:
5658             _trace();
5659             goto reload;
5660
5661         case 3:
5662             _trace();
5663             goto reload;
5664
5665         reload: {
5666             UIProgressHUD *hud([delegate_ addProgressHUD]);
5667             [hud setText:UCLocalize("LOADING")];
5668             [delegate_ performSelector:@selector(reloadSpringBoard) withObject:nil afterDelay:0.5];
5669             return;
5670         }
5671
5672         case 4:
5673             _trace();
5674             if (void (*SBReboot)(mach_port_t) = reinterpret_cast<void (*)(mach_port_t)>(dlsym(RTLD_DEFAULT, "SBReboot")))
5675                 SBReboot(SBSSpringBoardServerPort());
5676             else
5677                 reboot2(RB_AUTOBOOT);
5678         break;
5679     }
5680
5681     [super close];
5682 }
5683
5684 - (void) setTitle:(NSString *)title {
5685     [progress_ setTitle:title];
5686     [self updateProgress];
5687 }
5688
5689 - (UIBarButtonItem *) rightButton {
5690     return [[progress_ running] boolValue] ? [super rightButton] : [[[UIBarButtonItem alloc]
5691         initWithTitle:UCLocalize("CLOSE")
5692         style:UIBarButtonItemStylePlain
5693         target:self
5694         action:@selector(close)
5695     ] autorelease];
5696 }
5697
5698 - (void) invoke:(NSInvocation *)invocation withTitle:(NSString *)title {
5699     UpdateExternalStatus(1);
5700
5701     [progress_ setRunning:true];
5702     [self setTitle:title];
5703     // implicit updateProgress
5704
5705     SHA1SumValue notifyconf; {
5706         FileFd file;
5707         if (!file.Open(NotifyConfig_, FileFd::ReadOnly))
5708             _error->Discard();
5709         else {
5710             MMap mmap(file, MMap::ReadOnly);
5711             SHA1Summation sha1;
5712             sha1.Add(reinterpret_cast<uint8_t *>(mmap.Data()), mmap.Size());
5713             notifyconf = sha1.Result();
5714         }
5715     }
5716
5717     SHA1SumValue springlist; {
5718         FileFd file;
5719         if (!file.Open(SpringBoard_, FileFd::ReadOnly))
5720             _error->Discard();
5721         else {
5722             MMap mmap(file, MMap::ReadOnly);
5723             SHA1Summation sha1;
5724             sha1.Add(reinterpret_cast<uint8_t *>(mmap.Data()), mmap.Size());
5725             springlist = sha1.Result();
5726         }
5727     }
5728
5729     if (invocation != nil) {
5730         [invocation yieldToSelector:@selector(invoke)];
5731         [self setTitle:@"COMPLETE"];
5732     }
5733
5734     if (Finish_ < 4) {
5735         FileFd file;
5736         if (!file.Open(NotifyConfig_, FileFd::ReadOnly))
5737             _error->Discard();
5738         else {
5739             MMap mmap(file, MMap::ReadOnly);
5740             SHA1Summation sha1;
5741             sha1.Add(reinterpret_cast<uint8_t *>(mmap.Data()), mmap.Size());
5742             if (!(notifyconf == sha1.Result()))
5743                 Finish_ = 4;
5744         }
5745     }
5746
5747     if (Finish_ < 3) {
5748         FileFd file;
5749         if (!file.Open(SpringBoard_, FileFd::ReadOnly))
5750             _error->Discard();
5751         else {
5752             MMap mmap(file, MMap::ReadOnly);
5753             SHA1Summation sha1;
5754             sha1.Add(reinterpret_cast<uint8_t *>(mmap.Data()), mmap.Size());
5755             if (!(springlist == sha1.Result()))
5756                 Finish_ = 3;
5757         }
5758     }
5759
5760     if (Finish_ < 2) {
5761         if (RestartSubstrate_)
5762             Finish_ = 2;
5763     }
5764
5765     RestartSubstrate_ = false;
5766
5767     switch (Finish_) {
5768         case 0: [progress_ setFinish:UCLocalize("RETURN_TO_CYDIA")]; break; /* XXX: Maybe UCLocalize("DONE")? */
5769         case 1: [progress_ setFinish:UCLocalize("CLOSE_CYDIA")]; break;
5770         case 2: [progress_ setFinish:UCLocalize("RESTART_SPRINGBOARD")]; break;
5771         case 3: [progress_ setFinish:UCLocalize("RELOAD_SPRINGBOARD")]; break;
5772         case 4: [progress_ setFinish:UCLocalize("REBOOT_DEVICE")]; break;
5773     }
5774
5775     UpdateExternalStatus(Finish_ == 0 ? 0 : 2);
5776
5777     [progress_ setRunning:false];
5778     [self updateProgress];
5779
5780     [self applyRightButton];
5781 }
5782
5783 - (void) addProgressEvent:(CydiaProgressEvent *)event {
5784     [progress_ addEvent:event];
5785     [self updateProgress];
5786 }
5787
5788 - (bool) isProgressCancelled {
5789     return cancel_ == 2;
5790 }
5791
5792 - (void) cancel {
5793     cancel_ = 2;
5794     [self updateCancel];
5795 }
5796
5797 - (void) setCancellable:(bool)cancellable {
5798     unsigned cancel(cancel_);
5799
5800     if (!cancellable)
5801         cancel_ = 0;
5802     else if (cancel_ == 0)
5803         cancel_ = 1;
5804
5805     if (cancel != cancel_)
5806         [self updateCancel];
5807 }
5808
5809 - (void) setProgressCancellable:(NSNumber *)cancellable {
5810     [self setCancellable:[cancellable boolValue]];
5811 }
5812
5813 - (void) setProgressPercent:(NSNumber *)percent {
5814     [progress_ setPercent:[percent floatValue]];
5815     [self updateProgress];
5816 }
5817
5818 - (void) setProgressStatus:(NSDictionary *)status {
5819     if (status == nil) {
5820         [progress_ setCurrent:0];
5821         [progress_ setTotal:0];
5822         [progress_ setSpeed:0];
5823     } else {
5824         [progress_ setPercent:[[status objectForKey:@"Percent"] floatValue]];
5825
5826         [progress_ setCurrent:[[status objectForKey:@"Current"] floatValue]];
5827         [progress_ setTotal:[[status objectForKey:@"Total"] floatValue]];
5828         [progress_ setSpeed:[[status objectForKey:@"Speed"] floatValue]];
5829     }
5830
5831     [self updateProgress];
5832 }
5833
5834 @end
5835 /* }}} */
5836
5837 /* Package Cell {{{ */
5838 @interface PackageCell : CyteTableViewCell <
5839     CyteTableViewCellDelegate
5840 > {
5841     _H<UIImage> icon_;
5842     _H<NSString> name_;
5843     _H<NSString> description_;
5844     bool commercial_;
5845     _H<NSString> source_;
5846     _H<UIImage> badge_;
5847     _H<UIImage> placard_;
5848     bool summarized_;
5849 }
5850
5851 - (PackageCell *) init;
5852 - (void) setPackage:(Package *)package asSummary:(bool)summary;
5853
5854 - (void) drawContentRect:(CGRect)rect;
5855
5856 @end
5857
5858 @implementation PackageCell
5859
5860 - (PackageCell *) init {
5861     CGRect frame(CGRectMake(0, 0, 320, 74));
5862     if ((self = [super initWithFrame:frame reuseIdentifier:@"Package"]) != nil) {
5863         UIView *content([self contentView]);
5864         CGRect bounds([content bounds]);
5865
5866         content_ = [[[CyteTableViewCellContentView alloc] initWithFrame:bounds] autorelease];
5867         [content_ setAutoresizingMask:UIViewAutoresizingFlexibleBoth];
5868         [content addSubview:content_];
5869
5870         [content_ setDelegate:self];
5871         [content_ setOpaque:YES];
5872     } return self;
5873 }
5874
5875 - (NSString *) accessibilityLabel {
5876     return name_;
5877 }
5878
5879 - (void) setPackage:(Package *)package asSummary:(bool)summary {
5880     summarized_ = summary;
5881
5882     icon_ = nil;
5883     name_ = nil;
5884     description_ = nil;
5885     source_ = nil;
5886     badge_ = nil;
5887     placard_ = nil;
5888
5889     if (package == nil)
5890         [content_ setBackgroundColor:[UIColor whiteColor]];
5891     else {
5892         [package parse];
5893
5894         Source *source = [package source];
5895
5896         icon_ = [package icon];
5897
5898         if (NSString *name = [package name])
5899             name_ = [NSString stringWithString:name];
5900
5901         if (NSString *description = [package shortDescription])
5902             description_ = [NSString stringWithString:description];
5903
5904         commercial_ = [package isCommercial];
5905
5906         NSString *label = nil;
5907         bool trusted = false;
5908
5909         if (source != nil) {
5910             label = [source label];
5911             trusted = [source trusted];
5912         } else if ([[package id] isEqualToString:@"firmware"])
5913             label = UCLocalize("APPLE");
5914         else
5915             label = [NSString stringWithFormat:UCLocalize("SLASH_DELIMITED"), UCLocalize("UNKNOWN"), UCLocalize("LOCAL")];
5916
5917         NSString *from(label);
5918
5919         NSString *section = [package simpleSection];
5920         if (section != nil && ![section isEqualToString:label]) {
5921             section = [[NSBundle mainBundle] localizedStringForKey:section value:nil table:@"Sections"];
5922             from = [NSString stringWithFormat:UCLocalize("PARENTHETICAL"), from, section];
5923         }
5924
5925         source_ = [NSString stringWithFormat:UCLocalize("FROM"), from];
5926
5927         if (NSString *purpose = [package primaryPurpose])
5928             badge_ = [UIImage imageAtPath:[NSString stringWithFormat:@"%@/Purposes/%@.png", App_, purpose]];
5929
5930         UIColor *color;
5931         NSString *placard;
5932
5933         if (NSString *mode = [package mode]) {
5934             if ([mode isEqualToString:@"REMOVE"] || [mode isEqualToString:@"PURGE"]) {
5935                 color = RemovingColor_;
5936                 placard = @"removing";
5937             } else {
5938                 color = InstallingColor_;
5939                 placard = @"installing";
5940             }
5941         } else {
5942             color = [UIColor whiteColor];
5943
5944             if ([package installed] != nil)
5945                 placard = @"installed";
5946             else
5947                 placard = nil;
5948         }
5949
5950         [content_ setBackgroundColor:color];
5951
5952         if (placard != nil)
5953             placard_ = [UIImage imageAtPath:[NSString stringWithFormat:@"%@/%@.png", App_, placard]];
5954     }
5955
5956     [self setNeedsDisplay];
5957     [content_ setNeedsDisplay];
5958 }
5959
5960 - (void) drawSummaryContentRect:(CGRect)rect {
5961     bool highlighted(highlighted_);
5962     float width([self bounds].size.width);
5963
5964     if (icon_ != nil) {
5965         CGRect rect;
5966         rect.size = [(UIImage *) icon_ size];
5967
5968         while (rect.size.width > 16 || rect.size.height > 16) {
5969             rect.size.width /= 2;
5970             rect.size.height /= 2;
5971         }
5972
5973         rect.origin.x = 19 - rect.size.width / 2;
5974         rect.origin.y = 19 - rect.size.height / 2;
5975
5976         [icon_ drawInRect:Retina(rect)];
5977     }
5978
5979     if (badge_ != nil) {
5980         CGRect rect;
5981         rect.size = [(UIImage *) badge_ size];
5982
5983         rect.size.width /= 4;
5984         rect.size.height /= 4;
5985
5986         rect.origin.x = 25 - rect.size.width / 2;
5987         rect.origin.y = 25 - rect.size.height / 2;
5988
5989         [badge_ drawInRect:Retina(rect)];
5990     }
5991
5992     if (highlighted && kCFCoreFoundationVersionNumber < 800)
5993         UISetColor(White_);
5994
5995     if (!highlighted)
5996         UISetColor(commercial_ ? Purple_ : Black_);
5997     [name_ drawAtPoint:CGPointMake(36, 8) forWidth:(width - (placard_ == nil ? 68 : 94)) withFont:Font18Bold_ lineBreakMode:NSLineBreakByTruncatingTail];
5998
5999     if (placard_ != nil)
6000         [placard_ drawAtPoint:CGPointMake(width - 52, 11)];
6001 }
6002
6003 - (void) drawNormalContentRect:(CGRect)rect {
6004     bool highlighted(highlighted_);
6005     float width([self bounds].size.width);
6006
6007     if (icon_ != nil) {
6008         CGRect rect;
6009         rect.size = [(UIImage *) icon_ size];
6010
6011         while (rect.size.width > 32 || rect.size.height > 32) {
6012             rect.size.width /= 2;
6013             rect.size.height /= 2;
6014         }
6015
6016         rect.origin.x = 25 - rect.size.width / 2;
6017         rect.origin.y = 25 - rect.size.height / 2;
6018
6019         [icon_ drawInRect:Retina(rect)];
6020     }
6021
6022     if (badge_ != nil) {
6023         CGRect rect;
6024         rect.size = [(UIImage *) badge_ size];
6025
6026         rect.size.width /= 2;
6027         rect.size.height /= 2;
6028
6029         rect.origin.x = 36 - rect.size.width / 2;
6030         rect.origin.y = 36 - rect.size.height / 2;
6031
6032         [badge_ drawInRect:Retina(rect)];
6033     }
6034
6035     if (highlighted && kCFCoreFoundationVersionNumber < 800)
6036         UISetColor(White_);
6037
6038     if (!highlighted)
6039         UISetColor(commercial_ ? Purple_ : Black_);
6040     [name_ drawAtPoint:CGPointMake(48, 8) forWidth:(width - (placard_ == nil ? 80 : 106)) withFont:Font18Bold_ lineBreakMode:NSLineBreakByTruncatingTail];
6041     [source_ drawAtPoint:CGPointMake(58, 29) forWidth:(width - 95) withFont:Font12_ lineBreakMode:NSLineBreakByTruncatingTail];
6042
6043     if (!highlighted)
6044         UISetColor(commercial_ ? Purplish_ : Gray_);
6045     [description_ drawAtPoint:CGPointMake(12, 46) forWidth:(width - 46) withFont:Font14_ lineBreakMode:NSLineBreakByTruncatingTail];
6046
6047     if (placard_ != nil)
6048         [placard_ drawAtPoint:CGPointMake(width - 52, 9)];
6049 }
6050
6051 - (void) drawContentRect:(CGRect)rect {
6052     if (summarized_)
6053         [self drawSummaryContentRect:rect];
6054     else
6055         [self drawNormalContentRect:rect];
6056 }
6057
6058 @end
6059 /* }}} */
6060 /* Section Cell {{{ */
6061 @interface SectionCell : CyteTableViewCell <
6062     CyteTableViewCellDelegate
6063 > {
6064     _H<NSString> basic_;
6065     _H<NSString> section_;
6066     _H<NSString> name_;
6067     _H<NSString> count_;
6068     _H<UIImage> icon_;
6069     _H<UISwitch> switch_;
6070     BOOL editing_;
6071 }
6072
6073 - (void) setSection:(Section *)section editing:(BOOL)editing;
6074
6075 @end
6076
6077 @implementation SectionCell
6078
6079 - (id) initWithFrame:(CGRect)frame reuseIdentifier:(NSString *)reuseIdentifier {
6080     if ((self = [super initWithFrame:frame reuseIdentifier:reuseIdentifier]) != nil) {
6081         icon_ = [UIImage imageNamed:@"folder.png"];
6082         // XXX: this initial frame is wrong, but is fixed later
6083         switch_ = [[[UISwitch alloc] initWithFrame:CGRectMake(218, 9, 60, 25)] autorelease];
6084         [switch_ addTarget:self action:@selector(onSwitch:) forEvents:UIControlEventValueChanged];
6085
6086         UIView *content([self contentView]);
6087         CGRect bounds([content bounds]);
6088
6089         content_ = [[[CyteTableViewCellContentView alloc] initWithFrame:bounds] autorelease];
6090         [content_ setAutoresizingMask:UIViewAutoresizingFlexibleBoth];
6091         [content addSubview:content_];
6092         [content_ setBackgroundColor:[UIColor whiteColor]];
6093
6094         [content_ setDelegate:self];
6095     } return self;
6096 }
6097
6098 - (void) onSwitch:(id)sender {
6099     NSMutableDictionary *metadata([Sections_ objectForKey:basic_]);
6100     if (metadata == nil) {
6101         metadata = [NSMutableDictionary dictionaryWithCapacity:2];
6102         [Sections_ setObject:metadata forKey:basic_];
6103     }
6104
6105     [metadata setObject:[NSNumber numberWithBool:([switch_ isOn] == NO)] forKey:@"Hidden"];
6106 }
6107
6108 - (void) setSection:(Section *)section editing:(BOOL)editing {
6109     if (editing != editing_) {
6110         if (editing_)
6111             [switch_ removeFromSuperview];
6112         else
6113             [self addSubview:switch_];
6114         editing_ = editing;
6115     }
6116
6117     basic_ = nil;
6118     section_ = nil;
6119     name_ = nil;
6120     count_ = nil;
6121
6122     if (section == nil) {
6123         name_ = UCLocalize("ALL_PACKAGES");
6124         count_ = nil;
6125     } else {
6126         basic_ = [section name];
6127         section_ = [section localized];
6128
6129         name_  = section_ == nil || [section_ length] == 0 ? UCLocalize("NO_SECTION") : (NSString *) section_;
6130         count_ = [NSString stringWithFormat:@"%zd", [section count]];
6131
6132         if (editing_)
6133             [switch_ setOn:(isSectionVisible(basic_) ? 1 : 0) animated:NO];
6134     }
6135
6136     [self setAccessoryType:editing ? UITableViewCellAccessoryNone : UITableViewCellAccessoryDisclosureIndicator];
6137     [self setSelectionStyle:editing ? UITableViewCellSelectionStyleNone : UITableViewCellSelectionStyleBlue];
6138
6139     [content_ setNeedsDisplay];
6140 }
6141
6142 - (void) setFrame:(CGRect)frame {
6143     [super setFrame:frame];
6144
6145     CGRect rect([switch_ frame]);
6146     [switch_ setFrame:CGRectMake(frame.size.width - rect.size.width - 9, 9, rect.size.width, rect.size.height)];
6147 }
6148
6149 - (NSString *) accessibilityLabel {
6150     return name_;
6151 }
6152
6153 - (void) drawContentRect:(CGRect)rect {
6154     bool highlighted(highlighted_ && !editing_);
6155
6156     [icon_ drawInRect:CGRectMake(7, 7, 32, 32)];
6157
6158     if (highlighted && kCFCoreFoundationVersionNumber < 800)
6159         UISetColor(White_);
6160
6161     float width(rect.size.width);
6162     if (editing_)
6163         width -= 9 + [switch_ frame].size.width;
6164
6165     if (!highlighted)
6166         UISetColor(Black_);
6167     [name_ drawAtPoint:CGPointMake(48, 12) forWidth:(width - 58) withFont:Font18_ lineBreakMode:NSLineBreakByTruncatingTail];
6168
6169     CGSize size = [count_ sizeWithFont:Font14_];
6170
6171     UISetColor(Folder_);
6172     if (count_ != nil)
6173         [count_ drawAtPoint:CGPointMake(Retina(10 + (30 - size.width) / 2), 18) withFont:Font12Bold_];
6174 }
6175
6176 @end
6177 /* }}} */
6178
6179 /* File Table {{{ */
6180 @interface FileTable : CyteViewController <
6181     UITableViewDataSource,
6182     UITableViewDelegate
6183 > {
6184     _transient Database *database_;
6185     _H<Package> package_;
6186     _H<NSString> name_;
6187     _H<NSMutableArray> files_;
6188     _H<UITableView, 2> list_;
6189 }
6190
6191 - (id) initWithDatabase:(Database *)database;
6192 - (void) setPackage:(Package *)package;
6193
6194 @end
6195
6196 @implementation FileTable
6197
6198 - (NSInteger) tableView:(UITableView *)tableView numberOfRowsInSection:(NSInteger)section {
6199     return files_ == nil ? 0 : [files_ count];
6200 }
6201
6202 /*- (CGFloat) tableView:(UITableView *)tableView heightForRowAtIndexPath:(NSIndexPath *)indexPath {
6203     return 24.0f;
6204 }*/
6205
6206 - (UITableViewCell *) tableView:(UITableView *)tableView cellForRowAtIndexPath:(NSIndexPath *)indexPath {
6207     static NSString *reuseIdentifier = @"Cell";
6208
6209     UITableViewCell *cell = [tableView dequeueReusableCellWithIdentifier:reuseIdentifier];
6210     if (cell == nil) {
6211         cell = [[[UITableViewCell alloc] initWithFrame:CGRectZero reuseIdentifier:reuseIdentifier] autorelease];
6212         [cell setFont:[UIFont systemFontOfSize:16]];
6213     }
6214     [cell setText:[files_ objectAtIndex:indexPath.row]];
6215     [cell setSelectionStyle:UITableViewCellSelectionStyleNone];
6216
6217     return cell;
6218 }
6219
6220 - (NSURL *) navigationURL {
6221     return [NSURL URLWithString:[NSString stringWithFormat:@"cydia://package/%@/files", [package_ id]]];
6222 }
6223
6224 - (void) loadView {
6225     list_ = [[[UITableView alloc] initWithFrame:[[UIScreen mainScreen] applicationFrame]] autorelease];
6226     [list_ setAutoresizingMask:UIViewAutoresizingFlexibleBoth];
6227     [list_ setRowHeight:24.0f];
6228     [(UITableView *) list_ setDataSource:self];
6229     [list_ setDelegate:self];
6230     [self setView:list_];
6231 }
6232
6233 - (void) viewDidLoad {
6234     [super viewDidLoad];
6235
6236     [[self navigationItem] setTitle:UCLocalize("INSTALLED_FILES")];
6237 }
6238
6239 - (void) releaseSubviews {
6240     list_ = nil;
6241
6242     package_ = nil;
6243     files_ = nil;
6244
6245     [super releaseSubviews];
6246 }
6247
6248 - (id) initWithDatabase:(Database *)database {
6249     if ((self = [super init]) != nil) {
6250         database_ = database;
6251     } return self;
6252 }
6253
6254 - (void) setPackage:(Package *)package {
6255     package_ = nil;
6256     name_ = nil;
6257
6258     files_ = [NSMutableArray arrayWithCapacity:32];
6259
6260     if (package != nil) {
6261         package_ = package;
6262         name_ = [package id];
6263
6264         if (NSArray *files = [package files])
6265             [files_ addObjectsFromArray:files];
6266
6267         if ([files_ count] != 0) {
6268             if ([[files_ objectAtIndex:0] isEqualToString:@"/."])
6269                 [files_ removeObjectAtIndex:0];
6270             [files_ sortUsingSelector:@selector(compareByPath:)];
6271
6272             NSMutableArray *stack = [NSMutableArray arrayWithCapacity:8];
6273             [stack addObject:@"/"];
6274
6275             for (int i(0), e([files_ count]); i != e; ++i) {
6276                 NSString *file = [files_ objectAtIndex:i];
6277                 while (![file hasPrefix:[stack lastObject]])
6278                     [stack removeLastObject];
6279                 NSString *directory = [stack lastObject];
6280                 [stack addObject:[file stringByAppendingString:@"/"]];
6281                 [files_ replaceObjectAtIndex:i withObject:[NSString stringWithFormat:@"%*s%@",
6282                     int(([stack count] - 2) * 3), "",
6283                     [file substringFromIndex:[directory length]]
6284                 ]];
6285             }
6286         }
6287     }
6288
6289     [list_ reloadData];
6290 }
6291
6292 - (void) reloadData {
6293     [super reloadData];
6294
6295     [self setPackage:[database_ packageWithName:name_]];
6296 }
6297
6298 @end
6299 /* }}} */
6300 /* Package Controller {{{ */
6301 @interface CYPackageController : CydiaWebViewController <
6302     UIActionSheetDelegate
6303 > {
6304     _transient Database *database_;
6305     _H<Package> package_;
6306     _H<NSString> name_;
6307     bool commercial_;
6308     std::vector<std::pair<_H<NSString>, _H<NSString>>> buttons_;
6309     _H<UIActionSheet> sheet_;
6310     _H<UIBarButtonItem> button_;
6311     _H<NSArray> versions_;
6312 }
6313
6314 - (id) initWithDatabase:(Database *)database forPackage:(NSString *)name withReferrer:(NSString *)referrer;
6315
6316 @end
6317
6318 @implementation CYPackageController
6319
6320 - (NSURL *) navigationURL {
6321     return [NSURL URLWithString:[NSString stringWithFormat:@"cydia://package/%@", (id) name_]];
6322 }
6323
6324 - (void) _clickButtonWithPackage:(Package *)package {
6325     [delegate_ installPackage:package];
6326 }
6327
6328 - (void) _clickButtonWithName:(NSString *)name {
6329     if ([name isEqualToString:@"CLEAR"])
6330         return [delegate_ clearPackage:package_];
6331     else if ([name isEqualToString:@"REMOVE"])
6332         return [delegate_ removePackage:package_];
6333     else if ([name isEqualToString:@"DOWNGRADE"]) {
6334         sheet_ = [[[UIActionSheet alloc]
6335             initWithTitle:nil
6336             delegate:self
6337             cancelButtonTitle:nil
6338             destructiveButtonTitle:nil
6339             otherButtonTitles:nil
6340         ] autorelease];
6341
6342         for (Package *version in (id) versions_)
6343             [sheet_ addButtonWithTitle:[version latest]];
6344         [sheet_ setContext:@"version"];
6345
6346         [delegate_ showActionSheet:sheet_ fromItem:[[self navigationItem] rightBarButtonItem]];
6347         return;
6348     }
6349
6350     else if ([name isEqualToString:@"INSTALL"]);
6351     else if ([name isEqualToString:@"REINSTALL"]);
6352     else if ([name isEqualToString:@"UPGRADE"]);
6353     else _assert(false);
6354
6355     [delegate_ installPackage:package_];
6356 }
6357
6358 - (void) actionSheet:(UIActionSheet *)sheet clickedButtonAtIndex:(NSInteger)button {
6359     NSString *context([sheet context]);
6360     if (sheet_ == sheet)
6361         sheet_ = nil;
6362
6363     if ([context isEqualToString:@"modify"]) {
6364         if (button != [sheet cancelButtonIndex]) {
6365             if (IsWildcat_)
6366                 [self performSelector:@selector(_clickButtonWithName:) withObject:buttons_[button].first afterDelay:0];
6367             else
6368                 [self _clickButtonWithName:buttons_[button].first];
6369         }
6370
6371         [sheet dismissWithClickedButtonIndex:button animated:YES];
6372     } else if ([context isEqualToString:@"version"]) {
6373         if (button != [sheet cancelButtonIndex]) {
6374             Package *version([versions_ objectAtIndex:button]);
6375             if (IsWildcat_)
6376                 [self performSelector:@selector(_clickButtonWithPackage:) withObject:version afterDelay:0];
6377             else
6378                 [self _clickButtonWithPackage:version];
6379         }
6380
6381         [sheet dismissWithClickedButtonIndex:button animated:YES];
6382     }
6383 }
6384
6385 - (bool) _allowJavaScriptPanel {
6386     return commercial_;
6387 }
6388
6389 #if !AlwaysReload
6390 - (void) _customButtonClicked {
6391     size_t count(buttons_.size());
6392     if (count == 0)
6393         return;
6394
6395     if (count == 1)
6396         [self _clickButtonWithName:buttons_[0].first];
6397     else {
6398         NSMutableArray *buttons = [NSMutableArray arrayWithCapacity:count];
6399         for (const auto &button : buttons_)
6400             [buttons addObject:button.second];
6401
6402         sheet_ = [[[UIActionSheet alloc]
6403             initWithTitle:nil
6404             delegate:self
6405             cancelButtonTitle:nil
6406             destructiveButtonTitle:nil
6407             otherButtonTitles:nil
6408         ] autorelease];
6409
6410         for (NSString *button in buttons)
6411             [sheet_ addButtonWithTitle:button];
6412         [sheet_ setContext:@"modify"];
6413
6414         [delegate_ showActionSheet:sheet_ fromItem:[[self navigationItem] rightBarButtonItem]];
6415     }
6416 }
6417
6418 - (void) reloadButtonClicked {
6419     if (commercial_ && function_ == nil && [package_ uninstalled])
6420         return;
6421     [self customButtonClicked];
6422 }
6423
6424 - (void) applyLoadingTitle {
6425     // Don't show "Loading" as the title. Ever.
6426 }
6427
6428 - (UIBarButtonItem *) rightButton {
6429     return button_;
6430 }
6431 #endif
6432
6433 - (void) setPageColor:(UIColor *)color {
6434     return [super setPageColor:nil];
6435 }
6436
6437 - (id) initWithDatabase:(Database *)database forPackage:(NSString *)name withReferrer:(NSString *)referrer {
6438     if ((self = [super init]) != nil) {
6439         database_ = database;
6440         name_ = name == nil ? @"" : [NSString stringWithString:name];
6441         [self setURL:[NSURL URLWithString:[NSString stringWithFormat:@"%@/#!/package/%@", UI_, (id) name_]] withReferrer:referrer];
6442     } return self;
6443 }
6444
6445 - (void) reloadData {
6446     [super reloadData];
6447
6448     [sheet_ dismissWithClickedButtonIndex:[sheet_ cancelButtonIndex] animated:YES];
6449     sheet_ = nil;
6450
6451     package_ = [database_ packageWithName:name_];
6452     versions_ = [package_ downgrades];
6453
6454     buttons_.clear();
6455
6456     if (package_ != nil) {
6457         [(Package *) package_ parse];
6458
6459         commercial_ = [package_ isCommercial];
6460
6461         if ([package_ mode] != nil)
6462             buttons_.push_back(std::make_pair(@"CLEAR", UCLocalize("CLEAR")));
6463         if ([package_ source] == nil);
6464         else if ([package_ upgradableAndEssential:NO])
6465             buttons_.push_back(std::make_pair(@"UPGRADE", UCLocalize("UPGRADE")));
6466         else if ([package_ uninstalled])
6467             buttons_.push_back(std::make_pair(@"INSTALL", UCLocalize("INSTALL")));
6468         else
6469             buttons_.push_back(std::make_pair(@"REINSTALL", UCLocalize("REINSTALL")));
6470         if (![package_ uninstalled])
6471             buttons_.push_back(std::make_pair(@"REMOVE", UCLocalize("REMOVE")));
6472         if ([versions_ count] != 0)
6473             buttons_.push_back(std::make_pair(@"DOWNGRADE", UCLocalize("DOWNGRADE")));
6474     }
6475
6476     NSString *title;
6477     switch (buttons_.size()) {
6478         case 0: title = nil; break;
6479         case 1: title = buttons_[0].second; break;
6480         default: title = UCLocalize("MODIFY"); break;
6481     }
6482
6483     button_ = [[[UIBarButtonItem alloc]
6484         initWithTitle:title
6485         style:UIBarButtonItemStylePlain
6486         target:self
6487         action:@selector(customButtonClicked)
6488     ] autorelease];
6489 }
6490
6491 - (bool) isLoading {
6492     return commercial_ ? [super isLoading] : false;
6493 }
6494
6495 @end
6496 /* }}} */
6497
6498 /* Package List Controller {{{ */
6499 @interface PackageListController : CyteViewController <
6500     UITableViewDataSource,
6501     UITableViewDelegate
6502 > {
6503     _transient Database *database_;
6504     unsigned era_;
6505     _H<NSArray> packages_;
6506     _H<NSArray> sections_;
6507     _H<UITableView, 2> list_;
6508
6509     _H<NSArray> thumbs_;
6510     std::vector<NSInteger> offset_;
6511
6512     _H<NSString> title_;
6513     unsigned reloading_;
6514 }
6515
6516 - (id) initWithDatabase:(Database *)database title:(NSString *)title;
6517 - (void) setDelegate:(id)delegate;
6518 - (void) resetCursor;
6519 - (void) clearData;
6520
6521 - (NSArray *) sectionsForPackages:(NSMutableArray *)packages;
6522
6523 @end
6524
6525 @implementation PackageListController
6526
6527 - (NSURL *) referrerURL {
6528     return [self navigationURL];
6529 }
6530
6531 - (bool) isSummarized {
6532     return false;
6533 }
6534
6535 - (bool) showsSections {
6536     return true;
6537 }
6538
6539 - (void) deselectWithAnimation:(BOOL)animated {
6540     [list_ deselectRowAtIndexPath:[list_ indexPathForSelectedRow] animated:animated];
6541 }
6542
6543 - (void) resizeForKeyboardBounds:(CGRect)bounds duration:(NSTimeInterval)duration curve:(UIViewAnimationCurve)curve {
6544     CGRect base = [[self view] bounds];
6545     base.size.height -= bounds.size.height;
6546     base.origin = [list_ frame].origin;
6547
6548     [UIView beginAnimations:nil context:NULL];
6549     [UIView setAnimationBeginsFromCurrentState:YES];
6550     [UIView setAnimationCurve:curve];
6551     [UIView setAnimationDuration:duration];
6552     [list_ setFrame:base];
6553     [UIView commitAnimations];
6554 }
6555
6556 - (void) resizeForKeyboardBounds:(CGRect)bounds duration:(NSTimeInterval)duration {
6557     [self resizeForKeyboardBounds:bounds duration:duration curve:UIViewAnimationCurveLinear];
6558 }
6559
6560 - (void) resizeForKeyboardBounds:(CGRect)bounds {
6561     [self resizeForKeyboardBounds:bounds duration:0];
6562 }
6563
6564 - (void) getKeyboardCurve:(UIViewAnimationCurve *)curve duration:(NSTimeInterval *)duration forNotification:(NSNotification *)notification {
6565     if (&UIKeyboardAnimationCurveUserInfoKey == NULL)
6566         *curve = UIViewAnimationCurveEaseInOut;
6567     else
6568         [[[notification userInfo] objectForKey:UIKeyboardAnimationCurveUserInfoKey] getValue:curve];
6569
6570     if (&UIKeyboardAnimationDurationUserInfoKey == NULL)
6571         *duration = 0.3;
6572     else
6573         [[[notification userInfo] objectForKey:UIKeyboardAnimationDurationUserInfoKey] getValue:duration];
6574 }
6575
6576 - (void) keyboardWillShow:(NSNotification *)notification {
6577     CGRect bounds;
6578     CGPoint center;
6579     [[[notification userInfo] objectForKey:UIKeyboardBoundsUserInfoKey] getValue:&bounds];
6580     [[[notification userInfo] objectForKey:UIKeyboardCenterEndUserInfoKey] getValue:&center];
6581
6582     NSTimeInterval duration;
6583     UIViewAnimationCurve curve;
6584     [self getKeyboardCurve:&curve duration:&duration forNotification:notification];
6585
6586     CGRect kbframe = CGRectMake(Retina(center.x - bounds.size.width / 2), Retina(center.y - bounds.size.height / 2), bounds.size.width, bounds.size.height);
6587     UIViewController *base = self;
6588     while ([base parentOrPresentingViewController] != nil)
6589         base = [base parentOrPresentingViewController];
6590     CGRect viewframe = [[base view] convertRect:[list_ frame] fromView:[list_ superview]];
6591     CGRect intersection = CGRectIntersection(viewframe, kbframe);
6592
6593     if (kCFCoreFoundationVersionNumber < kCFCoreFoundationVersionNumber_iPhoneOS_3_0) // XXX: _UIApplicationLinkedOnOrAfter(4)
6594         intersection.size.height += CYStatusBarHeight();
6595
6596     [self resizeForKeyboardBounds:intersection duration:duration curve:curve];
6597 }
6598
6599 - (void) keyboardWillHide:(NSNotification *)notification {
6600     NSTimeInterval duration;
6601     UIViewAnimationCurve curve;
6602     [self getKeyboardCurve:&curve duration:&duration forNotification:notification];
6603
6604     [self resizeForKeyboardBounds:CGRectZero duration:duration curve:curve];
6605 }
6606
6607 - (void) viewWillAppear:(BOOL)animated {
6608     [super viewWillAppear:animated];
6609
6610     [self resizeForKeyboardBounds:CGRectZero];
6611     [[NSNotificationCenter defaultCenter] addObserver:self selector:@selector(keyboardWillShow:) name:UIKeyboardWillShowNotification object:nil];
6612     [[NSNotificationCenter defaultCenter] addObserver:self selector:@selector(keyboardWillHide:) name:UIKeyboardWillHideNotification object:nil];
6613 }
6614
6615 - (void) viewWillDisappear:(BOOL)animated {
6616     [super viewWillDisappear:animated];
6617
6618     [self resizeForKeyboardBounds:CGRectZero];
6619     [[NSNotificationCenter defaultCenter] removeObserver:self name:UIKeyboardWillShowNotification object:nil];
6620     [[NSNotificationCenter defaultCenter] removeObserver:self name:UIKeyboardWillHideNotification object:nil];
6621 }
6622
6623 - (void) viewDidAppear:(BOOL)animated {
6624     [super viewDidAppear:animated];
6625     [self deselectWithAnimation:animated];
6626 }
6627
6628 - (void) didSelectPackage:(Package *)package {
6629     CYPackageController *view([[[CYPackageController alloc] initWithDatabase:database_ forPackage:[package id] withReferrer:[[self referrerURL] absoluteString]] autorelease]);
6630     [view setDelegate:delegate_];
6631     [[self navigationController] pushViewController:view animated:YES];
6632 }
6633
6634 - (NSInteger) numberOfSectionsInTableView:(UITableView *)list {
6635     NSInteger count([sections_ count]);
6636     return count == 0 ? 1 : count;
6637 }
6638
6639 - (NSString *) tableView:(UITableView *)list titleForHeaderInSection:(NSInteger)section {
6640     if ([sections_ count] == 0 || [[sections_ objectAtIndex:section] count] == 0)
6641         return nil;
6642     return [[sections_ objectAtIndex:section] name];
6643 }
6644
6645 - (NSInteger) tableView:(UITableView *)list numberOfRowsInSection:(NSInteger)section {
6646     if ([sections_ count] == 0)
6647         return 0;
6648     return [[sections_ objectAtIndex:section] count];
6649 }
6650
6651 - (Package *) packageAtIndexPath:(NSIndexPath *)path {
6652 @synchronized (database_) {
6653     if ([database_ era] != era_)
6654         return nil;
6655
6656     Section *section([sections_ objectAtIndex:[path section]]);
6657     NSInteger row([path row]);
6658     Package *package([packages_ objectAtIndex:([section row] + row)]);
6659     return [[package retain] autorelease];
6660 } }
6661
6662 - (UITableViewCell *) tableView:(UITableView *)table cellForRowAtIndexPath:(NSIndexPath *)path {
6663     PackageCell *cell((PackageCell *) [table dequeueReusableCellWithIdentifier:@"Package"]);
6664     if (cell == nil)
6665         cell = [[[PackageCell alloc] init] autorelease];
6666
6667     Package *package([database_ packageWithName:[[self packageAtIndexPath:path] id]]);
6668     [cell setPackage:package asSummary:[self isSummarized]];
6669     return cell;
6670 }
6671
6672 - (void) tableView:(UITableView *)table didSelectRowAtIndexPath:(NSIndexPath *)path {
6673     Package *package([self packageAtIndexPath:path]);
6674     package = [database_ packageWithName:[package id]];
6675     [self didSelectPackage:package];
6676 }
6677
6678 - (NSArray *) sectionIndexTitlesForTableView:(UITableView *)tableView {
6679     return thumbs_;
6680 }
6681
6682 - (NSInteger) tableView:(UITableView *)tableView sectionForSectionIndexTitle:(NSString *)title atIndex:(NSInteger)index {
6683     return offset_[index];
6684 }
6685
6686 - (void) updateHeight {
6687     [list_ setRowHeight:([self isSummarized] ? 38 : 73)];
6688 }
6689
6690 - (id) initWithDatabase:(Database *)database title:(NSString *)title {
6691     if ((self = [super init]) != nil) {
6692         database_ = database;
6693         title_ = [title copy];
6694         [[self navigationItem] setTitle:title_];
6695     } return self;
6696 }
6697
6698 - (void) loadView {
6699     UIView *view([[[UIView alloc] initWithFrame:[[UIScreen mainScreen] applicationFrame]] autorelease]);
6700     [view setAutoresizingMask:(UIViewAutoresizingFlexibleWidth | UIViewAutoresizingFlexibleHeight)];
6701     [self setView:view];
6702
6703     list_ = [[[UITableView alloc] initWithFrame:[[self view] bounds] style:UITableViewStylePlain] autorelease];
6704     [list_ setAutoresizingMask:UIViewAutoresizingFlexibleBoth];
6705     [view addSubview:list_];
6706
6707     // XXX: is 20 the most optimal number here?
6708     [list_ setSectionIndexMinimumDisplayRowCount:20];
6709
6710     [(UITableView *) list_ setDataSource:self];
6711     [list_ setDelegate:self];
6712
6713     [self updateHeight];
6714 }
6715
6716 - (void) releaseSubviews {
6717     list_ = nil;
6718
6719     packages_ = nil;
6720     sections_ = nil;
6721
6722     thumbs_ = nil;
6723     offset_.clear();
6724
6725     [super releaseSubviews];
6726 }
6727
6728 - (void) setDelegate:(id)delegate {
6729     delegate_ = delegate;
6730 }
6731
6732 - (bool) shouldYield {
6733     return false;
6734 }
6735
6736 - (bool) shouldBlock {
6737     return false;
6738 }
6739
6740 - (NSMutableArray *) _reloadPackages {
6741 @synchronized (database_) {
6742     era_ = [database_ era];
6743     NSArray *packages([database_ packages]);
6744
6745     return [NSMutableArray arrayWithArray:packages];
6746 } }
6747
6748 - (void) _reloadData {
6749     if (reloading_ != 0) {
6750         reloading_ = 2;
6751         return;
6752     }
6753
6754     NSMutableArray *packages;
6755
6756   reload:
6757     if ([self shouldYield]) {
6758         do {
6759             UIProgressHUD *hud;
6760
6761             if (![self shouldBlock])
6762                 hud = nil;
6763             else {
6764                 hud = [delegate_ addProgressHUD];
6765                 [hud setText:UCLocalize("LOADING")];
6766             }
6767
6768             reloading_ = 1;
6769             packages = [self yieldToSelector:@selector(_reloadPackages)];
6770
6771             if (hud != nil)
6772                 [delegate_ removeProgressHUD:hud];
6773         } while (reloading_ == 2);
6774     } else {
6775         packages = [self _reloadPackages];
6776     }
6777
6778 @synchronized (database_) {
6779     if (era_ != [database_ era])
6780         goto reload;
6781     reloading_ = 0;
6782
6783     thumbs_ = nil;
6784     offset_.clear();
6785
6786     packages_ = packages;
6787
6788     if ([self showsSections])
6789         sections_ = [self sectionsForPackages:packages];
6790     else {
6791         Section *section([[[Section alloc] initWithName:nil row:0 localize:NO] autorelease]);
6792         [section setCount:[packages_ count]];
6793         sections_ = [NSArray arrayWithObject:section];
6794     }
6795
6796     [self updateHeight];
6797
6798     _profile(PackageTable$reloadData$List)
6799         [(UITableView *) list_ setDataSource:self];
6800         [list_ reloadData];
6801     _end
6802 }
6803
6804     PrintTimes();
6805 }
6806
6807 - (NSArray *) sectionsForPackages:(NSMutableArray *)packages {
6808     Section *prefix([[[Section alloc] initWithName:nil row:0 localize:NO] autorelease]);
6809     size_t end([packages count]);
6810
6811     NSMutableArray *sections([NSMutableArray arrayWithCapacity:16]);
6812     Section *section(prefix);
6813
6814     thumbs_ = CollationThumbs_;
6815     offset_ = CollationOffset_;
6816
6817     size_t offset(0);
6818     size_t offsets([CollationStarts_ count]);
6819
6820     NSString *start([CollationStarts_ objectAtIndex:offset]);
6821     size_t length([start length]);
6822
6823     for (size_t index(0); index != end; ++index) {
6824         if (start != nil) {
6825             Package *package([packages objectAtIndex:index]);
6826             NSString *name(PackageName(package, @selector(cyname)));
6827
6828             //while ([start compare:name options:NSNumericSearch range:NSMakeRange(0, length) locale:CollationLocale_] != NSOrderedDescending) {
6829             while (StringNameCompare(start, name, length) != kCFCompareGreaterThan) {
6830                 NSString *title([CollationTitles_ objectAtIndex:offset]);
6831                 section = [[[Section alloc] initWithName:title row:index localize:NO] autorelease];
6832                 [sections addObject:section];
6833
6834                 start = ++offset == offsets ? nil : [CollationStarts_ objectAtIndex:offset];
6835                 if (start == nil)
6836                     break;
6837                 length = [start length];
6838             }
6839         }
6840
6841         [section addToCount];
6842     }
6843
6844     for (; offset != offsets; ++offset) {
6845         NSString *title([CollationTitles_ objectAtIndex:offset]);
6846         Section *section([[[Section alloc] initWithName:title row:end localize:NO] autorelease]);
6847         [sections addObject:section];
6848     }
6849
6850     if ([prefix count] != 0) {
6851         Section *suffix([sections lastObject]);
6852         [prefix setName:[suffix name]];
6853         [suffix setName:nil];
6854         [sections insertObject:prefix atIndex:(offsets - 1)];
6855     }
6856
6857     return sections;
6858 }
6859
6860 - (void) reloadData {
6861     [super reloadData];
6862
6863     if ([self shouldYield])
6864         [self performSelector:@selector(_reloadData) withObject:nil afterDelay:0];
6865     else
6866         [self _reloadData];
6867 }
6868
6869 - (void) resetCursor {
6870     [list_ scrollRectToVisible:CGRectMake(0, 0, 1, 1) animated:NO];
6871 }
6872
6873 - (void) clearData {
6874     [self updateHeight];
6875
6876     [list_ setDataSource:nil];
6877     [list_ reloadData];
6878
6879     [self resetCursor];
6880 }
6881
6882 @end
6883 /* }}} */
6884 /* Filtered Package List Controller {{{ */
6885 typedef Function<bool, Package *> PackageFilter;
6886 typedef Function<void, NSMutableArray *> PackageSorter;
6887 @interface FilteredPackageListController : PackageListController {
6888     PackageFilter filter_;
6889     PackageSorter sorter_;
6890 }
6891
6892 - (id) initWithDatabase:(Database *)database title:(NSString *)title filter:(PackageFilter)filter;
6893
6894 - (void) setFilter:(PackageFilter)filter;
6895 - (void) setSorter:(PackageSorter)sorter;
6896
6897 @end
6898
6899 @implementation FilteredPackageListController
6900
6901 - (void) setFilter:(PackageFilter)filter {
6902 @synchronized (self) {
6903     filter_ = filter;
6904 } }
6905
6906 - (void) setSorter:(PackageSorter)sorter {
6907 @synchronized (self) {
6908     sorter_ = sorter;
6909 } }
6910
6911 - (NSMutableArray *) _reloadPackages {
6912 @synchronized (database_) {
6913     era_ = [database_ era];
6914
6915     NSArray *packages([database_ packages]);
6916     NSMutableArray *filtered([NSMutableArray arrayWithCapacity:[packages count]]);
6917
6918     PackageFilter filter;
6919     PackageSorter sorter;
6920
6921     @synchronized (self) {
6922         filter = filter_;
6923         sorter = sorter_;
6924     }
6925
6926     _profile(PackageTable$reloadData$Filter)
6927         for (Package *package in packages)
6928             if (filter(package))
6929                 [filtered addObject:package];
6930     _end
6931
6932     if (sorter)
6933         sorter(filtered);
6934     return filtered;
6935 } }
6936
6937 - (id) initWithDatabase:(Database *)database title:(NSString *)title filter:(PackageFilter)filter {
6938     if ((self = [super initWithDatabase:database title:title]) != nil) {
6939         [self setFilter:filter];
6940     } return self;
6941 }
6942
6943 @end
6944 /* }}} */
6945
6946 /* Home Controller {{{ */
6947 @interface HomeController : CydiaWebViewController {
6948     CFRunLoopRef runloop_;
6949     SCNetworkReachabilityRef reachability_;
6950 }
6951
6952 @end
6953
6954 @implementation HomeController
6955
6956 static void HomeControllerReachabilityCallback(SCNetworkReachabilityRef reachability, SCNetworkReachabilityFlags flags, void *info) {
6957     [(HomeController *) info dispatchEvent:@"CydiaReachabilityCallback"];
6958 }
6959
6960 - (id) init {
6961     if ((self = [super init]) != nil) {
6962         [self setURL:[NSURL URLWithString:[NSString stringWithFormat:@"%@/#!/home/", UI_]]];
6963         [self reloadData];
6964
6965         reachability_ = SCNetworkReachabilityCreateWithName(kCFAllocatorDefault, "cydia.saurik.com");
6966         if (reachability_ != NULL) {
6967             SCNetworkReachabilityContext context = {0, self, NULL, NULL, NULL};
6968             SCNetworkReachabilitySetCallback(reachability_, HomeControllerReachabilityCallback, &context);
6969
6970             CFRunLoopRef runloop(CFRunLoopGetCurrent());
6971             if (SCNetworkReachabilityScheduleWithRunLoop(reachability_, runloop, kCFRunLoopDefaultMode))
6972                 runloop_ = runloop;
6973         }
6974     } return self;
6975 }
6976
6977 - (void) dealloc {
6978     if (reachability_ != NULL && runloop_ != NULL)
6979         SCNetworkReachabilityUnscheduleFromRunLoop(reachability_, runloop_, kCFRunLoopDefaultMode);
6980     [super dealloc];
6981 }
6982
6983 - (NSURL *) navigationURL {
6984     return [NSURL URLWithString:@"cydia://home"];
6985 }
6986
6987 - (void) aboutButtonClicked {
6988     UIAlertView *alert([[[UIAlertView alloc] init] autorelease]);
6989
6990     [alert setTitle:UCLocalize("ABOUT_CYDIA")];
6991     [alert addButtonWithTitle:UCLocalize("CLOSE")];
6992     [alert setCancelButtonIndex:0];
6993
6994     [alert setMessage:
6995         @"Copyright \u00a9 2008-2015\n"
6996         "SaurikIT, LLC\n"
6997         "\n"
6998         "Jay Freeman (saurik)\n"
6999         "saurik@saurik.com\n"
7000         "http://www.saurik.com/"
7001     ];
7002
7003     [alert show];
7004 }
7005
7006 - (UIBarButtonItem *) leftButton {
7007     return [[[UIBarButtonItem alloc]
7008         initWithTitle:UCLocalize("ABOUT")
7009         style:UIBarButtonItemStylePlain
7010         target:self
7011         action:@selector(aboutButtonClicked)
7012     ] autorelease];
7013 }
7014
7015 @end
7016 /* }}} */
7017
7018 /* Cydia Navigation Controller Interface {{{ */
7019 @interface UINavigationController (Cydia)
7020
7021 - (NSArray *) navigationURLCollection;
7022 - (void) unloadData;
7023
7024 @end
7025 /* }}} */
7026
7027 /* Cydia Tab Bar Controller {{{ */
7028 @interface CydiaTabBarController : CyteTabBarController <
7029     UITabBarControllerDelegate,
7030     FetchDelegate
7031 > {
7032     _transient Database *database_;
7033
7034     _H<UIActivityIndicatorView> indicator_;
7035
7036     bool updating_;
7037     // XXX: ok, "updatedelegate_"?...
7038     _transient NSObject<CydiaDelegate> *updatedelegate_;
7039 }
7040
7041 - (NSArray *) navigationURLCollection;
7042 - (void) beginUpdate;
7043 - (BOOL) updating;
7044
7045 @end
7046
7047 @implementation CydiaTabBarController
7048
7049 - (NSArray *) navigationURLCollection {
7050     NSMutableArray *items([NSMutableArray array]);
7051
7052     // XXX: Should this deal with transient view controllers?
7053     for (id navigation in [self viewControllers]) {
7054         NSArray *stack = [navigation performSelector:@selector(navigationURLCollection)];
7055         if (stack != nil)
7056             [items addObject:stack];
7057     }
7058
7059     return items;
7060 }
7061
7062 - (id) initWithDatabase:(Database *)database {
7063     if ((self = [super init]) != nil) {
7064         database_ = database;
7065         [self setDelegate:self];
7066
7067         indicator_ = [[[UIActivityIndicatorView alloc] initWithActivityIndicatorStyle:UIActivityIndicatorViewStyleWhiteTiny] autorelease];
7068         [indicator_ setOrigin:CGPointMake(kCFCoreFoundationVersionNumber >= 800 ? 2 : 4, 2)];
7069
7070         [[self view] setAutoresizingMask:UIViewAutoresizingFlexibleBoth];
7071     } return self;
7072 }
7073
7074 - (void) beginUpdate {
7075     if (updating_)
7076         return;
7077
7078     UIViewController *controller([[self viewControllers] objectAtIndex:1]);
7079     UITabBarItem *item([controller tabBarItem]);
7080
7081     [item setBadgeValue:@""];
7082     UIView *badge(MSHookIvar<UIView *>([item view], "_badge"));
7083
7084     [indicator_ startAnimating];
7085     [badge addSubview:indicator_];
7086
7087     [updatedelegate_ retainNetworkActivityIndicator];
7088     updating_ = true;
7089
7090     [NSThread
7091         detachNewThreadSelector:@selector(performUpdate)
7092         toTarget:self
7093         withObject:nil
7094     ];
7095 }
7096
7097 - (void) performUpdate {
7098     NSAutoreleasePool *pool([[NSAutoreleasePool alloc] init]);
7099
7100     SourceStatus status(self, database_);
7101     [database_ updateWithStatus:status];
7102
7103     [self
7104         performSelectorOnMainThread:@selector(completeUpdate)
7105         withObject:nil
7106         waitUntilDone:NO
7107     ];
7108
7109     [pool release];
7110 }
7111
7112 - (void) stopUpdateWithSelector:(SEL)selector {
7113     updating_ = false;
7114     [updatedelegate_ releaseNetworkActivityIndicator];
7115
7116     UIViewController *controller([[self viewControllers] objectAtIndex:1]);
7117     [[controller tabBarItem] setBadgeValue:nil];
7118
7119     [indicator_ removeFromSuperview];
7120     [indicator_ stopAnimating];
7121
7122     [updatedelegate_ performSelector:selector withObject:nil afterDelay:0];
7123 }
7124
7125 - (void) completeUpdate {
7126     if (!updating_)
7127         return;
7128     [self stopUpdateWithSelector:@selector(reloadData)];
7129 }
7130
7131 - (void) cancelUpdate {
7132     [self stopUpdateWithSelector:@selector(updateDataAndLoad)];
7133 }
7134
7135 - (void) cancelPressed {
7136     [self cancelUpdate];
7137 }
7138
7139 - (BOOL) updating {
7140     return updating_;
7141 }
7142
7143 - (bool) isSourceCancelled {
7144     return !updating_;
7145 }
7146
7147 - (void) startSourceFetch:(NSString *)uri {
7148 }
7149
7150 - (void) stopSourceFetch:(NSString *)uri {
7151 }
7152
7153 - (void) setUpdateDelegate:(id)delegate {
7154     updatedelegate_ = delegate;
7155 }
7156
7157 @end
7158 /* }}} */
7159
7160 /* Cydia Navigation Controller Implementation {{{ */
7161 @implementation UINavigationController (Cydia)
7162
7163 - (NSArray *) navigationURLCollection {
7164     NSMutableArray *stack([NSMutableArray array]);
7165
7166     for (CyteViewController *controller in [self viewControllers]) {
7167         NSString *url = [[controller navigationURL] absoluteString];
7168         if (url != nil)
7169             [stack addObject:url];
7170     }
7171
7172     return stack;
7173 }
7174
7175 - (void) reloadData {
7176     [super reloadData];
7177
7178     UIViewController *visible([self visibleViewController]);
7179     if (visible != nil)
7180         [visible reloadData];
7181
7182     // on the iPad, this view controller is ALSO visible. :(
7183     if (IsWildcat_)
7184         if (UIViewController *modal = [self modalViewController])
7185             if ([modal modalPresentationStyle] == UIModalPresentationFormSheet)
7186                 if (UIViewController *top = [self topViewController])
7187                     if (top != visible)
7188                         [top reloadData];
7189 }
7190
7191 - (void) unloadData {
7192     for (CyteViewController *page in [self viewControllers])
7193         [page unloadData];
7194
7195     [super unloadData];
7196 }
7197
7198 @end
7199 /* }}} */
7200
7201 /* Cydia:// Protocol {{{ */
7202 @interface CydiaURLProtocol : NSURLProtocol {
7203 }
7204
7205 @end
7206
7207 @implementation CydiaURLProtocol
7208
7209 + (BOOL) canInitWithRequest:(NSURLRequest *)request {
7210     NSURL *url([request URL]);
7211     if (url == nil)
7212         return NO;
7213
7214     NSString *scheme([[url scheme] lowercaseString]);
7215     if (scheme != nil && [scheme isEqualToString:@"cydia"])
7216         return YES;
7217     if ([[url absoluteString] hasPrefix:@"about:cydia-"])
7218         return YES;
7219
7220     return NO;
7221 }
7222
7223 + (NSURLRequest *) canonicalRequestForRequest:(NSURLRequest *)request {
7224     return request;
7225 }
7226
7227 - (void) _returnPNGWithImage:(UIImage *)icon forRequest:(NSURLRequest *)request {
7228     id<NSURLProtocolClient> client([self client]);
7229     if (icon == nil)
7230         [client URLProtocol:self didFailWithError:[NSError errorWithDomain:NSURLErrorDomain code:NSURLErrorFileDoesNotExist userInfo:nil]];
7231     else {
7232         NSData *data(UIImagePNGRepresentation(icon));
7233
7234         NSURLResponse *response([[[NSURLResponse alloc] initWithURL:[request URL] MIMEType:@"image/png" expectedContentLength:-1 textEncodingName:nil] autorelease]);
7235         [client URLProtocol:self didReceiveResponse:response cacheStoragePolicy:NSURLCacheStorageNotAllowed];
7236         [client URLProtocol:self didLoadData:data];
7237         [client URLProtocolDidFinishLoading:self];
7238     }
7239 }
7240
7241 - (void) startLoading {
7242     id<NSURLProtocolClient> client([self client]);
7243     NSURLRequest *request([self request]);
7244
7245     NSURL *url([request URL]);
7246     NSString *href([url absoluteString]);
7247     NSString *scheme([[url scheme] lowercaseString]);
7248
7249     NSString *path;
7250
7251     if ([scheme isEqualToString:@"cydia"])
7252         path = [href substringFromIndex:8];
7253     else if ([scheme isEqualToString:@"about"])
7254         path = [href substringFromIndex:12];
7255     else _assert(false);
7256
7257     NSRange slash([path rangeOfString:@"/"]);
7258
7259     NSString *command;
7260     if (slash.location == NSNotFound) {
7261         command = path;
7262         path = nil;
7263     } else {
7264         command = [path substringToIndex:slash.location];
7265         path = [path substringFromIndex:(slash.location + 1)];
7266     }
7267
7268     Database *database([Database sharedInstance]);
7269
7270     if (false);
7271     else if ([command isEqualToString:@"application-icon"]) {
7272         if (path == nil)
7273             goto fail;
7274         path = [path stringByReplacingPercentEscapesUsingEncoding:NSUTF8StringEncoding];
7275
7276         UIImage *icon(nil);
7277
7278         if (icon == nil && $SBSCopyIconImagePNGDataForDisplayIdentifier != NULL) {
7279             NSData *data([$SBSCopyIconImagePNGDataForDisplayIdentifier(path) autorelease]);
7280             icon = [UIImage imageWithData:data];
7281         }
7282
7283         if (icon == nil)
7284             if (NSString *file = SBSCopyIconImagePathForDisplayIdentifier(path))
7285                 icon = [UIImage imageAtPath:file];
7286
7287         if (icon == nil)
7288             icon = [UIImage imageNamed:@"unknown.png"];
7289
7290         [self _returnPNGWithImage:icon forRequest:request];
7291     } else if ([command isEqualToString:@"package-icon"]) {
7292         if (path == nil)
7293             goto fail;
7294         path = [path stringByReplacingPercentEscapesUsingEncoding:NSUTF8StringEncoding];
7295         Package *package([database packageWithName:path]);
7296         if (package == nil)
7297             goto fail;
7298         [package parse];
7299         UIImage *icon([package icon]);
7300         [self _returnPNGWithImage:icon forRequest:request];
7301     } else if ([command isEqualToString:@"uikit-image"]) {
7302         if (path == nil)
7303             goto fail;
7304         path = [path stringByReplacingPercentEscapesUsingEncoding:NSUTF8StringEncoding];
7305         UIImage *icon(_UIImageWithName(path));
7306         [self _returnPNGWithImage:icon forRequest:request];
7307     } else if ([command isEqualToString:@"section-icon"]) {
7308         if (path == nil)
7309             goto fail;
7310         path = [path stringByReplacingPercentEscapesUsingEncoding:NSUTF8StringEncoding];
7311         UIImage *icon([UIImage imageAtPath:[NSString stringWithFormat:@"%@/Sections/%@.png", App_, [path stringByReplacingOccurrencesOfString:@" " withString:@"_"]]]);
7312         if (icon == nil)
7313             icon = [UIImage imageNamed:@"unknown.png"];
7314         [self _returnPNGWithImage:icon forRequest:request];
7315     } else fail: {
7316         [client URLProtocol:self didFailWithError:[NSError errorWithDomain:NSURLErrorDomain code:NSURLErrorResourceUnavailable userInfo:nil]];
7317     }
7318 }
7319
7320 - (void) stopLoading {
7321 }
7322
7323 @end
7324 /* }}} */
7325
7326 /* Section Controller {{{ */
7327 @interface SectionController : FilteredPackageListController {
7328     _H<NSString> key_;
7329     _H<NSString> section_;
7330 }
7331
7332 - (id) initWithDatabase:(Database *)database source:(Source *)source section:(NSString *)section;
7333
7334 @end
7335
7336 @implementation SectionController
7337
7338 - (NSURL *) referrerURL {
7339     NSString *name(section_);
7340     name = name ?: @"*";
7341     NSString *key(key_);
7342     key = key ?: @"*";
7343     return [NSURL URLWithString:[NSString stringWithFormat:@"%@/#!/sections/%@/%@", UI_, [key stringByAddingPercentEscapesIncludingReserved], [name stringByAddingPercentEscapesIncludingReserved]]];
7344 }
7345
7346 - (NSURL *) navigationURL {
7347     NSString *name(section_);
7348     name = name ?: @"*";
7349     NSString *key(key_);
7350     key = key ?: @"*";
7351     return [NSURL URLWithString:[NSString stringWithFormat:@"cydia://sections/%@/%@", [key stringByAddingPercentEscapesIncludingReserved], [name stringByAddingPercentEscapesIncludingReserved]]];
7352 }
7353
7354 - (id) initWithDatabase:(Database *)database source:(Source *)source section:(NSString *)section {
7355     NSString *title;
7356     if (section == nil)
7357         title = UCLocalize("ALL_PACKAGES");
7358     else if (![section isEqual:@""])
7359         title = [[NSBundle mainBundle] localizedStringForKey:Simplify(section) value:nil table:@"Sections"];
7360     else
7361         title = UCLocalize("NO_SECTION");
7362
7363     if ((self = [super initWithDatabase:database title:title]) != nil) {
7364         key_ = [source key];
7365         section_ = section;
7366     } return self;
7367 }
7368
7369 - (void) reloadData {
7370     Source *source([database_ sourceWithKey:key_]);
7371     _H<NSString> name(section_);
7372
7373     [self setFilter:[=](Package *package) {
7374         NSString *section([package section]);
7375
7376         return (
7377             name == nil ||
7378             section == nil && [name length] == 0 ||
7379             [name isEqualToString:section]
7380         ) && (
7381             source == nil ||
7382             [package source] == source
7383         ) && [package visible];
7384     }];
7385
7386     [super reloadData];
7387 }
7388
7389 @end
7390 /* }}} */
7391 /* Sections Controller {{{ */
7392 @interface SectionsController : CyteViewController <
7393     UITableViewDataSource,
7394     UITableViewDelegate
7395 > {
7396     _transient Database *database_;
7397     _H<NSString> key_;
7398     _H<NSMutableArray> sections_;
7399     _H<NSMutableArray> filtered_;
7400     _H<UITableView, 2> list_;
7401 }
7402
7403 - (id) initWithDatabase:(Database *)database source:(Source *)source;
7404 - (void) editButtonClicked;
7405
7406 @end
7407
7408 @implementation SectionsController
7409
7410 - (NSURL *) navigationURL {
7411     return [NSURL URLWithString:[NSString stringWithFormat:@"cydia://sources/%@", [key_ stringByAddingPercentEscapesIncludingReserved]]];
7412 }
7413
7414 - (Source *) source {
7415     if (key_ == nil)
7416         return nil;
7417     return [database_ sourceWithKey:key_];
7418 }
7419
7420 - (void) updateNavigationItem {
7421     [[self navigationItem] setTitle:[self isEditing] ? UCLocalize("SECTION_VISIBILITY") : UCLocalize("SECTIONS")];
7422     if ([sections_ count] == 0) {
7423         [[self navigationItem] setRightBarButtonItem:nil];
7424     } else {
7425         [[self navigationItem] setRightBarButtonItem:[[UIBarButtonItem alloc]
7426             initWithBarButtonSystemItem:([self isEditing] ? UIBarButtonSystemItemDone : UIBarButtonSystemItemEdit)
7427             target:self
7428             action:@selector(editButtonClicked)
7429         ] animated:([[self navigationItem] rightBarButtonItem] != nil)];
7430     }
7431 }
7432
7433 - (void) setEditing:(BOOL)editing animated:(BOOL)animated {
7434     [super setEditing:editing animated:animated];
7435
7436     if (editing)
7437         [list_ reloadData];
7438     else
7439         [delegate_ updateData];
7440
7441     [self updateNavigationItem];
7442 }
7443
7444 - (void) viewDidAppear:(BOOL)animated {
7445     [super viewDidAppear:animated];
7446     [list_ deselectRowAtIndexPath:[list_ indexPathForSelectedRow] animated:animated];
7447 }
7448
7449 - (void) viewWillDisappear:(BOOL)animated {
7450     [super viewWillDisappear:animated];
7451     [self setEditing:NO];
7452 }
7453
7454 - (Section *) sectionAtIndexPath:(NSIndexPath *)indexPath {
7455     Section *section = nil;
7456     int index = [indexPath row];
7457     if (![self isEditing]) {
7458         index -= 1;
7459         if (index >= 0)
7460             section = [filtered_ objectAtIndex:index];
7461     } else {
7462         section = [sections_ objectAtIndex:index];
7463     }
7464     return section;
7465 }
7466
7467 - (NSInteger) tableView:(UITableView *)tableView numberOfRowsInSection:(NSInteger)section {
7468     if ([self isEditing])
7469         return [sections_ count];
7470     else
7471         return [filtered_ count] + 1;
7472 }
7473
7474 /*- (CGFloat) tableView:(UITableView *)tableView heightForRowAtIndexPath:(NSIndexPath *)indexPath {
7475     return 45.0f;
7476 }*/
7477
7478 - (UITableViewCell *) tableView:(UITableView *)tableView cellForRowAtIndexPath:(NSIndexPath *)indexPath {
7479     static NSString *reuseIdentifier = @"SectionCell";
7480
7481     SectionCell *cell = (SectionCell *)[tableView dequeueReusableCellWithIdentifier:reuseIdentifier];
7482     if (cell == nil)
7483         cell = [[[SectionCell alloc] initWithFrame:CGRectZero reuseIdentifier:reuseIdentifier] autorelease];
7484
7485     [cell setSection:[self sectionAtIndexPath:indexPath] editing:[self isEditing]];
7486
7487     return cell;
7488 }
7489
7490 - (void) tableView:(UITableView *)tableView didSelectRowAtIndexPath:(NSIndexPath *)indexPath {
7491     if ([self isEditing])
7492         return;
7493
7494     Section *section = [self sectionAtIndexPath:indexPath];
7495
7496     SectionController *controller = [[[SectionController alloc]
7497         initWithDatabase:database_
7498         source:[self source]
7499         section:[section name]
7500     ] autorelease];
7501     [controller setDelegate:delegate_];
7502
7503     [[self navigationController] pushViewController:controller animated:YES];
7504 }
7505
7506 - (void) loadView {
7507     list_ = [[[UITableView alloc] initWithFrame:[[UIScreen mainScreen] applicationFrame]] autorelease];
7508     [list_ setAutoresizingMask:UIViewAutoresizingFlexibleBoth];
7509     [list_ setRowHeight:46];
7510     [(UITableView *) list_ setDataSource:self];
7511     [list_ setDelegate:self];
7512     [self setView:list_];
7513 }
7514
7515 - (void) viewDidLoad {
7516     [super viewDidLoad];
7517
7518     [[self navigationItem] setTitle:UCLocalize("SECTIONS")];
7519 }
7520
7521 - (void) releaseSubviews {
7522     list_ = nil;
7523
7524     sections_ = nil;
7525     filtered_ = nil;
7526
7527     [super releaseSubviews];
7528 }
7529
7530 - (id) initWithDatabase:(Database *)database source:(Source *)source {
7531     if ((self = [super init]) != nil) {
7532         database_ = database;
7533         key_ = [source key];
7534     } return self;
7535 }
7536
7537 - (void) reloadData {
7538     [super reloadData];
7539
7540     NSArray *packages = [database_ packages];
7541
7542     sections_ = [NSMutableArray arrayWithCapacity:16];
7543     filtered_ = [NSMutableArray arrayWithCapacity:16];
7544
7545     NSMutableDictionary *sections([NSMutableDictionary dictionaryWithCapacity:32]);
7546
7547     Source *source([self source]);
7548
7549     _trace();
7550     for (Package *package in packages) {
7551         if (source != nil && [package source] != source)
7552             continue;
7553
7554         NSString *name([package section]);
7555         NSString *key(name == nil ? @"" : name);
7556
7557         Section *section;
7558
7559         _profile(SectionsView$reloadData$Section)
7560             section = [sections objectForKey:key];
7561             if (section == nil) {
7562                 _profile(SectionsView$reloadData$Section$Allocate)
7563                     section = [[[Section alloc] initWithName:key localize:YES] autorelease];
7564                     [sections setObject:section forKey:key];
7565                 _end
7566             }
7567         _end
7568
7569         [section addToCount];
7570
7571         _profile(SectionsView$reloadData$Filter)
7572             if (![package visible])
7573                 continue;
7574         _end
7575
7576         [section addToRow];
7577     }
7578     _trace();
7579
7580     [sections_ addObjectsFromArray:[sections allValues]];
7581
7582     [sections_ sortUsingSelector:@selector(compareByLocalized:)];
7583
7584     for (Section *section in (id) sections_) {
7585         size_t count([section row]);
7586         if (count == 0)
7587             continue;
7588
7589         section = [[[Section alloc] initWithName:[section name] localized:[section localized]] autorelease];
7590         [section setCount:count];
7591         [filtered_ addObject:section];
7592     }
7593
7594     [self updateNavigationItem];
7595     [list_ reloadData];
7596     _trace();
7597 }
7598
7599 - (void) editButtonClicked {
7600     [self setEditing:![self isEditing] animated:YES];
7601 }
7602
7603 @end
7604 /* }}} */
7605
7606 /* Changes Controller {{{ */
7607 @interface ChangesController : FilteredPackageListController {
7608     unsigned upgrades_;
7609 }
7610
7611 - (id) initWithDatabase:(Database *)database;
7612
7613 @end
7614
7615 @implementation ChangesController
7616
7617 - (NSURL *) referrerURL {
7618     return [NSURL URLWithString:[NSString stringWithFormat:@"%@/#!/changes/", UI_]];
7619 }
7620
7621 - (NSURL *) navigationURL {
7622     return [NSURL URLWithString:@"cydia://changes"];
7623 }
7624
7625 - (Package *) packageAtIndexPath:(NSIndexPath *)path {
7626 @synchronized (database_) {
7627     if ([database_ era] != era_)
7628         return nil;
7629
7630     NSUInteger sectionIndex([path section]);
7631     if (sectionIndex >= [sections_ count])
7632         return nil;
7633     Section *section([sections_ objectAtIndex:sectionIndex]);
7634     NSInteger row([path row]);
7635     return [[[packages_ objectAtIndex:([section row] + row)] retain] autorelease];
7636 } }
7637
7638 - (void) alertView:(UIAlertView *)alert clickedButtonAtIndex:(NSInteger)button {
7639     NSString *context([alert context]);
7640
7641     if ([context isEqualToString:@"norefresh"])
7642         [alert dismissWithClickedButtonIndex:-1 animated:YES];
7643 }
7644
7645 - (void) setLeftBarButtonItem {
7646     if ([delegate_ updating])
7647         [[self navigationItem] setLeftBarButtonItem:[[[UIBarButtonItem alloc]
7648             initWithTitle:UCLocalize("CANCEL")
7649             style:UIBarButtonItemStyleDone
7650             target:self
7651             action:@selector(cancelButtonClicked)
7652         ] autorelease] animated:YES];
7653     else
7654         [[self navigationItem] setLeftBarButtonItem:[[[UIBarButtonItem alloc]
7655             initWithTitle:UCLocalize("REFRESH")
7656             style:UIBarButtonItemStylePlain
7657             target:self
7658             action:@selector(refreshButtonClicked)
7659         ] autorelease] animated:YES];
7660 }
7661
7662 - (void) refreshButtonClicked {
7663     if ([delegate_ requestUpdate])
7664         [self setLeftBarButtonItem];
7665 }
7666
7667 - (void) cancelButtonClicked {
7668     [delegate_ cancelUpdate];
7669 }
7670
7671 - (void) upgradeButtonClicked {
7672     [delegate_ distUpgrade];
7673     [[self navigationItem] setRightBarButtonItem:nil animated:YES];
7674 }
7675
7676 - (bool) shouldYield {
7677     return true;
7678 }
7679
7680 - (bool) shouldBlock {
7681     return true;
7682 }
7683
7684 - (void) useFilter {
7685 @synchronized (self) {
7686     [self setFilter:[](Package *package) {
7687         return [package upgradableAndEssential:YES] || [package visible];
7688     }];
7689
7690     [self setSorter:[](NSMutableArray *packages) {
7691         [packages radixSortUsingFunction:reinterpret_cast<MenesRadixSortFunction>(&PackageChangesRadix) withContext:NULL];
7692     }];
7693 } }
7694
7695 - (id) initWithDatabase:(Database *)database {
7696     if ((self = [super initWithDatabase:database title:UCLocalize("CHANGES")]) != nil) {
7697         [self useFilter];
7698     } return self;
7699 }
7700
7701 - (void) viewDidLoad {
7702     [super viewDidLoad];
7703     [self setLeftBarButtonItem];
7704 }
7705
7706 - (void) viewWillAppear:(BOOL)animated {
7707     [super viewWillAppear:animated];
7708     [self setLeftBarButtonItem];
7709 }
7710
7711 - (void) reloadData {
7712     [self setLeftBarButtonItem];
7713     [super reloadData];
7714 }
7715
7716 - (NSArray *) sectionsForPackages:(NSMutableArray *)packages {
7717     NSMutableArray *sections([NSMutableArray arrayWithCapacity:16]);
7718
7719     Section *upgradable = [[[Section alloc] initWithName:UCLocalize("AVAILABLE_UPGRADES") localize:NO] autorelease];
7720     Section *ignored = nil;
7721     Section *section = nil;
7722     time_t last = 0;
7723
7724     upgrades_ = 0;
7725     bool unseens = false;
7726
7727     CFDateFormatterRef formatter(CFDateFormatterCreate(NULL, Locale_, kCFDateFormatterMediumStyle, kCFDateFormatterMediumStyle));
7728
7729     for (size_t offset = 0, count = [packages count]; offset != count; ++offset) {
7730         Package *package = [packages objectAtIndex:offset];
7731
7732         BOOL uae = [package upgradableAndEssential:YES];
7733
7734         if (!uae) {
7735             unseens = true;
7736             time_t seen([package seen]);
7737
7738             if (section == nil || last != seen) {
7739                 last = seen;
7740
7741                 NSString *name;
7742                 name = (NSString *) CFDateFormatterCreateStringWithDate(NULL, formatter, (CFDateRef) [NSDate dateWithTimeIntervalSince1970:seen]);
7743                 [name autorelease];
7744
7745                 _profile(ChangesController$reloadData$Allocate)
7746                     name = [NSString stringWithFormat:UCLocalize("NEW_AT"), name];
7747                     section = [[[Section alloc] initWithName:name row:offset localize:NO] autorelease];
7748                     [sections addObject:section];
7749                 _end
7750             }
7751
7752             [section addToCount];
7753         } else if ([package ignored]) {
7754             if (ignored == nil) {
7755                 ignored = [[[Section alloc] initWithName:UCLocalize("IGNORED_UPGRADES") row:offset localize:NO] autorelease];
7756             }
7757             [ignored addToCount];
7758         } else {
7759             ++upgrades_;
7760             [upgradable addToCount];
7761         }
7762     }
7763     _trace();
7764
7765     CFRelease(formatter);
7766
7767     if (unseens) {
7768         Section *last = [sections lastObject];
7769         size_t count = [last count];
7770         [packages removeObjectsInRange:NSMakeRange([packages count] - count, count)];
7771         [sections removeLastObject];
7772     }
7773
7774     if ([ignored count] != 0)
7775         [sections insertObject:ignored atIndex:0];
7776     if (upgrades_ != 0)
7777         [sections insertObject:upgradable atIndex:0];
7778
7779     [list_ reloadData];
7780
7781     [[self navigationItem] setRightBarButtonItem:(upgrades_ == 0 ? nil : [[[UIBarButtonItem alloc]
7782         initWithTitle:[NSString stringWithFormat:UCLocalize("PARENTHETICAL"), UCLocalize("UPGRADE"), [NSString stringWithFormat:@"%u", upgrades_]]
7783         style:UIBarButtonItemStylePlain
7784         target:self
7785         action:@selector(upgradeButtonClicked)
7786     ] autorelease]) animated:YES];
7787
7788     return sections;
7789 }
7790
7791 @end
7792 /* }}} */
7793 /* Search Controller {{{ */
7794 @interface SearchController : FilteredPackageListController <
7795     UISearchBarDelegate
7796 > {
7797     _H<UISearchBar, 1> search_;
7798     BOOL searchloaded_;
7799     bool summary_;
7800 }
7801
7802 - (id) initWithDatabase:(Database *)database query:(NSString *)query;
7803 - (void) reloadData;
7804
7805 @end
7806
7807 @implementation SearchController
7808
7809 - (NSURL *) referrerURL {
7810     return [NSURL URLWithString:[NSString stringWithFormat:@"%@/#!/search?q=%@", UI_, [([search_ text] ?: @"") stringByAddingPercentEscapesIncludingReserved]]];
7811 }
7812
7813 - (NSURL *) navigationURL {
7814     if ([search_ text] == nil || [[search_ text] isEqualToString:@""])
7815         return [NSURL URLWithString:@"cydia://search"];
7816     else
7817         return [NSURL URLWithString:[NSString stringWithFormat:@"cydia://search/%@", [[search_ text] stringByAddingPercentEscapesIncludingReserved]]];
7818 }
7819
7820 - (NSArray *) termsForQuery:(NSString *)query {
7821     NSMutableArray *terms([NSMutableArray arrayWithCapacity:2]);
7822     for (NSString *component in [query componentsSeparatedByString:@" "])
7823         if ([component length] != 0)
7824             [terms addObject:component];
7825
7826     return terms;
7827 }
7828
7829 - (void) useSearch {
7830     _H<NSArray> query([self termsForQuery:[search_ text]]);
7831     summary_ = false;
7832
7833 @synchronized (self) {
7834     [self setFilter:[=](Package *package) {
7835         if (![package unfiltered])
7836             return false;
7837         if (![package matches:query])
7838             return false;
7839         return true;
7840     }];
7841
7842     [self setSorter:[](NSMutableArray *packages) {
7843         [packages radixSortUsingSelector:@selector(rank)];
7844     }];
7845 }
7846
7847     [self clearData];
7848     [self reloadData];
7849 }
7850
7851 - (void) usePrefix:(NSString *)prefix {
7852     _H<NSString> query(prefix);
7853     summary_ = true;
7854
7855 @synchronized (self) {
7856     [self setFilter:[=](Package *package) {
7857         if ([query length] == 0)
7858             return false;
7859         if (![package unfiltered])
7860             return false;
7861         if ([[package name] compare:query options:MatchCompareOptions_ range:NSMakeRange(0, [query length])] != NSOrderedSame)
7862             return false;
7863         return true;
7864     }];
7865
7866     [self setSorter:nullptr];
7867 }
7868
7869     [self reloadData];
7870 }
7871
7872 - (void) searchBarTextDidBeginEditing:(UISearchBar *)searchBar {
7873     [self clearData];
7874     [self usePrefix:[search_ text]];
7875 }
7876
7877 - (void) searchBarButtonClicked:(UISearchBar *)searchBar {
7878     [search_ resignFirstResponder];
7879     [self useSearch];
7880 }
7881
7882 - (void) searchBarCancelButtonClicked:(UISearchBar *)searchBar {
7883     [search_ setText:@""];
7884     [self searchBarButtonClicked:searchBar];
7885 }
7886
7887 - (void) searchBarSearchButtonClicked:(UISearchBar *)searchBar {
7888     [self searchBarButtonClicked:searchBar];
7889 }
7890
7891 - (void) searchBar:(UISearchBar *)searchBar textDidChange:(NSString *)text {
7892     [self usePrefix:text];
7893 }
7894
7895 - (bool) shouldYield {
7896     return YES;
7897 }
7898
7899 - (bool) shouldBlock {
7900     return !summary_;
7901 }
7902
7903 - (bool) isSummarized {
7904     return summary_;
7905 }
7906
7907 - (bool) showsSections {
7908     return false;
7909 }
7910
7911 - (id) initWithDatabase:(Database *)database query:(NSString *)query {
7912     if ((self = [super initWithDatabase:database title:UCLocalize("SEARCH")])) {
7913         search_ = [[[UISearchBar alloc] init] autorelease];
7914         [search_ setPlaceholder:UCLocalize("SEARCH_EX")];
7915         [search_ setDelegate:self];
7916
7917         UITextField *textField;
7918         if ([search_ respondsToSelector:@selector(searchField)])
7919             textField = [search_ searchField];
7920         else
7921             textField = MSHookIvar<UITextField *>(search_, "_searchField");
7922
7923         [textField setAutoresizingMask:UIViewAutoresizingFlexibleWidth | UIViewAutoresizingFlexibleTopMargin | UIViewAutoresizingFlexibleBottomMargin];
7924         [textField setEnablesReturnKeyAutomatically:NO];
7925         [[self navigationItem] setTitleView:textField];
7926
7927         if (query != nil)
7928             [search_ setText:query];
7929         [self useSearch];
7930     } return self;
7931 }
7932
7933 - (void) viewDidAppear:(BOOL)animated {
7934     [super viewDidAppear:animated];
7935
7936     if (!searchloaded_) {
7937         searchloaded_ = YES;
7938         [search_ setFrame:CGRectMake(0, 0, [[self view] bounds].size.width, 44.0f)];
7939         [search_ layoutSubviews];
7940     }
7941
7942     if ([self isSummarized])
7943         [search_ becomeFirstResponder];
7944 }
7945
7946 - (void) reloadData {
7947     [self resetCursor];
7948     [super reloadData];
7949 }
7950
7951 - (void) didSelectPackage:(Package *)package {
7952     [search_ resignFirstResponder];
7953     [super didSelectPackage:package];
7954 }
7955
7956 @end
7957 /* }}} */
7958 /* Package Settings Controller {{{ */
7959 @interface PackageSettingsController : CyteViewController <
7960     UITableViewDataSource,
7961     UITableViewDelegate
7962 > {
7963     _transient Database *database_;
7964     _H<NSString> name_;
7965     _H<Package> package_;
7966     _H<UITableView, 2> table_;
7967     _H<UISwitch> subscribedSwitch_;
7968     _H<UISwitch> ignoredSwitch_;
7969     _H<UITableViewCell> subscribedCell_;
7970     _H<UITableViewCell> ignoredCell_;
7971 }
7972
7973 - (id) initWithDatabase:(Database *)database package:(NSString *)package;
7974
7975 @end
7976
7977 @implementation PackageSettingsController
7978
7979 - (NSURL *) navigationURL {
7980     return [NSURL URLWithString:[NSString stringWithFormat:@"cydia://package/%@/settings", (id) name_]];
7981 }
7982
7983 - (NSInteger) numberOfSectionsInTableView:(UITableView *)tableView {
7984     if (package_ == nil)
7985         return 0;
7986
7987     if ([package_ installed] == nil)
7988         return 1;
7989     else
7990         return 2;
7991 }
7992
7993 - (NSInteger) tableView:(UITableView *)tableView numberOfRowsInSection:(NSInteger)section {
7994     if (package_ == nil)
7995         return 0;
7996
7997     // both sections contain just one item right now.
7998     return 1;
7999 }
8000
8001 - (NSString *) tableView:(UITableView *)tableView titleForHeaderInSection:(NSInteger)section {
8002     return nil;
8003 }
8004
8005 - (NSString *) tableView:(UITableView *)tableView titleForFooterInSection:(NSInteger)section {
8006     if (section == 0)
8007         return UCLocalize("SHOW_ALL_CHANGES_EX");
8008     else
8009         return UCLocalize("IGNORE_UPGRADES_EX");
8010 }
8011
8012 - (void) onSubscribed:(id)control {
8013     bool value([control isOn]);
8014     if (package_ == nil)
8015         return;
8016     if ([package_ setSubscribed:value])
8017         [delegate_ updateData];
8018 }
8019
8020 - (void) _updateIgnored {
8021     const char *package([name_ UTF8String]);
8022     bool on([ignoredSwitch_ isOn]);
8023
8024     FILE *dpkg(popen("/usr/libexec/cydia/cydo --set-selections", "w"));
8025     fwrite(package, strlen(package), 1, dpkg);
8026
8027     if (on)
8028         fwrite(" hold\n", 6, 1, dpkg);
8029     else
8030         fwrite(" install\n", 9, 1, dpkg);
8031
8032     pclose(dpkg);
8033 }
8034
8035 - (void) onIgnored:(id)control {
8036     NSInvocation *invocation([NSInvocation invocationWithMethodSignature:[self methodSignatureForSelector:@selector(_updateIgnored)]]);
8037     [invocation setTarget:self];
8038     [invocation setSelector:@selector(_updateIgnored)];
8039
8040     [delegate_ reloadDataWithInvocation:invocation];
8041 }
8042
8043 - (UITableViewCell *) tableView:(UITableView *)tableView cellForRowAtIndexPath:(NSIndexPath *)indexPath {
8044     if (package_ == nil)
8045         return nil;
8046
8047     switch ([indexPath section]) {
8048         case 0: return subscribedCell_;
8049         case 1: return ignoredCell_;
8050
8051         _nodefault
8052     }
8053
8054     return nil;
8055 }
8056
8057 - (void) loadView {
8058     UIView *view([[[UIView alloc] initWithFrame:[[UIScreen mainScreen] applicationFrame]] autorelease]);
8059     [view setAutoresizingMask:(UIViewAutoresizingFlexibleWidth | UIViewAutoresizingFlexibleHeight)];
8060     [self setView:view];
8061
8062     table_ = [[[UITableView alloc] initWithFrame:[[self view] bounds] style:UITableViewStyleGrouped] autorelease];
8063     [table_ setAutoresizingMask:UIViewAutoresizingFlexibleBoth];
8064     [(UITableView *) table_ setDataSource:self];
8065     [table_ setDelegate:self];
8066     [view addSubview:table_];
8067
8068     subscribedSwitch_ = [[[UISwitch alloc] initWithFrame:CGRectMake(0, 0, 50, 20)] autorelease];
8069     [subscribedSwitch_ setAutoresizingMask:UIViewAutoresizingFlexibleLeftMargin];
8070     [subscribedSwitch_ addTarget:self action:@selector(onSubscribed:) forEvents:UIControlEventValueChanged];
8071
8072     ignoredSwitch_ = [[[UISwitch alloc] initWithFrame:CGRectMake(0, 0, 50, 20)] autorelease];
8073     [ignoredSwitch_ setAutoresizingMask:UIViewAutoresizingFlexibleLeftMargin];
8074     [ignoredSwitch_ addTarget:self action:@selector(onIgnored:) forEvents:UIControlEventValueChanged];
8075
8076     subscribedCell_ = [[[UITableViewCell alloc] init] autorelease];
8077     [subscribedCell_ setText:UCLocalize("SHOW_ALL_CHANGES")];
8078     [subscribedCell_ setAccessoryView:subscribedSwitch_];
8079     [subscribedCell_ setSelectionStyle:UITableViewCellSelectionStyleNone];
8080
8081     ignoredCell_ = [[[UITableViewCell alloc] init] autorelease];
8082     [ignoredCell_ setText:UCLocalize("IGNORE_UPGRADES")];
8083     [ignoredCell_ setAccessoryView:ignoredSwitch_];
8084     [ignoredCell_ setSelectionStyle:UITableViewCellSelectionStyleNone];
8085 }
8086
8087 - (void) viewDidLoad {
8088     [super viewDidLoad];
8089
8090     [[self navigationItem] setTitle:UCLocalize("SETTINGS")];
8091 }
8092
8093 - (void) releaseSubviews {
8094     ignoredCell_ = nil;
8095     subscribedCell_ = nil;
8096     table_ = nil;
8097     ignoredSwitch_ = nil;
8098     subscribedSwitch_ = nil;
8099
8100     [super releaseSubviews];
8101 }
8102
8103 - (id) initWithDatabase:(Database *)database package:(NSString *)package {
8104     if ((self = [super init]) != nil) {
8105         database_ = database;
8106         name_ = package;
8107     } return self;
8108 }
8109
8110 - (void) reloadData {
8111     [super reloadData];
8112
8113     package_ = [database_ packageWithName:name_];
8114
8115     if (package_ != nil) {
8116         [subscribedSwitch_ setOn:([package_ subscribed] ? 1 : 0) animated:NO];
8117         [ignoredSwitch_ setOn:([package_ ignored] ? 1 : 0) animated:NO];
8118     } // XXX: what now, G?
8119
8120     [table_ reloadData];
8121 }
8122
8123 @end
8124 /* }}} */
8125
8126 /* Installed Controller {{{ */
8127 @interface InstalledController : FilteredPackageListController {
8128     bool sectioned_;
8129 }
8130
8131 - (id) initWithDatabase:(Database *)database;
8132 - (void) queueStatusDidChange;
8133
8134 @end
8135
8136 @implementation InstalledController
8137
8138 - (NSURL *) referrerURL {
8139     return [NSURL URLWithString:[NSString stringWithFormat:@"%@/#!/installed/", UI_]];
8140 }
8141
8142 - (NSURL *) navigationURL {
8143     return [NSURL URLWithString:@"cydia://installed"];
8144 }
8145
8146 - (void) useRecent {
8147     sectioned_ = false;
8148
8149 @synchronized (self) {
8150     [self setFilter:[](Package *package) {
8151         return ![package uninstalled] && package->role_ < 7;
8152     }];
8153
8154     [self setSorter:[](NSMutableArray *packages) {
8155         [packages radixSortUsingSelector:@selector(recent)];
8156     }];
8157 } }
8158
8159 - (void) useFilter:(UISegmentedControl *)segmented {
8160     NSInteger selected([segmented selectedSegmentIndex]);
8161     if (selected == 2)
8162         return [self useRecent];
8163     bool simple(selected == 0);
8164     sectioned_ = true;
8165
8166 @synchronized (self) {
8167     [self setFilter:[=](Package *package) {
8168         return ![package uninstalled] && package->role_ <= (simple ? 1 : 3);
8169     }];
8170
8171     [self setSorter:nullptr];
8172 } }
8173
8174 - (NSArray *) sectionsForPackages:(NSMutableArray *)packages {
8175     if (sectioned_)
8176         return [super sectionsForPackages:packages];
8177
8178     CFDateFormatterRef formatter(CFDateFormatterCreate(NULL, Locale_, kCFDateFormatterLongStyle, kCFDateFormatterNoStyle));
8179
8180     NSMutableArray *sections([NSMutableArray arrayWithCapacity:16]);
8181     Section *section(nil);
8182     time_t last(0);
8183
8184     for (size_t offset(0), count([packages count]); offset != count; ++offset) {
8185         Package *package([packages objectAtIndex:offset]);
8186
8187         time_t upgraded([package upgraded]);
8188         if (upgraded < 1168364520)
8189             upgraded = 0;
8190         else
8191             upgraded -= upgraded % (60 * 60 * 24);
8192
8193         if (section == nil || upgraded != last) {
8194             last = upgraded;
8195
8196             NSString *name;
8197             if (upgraded == 0)
8198                 continue; // XXX: name = UCLocalize("...");
8199             else {
8200                 name = (NSString *) CFDateFormatterCreateStringWithDate(NULL, formatter, (CFDateRef) [NSDate dateWithTimeIntervalSince1970:upgraded]);
8201                 [name autorelease];
8202             }
8203
8204             section = [[[Section alloc] initWithName:name row:offset localize:NO] autorelease];
8205             [sections addObject:section];
8206         }
8207
8208         [section addToCount];
8209     }
8210
8211     CFRelease(formatter);
8212     return sections;
8213 }
8214
8215 - (id) initWithDatabase:(Database *)database {
8216     if ((self = [super initWithDatabase:database title:UCLocalize("INSTALLED")]) != nil) {
8217         UISegmentedControl *segmented([[[UISegmentedControl alloc] initWithItems:[NSArray arrayWithObjects:UCLocalize("USER"), UCLocalize("EXPERT"), UCLocalize("RECENT"), nil]] autorelease]);
8218         [segmented setSelectedSegmentIndex:0];
8219         [segmented setSegmentedControlStyle:UISegmentedControlStyleBar];
8220         [[self navigationItem] setTitleView:segmented];
8221
8222         [segmented addTarget:self action:@selector(modeChanged:) forEvents:UIControlEventValueChanged];
8223         [self useFilter:segmented];
8224
8225         [self queueStatusDidChange];
8226     } return self;
8227 }
8228
8229 #if !AlwaysReload
8230 - (void) queueButtonClicked {
8231     [delegate_ queue];
8232 }
8233 #endif
8234
8235 - (void) queueStatusDidChange {
8236 #if !AlwaysReload
8237     if (Queuing_) {
8238         [[self navigationItem] setRightBarButtonItem:[[[UIBarButtonItem alloc]
8239             initWithTitle:UCLocalize("QUEUE")
8240             style:UIBarButtonItemStyleDone
8241             target:self
8242             action:@selector(queueButtonClicked)
8243         ] autorelease]];
8244     } else {
8245         [[self navigationItem] setRightBarButtonItem:nil];
8246     }
8247 #endif
8248 }
8249
8250 - (void) modeChanged:(UISegmentedControl *)segmented {
8251     [self useFilter:segmented];
8252     [self reloadData];
8253 }
8254
8255 @end
8256 /* }}} */
8257
8258 /* Source Cell {{{ */
8259 @interface SourceCell : CyteTableViewCell <
8260     CyteTableViewCellDelegate,
8261     SourceDelegate
8262 > {
8263     _H<Source, 1> source_;
8264     _H<NSURL> url_;
8265     _H<UIImage> icon_;
8266     _H<NSString> origin_;
8267     _H<NSString> label_;
8268     _H<UIActivityIndicatorView> indicator_;
8269 }
8270
8271 - (void) setSource:(Source *)source;
8272 - (void) setFetch:(NSNumber *)fetch;
8273
8274 @end
8275
8276 @implementation SourceCell
8277
8278 - (void) _setImage:(NSArray *)data {
8279     if ([url_ isEqual:[data objectAtIndex:0]]) {
8280         icon_ = [data objectAtIndex:1];
8281         [content_ setNeedsDisplay];
8282     }
8283 }
8284
8285 - (void) _setSource:(NSURL *) url {
8286     NSAutoreleasePool *pool([[NSAutoreleasePool alloc] init]);
8287
8288     if (NSData *data = [NSURLConnection
8289         sendSynchronousRequest:[NSURLRequest
8290             requestWithURL:url
8291             cachePolicy:NSURLRequestUseProtocolCachePolicy
8292             timeoutInterval:10
8293         ]
8294
8295         returningResponse:NULL
8296         error:NULL
8297     ])
8298         if (UIImage *image = [UIImage imageWithData:data])
8299             [self performSelectorOnMainThread:@selector(_setImage:) withObject:[NSArray arrayWithObjects:url, image, nil] waitUntilDone:NO];
8300
8301     [pool release];
8302 }
8303
8304 - (void) setSource:(Source *)source {
8305     source_ = source;
8306     [source_ setDelegate:self];
8307
8308     [self setFetch:[NSNumber numberWithBool:[source_ fetch]]];
8309
8310     icon_ = [UIImage imageNamed:@"unknown.png"];
8311
8312     origin_ = [source name];
8313     label_ = [source rooturi];
8314
8315     [content_ setNeedsDisplay];
8316
8317     url_ = [source iconURL];
8318     [NSThread detachNewThreadSelector:@selector(_setSource:) toTarget:self withObject:url_];
8319 }
8320
8321 - (void) setAllSource {
8322     source_ = nil;
8323     [indicator_ stopAnimating];
8324
8325     icon_ = [UIImage imageNamed:@"folder.png"];
8326     origin_ = UCLocalize("ALL_SOURCES");
8327     label_ = UCLocalize("ALL_SOURCES_EX");
8328     [content_ setNeedsDisplay];
8329 }
8330
8331 - (SourceCell *) initWithFrame:(CGRect)frame reuseIdentifier:(NSString *)reuseIdentifier {
8332     if ((self = [super initWithFrame:frame reuseIdentifier:reuseIdentifier]) != nil) {
8333         UIView *content([self contentView]);
8334         CGRect bounds([content bounds]);
8335
8336         content_ = [[[CyteTableViewCellContentView alloc] initWithFrame:bounds] autorelease];
8337         [content_ setAutoresizingMask:UIViewAutoresizingFlexibleBoth];
8338         [content_ setBackgroundColor:[UIColor whiteColor]];
8339         [content addSubview:content_];
8340
8341         [content_ setDelegate:self];
8342         [content_ setOpaque:YES];
8343
8344         indicator_ = [[[UIActivityIndicatorView alloc] initWithActivityIndicatorStyle:UIActivityIndicatorViewStyleGraySmall] autorelease];
8345         [indicator_ setAutoresizingMask:UIViewAutoresizingFlexibleLeftMargin | UIViewAutoresizingFlexibleTopMargin];// | UIViewAutoresizingFlexibleBottomMargin];
8346         [content addSubview:indicator_];
8347
8348         [[content_ layer] setContentsGravity:kCAGravityTopLeft];
8349     } return self;
8350 }
8351
8352 - (void) layoutSubviews {
8353     [super layoutSubviews];
8354
8355     UIView *content([self contentView]);
8356     CGRect bounds([content bounds]);
8357
8358     CGRect frame([indicator_ frame]);
8359     frame.origin.x = bounds.size.width - frame.size.width;
8360     frame.origin.y = Retina((bounds.size.height - frame.size.height) / 2);
8361
8362     if (kCFCoreFoundationVersionNumber < 800)
8363         frame.origin.x -= 8;
8364     [indicator_ setFrame:frame];
8365 }
8366
8367 - (NSString *) accessibilityLabel {
8368     return origin_;
8369 }
8370
8371 - (void) drawContentRect:(CGRect)rect {
8372     bool highlighted(highlighted_);
8373     float width(rect.size.width);
8374
8375     if (icon_ != nil) {
8376         CGRect rect;
8377         rect.size = [(UIImage *) icon_ size];
8378
8379         while (rect.size.width > 32 || rect.size.height > 32) {
8380             rect.size.width /= 2;
8381             rect.size.height /= 2;
8382         }
8383
8384         rect.origin.x = 26 - rect.size.width / 2;
8385         rect.origin.y = 26 - rect.size.height / 2;
8386
8387         [icon_ drawInRect:Retina(rect)];
8388     }
8389
8390     if (highlighted && kCFCoreFoundationVersionNumber < 800)
8391         UISetColor(White_);
8392
8393     if (!highlighted)
8394         UISetColor(Black_);
8395     [origin_ drawAtPoint:CGPointMake(52, 8) forWidth:(width - 49) withFont:Font18Bold_ lineBreakMode:NSLineBreakByTruncatingTail];
8396
8397     if (!highlighted)
8398         UISetColor(Gray_);
8399     [label_ drawAtPoint:CGPointMake(52, 29) forWidth:(width - 49) withFont:Font12_ lineBreakMode:NSLineBreakByTruncatingTail];
8400 }
8401
8402 - (void) setFetch:(NSNumber *)fetch {
8403     if ([fetch boolValue])
8404         [indicator_ startAnimating];
8405     else
8406         [indicator_ stopAnimating];
8407 }
8408
8409 @end
8410 /* }}} */
8411 /* Sources Controller {{{ */
8412 @interface SourcesController : CyteViewController <
8413     UITableViewDataSource,
8414     UITableViewDelegate
8415 > {
8416     _transient Database *database_;
8417     unsigned era_;
8418
8419     _H<UITableView, 2> list_;
8420     _H<NSMutableArray> sources_;
8421     int offset_;
8422
8423     _H<NSString> href_;
8424     _H<UIProgressHUD> hud_;
8425     _H<NSError> error_;
8426
8427     NSURLConnection *trivial_bz2_;
8428     NSURLConnection *trivial_gz_;
8429
8430     BOOL cydia_;
8431 }
8432
8433 - (id) initWithDatabase:(Database *)database;
8434 - (void) updateButtonsForEditingStatusAnimated:(BOOL)animated;
8435
8436 @end
8437
8438 @implementation SourcesController
8439
8440 - (void) _releaseConnection:(NSURLConnection *)connection {
8441     if (connection != nil) {
8442         [connection cancel];
8443         //[connection setDelegate:nil];
8444         [connection release];
8445     }
8446 }
8447
8448 - (void) dealloc {
8449     [self _releaseConnection:trivial_gz_];
8450     [self _releaseConnection:trivial_bz2_];
8451
8452     [super dealloc];
8453 }
8454
8455 - (NSURL *) navigationURL {
8456     return [NSURL URLWithString:@"cydia://sources"];
8457 }
8458
8459 - (void) viewDidAppear:(BOOL)animated {
8460     [super viewDidAppear:animated];
8461     [list_ deselectRowAtIndexPath:[list_ indexPathForSelectedRow] animated:animated];
8462 }
8463
8464 - (NSInteger) numberOfSectionsInTableView:(UITableView *)tableView {
8465     return 2;
8466 }
8467
8468 - (NSString *) tableView:(UITableView *)tableView titleForHeaderInSection:(NSInteger)section {
8469     if (section == 1)
8470         return UCLocalize("INDIVIDUAL_SOURCES");
8471     return nil;
8472 }
8473
8474 - (NSInteger) tableView:(UITableView *)tableView numberOfRowsInSection:(NSInteger)section {
8475     switch (section) {
8476         case 0: return 1;
8477         case 1: return [sources_ count];
8478         default: return 0;
8479     }
8480 }
8481
8482 - (Source *) sourceAtIndexPath:(NSIndexPath *)indexPath {
8483 @synchronized (database_) {
8484     if ([database_ era] != era_)
8485         return nil;
8486     if ([indexPath section] != 1)
8487         return nil;
8488     NSUInteger index([indexPath row]);
8489     if (index >= [sources_ count])
8490         return nil;
8491     return [sources_ objectAtIndex:index];
8492 } }
8493
8494 - (UITableViewCell *) tableView:(UITableView *)tableView cellForRowAtIndexPath:(NSIndexPath *)indexPath {
8495     static NSString *cellIdentifier = @"SourceCell";
8496
8497     SourceCell *cell = (SourceCell *) [tableView dequeueReusableCellWithIdentifier:cellIdentifier];
8498     if (cell == nil) cell = [[[SourceCell alloc] initWithFrame:CGRectZero reuseIdentifier:cellIdentifier] autorelease];
8499     [cell setAccessoryType:UITableViewCellAccessoryDisclosureIndicator];
8500
8501     Source *source([self sourceAtIndexPath:indexPath]);
8502     if (source == nil)
8503         [cell setAllSource];
8504     else
8505         [cell setSource:source];
8506
8507     return cell;
8508 }
8509
8510 - (void) tableView:(UITableView *)tableView didSelectRowAtIndexPath:(NSIndexPath *)indexPath {
8511     SectionsController *controller([[[SectionsController alloc]
8512         initWithDatabase:database_
8513         source:[self sourceAtIndexPath:indexPath]
8514     ] autorelease]);
8515
8516     [controller setDelegate:delegate_];
8517     [[self navigationController] pushViewController:controller animated:YES];
8518 }
8519
8520 - (BOOL) tableView:(UITableView *)tableView canEditRowAtIndexPath:(NSIndexPath *)indexPath {
8521     if ([indexPath section] != 1)
8522         return false;
8523     Source *source = [self sourceAtIndexPath:indexPath];
8524     return [source record] != nil;
8525 }
8526
8527 - (void) tableView:(UITableView *)tableView commitEditingStyle:(UITableViewCellEditingStyle)editingStyle forRowAtIndexPath:(NSIndexPath *)indexPath {
8528     _assert([indexPath section] == 1);
8529     if (editingStyle ==  UITableViewCellEditingStyleDelete) {
8530         Source *source = [self sourceAtIndexPath:indexPath];
8531         if (source == nil) return;
8532
8533         [Sources_ removeObjectForKey:[source key]];
8534
8535         [delegate_ _saveConfig];
8536         [delegate_ reloadDataWithInvocation:nil];
8537     }
8538 }
8539
8540 - (void) tableView:(UITableView *)tableView didEndEditingRowAtIndexPath:(NSIndexPath *)indexPath {
8541     [self updateButtonsForEditingStatusAnimated:YES];
8542 }
8543
8544 - (void) complete {
8545     [delegate_ addTrivialSource:href_];
8546     href_ = nil;
8547
8548     [delegate_ syncData];
8549 }
8550
8551 - (NSString *) getWarning {
8552     NSString *href(href_);
8553     NSRange colon([href rangeOfString:@"://"]);
8554     if (colon.location != NSNotFound)
8555         href = [href substringFromIndex:(colon.location + 3)];
8556     href = [href stringByAddingPercentEscapes];
8557     href = [CydiaURL(@"api/repotag/") stringByAppendingString:href];
8558
8559     NSURL *url([NSURL URLWithString:href]);
8560
8561     NSStringEncoding encoding;
8562     NSError *error(nil);
8563
8564     if (NSString *warning = [NSString stringWithContentsOfURL:url usedEncoding:&encoding error:&error])
8565         return [warning length] == 0 ? nil : warning;
8566     return nil;
8567 }
8568
8569 - (void) _endConnection:(NSURLConnection *)connection {
8570     // XXX: the memory management in this method is horribly awkward
8571
8572     NSURLConnection **field = NULL;
8573     if (connection == trivial_bz2_)
8574         field = &trivial_bz2_;
8575     else if (connection == trivial_gz_)
8576         field = &trivial_gz_;
8577     _assert(field != NULL);
8578     [connection release];
8579     *field = nil;
8580
8581     if (
8582         trivial_bz2_ == nil &&
8583         trivial_gz_ == nil
8584     ) {
8585         NSString *warning(cydia_ ? [self yieldToSelector:@selector(getWarning)] : nil);
8586
8587         [delegate_ releaseNetworkActivityIndicator];
8588
8589         [delegate_ removeProgressHUD:hud_];
8590         hud_ = nil;
8591
8592         if (cydia_) {
8593             if (warning != nil) {
8594                 UIAlertView *alert = [[[UIAlertView alloc]
8595                     initWithTitle:UCLocalize("SOURCE_WARNING")
8596                     message:warning
8597                     delegate:self
8598                     cancelButtonTitle:UCLocalize("CANCEL")
8599                     otherButtonTitles:
8600                         UCLocalize("ADD_ANYWAY"),
8601                     nil
8602                 ] autorelease];
8603
8604                 [alert setContext:@"warning"];
8605                 [alert setNumberOfRows:1];
8606                 [alert show];
8607
8608                 // XXX: there used to be this great mechanism called yieldToPopup... who deleted it?
8609                 error_ = nil;
8610                 return;
8611             }
8612
8613             [self complete];
8614         } else if (error_ != nil) {
8615             UIAlertView *alert = [[[UIAlertView alloc]
8616                 initWithTitle:UCLocalize("VERIFICATION_ERROR")
8617                 message:[error_ localizedDescription]
8618                 delegate:self
8619                 cancelButtonTitle:UCLocalize("OK")
8620                 otherButtonTitles:nil
8621             ] autorelease];
8622
8623             [alert setContext:@"urlerror"];
8624             [alert show];
8625
8626             href_ = nil;
8627         } else {
8628             UIAlertView *alert = [[[UIAlertView alloc]
8629                 initWithTitle:UCLocalize("NOT_REPOSITORY")
8630                 message:UCLocalize("NOT_REPOSITORY_EX")
8631                 delegate:self
8632                 cancelButtonTitle:UCLocalize("OK")
8633                 otherButtonTitles:nil
8634             ] autorelease];
8635
8636             [alert setContext:@"trivial"];
8637             [alert show];
8638
8639             href_ = nil;
8640         }
8641
8642         error_ = nil;
8643     }
8644 }
8645
8646 - (void) connection:(NSURLConnection *)connection didReceiveResponse:(NSHTTPURLResponse *)response {
8647     switch ([response statusCode]) {
8648         case 200:
8649             cydia_ = YES;
8650     }
8651 }
8652
8653 - (void) connection:(NSURLConnection *)connection didFailWithError:(NSError *)error {
8654     lprintf("connection:\"%s\" didFailWithError:\"%s\"\n", [href_ UTF8String], [[error localizedDescription] UTF8String]);
8655     error_ = error;
8656     [self _endConnection:connection];
8657 }
8658
8659 - (void) connectionDidFinishLoading:(NSURLConnection *)connection {
8660     [self _endConnection:connection];
8661 }
8662
8663 - (NSURLConnection *) _requestHRef:(NSString *)href method:(NSString *)method {
8664     NSURL *url([NSURL URLWithString:href]);
8665
8666     NSMutableURLRequest *request = [NSMutableURLRequest
8667         requestWithURL:url
8668         cachePolicy:NSURLRequestUseProtocolCachePolicy
8669         timeoutInterval:10
8670     ];
8671
8672     [request setHTTPMethod:method];
8673
8674     if (Machine_ != NULL)
8675         [request setValue:[NSString stringWithUTF8String:Machine_] forHTTPHeaderField:@"X-Machine"];
8676
8677     if (UniqueID_ != nil)
8678         [request setValue:UniqueID_ forHTTPHeaderField:@"X-Unique-ID"];
8679
8680     if ([url isCydiaSecure]) {
8681         if (UniqueID_ != nil)
8682             [request setValue:UniqueID_ forHTTPHeaderField:@"X-Cydia-Id"];
8683     }
8684
8685     return [[[NSURLConnection alloc] initWithRequest:request delegate:self] autorelease];
8686 }
8687
8688 - (void) alertView:(UIAlertView *)alert clickedButtonAtIndex:(NSInteger)button {
8689     NSString *context([alert context]);
8690
8691     if ([context isEqualToString:@"source"]) {
8692         switch (button) {
8693             case 1: {
8694                 NSString *href = [[alert textField] text];
8695                 href = VerifySource(href);
8696                 if (href == nil)
8697                     break;
8698                 href_ = href;
8699
8700                 trivial_bz2_ = [[self _requestHRef:[href_ stringByAppendingString:@"Packages.bz2"] method:@"HEAD"] retain];
8701                 trivial_gz_ = [[self _requestHRef:[href_ stringByAppendingString:@"Packages.gz"] method:@"HEAD"] retain];
8702
8703                 cydia_ = false;
8704
8705                 // XXX: this is stupid
8706                 hud_ = [delegate_ addProgressHUD];
8707                 [hud_ setText:UCLocalize("VERIFYING_URL")];
8708                 [delegate_ retainNetworkActivityIndicator];
8709             } break;
8710
8711             case 0:
8712             break;
8713
8714             _nodefault
8715         }
8716
8717         [alert dismissWithClickedButtonIndex:-1 animated:YES];
8718     } else if ([context isEqualToString:@"trivial"])
8719         [alert dismissWithClickedButtonIndex:-1 animated:YES];
8720     else if ([context isEqualToString:@"urlerror"])
8721         [alert dismissWithClickedButtonIndex:-1 animated:YES];
8722     else if ([context isEqualToString:@"warning"]) {
8723         switch (button) {
8724             case 1:
8725                 [self performSelector:@selector(complete) withObject:nil afterDelay:0];
8726             break;
8727
8728             case 0:
8729             break;
8730
8731             _nodefault
8732         }
8733
8734         [alert dismissWithClickedButtonIndex:-1 animated:YES];
8735     }
8736 }
8737
8738 - (void) updateButtonsForEditingStatusAnimated:(BOOL)animated {
8739     BOOL editing([list_ isEditing]);
8740
8741     if (editing)
8742         [[self navigationItem] setLeftBarButtonItem:[[[UIBarButtonItem alloc]
8743             initWithTitle:UCLocalize("ADD")
8744             style:UIBarButtonItemStylePlain
8745             target:self
8746             action:@selector(addButtonClicked)
8747         ] autorelease] animated:animated];
8748     else if ([delegate_ updating])
8749         [[self navigationItem] setLeftBarButtonItem:[[[UIBarButtonItem alloc]
8750             initWithTitle:UCLocalize("CANCEL")
8751             style:UIBarButtonItemStyleDone
8752             target:self
8753             action:@selector(cancelButtonClicked)
8754         ] autorelease] animated:animated];
8755     else
8756         [[self navigationItem] setLeftBarButtonItem:[[[UIBarButtonItem alloc]
8757             initWithTitle:UCLocalize("REFRESH")
8758             style:UIBarButtonItemStylePlain
8759             target:self
8760             action:@selector(refreshButtonClicked)
8761         ] autorelease] animated:animated];
8762
8763     [[self navigationItem] setRightBarButtonItem:[[[UIBarButtonItem alloc]
8764         initWithTitle:(editing ? UCLocalize("DONE") : UCLocalize("EDIT"))
8765         style:(editing ? UIBarButtonItemStyleDone : UIBarButtonItemStylePlain)
8766         target:self
8767         action:@selector(editButtonClicked)
8768     ] autorelease] animated:animated];
8769 }
8770
8771 - (void) loadView {
8772     list_ = [[[UITableView alloc] initWithFrame:[[UIScreen mainScreen] applicationFrame] style:UITableViewStylePlain] autorelease];
8773     [list_ setAutoresizingMask:UIViewAutoresizingFlexibleBoth];
8774     [list_ setRowHeight:53];
8775     [(UITableView *) list_ setDataSource:self];
8776     [list_ setDelegate:self];
8777     [self setView:list_];
8778 }
8779
8780 - (void) viewDidLoad {
8781     [super viewDidLoad];
8782
8783     [[self navigationItem] setTitle:UCLocalize("SOURCES")];
8784     [self updateButtonsForEditingStatusAnimated:NO];
8785 }
8786
8787 - (void) viewWillAppear:(BOOL)animated {
8788     [super viewWillAppear:animated];
8789
8790     [list_ setEditing:NO];
8791     [self updateButtonsForEditingStatusAnimated:NO];
8792 }
8793
8794 - (void) releaseSubviews {
8795     list_ = nil;
8796
8797     sources_ = nil;
8798
8799     [super releaseSubviews];
8800 }
8801
8802 - (id) initWithDatabase:(Database *)database {
8803     if ((self = [super init]) != nil) {
8804         database_ = database;
8805     } return self;
8806 }
8807
8808 - (void) reloadData {
8809     [super reloadData];
8810     [self updateButtonsForEditingStatusAnimated:YES];
8811
8812 @synchronized (database_) {
8813     era_ = [database_ era];
8814
8815     sources_ = [NSMutableArray arrayWithCapacity:16];
8816     [sources_ addObjectsFromArray:[database_ sources]];
8817     _trace();
8818     [sources_ sortUsingSelector:@selector(compareByName:)];
8819     _trace();
8820
8821     int count([sources_ count]);
8822     offset_ = 0;
8823     for (int i = 0; i != count; i++) {
8824         if ([[sources_ objectAtIndex:i] record] == nil)
8825             break;
8826         offset_++;
8827     }
8828
8829     [list_ reloadData];
8830 } }
8831
8832 - (void) showAddSourcePrompt {
8833     UIAlertView *alert = [[[UIAlertView alloc]
8834         initWithTitle:UCLocalize("ENTER_APT_URL")
8835         message:nil
8836         delegate:self
8837         cancelButtonTitle:UCLocalize("CANCEL")
8838         otherButtonTitles:
8839             UCLocalize("ADD_SOURCE"),
8840         nil
8841     ] autorelease];
8842
8843     [alert setContext:@"source"];
8844
8845     [alert setNumberOfRows:1];
8846     [alert addTextFieldWithValue:@"http://" label:@""];
8847
8848     UITextInputTraits *traits = [[alert textField] textInputTraits];
8849     [traits setAutocapitalizationType:UITextAutocapitalizationTypeNone];
8850     [traits setAutocorrectionType:UITextAutocorrectionTypeNo];
8851     [traits setKeyboardType:UIKeyboardTypeURL];
8852     // XXX: UIReturnKeyDone
8853     [traits setReturnKeyType:UIReturnKeyNext];
8854
8855     [alert show];
8856 }
8857
8858 - (void) addButtonClicked {
8859     [self showAddSourcePrompt];
8860 }
8861
8862 - (void) refreshButtonClicked {
8863     if ([delegate_ requestUpdate])
8864         [self updateButtonsForEditingStatusAnimated:YES];
8865 }
8866
8867 - (void) cancelButtonClicked {
8868     [delegate_ cancelUpdate];
8869 }
8870
8871 - (void) editButtonClicked {
8872     [list_ setEditing:![list_ isEditing] animated:YES];
8873     [self updateButtonsForEditingStatusAnimated:YES];
8874 }
8875
8876 @end
8877 /* }}} */
8878
8879 /* Stash Controller {{{ */
8880 @interface StashController : CyteViewController {
8881     _H<UIActivityIndicatorView> spinner_;
8882     _H<UILabel> status_;
8883     _H<UILabel> caption_;
8884 }
8885
8886 @end
8887
8888 @implementation StashController
8889
8890 - (void) loadView {
8891     UIView *view([[[UIView alloc] initWithFrame:[[UIScreen mainScreen] applicationFrame]] autorelease]);
8892     [view setAutoresizingMask:(UIViewAutoresizingFlexibleWidth | UIViewAutoresizingFlexibleHeight)];
8893     [self setView:view];
8894
8895     [view setBackgroundColor:[UIColor viewFlipsideBackgroundColor]];
8896
8897     spinner_ = [[[UIActivityIndicatorView alloc] initWithActivityIndicatorStyle:UIActivityIndicatorViewStyleWhiteLarge] autorelease];
8898     CGRect spinrect = [spinner_ frame];
8899     spinrect.origin.x = Retina([[self view] frame].size.width / 2 - spinrect.size.width / 2);
8900     spinrect.origin.y = [[self view] frame].size.height - 80.0f;
8901     [spinner_ setFrame:spinrect];
8902     [spinner_ setAutoresizingMask:UIViewAutoresizingFlexibleLeftMargin | UIViewAutoresizingFlexibleRightMargin | UIViewAutoresizingFlexibleTopMargin];
8903     [view addSubview:spinner_];
8904     [spinner_ startAnimating];
8905
8906     CGRect captrect;
8907     captrect.size.width = [[self view] frame].size.width;
8908     captrect.size.height = 40.0f;
8909     captrect.origin.x = 0;
8910     captrect.origin.y = Retina([[self view] frame].size.height / 2 - captrect.size.height * 2);
8911     caption_ = [[[UILabel alloc] initWithFrame:captrect] autorelease];
8912     [caption_ setText:UCLocalize("PREPARING_FILESYSTEM")];
8913     [caption_ setAutoresizingMask:UIViewAutoresizingFlexibleWidth | UIViewAutoresizingFlexibleTopMargin | UIViewAutoresizingFlexibleBottomMargin];
8914     [caption_ setFont:[UIFont boldSystemFontOfSize:28.0f]];
8915     [caption_ setTextColor:[UIColor whiteColor]];
8916     [caption_ setBackgroundColor:[UIColor clearColor]];
8917     [caption_ setShadowColor:[UIColor blackColor]];
8918     [caption_ setTextAlignment:NSTextAlignmentCenter];
8919     [view addSubview:caption_];
8920
8921     CGRect statusrect;
8922     statusrect.size.width = [[self view] frame].size.width;
8923     statusrect.size.height = 30.0f;
8924     statusrect.origin.x = 0;
8925     statusrect.origin.y = Retina([[self view] frame].size.height / 2 - statusrect.size.height);
8926     status_ = [[[UILabel alloc] initWithFrame:statusrect] autorelease];
8927     [status_ setAutoresizingMask:UIViewAutoresizingFlexibleLeftMargin | UIViewAutoresizingFlexibleRightMargin | UIViewAutoresizingFlexibleTopMargin | UIViewAutoresizingFlexibleBottomMargin];
8928     [status_ setText:UCLocalize("EXIT_WHEN_COMPLETE")];
8929     [status_ setFont:[UIFont systemFontOfSize:16.0f]];
8930     [status_ setTextColor:[UIColor whiteColor]];
8931     [status_ setBackgroundColor:[UIColor clearColor]];
8932     [status_ setShadowColor:[UIColor blackColor]];
8933     [status_ setTextAlignment:NSTextAlignmentCenter];
8934     [view addSubview:status_];
8935 }
8936
8937 - (void) releaseSubviews {
8938     spinner_ = nil;
8939     status_ = nil;
8940     caption_ = nil;
8941
8942     [super releaseSubviews];
8943 }
8944
8945 @end
8946 /* }}} */
8947
8948 @interface CYURLCache : SDURLCache {
8949 }
8950
8951 @end
8952
8953 @implementation CYURLCache
8954
8955 - (void) logEvent:(NSString *)event forRequest:(NSURLRequest *)request {
8956 #if !ForRelease
8957     if (false);
8958     else if ([event isEqualToString:@"no-cache"])
8959         event = @"!!!";
8960     else if ([event isEqualToString:@"store"])
8961         event = @">>>";
8962     else if ([event isEqualToString:@"invalid"])
8963         event = @"???";
8964     else if ([event isEqualToString:@"memory"])
8965         event = @"mem";
8966     else if ([event isEqualToString:@"disk"])
8967         event = @"ssd";
8968     else if ([event isEqualToString:@"miss"])
8969         event = @"---";
8970
8971     NSLog(@"%@: %@", event, [[request URL] absoluteString]);
8972 #endif
8973 }
8974
8975 - (void) storeCachedResponse:(NSCachedURLResponse *)cached forRequest:(NSURLRequest *)request {
8976     if (NSURLResponse *response = [cached response])
8977         if (NSString *mime = [response MIMEType])
8978             if ([mime isEqualToString:@"text/cache-manifest"]) {
8979                 NSURL *url([response URL]);
8980
8981 #if !ForRelease
8982                 NSLog(@"###: %@", [url absoluteString]);
8983 #endif
8984
8985                 @synchronized (HostConfig_) {
8986                     [CachedURLs_ addObject:url];
8987                 }
8988             }
8989
8990     [super storeCachedResponse:cached forRequest:request];
8991 }
8992
8993 - (void) createDiskCachePath {
8994     [super createDiskCachePath];
8995 }
8996
8997 @end
8998
8999 @interface Cydia : UIApplication <
9000     ConfirmationControllerDelegate,
9001     DatabaseDelegate,
9002     CydiaDelegate
9003 > {
9004     _H<UIWindow> window_;
9005     _H<CydiaTabBarController> tabbar_;
9006     _H<CyteTabBarController> emulated_;
9007     _H<AppCacheController> appcache_;
9008
9009     _H<NSMutableArray> essential_;
9010     _H<NSMutableArray> broken_;
9011
9012     Database *database_;
9013
9014     _H<NSURL> starturl_;
9015
9016     unsigned locked_;
9017     unsigned activity_;
9018
9019     _H<StashController> stash_;
9020
9021     bool loaded_;
9022 }
9023
9024 - (void) loadData;
9025
9026 @end
9027
9028 @implementation Cydia
9029
9030 - (void) lockSuspend {
9031     if (locked_++ == 0) {
9032         if ($SBSSetInterceptsMenuButtonForever != NULL)
9033             (*$SBSSetInterceptsMenuButtonForever)(true);
9034
9035         [self setIdleTimerDisabled:YES];
9036     }
9037 }
9038
9039 - (void) unlockSuspend {
9040     if (--locked_ == 0) {
9041         [self setIdleTimerDisabled:NO];
9042
9043         if ($SBSSetInterceptsMenuButtonForever != NULL)
9044             (*$SBSSetInterceptsMenuButtonForever)(false);
9045     }
9046 }
9047
9048 - (void) beginUpdate {
9049     [tabbar_ beginUpdate];
9050 }
9051
9052 - (void) cancelUpdate {
9053     [tabbar_ cancelUpdate];
9054 }
9055
9056 - (bool) requestUpdate {
9057     if (IsReachable("cydia.saurik.com")) {
9058         [self beginUpdate];
9059         return true;
9060     } else {
9061         UIAlertView *alert = [[[UIAlertView alloc]
9062             initWithTitle:[NSString stringWithFormat:Colon_, Error_, UCLocalize("REFRESH")]
9063             message:@"Host Unreachable" // XXX: Localize
9064             delegate:self
9065             cancelButtonTitle:UCLocalize("OK")
9066             otherButtonTitles:nil
9067         ] autorelease];
9068
9069         [alert setContext:@"norefresh"];
9070         [alert show];
9071
9072         return false;
9073     }
9074 }
9075
9076 - (BOOL) updating {
9077     return [tabbar_ updating];
9078 }
9079
9080 - (void) _loaded {
9081     if ([broken_ count] != 0) {
9082         int count = [broken_ count];
9083
9084         UIAlertView *alert = [[[UIAlertView alloc]
9085             initWithTitle:(count == 1 ? UCLocalize("HALFINSTALLED_PACKAGE") : [NSString stringWithFormat:UCLocalize("HALFINSTALLED_PACKAGES"), count])
9086             message:UCLocalize("HALFINSTALLED_PACKAGE_EX")
9087             delegate:self
9088             cancelButtonTitle:[NSString stringWithFormat:UCLocalize("PARENTHETICAL"), UCLocalize("FORCIBLY_CLEAR"), UCLocalize("UNSAFE")]
9089             otherButtonTitles:
9090                 UCLocalize("TEMPORARY_IGNORE"),
9091             nil
9092         ] autorelease];
9093
9094         [alert setContext:@"fixhalf"];
9095         [alert setNumberOfRows:2];
9096         [alert show];
9097     } else if (!Ignored_ && [essential_ count] != 0) {
9098         int count = [essential_ count];
9099
9100         UIAlertView *alert = [[[UIAlertView alloc]
9101             initWithTitle:(count == 1 ? UCLocalize("ESSENTIAL_UPGRADE") : [NSString stringWithFormat:UCLocalize("ESSENTIAL_UPGRADES"), count])
9102             message:UCLocalize("ESSENTIAL_UPGRADE_EX")
9103             delegate:self
9104             cancelButtonTitle:UCLocalize("TEMPORARY_IGNORE")
9105             otherButtonTitles:
9106                 UCLocalize("UPGRADE_ESSENTIAL"),
9107                 UCLocalize("COMPLETE_UPGRADE"),
9108             nil
9109         ] autorelease];
9110
9111         [alert setContext:@"upgrade"];
9112         [alert show];
9113     }
9114 }
9115
9116 - (void) returnToCydia {
9117     [self _loaded];
9118 }
9119
9120 - (void) reloadSpringBoard {
9121     if (kCFCoreFoundationVersionNumber >= 700) // XXX: iOS 6.x
9122         system("/bin/launchctl stop com.apple.backboardd");
9123     else
9124         system("/bin/launchctl stop com.apple.SpringBoard");
9125     sleep(15);
9126     system("/usr/bin/killall backboardd SpringBoard");
9127 }
9128
9129 - (void) _saveConfig {
9130     SaveConfig(database_);
9131 }
9132
9133 // Navigation controller for the queuing badge.
9134 - (UINavigationController *) queueNavigationController {
9135     NSArray *controllers = [tabbar_ viewControllers];
9136     return [controllers objectAtIndex:3];
9137 }
9138
9139 - (void) unloadData {
9140     [tabbar_ unloadData];
9141 }
9142
9143 - (void) _updateData {
9144     [self _saveConfig];
9145     [self unloadData];
9146
9147     UINavigationController *navigation = [self queueNavigationController];
9148
9149     id queuedelegate = nil;
9150     if ([[navigation viewControllers] count] > 0)
9151         queuedelegate = [[navigation viewControllers] objectAtIndex:0];
9152
9153     [queuedelegate queueStatusDidChange];
9154     [[navigation tabBarItem] setBadgeValue:(Queuing_ ? UCLocalize("Q_D") : nil)];
9155 }
9156
9157 - (void) _refreshIfPossible {
9158     NSAutoreleasePool *pool = [[NSAutoreleasePool alloc] init];
9159
9160     NSDate *update([[NSDictionary dictionaryWithContentsOfFile:@ CacheState_] objectForKey:@"LastUpdate"]);
9161
9162     bool recently = false;
9163     if (update != nil) {
9164         NSTimeInterval interval([update timeIntervalSinceNow]);
9165         if (interval > -(15*60))
9166             recently = true;
9167     }
9168
9169     // Don't automatic refresh if:
9170     //  - We already refreshed recently.
9171     //  - We already auto-refreshed this launch.
9172     //  - Auto-refresh is disabled.
9173     //  - Cydia's server is not reachable
9174     if (recently || loaded_ || ManualRefresh || !IsReachable("cydia.saurik.com")) {
9175         // If we are cancelling, we need to make sure it knows it's already loaded.
9176         loaded_ = true;
9177
9178         [self performSelectorOnMainThread:@selector(_loaded) withObject:nil waitUntilDone:NO];
9179     } else {
9180         // We are going to load, so remember that.
9181         loaded_ = true;
9182
9183         [tabbar_ performSelectorOnMainThread:@selector(beginUpdate) withObject:nil waitUntilDone:NO];
9184     }
9185
9186     [pool release];
9187 }
9188
9189 - (void) refreshIfPossible {
9190     [NSThread detachNewThreadSelector:@selector(_refreshIfPossible) toTarget:self withObject:nil];
9191 }
9192
9193 - (void) reloadDataWithInvocation:(NSInvocation *)invocation {
9194 _profile(reloadDataWithInvocation)
9195 @synchronized (self) {
9196     UIProgressHUD *hud(loaded_ ? [self addProgressHUD] : nil);
9197     if (hud != nil)
9198         [hud setText:UCLocalize("RELOADING_DATA")];
9199
9200     [database_ yieldToSelector:@selector(reloadDataWithInvocation:) withObject:invocation];
9201
9202     size_t changes(0);
9203
9204     [essential_ removeAllObjects];
9205     [broken_ removeAllObjects];
9206
9207     _profile(reloadDataWithInvocation$Essential)
9208     NSArray *packages([database_ packages]);
9209     for (Package *package in packages) {
9210         if ([package half])
9211             [broken_ addObject:package];
9212         if ([package upgradableAndEssential:YES] && ![package ignored]) {
9213             if ([package essential] && [package installed] != nil)
9214                 [essential_ addObject:package];
9215             ++changes;
9216         }
9217     }
9218     _end
9219
9220     UITabBarItem *changesItem = [[[tabbar_ viewControllers] objectAtIndex:2] tabBarItem];
9221     if (changes != 0) {
9222         _trace();
9223         NSString *badge([[NSNumber numberWithInt:changes] stringValue]);
9224         [changesItem setBadgeValue:badge];
9225         [changesItem setAnimatedBadge:([essential_ count] > 0)];
9226         [self setApplicationIconBadgeNumber:changes];
9227     } else {
9228         _trace();
9229         [changesItem setBadgeValue:nil];
9230         [changesItem setAnimatedBadge:NO];
9231         [self setApplicationIconBadgeNumber:0];
9232     }
9233
9234     Queuing_ = false;
9235     [self _updateData];
9236
9237     if (hud != nil)
9238         [self removeProgressHUD:hud];
9239 }
9240 _end
9241
9242     PrintTimes();
9243 }
9244
9245 - (void) updateData {
9246     [self _updateData];
9247 }
9248
9249 - (void) updateDataAndLoad {
9250     [self _updateData];
9251     if ([database_ progressDelegate] == nil)
9252         [self _loaded];
9253 }
9254
9255 - (void) update_ {
9256     [database_ update];
9257     [self performSelectorOnMainThread:@selector(reloadData) withObject:nil waitUntilDone:YES];
9258 }
9259
9260 - (void) disemulate {
9261     if (emulated_ == nil)
9262         return;
9263
9264     if ([window_ respondsToSelector:@selector(setRootViewController:)])
9265         [window_ setRootViewController:tabbar_];
9266     else {
9267         [window_ addSubview:[tabbar_ view]];
9268         [[emulated_ view] removeFromSuperview];
9269     }
9270
9271     emulated_ = nil;
9272     [window_ setUserInteractionEnabled:YES];
9273 }
9274
9275 - (void) presentModalViewController:(UIViewController *)controller force:(BOOL)force {
9276     UINavigationController *navigation([[[UINavigationController alloc] initWithRootViewController:controller] autorelease]);
9277
9278     UIViewController *parent;
9279     if (emulated_ == nil)
9280         parent = tabbar_;
9281     else if (!force)
9282         parent = emulated_;
9283     else {
9284         [self disemulate];
9285         parent = tabbar_;
9286     }
9287
9288     if (IsWildcat_)
9289         [navigation setModalPresentationStyle:UIModalPresentationFormSheet];
9290     [parent presentModalViewController:navigation animated:YES];
9291 }
9292
9293 - (ProgressController *) invokeNewProgress:(NSInvocation *)invocation forController:(UINavigationController *)navigation withTitle:(NSString *)title {
9294     ProgressController *progress([[[ProgressController alloc] initWithDatabase:database_ delegate:self] autorelease]);
9295
9296     if (navigation != nil)
9297         [navigation pushViewController:progress animated:YES];
9298     else
9299         [self presentModalViewController:progress force:YES];
9300
9301     [progress invoke:invocation withTitle:title];
9302     return progress;
9303 }
9304
9305 - (void) detachNewProgressSelector:(SEL)selector toTarget:(id)target forController:(UINavigationController *)navigation title:(NSString *)title {
9306     [self invokeNewProgress:[NSInvocation invocationWithSelector:selector forTarget:target] forController:navigation withTitle:title];
9307 }
9308
9309 - (void) repairWithInvocation:(NSInvocation *)invocation {
9310     _trace();
9311     [self invokeNewProgress:invocation forController:nil withTitle:@"REPAIRING"];
9312     _trace();
9313 }
9314
9315 - (void) repairWithSelector:(SEL)selector {
9316     [self performSelectorOnMainThread:@selector(repairWithInvocation:) withObject:[NSInvocation invocationWithSelector:selector forTarget:database_] waitUntilDone:YES];
9317 }
9318
9319 - (void) reloadData {
9320     [self reloadDataWithInvocation:nil];
9321     if ([database_ progressDelegate] == nil)
9322         [self _loaded];
9323 }
9324
9325 - (void) syncData {
9326     [self _saveConfig];
9327     [self detachNewProgressSelector:@selector(update_) toTarget:self forController:nil title:@"UPDATING_SOURCES"];
9328 }
9329
9330 - (void) addSource:(NSDictionary *) source {
9331     CydiaAddSource(source);
9332 }
9333
9334 - (void) addSource:(NSString *)href withDistribution:(NSString *)distribution andSections:(NSArray *)sections {
9335     CydiaAddSource(href, distribution, sections);
9336 }
9337
9338 // XXX: this method should not return anything
9339 - (BOOL) addTrivialSource:(NSString *)href {
9340     CydiaAddSource(href, @"./");
9341     return YES;
9342 }
9343
9344 - (void) resolve {
9345     pkgProblemResolver *resolver = [database_ resolver];
9346
9347     resolver->InstallProtect();
9348     if (!resolver->Resolve(true))
9349         _error->Discard();
9350 }
9351
9352 - (bool) perform {
9353     // XXX: this is a really crappy way of doing this.
9354     // like, seriously: this state machine is still broken, and cancelling this here doesn't really /fix/ that.
9355     // for one, the user can still /start/ a reloading data event while they have a queue, which is stupid
9356     // for two, this just means there is a race condition between the refresh completing and the confirmation controller appearing.
9357     if ([tabbar_ updating])
9358         [tabbar_ cancelUpdate];
9359
9360     if (![database_ prepare])
9361         return false;
9362
9363     ConfirmationController *page([[[ConfirmationController alloc] initWithDatabase:database_] autorelease]);
9364     [page setDelegate:self];
9365     UINavigationController *confirm_([[[UINavigationController alloc] initWithRootViewController:page] autorelease]);
9366
9367     if (IsWildcat_)
9368         [confirm_ setModalPresentationStyle:UIModalPresentationFormSheet];
9369     [tabbar_ presentModalViewController:confirm_ animated:YES];
9370
9371     return true;
9372 }
9373
9374 - (void) queue {
9375     @synchronized (self) {
9376         [self perform];
9377     }
9378 }
9379
9380 - (void) clearPackage:(Package *)package {
9381     @synchronized (self) {
9382         [package clear];
9383         [self resolve];
9384         [self perform];
9385     }
9386 }
9387
9388 - (void) installPackages:(NSArray *)packages {
9389     @synchronized (self) {
9390         for (Package *package in packages)
9391             [package install];
9392         [self resolve];
9393         [self perform];
9394     }
9395 }
9396
9397 - (void) installPackage:(Package *)package {
9398     @synchronized (self) {
9399         [package install];
9400         [self resolve];
9401         [self perform];
9402     }
9403 }
9404
9405 - (void) removePackage:(Package *)package {
9406     @synchronized (self) {
9407         [package remove];
9408         [self resolve];
9409         [self perform];
9410     }
9411 }
9412
9413 - (void) distUpgrade {
9414     @synchronized (self) {
9415         if (![database_ upgrade])
9416             return;
9417         [self perform];
9418     }
9419 }
9420
9421 - (void) _uicache {
9422     _trace();
9423     system("/usr/bin/uicache");
9424     _trace();
9425 }
9426
9427 - (void) uicache {
9428     UIProgressHUD *hud([self addProgressHUD]);
9429     [hud setText:UCLocalize("LOADING")];
9430     [self yieldToSelector:@selector(_uicache)];
9431     [self removeProgressHUD:hud];
9432 }
9433
9434 - (void) perform_ {
9435     [database_ perform];
9436     [self performSelectorOnMainThread:@selector(reloadData) withObject:nil waitUntilDone:YES];
9437     [self performSelectorOnMainThread:@selector(uicache) withObject:nil waitUntilDone:YES];
9438 }
9439
9440 - (void) confirmWithNavigationController:(UINavigationController *)navigation {
9441     Queuing_ = false;
9442     [self lockSuspend];
9443     [self detachNewProgressSelector:@selector(perform_) toTarget:self forController:navigation title:@"RUNNING"];
9444     [self unlockSuspend];
9445 }
9446
9447 - (void) retainNetworkActivityIndicator {
9448     if (activity_++ == 0)
9449         [self setNetworkActivityIndicatorVisible:YES];
9450
9451 #if TraceLogging
9452     NSLog(@"retainNetworkActivityIndicator->%d", activity_);
9453 #endif
9454 }
9455
9456 - (void) releaseNetworkActivityIndicator {
9457     if (--activity_ == 0)
9458         [self setNetworkActivityIndicatorVisible:NO];
9459
9460 #if TraceLogging
9461     NSLog(@"releaseNetworkActivityIndicator->%d", activity_);
9462 #endif
9463
9464 }
9465
9466 - (void) cancelAndClear:(bool)clear {
9467     @synchronized (self) {
9468         if (clear) {
9469             [database_ clear];
9470             Queuing_ = false;
9471         } else {
9472             Queuing_ = true;
9473         }
9474
9475         [self _updateData];
9476     }
9477 }
9478
9479 - (void) alertView:(UIAlertView *)alert clickedButtonAtIndex:(NSInteger)button {
9480     NSString *context([alert context]);
9481
9482     if ([context isEqualToString:@"conffile"]) {
9483         FILE *input = [database_ input];
9484         if (button == [alert cancelButtonIndex])
9485             fprintf(input, "N\n");
9486         else if (button == [alert firstOtherButtonIndex])
9487             fprintf(input, "Y\n");
9488         fflush(input);
9489
9490         [alert dismissWithClickedButtonIndex:-1 animated:YES];
9491     } else if ([context isEqualToString:@"fixhalf"]) {
9492         if (button == [alert cancelButtonIndex]) {
9493             @synchronized (self) {
9494                 for (Package *broken in (id) broken_) {
9495                     [broken remove];
9496                     NSString *id(ShellEscape([broken id]));
9497                     system([[NSString stringWithFormat:@"/usr/libexec/cydia/cydo /bin/rm -f"
9498                         " /var/lib/dpkg/info/%@.prerm"
9499                         " /var/lib/dpkg/info/%@.postrm"
9500                         " /var/lib/dpkg/info/%@.preinst"
9501                         " /var/lib/dpkg/info/%@.postinst"
9502                         " /var/lib/dpkg/info/%@.extrainst_"
9503                     "", id, id, id, id, id] UTF8String]);
9504                 }
9505
9506                 [self resolve];
9507                 [self perform];
9508             }
9509         } else if (button == [alert firstOtherButtonIndex]) {
9510             [broken_ removeAllObjects];
9511             [self _loaded];
9512         }
9513
9514         [alert dismissWithClickedButtonIndex:-1 animated:YES];
9515     } else if ([context isEqualToString:@"upgrade"]) {
9516         if (button == [alert firstOtherButtonIndex]) {
9517             @synchronized (self) {
9518                 for (Package *essential in (id) essential_)
9519                     [essential install];
9520
9521                 [self resolve];
9522                 [self perform];
9523             }
9524         } else if (button == [alert firstOtherButtonIndex] + 1) {
9525             [self distUpgrade];
9526         } else if (button == [alert cancelButtonIndex]) {
9527             Ignored_ = YES;
9528         }
9529
9530         [alert dismissWithClickedButtonIndex:-1 animated:YES];
9531     }
9532 }
9533
9534 - (void) system:(NSString *)command {
9535     NSAutoreleasePool *pool([[NSAutoreleasePool alloc] init]);
9536
9537     _trace();
9538     system([command UTF8String]);
9539     _trace();
9540
9541     [pool release];
9542 }
9543
9544 - (void) applicationWillSuspend {
9545     [database_ clean];
9546     [super applicationWillSuspend];
9547 }
9548
9549 - (BOOL) isSafeToSuspend {
9550     if (locked_ != 0) {
9551 #if !ForRelease
9552         NSLog(@"isSafeToSuspend: locked_ != 0");
9553 #endif
9554         return false;
9555     }
9556
9557     if ([tabbar_ modalViewController] != nil)
9558         return false;
9559
9560     // Use external process status API internally.
9561     // This is probably a really bad idea.
9562     // XXX: what is the point of this? does this solve anything at all?
9563     uint64_t status = 0;
9564     int notify_token;
9565     if (notify_register_check("com.saurik.Cydia.status", &notify_token) == NOTIFY_STATUS_OK) {
9566         notify_get_state(notify_token, &status);
9567         notify_cancel(notify_token);
9568     }
9569
9570     if (status != 0) {
9571 #if !ForRelease
9572         NSLog(@"isSafeToSuspend: status != 0");
9573 #endif
9574         return false;
9575     }
9576
9577 #if !ForRelease
9578     NSLog(@"isSafeToSuspend: -> true");
9579 #endif
9580     return true;
9581 }
9582
9583 - (void) suspendReturningToLastApp:(BOOL)returning {
9584     if ([self isSafeToSuspend])
9585         [super suspendReturningToLastApp:returning];
9586 }
9587
9588 - (void) suspend {
9589     if ([self isSafeToSuspend])
9590         [super suspend];
9591 }
9592
9593 - (void) applicationSuspend {
9594     if ([self isSafeToSuspend])
9595         [super applicationSuspend];
9596 }
9597
9598 - (void) applicationSuspend:(__GSEvent *)event {
9599     if ([self isSafeToSuspend])
9600         [super applicationSuspend:event];
9601 }
9602
9603 - (void) _animateSuspension:(BOOL)arg0 duration:(double)arg1 startTime:(double)arg2 scale:(float)arg3 {
9604     if ([self isSafeToSuspend])
9605         [super _animateSuspension:arg0 duration:arg1 startTime:arg2 scale:arg3];
9606 }
9607
9608 - (void) _setSuspended:(BOOL)value {
9609     if ([self isSafeToSuspend])
9610         [super _setSuspended:value];
9611 }
9612
9613 - (UIProgressHUD *) addProgressHUD {
9614     UIProgressHUD *hud([[[UIProgressHUD alloc] init] autorelease]);
9615     [hud setAutoresizingMask:UIViewAutoresizingFlexibleBoth];
9616
9617     [window_ setUserInteractionEnabled:NO];
9618
9619     UIViewController *target(tabbar_);
9620     if (UIViewController *modal = [target modalViewController])
9621         target = modal;
9622
9623     [hud showInView:[target view]];
9624
9625     [self lockSuspend];
9626     return hud;
9627 }
9628
9629 - (void) removeProgressHUD:(UIProgressHUD *)hud {
9630     [self unlockSuspend];
9631     [hud hide];
9632     [hud removeFromSuperview];
9633     [window_ setUserInteractionEnabled:YES];
9634 }
9635
9636 - (CyteViewController *) pageForPackage:(NSString *)name withReferrer:(NSString *)referrer {
9637     return [[[CYPackageController alloc] initWithDatabase:database_ forPackage:name withReferrer:referrer] autorelease];
9638 }
9639
9640 - (CyteViewController *) pageForURL:(NSURL *)url forExternal:(BOOL)external withReferrer:(NSString *)referrer {
9641     NSString *scheme([[url scheme] lowercaseString]);
9642     if ([[url absoluteString] length] <= [scheme length] + 3)
9643         return nil;
9644     NSString *path([[url absoluteString] substringFromIndex:[scheme length] + 3]);
9645     NSArray *components([path componentsSeparatedByString:@"/"]);
9646
9647     if ([scheme isEqualToString:@"apptapp"] && [components count] > 0 && [[components objectAtIndex:0] isEqualToString:@"package"]) {
9648         CyteViewController *controller([self pageForPackage:[components objectAtIndex:1] withReferrer:referrer]);
9649         if (controller != nil)
9650             [controller setDelegate:self];
9651         return controller;
9652     }
9653
9654     if ([components count] < 1 || ![scheme isEqualToString:@"cydia"])
9655         return nil;
9656
9657     NSString *base([components objectAtIndex:0]);
9658
9659     CyteViewController *controller = nil;
9660
9661     if ([base isEqualToString:@"url"]) {
9662         // This kind of URL can contain slashes in the argument, so we can't parse them below.
9663         NSString *destination = [[url absoluteString] substringFromIndex:([scheme length] + [@"://" length] + [base length] + [@"/" length])];
9664         controller = [[[CydiaWebViewController alloc] initWithURL:[NSURL URLWithString:destination]] autorelease];
9665     } else if (!external && [components count] == 1) {
9666         if ([base isEqualToString:@"sources"]) {
9667             controller = [[[SourcesController alloc] initWithDatabase:database_] autorelease];
9668         }
9669
9670         if ([base isEqualToString:@"home"]) {
9671             controller = [[[HomeController alloc] init] autorelease];
9672         }
9673
9674         if ([base isEqualToString:@"sections"]) {
9675             controller = [[[SectionsController alloc] initWithDatabase:database_ source:nil] autorelease];
9676         }
9677
9678         if ([base isEqualToString:@"search"]) {
9679             controller = [[[SearchController alloc] initWithDatabase:database_ query:nil] autorelease];
9680         }
9681
9682         if ([base isEqualToString:@"changes"]) {
9683             controller = [[[ChangesController alloc] initWithDatabase:database_] autorelease];
9684         }
9685
9686         if ([base isEqualToString:@"installed"]) {
9687             controller = [[[InstalledController alloc] initWithDatabase:database_] autorelease];
9688         }
9689     } else if ([components count] == 2) {
9690         NSString *argument = [[components objectAtIndex:1] stringByReplacingPercentEscapesUsingEncoding:NSUTF8StringEncoding];
9691
9692         if ([base isEqualToString:@"package"]) {
9693             controller = [self pageForPackage:argument withReferrer:referrer];
9694         }
9695
9696         if (!external && [base isEqualToString:@"search"]) {
9697             controller = [[[SearchController alloc] initWithDatabase:database_ query:argument] autorelease];
9698         }
9699
9700         if (!external && [base isEqualToString:@"sections"]) {
9701             if ([argument isEqualToString:@"all"] || [argument isEqualToString:@"*"])
9702                 argument = nil;
9703             controller = [[[SectionController alloc] initWithDatabase:database_ source:nil section:argument] autorelease];
9704         }
9705
9706         if ([base isEqualToString:@"sources"]) {
9707             if ([argument isEqualToString:@"add"]) {
9708                 controller = [[[SourcesController alloc] initWithDatabase:database_] autorelease];
9709                 [(SourcesController *)controller showAddSourcePrompt];
9710             } else {
9711                 Source *source([database_ sourceWithKey:argument]);
9712                 controller = [[[SectionsController alloc] initWithDatabase:database_ source:source] autorelease];
9713             }
9714         }
9715
9716         if (!external && [base isEqualToString:@"launch"]) {
9717             [self launchApplicationWithIdentifier:argument suspended:NO];
9718             return nil;
9719         }
9720     } else if (!external && [components count] == 3) {
9721         NSString *arg1 = [[components objectAtIndex:1] stringByReplacingPercentEscapesUsingEncoding:NSUTF8StringEncoding];
9722         NSString *arg2 = [[components objectAtIndex:2] stringByReplacingPercentEscapesUsingEncoding:NSUTF8StringEncoding];
9723
9724         if ([base isEqualToString:@"package"]) {
9725             if ([arg2 isEqualToString:@"settings"]) {
9726                 controller = [[[PackageSettingsController alloc] initWithDatabase:database_ package:arg1] autorelease];
9727             } else if ([arg2 isEqualToString:@"files"]) {
9728                 if (Package *package = [database_ packageWithName:arg1]) {
9729                     controller = [[[FileTable alloc] initWithDatabase:database_] autorelease];
9730                     [(FileTable *)controller setPackage:package];
9731                 }
9732             }
9733         }
9734
9735         if ([base isEqualToString:@"sections"]) {
9736             Source *source([arg1 isEqualToString:@"*"] ? nil : [database_ sourceWithKey:arg1]);
9737             NSString *section([arg2 isEqualToString:@"*"] ? nil : arg2);
9738             controller = [[[SectionController alloc] initWithDatabase:database_ source:source section:section] autorelease];
9739         }
9740     }
9741
9742     [controller setDelegate:self];
9743     return controller;
9744 }
9745
9746 - (BOOL) openCydiaURL:(NSURL *)url forExternal:(BOOL)external {
9747     CyteViewController *page([self pageForURL:url forExternal:external withReferrer:nil]);
9748
9749     if (page != nil)
9750         [tabbar_ setUnselectedViewController:page];
9751
9752     return page != nil;
9753 }
9754
9755 - (void) applicationOpenURL:(NSURL *)url {
9756     [super applicationOpenURL:url];
9757
9758     if (!loaded_)
9759         starturl_ = url;
9760     else
9761         [self openCydiaURL:url forExternal:YES];
9762 }
9763
9764 - (void) applicationWillResignActive:(UIApplication *)application {
9765     // Stop refreshing if you get a phone call or lock the device.
9766     if ([tabbar_ updating])
9767         [tabbar_ cancelUpdate];
9768
9769     if ([[self superclass] instancesRespondToSelector:@selector(applicationWillResignActive:)])
9770         [super applicationWillResignActive:application];
9771 }
9772
9773 - (void) saveState {
9774     [[NSDictionary dictionaryWithObjectsAndKeys:
9775         @"InterfaceState", [tabbar_ navigationURLCollection],
9776         @"LastClosed", [NSDate date],
9777         @"InterfaceIndex", [NSNumber numberWithInt:[tabbar_ selectedIndex]],
9778     nil] writeToFile:@ SavedState_ atomically:YES];
9779
9780     [self _saveConfig];
9781 }
9782
9783 - (void) applicationWillTerminate:(UIApplication *)application {
9784     [self saveState];
9785 }
9786
9787 - (void) applicationDidEnterBackground:(UIApplication *)application {
9788     if (kCFCoreFoundationVersionNumber < 1000 && [self isSafeToSuspend])
9789         return [self terminateWithSuccess];
9790     Backgrounded_ = [NSDate date];
9791     [self saveState];
9792 }
9793
9794 - (void) applicationWillEnterForeground:(UIApplication *)application {
9795     if (Backgrounded_ == nil)
9796         return;
9797
9798     NSTimeInterval interval([Backgrounded_ timeIntervalSinceNow]);
9799
9800     if (interval <= -(30*60)) {
9801         [tabbar_ setSelectedIndex:0];
9802         [[[tabbar_ viewControllers] objectAtIndex:0] popToRootViewControllerAnimated:NO];
9803     }
9804
9805     if (interval <= -(15*60)) {
9806         if (IsReachable("cydia.saurik.com")) {
9807             [tabbar_ beginUpdate];
9808             [appcache_ reloadURLWithCache:YES];
9809         }
9810     }
9811
9812     if ([database_ delocked])
9813         [self reloadData];
9814 }
9815
9816 - (void) setConfigurationData:(NSString *)data {
9817     static RegEx conffile_r("'(.*)' '(.*)' ([01]) ([01])");
9818
9819     if (!conffile_r(data)) {
9820         lprintf("E:invalid conffile\n");
9821         return;
9822     }
9823
9824     NSString *ofile = conffile_r[1];
9825     //NSString *nfile = conffile_r[2];
9826
9827     UIAlertView *alert = [[[UIAlertView alloc]
9828         initWithTitle:UCLocalize("CONFIGURATION_UPGRADE")
9829         message:[NSString stringWithFormat:@"%@\n\n%@", UCLocalize("CONFIGURATION_UPGRADE_EX"), ofile]
9830         delegate:self
9831         cancelButtonTitle:UCLocalize("KEEP_OLD_COPY")
9832         otherButtonTitles:
9833             UCLocalize("ACCEPT_NEW_COPY"),
9834             // XXX: UCLocalize("SEE_WHAT_CHANGED"),
9835         nil
9836     ] autorelease];
9837
9838     [alert setContext:@"conffile"];
9839     [alert setNumberOfRows:2];
9840     [alert show];
9841 }
9842
9843 - (void) addStashController {
9844     [self lockSuspend];
9845     stash_ = [[[StashController alloc] init] autorelease];
9846     [window_ addSubview:[stash_ view]];
9847 }
9848
9849 - (void) removeStashController {
9850     [[stash_ view] removeFromSuperview];
9851     stash_ = nil;
9852     [self unlockSuspend];
9853 }
9854
9855 - (void) stash {
9856     [[UIApplication sharedApplication] setStatusBarStyle:UIStatusBarStyleBlackOpaque];
9857     UpdateExternalStatus(1);
9858     [self yieldToSelector:@selector(system:) withObject:@"/usr/libexec/cydia/cydo /usr/libexec/cydia/free.sh"];
9859     UpdateExternalStatus(0);
9860
9861     [self removeStashController];
9862     [self reloadSpringBoard];
9863 }
9864
9865 - (void) setupViewControllers {
9866     tabbar_ = [[[CydiaTabBarController alloc] initWithDatabase:database_] autorelease];
9867
9868     NSMutableArray *items;
9869     if (kCFCoreFoundationVersionNumber < 800) {
9870         items = [NSMutableArray arrayWithObjects:
9871             [[[UITabBarItem alloc] initWithTitle:@"Cydia" image:[UIImage imageNamed:@"home.png"] tag:0] autorelease],
9872             [[[UITabBarItem alloc] initWithTitle:UCLocalize("SOURCES") image:[UIImage imageNamed:@"install.png"] tag:0] autorelease],
9873             [[[UITabBarItem alloc] initWithTitle:UCLocalize("CHANGES") image:[UIImage imageNamed:@"changes.png"] tag:0] autorelease],
9874             [[[UITabBarItem alloc] initWithTitle:UCLocalize("INSTALLED") image:[UIImage imageNamed:@"manage.png"] tag:0] autorelease],
9875             [[[UITabBarItem alloc] initWithTitle:UCLocalize("SEARCH") image:[UIImage imageNamed:@"search.png"] tag:0] autorelease],
9876         nil];
9877     } else {
9878         items = [NSMutableArray arrayWithObjects:
9879             [[[UITabBarItem alloc] initWithTitle:@"Cydia" image:[UIImage imageNamed:@"home7.png"] selectedImage:[UIImage imageNamed:@"home7s.png"]] autorelease],
9880             [[[UITabBarItem alloc] initWithTitle:UCLocalize("SOURCES") image:[UIImage imageNamed:@"install7.png"] selectedImage:[UIImage imageNamed:@"install7s.png"]] autorelease],
9881             [[[UITabBarItem alloc] initWithTitle:UCLocalize("CHANGES") image:[UIImage imageNamed:@"changes7.png"] selectedImage:[UIImage imageNamed:@"changes7s.png"]] autorelease],
9882             [[[UITabBarItem alloc] initWithTitle:UCLocalize("INSTALLED") image:[UIImage imageNamed:@"manage7.png"] selectedImage:[UIImage imageNamed:@"manage7s.png"]] autorelease],
9883             [[[UITabBarItem alloc] initWithTitle:UCLocalize("SEARCH") image:[UIImage imageNamed:@"search7.png"] selectedImage:[UIImage imageNamed:@"search7s.png"]] autorelease],
9884         nil];
9885     }
9886
9887     NSMutableArray *controllers([NSMutableArray array]);
9888     for (UITabBarItem *item in items) {
9889         UINavigationController *controller([[[UINavigationController alloc] init] autorelease]);
9890         [controller setTabBarItem:item];
9891         [controllers addObject:controller];
9892     }
9893     [tabbar_ setViewControllers:controllers];
9894
9895     [tabbar_ setUpdateDelegate:self];
9896 }
9897
9898 - (void) _sendMemoryWarningNotification {
9899     if (kCFCoreFoundationVersionNumber < kCFCoreFoundationVersionNumber_iPhoneOS_3_0) // XXX: maybe 4_0?
9900         [[NSNotificationCenter defaultCenter] postNotificationName:@"UIApplicationMemoryWarningNotification" object:[UIApplication sharedApplication]];
9901     else
9902         [[NSNotificationCenter defaultCenter] postNotificationName:@"UIApplicationDidReceiveMemoryWarningNotification" object:[UIApplication sharedApplication]];
9903 }
9904
9905 - (void) _sendMemoryWarningNotifications {
9906     while (true) {
9907         [self performSelectorOnMainThread:@selector(_sendMemoryWarningNotification) withObject:nil waitUntilDone:NO];
9908         sleep(2);
9909         //usleep(2000000);
9910     }
9911 }
9912
9913 - (void) applicationDidReceiveMemoryWarning:(UIApplication *)application {
9914     NSLog(@"--");
9915     [[NSURLCache sharedURLCache] removeAllCachedResponses];
9916 }
9917
9918 - (void) applicationDidFinishLaunching:(id)unused {
9919     //[NSThread detachNewThreadSelector:@selector(_sendMemoryWarningNotifications) toTarget:self withObject:nil];
9920
9921 _trace();
9922     if ([self respondsToSelector:@selector(setApplicationSupportsShakeToEdit:)])
9923         [self setApplicationSupportsShakeToEdit:NO];
9924
9925     @synchronized (HostConfig_) {
9926         [BridgedHosts_ addObject:[[NSURL URLWithString:CydiaURL(@"")] host]];
9927     }
9928
9929     [NSURLCache setSharedURLCache:[[[CYURLCache alloc]
9930         initWithMemoryCapacity:524288
9931         diskCapacity:10485760
9932         diskPath:Cache("SDURLCache")
9933     ] autorelease]];
9934
9935     [CydiaWebViewController _initialize];
9936
9937     [NSURLProtocol registerClass:[CydiaURLProtocol class]];
9938
9939     // this would disallow http{,s} URLs from accessing this data
9940     //[WebView registerURLSchemeAsLocal:@"cydia"];
9941
9942     Font12_ = [UIFont systemFontOfSize:12];
9943     Font12Bold_ = [UIFont boldSystemFontOfSize:12];
9944     Font14_ = [UIFont systemFontOfSize:14];
9945     Font18_ = [UIFont systemFontOfSize:18];
9946     Font18Bold_ = [UIFont boldSystemFontOfSize:18];
9947     Font22Bold_ = [UIFont boldSystemFontOfSize:22];
9948
9949     essential_ = [NSMutableArray arrayWithCapacity:4];
9950     broken_ = [NSMutableArray arrayWithCapacity:4];
9951
9952     // XXX: I really need this thing... like, seriously... I'm sorry
9953     appcache_ = [[[AppCacheController alloc] initWithURL:[NSURL URLWithString:[NSString stringWithFormat:@"%@/appcache/", UI_]]] autorelease];
9954     [appcache_ reloadData];
9955
9956     window_ = [[[UIWindow alloc] initWithFrame:[[UIScreen mainScreen] bounds]] autorelease];
9957     [window_ orderFront:self];
9958     [window_ makeKey:self];
9959     [window_ setHidden:NO];
9960
9961     if (access("/.cydia_no_stash", F_OK) == 0);
9962     else {
9963
9964     if (false) stash: {
9965         [self addStashController];
9966         // XXX: this would be much cleaner as a yieldToSelector:
9967         // that way the removeStashController could happen right here inline
9968         // we also could no longer require the useless stash_ field anymore
9969         [self performSelector:@selector(stash) withObject:nil afterDelay:0];
9970         return;
9971     }
9972
9973     struct stat root;
9974     int error(stat("/", &root));
9975     _assert(error != -1);
9976
9977     #define Stash_(path) do { \
9978         struct stat folder; \
9979         int error(lstat((path), &folder)); \
9980         if (error != -1 && ( \
9981             folder.st_dev == root.st_dev && \
9982             S_ISDIR(folder.st_mode) \
9983         ) || error == -1 && ( \
9984             errno == ENOENT || \
9985             errno == ENOTDIR \
9986         )) goto stash; \
9987     } while (false)
9988
9989     Stash_("/Applications");
9990     Stash_("/Library/Ringtones");
9991     Stash_("/Library/Wallpaper");
9992     //Stash_("/usr/bin");
9993     Stash_("/usr/include");
9994     Stash_("/usr/share");
9995     //Stash_("/var/lib");
9996
9997     }
9998
9999     database_ = [Database sharedInstance];
10000     [database_ setDelegate:self];
10001
10002     [window_ setUserInteractionEnabled:NO];
10003     [self setupViewControllers];
10004
10005     CydiaLoadingViewController *loading([[[CydiaLoadingViewController alloc] init] autorelease]);
10006     UINavigationController *navigation([[[UINavigationController alloc] init] autorelease]);
10007     [navigation setViewControllers:[NSArray arrayWithObject:loading]];
10008
10009     emulated_ = [[[CyteTabBarController alloc] init] autorelease];
10010     [emulated_ setViewControllers:[NSArray arrayWithObject:navigation]];
10011     [emulated_ setSelectedIndex:0];
10012
10013     if ([emulated_ respondsToSelector:@selector(concealTabBarSelection)])
10014         [emulated_ concealTabBarSelection];
10015
10016     if ([window_ respondsToSelector:@selector(setRootViewController:)])
10017         [window_ setRootViewController:emulated_];
10018     else
10019         [window_ addSubview:[emulated_ view]];
10020
10021     [self performSelector:@selector(loadData) withObject:nil afterDelay:0];
10022 _trace();
10023 }
10024
10025 - (NSArray *) defaultStartPages {
10026     NSMutableArray *standard = [NSMutableArray array];
10027     [standard addObject:[NSArray arrayWithObject:@"cydia://home"]];
10028     [standard addObject:[NSArray arrayWithObject:@"cydia://sources"]];
10029     [standard addObject:[NSArray arrayWithObject:@"cydia://changes"]];
10030     [standard addObject:[NSArray arrayWithObject:@"cydia://installed"]];
10031     [standard addObject:[NSArray arrayWithObject:@"cydia://search"]];
10032     return standard;
10033 }
10034
10035 - (void) loadData {
10036 _trace();
10037     if ([emulated_ modalViewController] != nil)
10038         [emulated_ dismissModalViewControllerAnimated:YES];
10039     [window_ setUserInteractionEnabled:NO];
10040
10041     [self reloadDataWithInvocation:nil];
10042     [self refreshIfPossible];
10043     [self disemulate];
10044
10045     NSDictionary *state([NSDictionary dictionaryWithContentsOfFile:@ SavedState_]);
10046
10047     int savedIndex = [[state objectForKey:@"InterfaceIndex"] intValue];
10048     NSArray *saved = [[[state objectForKey:@"InterfaceState"] mutableCopy] autorelease];
10049     int standardIndex = 0;
10050     NSArray *standard = [self defaultStartPages];
10051
10052     BOOL valid = YES;
10053
10054     if (saved == nil)
10055         valid = NO;
10056
10057     NSDate *closed = [state objectForKey:@"LastClosed"];
10058     if (valid && closed != nil) {
10059         NSTimeInterval interval([closed timeIntervalSinceNow]);
10060         if (interval <= -(30*60))
10061             valid = NO;
10062     }
10063
10064     if (valid && [saved count] != [standard count])
10065         valid = NO;
10066
10067     if (valid) {
10068         for (unsigned int i = 0; i < [standard count]; i++) {
10069             NSArray *std = [standard objectAtIndex:i], *sav = [saved objectAtIndex:i];
10070             // XXX: The "hasPrefix" sanity check here could be, in theory, fooled,
10071             //      but it's good enough for now.
10072             if ([sav count] == 0 || ![[sav objectAtIndex:0] hasPrefix:[std objectAtIndex:0]]) {
10073                 valid = NO;
10074                 break;
10075             }
10076         }
10077     }
10078
10079     NSArray *items = nil;
10080     if (valid) {
10081         [tabbar_ setSelectedIndex:savedIndex];
10082         items = saved;
10083     } else {
10084         [tabbar_ setSelectedIndex:standardIndex];
10085         items = standard;
10086     }
10087
10088     for (unsigned int tab = 0; tab < [[tabbar_ viewControllers] count]; tab++) {
10089         NSArray *stack = [items objectAtIndex:tab];
10090         UINavigationController *navigation = [[tabbar_ viewControllers] objectAtIndex:tab];
10091         NSMutableArray *current = [NSMutableArray array];
10092
10093         for (unsigned int nav = 0; nav < [stack count]; nav++) {
10094             NSString *addr = [stack objectAtIndex:nav];
10095             NSURL *url = [NSURL URLWithString:addr];
10096             CyteViewController *page = [self pageForURL:url forExternal:NO withReferrer:nil];
10097             if (page != nil)
10098                 [current addObject:page];
10099         }
10100
10101         [navigation setViewControllers:current];
10102     }
10103
10104     // (Try to) show the startup URL.
10105     if (starturl_ != nil) {
10106         [self openCydiaURL:starturl_ forExternal:YES];
10107         starturl_ = nil;
10108     }
10109 }
10110
10111 - (void) showActionSheet:(UIActionSheet *)sheet fromItem:(UIBarButtonItem *)item {
10112     if (!IsWildcat_) {
10113        [sheet addButtonWithTitle:UCLocalize("CANCEL")];
10114        [sheet setCancelButtonIndex:[sheet numberOfButtons] - 1];
10115     }
10116
10117     if (item != nil && IsWildcat_) {
10118         [sheet showFromBarButtonItem:item animated:YES];
10119     } else {
10120         [sheet showInView:window_];
10121     }
10122 }
10123
10124 - (void) addProgressEvent:(CydiaProgressEvent *)event forTask:(NSString *)task {
10125     id<ProgressDelegate> progress([database_ progressDelegate] ?: [self invokeNewProgress:nil forController:nil withTitle:task]);
10126     [progress setTitle:task];
10127     [progress addProgressEvent:event];
10128 }
10129
10130 - (void) addProgressEventForTask:(NSArray *)data {
10131     CydiaProgressEvent *event([data objectAtIndex:0]);
10132     NSString *task([data count] < 2 ? nil : [data objectAtIndex:1]);
10133     [self addProgressEvent:event forTask:task];
10134 }
10135
10136 - (void) addProgressEventOnMainThread:(CydiaProgressEvent *)event forTask:(NSString *)task {
10137     [self performSelectorOnMainThread:@selector(addProgressEventForTask:) withObject:[NSArray arrayWithObjects:event, task, nil] waitUntilDone:YES];
10138 }
10139
10140 @end
10141
10142 /*IMP alloc_;
10143 id Alloc_(id self, SEL selector) {
10144     id object = alloc_(self, selector);
10145     lprintf("[%s]A-%p\n", self->isa->name, object);
10146     return object;
10147 }*/
10148
10149 /*IMP dealloc_;
10150 id Dealloc_(id self, SEL selector) {
10151     id object = dealloc_(self, selector);
10152     lprintf("[%s]D-%p\n", self->isa->name, object);
10153     return object;
10154 }*/
10155
10156 Class $NSURLConnection;
10157
10158 MSHook(id, NSURLConnection$init$, NSURLConnection *self, SEL _cmd, NSURLRequest *request, id delegate, BOOL usesCache, int64_t maxContentLength, BOOL startImmediately, NSDictionary *connectionProperties) {
10159     NSMutableURLRequest *copy([[request mutableCopy] autorelease]);
10160
10161     NSURL *url([copy URL]);
10162
10163     NSString *host([url host]);
10164     NSString *scheme([[url scheme] lowercaseString]);
10165
10166     NSString *compound([NSString stringWithFormat:@"%@:%@", scheme, host]);
10167
10168     @synchronized (HostConfig_) {
10169         if ([copy respondsToSelector:@selector(setHTTPShouldUsePipelining:)])
10170             if ([PipelinedHosts_ containsObject:host] || [PipelinedHosts_ containsObject:compound])
10171                 [copy setHTTPShouldUsePipelining:YES];
10172
10173         if (NSString *control = [copy valueForHTTPHeaderField:@"Cache-Control"])
10174             if ([control isEqualToString:@"max-age=0"])
10175                 if ([CachedURLs_ containsObject:url]) {
10176 #if !ForRelease
10177                     NSLog(@"~~~: %@", url);
10178 #endif
10179
10180                     [copy setCachePolicy:NSURLRequestReturnCacheDataDontLoad];
10181
10182                     [copy setValue:nil forHTTPHeaderField:@"Cache-Control"];
10183                     [copy setValue:nil forHTTPHeaderField:@"If-Modified-Since"];
10184                     [copy setValue:nil forHTTPHeaderField:@"If-None-Match"];
10185                 }
10186     }
10187
10188     if ((self = _NSURLConnection$init$(self, _cmd, copy, delegate, usesCache, maxContentLength, startImmediately, connectionProperties)) != nil) {
10189     } return self;
10190 }
10191
10192 Class $WAKWindow;
10193
10194 static CGSize $WAKWindow$screenSize(WAKWindow *self, SEL _cmd) {
10195     CGSize size([[UIScreen mainScreen] bounds].size);
10196     /*if ([$WAKWindow respondsToSelector:@selector(hasLandscapeOrientation)])
10197         if ([$WAKWindow hasLandscapeOrientation])
10198             std::swap(size.width, size.height);*/
10199     return size;
10200 }
10201
10202 Class $NSUserDefaults;
10203
10204 MSHook(id, NSUserDefaults$objectForKey$, NSUserDefaults *self, SEL _cmd, NSString *key) {
10205     if ([key respondsToSelector:@selector(isEqualToString:)] && [key isEqualToString:@"WebKitLocalStorageDatabasePathPreferenceKey"])
10206         return Cache("LocalStorage");
10207     return _NSUserDefaults$objectForKey$(self, _cmd, key);
10208 }
10209
10210 static NSMutableDictionary *AutoreleaseDeepMutableCopyOfDictionary(CFTypeRef type) {
10211     if (type == NULL)
10212         return nil;
10213     if (CFGetTypeID(type) != CFDictionaryGetTypeID())
10214         return nil;
10215     CFTypeRef copy(CFPropertyListCreateDeepCopy(kCFAllocatorDefault, type, kCFPropertyListMutableContainers));
10216     CFRelease(type);
10217     return [(NSMutableDictionary *) copy autorelease];
10218 }
10219
10220 int main_store(int, char *argv[]);
10221
10222 int main(int argc, char *argv[]) {
10223 #ifdef __arm64__
10224     const char *argv0(argv[0]);
10225     if (const char *slash = strrchr(argv0, '/'))
10226         argv0 = slash + 1;
10227     if (false);
10228     else if (!strcmp(argv0, "store"))
10229         return main_store(argc, argv);
10230 #endif
10231
10232     int fd(open("/tmp/cydia.log", O_WRONLY | O_APPEND | O_CREAT, 0644));
10233     dup2(fd, 2);
10234     close(fd);
10235
10236     NSAutoreleasePool *pool([[NSAutoreleasePool alloc] init]);
10237
10238     _trace();
10239
10240     UpdateExternalStatus(0);
10241
10242     UIScreen *screen([UIScreen mainScreen]);
10243     if ([screen respondsToSelector:@selector(scale)])
10244         ScreenScale_ = [screen scale];
10245     else
10246         ScreenScale_ = 1;
10247
10248     UIDevice *device([UIDevice currentDevice]);
10249     if ([device respondsToSelector:@selector(userInterfaceIdiom)]) {
10250         UIUserInterfaceIdiom idiom([device userInterfaceIdiom]);
10251         if (idiom == UIUserInterfaceIdiomPad)
10252             IsWildcat_ = true;
10253     }
10254
10255     Idiom_ = IsWildcat_ ? @"ipad" : @"iphone";
10256
10257     RegEx pattern("([0-9]+\\.[0-9]+).*");
10258
10259     if (pattern([device systemVersion]))
10260         Firmware_ = pattern[1];
10261     if (pattern(Cydia_))
10262         Major_ = pattern[1];
10263
10264     SessionData_ = [NSMutableDictionary dictionaryWithCapacity:4];
10265
10266     HostConfig_ = [[[NSObject alloc] init] autorelease];
10267     @synchronized (HostConfig_) {
10268         BridgedHosts_ = [NSMutableSet setWithCapacity:4];
10269         InsecureHosts_ = [NSMutableSet setWithCapacity:4];
10270         PipelinedHosts_ = [NSMutableSet setWithCapacity:4];
10271         CachedURLs_ = [NSMutableSet setWithCapacity:32];
10272     }
10273
10274     NSString *ui(@"ui/ios");
10275     if (Idiom_ != nil)
10276         ui = [ui stringByAppendingString:[NSString stringWithFormat:@"~%@", Idiom_]];
10277     ui = [ui stringByAppendingString:[NSString stringWithFormat:@"/%@", Major_]];
10278     UI_ = CydiaURL(ui);
10279
10280     PackageName = reinterpret_cast<CYString &(*)(Package *, SEL)>(method_getImplementation(class_getInstanceMethod([Package class], @selector(cyname))));
10281
10282     /* Library Hacks {{{ */
10283     class_addMethod(objc_getClass("DOMNodeList"), @selector(countByEnumeratingWithState:objects:count:), (IMP) &DOMNodeList$countByEnumeratingWithState$objects$count$, "I20@0:4^{NSFastEnumerationState}8^@12I16");
10284
10285     $WAKWindow = objc_getClass("WAKWindow");
10286     if ($WAKWindow != NULL)
10287         if (Method method = class_getInstanceMethod($WAKWindow, @selector(screenSize)))
10288             method_setImplementation(method, (IMP) &$WAKWindow$screenSize);
10289
10290     $NSURLConnection = objc_getClass("NSURLConnection");
10291     Method NSURLConnection$init$(class_getInstanceMethod($NSURLConnection, @selector(_initWithRequest:delegate:usesCache:maxContentLength:startImmediately:connectionProperties:)));
10292     if (NSURLConnection$init$ != NULL) {
10293         _NSURLConnection$init$ = reinterpret_cast<id (*)(NSURLConnection *, SEL, NSURLRequest *, id, BOOL, int64_t, BOOL, NSDictionary *)>(method_getImplementation(NSURLConnection$init$));
10294         method_setImplementation(NSURLConnection$init$, reinterpret_cast<IMP>(&$NSURLConnection$init$));
10295     }
10296
10297     $NSUserDefaults = objc_getClass("NSUserDefaults");
10298     Method NSUserDefaults$objectForKey$(class_getInstanceMethod($NSUserDefaults, @selector(objectForKey:)));
10299     if (NSUserDefaults$objectForKey$ != NULL) {
10300         _NSUserDefaults$objectForKey$ = reinterpret_cast<id (*)(NSUserDefaults *, SEL, NSString *)>(method_getImplementation(NSUserDefaults$objectForKey$));
10301         method_setImplementation(NSUserDefaults$objectForKey$, reinterpret_cast<IMP>(&$NSUserDefaults$objectForKey$));
10302     }
10303     /* }}} */
10304     /* Set Locale {{{ */
10305     Locale_ = CFLocaleCopyCurrent();
10306     Languages_ = [NSLocale preferredLanguages];
10307
10308     std::string languages;
10309     const char *translation(NULL);
10310
10311     // XXX: this isn't really a language, but this is compatible with older Cydia builds
10312     if (Locale_ != NULL)
10313         if (const char *language = [(NSString *) CFLocaleGetIdentifier(Locale_) UTF8String]) {
10314             RegEx pattern("([a-z][a-z])(?:-[A-Za-z]*)?(_[A-Z][A-Z])?");
10315             if (pattern(language)) {
10316                 translation = strdup([pattern->*@"%1$@%2$@" UTF8String]);
10317                 languages += translation;
10318                 languages += ",";
10319             }
10320         }
10321
10322     if (Languages_ != nil)
10323         for (NSString *language : Languages_) {
10324             languages += [language UTF8String];
10325             languages += ",";
10326         }
10327
10328     languages += "en";
10329     NSLog(@"Setting Language: [%s] %s", translation, languages.c_str());
10330     /* }}} */
10331     /* Index Collation {{{ */
10332     if (Class $UILocalizedIndexedCollation = objc_getClass("UILocalizedIndexedCollation")) { @try {
10333         NSBundle *bundle([NSBundle bundleForClass:$UILocalizedIndexedCollation]);
10334         NSString *path([bundle pathForResource:@"UITableViewLocalizedSectionIndex" ofType:@"plist"]);
10335         //path = @"/System/Library/Frameworks/UIKit.framework/.lproj/UITableViewLocalizedSectionIndex.plist";
10336         NSDictionary *dictionary([NSDictionary dictionaryWithContentsOfFile:path]);
10337         _H<UILocalizedIndexedCollation> collation([[[$UILocalizedIndexedCollation alloc] initWithDictionary:dictionary] autorelease]);
10338
10339         CollationLocale_ = MSHookIvar<NSLocale *>(collation, "_locale");
10340
10341         if (kCFCoreFoundationVersionNumber >= 800 && [[CollationLocale_ localeIdentifier] isEqualToString:@"zh@collation=stroke"]) {
10342             CollationThumbs_ = [NSArray arrayWithObjects:@"1",@"•",@"4",@"•",@"7",@"•",@"10",@"•",@"13",@"•",@"16",@"•",@"19",@"A",@"•",@"E",@"•",@"I",@"•",@"M",@"•",@"R",@"•",@"V",@"•",@"Z",@"#",nil];
10343             for (NSInteger offset : (NSInteger[]) {0,1,3,4,6,7,9,10,12,13,15,16,18,25,26,29,30,33,34,37,38,42,43,46,47,50,51})
10344                 CollationOffset_.push_back(offset);
10345             CollationTitles_ = [NSArray arrayWithObjects:@"1 畫",@"2 畫",@"3 畫",@"4 畫",@"5 畫",@"6 畫",@"7 畫",@"8 畫",@"9 畫",@"10 畫",@"11 畫",@"12 畫",@"13 畫",@"14 畫",@"15 畫",@"16 畫",@"17 畫",@"18 畫",@"19 畫",@"20 畫",@"21 畫",@"22 畫",@"23 畫",@"24 畫",@"25 畫以上",@"A",@"B",@"C",@"D",@"E",@"F",@"G",@"H",@"I",@"J",@"K",@"L",@"M",@"N",@"O",@"P",@"Q",@"R",@"S",@"T",@"U",@"V",@"W",@"X",@"Y",@"Z",@"#",nil];
10346             CollationStarts_ = [NSArray arrayWithObjects:@"一",@"丁",@"丈",@"不",@"且",@"丞",@"串",@"並",@"亭",@"乘",@"乾",@"傀",@"亂",@"僎",@"僵",@"儐",@"償",@"叢",@"儳",@"嚴",@"儷",@"儻",@"囌",@"囑",@"廳",@"a",@"b",@"c",@"d",@"e",@"f",@"g",@"h",@"i",@"j",@"k",@"l",@"m",@"n",@"o",@"p",@"q",@"r",@"s",@"t",@"u",@"v",@"w",@"x",@"y",@"z",@"ʒ",nil];
10347         } else {
10348
10349         CollationThumbs_ = [collation sectionIndexTitles];
10350         for (size_t index(0), end([CollationThumbs_ count]); index != end; ++index)
10351             CollationOffset_.push_back([collation sectionForSectionIndexTitleAtIndex:index]);
10352
10353         CollationTitles_ = [collation sectionTitles];
10354         CollationStarts_ = MSHookIvar<NSArray *>(collation, "_sectionStartStrings");
10355
10356         NSString *&transform(MSHookIvar<NSString *>(collation, "_transform"));
10357         if (&transform != NULL && transform != nil) {
10358             /*if ([collation respondsToSelector:@selector(transformedCollationStringForString:)])
10359                 CollationModify_ = [=](NSString *value) { return [collation transformedCollationStringForString:value]; };*/
10360             const UChar *uid(reinterpret_cast<const UChar *>([transform cStringUsingEncoding:NSUnicodeStringEncoding]));
10361             UErrorCode code(U_ZERO_ERROR);
10362             CollationTransl_ = utrans_openU(uid, -1, UTRANS_FORWARD, NULL, 0, NULL, &code);
10363             if (!U_SUCCESS(code))
10364                 NSLog(@"%s", u_errorName(code));
10365         }
10366
10367         }
10368     } @catch (NSException *e) {
10369         NSLog(@"%@", e);
10370         goto hard;
10371     } } else hard: {
10372         CollationLocale_ = [[[NSLocale alloc] initWithLocaleIdentifier:@"en@collation=dictionary"] autorelease];
10373
10374         CollationThumbs_ = [NSArray arrayWithObjects:@"A",@"B",@"C",@"D",@"E",@"F",@"G",@"H",@"I",@"J",@"K",@"L",@"M",@"N",@"O",@"P",@"Q",@"R",@"S",@"T",@"U",@"V",@"W",@"X",@"Y",@"Z",@"#",nil];
10375         for (NSInteger offset(0); offset != 28; ++offset)
10376             CollationOffset_.push_back(offset);
10377
10378         CollationTitles_ = [NSArray arrayWithObjects:@"A",@"B",@"C",@"D",@"E",@"F",@"G",@"H",@"I",@"J",@"K",@"L",@"M",@"N",@"O",@"P",@"Q",@"R",@"S",@"T",@"U",@"V",@"W",@"X",@"Y",@"Z",@"#",nil];
10379         CollationStarts_ = [NSArray arrayWithObjects:@"a",@"b",@"c",@"d",@"e",@"f",@"g",@"h",@"i",@"j",@"k",@"l",@"m",@"n",@"o",@"p",@"q",@"r",@"s",@"t",@"u",@"v",@"w",@"x",@"y",@"z",@"ʒ",nil];
10380     }
10381     /* }}} */
10382     /* Parse Arguments {{{ */
10383     bool substrate(false);
10384
10385     if (argc != 0) {
10386         char **args(argv);
10387         int arge(1);
10388
10389         for (int argi(1); argi != argc; ++argi)
10390             if (strcmp(argv[argi], "--") == 0) {
10391                 arge = argi;
10392                 argv[argi] = argv[0];
10393                 argv += argi;
10394                 argc -= argi;
10395                 break;
10396             }
10397
10398         for (int argi(1); argi != arge; ++argi)
10399             if (strcmp(args[argi], "--substrate") == 0)
10400                 substrate = true;
10401             else
10402                 fprintf(stderr, "unknown argument: %s\n", args[argi]);
10403     }
10404     /* }}} */
10405
10406     App_ = [[NSBundle mainBundle] bundlePath];
10407     Advanced_ = YES;
10408
10409     Cache_ = [[NSString stringWithFormat:@"%@/Library/Caches/com.saurik.Cydia", @"/var/mobile"] retain];
10410     mkdir([Cache_ UTF8String], 0755);
10411
10412     /*Method alloc = class_getClassMethod([NSObject class], @selector(alloc));
10413     alloc_ = alloc->method_imp;
10414     alloc->method_imp = (IMP) &Alloc_;*/
10415
10416     /*Method dealloc = class_getClassMethod([NSObject class], @selector(dealloc));
10417     dealloc_ = dealloc->method_imp;
10418     dealloc->method_imp = (IMP) &Dealloc_;*/
10419
10420     void *gestalt(dlopen("/usr/lib/libMobileGestalt.dylib", RTLD_GLOBAL | RTLD_LAZY));
10421     $MGCopyAnswer = reinterpret_cast<CFStringRef (*)(CFStringRef)>(dlsym(gestalt, "MGCopyAnswer"));
10422
10423     /* System Information {{{ */
10424     size_t size;
10425
10426     int maxproc;
10427     size = sizeof(maxproc);
10428     if (sysctlbyname("kern.maxproc", &maxproc, &size, NULL, 0) == -1)
10429         perror("sysctlbyname(\"kern.maxproc\", ?)");
10430     else if (maxproc < 64) {
10431         maxproc = 64;
10432         if (sysctlbyname("kern.maxproc", NULL, NULL, &maxproc, sizeof(maxproc)) == -1)
10433             perror("sysctlbyname(\"kern.maxproc\", #)");
10434     }
10435
10436     sysctlbyname("kern.osversion", NULL, &size, NULL, 0);
10437     char *osversion = new char[size];
10438     if (sysctlbyname("kern.osversion", osversion, &size, NULL, 0) == -1)
10439         perror("sysctlbyname(\"kern.osversion\", ?)");
10440     else
10441         System_ = [NSString stringWithUTF8String:osversion];
10442
10443     sysctlbyname("hw.machine", NULL, &size, NULL, 0);
10444     char *machine = new char[size];
10445     if (sysctlbyname("hw.machine", machine, &size, NULL, 0) == -1)
10446         perror("sysctlbyname(\"hw.machine\", ?)");
10447     else
10448         Machine_ = machine;
10449
10450     int64_t usermem(0);
10451     size = sizeof(usermem);
10452     if (sysctlbyname("hw.usermem", &usermem, &size, NULL, 0) == -1)
10453         usermem = 0;
10454
10455     SerialNumber_ = (NSString *) CYIOGetValue("IOService:/", @"IOPlatformSerialNumber");
10456     ChipID_ = [CYHex((NSData *) CYIOGetValue("IODeviceTree:/chosen", @"unique-chip-id"), true) uppercaseString];
10457     BBSNum_ = CYHex((NSData *) CYIOGetValue("IOService:/AppleARMPE/baseband", @"snum"), false);
10458
10459     UniqueID_ = UniqueIdentifier(device);
10460
10461     if (NSDictionary *info = [NSDictionary dictionaryWithContentsOfFile:@"/Applications/MobileSafari.app/Info.plist"]) {
10462         Product_ = [info objectForKey:@"SafariProductVersion"];
10463         Safari_ = [info objectForKey:@"CFBundleVersion"];
10464     }
10465
10466     NSString *agent([NSString stringWithFormat:@"Cydia/%@ CyF/%.2f", Cydia_, kCFCoreFoundationVersionNumber]);
10467
10468     if (RegEx match = RegEx("([0-9]+(\\.[0-9]+)+).*", Safari_))
10469         agent = [NSString stringWithFormat:@"Safari/%@ %@", match[1], agent];
10470     if (RegEx match = RegEx("([0-9]+[A-Z][0-9]+[a-z]?).*", System_))
10471         agent = [NSString stringWithFormat:@"Mobile/%@ %@", match[1], agent];
10472     if (RegEx match = RegEx("([0-9]+(\\.[0-9]+)+).*", Product_))
10473         agent = [NSString stringWithFormat:@"Version/%@ %@", match[1], agent];
10474
10475     UserAgent_ = agent;
10476     /* }}} */
10477     /* Load Database {{{ */
10478     SectionMap_ = [[[NSDictionary alloc] initWithContentsOfFile:[[NSBundle mainBundle] pathForResource:@"Sections" ofType:@"plist"]] autorelease];
10479
10480     _trace();
10481     mkdir("/var/mobile/Library/Cydia", 0755);
10482     MetaFile_.Open("/var/mobile/Library/Cydia/metadata.cb0");
10483     _trace();
10484
10485     Values_ = AutoreleaseDeepMutableCopyOfDictionary(CFPreferencesCopyAppValue(CFSTR("CydiaValues"), CFSTR("com.saurik.Cydia")));
10486     Sections_ = AutoreleaseDeepMutableCopyOfDictionary(CFPreferencesCopyAppValue(CFSTR("CydiaSections"), CFSTR("com.saurik.Cydia")));
10487     Sources_ = AutoreleaseDeepMutableCopyOfDictionary(CFPreferencesCopyAppValue(CFSTR("CydiaSources"), CFSTR("com.saurik.Cydia")));
10488     Version_ = [(NSNumber *) CFPreferencesCopyAppValue(CFSTR("CydiaVersion"), CFSTR("com.saurik.Cydia")) autorelease];
10489
10490     _trace();
10491     NSDictionary *metadata([[[NSMutableDictionary alloc] initWithContentsOfFile:@"/var/lib/cydia/metadata.plist"] autorelease]);
10492
10493     if (Values_ == nil)
10494         Values_ = [metadata objectForKey:@"Values"];
10495     if (Values_ == nil)
10496         Values_ = [[[NSMutableDictionary alloc] initWithCapacity:4] autorelease];
10497
10498     if (Sections_ == nil)
10499         Sections_ = [metadata objectForKey:@"Sections"];
10500     if (Sections_ == nil)
10501         Sections_ = [[[NSMutableDictionary alloc] initWithCapacity:32] autorelease];
10502
10503     if (Sources_ == nil)
10504         Sources_ = [metadata objectForKey:@"Sources"];
10505     if (Sources_ == nil)
10506         Sources_ = [[[NSMutableDictionary alloc] initWithCapacity:0] autorelease];
10507
10508     // XXX: this wrong, but in a way that doesn't matter :/
10509     if (Version_ == nil)
10510         Version_ = [metadata objectForKey:@"Version"];
10511     if (Version_ == nil)
10512         Version_ = [NSNumber numberWithUnsignedInt:0];
10513
10514     if (NSDictionary *packages = [metadata objectForKey:@"Packages"]) {
10515         bool fail(false);
10516         CFDictionaryApplyFunction((CFDictionaryRef) packages, &PackageImport, &fail);
10517         _trace();
10518         if (fail)
10519             NSLog(@"unable to import package preferences... from 2010? oh well :/");
10520     }
10521
10522     if ([Version_ unsignedIntValue] == 0) {
10523         CydiaAddSource(@"http://apt.thebigboss.org/repofiles/cydia/", @"stable", [NSMutableArray arrayWithObject:@"main"]);
10524         CydiaAddSource(@"http://apt.modmyi.com/", @"stable", [NSMutableArray arrayWithObject:@"main"]);
10525         CydiaAddSource(@"http://cydia.zodttd.com/repo/cydia/", @"stable", [NSMutableArray arrayWithObject:@"main"]);
10526         CydiaAddSource(@"http://repo666.ultrasn0w.com/", @"./");
10527
10528         Version_ = [NSNumber numberWithUnsignedInt:1];
10529
10530         if (NSMutableDictionary *cache = [NSMutableDictionary dictionaryWithContentsOfFile:@ CacheState_]) {
10531             [cache removeObjectForKey:@"LastUpdate"];
10532             [cache writeToFile:@ CacheState_ atomically:YES];
10533         }
10534     }
10535
10536     _H<NSMutableArray> broken([NSMutableArray array]);
10537     for (NSString *key in (id) Sources_)
10538         if ([key rangeOfCharacterFromSet:[NSCharacterSet characterSetWithCharactersInString:@"# "]].location != NSNotFound || ![([[Sources_ objectForKey:key] objectForKey:@"URI"] ?: @"/") hasSuffix:@"/"])
10539             [broken addObject:key];
10540     if ([broken count] != 0)
10541         for (NSString *key in (id) broken)
10542             [Sources_ removeObjectForKey:key];
10543     broken = nil;
10544
10545     SaveConfig(nil);
10546     system("/usr/libexec/cydia/cydo /bin/rm -f /var/lib/cydia/metadata.plist");
10547     /* }}} */
10548
10549     Finishes_ = [NSArray arrayWithObjects:@"return", @"reopen", @"restart", @"reload", @"reboot", nil];
10550
10551     if (kCFCoreFoundationVersionNumber > 1000)
10552         system("/usr/libexec/cydia/cydo /usr/libexec/cydia/setnsfpn /var/lib");
10553
10554     int version([[NSString stringWithContentsOfFile:@"/var/lib/cydia/firmware.ver"] intValue]);
10555
10556     if (access("/User", F_OK) != 0 || version != 6) {
10557         _trace();
10558         system("/usr/libexec/cydia/cydo /usr/libexec/cydia/firmware.sh");
10559         _trace();
10560     }
10561
10562     if (access("/tmp/cydia.chk", F_OK) == 0) {
10563         if (unlink([Cache("pkgcache.bin") UTF8String]) == -1)
10564             _assert(errno == ENOENT);
10565         if (unlink([Cache("srcpkgcache.bin") UTF8String]) == -1)
10566             _assert(errno == ENOENT);
10567     }
10568
10569     system("/usr/libexec/cydia/cydo /bin/ln -sf /var/mobile/Library/Caches/com.saurik.Cydia/sources.list /etc/apt/sources.list.d/cydia.list");
10570
10571     /* APT Initialization {{{ */
10572     _assert(pkgInitConfig(*_config));
10573     _assert(pkgInitSystem(*_config, _system));
10574
10575     _config->Set("Acquire::AllowInsecureRepositories", true);
10576     _config->Set("Acquire::Check-Valid-Until", false);
10577     _config->Set("Dir::Bin::Methods::store", "/Applications/Cydia.app/store");
10578
10579     _config->Set("pkgCacheGen::ForceEssential", "");
10580
10581     if (translation != NULL)
10582         _config->Set("APT::Acquire::Translation", translation);
10583     _config->Set("Acquire::Languages", languages);
10584
10585     // XXX: this timeout might be important :(
10586     //_config->Set("Acquire::http::Timeout", 15);
10587
10588     _config->Set("Acquire::http::MaxParallel", usermem >= 384 * 1024 * 1024 ? 16 : 3);
10589
10590     mkdir([Cache("archives") UTF8String], 0755);
10591     mkdir([Cache("archives/partial") UTF8String], 0755);
10592     _config->Set("Dir::Cache", [Cache_ UTF8String]);
10593
10594     symlink("/var/lib/apt/extended_states", [Cache("extended_states") UTF8String]);
10595     _config->Set("Dir::State", [Cache_ UTF8String]);
10596
10597     mkdir([Cache("lists") UTF8String], 0755);
10598     mkdir([Cache("lists/partial") UTF8String], 0755);
10599     mkdir([Cache("periodic") UTF8String], 0755);
10600     _config->Set("Dir::State::Lists", [Cache("lists") UTF8String]);
10601
10602     std::string logs("/var/mobile/Library/Logs/Cydia");
10603     mkdir(logs.c_str(), 0755);
10604     _config->Set("Dir::Log", logs);
10605
10606     _config->Set("Dir::Bin::dpkg", "/usr/libexec/cydia/cydo");
10607     /* }}} */
10608     /* Color Choices {{{ */
10609     space_ = CGColorSpaceCreateDeviceRGB();
10610
10611     Blue_.Set(space_, 0.2, 0.2, 1.0, 1.0);
10612     Blueish_.Set(space_, 0x19/255.f, 0x32/255.f, 0x50/255.f, 1.0);
10613     Black_.Set(space_, 0.0, 0.0, 0.0, 1.0);
10614     Folder_.Set(space_, 0x8e/255.f, 0x8e/255.f, 0x93/255.f, 1.0);
10615     Off_.Set(space_, 0.9, 0.9, 0.9, 1.0);
10616     White_.Set(space_, 1.0, 1.0, 1.0, 1.0);
10617     Gray_.Set(space_, 0.4, 0.4, 0.4, 1.0);
10618     Green_.Set(space_, 0.0, 0.5, 0.0, 1.0);
10619     Purple_.Set(space_, 0.0, 0.0, 0.7, 1.0);
10620     Purplish_.Set(space_, 0.4, 0.4, 0.8, 1.0);
10621
10622     InstallingColor_ = [UIColor colorWithRed:0.88f green:1.00f blue:0.88f alpha:1.00f];
10623     RemovingColor_ = [UIColor colorWithRed:1.00f green:0.88f blue:0.88f alpha:1.00f];
10624     /* }}}*/
10625     /* UIKit Configuration {{{ */
10626     // XXX: I have a feeling this was important
10627     //UIKeyboardDisableAutomaticAppearance();
10628     /* }}} */
10629
10630     $SBSSetInterceptsMenuButtonForever = reinterpret_cast<void (*)(bool)>(dlsym(RTLD_DEFAULT, "SBSSetInterceptsMenuButtonForever"));
10631     $SBSCopyIconImagePNGDataForDisplayIdentifier = reinterpret_cast<NSData *(*)(NSString *)>(dlsym(RTLD_DEFAULT, "SBSCopyIconImagePNGDataForDisplayIdentifier"));
10632
10633     const char *symbol(kCFCoreFoundationVersionNumber >= 800 ? "MGGetBoolAnswer" : "GSSystemHasCapability");
10634     BOOL (*GSSystemHasCapability)(CFStringRef) = reinterpret_cast<BOOL (*)(CFStringRef)>(dlsym(RTLD_DEFAULT, symbol));
10635     bool fast = GSSystemHasCapability != NULL && GSSystemHasCapability(CFSTR("armv7"));
10636
10637     PulseInterval_ = fast ? 50000 : 500000;
10638
10639     Colon_ = UCLocalize("COLON_DELIMITED");
10640     Elision_ = UCLocalize("ELISION");
10641     Error_ = UCLocalize("ERROR");
10642     Warning_ = UCLocalize("WARNING");
10643
10644     _trace();
10645     int value(UIApplicationMain(argc, argv, @"Cydia", @"Cydia"));
10646
10647     CGColorSpaceRelease(space_);
10648     CFRelease(Locale_);
10649
10650     [pool release];
10651     return value;
10652 }