Parser.ypp.in

   1 /* Cycript - Optimizing JavaScript Compiler/Runtime
   2  * Copyright (C) 2009-2015  Jay Freeman (saurik)
   3 */
   4
   5 /* GNU Affero General Public License, Version 3 {{{ */
   6 /*
   7  * This program is free software: you can redistribute it and/or modify
   8  * it under the terms of the GNU Affero General Public License as published by
   9  * the Free Software Foundation, either version 3 of the License, or
  10  * (at your option) any later version.
  11
  12  * This program is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU Affero General Public License for more details.
  16
  17  * You should have received a copy of the GNU Affero General Public License
  18  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 **/
  20 /* }}} */
  21
  22 %code top {
  23 #define YYSTACKEXPANDABLE 1
  24 }
  25
  26 %code requires {
  27 #include "Driver.hpp"
  28 #include "Parser.hpp"
  29 #include "Stack.hpp"
  30 #define CYNew new(driver.pool_)
  31
  32 @begin ObjectiveC
  33 #include "ObjectiveC/Syntax.hpp"
  34 @end
  35
  36 @begin E4X
  37 #include "E4X/Syntax.hpp"
  38 @end
  39
  40 #include "Highlight.hpp"
  41 }
  42
  43 %union { bool bool_; }
  44
  45 %union { CYArgument *argument_; }
  46 %union { CYAssignment *assignment_; }
  47 %union { CYBoolean *boolean_; }
  48 %union { CYClause *clause_; }
  49 %union { cy::Syntax::Catch *catch_; }
  50 %union { CYComprehension *comprehension_; }
  51 %union { CYDeclaration *declaration_; }
  52 %union { CYDeclarations *declarations_; }
  53 %union { CYElement *element_; }
  54 %union { CYExpression *expression_; }
  55 %union { CYFalse *false_; }
  56 %union { CYVariable *variable_; }
  57 %union { CYFinally *finally_; }
  58 %union { CYForInitializer *for_; }
  59 %union { CYForInInitializer *forin_; }
  60 %union { CYFunctionParameter *functionParameter_; }
  61 %union { CYIdentifier *identifier_; }
  62 %union { CYInfix *infix_; }
  63 %union { CYLiteral *literal_; }
  64 %union { CYMember *member_; }
  65 %union { CYModule *module_; }
  66 %union { CYNull *null_; }
  67 %union { CYNumber *number_; }
  68 %union { CYParenthetical *parenthetical_; }
  69 %union { CYProperty *property_; }
  70 %union { CYPropertyName *propertyName_; }
  71 %union { CYRubyProc *rubyProc_; }
  72 %union { CYSpan *span_; }
  73 %union { CYStatement *statement_; }
  74 %union { CYString *string_; }
  75 %union { CYThis *this_; }
  76 %union { CYTrue *true_; }
  77 %union { CYWord *word_; }
  78
  79 @begin C
  80 %union { CYTypeModifier *modifier_; }
  81 %union { CYTypeSpecifier *specifier_; }
  82 %union { CYTypedIdentifier *typedIdentifier_; }
  83 %union { CYTypedParameter *typedParameter_; }
  84 @end
  85
  86 @begin ObjectiveC
  87 %union { CYClassName *className_; }
  88 %union { CYClassField *classField_; }
  89 %union { CYMessage *message_; }
  90 %union { CYMessageParameter *messageParameter_; }
  91 %union { CYProtocol *protocol_; }
  92 %union { CYSelectorPart *selector_; }
  93 @end
  94
  95 @begin E4X
  96 %union { CYAttribute *attribute_; }
  97 %union { CYPropertyIdentifier *propertyIdentifier_; }
  98 %union { CYSelector *selector_; }
  99 @end
 100
 101 %code provides {
 102
 103 struct YYSTYPE {
 104     cy::parser::semantic_type semantic_;
 105     hi::Value highlight_;
 106 };
 107
 108 int cylex(YYSTYPE *, CYLocation *, void *);
 109
 110 }
 111
 112 %code {
 113
 114 #undef yylex
 115 _finline int yylex(cy::parser::semantic_type *semantic, CYLocation *location, CYDriver &driver) {
 116     if (driver.mark_ == CYMarkIgnore);
 117     else if (driver.mark_ == CYMarkScript) {
 118         driver.mark_ = CYMarkIgnore;
 119         return cy::parser::token::MarkScript;
 120     } else if (driver.mark_ == CYMarkModule) {
 121         driver.mark_ = CYMarkIgnore;
 122         return cy::parser::token::MarkModule;
 123     }
 124
 125     YYSTYPE data;
 126     int token(cylex(&data, location, driver.scanner_));
 127     *semantic = data.semantic_;
 128     return token;
 129 }
 130
 131 #define CYMAP(to, from) do { \
 132     if (yyla.empty()) \
 133         yyla.type = yytranslate_(yylex(&yyla.value, &yyla.location, driver)); \
 134     if (yyla.type == yytranslate_(token::from)) \
 135         yyla.type = yytranslate_(token::to); \
 136 } while (false)
 137
 138 #define CYERR(location, message) do { \
 139     error(location, message); \
 140     YYABORT; \
 141 } while (false)
 142
 143 #define CYNOT(location) \
 144     CYERR(location, "unimplemented feature")
 145
 146 }
 147
 148 %name-prefix "cy"
 149
 150 %language "C++"
 151
 152 %initial-action {
 153     @$.begin.filename = @$.end.filename = &driver.filename_;
 154 };
 155
 156 %locations
 157 %defines
 158
 159 %define api.location.type { CYLocation }
 160
 161 //%glr-parser
 162 //%expect 1
 163
 164 %error-verbose
 165
 166 %param { CYDriver &driver }
 167
 168 /* Token Declarations {{{ */
 169 @begin E4X
 170 %token XMLCDATA
 171 %token XMLComment
 172 %token XMLPI
 173
 174 %token XMLAttributeValue
 175 %token XMLName
 176 %token XMLTagCharacters
 177 %token XMLText
 178 %token XMLWhitespace
 179 @end
 180
 181 @begin E4X
 182 %token LeftRight "<>"
 183 %token LeftSlashRight "</>"
 184
 185 %token SlashRight "/>"
 186 %token LeftSlash "</"
 187
 188 %token ColonColon "::"
 189 %token PeriodPeriod ".."
 190 @end
 191
 192 @begin E4X ObjectiveC
 193 %token At "@"
 194 %token Pound "#"
 195 @end
 196
 197 %token Ampersand "&"
 198 %token AmpersandAmpersand "&&"
 199 %token AmpersandEqual "&="
 200 %token Carrot "^"
 201 %token CarrotEqual "^="
 202 %token Equal "="
 203 %token EqualEqual "=="
 204 %token EqualEqualEqual "==="
 205 %token EqualRight "=>"
 206 %token EqualRight_ "\n=>"
 207 %token Exclamation "!"
 208 %token ExclamationEqual "!="
 209 %token ExclamationEqualEqual "!=="
 210 %token Hyphen "-"
 211 %token HyphenEqual "-="
 212 %token HyphenHyphen "--"
 213 %token HyphenHyphen_ "\n--"
 214 %token HyphenRight "->"
 215 %token Left "<"
 216 %token LeftEqual "<="
 217 %token LeftLeft "<<"
 218 %token LeftLeftEqual "<<="
 219 %token Percent "%"
 220 %token PercentEqual "%="
 221 %token Period "."
 222 %token PeriodPeriodPeriod "..."
 223 %token Pipe "|"
 224 %token PipeEqual "|="
 225 %token PipePipe "||"
 226 %token Plus "+"
 227 %token PlusEqual "+="
 228 %token PlusPlus "++"
 229 %token PlusPlus_ "\n++"
 230 %token Right ">"
 231 %token RightEqual ">="
 232 %token RightRight ">>"
 233 %token RightRightEqual ">>="
 234 %token RightRightRight ">>>"
 235 %token RightRightRightEqual ">>>="
 236 %token Slash "/"
 237 %token SlashEqual "/="
 238 %token Star "*"
 239 %token StarEqual "*="
 240 %token Tilde "~"
 241
 242 %token Colon ":"
 243 %token Comma ","
 244 %token Question "?"
 245 %token SemiColon ";"
 246 %token NewLine "\n"
 247
 248 %token Comment
 249
 250 %token OpenParen "("
 251 %token CloseParen ")"
 252
 253 %token OpenBrace "{"
 254 %token OpenBrace_ "\n{"
 255 %token OpenBrace__ ";{"
 256 %token CloseBrace "}"
 257
 258 %token OpenBracket "["
 259 %token CloseBracket "]"
 260
 261 %token At_error_ "@error"
 262
 263 @begin Java
 264 %token At_class_ "@class"
 265 @end
 266
 267 @begin C
 268 %token _typedef_ "typedef"
 269 %token _unsigned_ "unsigned"
 270 %token _signed_ "signed"
 271 %token _extern_ "extern"
 272 @end
 273
 274 @begin C
 275 %token At_encode_ "@encode"
 276 @end
 277
 278 @begin ObjectiveC
 279 %token At_implementation_ "@implementation"
 280 %token At_import_ "@import"
 281 %token At_end_ "@end"
 282 %token At_selector_ "@selector"
 283 %token At_null_ "@null"
 284 %token At_YES_ "@YES"
 285 %token At_NO_ "@NO"
 286 %token At_true_ "@true"
 287 %token At_false_ "@false"
 288 %token _YES_ "YES"
 289 %token _NO_ "NO"
 290 @end
 291
 292 %token _false_ "false"
 293 %token _null_ "null"
 294 %token _true_ "true"
 295
 296 %token _break_ "break"
 297 %token _case_ "case"
 298 %token _catch_ "catch"
 299 %token _class_ "class"
 300 %token _class__ ";class"
 301 %token _const_ "const"
 302 %token _continue_ "continue"
 303 %token _debugger_ "debugger"
 304 %token _default_ "default"
 305 %token _delete_ "delete"
 306 %token _do_ "do"
 307 %token _else_ "else"
 308 %token _enum_ "enum"
 309 %token _export_ "export"
 310 %token _extends_ "extends"
 311 %token _finally_ "finally"
 312 %token _for_ "for"
 313 %token _function_ "function"
 314 %token _function__ ";function"
 315 %token _if_ "if"
 316 %token _import_ "import"
 317 %token _in_ "in"
 318 %token _in__ "!in"
 319 %token _instanceof_ "instanceof"
 320 %token _new_ "new"
 321 %token _return_ "return"
 322 %token _return__ "!return"
 323 %token _super_ "super"
 324 %token _switch_ "switch"
 325 %token _this_ "this"
 326 %token _throw_ "throw"
 327 %token _try_ "try"
 328 %token _typeof_ "typeof"
 329 %token _var_ "var"
 330 %token _void_ "void"
 331 %token _while_ "while"
 332 %token _with_ "with"
 333
 334 %token _abstract_ "abstract"
 335 %token _await_ "await"
 336 %token _boolean_ "boolean"
 337 %token _byte_ "byte"
 338 %token _char_ "char"
 339 %token _double_ "double"
 340 %token _final_ "final"
 341 %token _float_ "float"
 342 %token _from_ "from"
 343 %token _get_ "get"
 344 %token _goto_ "goto"
 345 %token _implements_ "implements"
 346 %token _int_ "int"
 347 %token _interface_ "interface"
 348 %token _let_ "let"
 349 %token _long_ "long"
 350 %token _native_ "native"
 351 %token _package_ "package"
 352 %token _private_ "private"
 353 %token _protected_ "protected"
 354 %token _public_ "public"
 355 %token _set_ "set"
 356 %token _short_ "short"
 357 %token _static_ "static"
 358 %token _synchronized_ "synchronized"
 359 %token _throws_ "throws"
 360 %token _transient_ "transient"
 361 %token _volatile_ "volatile"
 362 %token _yield_ "yield"
 363 %token _yield__ "!yield"
 364
 365 %token _undefined_ "undefined"
 366
 367 @begin ObjectiveC
 368 %token _bool_ "bool"
 369 %token _BOOL_ "BOOL"
 370 %token _id_ "id"
 371 %token _nil_ "nil"
 372 %token _NULL_ "NULL"
 373 %token _SEL_ "SEL"
 374 @end
 375
 376 %token _auto_ "auto"
 377 %token _each_ "each"
 378 %token _of_ "of"
 379
 380 @begin E4X
 381 %token _namespace_ "namespace"
 382 %token _xml_ "xml"
 383 @end
 384
 385 %token AutoComplete
 386 %token YieldStar
 387
 388 %token <identifier_> Identifier_
 389 %token <number_> NumericLiteral
 390 %token <string_> StringLiteral
 391 %token <literal_> RegularExpressionLiteral
 392
 393 %token <string_> NoSubstitutionTemplate
 394 %token <string_> TemplateHead
 395 %token <string_> TemplateMiddle
 396 %token <string_> TemplateTail
 397
 398 %type <expression_> AdditiveExpression
 399 %type <argument_> ArgumentList_
 400 %type <argument_> ArgumentList
 401 %type <argument_> ArgumentListOpt
 402 %type <argument_> Arguments
 403 %type <expression_> ArrayComprehension
 404 %type <literal_> ArrayLiteral
 405 %type <expression_> ArrowFunction
 406 %type <functionParameter_> ArrowParameters
 407 %type <expression_> AssignmentExpression
 408 %type <expression_> AssignmentExpressionOpt
 409 %type <identifier_> BindingIdentifier
 410 %type <identifier_> BindingIdentifierOpt
 411 %type <declarations_> BindingList_
 412 %type <declarations_> BindingList
 413 %type <expression_> BitwiseANDExpression
 414 %type <statement_> Block
 415 %type <statement_> BlockStatement
 416 %type <boolean_> BooleanLiteral
 417 %type <declaration_> BindingElement
 418 %type <expression_> BitwiseORExpression
 419 %type <expression_> BitwiseXORExpression
 420 %type <statement_> BreakStatement
 421 %type <statement_> BreakableStatement
 422 %type <expression_> CallExpression_
 423 %type <expression_> CallExpression
 424 %type <clause_> CaseBlock
 425 %type <clause_> CaseClause
 426 %type <clause_> CaseClausesOpt
 427 %type <catch_> Catch
 428 %type <identifier_> CatchParameter
 429 %type <statement_> ClassDeclaration
 430 %type <expression_> ClassExpression
 431 %type <expression_> Comprehension
 432 %type <comprehension_> ComprehensionFor
 433 %type <comprehension_> ComprehensionIf
 434 %type <comprehension_> ComprehensionTail
 435 %type <expression_> ComputedPropertyName
 436 %type <expression_> ConditionalExpression
 437 %type <statement_> ContinueStatement
 438 %type <statement_> ConciseBody
 439 %type <parenthetical_> CoverParenthesizedExpressionAndArrowParameterList
 440 %type <statement_> DebuggerStatement
 441 %type <statement_> Declaration__
 442 %type <statement_> Declaration_
 443 %type <statement_> Declaration
 444 %type <clause_> DefaultClause
 445 %type <element_> ElementList
 446 %type <element_> ElementListOpt
 447 %type <statement_> ElseStatementOpt
 448 %type <statement_> EmptyStatement
 449 %type <expression_> EqualityExpression
 450 %type <expression_> Expression
 451 %type <expression_> ExpressionOpt
 452 %type <statement_> ExpressionStatement
 453 %type <finally_> Finally
 454 %type <declaration_> ForBinding
 455 %type <declaration_> ForDeclaration
 456 %type <forin_> ForInStatementInitializer
 457 %type <for_> ForStatementInitializer
 458 %type <declaration_> FormalParameter
 459 %type <functionParameter_> FormalParameterList_
 460 %type <functionParameter_> FormalParameterList
 461 %type <functionParameter_> FormalParameters
 462 %type <statement_> FunctionBody
 463 %type <statement_> FunctionDeclaration
 464 %type <expression_> FunctionExpression
 465 %type <statement_> FunctionStatementList
 466 %type <statement_> GeneratorBody
 467 %type <statement_> GeneratorDeclaration
 468 %type <expression_> GeneratorExpression
 469 %type <property_> GeneratorMethod
 470 %type <statement_> HoistableDeclaration
 471 %type <identifier_> Identifier
 472 %type <identifier_> IdentifierType
 473 %type <word_> IdentifierName
 474 %type <variable_> IdentifierReference
 475 %type <statement_> IfStatement
 476 %type <expression_> Initializer
 477 %type <expression_> InitializerOpt
 478 %type <statement_> IterationStatement
 479 %type <identifier_> LabelIdentifier
 480 %type <statement_> LabelledItem
 481 %type <statement_> LabelledStatement
 482 %type <expression_> LeftHandSideExpression
 483 %type <statement_> LetStatement
 484 %type <declaration_> LexicalBinding
 485 %type <statement_> LexicalDeclaration
 486 %type <literal_> Literal
 487 %type <propertyName_> LiteralPropertyName
 488 %type <expression_> LogicalANDExpression
 489 %type <expression_> LogicalORExpression
 490 %type <member_> MemberAccess
 491 %type <expression_> MemberExpression
 492 %type <property_> MethodDefinition
 493 %type <module_> ModulePath
 494 %type <expression_> MultiplicativeExpression
 495 %type <expression_> NewExpression
 496 %type <null_> NullLiteral
 497 %type <literal_> ObjectLiteral
 498 %type <expression_> PostfixExpression
 499 %type <expression_> PrimaryExpression
 500 %type <propertyName_> PropertyName
 501 %type <property_> PropertyDefinition
 502 %type <property_> PropertyDefinitionList_
 503 %type <property_> PropertyDefinitionList
 504 %type <property_> PropertyDefinitionListOpt
 505 %type <declaration_> PropertySetParameterList
 506 %type <expression_> RelationalExpression
 507 %type <statement_> ReturnStatement
 508 %type <rubyProc_> RubyProcExpression
 509 %type <functionParameter_> RubyProcParameterList_
 510 %type <functionParameter_> RubyProcParameterList
 511 %type <functionParameter_> RubyProcParameters
 512 %type <functionParameter_> RubyProcParametersOpt
 513 %type <statement_> Script
 514 %type <statement_> ScriptBody
 515 %type <statement_> ScriptBodyOpt
 516 %type <expression_> ShiftExpression
 517 %type <declaration_> SingleNameBinding
 518 %type <statement_> Statement__
 519 %type <statement_> Statement_
 520 %type <statement_> Statement
 521 %type <statement_> StatementList
 522 %type <statement_> StatementListOpt
 523 %type <statement_> StatementListItem
 524 %type <functionParameter_> StrictFormalParameters
 525 %type <statement_> SwitchStatement
 526 %type <expression_> TemplateLiteral
 527 %type <span_> TemplateSpans
 528 %type <statement_> ThrowStatement
 529 %type <statement_> TryStatement
 530 %type <expression_> UnaryExpression_
 531 %type <expression_> UnaryExpression
 532 %type <declaration_> VariableDeclaration
 533 %type <declarations_> VariableDeclarationList_
 534 %type <declarations_> VariableDeclarationList
 535 %type <statement_> VariableStatement
 536 %type <statement_> WithStatement
 537 %type <word_> Word
 538 @begin ObjectiveC
 539 %type <word_> WordOpt
 540 @end
 541 %type <expression_> YieldExpression
 542
 543 @begin C
 544 %type <specifier_> IntegerType
 545 %type <specifier_> IntegerTypeOpt
 546 %type <typedIdentifier_> PrefixedType
 547 %type <specifier_> PrimitiveType
 548 %type <typedIdentifier_> SuffixedType
 549 %type <typedIdentifier_> TypeSignifier
 550 %type <modifier_> TypeQualifierLeft
 551 %type <typedIdentifier_> TypeQualifierRight
 552 %type <typedIdentifier_> TypedIdentifier
 553 %type <typedParameter_> TypedParameterList_
 554 %type <typedParameter_> TypedParameterList
 555 %type <typedParameter_> TypedParameterListOpt
 556 @end
 557
 558 @begin ObjectiveC
 559 %type <expression_> BoxableExpression
 560 %type <statement_> CategoryStatement
 561 %type <classField_> ClassFieldListOpt
 562 %type <classField_> ClassFields
 563 %type <statement_> ClassStatement
 564 %type <expression_> ClassSuperOpt
 565 %type <message_> ClassMessageDeclaration
 566 %type <message_> ClassMessageDeclarationListOpt
 567 %type <className_> ClassName
 568 %type <protocol_> ClassProtocolListOpt
 569 %type <protocol_> ClassProtocols
 570 %type <protocol_> ClassProtocolsOpt
 571 %type <expression_> MessageExpression
 572 %type <messageParameter_> MessageParameter
 573 %type <messageParameter_> MessageParameters
 574 %type <messageParameter_> MessageParameterList
 575 %type <messageParameter_> MessageParameterListOpt
 576 %type <bool_> MessageScope
 577 %type <argument_> SelectorCall_
 578 %type <argument_> SelectorCall
 579 %type <selector_> SelectorExpression_
 580 %type <selector_> SelectorExpression
 581 %type <selector_> SelectorExpressionOpt
 582 %type <argument_> SelectorList
 583 %type <word_> SelectorWordOpt
 584 %type <typedIdentifier_> TypeOpt
 585 %type <argument_> VariadicCall
 586 @end
 587
 588 @begin E4X
 589 %type <propertyIdentifier_> PropertyIdentifier_
 590 %type <selector_> PropertySelector_
 591 %type <selector_> PropertySelector
 592 %type <identifier_> QualifiedIdentifier_
 593 %type <identifier_> QualifiedIdentifier
 594 %type <identifier_> WildcardIdentifier
 595 %type <identifier_> XMLComment
 596 %type <identifier_> XMLCDATA
 597 %type <identifier_> XMLElement
 598 %type <identifier_> XMLElementContent
 599 %type <identifier_> XMLMarkup
 600 %type <identifier_> XMLPI
 601
 602 %type <attribute_> AttributeIdentifier
 603 /* XXX: %type <statement_> DefaultXMLNamespaceStatement */
 604 %type <expression_> PropertyIdentifier
 605 %type <expression_> XMLListInitialiser
 606 %type <expression_> XMLInitialiser
 607 @end
 608 /* }}} */
 609 /* Token Priorities {{{ */
 610 %nonassoc ""
 611 %left "++" "--" "{"
 612
 613 %nonassoc "if"
 614 %nonassoc "else"
 615 /* }}} */
 616
 617 %start Program
 618 %token MarkModule
 619 %token MarkScript
 620
 621 %%
 622
 623 Program
 624     : MarkScript Script
 625     | MarkModule Module
 626     ;
 627
 628 /* Lexer State {{{ */
 629 LexPushInOn: { driver.in_.push(true); };
 630 LexPushInOff: { driver.in_.push(false); };
 631 LexPopIn: { driver.in_.pop(); };
 632
 633 LexPushReturnOn: { driver.return_.push(true); };
 634 LexPopReturn: { driver.return_.pop(); };
 635
 636 LexPushYieldOn: { driver.yield_.push(true); };
 637 LexPushYieldOff: { driver.yield_.push(false); };
 638 LexPopYield: { driver.yield_.pop(); };
 639
 640 LexSetRegExp
 641     : { driver.SetCondition(CYDriver::RegExpCondition); }
 642     ;
 643
 644 LexNewLine
 645     : { if (!yyla.empty() && yyla.type_get() != yyeof_) CYERR(@$, "unexpected lookahead"); driver.next_ = true; }
 646     ;
 647
 648 LexNoStar
 649     : { CYMAP(YieldStar, Star); }
 650     ;
 651
 652 LexNoBrace
 653     : { CYMAP(OpenBrace__, OpenBrace); CYMAP(OpenBrace__, OpenBrace_); }
 654     ;
 655
 656 LexNoClass
 657     : { CYMAP(_class__, _class_); }
 658     ;
 659
 660 LexNoFunction
 661     : { CYMAP(_function__, _function_); }
 662     ;
 663
 664 LexSetStatement
 665     : LexNoBrace LexNoClass LexNoFunction
 666     ;
 667 /* }}} */
 668 /* Virtual Tokens {{{ */
 669 BRACE
 670     : "{"
 671     | "\n{"
 672     ;
 673
 674 Var_
 675     : "var"
 676     ;
 677 /* }}} */
 678
 679 /* 11.6 Names and Keywords {{{ */
 680 IdentifierName
 681     : Word { $$ = $1; }
 682     | "for" { $$ = CYNew CYWord("for"); }
 683     | "in" { $$ = CYNew CYWord("in"); }
 684     | "instanceof" { $$ = CYNew CYWord("instanceof"); }
 685     ;
 686
 687 NewLineOpt
 688     : "\n"
 689     |
 690     ;
 691
 692 Word
 693     : Identifier { $$ = $1; }
 694     | "auto" { $$ = CYNew CYWord("auto"); }
 695     | "break" { $$ = CYNew CYWord("break"); }
 696     | "case" { $$ = CYNew CYWord("case"); }
 697     | "catch" { $$ = CYNew CYWord("catch"); }
 698     | "class" { $$ = CYNew CYWord("class"); }
 699     | ";class" { $$ = CYNew CYWord("class"); }
 700     | "const" { $$ = CYNew CYWord("const"); }
 701     | "continue" { $$ = CYNew CYWord("continue"); }
 702     | "debugger" { $$ = CYNew CYWord("debugger"); }
 703     | "default" { $$ = CYNew CYWord("default"); }
 704     | "delete" LexSetRegExp { $$ = CYNew CYWord("delete"); }
 705     | "do" { $$ = CYNew CYWord("do"); }
 706     | "else" { $$ = CYNew CYWord("else"); }
 707     | "enum" { $$ = CYNew CYWord("enum"); }
 708     | "export" { $$ = CYNew CYWord("export"); }
 709     | "extends" { $$ = CYNew CYWord("extends"); }
 710     | "false" { $$ = CYNew CYWord("false"); }
 711     | "finally" { $$ = CYNew CYWord("finally"); }
 712     | "function" { $$ = CYNew CYWord("function"); }
 713     | "if" { $$ = CYNew CYWord("if"); }
 714     | "import" { $$ = CYNew CYWord("import"); }
 715     | "!in" { $$ = CYNew CYWord("in"); }
 716     | "new" LexSetRegExp { $$ = CYNew CYWord("new"); }
 717     | "null" { $$ = CYNew CYWord("null"); }
 718     | "return" { $$ = CYNew CYWord("return"); }
 719     | "!return" { $$ = CYNew CYWord("return"); }
 720     | "super" { $$ = CYNew CYWord("super"); }
 721     | "switch" { $$ = CYNew CYWord("switch"); }
 722     | "this" { $$ = CYNew CYWord("this"); }
 723     | "throw" { $$ = CYNew CYWord("throw"); }
 724     | "true" { $$ = CYNew CYWord("true"); }
 725     | "try" { $$ = CYNew CYWord("try"); }
 726     | "typeof" LexSetRegExp { $$ = CYNew CYWord("typeof"); }
 727     | "var" { $$ = CYNew CYWord("var"); }
 728     | "void" LexSetRegExp { $$ = CYNew CYWord("void"); }
 729     | "while" { $$ = CYNew CYWord("while"); }
 730     | "with" { $$ = CYNew CYWord("with"); }
 731     | "yield" { $$ = CYNew CYIdentifier("yield"); }
 732
 733     | Yield LexSetRegExp NewLineOpt { $$ = CYNew CYIdentifier("yield"); }
 734
 735     // XXX: should be Identifier
 736     | "let" { $$ = CYNew CYIdentifier("let"); }
 737     ;
 738
 739 @begin ObjectiveC
 740 WordOpt
 741     : Word { $$ = $1; }
 742     | { $$ = NULL; }
 743     ;
 744 @end
 745 /* }}} */
 746 /* 11.8.1 Null Literals {{{ */
 747 NullLiteral
 748     : "null" { $$ = CYNew CYNull(); }
 749     ;
 750 /* }}} */
 751 /* 11.8.2 Boolean Literals {{{ */
 752 BooleanLiteral
 753     : "true" { $$ = CYNew CYTrue(); }
 754     | "false" { $$ = CYNew CYFalse(); }
 755     ;
 756 /* }}} */
 757
 758 /* 11.9 Automatic Semicolon Insertion {{{ */
 759 StrictSemi
 760     : { driver.Warning(@$, "warning, automatic semi-colon insertion required"); }
 761     ;
 762
 763 TerminatorSoft
 764     : ";"
 765     | "\n" StrictSemi
 766     ;
 767
 768 Terminator
 769     : ";"
 770     | error { if (yyla.type_get() != yyeof_ && yyla.type != yytranslate_(token::CloseBrace) && !driver.newline_) { CYERR(@1, "required semi-colon"); } else { yyerrok; driver.errors_.pop_back(); } } StrictSemi
 771     ;
 772
 773 TerminatorOpt
 774     : ";"
 775     | error { yyerrok; driver.errors_.pop_back(); } StrictSemi
 776     ;
 777 /* }}} */
 778
 779 /* 12.1 Identifiers {{{ */
 780 IdentifierReference
 781     : Identifier { $$ = CYNew CYVariable($1); }
 782     | "yield" { $$ = CYNew CYVariable(CYNew CYIdentifier("yield")); }
 783     ;
 784
 785 BindingIdentifier
 786     : Identifier { $$ = $1; }
 787     | "yield" { $$ = CYNew CYIdentifier("yield"); }
 788     ;
 789
 790 BindingIdentifierOpt
 791     : BindingIdentifier { $$ = $1; }
 792     | { $$ = NULL; }
 793     ;
 794
 795 LabelIdentifier
 796     : Identifier { $$ = $1; }
 797     | "yield" { $$ = CYNew CYIdentifier("yield"); }
 798     ;
 799
 800 IdentifierType
 801     : Identifier_ { $$ = $1; }
 802     | "abstract" { $$ = CYNew CYIdentifier("abstract"); }
 803     | "await" { $$ = CYNew CYIdentifier("await"); }
 804     | "boolean" { $$ = CYNew CYIdentifier("boolean"); }
 805     | "byte" { $$ = CYNew CYIdentifier("byte"); }
 806     | "double" { $$ = CYNew CYIdentifier("double"); }
 807     | "each" { $$ = CYNew CYIdentifier("each"); }
 808     | "final" { $$ = CYNew CYIdentifier("final"); }
 809     | "float" { $$ = CYNew CYIdentifier("float"); }
 810     | "goto" { $$ = CYNew CYIdentifier("goto"); }
 811     | "implements" { $$ = CYNew CYIdentifier("implements"); }
 812     | "interface" { $$ = CYNew CYIdentifier("interface"); }
 813     | "native" { $$ = CYNew CYIdentifier("native"); }
 814     | "of" { $$ = CYNew CYIdentifier("of"); }
 815     | "package" { $$ = CYNew CYIdentifier("package"); }
 816     | "private" { $$ = CYNew CYIdentifier("private"); }
 817     | "protected" { $$ = CYNew CYIdentifier("protected"); }
 818     | "public" { $$ = CYNew CYIdentifier("public"); }
 819     | "static" { $$ = CYNew CYIdentifier("static"); }
 820     | "synchronized" { $$ = CYNew CYIdentifier("synchronized"); }
 821     | "throws" { $$ = CYNew CYIdentifier("throws"); }
 822     | "transient" { $$ = CYNew CYIdentifier("transient"); }
 823 @begin ObjectiveC
 824     | "bool" { $$ = CYNew CYIdentifier("bool"); }
 825     | "BOOL" { $$ = CYNew CYIdentifier("BOOL"); }
 826     | "id" { $$ = CYNew CYIdentifier("id"); }
 827     | "SEL" { $$ = CYNew CYIdentifier("SEL"); }
 828 @end
 829     ;
 830
 831 Identifier
 832     : IdentifierType
 833     | "char" { $$ = CYNew CYIdentifier("char"); }
 834     | "from" { $$ = CYNew CYIdentifier("from"); }
 835     | "get" { $$ = CYNew CYIdentifier("get"); }
 836     | "int" { $$ = CYNew CYIdentifier("int"); }
 837     | "long" { $$ = CYNew CYIdentifier("long"); }
 838     | "set" { $$ = CYNew CYIdentifier("set"); }
 839     | "short" { $$ = CYNew CYIdentifier("short"); }
 840     | "undefined" { $$ = CYNew CYIdentifier("undefined"); }
 841     | "volatile" { $$ = CYNew CYIdentifier("volatile"); }
 842 @begin C
 843     | "extern" { $$ = CYNew CYIdentifier("extern"); }
 844     | "signed" { $$ = CYNew CYIdentifier("signed"); }
 845     | "typedef" { $$ = CYNew CYIdentifier("typedef"); }
 846     | "unsigned" { $$ = CYNew CYIdentifier("unsigned"); }
 847 @end
 848 @begin ObjectiveC
 849     | "nil" { $$ = CYNew CYIdentifier("nil"); }
 850     | "NO" { $$ = CYNew CYIdentifier("NO"); }
 851     | "NULL" { $$ = CYNew CYIdentifier("NULL"); }
 852     | "YES" { $$ = CYNew CYIdentifier("YES"); }
 853 @end
 854     ;
 855 /* }}} */
 856 /* 12.2 Primary Expression {{{ */
 857 PrimaryExpression
 858     : "this" { $$ = CYNew CYThis(); }
 859     | IdentifierReference { $$ = $1; }
 860     | Literal { $$ = $1; }
 861     | ArrayLiteral { $$ = $1; }
 862     | ObjectLiteral { $$ = $1; }
 863     | FunctionExpression { $$ = $1; }
 864     | ClassExpression { $$ = $1; }
 865     | GeneratorExpression { $$ = $1; }
 866     | RegularExpressionLiteral { $$ = $1; }
 867     | TemplateLiteral { $$ = $1; }
 868     | CoverParenthesizedExpressionAndArrowParameterList { if ($1 == NULL) CYERR(@1, "invalid parenthetical"); $$ = $1; }
 869     | AutoComplete { driver.mode_ = CYDriver::AutoPrimary; YYACCEPT; }
 870     ;
 871
 872 CoverParenthesizedExpressionAndArrowParameterList
 873     : "(" LexPushInOff Expression ")" LexPopIn { $$ = CYNew CYParenthetical($3); }
 874     | "(" LexPushInOff LexSetRegExp ")" LexPopIn { $$ = NULL; }
 875     | "(" LexPushInOff LexSetRegExp "..." BindingIdentifier ")" LexPopIn { CYNOT(@$); }
 876     | "(" LexPushInOff Expression "," LexSetRegExp "..." BindingIdentifier ")" LexPopIn { CYNOT(@$); }
 877     ;
 878 /* }}} */
 879 /* 12.2.4 Literals {{{ */
 880 Literal
 881     : NullLiteral { $$ = $1; }
 882     | BooleanLiteral { $$ = $1; }
 883     | NumericLiteral { $$ = $1; }
 884     | StringLiteral { $$ = $1; }
 885     ;
 886 /* }}} */
 887 /* 12.2.5 Array Initializer {{{ */
 888 ArrayLiteral
 889     : "[" LexPushInOff ElementListOpt "]" LexPopIn { $$ = CYNew CYArray($3); }
 890     ;
 891
 892 ElementList
 893     : AssignmentExpressionOpt "," ElementListOpt { $$ = CYNew CYElementValue($1, $3); }
 894     | LexSetRegExp "..." AssignmentExpression { $$ = CYNew CYElementSpread($3); }
 895     | AssignmentExpression { $$ = CYNew CYElementValue($1, NULL); }
 896     ;
 897
 898 ElementListOpt
 899     : ElementList { $$ = $1; }
 900     | LexSetRegExp { $$ = NULL; }
 901     ;
 902 /* }}} */
 903 /* 12.2.6 Object Initializer {{{ */
 904 ObjectLiteral
 905     : BRACE LexPushInOff PropertyDefinitionListOpt "}" LexPopIn { $$ = CYNew CYObject($3); }
 906     ;
 907
 908 PropertyDefinitionList_
 909     : "," PropertyDefinitionListOpt { $$ = $2; }
 910     | { $$ = NULL; }
 911     ;
 912
 913 PropertyDefinitionList
 914     : PropertyDefinition PropertyDefinitionList_ { $1->SetNext($2); $$ = $1; }
 915     ;
 916
 917 PropertyDefinitionListOpt
 918     : LexSetRegExp PropertyDefinitionList { $$ = $2; }
 919     | LexSetRegExp { $$ = NULL; }
 920     ;
 921
 922 PropertyDefinition
 923     : IdentifierReference { $$ = CYNew CYProperty($1->name_, $1); }
 924     | CoverInitializedName { CYNOT(@$); }
 925     | PropertyName ":" AssignmentExpression { $$ = CYNew CYProperty($1, $3); }
 926     | MethodDefinition { $$ = $1; }
 927     ;
 928
 929 PropertyName
 930     : LiteralPropertyName { $$ = $1; }
 931     | ComputedPropertyName { CYNOT(@$); /* $$ = $1; */ }
 932     ;
 933
 934 LiteralPropertyName
 935     : IdentifierName { $$ = $1; }
 936     | StringLiteral { $$ = $1; }
 937     | NumericLiteral { $$ = $1; }
 938     ;
 939
 940 ComputedPropertyName
 941     : "[" AssignmentExpression "]" { $$ = $2; }
 942     ;
 943
 944 CoverInitializedName
 945     : IdentifierReference Initializer
 946     ;
 947
 948 Initializer
 949     : "=" AssignmentExpression { $$ = $2; }
 950     ;
 951
 952 InitializerOpt
 953     : Initializer { $$ = $1; }
 954     | { $$ = NULL; }
 955     ;
 956 /* }}} */
 957 /* 12.2.9 Template Literals {{{ */
 958 TemplateLiteral
 959     : NoSubstitutionTemplate { $$ = CYNew CYTemplate($1, NULL); }
 960     | TemplateHead TemplateSpans { $$ = CYNew CYTemplate($1, $2); }
 961     ;
 962
 963 TemplateSpans
 964     : Expression TemplateMiddle TemplateSpans { $$ = CYNew CYSpan($1, $2, $3); }
 965     | Expression TemplateTail { $$ = CYNew CYSpan($1, $2, NULL); }
 966     ;
 967 /* }}} */
 968
 969 /* 12.3 Left-Hand-Side Expressions {{{ */
 970 MemberAccess
 971     : "[" LexPushInOff Expression "]" LexPopIn { $$ = CYNew CYDirectMember(NULL, $3); }
 972     | "." IdentifierName { $$ = CYNew CYDirectMember(NULL, CYNew CYString($2)); }
 973     | "." AutoComplete { driver.mode_ = CYDriver::AutoDirect; YYACCEPT; }
 974     | TemplateLiteral { CYNOT(@$); }
 975     ;
 976
 977 MemberExpression
 978     : LexSetRegExp PrimaryExpression { $$ = $2; }
 979     | MemberExpression { driver.context_ = $1; } MemberAccess { $3->SetLeft($1); $$ = $3; }
 980     | SuperProperty { CYNOT(@$); }
 981     | MetaProperty { CYNOT(@$); }
 982     | LexSetRegExp "new" MemberExpression Arguments { $$ = CYNew cy::Syntax::New($3, $4); }
 983     ;
 984
 985 SuperProperty
 986     : LexSetRegExp "super" "[" Expression "]"
 987     | LexSetRegExp "super" "." IdentifierName
 988     ;
 989
 990 MetaProperty
 991     : NewTarget
 992     ;
 993
 994 NewTarget
 995     : LexSetRegExp "new" LexSetRegExp "." "target"
 996     ;
 997
 998 NewExpression
 999     : MemberExpression { $$ = $1; }
1000     | LexSetRegExp "new" NewExpression { $$ = CYNew cy::Syntax::New($3, NULL); }
1001     ;
1002
1003 CallExpression_
1004     : MemberExpression
1005     | CallExpression
1006     ;
1007
1008 CallExpression
1009     : CallExpression_ Arguments { $$ = CYNew CYCall($1, $2); }
1010     | SuperCall { CYNOT(@$); }
1011     | CallExpression { driver.context_ = $1; } MemberAccess { $3->SetLeft($1); $$ = $3; }
1012     ;
1013
1014 SuperCall
1015     : LexSetRegExp "super" Arguments
1016     ;
1017
1018 Arguments
1019     : "(" LexPushInOff ArgumentListOpt ")" LexPopIn { $$ = $3; }
1020     ;
1021
1022 ArgumentList_
1023     : "," ArgumentList { $$ = $2; }
1024     | { $$ = NULL; }
1025     ;
1026
1027 ArgumentList
1028     : AssignmentExpression ArgumentList_ { $$ = CYNew CYArgument(NULL, $1, $2); }
1029     | LexSetRegExp "..." AssignmentExpression { CYNOT(@$); }
1030     ;
1031
1032 ArgumentListOpt
1033     : ArgumentList { $$ = $1; }
1034     | LexSetRegExp { $$ = NULL; }
1035     ;
1036
1037 LeftHandSideExpression
1038     : NewExpression { $$ = $1; }
1039     | CallExpression { $$ = $1; }
1040     ;
1041 /* }}} */
1042 /* 12.4 Postfix Expressions {{{ */
1043 PostfixExpression
1044     : %prec "" LeftHandSideExpression { $$ = $1; }
1045     | LeftHandSideExpression "++" { $$ = CYNew CYPostIncrement($1); }
1046     | LeftHandSideExpression "--" { $$ = CYNew CYPostDecrement($1); }
1047     ;
1048 /* }}} */
1049 /* 12.5 Unary Operators {{{ */
1050 UnaryExpression_
1051     : "delete" UnaryExpression { $$ = CYNew CYDelete($2); }
1052     | "void" UnaryExpression { $$ = CYNew CYVoid($2); }
1053     | "typeof" UnaryExpression { $$ = CYNew CYTypeOf($2); }
1054     | "++" UnaryExpression { $$ = CYNew CYPreIncrement($2); }
1055     | "\n++" UnaryExpression { $$ = CYNew CYPreIncrement($2); }
1056     | "--" UnaryExpression { $$ = CYNew CYPreDecrement($2); }
1057     | "\n--" UnaryExpression { $$ = CYNew CYPreDecrement($2); }
1058     | "+" UnaryExpression { $$ = CYNew CYAffirm($2); }
1059     | "-" UnaryExpression { $$ = CYNew CYNegate($2); }
1060     | "~" UnaryExpression { $$ = CYNew CYBitwiseNot($2); }
1061     | "!" UnaryExpression { $$ = CYNew CYLogicalNot($2); }
1062     ;
1063
1064 UnaryExpression
1065     : PostfixExpression { $$ = $1; }
1066     | LexSetRegExp UnaryExpression_ { $$ = $2; }
1067     ;
1068 /* }}} */
1069 /* 12.6 Multiplicative Operators {{{ */
1070 MultiplicativeExpression
1071     : UnaryExpression { $$ = $1; }
1072     | MultiplicativeExpression "*" UnaryExpression { $$ = CYNew CYMultiply($1, $3); }
1073     | MultiplicativeExpression "/" UnaryExpression { $$ = CYNew CYDivide($1, $3); }
1074     | MultiplicativeExpression "%" UnaryExpression { $$ = CYNew CYModulus($1, $3); }
1075     ;
1076 /* }}} */
1077 /* 12.7 Additive Operators {{{ */
1078 AdditiveExpression
1079     : MultiplicativeExpression { $$ = $1; }
1080     | AdditiveExpression "+" MultiplicativeExpression { $$ = CYNew CYAdd($1, $3); }
1081     | AdditiveExpression "-" MultiplicativeExpression { $$ = CYNew CYSubtract($1, $3); }
1082     ;
1083 /* }}} */
1084 /* 12.8 Bitwise Shift Operators {{{ */
1085 ShiftExpression
1086     : AdditiveExpression { $$ = $1; }
1087     | ShiftExpression "<<" AdditiveExpression { $$ = CYNew CYShiftLeft($1, $3); }
1088     | ShiftExpression ">>" AdditiveExpression { $$ = CYNew CYShiftRightSigned($1, $3); }
1089     | ShiftExpression ">>>" AdditiveExpression { $$ = CYNew CYShiftRightUnsigned($1, $3); }
1090     ;
1091 /* }}} */
1092 /* 12.9 Relational Operators {{{ */
1093 RelationalExpression
1094     : ShiftExpression { $$ = $1; }
1095     | RelationalExpression "<" ShiftExpression { $$ = CYNew CYLess($1, $3); }
1096     | RelationalExpression ">" ShiftExpression { $$ = CYNew CYGreater($1, $3); }
1097     | RelationalExpression "<=" ShiftExpression { $$ = CYNew CYLessOrEqual($1, $3); }
1098     | RelationalExpression ">=" ShiftExpression { $$ = CYNew CYGreaterOrEqual($1, $3); }
1099     | RelationalExpression "instanceof" ShiftExpression { $$ = CYNew CYInstanceOf($1, $3); }
1100     | RelationalExpression "in" ShiftExpression { $$ = CYNew CYIn($1, $3); }
1101     ;
1102 /* }}} */
1103 /* 12.10 Equality Operators {{{ */
1104 EqualityExpression
1105     : RelationalExpression { $$ = $1; }
1106     | EqualityExpression "==" RelationalExpression { $$ = CYNew CYEqual($1, $3); }
1107     | EqualityExpression "!=" RelationalExpression { $$ = CYNew CYNotEqual($1, $3); }
1108     | EqualityExpression "===" RelationalExpression { $$ = CYNew CYIdentical($1, $3); }
1109     | EqualityExpression "!==" RelationalExpression { $$ = CYNew CYNotIdentical($1, $3); }
1110     ;
1111 /* }}} */
1112 /* 12.11 Binary Bitwise Operators {{{ */
1113 BitwiseANDExpression
1114     : EqualityExpression { $$ = $1; }
1115     | BitwiseANDExpression "&" EqualityExpression { $$ = CYNew CYBitwiseAnd($1, $3); }
1116     ;
1117
1118 BitwiseXORExpression
1119     : BitwiseANDExpression { $$ = $1; }
1120     | BitwiseXORExpression "^" BitwiseANDExpression { $$ = CYNew CYBitwiseXOr($1, $3); }
1121     ;
1122
1123 BitwiseORExpression
1124     : BitwiseXORExpression { $$ = $1; }
1125     | BitwiseORExpression "|" BitwiseXORExpression { $$ = CYNew CYBitwiseOr($1, $3); }
1126     ;
1127 /* }}} */
1128 /* 12.12 Binary Logical Operators {{{ */
1129 LogicalANDExpression
1130     : BitwiseORExpression { $$ = $1; }
1131     | LogicalANDExpression "&&" BitwiseORExpression { $$ = CYNew CYLogicalAnd($1, $3); }
1132     ;
1133
1134 LogicalORExpression
1135     : LogicalANDExpression { $$ = $1; }
1136     | LogicalORExpression "||" LogicalANDExpression { $$ = CYNew CYLogicalOr($1, $3); }
1137     ;
1138 /* }}} */
1139 /* 12.13 Conditional Operator ( ? : ) {{{ */
1140 ConditionalExpression
1141     : LogicalORExpression { $$ = $1; }
1142     | LogicalORExpression "?" LexPushInOff AssignmentExpression ":" LexPopIn AssignmentExpression { $$ = CYNew CYCondition($1, $4, $7); }
1143     ;
1144 /* }}} */
1145 /* 12.14 Assignment Operators {{{ */
1146 AssignmentExpression
1147     : ConditionalExpression { $$ = $1; }
1148     | LexSetRegExp YieldExpression { $$ = $2; }
1149     | ArrowFunction { $$ = $1; }
1150     | LeftHandSideExpression "=" AssignmentExpression { $$ = CYNew CYAssign($1, $3); }
1151     | LeftHandSideExpression "*=" AssignmentExpression { $$ = CYNew CYMultiplyAssign($1, $3); }
1152     | LeftHandSideExpression "/=" AssignmentExpression { $$ = CYNew CYDivideAssign($1, $3); }
1153     | LeftHandSideExpression "%=" AssignmentExpression { $$ = CYNew CYModulusAssign($1, $3); }
1154     | LeftHandSideExpression "+=" AssignmentExpression { $$ = CYNew CYAddAssign($1, $3); }
1155     | LeftHandSideExpression "-=" AssignmentExpression { $$ = CYNew CYSubtractAssign($1, $3); }
1156     | LeftHandSideExpression "<<=" AssignmentExpression { $$ = CYNew CYShiftLeftAssign($1, $3); }
1157     | LeftHandSideExpression ">>=" AssignmentExpression { $$ = CYNew CYShiftRightSignedAssign($1, $3); }
1158     | LeftHandSideExpression ">>>=" AssignmentExpression { $$ = CYNew CYShiftRightUnsignedAssign($1, $3); }
1159     | LeftHandSideExpression "&=" AssignmentExpression { $$ = CYNew CYBitwiseAndAssign($1, $3); }
1160     | LeftHandSideExpression "^=" AssignmentExpression { $$ = CYNew CYBitwiseXOrAssign($1, $3); }
1161     | LeftHandSideExpression "|=" AssignmentExpression { $$ = CYNew CYBitwiseOrAssign($1, $3); }
1162     ;
1163
1164 AssignmentExpressionOpt
1165     : AssignmentExpression { $$ = $1; }
1166     | LexSetRegExp { $$ = NULL; }
1167     ;
1168 /* }}} */
1169 /* 12.15 Comma Operator ( , ) {{{ */
1170 Expression
1171     : AssignmentExpression { $$ = $1; }
1172     | Expression "," AssignmentExpression { $$ = CYNew CYCompound($1, $3); }
1173     ;
1174
1175 ExpressionOpt
1176     : Expression { $$ = $1; }
1177     | LexSetRegExp { $$ = NULL; }
1178     ;
1179 /* }}} */
1180
1181 /* 13 Statements and Declarations {{{ */
1182 Statement__
1183     : BlockStatement { $$ = $1; }
1184     | VariableStatement { $$ = $1; }
1185     | EmptyStatement { $$ = $1; }
1186     | IfStatement { $$ = $1; }
1187     | BreakableStatement { $$ = $1; }
1188     | ContinueStatement { $$ = $1; }
1189     | BreakStatement { $$ = $1; }
1190     | ReturnStatement { $$ = $1; }
1191     | WithStatement { $$ = $1; }
1192     | LabelledStatement { $$ = $1; }
1193     | ThrowStatement { $$ = $1; }
1194     | TryStatement { $$ = $1; }
1195     | DebuggerStatement { $$ = $1; }
1196     ;
1197
1198 Statement_
1199     : LexSetRegExp Statement__ { $$ = $2; }
1200     | ExpressionStatement { $$ = $1; }
1201     ;
1202
1203 Statement
1204     : LexSetStatement Statement_ { $$ = $2; }
1205     ;
1206
1207 Declaration__
1208     : HoistableDeclaration { $$ = $1; }
1209     | ClassDeclaration { $$ = $1; }
1210     | LexicalDeclaration { $$ = $1; }
1211     ;
1212
1213 Declaration_
1214     : LexSetRegExp Declaration__ { $$ = $2; }
1215     ;
1216
1217 Declaration
1218     : LexSetStatement Declaration_ { $$ = $2; }
1219     ;
1220
1221 HoistableDeclaration
1222     : FunctionDeclaration { $$ = $1; }
1223     | GeneratorDeclaration { $$ = $1; }
1224     ;
1225
1226 BreakableStatement
1227     : IterationStatement { $$ = $1; }
1228     | SwitchStatement { $$ = $1; }
1229     ;
1230 /* }}} */
1231 /* 13.2 Block {{{ */
1232 BlockStatement
1233     : ";{" StatementListOpt "}" { $$ = CYNew CYBlock($2); }
1234     ;
1235
1236 Block
1237     : BRACE StatementListOpt "}" { $$ = $2; }
1238     ;
1239
1240 StatementList
1241     : StatementListItem StatementListOpt { $1->SetNext($2); $$ = $1; }
1242     ;
1243
1244 StatementListOpt
1245     : StatementList { $$ = $1; }
1246     | LexSetStatement LexSetRegExp { $$ = NULL; }
1247     ;
1248
1249 StatementListItem
1250     : Statement { $$ = $1; }
1251     | Declaration { $$ = $1; }
1252     ;
1253 /* }}} */
1254 /* 13.3 Let and Const Declarations {{{ */
1255 LexicalDeclaration
1256     : LetOrConst BindingList Terminator { $$ = CYNew CYVar($2); }
1257     ;
1258
1259 LetOrConst
1260     : "let"
1261     | "const"
1262     ;
1263
1264 BindingList_
1265     : "," BindingList { $$ = $2; }
1266     | { $$ = NULL; }
1267     ;
1268
1269 BindingList
1270     : LexicalBinding BindingList_ { $$ = CYNew CYDeclarations($1, $2); }
1271     ;
1272
1273 LexicalBinding
1274     : BindingIdentifier InitializerOpt { $$ = CYNew CYDeclaration($1, $2); }
1275     | BindingPattern Initializer { CYNOT(@1); }
1276     ;
1277 /* }}} */
1278 /* 13.3.2 Variable Statement {{{ */
1279 VariableStatement
1280     : Var_ VariableDeclarationList Terminator { $$ = CYNew CYVar($2); }
1281     ;
1282
1283 VariableDeclarationList_
1284     : "," VariableDeclarationList { $$ = $2; }
1285     | { $$ = NULL; }
1286     ;
1287
1288 VariableDeclarationList
1289     : VariableDeclaration VariableDeclarationList_ { $$ = CYNew CYDeclarations($1, $2); }
1290     ;
1291
1292 VariableDeclaration
1293     : BindingIdentifier InitializerOpt { $$ = CYNew CYDeclaration($1, $2); }
1294     | BindingPattern Initializer { CYNOT(@1); }
1295     ;
1296 /* }}} */
1297 /* 13.3.3 Destructuring Binding Patterns {{{ */
1298 BindingPattern
1299     : ObjectBindingPattern
1300     | ArrayBindingPattern
1301     ;
1302
1303 ObjectBindingPattern
1304     : BRACE BindingPropertyListOpt "}"
1305     ;
1306
1307 ArrayBindingPattern
1308     : "[" { CYNOT(@$); }
1309     ;
1310
1311 BindingPropertyList_
1312     : "," BindingPropertyListOpt
1313     |
1314     ;
1315
1316 BindingPropertyList
1317     : BindingProperty BindingPropertyList_
1318     ;
1319
1320 BindingPropertyListOpt
1321     : BindingPropertyList
1322     |
1323     ;
1324
1325 BindingProperty
1326     : SingleNameBinding
1327     | PropertyName ":" BindingElement
1328     ;
1329
1330 BindingElement
1331     : SingleNameBinding { $$ = $1; }
1332     | BindingPattern InitializerOpt { CYNOT(@$); }
1333     ;
1334
1335 SingleNameBinding
1336     : BindingIdentifier InitializerOpt { $$ = CYNew CYDeclaration($1, $2); }
1337     ;
1338
1339 BindingRestElement
1340     : "..." BindingIdentifier
1341     ;
1342 /* }}} */
1343 /* 13.4 Empty Statement {{{ */
1344 EmptyStatement
1345     : ";" { $$ = CYNew CYEmpty(); }
1346     ;
1347 /* }}} */
1348 /* 13.5 Expression Statement {{{ */
1349 ExpressionStatement
1350     : Expression Terminator { $$ = CYNew CYExpress($1); }
1351     ;
1352 /* }}} */
1353 /* 13.6 The if Statement {{{ */
1354 ElseStatementOpt
1355     : "else" Statement { $$ = $2; }
1356     | %prec "if" { $$ = NULL; }
1357     ;
1358
1359 IfStatement
1360     : "if" "(" Expression ")" Statement ElseStatementOpt { $$ = CYNew CYIf($3, $5, $6); }
1361     ;
1362 /* }}} */
1363 /* 13.7 Iteration Statements {{{ */
1364 IterationStatement
1365     : "do" Statement "while" "(" Expression ")" TerminatorOpt { $$ = CYNew CYDoWhile($5, $2); }
1366     | "while" "(" Expression ")" Statement { $$ = CYNew CYWhile($3, $5); }
1367     | "for" "(" LexPushInOn ForStatementInitializer ";" LexPopIn ExpressionOpt ";" ExpressionOpt ")" Statement { $$ = CYNew CYFor($4, $7, $9, $11); }
1368     | "for" "(" LexPushInOn ForInStatementInitializer "!in" LexPopIn Expression ")" Statement { $$ = CYNew CYForIn($4, $7, $9); }
1369     | "for" "(" LexPushInOn ForInStatementInitializer "of" LexPopIn Expression ")" Statement { $$ = CYNew CYForOf($4, $7, $9); }
1370     ;
1371
1372 ForStatementInitializer
1373     : ExpressionOpt { $$ = $1; }
1374     | LexSetRegExp Var_ VariableDeclarationList { $$ = CYNew CYForDeclarations($3); }
1375     | LexSetRegExp LexicalDeclaration { CYNOT(@$); }
1376     ;
1377
1378 ForInStatementInitializer
1379     : LeftHandSideExpression { $$ = $1; }
1380     | LexSetRegExp Var_ ForBinding { $$ = $3; }
1381     | LexSetRegExp ForDeclaration { $$ = $2; }
1382     ;
1383
1384 ForDeclaration
1385     : LetOrConst ForBinding { $$ = $2; }
1386     ;
1387
1388 ForBinding
1389     : BindingIdentifier { $$ = CYNew CYDeclaration($1, NULL); }
1390     | BindingPattern { CYNOT(@1); }
1391     ;
1392 /* }}} */
1393 /* 13.8 The continue Statement {{{ */
1394 Continue
1395     : "continue" LexNewLine
1396     ;
1397
1398 ContinueStatement
1399     : Continue TerminatorSoft { $$ = CYNew CYContinue(NULL); }
1400     | Continue Identifier Terminator { $$ = CYNew CYContinue($2); }
1401     ;
1402 /* }}} */
1403 /* 13.9 The break Statement {{{ */
1404 Break
1405     : "break" LexNewLine
1406     ;
1407
1408 BreakStatement
1409     : Break TerminatorSoft { $$ = CYNew CYBreak(NULL); }
1410     | Break Identifier Terminator { $$ = CYNew CYBreak($2); }
1411     ;
1412 /* }}} */
1413 /* 13.10 The return Statement {{{ */
1414 Return
1415     : "!return" LexNewLine
1416     ;
1417
1418 ReturnStatement
1419     : Return LexSetRegExp TerminatorSoft { $$ = CYNew CYReturn(NULL); }
1420     | Return Expression Terminator { $$ = CYNew CYReturn($2); }
1421     ;
1422 /* }}} */
1423 /* 13.11 The with Statement {{{ */
1424 WithStatement
1425     : "with" "(" Expression ")" Statement { $$ = CYNew CYWith($3, $5); }
1426     ;
1427 /* }}} */
1428 /* 13.12 The switch Statement {{{ */
1429 SwitchStatement
1430     : "switch" "(" Expression ")" CaseBlock { $$ = CYNew CYSwitch($3, $5); }
1431     ;
1432
1433 CaseBlock
1434     : BRACE CaseClausesOpt "}" { $$ = $2; }
1435     ;
1436
1437 CaseClause
1438     : "case" Expression ":" StatementListOpt { $$ = CYNew CYClause($2, $4); }
1439     ;
1440
1441 CaseClausesOpt
1442     : CaseClause CaseClausesOpt { $1->SetNext($2); $$ = $1; }
1443     | DefaultClause CaseClausesOpt { $1->SetNext($2); $$ = $1; }
1444     | { $$ = NULL; }
1445     ;
1446
1447 // XXX: the standard makes certain you can only have one of these
1448 DefaultClause
1449     : "default" ":" StatementListOpt { $$ = CYNew CYClause(NULL, $3); }
1450     ;
1451 /* }}} */
1452 /* 13.13 Labelled Statements {{{ */
1453 LabelledStatement
1454     : LabelIdentifier ":" LabelledItem { $$ = CYNew CYLabel($1, $3); }
1455     ;
1456
1457 LabelledItem
1458     : Statement { $$ = $1; }
1459     | LexSetStatement LexSetRegExp FunctionDeclaration { $$ = $3; }
1460     ;
1461 /* }}} */
1462 /* 13.14 The throw Statement {{{ */
1463 Throw
1464     : "throw" LexNewLine
1465     ;
1466
1467 ThrowStatement
1468     : Throw LexSetRegExp TerminatorSoft { CYERR(@1, "throw without exception"); }
1469     | Throw Expression Terminator { $$ = CYNew cy::Syntax::Throw($2); }
1470     ;
1471 /* }}} */
1472 /* 13.15 The try Statement {{{ */
1473 TryStatement
1474     : "try" Block Catch { $$ = CYNew cy::Syntax::Try($2, $3, NULL); }
1475     | "try" Block Finally { $$ = CYNew cy::Syntax::Try($2, NULL, $3); }
1476     | "try" Block Catch Finally { $$ = CYNew cy::Syntax::Try($2, $3, $4); }
1477     ;
1478
1479 Catch
1480     : "catch" "(" CatchParameter ")" Block { $$ = CYNew cy::Syntax::Catch($3, $5); }
1481     ;
1482
1483 Finally
1484     : "finally" Block { $$ = CYNew CYFinally($2); }
1485     ;
1486
1487 CatchParameter
1488     : BindingIdentifier { $$ = $1; }
1489     | BindingPattern { CYNOT(@$); }
1490     ;
1491 /* }}} */
1492 /* 13.16 The debugger Statement {{{ */
1493 DebuggerStatement
1494     : "debugger" Terminator { $$ = CYNew CYDebugger(); }
1495     ;
1496 /* }}} */
1497
1498 /* 14.1 Function Definitions {{{ */
1499 FunctionDeclaration
1500     : ";function" BindingIdentifier "(" FormalParameters ")" BRACE FunctionBody "}" { $$ = CYNew CYFunctionStatement($2, $4, $7); }
1501     ;
1502
1503 FunctionExpression
1504     : "function" BindingIdentifierOpt "(" LexPushInOff FormalParameters ")" LexPopIn BRACE LexPushInOff FunctionBody "}" LexPopIn { $$ = CYNew CYFunctionExpression($2, $5, $10); }
1505     ;
1506
1507 StrictFormalParameters
1508     : FormalParameters { $$ = $1; }
1509     ;
1510
1511 FormalParameters
1512     : { $$ = NULL; }
1513     | FormalParameterList
1514     ;
1515
1516 FormalParameterList_
1517     : "," FormalParameterList { $$ = $2; }
1518     | { $$ = NULL; }
1519     ;
1520
1521 FormalParameterList
1522     : FunctionRestParameter { CYNOT(@$); }
1523     | FormalParameter FormalParameterList_ { $$ = CYNew CYFunctionParameter($1, $2); }
1524     ;
1525
1526 FunctionRestParameter
1527     : BindingRestElement
1528     ;
1529
1530 FormalParameter
1531     : BindingElement { $$ = $1; }
1532     ;
1533
1534 FunctionBody
1535     : LexPushYieldOff FunctionStatementList LexPopYield { $$ = $2; }
1536     ;
1537
1538 FunctionStatementList
1539     : LexPushReturnOn StatementListOpt LexPopReturn { $$ = $2; }
1540     ;
1541 /* }}} */
1542 /* 14.2 Arrow Function Definitions {{{ */
1543 ArrowFunction
1544     : LexSetRegExp ArrowParameters "=>" LexNoBrace ConciseBody { $$ = CYNew CYFatArrow($2, $5); }
1545     ;
1546
1547 ArrowParameters
1548     : BindingIdentifier { $$ = CYNew CYFunctionParameter(CYNew CYDeclaration($1)); }
1549     | CoverParenthesizedExpressionAndArrowParameterList { if ($1 == NULL) $$ = NULL; else { $$ = $1->expression_->Parameter(); if ($$ == NULL) CYERR(@1, "invalid parameter list"); } }
1550     ;
1551
1552 ConciseBody
1553     : AssignmentExpression { $$ = CYNew CYReturn($1); }
1554     | LexSetRegExp ";{" LexPushInOff FunctionBody "}" LexPopIn { $$ = $4; }
1555     ;
1556 /* }}} */
1557 /* 14.3 Method Definitions {{{ */
1558 MethodDefinition
1559     : PropertyName "(" StrictFormalParameters ")" BRACE FunctionBody "}" { CYNOT(@$); /* $$ = CYNew CYFunctionMethod($1, $3, $6); */ }
1560     | GeneratorMethod { $$ = $1; }
1561     | "get" PropertyName "(" ")" BRACE FunctionBody "}" { CYNOT(@$); /* $$ = CYNew CYMethodGet($2, $6); */ }
1562     | "set" PropertyName "(" PropertySetParameterList ")" BRACE FunctionBody "}" { CYNOT(@$); /* $$ = CYNew CYMethodSet($2, $4); */ }
1563     ;
1564
1565 PropertySetParameterList
1566     : FormalParameter { $$ = $1; }
1567     ;
1568 /* }}} */
1569 /* 14.4 Generator Function Definitions {{{ */
1570 GeneratorMethod
1571     : "*" PropertyName "(" StrictFormalParameters ")" BRACE GeneratorBody "}" { CYNOT(@$); /* $$ = CYNew CYGeneratorMethod($2, $4, $7); */ }
1572     ;
1573
1574 GeneratorDeclaration
1575     : ";function" "*" BindingIdentifier "(" FormalParameters ")" BRACE GeneratorBody "}" { CYNOT(@$); /* $$ = CYNew CYGeneratorStatement($3, $5, $8); */ }
1576     ;
1577
1578 GeneratorExpression
1579     : "function" "*" BindingIdentifierOpt "(" FormalParameters ")" BRACE GeneratorBody "}" { CYNOT(@$); /* $$ = CYNew CYGeneratorExpression($3, $5, $8); */ }
1580     ;
1581
1582 GeneratorBody
1583     : LexPushYieldOn FunctionStatementList LexPopYield { $$ = $2; }
1584     ;
1585
1586 Yield
1587     : "!yield" LexNewLine LexNoStar
1588     ;
1589
1590 YieldExpression
1591     : Yield LexSetRegExp "\n" { CYNOT(@$); /* $$ = CYNew CYYieldValue(NULL); */ }
1592     | Yield AssignmentExpression { CYNOT(@$); /* $$ = CYNew CYYieldValue($2); */ }
1593     | Yield LexSetRegExp YieldStar AssignmentExpression { CYNOT(@$); /* $$ = CYNew CYYieldGenerator($4); */ }
1594     ;
1595 /* }}} */
1596 /* 14.5 Class Definitions {{{ */
1597 ClassDeclaration
1598     : ";class" BindingIdentifier ClassTail { CYNOT(@$); }
1599     ;
1600
1601 ClassExpression
1602     : "class" BindingIdentifierOpt ClassTail { CYNOT(@$); }
1603     ;
1604
1605 ClassTail
1606     : ClassHeritageOpt BRACE ClassBodyOpt "}"
1607     ;
1608
1609 ClassHeritage
1610     : "extends" LeftHandSideExpression
1611     ;
1612
1613 ClassHeritageOpt
1614     : ClassHeritage
1615     |
1616     ;
1617
1618 ClassBody
1619     : ClassElementList
1620     ;
1621
1622 ClassBodyOpt
1623     : ClassBody
1624     |
1625     ;
1626
1627 ClassElementList
1628     : ClassElementListOpt ClassElement
1629     ;
1630
1631 ClassElementListOpt
1632     : ClassElementList
1633     |
1634     ;
1635
1636 ClassElement
1637     : MethodDefinition
1638     | "static" MethodDefinition
1639     | ";"
1640     ;
1641 /* }}} */
1642
1643 /* 15.1 Scripts {{{ */
1644 Script
1645     : ScriptBodyOpt { driver.script_ = CYNew CYScript($1); }
1646     ;
1647
1648 ScriptBody
1649     : StatementList { $$ = $1; }
1650     ;
1651
1652 ScriptBodyOpt
1653     : ScriptBody { $$ = $1; }
1654     | LexSetStatement LexSetRegExp { $$ = NULL; }
1655     ;
1656 /* }}} */
1657 /* 15.2 Modules {{{ */
1658 Module
1659     : ModuleBodyOpt
1660     ;
1661
1662 ModuleBody
1663     : ModuleItemList
1664     ;
1665
1666 ModuleBodyOpt
1667     : ModuleBody
1668     |
1669     ;
1670
1671 ModuleItemList
1672     : ModuleItemListOpt ModuleItem
1673     ;
1674
1675 ModuleItemListOpt
1676     : ModuleItemList
1677     |
1678     ;
1679
1680 ModuleItem
1681     : LexSetStatement LexSetRegExp ImportDeclaration
1682     | LexSetStatement LexSetRegExp ExportDeclaration
1683     | StatementListItem
1684     ;
1685 /* }}} */
1686 /* 15.2.2 Imports {{{ */
1687 ImportDeclaration
1688     : "import" ImportClause FromClause Terminator
1689     | "import" ModuleSpecifier Terminator
1690     ;
1691
1692 ImportClause
1693     : ImportedDefaultBinding
1694     | NameSpaceImport
1695     | NamedImports
1696     | ImportedDefaultBinding "," NameSpaceImport
1697     | ImportedDefaultBinding "," NamedImports
1698     ;
1699
1700 ImportedDefaultBinding
1701     : ImportedBinding
1702     ;
1703
1704 NameSpaceImport
1705     : "*" "as" ImportedBinding
1706     ;
1707
1708 NamedImports
1709     : BRACE ImportsListOpt "}"
1710     ;
1711
1712 FromClause
1713     : "from" ModuleSpecifier
1714     ;
1715
1716 ImportsList_
1717     : "," ImportsListOpt
1718     |
1719     ;
1720
1721 ImportsList
1722     : ImportSpecifier ImportsList_
1723     ;
1724
1725 ImportsListOpt
1726     : ImportsList
1727     |
1728     ;
1729
1730 ImportSpecifier
1731     : ImportedBinding
1732     | IdentifierName "as" ImportedBinding
1733     ;
1734
1735 ModuleSpecifier
1736     : StringLiteral
1737     ;
1738
1739 ImportedBinding
1740     : BindingIdentifier
1741     ;
1742 /* }}} */
1743 /* 15.2.3 Exports {{{ */
1744 ExportDeclaration_
1745     : "*" FromClause Terminator
1746     | ExportClause FromClause Terminator
1747     | ExportClause Terminator
1748     | VariableStatement
1749     | "default" LexSetStatement LexSetRegExp HoistableDeclaration
1750     | "default" LexSetStatement LexSetRegExp ClassDeclaration
1751     | "default" LexSetStatement AssignmentExpression Terminator
1752     ;
1753
1754 ExportDeclaration
1755     : "export" LexSetStatement LexSetRegExp ExportDeclaration_
1756     | "export" Declaration
1757     ;
1758
1759 ExportClause
1760     : ";{" ExportsListOpt "}"
1761     ;
1762
1763 ExportsList_
1764     : "," ExportsListOpt
1765     |
1766     ;
1767
1768 ExportsList
1769     : ExportSpecifier ExportsList_
1770     ;
1771
1772 ExportsListOpt
1773     : ExportsList
1774     |
1775     ;
1776
1777 ExportSpecifier
1778     : IdentifierName
1779     | IdentifierName "as" IdentifierName
1780     ;
1781 /* }}} */
1782
1783 @begin C
1784 /* Cycript (C): Type Encoding {{{ */
1785 TypeSignifier
1786     : IdentifierType { $$ = CYNew CYTypedIdentifier(@1, $1); }
1787     | "(" LexPushInOff "*" TypeQualifierRight ")" LexPopIn { $$ = $4; }
1788     ;
1789
1790 SuffixedType
1791     : SuffixedType "[" NumericLiteral "]" { $$ = $1; $$->modifier_ = CYNew CYTypeArrayOf($3, $$->modifier_); }
1792     | "(" LexPushInOff "^" TypeQualifierRight ")" LexPopIn "(" LexPushInOff TypedParameterListOpt ")" LexPopIn { $$ = $4; $$->modifier_ = CYNew CYTypeBlockWith($9, $$->modifier_); }
1793     | TypeSignifier "(" LexPushInOff TypedParameterListOpt ")" LexPopIn { $$ = $1; $$->modifier_ = CYNew CYTypeFunctionWith($4, $$->modifier_); }
1794     | "(" LexPushInOff TypedParameterListOpt ")" LexPopIn { $$ = CYNew CYTypedIdentifier(@1); $$->modifier_ = CYNew CYTypeFunctionWith($3, $$->modifier_); }
1795     | TypeSignifier { $$ = $1; }
1796     | { $$ = CYNew CYTypedIdentifier(@$); }
1797     ;
1798
1799 PrefixedType
1800     : "*" TypeQualifierRight { $$ = $2; $$->modifier_ = CYNew CYTypePointerTo($$->modifier_); }
1801     ;
1802
1803 TypeQualifierLeft
1804     : { $$ = NULL; }
1805     | "const" TypeQualifierLeft { $$ = $2; CYSetLast($$) = CYNew CYTypeConstant(); }
1806     | "volatile" TypeQualifierLeft { $$ = $2; CYSetLast($$) = CYNew CYTypeVolatile(); }
1807     ;
1808
1809 TypeQualifierRight
1810     : PrefixedType { $$ = $1; }
1811     | SuffixedType { $$ = $1; }
1812     | "const" TypeQualifierRight { $$ = $2; $$->modifier_ = CYNew CYTypeConstant($$->modifier_); }
1813     | "volatile" TypeQualifierRight { $$ = $2; $$->modifier_ = CYNew CYTypeVolatile($$->modifier_); }
1814     ;
1815
1816 IntegerType
1817     : "int" { $$ = CYNew CYTypeVariable("int"); }
1818     | "unsigned" IntegerTypeOpt { $$ = CYNew CYTypeUnsigned($2); }
1819     | "signed" IntegerTypeOpt { $$ = CYNew CYTypeSigned($2); }
1820     | "long" IntegerTypeOpt { $$ = CYNew CYTypeLong($2); }
1821     | "short" IntegerTypeOpt { $$ = CYNew CYTypeShort($2); }
1822     ;
1823
1824 IntegerTypeOpt
1825     : IntegerType { $$ = $1; }
1826     | { $$ = CYNew CYTypeVariable("int"); }
1827     ;
1828
1829 PrimitiveType
1830     : IdentifierType { $$ = CYNew CYTypeVariable($1); }
1831     | IntegerType { $$ = $1; }
1832     | "void" { $$ = CYNew CYTypeVoid(); }
1833     | "char" { $$ = CYNew CYTypeVariable("char"); }
1834     | "signed" "char" { $$ = CYNew CYTypeSigned(CYNew CYTypeVariable("char")); }
1835     | "unsigned" "char" { $$ = CYNew CYTypeUnsigned(CYNew CYTypeVariable("char")); }
1836     ;
1837
1838 TypedIdentifier
1839     : TypeQualifierLeft PrimitiveType TypeQualifierRight { $$ = $3; $$->specifier_ = $2; CYSetLast($1) = $$->modifier_; $$->modifier_ = $1; }
1840     ;
1841
1842 PrimaryExpression
1843     : "@encode" "(" TypedIdentifier ")" { $$ = CYNew CYEncodedType($3); }
1844     ;
1845 /* }}} */
1846 @end
1847
1848 @begin ObjectiveC
1849 /* Cycript (Objective-C): @class Declaration {{{ */
1850 ClassSuperOpt
1851     /* XXX: why the hell did I choose MemberExpression? */
1852     : ":" LexSetRegExp MemberExpression { $$ = $3; }
1853     | { $$ = NULL; }
1854     ;
1855
1856 ClassFieldListOpt
1857     : TypedIdentifier ";" ClassFieldListOpt { $$ = CYNew CYClassField($1, $3); }
1858     | LexSetRegExp { $$ = NULL; }
1859     ;
1860
1861 ClassFields
1862     : BRACE ClassFieldListOpt "}" { $$ = $2; }
1863     ;
1864
1865 MessageScope
1866     : "+" { $$ = false; }
1867     | "-" { $$ = true; }
1868     ;
1869
1870 TypeOpt
1871     : "(" LexSetRegExp TypedIdentifier ")" { if ($3->identifier_ != NULL) CYERR($3->location_, "unexpected identifier"); $$ = $3; }
1872     | { $$ = CYNew CYTypedIdentifier(CYNew CYTypeVariable("id")); }
1873     ;
1874
1875 MessageParameter
1876     : Word ":" TypeOpt Identifier { $3->identifier_ = $4; $$ = CYNew CYMessageParameter($1, $3); }
1877     ;
1878
1879 MessageParameterList
1880     : MessageParameter MessageParameterListOpt { $1->SetNext($2); $$ = $1; }
1881     ;
1882
1883 MessageParameterListOpt
1884     : MessageParameterList { $$ = $1; }
1885     | { $$ = NULL; }
1886     ;
1887
1888 MessageParameters
1889     : MessageParameterList { $$ = $1; }
1890     | Word { $$ = CYNew CYMessageParameter($1, NULL); }
1891     ;
1892
1893 ClassMessageDeclaration
1894     : MessageScope TypeOpt MessageParameters BRACE FunctionBody "}" { $$ = CYNew CYMessage($1, $2, $3, $5); }
1895     ;
1896
1897 ClassMessageDeclarationListOpt
1898     : ClassMessageDeclarationListOpt ClassMessageDeclaration { $2->SetNext($1); $$ = $2; }
1899     | { $$ = NULL; }
1900     ;
1901
1902 ClassName
1903     : Identifier { $$ = $1; }
1904     | "(" AssignmentExpression ")" { $$ = $2; }
1905     ;
1906
1907 // XXX: this should be AssignmentExpressionNoRight
1908 ClassProtocols
1909     : ShiftExpression ClassProtocolsOpt { $$ = CYNew CYProtocol($1, $2); }
1910     ;
1911
1912 ClassProtocolsOpt
1913     : "," ClassProtocols { $$ = $2; }
1914     | { $$ = NULL; }
1915     ;
1916
1917 ClassProtocolListOpt
1918     : "<" ClassProtocols ">" { $$ = $2; }
1919     | { $$ = NULL; }
1920     ;
1921
1922 ClassStatement
1923     : "@implementation" ClassName ClassSuperOpt ClassProtocolListOpt ClassFields ClassMessageDeclarationListOpt "@end" { $$ = CYNew CYClassStatement($2, $3, $4, $5, $6); }
1924     ;
1925
1926 CategoryName
1927     : "(" WordOpt ")"
1928     ;
1929
1930 CategoryStatement
1931     : "@implementation" ClassName CategoryName ClassMessageDeclarationListOpt "@end" { $$ = CYNew CYCategory($2, $4); }
1932     ;
1933
1934 Statement__
1935     : ClassStatement { $$ = $1; }
1936     | CategoryStatement { $$ = $1; }
1937     ;
1938 /* }}} */
1939 /* Cycript (Objective-C): Send Message {{{ */
1940 VariadicCall
1941     : "," AssignmentExpression VariadicCall { $$ = CYNew CYArgument(NULL, $2, $3); }
1942     | { $$ = NULL; }
1943     ;
1944
1945 SelectorWordOpt
1946     : WordOpt { driver.contexts_.back().words_.push_back($1); } { $$ = $1; }
1947     | AutoComplete { driver.mode_ = CYDriver::AutoMessage; YYACCEPT; }
1948     ;
1949
1950 SelectorCall_
1951     : SelectorCall { $$ = $1; }
1952     | VariadicCall { $$ = $1; }
1953     ;
1954
1955 SelectorCall
1956     : SelectorWordOpt ":" AssignmentExpression SelectorCall_ { $$ = CYNew CYArgument($1 ?: CYNew CYWord(""), $3, $4); }
1957     ;
1958
1959 SelectorList
1960     : SelectorCall { $$ = $1; }
1961     | Word { $$ = CYNew CYArgument($1, NULL); }
1962     ;
1963
1964 MessageExpression
1965     : "[" LexPushInOff AssignmentExpression { driver.contexts_.push_back($3); } SelectorList "]" LexPopIn { driver.contexts_.pop_back(); } { $$ = CYNew CYSendDirect($3, $5); }
1966     | "[" LexPushInOff LexSetRegExp "super" { driver.context_ = NULL; } SelectorList "]" LexPopIn { $$ = CYNew CYSendSuper($6); }
1967     ;
1968
1969 SelectorExpression_
1970     : WordOpt ":" SelectorExpressionOpt { $$ = CYNew CYSelectorPart($1, true, $3); }
1971     ;
1972
1973 SelectorExpression
1974     : SelectorExpression_ { $$ = $1; }
1975     | Word { $$ = CYNew CYSelectorPart($1, false, NULL); }
1976     ;
1977
1978 SelectorExpressionOpt
1979     : SelectorExpression_ { $$ = $1; }
1980     | { $$ = NULL; }
1981     ;
1982
1983 PrimaryExpression
1984     : MessageExpression { $$ = $1; }
1985     | "@selector" "(" LexPushInOff SelectorExpression ")" LexPopIn { $$ = CYNew CYSelector($4); }
1986     ;
1987 /* }}} */
1988 @end
1989
1990 /* Cycript: @import Directive {{{ */
1991 ModulePath
1992     : ModulePath "." Word { $$ = CYNew CYModule($3, $1); }
1993     | Word { $$ = CYNew CYModule($1); }
1994     ;
1995
1996 Declaration__
1997     : "@import" ModulePath { $$ = CYNew CYImport($2); }
1998     ;
1999 /* }}} */
2000
2001 @begin ObjectiveC
2002 /* Cycript (Objective-C): Boxed Expressions {{{ */
2003 BoxableExpression
2004     : NullLiteral { $$ = $1; }
2005     | BooleanLiteral { $$ = $1; }
2006     | NumericLiteral { $$ = $1; }
2007     | StringLiteral { $$ = $1; }
2008     | ArrayLiteral { $$ = $1; }
2009     | ObjectLiteral { $$ = $1; }
2010     | CoverParenthesizedExpressionAndArrowParameterList { $$ = $1; }
2011     | "YES" { $$ = CYNew CYTrue(); }
2012     | "NO" { $$ = CYNew CYFalse(); }
2013     ;
2014
2015 PrimaryExpression
2016     : "@" BoxableExpression { $$ = CYNew CYBox($2); }
2017     | "@YES" { $$ = CYNew CYBox(CYNew CYTrue()); }
2018     | "@NO" { $$ = CYNew CYBox(CYNew CYFalse()); }
2019     | "@true" { $$ = CYNew CYBox(CYNew CYTrue()); }
2020     | "@false" { $$ = CYNew CYBox(CYNew CYFalse()); }
2021     | "@null" { $$ = CYNew CYBox(CYNew CYNull()); }
2022     ;
2023 /* }}} */
2024 /* Cycript (Objective-C): Block Expressions {{{ */
2025 PrimaryExpression
2026     : "^" TypedIdentifier { if ($2->identifier_ != NULL) CYERR($2->location_, "unexpected identifier"); } BRACE LexPushInOff FunctionBody "}" LexPopIn { if (CYTypeFunctionWith *function = $2->Function()) $$ = CYNew CYObjCBlock($2, function->parameters_, $6); else CYERR($2->location_, "expected parameters"); }
2027     ;
2028 /* }}} */
2029 /* Cycript (Objective-C): Instance Literals {{{ */
2030 PrimaryExpression
2031     : "#" NumericLiteral { $$ = CYNew CYInstanceLiteral($2); }
2032     ;
2033 /* }}} */
2034 @end
2035
2036 @begin C
2037 /* Cycript (C): Pointer Indirection/Addressing {{{ */
2038 LeftHandSideExpression
2039     : LexSetRegExp "*" UnaryExpression { $$ = CYNew CYIndirect($3); }
2040     ;
2041
2042 UnaryExpression_
2043     : "&" UnaryExpression { $$ = CYNew CYAddressOf($2); }
2044     ;
2045
2046 MemberAccess
2047     : "->" "[" Expression "]" { $$ = CYNew CYIndirectMember(NULL, $3); }
2048     | "->" IdentifierName { $$ = CYNew CYIndirectMember(NULL, CYNew CYString($2)); }
2049     | "->" AutoComplete { driver.mode_ = CYDriver::AutoIndirect; YYACCEPT; }
2050     ;
2051 /* }}} */
2052 /* Cycript (C): auto Compatibility {{{ */
2053 Var_
2054     : "auto"
2055     ;
2056 /* }}} */
2057 /* Cycript (C): Lambda Expressions {{{ */
2058 TypedParameterList_
2059     : "," TypedParameterList { $$ = $2; }
2060     | { $$ = NULL; }
2061     ;
2062
2063 TypedParameterList
2064     : TypedIdentifier TypedParameterList_ { $$ = CYNew CYTypedParameter($1, $2); }
2065     ;
2066
2067 TypedParameterListOpt
2068     : TypedParameterList { $$ = $1; }
2069     | { $$ = NULL; }
2070     ;
2071
2072 PrimaryExpression
2073     : "[" LexPushInOff LexSetRegExp "&" LexSetRegExp "]" LexPopIn "(" LexPushInOff TypedParameterListOpt ")" LexPopIn "->" TypedIdentifier BRACE LexPushInOff FunctionBody "}" LexPopIn { $$ = CYNew CYLambda($14, $10, $17); }
2074     ;
2075 /* }}} */
2076 /* Cycript (C): Type Definitions {{{ */
2077 Statement__
2078     : "typedef" TypedIdentifier { if ($2->identifier_ == NULL) CYERR($2->location_, "expected identifier"); } Terminator { $$ = CYNew CYTypeDefinition($2); }
2079     ;
2080 /* }}} */
2081 /* Cycript (C): extern "C" {{{ */
2082 Statement__
2083     : "extern" StringLiteral { if (strcmp($2->Value(), "C") != 0) CYERR(@2, "unknown extern binding"); } TypedIdentifier { if ($4->identifier_ == NULL) CYERR($4->location_, "expected identifier"); } Terminator { $$ = CYNew CYExternal($2, $4); }
2084     ;
2085 /* }}} */
2086
2087 @end
2088
2089 @begin E4X
2090 /* Lexer State {{{ */
2091 LexPushRegExp
2092     : { driver.PushCondition(CYDriver::RegExpCondition); }
2093     ;
2094
2095 LexPushXMLContent
2096     : { driver.PushCondition(CYDriver::XMLContentCondition); }
2097     ;
2098
2099 LexPushXMLTag
2100     : { driver.PushCondition(CYDriver::XMLTagCondition); }
2101     ;
2102
2103 LexPop
2104     : { driver.PopCondition(); }
2105     ;
2106
2107 LexSetXMLContent
2108     : { driver.SetCondition(CYDriver::XMLContentCondition); }
2109     ;
2110
2111 LexSetXMLTag
2112     : { driver.SetCondition(CYDriver::XMLTagCondition); }
2113     ;
2114 /* }}} */
2115 /* Virtual Tokens {{{ */
2116 XMLWhitespaceOpt
2117     : XMLWhitespace
2118     |
2119     ;
2120 /* }}} */
2121
2122 /* 8.1 Context Keywords {{{ */
2123 Identifier
2124     : "namespace" { $$ = CYNew CYIdentifier("namespace"); }
2125     | "xml" { $$ = CYNew CYIdentifier("xml"); }
2126     ;
2127 /* }}} */
2128 /* 8.3 XML Initializer Input Elements {{{ */
2129 XMLMarkup
2130     : XMLComment { $$ = $1; }
2131     | XMLCDATA { $$ = $1; }
2132     | XMLPI { $$ = $1; }
2133     ;
2134 /* }}} */
2135
2136 /* 11.1 Primary Expressions {{{ */
2137 PrimaryExpression
2138     : PropertyIdentifier { $$ = CYNew CYPropertyVariable($1); }
2139     | XMLInitialiser { $$ = $1; }
2140     | XMLListInitialiser { $$ = $1; }
2141     ;
2142
2143 PropertyIdentifier
2144     : AttributeIdentifier { $$ = $1; }
2145     | QualifiedIdentifier { $$ = $1; }
2146     | WildcardIdentifier { $$ = $1; }
2147     ;
2148 /* }}} */
2149 /* 11.1.1 Attribute Identifiers {{{ */
2150 AttributeIdentifier
2151     : "@" QualifiedIdentifier_ { $$ = CYNew CYAttribute($2); }
2152     ;
2153
2154 PropertySelector_
2155     : PropertySelector { $$ = $1; }
2156     | "[" LexPushInOff Expression "]" LexPopIn { $$ = CYNew CYSelector($3); }
2157     ;
2158
2159 PropertySelector
2160     : Identifier { $$ = CYNew CYSelector($1); }
2161     | WildcardIdentifier { $$ = $1; }
2162     ;
2163 /* }}} */
2164 /* 11.1.2 Qualified Identifiers {{{ */
2165 QualifiedIdentifier_
2166     : PropertySelector_ { $$ = CYNew CYQualified(NULL, $1); }
2167     | QualifiedIdentifier { $$ = $1; }
2168     ;
2169
2170 QualifiedIdentifier
2171     : PropertySelector "::" PropertySelector_ { $$ = CYNew CYQualified($1, $3); }
2172     ;
2173 /* }}} */
2174 /* 11.1.3 Wildcard Identifiers {{{ */
2175 WildcardIdentifier
2176     : "*" { $$ = CYNew CYWildcard(); }
2177     ;
2178 /* }}} */
2179 /* 11.1.4 XML Initializer {{{ */
2180 XMLInitialiser
2181     : XMLMarkup { $$ = $1; }
2182     | XMLElement { $$ = $1; }
2183     ;
2184
2185 XMLElement
2186     : "<" LexPushInOff XMLTagContent LexPop "/>" LexPopIn
2187     | "<" LexPushInOff XMLTagContent ">" LexSetXMLContent XMLElementContentOpt "</" LexSetXMLTag XMLTagName XMLWhitespaceOpt LexPop ">" LexPopIn
2188     ;
2189
2190 XMLTagContent
2191     : LexPushXMLTag XMLTagName XMLAttributes
2192     ;
2193
2194 XMLExpression
2195     : BRACE LexPushRegExp Expression LexPop "}"
2196     ;
2197
2198 XMLTagName
2199     : XMLExpression
2200     | XMLName
2201     ;
2202
2203 XMLAttributes_
2204     : XMLAttributes_ XMLAttribute
2205     |
2206     ;
2207
2208 XMLAttributes
2209     : XMLAttributes_ XMLWhitespace XMLExpression XMLWhitespaceOpt
2210     | XMLAttributes_ XMLWhitespaceOpt
2211     ;
2212
2213 XMLAttributeValue_
2214     : XMLExpression
2215     | XMLAttributeValue
2216     ;
2217
2218 XMLAttribute
2219     : XMLWhitespace XMLName XMLWhitespaceOpt "=" XMLWhitespaceOpt XMLAttributeValue_
2220     ;
2221
2222 XMLElementContent
2223     : XMLExpression XMLElementContentOpt
2224     | XMLMarkup XMLElementContentOpt
2225     | XMLText XMLElementContentOpt
2226     | XMLElement XMLElementContentOpt
2227     ;
2228
2229 XMLElementContentOpt
2230     : XMLElementContent
2231     |
2232     ;
2233 /* }}} */
2234 /* 11.1.5 XMLList Initializer {{{ */
2235 XMLListInitialiser
2236     : "<>" LexPushInOff LexPushXMLContent XMLElementContent LexPop "</>" LexPopIn { $$ = CYNew CYXMLList($4); }
2237     ;
2238 /* }}} */
2239
2240 /* 11.2 Left-Hand-Side Expressions {{{ */
2241 PropertyIdentifier_
2242     : Identifier { $$ = $1; }
2243     | PropertyIdentifier { $$ = $1; }
2244     ;
2245
2246 MemberAccess
2247     : "." PropertyIdentifier { $$ = CYNew CYPropertyMember(NULL, $2); }
2248     | ".." PropertyIdentifier_ { $$ = CYNew CYDescendantMember(NULL, $2); }
2249     | "." "(" Expression ")" { $$ = CYNew CYFilteringPredicate(NULL, $3); }
2250     ;
2251 /* }}} */
2252 /* 12.1 The default xml namespace Statement {{{ */
2253 /* XXX: DefaultXMLNamespaceStatement
2254     : "default" "xml" "namespace" "=" Expression Terminator { $$ = CYNew CYDefaultXMLNamespace($5); }
2255     ;
2256
2257 Statement__
2258     : DefaultXMLNamespaceStatement { $$ = $1; }
2259     ; */
2260 /* }}} */
2261 @end
2262
2263 /* JavaScript FTL: Array Comprehensions {{{ */
2264 Comprehension
2265     : AssignmentExpression ComprehensionFor ComprehensionTail { $$ = CYNew CYArrayComprehension($1, $2->Modify($3)); }
2266     ;
2267
2268 ComprehensionFor
2269     : "for" "each" "(" LexPushInOn LexicalBinding "!in" LexPopIn Expression ")" { $$ = CYNew CYForOfComprehension($5, $8); }
2270     ;
2271 /* }}} */
2272 /* JavaScript FTL: for each {{{ */
2273 IterationStatement
2274     : "for" "each" "(" LexPushInOn ForInStatementInitializer "!in" LexPopIn Expression ")" Statement { $$ = CYNew CYForOf($5, $8, $10); }
2275     ;
2276 /* }}} */
2277 /* JavaScript FTL: let Statements {{{ */
2278 LetStatement
2279     : "let" "(" VariableDeclarationList ")" Statement { $$ = CYNew CYLetStatement($3, $5); }
2280     ;
2281
2282 Statement__
2283     : LetStatement
2284     ;
2285 /* }}} */
2286
2287 /* JavaScript FTW: Array Comprehensions {{{ */
2288 PrimaryExpression
2289     : ArrayComprehension
2290     ;
2291
2292 ArrayComprehension
2293     : "[" LexPushInOff Comprehension "]" LexPopIn { $$ = $3; }
2294     ;
2295
2296 Comprehension
2297     : LexSetRegExp ComprehensionFor ComprehensionTail AssignmentExpression { $$ = CYNew CYArrayComprehension($4, $2->Modify($3)); }
2298     ;
2299
2300 ComprehensionTail
2301     : { $$ = NULL; }
2302     | ComprehensionFor ComprehensionTail { $$ = $1->Modify($2); }
2303     | ComprehensionIf ComprehensionTail { $$ = $1->Modify($2); }
2304     ;
2305
2306 ComprehensionFor
2307     : "for" "(" LexPushInOn LexicalBinding "!in" LexPopIn Expression ")" { $$ = CYNew CYForInComprehension($4, $7); }
2308     | "for" "(" LexPushInOn LexicalBinding "of" LexPopIn Expression ")" { $$ = CYNew CYForOfComprehension($4, $7); }
2309     ;
2310
2311 ComprehensionIf
2312     : "if" "(" AssignmentExpression ")" { $$ = CYNew CYIfComprehension($3); }
2313     ;
2314 /* }}} */
2315 /* JavaScript FTW: Coalesce Operator {{{ */
2316 ConditionalExpression
2317     : LogicalORExpression "?" LexPushInOff LexSetRegExp ":" LexPopIn AssignmentExpression { $$ = CYNew CYCondition($1, $1, $7); }
2318     ;
2319 /* }}} */
2320 /* JavaScript FTW: Named Arguments {{{ */
2321 ArgumentList
2322     : LexSetRegExp Word ":" AssignmentExpression ArgumentList_ { $$ = CYNew CYArgument($2, $4, $5); }
2323     ;
2324 /* }}} */
2325 /* JavaScript FTW: Ruby Blocks {{{ */
2326 RubyProcParameterList_
2327     : "," RubyProcParameterList { $$ = $2; }
2328     | { $$ = NULL; }
2329     ;
2330
2331 RubyProcParameterList
2332     : Identifier RubyProcParameterList_ { $$ = CYNew CYFunctionParameter(CYNew CYDeclaration($1), $2); }
2333     | { $$ = NULL; }
2334     ;
2335
2336 RubyProcParameters
2337     : LexSetRegExp "|" RubyProcParameterList "|" { $$ = $3; }
2338     | LexSetRegExp "||" { $$ = NULL; }
2339     ;
2340
2341 RubyProcParametersOpt
2342     : RubyProcParameters { $$ = $1; }
2343     | { $$ = NULL; }
2344     ;
2345
2346 RubyProcExpression
2347     : "{" RubyProcParametersOpt StatementListOpt "}" { $$ = CYNew CYRubyProc($2, $3); }
2348     ;
2349
2350 PrimaryExpression
2351     : BRACE LexPushInOff RubyProcParameters StatementListOpt "}" LexPopIn { $$ = CYNew CYRubyProc($3, $4); }
2352     ;
2353
2354 PostfixExpression
2355     : LeftHandSideExpression RubyProcExpression { $$ = CYNew CYRubyBlock($1, $2); }
2356     ;
2357 /* }}} */
2358
2359 %%
2360
2361 bool CYDriver::Parse(CYMark mark) {
2362     mark_ = mark;
2363     CYLocal<CYPool> local(&pool_);
2364     cy::parser parser(*this);
2365 #ifdef YYDEBUG
2366     parser.set_debug_level(debug_);
2367 #endif
2368     return parser.parse() != 0;
2369 }
2370
2371 void CYDriver::Warning(const cy::parser::location_type &location, const char *message) {
2372     if (!strict_)
2373         return;
2374
2375     CYDriver::Error error;
2376     error.warning_ = true;
2377     error.location_ = location;
2378     error.message_ = message;
2379     errors_.push_back(error);
2380 }
2381
2382 void cy::parser::error(const cy::parser::location_type &location, const std::string &message) {
2383     CYDriver::Error error;
2384     error.warning_ = false;
2385     error.location_ = location;
2386     error.message_ = message;
2387     driver.errors_.push_back(error);
2388 }