src/cocoa/dcmemory.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/cocoa/dcmemory.mm
   3 // Purpose:     wxMemoryDC class
   4 // Author:      David Elliott
   5 // Modified by:
   6 // Created:     2003/03/16
   7 // RCS-ID:      $Id$
   8 // Copyright:   (c) 2002 David Elliott
   9 // Licence:     wxWindows licence
  10 /////////////////////////////////////////////////////////////////////////////
  11
  12 #include "wx/wxprec.h"
  13 #ifndef WX_PRECOMP
  14     #include "wx/log.h"
  15     #include "wx/dcmemory.h"
  16 #endif //WX_PRECOMP
  17
  18 #import <AppKit/NSImage.h>
  19 #import <AppKit/NSAffineTransform.h>
  20 #import <AppKit/NSGraphicsContext.h>
  21
  22 //-----------------------------------------------------------------------------
  23 // wxMemoryDC
  24 //-----------------------------------------------------------------------------
  25
  26 IMPLEMENT_DYNAMIC_CLASS(wxMemoryDC,wxDC)
  27
  28 wxMemoryDC::wxMemoryDC(void)
  29 {
  30     m_cocoaNSImage = NULL;
  31     m_ok = false;
  32 }
  33
  34 wxMemoryDC::wxMemoryDC( wxDC *WXUNUSED(dc) )
  35 {
  36     m_cocoaNSImage = NULL;
  37     m_ok = false;
  38 }
  39
  40 wxMemoryDC::~wxMemoryDC(void)
  41 {
  42     CocoaUnwindStackAndLoseFocus();
  43     [m_cocoaNSImage release];
  44 }
  45
  46 bool wxMemoryDC::CocoaLockFocus()
  47 {
  48     if(m_cocoaNSImage)
  49     {
  50         [m_cocoaNSImage lockFocus];
  51         sm_cocoaDCStack.Insert(this);
  52         m_cocoaFlipped = [m_cocoaNSImage isFlipped];
  53         m_cocoaHeight = [m_cocoaNSImage size].height;
  54         CocoaApplyTransformations();
  55         return true;
  56     }
  57     return false;
  58 }
  59
  60 bool wxMemoryDC::CocoaUnlockFocus()
  61 {
  62     [m_cocoaNSImage unlockFocus];
  63     return true;
  64 }
  65
  66 // NOTE: The AppKit is unable to draw onto an NSBitmapImageRep so we must
  67 // instead copy the data to an offscreen window, then copy it back
  68 void wxMemoryDC::SelectObject( const wxBitmap& bitmap )
  69 {
  70     if(m_selectedBitmap.Ok())
  71     {
  72         CocoaTakeFocus();
  73         wxASSERT(m_cocoaNSImage);
  74         m_selectedBitmap.SetNSBitmapImageRep(
  75             [[NSBitmapImageRep alloc]
  76                 initWithFocusedViewRect:NSMakeRect(0.0,0.0,
  77                     m_selectedBitmap.GetWidth(),
  78                     m_selectedBitmap.GetHeight())]);
  79     }
  80     CocoaUnwindStackAndLoseFocus();
  81     [m_cocoaNSImage release];
  82     m_cocoaNSImage = nil;
  83     m_selectedBitmap = bitmap;
  84     if(m_selectedBitmap.Ok())
  85     {
  86         // Create an offscreen window of the same size
  87         m_cocoaNSImage = [[NSImage alloc]
  88                 initWithSize:NSMakeSize(m_selectedBitmap.GetWidth(),
  89                     m_selectedBitmap.GetHeight())];
  90
  91         // Now copy the data
  92         NSImage *nsimage = [[NSImage alloc]
  93                 initWithSize:NSMakeSize(m_selectedBitmap.GetWidth(),
  94                     m_selectedBitmap.GetHeight())];
  95         [nsimage addRepresentation: const_cast<wxBitmap&>(m_selectedBitmap).GetNSBitmapImageRep()];
  96         [m_cocoaNSImage lockFocus];
  97         [nsimage drawAtPoint: NSMakePoint(0,0)
  98             fromRect: NSMakeRect(0.0,0.0,m_selectedBitmap.GetWidth(),m_selectedBitmap.GetHeight())
  99             operation: NSCompositeCopy
 100             fraction: 1.0];
 101         [m_cocoaNSImage unlockFocus];
 102
 103         [nsimage release];
 104     }
 105 }
 106
 107 void wxMemoryDC::DoGetSize( int *width, int *height ) const
 108 {
 109     if(width)
 110         *width = m_selectedBitmap.GetWidth();
 111     if(height)
 112         *height = m_selectedBitmap.GetHeight();
 113 }
 114
 115 bool wxMemoryDC::CocoaDoBlitOnFocusedDC(wxCoord xdest, wxCoord ydest,
 116     wxCoord width, wxCoord height, wxCoord xsrc, wxCoord ysrc,
 117     int logicalFunc, bool useMask, wxCoord xsrcMask, wxCoord ysrcMask)
 118 {
 119     if(!m_selectedBitmap.Ok())
 120         return false;
 121
 122     NSAffineTransform *transform = [NSAffineTransform transform];
 123     [transform translateXBy:xdest yBy:ydest];
 124
 125     NSAffineTransform *flipTransform = [NSAffineTransform transform];
 126     /*  x' = 1x + 0y + 0
 127         y' = 0x + -1y + window's height
 128     */
 129     NSAffineTransformStruct matrix = {
 130         1,  0
 131     ,   0, -1
 132     ,   0, height
 133     };
 134     [flipTransform setTransformStruct: matrix];
 135
 136     NSGraphicsContext *context = [NSGraphicsContext currentContext];
 137     [context saveGraphicsState];
 138     [transform concat];
 139     [flipTransform concat];
 140
 141     wxLogDebug("[m_cocoaNSImage isFlipped]=%d", [m_cocoaNSImage isFlipped]);
 142     [m_cocoaNSImage drawAtPoint: NSMakePoint(0,0)
 143         fromRect: NSMakeRect(xsrc,
 144             m_selectedBitmap.GetHeight()-height-ysrc,
 145             width, height)
 146         operation: NSCompositeCopy // FIXME: raster ops
 147         fraction: 1.0];
 148
 149     [context restoreGraphicsState];
 150     return false;
 151 }
 152