CyteKit/WebViewController.mm

   1 #include "CyteKit/UCPlatform.h"
   2 #include "CyteKit/WebViewController.h"
   3
   4 #include "CyteKit/MFMailComposeViewController-MailToURL.h"
   5
   6 #include "iPhonePrivate.h"
   7
   8 #include "CyteKit/Localize.h"
   9 #include "CyteKit/WebViewController.h"
  10 #include "CyteKit/PerlCompatibleRegEx.hpp"
  11 #include "CyteKit/WebThreadLocked.hpp"
  12
  13 //#include <QuartzCore/CALayer.h>
  14 // XXX: fix the minimum requirement
  15 extern NSString * const kCAFilterNearest;
  16
  17 #include <WebCore/WebCoreThread.h>
  18
  19 #include <WebKit/WebKitErrors.h>
  20 #include <WebKit/WebPreferences.h>
  21
  22 #include <WebKit/DOMCSSPrimitiveValue.h>
  23 #include <WebKit/DOMCSSStyleDeclaration.h>
  24 #include <WebKit/DOMDocument.h>
  25 #include <WebKit/DOMHTMLBodyElement.h>
  26 #include <WebKit/DOMRGBColor.h>
  27
  28 #include <dlfcn.h>
  29 #include <objc/runtime.h>
  30
  31 #define ForSaurik 0
  32 #define DefaultTimeout_ 120.0
  33
  34 #define ShowInternals 0
  35 #define LogBrowser 0
  36 #define LogMessages 0
  37
  38 #define lprintf(args...) fprintf(stderr, args)
  39
  40 // XXX: centralize these special class things to some file or mechanism?
  41 static Class $MFMailComposeViewController;
  42
  43 float CYScrollViewDecelerationRateNormal;
  44
  45 @interface WebView (Apple)
  46 - (void) _setLayoutInterval:(float)interval;
  47 - (void) _setAllowsMessaging:(BOOL)allows;
  48 @end
  49
  50 @interface WebPreferences (Apple)
  51 + (void) _setInitialDefaultTextEncodingToSystemEncoding;
  52 - (void) _setLayoutInterval:(NSInteger)interval;
  53 - (void) setOfflineWebApplicationCacheEnabled:(BOOL)enabled;
  54 @end
  55
  56 @implementation WebFrame (Cydia)
  57
  58 - (NSString *) description {
  59     return [NSString stringWithFormat:@"<%s: %p, %@>", class_getName([self class]), self, [[[([self provisionalDataSource] ?: [self dataSource]) request] URL] absoluteString]];
  60 }
  61
  62 @end
  63
  64 /* Indirect Delegate {{{ */
  65 @interface IndirectDelegate : NSObject {
  66     _transient volatile id delegate_;
  67 }
  68
  69 - (void) setDelegate:(id)delegate;
  70 - (id) initWithDelegate:(id)delegate;
  71 @end
  72
  73 @implementation IndirectDelegate
  74
  75 - (void) setDelegate:(id)delegate {
  76     delegate_ = delegate;
  77 }
  78
  79 - (id) initWithDelegate:(id)delegate {
  80     delegate_ = delegate;
  81     return self;
  82 }
  83
  84 - (IMP) methodForSelector:(SEL)sel {
  85     if (IMP method = [super methodForSelector:sel])
  86         return method;
  87     fprintf(stderr, "methodForSelector:[%s] == NULL\n", sel_getName(sel));
  88     return NULL;
  89 }
  90
  91 - (BOOL) respondsToSelector:(SEL)sel {
  92     if ([super respondsToSelector:sel])
  93         return YES;
  94
  95     // XXX: WebThreadCreateNSInvocation returns nil
  96
  97 #if ShowInternals
  98     fprintf(stderr, "[%s]R?%s\n", class_getName(self->isa), sel_getName(sel));
  99 #endif
 100
 101     return delegate_ == nil ? NO : [delegate_ respondsToSelector:sel];
 102 }
 103
 104 - (NSMethodSignature *) methodSignatureForSelector:(SEL)sel {
 105     if (NSMethodSignature *method = [super methodSignatureForSelector:sel])
 106         return method;
 107
 108 #if ShowInternals
 109     fprintf(stderr, "[%s]S?%s\n", class_getName(self->isa), sel_getName(sel));
 110 #endif
 111
 112     if (delegate_ != nil)
 113         if (NSMethodSignature *sig = [delegate_ methodSignatureForSelector:sel])
 114             return sig;
 115
 116     // XXX: I fucking hate Apple so very very bad
 117     return [NSMethodSignature signatureWithObjCTypes:"v@:"];
 118 }
 119
 120 - (void) forwardInvocation:(NSInvocation *)inv {
 121     SEL sel = [inv selector];
 122     if (delegate_ != nil && [delegate_ respondsToSelector:sel])
 123         [inv invokeWithTarget:delegate_];
 124 }
 125
 126 @end
 127 /* }}} */
 128
 129 @implementation CyteWebViewController
 130
 131 #if ShowInternals
 132 #include "CyteKit/UCInternal.h"
 133 #endif
 134
 135 + (void) _initialize {
 136     [WebPreferences _setInitialDefaultTextEncodingToSystemEncoding];
 137
 138     dlopen("/System/Library/Frameworks/MessageUI.framework/MessageUI", RTLD_GLOBAL | RTLD_LAZY);
 139     $MFMailComposeViewController = objc_getClass("MFMailComposeViewController");
 140
 141     if (float *_UIScrollViewDecelerationRateNormal = reinterpret_cast<float *>(dlsym(RTLD_DEFAULT, "UIScrollViewDecelerationRateNormal")))
 142         CYScrollViewDecelerationRateNormal = *_UIScrollViewDecelerationRateNormal;
 143     else // XXX: this actually might be fast on some older systems: we should look into this
 144         CYScrollViewDecelerationRateNormal = 0.998;
 145 }
 146
 147 - (void) dealloc {
 148 #if LogBrowser
 149     NSLog(@"[CyteWebViewController dealloc]");
 150 #endif
 151
 152     if ([loading_ count] != 0)
 153         [delegate_ releaseNetworkActivityIndicator];
 154
 155     [super dealloc];
 156 }
 157
 158 - (NSString *) description {
 159     return [NSString stringWithFormat:@"<%s: %p, %@>", class_getName([self class]), self, [[request_ URL] absoluteString]];
 160 }
 161
 162 - (CyteWebView *) webView {
 163     return (CyteWebView *) [self view];
 164 }
 165
 166 - (NSURL *) URLWithURL:(NSURL *)url {
 167     return url;
 168 }
 169
 170 - (NSURLRequest *) requestWithURL:(NSURL *)url cachePolicy:(NSURLRequestCachePolicy)policy {
 171     return [NSURLRequest
 172         requestWithURL:[self URLWithURL:url]
 173         cachePolicy:policy
 174         timeoutInterval:DefaultTimeout_
 175     ];
 176 }
 177
 178 - (void) setRequest:(NSURLRequest *)request {
 179     _assert(request_ == nil);
 180     request_ = request;
 181 }
 182
 183 - (void) setURL:(NSURL *)url {
 184     [self setRequest:[self requestWithURL:url cachePolicy:NSURLRequestUseProtocolCachePolicy]];
 185 }
 186
 187 - (void) loadURL:(NSURL *)url cachePolicy:(NSURLRequestCachePolicy)policy {
 188     [self loadRequest:[self requestWithURL:url cachePolicy:policy]];
 189 }
 190
 191 - (void) loadURL:(NSURL *)url {
 192     [self loadURL:url cachePolicy:NSURLRequestUseProtocolCachePolicy];
 193 }
 194
 195 - (void) loadRequest:(NSURLRequest *)request {
 196 #if LogBrowser
 197     NSLog(@"loadRequest:%@", request);
 198 #endif
 199
 200     error_ = false;
 201     ready_ = true;
 202
 203     WebThreadLocked lock;
 204     [[self webView] loadRequest:request];
 205 }
 206
 207 - (void) reloadURLWithCache:(BOOL)cache {
 208     if (request_ == nil)
 209         return;
 210
 211     NSMutableURLRequest *request([request_ mutableCopy]);
 212     [request setCachePolicy:(cache ? NSURLRequestUseProtocolCachePolicy : NSURLRequestReloadIgnoringLocalCacheData)];
 213
 214     request_ = request;
 215
 216     if ([request_ HTTPBody] == nil && [request_ HTTPBodyStream] == nil)
 217         [self loadRequest:request_];
 218     else {
 219         UIAlertView *alert = [[[UIAlertView alloc]
 220             initWithTitle:UCLocalize("RESUBMIT_FORM")
 221             message:nil
 222             delegate:self
 223             cancelButtonTitle:UCLocalize("CANCEL")
 224             otherButtonTitles:
 225                 UCLocalize("SUBMIT"),
 226             nil
 227         ] autorelease];
 228
 229         [alert setContext:@"submit"];
 230         [alert show];
 231     }
 232 }
 233
 234 - (void) reloadURL {
 235     [self reloadURLWithCache:YES];
 236 }
 237
 238 - (void) reloadData {
 239     [super reloadData];
 240
 241     if (ready_)
 242         [self dispatchEvent:@"CydiaReloadData"];
 243     else
 244         [self reloadURLWithCache:YES];
 245 }
 246
 247 - (void) setButtonImage:(NSString *)button withStyle:(NSString *)style toFunction:(id)function {
 248     custom_ = button;
 249     style_ = style;
 250     function_ = function;
 251
 252     [self performSelectorOnMainThread:@selector(applyRightButton) withObject:nil waitUntilDone:NO];
 253 }
 254
 255 - (void) setButtonTitle:(NSString *)button withStyle:(NSString *)style toFunction:(id)function {
 256     custom_ = button;
 257     style_ = style;
 258     function_ = function;
 259
 260     [self performSelectorOnMainThread:@selector(applyRightButton) withObject:nil waitUntilDone:NO];
 261 }
 262
 263 - (void) removeButton {
 264     custom_ = [NSNull null];
 265     [self performSelectorOnMainThread:@selector(applyRightButton) withObject:nil waitUntilDone:NO];
 266 }
 267
 268 - (void) scrollToBottomAnimated:(NSNumber *)animated {
 269     CGSize size([scroller_ contentSize]);
 270     CGPoint offset([scroller_ contentOffset]);
 271     CGRect frame([scroller_ frame]);
 272
 273     if (size.height - offset.y < frame.size.height + 20.f) {
 274         CGRect rect = {{0, size.height-1}, {size.width, 1}};
 275         [scroller_ scrollRectToVisible:rect animated:[animated boolValue]];
 276     }
 277 }
 278
 279 - (void) _setViewportWidth {
 280     [[[self webView] _documentView] setViewportSize:CGSizeMake(width_, UIWebViewGrowsAndShrinksToFitHeight) forDocumentTypes:0x10];
 281 }
 282
 283 - (void) setViewportWidth:(float)width {
 284     width_ = width != 0 ? width : [[self class] defaultWidth];
 285     [self _setViewportWidth];
 286 }
 287
 288 - (void) _setViewportWidthOnMainThread:(NSNumber *)width {
 289     [self setViewportWidth:[width floatValue]];
 290 }
 291
 292 - (void) setViewportWidthOnMainThread:(float)width {
 293     [self performSelectorOnMainThread:@selector(_setViewportWidthOnMainThread:) withObject:[NSNumber numberWithFloat:width] waitUntilDone:NO];
 294 }
 295
 296 - (void) webViewUpdateViewSettings:(UIWebView *)view {
 297     [self _setViewportWidth];
 298 }
 299
 300 - (void) mailComposeController:(MFMailComposeViewController*)controller didFinishWithResult:(MFMailComposeResult)result error:(NSError*)error {
 301     [self dismissModalViewControllerAnimated:YES];
 302 }
 303
 304 - (void) _setupMail:(MFMailComposeViewController *)controller {
 305 }
 306
 307 - (void) _openMailToURL:(NSURL *)url {
 308     if ($MFMailComposeViewController != nil && [$MFMailComposeViewController canSendMail]) {
 309         MFMailComposeViewController *controller([[[$MFMailComposeViewController alloc] init] autorelease]);
 310         [controller setMailComposeDelegate:self];
 311
 312         [controller setMailToURL:url];
 313
 314         [self _setupMail:controller];
 315
 316         [self presentModalViewController:controller animated:YES];
 317         return;
 318     }
 319
 320     UIApplication *app([UIApplication sharedApplication]);
 321     if ([app respondsToSelector:@selector(openURL:asPanel:)])
 322         [app openURL:url asPanel:YES];
 323     else
 324         [app openURL:url];
 325 }
 326
 327 - (bool) _allowJavaScriptPanel {
 328     return true;
 329 }
 330
 331 - (bool) allowsNavigationAction {
 332     return allowsNavigationAction_;
 333 }
 334
 335 - (void) setAllowsNavigationAction:(bool)value {
 336     allowsNavigationAction_ = value;
 337 }
 338
 339 - (void) setAllowsNavigationActionByNumber:(NSNumber *)value {
 340     [self setAllowsNavigationAction:[value boolValue]];
 341 }
 342
 343 - (void) popViewControllerWithNumber:(NSNumber *)value {
 344     UINavigationController *navigation([self navigationController]);
 345     if ([navigation topViewController] == self)
 346         [navigation popViewControllerAnimated:[value boolValue]];
 347 }
 348
 349 - (void) _didFailWithError:(NSError *)error forFrame:(WebFrame *)frame {
 350     [loading_ removeObject:[NSValue valueWithNonretainedObject:frame]];
 351     [self _didFinishLoading];
 352
 353     if ([[error domain] isEqualToString:NSURLErrorDomain] && [error code] == NSURLErrorCancelled)
 354         return;
 355
 356     if ([[error domain] isEqualToString:WebKitErrorDomain] && [error code] == WebKitErrorFrameLoadInterruptedByPolicyChange) {
 357         request_ = nil;
 358         return;
 359     }
 360
 361     if ([frame parentFrame] == nil) {
 362         [self loadURL:[NSURL URLWithString:[NSString stringWithFormat:@"%@?%@",
 363             [[NSURL fileURLWithPath:[[NSBundle mainBundle] pathForResource:@"error" ofType:@"html"]] absoluteString],
 364             [[error localizedDescription] stringByAddingPercentEscapes]
 365         ]]];
 366
 367         error_ = true;
 368     }
 369 }
 370
 371 - (void) pushRequest:(NSURLRequest *)request asPop:(bool)pop {
 372     NSURL *url([request URL]);
 373
 374     // XXX: filter to internal usage?
 375     CyteViewController *page([delegate_ pageForURL:url forExternal:NO]);
 376
 377     if (page == nil) {
 378         CyteWebViewController *browser([[[class_ alloc] init] autorelease]);
 379         [browser setRequest:request];
 380         page = browser;
 381     }
 382
 383     [page setDelegate:delegate_];
 384
 385     if (!pop) {
 386         [[self navigationItem] setTitle:title_];
 387
 388         [[self navigationController] pushViewController:page animated:YES];
 389     } else {
 390         UINavigationController *navigation([[[UINavigationController alloc] initWithRootViewController:page] autorelease]);
 391
 392         [navigation setDelegate:delegate_];
 393
 394         [[page navigationItem] setLeftBarButtonItem:[[[UIBarButtonItem alloc]
 395             initWithTitle:UCLocalize("CLOSE")
 396             style:UIBarButtonItemStylePlain
 397             target:page
 398             action:@selector(close)
 399         ] autorelease]];
 400
 401         [[self navigationController] presentModalViewController:navigation animated:YES];
 402     }
 403 }
 404
 405 // CyteWebViewDelegate {{{
 406 - (void) webView:(WebView *)view addMessageToConsole:(NSDictionary *)message {
 407 #if LogMessages
 408     static Pcre irritating("^(?"
 409         ":" "The page at .* displayed insecure content from .*\\."
 410         "|" "Unsafe JavaScript attempt to access frame with URL .* from frame with URL .*\\. Domains, protocols and ports must match\\."
 411     ")\\n$");
 412
 413     if (NSString *data = [message objectForKey:@"message"])
 414         if (irritating(data))
 415             return;
 416
 417     NSLog(@"addMessageToConsole:%@", message);
 418 #endif
 419 }
 420
 421 - (void) webView:(WebView *)view decidePolicyForNavigationAction:(NSDictionary *)action request:(NSURLRequest *)request frame:(WebFrame *)frame decisionListener:(id<WebPolicyDecisionListener>)listener {
 422 #if LogBrowser
 423     NSLog(@"decidePolicyForNavigationAction:%@ request:%@ frame:%@", action, request, frame);
 424 #endif
 425
 426     if ([frame parentFrame] == nil) {
 427         if (!error_) {
 428             NSURL *url(request == nil ? nil : [request URL]);
 429
 430             if (request_ != nil && ![[request_ URL] isEqual:url] && ![self allowsNavigationAction]) {
 431                 if (url != nil)
 432                     [self pushRequest:request asPop:NO];
 433                 [listener ignore];
 434             }
 435         }
 436     }
 437 }
 438
 439 - (void) webView:(WebView *)view didDecidePolicy:(CYWebPolicyDecision)decision forNavigationAction:(NSDictionary *)action request:(NSURLRequest *)request frame:(WebFrame *)frame {
 440     if ([frame parentFrame] == nil)
 441         if (decision == CYWebPolicyDecisionUse)
 442             if (!error_)
 443                 request_ = request;
 444 }
 445
 446 - (void) webView:(WebView *)view decidePolicyForNewWindowAction:(NSDictionary *)action request:(NSURLRequest *)request newFrameName:(NSString *)frame decisionListener:(id<WebPolicyDecisionListener>)listener {
 447 #if LogBrowser
 448     NSLog(@"decidePolicyForNewWindowAction:%@ request:%@ newFrameName:%@", action, request, frame);
 449 #endif
 450
 451     NSURL *url([request URL]);
 452     if (url == nil)
 453         return;
 454
 455     if ([frame isEqualToString:@"_open"])
 456         [delegate_ openURL:url];
 457     else {
 458         NSString *scheme([[url scheme] lowercaseString]);
 459         if ([scheme isEqualToString:@"mailto"])
 460             [self _openMailToURL:url];
 461         else
 462             [self pushRequest:request asPop:[frame isEqualToString:@"_popup"]];
 463     }
 464
 465     [listener ignore];
 466 }
 467
 468 - (void) webView:(WebView *)view didClearWindowObject:(WebScriptObject *)window forFrame:(WebFrame *)frame {
 469 }
 470
 471 - (void) webView:(WebView *)view didCommitLoadForFrame:(WebFrame *)frame {
 472 #if LogBrowser
 473     NSLog(@"didCommitLoadForFrame:%@", frame);
 474 #endif
 475
 476     if ([frame parentFrame] == nil) {
 477         loaded_ = true;
 478     }
 479 }
 480
 481 - (void) webView:(WebView *)view didFailLoadWithError:(NSError *)error forFrame:(WebFrame *)frame {
 482 #if LogBrowser
 483     NSLog(@"didFailLoadWithError:%@ forFrame:%@", error, frame);
 484 #endif
 485
 486     [self _didFailWithError:error forFrame:frame];
 487 }
 488
 489 - (void) webView:(WebView *)view didFailProvisionalLoadWithError:(NSError *)error forFrame:(WebFrame *)frame {
 490 #if LogBrowser
 491     NSLog(@"didFailProvisionalLoadWithError:%@ forFrame:%@", error, frame);
 492 #endif
 493
 494     [self _didFailWithError:error forFrame:frame];
 495 }
 496
 497 - (void) webView:(WebView *)view didFinishLoadForFrame:(WebFrame *)frame {
 498     [loading_ removeObject:[NSValue valueWithNonretainedObject:frame]];
 499
 500     if ([frame parentFrame] == nil) {
 501         if (DOMDocument *document = [frame DOMDocument])
 502             if (DOMNodeList<NSFastEnumeration> *bodies = [document getElementsByTagName:@"body"])
 503                 for (DOMHTMLBodyElement *body in (id) bodies) {
 504                     DOMCSSStyleDeclaration *style([document getComputedStyle:body pseudoElement:nil]);
 505
 506                     UIColor *uic(nil);
 507
 508                     if (DOMCSSPrimitiveValue *color = static_cast<DOMCSSPrimitiveValue *>([style getPropertyCSSValue:@"background-color"])) {
 509                         if ([color primitiveType] == DOM_CSS_RGBCOLOR) {
 510                             DOMRGBColor *rgb([color getRGBColorValue]);
 511
 512                             float red([[rgb red] getFloatValue:DOM_CSS_NUMBER]);
 513                             float green([[rgb green] getFloatValue:DOM_CSS_NUMBER]);
 514                             float blue([[rgb blue] getFloatValue:DOM_CSS_NUMBER]);
 515                             float alpha([[rgb alpha] getFloatValue:DOM_CSS_NUMBER]);
 516
 517                             if (red == 0xc7 && green == 0xce && blue == 0xd5)
 518                                 uic = [UIColor pinStripeColor];
 519                             else if (alpha != 0)
 520                                 uic = [UIColor
 521                                     colorWithRed:(red / 255)
 522                                     green:(green / 255)
 523                                     blue:(blue / 255)
 524                                     alpha:alpha
 525                                 ];
 526                         }
 527                     }
 528
 529                     [scroller_ setBackgroundColor:(uic ?: [UIColor clearColor])];
 530                     break;
 531                 }
 532     }
 533
 534     [self _didFinishLoading];
 535 }
 536
 537 - (void) webView:(WebView *)view didReceiveTitle:(NSString *)title forFrame:(WebFrame *)frame {
 538     if ([frame parentFrame] != nil)
 539         return;
 540
 541     title_ = title;
 542
 543     [[self navigationItem] setTitle:title_];
 544 }
 545
 546 - (void) webView:(WebView *)view didStartProvisionalLoadForFrame:(WebFrame *)frame {
 547 #if LogBrowser
 548     NSLog(@"didStartProvisionalLoadForFrame:%@", frame);
 549 #endif
 550
 551     [loading_ addObject:[NSValue valueWithNonretainedObject:frame]];
 552
 553     if ([frame parentFrame] == nil) {
 554         title_ = nil;
 555         custom_ = nil;
 556         style_ = nil;
 557         function_ = nil;
 558
 559         allowsNavigationAction_ = true;
 560
 561         [self setHidesNavigationBar:NO];
 562
 563         // XXX: do we still need to do this?
 564         [[self navigationItem] setTitle:nil];
 565     }
 566
 567     [self _didStartLoading];
 568 }
 569
 570 - (NSURLRequest *) webView:(WebView *)view resource:(id)identifier willSendRequest:(NSURLRequest *)request redirectResponse:(NSURLResponse *)response fromDataSource:(WebDataSource *)source {
 571 #if LogBrowser
 572     NSLog(@"resource:%@ willSendRequest:%@ redirectResponse:%@ fromDataSource:%@", identifier, request, response, source);
 573 #endif
 574
 575     return request;
 576 }
 577
 578 - (bool) webView:(WebView *)view shouldRunJavaScriptAlertPanelWithMessage:(NSString *)message initiatedByFrame:(WebFrame *)frame {
 579     return [self _allowJavaScriptPanel];
 580 }
 581
 582 - (bool) webView:(WebView *)view shouldRunJavaScriptConfirmPanelWithMessage:(NSString *)message initiatedByFrame:(WebFrame *)frame {
 583     return [self _allowJavaScriptPanel];
 584 }
 585
 586 - (bool) webView:(WebView *)view shouldRunJavaScriptTextInputPanelWithPrompt:(NSString *)prompt defaultText:(NSString *)text initiatedByFrame:(WebFrame *)frame {
 587     return [self _allowJavaScriptPanel];
 588 }
 589
 590 - (void) webViewClose:(WebView *)view {
 591     [self close];
 592 }
 593 // }}}
 594
 595 - (void) close {
 596     [[[self navigationController] parentViewController] dismissModalViewControllerAnimated:YES];
 597 }
 598
 599 - (void) alertView:(UIAlertView *)alert clickedButtonAtIndex:(NSInteger)button {
 600     NSString *context([alert context]);
 601
 602     if ([context isEqualToString:@"sensitive"]) {
 603         switch (button) {
 604             case 1:
 605                 sensitive_ = [NSNumber numberWithBool:YES];
 606             break;
 607
 608             case 2:
 609                 sensitive_ = [NSNumber numberWithBool:NO];
 610             break;
 611         }
 612
 613         [alert dismissWithClickedButtonIndex:-1 animated:YES];
 614     } else if ([context isEqualToString:@"challenge"]) {
 615         id<NSURLAuthenticationChallengeSender> sender([challenge_ sender]);
 616
 617         switch (button) {
 618             case 1: {
 619                 NSString *username([[alert textFieldAtIndex:0] text]);
 620                 NSString *password([[alert textFieldAtIndex:1] text]);
 621
 622                 NSURLCredential *credential([NSURLCredential credentialWithUser:username password:password persistence:NSURLCredentialPersistenceForSession]);
 623
 624                 [sender useCredential:credential forAuthenticationChallenge:challenge_];
 625             } break;
 626
 627             case 2:
 628                 [sender cancelAuthenticationChallenge:challenge_];
 629             break;
 630
 631             _nodefault
 632         }
 633
 634         challenge_ = nil;
 635
 636         [alert dismissWithClickedButtonIndex:-1 animated:YES];
 637     } else if ([context isEqualToString:@"submit"]) {
 638         if (button == [alert cancelButtonIndex]) {
 639         } else if (button == [alert firstOtherButtonIndex]) {
 640             if (request_ != nil) {
 641                 WebThreadLocked lock;
 642                 [[self webView] loadRequest:request_];
 643             }
 644         }
 645
 646         [alert dismissWithClickedButtonIndex:-1 animated:YES];
 647     }
 648 }
 649
 650 - (UIBarButtonItemStyle) rightButtonStyle {
 651     if (style_ == nil) normal:
 652         return UIBarButtonItemStylePlain;
 653     else if ([style_ isEqualToString:@"Normal"])
 654         return UIBarButtonItemStylePlain;
 655     else if ([style_ isEqualToString:@"Highlighted"])
 656         return UIBarButtonItemStyleDone;
 657     else goto normal;
 658 }
 659
 660 - (UIBarButtonItem *) customButton {
 661     if (custom_ == nil)
 662         return nil;
 663     else if (custom_ == [NSNull null])
 664         return (UIBarButtonItem *) [NSNull null];
 665
 666     return [[[UIBarButtonItem alloc]
 667         initWithTitle:static_cast<NSString *>(custom_.operator NSObject *())
 668         style:[self rightButtonStyle]
 669         target:self
 670         action:@selector(customButtonClicked)
 671     ] autorelease];
 672 }
 673
 674 - (UIBarButtonItem *) leftButton {
 675     UINavigationItem *item([self navigationItem]);
 676     if ([item backBarButtonItem] != nil && ![item hidesBackButton])
 677         return nil;
 678
 679     if (UINavigationController *navigation = [self navigationController])
 680         if ([[navigation parentViewController] modalViewController] == navigation)
 681             return [[[UIBarButtonItem alloc]
 682                 initWithTitle:UCLocalize("CLOSE")
 683                 style:UIBarButtonItemStylePlain
 684                 target:self
 685                 action:@selector(close)
 686             ] autorelease];
 687
 688     return nil;
 689 }
 690
 691 - (void) applyLeftButton {
 692     [[self navigationItem] setLeftBarButtonItem:[self leftButton]];
 693 }
 694
 695 - (UIBarButtonItem *) rightButton {
 696     return reloaditem_;
 697 }
 698
 699 - (void) applyLoadingTitle {
 700     [[self navigationItem] setTitle:UCLocalize("LOADING")];
 701 }
 702
 703 - (void) layoutRightButton {
 704     [[loadingitem_ view] addSubview:indicator_];
 705     [[loadingitem_ view] bringSubviewToFront:indicator_];
 706 }
 707
 708 - (void) applyRightButton {
 709     if ([self isLoading]) {
 710         [[self navigationItem] setRightBarButtonItem:loadingitem_ animated:YES];
 711         [self performSelector:@selector(layoutRightButton) withObject:nil afterDelay:0];
 712
 713         [indicator_ startAnimating];
 714         [self applyLoadingTitle];
 715     } else {
 716         [indicator_ stopAnimating];
 717
 718         UIBarButtonItem *button([self customButton]);
 719         if (button == nil)
 720             button = [self rightButton];
 721         else if (button == (UIBarButtonItem *) [NSNull null])
 722             button = nil;
 723
 724         [[self navigationItem] setRightBarButtonItem:button animated:YES];
 725     }
 726 }
 727
 728 - (void) didStartLoading {
 729     // Overridden in subclasses.
 730 }
 731
 732 - (void) _didStartLoading {
 733     [self applyRightButton];
 734
 735     if ([loading_ count] != 1)
 736         return;
 737
 738     [delegate_ retainNetworkActivityIndicator];
 739     [self didStartLoading];
 740 }
 741
 742 - (void) didFinishLoading {
 743     // Overridden in subclasses.
 744 }
 745
 746 - (void) _didFinishLoading {
 747     if ([loading_ count] != 0)
 748         return;
 749
 750     [self applyRightButton];
 751     [[self navigationItem] setTitle:title_];
 752
 753     [delegate_ releaseNetworkActivityIndicator];
 754     [self didFinishLoading];
 755 }
 756
 757 - (bool) isLoading {
 758     return [loading_ count] != 0;
 759 }
 760
 761 - (id) initWithWidth:(float)width ofClass:(Class)_class {
 762     if ((self = [super init]) != nil) {
 763         width_ = width;
 764         class_ = _class;
 765
 766         allowsNavigationAction_ = true;
 767
 768         loading_ = [NSMutableSet setWithCapacity:5];
 769         indirect_ = [[[IndirectDelegate alloc] initWithDelegate:self] autorelease];
 770
 771         reloaditem_ = [[[UIBarButtonItem alloc]
 772             initWithTitle:UCLocalize("RELOAD")
 773             style:[self rightButtonStyle]
 774             target:self
 775             action:@selector(reloadButtonClicked)
 776         ] autorelease];
 777
 778         loadingitem_ = [[[UIBarButtonItem alloc]
 779             initWithTitle:@" "
 780             style:UIBarButtonItemStylePlain
 781             target:self
 782             action:@selector(reloadButtonClicked)
 783         ] autorelease];
 784
 785         indicator_ = [[[UIActivityIndicatorView alloc] initWithActivityIndicatorStyle:UIActivityIndicatorViewStyleWhite] autorelease];
 786         [indicator_ setFrame:CGRectMake(15, 5, [indicator_ frame].size.width, [indicator_ frame].size.height)];
 787         [indicator_ setAutoresizingMask:UIViewAutoresizingFlexibleLeftMargin];
 788
 789         [self applyLeftButton];
 790         [self applyRightButton];
 791     } return self;
 792 }
 793
 794 - (NSString *) applicationNameForUserAgent {
 795     return nil;
 796 }
 797
 798 - (void) loadView {
 799     CGRect bounds([[UIScreen mainScreen] applicationFrame]);
 800
 801     webview_ = [[[CyteWebView alloc] initWithFrame:bounds] autorelease];
 802     [webview_ setDelegate:self];
 803     [self setView:webview_];
 804
 805     if ([webview_ respondsToSelector:@selector(setDataDetectorTypes:)])
 806         [webview_ setDataDetectorTypes:UIDataDetectorTypeAutomatic];
 807     else
 808         [webview_ setDetectsPhoneNumbers:NO];
 809
 810     [webview_ setScalesPageToFit:YES];
 811
 812     UIWebDocumentView *document([webview_ _documentView]);
 813
 814     // XXX: I think this improves scrolling; the hardcoded-ness sucks
 815     [document setTileSize:CGSizeMake(320, 500)];
 816
 817     [document setBackgroundColor:[UIColor clearColor]];
 818
 819     // XXX: this is terribly (too?) expensive
 820     [document setDrawsBackground:NO];
 821
 822     WebView *webview([document webView]);
 823     WebPreferences *preferences([webview preferences]);
 824
 825     // XXX: I have no clue if I actually /want/ this modification
 826     if ([webview respondsToSelector:@selector(_setLayoutInterval:)])
 827         [webview _setLayoutInterval:0];
 828     else if ([preferences respondsToSelector:@selector(_setLayoutInterval:)])
 829         [preferences _setLayoutInterval:0];
 830
 831     [preferences setCacheModel:WebCacheModelDocumentBrowser];
 832     [preferences setJavaScriptCanOpenWindowsAutomatically:YES];
 833     [preferences setOfflineWebApplicationCacheEnabled:YES];
 834
 835     if (NSString *agent = [self applicationNameForUserAgent])
 836         [webview setApplicationNameForUserAgent:agent];
 837
 838     if ([webview respondsToSelector:@selector(setShouldUpdateWhileOffscreen:)])
 839         [webview setShouldUpdateWhileOffscreen:NO];
 840
 841 #if LogMessages
 842     if ([document respondsToSelector:@selector(setAllowsMessaging:)])
 843         [document setAllowsMessaging:YES];
 844     if ([webview respondsToSelector:@selector(_setAllowsMessaging:)])
 845         [webview _setAllowsMessaging:YES];
 846 #endif
 847
 848     if ([webview_ respondsToSelector:@selector(_scrollView)]) {
 849         scroller_ = [webview_ _scrollView];
 850
 851         [scroller_ setDirectionalLockEnabled:YES];
 852         [scroller_ setDecelerationRate:CYScrollViewDecelerationRateNormal];
 853         [scroller_ setDelaysContentTouches:NO];
 854
 855         [scroller_ setCanCancelContentTouches:YES];
 856     } else if ([webview_ respondsToSelector:@selector(_scroller)]) {
 857         UIScroller *scroller([webview_ _scroller]);
 858         scroller_ = (UIScrollView *) scroller;
 859
 860         [scroller setDirectionalScrolling:YES];
 861         // XXX: we might be better off /not/ setting this on older systems
 862         [scroller setScrollDecelerationFactor:CYScrollViewDecelerationRateNormal]; /* 0.989324 */
 863         [scroller setScrollHysteresis:0]; /* 8 */
 864
 865         [scroller setThumbDetectionEnabled:NO];
 866
 867         // use NO with UIApplicationUseLegacyEvents(YES)
 868         [scroller setEventMode:YES];
 869
 870         // XXX: this is handled by setBounces, right?
 871         //[scroller setAllowsRubberBanding:YES];
 872     }
 873
 874     [scroller_ setFixedBackgroundPattern:YES];
 875     [scroller_ setBackgroundColor:[UIColor clearColor]];
 876     [scroller_ setClipsSubviews:YES];
 877
 878     [scroller_ setBounces:YES];
 879     [scroller_ setScrollingEnabled:YES];
 880     [scroller_ setShowBackgroundShadow:NO];
 881
 882     [self setViewportWidth:width_];
 883
 884     UITableView *table([[[UITableView alloc] initWithFrame:[webview_ bounds] style:UITableViewStyleGrouped] autorelease]);
 885     [table setScrollsToTop:NO];
 886     [webview_ insertSubview:table atIndex:0];
 887
 888     [table setAutoresizingMask:(UIViewAutoresizingFlexibleWidth | UIViewAutoresizingFlexibleHeight)];
 889     [webview_ setAutoresizingMask:(UIViewAutoresizingFlexibleWidth | UIViewAutoresizingFlexibleHeight)];
 890
 891     ready_ = false;
 892 }
 893
 894 - (void) releaseSubviews {
 895     webview_ = nil;
 896     scroller_ = nil;
 897
 898     [super releaseSubviews];
 899 }
 900
 901 - (id) initWithWidth:(float)width {
 902     return [self initWithWidth:width ofClass:[self class]];
 903 }
 904
 905 - (id) init {
 906     return [self initWithWidth:0];
 907 }
 908
 909 - (id) initWithURL:(NSURL *)url {
 910     if ((self = [self init]) != nil) {
 911         [self setURL:url];
 912     } return self;
 913 }
 914
 915 - (void) callFunction:(WebScriptObject *)function {
 916     WebThreadLocked lock;
 917
 918     WebView *webview([[[self webView] _documentView] webView]);
 919     WebFrame *frame([webview mainFrame]);
 920
 921     JSGlobalContextRef context([frame globalContext]);
 922     JSObjectRef object([function JSObject]);
 923     JSObjectCallAsFunction(context, object, NULL, 0, NULL, NULL);
 924 }
 925
 926 - (void) reloadButtonClicked {
 927     [self reloadURLWithCache:YES];
 928 }
 929
 930 - (void) _customButtonClicked {
 931     [self reloadButtonClicked];
 932 }
 933
 934 - (void) customButtonClicked {
 935 #if !AlwaysReload
 936     if (function_ != nil)
 937         [self callFunction:function_];
 938     else
 939 #endif
 940     [self _customButtonClicked];
 941 }
 942
 943 + (float) defaultWidth {
 944     return 980;
 945 }
 946
 947 - (void) setNavigationBarStyle:(NSString *)name {
 948     UIBarStyle style;
 949     if ([name isEqualToString:@"Black"])
 950         style = UIBarStyleBlack;
 951     else
 952         style = UIBarStyleDefault;
 953
 954     [[[self navigationController] navigationBar] setBarStyle:style];
 955 }
 956
 957 - (void) setNavigationBarTintColor:(UIColor *)color {
 958     [[[self navigationController] navigationBar] setTintColor:color];
 959 }
 960
 961 - (void) setBadgeValue:(id)value {
 962     [[[self navigationController] tabBarItem] setBadgeValue:value];
 963 }
 964
 965 - (void) setHidesBackButton:(bool)value {
 966     [[self navigationItem] setHidesBackButton:value];
 967     [self applyLeftButton];
 968 }
 969
 970 - (void) setHidesBackButtonByNumber:(NSNumber *)value {
 971     [self setHidesBackButton:[value boolValue]];
 972 }
 973
 974 - (void) dispatchEvent:(NSString *)event {
 975     [[self webView] dispatchEvent:event];
 976 }
 977
 978 - (bool) hidesNavigationBar {
 979     return hidesNavigationBar_;
 980 }
 981
 982 - (void) _setHidesNavigationBar:(bool)value animated:(bool)animated {
 983     if (visible_)
 984         [[self navigationController] setNavigationBarHidden:(value && [self hidesNavigationBar]) animated:animated];
 985 }
 986
 987 - (void) setHidesNavigationBar:(bool)value {
 988     if (hidesNavigationBar_ != value) {
 989         hidesNavigationBar_ = value;
 990         [self _setHidesNavigationBar:YES animated:YES];
 991     }
 992 }
 993
 994 - (void) setHidesNavigationBarByNumber:(NSNumber *)value {
 995     [self setHidesNavigationBar:[value boolValue]];
 996 }
 997
 998 - (void) viewWillAppear:(BOOL)animated {
 999     visible_ = true;
1000
1001     if ([self hidesNavigationBar])
1002         [self _setHidesNavigationBar:YES animated:animated];
1003
1004     [self dispatchEvent:@"CydiaViewWillAppear"];
1005     [super viewWillAppear:animated];
1006 }
1007
1008 - (void) viewDidAppear:(BOOL)animated {
1009     [super viewDidAppear:animated];
1010     [self dispatchEvent:@"CydiaViewDidAppear"];
1011 }
1012
1013 - (void) viewWillDisappear:(BOOL)animated {
1014     [self dispatchEvent:@"CydiaViewWillDisappear"];
1015     [super viewWillDisappear:animated];
1016
1017     if ([self hidesNavigationBar])
1018         [self _setHidesNavigationBar:NO animated:animated];
1019
1020     visible_ = false;
1021 }
1022
1023 - (void) viewDidDisappear:(BOOL)animated {
1024     [super viewDidDisappear:animated];
1025     [self dispatchEvent:@"CydiaViewDidDisappear"];
1026 }
1027
1028 @end