UICaboodle/BrowserView.mm

   1 #include <UIKit/UIKit.h>
   2 #include "iPhonePrivate.h"
   3
   4 #include "UCPlatform.h"
   5
   6 #include <UICaboodle/BrowserView.h>
   7 #include <UICaboodle/UCLocalize.h>
   8
   9 //#include <QuartzCore/CALayer.h>
  10 // XXX: fix the minimum requirement
  11 extern NSString * const kCAFilterNearest;
  12
  13 #include <WebCore/WebCoreThread.h>
  14
  15 #include <WebKit/WebPolicyDelegate.h>
  16 #include <WebKit/WebPreferences.h>
  17
  18 #include <WebKit/DOMCSSPrimitiveValue.h>
  19 #include <WebKit/DOMCSSStyleDeclaration.h>
  20 #include <WebKit/DOMDocument.h>
  21 #include <WebKit/DOMHTMLBodyElement.h>
  22 #include <WebKit/DOMRGBColor.h>
  23
  24 //#include <WebCore/Page.h>
  25 //#include <WebCore/Settings.h>
  26
  27 #include "substrate.h"
  28
  29 #define ForSaurik 0
  30 #define DefaultTimeout_ 120.0
  31
  32 #define ShowInternals 0
  33 #define LogBrowser 0
  34 #define LogMessages 0
  35
  36 #define lprintf(args...) fprintf(stderr, args)
  37
  38 // WebThreadLocked {{{
  39 struct WebThreadLocked {
  40     _finline WebThreadLocked() {
  41         WebThreadLock();
  42     }
  43
  44     _finline ~WebThreadLocked() {
  45         WebThreadUnlock();
  46     }
  47 };
  48 // }}}
  49
  50 template <typename Type_>
  51 static inline void CYRelease(Type_ &value) {
  52     if (value != nil) {
  53         [value release];
  54         value = nil;
  55     }
  56 }
  57
  58 float CYScrollViewDecelerationRateNormal;
  59
  60 @interface WebView (Apple)
  61 - (void) _setLayoutInterval:(float)interval;
  62 - (void) _setAllowsMessaging:(BOOL)allows;
  63 @end
  64
  65 @interface WebPreferences (Apple)
  66 + (void) _setInitialDefaultTextEncodingToSystemEncoding;
  67 - (void) _setLayoutInterval:(NSInteger)interval;
  68 - (void) setOfflineWebApplicationCacheEnabled:(BOOL)enabled;
  69 @end
  70
  71 /* Indirect Delegate {{{ */
  72 @interface IndirectDelegate : NSObject {
  73     _transient volatile id delegate_;
  74 }
  75
  76 - (void) setDelegate:(id)delegate;
  77 - (id) initWithDelegate:(id)delegate;
  78 @end
  79
  80 @implementation IndirectDelegate
  81
  82 - (void) setDelegate:(id)delegate {
  83     delegate_ = delegate;
  84 }
  85
  86 - (id) initWithDelegate:(id)delegate {
  87     delegate_ = delegate;
  88     return self;
  89 }
  90
  91 - (IMP) methodForSelector:(SEL)sel {
  92     if (IMP method = [super methodForSelector:sel])
  93         return method;
  94     fprintf(stderr, "methodForSelector:[%s] == NULL\n", sel_getName(sel));
  95     return NULL;
  96 }
  97
  98 - (BOOL) respondsToSelector:(SEL)sel {
  99     if ([super respondsToSelector:sel])
 100         return YES;
 101
 102     // XXX: WebThreadCreateNSInvocation returns nil
 103
 104 #if ShowInternals
 105     fprintf(stderr, "[%s]R?%s\n", class_getName(self->isa), sel_getName(sel));
 106 #endif
 107
 108     return delegate_ == nil ? NO : [delegate_ respondsToSelector:sel];
 109 }
 110
 111 - (NSMethodSignature *) methodSignatureForSelector:(SEL)sel {
 112     if (NSMethodSignature *method = [super methodSignatureForSelector:sel])
 113         return method;
 114
 115 #if ShowInternals
 116     fprintf(stderr, "[%s]S?%s\n", class_getName(self->isa), sel_getName(sel));
 117 #endif
 118
 119     if (delegate_ != nil)
 120         if (NSMethodSignature *sig = [delegate_ methodSignatureForSelector:sel])
 121             return sig;
 122
 123     // XXX: I fucking hate Apple so very very bad
 124     return [NSMethodSignature signatureWithObjCTypes:"v@:"];
 125 }
 126
 127 - (void) forwardInvocation:(NSInvocation *)inv {
 128     SEL sel = [inv selector];
 129     if (delegate_ != nil && [delegate_ respondsToSelector:sel])
 130         [inv invokeWithTarget:delegate_];
 131 }
 132
 133 @end
 134 /* }}} */
 135
 136 @implementation WebScriptObject (UICaboodle)
 137
 138 - (NSUInteger) count {
 139     id length([self valueForKey:@"length"]);
 140     if ([length respondsToSelector:@selector(intValue)])
 141         return [length intValue];
 142     else
 143         return 0;
 144 }
 145
 146 - (id) objectAtIndex:(unsigned)index {
 147     return [self webScriptValueAtIndex:index];
 148 }
 149
 150 @end
 151
 152 // CYWebPolicyDecision* {{{
 153 enum CYWebPolicyDecision {
 154     CYWebPolicyDecisionUnknown,
 155     CYWebPolicyDecisionDownload,
 156     CYWebPolicyDecisionIgnore,
 157     CYWebPolicyDecisionUse,
 158 };
 159
 160 @interface CYWebPolicyDecisionMediator : NSObject <
 161     WebPolicyDecisionListener
 162 > {
 163     id<WebPolicyDecisionListener> listener_;
 164     CYWebPolicyDecision decision_;
 165 }
 166
 167 - (id) initWithListener:(id<WebPolicyDecisionListener>)listener;
 168
 169 - (CYWebPolicyDecision) decision;
 170 - (bool) decided;
 171 - (bool) decide;
 172
 173 @end
 174
 175 @implementation CYWebPolicyDecisionMediator
 176
 177 - (id) initWithListener:(id<WebPolicyDecisionListener>)listener {
 178     if ((self = [super init]) != nil) {
 179         listener_ = listener;
 180     } return self;
 181 }
 182
 183 - (CYWebPolicyDecision) decision {
 184     return decision_;
 185 }
 186
 187 - (bool) decided {
 188     return decision_ != CYWebPolicyDecisionUnknown;
 189 }
 190
 191 - (bool) decide {
 192     switch (decision_) {
 193         case CYWebPolicyDecisionUnknown:
 194         default:
 195             NSLog(@"CYWebPolicyDecisionUnknown");
 196             return false;
 197
 198         case CYWebPolicyDecisionDownload: [listener_ download]; break;
 199         case CYWebPolicyDecisionIgnore: [listener_ ignore]; break;
 200         case CYWebPolicyDecisionUse: [listener_ use]; break;
 201     }
 202
 203     return true;
 204 }
 205
 206 - (void) download {
 207     decision_ = CYWebPolicyDecisionDownload;
 208 }
 209
 210 - (void) ignore {
 211     decision_ = CYWebPolicyDecisionIgnore;
 212 }
 213
 214 - (void) use {
 215     decision_ = CYWebPolicyDecisionUse;
 216 }
 217
 218 @end
 219 // }}}
 220
 221 @implementation CYWebView : UIWebView
 222
 223 #if ShowInternals
 224 #include "UICaboodle/UCInternal.h"
 225 #endif
 226
 227 - (id) initWithFrame:(CGRect)frame {
 228     if ((self = [super initWithFrame:frame]) != nil) {
 229     } return self;
 230 }
 231
 232 - (void) dealloc {
 233     [super dealloc];
 234 }
 235
 236 - (id<CYWebViewDelegate>) delegate {
 237     return (id<CYWebViewDelegate>) [super delegate];
 238 }
 239
 240 /*- (WebView *) webView:(WebView *)view createWebViewWithRequest:(NSURLRequest *)request {
 241     id<CYWebViewDelegate> delegate([self delegate]);
 242     WebView *created(nil);
 243     if (created == nil && [delegate respondsToSelector:@selector(webView:createWebViewWithRequest:)])
 244         created = [delegate webView:view createWebViewWithRequest:request];
 245     if (created == nil && [UIWebView instancesRespondToSelector:@selector(webView:createWebViewWithRequest:)])
 246         created = [super webView:view createWebViewWithRequest:request];
 247     return created;
 248 }*/
 249
 250 // webView:addMessageToConsole: (X.Xx) {{{
 251 static void $UIWebViewWebViewDelegate$webView$addMessageToConsole$(UIWebViewWebViewDelegate *self, SEL sel, WebView *view, NSDictionary *message) {
 252     UIWebView *uiWebView(MSHookIvar<UIWebView *>(self, "uiWebView"));
 253     if ([uiWebView respondsToSelector:@selector(webView:addMessageToConsole:)])
 254         [uiWebView webView:view addMessageToConsole:message];
 255 }
 256
 257 - (void) webView:(WebView *)view addMessageToConsole:(NSDictionary *)message {
 258     id<CYWebViewDelegate> delegate([self delegate]);
 259     if ([delegate respondsToSelector:@selector(webView:addMessageToConsole:)])
 260         [delegate webView:view addMessageToConsole:message];
 261     if ([UIWebView instancesRespondToSelector:@selector(webView:addMessageToConsole:)])
 262         [super webView:view addMessageToConsole:message];
 263 }
 264 // }}}
 265 // webView:decidePolicyForNavigationAction:request:frame:decisionListener: (2.0+) {{{
 266 - (void) webView:(WebView *)view decidePolicyForNavigationAction:(NSDictionary *)action request:(NSURLRequest *)request frame:(WebFrame *)frame decisionListener:(id<WebPolicyDecisionListener>)listener {
 267     id<CYWebViewDelegate> delegate([self delegate]);
 268     CYWebPolicyDecisionMediator *mediator([[[CYWebPolicyDecisionMediator alloc] initWithListener:listener] autorelease]);
 269     if (![mediator decided] && [delegate respondsToSelector:@selector(webView:decidePolicyForNavigationAction:request:frame:decisionListener:)])
 270         [delegate webView:view decidePolicyForNavigationAction:action request:request frame:frame decisionListener:mediator];
 271     if (![mediator decided] && [UIWebView instancesRespondToSelector:@selector(webView:decidePolicyForNavigationAction:request:frame:decisionListener:)])
 272         [super webView:view decidePolicyForNavigationAction:action request:request frame:frame decisionListener:mediator];
 273     [mediator decide];
 274 }
 275 // }}}
 276 // webView:decidePolicyForNewWindowAction:request:newFrameName:decisionListener: (3.0+) {{{
 277 static void $UIWebViewWebViewDelegate$webView$decidePolicyForNewWindowAction$request$newFrameName$decisionListener$(UIWebViewWebViewDelegate *self, SEL sel, WebView *view, NSDictionary *action, NSURLRequest *request, NSString *frame, id<WebPolicyDecisionListener> listener) {
 278     UIWebView *uiWebView(MSHookIvar<UIWebView *>(self, "uiWebView"));
 279     if ([uiWebView respondsToSelector:@selector(webView:decidePolicyForNewWindowAction:request:newFrameName:decisionListener:)])
 280         [uiWebView webView:view decidePolicyForNewWindowAction:action request:request newFrameName:frame decisionListener:listener];
 281 }
 282
 283 - (void) webView:(WebView *)view decidePolicyForNewWindowAction:(NSDictionary *)action request:(NSURLRequest *)request newFrameName:(NSString *)frame decisionListener:(id<WebPolicyDecisionListener>)listener {
 284     id<CYWebViewDelegate> delegate([self delegate]);
 285     CYWebPolicyDecisionMediator *mediator([[[CYWebPolicyDecisionMediator alloc] initWithListener:listener] autorelease]);
 286     if (![mediator decided] && [delegate respondsToSelector:@selector(webView:decidePolicyForNewWindowAction:request:newFrameName:decisionListener:)])
 287         [delegate webView:view decidePolicyForNewWindowAction:action request:request newFrameName:frame decisionListener:mediator];
 288     if (![mediator decided] && [UIWebView instancesRespondToSelector:@selector(webView:decidePolicyForNewWindowAction:request:newFrameName:decisionListener:)])
 289         [super webView:view decidePolicyForNewWindowAction:action request:request newFrameName:frame decisionListener:mediator];
 290     [mediator decide];
 291 }
 292 // }}}
 293 // webView:didClearWindowObject:forFrame: (3.2+) {{{
 294 static void $UIWebViewWebViewDelegate$webView$didClearWindowObject$forFrame$(UIWebViewWebViewDelegate *self, SEL sel, WebView *view, WebScriptObject *window, WebFrame *frame) {
 295     UIWebView *uiWebView(MSHookIvar<UIWebView *>(self, "uiWebView"));
 296     if ([uiWebView respondsToSelector:@selector(webView:didClearWindowObject:forFrame:)])
 297         [uiWebView webView:view didClearWindowObject:window forFrame:frame];
 298 }
 299
 300 - (void) webView:(WebView *)view didClearWindowObject:(WebScriptObject *)window forFrame:(WebFrame *)frame {
 301     id<CYWebViewDelegate> delegate([self delegate]);
 302     if ([delegate respondsToSelector:@selector(webView:didClearWindowObject:forFrame:)])
 303         [delegate webView:view didClearWindowObject:window forFrame:frame];
 304     if ([UIWebView instancesRespondToSelector:@selector(webView:didClearWindowObject:forFrame:)])
 305         [super webView:view didClearWindowObject:window forFrame:frame];
 306 }
 307 // }}}
 308 // webView:didFailLoadWithError:forFrame: (2.0+) {{{
 309 - (void) webView:(WebView *)view didFailLoadWithError:(NSError *)error forFrame:(WebFrame *)frame {
 310     id<CYWebViewDelegate> delegate([self delegate]);
 311     if ([delegate respondsToSelector:@selector(webView:didFailLoadWithError:forFrame:)])
 312         [delegate webView:view didFailLoadWithError:error forFrame:frame];
 313     if ([UIWebView instancesRespondToSelector:@selector(webView:didFailLoadWithError:forFrame:)])
 314         [super webView:view didFailLoadWithError:error forFrame:frame];
 315 }
 316 // }}}
 317 // webView:didFailProvisionalLoadWithError:forFrame: (2.0+) {{{
 318 - (void) webView:(WebView *)view didFailProvisionalLoadWithError:(NSError *)error forFrame:(WebFrame *)frame {
 319     id<CYWebViewDelegate> delegate([self delegate]);
 320     if ([delegate respondsToSelector:@selector(webView:didFailProvisionalLoadWithError:forFrame:)])
 321         [delegate webView:view didFailProvisionalLoadWithError:error forFrame:frame];
 322     if ([UIWebView instancesRespondToSelector:@selector(webView:didFailProvisionalLoadWithError:forFrame:)])
 323         [super webView:view didFailProvisionalLoadWithError:error forFrame:frame];
 324 }
 325 // }}}
 326 // webView:didFinishLoadForFrame: (2.0+) {{{
 327 - (void) webView:(WebView *)view didFinishLoadForFrame:(WebFrame *)frame {
 328     id<CYWebViewDelegate> delegate([self delegate]);
 329     if ([delegate respondsToSelector:@selector(webView:didFinishLoadForFrame:)])
 330         [delegate webView:view didFinishLoadForFrame:frame];
 331     if ([UIWebView instancesRespondToSelector:@selector(webView:didFinishLoadForFrame:)])
 332         [super webView:view didFinishLoadForFrame:frame];
 333 }
 334 // }}}
 335 // webView:didReceiveTitle:forFrame: (3.2+) {{{
 336 static void $UIWebViewWebViewDelegate$webView$didReceiveTitle$forFrame$(UIWebViewWebViewDelegate *self, SEL sel, WebView *view, NSString *title, WebFrame *frame) {
 337     UIWebView *uiWebView(MSHookIvar<UIWebView *>(self, "uiWebView"));
 338     if ([uiWebView respondsToSelector:@selector(webView:didReceiveTitle:forFrame:)])
 339         [uiWebView webView:view didReceiveTitle:title forFrame:frame];
 340 }
 341
 342 - (void) webView:(WebView *)view didReceiveTitle:(NSString *)title forFrame:(WebFrame *)frame {
 343     id<CYWebViewDelegate> delegate([self delegate]);
 344     if ([delegate respondsToSelector:@selector(webView:didReceiveTitle:forFrame:)])
 345         [delegate webView:view didReceiveTitle:title forFrame:frame];
 346     if ([UIWebView instancesRespondToSelector:@selector(webView:didReceiveTitle:forFrame:)])
 347         [super webView:view didReceiveTitle:title forFrame:frame];
 348 }
 349 // }}}
 350 // webView:didStartProvisionalLoadForFrame: (2.0+) {{{
 351 - (void) webView:(WebView *)view didStartProvisionalLoadForFrame:(WebFrame *)frame {
 352     id<CYWebViewDelegate> delegate([self delegate]);
 353     if ([delegate respondsToSelector:@selector(webView:didStartProvisionalLoadForFrame:)])
 354         [delegate webView:view didStartProvisionalLoadForFrame:frame];
 355     if ([UIWebView instancesRespondToSelector:@selector(webView:didStartProvisionalLoadForFrame:)])
 356         [super webView:view didStartProvisionalLoadForFrame:frame];
 357 }
 358 // }}}
 359 // webView:resource:willSendRequest:redirectResponse:fromDataSource: (3.2+) {{{
 360 static NSURLRequest *$UIWebViewWebViewDelegate$webView$resource$willSendRequest$redirectResponse$fromDataSource$(UIWebViewWebViewDelegate *self, SEL sel, WebView *view, id identifier, NSURLRequest *request, NSURLResponse *response, WebDataSource *source) {
 361     UIWebView *uiWebView(MSHookIvar<UIWebView *>(self, "uiWebView"));
 362     if ([uiWebView respondsToSelector:@selector(webView:resource:willSendRequest:redirectResponse:fromDataSource:)])
 363         request = [uiWebView webView:view resource:identifier willSendRequest:request redirectResponse:response fromDataSource:source];
 364     return request;
 365 }
 366
 367 - (NSURLRequest *) webView:(WebView *)view resource:(id)identifier willSendRequest:(NSURLRequest *)request redirectResponse:(NSURLResponse *)response fromDataSource:(WebDataSource *)source {
 368     id<CYWebViewDelegate> delegate([self delegate]);
 369     if ([UIWebView instancesRespondToSelector:@selector(webView:resource:willSendRequest:redirectResponse:fromDataSource:)])
 370         request = [super webView:view resource:identifier willSendRequest:request redirectResponse:response fromDataSource:source];
 371     if ([delegate respondsToSelector:@selector(webView:resource:willSendRequest:redirectResponse:fromDataSource:)])
 372         request = [delegate webView:view resource:identifier willSendRequest:request redirectResponse:response fromDataSource:source];
 373     return request;
 374 }
 375 // }}}
 376 // webView:runJavaScriptAlertPanelWithMessage:initiatedByFrame: (2.1+) {{{
 377 - (void) webView:(WebView *)view runJavaScriptAlertPanelWithMessage:(NSString *)message initiatedByFrame:(WebFrame *)frame {
 378     id<CYWebViewDelegate> delegate([self delegate]);
 379     if ([UIWebView instancesRespondToSelector:@selector(webView:runJavaScriptAlertPanelWithMessage:initiatedByFrame:)])
 380         if (
 381             ![delegate respondsToSelector:@selector(webView:shouldRunJavaScriptAlertPanelWithMessage:initiatedByFrame:)] ||
 382             [delegate webView:view shouldRunJavaScriptAlertPanelWithMessage:message initiatedByFrame:frame]
 383         )
 384             [super webView:view runJavaScriptAlertPanelWithMessage:message initiatedByFrame:frame];
 385 }
 386 // }}}
 387 // webView:runJavaScriptConfirmPanelWithMessage:initiatedByFrame: (2.1+) {{{
 388 - (BOOL) webView:(WebView *)view runJavaScriptConfirmPanelWithMessage:(NSString *)message initiatedByFrame:(WebFrame *)frame {
 389     id<CYWebViewDelegate> delegate([self delegate]);
 390     if ([UIWebView instancesRespondToSelector:@selector(webView:runJavaScriptConfirmPanelWithMessage:initiatedByFrame:)])
 391         if (
 392             ![delegate respondsToSelector:@selector(webView:shouldRunJavaScriptConfirmPanelWithMessage:initiatedByFrame:)] ||
 393             [delegate webView:view shouldRunJavaScriptConfirmPanelWithMessage:message initiatedByFrame:frame]
 394         )
 395             return [super webView:view runJavaScriptConfirmPanelWithMessage:message initiatedByFrame:frame];
 396     return NO;
 397 }
 398 // }}}
 399 // webView:runJavaScriptTextInputPanelWithPrompt:defaultText:initiatedByFrame: (2.1+) {{{
 400 - (NSString *) webView:(WebView *)view runJavaScriptTextInputPanelWithPrompt:(NSString *)prompt defaultText:(NSString *)text initiatedByFrame:(WebFrame *)frame {
 401     id<CYWebViewDelegate> delegate([self delegate]);
 402     if ([UIWebView instancesRespondToSelector:@selector(webView:runJavaScriptTextInputPanelWithPrompt:defaultText:initiatedByFrame:)])
 403         if (
 404             ![delegate respondsToSelector:@selector(webView:shouldRunJavaScriptTextInputPanelWithPrompt:defaultText:initiatedByFrame:)] ||
 405             [delegate webView:view shouldRunJavaScriptTextInputPanelWithPrompt:prompt defaultText:text initiatedByFrame:frame]
 406         )
 407             return [super webView:view runJavaScriptTextInputPanelWithPrompt:prompt defaultText:text initiatedByFrame:frame];
 408     return nil;
 409 }
 410 // }}}
 411 // webViewClose: (3.2+) {{{
 412 static void $UIWebViewWebViewDelegate$webViewClose$(UIWebViewWebViewDelegate *self, SEL sel, WebView *view) {
 413     UIWebView *uiWebView(MSHookIvar<UIWebView *>(self, "uiWebView"));
 414     if ([uiWebView respondsToSelector:@selector(webViewClose:)])
 415         [uiWebView webViewClose:view];
 416 }
 417
 418 - (void) webViewClose:(WebView *)view {
 419     id<CYWebViewDelegate> delegate([self delegate]);
 420     if ([delegate respondsToSelector:@selector(webViewClose:)])
 421         [delegate webViewClose:view];
 422     if ([UIWebView instancesRespondToSelector:@selector(webViewClose:)])
 423         [super webViewClose:view];
 424 }
 425 // }}}
 426
 427 - (void) _updateViewSettings {
 428     [super _updateViewSettings];
 429
 430     id<CYWebViewDelegate> delegate([self delegate]);
 431     if ([delegate respondsToSelector:@selector(webViewUpdateViewSettings:)])
 432         [delegate webViewUpdateViewSettings:self];
 433 }
 434
 435 + (void) initialize {
 436     if (Class $UIWebViewWebViewDelegate = objc_getClass("UIWebViewWebViewDelegate")) {
 437         class_addMethod($UIWebViewWebViewDelegate, @selector(webView:addMessageToConsole:), (IMP) &$UIWebViewWebViewDelegate$webView$addMessageToConsole$, "v16@0:4@8@12");
 438         class_addMethod($UIWebViewWebViewDelegate, @selector(webView:decidePolicyForNewWindowAction:request:newFrameName:decisionListener:), (IMP) &$UIWebViewWebViewDelegate$webView$decidePolicyForNewWindowAction$request$newFrameName$decisionListener$, "v28@0:4@8@12@16@20@24");
 439         class_addMethod($UIWebViewWebViewDelegate, @selector(webView:didClearWindowObject:forFrame:), (IMP) &$UIWebViewWebViewDelegate$webView$didClearWindowObject$forFrame$, "v20@0:4@8@12@16");
 440         class_addMethod($UIWebViewWebViewDelegate, @selector(webView:didReceiveTitle:forFrame:), (IMP) &$UIWebViewWebViewDelegate$webView$didReceiveTitle$forFrame$, "v20@0:4@8@12@16");
 441         class_addMethod($UIWebViewWebViewDelegate, @selector(webView:resource:willSendRequest:redirectResponse:fromDataSource:), (IMP) &$UIWebViewWebViewDelegate$webView$resource$willSendRequest$redirectResponse$fromDataSource$, "@28@0:4@8@12@16@20@24");
 442         class_addMethod($UIWebViewWebViewDelegate, @selector(webViewClose:), (IMP) &$UIWebViewWebViewDelegate$webViewClose$, "v12@0:4@8");
 443     }
 444 }
 445
 446 @end
 447
 448 @implementation BrowserController
 449
 450 #if ShowInternals
 451 #include "UICaboodle/UCInternal.h"
 452 #endif
 453
 454 + (void) _initialize {
 455     [WebPreferences _setInitialDefaultTextEncodingToSystemEncoding];
 456
 457     if (float *_UIScrollViewDecelerationRateNormal = reinterpret_cast<float *>(dlsym(RTLD_DEFAULT, "UIScrollViewDecelerationRateNormal")))
 458         CYScrollViewDecelerationRateNormal = *_UIScrollViewDecelerationRateNormal;
 459     else // XXX: this actually might be fast on some older systems: we should look into this
 460         CYScrollViewDecelerationRateNormal = 0.998;
 461 }
 462
 463 - (void) dealloc {
 464 #if LogBrowser
 465     NSLog(@"[BrowserController dealloc]");
 466 #endif
 467
 468     [webview_ setDelegate:nil];
 469
 470     [indirect_ setDelegate:nil];
 471     [indirect_ release];
 472
 473     if (challenge_ != nil)
 474         [challenge_ release];
 475
 476     if (title_ != nil)
 477         [title_ release];
 478
 479     if ([loading_ count] != 0)
 480         [delegate_ releaseNetworkActivityIndicator];
 481     [loading_ release];
 482
 483     [reloaditem_ release];
 484     [loadingitem_ release];
 485
 486     [indicator_ release];
 487
 488     [super dealloc];
 489 }
 490
 491 - (NSURL *) URLWithURL:(NSURL *)url {
 492     return url;
 493 }
 494
 495 - (NSURLRequest *) requestWithURL:(NSURL *)url cachePolicy:(NSURLRequestCachePolicy)policy {
 496     return [NSURLRequest
 497         requestWithURL:[self URLWithURL:url]
 498         cachePolicy:policy
 499         timeoutInterval:DefaultTimeout_
 500     ];
 501 }
 502
 503 - (void) setURL:(NSURL *)url {
 504     _assert(request_ == nil);
 505     request_ = [self requestWithURL:url cachePolicy:NSURLRequestUseProtocolCachePolicy];
 506 }
 507
 508 - (void) loadURL:(NSURL *)url cachePolicy:(NSURLRequestCachePolicy)policy {
 509     [self loadRequest:[self requestWithURL:url cachePolicy:policy]];
 510 }
 511
 512 - (void) loadURL:(NSURL *)url {
 513     [self loadURL:url cachePolicy:NSURLRequestUseProtocolCachePolicy];
 514 }
 515
 516 - (void) loadRequest:(NSURLRequest *)request {
 517 #if LogBrowser
 518     NSLog(@"loadRequest:%@", request);
 519 #endif
 520
 521     error_ = false;
 522
 523     WebThreadLocked lock;
 524     [webview_ loadRequest:request];
 525 }
 526
 527 - (void) reloadURLWithCache:(BOOL)cache {
 528     if (request_ == nil)
 529         return;
 530
 531     NSMutableURLRequest *request([request_ mutableCopy]);
 532     [request setCachePolicy:(cache ? NSURLRequestUseProtocolCachePolicy : NSURLRequestReloadIgnoringLocalCacheData)];
 533
 534     request_ = request;
 535
 536     if ([request_ HTTPBody] == nil && [request_ HTTPBodyStream] == nil)
 537         [self loadRequest:request_];
 538     else {
 539         UIAlertView *alert = [[[UIAlertView alloc]
 540             initWithTitle:UCLocalize("RESUBMIT_FORM")
 541             message:nil
 542             delegate:self
 543             cancelButtonTitle:UCLocalize("CANCEL")
 544             otherButtonTitles:
 545                 UCLocalize("SUBMIT"),
 546             nil
 547         ] autorelease];
 548
 549         [alert setContext:@"submit"];
 550         [alert show];
 551     }
 552 }
 553
 554 - (void) reloadURL {
 555     [self reloadURLWithCache:YES];
 556 }
 557
 558 - (void) reloadData {
 559     [super reloadData];
 560     [self reloadURLWithCache:YES];
 561 }
 562
 563 - (void) setButtonImage:(NSString *)button withStyle:(NSString *)style toFunction:(id)function {
 564     custom_ = button;
 565     style_ = style;
 566     function_ = function;
 567
 568     [self performSelectorOnMainThread:@selector(applyRightButton) withObject:nil waitUntilDone:NO];
 569 }
 570
 571 - (void) setButtonTitle:(NSString *)button withStyle:(NSString *)style toFunction:(id)function {
 572     custom_ = button;
 573     style_ = style;
 574     function_ = function;
 575
 576     [self performSelectorOnMainThread:@selector(applyRightButton) withObject:nil waitUntilDone:NO];
 577 }
 578
 579 - (void) removeButton {
 580     custom_ = [NSNull null];
 581     [self performSelectorOnMainThread:@selector(applyRightButton) withObject:nil waitUntilDone:NO];
 582 }
 583
 584 - (void) scrollToBottomAnimated:(NSNumber *)animated {
 585     CGSize size([scroller_ contentSize]);
 586     CGPoint offset([scroller_ contentOffset]);
 587     CGRect frame([scroller_ frame]);
 588
 589     if (size.height - offset.y < frame.size.height + 20.f) {
 590         CGRect rect = {{0, size.height-1}, {size.width, 1}};
 591         [scroller_ scrollRectToVisible:rect animated:[animated boolValue]];
 592     }
 593 }
 594
 595 - (void) _setViewportWidth {
 596     [[webview_ _documentView] setViewportSize:CGSizeMake(width_, UIWebViewGrowsAndShrinksToFitHeight) forDocumentTypes:0x10];
 597 }
 598
 599 - (void) setViewportWidth:(float)width {
 600     width_ = width != 0 ? width : [[self class] defaultWidth];
 601     [self _setViewportWidth];
 602 }
 603
 604 - (void) _setViewportWidthOnMainThread:(NSNumber *)width {
 605     [self setViewportWidth:[width floatValue]];
 606 }
 607
 608 - (void) setViewportWidthOnMainThread:(float)width {
 609     [self performSelectorOnMainThread:@selector(_setViewportWidthOnMainThread:) withObject:[NSNumber numberWithFloat:width] waitUntilDone:NO];
 610 }
 611
 612 - (void) webViewUpdateViewSettings:(UIWebView *)view {
 613     [self _setViewportWidth];
 614 }
 615
 616 - (void) _openMailToURL:(NSURL *)url {
 617     [[UIApplication sharedApplication] openURL:url];// asPanel:YES];
 618 }
 619
 620 - (bool) _allowJavaScriptPanel {
 621     return true;
 622 }
 623
 624 - (bool) allowsNavigationAction {
 625     return allowsNavigationAction_;
 626 }
 627
 628 - (void) setAllowsNavigationAction:(bool)value {
 629     allowsNavigationAction_ = value;
 630 }
 631
 632 - (void) setAllowsNavigationActionByNumber:(NSNumber *)value {
 633     [self setAllowsNavigationAction:[value boolValue]];
 634 }
 635
 636 - (void) popViewControllerWithNumber:(NSNumber *)value {
 637     UINavigationController *navigation([self navigationController]);
 638     if ([navigation topViewController] == self)
 639         [navigation popViewControllerAnimated:[value boolValue]];
 640 }
 641
 642 - (void) _didFailWithError:(NSError *)error forFrame:(WebFrame *)frame {
 643     [loading_ removeObject:[NSValue valueWithNonretainedObject:frame]];
 644     [self _didFinishLoading];
 645
 646     if ([error code] == NSURLErrorCancelled)
 647         return;
 648
 649     if ([frame parentFrame] == nil) {
 650         [self loadURL:[NSURL URLWithString:[NSString stringWithFormat:@"%@?%@",
 651             [[NSURL fileURLWithPath:[[NSBundle mainBundle] pathForResource:@"error" ofType:@"html"]] absoluteString],
 652             [[error localizedDescription] stringByAddingPercentEscapes]
 653         ]]];
 654
 655         error_ = true;
 656     }
 657 }
 658
 659 - (void) pushRequest:(NSURLRequest *)request asPop:(bool)pop {
 660     NSURL *url([request URL]);
 661
 662     // XXX: filter to internal usage?
 663     CYViewController *page([delegate_ pageForURL:url forExternal:NO]);
 664
 665     if (page == nil) {
 666         BrowserController *browser([[[class_ alloc] init] autorelease]);
 667         [browser loadRequest:request];
 668         page = browser;
 669     }
 670
 671     [page setDelegate:delegate_];
 672
 673     if (!pop) {
 674         [[self navigationItem] setTitle:title_];
 675
 676         [[self navigationController] pushViewController:page animated:YES];
 677     } else {
 678         UINavigationController *navigation([[[UINavigationController alloc] initWithRootViewController:page] autorelease]);
 679
 680         [navigation setDelegate:delegate_];
 681
 682         [[page navigationItem] setLeftBarButtonItem:[[[UIBarButtonItem alloc]
 683             initWithTitle:UCLocalize("CLOSE")
 684             style:UIBarButtonItemStylePlain
 685             target:page
 686             action:@selector(close)
 687         ] autorelease]];
 688
 689         [[self navigationController] presentModalViewController:navigation animated:YES];
 690
 691         [delegate_ unloadData];
 692     }
 693 }
 694
 695 // CYWebViewDelegate {{{
 696 - (void) webView:(WebView *)view addMessageToConsole:(NSDictionary *)message {
 697 #if LogMessages
 698     NSLog(@"addMessageToConsole:%@", message);
 699 #endif
 700 }
 701
 702 - (void) webView:(WebView *)view decidePolicyForNavigationAction:(NSDictionary *)action request:(NSURLRequest *)request frame:(WebFrame *)frame decisionListener:(id<WebPolicyDecisionListener>)listener {
 703 #if LogBrowser
 704     NSLog(@"decidePolicyForNavigationAction:%@ request:%@ frame:%@", action, request, frame);
 705 #endif
 706
 707     if ([frame parentFrame] == nil) {
 708         if (!error_) {
 709             NSURL *url(request == nil ? nil : [request URL]);
 710
 711             if (request_ == nil || [self allowsNavigationAction] || [[request_ URL] isEqual:url])
 712                 request_ = request;
 713             else {
 714                 if (url != nil)
 715                     [self pushRequest:request asPop:NO];
 716                 [listener ignore];
 717             }
 718         }
 719     }
 720 }
 721
 722 - (void) webView:(WebView *)view decidePolicyForNewWindowAction:(NSDictionary *)action request:(NSURLRequest *)request newFrameName:(NSString *)frame decisionListener:(id<WebPolicyDecisionListener>)listener {
 723 #if LogBrowser
 724     NSLog(@"decidePolicyForNewWindowAction:%@ request:%@ newFrameName:%@", action, request, frame);
 725 #endif
 726
 727     NSURL *url([request URL]);
 728     if (url == nil)
 729         return;
 730
 731     if ([frame isEqualToString:@"_open"])
 732         [delegate_ openURL:url];
 733     else {
 734         NSString *scheme([[url scheme] lowercaseString]);
 735         if ([scheme isEqualToString:@"mailto"])
 736             [self _openMailToURL:url];
 737         else
 738             [self pushRequest:request asPop:[frame isEqualToString:@"_popup"]];
 739     }
 740
 741     [listener ignore];
 742 }
 743
 744 - (void) webView:(WebView *)view didClearWindowObject:(WebScriptObject *)window forFrame:(WebFrame *)frame {
 745 }
 746
 747 - (void) webView:(WebView *)view didFailLoadWithError:(NSError *)error forFrame:(WebFrame *)frame {
 748 #if LogBrowser
 749     NSLog(@"didFailLoadWithError:%@ forFrame:%@", error, frame);
 750 #endif
 751
 752     [self _didFailWithError:error forFrame:frame];
 753 }
 754
 755 - (void) webView:(WebView *)view didFailProvisionalLoadWithError:(NSError *)error forFrame:(WebFrame *)frame {
 756 #if LogBrowser
 757     NSLog(@"didFailProvisionalLoadWithError:%@ forFrame:%@", error, frame);
 758 #endif
 759
 760     [self _didFailWithError:error forFrame:frame];
 761 }
 762
 763 - (void) webView:(WebView *)view didFinishLoadForFrame:(WebFrame *)frame {
 764     [loading_ removeObject:[NSValue valueWithNonretainedObject:frame]];
 765
 766     if ([frame parentFrame] == nil) {
 767         if (DOMDocument *document = [frame DOMDocument])
 768             if (DOMNodeList<NSFastEnumeration> *bodies = [document getElementsByTagName:@"body"])
 769                 for (DOMHTMLBodyElement *body in (id) bodies) {
 770                     DOMCSSStyleDeclaration *style([document getComputedStyle:body pseudoElement:nil]);
 771
 772                     UIColor *uic(nil);
 773
 774                     if (DOMCSSPrimitiveValue *color = static_cast<DOMCSSPrimitiveValue *>([style getPropertyCSSValue:@"background-color"])) {
 775                         if ([color primitiveType] == DOM_CSS_RGBCOLOR) {
 776                             DOMRGBColor *rgb([color getRGBColorValue]);
 777
 778                             float red([[rgb red] getFloatValue:DOM_CSS_NUMBER]);
 779                             float green([[rgb green] getFloatValue:DOM_CSS_NUMBER]);
 780                             float blue([[rgb blue] getFloatValue:DOM_CSS_NUMBER]);
 781                             float alpha([[rgb alpha] getFloatValue:DOM_CSS_NUMBER]);
 782
 783                             if (red == 0xc7 && green == 0xce && blue == 0xd5)
 784                                 uic = [UIColor pinStripeColor];
 785                             else if (alpha != 0)
 786                                 uic = [UIColor
 787                                     colorWithRed:(red / 255)
 788                                     green:(green / 255)
 789                                     blue:(blue / 255)
 790                                     alpha:alpha
 791                                 ];
 792                         }
 793                     }
 794
 795                     [scroller_ setBackgroundColor:(uic ?: [UIColor clearColor])];
 796                     break;
 797                 }
 798     }
 799
 800     [self _didFinishLoading];
 801 }
 802
 803 - (void) webView:(WebView *)view didReceiveTitle:(NSString *)title forFrame:(WebFrame *)frame {
 804     if ([frame parentFrame] != nil)
 805         return;
 806
 807     if (title_ != nil)
 808         [title_ autorelease];
 809     title_ = [title retain];
 810
 811     [[self navigationItem] setTitle:title_];
 812 }
 813
 814 - (void) webView:(WebView *)view didStartProvisionalLoadForFrame:(WebFrame *)frame {
 815     [loading_ addObject:[NSValue valueWithNonretainedObject:frame]];
 816
 817     if ([frame parentFrame] == nil) {
 818         CYRelease(title_);
 819         custom_ = nil;
 820         style_ = nil;
 821         function_ = nil;
 822
 823         [self setHidesNavigationBar:NO];
 824
 825         // XXX: do we still need to do this?
 826         [[self navigationItem] setTitle:nil];
 827     }
 828
 829     [self _didStartLoading];
 830 }
 831
 832 - (NSURLRequest *) webView:(WebView *)view resource:(id)identifier willSendRequest:(NSURLRequest *)request redirectResponse:(NSURLResponse *)response fromDataSource:(WebDataSource *)source {
 833 #if LogBrowser
 834     NSLog(@"resource:%@ willSendRequest:%@ redirectResponse:%@ fromDataSource:%@", identifier, request, response, source);
 835 #endif
 836
 837     return request;
 838 }
 839
 840 - (bool) webView:(WebView *)view shouldRunJavaScriptAlertPanelWithMessage:(NSString *)message initiatedByFrame:(WebFrame *)frame {
 841     return [self _allowJavaScriptPanel];
 842 }
 843
 844 - (bool) webView:(WebView *)view shouldRunJavaScriptConfirmPanelWithMessage:(NSString *)message initiatedByFrame:(WebFrame *)frame {
 845     return [self _allowJavaScriptPanel];
 846 }
 847
 848 - (bool) webView:(WebView *)view shouldRunJavaScriptTextInputPanelWithPrompt:(NSString *)prompt defaultText:(NSString *)text initiatedByFrame:(WebFrame *)frame {
 849     return [self _allowJavaScriptPanel];
 850 }
 851
 852 - (void) webViewClose:(WebView *)view {
 853     [self close];
 854 }
 855 // }}}
 856
 857 - (void) close {
 858     [[self navigationController] dismissModalViewControllerAnimated:YES];
 859 }
 860
 861 - (void) alertView:(UIAlertView *)alert clickedButtonAtIndex:(NSInteger)button {
 862     NSString *context([alert context]);
 863
 864     if ([context isEqualToString:@"sensitive"]) {
 865         switch (button) {
 866             case 1:
 867                 sensitive_ = [NSNumber numberWithBool:YES];
 868             break;
 869
 870             case 2:
 871                 sensitive_ = [NSNumber numberWithBool:NO];
 872             break;
 873         }
 874
 875         [alert dismissWithClickedButtonIndex:-1 animated:YES];
 876     } else if ([context isEqualToString:@"challenge"]) {
 877         id<NSURLAuthenticationChallengeSender> sender([challenge_ sender]);
 878
 879         switch (button) {
 880             case 1: {
 881                 NSString *username([[alert textFieldAtIndex:0] text]);
 882                 NSString *password([[alert textFieldAtIndex:1] text]);
 883
 884                 NSURLCredential *credential([NSURLCredential credentialWithUser:username password:password persistence:NSURLCredentialPersistenceForSession]);
 885
 886                 [sender useCredential:credential forAuthenticationChallenge:challenge_];
 887             } break;
 888
 889             case 2:
 890                 [sender cancelAuthenticationChallenge:challenge_];
 891             break;
 892
 893             _nodefault
 894         }
 895
 896         [challenge_ release];
 897         challenge_ = nil;
 898
 899         [alert dismissWithClickedButtonIndex:-1 animated:YES];
 900     } else if ([context isEqualToString:@"submit"]) {
 901         if (button == [alert cancelButtonIndex]) {
 902         } else if (button == [alert firstOtherButtonIndex]) {
 903             if (request_ != nil) {
 904                 WebThreadLocked lock;
 905                 [webview_ loadRequest:request_];
 906             }
 907         }
 908
 909         [alert dismissWithClickedButtonIndex:-1 animated:YES];
 910     }
 911 }
 912
 913 - (UIBarButtonItemStyle) rightButtonStyle {
 914     if (style_ == nil) normal:
 915         return UIBarButtonItemStylePlain;
 916     else if ([style_ isEqualToString:@"Normal"])
 917         return UIBarButtonItemStylePlain;
 918     else if ([style_ isEqualToString:@"Highlighted"])
 919         return UIBarButtonItemStyleDone;
 920     else goto normal;
 921 }
 922
 923 - (UIBarButtonItem *) customButton {
 924     return custom_ == [NSNull null] ? nil : [[[UIBarButtonItem alloc]
 925         initWithTitle:static_cast<NSString *>(custom_.operator NSObject *())
 926         style:[self rightButtonStyle]
 927         target:self
 928         action:@selector(customButtonClicked)
 929     ] autorelease];
 930 }
 931
 932 - (UIBarButtonItem *) rightButton {
 933     return reloaditem_;
 934 }
 935
 936 - (void) applyLoadingTitle {
 937     [[self navigationItem] setTitle:UCLocalize("LOADING")];
 938 }
 939
 940 - (void) layoutRightButton {
 941     [[loadingitem_ view] addSubview:indicator_];
 942     [[loadingitem_ view] bringSubviewToFront:indicator_];
 943 }
 944
 945 - (void) applyRightButton {
 946     if ([self isLoading]) {
 947         [[self navigationItem] setRightBarButtonItem:loadingitem_ animated:YES];
 948         [self performSelector:@selector(layoutRightButton) withObject:nil afterDelay:0];
 949
 950         [indicator_ startAnimating];
 951         [self applyLoadingTitle];
 952     } else {
 953         [indicator_ stopAnimating];
 954
 955         [[self navigationItem] setRightBarButtonItem:(
 956             custom_ != nil ? [self customButton] : [self rightButton]
 957         ) animated:YES];
 958     }
 959 }
 960
 961 - (void) didStartLoading {
 962     // Overridden in subclasses.
 963 }
 964
 965 - (void) _didStartLoading {
 966     [self applyRightButton];
 967
 968     if ([loading_ count] != 1)
 969         return;
 970
 971     [delegate_ retainNetworkActivityIndicator];
 972     [self didStartLoading];
 973 }
 974
 975 - (void) didFinishLoading {
 976     // Overridden in subclasses.
 977 }
 978
 979 - (void) _didFinishLoading {
 980     if ([loading_ count] != 0)
 981         return;
 982
 983     [self applyRightButton];
 984     [[self navigationItem] setTitle:title_];
 985
 986     [delegate_ releaseNetworkActivityIndicator];
 987     [self didFinishLoading];
 988 }
 989
 990 - (bool) isLoading {
 991     return [loading_ count] != 0;
 992 }
 993
 994 - (id) initWithWidth:(float)width ofClass:(Class)_class {
 995     if ((self = [super init]) != nil) {
 996         allowsNavigationAction_ = true;
 997
 998         class_ = _class;
 999         loading_ = [[NSMutableSet alloc] initWithCapacity:5];
1000
1001         indirect_ = [[IndirectDelegate alloc] initWithDelegate:self];
1002
1003         CGRect bounds([[self view] bounds]);
1004
1005         webview_ = [[[CYWebView alloc] initWithFrame:bounds] autorelease];
1006         [webview_ setDelegate:self];
1007         [self setView:webview_];
1008
1009         if ([webview_ respondsToSelector:@selector(setDataDetectorTypes:)])
1010             [webview_ setDataDetectorTypes:UIDataDetectorTypeAutomatic];
1011         else
1012             [webview_ setDetectsPhoneNumbers:NO];
1013
1014         [webview_ setScalesPageToFit:YES];
1015
1016         UIWebDocumentView *document([webview_ _documentView]);
1017
1018         // XXX: I think this improves scrolling; the hardcoded-ness sucks
1019         [document setTileSize:CGSizeMake(320, 500)];
1020
1021         [document setBackgroundColor:[UIColor clearColor]];
1022
1023         // XXX: this is terribly (too?) expensive
1024         [document setDrawsBackground:NO];
1025
1026         WebView *webview([document webView]);
1027         WebPreferences *preferences([webview preferences]);
1028
1029         // XXX: I have no clue if I actually /want/ this modification
1030         if ([webview respondsToSelector:@selector(_setLayoutInterval:)])
1031             [webview _setLayoutInterval:0];
1032         else if ([preferences respondsToSelector:@selector(_setLayoutInterval:)])
1033             [preferences _setLayoutInterval:0];
1034
1035         [preferences setCacheModel:WebCacheModelDocumentBrowser];
1036         [preferences setOfflineWebApplicationCacheEnabled:YES];
1037
1038 #if LogMessages
1039         if ([document respondsToSelector:@selector(setAllowsMessaging:)])
1040             [document setAllowsMessaging:YES];
1041         if ([webview respondsToSelector:@selector(_setAllowsMessaging:)])
1042             [webview _setAllowsMessaging:YES];
1043 #endif
1044
1045         if ([webview_ respondsToSelector:@selector(_scrollView)]) {
1046             scroller_ = [webview_ _scrollView];
1047
1048             [scroller_ setDirectionalLockEnabled:YES];
1049             [scroller_ setDecelerationRate:CYScrollViewDecelerationRateNormal];
1050             [scroller_ setDelaysContentTouches:NO];
1051
1052             [scroller_ setCanCancelContentTouches:YES];
1053         } else if ([webview_ respondsToSelector:@selector(_scroller)]) {
1054             UIScroller *scroller([webview_ _scroller]);
1055             scroller_ = (UIScrollView *) scroller;
1056
1057             [scroller setDirectionalScrolling:YES];
1058             // XXX: we might be better off /not/ setting this on older systems
1059             [scroller setScrollDecelerationFactor:CYScrollViewDecelerationRateNormal]; /* 0.989324 */
1060             [scroller setScrollHysteresis:0]; /* 8 */
1061
1062             [scroller setThumbDetectionEnabled:NO];
1063
1064             // use NO with UIApplicationUseLegacyEvents(YES)
1065             [scroller setEventMode:YES];
1066
1067             // XXX: this is handled by setBounces, right?
1068             //[scroller setAllowsRubberBanding:YES];
1069         }
1070
1071         [scroller_ setFixedBackgroundPattern:YES];
1072         [scroller_ setBackgroundColor:[UIColor clearColor]];
1073         [scroller_ setClipsSubviews:YES];
1074
1075         [scroller_ setBounces:YES];
1076         [scroller_ setScrollingEnabled:YES];
1077         [scroller_ setShowBackgroundShadow:NO];
1078
1079         [self setViewportWidth:width];
1080
1081         reloaditem_ = [[UIBarButtonItem alloc]
1082             initWithTitle:UCLocalize("RELOAD")
1083             style:[self rightButtonStyle]
1084             target:self
1085             action:@selector(reloadButtonClicked)
1086         ];
1087
1088         loadingitem_ = [[UIBarButtonItem alloc]
1089             initWithTitle:@" "
1090             style:UIBarButtonItemStylePlain
1091             target:self
1092             action:@selector(reloadButtonClicked)
1093         ];
1094
1095         indicator_ = [[UIActivityIndicatorView alloc] initWithActivityIndicatorStyle:UIActivityIndicatorViewStyleWhite];
1096         [indicator_ setFrame:CGRectMake(15, 5, [indicator_ frame].size.width, [indicator_ frame].size.height)];
1097
1098         UITableView *table([[[UITableView alloc] initWithFrame:bounds style:UITableViewStyleGrouped] autorelease]);
1099         [webview_ insertSubview:table atIndex:0];
1100
1101         [table setAutoresizingMask:(UIViewAutoresizingFlexibleWidth | UIViewAutoresizingFlexibleHeight)];
1102         [webview_ setAutoresizingMask:(UIViewAutoresizingFlexibleWidth | UIViewAutoresizingFlexibleHeight)];
1103         [indicator_ setAutoresizingMask:UIViewAutoresizingFlexibleLeftMargin];
1104     } return self;
1105 }
1106
1107 - (id) initWithWidth:(float)width {
1108     return [self initWithWidth:width ofClass:[self class]];
1109 }
1110
1111 - (id) init {
1112     return [self initWithWidth:0];
1113 }
1114
1115 - (id) initWithURL:(NSURL *)url {
1116     if ((self = [self init]) != nil) {
1117         [self setURL:url];
1118     } return self;
1119 }
1120
1121 - (void) callFunction:(WebScriptObject *)function {
1122     WebThreadLocked lock;
1123
1124     WebView *webview([[webview_ _documentView] webView]);
1125     WebFrame *frame([webview mainFrame]);
1126     WebPreferences *preferences([webview preferences]);
1127
1128     bool maybe([preferences javaScriptCanOpenWindowsAutomatically]);
1129     [preferences setJavaScriptCanOpenWindowsAutomatically:NO];
1130
1131     /*id _private(MSHookIvar<id>(webview, "_private"));
1132     WebCore::Page *page(_private == nil ? NULL : MSHookIvar<WebCore::Page *>(_private, "page"));
1133     WebCore::Settings *settings(page == NULL ? NULL : page->settings());
1134
1135     bool no;
1136     if (settings == NULL)
1137         no = 0;
1138     else {
1139         no = settings->JavaScriptCanOpenWindowsAutomatically();
1140         settings->setJavaScriptCanOpenWindowsAutomatically(true);
1141     }*/
1142
1143     if (UIWindow *window = [[self view] window])
1144         if (UIResponder *responder = [window firstResponder])
1145             [responder resignFirstResponder];
1146
1147     JSObjectRef object([function JSObject]);
1148     JSGlobalContextRef context([frame globalContext]);
1149     JSObjectCallAsFunction(context, object, NULL, 0, NULL, NULL);
1150
1151     /*if (settings != NULL)
1152         settings->setJavaScriptCanOpenWindowsAutomatically(no);*/
1153
1154     [preferences setJavaScriptCanOpenWindowsAutomatically:maybe];
1155 }
1156
1157 - (void) reloadButtonClicked {
1158     [self reloadURLWithCache:YES];
1159 }
1160
1161 - (void) _customButtonClicked {
1162     [self reloadButtonClicked];
1163 }
1164
1165 - (void) customButtonClicked {
1166 #if !AlwaysReload
1167     if (function_ != nil)
1168         [self callFunction:function_];
1169     else
1170 #endif
1171     [self _customButtonClicked];
1172 }
1173
1174 + (float) defaultWidth {
1175     return 980;
1176 }
1177
1178 - (void) setNavigationBarStyle:(NSString *)name {
1179     UIBarStyle style;
1180     if ([name isEqualToString:@"Black"])
1181         style = UIBarStyleBlack;
1182     else
1183         style = UIBarStyleDefault;
1184
1185     [[[self navigationController] navigationBar] setBarStyle:style];
1186 }
1187
1188 - (void) setNavigationBarTintColor:(UIColor *)color {
1189     [[[self navigationController] navigationBar] setTintColor:color];
1190 }
1191
1192 - (void) setHidesBackButton:(bool)value {
1193     [[self navigationItem] setHidesBackButton:value];
1194 }
1195
1196 - (void) setHidesBackButtonByNumber:(NSNumber *)value {
1197     [self setHidesBackButton:[value boolValue]];
1198 }
1199
1200 - (void) dispatchEvent:(NSString *)event {
1201     WebThreadLocked lock;
1202
1203     NSString *script([NSString stringWithFormat:@
1204         "(function() {"
1205             "var event = this.document.createEvent('Events');"
1206             "event.initEvent('%@', false, false);"
1207             "this.document.dispatchEvent(event);"
1208         "})();"
1209     , event]);
1210
1211     NSMutableArray *frames([NSMutableArray arrayWithObjects:
1212         [[[webview_ _documentView] webView] mainFrame]
1213     , nil]);
1214
1215     while (WebFrame *frame = [frames lastObject]) {
1216         WebScriptObject *object([frame windowObject]);
1217         [object evaluateWebScript:script];
1218         [frames removeLastObject];
1219         [frames addObjectsFromArray:[frame childFrames]];
1220     }
1221 }
1222
1223 - (bool) hidesNavigationBar {
1224     return hidesNavigationBar_;
1225 }
1226
1227 - (void) _setHidesNavigationBar:(bool)value animated:(bool)animated {
1228     if (visible_)
1229         [[self navigationController] setNavigationBarHidden:(value && [self hidesNavigationBar]) animated:animated];
1230 }
1231
1232 - (void) setHidesNavigationBar:(bool)value {
1233     if (hidesNavigationBar_ != value) {
1234         hidesNavigationBar_ = value;
1235         [self _setHidesNavigationBar:YES animated:YES];
1236     }
1237 }
1238
1239 - (void) setHidesNavigationBarByNumber:(NSNumber *)value {
1240     [self setHidesNavigationBar:[value boolValue]];
1241 }
1242
1243 - (void) viewWillAppear:(BOOL)animated {
1244     visible_ = true;
1245
1246     if ([self hidesNavigationBar])
1247         [self _setHidesNavigationBar:YES animated:animated];
1248
1249     [self dispatchEvent:@"CydiaViewWillAppear"];
1250     [super viewWillAppear:animated];
1251 }
1252
1253 - (void) viewDidAppear:(BOOL)animated {
1254     [super viewDidAppear:animated];
1255     [self dispatchEvent:@"CydiaViewDidAppear"];
1256 }
1257
1258 - (void) viewWillDisappear:(BOOL)animated {
1259     [self dispatchEvent:@"CydiaViewWillDisappear"];
1260     [super viewWillDisappear:animated];
1261
1262     if ([self hidesNavigationBar])
1263         [self _setHidesNavigationBar:NO animated:animated];
1264
1265     visible_ = false;
1266 }
1267
1268 - (void) viewDidDisappear:(BOOL)animated {
1269     [super viewDidDisappear:animated];
1270     [self dispatchEvent:@"CydiaViewDidDisappear"];
1271 }
1272
1273 @end