CyteKit/WebViewController.mm

   1 #include "CyteKit/UCPlatform.h"
   2 #include "CyteKit/WebViewController.h"
   3
   4 #include "CyteKit/MFMailComposeViewController-MailToURL.h"
   5
   6 #include "iPhonePrivate.h"
   7
   8 #include "CyteKit/Localize.h"
   9 #include "CyteKit/WebViewController.h"
  10 #include "CyteKit/PerlCompatibleRegEx.hpp"
  11 #include "CyteKit/WebThreadLocked.hpp"
  12
  13 //#include <QuartzCore/CALayer.h>
  14 // XXX: fix the minimum requirement
  15 extern NSString * const kCAFilterNearest;
  16
  17 #include <WebCore/WebCoreThread.h>
  18
  19 #include <WebKit/WebKitErrors.h>
  20 #include <WebKit/WebPreferences.h>
  21
  22 #include <WebKit/DOMCSSPrimitiveValue.h>
  23 #include <WebKit/DOMCSSStyleDeclaration.h>
  24 #include <WebKit/DOMDocument.h>
  25 #include <WebKit/DOMHTMLBodyElement.h>
  26 #include <WebKit/DOMRGBColor.h>
  27
  28 #include <dlfcn.h>
  29 #include <objc/runtime.h>
  30
  31 #define ForSaurik 0
  32 #define DefaultTimeout_ 120.0
  33
  34 #define ShowInternals 0
  35 #define LogBrowser 0
  36 #define LogMessages 0
  37
  38 #define lprintf(args...) fprintf(stderr, args)
  39
  40 // XXX: centralize these special class things to some file or mechanism?
  41 static Class $MFMailComposeViewController;
  42
  43 float CYScrollViewDecelerationRateNormal;
  44
  45 @interface WebView (Apple)
  46 - (void) _setLayoutInterval:(float)interval;
  47 - (void) _setAllowsMessaging:(BOOL)allows;
  48 @end
  49
  50 @interface WebPreferences (Apple)
  51 + (void) _setInitialDefaultTextEncodingToSystemEncoding;
  52 - (void) _setLayoutInterval:(NSInteger)interval;
  53 - (void) setOfflineWebApplicationCacheEnabled:(BOOL)enabled;
  54 @end
  55
  56 /* Indirect Delegate {{{ */
  57 @interface IndirectDelegate : NSObject {
  58     _transient volatile id delegate_;
  59 }
  60
  61 - (void) setDelegate:(id)delegate;
  62 - (id) initWithDelegate:(id)delegate;
  63 @end
  64
  65 @implementation IndirectDelegate
  66
  67 - (void) setDelegate:(id)delegate {
  68     delegate_ = delegate;
  69 }
  70
  71 - (id) initWithDelegate:(id)delegate {
  72     delegate_ = delegate;
  73     return self;
  74 }
  75
  76 - (IMP) methodForSelector:(SEL)sel {
  77     if (IMP method = [super methodForSelector:sel])
  78         return method;
  79     fprintf(stderr, "methodForSelector:[%s] == NULL\n", sel_getName(sel));
  80     return NULL;
  81 }
  82
  83 - (BOOL) respondsToSelector:(SEL)sel {
  84     if ([super respondsToSelector:sel])
  85         return YES;
  86
  87     // XXX: WebThreadCreateNSInvocation returns nil
  88
  89 #if ShowInternals
  90     fprintf(stderr, "[%s]R?%s\n", class_getName(self->isa), sel_getName(sel));
  91 #endif
  92
  93     return delegate_ == nil ? NO : [delegate_ respondsToSelector:sel];
  94 }
  95
  96 - (NSMethodSignature *) methodSignatureForSelector:(SEL)sel {
  97     if (NSMethodSignature *method = [super methodSignatureForSelector:sel])
  98         return method;
  99
 100 #if ShowInternals
 101     fprintf(stderr, "[%s]S?%s\n", class_getName(self->isa), sel_getName(sel));
 102 #endif
 103
 104     if (delegate_ != nil)
 105         if (NSMethodSignature *sig = [delegate_ methodSignatureForSelector:sel])
 106             return sig;
 107
 108     // XXX: I fucking hate Apple so very very bad
 109     return [NSMethodSignature signatureWithObjCTypes:"v@:"];
 110 }
 111
 112 - (void) forwardInvocation:(NSInvocation *)inv {
 113     SEL sel = [inv selector];
 114     if (delegate_ != nil && [delegate_ respondsToSelector:sel])
 115         [inv invokeWithTarget:delegate_];
 116 }
 117
 118 @end
 119 /* }}} */
 120
 121 @implementation CyteWebViewController
 122
 123 #if ShowInternals
 124 #include "CyteKit/UCInternal.h"
 125 #endif
 126
 127 + (void) _initialize {
 128     [WebPreferences _setInitialDefaultTextEncodingToSystemEncoding];
 129
 130     dlopen("/System/Library/Frameworks/MessageUI.framework/MessageUI", RTLD_GLOBAL | RTLD_LAZY);
 131     $MFMailComposeViewController = objc_getClass("MFMailComposeViewController");
 132
 133     if (float *_UIScrollViewDecelerationRateNormal = reinterpret_cast<float *>(dlsym(RTLD_DEFAULT, "UIScrollViewDecelerationRateNormal")))
 134         CYScrollViewDecelerationRateNormal = *_UIScrollViewDecelerationRateNormal;
 135     else // XXX: this actually might be fast on some older systems: we should look into this
 136         CYScrollViewDecelerationRateNormal = 0.998;
 137 }
 138
 139 - (void) dealloc {
 140 #if LogBrowser
 141     NSLog(@"[CyteWebViewController dealloc]");
 142 #endif
 143
 144     if ([loading_ count] != 0)
 145         [delegate_ releaseNetworkActivityIndicator];
 146
 147     [super dealloc];
 148 }
 149
 150 - (NSString *) description {
 151     return [NSString stringWithFormat:@"<%s: %p, %@>", class_getName([self class]), self, [[request_ URL] absoluteString]];
 152 }
 153
 154 - (CyteWebView *) webView {
 155     return (CyteWebView *) [self view];
 156 }
 157
 158 - (NSURL *) URLWithURL:(NSURL *)url {
 159     return url;
 160 }
 161
 162 - (NSURLRequest *) requestWithURL:(NSURL *)url cachePolicy:(NSURLRequestCachePolicy)policy {
 163     return [NSURLRequest
 164         requestWithURL:[self URLWithURL:url]
 165         cachePolicy:policy
 166         timeoutInterval:DefaultTimeout_
 167     ];
 168 }
 169
 170 - (void) setRequest:(NSURLRequest *)request {
 171     _assert(request_ == nil);
 172     request_ = request;
 173 }
 174
 175 - (void) setURL:(NSURL *)url {
 176     [self setRequest:[self requestWithURL:url cachePolicy:NSURLRequestUseProtocolCachePolicy]];
 177 }
 178
 179 - (void) loadURL:(NSURL *)url cachePolicy:(NSURLRequestCachePolicy)policy {
 180     [self loadRequest:[self requestWithURL:url cachePolicy:policy]];
 181 }
 182
 183 - (void) loadURL:(NSURL *)url {
 184     [self loadURL:url cachePolicy:NSURLRequestUseProtocolCachePolicy];
 185 }
 186
 187 - (void) loadRequest:(NSURLRequest *)request {
 188 #if LogBrowser
 189     NSLog(@"loadRequest:%@", request);
 190 #endif
 191
 192     error_ = false;
 193     ready_ = true;
 194
 195     WebThreadLocked lock;
 196     [[self webView] loadRequest:request];
 197 }
 198
 199 - (void) reloadURLWithCache:(BOOL)cache {
 200     if (request_ == nil)
 201         return;
 202
 203     NSMutableURLRequest *request([request_ mutableCopy]);
 204     [request setCachePolicy:(cache ? NSURLRequestUseProtocolCachePolicy : NSURLRequestReloadIgnoringLocalCacheData)];
 205
 206     request_ = request;
 207
 208     if ([request_ HTTPBody] == nil && [request_ HTTPBodyStream] == nil)
 209         [self loadRequest:request_];
 210     else {
 211         UIAlertView *alert = [[[UIAlertView alloc]
 212             initWithTitle:UCLocalize("RESUBMIT_FORM")
 213             message:nil
 214             delegate:self
 215             cancelButtonTitle:UCLocalize("CANCEL")
 216             otherButtonTitles:
 217                 UCLocalize("SUBMIT"),
 218             nil
 219         ] autorelease];
 220
 221         [alert setContext:@"submit"];
 222         [alert show];
 223     }
 224 }
 225
 226 - (void) reloadURL {
 227     [self reloadURLWithCache:YES];
 228 }
 229
 230 - (void) reloadData {
 231     [super reloadData];
 232
 233     if (ready_)
 234         [self dispatchEvent:@"CydiaReloadData"];
 235     else
 236         [self reloadURLWithCache:YES];
 237 }
 238
 239 - (void) setButtonImage:(NSString *)button withStyle:(NSString *)style toFunction:(id)function {
 240     custom_ = button;
 241     style_ = style;
 242     function_ = function;
 243
 244     [self performSelectorOnMainThread:@selector(applyRightButton) withObject:nil waitUntilDone:NO];
 245 }
 246
 247 - (void) setButtonTitle:(NSString *)button withStyle:(NSString *)style toFunction:(id)function {
 248     custom_ = button;
 249     style_ = style;
 250     function_ = function;
 251
 252     [self performSelectorOnMainThread:@selector(applyRightButton) withObject:nil waitUntilDone:NO];
 253 }
 254
 255 - (void) removeButton {
 256     custom_ = [NSNull null];
 257     [self performSelectorOnMainThread:@selector(applyRightButton) withObject:nil waitUntilDone:NO];
 258 }
 259
 260 - (void) scrollToBottomAnimated:(NSNumber *)animated {
 261     CGSize size([scroller_ contentSize]);
 262     CGPoint offset([scroller_ contentOffset]);
 263     CGRect frame([scroller_ frame]);
 264
 265     if (size.height - offset.y < frame.size.height + 20.f) {
 266         CGRect rect = {{0, size.height-1}, {size.width, 1}};
 267         [scroller_ scrollRectToVisible:rect animated:[animated boolValue]];
 268     }
 269 }
 270
 271 - (void) _setViewportWidth {
 272     [[[self webView] _documentView] setViewportSize:CGSizeMake(width_, UIWebViewGrowsAndShrinksToFitHeight) forDocumentTypes:0x10];
 273 }
 274
 275 - (void) setViewportWidth:(float)width {
 276     width_ = width != 0 ? width : [[self class] defaultWidth];
 277     [self _setViewportWidth];
 278 }
 279
 280 - (void) _setViewportWidthOnMainThread:(NSNumber *)width {
 281     [self setViewportWidth:[width floatValue]];
 282 }
 283
 284 - (void) setViewportWidthOnMainThread:(float)width {
 285     [self performSelectorOnMainThread:@selector(_setViewportWidthOnMainThread:) withObject:[NSNumber numberWithFloat:width] waitUntilDone:NO];
 286 }
 287
 288 - (void) webViewUpdateViewSettings:(UIWebView *)view {
 289     [self _setViewportWidth];
 290 }
 291
 292 - (void) mailComposeController:(MFMailComposeViewController*)controller didFinishWithResult:(MFMailComposeResult)result error:(NSError*)error {
 293     [self dismissModalViewControllerAnimated:YES];
 294 }
 295
 296 - (void) _setupMail:(MFMailComposeViewController *)controller {
 297 }
 298
 299 - (void) _openMailToURL:(NSURL *)url {
 300     if ($MFMailComposeViewController != nil && [$MFMailComposeViewController canSendMail]) {
 301         MFMailComposeViewController *controller([[[$MFMailComposeViewController alloc] init] autorelease]);
 302         [controller setMailComposeDelegate:self];
 303
 304         [controller setMailToURL:url];
 305
 306         [self _setupMail:controller];
 307
 308         [self presentModalViewController:controller animated:YES];
 309         return;
 310     }
 311
 312     UIApplication *app([UIApplication sharedApplication]);
 313     if ([app respondsToSelector:@selector(openURL:asPanel:)])
 314         [app openURL:url asPanel:YES];
 315     else
 316         [app openURL:url];
 317 }
 318
 319 - (bool) _allowJavaScriptPanel {
 320     return true;
 321 }
 322
 323 - (bool) allowsNavigationAction {
 324     return allowsNavigationAction_;
 325 }
 326
 327 - (void) setAllowsNavigationAction:(bool)value {
 328     allowsNavigationAction_ = value;
 329 }
 330
 331 - (void) setAllowsNavigationActionByNumber:(NSNumber *)value {
 332     [self setAllowsNavigationAction:[value boolValue]];
 333 }
 334
 335 - (void) popViewControllerWithNumber:(NSNumber *)value {
 336     UINavigationController *navigation([self navigationController]);
 337     if ([navigation topViewController] == self)
 338         [navigation popViewControllerAnimated:[value boolValue]];
 339 }
 340
 341 - (void) _didFailWithError:(NSError *)error forFrame:(WebFrame *)frame {
 342     [loading_ removeObject:[NSValue valueWithNonretainedObject:frame]];
 343     [self _didFinishLoading];
 344
 345     if ([[error domain] isEqualToString:NSURLErrorDomain] && [error code] == NSURLErrorCancelled)
 346         return;
 347
 348     if ([[error domain] isEqualToString:WebKitErrorDomain] && [error code] == WebKitErrorFrameLoadInterruptedByPolicyChange) {
 349         request_ = stage2_;
 350         stage1_ = nil;
 351         stage2_ = nil;
 352         return;
 353     }
 354
 355     if ([frame parentFrame] == nil) {
 356         [self loadURL:[NSURL URLWithString:[NSString stringWithFormat:@"%@?%@",
 357             [[NSURL fileURLWithPath:[[NSBundle mainBundle] pathForResource:@"error" ofType:@"html"]] absoluteString],
 358             [[error localizedDescription] stringByAddingPercentEscapes]
 359         ]]];
 360
 361         error_ = true;
 362     }
 363 }
 364
 365 - (void) pushRequest:(NSURLRequest *)request asPop:(bool)pop {
 366     NSURL *url([request URL]);
 367
 368     // XXX: filter to internal usage?
 369     CyteViewController *page([delegate_ pageForURL:url forExternal:NO]);
 370
 371     if (page == nil) {
 372         CyteWebViewController *browser([[[class_ alloc] init] autorelease]);
 373         [browser setRequest:request];
 374         page = browser;
 375     }
 376
 377     [page setDelegate:delegate_];
 378
 379     if (!pop) {
 380         [[self navigationItem] setTitle:title_];
 381
 382         [[self navigationController] pushViewController:page animated:YES];
 383     } else {
 384         UINavigationController *navigation([[[UINavigationController alloc] initWithRootViewController:page] autorelease]);
 385
 386         [navigation setDelegate:delegate_];
 387
 388         [[page navigationItem] setLeftBarButtonItem:[[[UIBarButtonItem alloc]
 389             initWithTitle:UCLocalize("CLOSE")
 390             style:UIBarButtonItemStylePlain
 391             target:page
 392             action:@selector(close)
 393         ] autorelease]];
 394
 395         [[self navigationController] presentModalViewController:navigation animated:YES];
 396     }
 397 }
 398
 399 // CyteWebViewDelegate {{{
 400 - (void) webView:(WebView *)view addMessageToConsole:(NSDictionary *)message {
 401 #if LogMessages
 402     static Pcre irritating("^(?"
 403         ":" "The page at .* displayed insecure content from .*\\."
 404         "|" "Unsafe JavaScript attempt to access frame with URL .* from frame with URL .*\\. Domains, protocols and ports must match\\."
 405     ")\\n$");
 406
 407     if (NSString *data = [message objectForKey:@"message"])
 408         if (irritating(data))
 409             return;
 410
 411     NSLog(@"addMessageToConsole:%@", message);
 412 #endif
 413 }
 414
 415 - (void) webView:(WebView *)view decidePolicyForNavigationAction:(NSDictionary *)action request:(NSURLRequest *)request frame:(WebFrame *)frame decisionListener:(id<WebPolicyDecisionListener>)listener {
 416 #if LogBrowser
 417     NSLog(@"decidePolicyForNavigationAction:%@ request:%@ frame:%@", action, request, frame);
 418 #endif
 419
 420     if ([frame parentFrame] == nil) {
 421         if (!error_) {
 422             NSURL *url(request == nil ? nil : [request URL]);
 423
 424             if (request_ != nil && ![[request_ URL] isEqual:url] && ![self allowsNavigationAction]) {
 425                 if (url != nil)
 426                     [self pushRequest:request asPop:NO];
 427                 [listener ignore];
 428             }
 429         }
 430     }
 431 }
 432
 433 - (void) webView:(WebView *)view didDecidePolicy:(CYWebPolicyDecision)decision forNavigationAction:(NSDictionary *)action request:(NSURLRequest *)request frame:(WebFrame *)frame {
 434     if ([frame parentFrame] == nil)
 435         if (decision == CYWebPolicyDecisionUse)
 436             if (!error_) {
 437                 stage1_ = request_;
 438                 request_ = request;
 439             }
 440 }
 441
 442 - (void) webView:(WebView *)view decidePolicyForNewWindowAction:(NSDictionary *)action request:(NSURLRequest *)request newFrameName:(NSString *)frame decisionListener:(id<WebPolicyDecisionListener>)listener {
 443 #if LogBrowser
 444     NSLog(@"decidePolicyForNewWindowAction:%@ request:%@ newFrameName:%@", action, request, frame);
 445 #endif
 446
 447     NSURL *url([request URL]);
 448     if (url == nil)
 449         return;
 450
 451     if ([frame isEqualToString:@"_open"])
 452         [delegate_ openURL:url];
 453     else {
 454         NSString *scheme([[url scheme] lowercaseString]);
 455         if ([scheme isEqualToString:@"mailto"])
 456             [self _openMailToURL:url];
 457         else
 458             [self pushRequest:request asPop:[frame isEqualToString:@"_popup"]];
 459     }
 460
 461     [listener ignore];
 462 }
 463
 464 - (void) webView:(WebView *)view didClearWindowObject:(WebScriptObject *)window forFrame:(WebFrame *)frame {
 465 }
 466
 467 - (void) webView:(WebView *)view didCommitLoadForFrame:(WebFrame *)frame {
 468 #if LogBrowser
 469     NSLog(@"didCommitLoadForFrame:%@", frame);
 470 #endif
 471
 472     if ([frame parentFrame] == nil) {
 473     }
 474 }
 475
 476 - (void) webView:(WebView *)view didFailLoadWithError:(NSError *)error forFrame:(WebFrame *)frame {
 477 #if LogBrowser
 478     NSLog(@"didFailLoadWithError:%@ forFrame:%@", error, frame);
 479 #endif
 480
 481     [self _didFailWithError:error forFrame:frame];
 482 }
 483
 484 - (void) webView:(WebView *)view didFailProvisionalLoadWithError:(NSError *)error forFrame:(WebFrame *)frame {
 485 #if LogBrowser
 486     NSLog(@"didFailProvisionalLoadWithError:%@ forFrame:%@", error, frame);
 487 #endif
 488
 489     [self _didFailWithError:error forFrame:frame];
 490 }
 491
 492 - (void) webView:(WebView *)view didFinishLoadForFrame:(WebFrame *)frame {
 493     [loading_ removeObject:[NSValue valueWithNonretainedObject:frame]];
 494
 495     if ([frame parentFrame] == nil) {
 496         stage1_ = nil;
 497         stage2_ = nil;
 498
 499         if (DOMDocument *document = [frame DOMDocument])
 500             if (DOMNodeList<NSFastEnumeration> *bodies = [document getElementsByTagName:@"body"])
 501                 for (DOMHTMLBodyElement *body in (id) bodies) {
 502                     DOMCSSStyleDeclaration *style([document getComputedStyle:body pseudoElement:nil]);
 503
 504                     UIColor *uic(nil);
 505
 506                     if (DOMCSSPrimitiveValue *color = static_cast<DOMCSSPrimitiveValue *>([style getPropertyCSSValue:@"background-color"])) {
 507                         if ([color primitiveType] == DOM_CSS_RGBCOLOR) {
 508                             DOMRGBColor *rgb([color getRGBColorValue]);
 509
 510                             float red([[rgb red] getFloatValue:DOM_CSS_NUMBER]);
 511                             float green([[rgb green] getFloatValue:DOM_CSS_NUMBER]);
 512                             float blue([[rgb blue] getFloatValue:DOM_CSS_NUMBER]);
 513                             float alpha([[rgb alpha] getFloatValue:DOM_CSS_NUMBER]);
 514
 515                             if (red == 0xc7 && green == 0xce && blue == 0xd5)
 516                                 uic = [UIColor pinStripeColor];
 517                             else if (alpha != 0)
 518                                 uic = [UIColor
 519                                     colorWithRed:(red / 255)
 520                                     green:(green / 255)
 521                                     blue:(blue / 255)
 522                                     alpha:alpha
 523                                 ];
 524                         }
 525                     }
 526
 527                     [scroller_ setBackgroundColor:(uic ?: [UIColor clearColor])];
 528                     break;
 529                 }
 530     }
 531
 532     [self _didFinishLoading];
 533 }
 534
 535 - (void) webView:(WebView *)view didReceiveTitle:(NSString *)title forFrame:(WebFrame *)frame {
 536     if ([frame parentFrame] != nil)
 537         return;
 538
 539     title_ = title;
 540
 541     [[self navigationItem] setTitle:title_];
 542 }
 543
 544 - (void) webView:(WebView *)view didStartProvisionalLoadForFrame:(WebFrame *)frame {
 545 #if LogBrowser
 546     NSLog(@"didStartProvisionalLoadForFrame:%@", frame);
 547 #endif
 548
 549     [loading_ addObject:[NSValue valueWithNonretainedObject:frame]];
 550
 551     if ([frame parentFrame] == nil) {
 552         title_ = nil;
 553         custom_ = nil;
 554         style_ = nil;
 555         function_ = nil;
 556
 557         allowsNavigationAction_ = true;
 558
 559         stage2_ = stage1_;
 560         stage1_ = nil;
 561
 562         [self setHidesNavigationBar:NO];
 563
 564         // XXX: do we still need to do this?
 565         [[self navigationItem] setTitle:nil];
 566     }
 567
 568     [self _didStartLoading];
 569 }
 570
 571 - (NSURLRequest *) webView:(WebView *)view resource:(id)identifier willSendRequest:(NSURLRequest *)request redirectResponse:(NSURLResponse *)response fromDataSource:(WebDataSource *)source {
 572 #if LogBrowser
 573     NSLog(@"resource:%@ willSendRequest:%@ redirectResponse:%@ fromDataSource:%@", identifier, request, response, source);
 574 #endif
 575
 576     return request;
 577 }
 578
 579 - (bool) webView:(WebView *)view shouldRunJavaScriptAlertPanelWithMessage:(NSString *)message initiatedByFrame:(WebFrame *)frame {
 580     return [self _allowJavaScriptPanel];
 581 }
 582
 583 - (bool) webView:(WebView *)view shouldRunJavaScriptConfirmPanelWithMessage:(NSString *)message initiatedByFrame:(WebFrame *)frame {
 584     return [self _allowJavaScriptPanel];
 585 }
 586
 587 - (bool) webView:(WebView *)view shouldRunJavaScriptTextInputPanelWithPrompt:(NSString *)prompt defaultText:(NSString *)text initiatedByFrame:(WebFrame *)frame {
 588     return [self _allowJavaScriptPanel];
 589 }
 590
 591 - (void) webViewClose:(WebView *)view {
 592     [self close];
 593 }
 594 // }}}
 595
 596 - (void) close {
 597     [[[self navigationController] parentViewController] dismissModalViewControllerAnimated:YES];
 598 }
 599
 600 - (void) alertView:(UIAlertView *)alert clickedButtonAtIndex:(NSInteger)button {
 601     NSString *context([alert context]);
 602
 603     if ([context isEqualToString:@"sensitive"]) {
 604         switch (button) {
 605             case 1:
 606                 sensitive_ = [NSNumber numberWithBool:YES];
 607             break;
 608
 609             case 2:
 610                 sensitive_ = [NSNumber numberWithBool:NO];
 611             break;
 612         }
 613
 614         [alert dismissWithClickedButtonIndex:-1 animated:YES];
 615     } else if ([context isEqualToString:@"challenge"]) {
 616         id<NSURLAuthenticationChallengeSender> sender([challenge_ sender]);
 617
 618         switch (button) {
 619             case 1: {
 620                 NSString *username([[alert textFieldAtIndex:0] text]);
 621                 NSString *password([[alert textFieldAtIndex:1] text]);
 622
 623                 NSURLCredential *credential([NSURLCredential credentialWithUser:username password:password persistence:NSURLCredentialPersistenceForSession]);
 624
 625                 [sender useCredential:credential forAuthenticationChallenge:challenge_];
 626             } break;
 627
 628             case 2:
 629                 [sender cancelAuthenticationChallenge:challenge_];
 630             break;
 631
 632             _nodefault
 633         }
 634
 635         challenge_ = nil;
 636
 637         [alert dismissWithClickedButtonIndex:-1 animated:YES];
 638     } else if ([context isEqualToString:@"submit"]) {
 639         if (button == [alert cancelButtonIndex]) {
 640         } else if (button == [alert firstOtherButtonIndex]) {
 641             if (request_ != nil) {
 642                 WebThreadLocked lock;
 643                 [[self webView] loadRequest:request_];
 644             }
 645         }
 646
 647         [alert dismissWithClickedButtonIndex:-1 animated:YES];
 648     }
 649 }
 650
 651 - (UIBarButtonItemStyle) rightButtonStyle {
 652     if (style_ == nil) normal:
 653         return UIBarButtonItemStylePlain;
 654     else if ([style_ isEqualToString:@"Normal"])
 655         return UIBarButtonItemStylePlain;
 656     else if ([style_ isEqualToString:@"Highlighted"])
 657         return UIBarButtonItemStyleDone;
 658     else goto normal;
 659 }
 660
 661 - (UIBarButtonItem *) customButton {
 662     if (custom_ == nil)
 663         return nil;
 664     else if (custom_ == [NSNull null])
 665         return (UIBarButtonItem *) [NSNull null];
 666
 667     return [[[UIBarButtonItem alloc]
 668         initWithTitle:static_cast<NSString *>(custom_.operator NSObject *())
 669         style:[self rightButtonStyle]
 670         target:self
 671         action:@selector(customButtonClicked)
 672     ] autorelease];
 673 }
 674
 675 - (UIBarButtonItem *) leftButton {
 676     UINavigationItem *item([self navigationItem]);
 677     if ([item backBarButtonItem] != nil && ![item hidesBackButton])
 678         return nil;
 679
 680     if (UINavigationController *navigation = [self navigationController])
 681         if ([[navigation parentViewController] modalViewController] == navigation)
 682             return [[[UIBarButtonItem alloc]
 683                 initWithTitle:UCLocalize("CLOSE")
 684                 style:UIBarButtonItemStylePlain
 685                 target:self
 686                 action:@selector(close)
 687             ] autorelease];
 688
 689     return nil;
 690 }
 691
 692 - (void) applyLeftButton {
 693     [[self navigationItem] setLeftBarButtonItem:[self leftButton]];
 694 }
 695
 696 - (UIBarButtonItem *) rightButton {
 697     return reloaditem_;
 698 }
 699
 700 - (void) applyLoadingTitle {
 701     [[self navigationItem] setTitle:UCLocalize("LOADING")];
 702 }
 703
 704 - (void) layoutRightButton {
 705     [[loadingitem_ view] addSubview:indicator_];
 706     [[loadingitem_ view] bringSubviewToFront:indicator_];
 707 }
 708
 709 - (void) applyRightButton {
 710     if ([self isLoading]) {
 711         [[self navigationItem] setRightBarButtonItem:loadingitem_ animated:YES];
 712         [self performSelector:@selector(layoutRightButton) withObject:nil afterDelay:0];
 713
 714         [indicator_ startAnimating];
 715         [self applyLoadingTitle];
 716     } else {
 717         [indicator_ stopAnimating];
 718
 719         UIBarButtonItem *button([self customButton]);
 720         if (button == nil)
 721             button = [self rightButton];
 722         else if (button == (UIBarButtonItem *) [NSNull null])
 723             button = nil;
 724
 725         [[self navigationItem] setRightBarButtonItem:button animated:YES];
 726     }
 727 }
 728
 729 - (void) didStartLoading {
 730     // Overridden in subclasses.
 731 }
 732
 733 - (void) _didStartLoading {
 734     [self applyRightButton];
 735
 736     if ([loading_ count] != 1)
 737         return;
 738
 739     [delegate_ retainNetworkActivityIndicator];
 740     [self didStartLoading];
 741 }
 742
 743 - (void) didFinishLoading {
 744     // Overridden in subclasses.
 745 }
 746
 747 - (void) _didFinishLoading {
 748     if ([loading_ count] != 0)
 749         return;
 750
 751     [self applyRightButton];
 752     [[self navigationItem] setTitle:title_];
 753
 754     [delegate_ releaseNetworkActivityIndicator];
 755     [self didFinishLoading];
 756 }
 757
 758 - (bool) isLoading {
 759     return [loading_ count] != 0;
 760 }
 761
 762 - (id) initWithWidth:(float)width ofClass:(Class)_class {
 763     if ((self = [super init]) != nil) {
 764         width_ = width;
 765         class_ = _class;
 766
 767         allowsNavigationAction_ = true;
 768
 769         loading_ = [NSMutableSet setWithCapacity:5];
 770         indirect_ = [[[IndirectDelegate alloc] initWithDelegate:self] autorelease];
 771
 772         reloaditem_ = [[[UIBarButtonItem alloc]
 773             initWithTitle:UCLocalize("RELOAD")
 774             style:[self rightButtonStyle]
 775             target:self
 776             action:@selector(reloadButtonClicked)
 777         ] autorelease];
 778
 779         loadingitem_ = [[[UIBarButtonItem alloc]
 780             initWithTitle:@" "
 781             style:UIBarButtonItemStylePlain
 782             target:self
 783             action:@selector(reloadButtonClicked)
 784         ] autorelease];
 785
 786         indicator_ = [[[UIActivityIndicatorView alloc] initWithActivityIndicatorStyle:UIActivityIndicatorViewStyleWhite] autorelease];
 787         [indicator_ setFrame:CGRectMake(15, 5, [indicator_ frame].size.width, [indicator_ frame].size.height)];
 788         [indicator_ setAutoresizingMask:UIViewAutoresizingFlexibleLeftMargin];
 789
 790         [self applyLeftButton];
 791         [self applyRightButton];
 792     } return self;
 793 }
 794
 795 - (NSString *) applicationNameForUserAgent {
 796     return nil;
 797 }
 798
 799 - (void) loadView {
 800     CGRect bounds([[UIScreen mainScreen] applicationFrame]);
 801
 802     webview_ = [[[CyteWebView alloc] initWithFrame:bounds] autorelease];
 803     [webview_ setDelegate:self];
 804     [self setView:webview_];
 805
 806     if ([webview_ respondsToSelector:@selector(setDataDetectorTypes:)])
 807         [webview_ setDataDetectorTypes:UIDataDetectorTypeAutomatic];
 808     else
 809         [webview_ setDetectsPhoneNumbers:NO];
 810
 811     [webview_ setScalesPageToFit:YES];
 812
 813     UIWebDocumentView *document([webview_ _documentView]);
 814
 815     // XXX: I think this improves scrolling; the hardcoded-ness sucks
 816     [document setTileSize:CGSizeMake(320, 500)];
 817
 818     [document setBackgroundColor:[UIColor clearColor]];
 819
 820     // XXX: this is terribly (too?) expensive
 821     [document setDrawsBackground:NO];
 822
 823     WebView *webview([document webView]);
 824     WebPreferences *preferences([webview preferences]);
 825
 826     // XXX: I have no clue if I actually /want/ this modification
 827     if ([webview respondsToSelector:@selector(_setLayoutInterval:)])
 828         [webview _setLayoutInterval:0];
 829     else if ([preferences respondsToSelector:@selector(_setLayoutInterval:)])
 830         [preferences _setLayoutInterval:0];
 831
 832     [preferences setCacheModel:WebCacheModelDocumentBrowser];
 833     [preferences setJavaScriptCanOpenWindowsAutomatically:YES];
 834     [preferences setOfflineWebApplicationCacheEnabled:YES];
 835
 836     if (NSString *agent = [self applicationNameForUserAgent])
 837         [webview setApplicationNameForUserAgent:agent];
 838
 839     if ([webview respondsToSelector:@selector(setShouldUpdateWhileOffscreen:)])
 840         [webview setShouldUpdateWhileOffscreen:NO];
 841
 842 #if LogMessages
 843     if ([document respondsToSelector:@selector(setAllowsMessaging:)])
 844         [document setAllowsMessaging:YES];
 845     if ([webview respondsToSelector:@selector(_setAllowsMessaging:)])
 846         [webview _setAllowsMessaging:YES];
 847 #endif
 848
 849     if ([webview_ respondsToSelector:@selector(_scrollView)]) {
 850         scroller_ = [webview_ _scrollView];
 851
 852         [scroller_ setDirectionalLockEnabled:YES];
 853         [scroller_ setDecelerationRate:CYScrollViewDecelerationRateNormal];
 854         [scroller_ setDelaysContentTouches:NO];
 855
 856         [scroller_ setCanCancelContentTouches:YES];
 857     } else if ([webview_ respondsToSelector:@selector(_scroller)]) {
 858         UIScroller *scroller([webview_ _scroller]);
 859         scroller_ = (UIScrollView *) scroller;
 860
 861         [scroller setDirectionalScrolling:YES];
 862         // XXX: we might be better off /not/ setting this on older systems
 863         [scroller setScrollDecelerationFactor:CYScrollViewDecelerationRateNormal]; /* 0.989324 */
 864         [scroller setScrollHysteresis:0]; /* 8 */
 865
 866         [scroller setThumbDetectionEnabled:NO];
 867
 868         // use NO with UIApplicationUseLegacyEvents(YES)
 869         [scroller setEventMode:YES];
 870
 871         // XXX: this is handled by setBounces, right?
 872         //[scroller setAllowsRubberBanding:YES];
 873     }
 874
 875     [scroller_ setFixedBackgroundPattern:YES];
 876     [scroller_ setBackgroundColor:[UIColor clearColor]];
 877     [scroller_ setClipsSubviews:YES];
 878
 879     [scroller_ setBounces:YES];
 880     [scroller_ setScrollingEnabled:YES];
 881     [scroller_ setShowBackgroundShadow:NO];
 882
 883     [self setViewportWidth:width_];
 884
 885     UITableView *table([[[UITableView alloc] initWithFrame:[webview_ bounds] style:UITableViewStyleGrouped] autorelease]);
 886     [table setScrollsToTop:NO];
 887     [webview_ insertSubview:table atIndex:0];
 888
 889     [table setAutoresizingMask:(UIViewAutoresizingFlexibleWidth | UIViewAutoresizingFlexibleHeight)];
 890     [webview_ setAutoresizingMask:(UIViewAutoresizingFlexibleWidth | UIViewAutoresizingFlexibleHeight)];
 891
 892     ready_ = false;
 893 }
 894
 895 - (void) releaseSubviews {
 896     webview_ = nil;
 897     scroller_ = nil;
 898
 899     [super releaseSubviews];
 900 }
 901
 902 - (id) initWithWidth:(float)width {
 903     return [self initWithWidth:width ofClass:[self class]];
 904 }
 905
 906 - (id) init {
 907     return [self initWithWidth:0];
 908 }
 909
 910 - (id) initWithURL:(NSURL *)url {
 911     if ((self = [self init]) != nil) {
 912         [self setURL:url];
 913     } return self;
 914 }
 915
 916 - (void) callFunction:(WebScriptObject *)function {
 917     WebThreadLocked lock;
 918
 919     WebView *webview([[[self webView] _documentView] webView]);
 920     WebFrame *frame([webview mainFrame]);
 921
 922     JSGlobalContextRef context([frame globalContext]);
 923     JSObjectRef object([function JSObject]);
 924     JSObjectCallAsFunction(context, object, NULL, 0, NULL, NULL);
 925 }
 926
 927 - (void) reloadButtonClicked {
 928     [self reloadURLWithCache:YES];
 929 }
 930
 931 - (void) _customButtonClicked {
 932     [self reloadButtonClicked];
 933 }
 934
 935 - (void) customButtonClicked {
 936 #if !AlwaysReload
 937     if (function_ != nil)
 938         [self callFunction:function_];
 939     else
 940 #endif
 941     [self _customButtonClicked];
 942 }
 943
 944 + (float) defaultWidth {
 945     return 980;
 946 }
 947
 948 - (void) setNavigationBarStyle:(NSString *)name {
 949     UIBarStyle style;
 950     if ([name isEqualToString:@"Black"])
 951         style = UIBarStyleBlack;
 952     else
 953         style = UIBarStyleDefault;
 954
 955     [[[self navigationController] navigationBar] setBarStyle:style];
 956 }
 957
 958 - (void) setNavigationBarTintColor:(UIColor *)color {
 959     [[[self navigationController] navigationBar] setTintColor:color];
 960 }
 961
 962 - (void) setBadgeValue:(id)value {
 963     [[[self navigationController] tabBarItem] setBadgeValue:value];
 964 }
 965
 966 - (void) setHidesBackButton:(bool)value {
 967     [[self navigationItem] setHidesBackButton:value];
 968     [self applyLeftButton];
 969 }
 970
 971 - (void) setHidesBackButtonByNumber:(NSNumber *)value {
 972     [self setHidesBackButton:[value boolValue]];
 973 }
 974
 975 - (void) dispatchEvent:(NSString *)event {
 976     [[self webView] dispatchEvent:event];
 977 }
 978
 979 - (bool) hidesNavigationBar {
 980     return hidesNavigationBar_;
 981 }
 982
 983 - (void) _setHidesNavigationBar:(bool)value animated:(bool)animated {
 984     if (visible_)
 985         [[self navigationController] setNavigationBarHidden:(value && [self hidesNavigationBar]) animated:animated];
 986 }
 987
 988 - (void) setHidesNavigationBar:(bool)value {
 989     if (hidesNavigationBar_ != value) {
 990         hidesNavigationBar_ = value;
 991         [self _setHidesNavigationBar:YES animated:YES];
 992     }
 993 }
 994
 995 - (void) setHidesNavigationBarByNumber:(NSNumber *)value {
 996     [self setHidesNavigationBar:[value boolValue]];
 997 }
 998
 999 - (void) viewWillAppear:(BOOL)animated {
1000     visible_ = true;
1001
1002     if ([self hidesNavigationBar])
1003         [self _setHidesNavigationBar:YES animated:animated];
1004
1005     [self dispatchEvent:@"CydiaViewWillAppear"];
1006     [super viewWillAppear:animated];
1007 }
1008
1009 - (void) viewDidAppear:(BOOL)animated {
1010     [super viewDidAppear:animated];
1011     [self dispatchEvent:@"CydiaViewDidAppear"];
1012 }
1013
1014 - (void) viewWillDisappear:(BOOL)animated {
1015     [self dispatchEvent:@"CydiaViewWillDisappear"];
1016     [super viewWillDisappear:animated];
1017
1018     if ([self hidesNavigationBar])
1019         [self _setHidesNavigationBar:NO animated:animated];
1020
1021     visible_ = false;
1022 }
1023
1024 - (void) viewDidDisappear:(BOOL)animated {
1025     [super viewDidDisappear:animated];
1026     [self dispatchEvent:@"CydiaViewDidDisappear"];
1027 }
1028
1029 @end