Handler.mm

   1 /* Cycript - Inlining/Optimizing JavaScript Compiler
   2  * Copyright (C) 2009  Jay Freeman (saurik)
   3 */
   4
   5 /* Modified BSD License {{{ */
   6 /*
   7  *        Redistribution and use in source and binary
   8  * forms, with or without modification, are permitted
   9  * provided that the following conditions are met:
  10  *
  11  * 1. Redistributions of source code must retain the
  12  *    above copyright notice, this list of conditions
  13  *    and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the
  15  *    above copyright notice, this list of conditions
  16  *    and the following disclaimer in the documentation
  17  *    and/or other materials provided with the
  18  *    distribution.
  19  * 3. The name of the author may not be used to endorse
  20  *    or promote products derived from this software
  21  *    without specific prior written permission.
  22  *
  23  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS''
  24  * AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING,
  25  * BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
  26  * MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  27  * ARE DISCLAIMED. IN NO EVENT SHALL THE AUTHOR BE
  28  * LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  29  * EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  30  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
  31  * SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  32  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
  33  * LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR
  34  * TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
  35  * ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
  36  * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  37 */
  38 /* }}} */
  39
  40 #include "cycript.hpp"
  41
  42 #include "Pooling.hpp"
  43 #include "Parser.hpp"
  44
  45 #include "Cycript.tab.hh"
  46
  47 #include <Foundation/Foundation.h>
  48 #include <apr_thread_proc.h>
  49 #include <unistd.h>
  50 #include <sstream>
  51
  52 struct CYExecute_ {
  53     apr_pool_t *pool_;
  54     const char * volatile data_;
  55 };
  56
  57 // XXX: this is "tre lame"
  58 @interface CYClient_ : NSObject {
  59 }
  60
  61 - (void) execute:(NSValue *)value;
  62
  63 @end
  64
  65 @implementation CYClient_
  66
  67 - (void) execute:(NSValue *)value {
  68     CYExecute_ *execute(reinterpret_cast<CYExecute_ *>([value pointerValue]));
  69     const char *data(execute->data_);
  70     execute->data_ = NULL;
  71     execute->data_ = CYExecute(execute->pool_, data);
  72 }
  73
  74 @end
  75
  76 struct CYClient :
  77     CYData
  78 {
  79     int socket_;
  80     apr_thread_t *thread_;
  81
  82     CYClient(int socket) :
  83         socket_(socket)
  84     {
  85     }
  86
  87     ~CYClient() {
  88         _syscall(close(socket_));
  89     }
  90
  91     void Handle() {
  92         NSAutoreleasePool *pool = [[NSAutoreleasePool alloc] init];
  93
  94         CYClient_ *client = [[[CYClient_ alloc] init] autorelease];
  95
  96         for (;;) {
  97             size_t size;
  98             if (!CYRecvAll(socket_, &size, sizeof(size)))
  99                 return;
 100
 101             CYPool pool;
 102             char *data(new(pool) char[size + 1]);
 103             if (!CYRecvAll(socket_, data, size))
 104                 return;
 105             data[size] = '\0';
 106
 107             CYDriver driver("");
 108             cy::parser parser(driver);
 109
 110             driver.data_ = data;
 111             driver.size_ = size;
 112
 113             const char *json;
 114             if (parser.parse() != 0 || !driver.errors_.empty()) {
 115                 json = NULL;
 116                 size = _not(size_t);
 117             } else {
 118                 CYContext context(driver.pool_);
 119                 driver.program_->Replace(context);
 120                 std::ostringstream str;
 121                 CYOutput out(str);
 122                 out << *driver.program_;
 123                 std::string code(str.str());
 124                 CYExecute_ execute = {pool, code.c_str()};
 125                 [client performSelectorOnMainThread:@selector(execute:) withObject:[NSValue valueWithPointer:&execute] waitUntilDone:YES];
 126                 json = execute.data_;
 127                 size = json == NULL ? _not(size_t) : strlen(json);
 128             }
 129
 130             if (!CYSendAll(socket_, &size, sizeof(size)))
 131                 return;
 132             if (json != NULL)
 133                 if (!CYSendAll(socket_, json, size))
 134                     return;
 135         }
 136
 137         [pool release];
 138     }
 139 };
 140
 141 static void * APR_THREAD_FUNC OnClient(apr_thread_t *thread, void *data) {
 142     CYClient *client(reinterpret_cast<CYClient *>(data));
 143     client->Handle();
 144     delete client;
 145     return NULL;
 146 }
 147
 148 extern "C" void CYHandleClient(apr_pool_t *pool, int socket) {
 149     CYClient *client(new(pool) CYClient(socket));
 150     apr_threadattr_t *attr;
 151     _aprcall(apr_threadattr_create(&attr, client->pool_));
 152     _aprcall(apr_thread_create(&client->thread_, attr, &OnClient, client, client->pool_));
 153 }