configure.ac

   1 dnl Cycript - Optimizing JavaScript Compiler/Runtime
   2 dnl Copyright (C) 2009-2013  Jay Freeman (saurik)
   3
   4 dnl GNU General Public License, Version 3 {{{
   5 dnl
   6 dnl Cycript is free software: you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published
   8 dnl by the Free Software Foundation, either version 3 of the License,
   9 dnl or (at your option) any later version.
  10 dnl
  11 dnl Cycript is distributed in the hope that it will be useful, but
  12 dnl WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with Cycript.  If not, see <http://www.gnu.org/licenses/>.
  18 dnl }}}
  19
  20 AC_PREREQ([2.65])
  21 AC_INIT([Cycript], [0.9], [saurik@saurik.com], [cycript], [http://www.cycript.org/])
  22 AC_COPYRIGHT([Copyright (C) 2009-2012  Jay Freeman (saurik)])
  23
  24 AC_CONFIG_SRCDIR([Console.cpp])
  25 AC_CONFIG_AUX_DIR([.])
  26 AC_CONFIG_MACRO_DIR([m4])
  27 AC_CONFIG_HEADERS([config.h])
  28
  29 AM_INIT_AUTOMAKE([-Wall -Werror foreign])
  30 AM_MAINTAINER_MODE([disable])
  31
  32 dnl XXX: do this only on Mac OS X
  33 am_cv_CC_dependencies_compiler_type=none
  34 am_cv_CXX_dependencies_compiler_type=none
  35 am_cv_OBJCXX_dependencies_compiler_type=none
  36
  37 AC_PROG_CXX
  38 AC_PROG_OBJCXX
  39
  40 AM_PROG_AR
  41 AC_PROG_INSTALL
  42
  43 LT_INIT([disable-static])
  44
  45 AC_LANG([C++])
  46
  47 PKG_PROG_PKG_CONFIG([0.22])
  48
  49 AC_PATH_PROG([GIT], [git])
  50 AC_PATH_PROG([TIME], [time])
  51
  52 dnl CY_CHECK_PROGS_VERSION {{{
  53 AC_DEFUN([CY_CHECK_PROGS_VERSION], [
  54     AC_ARG_VAR(]$1[, ]$3[)
  55
  56     AC_MSG_CHECKING(for ]$2[ >= ]$5[)
  57     AC_PATH_PROGS_FEATURE_CHECK(]$1[, ]$2[,
  58         AS_VAR_SET(version, [`$ac_path_]$1[ ]$4[`])
  59         AS_VAR_IF(version, [], ,
  60             AS_VERSION_COMPARE($version, ]$5[, ,
  61                 ac_cv_path_]$1[=$ac_path_]$1[,
  62                 ac_cv_path_]$1[=$ac_path_]$1[))
  63     , AC_MSG_RESULT(no))
  64
  65     AS_IF([true], [
  66         AC_SUBST(]$1[, $ac_cv_path_]$1[)
  67         AC_MSG_RESULT($]$1[)
  68     ], AS_IF([true], [
  69         AC_MSG_ERROR(You need ]$2[ ]$5[ or greater)
  70     ], [
  71         AC_SUBST(]$1[, [:])
  72         AC_MSG_RESULT([no])
  73     ]))
  74 ]) dnl }}}
  75
  76 CY_CHECK_PROGS_VERSION([BISON], [bison], [GNU Project parser generator (yacc replacement)],
  77     [-V | $SED -e '1 s/^bison (GNU Bison) \(.*\)$/\1/p;d'], [2.3])
  78 CY_CHECK_PROGS_VERSION([FLEX], [flex], [the fast lexical analyser generator],
  79     [--version | $SED -e '1 s/^@<:@^0-9.@:>@* \(@<:@0-9.@:>@*\).*$/\1/p;d'], [2.5.33])
  80 CY_CHECK_PROGS_VERSION([GPERF], [gperf], [perfect hash function generator],
  81     [--version | $SED -e '1 s/^.* \(@<:@0-9.@:>@*\)$/\1/p;d'], [3.0.3])
  82 CY_CHECK_PROGS_VERSION([GNUTAR], [tar gtar gnutar], [a very sticky lump of files],
  83     [--version | $SED -e '1 s/^tar (GNU tar) \(.*\)$/\1/p;d'], [1.19])
  84
  85 AC_MSG_CHECKING([bison for %code{}])
  86 echo '%code{}%%_:' >conftest.y
  87 if $BISON conftest.y -o/dev/null 2>/dev/null; then
  88     AC_LIB_APPENDTOVAR([CY_FILTERS], [Bison24])
  89     AC_MSG_RESULT([yes])
  90 else
  91     AC_LIB_APPENDTOVAR([CY_FILTERS], [Bison23])
  92     AC_MSG_RESULT([no])
  93 fi
  94
  95 rm -f conftest.y
  96 AC_SUBST([CY_FILTERS])
  97
  98 dnl CY_TRY {{{
  99 AC_DEFUN([CY_SUCCESS], [cy_good=1])
 100 AC_DEFUN([CY_FAILURE], [cy_good=0])
 101
 102 AC_DEFUN([CY_TRY], [
 103     cy_save=$]$1[
 104         AC_LIB_APPENDTOVAR(]$1[, ]$2[)
 105         ]$3[
 106     ]$1[=$cy_save
 107     AS_IF([test "x$cy_good" = x1], ]$4[, ]$5[)
 108 ]) dnl }}}
 109
 110 AC_DEFUN([CY_TEST_FLAG_], [
 111     AC_LANG_PUSH(]$2[)
 112     AC_MSG_CHECKING([for ]]$4[[ ]]$1[)
 113     CY_TRY(]$3[, $1, [
 114         AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
 115             [CY_SUCCESS], [CY_FAILURE])
 116     ], [
 117         AC_MSG_RESULT([yes])
 118         AC_LIB_APPENDTOVAR(]$3[, ]$1[)
 119     ], [AC_MSG_RESULT([no])])
 120     AC_LANG_POP(]$2[)
 121 ])
 122
 123 AC_DEFUN([CY_TEST_FLAG], [
 124     CY_TEST_FLAG_(]$1[, [C], [CFLAGS], [cc])
 125     CY_TEST_FLAG_(]$1[, [C++], [CXXFLAGS], [c++])
 126     CY_TEST_FLAG_(]$1[, [Objective C++], [OBJCXXFLAGS], [c++ -ObjC])
 127 ])
 128
 129 AX_CFLAGS_WARN_ALL
 130 AX_CXXFLAGS_WARN_ALL
 131 AX_FLAGS_WARN_ALL
 132
 133 CY_TEST_FLAG([-Werror])
 134
 135 dnl XXX: this is used to support GNU Objective-C struct objc_method
 136 CY_TEST_FLAG([-Wno-deprecated-declarations])
 137
 138 CY_TEST_FLAG([-Wno-dangling-else])
 139 CY_TEST_FLAG([-Wno-overloaded-virtual])
 140 CY_TEST_FLAG([-Wno-parentheses])
 141 CY_TEST_FLAG([-Wno-unneeded-internal-declaration])
 142
 143 dnl -arch * {{{
 144 for cy_arch in ppc ppc64 i386 x86_64 armv6; do
 145     AC_MSG_CHECKING([for -arch $cy_arch])
 146     CY_TRY([CXXFLAGS], ["-arch $cy_arch"], [
 147         AC_TRY_LINK([], [], [CY_SUCCESS], [CY_FAILURE])
 148     ], [
 149         AC_MSG_RESULT([yes])
 150         AC_LIB_APPENDTOVAR([CY_ARCH], ["-arch $cy_arch"])
 151     ], [AC_MSG_RESULT([no])])
 152 done
 153 AC_SUBST([CY_ARCH])
 154 dnl }}}
 155 dnl iOS SDK {{{
 156 AC_PATH_PROG([XCODEBUILD], [xcodebuild])
 157
 158 AS_IF([test "x$XCODEBUILD" != x], [
 159     AC_SUBST([CY_IOS_SIMULATOR], [`xcodebuild -sdk iphonesimulator -version Path`])
 160 ])
 161
 162 AM_CONDITIONAL([CY_IOS_SIMULATOR], [test "x$CY_IOS_SIMULATOR" != x])
 163 dnl }}}
 164
 165 AC_DEFUN([CY_LT_LIB], [
 166     cy_save=$LIBS
 167     LIBS=
 168     ]$2[
 169     ]$1[=$LIBS
 170     LIBS=$cy_save
 171     AC_SUBST(]$1[)
 172 ])
 173
 174 dnl --enable-javascript {{{
 175 AC_DEFUN([CY_CHECK_JAVASCRIPTCORE], [
 176     CY_LT_LIB([LTJAVASCRIPTCORE], [AC_CHECK_FRAMEWORK([JavaScriptCore], [
 177         #include <JavaScriptCore/JSBase.h>
 178     ], [
 179         JSEvaluateScript(0, 0, 0, 0, 0, 0);
 180     ], [
 181         AC_SUBST([CY_EXECUTE], [1])
 182     ], [
 183         for cy_webkit_pkg in "webkit-1.0" "WebKitGtk"; do
 184             PKG_CHECK_MODULES([WEBKIT], [$cy_webkit_pkg], [
 185                 AC_SUBST([CY_EXECUTE], [1])
 186                 AC_LIB_APPENDTOVAR([CPPFLAGS], [`$PKG_CONFIG --cflags $cy_webkit_pkg`])
 187                 AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs $cy_webkit_pkg`])
 188             ], [:]); if test "x$CY_EXECUTE" = x1; then break; fi
 189         done
 190     ])])
 191 ])
 192
 193 AC_DEFUN([CY_CHECK_JAVASCRIPT], [
 194     CY_CHECK_JAVASCRIPTCORE])
 195
 196 AC_ARG_ENABLE([javascript], [AS_HELP_STRING(
 197     [--enable-javascript@<:@=ENGINE@:>@],
 198     [use a JavaScript runtime (currently the only available option for ENGINE is JavaScriptCore) @<:@default=yes@:>@]
 199 )], [
 200     AS_CASE([$enableval],
 201         [yes], [
 202             CY_CHECK_JAVASCRIPT],
 203         [no], [
 204             AC_SUBST([CY_EXECUTE], [0])],
 205         [JavaScriptCore], [
 206             CY_CHECK_JAVASCRIPTCORE],
 207         [AC_MSG_ERROR([Unknown JavaScript engine: $enableval])])
 208 ], [CY_CHECK_JAVASCRIPT])
 209 dnl }}}
 210
 211 dnl APR_FIND_APR {{{
 212 APR_FIND_APR([], [], [1], [1])
 213 AS_CASE([$apr_found], [yes], [
 214     AC_LIB_APPENDTOVAR([CPPFLAGS], [`$apr_config --includes`])
 215     AC_LIB_APPENDTOVAR([LTLIBAPR], [`$apr_config --link-libtool`])
 216     AC_SUBST([LTLIBAPR])
 217 ], [AC_MSG_ERROR([missing "libapr"])])
 218 dnl }}}
 219
 220 AC_DEFUN([CY_CHECK_PKG_CONFIG_LIBFFI], [
 221     PKG_CHECK_MODULES([LIBFFI], [libffi], [
 222         AC_LIB_APPENDTOVAR([CPPFLAGS], [`$PKG_CONFIG --cflags libffi`])
 223         AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs libffi`])
 224     ], [AC_MSG_ERROR([missing "libffi"])])])
 225
 226 AM_CONDITIONAL([CY_EXECUTE], [test "x$CY_EXECUTE" = x1])
 227
 228 AS_CASE([$CY_EXECUTE], [1], [
 229     AC_CHECK_HEADERS([ffi.h ffi/ffi.h], [break])
 230
 231     CY_LT_LIB([LTLIBFFI], AS_IF([test "x$ac_cv_header_ffi_h" = xno && test "x$ac_cv_header_ffi_ffi_h" = xno], [
 232         CY_CHECK_PKG_CONFIG_LIBFFI
 233     ], [
 234         AC_SEARCH_LIBS([ffi_call], [ffi])
 235         AS_CASE([$ac_cv_search_ffi_call], [no], [CY_CHECK_PKG_CONFIG_LIBFFI])
 236     ]))
 237
 238     AC_LANG_PUSH([Objective C++])
 239
 240     AC_MSG_CHECKING([if we really have Objective C++])
 241     AC_COMPILE_IFELSE([AC_LANG_SOURCE([])], [
 242         CY_OBJECTIVEC=1
 243         AC_MSG_RESULT([yes])
 244     ], [AC_MSG_RESULT([no])])
 245
 246     AS_IF([test "x$CY_OBJECTIVEC" = x1], [
 247         CY_LT_LIB([LTOBJECTIVEC], [AC_CHECK_FRAMEWORK([CoreFoundation], [
 248             #include <CoreFoundation/CFBase.h>
 249         ], [CFAllocatorGetDefault();], [
 250             AC_SUBST([CY_OBJECTIVEC])
 251
 252             AC_CHECK_FRAMEWORK([Foundation], [
 253                 #include <Foundation/NSObject.h>
 254             ], [[[[NSObject alloc] init];]])
 255         ], [
 256             AC_ARG_VAR([GNUSTEP_CONFIG], [prints information about the current gnustep installation])
 257             AC_CHECK_PROGS([GNUSTEP_CONFIG], [gnustep-config])
 258
 259             AS_IF([test "x$GNUSTEP_CONFIG" != x], [
 260                 AC_SUBST([CY_OBJECTIVEC])
 261                 AC_LIB_APPENDTOVAR([OBJCXXFLAGS], [`$GNUSTEP_CONFIG --objc-flags`])
 262                 AC_LIB_APPENDTOVAR([LIBS], [`$GNUSTEP_CONFIG --base-libs`])
 263             ], [AC_SUBST([CY_OBJECTIVEC], [0])])
 264         ])])
 265     ])
 266
 267     AC_LANG_POP([Objective C++])
 268 ])
 269
 270 AM_CONDITIONAL([CY_OBJECTIVEC], [test "x$CY_OBJECTIVEC" = x1])
 271
 272 CY_LT_LIB([LTLIBREADLINE], [AX_LIB_READLINE])
 273 AS_CASE([$ax_cv_lib_readline], [no], [AC_MSG_ERROR([missing "libreadline"])])
 274
 275 CY_LT_LIB([LTLIBTERMCAP], [AC_SEARCH_LIBS([cur_term], [termcap])])
 276
 277 AC_SUBST([LTFLAGS])
 278 AC_SUBST([SO], [$acl_shlibext])
 279
 280 AS_IF([test "x$CY_EXECUTE" = x1], [
 281     AC_CHECK_HEADER([mach/mach.h], [
 282         AC_CHECK_TOOLS([_LIPO], [lipo], [AC_MSG_ERROR([missing "lipo"])])
 283         AC_CHECK_TOOLS([_NM], [nm], [AC_MSG_ERROR([missing "nm"])])
 284         AC_CHECK_TOOLS([_OTOOL], [otool], [AC_MSG_ERROR([missing "otool"])])
 285         AC_SUBST([CY_ATTACH_GROUP], [procmod])
 286         AC_SUBST([CY_MACH], [1])])])
 287 AM_CONDITIONAL([CY_MACH], [test "x$CY_MACH" = x1])
 288
 289 AC_CONFIG_FILES([Makefile])
 290 AC_OUTPUT