CyteKit/WebViewController.mm

   1 #include "CyteKit/UCPlatform.h"
   2 #include "CyteKit/WebViewController.h"
   3
   4 #include "CyteKit/MFMailComposeViewController-MailToURL.h"
   5
   6 #include "iPhonePrivate.h"
   7
   8 #include "CyteKit/Localize.h"
   9 #include "CyteKit/WebViewController.h"
  10 #include "CyteKit/PerlCompatibleRegEx.hpp"
  11 #include "CyteKit/WebThreadLocked.hpp"
  12
  13 //#include <QuartzCore/CALayer.h>
  14 // XXX: fix the minimum requirement
  15 extern NSString * const kCAFilterNearest;
  16
  17 #include <WebCore/WebCoreThread.h>
  18
  19 #include <WebKit/WebKitErrors.h>
  20 #include <WebKit/WebPreferences.h>
  21
  22 #include <WebKit/DOMCSSPrimitiveValue.h>
  23 #include <WebKit/DOMCSSStyleDeclaration.h>
  24 #include <WebKit/DOMDocument.h>
  25 #include <WebKit/DOMHTMLBodyElement.h>
  26 #include <WebKit/DOMRGBColor.h>
  27
  28 #include <dlfcn.h>
  29 #include <objc/runtime.h>
  30
  31 #define ForSaurik 0
  32 #define DefaultTimeout_ 120.0
  33
  34 #define ShowInternals 0
  35 #define LogBrowser 0
  36 #define LogMessages 0
  37
  38 #define lprintf(args...) fprintf(stderr, args)
  39
  40 // XXX: centralize these special class things to some file or mechanism?
  41 static Class $MFMailComposeViewController;
  42
  43 float CYScrollViewDecelerationRateNormal;
  44
  45 @interface WebView (Apple)
  46 - (void) _setLayoutInterval:(float)interval;
  47 - (void) _setAllowsMessaging:(BOOL)allows;
  48 @end
  49
  50 @interface WebPreferences (Apple)
  51 + (void) _setInitialDefaultTextEncodingToSystemEncoding;
  52 - (void) _setLayoutInterval:(NSInteger)interval;
  53 - (void) setOfflineWebApplicationCacheEnabled:(BOOL)enabled;
  54 @end
  55
  56 @implementation WebFrame (Cydia)
  57
  58 - (NSString *) description {
  59     return [NSString stringWithFormat:@"<%s: %p, %@>", class_getName([self class]), self, [[[([self provisionalDataSource] ?: [self dataSource]) request] URL] absoluteString]];
  60 }
  61
  62 @end
  63
  64 /* Indirect Delegate {{{ */
  65 @interface IndirectDelegate : NSObject {
  66     _transient volatile id delegate_;
  67 }
  68
  69 - (void) setDelegate:(id)delegate;
  70 - (id) initWithDelegate:(id)delegate;
  71 @end
  72
  73 @implementation IndirectDelegate
  74
  75 - (void) setDelegate:(id)delegate {
  76     delegate_ = delegate;
  77 }
  78
  79 - (id) initWithDelegate:(id)delegate {
  80     delegate_ = delegate;
  81     return self;
  82 }
  83
  84 - (IMP) methodForSelector:(SEL)sel {
  85     if (IMP method = [super methodForSelector:sel])
  86         return method;
  87     fprintf(stderr, "methodForSelector:[%s] == NULL\n", sel_getName(sel));
  88     return NULL;
  89 }
  90
  91 - (BOOL) respondsToSelector:(SEL)sel {
  92     if ([super respondsToSelector:sel])
  93         return YES;
  94
  95     // XXX: WebThreadCreateNSInvocation returns nil
  96
  97 #if ShowInternals
  98     fprintf(stderr, "[%s]R?%s\n", class_getName(self->isa), sel_getName(sel));
  99 #endif
 100
 101     return delegate_ == nil ? NO : [delegate_ respondsToSelector:sel];
 102 }
 103
 104 - (NSMethodSignature *) methodSignatureForSelector:(SEL)sel {
 105     if (NSMethodSignature *method = [super methodSignatureForSelector:sel])
 106         return method;
 107
 108 #if ShowInternals
 109     fprintf(stderr, "[%s]S?%s\n", class_getName(self->isa), sel_getName(sel));
 110 #endif
 111
 112     if (delegate_ != nil)
 113         if (NSMethodSignature *sig = [delegate_ methodSignatureForSelector:sel])
 114             return sig;
 115
 116     // XXX: I fucking hate Apple so very very bad
 117     return [NSMethodSignature signatureWithObjCTypes:"v@:"];
 118 }
 119
 120 - (void) forwardInvocation:(NSInvocation *)inv {
 121     SEL sel = [inv selector];
 122     if (delegate_ != nil && [delegate_ respondsToSelector:sel])
 123         [inv invokeWithTarget:delegate_];
 124 }
 125
 126 @end
 127 /* }}} */
 128
 129 @implementation CyteWebViewController
 130
 131 #if ShowInternals
 132 #include "CyteKit/UCInternal.h"
 133 #endif
 134
 135 + (void) _initialize {
 136     [WebPreferences _setInitialDefaultTextEncodingToSystemEncoding];
 137
 138     dlopen("/System/Library/Frameworks/MessageUI.framework/MessageUI", RTLD_GLOBAL | RTLD_LAZY);
 139     $MFMailComposeViewController = objc_getClass("MFMailComposeViewController");
 140
 141     if (float *_UIScrollViewDecelerationRateNormal = reinterpret_cast<float *>(dlsym(RTLD_DEFAULT, "UIScrollViewDecelerationRateNormal")))
 142         CYScrollViewDecelerationRateNormal = *_UIScrollViewDecelerationRateNormal;
 143     else // XXX: this actually might be fast on some older systems: we should look into this
 144         CYScrollViewDecelerationRateNormal = 0.998;
 145 }
 146
 147 - (void) dealloc {
 148 #if LogBrowser
 149     NSLog(@"[CyteWebViewController dealloc]");
 150 #endif
 151
 152     if ([loading_ count] != 0)
 153         [delegate_ releaseNetworkActivityIndicator];
 154
 155     [super dealloc];
 156 }
 157
 158 - (NSString *) description {
 159     return [NSString stringWithFormat:@"<%s: %p, %@>", class_getName([self class]), self, [[request_ URL] absoluteString]];
 160 }
 161
 162 - (CyteWebView *) webView {
 163     return (CyteWebView *) [self view];
 164 }
 165
 166 - (NSURL *) URLWithURL:(NSURL *)url {
 167     return url;
 168 }
 169
 170 - (NSURLRequest *) requestWithURL:(NSURL *)url cachePolicy:(NSURLRequestCachePolicy)policy {
 171     return [NSURLRequest
 172         requestWithURL:[self URLWithURL:url]
 173         cachePolicy:policy
 174         timeoutInterval:DefaultTimeout_
 175     ];
 176 }
 177
 178 - (void) setRequest:(NSURLRequest *)request {
 179     _assert(request_ == nil);
 180     request_ = request;
 181 }
 182
 183 - (void) setURL:(NSURL *)url {
 184     [self setRequest:[self requestWithURL:url cachePolicy:NSURLRequestUseProtocolCachePolicy]];
 185 }
 186
 187 - (void) loadURL:(NSURL *)url cachePolicy:(NSURLRequestCachePolicy)policy {
 188     [self loadRequest:[self requestWithURL:url cachePolicy:policy]];
 189 }
 190
 191 - (void) loadURL:(NSURL *)url {
 192     [self loadURL:url cachePolicy:NSURLRequestUseProtocolCachePolicy];
 193 }
 194
 195 - (void) loadRequest:(NSURLRequest *)request {
 196 #if LogBrowser
 197     NSLog(@"loadRequest:%@", request);
 198 #endif
 199
 200     error_ = false;
 201     ready_ = true;
 202
 203     WebThreadLocked lock;
 204     [[self webView] loadRequest:request];
 205 }
 206
 207 - (void) reloadURLWithCache:(BOOL)cache {
 208     if (request_ == nil)
 209         return;
 210
 211     NSMutableURLRequest *request([request_ mutableCopy]);
 212     [request setCachePolicy:(cache ? NSURLRequestUseProtocolCachePolicy : NSURLRequestReloadIgnoringLocalCacheData)];
 213
 214     request_ = request;
 215
 216     if ([request_ HTTPBody] == nil && [request_ HTTPBodyStream] == nil)
 217         [self loadRequest:request_];
 218     else {
 219         UIAlertView *alert = [[[UIAlertView alloc]
 220             initWithTitle:UCLocalize("RESUBMIT_FORM")
 221             message:nil
 222             delegate:self
 223             cancelButtonTitle:UCLocalize("CANCEL")
 224             otherButtonTitles:
 225                 UCLocalize("SUBMIT"),
 226             nil
 227         ] autorelease];
 228
 229         [alert setContext:@"submit"];
 230         [alert show];
 231     }
 232 }
 233
 234 - (void) reloadURL {
 235     [self reloadURLWithCache:YES];
 236 }
 237
 238 - (void) reloadData {
 239     [super reloadData];
 240
 241     if (ready_)
 242         [self dispatchEvent:@"CydiaReloadData"];
 243     else
 244         [self reloadURLWithCache:YES];
 245 }
 246
 247 - (void) setButtonImage:(NSString *)button withStyle:(NSString *)style toFunction:(id)function {
 248     custom_ = button;
 249     style_ = style;
 250     function_ = function;
 251
 252     [self performSelectorOnMainThread:@selector(applyRightButton) withObject:nil waitUntilDone:NO];
 253 }
 254
 255 - (void) setButtonTitle:(NSString *)button withStyle:(NSString *)style toFunction:(id)function {
 256     custom_ = button;
 257     style_ = style;
 258     function_ = function;
 259
 260     [self performSelectorOnMainThread:@selector(applyRightButton) withObject:nil waitUntilDone:NO];
 261 }
 262
 263 - (void) removeButton {
 264     custom_ = [NSNull null];
 265     [self performSelectorOnMainThread:@selector(applyRightButton) withObject:nil waitUntilDone:NO];
 266 }
 267
 268 - (void) scrollToBottomAnimated:(NSNumber *)animated {
 269     CGSize size([scroller_ contentSize]);
 270     CGPoint offset([scroller_ contentOffset]);
 271     CGRect frame([scroller_ frame]);
 272
 273     if (size.height - offset.y < frame.size.height + 20.f) {
 274         CGRect rect = {{0, size.height-1}, {size.width, 1}};
 275         [scroller_ scrollRectToVisible:rect animated:[animated boolValue]];
 276     }
 277 }
 278
 279 - (void) _setViewportWidth {
 280     [[[self webView] _documentView] setViewportSize:CGSizeMake(width_, UIWebViewGrowsAndShrinksToFitHeight) forDocumentTypes:0x10];
 281 }
 282
 283 - (void) setViewportWidth:(float)width {
 284     width_ = width != 0 ? width : [[self class] defaultWidth];
 285     [self _setViewportWidth];
 286 }
 287
 288 - (void) _setViewportWidthOnMainThread:(NSNumber *)width {
 289     [self setViewportWidth:[width floatValue]];
 290 }
 291
 292 - (void) setViewportWidthOnMainThread:(float)width {
 293     [self performSelectorOnMainThread:@selector(_setViewportWidthOnMainThread:) withObject:[NSNumber numberWithFloat:width] waitUntilDone:NO];
 294 }
 295
 296 - (void) webViewUpdateViewSettings:(UIWebView *)view {
 297     [self _setViewportWidth];
 298 }
 299
 300 - (void) mailComposeController:(MFMailComposeViewController*)controller didFinishWithResult:(MFMailComposeResult)result error:(NSError*)error {
 301     [self dismissModalViewControllerAnimated:YES];
 302 }
 303
 304 - (void) _setupMail:(MFMailComposeViewController *)controller {
 305 }
 306
 307 - (void) _openMailToURL:(NSURL *)url {
 308     if ($MFMailComposeViewController != nil && [$MFMailComposeViewController canSendMail]) {
 309         MFMailComposeViewController *controller([[[$MFMailComposeViewController alloc] init] autorelease]);
 310         [controller setMailComposeDelegate:self];
 311
 312         [controller setMailToURL:url];
 313
 314         [self _setupMail:controller];
 315
 316         [self presentModalViewController:controller animated:YES];
 317         return;
 318     }
 319
 320     UIApplication *app([UIApplication sharedApplication]);
 321     if ([app respondsToSelector:@selector(openURL:asPanel:)])
 322         [app openURL:url asPanel:YES];
 323     else
 324         [app openURL:url];
 325 }
 326
 327 - (bool) _allowJavaScriptPanel {
 328     return true;
 329 }
 330
 331 - (bool) allowsNavigationAction {
 332     return allowsNavigationAction_;
 333 }
 334
 335 - (void) setAllowsNavigationAction:(bool)value {
 336     allowsNavigationAction_ = value;
 337 }
 338
 339 - (void) setAllowsNavigationActionByNumber:(NSNumber *)value {
 340     [self setAllowsNavigationAction:[value boolValue]];
 341 }
 342
 343 - (void) popViewControllerWithNumber:(NSNumber *)value {
 344     UINavigationController *navigation([self navigationController]);
 345     if ([navigation topViewController] == self)
 346         [navigation popViewControllerAnimated:[value boolValue]];
 347 }
 348
 349 - (void) _didFailWithError:(NSError *)error forFrame:(WebFrame *)frame {
 350     [loading_ removeObject:[NSValue valueWithNonretainedObject:frame]];
 351     [self _didFinishLoading];
 352
 353     if ([[error domain] isEqualToString:NSURLErrorDomain] && [error code] == NSURLErrorCancelled)
 354         return;
 355
 356     if ([[error domain] isEqualToString:WebKitErrorDomain] && [error code] == WebKitErrorFrameLoadInterruptedByPolicyChange) {
 357         request_ = nil;
 358         return;
 359     }
 360
 361     if ([frame parentFrame] == nil) {
 362         [self loadURL:[NSURL URLWithString:[NSString stringWithFormat:@"%@?%@",
 363             [[NSURL fileURLWithPath:[[NSBundle mainBundle] pathForResource:@"error" ofType:@"html"]] absoluteString],
 364             [[error localizedDescription] stringByAddingPercentEscapes]
 365         ]]];
 366
 367         error_ = true;
 368     }
 369 }
 370
 371 - (void) pushRequest:(NSURLRequest *)request asPop:(bool)pop {
 372     NSURL *url([request URL]);
 373
 374     // XXX: filter to internal usage?
 375     CyteViewController *page([delegate_ pageForURL:url forExternal:NO]);
 376
 377     if (page == nil) {
 378         CyteWebViewController *browser([[[class_ alloc] init] autorelease]);
 379         [browser setRequest:request];
 380         page = browser;
 381     }
 382
 383     [page setDelegate:delegate_];
 384
 385     if (!pop) {
 386         [[self navigationItem] setTitle:title_];
 387
 388         [[self navigationController] pushViewController:page animated:YES];
 389     } else {
 390         UINavigationController *navigation([[[UINavigationController alloc] initWithRootViewController:page] autorelease]);
 391
 392         [navigation setDelegate:delegate_];
 393
 394         [[page navigationItem] setLeftBarButtonItem:[[[UIBarButtonItem alloc]
 395             initWithTitle:UCLocalize("CLOSE")
 396             style:UIBarButtonItemStylePlain
 397             target:page
 398             action:@selector(close)
 399         ] autorelease]];
 400
 401         [[self navigationController] presentModalViewController:navigation animated:YES];
 402     }
 403 }
 404
 405 // CyteWebViewDelegate {{{
 406 - (void) webView:(WebView *)view addMessageToConsole:(NSDictionary *)message {
 407 #if LogMessages
 408     static Pcre irritating("^(?"
 409         ":" "The page at .* displayed insecure content from .*\\."
 410         "|" "Unsafe JavaScript attempt to access frame with URL .* from frame with URL .*\\. Domains, protocols and ports must match\\."
 411     ")\\n$");
 412
 413     if (NSString *data = [message objectForKey:@"message"])
 414         if (irritating(data))
 415             return;
 416
 417     NSLog(@"addMessageToConsole:%@", message);
 418 #endif
 419 }
 420
 421 - (void) webView:(WebView *)view decidePolicyForNavigationAction:(NSDictionary *)action request:(NSURLRequest *)request frame:(WebFrame *)frame decisionListener:(id<WebPolicyDecisionListener>)listener {
 422 #if LogBrowser
 423     NSLog(@"decidePolicyForNavigationAction:%@ request:%@ frame:%@", action, request, frame);
 424 #endif
 425
 426     if ([frame parentFrame] == nil) {
 427         if (!error_) {
 428             NSURL *url(request == nil ? nil : [request URL]);
 429
 430             if (request_ != nil && ![[request_ URL] isEqual:url] && ![self allowsNavigationAction]) {
 431                 if (url != nil)
 432                     [self pushRequest:request asPop:NO];
 433                 [listener ignore];
 434             }
 435         }
 436     }
 437 }
 438
 439 - (void) webView:(WebView *)view didDecidePolicy:(CYWebPolicyDecision)decision forNavigationAction:(NSDictionary *)action request:(NSURLRequest *)request frame:(WebFrame *)frame {
 440     if ([frame parentFrame] == nil)
 441         if (decision == CYWebPolicyDecisionUse)
 442             if (!error_)
 443                 request_ = request;
 444 }
 445
 446 - (void) webView:(WebView *)view decidePolicyForNewWindowAction:(NSDictionary *)action request:(NSURLRequest *)request newFrameName:(NSString *)frame decisionListener:(id<WebPolicyDecisionListener>)listener {
 447 #if LogBrowser
 448     NSLog(@"decidePolicyForNewWindowAction:%@ request:%@ newFrameName:%@", action, request, frame);
 449 #endif
 450
 451     NSURL *url([request URL]);
 452     if (url == nil)
 453         return;
 454
 455     if ([frame isEqualToString:@"_open"])
 456         [delegate_ openURL:url];
 457     else {
 458         NSString *scheme([[url scheme] lowercaseString]);
 459         if ([scheme isEqualToString:@"mailto"])
 460             [self _openMailToURL:url];
 461         else
 462             [self pushRequest:request asPop:[frame isEqualToString:@"_popup"]];
 463     }
 464
 465     [listener ignore];
 466 }
 467
 468 - (void) webView:(WebView *)view didClearWindowObject:(WebScriptObject *)window forFrame:(WebFrame *)frame {
 469 }
 470
 471 - (void) webView:(WebView *)view didCommitLoadForFrame:(WebFrame *)frame {
 472 #if LogBrowser
 473     NSLog(@"didCommitLoadForFrame:%@", frame);
 474 #endif
 475
 476     if ([frame parentFrame] == nil) {
 477         loaded_ = true;
 478     }
 479 }
 480
 481 - (void) webView:(WebView *)view didFailLoadWithError:(NSError *)error forFrame:(WebFrame *)frame {
 482 #if LogBrowser
 483     NSLog(@"didFailLoadWithError:%@ forFrame:%@", error, frame);
 484 #endif
 485
 486     [self _didFailWithError:error forFrame:frame];
 487 }
 488
 489 - (void) webView:(WebView *)view didFailProvisionalLoadWithError:(NSError *)error forFrame:(WebFrame *)frame {
 490 #if LogBrowser
 491     NSLog(@"didFailProvisionalLoadWithError:%@ forFrame:%@", error, frame);
 492 #endif
 493
 494     [self _didFailWithError:error forFrame:frame];
 495 }
 496
 497 - (void) webView:(WebView *)view didFinishLoadForFrame:(WebFrame *)frame {
 498     [loading_ removeObject:[NSValue valueWithNonretainedObject:frame]];
 499
 500     if ([frame parentFrame] == nil) {
 501         if (DOMDocument *document = [frame DOMDocument])
 502             if (DOMNodeList<NSFastEnumeration> *bodies = [document getElementsByTagName:@"body"])
 503                 for (DOMHTMLBodyElement *body in (id) bodies) {
 504                     DOMCSSStyleDeclaration *style([document getComputedStyle:body pseudoElement:nil]);
 505
 506                     UIColor *uic(nil);
 507
 508                     if (DOMCSSPrimitiveValue *color = static_cast<DOMCSSPrimitiveValue *>([style getPropertyCSSValue:@"background-color"])) {
 509                         if ([color primitiveType] == DOM_CSS_RGBCOLOR) {
 510                             DOMRGBColor *rgb([color getRGBColorValue]);
 511
 512                             float red([[rgb red] getFloatValue:DOM_CSS_NUMBER]);
 513                             float green([[rgb green] getFloatValue:DOM_CSS_NUMBER]);
 514                             float blue([[rgb blue] getFloatValue:DOM_CSS_NUMBER]);
 515                             float alpha([[rgb alpha] getFloatValue:DOM_CSS_NUMBER]);
 516
 517                             if (red == 0xc7 && green == 0xce && blue == 0xd5)
 518                                 uic = [UIColor pinStripeColor];
 519                             else if (alpha != 0)
 520                                 uic = [UIColor
 521                                     colorWithRed:(red / 255)
 522                                     green:(green / 255)
 523                                     blue:(blue / 255)
 524                                     alpha:alpha
 525                                 ];
 526                         }
 527                     }
 528
 529                     [scroller_ setBackgroundColor:(uic ?: [UIColor clearColor])];
 530                     break;
 531                 }
 532     }
 533
 534     [self _didFinishLoading];
 535 }
 536
 537 - (void) webView:(WebView *)view didReceiveTitle:(NSString *)title forFrame:(WebFrame *)frame {
 538     if ([frame parentFrame] != nil)
 539         return;
 540
 541     title_ = title;
 542
 543     [[self navigationItem] setTitle:title_];
 544 }
 545
 546 - (void) webView:(WebView *)view didStartProvisionalLoadForFrame:(WebFrame *)frame {
 547 #if LogBrowser
 548     NSLog(@"didStartProvisionalLoadForFrame:%@", frame);
 549 #endif
 550
 551     [loading_ addObject:[NSValue valueWithNonretainedObject:frame]];
 552
 553     if ([frame parentFrame] == nil) {
 554         title_ = nil;
 555         custom_ = nil;
 556         style_ = nil;
 557         function_ = nil;
 558
 559         allowsNavigationAction_ = true;
 560
 561         [self setHidesNavigationBar:NO];
 562         [self setScrollIndicatorStyle:UIScrollViewIndicatorStyleDefault];
 563
 564         // XXX: do we still need to do this?
 565         [[self navigationItem] setTitle:nil];
 566     }
 567
 568     [self _didStartLoading];
 569 }
 570
 571 - (NSURLRequest *) webView:(WebView *)view resource:(id)identifier willSendRequest:(NSURLRequest *)request redirectResponse:(NSURLResponse *)response fromDataSource:(WebDataSource *)source {
 572 #if LogBrowser
 573     NSLog(@"resource:%@ willSendRequest:%@ redirectResponse:%@ fromDataSource:%@", identifier, request, response, source);
 574 #endif
 575
 576     return request;
 577 }
 578
 579 - (bool) webView:(WebView *)view shouldRunJavaScriptAlertPanelWithMessage:(NSString *)message initiatedByFrame:(WebFrame *)frame {
 580     return [self _allowJavaScriptPanel];
 581 }
 582
 583 - (bool) webView:(WebView *)view shouldRunJavaScriptConfirmPanelWithMessage:(NSString *)message initiatedByFrame:(WebFrame *)frame {
 584     return [self _allowJavaScriptPanel];
 585 }
 586
 587 - (bool) webView:(WebView *)view shouldRunJavaScriptTextInputPanelWithPrompt:(NSString *)prompt defaultText:(NSString *)text initiatedByFrame:(WebFrame *)frame {
 588     return [self _allowJavaScriptPanel];
 589 }
 590
 591 - (void) webViewClose:(WebView *)view {
 592     [self close];
 593 }
 594 // }}}
 595
 596 - (void) close {
 597     [[[self navigationController] parentViewController] dismissModalViewControllerAnimated:YES];
 598 }
 599
 600 - (void) alertView:(UIAlertView *)alert clickedButtonAtIndex:(NSInteger)button {
 601     NSString *context([alert context]);
 602
 603     if ([context isEqualToString:@"sensitive"]) {
 604         switch (button) {
 605             case 1:
 606                 sensitive_ = [NSNumber numberWithBool:YES];
 607             break;
 608
 609             case 2:
 610                 sensitive_ = [NSNumber numberWithBool:NO];
 611             break;
 612         }
 613
 614         [alert dismissWithClickedButtonIndex:-1 animated:YES];
 615     } else if ([context isEqualToString:@"challenge"]) {
 616         id<NSURLAuthenticationChallengeSender> sender([challenge_ sender]);
 617
 618         switch (button) {
 619             case 1: {
 620                 NSString *username([[alert textFieldAtIndex:0] text]);
 621                 NSString *password([[alert textFieldAtIndex:1] text]);
 622
 623                 NSURLCredential *credential([NSURLCredential credentialWithUser:username password:password persistence:NSURLCredentialPersistenceForSession]);
 624
 625                 [sender useCredential:credential forAuthenticationChallenge:challenge_];
 626             } break;
 627
 628             case 2:
 629                 [sender cancelAuthenticationChallenge:challenge_];
 630             break;
 631
 632             _nodefault
 633         }
 634
 635         challenge_ = nil;
 636
 637         [alert dismissWithClickedButtonIndex:-1 animated:YES];
 638     } else if ([context isEqualToString:@"submit"]) {
 639         if (button == [alert cancelButtonIndex]) {
 640         } else if (button == [alert firstOtherButtonIndex]) {
 641             if (request_ != nil) {
 642                 WebThreadLocked lock;
 643                 [[self webView] loadRequest:request_];
 644             }
 645         }
 646
 647         [alert dismissWithClickedButtonIndex:-1 animated:YES];
 648     }
 649 }
 650
 651 - (UIBarButtonItemStyle) rightButtonStyle {
 652     if (style_ == nil) normal:
 653         return UIBarButtonItemStylePlain;
 654     else if ([style_ isEqualToString:@"Normal"])
 655         return UIBarButtonItemStylePlain;
 656     else if ([style_ isEqualToString:@"Highlighted"])
 657         return UIBarButtonItemStyleDone;
 658     else goto normal;
 659 }
 660
 661 - (UIBarButtonItem *) customButton {
 662     if (custom_ == nil)
 663         return nil;
 664     else if (custom_ == [NSNull null])
 665         return (UIBarButtonItem *) [NSNull null];
 666
 667     return [[[UIBarButtonItem alloc]
 668         initWithTitle:static_cast<NSString *>(custom_.operator NSObject *())
 669         style:[self rightButtonStyle]
 670         target:self
 671         action:@selector(customButtonClicked)
 672     ] autorelease];
 673 }
 674
 675 - (UIBarButtonItem *) leftButton {
 676     UINavigationItem *item([self navigationItem]);
 677     if ([item backBarButtonItem] != nil && ![item hidesBackButton])
 678         return nil;
 679
 680     if (UINavigationController *navigation = [self navigationController])
 681         if ([[navigation parentViewController] modalViewController] == navigation)
 682             return [[[UIBarButtonItem alloc]
 683                 initWithTitle:UCLocalize("CLOSE")
 684                 style:UIBarButtonItemStylePlain
 685                 target:self
 686                 action:@selector(close)
 687             ] autorelease];
 688
 689     return nil;
 690 }
 691
 692 - (void) applyLeftButton {
 693     [[self navigationItem] setLeftBarButtonItem:[self leftButton]];
 694 }
 695
 696 - (UIBarButtonItem *) rightButton {
 697     return reloaditem_;
 698 }
 699
 700 - (void) applyLoadingTitle {
 701     [[self navigationItem] setTitle:UCLocalize("LOADING")];
 702 }
 703
 704 - (void) layoutRightButton {
 705     [[loadingitem_ view] addSubview:indicator_];
 706     [[loadingitem_ view] bringSubviewToFront:indicator_];
 707 }
 708
 709 - (void) applyRightButton {
 710     if ([self isLoading]) {
 711         [[self navigationItem] setRightBarButtonItem:loadingitem_ animated:YES];
 712         [self performSelector:@selector(layoutRightButton) withObject:nil afterDelay:0];
 713
 714         [indicator_ startAnimating];
 715         [self applyLoadingTitle];
 716     } else {
 717         [indicator_ stopAnimating];
 718
 719         UIBarButtonItem *button([self customButton]);
 720         if (button == nil)
 721             button = [self rightButton];
 722         else if (button == (UIBarButtonItem *) [NSNull null])
 723             button = nil;
 724
 725         [[self navigationItem] setRightBarButtonItem:button animated:YES];
 726     }
 727 }
 728
 729 - (void) didStartLoading {
 730     // Overridden in subclasses.
 731 }
 732
 733 - (void) _didStartLoading {
 734     [self applyRightButton];
 735
 736     if ([loading_ count] != 1)
 737         return;
 738
 739     [delegate_ retainNetworkActivityIndicator];
 740     [self didStartLoading];
 741 }
 742
 743 - (void) didFinishLoading {
 744     // Overridden in subclasses.
 745 }
 746
 747 - (void) _didFinishLoading {
 748     if ([loading_ count] != 0)
 749         return;
 750
 751     [self applyRightButton];
 752     [[self navigationItem] setTitle:title_];
 753
 754     [delegate_ releaseNetworkActivityIndicator];
 755     [self didFinishLoading];
 756 }
 757
 758 - (bool) isLoading {
 759     return [loading_ count] != 0;
 760 }
 761
 762 - (id) initWithWidth:(float)width ofClass:(Class)_class {
 763     if ((self = [super init]) != nil) {
 764         width_ = width;
 765         class_ = _class;
 766
 767         allowsNavigationAction_ = true;
 768
 769         loading_ = [NSMutableSet setWithCapacity:5];
 770         indirect_ = [[[IndirectDelegate alloc] initWithDelegate:self] autorelease];
 771
 772         reloaditem_ = [[[UIBarButtonItem alloc]
 773             initWithTitle:UCLocalize("RELOAD")
 774             style:[self rightButtonStyle]
 775             target:self
 776             action:@selector(reloadButtonClicked)
 777         ] autorelease];
 778
 779         loadingitem_ = [[[UIBarButtonItem alloc]
 780             initWithTitle:@" "
 781             style:UIBarButtonItemStylePlain
 782             target:self
 783             action:@selector(reloadButtonClicked)
 784         ] autorelease];
 785
 786         indicator_ = [[[UIActivityIndicatorView alloc] initWithActivityIndicatorStyle:UIActivityIndicatorViewStyleWhite] autorelease];
 787         [indicator_ setFrame:CGRectMake(15, 5, [indicator_ frame].size.width, [indicator_ frame].size.height)];
 788         [indicator_ setAutoresizingMask:UIViewAutoresizingFlexibleLeftMargin];
 789
 790         [self applyLeftButton];
 791         [self applyRightButton];
 792     } return self;
 793 }
 794
 795 - (NSString *) applicationNameForUserAgent {
 796     return nil;
 797 }
 798
 799 - (void) loadView {
 800     CGRect bounds([[UIScreen mainScreen] applicationFrame]);
 801
 802     webview_ = [[[CyteWebView alloc] initWithFrame:bounds] autorelease];
 803     [webview_ setDelegate:self];
 804     [self setView:webview_];
 805
 806     if ([webview_ respondsToSelector:@selector(setDataDetectorTypes:)])
 807         [webview_ setDataDetectorTypes:UIDataDetectorTypeAutomatic];
 808     else
 809         [webview_ setDetectsPhoneNumbers:NO];
 810
 811     [webview_ setScalesPageToFit:YES];
 812
 813     UIWebDocumentView *document([webview_ _documentView]);
 814
 815     // XXX: I think this improves scrolling; the hardcoded-ness sucks
 816     [document setTileSize:CGSizeMake(320, 500)];
 817
 818     [document setBackgroundColor:[UIColor clearColor]];
 819
 820     // XXX: this is terribly (too?) expensive
 821     [document setDrawsBackground:NO];
 822
 823     WebView *webview([document webView]);
 824     WebPreferences *preferences([webview preferences]);
 825
 826     // XXX: I have no clue if I actually /want/ this modification
 827     if ([webview respondsToSelector:@selector(_setLayoutInterval:)])
 828         [webview _setLayoutInterval:0];
 829     else if ([preferences respondsToSelector:@selector(_setLayoutInterval:)])
 830         [preferences _setLayoutInterval:0];
 831
 832     [preferences setCacheModel:WebCacheModelDocumentBrowser];
 833     [preferences setJavaScriptCanOpenWindowsAutomatically:YES];
 834     [preferences setOfflineWebApplicationCacheEnabled:YES];
 835
 836     if (NSString *agent = [self applicationNameForUserAgent])
 837         [webview setApplicationNameForUserAgent:agent];
 838
 839     if ([webview respondsToSelector:@selector(setShouldUpdateWhileOffscreen:)])
 840         [webview setShouldUpdateWhileOffscreen:NO];
 841
 842 #if LogMessages
 843     if ([document respondsToSelector:@selector(setAllowsMessaging:)])
 844         [document setAllowsMessaging:YES];
 845     if ([webview respondsToSelector:@selector(_setAllowsMessaging:)])
 846         [webview _setAllowsMessaging:YES];
 847 #endif
 848
 849     if ([webview_ respondsToSelector:@selector(_scrollView)]) {
 850         scroller_ = [webview_ _scrollView];
 851
 852         [scroller_ setDirectionalLockEnabled:YES];
 853         [scroller_ setDecelerationRate:CYScrollViewDecelerationRateNormal];
 854         [scroller_ setDelaysContentTouches:NO];
 855
 856         [scroller_ setCanCancelContentTouches:YES];
 857     } else if ([webview_ respondsToSelector:@selector(_scroller)]) {
 858         UIScroller *scroller([webview_ _scroller]);
 859         scroller_ = (UIScrollView *) scroller;
 860
 861         [scroller setDirectionalScrolling:YES];
 862         // XXX: we might be better off /not/ setting this on older systems
 863         [scroller setScrollDecelerationFactor:CYScrollViewDecelerationRateNormal]; /* 0.989324 */
 864         [scroller setScrollHysteresis:0]; /* 8 */
 865
 866         [scroller setThumbDetectionEnabled:NO];
 867
 868         // use NO with UIApplicationUseLegacyEvents(YES)
 869         [scroller setEventMode:YES];
 870
 871         // XXX: this is handled by setBounces, right?
 872         //[scroller setAllowsRubberBanding:YES];
 873     }
 874
 875     [scroller_ setFixedBackgroundPattern:YES];
 876     [scroller_ setBackgroundColor:[UIColor clearColor]];
 877     [scroller_ setClipsSubviews:YES];
 878
 879     [scroller_ setBounces:YES];
 880     [scroller_ setScrollingEnabled:YES];
 881     [scroller_ setShowBackgroundShadow:NO];
 882
 883     [self setViewportWidth:width_];
 884
 885     UITableView *table([[[UITableView alloc] initWithFrame:[webview_ bounds] style:UITableViewStyleGrouped] autorelease]);
 886     [table setScrollsToTop:NO];
 887     [webview_ insertSubview:table atIndex:0];
 888
 889     [table setAutoresizingMask:(UIViewAutoresizingFlexibleWidth | UIViewAutoresizingFlexibleHeight)];
 890     [webview_ setAutoresizingMask:(UIViewAutoresizingFlexibleWidth | UIViewAutoresizingFlexibleHeight)];
 891
 892     ready_ = false;
 893 }
 894
 895 - (void) releaseSubviews {
 896     webview_ = nil;
 897     scroller_ = nil;
 898
 899     [super releaseSubviews];
 900 }
 901
 902 - (id) initWithWidth:(float)width {
 903     return [self initWithWidth:width ofClass:[self class]];
 904 }
 905
 906 - (id) init {
 907     return [self initWithWidth:0];
 908 }
 909
 910 - (id) initWithURL:(NSURL *)url {
 911     if ((self = [self init]) != nil) {
 912         [self setURL:url];
 913     } return self;
 914 }
 915
 916 - (void) callFunction:(WebScriptObject *)function {
 917     WebThreadLocked lock;
 918
 919     WebView *webview([[[self webView] _documentView] webView]);
 920     WebFrame *frame([webview mainFrame]);
 921
 922     JSGlobalContextRef context([frame globalContext]);
 923     JSObjectRef object([function JSObject]);
 924     JSObjectCallAsFunction(context, object, NULL, 0, NULL, NULL);
 925 }
 926
 927 - (void) reloadButtonClicked {
 928     [self reloadURLWithCache:YES];
 929 }
 930
 931 - (void) _customButtonClicked {
 932     [self reloadButtonClicked];
 933 }
 934
 935 - (void) customButtonClicked {
 936 #if !AlwaysReload
 937     if (function_ != nil)
 938         [self callFunction:function_];
 939     else
 940 #endif
 941     [self _customButtonClicked];
 942 }
 943
 944 + (float) defaultWidth {
 945     return 980;
 946 }
 947
 948 - (void) setNavigationBarStyle:(NSString *)name {
 949     UIBarStyle style;
 950     if ([name isEqualToString:@"Black"])
 951         style = UIBarStyleBlack;
 952     else
 953         style = UIBarStyleDefault;
 954
 955     [[[self navigationController] navigationBar] setBarStyle:style];
 956 }
 957
 958 - (void) setNavigationBarTintColor:(UIColor *)color {
 959     [[[self navigationController] navigationBar] setTintColor:color];
 960 }
 961
 962 - (void) setBadgeValue:(id)value {
 963     [[[self navigationController] tabBarItem] setBadgeValue:value];
 964 }
 965
 966 - (void) setHidesBackButton:(bool)value {
 967     [[self navigationItem] setHidesBackButton:value];
 968     [self applyLeftButton];
 969 }
 970
 971 - (void) setHidesBackButtonByNumber:(NSNumber *)value {
 972     [self setHidesBackButton:[value boolValue]];
 973 }
 974
 975 - (void) dispatchEvent:(NSString *)event {
 976     [[self webView] dispatchEvent:event];
 977 }
 978
 979 - (bool) hidesNavigationBar {
 980     return hidesNavigationBar_;
 981 }
 982
 983 - (void) _setHidesNavigationBar:(bool)value animated:(bool)animated {
 984     if (visible_)
 985         [[self navigationController] setNavigationBarHidden:(value && [self hidesNavigationBar]) animated:animated];
 986 }
 987
 988 - (void) setHidesNavigationBar:(bool)value {
 989     if (hidesNavigationBar_ != value) {
 990         hidesNavigationBar_ = value;
 991         [self _setHidesNavigationBar:YES animated:YES];
 992     }
 993 }
 994
 995 - (void) setHidesNavigationBarByNumber:(NSNumber *)value {
 996     [self setHidesNavigationBar:[value boolValue]];
 997 }
 998
 999 - (void) setScrollIndicatorStyle:(UIScrollViewIndicatorStyle)style {
1000     if ([webview_ respondsToSelector:@selector(_scrollView)]) {
1001         UIScrollView *scroller([webview_ _scrollView]);
1002         [scroller setIndicatorStyle:style];
1003     } else if ([webview_ respondsToSelector:@selector(_scroller)]) {
1004         UIScroller *scroller([webview_ _scroller]);
1005         [scroller setScrollerIndicatorStyle:style];
1006     } else return;
1007 }
1008
1009 - (void) setScrollIndicatorStyleWithName:(NSString *)style {
1010     UIScrollViewIndicatorStyle value;
1011
1012     if (false);
1013     else if ([style isEqualToString:@"default"])
1014         value = UIScrollViewIndicatorStyleDefault;
1015     else if ([style isEqualToString:@"black"])
1016         value = UIScrollViewIndicatorStyleBlack;
1017     else if ([style isEqualToString:@"white"])
1018         value = UIScrollViewIndicatorStyleWhite;
1019     else return;
1020
1021     [self setScrollIndicatorStyle:value];
1022 }
1023
1024 - (void) viewWillAppear:(BOOL)animated {
1025     visible_ = true;
1026
1027     if ([self hidesNavigationBar])
1028         [self _setHidesNavigationBar:YES animated:animated];
1029
1030     [self dispatchEvent:@"CydiaViewWillAppear"];
1031     [super viewWillAppear:animated];
1032 }
1033
1034 - (void) viewDidAppear:(BOOL)animated {
1035     [super viewDidAppear:animated];
1036     [self dispatchEvent:@"CydiaViewDidAppear"];
1037 }
1038
1039 - (void) viewWillDisappear:(BOOL)animated {
1040     [self dispatchEvent:@"CydiaViewWillDisappear"];
1041     [super viewWillDisappear:animated];
1042
1043     if ([self hidesNavigationBar])
1044         [self _setHidesNavigationBar:NO animated:animated];
1045
1046     visible_ = false;
1047 }
1048
1049 - (void) viewDidDisappear:(BOOL)animated {
1050     [super viewDidDisappear:animated];
1051     [self dispatchEvent:@"CydiaViewDidDisappear"];
1052 }
1053
1054 @end