ObjectiveC/Library.mm

   1 /* Cycript - Optimizing JavaScript Compiler/Runtime
   2  * Copyright (C) 2009-2013  Jay Freeman (saurik)
   3 */
   4
   5 /* GNU General Public License, Version 3 {{{ */
   6 /*
   7  * Cycript is free software: you can redistribute it and/or modify
   8  * it under the terms of the GNU General Public License as published
   9  * by the Free Software Foundation, either version 3 of the License,
  10  * or (at your option) any later version.
  11  *
  12  * Cycript is distributed in the hope that it will be useful, but
  13  * WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with Cycript.  If not, see <http://www.gnu.org/licenses/>.
  19 **/
  20 /* }}} */
  21
  22 #include <Foundation/Foundation.h>
  23
  24 #include "ObjectiveC/Internal.hpp"
  25
  26 #include <objc/objc-api.h>
  27
  28 #include "cycript.hpp"
  29
  30 #include "ObjectiveC/Internal.hpp"
  31
  32 #ifdef __APPLE__
  33 #include <CoreFoundation/CoreFoundation.h>
  34 #include <JavaScriptCore/JSStringRefCF.h>
  35 #include <objc/runtime.h>
  36 #endif
  37
  38 #ifdef __APPLE__
  39 #include <malloc/malloc.h>
  40 #include <mach/mach.h>
  41 #endif
  42
  43 #include "Code.hpp"
  44 #include "Error.hpp"
  45 #include "JavaScript.hpp"
  46 #include "String.hpp"
  47 #include "Execute.hpp"
  48
  49 #include <cmath>
  50 #include <map>
  51 #include <set>
  52
  53 #include <dlfcn.h>
  54
  55 #define CYObjectiveTry_ { \
  56     try
  57 #define CYObjectiveTry { \
  58     JSContextRef context(context_); \
  59     try
  60 #define CYObjectiveCatch \
  61     catch (const CYException &error) { \
  62         @throw CYCastNSObject(NULL, context, error.CastJSValue(context)); \
  63     } \
  64 }
  65
  66 #define CYPoolTry { \
  67     id _saved(nil); \
  68     NSAutoreleasePool *_pool([[NSAutoreleasePool alloc] init]); \
  69     @try
  70 #define CYPoolCatch(value) \
  71     @catch (NSException *error) { \
  72         _saved = [error retain]; \
  73         throw CYJSError(context, CYCastJSValue(context, error)); \
  74         return value; \
  75     } @finally { \
  76         [_pool release]; \
  77         if (_saved != nil) \
  78             [_saved autorelease]; \
  79     } \
  80 }
  81
  82 #define CYSadTry { \
  83     @try
  84 #define CYSadCatch(value) \
  85     @catch (NSException *error ) { \
  86         throw CYJSError(context, CYCastJSValue(context, error)); \
  87     } return value; \
  88 }
  89
  90 #ifndef __APPLE__
  91 #define class_getSuperclass GSObjCSuper
  92 #define class_getInstanceVariable GSCGetInstanceVariableDefinition
  93 #define class_getName GSNameFromClass
  94
  95 #define class_removeMethods(cls, list) GSRemoveMethodList(cls, list, YES)
  96
  97 #define ivar_getName(ivar) ((ivar)->ivar_name)
  98 #define ivar_getOffset(ivar) ((ivar)->ivar_offset)
  99 #define ivar_getTypeEncoding(ivar) ((ivar)->ivar_type)
 100
 101 #define method_getName(method) ((method)->method_name)
 102 #define method_getImplementation(method) ((method)->method_imp)
 103 #define method_getTypeEncoding(method) ((method)->method_types)
 104 #define method_setImplementation(method, imp) ((void) ((method)->method_imp = (imp)))
 105
 106 #undef objc_getClass
 107 #define objc_getClass GSClassFromName
 108
 109 #define objc_getProtocol GSProtocolFromName
 110
 111 #define object_getClass GSObjCClass
 112
 113 #define object_getInstanceVariable(object, name, value) ({ \
 114     objc_ivar *ivar(class_getInstanceVariable(object_getClass(object), name)); \
 115     _assert(value != NULL); \
 116     if (ivar != NULL) \
 117         GSObjCGetVariable(object, ivar_getOffset(ivar), sizeof(void *), value); \
 118     ivar; \
 119 })
 120
 121 #define object_setIvar(object, ivar, value) ({ \
 122     void *data = (value); \
 123     GSObjCSetVariable(object, ivar_getOffset(ivar), sizeof(void *), &data); \
 124 })
 125
 126 #define protocol_getName(protocol) [(protocol) name]
 127 #endif
 128
 129 static void (*$objc_setAssociatedObject)(id object, void *key, id value, objc_AssociationPolicy policy);
 130 static id (*$objc_getAssociatedObject)(id object, void *key);
 131 static void (*$objc_removeAssociatedObjects)(id object);
 132
 133 @class NSBlock;
 134
 135 struct BlockLiteral {
 136     Class isa;
 137     int flags;
 138     int reserved;
 139     void (*invoke)(void *, ...);
 140     void *descriptor;
 141 };
 142
 143 struct BlockDescriptor1 {
 144     unsigned long int reserved;
 145     unsigned long int size;
 146 };
 147
 148 struct BlockDescriptor2 {
 149     void (*copy_helper)(BlockLiteral *dst, BlockLiteral *src);
 150     void (*dispose_helper)(BlockLiteral *src);
 151 };
 152
 153 struct BlockDescriptor3 {
 154     const char *signature;
 155     const char *layout;
 156 };
 157
 158 enum {
 159     BLOCK_DEALLOCATING = 0x0001,
 160     BLOCK_REFCOUNT_MASK = 0xfffe,
 161     BLOCK_NEEDS_FREE = 1 << 24,
 162     BLOCK_HAS_COPY_DISPOSE = 1 << 25,
 163     BLOCK_HAS_CTOR = 1 << 26,
 164     BLOCK_IS_GC = 1 << 27,
 165     BLOCK_IS_GLOBAL = 1 << 28,
 166     BLOCK_HAS_STRET = 1 << 29,
 167     BLOCK_HAS_SIGNATURE = 1 << 30,
 168 };
 169
 170 JSValueRef CYSendMessage(CYPool &pool, JSContextRef context, id self, Class super, SEL _cmd, size_t count, const JSValueRef arguments[], bool initialize);
 171
 172 /* Objective-C Pool Release {{{ */
 173 void CYPoolRelease_(void *data) {
 174     id object(reinterpret_cast<id>(data));
 175     [object release];
 176 }
 177
 178 id CYPoolRelease_(CYPool *pool, id object) {
 179     if (object == nil)
 180         return nil;
 181     else if (pool == NULL)
 182         return [object autorelease];
 183     else {
 184         pool->atexit(CYPoolRelease_);
 185         return object;
 186     }
 187 }
 188
 189 template <typename Type_>
 190 Type_ CYPoolRelease(CYPool *pool, Type_ object) {
 191     return (Type_) CYPoolRelease_(pool, (id) object);
 192 }
 193 /* }}} */
 194 /* Objective-C Strings {{{ */
 195 const char *CYPoolCString(CYPool &pool, JSContextRef context, NSString *value) {
 196     size_t size([value maximumLengthOfBytesUsingEncoding:NSUTF8StringEncoding] + 1);
 197     char *string(new(pool) char[size]);
 198     if (![value getCString:string maxLength:size encoding:NSUTF8StringEncoding])
 199         throw CYJSError(context, "[NSString getCString:maxLength:encoding:] == NO");
 200     return string;
 201 }
 202
 203 JSStringRef CYCopyJSString(JSContextRef context, NSString *value) {
 204 #ifdef __APPLE__
 205     return JSStringCreateWithCFString(reinterpret_cast<CFStringRef>(value));
 206 #else
 207     CYPool pool;
 208     return CYCopyJSString(CYPoolCString(pool, context, value));
 209 #endif
 210 }
 211
 212 JSStringRef CYCopyJSString(JSContextRef context, NSObject *value) {
 213     if (value == nil)
 214         return NULL;
 215     // XXX: this definition scares me; is anyone using this?!
 216     NSString *string([value description]);
 217     return CYCopyJSString(context, string);
 218 }
 219
 220 NSString *CYCopyNSString(const CYUTF8String &value) {
 221 #ifdef __APPLE__
 222     return (NSString *) CFStringCreateWithBytes(kCFAllocatorDefault, reinterpret_cast<const UInt8 *>(value.data), value.size, kCFStringEncodingUTF8, true);
 223 #else
 224     return [[NSString alloc] initWithBytes:value.data length:value.size encoding:NSUTF8StringEncoding];
 225 #endif
 226 }
 227
 228 NSString *CYCopyNSString(JSContextRef context, JSStringRef value) {
 229 #ifdef __APPLE__
 230     return (NSString *) JSStringCopyCFString(kCFAllocatorDefault, value);
 231 #else
 232     CYPool pool;
 233     return CYCopyNSString(CYPoolUTF8String(pool, context, value));
 234 #endif
 235 }
 236
 237 NSString *CYCopyNSString(JSContextRef context, JSValueRef value) {
 238     return CYCopyNSString(context, CYJSString(context, value));
 239 }
 240
 241 NSString *CYCastNSString(CYPool *pool, const CYUTF8String &value) {
 242     return CYPoolRelease(pool, CYCopyNSString(value));
 243 }
 244
 245 NSString *CYCastNSString(CYPool *pool, SEL sel) {
 246     const char *name(sel_getName(sel));
 247     return CYPoolRelease(pool, CYCopyNSString(CYUTF8String(name, strlen(name))));
 248 }
 249
 250 NSString *CYCastNSString(CYPool *pool, JSContextRef context, JSStringRef value) {
 251     return CYPoolRelease(pool, CYCopyNSString(context, value));
 252 }
 253
 254 CYUTF8String CYCastUTF8String(NSString *value) {
 255     NSData *data([value dataUsingEncoding:NSUTF8StringEncoding allowLossyConversion:NO]);
 256     return CYUTF8String(reinterpret_cast<const char *>([data bytes]), [data length]);
 257 }
 258 /* }}} */
 259
 260 JSValueRef CYCastJSValue(JSContextRef context, NSObject *value);
 261
 262 void CYThrow(JSContextRef context, NSException *error, JSValueRef *exception) {
 263     if (exception == NULL)
 264         throw error;
 265     *exception = CYCastJSValue(context, error);
 266 }
 267
 268 size_t CYGetIndex(NSString *value) {
 269     return CYGetIndex(CYCastUTF8String(value));
 270 }
 271
 272 bool CYGetOffset(CYPool &pool, JSContextRef context, NSString *value, ssize_t &index) {
 273     return CYGetOffset(CYPoolCString(pool, context, value), index);
 274 }
 275
 276 static JSClassRef Instance_;
 277
 278 static JSClassRef ArrayInstance_;
 279 static JSClassRef BooleanInstance_;
 280 static JSClassRef FunctionInstance_;
 281 static JSClassRef NumberInstance_;
 282 static JSClassRef ObjectInstance_;
 283 static JSClassRef StringInstance_;
 284
 285 static JSClassRef Class_;
 286 static JSClassRef Internal_;
 287 static JSClassRef Message_;
 288 static JSClassRef Messages_;
 289 static JSClassRef Selector_;
 290 static JSClassRef Super_;
 291
 292 static JSClassRef ObjectiveC_Classes_;
 293 static JSClassRef ObjectiveC_Constants_;
 294 static JSClassRef ObjectiveC_Protocols_;
 295
 296 #ifdef __APPLE__
 297 static JSClassRef ObjectiveC_Image_Classes_;
 298 static JSClassRef ObjectiveC_Images_;
 299 #endif
 300
 301 #ifdef __APPLE__
 302 static Class __NSMallocBlock__;
 303 static Class NSCFBoolean_;
 304 static Class NSCFType_;
 305 static Class NSGenericDeallocHandler_;
 306 static Class NSZombie_;
 307
 308 static std::set<Class> banned_;
 309 #else
 310 static Class NSBoolNumber_;
 311 #endif
 312
 313 static Class NSArray_;
 314 static Class NSBlock_;
 315 static Class NSDictionary_;
 316 static Class NSNumber_;
 317 static Class NSString_;
 318 static Class Object_;
 319
 320 static Type_privateData *Object_type;
 321 static Type_privateData *Selector_type;
 322
 323 Type_privateData *Instance::GetType() const {
 324     return Object_type;
 325 }
 326
 327 Type_privateData *Selector_privateData::GetType() const {
 328     return Selector_type;
 329 }
 330
 331 static JSValueRef Instance_callAsFunction_toString(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception);
 332
 333 JSValueRef CYGetClassPrototype(JSContextRef context, Class self, bool meta) {
 334     if (self == nil)
 335         return CYGetCachedObject(context, CYJSString("Instance_prototype"));
 336     else if (meta && !class_isMetaClass(self))
 337         return CYGetCachedObject(context, CYJSString("Class_prototype"));
 338
 339     JSObjectRef global(CYGetGlobalObject(context));
 340     JSObjectRef cy(CYCastJSObject(context, CYGetProperty(context, global, cy_s)));
 341
 342     char label[32];
 343     sprintf(label, "i%p", self);
 344     CYJSString name(label);
 345
 346     JSValueRef value(CYGetProperty(context, cy, name));
 347     if (!JSValueIsUndefined(context, value))
 348         return value;
 349
 350     JSClassRef _class(NULL);
 351     JSValueRef prototype;
 352
 353 #ifdef __APPLE__
 354     if (self == NSCFBoolean_)
 355 #else
 356     if (self == NSBoolNumber_)
 357 #endif
 358         prototype = CYGetCachedObject(context, CYJSString("BooleanInstance_prototype"));
 359     else if (self == NSArray_)
 360         prototype = CYGetCachedObject(context, CYJSString("ArrayInstance_prototype"));
 361     else if (self == NSBlock_)
 362         prototype = CYGetCachedObject(context, CYJSString("FunctionInstance_prototype"));
 363     else if (self == NSNumber_)
 364         prototype = CYGetCachedObject(context, CYJSString("NumberInstance_prototype"));
 365     else if (self == NSDictionary_)
 366         prototype = CYGetCachedObject(context, CYJSString("ObjectInstance_prototype"));
 367     else if (self == NSString_)
 368         prototype = CYGetCachedObject(context, CYJSString("StringInstance_prototype"));
 369     else
 370         prototype = CYGetClassPrototype(context, class_getSuperclass(self), meta);
 371
 372     JSObjectRef object(JSObjectMake(context, _class, NULL));
 373     CYSetPrototype(context, object, prototype);
 374     CYSetProperty(context, cy, name, object);
 375
 376     return object;
 377 }
 378
 379 _finline JSValueRef CYGetClassPrototype(JSContextRef context, Class self) {
 380     return CYGetClassPrototype(context, self, class_isMetaClass(self));
 381 }
 382
 383 JSObjectRef Messages::Make(JSContextRef context, Class _class) {
 384     JSObjectRef value(JSObjectMake(context, Messages_, new Messages(_class)));
 385     if (Class super = class_getSuperclass(_class))
 386         CYSetPrototype(context, value, Messages::Make(context, super));
 387     return value;
 388 }
 389
 390 JSObjectRef Internal::Make(JSContextRef context, id object, JSObjectRef owner) {
 391     return JSObjectMake(context, Internal_, new Internal(object, context, owner));
 392 }
 393
 394 namespace cy {
 395 JSObjectRef Super::Make(JSContextRef context, id object, Class _class) {
 396     JSObjectRef value(JSObjectMake(context, Super_, new Super(object, _class)));
 397     return value;
 398 } }
 399
 400 bool CYIsKindOfClass(id object, Class _class) {
 401     for (Class isa(object_getClass(object)); isa != NULL; isa = class_getSuperclass(isa))
 402         if (isa == _class)
 403             return true;
 404     return false;
 405 }
 406
 407 JSObjectRef Instance::Make(JSContextRef context, id object, Flags flags) {
 408     JSObjectRef value(JSObjectMake(context, CYIsKindOfClass(object, NSBlock_) ? FunctionInstance_ : Instance_, new Instance(object, flags)));
 409     CYSetPrototype(context, value, CYGetClassPrototype(context, object_getClass(object)));
 410     return value;
 411 }
 412
 413 Instance::~Instance() {
 414     if ((flags_ & Transient) == 0)
 415         [GetValue() release];
 416 }
 417
 418 struct Message_privateData :
 419     cy::Functor
 420 {
 421     SEL sel_;
 422
 423     Message_privateData(SEL sel, const char *type, IMP value = NULL) :
 424         cy::Functor(type, reinterpret_cast<void (*)()>(value)),
 425         sel_(sel)
 426     {
 427     }
 428 };
 429
 430 JSObjectRef CYMakeInstance(JSContextRef context, id object, bool transient) {
 431     Instance::Flags flags;
 432
 433     if (transient)
 434         flags = Instance::Transient;
 435     else {
 436         flags = Instance::None;
 437         object = [object retain];
 438     }
 439
 440     return Instance::Make(context, object, flags);
 441 }
 442
 443 @interface NSMethodSignature (Cycript)
 444 - (NSString *) _typeString;
 445 @end
 446
 447 @interface NSObject (Cycript)
 448
 449 - (JSValueRef) cy$valueOfInContext:(JSContextRef)context;
 450 - (JSType) cy$JSType;
 451
 452 - (JSValueRef) cy$toJSON:(NSString *)key inContext:(JSContextRef)context;
 453 - (NSString *) cy$toCYON:(bool)objective;
 454
 455 - (bool) cy$hasProperty:(NSString *)name;
 456 - (NSObject *) cy$getProperty:(NSString *)name;
 457 - (JSValueRef) cy$getProperty:(NSString *)name inContext:(JSContextRef)context;
 458 - (bool) cy$setProperty:(NSString *)name to:(NSObject *)value;
 459 - (bool) cy$deleteProperty:(NSString *)name;
 460 - (void) cy$getPropertyNames:(JSPropertyNameAccumulatorRef)names inContext:(JSContextRef)context;
 461
 462 + (bool) cy$hasImplicitProperties;
 463
 464 @end
 465
 466 @protocol Cycript
 467 - (id) cy$box;
 468 - (JSValueRef) cy$valueOfInContext:(JSContextRef)context;
 469 @end
 470
 471 NSString *CYCastNSCYON(id value, bool objective) {
 472     NSString *string;
 473
 474     if (value == nil)
 475         string = @"nil";
 476     else {
 477         Class _class(object_getClass(value));
 478         SEL sel(@selector(cy$toCYON:));
 479
 480         if (objc_method *toCYON = class_getInstanceMethod(_class, sel))
 481             string = reinterpret_cast<NSString *(*)(id, SEL, bool)>(method_getImplementation(toCYON))(value, sel, objective);
 482         else if (objc_method *methodSignatureForSelector = class_getInstanceMethod(_class, @selector(methodSignatureForSelector:))) {
 483             if (reinterpret_cast<NSMethodSignature *(*)(id, SEL, SEL)>(method_getImplementation(methodSignatureForSelector))(value, @selector(methodSignatureForSelector:), sel) != nil)
 484                 string = [value cy$toCYON:objective];
 485             else goto fail;
 486         } else fail: {
 487             if (false);
 488 #ifdef __APPLE__
 489             else if (value == NSZombie_)
 490                 string = @"_NSZombie_";
 491             else if (_class == NSZombie_)
 492                 string = [NSString stringWithFormat:@"<_NSZombie_: %p>", value];
 493             // XXX: frowny /in/ the pants
 494             else if (banned_.find(value) != banned_.end())
 495                 string = nil;
 496 #endif
 497             else
 498                 string = [NSString stringWithFormat:@"%@", value];
 499         }
 500
 501         // XXX: frowny pants
 502         if (string == nil)
 503             string = @"undefined";
 504     }
 505
 506     return string;
 507 }
 508
 509 #ifdef __APPLE__
 510 struct PropertyAttributes {
 511     CYPool pool_;
 512
 513     const char *name;
 514
 515     const char *variable;
 516
 517     const char *getter_;
 518     const char *setter_;
 519
 520     bool readonly;
 521     bool copy;
 522     bool retain;
 523     bool nonatomic;
 524     bool dynamic;
 525     bool weak;
 526     bool garbage;
 527
 528     PropertyAttributes(objc_property_t property) :
 529         variable(NULL),
 530         getter_(NULL),
 531         setter_(NULL),
 532         readonly(false),
 533         copy(false),
 534         retain(false),
 535         nonatomic(false),
 536         dynamic(false),
 537         weak(false),
 538         garbage(false)
 539     {
 540         name = property_getName(property);
 541         const char *attributes(property_getAttributes(property));
 542
 543         for (char *token(pool_.strdup(attributes)), *next; token != NULL; token = next) {
 544             if ((next = strchr(token, ',')) != NULL)
 545                 *next++ = '\0';
 546             switch (*token) {
 547                 case 'R': readonly = true; break;
 548                 case 'C': copy = true; break;
 549                 case '&': retain = true; break;
 550                 case 'N': nonatomic = true; break;
 551                 case 'G': getter_ = token + 1; break;
 552                 case 'S': setter_ = token + 1; break;
 553                 case 'V': variable = token + 1; break;
 554             }
 555         }
 556
 557         /*if (variable == NULL) {
 558             variable = property_getName(property);
 559             size_t size(strlen(variable));
 560             char *name(new(pool_) char[size + 2]);
 561             name[0] = '_';
 562             memcpy(name + 1, variable, size);
 563             name[size + 1] = '\0';
 564             variable = name;
 565         }*/
 566     }
 567
 568     const char *Getter() {
 569         if (getter_ == NULL)
 570             getter_ = pool_.strdup(name);
 571         return getter_;
 572     }
 573
 574     const char *Setter() {
 575         if (setter_ == NULL && !readonly) {
 576             size_t length(strlen(name));
 577
 578             char *temp(new(pool_) char[length + 5]);
 579             temp[0] = 's';
 580             temp[1] = 'e';
 581             temp[2] = 't';
 582
 583             if (length != 0) {
 584                 temp[3] = toupper(name[0]);
 585                 memcpy(temp + 4, name + 1, length - 1);
 586             }
 587
 588             temp[length + 3] = ':';
 589             temp[length + 4] = '\0';
 590             setter_ = temp;
 591         }
 592
 593         return setter_;
 594     }
 595
 596 };
 597 #endif
 598
 599 @interface CYWebUndefined : NSObject {
 600 }
 601
 602 + (CYWebUndefined *) undefined;
 603
 604 @end
 605
 606 @implementation CYWebUndefined
 607
 608 + (CYWebUndefined *) undefined {
 609     static CYWebUndefined *instance_([[CYWebUndefined alloc] init]);
 610     return instance_;
 611 }
 612
 613 @end
 614
 615 #define WebUndefined CYWebUndefined
 616
 617 /* Bridge: CYJSObject {{{ */
 618 @interface CYJSObject : NSMutableDictionary {
 619     JSObjectRef object_;
 620     JSGlobalContextRef context_;
 621 }
 622
 623 - (id) initWithJSObject:(JSObjectRef)object inContext:(JSContextRef)context;
 624
 625 - (NSUInteger) count;
 626 - (id) objectForKey:(id)key;
 627 - (NSEnumerator *) keyEnumerator;
 628 - (void) setObject:(id)object forKey:(id)key;
 629 - (void) removeObjectForKey:(id)key;
 630
 631 @end
 632 /* }}} */
 633 /* Bridge: CYJSArray {{{ */
 634 @interface CYJSArray : NSMutableArray {
 635     JSObjectRef object_;
 636     JSGlobalContextRef context_;
 637 }
 638
 639 - (id) initWithJSObject:(JSObjectRef)object inContext:(JSContextRef)context;
 640
 641 - (NSUInteger) count;
 642 - (id) objectAtIndex:(NSUInteger)index;
 643
 644 - (void) addObject:(id)anObject;
 645 - (void) insertObject:(id)anObject atIndex:(NSUInteger)index;
 646 - (void) removeLastObject;
 647 - (void) removeObjectAtIndex:(NSUInteger)index;
 648 - (void) replaceObjectAtIndex:(NSUInteger)index withObject:(id)anObject;
 649
 650 @end
 651 /* }}} */
 652
 653 _finline bool CYJSValueIsNSObject(JSContextRef context, JSValueRef value) {
 654     return JSValueIsObjectOfClass(context, value, Instance_) || JSValueIsObjectOfClass(context, value, FunctionInstance_);
 655 }
 656
 657 _finline bool CYJSValueIsInstanceOfCachedConstructor(JSContextRef context, JSValueRef value, JSStringRef cache) {
 658     return _jsccall(JSValueIsInstanceOfConstructor, context, value, CYGetCachedObject(context, cache));
 659 }
 660
 661 struct CYBlockDescriptor {
 662     struct {
 663         BlockDescriptor1 one_;
 664         BlockDescriptor2 two_;
 665         BlockDescriptor3 three_;
 666     } d_;
 667
 668     Closure_privateData *internal_;
 669 };
 670
 671 void CYDisposeBlock(BlockLiteral *literal) {
 672     delete reinterpret_cast<CYBlockDescriptor *>(literal->descriptor)->internal_;
 673 }
 674
 675 static JSValueRef BlockAdapter_(JSContextRef context, size_t count, JSValueRef values[], JSObjectRef function) {
 676     JSObjectRef _this(CYCastJSObject(context, values[0]));
 677     return CYCallAsFunction(context, function, _this, count - 1, values + 1);
 678 }
 679
 680 static void BlockClosure_(ffi_cif *cif, void *result, void **arguments, void *arg) {
 681     CYExecuteClosure(cif, result, arguments, arg, &BlockAdapter_);
 682 }
 683
 684 NSBlock *CYMakeBlock(JSContextRef context, JSObjectRef function, sig::Signature &signature) {
 685     _assert(__NSMallocBlock__ != Nil);
 686     BlockLiteral *literal(reinterpret_cast<BlockLiteral *>(malloc(sizeof(BlockLiteral))));
 687
 688     CYBlockDescriptor *descriptor(new CYBlockDescriptor);
 689     memset(&descriptor->d_, 0, sizeof(descriptor->d_));
 690
 691     descriptor->internal_ = CYMakeFunctor_(context, function, signature, &BlockClosure_);
 692     literal->invoke = reinterpret_cast<void (*)(void *, ...)>(descriptor->internal_->GetValue());
 693
 694     literal->isa = __NSMallocBlock__;
 695     literal->flags = BLOCK_HAS_SIGNATURE | BLOCK_HAS_COPY_DISPOSE | BLOCK_IS_GLOBAL;
 696     literal->reserved = 0;
 697     literal->descriptor = descriptor;
 698
 699     descriptor->d_.one_.size = sizeof(descriptor->d_);
 700     descriptor->d_.two_.dispose_helper = &CYDisposeBlock;
 701     descriptor->d_.three_.signature = sig::Unparse(*descriptor->internal_->pool_, &signature);
 702
 703     return reinterpret_cast<NSBlock *>(literal);
 704 }
 705
 706 NSObject *CYCastNSObject(CYPool *pool, JSContextRef context, JSObjectRef object) {
 707     if (CYJSValueIsNSObject(context, object)) {
 708         Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
 709         return internal->GetValue();
 710     }
 711
 712     bool array(CYJSValueIsInstanceOfCachedConstructor(context, object, Array_s));
 713     id value(array ? [CYJSArray alloc] : [CYJSObject alloc]);
 714     return CYPoolRelease(pool, [value initWithJSObject:object inContext:context]);
 715 }
 716
 717 NSNumber *CYCopyNSNumber(JSContextRef context, JSValueRef value) {
 718     return [[NSNumber alloc] initWithDouble:CYCastDouble(context, value)];
 719 }
 720
 721 #ifndef __APPLE__
 722 @interface NSBoolNumber : NSNumber {
 723 }
 724 @end
 725 #endif
 726
 727 id CYNSObject(CYPool *pool, JSContextRef context, JSValueRef value, bool cast) {
 728     id object;
 729     bool copy;
 730
 731     switch (JSType type = JSValueGetType(context, value)) {
 732         case kJSTypeUndefined:
 733             object = [WebUndefined undefined];
 734             copy = false;
 735         break;
 736
 737         case kJSTypeNull:
 738             return NULL;
 739         break;
 740
 741         case kJSTypeBoolean:
 742 #ifdef __APPLE__
 743             object = (id) (CYCastBool(context, value) ? kCFBooleanTrue : kCFBooleanFalse);
 744             copy = false;
 745 #else
 746             object = [[NSBoolNumber alloc] initWithBool:CYCastBool(context, value)];
 747             copy = true;
 748 #endif
 749         break;
 750
 751         case kJSTypeNumber:
 752             object = CYCopyNSNumber(context, value);
 753             copy = true;
 754         break;
 755
 756         case kJSTypeString:
 757             object = CYCopyNSString(context, value);
 758             copy = true;
 759         break;
 760
 761         case kJSTypeObject:
 762             // XXX: this might could be more efficient
 763             object = CYCastNSObject(pool, context, (JSObjectRef) value);
 764             copy = false;
 765         break;
 766
 767         default:
 768             throw CYJSError(context, "JSValueGetType() == 0x%x", type);
 769         break;
 770     }
 771
 772     if (cast != copy)
 773         return object;
 774     else if (copy)
 775         return CYPoolRelease(pool, object);
 776     else
 777         return [object retain];
 778 }
 779
 780 NSObject *CYCastNSObject(CYPool *pool, JSContextRef context, JSValueRef value) {
 781     return CYNSObject(pool, context, value, true);
 782 }
 783
 784 NSObject *CYCopyNSObject(CYPool &pool, JSContextRef context, JSValueRef value) {
 785     return CYNSObject(&pool, context, value, false);
 786 }
 787
 788 /* Bridge: NSArray {{{ */
 789 @implementation NSArray (Cycript)
 790
 791 - (id) cy$box {
 792     return [[self mutableCopy] autorelease];
 793 }
 794
 795 - (NSString *) cy$toCYON:(bool)objective {
 796     NSMutableString *json([[[NSMutableString alloc] init] autorelease]);
 797     [json appendString:@"@["];
 798
 799     bool comma(false);
 800 #ifdef __APPLE__
 801     for (id object in self) {
 802 #else
 803     for (size_t index(0), count([self count]); index != count; ++index) {
 804         id object([self objectAtIndex:index]);
 805 #endif
 806         if (comma)
 807             [json appendString:@","];
 808         else
 809             comma = true;
 810         if (object == nil || [object cy$JSType] != kJSTypeUndefined)
 811             [json appendString:CYCastNSCYON(object, true)];
 812         else {
 813             [json appendString:@","];
 814             comma = false;
 815         }
 816     }
 817
 818     [json appendString:@"]"];
 819     return json;
 820 }
 821
 822 - (bool) cy$hasProperty:(NSString *)name {
 823     if ([name isEqualToString:@"length"])
 824         return true;
 825
 826     size_t index(CYGetIndex(name));
 827     if (index == _not(size_t) || index >= [self count])
 828         return [super cy$hasProperty:name];
 829     else
 830         return true;
 831 }
 832
 833 - (NSObject *) cy$getProperty:(NSString *)name {
 834     size_t index(CYGetIndex(name));
 835     if (index == _not(size_t) || index >= [self count])
 836         return [super cy$getProperty:name];
 837     else
 838         return [self objectAtIndex:index];
 839 }
 840
 841 - (JSValueRef) cy$getProperty:(NSString *)name inContext:(JSContextRef)context {
 842     CYObjectiveTry_ {
 843         if ([name isEqualToString:@"length"])
 844             return CYCastJSValue(context, [self count]);
 845     } CYObjectiveCatch
 846
 847     return [super cy$getProperty:name inContext:context];
 848 }
 849
 850 - (void) cy$getPropertyNames:(JSPropertyNameAccumulatorRef)names inContext:(JSContextRef)context {
 851     [super cy$getPropertyNames:names inContext:context];
 852
 853     for (size_t index(0), count([self count]); index != count; ++index) {
 854         id object([self objectAtIndex:index]);
 855         if (object == nil || [object cy$JSType] != kJSTypeUndefined) {
 856             char name[32];
 857             sprintf(name, "%zu", index);
 858             JSPropertyNameAccumulatorAddName(names, CYJSString(name));
 859         }
 860     }
 861 }
 862
 863 + (bool) cy$hasImplicitProperties {
 864     return false;
 865 }
 866
 867 @end
 868 /* }}} */
 869 /* Bridge: NSBlock {{{ */
 870 #ifdef __APPLE__
 871 @interface NSBlock
 872 - (void) invoke;
 873 @end
 874 #endif
 875 /* }}} */
 876 /* Bridge: NSBoolNumber {{{ */
 877 #ifndef __APPLE__
 878 @implementation NSBoolNumber (Cycript)
 879
 880 - (JSType) cy$JSType {
 881     return kJSTypeBoolean;
 882 }
 883
 884 - (NSString *) cy$toCYON:(bool)objective {
 885     NSString *value([self boolValue] ? @"true" : @"false");
 886     return objective ? value : [NSString stringWithFormat:@"@%@", value];
 887 }
 888
 889 - (JSValueRef) cy$valueOfInContext:(JSContextRef)context { CYObjectiveTry_ {
 890     return CYCastJSValue(context, (bool) [self boolValue]);
 891 } CYObjectiveCatch }
 892
 893 @end
 894 #endif
 895 /* }}} */
 896 /* Bridge: NSDictionary {{{ */
 897 @implementation NSDictionary (Cycript)
 898
 899 - (id) cy$box {
 900     return [[self mutableCopy] autorelease];
 901 }
 902
 903 - (NSString *) cy$toCYON:(bool)objective {
 904     NSMutableString *json([[[NSMutableString alloc] init] autorelease]);
 905     [json appendString:@"@{"];
 906
 907     bool comma(false);
 908 #ifdef __APPLE__
 909     for (NSObject *key in self) {
 910 #else
 911     NSEnumerator *keys([self keyEnumerator]);
 912     while (NSObject *key = [keys nextObject]) {
 913 #endif
 914         if (comma)
 915             [json appendString:@","];
 916         else
 917             comma = true;
 918         [json appendString:CYCastNSCYON(key, true)];
 919         [json appendString:@":"];
 920         NSObject *object([self objectForKey:key]);
 921         [json appendString:CYCastNSCYON(object, true)];
 922     }
 923
 924     [json appendString:@"}"];
 925     return json;
 926 }
 927
 928 - (bool) cy$hasProperty:(NSString *)name {
 929     return [self objectForKey:name] != nil;
 930 }
 931
 932 - (NSObject *) cy$getProperty:(NSString *)name {
 933     return [self objectForKey:name];
 934 }
 935
 936 - (void) cy$getPropertyNames:(JSPropertyNameAccumulatorRef)names inContext:(JSContextRef)context {
 937     [super cy$getPropertyNames:names inContext:context];
 938
 939 #ifdef __APPLE__
 940     for (NSObject *key in self) {
 941 #else
 942     NSEnumerator *keys([self keyEnumerator]);
 943     while (NSObject *key = [keys nextObject]) {
 944 #endif
 945         JSPropertyNameAccumulatorAddName(names, CYJSString(context, key));
 946     }
 947 }
 948
 949 + (bool) cy$hasImplicitProperties {
 950     return false;
 951 }
 952
 953 @end
 954 /* }}} */
 955 /* Bridge: NSMutableArray {{{ */
 956 @implementation NSMutableArray (Cycript)
 957
 958 - (bool) cy$setProperty:(NSString *)name to:(NSObject *)value {
 959     if ([name isEqualToString:@"length"]) {
 960         // XXX: is this not intelligent?
 961         NSNumber *number(reinterpret_cast<NSNumber *>(value));
 962 #ifdef __APPLE__
 963         NSUInteger size([number unsignedIntegerValue]);
 964 #else
 965         NSUInteger size([number unsignedIntValue]);
 966 #endif
 967         NSUInteger count([self count]);
 968         if (size < count)
 969             [self removeObjectsInRange:NSMakeRange(size, count - size)];
 970         else if (size != count) {
 971             WebUndefined *undefined([WebUndefined undefined]);
 972             for (size_t i(count); i != size; ++i)
 973                 [self addObject:undefined];
 974         }
 975         return true;
 976     }
 977
 978     size_t index(CYGetIndex(name));
 979     if (index == _not(size_t))
 980         return [super cy$setProperty:name to:value];
 981
 982     id object(value ?: [NSNull null]);
 983
 984     size_t count([self count]);
 985     if (index < count)
 986         [self replaceObjectAtIndex:index withObject:object];
 987     else {
 988         if (index != count) {
 989             WebUndefined *undefined([WebUndefined undefined]);
 990             for (size_t i(count); i != index; ++i)
 991                 [self addObject:undefined];
 992         }
 993
 994         [self addObject:object];
 995     }
 996
 997     return true;
 998 }
 999
1000 - (bool) cy$deleteProperty:(NSString *)name {
1001     size_t index(CYGetIndex(name));
1002     if (index == _not(size_t) || index >= [self count])
1003         return [super cy$deleteProperty:name];
1004     [self replaceObjectAtIndex:index withObject:[WebUndefined undefined]];
1005     return true;
1006 }
1007
1008 @end
1009 /* }}} */
1010 /* Bridge: NSMutableDictionary {{{ */
1011 @implementation NSMutableDictionary (Cycript)
1012
1013 - (bool) cy$setProperty:(NSString *)name to:(NSObject *)value {
1014     [self setObject:(value ?: [NSNull null]) forKey:name];
1015     return true;
1016 }
1017
1018 - (bool) cy$deleteProperty:(NSString *)name {
1019     if ([self objectForKey:name] == nil)
1020         return false;
1021     else {
1022         [self removeObjectForKey:name];
1023         return true;
1024     }
1025 }
1026
1027 @end
1028 /* }}} */
1029 /* Bridge: NSNumber {{{ */
1030 @implementation NSNumber (Cycript)
1031
1032 - (JSType) cy$JSType {
1033 #ifdef __APPLE__
1034     // XXX: this just seems stupid
1035     if ([self class] == NSCFBoolean_)
1036         return kJSTypeBoolean;
1037 #endif
1038     return kJSTypeNumber;
1039 }
1040
1041 - (NSString *) cy$toCYON:(bool)objective {
1042     NSString *value([self cy$JSType] != kJSTypeBoolean ? [self stringValue] : [self boolValue] ? @"true" : @"false");
1043     return objective ? value : [NSString stringWithFormat:@"@%@", value];
1044 }
1045
1046 - (JSValueRef) cy$valueOfInContext:(JSContextRef)context { CYObjectiveTry_ {
1047     return [self cy$JSType] != kJSTypeBoolean ? CYCastJSValue(context, [self doubleValue]) : CYCastJSValue(context, static_cast<bool>([self boolValue]));
1048 } CYObjectiveCatch }
1049
1050 @end
1051 /* }}} */
1052 /* Bridge: NSNull {{{ */
1053 @implementation NSNull (Cycript)
1054
1055 - (JSType) cy$JSType {
1056     return kJSTypeNull;
1057 }
1058
1059 - (NSString *) cy$toCYON:(bool)objective {
1060     NSString *value(@"null");
1061     return objective ? value : [NSString stringWithFormat:@"@%@", value];
1062 }
1063
1064 - (JSValueRef) cy$valueOfInContext:(JSContextRef)context { CYObjectiveTry_ {
1065     return CYJSNull(context);
1066 } CYObjectiveCatch }
1067
1068 @end
1069 /* }}} */
1070 /* Bridge: NSObject {{{ */
1071 @implementation NSObject (Cycript)
1072
1073 - (id) cy$box {
1074     return self;
1075 }
1076
1077 - (JSValueRef) cy$toJSON:(NSString *)key inContext:(JSContextRef)context {
1078     return [self cy$valueOfInContext:context];
1079 }
1080
1081 - (JSValueRef) cy$valueOfInContext:(JSContextRef)context { CYObjectiveTry_ {
1082     return NULL;
1083 } CYObjectiveCatch }
1084
1085 - (JSType) cy$JSType {
1086     return kJSTypeObject;
1087 }
1088
1089 - (NSString *) cy$toCYON:(bool)objective {
1090     return [@"#" stringByAppendingString:[[self description] cy$toCYON:true]];
1091 }
1092
1093 - (bool) cy$hasProperty:(NSString *)name {
1094     return false;
1095 }
1096
1097 - (NSObject *) cy$getProperty:(NSString *)name {
1098     return nil;
1099 }
1100
1101 - (JSValueRef) cy$getProperty:(NSString *)name inContext:(JSContextRef)context { CYObjectiveTry_ {
1102     if (NSObject *value = [self cy$getProperty:name])
1103         return CYCastJSValue(context, value);
1104     return NULL;
1105 } CYObjectiveCatch }
1106
1107 - (bool) cy$setProperty:(NSString *)name to:(NSObject *)value {
1108     return false;
1109 }
1110
1111 - (bool) cy$deleteProperty:(NSString *)name {
1112     return false;
1113 }
1114
1115 - (void) cy$getPropertyNames:(JSPropertyNameAccumulatorRef)names inContext:(JSContextRef)context {
1116 }
1117
1118 + (bool) cy$hasImplicitProperties {
1119     return true;
1120 }
1121
1122 @end
1123 /* }}} */
1124 /* Bridge: NSProxy {{{ */
1125 @implementation NSProxy (Cycript)
1126
1127 - (NSString *) cy$toCYON:(bool)objective {
1128     return [[self description] cy$toCYON:objective];
1129 }
1130
1131 @end
1132 /* }}} */
1133 /* Bridge: NSSet {{{ */
1134 @implementation NSSet (Cycript)
1135
1136 - (NSString *) cy$toCYON:(bool)objective {
1137     NSMutableString *json([[[NSMutableString alloc] init] autorelease]);
1138     [json appendString:@"[NSSet setWithArray:"];
1139     [json appendString:CYCastNSCYON([self allObjects], true)];
1140     [json appendString:@"]]"];
1141     return json;
1142 }
1143
1144 @end
1145 /* }}} */
1146 /* Bridge: NSString {{{ */
1147 @implementation NSString (Cycript)
1148
1149 - (id) cy$box {
1150     return [[self copy] autorelease];
1151 }
1152
1153 - (JSType) cy$JSType {
1154     return kJSTypeString;
1155 }
1156
1157 - (NSString *) cy$toCYON:(bool)objective {
1158     std::ostringstream str;
1159     if (!objective)
1160         str << '@';
1161     CYUTF8String string(CYCastUTF8String(self));
1162     CYStringify(str, string.data, string.size);
1163     std::string value(str.str());
1164     return CYCastNSString(NULL, CYUTF8String(value.c_str(), value.size()));
1165 }
1166
1167 - (bool) cy$hasProperty:(NSString *)name {
1168     size_t index(CYGetIndex(name));
1169     if (index == _not(size_t) || index >= [self length])
1170         return [super cy$hasProperty:name];
1171     else
1172         return true;
1173 }
1174
1175 - (NSObject *) cy$getProperty:(NSString *)name {
1176     size_t index(CYGetIndex(name));
1177     if (index == _not(size_t) || index >= [self length])
1178         return [super cy$getProperty:name];
1179     else
1180         return [self substringWithRange:NSMakeRange(index, 1)];
1181 }
1182
1183 - (void) cy$getPropertyNames:(JSPropertyNameAccumulatorRef)names inContext:(JSContextRef)context {
1184     [super cy$getPropertyNames:names inContext:context];
1185
1186     for (size_t index(0), length([self length]); index != length; ++index) {
1187         char name[32];
1188         sprintf(name, "%zu", index);
1189         JSPropertyNameAccumulatorAddName(names, CYJSString(name));
1190     }
1191 }
1192
1193 - (JSValueRef) cy$valueOfInContext:(JSContextRef)context { CYObjectiveTry_ {
1194     return CYCastJSValue(context, CYJSString(context, self));
1195 } CYObjectiveCatch }
1196
1197 @end
1198 /* }}} */
1199 /* Bridge: WebUndefined {{{ */
1200 @implementation WebUndefined (Cycript)
1201
1202 - (JSType) cy$JSType {
1203     return kJSTypeUndefined;
1204 }
1205
1206 - (NSString *) cy$toCYON:(bool)objective {
1207     NSString *value(@"undefined");
1208     return value; // XXX: maybe use the below code, adding @undefined?
1209     //return objective ? value : [NSString stringWithFormat:@"@%@", value];
1210 }
1211
1212 - (JSValueRef) cy$valueOfInContext:(JSContextRef)context { CYObjectiveTry_ {
1213     return CYJSUndefined(context);
1214 } CYObjectiveCatch }
1215
1216 @end
1217 /* }}} */
1218
1219 static bool CYIsClass(id self) {
1220 #ifdef __APPLE__
1221     return class_isMetaClass(object_getClass(self));
1222 #else
1223     return GSObjCIsClass(self);
1224 #endif
1225 }
1226
1227 Class CYCastClass(CYPool &pool, JSContextRef context, JSValueRef value) {
1228     id self(CYCastNSObject(&pool, context, value));
1229     if (CYIsClass(self))
1230         return (Class) self;
1231     throw CYJSError(context, "got something that is not a Class");
1232     return NULL;
1233 }
1234
1235 NSArray *CYCastNSArray(JSContextRef context, JSPropertyNameArrayRef names) {
1236     CYPool pool;
1237     size_t size(JSPropertyNameArrayGetCount(names));
1238     NSMutableArray *array([NSMutableArray arrayWithCapacity:size]);
1239     for (size_t index(0); index != size; ++index)
1240         [array addObject:CYCastNSString(&pool, context, JSPropertyNameArrayGetNameAtIndex(names, index))];
1241     return array;
1242 }
1243
1244 JSValueRef CYCastJSValue(JSContextRef context, NSObject *value) { CYPoolTry {
1245     if (value == nil)
1246         return CYJSNull(context);
1247     else
1248         return CYMakeInstance(context, value, false);
1249 } CYPoolCatch(NULL) return /*XXX*/ NULL; }
1250
1251 @implementation CYJSObject
1252
1253 - (id) initWithJSObject:(JSObjectRef)object inContext:(JSContextRef)context { CYObjectiveTry_ {
1254     if ((self = [super init]) != nil) {
1255         object_ = object;
1256         context_ = CYGetJSContext(context);
1257         JSGlobalContextRetain(context_);
1258         JSValueProtect(context_, object_);
1259     } return self;
1260 } CYObjectiveCatch }
1261
1262 - (void) dealloc { CYObjectiveTry {
1263     JSValueUnprotect(context_, object_);
1264     JSGlobalContextRelease(context_);
1265     [super dealloc];
1266 } CYObjectiveCatch }
1267
1268 - (NSString *) cy$toCYON:(bool)objective { CYObjectiveTry {
1269     CYPool pool;
1270     const char *cyon(CYPoolCCYON(pool, context, object_));
1271     if (cyon == NULL)
1272         return [super cy$toCYON:objective];
1273     else
1274         return [NSString stringWithUTF8String:cyon];
1275 } CYObjectiveCatch }
1276
1277 - (NSUInteger) count { CYObjectiveTry {
1278     JSPropertyNameArrayRef names(JSObjectCopyPropertyNames(context, object_));
1279     size_t size(JSPropertyNameArrayGetCount(names));
1280     JSPropertyNameArrayRelease(names);
1281     return size;
1282 } CYObjectiveCatch }
1283
1284 - (id) objectForKey:(id)key { CYObjectiveTry {
1285     JSValueRef value(CYGetProperty(context, object_, CYJSString(context, (NSObject *) key)));
1286     if (JSValueIsUndefined(context, value))
1287         return nil;
1288     return CYCastNSObject(NULL, context, value) ?: [NSNull null];
1289 } CYObjectiveCatch }
1290
1291 - (NSEnumerator *) keyEnumerator { CYObjectiveTry {
1292     JSPropertyNameArrayRef names(JSObjectCopyPropertyNames(context, object_));
1293     NSEnumerator *enumerator([CYCastNSArray(context, names) objectEnumerator]);
1294     JSPropertyNameArrayRelease(names);
1295     return enumerator;
1296 } CYObjectiveCatch }
1297
1298 - (void) setObject:(id)object forKey:(id)key { CYObjectiveTry {
1299     CYSetProperty(context, object_, CYJSString(context, (NSObject *) key), CYCastJSValue(context, (NSString *) object));
1300 } CYObjectiveCatch }
1301
1302 - (void) removeObjectForKey:(id)key { CYObjectiveTry {
1303     (void) _jsccall(JSObjectDeleteProperty, context, object_, CYJSString(context, (NSObject *) key));
1304 } CYObjectiveCatch }
1305
1306 @end
1307
1308 @implementation CYJSArray
1309
1310 - (NSString *) cy$toCYON:(bool)objective { CYObjectiveTry {
1311     CYPool pool;
1312     return [NSString stringWithUTF8String:CYPoolCCYON(pool, context, object_)];
1313 } CYObjectiveCatch }
1314
1315 - (id) initWithJSObject:(JSObjectRef)object inContext:(JSContextRef)context { CYObjectiveTry_ {
1316     if ((self = [super init]) != nil) {
1317         object_ = object;
1318         context_ = CYGetJSContext(context);
1319         JSGlobalContextRetain(context_);
1320         JSValueProtect(context_, object_);
1321     } return self;
1322 } CYObjectiveCatch }
1323
1324 - (void) dealloc { CYObjectiveTry {
1325     JSValueUnprotect(context_, object_);
1326     JSGlobalContextRelease(context_);
1327     [super dealloc];
1328 } CYObjectiveCatch }
1329
1330 - (NSUInteger) count { CYObjectiveTry {
1331     return CYArrayLength(context, object_);
1332 } CYObjectiveCatch }
1333
1334 - (id) objectAtIndex:(NSUInteger)index { CYObjectiveTry {
1335     size_t bounds([self count]);
1336     if (index >= bounds)
1337         @throw [NSException exceptionWithName:NSRangeException reason:[NSString stringWithFormat:@"*** -[CYJSArray objectAtIndex:]: index (%zu) beyond bounds (%zu)", static_cast<size_t>(index), bounds] userInfo:nil];
1338     JSValueRef value(_jsccall(JSObjectGetPropertyAtIndex, context, object_, index));
1339     return CYCastNSObject(NULL, context, value) ?: [NSNull null];
1340 } CYObjectiveCatch }
1341
1342 - (void) addObject:(id)object { CYObjectiveTry {
1343     CYArrayPush(context, object_, CYCastJSValue(context, (NSObject *) object));
1344 } CYObjectiveCatch }
1345
1346 - (void) insertObject:(id)object atIndex:(NSUInteger)index { CYObjectiveTry {
1347     size_t bounds([self count] + 1);
1348     if (index >= bounds)
1349         @throw [NSException exceptionWithName:NSRangeException reason:[NSString stringWithFormat:@"*** -[CYJSArray insertObject:atIndex:]: index (%zu) beyond bounds (%zu)", static_cast<size_t>(index), bounds] userInfo:nil];
1350     JSValueRef arguments[3];
1351     arguments[0] = CYCastJSValue(context, index);
1352     arguments[1] = CYCastJSValue(context, 0);
1353     arguments[2] = CYCastJSValue(context, (NSObject *) object);
1354     JSObjectRef Array(CYGetCachedObject(context, CYJSString("Array_prototype")));
1355     _jsccall(JSObjectCallAsFunction, context, CYCastJSObject(context, CYGetProperty(context, Array, splice_s)), object_, 3, arguments);
1356 } CYObjectiveCatch }
1357
1358 - (void) removeLastObject { CYObjectiveTry {
1359     JSObjectRef Array(CYGetCachedObject(context, CYJSString("Array_prototype")));
1360     _jsccall(JSObjectCallAsFunction, context, CYCastJSObject(context, CYGetProperty(context, Array, pop_s)), object_, 0, NULL);
1361 } CYObjectiveCatch }
1362
1363 - (void) removeObjectAtIndex:(NSUInteger)index { CYObjectiveTry {
1364     size_t bounds([self count]);
1365     if (index >= bounds)
1366         @throw [NSException exceptionWithName:NSRangeException reason:[NSString stringWithFormat:@"*** -[CYJSArray removeObjectAtIndex:]: index (%zu) beyond bounds (%zu)", static_cast<size_t>(index), bounds] userInfo:nil];
1367     JSValueRef arguments[2];
1368     arguments[0] = CYCastJSValue(context, index);
1369     arguments[1] = CYCastJSValue(context, 1);
1370     JSObjectRef Array(CYGetCachedObject(context, CYJSString("Array_prototype")));
1371     _jsccall(JSObjectCallAsFunction, context, CYCastJSObject(context, CYGetProperty(context, Array, splice_s)), object_, 2, arguments);
1372 } CYObjectiveCatch }
1373
1374 - (void) replaceObjectAtIndex:(NSUInteger)index withObject:(id)object { CYObjectiveTry {
1375     size_t bounds([self count]);
1376     if (index >= bounds)
1377         @throw [NSException exceptionWithName:NSRangeException reason:[NSString stringWithFormat:@"*** -[CYJSArray replaceObjectAtIndex:withObject:]: index (%zu) beyond bounds (%zu)", static_cast<size_t>(index), bounds] userInfo:nil];
1378     CYSetProperty(context, object_, index, CYCastJSValue(context, (NSObject *) object));
1379 } CYObjectiveCatch }
1380
1381 @end
1382
1383 // XXX: inherit from or replace with CYJSObject
1384 @interface CYInternal : NSObject {
1385     JSGlobalContextRef context_;
1386     JSObjectRef object_;
1387 }
1388
1389 @end
1390
1391 @implementation CYInternal
1392
1393 - (void) dealloc { CYObjectiveTry {
1394     JSValueUnprotect(context_, object_);
1395     JSGlobalContextRelease(context_);
1396     [super dealloc];
1397 } CYObjectiveCatch }
1398
1399 - (id) initInContext:(JSContextRef)context { CYObjectiveTry_ {
1400     if ((self = [super init]) != nil) {
1401         context_ = CYGetJSContext(context);
1402         JSGlobalContextRetain(context_);
1403     } return self;
1404 } CYObjectiveCatch }
1405
1406 - (bool) hasProperty:(JSStringRef)name inContext:(JSContextRef)context {
1407     if (object_ == NULL)
1408         return false;
1409
1410     return JSObjectHasProperty(context, object_, name);
1411 }
1412
1413 - (JSValueRef) getProperty:(JSStringRef)name inContext:(JSContextRef)context {
1414     if (object_ == NULL)
1415         return NULL;
1416
1417     return CYGetProperty(context, object_, name);
1418 }
1419
1420 - (void) setProperty:(JSStringRef)name toValue:(JSValueRef)value inContext:(JSContextRef)context {
1421     @synchronized (self) {
1422         if (object_ == NULL) {
1423             object_ = JSObjectMake(context, NULL, NULL);
1424             JSValueProtect(context, object_);
1425         }
1426     }
1427
1428     CYSetProperty(context, object_, name, value);
1429 }
1430
1431 + (CYInternal *) get:(id)object {
1432     if ($objc_getAssociatedObject == NULL)
1433         return nil;
1434
1435     @synchronized (object) {
1436         if (CYInternal *internal = $objc_getAssociatedObject(object, @selector(cy$internal)))
1437             return internal;
1438     }
1439
1440     return nil;
1441 }
1442
1443 + (CYInternal *) set:(id)object inContext:(JSContextRef)context {
1444     if ($objc_getAssociatedObject == NULL)
1445         return nil;
1446
1447     @synchronized (object) {
1448         if (CYInternal *internal = $objc_getAssociatedObject(object, @selector(cy$internal)))
1449             return internal;
1450
1451         if ($objc_setAssociatedObject == NULL)
1452             return nil;
1453
1454         CYInternal *internal([[[CYInternal alloc] initInContext:context] autorelease]);
1455         objc_setAssociatedObject(object, @selector(cy$internal), internal, OBJC_ASSOCIATION_RETAIN_NONATOMIC);
1456         return internal;
1457     }
1458
1459     return nil;
1460 }
1461
1462 @end
1463
1464 static JSObjectRef CYMakeSelector(JSContextRef context, SEL sel) {
1465     Selector_privateData *internal(new Selector_privateData(sel));
1466     return JSObjectMake(context, Selector_, internal);
1467 }
1468
1469 static SEL CYCastSEL(JSContextRef context, JSValueRef value) {
1470     if (JSValueIsObjectOfClass(context, value, Selector_)) {
1471         Selector_privateData *internal(reinterpret_cast<Selector_privateData *>(JSObjectGetPrivate((JSObjectRef) value)));
1472         return reinterpret_cast<SEL>(internal->value_);
1473     } else {
1474         CYPool pool;
1475         return sel_registerName(CYPoolCString(pool, context, value));
1476     }
1477 }
1478
1479 void *CYObjectiveC_ExecuteStart(JSContextRef context) { CYSadTry {
1480     return (void *) [[NSAutoreleasePool alloc] init];
1481 } CYSadCatch(NULL) }
1482
1483 void CYObjectiveC_ExecuteEnd(JSContextRef context, void *handle) { CYSadTry {
1484     return [(NSAutoreleasePool *) handle release];
1485 } CYSadCatch() }
1486
1487 JSValueRef CYObjectiveC_RuntimeProperty(JSContextRef context, CYUTF8String name) { CYPoolTry {
1488     if (name == "nil")
1489         return Instance::Make(context, nil);
1490     if (Class _class = objc_getClass(name.data))
1491         return CYMakeInstance(context, _class, true);
1492     if (Protocol *protocol = objc_getProtocol(name.data))
1493         return CYMakeInstance(context, protocol, true);
1494     return NULL;
1495 } CYPoolCatch(NULL) return /*XXX*/ NULL; }
1496
1497 static void CYObjectiveC_CallFunction(JSContextRef context, ffi_cif *cif, void (*function)(), uint8_t *value, void **values) { CYSadTry {
1498     ffi_call(cif, function, value, values);
1499 } CYSadCatch() }
1500
1501 static NSBlock *CYCastNSBlock(CYPool &pool, JSContextRef context, JSValueRef value, sig::Signature *signature) {
1502     if (JSValueIsNull(context, value))
1503         return nil;
1504     JSObjectRef object(CYCastJSObject(context, value));
1505
1506     if (JSValueIsObjectOfClass(context, object, FunctionInstance_))
1507         return reinterpret_cast<Instance *>(JSObjectGetPrivate(object))->GetValue();
1508
1509     if (JSValueIsObjectOfClass(context, object, Instance_)) {
1510         _assert(reinterpret_cast<Instance *>(JSObjectGetPrivate(object))->GetValue() == nil);
1511         return nil;
1512     }
1513
1514     _assert(JSObjectIsFunction(context, object));
1515
1516     _assert(signature != NULL);
1517     _assert(signature->count != 0);
1518
1519     sig::Signature modified;
1520     modified.count = signature->count + 1;
1521     modified.elements = new(pool) sig::Element[modified.count];
1522
1523     modified.elements[0] = signature->elements[0];
1524     memcpy(modified.elements + 2, signature->elements + 1, sizeof(sig::Element) * (signature->count - 1));
1525
1526     modified.elements[1].name = NULL;
1527     modified.elements[1].type = new(pool) sig::Type();
1528     modified.elements[1].offset = _not(size_t);
1529
1530     memset(modified.elements[1].type, 0, sizeof(sig::Type));
1531     modified.elements[1].type->primitive = sig::object_P;
1532
1533     return CYMakeBlock(context, object, modified);
1534 }
1535
1536 static bool CYObjectiveC_PoolFFI(CYPool *pool, JSContextRef context, sig::Type *type, ffi_type *ffi, void *data, JSValueRef value) { CYSadTry {
1537     // XXX: assigning to an indirect id * works for return values, but not for properties and fields
1538
1539     switch (type->primitive) {
1540         case sig::block_P:
1541             // XXX: this function might not handle the idea of a null pool
1542             *reinterpret_cast<id *>(data) = CYCastNSBlock(*pool, context, value, &type->data.signature);
1543         break;
1544
1545         case sig::object_P:
1546         case sig::typename_P:
1547             *reinterpret_cast<id *>(data) = CYCastNSObject(pool, context, value);
1548         break;
1549
1550         case sig::selector_P:
1551             *reinterpret_cast<SEL *>(data) = CYCastSEL(context, value);
1552         break;
1553
1554         default:
1555             return false;
1556     }
1557
1558     return true;
1559 } CYSadCatch(false) }
1560
1561 static JSValueRef CYObjectiveC_FromFFI(JSContextRef context, sig::Type *type, ffi_type *ffi, void *data, bool initialize, JSObjectRef owner) { CYPoolTry {
1562     switch (type->primitive) {
1563         // XXX: do something epic about blocks
1564         case sig::block_P:
1565         case sig::object_P:
1566             if (NSObject *object = *reinterpret_cast<NSObject **>(data)) {
1567                 JSValueRef value(CYCastJSValue(context, object));
1568                 if (initialize)
1569                     [object release];
1570                 return value;
1571             } else goto null;
1572
1573         case sig::typename_P:
1574             return CYMakeInstance(context, *reinterpret_cast<Class *>(data), true);
1575
1576         case sig::selector_P:
1577             if (SEL sel = *reinterpret_cast<SEL *>(data))
1578                 return CYMakeSelector(context, sel);
1579             else goto null;
1580
1581         null:
1582             return CYJSNull(context);
1583         default:
1584             return NULL;
1585     }
1586 } CYPoolCatch(NULL) return /*XXX*/ NULL; }
1587
1588 static bool CYImplements(id object, Class _class, SEL selector, bool devoid = false) {
1589     if (objc_method *method = class_getInstanceMethod(_class, selector)) {
1590         if (!devoid)
1591             return true;
1592 #if OBJC_API_VERSION >= 2
1593         char type[16];
1594         method_getReturnType(method, type, sizeof(type));
1595 #else
1596         const char *type(method_getTypeEncoding(method));
1597 #endif
1598         if (type[0] != 'v')
1599             return true;
1600     }
1601
1602     // XXX: possibly use a more "awesome" check?
1603     return false;
1604 }
1605
1606 static JSValueRef MessageAdapter_(JSContextRef context, size_t count, JSValueRef values[], JSObjectRef function) {
1607     JSObjectRef _this(CYCastJSObject(context, values[0]));
1608     return CYCallAsFunction(context, function, _this, count - 2, values + 2);
1609 }
1610
1611 static void MessageClosure_(ffi_cif *cif, void *result, void **arguments, void *arg) {
1612     CYExecuteClosure(cif, result, arguments, arg, &MessageAdapter_);
1613 }
1614
1615 static JSObjectRef CYMakeMessage(JSContextRef context, SEL sel, IMP imp, const char *type) {
1616     Message_privateData *internal(new Message_privateData(sel, type, imp));
1617     return JSObjectMake(context, Message_, internal);
1618 }
1619
1620 static IMP CYMakeMessage(JSContextRef context, JSValueRef value, const char *encoding) {
1621     JSObjectRef function(CYCastJSObject(context, value));
1622     CYPool pool;
1623     sig::Signature signature;
1624     sig::Parse(pool, &signature, encoding, &Structor_);
1625     Closure_privateData *internal(CYMakeFunctor_(context, function, signature, &MessageClosure_));
1626     // XXX: see notes in Library.cpp about needing to leak
1627     return reinterpret_cast<IMP>(internal->GetValue());
1628 }
1629
1630 static bool Messages_hasProperty(JSContextRef context, JSObjectRef object, JSStringRef property) {
1631     Messages *internal(reinterpret_cast<Messages *>(JSObjectGetPrivate(object)));
1632     Class _class(internal->GetValue());
1633
1634     CYPool pool;
1635     const char *name(CYPoolCString(pool, context, property));
1636
1637     if (SEL sel = sel_getUid(name))
1638         if (class_getInstanceMethod(_class, sel) != NULL)
1639             return true;
1640
1641     return false;
1642 }
1643
1644 static JSValueRef Messages_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
1645     Messages *internal(reinterpret_cast<Messages *>(JSObjectGetPrivate(object)));
1646     Class _class(internal->GetValue());
1647
1648     CYPool pool;
1649     const char *name(CYPoolCString(pool, context, property));
1650
1651     if (SEL sel = sel_getUid(name))
1652         if (objc_method *method = class_getInstanceMethod(_class, sel))
1653             return CYMakeMessage(context, sel, method_getImplementation(method), method_getTypeEncoding(method));
1654
1655     return NULL;
1656 } CYCatch(NULL) }
1657
1658 static bool Messages_setProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef value, JSValueRef *exception) { CYTry {
1659     Messages *internal(reinterpret_cast<Messages *>(JSObjectGetPrivate(object)));
1660     Class _class(internal->GetValue());
1661
1662     CYPool pool;
1663     const char *name(CYPoolCString(pool, context, property));
1664     SEL sel(sel_registerName(name));
1665
1666     const char *type;
1667     IMP imp;
1668
1669     if (JSValueIsObjectOfClass(context, value, Message_)) {
1670         Message_privateData *message(reinterpret_cast<Message_privateData *>(JSObjectGetPrivate((JSObjectRef) value)));
1671         type = sig::Unparse(pool, &message->signature_);
1672         imp = reinterpret_cast<IMP>(message->GetValue());
1673     } else if (objc_method *method = class_getInstanceMethod(_class, sel)) {
1674         type = method_getTypeEncoding(method);
1675         imp = CYMakeMessage(context, value, type);
1676     } else _assert(false);
1677
1678     objc_method *method(NULL);
1679 #if OBJC_API_VERSION >= 2
1680     unsigned int size;
1681     objc_method **methods(class_copyMethodList(_class, &size));
1682     for (size_t i(0); i != size; ++i)
1683         if (sel_isEqual(method_getName(methods[i]), sel)) {
1684             method = methods[i];
1685             break;
1686         }
1687     free(methods);
1688 #else
1689     for (objc_method_list *methods(_class->methods); methods != NULL; methods = methods->method_next)
1690         for (int i(0); i != methods->method_count; ++i)
1691             if (sel_isEqual(method_getName(&methods->method_list[i]), sel)) {
1692                 method = &methods->method_list[i];
1693                 break;
1694             }
1695 #endif
1696
1697     if (method != NULL)
1698         method_setImplementation(method, imp);
1699     else {
1700 #ifdef GNU_RUNTIME
1701         GSMethodList list(GSAllocMethodList(1));
1702         GSAppendMethodToList(list, sel, type, imp, YES);
1703         GSAddMethodList(_class, list, YES);
1704         GSFlushMethodCacheForClass(_class);
1705 #else
1706         class_addMethod(_class, sel, imp, type);
1707 #endif
1708     }
1709
1710     return true;
1711 } CYCatch(false) }
1712
1713 #if 0 && OBJC_API_VERSION < 2
1714 static bool Messages_deleteProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
1715     Messages *internal(reinterpret_cast<Messages *>(JSObjectGetPrivate(object)));
1716     Class _class(internal->GetValue());
1717
1718     CYPool pool;
1719     const char *name(CYPoolCString(pool, context, property));
1720
1721     if (SEL sel = sel_getUid(name))
1722         if (objc_method *method = class_getInstanceMethod(_class, sel)) {
1723             objc_method_list list = {NULL, 1, {method}};
1724             class_removeMethods(_class, &list);
1725             return true;
1726         }
1727
1728     return false;
1729 } CYCatch(false) }
1730 #endif
1731
1732 static void Messages_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
1733     Messages *internal(reinterpret_cast<Messages *>(JSObjectGetPrivate(object)));
1734     Class _class(internal->GetValue());
1735
1736 #if OBJC_API_VERSION >= 2
1737     unsigned int size;
1738     objc_method **data(class_copyMethodList(_class, &size));
1739     for (size_t i(0); i != size; ++i)
1740         JSPropertyNameAccumulatorAddName(names, CYJSString(sel_getName(method_getName(data[i]))));
1741     free(data);
1742 #else
1743     for (objc_method_list *methods(_class->methods); methods != NULL; methods = methods->method_next)
1744         for (int i(0); i != methods->method_count; ++i)
1745             JSPropertyNameAccumulatorAddName(names, CYJSString(sel_getName(method_getName(&methods->method_list[i]))));
1746 #endif
1747 }
1748
1749 static bool CYHasImplicitProperties(Class _class) {
1750     // XXX: this is an evil hack to deal with NSProxy; fix elsewhere
1751     if (!CYImplements(_class, object_getClass(_class), @selector(cy$hasImplicitProperties)))
1752         return true;
1753     return [_class cy$hasImplicitProperties];
1754 }
1755
1756 static bool Instance_hasProperty(JSContextRef context, JSObjectRef object, JSStringRef property) {
1757     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
1758     id self(internal->GetValue());
1759
1760     if (JSStringIsEqualToUTF8CString(property, "$cyi"))
1761         return true;
1762
1763     CYPool pool;
1764     NSString *name(CYCastNSString(&pool, context, property));
1765
1766     if (CYInternal *internal = [CYInternal get:self])
1767         if ([internal hasProperty:property inContext:context])
1768             return true;
1769
1770     Class _class(object_getClass(self));
1771
1772     CYPoolTry {
1773         // XXX: this is an evil hack to deal with NSProxy; fix elsewhere
1774         if (CYImplements(self, _class, @selector(cy$hasProperty:)))
1775             if ([self cy$hasProperty:name])
1776                 return true;
1777     } CYPoolCatch(false)
1778
1779     const char *string(CYPoolCString(pool, context, name));
1780
1781 #ifdef __APPLE__
1782     if (class_getProperty(_class, string) != NULL)
1783         return true;
1784 #endif
1785
1786     if (CYHasImplicitProperties(_class))
1787         if (SEL sel = sel_getUid(string))
1788             if (CYImplements(self, _class, sel, true))
1789                 return true;
1790
1791     return false;
1792 }
1793
1794 static JSValueRef Instance_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
1795     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
1796     id self(internal->GetValue());
1797
1798     if (JSStringIsEqualToUTF8CString(property, "$cyi"))
1799         return Internal::Make(context, self, object);
1800
1801     CYPool pool;
1802     NSString *name(CYCastNSString(&pool, context, property));
1803
1804     if (CYInternal *internal = [CYInternal get:self])
1805         if (JSValueRef value = [internal getProperty:property inContext:context])
1806             return value;
1807
1808     CYPoolTry {
1809         if (JSValueRef value = [self cy$getProperty:name inContext:context])
1810             return value;
1811     } CYPoolCatch(NULL)
1812
1813     const char *string(CYPoolCString(pool, context, name));
1814     Class _class(object_getClass(self));
1815
1816 #ifdef __APPLE__
1817     if (objc_property_t property = class_getProperty(_class, string)) {
1818         PropertyAttributes attributes(property);
1819         SEL sel(sel_registerName(attributes.Getter()));
1820         return CYSendMessage(pool, context, self, NULL, sel, 0, NULL, false);
1821     }
1822 #endif
1823
1824     if (CYHasImplicitProperties(_class))
1825         if (SEL sel = sel_getUid(string))
1826             if (CYImplements(self, _class, sel, true))
1827                 return CYSendMessage(pool, context, self, NULL, sel, 0, NULL, false);
1828
1829     return NULL;
1830 } CYCatch(NULL) }
1831
1832 static bool Instance_setProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef value, JSValueRef *exception) { CYTry {
1833     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
1834     id self(internal->GetValue());
1835
1836     CYPool pool;
1837
1838     NSString *name(CYCastNSString(&pool, context, property));
1839     NSObject *data(CYCastNSObject(&pool, context, value));
1840
1841     CYPoolTry {
1842         if ([self cy$setProperty:name to:data])
1843             return true;
1844     } CYPoolCatch(false)
1845
1846     const char *string(CYPoolCString(pool, context, name));
1847     Class _class(object_getClass(self));
1848
1849 #ifdef __APPLE__
1850     if (objc_property_t property = class_getProperty(_class, string)) {
1851         PropertyAttributes attributes(property);
1852         if (const char *setter = attributes.Setter()) {
1853             SEL sel(sel_registerName(setter));
1854             JSValueRef arguments[1] = {value};
1855             CYSendMessage(pool, context, self, NULL, sel, 1, arguments, false);
1856             return true;
1857         }
1858     }
1859 #endif
1860
1861     size_t length(strlen(string));
1862
1863     char set[length + 5];
1864
1865     set[0] = 's';
1866     set[1] = 'e';
1867     set[2] = 't';
1868
1869     if (string[0] != '\0') {
1870         set[3] = toupper(string[0]);
1871         memcpy(set + 4, string + 1, length - 1);
1872     }
1873
1874     set[length + 3] = ':';
1875     set[length + 4] = '\0';
1876
1877     if (SEL sel = sel_getUid(set))
1878         if (CYImplements(self, _class, sel)) {
1879             JSValueRef arguments[1] = {value};
1880             CYSendMessage(pool, context, self, NULL, sel, 1, arguments, false);
1881             return true;
1882         }
1883
1884     if (CYInternal *internal = [CYInternal set:self inContext:context]) {
1885         [internal setProperty:property toValue:value inContext:context];
1886         return true;
1887     }
1888
1889     return false;
1890 } CYCatch(false) }
1891
1892 static bool Instance_deleteProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
1893     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
1894     id self(internal->GetValue());
1895
1896     CYPoolTry {
1897         NSString *name(CYCastNSString(NULL, context, property));
1898         return [self cy$deleteProperty:name];
1899     } CYPoolCatch(false)
1900 } CYCatch(false) return /*XXX*/ false; }
1901
1902 static void Instance_getPropertyNames_message(JSPropertyNameAccumulatorRef names, objc_method *method) {
1903     const char *name(sel_getName(method_getName(method)));
1904     if (strchr(name, ':') != NULL)
1905         return;
1906
1907     const char *type(method_getTypeEncoding(method));
1908     if (type == NULL || *type == '\0' || *type == 'v')
1909         return;
1910
1911     JSPropertyNameAccumulatorAddName(names, CYJSString(name));
1912 }
1913
1914 static void Instance_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
1915     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
1916     id self(internal->GetValue());
1917
1918     CYPool pool;
1919     Class _class(object_getClass(self));
1920
1921 #ifdef __APPLE__
1922     {
1923         unsigned int size;
1924         objc_property_t *data(class_copyPropertyList(_class, &size));
1925         for (size_t i(0); i != size; ++i)
1926             JSPropertyNameAccumulatorAddName(names, CYJSString(property_getName(data[i])));
1927         free(data);
1928     }
1929 #endif
1930
1931     if (CYHasImplicitProperties(_class))
1932         for (Class current(_class); current != nil; current = class_getSuperclass(current)) {
1933 #if OBJC_API_VERSION >= 2
1934             unsigned int size;
1935             objc_method **data(class_copyMethodList(current, &size));
1936             for (size_t i(0); i != size; ++i)
1937                 Instance_getPropertyNames_message(names, data[i]);
1938             free(data);
1939 #else
1940             for (objc_method_list *methods(current->methods); methods != NULL; methods = methods->method_next)
1941                 for (int i(0); i != methods->method_count; ++i)
1942                     Instance_getPropertyNames_message(names, &methods->method_list[i]);
1943 #endif
1944         }
1945
1946     CYPoolTry {
1947         // XXX: this is an evil hack to deal with NSProxy; fix elsewhere
1948         if (CYImplements(self, _class, @selector(cy$getPropertyNames:inContext:)))
1949             [self cy$getPropertyNames:names inContext:context];
1950     } CYPoolCatch()
1951 }
1952
1953 static JSObjectRef Instance_callAsConstructor(JSContextRef context, JSObjectRef object, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
1954     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
1955     JSObjectRef value(Instance::Make(context, [internal->GetValue() alloc], Instance::Uninitialized));
1956     return value;
1957 } CYCatch(NULL) }
1958
1959 static const char *CYBlockEncoding(NSBlock *self) {
1960     BlockLiteral *literal(reinterpret_cast<BlockLiteral *>(self));
1961     if ((literal->flags & BLOCK_HAS_SIGNATURE) == 0)
1962         return NULL;
1963     uint8_t *descriptor(reinterpret_cast<uint8_t *>(literal->descriptor));
1964     descriptor += sizeof(BlockDescriptor1);
1965     if ((literal->flags & BLOCK_HAS_COPY_DISPOSE) != 0)
1966         descriptor += sizeof(BlockDescriptor2);
1967     BlockDescriptor3 *descriptor3(reinterpret_cast<BlockDescriptor3 *>(descriptor));
1968     return descriptor3->signature;
1969 }
1970
1971 static JSValueRef FunctionInstance_callAsFunction(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
1972     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
1973     id self(internal->GetValue());
1974
1975     if (const char *encoding = CYBlockEncoding(self)) {
1976         CYPool pool;
1977
1978         void *setup[1];
1979         setup[0] = &self;
1980
1981         sig::Signature signature;
1982         sig::Parse(pool, &signature, encoding, &Structor_);
1983
1984         ffi_cif cif;
1985         sig::sig_ffi_cif(pool, &sig::ObjectiveC, &signature, &cif);
1986
1987         BlockLiteral *literal(reinterpret_cast<BlockLiteral *>(self));
1988         void (*function)() = reinterpret_cast<void (*)()>(literal->invoke);
1989         return CYCallFunction(pool, context, 1, setup, count, arguments, false, &signature, &cif, function);
1990     }
1991
1992     if (count != 0)
1993         CYThrow("NSBlock without signature field passed arguments");
1994
1995     CYPoolTry {
1996         [self invoke];
1997     } CYPoolCatch(NULL);
1998
1999     return NULL;
2000 } CYCatch(NULL) }
2001
2002 static bool Instance_hasInstance(JSContextRef context, JSObjectRef constructor, JSValueRef instance, JSValueRef *exception) { CYTry {
2003     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate((JSObjectRef) constructor)));
2004     Class _class(internal->GetValue());
2005     if (!CYIsClass(_class))
2006         return false;
2007
2008     if (CYJSValueIsNSObject(context, instance)) {
2009         Instance *linternal(reinterpret_cast<Instance *>(JSObjectGetPrivate((JSObjectRef) instance)));
2010         // XXX: this isn't always safe
2011         return [linternal->GetValue() isKindOfClass:_class];
2012     }
2013
2014     return false;
2015 } CYCatch(false) }
2016
2017 static JSValueRef Instance_box_callAsFunction(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2018     if (count == 0)
2019         throw CYJSError(context, "incorrect number of arguments to Instance");
2020     CYPool pool;
2021     id value(CYCastNSObject(&pool, context, arguments[0]));
2022     if (value == nil)
2023         value = [NSNull null];
2024     return CYCastJSValue(context, [value cy$box]);
2025 } CYCatch(NULL) }
2026
2027 static bool Internal_hasProperty(JSContextRef context, JSObjectRef object, JSStringRef property) {
2028     Internal *internal(reinterpret_cast<Internal *>(JSObjectGetPrivate(object)));
2029     CYPool pool;
2030
2031     id self(internal->GetValue());
2032     const char *name(CYPoolCString(pool, context, property));
2033
2034     if (object_getInstanceVariable(self, name, NULL) != NULL)
2035         return true;
2036
2037     return false;
2038 }
2039
2040 static void CYBitField(unsigned &length, unsigned &shift, id self, Ivar ivar, const char *encoding, unsigned offset) {
2041     length = CYCastDouble(encoding + 1);
2042     shift = 0;
2043
2044     unsigned int size;
2045     objc_ivar **ivars(class_copyIvarList(object_getClass(self), &size));
2046     for (size_t i(0); i != size; ++i)
2047         if (ivars[i] == ivar)
2048             break;
2049         else if (ivar_getOffset(ivars[i]) == offset) {
2050             const char *encoding(ivar_getTypeEncoding(ivars[i]));
2051             _assert(encoding != NULL);
2052             _assert(encoding[0] == 'b');
2053             shift += CYCastDouble(encoding + 1);
2054         }
2055     free(ivars);
2056 }
2057
2058 static JSValueRef Internal_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
2059     Internal *internal(reinterpret_cast<Internal *>(JSObjectGetPrivate(object)));
2060     CYPool pool;
2061
2062     id self(internal->GetValue());
2063     const char *name(CYPoolCString(pool, context, property));
2064
2065 #ifdef __arm64__
2066     if (strcmp(name, "isa") == 0)
2067         return CYCastJSValue(context, object_getClass(self));
2068 #endif
2069
2070     if (objc_ivar *ivar = object_getInstanceVariable(self, name, NULL)) {
2071         ptrdiff_t offset(ivar_getOffset(ivar));
2072         void *data(reinterpret_cast<uint8_t *>(self) + offset);
2073
2074         const char *encoding(ivar_getTypeEncoding(ivar));
2075         _assert(encoding != NULL);
2076         if (encoding[0] == 'b') {
2077             unsigned length, shift;
2078             CYBitField(length, shift, self, ivar, encoding, offset);
2079             _assert(shift + length <= sizeof(uintptr_t) * 8);
2080             uintptr_t &field(*reinterpret_cast<uintptr_t *>(data));
2081             uintptr_t mask((1 << length) - 1);
2082             return CYCastJSValue(context, (field >> shift) & mask);
2083         } else {
2084             Type_privateData type(pool, ivar_getTypeEncoding(ivar));
2085             return CYFromFFI(context, type.type_, type.GetFFI(), data);
2086         }
2087     }
2088
2089     return NULL;
2090 } CYCatch(NULL) }
2091
2092 static bool Internal_setProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef value, JSValueRef *exception) { CYTry {
2093     Internal *internal(reinterpret_cast<Internal *>(JSObjectGetPrivate(object)));
2094     CYPool pool;
2095
2096     id self(internal->GetValue());
2097     const char *name(CYPoolCString(pool, context, property));
2098
2099     if (objc_ivar *ivar = object_getInstanceVariable(self, name, NULL)) {
2100         ptrdiff_t offset(ivar_getOffset(ivar));
2101         void *data(reinterpret_cast<uint8_t *>(self) + offset);
2102
2103         const char *encoding(ivar_getTypeEncoding(ivar));
2104         _assert(encoding != NULL);
2105         if (encoding[0] == 'b') {
2106             unsigned length, shift;
2107             CYBitField(length, shift, self, ivar, encoding, offset);
2108             _assert(shift + length <= sizeof(uintptr_t) * 8);
2109             uintptr_t &field(*reinterpret_cast<uintptr_t *>(data));
2110             uintptr_t mask((1 << length) - 1);
2111             field = field & ~(mask << shift) | (uintptr_t(CYCastDouble(context, value)) & mask) << shift;
2112         } else {
2113             Type_privateData type(pool, ivar_getTypeEncoding(ivar));
2114             CYPoolFFI(&pool, context, type.type_, type.GetFFI(), reinterpret_cast<uint8_t *>(self) + ivar_getOffset(ivar), value);
2115             return true;
2116         }
2117     }
2118
2119     return false;
2120 } CYCatch(false) }
2121
2122 static void Internal_getPropertyNames_(Class _class, JSPropertyNameAccumulatorRef names) {
2123     if (Class super = class_getSuperclass(_class))
2124         Internal_getPropertyNames_(super, names);
2125
2126 #if OBJC_API_VERSION >= 2
2127     unsigned int size;
2128     objc_ivar **data(class_copyIvarList(_class, &size));
2129     for (size_t i(0); i != size; ++i)
2130         JSPropertyNameAccumulatorAddName(names, CYJSString(ivar_getName(data[i])));
2131     free(data);
2132 #else
2133     if (objc_ivar_list *ivars = _class->ivars)
2134         for (int i(0); i != ivars->ivar_count; ++i)
2135             JSPropertyNameAccumulatorAddName(names, CYJSString(ivar_getName(&ivars->ivar_list[i])));
2136 #endif
2137 }
2138
2139 static void Internal_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
2140     Internal *internal(reinterpret_cast<Internal *>(JSObjectGetPrivate(object)));
2141     CYPool pool;
2142
2143     id self(internal->GetValue());
2144     Class _class(object_getClass(self));
2145
2146     Internal_getPropertyNames_(_class, names);
2147 }
2148
2149 static JSValueRef Internal_callAsFunction_$cya(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2150     Internal *internal(reinterpret_cast<Internal *>(JSObjectGetPrivate(object)));
2151     return internal->GetOwner();
2152 } CYCatch(NULL) }
2153
2154 static bool ObjectiveC_Classes_hasProperty(JSContextRef context, JSObjectRef object, JSStringRef property) {
2155     CYPool pool;
2156     return objc_getClass(CYPoolCString(pool, context, property)) != Nil;
2157 }
2158
2159 static JSValueRef ObjectiveC_Classes_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
2160     CYPool pool;
2161     NSString *name(CYCastNSString(&pool, context, property));
2162     if (Class _class = NSClassFromString(name))
2163         return CYMakeInstance(context, _class, true);
2164     return NULL;
2165 } CYCatch(NULL) }
2166
2167 #ifdef __APPLE__
2168 static Class *CYCopyClassList(size_t &size) {
2169     size = objc_getClassList(NULL, 0);
2170     Class *data(reinterpret_cast<Class *>(malloc(sizeof(Class) * size)));
2171
2172     for (;;) {
2173         size_t writ(objc_getClassList(data, size));
2174         if (writ <= size) {
2175             size = writ;
2176             return data;
2177         }
2178
2179         Class *copy(reinterpret_cast<Class *>(realloc(data, sizeof(Class) * writ)));
2180         if (copy == NULL) {
2181             free(data);
2182             return NULL;
2183         }
2184
2185         data = copy;
2186         size = writ;
2187     }
2188 }
2189 #endif
2190
2191 static void ObjectiveC_Classes_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
2192 #ifdef __APPLE__
2193     size_t size;
2194     if (Class *data = CYCopyClassList(size)) {
2195         for (size_t i(0); i != size; ++i)
2196             JSPropertyNameAccumulatorAddName(names, CYJSString(class_getName(data[i])));
2197         free(data);
2198     }
2199 #else
2200     void *state(NULL);
2201     while (Class _class = objc_next_class(&state))
2202         JSPropertyNameAccumulatorAddName(names, CYJSString(class_getName(_class)));
2203 #endif
2204 }
2205
2206 #if OBJC_API_VERSION >= 2
2207 static JSValueRef ObjectiveC_Image_Classes_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
2208     const char *internal(reinterpret_cast<const char *>(JSObjectGetPrivate(object)));
2209
2210     CYPool pool;
2211     const char *name(CYPoolCString(pool, context, property));
2212     unsigned int size;
2213     const char **data(objc_copyClassNamesForImage(internal, &size));
2214     JSValueRef value;
2215     for (size_t i(0); i != size; ++i)
2216         if (strcmp(name, data[i]) == 0) {
2217             if (Class _class = objc_getClass(name)) {
2218                 value = CYMakeInstance(context, _class, true);
2219                 goto free;
2220             } else
2221                 break;
2222         }
2223     value = NULL;
2224   free:
2225     free(data);
2226     return value;
2227 } CYCatch(NULL) }
2228
2229 static void ObjectiveC_Image_Classes_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
2230     const char *internal(reinterpret_cast<const char *>(JSObjectGetPrivate(object)));
2231     unsigned int size;
2232     const char **data(objc_copyClassNamesForImage(internal, &size));
2233     for (size_t i(0); i != size; ++i)
2234         JSPropertyNameAccumulatorAddName(names, CYJSString(data[i]));
2235     free(data);
2236 }
2237
2238 static JSValueRef ObjectiveC_Images_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
2239     CYPool pool;
2240     const char *name(CYPoolCString(pool, context, property));
2241     unsigned int size;
2242     const char **data(objc_copyImageNames(&size));
2243     for (size_t i(0); i != size; ++i)
2244         if (strcmp(name, data[i]) == 0) {
2245             name = data[i];
2246             goto free;
2247         }
2248     name = NULL;
2249   free:
2250     free(data);
2251     if (name == NULL)
2252         return NULL;
2253     JSObjectRef value(JSObjectMake(context, NULL, NULL));
2254     CYSetProperty(context, value, CYJSString("classes"), JSObjectMake(context, ObjectiveC_Image_Classes_, const_cast<char *>(name)));
2255     return value;
2256 } CYCatch(NULL) }
2257
2258 static void ObjectiveC_Images_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
2259     unsigned int size;
2260     const char **data(objc_copyImageNames(&size));
2261     for (size_t i(0); i != size; ++i)
2262         JSPropertyNameAccumulatorAddName(names, CYJSString(data[i]));
2263     free(data);
2264 }
2265 #endif
2266
2267 static JSValueRef ObjectiveC_Protocols_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
2268     CYPool pool;
2269     const char *name(CYPoolCString(pool, context, property));
2270     if (Protocol *protocol = objc_getProtocol(name))
2271         return CYMakeInstance(context, protocol, true);
2272     return NULL;
2273 } CYCatch(NULL) }
2274
2275 static void ObjectiveC_Protocols_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
2276 #if OBJC_API_VERSION >= 2
2277     unsigned int size;
2278     Protocol **data(objc_copyProtocolList(&size));
2279     for (size_t i(0); i != size; ++i)
2280         JSPropertyNameAccumulatorAddName(names, CYJSString(protocol_getName(data[i])));
2281     free(data);
2282 #else
2283     // XXX: fix this!
2284 #endif
2285 }
2286
2287 static JSValueRef ObjectiveC_Constants_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
2288     CYPool pool;
2289     CYUTF8String name(CYPoolUTF8String(pool, context, property));
2290     if (name == "nil")
2291         return Instance::Make(context, nil);
2292     return NULL;
2293 } CYCatch(NULL) }
2294
2295 static void ObjectiveC_Constants_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
2296     JSPropertyNameAccumulatorAddName(names, CYJSString("nil"));
2297 }
2298
2299 #ifdef __APPLE__
2300 static kern_return_t CYReadMemory(task_t task, vm_address_t address, vm_size_t size, void **data) {
2301     *data = reinterpret_cast<void *>(address);
2302     return KERN_SUCCESS;
2303 }
2304
2305 struct CYChoice {
2306     std::set<Class> query_;
2307     JSContextRef context_;
2308     JSObjectRef results_;
2309 };
2310
2311 struct CYObjectStruct {
2312     Class isa_;
2313 };
2314
2315 static void choose_(task_t task, void *baton, unsigned type, vm_range_t *ranges, unsigned count) {
2316     CYChoice *choice(reinterpret_cast<CYChoice *>(baton));
2317     JSContextRef context(choice->context_);
2318
2319     for (unsigned i(0); i != count; ++i) {
2320         vm_range_t &range(ranges[i]);
2321         void *data(reinterpret_cast<void *>(range.address));
2322         size_t size(range.size);
2323
2324         if (size < sizeof(CYObjectStruct))
2325             continue;
2326
2327         uintptr_t *pointers(reinterpret_cast<uintptr_t *>(data));
2328 #ifdef __arm64__
2329         Class isa(reinterpret_cast<Class>(pointers[0] & 0x1fffffff8));
2330 #else
2331         Class isa(reinterpret_cast<Class>(pointers[0]));
2332 #endif
2333
2334         std::set<Class>::const_iterator result(choice->query_.find(isa));
2335         if (result == choice->query_.end())
2336             continue;
2337
2338         size_t needed(class_getInstanceSize(*result));
2339         // XXX: if (size < needed)
2340
2341         size_t boundary(496);
2342 #ifdef __LP64__
2343         boundary *= 2;
2344 #endif
2345         if (needed <= boundary && (needed + 15) / 16 * 16 != size || needed > boundary && (needed + 511) / 512 * 512 != size)
2346             continue;
2347         CYArrayPush(context, choice->results_, CYCastJSValue(context, reinterpret_cast<id>(data)));
2348     }
2349 }
2350
2351 static JSValueRef choose(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2352     if (count != 1)
2353         throw CYJSError(context, "choose() takes a class argument");
2354
2355     CYGarbageCollect(context);
2356
2357     CYPool pool;
2358     Class _class(CYCastNSObject(&pool, context, arguments[0]));
2359
2360     vm_address_t *zones(NULL);
2361     unsigned size(0);
2362     kern_return_t error(malloc_get_all_zones(0, &CYReadMemory, &zones, &size));
2363     _assert(error == KERN_SUCCESS);
2364
2365     JSObjectRef Array(CYGetCachedObject(context, CYJSString("Array")));
2366     JSObjectRef results(_jsccall(JSObjectCallAsConstructor, context, Array, 0, NULL));
2367
2368     CYChoice choice;
2369     choice.context_ = context;
2370     choice.results_ = results;
2371
2372     size_t number;
2373     Class *classes(CYCopyClassList(number));
2374     _assert(classes != NULL);
2375
2376     for (size_t i(0); i != number; ++i)
2377         for (Class current(classes[i]); current != Nil; current = class_getSuperclass(current))
2378             if (current == _class) {
2379                 choice.query_.insert(classes[i]);
2380                 break;
2381             }
2382
2383     free(classes);
2384
2385     for (unsigned i(0); i != size; ++i) {
2386         const malloc_zone_t *zone(reinterpret_cast<const malloc_zone_t *>(zones[i]));
2387         if (zone == NULL || zone->introspect == NULL)
2388             continue;
2389
2390         zone->introspect->enumerator(mach_task_self(), &choice, MALLOC_PTR_IN_USE_RANGE_TYPE, zones[i], &CYReadMemory, &choose_);
2391     }
2392
2393     return results;
2394 } CYCatch(NULL) }
2395 #endif
2396
2397 #ifdef __APPLE__
2398 #if defined(__i386__) || defined(__x86_64__)
2399 #define OBJC_MAX_STRUCT_BY_VALUE 8
2400 static int struct_forward_array[] = {
2401     0, 0, 0, 1, 0, 1, 1, 1, 0 };
2402 #elif defined(__arm__)
2403 #define OBJC_MAX_STRUCT_BY_VALUE 1
2404 static int struct_forward_array[] = {
2405     0, 0 };
2406 #elif defined(__arm64__)
2407 #define CY_NO_STRET
2408 #else
2409 #error missing objc-runtime-info
2410 #endif
2411
2412 #ifndef CY_NO_STRET
2413 static bool stret(ffi_type *ffi_type) {
2414     return ffi_type->type == FFI_TYPE_STRUCT && (
2415         ffi_type->size > OBJC_MAX_STRUCT_BY_VALUE ||
2416         struct_forward_array[ffi_type->size] != 0
2417     );
2418 }
2419 #endif
2420 #endif
2421
2422 JSValueRef CYSendMessage(CYPool &pool, JSContextRef context, id self, Class _class, SEL _cmd, size_t count, const JSValueRef arguments[], bool initialize) {
2423     const char *type;
2424
2425     if (_class == NULL)
2426         _class = object_getClass(self);
2427
2428     IMP imp;
2429
2430     if (objc_method *method = class_getInstanceMethod(_class, _cmd)) {
2431         imp = method_getImplementation(method);
2432         type = method_getTypeEncoding(method);
2433     } else {
2434         imp = NULL;
2435
2436         CYPoolTry {
2437             NSMethodSignature *method([self methodSignatureForSelector:_cmd]);
2438             if (method == nil)
2439                 throw CYJSError(context, "unrecognized selector %s sent to object %p", sel_getName(_cmd), self);
2440             type = CYPoolCString(pool, context, [method _typeString]);
2441         } CYPoolCatch(NULL)
2442     }
2443
2444     void *setup[2];
2445     setup[0] = &self;
2446     setup[1] = &_cmd;
2447
2448     sig::Signature signature;
2449     sig::Parse(pool, &signature, type, &Structor_);
2450
2451     size_t used(count + 3);
2452     if (used > signature.count) {
2453         sig::Element *elements(new (pool) sig::Element[used]);
2454         memcpy(elements, signature.elements, used * sizeof(sig::Element));
2455
2456         for (size_t index(signature.count); index != used; ++index) {
2457             sig::Element *element(&elements[index]);
2458             element->name = NULL;
2459             element->offset = _not(size_t);
2460
2461             sig::Type *type(new (pool) sig::Type);
2462             memset(type, 0, sizeof(*type));
2463             type->primitive = sig::object_P;
2464             element->type = type;
2465         }
2466
2467         signature.elements = elements;
2468         signature.count = used;
2469     }
2470
2471     ffi_cif cif;
2472     sig::sig_ffi_cif(pool, &sig::ObjectiveC, &signature, &cif);
2473
2474     if (imp == NULL) {
2475 #ifdef __APPLE__
2476 #ifndef CY_NO_STRET
2477         if (stret(cif.rtype))
2478             imp = class_getMethodImplementation_stret(_class, _cmd);
2479         else
2480 #endif
2481             imp = class_getMethodImplementation(_class, _cmd);
2482 #else
2483         objc_super super = {self, _class};
2484         imp = objc_msg_lookup_super(&super, _cmd);
2485 #endif
2486     }
2487
2488     void (*function)() = reinterpret_cast<void (*)()>(imp);
2489     return CYCallFunction(pool, context, 2, setup, count, arguments, initialize, &signature, &cif, function);
2490 }
2491
2492 static JSValueRef $objc_msgSend(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[]) {
2493     if (count < 2)
2494         throw CYJSError(context, "too few arguments to objc_msgSend");
2495
2496     CYPool pool;
2497
2498     bool uninitialized;
2499
2500     id self;
2501     SEL _cmd;
2502     Class _class;
2503
2504     if (JSValueIsObjectOfClass(context, arguments[0], Super_)) {
2505         cy::Super *internal(reinterpret_cast<cy::Super *>(JSObjectGetPrivate((JSObjectRef) arguments[0])));
2506         self = internal->GetValue();
2507         _class = internal->class_;;
2508         uninitialized = false;
2509     } else if (CYJSValueIsNSObject(context, arguments[0])) {
2510         Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate((JSObjectRef) arguments[0])));
2511         self = internal->GetValue();
2512         _class = nil;
2513         uninitialized = internal->IsUninitialized();
2514         if (uninitialized)
2515             internal->value_ = nil;
2516     } else {
2517         self = CYCastNSObject(&pool, context, arguments[0]);
2518         _class = nil;
2519         uninitialized = false;
2520     }
2521
2522     if (self == nil)
2523         return CYJSNull(context);
2524
2525     _cmd = CYCastSEL(context, arguments[1]);
2526
2527     return CYSendMessage(pool, context, self, _class, _cmd, count - 2, arguments + 2, uninitialized);
2528 }
2529
2530 static JSValueRef $objc_msgSend(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2531     return $objc_msgSend(context, object, _this, count, arguments);
2532 } CYCatch(NULL) }
2533
2534 static JSValueRef Selector_callAsFunction(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2535     JSValueRef setup[count + 2];
2536     setup[0] = _this;
2537     setup[1] = object;
2538     memcpy(setup + 2, arguments, sizeof(JSValueRef) * count);
2539     return $objc_msgSend(context, NULL, NULL, count + 2, setup);
2540 } CYCatch(NULL) }
2541
2542 static JSValueRef Message_callAsFunction(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2543     CYPool pool;
2544     Message_privateData *internal(reinterpret_cast<Message_privateData *>(JSObjectGetPrivate(object)));
2545
2546     // XXX: handle Instance::Uninitialized?
2547     id self(CYCastNSObject(&pool, context, _this));
2548
2549     void *setup[2];
2550     setup[0] = &self;
2551     setup[1] = &internal->sel_;
2552
2553     return CYCallFunction(pool, context, 2, setup, count, arguments, false, &internal->signature_, &internal->cif_, internal->GetValue());
2554 } CYCatch(NULL) }
2555
2556 static JSObjectRef Super_new(JSContextRef context, JSObjectRef object, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2557     if (count != 2)
2558         throw CYJSError(context, "incorrect number of arguments to objc_super constructor");
2559     CYPool pool;
2560     id self(CYCastNSObject(&pool, context, arguments[0]));
2561     Class _class(CYCastClass(pool, context, arguments[1]));
2562     return cy::Super::Make(context, self, _class);
2563 } CYCatch(NULL) }
2564
2565 static JSObjectRef Selector_new(JSContextRef context, JSObjectRef object, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2566     if (count != 1)
2567         throw CYJSError(context, "incorrect number of arguments to Selector constructor");
2568     CYPool pool;
2569     const char *name(CYPoolCString(pool, context, arguments[0]));
2570     return CYMakeSelector(context, sel_registerName(name));
2571 } CYCatch(NULL) }
2572
2573 static JSObjectRef Instance_new(JSContextRef context, JSObjectRef object, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2574     if (count > 1)
2575         throw CYJSError(context, "incorrect number of arguments to Instance constructor");
2576     id self(count == 0 ? nil : CYCastPointer<id>(context, arguments[0]));
2577     return CYMakeInstance(context, self, false);
2578 } CYCatch(NULL) }
2579
2580 static JSValueRef CYValue_getProperty_value(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
2581     CYValue *internal(reinterpret_cast<CYValue *>(JSObjectGetPrivate(object)));
2582     return CYCastJSValue(context, reinterpret_cast<uintptr_t>(internal->value_));
2583 } CYCatch(NULL) }
2584
2585 static JSValueRef CYValue_callAsFunction_$cya(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2586     CYValue *internal(reinterpret_cast<CYValue *>(JSObjectGetPrivate(_this)));
2587     Type_privateData *typical(internal->GetType());
2588
2589     sig::Type *type;
2590     ffi_type *ffi;
2591
2592     if (typical == NULL) {
2593         type = NULL;
2594         ffi = NULL;
2595     } else {
2596         type = typical->type_;
2597         ffi = typical->ffi_;
2598     }
2599
2600     return CYMakePointer(context, &internal->value_, _not(size_t), type, ffi, object);
2601 } CYCatch(NULL) }
2602
2603 static JSValueRef FunctionInstance_getProperty_type(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
2604     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
2605     const char *encoding(CYBlockEncoding(internal->GetValue()));
2606     if (encoding == NULL)
2607         return CYJSNull(context);
2608     // XXX: this should be stored on a FunctionInstance private value subclass
2609     CYPool pool;
2610     sig::Signature signature;
2611     sig::Parse(pool, &signature, encoding, &Structor_);
2612     return CYMakeType(context, &signature);
2613 } CYCatch(NULL) }
2614
2615 static JSValueRef Instance_getProperty_constructor(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
2616     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
2617     return Instance::Make(context, (id) object_getClass(internal->GetValue()));
2618 } CYCatch(NULL) }
2619
2620 static JSValueRef Instance_getProperty_prototype(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
2621     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
2622     id self(internal->GetValue());
2623     if (!CYIsClass(self))
2624         return CYJSUndefined(context);
2625     return CYGetClassPrototype(context, self);
2626 } CYCatch(NULL) }
2627
2628 static JSValueRef Instance_getProperty_messages(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
2629     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
2630     id self(internal->GetValue());
2631     if (!CYIsClass(self))
2632         return CYJSUndefined(context);
2633     return Messages::Make(context, (Class) self);
2634 } CYCatch(NULL) }
2635
2636 static JSValueRef Instance_callAsFunction_toCYON(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2637     if (!CYJSValueIsNSObject(context, _this))
2638         return NULL;
2639
2640     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(_this)));
2641     return CYCastJSValue(context, CYJSString(context, CYCastNSCYON(internal->GetValue(), false)));
2642 } CYCatch(NULL) }
2643
2644 static JSValueRef Instance_callAsFunction_toJSON(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2645     if (!CYJSValueIsNSObject(context, _this))
2646         return NULL;
2647
2648     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(_this)));
2649     id value(internal->GetValue());
2650
2651     CYPoolTry {
2652         NSString *key;
2653         if (count == 0)
2654             key = nil;
2655         else
2656             key = CYCastNSString(NULL, context, CYJSString(context, arguments[0]));
2657
2658         if (!CYImplements(value, object_getClass(value), @selector(cy$toJSON:inContext:)))
2659             return CYJSUndefined(context);
2660         else if (JSValueRef json = [value cy$toJSON:key inContext:context])
2661             return json;
2662         else
2663             return CYCastJSValue(context, CYJSString(context, [value description]));
2664     } CYPoolCatch(NULL)
2665 } CYCatch(NULL) return /*XXX*/ NULL; }
2666
2667 static JSValueRef Instance_callAsFunction_valueOf(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2668     if (!CYJSValueIsNSObject(context, _this))
2669         return NULL;
2670
2671     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(_this)));
2672     id value(internal->GetValue());
2673
2674     if (![value respondsToSelector:@selector(cy$valueOfInContext:)])
2675         return _this;
2676
2677     if (JSValueRef result = [value cy$valueOfInContext:context])
2678         return result;
2679
2680     return _this;
2681 } CYCatch(NULL) return /*XXX*/ NULL; }
2682
2683 static JSValueRef Instance_callAsFunction_toPointer(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2684     if (!CYJSValueIsNSObject(context, _this))
2685         return NULL;
2686
2687     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(_this)));
2688     // XXX: but... but... THIS ISN'T A POINTER! :(
2689     return CYCastJSValue(context, reinterpret_cast<uintptr_t>(internal->GetValue()));
2690 } CYCatch(NULL) return /*XXX*/ NULL; }
2691
2692 static JSValueRef Instance_callAsFunction_toString(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2693     if (!CYJSValueIsNSObject(context, _this))
2694         return NULL;
2695
2696     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(_this)));
2697     id value(internal->GetValue());
2698
2699     CYPoolTry {
2700         // XXX: this seems like a stupid implementation; what if it crashes? why not use the CYONifier backend?
2701         return CYCastJSValue(context, CYJSString(context, [value description]));
2702     } CYPoolCatch(NULL)
2703 } CYCatch(NULL) return /*XXX*/ NULL; }
2704
2705 static JSValueRef Class_callAsFunction_pointerTo(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2706     if (!CYJSValueIsNSObject(context, _this))
2707         return NULL;
2708
2709     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(_this)));
2710     id value(internal->GetValue());
2711
2712     if (!CYIsClass(value))
2713         CYThrow("non-Class object cannot be used as Type");
2714
2715     // XXX: this is a very silly implementation
2716
2717     std::ostringstream type;
2718     type << "@\"";
2719     type << class_getName(value);
2720     type << "\"";
2721
2722     CYPoolTry {
2723         return CYMakeType(context, type.str().c_str());
2724     } CYPoolCatch(NULL)
2725 } CYCatch(NULL) return /*XXX*/ NULL; }
2726
2727 static JSValueRef Selector_callAsFunction_toString(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2728     Selector_privateData *internal(reinterpret_cast<Selector_privateData *>(JSObjectGetPrivate(_this)));
2729     return CYCastJSValue(context, sel_getName(internal->GetValue()));
2730 } CYCatch(NULL) }
2731
2732 static JSValueRef Selector_callAsFunction_toJSON(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2733     return Selector_callAsFunction_toString(context, object, _this, count, arguments, exception);
2734 }
2735
2736 static JSValueRef Selector_callAsFunction_toCYON(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2737     Selector_privateData *internal(reinterpret_cast<Selector_privateData *>(JSObjectGetPrivate(_this)));
2738     const char *name(sel_getName(internal->GetValue()));
2739
2740     CYPoolTry {
2741         NSString *string([NSString stringWithFormat:@"@selector(%s)", name]);
2742         return CYCastJSValue(context, CYJSString(context, string));
2743     } CYPoolCatch(NULL)
2744 } CYCatch(NULL) return /*XXX*/ NULL; }
2745
2746 static JSValueRef Selector_callAsFunction_type(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2747     if (count != 1)
2748         throw CYJSError(context, "incorrect number of arguments to Selector.type");
2749
2750     CYPool pool;
2751     Selector_privateData *internal(reinterpret_cast<Selector_privateData *>(JSObjectGetPrivate(_this)));
2752     SEL sel(internal->GetValue());
2753
2754     Class _class(_require(CYCastClass(pool, context, arguments[0])));
2755     objc_method *method(_require(class_getInstanceMethod(_class, sel)));
2756     const char *encoding(method_getTypeEncoding(method));
2757
2758     sig::Signature signature;
2759     sig::Parse(pool, &signature, encoding, &Structor_);
2760     return CYMakeType(context, &signature);
2761 } CYCatch(NULL) }
2762
2763 static JSStaticValue Selector_staticValues[2] = {
2764     {"value", &CYValue_getProperty_value, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontDelete},
2765     {NULL, NULL, NULL, 0}
2766 };
2767
2768 // XXX: this is sadly duplicated in FunctionInstance_staticValues
2769 static JSStaticValue Instance_staticValues[5] = {
2770     {"constructor", &Instance_getProperty_constructor, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2771     {"messages", &Instance_getProperty_messages, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2772     {"prototype", &Instance_getProperty_prototype, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2773     {"value", &CYValue_getProperty_value, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2774     {NULL, NULL, NULL, 0}
2775 };
2776
2777 static JSStaticValue FunctionInstance_staticValues[6] = {
2778     {"type", &FunctionInstance_getProperty_type, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2779     // XXX: this is sadly a duplicate of Instance_staticValues
2780     {"constructor", &Instance_getProperty_constructor, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2781     {"messages", &Instance_getProperty_messages, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2782     {"prototype", &Instance_getProperty_prototype, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2783     {"value", &CYValue_getProperty_value, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2784     {NULL, NULL, NULL, 0}
2785 };
2786
2787 static JSStaticFunction Instance_staticFunctions[7] = {
2788     {"$cya", &CYValue_callAsFunction_$cya, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2789     {"toCYON", &Instance_callAsFunction_toCYON, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2790     {"toJSON", &Instance_callAsFunction_toJSON, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2791     {"valueOf", &Instance_callAsFunction_valueOf, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2792     {"toPointer", &Instance_callAsFunction_toPointer, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2793     {"toString", &Instance_callAsFunction_toString, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2794     {NULL, NULL, 0}
2795 };
2796
2797 static JSStaticFunction Class_staticFunctions[2] = {
2798     {"pointerTo", &Class_callAsFunction_pointerTo, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2799     {NULL, NULL, 0}
2800 };
2801
2802 static JSStaticFunction Internal_staticFunctions[2] = {
2803     {"$cya", &Internal_callAsFunction_$cya, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2804     {NULL, NULL, 0}
2805 };
2806
2807 static JSStaticFunction Selector_staticFunctions[5] = {
2808     {"toCYON", &Selector_callAsFunction_toCYON, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2809     {"toJSON", &Selector_callAsFunction_toJSON, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2810     {"toString", &Selector_callAsFunction_toString, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2811     {"type", &Selector_callAsFunction_type, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2812     {NULL, NULL, 0}
2813 };
2814
2815 #ifdef __APPLE__
2816 JSValueRef NSCFType$cy$toJSON$inContext$(id self, SEL sel, JSValueRef key, JSContextRef context) { CYObjectiveTry_ {
2817     return CYCastJSValue(context, [(NSString *) CFCopyDescription((CFTypeRef) self) autorelease]);
2818 } CYObjectiveCatch }
2819 #endif
2820
2821 void CYObjectiveC_Initialize() { /*XXX*/ JSContextRef context(NULL); CYPoolTry {
2822     $objc_setAssociatedObject = reinterpret_cast<void (*)(id, void *, id value, objc_AssociationPolicy)>(dlsym(RTLD_DEFAULT, "objc_setAssociatedObject"));
2823     $objc_getAssociatedObject = reinterpret_cast<id (*)(id, void *)>(dlsym(RTLD_DEFAULT, "objc_getAssociatedObject"));
2824     $objc_removeAssociatedObjects = reinterpret_cast<void (*)(id)>(dlsym(RTLD_DEFAULT, "objc_removeAssociatedObjects"));
2825
2826     CYPool &pool(CYGetGlobalPool());
2827
2828     Object_type = new(pool) Type_privateData("@");
2829     Selector_type = new(pool) Type_privateData(":");
2830
2831     NSArray_ = objc_getClass("NSArray");
2832     NSBlock_ = objc_getClass("NSBlock");
2833     NSDictionary_ = objc_getClass("NSDictionary");
2834     NSNumber_ = objc_getClass("NSNumber");
2835     NSString_ = objc_getClass("NSString");
2836     Object_ = objc_getClass("Object");
2837
2838 #ifdef __APPLE__
2839     __NSMallocBlock__ = objc_getClass("__NSMallocBlock__");
2840
2841     // XXX: apparently, iOS now has both of these
2842     NSCFBoolean_ = objc_getClass("__NSCFBoolean");
2843     if (NSCFBoolean_ == nil)
2844         NSCFBoolean_ = objc_getClass("NSCFBoolean");
2845
2846     NSCFType_ = objc_getClass("NSCFType");
2847
2848     NSZombie_ = objc_getClass("_NSZombie_");
2849
2850     banned_.insert(Object_);
2851     banned_.insert(objc_getClass("__NSAtom"));
2852     banned_.insert(objc_getClass("__NSGenericDeallocHandler"));
2853     banned_.insert(objc_getClass("NSMessageBuilder"));
2854     banned_.insert(objc_getClass("__NSMessageBuilder"));
2855 #else
2856     NSBoolNumber_ = objc_getClass("NSBoolNumber");
2857 #endif
2858
2859     JSClassDefinition definition;
2860
2861     definition = kJSClassDefinitionEmpty;
2862     definition.className = "Instance";
2863     definition.staticValues = Instance_staticValues;
2864     definition.staticFunctions = Instance_staticFunctions;
2865     definition.hasProperty = &Instance_hasProperty;
2866     definition.getProperty = &Instance_getProperty;
2867     definition.setProperty = &Instance_setProperty;
2868     definition.deleteProperty = &Instance_deleteProperty;
2869     definition.getPropertyNames = &Instance_getPropertyNames;
2870     definition.callAsConstructor = &Instance_callAsConstructor;
2871     definition.hasInstance = &Instance_hasInstance;
2872     definition.finalize = &CYFinalize;
2873     Instance_ = JSClassCreate(&definition);
2874
2875     definition.className = "ArrayInstance";
2876     ArrayInstance_ = JSClassCreate(&definition);
2877
2878     definition.className = "BooleanInstance";
2879     BooleanInstance_ = JSClassCreate(&definition);
2880
2881     definition.className = "NumberInstance";
2882     NumberInstance_ = JSClassCreate(&definition);
2883
2884     definition.className = "ObjectInstance";
2885     ObjectInstance_ = JSClassCreate(&definition);
2886
2887     definition.className = "StringInstance";
2888     StringInstance_ = JSClassCreate(&definition);
2889
2890     definition.className = "FunctionInstance";
2891     definition.staticValues = FunctionInstance_staticValues;
2892     definition.callAsFunction = &FunctionInstance_callAsFunction;
2893     FunctionInstance_ = JSClassCreate(&definition);
2894
2895     definition = kJSClassDefinitionEmpty;
2896     definition.className = "Class";
2897     definition.staticFunctions = Class_staticFunctions;
2898     Class_ = JSClassCreate(&definition);
2899
2900     definition = kJSClassDefinitionEmpty;
2901     definition.className = "Internal";
2902     definition.staticFunctions = Internal_staticFunctions;
2903     definition.hasProperty = &Internal_hasProperty;
2904     definition.getProperty = &Internal_getProperty;
2905     definition.setProperty = &Internal_setProperty;
2906     definition.getPropertyNames = &Internal_getPropertyNames;
2907     definition.finalize = &CYFinalize;
2908     Internal_ = JSClassCreate(&definition);
2909
2910     definition = kJSClassDefinitionEmpty;
2911     definition.className = "Message";
2912     definition.staticFunctions = cy::Functor::StaticFunctions;
2913     definition.staticValues = cy::Functor::StaticValues;
2914     definition.callAsFunction = &Message_callAsFunction;
2915     definition.finalize = &CYFinalize;
2916     Message_ = JSClassCreate(&definition);
2917
2918     definition = kJSClassDefinitionEmpty;
2919     definition.className = "Messages";
2920     definition.hasProperty = &Messages_hasProperty;
2921     definition.getProperty = &Messages_getProperty;
2922     definition.setProperty = &Messages_setProperty;
2923 #if 0 && OBJC_API_VERSION < 2
2924     definition.deleteProperty = &Messages_deleteProperty;
2925 #endif
2926     definition.getPropertyNames = &Messages_getPropertyNames;
2927     definition.finalize = &CYFinalize;
2928     Messages_ = JSClassCreate(&definition);
2929
2930     definition = kJSClassDefinitionEmpty;
2931     definition.className = "Selector";
2932     definition.staticValues = Selector_staticValues;
2933     definition.staticFunctions = Selector_staticFunctions;
2934     definition.callAsFunction = &Selector_callAsFunction;
2935     definition.finalize = &CYFinalize;
2936     Selector_ = JSClassCreate(&definition);
2937
2938     definition = kJSClassDefinitionEmpty;
2939     definition.className = "Super";
2940     definition.staticFunctions = Internal_staticFunctions;
2941     definition.finalize = &CYFinalize;
2942     Super_ = JSClassCreate(&definition);
2943
2944     definition = kJSClassDefinitionEmpty;
2945     definition.className = "ObjectiveC::Classes";
2946     definition.hasProperty = &ObjectiveC_Classes_hasProperty;
2947     definition.getProperty = &ObjectiveC_Classes_getProperty;
2948     definition.getPropertyNames = &ObjectiveC_Classes_getPropertyNames;
2949     ObjectiveC_Classes_ = JSClassCreate(&definition);
2950
2951     definition = kJSClassDefinitionEmpty;
2952     definition.className = "ObjectiveC::Constants";
2953     definition.getProperty = &ObjectiveC_Constants_getProperty;
2954     definition.getPropertyNames = &ObjectiveC_Constants_getPropertyNames;
2955     ObjectiveC_Constants_ = JSClassCreate(&definition);
2956
2957 #if OBJC_API_VERSION >= 2
2958     definition = kJSClassDefinitionEmpty;
2959     definition.className = "ObjectiveC::Images";
2960     definition.getProperty = &ObjectiveC_Images_getProperty;
2961     definition.getPropertyNames = &ObjectiveC_Images_getPropertyNames;
2962     ObjectiveC_Images_ = JSClassCreate(&definition);
2963
2964     definition = kJSClassDefinitionEmpty;
2965     definition.className = "ObjectiveC::Image::Classes";
2966     definition.getProperty = &ObjectiveC_Image_Classes_getProperty;
2967     definition.getPropertyNames = &ObjectiveC_Image_Classes_getPropertyNames;
2968     ObjectiveC_Image_Classes_ = JSClassCreate(&definition);
2969 #endif
2970
2971     definition = kJSClassDefinitionEmpty;
2972     definition.className = "ObjectiveC::Protocols";
2973     definition.getProperty = &ObjectiveC_Protocols_getProperty;
2974     definition.getPropertyNames = &ObjectiveC_Protocols_getPropertyNames;
2975     ObjectiveC_Protocols_ = JSClassCreate(&definition);
2976
2977 #ifdef __APPLE__
2978     class_addMethod(NSCFType_, @selector(cy$toJSON:inContext:), reinterpret_cast<IMP>(&NSCFType$cy$toJSON$inContext$),
2979         // XXX: this is horrible; there has to be a better way to do this
2980     #ifdef __LP64__
2981         "^{OpaqueJSValue=}32@0:8@16^{OpaqueJSContext=}24"
2982     #else
2983         "^{OpaqueJSValue=}16@0:4@8^{OpaqueJSContext=}12"
2984     #endif
2985     );
2986 #endif
2987 } CYPoolCatch() }
2988
2989 void CYObjectiveC_SetupContext(JSContextRef context) { CYPoolTry {
2990     JSObjectRef global(CYGetGlobalObject(context));
2991     JSObjectRef cy(CYCastJSObject(context, CYGetProperty(context, global, cy_s)));
2992     JSObjectRef cycript(CYCastJSObject(context, CYGetProperty(context, global, CYJSString("Cycript"))));
2993     JSObjectRef all(CYCastJSObject(context, CYGetProperty(context, cycript, CYJSString("all"))));
2994     JSObjectRef alls(CYCastJSObject(context, CYGetProperty(context, cycript, CYJSString("alls"))));
2995
2996     JSObjectRef ObjectiveC(JSObjectMake(context, NULL, NULL));
2997     CYSetProperty(context, cycript, CYJSString("ObjectiveC"), ObjectiveC);
2998
2999     JSObjectRef protocols(JSObjectMake(context, ObjectiveC_Protocols_, NULL));
3000     CYSetProperty(context, ObjectiveC, CYJSString("protocols"), protocols);
3001     CYArrayPush(context, alls, protocols);
3002
3003     JSObjectRef classes(JSObjectMake(context, ObjectiveC_Classes_, NULL));
3004     CYSetProperty(context, ObjectiveC, CYJSString("classes"), classes);
3005     CYArrayPush(context, alls, classes);
3006
3007     JSObjectRef constants(JSObjectMake(context, ObjectiveC_Constants_, NULL));
3008     CYSetProperty(context, ObjectiveC, CYJSString("constants"), constants);
3009     CYArrayPush(context, alls, constants);
3010
3011 #if OBJC_API_VERSION >= 2
3012     CYSetProperty(context, ObjectiveC, CYJSString("images"), JSObjectMake(context, ObjectiveC_Images_, NULL));
3013 #endif
3014
3015     JSObjectRef Class(JSObjectMakeConstructor(context, Class_, NULL));
3016     JSObjectRef Instance(JSObjectMakeConstructor(context, Instance_, &Instance_new));
3017     JSObjectRef Message(JSObjectMakeConstructor(context, Message_, NULL));
3018     JSObjectRef Selector(JSObjectMakeConstructor(context, Selector_, &Selector_new));
3019     JSObjectRef Super(JSObjectMakeConstructor(context, Super_, &Super_new));
3020
3021     JSObjectRef Instance_prototype(CYCastJSObject(context, CYGetProperty(context, Instance, prototype_s)));
3022     CYSetProperty(context, cy, CYJSString("Instance_prototype"), Instance_prototype);
3023
3024     JSObjectRef ArrayInstance(JSObjectMakeConstructor(context, ArrayInstance_, NULL));
3025     JSObjectRef ArrayInstance_prototype(CYCastJSObject(context, CYGetProperty(context, ArrayInstance, prototype_s)));
3026     CYSetProperty(context, cy, CYJSString("ArrayInstance_prototype"), ArrayInstance_prototype);
3027     JSObjectRef Array_prototype(CYGetCachedObject(context, CYJSString("Array_prototype")));
3028     CYSetPrototype(context, ArrayInstance_prototype, Array_prototype);
3029
3030     JSObjectRef BooleanInstance(JSObjectMakeConstructor(context, BooleanInstance_, NULL));
3031     JSObjectRef BooleanInstance_prototype(CYCastJSObject(context, CYGetProperty(context, BooleanInstance, prototype_s)));
3032     CYSetProperty(context, cy, CYJSString("BooleanInstance_prototype"), BooleanInstance_prototype);
3033     JSObjectRef Boolean_prototype(CYGetCachedObject(context, CYJSString("Boolean_prototype")));
3034     CYSetPrototype(context, BooleanInstance_prototype, Boolean_prototype);
3035
3036     JSObjectRef FunctionInstance(JSObjectMakeConstructor(context, FunctionInstance_, NULL));
3037     JSObjectRef FunctionInstance_prototype(CYCastJSObject(context, CYGetProperty(context, FunctionInstance, prototype_s)));
3038     CYSetProperty(context, cy, CYJSString("FunctionInstance_prototype"), FunctionInstance_prototype);
3039     JSObjectRef Function_prototype(CYGetCachedObject(context, CYJSString("Function_prototype")));
3040     CYSetPrototype(context, FunctionInstance_prototype, Function_prototype);
3041
3042     JSObjectRef NumberInstance(JSObjectMakeConstructor(context, NumberInstance_, NULL));
3043     JSObjectRef NumberInstance_prototype(CYCastJSObject(context, CYGetProperty(context, NumberInstance, prototype_s)));
3044     CYSetProperty(context, cy, CYJSString("NumberInstance_prototype"), NumberInstance_prototype);
3045     JSObjectRef Number_prototype(CYGetCachedObject(context, CYJSString("Number_prototype")));
3046     CYSetPrototype(context, NumberInstance_prototype, Number_prototype);
3047
3048     JSObjectRef ObjectInstance(JSObjectMakeConstructor(context, ObjectInstance_, NULL));
3049     JSObjectRef ObjectInstance_prototype(CYCastJSObject(context, CYGetProperty(context, ObjectInstance, prototype_s)));
3050     CYSetProperty(context, cy, CYJSString("ObjectInstance_prototype"), ObjectInstance_prototype);
3051     JSObjectRef Object_prototype(CYGetCachedObject(context, CYJSString("Object_prototype")));
3052     CYSetPrototype(context, ObjectInstance_prototype, Object_prototype);
3053
3054     JSObjectRef StringInstance(JSObjectMakeConstructor(context, StringInstance_, NULL));
3055     JSObjectRef StringInstance_prototype(CYCastJSObject(context, CYGetProperty(context, StringInstance, prototype_s)));
3056     CYSetProperty(context, cy, CYJSString("StringInstance_prototype"), StringInstance_prototype);
3057     JSObjectRef String_prototype(CYGetCachedObject(context, CYJSString("String_prototype")));
3058     CYSetPrototype(context, StringInstance_prototype, String_prototype);
3059
3060     JSObjectRef Class_prototype(CYCastJSObject(context, CYGetProperty(context, Class, prototype_s)));
3061     CYSetProperty(context, cy, CYJSString("Class_prototype"), Class_prototype);
3062     CYSetPrototype(context, Class_prototype, Instance_prototype);
3063
3064     CYSetProperty(context, cycript, CYJSString("Instance"), Instance);
3065     CYSetProperty(context, cycript, CYJSString("Selector"), Selector);
3066     CYSetProperty(context, cycript, CYJSString("objc_super"), Super);
3067
3068     JSObjectRef box(JSObjectMakeFunctionWithCallback(context, CYJSString("box"), &Instance_box_callAsFunction));
3069     CYSetProperty(context, Instance, CYJSString("box"), box, kJSPropertyAttributeDontEnum);
3070
3071 #ifdef __APPLE__
3072     CYSetProperty(context, all, CYJSString("choose"), &choose, kJSPropertyAttributeDontEnum);
3073 #endif
3074
3075     CYSetProperty(context, all, CYJSString("objc_msgSend"), &$objc_msgSend, kJSPropertyAttributeDontEnum);
3076
3077     CYSetPrototype(context, CYCastJSObject(context, CYGetProperty(context, Message, prototype_s)), Function_prototype);
3078     CYSetPrototype(context, CYCastJSObject(context, CYGetProperty(context, Selector, prototype_s)), Function_prototype);
3079 } CYPoolCatch() }
3080
3081 static CYHooks CYObjectiveCHooks = {
3082     &CYObjectiveC_ExecuteStart,
3083     &CYObjectiveC_ExecuteEnd,
3084     &CYObjectiveC_CallFunction,
3085     &CYObjectiveC_Initialize,
3086     &CYObjectiveC_SetupContext,
3087     &CYObjectiveC_PoolFFI,
3088     &CYObjectiveC_FromFFI,
3089 };
3090
3091 struct CYObjectiveC {
3092     CYObjectiveC() {
3093         hooks_ = &CYObjectiveCHooks;
3094         // XXX: evil magic juju to make this actually take effect on a Mac when compiled with autoconf/libtool doom!
3095         _assert(hooks_ != NULL);
3096     }
3097 } CYObjectiveC;
3098
3099 extern "C" void CydgetSetupContext(JSGlobalContextRef context) { CYObjectiveTry_ {
3100     CYSetupContext(context);
3101 } CYObjectiveCatch }
3102
3103 extern "C" void CydgetMemoryParse(const uint16_t **data, size_t *size) { try {
3104     CYPool pool;
3105
3106     CYUTF8String utf8(CYPoolUTF8String(pool, CYUTF16String(*data, *size)));
3107     CYStream stream(utf8.data, utf8.data + utf8.size);
3108     utf8 = CYPoolCode(pool, stream);
3109
3110     CYUTF16String utf16(CYPoolUTF16String(pool, CYUTF8String(utf8.data, utf8.size)));
3111     size_t bytes(utf16.size * sizeof(uint16_t));
3112     uint16_t *copy(reinterpret_cast<uint16_t *>(malloc(bytes)));
3113     memcpy(copy, utf16.data, bytes);
3114
3115     *data = copy;
3116     *size = utf16.size;
3117 } catch (const CYException &exception) {
3118     CYPool pool;
3119     @throw [NSException exceptionWithName:NSRangeException reason:[NSString stringWithFormat:@"%s", exception.PoolCString(pool)] userInfo:nil];
3120 } }