CyteKit/WebView.mm

   1 /* Cydia - iPhone UIKit Front-End for Debian APT
   2  * Copyright (C) 2008-2011  Jay Freeman (saurik)
   3 */
   4
   5 /* Modified BSD License {{{ */
   6 /*
   7  *        Redistribution and use in source and binary
   8  * forms, with or without modification, are permitted
   9  * provided that the following conditions are met:
  10  *
  11  * 1. Redistributions of source code must retain the
  12  *    above copyright notice, this list of conditions
  13  *    and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the
  15  *    above copyright notice, this list of conditions
  16  *    and the following disclaimer in the documentation
  17  *    and/or other materials provided with the
  18  *    distribution.
  19  * 3. The name of the author may not be used to endorse
  20  *    or promote products derived from this software
  21  *    without specific prior written permission.
  22  *
  23  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS''
  24  * AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING,
  25  * BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
  26  * MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  27  * ARE DISCLAIMED. IN NO EVENT SHALL THE AUTHOR BE
  28  * LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  29  * EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  30  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
  31  * SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  32  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
  33  * LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR
  34  * TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
  35  * ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
  36  * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  37 */
  38 /* }}} */
  39
  40 #include "CyteKit/WebView.h"
  41 #include "CyteKit/WebThreadLocked.hpp"
  42
  43 #include <CydiaSubstrate/CydiaSubstrate.h>
  44
  45 #include "iPhonePrivate.h"
  46
  47 // CYWebPolicyDecision* {{{
  48 enum CYWebPolicyDecision {
  49     CYWebPolicyDecisionUnknown,
  50     CYWebPolicyDecisionDownload,
  51     CYWebPolicyDecisionIgnore,
  52     CYWebPolicyDecisionUse,
  53 };
  54
  55 @interface CYWebPolicyDecisionMediator : NSObject <
  56     WebPolicyDecisionListener
  57 > {
  58     id<WebPolicyDecisionListener> listener_;
  59     CYWebPolicyDecision decision_;
  60 }
  61
  62 - (id) initWithListener:(id<WebPolicyDecisionListener>)listener;
  63
  64 - (CYWebPolicyDecision) decision;
  65 - (bool) decided;
  66 - (bool) decide;
  67
  68 @end
  69
  70 @implementation CYWebPolicyDecisionMediator
  71
  72 - (id) initWithListener:(id<WebPolicyDecisionListener>)listener {
  73     if ((self = [super init]) != nil) {
  74         listener_ = listener;
  75     } return self;
  76 }
  77
  78 - (CYWebPolicyDecision) decision {
  79     return decision_;
  80 }
  81
  82 - (bool) decided {
  83     return decision_ != CYWebPolicyDecisionUnknown;
  84 }
  85
  86 - (bool) decide {
  87     switch (decision_) {
  88         case CYWebPolicyDecisionUnknown:
  89         default:
  90             NSLog(@"CYWebPolicyDecisionUnknown");
  91             return false;
  92
  93         case CYWebPolicyDecisionDownload: [listener_ download]; break;
  94         case CYWebPolicyDecisionIgnore: [listener_ ignore]; break;
  95         case CYWebPolicyDecisionUse: [listener_ use]; break;
  96     }
  97
  98     return true;
  99 }
 100
 101 - (void) download {
 102     decision_ = CYWebPolicyDecisionDownload;
 103 }
 104
 105 - (void) ignore {
 106     decision_ = CYWebPolicyDecisionIgnore;
 107 }
 108
 109 - (void) use {
 110     decision_ = CYWebPolicyDecisionUse;
 111 }
 112
 113 @end
 114 // }}}
 115
 116 @implementation CyteWebView : UIWebView
 117
 118 #if ShowInternals
 119 #include "CyteKit/UCInternal.h"
 120 #endif
 121
 122 - (id) initWithFrame:(CGRect)frame {
 123     if ((self = [super initWithFrame:frame]) != nil) {
 124     } return self;
 125 }
 126
 127 - (void) dealloc {
 128     [super dealloc];
 129 }
 130
 131 - (id<CyteWebViewDelegate>) delegate {
 132     return (id<CyteWebViewDelegate>) [super delegate];
 133 }
 134
 135 /*- (WebView *) webView:(WebView *)view createWebViewWithRequest:(NSURLRequest *)request {
 136     id<CyteWebViewDelegate> delegate([self delegate]);
 137     WebView *created(nil);
 138     if (created == nil && [delegate respondsToSelector:@selector(webView:createWebViewWithRequest:)])
 139         created = [delegate webView:view createWebViewWithRequest:request];
 140     if (created == nil && [UIWebView instancesRespondToSelector:@selector(webView:createWebViewWithRequest:)])
 141         created = [super webView:view createWebViewWithRequest:request];
 142     return created;
 143 }*/
 144
 145 // webView:addMessageToConsole: (X.Xx) {{{
 146 static void $UIWebViewWebViewDelegate$webView$addMessageToConsole$(UIWebViewWebViewDelegate *self, SEL sel, WebView *view, NSDictionary *message) {
 147     UIWebView *uiWebView(MSHookIvar<UIWebView *>(self, "uiWebView"));
 148     if ([uiWebView respondsToSelector:@selector(webView:addMessageToConsole:)])
 149         [uiWebView webView:view addMessageToConsole:message];
 150 }
 151
 152 - (void) webView:(WebView *)view addMessageToConsole:(NSDictionary *)message {
 153     id<CyteWebViewDelegate> delegate([self delegate]);
 154     if ([delegate respondsToSelector:@selector(webView:addMessageToConsole:)])
 155         [delegate webView:view addMessageToConsole:message];
 156     if ([UIWebView instancesRespondToSelector:@selector(webView:addMessageToConsole:)])
 157         [super webView:view addMessageToConsole:message];
 158 }
 159 // }}}
 160 // webView:decidePolicyForNavigationAction:request:frame:decisionListener: (2.0+) {{{
 161 - (void) webView:(WebView *)view decidePolicyForNavigationAction:(NSDictionary *)action request:(NSURLRequest *)request frame:(WebFrame *)frame decisionListener:(id<WebPolicyDecisionListener>)listener {
 162     id<CyteWebViewDelegate> delegate([self delegate]);
 163     CYWebPolicyDecisionMediator *mediator([[[CYWebPolicyDecisionMediator alloc] initWithListener:listener] autorelease]);
 164     if (![mediator decided] && [delegate respondsToSelector:@selector(webView:decidePolicyForNavigationAction:request:frame:decisionListener:)])
 165         [delegate webView:view decidePolicyForNavigationAction:action request:request frame:frame decisionListener:mediator];
 166     if (![mediator decided] && [UIWebView instancesRespondToSelector:@selector(webView:decidePolicyForNavigationAction:request:frame:decisionListener:)])
 167         [super webView:view decidePolicyForNavigationAction:action request:request frame:frame decisionListener:mediator];
 168     [mediator decide];
 169 }
 170 // }}}
 171 // webView:decidePolicyForNewWindowAction:request:newFrameName:decisionListener: (3.0+) {{{
 172 static void $UIWebViewWebViewDelegate$webView$decidePolicyForNewWindowAction$request$newFrameName$decisionListener$(UIWebViewWebViewDelegate *self, SEL sel, WebView *view, NSDictionary *action, NSURLRequest *request, NSString *frame, id<WebPolicyDecisionListener> listener) {
 173     UIWebView *uiWebView(MSHookIvar<UIWebView *>(self, "uiWebView"));
 174     if ([uiWebView respondsToSelector:@selector(webView:decidePolicyForNewWindowAction:request:newFrameName:decisionListener:)])
 175         [uiWebView webView:view decidePolicyForNewWindowAction:action request:request newFrameName:frame decisionListener:listener];
 176 }
 177
 178 - (void) webView:(WebView *)view decidePolicyForNewWindowAction:(NSDictionary *)action request:(NSURLRequest *)request newFrameName:(NSString *)frame decisionListener:(id<WebPolicyDecisionListener>)listener {
 179     id<CyteWebViewDelegate> delegate([self delegate]);
 180     CYWebPolicyDecisionMediator *mediator([[[CYWebPolicyDecisionMediator alloc] initWithListener:listener] autorelease]);
 181     if (![mediator decided] && [delegate respondsToSelector:@selector(webView:decidePolicyForNewWindowAction:request:newFrameName:decisionListener:)])
 182         [delegate webView:view decidePolicyForNewWindowAction:action request:request newFrameName:frame decisionListener:mediator];
 183     if (![mediator decided] && [UIWebView instancesRespondToSelector:@selector(webView:decidePolicyForNewWindowAction:request:newFrameName:decisionListener:)])
 184         [super webView:view decidePolicyForNewWindowAction:action request:request newFrameName:frame decisionListener:mediator];
 185     [mediator decide];
 186 }
 187 // }}}
 188 // webView:didClearWindowObject:forFrame: (3.2+) {{{
 189 static void $UIWebViewWebViewDelegate$webView$didClearWindowObject$forFrame$(UIWebViewWebViewDelegate *self, SEL sel, WebView *view, WebScriptObject *window, WebFrame *frame) {
 190     UIWebView *uiWebView(MSHookIvar<UIWebView *>(self, "uiWebView"));
 191     if ([uiWebView respondsToSelector:@selector(webView:didClearWindowObject:forFrame:)])
 192         [uiWebView webView:view didClearWindowObject:window forFrame:frame];
 193 }
 194
 195 - (void) webView:(WebView *)view didClearWindowObject:(WebScriptObject *)window forFrame:(WebFrame *)frame {
 196     id<CyteWebViewDelegate> delegate([self delegate]);
 197     if ([delegate respondsToSelector:@selector(webView:didClearWindowObject:forFrame:)])
 198         [delegate webView:view didClearWindowObject:window forFrame:frame];
 199     if ([UIWebView instancesRespondToSelector:@selector(webView:didClearWindowObject:forFrame:)])
 200         [super webView:view didClearWindowObject:window forFrame:frame];
 201 }
 202 // }}}
 203 // webView:didFailLoadWithError:forFrame: (2.0+) {{{
 204 - (void) webView:(WebView *)view didFailLoadWithError:(NSError *)error forFrame:(WebFrame *)frame {
 205     id<CyteWebViewDelegate> delegate([self delegate]);
 206     if ([delegate respondsToSelector:@selector(webView:didFailLoadWithError:forFrame:)])
 207         [delegate webView:view didFailLoadWithError:error forFrame:frame];
 208     if ([UIWebView instancesRespondToSelector:@selector(webView:didFailLoadWithError:forFrame:)])
 209         [super webView:view didFailLoadWithError:error forFrame:frame];
 210 }
 211 // }}}
 212 // webView:didFailProvisionalLoadWithError:forFrame: (2.0+) {{{
 213 - (void) webView:(WebView *)view didFailProvisionalLoadWithError:(NSError *)error forFrame:(WebFrame *)frame {
 214     id<CyteWebViewDelegate> delegate([self delegate]);
 215     if ([delegate respondsToSelector:@selector(webView:didFailProvisionalLoadWithError:forFrame:)])
 216         [delegate webView:view didFailProvisionalLoadWithError:error forFrame:frame];
 217     if ([UIWebView instancesRespondToSelector:@selector(webView:didFailProvisionalLoadWithError:forFrame:)])
 218         [super webView:view didFailProvisionalLoadWithError:error forFrame:frame];
 219 }
 220 // }}}
 221 // webView:didFinishLoadForFrame: (2.0+) {{{
 222 - (void) webView:(WebView *)view didFinishLoadForFrame:(WebFrame *)frame {
 223     id<CyteWebViewDelegate> delegate([self delegate]);
 224     if ([delegate respondsToSelector:@selector(webView:didFinishLoadForFrame:)])
 225         [delegate webView:view didFinishLoadForFrame:frame];
 226     if ([UIWebView instancesRespondToSelector:@selector(webView:didFinishLoadForFrame:)])
 227         [super webView:view didFinishLoadForFrame:frame];
 228 }
 229 // }}}
 230 // webView:didReceiveTitle:forFrame: (3.2+) {{{
 231 static void $UIWebViewWebViewDelegate$webView$didReceiveTitle$forFrame$(UIWebViewWebViewDelegate *self, SEL sel, WebView *view, NSString *title, WebFrame *frame) {
 232     UIWebView *uiWebView(MSHookIvar<UIWebView *>(self, "uiWebView"));
 233     if ([uiWebView respondsToSelector:@selector(webView:didReceiveTitle:forFrame:)])
 234         [uiWebView webView:view didReceiveTitle:title forFrame:frame];
 235 }
 236
 237 - (void) webView:(WebView *)view didReceiveTitle:(NSString *)title forFrame:(WebFrame *)frame {
 238     id<CyteWebViewDelegate> delegate([self delegate]);
 239     if ([delegate respondsToSelector:@selector(webView:didReceiveTitle:forFrame:)])
 240         [delegate webView:view didReceiveTitle:title forFrame:frame];
 241     if ([UIWebView instancesRespondToSelector:@selector(webView:didReceiveTitle:forFrame:)])
 242         [super webView:view didReceiveTitle:title forFrame:frame];
 243 }
 244 // }}}
 245 // webView:didStartProvisionalLoadForFrame: (2.0+) {{{
 246 - (void) webView:(WebView *)view didStartProvisionalLoadForFrame:(WebFrame *)frame {
 247     id<CyteWebViewDelegate> delegate([self delegate]);
 248     if ([delegate respondsToSelector:@selector(webView:didStartProvisionalLoadForFrame:)])
 249         [delegate webView:view didStartProvisionalLoadForFrame:frame];
 250     if ([UIWebView instancesRespondToSelector:@selector(webView:didStartProvisionalLoadForFrame:)])
 251         [super webView:view didStartProvisionalLoadForFrame:frame];
 252 }
 253 // }}}
 254 // webView:resource:willSendRequest:redirectResponse:fromDataSource: (3.2+) {{{
 255 static NSURLRequest *$UIWebViewWebViewDelegate$webView$resource$willSendRequest$redirectResponse$fromDataSource$(UIWebViewWebViewDelegate *self, SEL sel, WebView *view, id identifier, NSURLRequest *request, NSURLResponse *response, WebDataSource *source) {
 256     UIWebView *uiWebView(MSHookIvar<UIWebView *>(self, "uiWebView"));
 257     if ([uiWebView respondsToSelector:@selector(webView:resource:willSendRequest:redirectResponse:fromDataSource:)])
 258         request = [uiWebView webView:view resource:identifier willSendRequest:request redirectResponse:response fromDataSource:source];
 259     return request;
 260 }
 261
 262 - (NSURLRequest *) webView:(WebView *)view resource:(id)identifier willSendRequest:(NSURLRequest *)request redirectResponse:(NSURLResponse *)response fromDataSource:(WebDataSource *)source {
 263     id<CyteWebViewDelegate> delegate([self delegate]);
 264     if ([UIWebView instancesRespondToSelector:@selector(webView:resource:willSendRequest:redirectResponse:fromDataSource:)])
 265         request = [super webView:view resource:identifier willSendRequest:request redirectResponse:response fromDataSource:source];
 266     if ([delegate respondsToSelector:@selector(webView:resource:willSendRequest:redirectResponse:fromDataSource:)])
 267         request = [delegate webView:view resource:identifier willSendRequest:request redirectResponse:response fromDataSource:source];
 268     return request;
 269 }
 270 // }}}
 271 // webView:runJavaScriptAlertPanelWithMessage:initiatedByFrame: (2.1+) {{{
 272 - (void) webView:(WebView *)view runJavaScriptAlertPanelWithMessage:(NSString *)message initiatedByFrame:(WebFrame *)frame {
 273     id<CyteWebViewDelegate> delegate([self delegate]);
 274     if ([UIWebView instancesRespondToSelector:@selector(webView:runJavaScriptAlertPanelWithMessage:initiatedByFrame:)])
 275         if (
 276             ![delegate respondsToSelector:@selector(webView:shouldRunJavaScriptAlertPanelWithMessage:initiatedByFrame:)] ||
 277             [delegate webView:view shouldRunJavaScriptAlertPanelWithMessage:message initiatedByFrame:frame]
 278         )
 279             [super webView:view runJavaScriptAlertPanelWithMessage:message initiatedByFrame:frame];
 280 }
 281 // }}}
 282 // webView:runJavaScriptConfirmPanelWithMessage:initiatedByFrame: (2.1+) {{{
 283 - (BOOL) webView:(WebView *)view runJavaScriptConfirmPanelWithMessage:(NSString *)message initiatedByFrame:(WebFrame *)frame {
 284     id<CyteWebViewDelegate> delegate([self delegate]);
 285     if ([UIWebView instancesRespondToSelector:@selector(webView:runJavaScriptConfirmPanelWithMessage:initiatedByFrame:)])
 286         if (
 287             ![delegate respondsToSelector:@selector(webView:shouldRunJavaScriptConfirmPanelWithMessage:initiatedByFrame:)] ||
 288             [delegate webView:view shouldRunJavaScriptConfirmPanelWithMessage:message initiatedByFrame:frame]
 289         )
 290             return [super webView:view runJavaScriptConfirmPanelWithMessage:message initiatedByFrame:frame];
 291     return NO;
 292 }
 293 // }}}
 294 // webView:runJavaScriptTextInputPanelWithPrompt:defaultText:initiatedByFrame: (2.1+) {{{
 295 - (NSString *) webView:(WebView *)view runJavaScriptTextInputPanelWithPrompt:(NSString *)prompt defaultText:(NSString *)text initiatedByFrame:(WebFrame *)frame {
 296     id<CyteWebViewDelegate> delegate([self delegate]);
 297     if ([UIWebView instancesRespondToSelector:@selector(webView:runJavaScriptTextInputPanelWithPrompt:defaultText:initiatedByFrame:)])
 298         if (
 299             ![delegate respondsToSelector:@selector(webView:shouldRunJavaScriptTextInputPanelWithPrompt:defaultText:initiatedByFrame:)] ||
 300             [delegate webView:view shouldRunJavaScriptTextInputPanelWithPrompt:prompt defaultText:text initiatedByFrame:frame]
 301         )
 302             return [super webView:view runJavaScriptTextInputPanelWithPrompt:prompt defaultText:text initiatedByFrame:frame];
 303     return nil;
 304 }
 305 // }}}
 306 // webViewClose: (3.2+) {{{
 307 static void $UIWebViewWebViewDelegate$webViewClose$(UIWebViewWebViewDelegate *self, SEL sel, WebView *view) {
 308     UIWebView *uiWebView(MSHookIvar<UIWebView *>(self, "uiWebView"));
 309     if ([uiWebView respondsToSelector:@selector(webViewClose:)])
 310         [uiWebView webViewClose:view];
 311 }
 312
 313 - (void) webViewClose:(WebView *)view {
 314     id<CyteWebViewDelegate> delegate([self delegate]);
 315     if ([delegate respondsToSelector:@selector(webViewClose:)])
 316         [delegate webViewClose:view];
 317     if ([UIWebView instancesRespondToSelector:@selector(webViewClose:)])
 318         [super webViewClose:view];
 319 }
 320 // }}}
 321
 322 - (void) _updateViewSettings {
 323     [super _updateViewSettings];
 324
 325     id<CyteWebViewDelegate> delegate([self delegate]);
 326     if ([delegate respondsToSelector:@selector(webViewUpdateViewSettings:)])
 327         [delegate webViewUpdateViewSettings:self];
 328 }
 329
 330 - (void) dispatchEvent:(NSString *)event {
 331     WebThreadLocked lock;
 332
 333     NSString *script([NSString stringWithFormat:@
 334         "(function() {"
 335             "var event = this.document.createEvent('Events');"
 336             "event.initEvent('%@', false, false);"
 337             "this.document.dispatchEvent(event);"
 338         "})();"
 339     , event]);
 340
 341     NSMutableArray *frames([NSMutableArray arrayWithObjects:
 342         [[[self _documentView] webView] mainFrame]
 343     , nil]);
 344
 345     while (WebFrame *frame = [frames lastObject]) {
 346         WebScriptObject *object([frame windowObject]);
 347         [object evaluateWebScript:script];
 348         [frames removeLastObject];
 349         [frames addObjectsFromArray:[frame childFrames]];
 350     }
 351 }
 352
 353 - (void) reloadFromOrigin {
 354     [[[self _documentView] webView] reloadFromOrigin:nil];
 355 }
 356
 357 + (void) initialize {
 358     if (Class $UIWebViewWebViewDelegate = objc_getClass("UIWebViewWebViewDelegate")) {
 359         class_addMethod($UIWebViewWebViewDelegate, @selector(webView:addMessageToConsole:), (IMP) &$UIWebViewWebViewDelegate$webView$addMessageToConsole$, "v16@0:4@8@12");
 360         class_addMethod($UIWebViewWebViewDelegate, @selector(webView:decidePolicyForNewWindowAction:request:newFrameName:decisionListener:), (IMP) &$UIWebViewWebViewDelegate$webView$decidePolicyForNewWindowAction$request$newFrameName$decisionListener$, "v28@0:4@8@12@16@20@24");
 361         class_addMethod($UIWebViewWebViewDelegate, @selector(webView:didClearWindowObject:forFrame:), (IMP) &$UIWebViewWebViewDelegate$webView$didClearWindowObject$forFrame$, "v20@0:4@8@12@16");
 362         class_addMethod($UIWebViewWebViewDelegate, @selector(webView:didReceiveTitle:forFrame:), (IMP) &$UIWebViewWebViewDelegate$webView$didReceiveTitle$forFrame$, "v20@0:4@8@12@16");
 363         class_addMethod($UIWebViewWebViewDelegate, @selector(webView:resource:willSendRequest:redirectResponse:fromDataSource:), (IMP) &$UIWebViewWebViewDelegate$webView$resource$willSendRequest$redirectResponse$fromDataSource$, "@28@0:4@8@12@16@20@24");
 364         class_addMethod($UIWebViewWebViewDelegate, @selector(webViewClose:), (IMP) &$UIWebViewWebViewDelegate$webViewClose$, "v12@0:4@8");
 365     }
 366 }
 367
 368 @end