configure.ac

   1 AC_PREREQ([2.65])
   2 AC_INIT([Cycript], [0.9], [saurik@saurik.com], [cycript], [http://www.cycript.org/])
   3 AC_CONFIG_SRCDIR([Console.cpp])
   4 AC_CONFIG_AUX_DIR([.])
   5 LT_INIT([disable-static])
   6 PKG_PROG_PKG_CONFIG([0.22])
   7 CHECK_GNU_MAKE
   8 AC_SUBST([GMAKE], [$_cv_gnu_make_command])
   9 AS_IF([test "x$GMAKE" = x], [AC_MSG_ERROR([You need GNU make])])
  10 AC_PATH_PROGS([_BASH], [bash])
  11 AS_IF([test "x$_BASH" = x], [AC_MSG_ERROR([You need GNU bash])])
  12 AC_PATH_PROGS([TIME], [time])
  13 AC_DEFUN([CY_CHECK_PROGS_VERSION], [
  14         AC_MSG_CHECKING(for ]$2[ >= ]$5[)
  15         AC_PATH_PROGS_FEATURE_CHECK(]$1[, ]$3[,
  16                 AS_VERSION_COMPARE(`$ac_path_]$1[ ]$4[`, ]$5[, ,
  17                         ac_cv_path_]$1[=$ac_path_]$1[
  18                 ,
  19                         ac_cv_path_]$1[=$ac_path_]$1[
  20                 )
  21         ,
  22                 AC_MSG_RESULT(no)
  23                 AC_MSG_ERROR(You need ]$2[ ]$5[ or greater)
  24         )
  25         AC_SUBST(]$1[, $ac_cv_path_]$1[)
  26         AC_MSG_RESULT($]$1[)
  27 ])
  28 AC_ARG_VAR([BISON], [GNU Project parser generator (yacc replacement)])
  29 CY_CHECK_PROGS_VERSION([BISON], [bison], [bison],
  30         [-V | $SED -e '1 s/^bison (GNU Bison) \(.*\)$/\1/p;d'], [2.3])
  31 AC_ARG_VAR([FLEX], [the fast lexical analyser generator])
  32 CY_CHECK_PROGS_VERSION([FLEX], [flex], [flex],
  33         [--version | $SED -e '1 s/^.* \(@<:@0-9.@:>@*\)$/\1/p;d'], [2.5.33])
  34 AC_ARG_VAR([GPERF], [perfect hash function generator])
  35 CY_CHECK_PROGS_VERSION([GPERF], [gperf], [gperf],
  36         [--version | $SED -e '1 s/^.* \(@<:@0-9.@:>@*\)$/\1/p;d'], [3.0.3])
  37 AC_PROG_INSTALL
  38 AC_MSG_CHECKING([for GNU tar >=1.19])
  39 AC_PATH_PROGS_FEATURE_CHECK([GNUTAR], [tar gtar gnutar], [
  40         AS_IF([test "x`$ac_path_GNUTAR --version | $SED -e '1 s/^tar (GNU tar)/&/p;d'`" != x], [
  41                 AS_VERSION_COMPARE([`$ac_path_GNUTAR --version | $SED -e '1 s/^tar (GNU tar) \(.*\)$/\1/p;d'`], [1.19], , [
  42                         ac_cv_path_GNUTAR=$ac_path_GNUTAR
  43                 ], [
  44                         ac_cv_path_GNUTAR=$ac_path_GNUTAR
  45                 ])
  46         ])
  47 ])
  48 AS_IF([test "x$ac_cv_path_GNUTAR" != x], [
  49         AC_SUBST([GNUTAR], [$ac_cv_path_GNUTAR])
  50         AC_MSG_RESULT([$GNUTAR])
  51 ], [
  52         AC_SUBST([GNUTAR], [:])
  53         AC_MSG_RESULT([no])
  54 ])
  55 AC_CHECK_PROGS([SVN], [svn])
  56 AC_CHECK_PROGS([SVNVERSION], [svnversion])
  57 AC_PROG_CXX
  58 AC_PROG_OBJCXX
  59 AC_DEFUN([CY_CHECK_UNIVERSAL], [
  60         AC_MSG_CHECKING([for universal binary support])
  61         AS_CASE([$host_vendor], [apple], [
  62                 AS_CASE([$host_cpu], [i386|x86_64], [
  63                         for cy_arch in i386 x86_64; do
  64                                 cy_save_CXXFLAGS=$CXXFLAGS
  65                                 AC_LIB_APPENDTOVAR([CXXFLAGS], ["-arch $cy_arch"])
  66                                 AC_TRY_LINK([], [], [
  67                                         AC_LIB_APPENDTOVAR([cy_arches], [$cy_arch])
  68                                         AC_LIB_APPENDTOVAR([CFLAGS], ["-arch $cy_arch"])
  69                                         AC_LIB_APPENDTOVAR([LDFLAGS], ["-arch $cy_arch"])
  70                                         AC_LIB_APPENDTOVAR([OBJCXXFLAGS], ["-arch $cy_arch"])
  71                                 ], [
  72                                         CXXFLAGS=$cy_save_CXXFLAGS
  73                                 ])
  74                         done
  75                 ])
  76         ])
  77         AC_MSG_RESULT([${cy_arches-no}])
  78 ])
  79 AC_ARG_ENABLE([universal-binary], [AS_HELP_STRING(
  80         [--disable-universal-binary],
  81         [do not build with universal binary support on Darwin]
  82 )], [
  83         AS_CASE([$enableval], [no], [], [CY_CHECK_UNIVERSAL])
  84 ], [CY_CHECK_UNIVERSAL])
  85 AC_ARG_WITH([frameworks], [AS_HELP_STRING(
  86         [--with-frameworks=DIRS],
  87         [add to DIRS (space separated) to the Darwin include path for frameworks with -F]
  88 )], [
  89         for cy_framework in $withval; do
  90                 AC_LIB_APPENDTOVAR([CFLAGS], [-F$cy_framework])
  91                 AC_LIB_APPENDTOVAR([CXXFLAGS], [-F$cy_framework])
  92                 AC_LIB_APPENDTOVAR([OBJCCXXFLAGS], [-F$cy_framework])
  93         done
  94 ])
  95 AC_LANG([C++])
  96 APR_FIND_APR([], [], [1], [1])
  97 AS_CASE([$apr_found], [yes], [
  98         AC_LIB_APPENDTOVAR([CPPFLAGS], [`$apr_config --includes`])
  99         AC_SUBST([LTLIBAPR], [`$apr_config --link-libtool`])
 100 ], [AC_MSG_ERROR([You need apr])])
 101 AC_DEFUN([CY_CHECK_JAVASCRIPTCORE], [
 102         PKG_CHECK_MODULES([WEBKIT], [webkit-1.0], [
 103                 CY_EXECUTE=1
 104                 AC_LIB_APPENDTOVAR([CXXFLAGS], [`$PKG_CONFIG --cflags webkit-1.0`])
 105                 AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs webkit-1.0`])
 106         ], [
 107                 PKG_CHECK_MODULES([WEBKIT], [WebKitGtk], [
 108                         CY_EXECUTE=1
 109                         AC_LIB_APPENDTOVAR([CXXFLAGS], [`$PKG_CONFIG --cflags WebKitGtk`])
 110                         AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs WebKitGtk`])
 111                 ], [
 112                         AC_CHECK_FRAMEWORK([JavaScriptCore], [
 113                                 #include <JavaScriptCore/JSBase.h>
 114                         ], [JSEvaluateScript(0, 0, 0, 0, 0, 0);], [CY_EXECUTE=1])
 115                 ])
 116         ])
 117 ])
 118 AC_DEFUN([CY_CHECK_JAVASCRIPT], [
 119         CY_CHECK_JAVASCRIPTCORE
 120 ])
 121 AC_ARG_ENABLE([javascript], [AS_HELP_STRING(
 122         [--enable-javascript@<:@=ENGINE@:>@],
 123         [use a JavaScript runtime (currently the only available option for ENGINE is JavaScriptCore) @<:@default=yes@:>@]
 124 )], [
 125         AS_CASE([$enableval], [yes], [CY_CHECK_JAVASCRIPT], [no], [
 126                 AC_SUBST([CY_EXECUTE], [0])
 127         ], [JavaScriptCore], [
 128                 CY_CHECK_JAVASCRIPTCORE
 129         ], [AC_MSG_ERROR([Unknown JavaScript engine: $enableval])])
 130 ], [CY_CHECK_JAVASCRIPT])
 131 AC_DEFUN([CY_CHECK_PKG_CONFIG_LIBFFI], [
 132         PKG_CHECK_MODULES([LIBFFI], [libffi], [
 133                 AC_LIB_APPENDTOVAR([CXXFLAGS], [`$PKG_CONFIG --cflags libffi`])
 134                 AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs libffi`])
 135         ], [
 136                 AC_MSG_ERROR([You need libffi])
 137         ])
 138 ])
 139 AS_CASE([$CY_EXECUTE], [1], [
 140         AC_SUBST([CY_EXECUTE])
 141         AC_CHECK_HEADERS([ffi.h ffi/ffi.h], [break])
 142         AS_IF([test "x$ac_cv_header_ffi_h" = xno && test "x$ac_cv_header_ffi_ffi_h" = xno], [
 143                 CY_CHECK_PKG_CONFIG_LIBFFI
 144         ], [
 145                 AC_SEARCH_LIBS([ffi_call], [ffi])
 146                 AS_CASE([$ac_cv_search_ffi_call], [no], [CY_CHECK_PKG_CONFIG_LIBFFI])
 147         ])
 148         AC_LANG_PUSH([Objective C++])
 149         AC_MSG_CHECKING([if we really have Objective C++])
 150         AC_COMPILE_IFELSE([
 151                 // This space intentionally left blank
 152         ], [
 153                 CY_OBJECTIVEC=1
 154                 AC_MSG_RESULT([yes])
 155         ], [AC_MSG_RESULT([no])])
 156         AS_IF([test "x$CY_OBJECTIVEC" = x1], [
 157                 AC_CHECK_FRAMEWORK([CoreFoundation], [
 158                         #include <CoreFoundation/CFBase.h>
 159                 ], [CFAllocatorGetDefault();], [
 160                         AC_SUBST([CY_OBJECTIVEC])
 161                         AC_CHECK_FRAMEWORK([Foundation], [
 162                                 #include <Foundation/NSObject.h>
 163                         ], [[[[NSObject alloc] init];]])
 164                         AC_CHECK_FRAMEWORK([WebKit], [
 165                                 #include <WebKit/WebScriptObject.h>
 166                         ], [[[[WebScriptObject alloc] init];]])
 167                 ], [
 168                         AC_ARG_VAR([GNUSTEP_CONFIG], [prints information about the current gnustep installation])
 169                         AC_CHECK_PROGS([GNUSTEP_CONFIG], [gnustep-config])
 170                         AS_IF([test "x$GNUSTEP_CONFIG" != x], [
 171                                 AC_SUBST([CY_OBJECTIVEC])
 172                                 AC_LIB_APPENDTOVAR([OBJCXXFLAGS], [`$GNUSTEP_CONFIG --objc-flags`])
 173                                 AC_LIB_APPENDTOVAR([LIBS], [`$GNUSTEP_CONFIG --base-libs`])
 174                         ], [AC_SUBST([CY_OBJECTIVEC], [0])])
 175                 ])
 176         ])
 177         AC_LANG_POP([Objective C++])
 178 ])
 179 VL_LIB_READLINE
 180 AS_CASE([$vl_cv_lib_readline], [no], [AC_MSG_ERROR([You need readline])])
 181 AC_LANG_PUSH([C])
 182 AM_ICONV
 183 AS_CASE([$am_cv_func_iconv], [yes], [], [
 184         for cy_iconv_prefix_arg in $CFLAGS $CXXFLAGS $OBJCXXFLAGS $LDFLAGS $LIBS; do
 185                 AS_CASE([$cy_iconv_prefix_arg], [-I*], [
 186                         AC_LIB_APPENDTOVAR([cy_iconv_prefixes], [`echo $cy_iconv_prefix_arg | sed -e 's/^-I//;s|/include$||'`])
 187                 ], [-L*], [
 188                         AC_LIB_APPENDTOVAR([cy_iconv_prefixes], [`echo $cy_iconv_prefix_arg | sed -e 's/^-L//;s|/lib$||'`])
 189                 ])
 190         done
 191         for with_libiconv_prefix in $cy_iconv_prefixes; do
 192                 AS_UNSET([am_cv_func_iconv])
 193                 AM_ICONV_LINKFLAGS_BODY
 194                 AM_ICONV
 195         done
 196 ])
 197 AS_CASE([$am_cv_func_iconv], [yes], [], [AC_MSG_ERROR([You need iconv])])
 198 AC_LANG_POP([C])
 199 AS_IF([test "x$CY_OBJECTIVEC" = x1], [
 200         AC_CHECK_HEADER([mach/mach.h], [
 201                 AC_CHECK_TOOLS([_OTOOL], [otool])
 202                 AS_IF([test "x$_OTOOL" = x], [AC_MSG_ERROR([You need otool])])
 203                 AC_CHECK_TOOLS([_LIPO], [lipo])
 204                 AS_IF([test "x$_LIPO" = x], [AC_MSG_ERROR([You need lipo])])
 205                 AC_CHECK_TOOLS([_NM], [nm])
 206                 AS_IF([test "x$_NM" = x], [AC_MSG_ERROR([You need nm])])
 207                 AC_SUBST([SO], [$acl_shlibext])
 208                 AC_SUBST([CY_OBJECTIVEC_MACH], [1])
 209                 AC_SUBST([CY_ATTACH_GROUP], [procmod])
 210         ])
 211 ])
 212 AS_IF([test "x$GMAKE" != xmake], [
 213         AC_CONFIG_FILES([Makefile])
 214 ])
 215 AC_CONFIG_FILES([GNUmakefile])
 216 AC_OUTPUT