UICaboodle/BrowserView.mm

   1 #include <UIKit/UIKit.h>
   2 #include "iPhonePrivate.h"
   3
   4 #include "UCPlatform.h"
   5
   6 #include <UICaboodle/BrowserView.h>
   7 #include <UICaboodle/UCLocalize.h>
   8
   9 //#include <QuartzCore/CALayer.h>
  10 // XXX: fix the minimum requirement
  11 extern NSString * const kCAFilterNearest;
  12
  13 #include <WebCore/WebCoreThread.h>
  14
  15 #include <WebKit/WebPolicyDelegate.h>
  16 #include <WebKit/WebPreferences.h>
  17
  18 #include <WebKit/DOMCSSPrimitiveValue.h>
  19 #include <WebKit/DOMCSSStyleDeclaration.h>
  20 #include <WebKit/DOMDocument.h>
  21 #include <WebKit/DOMHTMLBodyElement.h>
  22 #include <WebKit/DOMRGBColor.h>
  23
  24 //#include <WebCore/Page.h>
  25 //#include <WebCore/Settings.h>
  26
  27 #include "substrate.h"
  28
  29 #define ForSaurik 0
  30 #define DefaultTimeout_ 120.0
  31
  32 #define ShowInternals 0
  33 #define LogBrowser 0
  34 #define LogMessages 0
  35
  36 #define lprintf(args...) fprintf(stderr, args)
  37
  38 // WebThreadLocked {{{
  39 struct WebThreadLocked {
  40     _finline WebThreadLocked() {
  41         WebThreadLock();
  42     }
  43
  44     _finline ~WebThreadLocked() {
  45         WebThreadUnlock();
  46     }
  47 };
  48 // }}}
  49
  50 template <typename Type_>
  51 static inline void CYRelease(Type_ &value) {
  52     if (value != nil) {
  53         [value release];
  54         value = nil;
  55     }
  56 }
  57
  58 float CYScrollViewDecelerationRateNormal;
  59
  60 @interface WebView (Apple)
  61 - (void) _setLayoutInterval:(float)interval;
  62 - (void) _setAllowsMessaging:(BOOL)allows;
  63 @end
  64
  65 @interface WebPreferences (Apple)
  66 + (void) _setInitialDefaultTextEncodingToSystemEncoding;
  67 - (void) _setLayoutInterval:(NSInteger)interval;
  68 - (void) setOfflineWebApplicationCacheEnabled:(BOOL)enabled;
  69 @end
  70
  71 /* Indirect Delegate {{{ */
  72 @interface IndirectDelegate : NSObject <
  73     HookProtocol
  74 > {
  75     _transient volatile id delegate_;
  76 }
  77
  78 - (void) setDelegate:(id)delegate;
  79 - (id) initWithDelegate:(id)delegate;
  80 @end
  81
  82 @implementation IndirectDelegate
  83
  84 - (void) setDelegate:(id)delegate {
  85     delegate_ = delegate;
  86 }
  87
  88 - (id) initWithDelegate:(id)delegate {
  89     delegate_ = delegate;
  90     return self;
  91 }
  92
  93 - (void) didDismissModalViewController {
  94     if (delegate_ != nil)
  95         return [delegate_ didDismissModalViewController];
  96 }
  97
  98 - (IMP) methodForSelector:(SEL)sel {
  99     if (IMP method = [super methodForSelector:sel])
 100         return method;
 101     fprintf(stderr, "methodForSelector:[%s] == NULL\n", sel_getName(sel));
 102     return NULL;
 103 }
 104
 105 - (BOOL) respondsToSelector:(SEL)sel {
 106     if ([super respondsToSelector:sel])
 107         return YES;
 108
 109     // XXX: WebThreadCreateNSInvocation returns nil
 110
 111 #if ShowInternals
 112     fprintf(stderr, "[%s]R?%s\n", class_getName(self->isa), sel_getName(sel));
 113 #endif
 114
 115     return delegate_ == nil ? NO : [delegate_ respondsToSelector:sel];
 116 }
 117
 118 - (NSMethodSignature *) methodSignatureForSelector:(SEL)sel {
 119     if (NSMethodSignature *method = [super methodSignatureForSelector:sel])
 120         return method;
 121
 122 #if ShowInternals
 123     fprintf(stderr, "[%s]S?%s\n", class_getName(self->isa), sel_getName(sel));
 124 #endif
 125
 126     if (delegate_ != nil)
 127         if (NSMethodSignature *sig = [delegate_ methodSignatureForSelector:sel])
 128             return sig;
 129
 130     // XXX: I fucking hate Apple so very very bad
 131     return [NSMethodSignature signatureWithObjCTypes:"v@:"];
 132 }
 133
 134 - (void) forwardInvocation:(NSInvocation *)inv {
 135     SEL sel = [inv selector];
 136     if (delegate_ != nil && [delegate_ respondsToSelector:sel])
 137         [inv invokeWithTarget:delegate_];
 138 }
 139
 140 @end
 141 /* }}} */
 142
 143 @implementation WebScriptObject (UICaboodle)
 144
 145 - (NSUInteger) count {
 146     id length([self valueForKey:@"length"]);
 147     if ([length respondsToSelector:@selector(intValue)])
 148         return [length intValue];
 149     else
 150         return 0;
 151 }
 152
 153 - (id) objectAtIndex:(unsigned)index {
 154     return [self webScriptValueAtIndex:index];
 155 }
 156
 157 @end
 158
 159 // CYWebPolicyDecision* {{{
 160 enum CYWebPolicyDecision {
 161     CYWebPolicyDecisionUnknown,
 162     CYWebPolicyDecisionDownload,
 163     CYWebPolicyDecisionIgnore,
 164     CYWebPolicyDecisionUse,
 165 };
 166
 167 @interface CYWebPolicyDecisionMediator : NSObject <
 168     WebPolicyDecisionListener
 169 > {
 170     id<WebPolicyDecisionListener> listener_;
 171     CYWebPolicyDecision decision_;
 172 }
 173
 174 - (id) initWithListener:(id<WebPolicyDecisionListener>)listener;
 175
 176 - (CYWebPolicyDecision) decision;
 177 - (bool) decided;
 178 - (bool) decide;
 179
 180 @end
 181
 182 @implementation CYWebPolicyDecisionMediator
 183
 184 - (id) initWithListener:(id<WebPolicyDecisionListener>)listener {
 185     if ((self = [super init]) != nil) {
 186         listener_ = listener;
 187     } return self;
 188 }
 189
 190 - (CYWebPolicyDecision) decision {
 191     return decision_;
 192 }
 193
 194 - (bool) decided {
 195     return decision_ != CYWebPolicyDecisionUnknown;
 196 }
 197
 198 - (bool) decide {
 199     switch (decision_) {
 200         case CYWebPolicyDecisionUnknown:
 201         default:
 202             NSLog(@"CYWebPolicyDecisionUnknown");
 203             return false;
 204
 205         case CYWebPolicyDecisionDownload: [listener_ download]; break;
 206         case CYWebPolicyDecisionIgnore: [listener_ ignore]; break;
 207         case CYWebPolicyDecisionUse: [listener_ use]; break;
 208     }
 209
 210     return true;
 211 }
 212
 213 - (void) download {
 214     decision_ = CYWebPolicyDecisionDownload;
 215 }
 216
 217 - (void) ignore {
 218     decision_ = CYWebPolicyDecisionIgnore;
 219 }
 220
 221 - (void) use {
 222     decision_ = CYWebPolicyDecisionUse;
 223 }
 224
 225 @end
 226 // }}}
 227
 228 @implementation CYWebView : UIWebView
 229
 230 #if ShowInternals
 231 #include "UICaboodle/UCInternal.h"
 232 #endif
 233
 234 - (id) initWithFrame:(CGRect)frame {
 235     if ((self = [super initWithFrame:frame]) != nil) {
 236     } return self;
 237 }
 238
 239 - (void) dealloc {
 240     [super dealloc];
 241 }
 242
 243 - (id<CYWebViewDelegate>) delegate {
 244     return (id<CYWebViewDelegate>) [super delegate];
 245 }
 246
 247 /*- (WebView *) webView:(WebView *)view createWebViewWithRequest:(NSURLRequest *)request {
 248     id<CYWebViewDelegate> delegate([self delegate]);
 249     WebView *created(nil);
 250     if (created == nil && [delegate respondsToSelector:@selector(webView:createWebViewWithRequest:)])
 251         created = [delegate webView:view createWebViewWithRequest:request];
 252     if (created == nil && [UIWebView instancesRespondToSelector:@selector(webView:createWebViewWithRequest:)])
 253         created = [super webView:view createWebViewWithRequest:request];
 254     return created;
 255 }*/
 256
 257 // webView:addMessageToConsole: (X.Xx) {{{
 258 static void $UIWebViewWebViewDelegate$webView$addMessageToConsole$(UIWebViewWebViewDelegate *self, SEL sel, WebView *view, NSDictionary *message) {
 259     UIWebView *uiWebView(MSHookIvar<UIWebView *>(self, "uiWebView"));
 260     if ([uiWebView respondsToSelector:@selector(webView:addMessageToConsole:)])
 261         [uiWebView webView:view addMessageToConsole:message];
 262 }
 263
 264 - (void) webView:(WebView *)view addMessageToConsole:(NSDictionary *)message {
 265     id<CYWebViewDelegate> delegate([self delegate]);
 266     if ([delegate respondsToSelector:@selector(webView:addMessageToConsole:)])
 267         [delegate webView:view addMessageToConsole:message];
 268     if ([UIWebView instancesRespondToSelector:@selector(webView:addMessageToConsole:)])
 269         [super webView:view addMessageToConsole:message];
 270 }
 271 // }}}
 272 // webView:decidePolicyForNavigationAction:request:frame:decisionListener: (2.0+) {{{
 273 - (void) webView:(WebView *)view decidePolicyForNavigationAction:(NSDictionary *)action request:(NSURLRequest *)request frame:(WebFrame *)frame decisionListener:(id<WebPolicyDecisionListener>)listener {
 274     id<CYWebViewDelegate> delegate([self delegate]);
 275     CYWebPolicyDecisionMediator *mediator([[[CYWebPolicyDecisionMediator alloc] initWithListener:listener] autorelease]);
 276     if (![mediator decided] && [delegate respondsToSelector:@selector(webView:decidePolicyForNavigationAction:request:frame:decisionListener:)])
 277         [delegate webView:view decidePolicyForNavigationAction:action request:request frame:frame decisionListener:mediator];
 278     if (![mediator decided] && [UIWebView instancesRespondToSelector:@selector(webView:decidePolicyForNavigationAction:request:frame:decisionListener:)])
 279         [super webView:view decidePolicyForNavigationAction:action request:request frame:frame decisionListener:mediator];
 280     [mediator decide];
 281 }
 282 // }}}
 283 // webView:decidePolicyForNewWindowAction:request:newFrameName:decisionListener: (3.0+) {{{
 284 static void $UIWebViewWebViewDelegate$webView$decidePolicyForNewWindowAction$request$newFrameName$decisionListener$(UIWebViewWebViewDelegate *self, SEL sel, WebView *view, NSDictionary *action, NSURLRequest *request, NSString *frame, id<WebPolicyDecisionListener> listener) {
 285     UIWebView *uiWebView(MSHookIvar<UIWebView *>(self, "uiWebView"));
 286     if ([uiWebView respondsToSelector:@selector(webView:decidePolicyForNewWindowAction:request:newFrameName:decisionListener:)])
 287         [uiWebView webView:view decidePolicyForNewWindowAction:action request:request newFrameName:frame decisionListener:listener];
 288 }
 289
 290 - (void) webView:(WebView *)view decidePolicyForNewWindowAction:(NSDictionary *)action request:(NSURLRequest *)request newFrameName:(NSString *)frame decisionListener:(id<WebPolicyDecisionListener>)listener {
 291     id<CYWebViewDelegate> delegate([self delegate]);
 292     CYWebPolicyDecisionMediator *mediator([[[CYWebPolicyDecisionMediator alloc] initWithListener:listener] autorelease]);
 293     if (![mediator decided] && [delegate respondsToSelector:@selector(webView:decidePolicyForNewWindowAction:request:newFrameName:decisionListener:)])
 294         [delegate webView:view decidePolicyForNewWindowAction:action request:request newFrameName:frame decisionListener:mediator];
 295     if (![mediator decided] && [UIWebView instancesRespondToSelector:@selector(webView:decidePolicyForNewWindowAction:request:newFrameName:decisionListener:)])
 296         [super webView:view decidePolicyForNewWindowAction:action request:request newFrameName:frame decisionListener:mediator];
 297     [mediator decide];
 298 }
 299 // }}}
 300 // webView:didClearWindowObject:forFrame: (3.2+) {{{
 301 static void $UIWebViewWebViewDelegate$webView$didClearWindowObject$forFrame$(UIWebViewWebViewDelegate *self, SEL sel, WebView *view, WebScriptObject *window, WebFrame *frame) {
 302     UIWebView *uiWebView(MSHookIvar<UIWebView *>(self, "uiWebView"));
 303     if ([uiWebView respondsToSelector:@selector(webView:didClearWindowObject:forFrame:)])
 304         [uiWebView webView:view didClearWindowObject:window forFrame:frame];
 305 }
 306
 307 - (void) webView:(WebView *)view didClearWindowObject:(WebScriptObject *)window forFrame:(WebFrame *)frame {
 308     id<CYWebViewDelegate> delegate([self delegate]);
 309     if ([delegate respondsToSelector:@selector(webView:didClearWindowObject:forFrame:)])
 310         [delegate webView:view didClearWindowObject:window forFrame:frame];
 311     if ([UIWebView instancesRespondToSelector:@selector(webView:didClearWindowObject:forFrame:)])
 312         [super webView:view didClearWindowObject:window forFrame:frame];
 313 }
 314 // }}}
 315 // webView:didFailLoadWithError:forFrame: (2.0+) {{{
 316 - (void) webView:(WebView *)view didFailLoadWithError:(NSError *)error forFrame:(WebFrame *)frame {
 317     id<CYWebViewDelegate> delegate([self delegate]);
 318     if ([delegate respondsToSelector:@selector(webView:didFailLoadWithError:forFrame:)])
 319         [delegate webView:view didFailLoadWithError:error forFrame:frame];
 320     if ([UIWebView instancesRespondToSelector:@selector(webView:didFailLoadWithError:forFrame:)])
 321         [super webView:view didFailLoadWithError:error forFrame:frame];
 322 }
 323 // }}}
 324 // webView:didFailProvisionalLoadWithError:forFrame: (2.0+) {{{
 325 - (void) webView:(WebView *)view didFailProvisionalLoadWithError:(NSError *)error forFrame:(WebFrame *)frame {
 326     id<CYWebViewDelegate> delegate([self delegate]);
 327     if ([delegate respondsToSelector:@selector(webView:didFailProvisionalLoadWithError:forFrame:)])
 328         [delegate webView:view didFailProvisionalLoadWithError:error forFrame:frame];
 329     if ([UIWebView instancesRespondToSelector:@selector(webView:didFailProvisionalLoadWithError:forFrame:)])
 330         [super webView:view didFailProvisionalLoadWithError:error forFrame:frame];
 331 }
 332 // }}}
 333 // webView:didFinishLoadForFrame: (2.0+) {{{
 334 - (void) webView:(WebView *)view didFinishLoadForFrame:(WebFrame *)frame {
 335     id<CYWebViewDelegate> delegate([self delegate]);
 336     if ([delegate respondsToSelector:@selector(webView:didFinishLoadForFrame:)])
 337         [delegate webView:view didFinishLoadForFrame:frame];
 338     if ([UIWebView instancesRespondToSelector:@selector(webView:didFinishLoadForFrame:)])
 339         [super webView:view didFinishLoadForFrame:frame];
 340 }
 341 // }}}
 342 // webView:didReceiveTitle:forFrame: (3.2+) {{{
 343 static void $UIWebViewWebViewDelegate$webView$didReceiveTitle$forFrame$(UIWebViewWebViewDelegate *self, SEL sel, WebView *view, NSString *title, WebFrame *frame) {
 344     UIWebView *uiWebView(MSHookIvar<UIWebView *>(self, "uiWebView"));
 345     if ([uiWebView respondsToSelector:@selector(webView:didReceiveTitle:forFrame:)])
 346         [uiWebView webView:view didReceiveTitle:title forFrame:frame];
 347 }
 348
 349 - (void) webView:(WebView *)view didReceiveTitle:(NSString *)title forFrame:(WebFrame *)frame {
 350     id<CYWebViewDelegate> delegate([self delegate]);
 351     if ([delegate respondsToSelector:@selector(webView:didReceiveTitle:forFrame:)])
 352         [delegate webView:view didReceiveTitle:title forFrame:frame];
 353     if ([UIWebView instancesRespondToSelector:@selector(webView:didReceiveTitle:forFrame:)])
 354         [super webView:view didReceiveTitle:title forFrame:frame];
 355 }
 356 // }}}
 357 // webView:didStartProvisionalLoadForFrame: (2.0+) {{{
 358 - (void) webView:(WebView *)view didStartProvisionalLoadForFrame:(WebFrame *)frame {
 359     id<CYWebViewDelegate> delegate([self delegate]);
 360     if ([delegate respondsToSelector:@selector(webView:didStartProvisionalLoadForFrame:)])
 361         [delegate webView:view didStartProvisionalLoadForFrame:frame];
 362     if ([UIWebView instancesRespondToSelector:@selector(webView:didStartProvisionalLoadForFrame:)])
 363         [super webView:view didStartProvisionalLoadForFrame:frame];
 364 }
 365 // }}}
 366 // webView:resource:willSendRequest:redirectResponse:fromDataSource: (3.2+) {{{
 367 static NSURLRequest *$UIWebViewWebViewDelegate$webView$resource$willSendRequest$redirectResponse$fromDataSource$(UIWebViewWebViewDelegate *self, SEL sel, WebView *view, id identifier, NSURLRequest *request, NSURLResponse *response, WebDataSource *source) {
 368     UIWebView *uiWebView(MSHookIvar<UIWebView *>(self, "uiWebView"));
 369     if ([uiWebView respondsToSelector:@selector(webView:resource:willSendRequest:redirectResponse:fromDataSource:)])
 370         request = [uiWebView webView:view resource:identifier willSendRequest:request redirectResponse:response fromDataSource:source];
 371     return request;
 372 }
 373
 374 - (NSURLRequest *) webView:(WebView *)view resource:(id)identifier willSendRequest:(NSURLRequest *)request redirectResponse:(NSURLResponse *)response fromDataSource:(WebDataSource *)source {
 375     id<CYWebViewDelegate> delegate([self delegate]);
 376     if ([UIWebView instancesRespondToSelector:@selector(webView:resource:willSendRequest:redirectResponse:fromDataSource:)])
 377         request = [super webView:view resource:identifier willSendRequest:request redirectResponse:response fromDataSource:source];
 378     if ([delegate respondsToSelector:@selector(webView:resource:willSendRequest:redirectResponse:fromDataSource:)])
 379         request = [delegate webView:view resource:identifier willSendRequest:request redirectResponse:response fromDataSource:source];
 380     return request;
 381 }
 382 // }}}
 383 // webView:runJavaScriptAlertPanelWithMessage:initiatedByFrame: (2.1+) {{{
 384 - (void) webView:(WebView *)view runJavaScriptAlertPanelWithMessage:(NSString *)message initiatedByFrame:(WebFrame *)frame {
 385     id<CYWebViewDelegate> delegate([self delegate]);
 386     if ([UIWebView instancesRespondToSelector:@selector(webView:runJavaScriptAlertPanelWithMessage:initiatedByFrame:)])
 387         if (
 388             ![delegate respondsToSelector:@selector(webView:shouldRunJavaScriptAlertPanelWithMessage:initiatedByFrame:)] ||
 389             [delegate webView:view shouldRunJavaScriptAlertPanelWithMessage:message initiatedByFrame:frame]
 390         )
 391             [super webView:view runJavaScriptAlertPanelWithMessage:message initiatedByFrame:frame];
 392 }
 393 // }}}
 394 // webView:runJavaScriptConfirmPanelWithMessage:initiatedByFrame: (2.1+) {{{
 395 - (BOOL) webView:(WebView *)view runJavaScriptConfirmPanelWithMessage:(NSString *)message initiatedByFrame:(WebFrame *)frame {
 396     id<CYWebViewDelegate> delegate([self delegate]);
 397     if ([UIWebView instancesRespondToSelector:@selector(webView:runJavaScriptConfirmPanelWithMessage:initiatedByFrame:)])
 398         if (
 399             ![delegate respondsToSelector:@selector(webView:shouldRunJavaScriptConfirmPanelWithMessage:initiatedByFrame:)] ||
 400             [delegate webView:view shouldRunJavaScriptConfirmPanelWithMessage:message initiatedByFrame:frame]
 401         )
 402             return [super webView:view runJavaScriptConfirmPanelWithMessage:message initiatedByFrame:frame];
 403     return NO;
 404 }
 405 // }}}
 406 // webView:runJavaScriptTextInputPanelWithPrompt:defaultText:initiatedByFrame: (2.1+) {{{
 407 - (NSString *) webView:(WebView *)view runJavaScriptTextInputPanelWithPrompt:(NSString *)prompt defaultText:(NSString *)text initiatedByFrame:(WebFrame *)frame {
 408     id<CYWebViewDelegate> delegate([self delegate]);
 409     if ([UIWebView instancesRespondToSelector:@selector(webView:runJavaScriptTextInputPanelWithPrompt:defaultText:initiatedByFrame:)])
 410         if (
 411             ![delegate respondsToSelector:@selector(webView:shouldRunJavaScriptTextInputPanelWithPrompt:defaultText:initiatedByFrame:)] ||
 412             [delegate webView:view shouldRunJavaScriptTextInputPanelWithPrompt:prompt defaultText:text initiatedByFrame:frame]
 413         )
 414             return [super webView:view runJavaScriptTextInputPanelWithPrompt:prompt defaultText:text initiatedByFrame:frame];
 415     return nil;
 416 }
 417 // }}}
 418 // webViewClose: (3.2+) {{{
 419 static void $UIWebViewWebViewDelegate$webViewClose$(UIWebViewWebViewDelegate *self, SEL sel, WebView *view) {
 420     UIWebView *uiWebView(MSHookIvar<UIWebView *>(self, "uiWebView"));
 421     if ([uiWebView respondsToSelector:@selector(webViewClose:)])
 422         [uiWebView webViewClose:view];
 423 }
 424
 425 - (void) webViewClose:(WebView *)view {
 426     id<CYWebViewDelegate> delegate([self delegate]);
 427     if ([delegate respondsToSelector:@selector(webViewClose:)])
 428         [delegate webViewClose:view];
 429     if ([UIWebView instancesRespondToSelector:@selector(webViewClose:)])
 430         [super webViewClose:view];
 431 }
 432 // }}}
 433
 434 - (void) _updateViewSettings {
 435     [super _updateViewSettings];
 436
 437     id<CYWebViewDelegate> delegate([self delegate]);
 438     if ([delegate respondsToSelector:@selector(webViewUpdateViewSettings:)])
 439         [delegate webViewUpdateViewSettings:self];
 440 }
 441
 442 + (void) initialize {
 443     if (Class $UIWebViewWebViewDelegate = objc_getClass("UIWebViewWebViewDelegate")) {
 444         class_addMethod($UIWebViewWebViewDelegate, @selector(webView:addMessageToConsole:), (IMP) &$UIWebViewWebViewDelegate$webView$addMessageToConsole$, "v16@0:4@8@12");
 445         class_addMethod($UIWebViewWebViewDelegate, @selector(webView:decidePolicyForNewWindowAction:request:newFrameName:decisionListener:), (IMP) &$UIWebViewWebViewDelegate$webView$decidePolicyForNewWindowAction$request$newFrameName$decisionListener$, "v28@0:4@8@12@16@20@24");
 446         class_addMethod($UIWebViewWebViewDelegate, @selector(webView:didClearWindowObject:forFrame:), (IMP) &$UIWebViewWebViewDelegate$webView$didClearWindowObject$forFrame$, "v20@0:4@8@12@16");
 447         class_addMethod($UIWebViewWebViewDelegate, @selector(webView:didReceiveTitle:forFrame:), (IMP) &$UIWebViewWebViewDelegate$webView$didReceiveTitle$forFrame$, "v20@0:4@8@12@16");
 448         class_addMethod($UIWebViewWebViewDelegate, @selector(webView:resource:willSendRequest:redirectResponse:fromDataSource:), (IMP) &$UIWebViewWebViewDelegate$webView$resource$willSendRequest$redirectResponse$fromDataSource$, "@28@0:4@8@12@16@20@24");
 449         class_addMethod($UIWebViewWebViewDelegate, @selector(webViewClose:), (IMP) &$UIWebViewWebViewDelegate$webViewClose$, "v12@0:4@8");
 450     }
 451 }
 452
 453 @end
 454
 455 @implementation BrowserController
 456
 457 #if ShowInternals
 458 #include "UICaboodle/UCInternal.h"
 459 #endif
 460
 461 + (void) _initialize {
 462     [WebPreferences _setInitialDefaultTextEncodingToSystemEncoding];
 463
 464     if (float *_UIScrollViewDecelerationRateNormal = reinterpret_cast<float *>(dlsym(RTLD_DEFAULT, "UIScrollViewDecelerationRateNormal")))
 465         CYScrollViewDecelerationRateNormal = *_UIScrollViewDecelerationRateNormal;
 466     else // XXX: this actually might be fast on some older systems: we should look into this
 467         CYScrollViewDecelerationRateNormal = 0.998;
 468 }
 469
 470 - (void) dealloc {
 471 #if LogBrowser
 472     NSLog(@"[BrowserController dealloc]");
 473 #endif
 474
 475     [webview_ setDelegate:nil];
 476
 477     [indirect_ setDelegate:nil];
 478     [indirect_ release];
 479
 480     if (challenge_ != nil)
 481         [challenge_ release];
 482
 483     if (closer_ != nil)
 484         [closer_ release];
 485
 486     if (title_ != nil)
 487         [title_ release];
 488
 489     if ([loading_ count] != 0)
 490         [delegate_ releaseNetworkActivityIndicator];
 491     [loading_ release];
 492
 493     [reloaditem_ release];
 494     [loadingitem_ release];
 495
 496     [indicator_ release];
 497
 498     [super dealloc];
 499 }
 500
 501 - (void) setURL:(NSURL *)url {
 502     _assert(request_ == nil);
 503
 504     request_ = [NSURLRequest
 505         requestWithURL:url
 506         cachePolicy:NSURLRequestUseProtocolCachePolicy
 507         timeoutInterval:DefaultTimeout_
 508     ];
 509 }
 510
 511 - (void) loadURL:(NSURL *)url cachePolicy:(NSURLRequestCachePolicy)policy {
 512     [self loadRequest:[NSURLRequest
 513         requestWithURL:url
 514         cachePolicy:policy
 515         timeoutInterval:DefaultTimeout_
 516     ]];
 517 }
 518
 519 - (void) loadURL:(NSURL *)url {
 520     [self loadURL:url cachePolicy:NSURLRequestUseProtocolCachePolicy];
 521 }
 522
 523 - (void) loadRequest:(NSURLRequest *)request {
 524 #if LogBrowser
 525     NSLog(@"loadRequest:%@", request);
 526 #endif
 527
 528     error_ = false;
 529
 530     WebThreadLocked lock;
 531     [webview_ loadRequest:request];
 532 }
 533
 534 - (void) reloadURLWithCache:(BOOL)cache {
 535     if (request_ == nil)
 536         return;
 537
 538     NSMutableURLRequest *request([request_ mutableCopy]);
 539     [request setCachePolicy:(cache ? NSURLRequestUseProtocolCachePolicy : NSURLRequestReloadIgnoringLocalCacheData)];
 540
 541     request_ = request;
 542
 543     if ([request_ HTTPBody] == nil && [request_ HTTPBodyStream] == nil)
 544         [self loadRequest:request_];
 545     else {
 546         UIAlertView *alert = [[[UIAlertView alloc]
 547             initWithTitle:UCLocalize("RESUBMIT_FORM")
 548             message:nil
 549             delegate:self
 550             cancelButtonTitle:UCLocalize("CANCEL")
 551             otherButtonTitles:
 552                 UCLocalize("SUBMIT"),
 553             nil
 554         ] autorelease];
 555
 556         [alert setContext:@"submit"];
 557         [alert show];
 558     }
 559 }
 560
 561 - (void) reloadURL {
 562     [self reloadURLWithCache:YES];
 563 }
 564
 565 - (void) reloadData {
 566     [super reloadData];
 567     [self reloadURLWithCache:YES];
 568 }
 569
 570 - (void) setButtonImage:(NSString *)button withStyle:(NSString *)style toFunction:(id)function {
 571     custom_ = button;
 572     style_ = style;
 573     function_ = function;
 574
 575     [self performSelectorOnMainThread:@selector(applyRightButton) withObject:nil waitUntilDone:NO];
 576 }
 577
 578 - (void) setButtonTitle:(NSString *)button withStyle:(NSString *)style toFunction:(id)function {
 579     custom_ = button;
 580     style_ = style;
 581     function_ = function;
 582
 583     [self performSelectorOnMainThread:@selector(applyRightButton) withObject:nil waitUntilDone:NO];
 584 }
 585
 586 - (void) removeButton {
 587     custom_ = [NSNull null];
 588     [self performSelectorOnMainThread:@selector(applyRightButton) withObject:nil waitUntilDone:NO];
 589 }
 590
 591 - (void) setPopupHook:(id)function {
 592     if (closer_ != nil)
 593         [closer_ autorelease];
 594     if (function == nil)
 595         closer_ = nil;
 596     else
 597         closer_ = [function retain];
 598 }
 599
 600 - (void) scrollToBottomAnimated:(NSNumber *)animated {
 601     CGSize size([scroller_ contentSize]);
 602     CGPoint offset([scroller_ contentOffset]);
 603     CGRect frame([scroller_ frame]);
 604
 605     if (size.height - offset.y < frame.size.height + 20.f) {
 606         CGRect rect = {{0, size.height-1}, {size.width, 1}};
 607         [scroller_ scrollRectToVisible:rect animated:[animated boolValue]];
 608     }
 609 }
 610
 611 - (void) _setViewportWidth {
 612     [[webview_ _documentView] setViewportSize:CGSizeMake(width_, UIWebViewGrowsAndShrinksToFitHeight) forDocumentTypes:0x10];
 613 }
 614
 615 - (void) setViewportWidth:(float)width {
 616     width_ = width != 0 ? width : [[self class] defaultWidth];
 617     [self _setViewportWidth];
 618 }
 619
 620 - (void) _setViewportWidthOnMainThread:(NSNumber *)width {
 621     [self setViewportWidth:[width floatValue]];
 622 }
 623
 624 - (void) setViewportWidthOnMainThread:(float)width {
 625     [self performSelectorOnMainThread:@selector(_setViewportWidthOnMainThread:) withObject:[NSNumber numberWithFloat:width] waitUntilDone:NO];
 626 }
 627
 628 - (void) webViewUpdateViewSettings:(UIWebView *)view {
 629     [self _setViewportWidth];
 630 }
 631
 632 - (void) _openMailToURL:(NSURL *)url {
 633     [[UIApplication sharedApplication] openURL:url];// asPanel:YES];
 634 }
 635
 636 - (bool) _allowJavaScriptPanel {
 637     return true;
 638 }
 639
 640 - (bool) allowsNavigationAction {
 641     return allowsNavigationAction_;
 642 }
 643
 644 - (void) setAllowsNavigationAction:(bool)value {
 645     allowsNavigationAction_ = value;
 646 }
 647
 648 - (void) setAllowsNavigationActionByNumber:(NSNumber *)value {
 649     [self setAllowsNavigationAction:[value boolValue]];
 650 }
 651
 652 - (void) popViewControllerWithNumber:(NSNumber *)value {
 653     UINavigationController *navigation([self navigationController]);
 654     if ([navigation topViewController] == self)
 655         [navigation popViewControllerAnimated:[value boolValue]];
 656 }
 657
 658 - (void) _didFailWithError:(NSError *)error forFrame:(WebFrame *)frame {
 659     [loading_ removeObject:[NSValue valueWithNonretainedObject:frame]];
 660     [self _didFinishLoading];
 661
 662     if ([error code] == NSURLErrorCancelled)
 663         return;
 664
 665     if ([frame parentFrame] == nil) {
 666         [self loadURL:[NSURL URLWithString:[NSString stringWithFormat:@"%@?%@",
 667             [[NSURL fileURLWithPath:[[NSBundle mainBundle] pathForResource:@"error" ofType:@"html"]] absoluteString],
 668             [[error localizedDescription] stringByAddingPercentEscapes]
 669         ]]];
 670
 671         error_ = true;
 672     }
 673 }
 674
 675 - (void) pushRequest:(NSURLRequest *)request asPop:(bool)pop {
 676     NSURL *url([request URL]);
 677
 678     // XXX: filter to internal usage?
 679     CYViewController *page([delegate_ pageForURL:url forExternal:NO]);
 680
 681     if (page == nil) {
 682         BrowserController *browser([[[class_ alloc] init] autorelease]);
 683         [browser loadRequest:request];
 684         page = browser;
 685     }
 686
 687     [page setDelegate:delegate_];
 688
 689     if (!pop) {
 690         [[self navigationItem] setTitle:title_];
 691
 692         [[self navigationController] pushViewController:page animated:YES];
 693     } else {
 694         UCNavigationController *navigation([[[UCNavigationController alloc] initWithRootViewController:page] autorelease]);
 695
 696         [navigation setHook:indirect_];
 697         [navigation setDelegate:delegate_];
 698
 699         [[page navigationItem] setLeftBarButtonItem:[[[UIBarButtonItem alloc]
 700             initWithTitle:UCLocalize("CLOSE")
 701             style:UIBarButtonItemStylePlain
 702             target:page
 703             action:@selector(close)
 704         ] autorelease]];
 705
 706         [[self navigationController] presentModalViewController:navigation animated:YES];
 707     }
 708 }
 709
 710 // CYWebViewDelegate {{{
 711 - (void) webView:(WebView *)view addMessageToConsole:(NSDictionary *)message {
 712 #if LogMessages
 713     NSLog(@"addMessageToConsole:%@", message);
 714 #endif
 715 }
 716
 717 - (void) webView:(WebView *)view decidePolicyForNavigationAction:(NSDictionary *)action request:(NSURLRequest *)request frame:(WebFrame *)frame decisionListener:(id<WebPolicyDecisionListener>)listener {
 718 #if LogBrowser
 719     NSLog(@"decidePolicyForNavigationAction:%@ request:%@ frame:%@", action, request, frame);
 720 #endif
 721
 722     if ([frame parentFrame] == nil) {
 723         if (!error_) {
 724             NSURL *url(request == nil ? nil : [request URL]);
 725
 726             if (request_ == nil || [self allowsNavigationAction] || [[request_ URL] isEqual:url])
 727                 request_ = request;
 728             else {
 729                 if (url != nil)
 730                     [self pushRequest:request asPop:NO];
 731                 [listener ignore];
 732             }
 733         }
 734     }
 735 }
 736
 737 - (void) webView:(WebView *)view decidePolicyForNewWindowAction:(NSDictionary *)action request:(NSURLRequest *)request newFrameName:(NSString *)frame decisionListener:(id<WebPolicyDecisionListener>)listener {
 738 #if LogBrowser
 739     NSLog(@"decidePolicyForNewWindowAction:%@ request:%@ newFrameName:%@", action, request, frame);
 740 #endif
 741
 742     NSURL *url([request URL]);
 743     if (url == nil)
 744         return;
 745
 746     if ([frame isEqualToString:@"_open"])
 747         [delegate_ openURL:url];
 748     else {
 749         NSString *scheme([[url scheme] lowercaseString]);
 750         if ([scheme isEqualToString:@"mailto"])
 751             [self _openMailToURL:url];
 752         else
 753             [self pushRequest:request asPop:[frame isEqualToString:@"_popup"]];
 754     }
 755
 756     [listener ignore];
 757 }
 758
 759 - (void) webView:(WebView *)view didClearWindowObject:(WebScriptObject *)window forFrame:(WebFrame *)frame {
 760 }
 761
 762 - (void) webView:(WebView *)view didFailLoadWithError:(NSError *)error forFrame:(WebFrame *)frame {
 763 #if LogBrowser
 764     NSLog(@"didFailLoadWithError:%@ forFrame:%@", error, frame);
 765 #endif
 766
 767     [self _didFailWithError:error forFrame:frame];
 768 }
 769
 770 - (void) webView:(WebView *)view didFailProvisionalLoadWithError:(NSError *)error forFrame:(WebFrame *)frame {
 771 #if LogBrowser
 772     NSLog(@"didFailProvisionalLoadWithError:%@ forFrame:%@", error, frame);
 773 #endif
 774
 775     [self _didFailWithError:error forFrame:frame];
 776 }
 777
 778 - (void) webView:(WebView *)view didFinishLoadForFrame:(WebFrame *)frame {
 779     [loading_ removeObject:[NSValue valueWithNonretainedObject:frame]];
 780
 781     if ([frame parentFrame] == nil) {
 782         if (DOMDocument *document = [frame DOMDocument])
 783             if (DOMNodeList<NSFastEnumeration> *bodies = [document getElementsByTagName:@"body"])
 784                 for (DOMHTMLBodyElement *body in (id) bodies) {
 785                     DOMCSSStyleDeclaration *style([document getComputedStyle:body pseudoElement:nil]);
 786
 787                     UIColor *uic(nil);
 788
 789                     if (DOMCSSPrimitiveValue *color = static_cast<DOMCSSPrimitiveValue *>([style getPropertyCSSValue:@"background-color"])) {
 790                         if ([color primitiveType] == DOM_CSS_RGBCOLOR) {
 791                             DOMRGBColor *rgb([color getRGBColorValue]);
 792
 793                             float red([[rgb red] getFloatValue:DOM_CSS_NUMBER]);
 794                             float green([[rgb green] getFloatValue:DOM_CSS_NUMBER]);
 795                             float blue([[rgb blue] getFloatValue:DOM_CSS_NUMBER]);
 796                             float alpha([[rgb alpha] getFloatValue:DOM_CSS_NUMBER]);
 797
 798                             if (red == 0xc7 && green == 0xce && blue == 0xd5)
 799                                 uic = [UIColor pinStripeColor];
 800                             else if (alpha != 0)
 801                                 uic = [UIColor
 802                                     colorWithRed:(red / 255)
 803                                     green:(green / 255)
 804                                     blue:(blue / 255)
 805                                     alpha:alpha
 806                                 ];
 807                         }
 808                     }
 809
 810                     [scroller_ setBackgroundColor:(uic ?: [UIColor clearColor])];
 811                     break;
 812                 }
 813     }
 814
 815     [self _didFinishLoading];
 816 }
 817
 818 - (void) webView:(WebView *)view didReceiveTitle:(NSString *)title forFrame:(WebFrame *)frame {
 819     if ([frame parentFrame] != nil)
 820         return;
 821
 822     if (title_ != nil)
 823         [title_ autorelease];
 824     title_ = [title retain];
 825
 826     [[self navigationItem] setTitle:title_];
 827 }
 828
 829 - (void) webView:(WebView *)view didStartProvisionalLoadForFrame:(WebFrame *)frame {
 830     [loading_ addObject:[NSValue valueWithNonretainedObject:frame]];
 831
 832     if ([frame parentFrame] == nil) {
 833         CYRelease(title_);
 834         custom_ = nil;
 835         style_ = nil;
 836         function_ = nil;
 837         CYRelease(closer_);
 838
 839         [self setHidesNavigationBar:NO];
 840
 841         // XXX: do we still need to do this?
 842         [[self navigationItem] setTitle:nil];
 843     }
 844
 845     [self _didStartLoading];
 846 }
 847
 848 - (NSURLRequest *) webView:(WebView *)view resource:(id)identifier willSendRequest:(NSURLRequest *)request redirectResponse:(NSURLResponse *)response fromDataSource:(WebDataSource *)source {
 849 #if LogBrowser
 850     NSLog(@"resource:%@ willSendRequest:%@ redirectResponse:%@ fromDataSource:%@", identifier, request, response, source);
 851 #endif
 852
 853     return request;
 854 }
 855
 856 - (bool) webView:(WebView *)view shouldRunJavaScriptAlertPanelWithMessage:(NSString *)message initiatedByFrame:(WebFrame *)frame {
 857     return [self _allowJavaScriptPanel];
 858 }
 859
 860 - (bool) webView:(WebView *)view shouldRunJavaScriptConfirmPanelWithMessage:(NSString *)message initiatedByFrame:(WebFrame *)frame {
 861     return [self _allowJavaScriptPanel];
 862 }
 863
 864 - (bool) webView:(WebView *)view shouldRunJavaScriptTextInputPanelWithPrompt:(NSString *)prompt defaultText:(NSString *)text initiatedByFrame:(WebFrame *)frame {
 865     return [self _allowJavaScriptPanel];
 866 }
 867
 868 - (void) webViewClose:(WebView *)view {
 869     [self close];
 870 }
 871 // }}}
 872
 873 - (void) close {
 874     [[self navigationController] dismissModalViewControllerAnimated:YES];
 875 }
 876
 877 - (void) alertView:(UIAlertView *)alert clickedButtonAtIndex:(NSInteger)button {
 878     NSString *context([alert context]);
 879
 880     if ([context isEqualToString:@"sensitive"]) {
 881         switch (button) {
 882             case 1:
 883                 sensitive_ = [NSNumber numberWithBool:YES];
 884             break;
 885
 886             case 2:
 887                 sensitive_ = [NSNumber numberWithBool:NO];
 888             break;
 889         }
 890
 891         [alert dismissWithClickedButtonIndex:-1 animated:YES];
 892     } else if ([context isEqualToString:@"challenge"]) {
 893         id<NSURLAuthenticationChallengeSender> sender([challenge_ sender]);
 894
 895         switch (button) {
 896             case 1: {
 897                 NSString *username([[alert textFieldAtIndex:0] text]);
 898                 NSString *password([[alert textFieldAtIndex:1] text]);
 899
 900                 NSURLCredential *credential([NSURLCredential credentialWithUser:username password:password persistence:NSURLCredentialPersistenceForSession]);
 901
 902                 [sender useCredential:credential forAuthenticationChallenge:challenge_];
 903             } break;
 904
 905             case 2:
 906                 [sender cancelAuthenticationChallenge:challenge_];
 907             break;
 908
 909             _nodefault
 910         }
 911
 912         [challenge_ release];
 913         challenge_ = nil;
 914
 915         [alert dismissWithClickedButtonIndex:-1 animated:YES];
 916     } else if ([context isEqualToString:@"submit"]) {
 917         if (button == [alert cancelButtonIndex]) {
 918         } else if (button == [alert firstOtherButtonIndex]) {
 919             if (request_ != nil) {
 920                 WebThreadLocked lock;
 921                 [webview_ loadRequest:request_];
 922             }
 923         }
 924
 925         [alert dismissWithClickedButtonIndex:-1 animated:YES];
 926     }
 927 }
 928
 929 - (UIBarButtonItemStyle) rightButtonStyle {
 930     if (style_ == nil) normal:
 931         return UIBarButtonItemStylePlain;
 932     else if ([style_ isEqualToString:@"Normal"])
 933         return UIBarButtonItemStylePlain;
 934     else if ([style_ isEqualToString:@"Highlighted"])
 935         return UIBarButtonItemStyleDone;
 936     else goto normal;
 937 }
 938
 939 - (UIBarButtonItem *) customButton {
 940     return custom_ == [NSNull null] ? nil : [[[UIBarButtonItem alloc]
 941         initWithTitle:static_cast<NSString *>(custom_.operator NSObject *())
 942         style:[self rightButtonStyle]
 943         target:self
 944         action:@selector(customButtonClicked)
 945     ] autorelease];
 946 }
 947
 948 - (UIBarButtonItem *) rightButton {
 949     return reloaditem_;
 950 }
 951
 952 - (void) applyLoadingTitle {
 953     [[self navigationItem] setTitle:UCLocalize("LOADING")];
 954 }
 955
 956 - (void) layoutRightButton {
 957     [[loadingitem_ view] addSubview:indicator_];
 958     [[loadingitem_ view] bringSubviewToFront:indicator_];
 959 }
 960
 961 - (void) applyRightButton {
 962     if ([self isLoading]) {
 963         [[self navigationItem] setRightBarButtonItem:loadingitem_ animated:YES];
 964         [self performSelector:@selector(layoutRightButton) withObject:nil afterDelay:0];
 965
 966         [indicator_ startAnimating];
 967         [self applyLoadingTitle];
 968     } else {
 969         [indicator_ stopAnimating];
 970
 971         [[self navigationItem] setRightBarButtonItem:(
 972             custom_ != nil ? [self customButton] : [self rightButton]
 973         ) animated:YES];
 974     }
 975 }
 976
 977 - (void) didStartLoading {
 978     // Overridden in subclasses.
 979 }
 980
 981 - (void) _didStartLoading {
 982     [self applyRightButton];
 983
 984     if ([loading_ count] != 1)
 985         return;
 986
 987     [delegate_ retainNetworkActivityIndicator];
 988     [self didStartLoading];
 989 }
 990
 991 - (void) didFinishLoading {
 992     // Overridden in subclasses.
 993 }
 994
 995 - (void) _didFinishLoading {
 996     if ([loading_ count] != 0)
 997         return;
 998
 999     [self applyRightButton];
1000     [[self navigationItem] setTitle:title_];
1001
1002     [delegate_ releaseNetworkActivityIndicator];
1003     [self didFinishLoading];
1004 }
1005
1006 - (bool) isLoading {
1007     return [loading_ count] != 0;
1008 }
1009
1010 - (id) initWithWidth:(float)width ofClass:(Class)_class {
1011     if ((self = [super init]) != nil) {
1012         allowsNavigationAction_ = true;
1013
1014         class_ = _class;
1015         loading_ = [[NSMutableSet alloc] initWithCapacity:5];
1016
1017         indirect_ = [[IndirectDelegate alloc] initWithDelegate:self];
1018
1019         CGRect bounds([[self view] bounds]);
1020
1021         webview_ = [[[CYWebView alloc] initWithFrame:bounds] autorelease];
1022         [webview_ setDelegate:self];
1023         [self setView:webview_];
1024
1025         if ([webview_ respondsToSelector:@selector(setDataDetectorTypes:)])
1026             [webview_ setDataDetectorTypes:UIDataDetectorTypeAutomatic];
1027         else
1028             [webview_ setDetectsPhoneNumbers:NO];
1029
1030         [webview_ setScalesPageToFit:YES];
1031
1032         UIWebDocumentView *document([webview_ _documentView]);
1033
1034         // XXX: I think this improves scrolling; the hardcoded-ness sucks
1035         [document setTileSize:CGSizeMake(320, 500)];
1036
1037         [document setBackgroundColor:[UIColor clearColor]];
1038
1039         // XXX: this is terribly (too?) expensive
1040         [document setDrawsBackground:NO];
1041
1042         WebView *webview([document webView]);
1043         WebPreferences *preferences([webview preferences]);
1044
1045         // XXX: I have no clue if I actually /want/ this modification
1046         if ([webview respondsToSelector:@selector(_setLayoutInterval:)])
1047             [webview _setLayoutInterval:0];
1048         else if ([preferences respondsToSelector:@selector(_setLayoutInterval:)])
1049             [preferences _setLayoutInterval:0];
1050
1051         [preferences setCacheModel:WebCacheModelDocumentBrowser];
1052         [preferences setOfflineWebApplicationCacheEnabled:YES];
1053
1054 #if LogMessages
1055         if ([document respondsToSelector:@selector(setAllowsMessaging:)])
1056             [document setAllowsMessaging:YES];
1057         if ([webview respondsToSelector:@selector(_setAllowsMessaging:)])
1058             [webview _setAllowsMessaging:YES];
1059 #endif
1060
1061         if ([webview_ respondsToSelector:@selector(_scrollView)]) {
1062             scroller_ = [webview_ _scrollView];
1063
1064             [scroller_ setDirectionalLockEnabled:YES];
1065             [scroller_ setDecelerationRate:CYScrollViewDecelerationRateNormal];
1066             [scroller_ setDelaysContentTouches:NO];
1067
1068             [scroller_ setCanCancelContentTouches:YES];
1069         } else if ([webview_ respondsToSelector:@selector(_scroller)]) {
1070             UIScroller *scroller([webview_ _scroller]);
1071             scroller_ = (UIScrollView *) scroller;
1072
1073             [scroller setDirectionalScrolling:YES];
1074             // XXX: we might be better off /not/ setting this on older systems
1075             [scroller setScrollDecelerationFactor:CYScrollViewDecelerationRateNormal]; /* 0.989324 */
1076             [scroller setScrollHysteresis:0]; /* 8 */
1077
1078             [scroller setThumbDetectionEnabled:NO];
1079
1080             // use NO with UIApplicationUseLegacyEvents(YES)
1081             [scroller setEventMode:YES];
1082
1083             // XXX: this is handled by setBounces, right?
1084             //[scroller setAllowsRubberBanding:YES];
1085         }
1086
1087         [scroller_ setFixedBackgroundPattern:YES];
1088         [scroller_ setBackgroundColor:[UIColor clearColor]];
1089         [scroller_ setClipsSubviews:YES];
1090
1091         [scroller_ setBounces:YES];
1092         [scroller_ setScrollingEnabled:YES];
1093         [scroller_ setShowBackgroundShadow:NO];
1094
1095         [self setViewportWidth:width];
1096
1097         reloaditem_ = [[UIBarButtonItem alloc]
1098             initWithTitle:UCLocalize("RELOAD")
1099             style:[self rightButtonStyle]
1100             target:self
1101             action:@selector(reloadButtonClicked)
1102         ];
1103
1104         loadingitem_ = [[UIBarButtonItem alloc]
1105             initWithTitle:@" "
1106             style:UIBarButtonItemStylePlain
1107             target:self
1108             action:@selector(reloadButtonClicked)
1109         ];
1110
1111         indicator_ = [[UIActivityIndicatorView alloc] initWithActivityIndicatorStyle:UIActivityIndicatorViewStyleWhite];
1112         [indicator_ setFrame:CGRectMake(15, 5, [indicator_ frame].size.width, [indicator_ frame].size.height)];
1113
1114         UITableView *table([[[UITableView alloc] initWithFrame:bounds style:UITableViewStyleGrouped] autorelease]);
1115         [webview_ insertSubview:table atIndex:0];
1116
1117         [table setAutoresizingMask:(UIViewAutoresizingFlexibleWidth | UIViewAutoresizingFlexibleHeight)];
1118         [webview_ setAutoresizingMask:(UIViewAutoresizingFlexibleWidth | UIViewAutoresizingFlexibleHeight)];
1119         [indicator_ setAutoresizingMask:UIViewAutoresizingFlexibleLeftMargin];
1120     } return self;
1121 }
1122
1123 - (id) initWithWidth:(float)width {
1124     return [self initWithWidth:width ofClass:[self class]];
1125 }
1126
1127 - (id) init {
1128     return [self initWithWidth:0];
1129 }
1130
1131 - (id) initWithURL:(NSURL *)url {
1132     if ((self = [self init]) != nil) {
1133         [self setURL:url];
1134     } return self;
1135 }
1136
1137 - (void) didDismissModalViewController {
1138     if (closer_ != nil)
1139         [self callFunction:closer_];
1140 }
1141
1142 - (void) callFunction:(WebScriptObject *)function {
1143     WebThreadLocked lock;
1144
1145     WebView *webview([[webview_ _documentView] webView]);
1146     WebFrame *frame([webview mainFrame]);
1147     WebPreferences *preferences([webview preferences]);
1148
1149     bool maybe([preferences javaScriptCanOpenWindowsAutomatically]);
1150     [preferences setJavaScriptCanOpenWindowsAutomatically:NO];
1151
1152     /*id _private(MSHookIvar<id>(webview, "_private"));
1153     WebCore::Page *page(_private == nil ? NULL : MSHookIvar<WebCore::Page *>(_private, "page"));
1154     WebCore::Settings *settings(page == NULL ? NULL : page->settings());
1155
1156     bool no;
1157     if (settings == NULL)
1158         no = 0;
1159     else {
1160         no = settings->JavaScriptCanOpenWindowsAutomatically();
1161         settings->setJavaScriptCanOpenWindowsAutomatically(true);
1162     }*/
1163
1164     if (UIWindow *window = [[self view] window])
1165         if (UIResponder *responder = [window firstResponder])
1166             [responder resignFirstResponder];
1167
1168     JSObjectRef object([function JSObject]);
1169     JSGlobalContextRef context([frame globalContext]);
1170     JSObjectCallAsFunction(context, object, NULL, 0, NULL, NULL);
1171
1172     /*if (settings != NULL)
1173         settings->setJavaScriptCanOpenWindowsAutomatically(no);*/
1174
1175     [preferences setJavaScriptCanOpenWindowsAutomatically:maybe];
1176 }
1177
1178 - (void) reloadButtonClicked {
1179     [self reloadURLWithCache:YES];
1180 }
1181
1182 - (void) _customButtonClicked {
1183     [self reloadButtonClicked];
1184 }
1185
1186 - (void) customButtonClicked {
1187 #if !AlwaysReload
1188     if (function_ != nil)
1189         [self callFunction:function_];
1190     else
1191 #endif
1192     [self _customButtonClicked];
1193 }
1194
1195 + (float) defaultWidth {
1196     return 980;
1197 }
1198
1199 - (void) setNavigationBarStyle:(NSString *)name {
1200     UIBarStyle style;
1201     if ([name isEqualToString:@"Black"])
1202         style = UIBarStyleBlack;
1203     else
1204         style = UIBarStyleDefault;
1205
1206     [[[self navigationController] navigationBar] setBarStyle:style];
1207 }
1208
1209 - (void) setNavigationBarTintColor:(UIColor *)color {
1210     [[[self navigationController] navigationBar] setTintColor:color];
1211 }
1212
1213 - (void) setHidesBackButton:(bool)value {
1214     [[self navigationItem] setHidesBackButton:value];
1215 }
1216
1217 - (void) setHidesBackButtonByNumber:(NSNumber *)value {
1218     [self setHidesBackButton:[value boolValue]];
1219 }
1220
1221 - (void) dispatchEvent:(NSString *)event {
1222     WebThreadLocked lock;
1223
1224     NSString *script([NSString stringWithFormat:@
1225         "(function() {"
1226             "var event = this.document.createEvent('Events');"
1227             "event.initEvent('%@', false, false);"
1228             "this.document.dispatchEvent(event);"
1229         "})();"
1230     , event]);
1231
1232     NSMutableArray *frames([NSMutableArray arrayWithObjects:
1233         [[[webview_ _documentView] webView] mainFrame]
1234     , nil]);
1235
1236     while (WebFrame *frame = [frames lastObject]) {
1237         WebScriptObject *object([frame windowObject]);
1238         [object evaluateWebScript:script];
1239         [frames removeLastObject];
1240         [frames addObjectsFromArray:[frame childFrames]];
1241     }
1242 }
1243
1244 - (bool) hidesNavigationBar {
1245     return hidesNavigationBar_;
1246 }
1247
1248 - (void) _setHidesNavigationBar:(bool)value animated:(bool)animated {
1249     if (visible_)
1250         [[self navigationController] setNavigationBarHidden:(value && [self hidesNavigationBar]) animated:animated];
1251 }
1252
1253 - (void) setHidesNavigationBar:(bool)value {
1254     if (hidesNavigationBar_ != value) {
1255         hidesNavigationBar_ = value;
1256         [self _setHidesNavigationBar:YES animated:YES];
1257     }
1258 }
1259
1260 - (void) setHidesNavigationBarByNumber:(NSNumber *)value {
1261     [self setHidesNavigationBar:[value boolValue]];
1262 }
1263
1264 - (void) viewWillAppear:(BOOL)animated {
1265     visible_ = true;
1266
1267     if ([self hidesNavigationBar])
1268         [self _setHidesNavigationBar:YES animated:animated];
1269
1270     [self dispatchEvent:@"CydiaViewWillAppear"];
1271     [super viewWillAppear:animated];
1272 }
1273
1274 - (void) viewDidAppear:(BOOL)animated {
1275     [super viewDidAppear:animated];
1276     [self dispatchEvent:@"CydiaViewDidAppear"];
1277 }
1278
1279 - (void) viewWillDisappear:(BOOL)animated {
1280     [self dispatchEvent:@"CydiaViewWillDisappear"];
1281     [super viewWillDisappear:animated];
1282
1283     if ([self hidesNavigationBar])
1284         [self _setHidesNavigationBar:NO animated:animated];
1285
1286     visible_ = false;
1287 }
1288
1289 - (void) viewDidDisappear:(BOOL)animated {
1290     [super viewDidDisappear:animated];
1291     [self dispatchEvent:@"CydiaViewDidDisappear"];
1292 }
1293
1294 @end