CyteKit/WebViewController.mm

   1 #include "CyteKit/UCPlatform.h"
   2 #include "CyteKit/WebViewController.h"
   3
   4 #include "CyteKit/MFMailComposeViewController-MailToURL.h"
   5
   6 #include "iPhonePrivate.h"
   7
   8 #include "CyteKit/IndirectDelegate.h"
   9 #include "CyteKit/Localize.h"
  10 #include "CyteKit/WebViewController.h"
  11 #include "CyteKit/PerlCompatibleRegEx.hpp"
  12 #include "CyteKit/WebThreadLocked.hpp"
  13
  14 //#include <QuartzCore/CALayer.h>
  15 // XXX: fix the minimum requirement
  16 extern NSString * const kCAFilterNearest;
  17
  18 #include <WebCore/WebCoreThread.h>
  19
  20 #import <WebKit/WebKitErrors.h>
  21 #import <WebKit/WebPreferences.h>
  22
  23 #include <WebKit/DOMCSSPrimitiveValue.h>
  24 #include <WebKit/DOMCSSStyleDeclaration.h>
  25 #include <WebKit/DOMDocument.h>
  26 #include <WebKit/DOMHTMLBodyElement.h>
  27 #include <WebKit/DOMRGBColor.h>
  28
  29 #include <dlfcn.h>
  30 #include <objc/runtime.h>
  31
  32 #define ForSaurik 0
  33 #define DefaultTimeout_ 120.0
  34
  35 #define ShowInternals 0
  36 #define LogBrowser 0
  37 #define LogMessages 0
  38
  39 #define lprintf(args...) fprintf(stderr, args)
  40
  41 JSValueRef (*$JSObjectCallAsFunction)(JSContextRef, JSObjectRef, JSObjectRef, size_t, const JSValueRef[], JSValueRef *);
  42
  43 // XXX: centralize these special class things to some file or mechanism?
  44 static Class $MFMailComposeViewController;
  45
  46 float CYScrollViewDecelerationRateNormal;
  47
  48 @interface WebView (Apple)
  49 - (void) _setLayoutInterval:(float)interval;
  50 - (void) _setAllowsMessaging:(BOOL)allows;
  51 @end
  52
  53 @interface WebFrame (Cydia)
  54 - (void) cydia$updateHeight;
  55 @end
  56
  57 @implementation WebFrame (Cydia)
  58
  59 - (NSString *) description {
  60     return [NSString stringWithFormat:@"<%s: %p, %@>", class_getName([self class]), self, [[[([self provisionalDataSource] ?: [self dataSource]) request] URL] absoluteString]];
  61 }
  62
  63 - (void) cydia$updateHeight {
  64     [[[self frameElement] style]
  65         setProperty:@"height"
  66         value:[NSString stringWithFormat:@"%dpx",
  67             [[[self DOMDocument] body] scrollHeight]]
  68         priority:nil];
  69 }
  70
  71 @end
  72
  73 /* Indirect Delegate {{{ */
  74 @implementation IndirectDelegate
  75
  76 - (id) delegate {
  77     return delegate_;
  78 }
  79
  80 - (void) setDelegate:(id)delegate {
  81     delegate_ = delegate;
  82 }
  83
  84 - (id) initWithDelegate:(id)delegate {
  85     delegate_ = delegate;
  86     return self;
  87 }
  88
  89 - (IMP) methodForSelector:(SEL)sel {
  90     if (IMP method = [super methodForSelector:sel])
  91         return method;
  92     fprintf(stderr, "methodForSelector:[%s] == NULL\n", sel_getName(sel));
  93     return NULL;
  94 }
  95
  96 - (BOOL) respondsToSelector:(SEL)sel {
  97     if ([super respondsToSelector:sel])
  98         return YES;
  99
 100     // XXX: WebThreadCreateNSInvocation returns nil
 101
 102 #if ShowInternals
 103     fprintf(stderr, "[%s]R?%s\n", class_getName(self->isa), sel_getName(sel));
 104 #endif
 105
 106     return delegate_ == nil ? NO : [delegate_ respondsToSelector:sel];
 107 }
 108
 109 - (NSMethodSignature *) methodSignatureForSelector:(SEL)sel {
 110     if (NSMethodSignature *method = [super methodSignatureForSelector:sel])
 111         return method;
 112
 113 #if ShowInternals
 114     fprintf(stderr, "[%s]S?%s\n", class_getName(self->isa), sel_getName(sel));
 115 #endif
 116
 117     if (delegate_ != nil)
 118         if (NSMethodSignature *sig = [delegate_ methodSignatureForSelector:sel])
 119             return sig;
 120
 121     // XXX: I fucking hate Apple so very very bad
 122     return [NSMethodSignature signatureWithObjCTypes:"v@:"];
 123 }
 124
 125 - (void) forwardInvocation:(NSInvocation *)inv {
 126     SEL sel = [inv selector];
 127     if (delegate_ != nil && [delegate_ respondsToSelector:sel])
 128         [inv invokeWithTarget:delegate_];
 129 }
 130
 131 @end
 132 /* }}} */
 133
 134 @implementation CyteWebViewController
 135
 136 #if ShowInternals
 137 #include "CyteKit/UCInternal.h"
 138 #endif
 139
 140 + (void) _initialize {
 141     [WebPreferences _setInitialDefaultTextEncodingToSystemEncoding];
 142
 143     void *js(NULL);
 144     if (js == NULL)
 145         js = dlopen("/System/Library/Frameworks/JavaScriptCore.framework/JavaScriptCore", RTLD_GLOBAL | RTLD_LAZY);
 146     if (js == NULL)
 147         js = dlopen("/System/Library/PrivateFrameworks/JavaScriptCore.framework/JavaScriptCore", RTLD_GLOBAL | RTLD_LAZY);
 148     if (js != NULL)
 149         $JSObjectCallAsFunction = reinterpret_cast<JSValueRef (*)(JSContextRef, JSObjectRef, JSObjectRef, size_t, const JSValueRef[], JSValueRef *)>(dlsym(js, "JSObjectCallAsFunction"));
 150
 151     dlopen("/System/Library/Frameworks/MessageUI.framework/MessageUI", RTLD_GLOBAL | RTLD_LAZY);
 152     $MFMailComposeViewController = objc_getClass("MFMailComposeViewController");
 153
 154     if (float *_UIScrollViewDecelerationRateNormal = reinterpret_cast<float *>(dlsym(RTLD_DEFAULT, "UIScrollViewDecelerationRateNormal")))
 155         CYScrollViewDecelerationRateNormal = *_UIScrollViewDecelerationRateNormal;
 156     else // XXX: this actually might be fast on some older systems: we should look into this
 157         CYScrollViewDecelerationRateNormal = 0.998;
 158 }
 159
 160 - (bool) retainsNetworkActivityIndicator {
 161     return true;
 162 }
 163
 164 - (void) releaseNetworkActivityIndicator {
 165     if ([loading_ count] != 0) {
 166         [loading_ removeAllObjects];
 167
 168         if ([self retainsNetworkActivityIndicator])
 169             [delegate_ releaseNetworkActivityIndicator];
 170     }
 171 }
 172
 173 - (void) dealloc {
 174 #if LogBrowser
 175     NSLog(@"[CyteWebViewController dealloc]");
 176 #endif
 177
 178     [self releaseNetworkActivityIndicator];
 179
 180     [super dealloc];
 181 }
 182
 183 - (NSString *) description {
 184     return [NSString stringWithFormat:@"<%s: %p, %@>", class_getName([self class]), self, [[request_ URL] absoluteString]];
 185 }
 186
 187 - (CyteWebView *) webView {
 188     return (CyteWebView *) [self view];
 189 }
 190
 191 - (NSURL *) URLWithURL:(NSURL *)url {
 192     return url;
 193 }
 194
 195 - (NSURLRequest *) requestWithURL:(NSURL *)url cachePolicy:(NSURLRequestCachePolicy)policy referrer:(NSString *)referrer {
 196     NSMutableURLRequest *request([NSMutableURLRequest
 197         requestWithURL:[self URLWithURL:url]
 198         cachePolicy:policy
 199         timeoutInterval:DefaultTimeout_
 200     ]);
 201
 202     [request setValue:referrer forHTTPHeaderField:@"Referer"];
 203
 204     return request;
 205 }
 206
 207 - (void) setRequest:(NSURLRequest *)request {
 208     _assert(request_ == nil);
 209     request_ = request;
 210 }
 211
 212 - (void) setURL:(NSURL *)url {
 213     [self setURL:url withReferrer:nil];
 214 }
 215
 216 - (void) setURL:(NSURL *)url withReferrer:(NSString *)referrer {
 217     [self setRequest:[self requestWithURL:url cachePolicy:NSURLRequestUseProtocolCachePolicy referrer:referrer]];
 218 }
 219
 220 - (void) loadURL:(NSURL *)url cachePolicy:(NSURLRequestCachePolicy)policy {
 221     [self loadRequest:[self requestWithURL:url cachePolicy:policy referrer:nil]];
 222 }
 223
 224 - (void) loadURL:(NSURL *)url {
 225     [self loadURL:url cachePolicy:NSURLRequestUseProtocolCachePolicy];
 226 }
 227
 228 - (void) loadRequest:(NSURLRequest *)request {
 229 #if LogBrowser
 230     NSLog(@"loadRequest:%@", request);
 231 #endif
 232
 233     error_ = false;
 234     ready_ = true;
 235
 236     WebThreadLocked lock;
 237     [[self webView] loadRequest:request];
 238 }
 239
 240 - (void) reloadURLWithCache:(BOOL)cache {
 241     if (request_ == nil)
 242         return;
 243
 244     NSMutableURLRequest *request([request_ mutableCopy]);
 245     [request setCachePolicy:(cache ? NSURLRequestUseProtocolCachePolicy : NSURLRequestReloadIgnoringLocalCacheData)];
 246
 247     request_ = request;
 248
 249     if (cache || [request_ HTTPBody] == nil && [request_ HTTPBodyStream] == nil)
 250         [self loadRequest:request_];
 251     else {
 252         UIAlertView *alert = [[[UIAlertView alloc]
 253             initWithTitle:UCLocalize("RESUBMIT_FORM")
 254             message:nil
 255             delegate:self
 256             cancelButtonTitle:UCLocalize("CANCEL")
 257             otherButtonTitles:
 258                 UCLocalize("SUBMIT"),
 259             nil
 260         ] autorelease];
 261
 262         [alert setContext:@"submit"];
 263         [alert show];
 264     }
 265 }
 266
 267 - (void) reloadData {
 268     [super reloadData];
 269
 270     if (ready_)
 271         [self dispatchEvent:@"CydiaReloadData"];
 272     else
 273         [self reloadURLWithCache:YES];
 274 }
 275
 276 - (void) setButtonImage:(NSString *)button withStyle:(NSString *)style toFunction:(id)function {
 277     custom_ = button;
 278     style_ = style;
 279     function_ = function;
 280
 281     [self performSelectorOnMainThread:@selector(applyRightButton) withObject:nil waitUntilDone:NO];
 282 }
 283
 284 - (void) setButtonTitle:(NSString *)button withStyle:(NSString *)style toFunction:(id)function {
 285     custom_ = button;
 286     style_ = style;
 287     function_ = function;
 288
 289     [self performSelectorOnMainThread:@selector(applyRightButton) withObject:nil waitUntilDone:NO];
 290 }
 291
 292 - (void) removeButton {
 293     custom_ = [NSNull null];
 294     [self performSelectorOnMainThread:@selector(applyRightButton) withObject:nil waitUntilDone:NO];
 295 }
 296
 297 - (void) scrollToBottomAnimated:(NSNumber *)animated {
 298     CGSize size([scroller_ contentSize]);
 299     CGPoint offset([scroller_ contentOffset]);
 300     CGRect frame([scroller_ frame]);
 301
 302     if (size.height - offset.y < frame.size.height + 20.f) {
 303         CGRect rect = {{0, size.height-1}, {size.width, 1}};
 304         [scroller_ scrollRectToVisible:rect animated:[animated boolValue]];
 305     }
 306 }
 307
 308 - (void) _setViewportWidth {
 309     [[[self webView] _documentView] setViewportSize:CGSizeMake(width_, UIWebViewGrowsAndShrinksToFitHeight) forDocumentTypes:0x10];
 310 }
 311
 312 - (void) setViewportWidth:(float)width {
 313     width_ = width != 0 ? width : [[self class] defaultWidth];
 314     [self _setViewportWidth];
 315 }
 316
 317 - (void) _setViewportWidthOnMainThread:(NSNumber *)width {
 318     [self setViewportWidth:[width floatValue]];
 319 }
 320
 321 - (void) setViewportWidthOnMainThread:(float)width {
 322     [self performSelectorOnMainThread:@selector(_setViewportWidthOnMainThread:) withObject:[NSNumber numberWithFloat:width] waitUntilDone:NO];
 323 }
 324
 325 - (void) webViewUpdateViewSettings:(UIWebView *)view {
 326     [self _setViewportWidth];
 327 }
 328
 329 - (void) mailComposeController:(MFMailComposeViewController*)controller didFinishWithResult:(MFMailComposeResult)result error:(NSError*)error {
 330     [self dismissModalViewControllerAnimated:YES];
 331 }
 332
 333 - (void) _setupMail:(MFMailComposeViewController *)controller {
 334 }
 335
 336 - (void) _openMailToURL:(NSURL *)url {
 337     if ($MFMailComposeViewController != nil && [$MFMailComposeViewController canSendMail]) {
 338         MFMailComposeViewController *controller([[[$MFMailComposeViewController alloc] init] autorelease]);
 339         [controller setMailComposeDelegate:self];
 340
 341         [controller setMailToURL:url];
 342
 343         [self _setupMail:controller];
 344
 345         [self presentModalViewController:controller animated:YES];
 346         return;
 347     }
 348
 349     UIApplication *app([UIApplication sharedApplication]);
 350     if ([app respondsToSelector:@selector(openURL:asPanel:)])
 351         [app openURL:url asPanel:YES];
 352     else
 353         [app openURL:url];
 354 }
 355
 356 - (bool) _allowJavaScriptPanel {
 357     return true;
 358 }
 359
 360 - (bool) allowsNavigationAction {
 361     return allowsNavigationAction_;
 362 }
 363
 364 - (void) setAllowsNavigationAction:(bool)value {
 365     allowsNavigationAction_ = value;
 366 }
 367
 368 - (void) setAllowsNavigationActionByNumber:(NSNumber *)value {
 369     [self setAllowsNavigationAction:[value boolValue]];
 370 }
 371
 372 - (void) popViewControllerWithNumber:(NSNumber *)value {
 373     UINavigationController *navigation([self navigationController]);
 374     if ([navigation topViewController] == self)
 375         [navigation popViewControllerAnimated:[value boolValue]];
 376 }
 377
 378 - (void) _didFailWithError:(NSError *)error forFrame:(WebFrame *)frame {
 379     NSValue *object([NSValue valueWithNonretainedObject:frame]);
 380     if (![loading_ containsObject:object])
 381         return;
 382     [loading_ removeObject:object];
 383
 384     [self _didFinishLoading];
 385
 386     if ([[error domain] isEqualToString:NSURLErrorDomain] && [error code] == NSURLErrorCancelled)
 387         return;
 388
 389     if ([[error domain] isEqualToString:WebKitErrorDomain] && [error code] == WebKitErrorFrameLoadInterruptedByPolicyChange) {
 390         request_ = nil;
 391         return;
 392     }
 393
 394     if ([frame parentFrame] == nil) {
 395         [self loadURL:[NSURL URLWithString:[NSString stringWithFormat:@"%@?%@",
 396             [[NSURL fileURLWithPath:[[NSBundle mainBundle] pathForResource:@"error" ofType:@"html"]] absoluteString],
 397             [[error localizedDescription] stringByAddingPercentEscapes]
 398         ]]];
 399
 400         error_ = true;
 401     }
 402 }
 403
 404 - (void) pushRequest:(NSURLRequest *)request forAction:(NSDictionary *)action asPop:(bool)pop {
 405     WebFrame *frame(nil);
 406     if (NSDictionary *WebActionElement = [action objectForKey:@"WebActionElementKey"])
 407         frame = [WebActionElement objectForKey:@"WebElementFrame"];
 408     if (frame == nil)
 409         frame = [[[[self webView] _documentView] webView] mainFrame];
 410
 411     WebDataSource *source([frame provisionalDataSource] ?: [frame dataSource]);
 412     NSString *referrer([request valueForHTTPHeaderField:@"Referer"] ?: [[[source request] URL] absoluteString]);
 413
 414     NSURL *url([request URL]);
 415
 416     // XXX: filter to internal usage?
 417     CyteViewController *page([delegate_ pageForURL:url forExternal:NO withReferrer:referrer]);
 418
 419     if (page == nil) {
 420         CyteWebViewController *browser([[[class_ alloc] init] autorelease]);
 421         [browser setRequest:request];
 422         page = browser;
 423     }
 424
 425     [page setDelegate:delegate_];
 426     [page setPageColor:color_];
 427
 428     if (!pop) {
 429         [[self navigationItem] setTitle:title_];
 430
 431         [[self navigationController] pushViewController:page animated:YES];
 432     } else {
 433         UINavigationController *navigation([[[UINavigationController alloc] initWithRootViewController:page] autorelease]);
 434
 435         [navigation setDelegate:delegate_];
 436
 437         [[page navigationItem] setLeftBarButtonItem:[[[UIBarButtonItem alloc]
 438             initWithTitle:UCLocalize("CLOSE")
 439             style:UIBarButtonItemStylePlain
 440             target:page
 441             action:@selector(close)
 442         ] autorelease]];
 443
 444         [[self navigationController] presentModalViewController:navigation animated:YES];
 445     }
 446 }
 447
 448 // CyteWebViewDelegate {{{
 449 - (void) webView:(WebView *)view addMessageToConsole:(NSDictionary *)message {
 450 #if LogMessages
 451     static Pcre irritating("^(?"
 452         ":" "The page at .* displayed insecure content from .*\\."
 453         "|" "Unsafe JavaScript attempt to access frame with URL .* from frame with URL .*\\. Domains, protocols and ports must match\\."
 454     ")\\n$");
 455
 456     if (NSString *data = [message objectForKey:@"message"])
 457         if (irritating(data))
 458             return;
 459
 460     NSLog(@"addMessageToConsole:%@", message);
 461 #endif
 462 }
 463
 464 - (void) webView:(WebView *)view decidePolicyForNavigationAction:(NSDictionary *)action request:(NSURLRequest *)request frame:(WebFrame *)frame decisionListener:(id<WebPolicyDecisionListener>)listener {
 465 #if LogBrowser
 466     NSLog(@"decidePolicyForNavigationAction:%@ request:%@ %@ frame:%@", action, request, [request allHTTPHeaderFields], frame);
 467 #endif
 468
 469     if ([frame parentFrame] == nil) {
 470         if (!error_) {
 471             NSURL *url(request == nil ? nil : [request URL]);
 472
 473             if (request_ != nil && ![[request_ URL] isEqual:url] && ![self allowsNavigationAction]) {
 474                 if (url != nil)
 475                     [self pushRequest:request forAction:action asPop:NO];
 476                 [listener ignore];
 477             }
 478         }
 479     }
 480 }
 481
 482 - (void) webView:(WebView *)view didDecidePolicy:(CYWebPolicyDecision)decision forNavigationAction:(NSDictionary *)action request:(NSURLRequest *)request frame:(WebFrame *)frame {
 483 #if LogBrowser
 484     NSLog(@"didDecidePolicy:%u forNavigationAction:%@ request:%@ frame:%@", decision, action, request, [request allHTTPHeaderFields], frame);
 485 #endif
 486
 487     if ([frame parentFrame] == nil) {
 488         switch (decision) {
 489             case CYWebPolicyDecisionIgnore:
 490                 if ([[request_ URL] isEqual:[request URL]])
 491                     request_ = nil;
 492             break;
 493
 494             case CYWebPolicyDecisionUse:
 495                 if (!error_)
 496                     request_ = request;
 497             break;
 498
 499             default:
 500             break;
 501         }
 502     }
 503 }
 504
 505 - (void) webView:(WebView *)view decidePolicyForNewWindowAction:(NSDictionary *)action request:(NSURLRequest *)request newFrameName:(NSString *)name decisionListener:(id<WebPolicyDecisionListener>)listener {
 506 #if LogBrowser
 507     NSLog(@"decidePolicyForNewWindowAction:%@ request:%@ %@ newFrameName:%@", action, request, [request allHTTPHeaderFields], name);
 508 #endif
 509
 510     NSURL *url([request URL]);
 511     if (url == nil)
 512         return;
 513
 514     if ([name isEqualToString:@"_open"])
 515         [delegate_ openURL:url];
 516     else {
 517         NSString *scheme([[url scheme] lowercaseString]);
 518         if ([scheme isEqualToString:@"mailto"])
 519             [self _openMailToURL:url];
 520         else
 521             [self pushRequest:request forAction:action asPop:[name isEqualToString:@"_popup"]];
 522     }
 523
 524     [listener ignore];
 525 }
 526
 527 - (void) webView:(WebView *)view didClearWindowObject:(WebScriptObject *)window forFrame:(WebFrame *)frame {
 528 #if LogBrowser
 529     NSLog(@"didClearWindowObject:%@ forFrame:%@", window, frame);
 530 #endif
 531 }
 532
 533 - (void) webView:(WebView *)view didCommitLoadForFrame:(WebFrame *)frame {
 534 #if LogBrowser
 535     NSLog(@"didCommitLoadForFrame:%@", frame);
 536 #endif
 537
 538     if ([frame parentFrame] == nil) {
 539         loaded_ = true;
 540     }
 541 }
 542
 543 - (void) webView:(WebView *)view didFailLoadWithError:(NSError *)error forFrame:(WebFrame *)frame {
 544 #if LogBrowser
 545     NSLog(@"didFailLoadWithError:%@ forFrame:%@", error, frame);
 546 #endif
 547
 548     [self _didFailWithError:error forFrame:frame];
 549 }
 550
 551 - (void) webView:(WebView *)view didFailProvisionalLoadWithError:(NSError *)error forFrame:(WebFrame *)frame {
 552 #if LogBrowser
 553     NSLog(@"didFailProvisionalLoadWithError:%@ forFrame:%@", error, frame);
 554 #endif
 555
 556     [self _didFailWithError:error forFrame:frame];
 557 }
 558
 559 - (void) webView:(WebView *)view didFinishLoadForFrame:(WebFrame *)frame {
 560     NSValue *object([NSValue valueWithNonretainedObject:frame]);
 561     if (![loading_ containsObject:object])
 562         return;
 563     [loading_ removeObject:object];
 564
 565     if ([frame parentFrame] == nil) {
 566         if (DOMDocument *document = [frame DOMDocument])
 567             if (DOMNodeList *bodies = [document getElementsByTagName:@"body"])
 568                 for (DOMHTMLBodyElement *body in (id) bodies) {
 569                     DOMCSSStyleDeclaration *style([document getComputedStyle:body pseudoElement:nil]);
 570
 571                     UIColor *uic(nil);
 572
 573                     if (DOMCSSPrimitiveValue *color = static_cast<DOMCSSPrimitiveValue *>([style getPropertyCSSValue:@"background-color"])) {
 574                         if ([color primitiveType] == DOM_CSS_RGBCOLOR) {
 575                             DOMRGBColor *rgb([color getRGBColorValue]);
 576
 577                             float red([[rgb red] getFloatValue:DOM_CSS_NUMBER]);
 578                             float green([[rgb green] getFloatValue:DOM_CSS_NUMBER]);
 579                             float blue([[rgb blue] getFloatValue:DOM_CSS_NUMBER]);
 580                             float alpha([[rgb alpha] getFloatValue:DOM_CSS_NUMBER]);
 581
 582                             if (alpha == 1)
 583                                 uic = [UIColor
 584                                     colorWithRed:(red / 255)
 585                                     green:(green / 255)
 586                                     blue:(blue / 255)
 587                                     alpha:alpha
 588                                 ];
 589                         }
 590                     }
 591
 592                     [self setPageColor:uic];
 593                     [scroller_ setBackgroundColor:color_];
 594                     break;
 595                 }
 596     }
 597
 598     [self _didFinishLoading];
 599 }
 600
 601 - (void) webView:(WebView *)view didReceiveTitle:(NSString *)title forFrame:(WebFrame *)frame {
 602     if ([frame parentFrame] != nil)
 603         return;
 604
 605     title_ = title;
 606
 607     [[self navigationItem] setTitle:title_];
 608 }
 609
 610 - (void) webView:(WebView *)view didStartProvisionalLoadForFrame:(WebFrame *)frame {
 611 #if LogBrowser
 612     NSLog(@"didStartProvisionalLoadForFrame:%@", frame);
 613 #endif
 614
 615     [loading_ addObject:[NSValue valueWithNonretainedObject:frame]];
 616
 617     if ([frame parentFrame] == nil) {
 618         title_ = nil;
 619         custom_ = nil;
 620         style_ = nil;
 621         function_ = nil;
 622
 623         [registered_ removeAllObjects];
 624         timer_ = nil;
 625
 626         allowsNavigationAction_ = true;
 627
 628         [self setHidesNavigationBar:NO];
 629         [self setScrollAlwaysBounceVertical:true];
 630         [self setScrollIndicatorStyle:UIScrollViewIndicatorStyleDefault];
 631
 632         // XXX: do we still need to do this?
 633         [[self navigationItem] setTitle:nil];
 634     }
 635
 636     [self _didStartLoading];
 637 }
 638
 639 - (void) webView:(WebView *)view resource:(id)identifier didReceiveAuthenticationChallenge:(NSURLAuthenticationChallenge *)challenge fromDataSource:(WebDataSource *)source {
 640     challenge_ = [challenge retain];
 641
 642     NSURLProtectionSpace *space([challenge protectionSpace]);
 643     NSString *realm([space realm]);
 644     if (realm == nil)
 645         realm = @"";
 646
 647     UIAlertView *alert = [[[UIAlertView alloc]
 648         initWithTitle:realm
 649         message:nil
 650         delegate:self
 651         cancelButtonTitle:UCLocalize("CANCEL")
 652         otherButtonTitles:UCLocalize("LOGIN"), nil
 653     ] autorelease];
 654
 655     [alert setContext:@"challenge"];
 656     [alert setNumberOfRows:1];
 657
 658     [alert addTextFieldWithValue:@"" label:UCLocalize("USERNAME")];
 659     [alert addTextFieldWithValue:@"" label:UCLocalize("PASSWORD")];
 660
 661     UITextField *username([alert textFieldAtIndex:0]); {
 662         UITextInputTraits *traits([username textInputTraits]);
 663         [traits setAutocapitalizationType:UITextAutocapitalizationTypeNone];
 664         [traits setAutocorrectionType:UITextAutocorrectionTypeNo];
 665         [traits setKeyboardType:UIKeyboardTypeASCIICapable];
 666         [traits setReturnKeyType:UIReturnKeyNext];
 667     }
 668
 669     UITextField *password([alert textFieldAtIndex:1]); {
 670         UITextInputTraits *traits([password textInputTraits]);
 671         [traits setAutocapitalizationType:UITextAutocapitalizationTypeNone];
 672         [traits setAutocorrectionType:UITextAutocorrectionTypeNo];
 673         [traits setKeyboardType:UIKeyboardTypeASCIICapable];
 674         // XXX: UIReturnKeyDone
 675         [traits setReturnKeyType:UIReturnKeyNext];
 676         [traits setSecureTextEntry:YES];
 677     }
 678
 679     [alert show];
 680 }
 681
 682 - (NSURLRequest *) webView:(WebView *)view resource:(id)identifier willSendRequest:(NSURLRequest *)request redirectResponse:(NSURLResponse *)response fromDataSource:(WebDataSource *)source {
 683 #if LogBrowser
 684     NSLog(@"resource:%@ willSendRequest:%@ redirectResponse:%@ fromDataSource:%@", identifier, request, response, source);
 685 #endif
 686
 687     return request;
 688 }
 689
 690 - (bool) webView:(WebView *)view shouldRunJavaScriptAlertPanelWithMessage:(NSString *)message initiatedByFrame:(WebFrame *)frame {
 691     return [self _allowJavaScriptPanel];
 692 }
 693
 694 - (bool) webView:(WebView *)view shouldRunJavaScriptConfirmPanelWithMessage:(NSString *)message initiatedByFrame:(WebFrame *)frame {
 695     return [self _allowJavaScriptPanel];
 696 }
 697
 698 - (bool) webView:(WebView *)view shouldRunJavaScriptTextInputPanelWithPrompt:(NSString *)prompt defaultText:(NSString *)text initiatedByFrame:(WebFrame *)frame {
 699     return [self _allowJavaScriptPanel];
 700 }
 701
 702 - (void) webViewClose:(WebView *)view {
 703     [self close];
 704 }
 705 // }}}
 706
 707 - (void) close {
 708     [[[self navigationController] parentOrPresentingViewController] dismissModalViewControllerAnimated:YES];
 709 }
 710
 711 - (void) alertView:(UIAlertView *)alert clickedButtonAtIndex:(NSInteger)button {
 712     NSString *context([alert context]);
 713
 714     if ([context isEqualToString:@"sensitive"]) {
 715         switch (button) {
 716             case 1:
 717                 sensitive_ = [NSNumber numberWithBool:YES];
 718             break;
 719
 720             case 2:
 721                 sensitive_ = [NSNumber numberWithBool:NO];
 722             break;
 723         }
 724
 725         [alert dismissWithClickedButtonIndex:-1 animated:YES];
 726     } else if ([context isEqualToString:@"challenge"]) {
 727         id<NSURLAuthenticationChallengeSender> sender([challenge_ sender]);
 728
 729         if (button == [alert cancelButtonIndex])
 730             [sender cancelAuthenticationChallenge:challenge_];
 731         else if (button == [alert firstOtherButtonIndex]) {
 732             NSString *username([[alert textFieldAtIndex:0] text]);
 733             NSString *password([[alert textFieldAtIndex:1] text]);
 734
 735             NSURLCredential *credential([NSURLCredential credentialWithUser:username password:password persistence:NSURLCredentialPersistenceForSession]);
 736
 737             [sender useCredential:credential forAuthenticationChallenge:challenge_];
 738         }
 739
 740         challenge_ = nil;
 741
 742         [alert dismissWithClickedButtonIndex:-1 animated:YES];
 743     } else if ([context isEqualToString:@"submit"]) {
 744         if (button == [alert cancelButtonIndex]) {
 745         } else if (button == [alert firstOtherButtonIndex]) {
 746             if (request_ != nil) {
 747                 WebThreadLocked lock;
 748                 [[self webView] loadRequest:request_];
 749             }
 750         }
 751
 752         [alert dismissWithClickedButtonIndex:-1 animated:YES];
 753     }
 754 }
 755
 756 - (UIBarButtonItemStyle) rightButtonStyle {
 757     if (style_ == nil) normal:
 758         return UIBarButtonItemStylePlain;
 759     else if ([style_ isEqualToString:@"Normal"])
 760         return UIBarButtonItemStylePlain;
 761     else if ([style_ isEqualToString:@"Highlighted"])
 762         return UIBarButtonItemStyleDone;
 763     else goto normal;
 764 }
 765
 766 - (UIBarButtonItem *) customButton {
 767     if (custom_ == nil)
 768         return nil;
 769     else if ((/*clang:*/id) custom_ == [NSNull null])
 770         return (UIBarButtonItem *) [NSNull null];
 771
 772     return [[[UIBarButtonItem alloc]
 773         initWithTitle:static_cast<NSString *>(custom_.operator NSObject *())
 774         style:[self rightButtonStyle]
 775         target:self
 776         action:@selector(customButtonClicked)
 777     ] autorelease];
 778 }
 779
 780 - (UIBarButtonItem *) leftButton {
 781     UINavigationItem *item([self navigationItem]);
 782     if ([item backBarButtonItem] != nil && ![item hidesBackButton])
 783         return nil;
 784
 785     if (UINavigationController *navigation = [self navigationController])
 786         if ([[navigation parentOrPresentingViewController] modalViewController] == navigation)
 787             return [[[UIBarButtonItem alloc]
 788                 initWithTitle:UCLocalize("CLOSE")
 789                 style:UIBarButtonItemStylePlain
 790                 target:self
 791                 action:@selector(close)
 792             ] autorelease];
 793
 794     return nil;
 795 }
 796
 797 - (void) applyLeftButton {
 798     [[self navigationItem] setLeftBarButtonItem:[self leftButton]];
 799 }
 800
 801 - (UIBarButtonItem *) rightButton {
 802     return reloaditem_;
 803 }
 804
 805 - (void) applyLoadingTitle {
 806     [[self navigationItem] setTitle:UCLocalize("LOADING")];
 807 }
 808
 809 - (void) layoutRightButton {
 810     [[loadingitem_ view] addSubview:indicator_];
 811     [[loadingitem_ view] bringSubviewToFront:indicator_];
 812 }
 813
 814 - (void) applyRightButton {
 815     if ([self isLoading]) {
 816         [[self navigationItem] setRightBarButtonItem:loadingitem_ animated:YES];
 817         [self performSelector:@selector(layoutRightButton) withObject:nil afterDelay:0];
 818
 819         [indicator_ startAnimating];
 820         [self applyLoadingTitle];
 821     } else {
 822         [indicator_ stopAnimating];
 823
 824         UIBarButtonItem *button([self customButton]);
 825         if (button == nil)
 826             button = [self rightButton];
 827         else if (button == (UIBarButtonItem *) [NSNull null])
 828             button = nil;
 829
 830         [[self navigationItem] setRightBarButtonItem:button animated:YES];
 831     }
 832 }
 833
 834 - (void) didStartLoading {
 835     // Overridden in subclasses.
 836 }
 837
 838 - (void) _didStartLoading {
 839     [self applyRightButton];
 840
 841     if ([loading_ count] != 1)
 842         return;
 843
 844     if ([self retainsNetworkActivityIndicator])
 845         [delegate_ retainNetworkActivityIndicator];
 846
 847     [self didStartLoading];
 848 }
 849
 850 - (void) didFinishLoading {
 851     // Overridden in subclasses.
 852 }
 853
 854 - (void) _didFinishLoading {
 855     if ([loading_ count] != 0)
 856         return;
 857
 858     [self applyRightButton];
 859     [[self navigationItem] setTitle:title_];
 860
 861     if ([self retainsNetworkActivityIndicator])
 862         [delegate_ releaseNetworkActivityIndicator];
 863
 864     [self didFinishLoading];
 865 }
 866
 867 - (bool) isLoading {
 868     return [loading_ count] != 0;
 869 }
 870
 871 - (id) initWithWidth:(float)width ofClass:(Class)_class {
 872     if ((self = [super init]) != nil) {
 873         width_ = width;
 874         class_ = _class;
 875
 876         [self setPageColor:nil];
 877
 878         allowsNavigationAction_ = true;
 879
 880         loading_ = [NSMutableSet setWithCapacity:5];
 881         registered_ = [NSMutableSet setWithCapacity:5];
 882         indirect_ = [[[IndirectDelegate alloc] initWithDelegate:self] autorelease];
 883
 884         reloaditem_ = [[[UIBarButtonItem alloc]
 885             initWithTitle:UCLocalize("RELOAD")
 886             style:[self rightButtonStyle]
 887             target:self
 888             action:@selector(reloadButtonClicked)
 889         ] autorelease];
 890
 891         loadingitem_ = [[[UIBarButtonItem alloc]
 892             initWithTitle:(kCFCoreFoundationVersionNumber >= 800 ? @"       " : @" ")
 893             style:UIBarButtonItemStylePlain
 894             target:self
 895             action:@selector(reloadButtonClicked)
 896         ] autorelease];
 897
 898         UIActivityIndicatorViewStyle style;
 899         float left;
 900         if (kCFCoreFoundationVersionNumber >= 800) {
 901             style = UIActivityIndicatorViewStyleGray;
 902             left = 7;
 903         } else {
 904             style = UIActivityIndicatorViewStyleWhite;
 905             left = 15;
 906         }
 907
 908         indicator_ = [[[UIActivityIndicatorView alloc] initWithActivityIndicatorStyle:style] autorelease];
 909         [indicator_ setFrame:CGRectMake(left, 5, [indicator_ frame].size.width, [indicator_ frame].size.height)];
 910         [indicator_ setAutoresizingMask:UIViewAutoresizingFlexibleLeftMargin];
 911
 912         [self applyLeftButton];
 913         [self applyRightButton];
 914     } return self;
 915 }
 916
 917 - (NSString *) applicationNameForUserAgent {
 918     return nil;
 919 }
 920
 921 - (void) loadView {
 922     CGRect bounds([[UIScreen mainScreen] applicationFrame]);
 923
 924     webview_ = [[[CyteWebView alloc] initWithFrame:bounds] autorelease];
 925     [webview_ setDelegate:self];
 926     [self setView:webview_];
 927
 928     if ([webview_ respondsToSelector:@selector(setDataDetectorTypes:)])
 929         [webview_ setDataDetectorTypes:UIDataDetectorTypeAutomatic];
 930     else
 931         [webview_ setDetectsPhoneNumbers:NO];
 932
 933     [webview_ setScalesPageToFit:YES];
 934
 935     UIWebDocumentView *document([webview_ _documentView]);
 936
 937     // XXX: I think this improves scrolling; the hardcoded-ness sucks
 938     [document setTileSize:CGSizeMake(320, 500)];
 939
 940     WebView *webview([document webView]);
 941     WebPreferences *preferences([webview preferences]);
 942
 943     // XXX: I have no clue if I actually /want/ this modification
 944     if ([webview respondsToSelector:@selector(_setLayoutInterval:)])
 945         [webview _setLayoutInterval:0];
 946     else if ([preferences respondsToSelector:@selector(_setLayoutInterval:)])
 947         [preferences _setLayoutInterval:0];
 948
 949     [preferences setCacheModel:WebCacheModelDocumentBrowser];
 950     [preferences setJavaScriptCanOpenWindowsAutomatically:YES];
 951
 952     if ([preferences respondsToSelector:@selector(setOfflineWebApplicationCacheEnabled:)])
 953         [preferences setOfflineWebApplicationCacheEnabled:YES];
 954
 955     if (NSString *agent = [self applicationNameForUserAgent])
 956         [webview setApplicationNameForUserAgent:agent];
 957
 958     if ([webview respondsToSelector:@selector(setShouldUpdateWhileOffscreen:)])
 959         [webview setShouldUpdateWhileOffscreen:NO];
 960
 961 #if LogMessages
 962     if ([document respondsToSelector:@selector(setAllowsMessaging:)])
 963         [document setAllowsMessaging:YES];
 964     if ([webview respondsToSelector:@selector(_setAllowsMessaging:)])
 965         [webview _setAllowsMessaging:YES];
 966 #endif
 967
 968     if ([webview_ respondsToSelector:@selector(_scrollView)]) {
 969         scroller_ = [webview_ _scrollView];
 970
 971         [scroller_ setDirectionalLockEnabled:YES];
 972         [scroller_ setDecelerationRate:CYScrollViewDecelerationRateNormal];
 973         [scroller_ setDelaysContentTouches:NO];
 974
 975         [scroller_ setCanCancelContentTouches:YES];
 976     } else if ([webview_ respondsToSelector:@selector(_scroller)]) {
 977         UIScroller *scroller([webview_ _scroller]);
 978         scroller_ = (UIScrollView *) scroller;
 979
 980         [scroller setDirectionalScrolling:YES];
 981         // XXX: we might be better off /not/ setting this on older systems
 982         [scroller setScrollDecelerationFactor:CYScrollViewDecelerationRateNormal]; /* 0.989324 */
 983         [scroller setScrollHysteresis:0]; /* 8 */
 984
 985         [scroller setThumbDetectionEnabled:NO];
 986
 987         // use NO with UIApplicationUseLegacyEvents(YES)
 988         [scroller setEventMode:YES];
 989
 990         // XXX: this is handled by setBounces, right?
 991         //[scroller setAllowsRubberBanding:YES];
 992     }
 993
 994     [webview_ setOpaque:NO];
 995     [webview_ setBackgroundColor:nil];
 996
 997     [scroller_ setFixedBackgroundPattern:YES];
 998     [scroller_ setBackgroundColor:color_];
 999     [scroller_ setClipsSubviews:YES];
1000
1001     [scroller_ setBounces:YES];
1002     [scroller_ setScrollingEnabled:YES];
1003     [scroller_ setShowBackgroundShadow:NO];
1004
1005     [self setViewportWidth:width_];
1006
1007     [webview_ setAutoresizingMask:(UIViewAutoresizingFlexibleWidth | UIViewAutoresizingFlexibleHeight)];
1008
1009     ready_ = false;
1010 }
1011
1012 - (void) releaseSubviews {
1013     webview_ = nil;
1014     scroller_ = nil;
1015
1016     [self releaseNetworkActivityIndicator];
1017
1018     [super releaseSubviews];
1019 }
1020
1021 - (id) initWithWidth:(float)width {
1022     return [self initWithWidth:width ofClass:[self class]];
1023 }
1024
1025 - (id) init {
1026     return [self initWithWidth:0];
1027 }
1028
1029 - (id) initWithURL:(NSURL *)url {
1030     if ((self = [self init]) != nil) {
1031         [self setURL:url];
1032     } return self;
1033 }
1034
1035 - (id) initWithRequest:(NSURLRequest *)request {
1036     if ((self = [self init]) != nil) {
1037         [self setRequest:request];
1038     } return self;
1039 }
1040
1041 - (void) callFunction:(WebScriptObject *)function {
1042     WebThreadLocked lock;
1043
1044     WebView *webview([[[self webView] _documentView] webView]);
1045     WebFrame *frame([webview mainFrame]);
1046
1047     JSGlobalContextRef context([frame globalContext]);
1048     JSObjectRef object([function JSObject]);
1049     if ($JSObjectCallAsFunction != NULL)
1050         ($JSObjectCallAsFunction)(context, object, NULL, 0, NULL, NULL);
1051 }
1052
1053 - (void) reloadButtonClicked {
1054     [self reloadURLWithCache:NO];
1055 }
1056
1057 - (void) _customButtonClicked {
1058     [self reloadButtonClicked];
1059 }
1060
1061 - (void) customButtonClicked {
1062 #if !AlwaysReload
1063     if (function_ != nil)
1064         [self callFunction:function_];
1065     else
1066 #endif
1067     [self _customButtonClicked];
1068 }
1069
1070 + (float) defaultWidth {
1071     return 980;
1072 }
1073
1074 - (void) setNavigationBarStyle:(NSString *)name {
1075     UIBarStyle style;
1076     if ([name isEqualToString:@"Black"])
1077         style = UIBarStyleBlack;
1078     else
1079         style = UIBarStyleDefault;
1080
1081     [[[self navigationController] navigationBar] setBarStyle:style];
1082 }
1083
1084 - (void) setNavigationBarTintColor:(UIColor *)color {
1085     [[[self navigationController] navigationBar] setTintColor:color];
1086 }
1087
1088 - (void) setBadgeValue:(id)value {
1089     [[[self navigationController] tabBarItem] setBadgeValue:value];
1090 }
1091
1092 - (void) setHidesBackButton:(bool)value {
1093     [[self navigationItem] setHidesBackButton:value];
1094     [self applyLeftButton];
1095 }
1096
1097 - (void) setHidesBackButtonByNumber:(NSNumber *)value {
1098     [self setHidesBackButton:[value boolValue]];
1099 }
1100
1101 - (void) dispatchEvent:(NSString *)event {
1102     [[self webView] dispatchEvent:event];
1103 }
1104
1105 - (bool) hidesNavigationBar {
1106     return hidesNavigationBar_;
1107 }
1108
1109 - (void) _setHidesNavigationBar:(bool)value animated:(bool)animated {
1110     if (visible_)
1111         [[self navigationController] setNavigationBarHidden:(value && [self hidesNavigationBar]) animated:animated];
1112 }
1113
1114 - (void) setHidesNavigationBar:(bool)value {
1115     if (hidesNavigationBar_ != value) {
1116         hidesNavigationBar_ = value;
1117         [self _setHidesNavigationBar:YES animated:YES];
1118     }
1119 }
1120
1121 - (void) setHidesNavigationBarByNumber:(NSNumber *)value {
1122     [self setHidesNavigationBar:[value boolValue]];
1123 }
1124
1125 - (void) setScrollAlwaysBounceVertical:(bool)value {
1126     if ([webview_ respondsToSelector:@selector(_scrollView)]) {
1127         UIScrollView *scroller([webview_ _scrollView]);
1128         [scroller setAlwaysBounceVertical:value];
1129     } else if ([webview_ respondsToSelector:@selector(_scroller)]) {
1130         //UIScroller *scroller([webview_ _scroller]);
1131         // XXX: I am sad here.
1132     } else return;
1133 }
1134
1135 - (void) setScrollAlwaysBounceVerticalNumber:(NSNumber *)value {
1136     [self setScrollAlwaysBounceVertical:[value boolValue]];
1137 }
1138
1139 - (void) setScrollIndicatorStyle:(UIScrollViewIndicatorStyle)style {
1140     if ([webview_ respondsToSelector:@selector(_scrollView)]) {
1141         UIScrollView *scroller([webview_ _scrollView]);
1142         [scroller setIndicatorStyle:style];
1143     } else if ([webview_ respondsToSelector:@selector(_scroller)]) {
1144         UIScroller *scroller([webview_ _scroller]);
1145         [scroller setScrollerIndicatorStyle:style];
1146     } else return;
1147 }
1148
1149 - (void) setScrollIndicatorStyleWithName:(NSString *)style {
1150     UIScrollViewIndicatorStyle value;
1151
1152     if (false);
1153     else if ([style isEqualToString:@"default"])
1154         value = UIScrollViewIndicatorStyleDefault;
1155     else if ([style isEqualToString:@"black"])
1156         value = UIScrollViewIndicatorStyleBlack;
1157     else if ([style isEqualToString:@"white"])
1158         value = UIScrollViewIndicatorStyleWhite;
1159     else return;
1160
1161     [self setScrollIndicatorStyle:value];
1162 }
1163
1164 - (void) viewWillAppear:(BOOL)animated {
1165     visible_ = true;
1166
1167     if ([self hidesNavigationBar])
1168         [self _setHidesNavigationBar:YES animated:animated];
1169
1170     // XXX: why isn't this evern called automatically?
1171     [[self webView] setNeedsLayout];
1172
1173     [self dispatchEvent:@"CydiaViewWillAppear"];
1174     [super viewWillAppear:animated];
1175 }
1176
1177 - (void) viewDidAppear:(BOOL)animated {
1178     [super viewDidAppear:animated];
1179     [self dispatchEvent:@"CydiaViewDidAppear"];
1180 }
1181
1182 - (void) viewWillDisappear:(BOOL)animated {
1183     [self dispatchEvent:@"CydiaViewWillDisappear"];
1184     [super viewWillDisappear:animated];
1185
1186     if ([self hidesNavigationBar])
1187         [self _setHidesNavigationBar:NO animated:animated];
1188
1189     visible_ = false;
1190 }
1191
1192 - (void) viewDidDisappear:(BOOL)animated {
1193     [super viewDidDisappear:animated];
1194     [self dispatchEvent:@"CydiaViewDidDisappear"];
1195 }
1196
1197 - (void) updateHeights:(NSTimer *)timer {
1198     for (WebFrame *frame in (id) registered_)
1199         [frame cydia$updateHeight];
1200 }
1201
1202 - (void) registerFrame:(WebFrame *)frame {
1203     [registered_ addObject:frame];
1204
1205     if (timer_ == nil)
1206         timer_ = [NSTimer scheduledTimerWithTimeInterval:0.2 target:self selector:@selector(updateHeights:) userInfo:nil repeats:YES];
1207 }
1208
1209 @end