Cycript.y

   1 %code top {
   2 #include "Cycript.tab.hh"
   3 #define scanner driver.scanner_
   4 #define YYSTACKEXPANDABLE 1
   5 }
   6
   7 %code requires {
   8 #include "Parser.hpp"
   9
  10 typedef struct {
  11     bool newline_;
  12
  13     union {
  14         CYArgument *argument_;
  15         CYBoolean *boolean_;
  16         CYClause *clause_;
  17         CYCatch *catch_;
  18         CYCompound *compound_;
  19         CYDeclaration *declaration_;
  20         CYDeclarations *declarations_;
  21         CYElement *element_;
  22         CYExpression *expression_;
  23         CYFalse *false_;
  24         CYForInitialiser *for_;
  25         CYForInInitialiser *forin_;
  26         CYIdentifier *identifier_;
  27         CYLiteral *literal_;
  28         CYName *name_;
  29         CYNull *null_;
  30         CYNumber *number_;
  31         CYParameter *parameter_;
  32         CYProperty *property_;
  33         CYSelectorPart *selector_;
  34         CYSource *source_;
  35         CYStatement *statement_;
  36         CYString *string_;
  37         CYThis *this_;
  38         CYTrue *true_;
  39         CYWord *word_;
  40     };
  41 } YYSTYPE;
  42
  43 }
  44
  45 %code provides {
  46 int cylex(YYSTYPE *lvalp, cy::location *llocp, void *scanner);
  47 }
  48
  49 %name-prefix "cy"
  50
  51 %language "C++"
  52 %locations
  53
  54 %initial-action {
  55     @$.begin.filename = @$.end.filename = &driver.filename_;
  56 };
  57
  58 %defines
  59
  60 %debug
  61 %error-verbose
  62
  63 %parse-param { CYDriver &driver }
  64 %lex-param { void *scanner }
  65
  66 %token Ampersand "&"
  67 %token AmpersandAmpersand "&&"
  68 %token AmpersandEqual "&="
  69 %token Carrot "^"
  70 %token CarrotEqual "^="
  71 %token Equal "="
  72 %token EqualEqual "=="
  73 %token EqualEqualEqual "==="
  74 %token Exclamation "!"
  75 %token ExclamationEqual "!="
  76 %token ExclamationEqualEqual "!=="
  77 %token Hyphen "-"
  78 %token HyphenEqual "-="
  79 %token HyphenHyphen "--"
  80 %token HyphenHyphen_ "\n--"
  81 %token HyphenRight "->"
  82 %token Left "<"
  83 %token LeftEqual "<="
  84 %token LeftLeft "<<"
  85 %token LeftLeftEqual "<<="
  86 %token Percent "%"
  87 %token PercentEqual "%="
  88 %token Period "."
  89 %token Pipe "|"
  90 %token PipeEqual "|="
  91 %token PipePipe "||"
  92 %token Plus "+"
  93 %token PlusEqual "+="
  94 %token PlusPlus "++"
  95 %token PlusPlus_ "\n++"
  96 %token Right ">"
  97 %token RightEqual ">="
  98 %token RightRight ">>"
  99 %token RightRightEqual ">>="
 100 %token RightRightRight ">>>"
 101 %token RightRightRightEqual ">>>="
 102 %token Slash "/"
 103 %token SlashEqual "/="
 104 %token Star "*"
 105 %token StarEqual "*="
 106 %token Tilde "~"
 107
 108 %token Colon ":"
 109 %token Comma ","
 110 %token Question "?"
 111 %token SemiColon ";"
 112 %token NewLine "\n"
 113
 114 %token OpenParen "("
 115 %token CloseParen ")"
 116
 117 %token OpenBrace "{"
 118 %token CloseBrace "}"
 119
 120 %token OpenBracket "["
 121 %token CloseBracket "]"
 122
 123 %token AtSelector "@selector"
 124 %token AtImplementation "@implementation"
 125 %token AtEnd "@end"
 126
 127 %token <word_> Break "break"
 128 %token <word_> Case "case"
 129 %token <word_> Catch "catch"
 130 %token <word_> Continue "continue"
 131 %token <word_> Default "default"
 132 %token <word_> Delete "delete"
 133 %token <word_> Do "do"
 134 %token <word_> Else "else"
 135 %token <false_> False "false"
 136 %token <word_> Finally "finally"
 137 %token <word_> For "for"
 138 %token <word_> Function "function"
 139 %token <word_> If "if"
 140 %token <word_> In "in"
 141 %token <word_> InstanceOf "instanceof"
 142 %token <word_> New "new"
 143 %token <null_> Null "null"
 144 %token <word_> Return "return"
 145 %token <word_> Switch "switch"
 146 %token <this_> This "this"
 147 %token <word_> Throw "throw"
 148 %token <true_> True "true"
 149 %token <word_> Try "try"
 150 %token <word_> TypeOf "typeof"
 151 %token <word_> Var "var"
 152 %token <word_> Void "void"
 153 %token <word_> While "while"
 154 %token <word_> With "with"
 155
 156 %token <word_> Abstract "abstract"
 157 %token <word_> Boolean "boolean"
 158 %token <word_> Byte "byte"
 159 %token <word_> Char "char"
 160 %token <word_> Class "class"
 161 %token <word_> Const "const"
 162 %token <word_> Debugger "debugger"
 163 %token <word_> Double "double"
 164 %token <word_> Enum "enum"
 165 %token <word_> Export "export"
 166 %token <word_> Extends "extends"
 167 %token <word_> Final "final"
 168 %token <word_> Float "float"
 169 %token <word_> Goto "goto"
 170 %token <word_> Implements "implements"
 171 %token <word_> Import "import"
 172 %token <word_> Int "int"
 173 %token <word_> Interface "interface"
 174 %token <word_> Long "long"
 175 %token <word_> Native "native"
 176 %token <word_> Package "package"
 177 %token <word_> Private "private"
 178 %token <word_> Protected "protected"
 179 %token <word_> Public "public"
 180 %token <word_> Short "short"
 181 %token <word_> Static "static"
 182 %token <word_> Super "super"
 183 %token <word_> Synchronized "synchronized"
 184 %token <word_> Throws "throws"
 185 %token <word_> Transient "transient"
 186 %token <word_> Volatile "volatile"
 187
 188 %token <identifier_> Identifier
 189 %token <number_> NumericLiteral
 190 %token <string_> StringLiteral
 191
 192 %type <expression_> AdditiveExpression
 193 %type <expression_> AdditiveExpressionNoBF
 194 %type <argument_> ArgumentList
 195 %type <argument_> ArgumentList_
 196 %type <argument_> ArgumentListOpt
 197 %type <argument_> Arguments
 198 %type <literal_> ArrayLiteral
 199 %type <expression_> AssignmentExpression
 200 %type <expression_> AssignmentExpressionNoBF
 201 %type <expression_> AssignmentExpressionNoIn
 202 %type <expression_> BitwiseANDExpression
 203 %type <expression_> BitwiseANDExpressionNoBF
 204 %type <expression_> BitwiseANDExpressionNoIn
 205 %type <statement_> Block
 206 %type <boolean_> BooleanLiteral
 207 %type <expression_> BitwiseORExpression
 208 %type <expression_> BitwiseORExpressionNoBF
 209 %type <expression_> BitwiseORExpressionNoIn
 210 %type <expression_> BitwiseXORExpression
 211 %type <expression_> BitwiseXORExpressionNoBF
 212 %type <expression_> BitwiseXORExpressionNoIn
 213 %type <statement_> BreakStatement
 214 %type <expression_> CallExpression
 215 %type <expression_> CallExpressionNoBF
 216 %type <clause_> CaseBlock
 217 %type <clause_> CaseClause
 218 %type <clause_> CaseClausesOpt
 219 %type <catch_> CatchOpt
 220 %type <expression_> ConditionalExpression
 221 %type <expression_> ConditionalExpressionNoBF
 222 %type <expression_> ConditionalExpressionNoIn
 223 %type <statement_> ContinueStatement
 224 %type <clause_> DefaultClause
 225 %type <statement_> DoWhileStatement
 226 %type <expression_> Element
 227 %type <expression_> ElementOpt
 228 %type <element_> ElementList
 229 %type <element_> ElementListOpt
 230 %type <statement_> ElseStatementOpt
 231 %type <statement_> EmptyStatement
 232 %type <expression_> EqualityExpression
 233 %type <expression_> EqualityExpressionNoBF
 234 %type <expression_> EqualityExpressionNoIn
 235 %type <expression_> Expression
 236 %type <expression_> ExpressionOpt
 237 %type <compound_> Expression_
 238 %type <expression_> ExpressionNoBF
 239 %type <expression_> ExpressionNoIn
 240 %type <compound_> ExpressionNoIn_
 241 %type <expression_> ExpressionNoInOpt
 242 %type <statement_> ExpressionStatement
 243 %type <statement_> FinallyOpt
 244 %type <statement_> ForStatement
 245 %type <for_> ForStatementInitialiser
 246 %type <statement_> ForInStatement
 247 %type <forin_> ForInStatementInitialiser
 248 %type <parameter_> FormalParameterList
 249 %type <parameter_> FormalParameterList_
 250 %type <source_> FunctionBody
 251 %type <source_> FunctionDeclaration
 252 %type <expression_> FunctionExpression
 253 %type <identifier_> IdentifierOpt
 254 %type <statement_> IfStatement
 255 %type <expression_> Initialiser
 256 %type <expression_> InitialiserOpt
 257 %type <expression_> InitialiserNoIn
 258 %type <expression_> InitialiserNoInOpt
 259 %type <statement_> IterationStatement
 260 %type <statement_> LabelledStatement
 261 %type <expression_> LeftHandSideExpression
 262 %type <expression_> LeftHandSideExpression_
 263 %type <expression_> LeftHandSideExpressionNoBF
 264 %type <literal_> Literal
 265 %type <expression_> LogicalANDExpression
 266 %type <expression_> LogicalANDExpressionNoBF
 267 %type <expression_> LogicalANDExpressionNoIn
 268 %type <expression_> LogicalORExpression
 269 %type <expression_> LogicalORExpressionNoBF
 270 %type <expression_> LogicalORExpressionNoIn
 271 %type <expression_> MemberExpression
 272 %type <expression_> MemberExpression_
 273 %type <expression_> MemberExpressionNoBF
 274 %type <expression_> MultiplicativeExpression
 275 %type <expression_> MultiplicativeExpressionNoBF
 276 %type <expression_> NewExpression
 277 %type <expression_> NewExpression_
 278 %type <expression_> NewExpressionNoBF
 279 %type <null_> NullLiteral
 280 %type <literal_> ObjectLiteral
 281 %type <expression_> PostfixExpression
 282 %type <expression_> PostfixExpressionNoBF
 283 %type <expression_> PrimaryExpression
 284 %type <expression_> PrimaryExpression_
 285 %type <expression_> PrimaryExpressionNoBF
 286 %type <source_> Program
 287 %type <name_> PropertyName
 288 %type <property_> PropertyNameAndValueList
 289 %type <property_> PropertyNameAndValueList_
 290 %type <property_> PropertyNameAndValueListOpt
 291 %type <expression_> RelationalExpression
 292 %type <expression_> RelationalExpressionNoBF
 293 %type <expression_> RelationalExpressionNoIn
 294 %type <statement_> ReturnStatement
 295 %type <selector_> SelectorExpression
 296 %type <selector_> SelectorExpression_
 297 %type <selector_> SelectorExpressionOpt
 298 %type <expression_> ShiftExpression
 299 %type <expression_> ShiftExpressionNoBF
 300 %type <source_> SourceElement
 301 %type <source_> SourceElements
 302 %type <statement_> Statement
 303 %type <statement_> StatementList
 304 %type <statement_> StatementListOpt
 305 %type <statement_> SwitchStatement
 306 %type <statement_> ThrowStatement
 307 %type <statement_> TryStatement
 308 %type <expression_> UnaryExpression
 309 %type <expression_> UnaryExpression_
 310 %type <expression_> UnaryExpressionNoBF
 311 %type <declaration_> VariableDeclaration
 312 %type <declaration_> VariableDeclarationNoIn
 313 %type <declarations_> VariableDeclarationList
 314 %type <declarations_> VariableDeclarationList_
 315 %type <declarations_> VariableDeclarationListNoIn
 316 %type <declarations_> VariableDeclarationListNoIn_
 317 %type <statement_> VariableStatement
 318 %type <statement_> WhileStatement
 319 %type <statement_> WithStatement
 320 %type <word_> Word
 321 %type <word_> WordOpt
 322
 323 %type <expression_> MessageExpression
 324 %type <argument_> SelectorCall
 325 %type <argument_> SelectorCall_
 326 %type <argument_> SelectorList
 327 %type <argument_> VariadicCall
 328
 329 %left "*" "/" "%"
 330 %left "+" "-"
 331 %left "<<" ">>" ">>>"
 332 %left "<" ">" "<=" ">=" "instanceof" "in"
 333 %left "==" "!=" "===" "!=="
 334 %left "&"
 335 %left "^"
 336 %left "|"
 337 %left "&&"
 338 %left "||"
 339
 340 %right "=" "*=" "/=" "%=" "+=" "-=" "<<=" ">>=" ">>>=" "&=" "^=" "|="
 341
 342 %nonassoc "if"
 343 %nonassoc "else"
 344
 345 %start Program
 346
 347 %%
 348
 349 TerminatorOpt
 350     : ";"
 351     | "\n"
 352     | error { yyerrok; driver.errors_.pop_back(); }
 353     ;
 354
 355 Terminator
 356     : ";"
 357     | "\n"
 358     | error { if (yychar != 0 && yychar != cy::parser::token::CloseBrace && !yylval.newline_) YYABORT; else { yyerrok; driver.errors_.pop_back(); } }
 359     ;
 360
 361 CommaOpt
 362     : ","
 363     |
 364     ;
 365
 366 NewLineOpt
 367     : "\n"
 368     |
 369     ;
 370
 371 WordOpt
 372     : Word { $$ = $1; }
 373     | { $$ = NULL; }
 374     ;
 375
 376 Word
 377     : Identifier { $$ = $1; }
 378     | "abstract" { $$ = $1; }
 379     | "boolean" { $$ = $1; }
 380     | "break" NewLineOpt { $$ = $1; }
 381     | "byte" { $$ = $1; }
 382     | "case" { $$ = $1; }
 383     | "catch" { $$ = $1; }
 384     | "char" { $$ = $1; }
 385     | "class" { $$ = $1; }
 386     | "const" { $$ = $1; }
 387     | "continue" NewLineOpt { $$ = $1; }
 388     | "debugger" { $$ = $1; }
 389     | "default" { $$ = $1; }
 390     | "delete" { $$ = $1; }
 391     | "do" { $$ = $1; }
 392     | "double" { $$ = $1; }
 393     | "else" { $$ = $1; }
 394     | "enum" { $$ = $1; }
 395     | "export" { $$ = $1; }
 396     | "extends" { $$ = $1; }
 397     | "false" { $$ = $1; }
 398     | "final" { $$ = $1; }
 399     | "finally" { $$ = $1; }
 400     | "float" { $$ = $1; }
 401     | "for" { $$ = $1; }
 402     | "function" { $$ = $1; }
 403     | "goto" { $$ = $1; }
 404     | "if" { $$ = $1; }
 405     | "implements" { $$ = $1; }
 406     | "import" { $$ = $1; }
 407     /* XXX: | "in" { $$ = $1; } */
 408     /* XXX: | "instanceof" { $$ = $1; } */
 409     | "int" { $$ = $1; }
 410     | "interface" { $$ = $1; }
 411     | "long" { $$ = $1; }
 412     | "native" { $$ = $1; }
 413     | "new" { $$ = $1; }
 414     | "null" { $$ = $1; }
 415     | "package" { $$ = $1; }
 416     | "private" { $$ = $1; }
 417     | "protected" { $$ = $1; }
 418     | "public" { $$ = $1; }
 419     | "return" NewLineOpt { $$ = $1; }
 420     | "short" { $$ = $1; }
 421     | "static" { $$ = $1; }
 422     | "super" { $$ = $1; }
 423     | "switch" { $$ = $1; }
 424     | "synchronized" { $$ = $1; }
 425     | "this" { $$ = $1; }
 426     | "throw" NewLineOpt { $$ = $1; }
 427     | "throws" { $$ = $1; }
 428     | "transient" { $$ = $1; }
 429     | "true" { $$ = $1; }
 430     | "try" { $$ = $1; }
 431     | "typeof" { $$ = $1; }
 432     | "var" { $$ = $1; }
 433     | "void" { $$ = $1; }
 434     | "volatile" { $$ = $1; }
 435     | "while" { $$ = $1; }
 436     | "with" { $$ = $1; }
 437     ;
 438
 439 IdentifierOpt
 440     : Identifier { $$ = $1; }
 441     | { $$ = NULL; }
 442     ;
 443
 444 Literal
 445     : NullLiteral { $$ = $1; }
 446     | BooleanLiteral { $$ = $1; }
 447     | NumericLiteral { $$ = $1; }
 448     | StringLiteral { $$ = $1; }
 449     ;
 450
 451 NullLiteral
 452     : "null" { $$ = $1; }
 453     ;
 454
 455 BooleanLiteral
 456     : "true" { $$ = $1; }
 457     | "false" { $$ = $1; }
 458     ;
 459
 460 /* 11.1 Primary Expressions {{{ */
 461 PrimaryExpression_
 462     : "this" { $$ = $1; }
 463     | Identifier { $$ = new(driver.pool_) CYVariable($1); }
 464     | Literal { $$ = $1; }
 465     | ArrayLiteral { $$ = $1; }
 466     | "(" Expression ")" { $$ = $2; }
 467     ;
 468
 469 PrimaryExpression
 470     : ObjectLiteral { $$ = $1; }
 471     | PrimaryExpression_ { $$ = $1; }
 472     ;
 473
 474 PrimaryExpressionNoBF
 475     : PrimaryExpression_ { $$ = $1; }
 476     ;
 477 /* }}} */
 478 /* 11.1.4 Array Initialiser {{{ */
 479 ArrayLiteral
 480     : "[" ElementListOpt "]" { $$ = new(driver.pool_) CYArray($2); }
 481     ;
 482
 483 Element
 484     : AssignmentExpression { $$ = $1; }
 485     ;
 486
 487 ElementOpt
 488     : Element { $$ = $1; }
 489     | { $$ = NULL; }
 490     ;
 491
 492 ElementListOpt
 493     : ElementList { $$ = $1; }
 494     | { $$ = NULL; }
 495     ;
 496
 497 ElementList
 498     : ElementOpt "," ElementListOpt { $$ = new(driver.pool_) CYElement($1, $3); }
 499     | Element { $$ = new(driver.pool_) CYElement($1, NULL); }
 500     ;
 501 /* }}} */
 502 /* 11.1.5 Object Initialiser {{{ */
 503 ObjectLiteral
 504     : "{" PropertyNameAndValueListOpt "}" { $$ = new(driver.pool_) CYObject($2); }
 505     ;
 506
 507 PropertyNameAndValueList_
 508     : "," PropertyNameAndValueList { $$ = $2; }
 509     | CommaOpt { $$ = NULL; }
 510     ;
 511
 512 PropertyNameAndValueListOpt
 513     : PropertyNameAndValueList { $$ = $1; }
 514     | { $$ = NULL; }
 515     ;
 516
 517 PropertyNameAndValueList
 518     : PropertyName ":" AssignmentExpression PropertyNameAndValueList_ { $$ = new(driver.pool_) CYProperty($1, $3, $4); }
 519     ;
 520
 521 PropertyName
 522     : Identifier { $$ = $1; }
 523     | StringLiteral { $$ = $1; }
 524     | NumericLiteral { $$ = $1; }
 525     ;
 526 /* }}} */
 527
 528 MemberExpression_
 529     : "new" MemberExpression Arguments { $$ = new(driver.pool_) CYNew($2, $3); }
 530     ;
 531
 532 MemberExpression
 533     : PrimaryExpression { $$ = $1; }
 534     | FunctionExpression { $$ = $1; }
 535     | MemberExpression "[" Expression "]" { $$ = new(driver.pool_) CYMember($1, $3); }
 536     | MemberExpression "." Identifier { $$ = new(driver.pool_) CYMember($1, new(driver.pool_) CYString($3)); }
 537     | MemberExpression_ { $$ = $1; }
 538     ;
 539
 540 MemberExpressionNoBF
 541     : PrimaryExpressionNoBF { $$ = $1; }
 542     | MemberExpressionNoBF "[" Expression "]" { $$ = new(driver.pool_) CYMember($1, $3); }
 543     | MemberExpressionNoBF "." Identifier { $$ = new(driver.pool_) CYMember($1, new(driver.pool_) CYString($3)); }
 544     | MemberExpression_ { $$ = $1; }
 545     ;
 546
 547 NewExpression_
 548     : "new" NewExpression { $$ = new(driver.pool_) CYNew($2, NULL); }
 549     ;
 550
 551 NewExpression
 552     : MemberExpression { $$ = $1; }
 553     | NewExpression_ { $$ = $1; }
 554     ;
 555
 556 NewExpressionNoBF
 557     : MemberExpressionNoBF { $$ = $1; }
 558     | NewExpression_ { $$ = $1; }
 559     ;
 560
 561 CallExpression
 562     : MemberExpression Arguments { $$ = new(driver.pool_) CYCall($1, $2); }
 563     | CallExpression Arguments { $$ = new(driver.pool_) CYCall($1, $2); }
 564     | CallExpression "[" Expression "]" { $$ = new(driver.pool_) CYMember($1, $3); }
 565     | CallExpression "." Identifier { $$ = new(driver.pool_) CYMember($1, new(driver.pool_) CYString($3)); }
 566     ;
 567
 568 CallExpressionNoBF
 569     : MemberExpressionNoBF Arguments { $$ = new(driver.pool_) CYCall($1, $2); }
 570     | CallExpressionNoBF Arguments { $$ = new(driver.pool_) CYCall($1, $2); }
 571     | CallExpressionNoBF "[" Expression "]" { $$ = new(driver.pool_) CYMember($1, $3); }
 572     | CallExpressionNoBF "." Identifier { $$ = new(driver.pool_) CYMember($1, new(driver.pool_) CYString($3)); }
 573     ;
 574
 575 ArgumentList_
 576     : "," ArgumentList { $$ = $2; }
 577     | { $$ = NULL; }
 578     ;
 579
 580 ArgumentListOpt
 581     : ArgumentList { $$ = $1; }
 582     | { $$ = NULL; }
 583     ;
 584
 585 ArgumentList
 586     : AssignmentExpression ArgumentList_ { $$ = new(driver.pool_) CYArgument(NULL, $1, $2); }
 587     ;
 588
 589 Arguments
 590     : "(" ArgumentListOpt ")" { $$ = $2; }
 591     ;
 592
 593 LeftHandSideExpression
 594     : NewExpression { $$ = $1; }
 595     | CallExpression { $$ = $1; }
 596     | LeftHandSideExpression_ { $$ = $1; }
 597     ;
 598
 599 LeftHandSideExpressionNoBF
 600     : NewExpressionNoBF { $$ = $1; }
 601     | CallExpressionNoBF { $$ = $1; }
 602     | LeftHandSideExpression_ { $$ = $1; }
 603     ;
 604
 605 PostfixExpression
 606     : LeftHandSideExpression { $$ = $1; }
 607     | LeftHandSideExpression "++" { $$ = new(driver.pool_) CYPostIncrement($1); }
 608     | LeftHandSideExpression "--" { $$ = new(driver.pool_) CYPostDecrement($1); }
 609     ;
 610
 611 PostfixExpressionNoBF
 612     : LeftHandSideExpressionNoBF { $$ = $1; }
 613     | LeftHandSideExpressionNoBF "++" { $$ = new(driver.pool_) CYPostIncrement($1); }
 614     | LeftHandSideExpressionNoBF "--" { $$ = new(driver.pool_) CYPostDecrement($1); }
 615     ;
 616
 617 UnaryExpression_
 618     : "delete" UnaryExpression { $$ = new(driver.pool_) CYDelete($2); }
 619     | "void" UnaryExpression { $$ = new(driver.pool_) CYVoid($2); }
 620     | "typeof" UnaryExpression { $$ = new(driver.pool_) CYTypeOf($2); }
 621     | "++" UnaryExpression { $$ = new(driver.pool_) CYPreIncrement($2); }
 622     | "\n++" UnaryExpression { $$ = new(driver.pool_) CYPreIncrement($2); }
 623     | "--" UnaryExpression { $$ = new(driver.pool_) CYPreDecrement($2); }
 624     | "\n--" UnaryExpression { $$ = new(driver.pool_) CYPreDecrement($2); }
 625     | "+" UnaryExpression { $$ = $2; }
 626     | "-" UnaryExpression { $$ = new(driver.pool_) CYNegate($2); }
 627     | "~" UnaryExpression { $$ = new(driver.pool_) CYBitwiseNot($2); }
 628     | "!" UnaryExpression { $$ = new(driver.pool_) CYLogicalNot($2); }
 629     ;
 630
 631 UnaryExpression
 632     : PostfixExpression { $$ = $1; }
 633     | UnaryExpression_ { $$ = $1; }
 634     ;
 635
 636 UnaryExpressionNoBF
 637     : PostfixExpressionNoBF { $$ = $1; }
 638     | UnaryExpression_ { $$ = $1; }
 639     ;
 640
 641 MultiplicativeExpression
 642     : UnaryExpression { $$ = $1; }
 643     | MultiplicativeExpression "*" UnaryExpression { $$ = new(driver.pool_) CYMultiply($1, $3); }
 644     | MultiplicativeExpression "/" UnaryExpression { $$ = new(driver.pool_) CYDivide($1, $3); }
 645     | MultiplicativeExpression "%" UnaryExpression { $$ = new(driver.pool_) CYModulus($1, $3); }
 646     ;
 647
 648 MultiplicativeExpressionNoBF
 649     : UnaryExpressionNoBF { $$ = $1; }
 650     | MultiplicativeExpressionNoBF "*" UnaryExpression { $$ = new(driver.pool_) CYMultiply($1, $3); }
 651     | MultiplicativeExpressionNoBF "/" UnaryExpression { $$ = new(driver.pool_) CYDivide($1, $3); }
 652     | MultiplicativeExpressionNoBF "%" UnaryExpression { $$ = new(driver.pool_) CYModulus($1, $3); }
 653     ;
 654
 655 AdditiveExpression
 656     : MultiplicativeExpression { $$ = $1; }
 657     | AdditiveExpression "+" MultiplicativeExpression { $$ = new(driver.pool_) CYAdd($1, $3); }
 658     | AdditiveExpression "-" MultiplicativeExpression { $$ = new(driver.pool_) CYSubtract($1, $3); }
 659     ;
 660
 661 AdditiveExpressionNoBF
 662     : MultiplicativeExpressionNoBF { $$ = $1; }
 663     | AdditiveExpressionNoBF "+" MultiplicativeExpression { $$ = new(driver.pool_) CYAdd($1, $3); }
 664     | AdditiveExpressionNoBF "-" MultiplicativeExpression { $$ = new(driver.pool_) CYSubtract($1, $3); }
 665     ;
 666
 667 ShiftExpression
 668     : AdditiveExpression { $$ = $1; }
 669     | ShiftExpression "<<" AdditiveExpression { $$ = new(driver.pool_) CYShiftLeft($1, $3); }
 670     | ShiftExpression ">>" AdditiveExpression { $$ = new(driver.pool_) CYShiftRightSigned($1, $3); }
 671     | ShiftExpression ">>>" AdditiveExpression { $$ = new(driver.pool_) CYShiftRightUnsigned($1, $3); }
 672     ;
 673
 674 ShiftExpressionNoBF
 675     : AdditiveExpressionNoBF { $$ = $1; }
 676     | ShiftExpressionNoBF "<<" AdditiveExpression { $$ = new(driver.pool_) CYShiftLeft($1, $3); }
 677     | ShiftExpressionNoBF ">>" AdditiveExpression { $$ = new(driver.pool_) CYShiftRightSigned($1, $3); }
 678     | ShiftExpressionNoBF ">>>" AdditiveExpression { $$ = new(driver.pool_) CYShiftRightUnsigned($1, $3); }
 679     ;
 680
 681 RelationalExpression
 682     : ShiftExpression { $$ = $1; }
 683     | RelationalExpression "<" ShiftExpression { $$ = new(driver.pool_) CYLess($1, $3); }
 684     | RelationalExpression ">" ShiftExpression { $$ = new(driver.pool_) CYGreater($1, $3); }
 685     | RelationalExpression "<=" ShiftExpression { $$ = new(driver.pool_) CYLessOrEqual($1, $3); }
 686     | RelationalExpression ">=" ShiftExpression { $$ = new(driver.pool_) CYGreaterOrEqual($1, $3); }
 687     | RelationalExpression "instanceof" ShiftExpression { $$ = new(driver.pool_) CYInstanceOf($1, $3); }
 688     | RelationalExpression "in" ShiftExpression { $$ = new(driver.pool_) CYIn($1, $3); }
 689     ;
 690
 691 RelationalExpressionNoIn
 692     : ShiftExpression { $$ = $1; }
 693     | RelationalExpressionNoIn "<" ShiftExpression { $$ = new(driver.pool_) CYLess($1, $3); }
 694     | RelationalExpressionNoIn ">" ShiftExpression { $$ = new(driver.pool_) CYGreater($1, $3); }
 695     | RelationalExpressionNoIn "<=" ShiftExpression { $$ = new(driver.pool_) CYLessOrEqual($1, $3); }
 696     | RelationalExpressionNoIn ">=" ShiftExpression { $$ = new(driver.pool_) CYGreaterOrEqual($1, $3); }
 697     | RelationalExpressionNoIn "instanceof" ShiftExpression { $$ = new(driver.pool_) CYInstanceOf($1, $3); }
 698     ;
 699
 700 RelationalExpressionNoBF
 701     : ShiftExpressionNoBF { $$ = $1; }
 702     | RelationalExpressionNoBF "<" ShiftExpression { $$ = new(driver.pool_) CYLess($1, $3); }
 703     | RelationalExpressionNoBF ">" ShiftExpression { $$ = new(driver.pool_) CYGreater($1, $3); }
 704     | RelationalExpressionNoBF "<=" ShiftExpression { $$ = new(driver.pool_) CYLessOrEqual($1, $3); }
 705     | RelationalExpressionNoBF ">=" ShiftExpression { $$ = new(driver.pool_) CYGreaterOrEqual($1, $3); }
 706     | RelationalExpressionNoBF "instanceof" ShiftExpression { $$ = new(driver.pool_) CYInstanceOf($1, $3); }
 707     | RelationalExpressionNoBF "in" ShiftExpression { $$ = new(driver.pool_) CYIn($1, $3); }
 708     ;
 709
 710 EqualityExpression
 711     : RelationalExpression { $$ = $1; }
 712     | EqualityExpression "==" RelationalExpression { $$ = new(driver.pool_) CYEqual($1, $3); }
 713     | EqualityExpression "!=" RelationalExpression { $$ = new(driver.pool_) CYNotEqual($1, $3); }
 714     | EqualityExpression "===" RelationalExpression { $$ = new(driver.pool_) CYIdentical($1, $3); }
 715     | EqualityExpression "!==" RelationalExpression { $$ = new(driver.pool_) CYNotIdentical($1, $3); }
 716     ;
 717
 718 EqualityExpressionNoIn
 719     : RelationalExpressionNoIn { $$ = $1; }
 720     | EqualityExpressionNoIn "==" RelationalExpressionNoIn { $$ = new(driver.pool_) CYEqual($1, $3); }
 721     | EqualityExpressionNoIn "!=" RelationalExpressionNoIn { $$ = new(driver.pool_) CYNotEqual($1, $3); }
 722     | EqualityExpressionNoIn "===" RelationalExpressionNoIn { $$ = new(driver.pool_) CYIdentical($1, $3); }
 723     | EqualityExpressionNoIn "!==" RelationalExpressionNoIn { $$ = new(driver.pool_) CYNotIdentical($1, $3); }
 724     ;
 725
 726 EqualityExpressionNoBF
 727     : RelationalExpressionNoBF { $$ = $1; }
 728     | EqualityExpressionNoBF "==" RelationalExpression { $$ = new(driver.pool_) CYEqual($1, $3); }
 729     | EqualityExpressionNoBF "!=" RelationalExpression { $$ = new(driver.pool_) CYNotEqual($1, $3); }
 730     | EqualityExpressionNoBF "===" RelationalExpression { $$ = new(driver.pool_) CYIdentical($1, $3); }
 731     | EqualityExpressionNoBF "!==" RelationalExpression { $$ = new(driver.pool_) CYNotIdentical($1, $3); }
 732     ;
 733
 734 BitwiseANDExpression
 735     : EqualityExpression { $$ = $1; }
 736     | BitwiseANDExpression "&" EqualityExpression { $$ = new(driver.pool_) CYBitwiseAnd($1, $3); }
 737     ;
 738
 739 BitwiseANDExpressionNoIn
 740     : EqualityExpressionNoIn { $$ = $1; }
 741     | BitwiseANDExpressionNoIn "&" EqualityExpressionNoIn { $$ = new(driver.pool_) CYBitwiseAnd($1, $3); }
 742     ;
 743
 744 BitwiseANDExpressionNoBF
 745     : EqualityExpressionNoBF { $$ = $1; }
 746     | BitwiseANDExpressionNoBF "&" EqualityExpression { $$ = new(driver.pool_) CYBitwiseAnd($1, $3); }
 747     ;
 748
 749 BitwiseXORExpression
 750     : BitwiseANDExpression { $$ = $1; }
 751     | BitwiseXORExpression "^" BitwiseANDExpression { $$ = new(driver.pool_) CYBitwiseXOr($1, $3); }
 752     ;
 753
 754 BitwiseXORExpressionNoIn
 755     : BitwiseANDExpressionNoIn { $$ = $1; }
 756     | BitwiseXORExpressionNoIn "^" BitwiseANDExpressionNoIn { $$ = new(driver.pool_) CYBitwiseXOr($1, $3); }
 757     ;
 758
 759 BitwiseXORExpressionNoBF
 760     : BitwiseANDExpressionNoBF { $$ = $1; }
 761     | BitwiseXORExpressionNoBF "^" BitwiseANDExpression { $$ = new(driver.pool_) CYBitwiseXOr($1, $3); }
 762     ;
 763
 764 BitwiseORExpression
 765     : BitwiseXORExpression { $$ = $1; }
 766     | BitwiseORExpression "|" BitwiseXORExpression { $$ = new(driver.pool_) CYBitwiseOr($1, $3); }
 767     ;
 768
 769 BitwiseORExpressionNoIn
 770     : BitwiseXORExpressionNoIn { $$ = $1; }
 771     | BitwiseORExpressionNoIn "|" BitwiseXORExpressionNoIn { $$ = new(driver.pool_) CYBitwiseOr($1, $3); }
 772     ;
 773
 774 BitwiseORExpressionNoBF
 775     : BitwiseXORExpressionNoBF { $$ = $1; }
 776     | BitwiseORExpressionNoBF "|" BitwiseXORExpression { $$ = new(driver.pool_) CYBitwiseOr($1, $3); }
 777     ;
 778
 779 LogicalANDExpression
 780     : BitwiseORExpression { $$ = $1; }
 781     | LogicalANDExpression "&&" BitwiseORExpression { $$ = new(driver.pool_) CYLogicalAnd($1, $3); }
 782     ;
 783
 784 LogicalANDExpressionNoIn
 785     : BitwiseORExpressionNoIn { $$ = $1; }
 786     | LogicalANDExpressionNoIn "&&" BitwiseORExpressionNoIn { $$ = new(driver.pool_) CYLogicalAnd($1, $3); }
 787     ;
 788
 789 LogicalANDExpressionNoBF
 790     : BitwiseORExpressionNoBF { $$ = $1; }
 791     | LogicalANDExpressionNoBF "&&" BitwiseORExpression { $$ = new(driver.pool_) CYLogicalAnd($1, $3); }
 792     ;
 793
 794 LogicalORExpression
 795     : LogicalANDExpression { $$ = $1; }
 796     | LogicalORExpression "||" LogicalANDExpression { $$ = new(driver.pool_) CYLogicalOr($1, $3); }
 797     ;
 798
 799 LogicalORExpressionNoIn
 800     : LogicalANDExpressionNoIn { $$ = $1; }
 801     | LogicalORExpressionNoIn "||" LogicalANDExpressionNoIn { $$ = new(driver.pool_) CYLogicalOr($1, $3); }
 802     ;
 803
 804 LogicalORExpressionNoBF
 805     : LogicalANDExpressionNoBF { $$ = $1; }
 806     | LogicalORExpressionNoBF "||" LogicalANDExpression { $$ = new(driver.pool_) CYLogicalOr($1, $3); }
 807     ;
 808
 809 ConditionalExpression
 810     : LogicalORExpression { $$ = $1; }
 811     | LogicalORExpression "?" AssignmentExpression ":" AssignmentExpression { $$ = new(driver.pool_) CYCondition($1, $3, $5); }
 812     ;
 813
 814 ConditionalExpressionNoIn
 815     : LogicalORExpressionNoIn { $$ = $1; }
 816     | LogicalORExpressionNoIn "?" AssignmentExpression ":" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYCondition($1, $3, $5); }
 817     ;
 818
 819 ConditionalExpressionNoBF
 820     : LogicalORExpressionNoBF { $$ = $1; }
 821     | LogicalORExpressionNoBF "?" AssignmentExpression ":" AssignmentExpression { $$ = new(driver.pool_) CYCondition($1, $3, $5); }
 822     ;
 823
 824 AssignmentExpression
 825     : ConditionalExpression { $$ = $1; }
 826     | LeftHandSideExpression "=" AssignmentExpression { $$ = new(driver.pool_) CYAssign($1, $3); }
 827     | LeftHandSideExpression "*=" AssignmentExpression { $$ = new(driver.pool_) CYMultiplyAssign($1, $3); }
 828     | LeftHandSideExpression "/=" AssignmentExpression { $$ = new(driver.pool_) CYDivideAssign($1, $3); }
 829     | LeftHandSideExpression "%=" AssignmentExpression { $$ = new(driver.pool_) CYModulusAssign($1, $3); }
 830     | LeftHandSideExpression "+=" AssignmentExpression { $$ = new(driver.pool_) CYAddAssign($1, $3); }
 831     | LeftHandSideExpression "-=" AssignmentExpression { $$ = new(driver.pool_) CYSubtractAssign($1, $3); }
 832     | LeftHandSideExpression "<<=" AssignmentExpression { $$ = new(driver.pool_) CYShiftLeftAssign($1, $3); }
 833     | LeftHandSideExpression ">>=" AssignmentExpression { $$ = new(driver.pool_) CYShiftRightSignedAssign($1, $3); }
 834     | LeftHandSideExpression ">>>=" AssignmentExpression { $$ = new(driver.pool_) CYShiftRightUnsignedAssign($1, $3); }
 835     | LeftHandSideExpression "&=" AssignmentExpression { $$ = new(driver.pool_) CYBitwiseAndAssign($1, $3); }
 836     | LeftHandSideExpression "^=" AssignmentExpression { $$ = new(driver.pool_) CYBitwiseXOrAssign($1, $3); }
 837     | LeftHandSideExpression "|=" AssignmentExpression { $$ = new(driver.pool_) CYBitwiseOrAssign($1, $3); }
 838     ;
 839
 840 AssignmentExpressionNoIn
 841     : ConditionalExpressionNoIn { $$ = $1; }
 842     | LeftHandSideExpression "=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYAssign($1, $3); }
 843     | LeftHandSideExpression "*=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYMultiplyAssign($1, $3); }
 844     | LeftHandSideExpression "/=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYDivideAssign($1, $3); }
 845     | LeftHandSideExpression "%=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYModulusAssign($1, $3); }
 846     | LeftHandSideExpression "+=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYAddAssign($1, $3); }
 847     | LeftHandSideExpression "-=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYSubtractAssign($1, $3); }
 848     | LeftHandSideExpression "<<=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYShiftLeftAssign($1, $3); }
 849     | LeftHandSideExpression ">>=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYShiftRightSignedAssign($1, $3); }
 850     | LeftHandSideExpression ">>>=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYShiftRightUnsignedAssign($1, $3); }
 851     | LeftHandSideExpression "&=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYBitwiseAndAssign($1, $3); }
 852     | LeftHandSideExpression "^=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYBitwiseXOrAssign($1, $3); }
 853     | LeftHandSideExpression "|=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYBitwiseOrAssign($1, $3); }
 854     ;
 855
 856 AssignmentExpressionNoBF
 857     : ConditionalExpressionNoBF { $$ = $1; }
 858     | LeftHandSideExpressionNoBF "=" AssignmentExpression { $$ = new(driver.pool_) CYAssign($1, $3); }
 859     | LeftHandSideExpressionNoBF "*=" AssignmentExpression { $$ = new(driver.pool_) CYMultiplyAssign($1, $3); }
 860     | LeftHandSideExpressionNoBF "/=" AssignmentExpression { $$ = new(driver.pool_) CYDivideAssign($1, $3); }
 861     | LeftHandSideExpressionNoBF "%=" AssignmentExpression { $$ = new(driver.pool_) CYModulusAssign($1, $3); }
 862     | LeftHandSideExpressionNoBF "+=" AssignmentExpression { $$ = new(driver.pool_) CYAddAssign($1, $3); }
 863     | LeftHandSideExpressionNoBF "-=" AssignmentExpression { $$ = new(driver.pool_) CYSubtractAssign($1, $3); }
 864     | LeftHandSideExpressionNoBF "<<=" AssignmentExpression { $$ = new(driver.pool_) CYShiftLeftAssign($1, $3); }
 865     | LeftHandSideExpressionNoBF ">>=" AssignmentExpression { $$ = new(driver.pool_) CYShiftRightSignedAssign($1, $3); }
 866     | LeftHandSideExpressionNoBF ">>>=" AssignmentExpression { $$ = new(driver.pool_) CYShiftRightUnsignedAssign($1, $3); }
 867     | LeftHandSideExpressionNoBF "&=" AssignmentExpression { $$ = new(driver.pool_) CYBitwiseAndAssign($1, $3); }
 868     | LeftHandSideExpressionNoBF "^=" AssignmentExpression { $$ = new(driver.pool_) CYBitwiseXOrAssign($1, $3); }
 869     | LeftHandSideExpressionNoBF "|=" AssignmentExpression { $$ = new(driver.pool_) CYBitwiseOrAssign($1, $3); }
 870     ;
 871
 872 Expression_
 873     : "," Expression { $$ = new(driver.pool_) CYCompound($2); }
 874     | { $$ = NULL; }
 875     ;
 876
 877 ExpressionNoIn_
 878     : "," ExpressionNoIn { $$ = new(driver.pool_) CYCompound($2); }
 879     | { $$ = NULL; }
 880     ;
 881
 882 ExpressionOpt
 883     : Expression { $$ = $1; }
 884     | { $$ = NULL; }
 885     ;
 886
 887 ExpressionNoInOpt
 888     : ExpressionNoIn { $$ = $1; }
 889     | { $$ = NULL; }
 890     ;
 891
 892 Expression
 893     : AssignmentExpression Expression_ { if ($2) { $2->AddPrev($1); $$ = $2; } else $$ = $1; }
 894     ;
 895
 896 ExpressionNoIn
 897     : AssignmentExpressionNoIn ExpressionNoIn_ { if ($2) { $2->AddPrev($1); $$ = $2; } else $$ = $1; }
 898     ;
 899
 900 ExpressionNoBF
 901     : AssignmentExpressionNoBF Expression_ { if ($2) { $2->AddPrev($1); $$ = $2; } else $$ = $1; }
 902     ;
 903
 904 Statement
 905     : Block { $$ = $1; }
 906     | VariableStatement { $$ = $1; }
 907     | EmptyStatement { $$ = $1; }
 908     | ExpressionStatement { $$ = $1; }
 909     | IfStatement { $$ = $1; }
 910     | IterationStatement { $$ = $1; }
 911     | ContinueStatement { $$ = $1; }
 912     | BreakStatement { $$ = $1; }
 913     | ReturnStatement { $$ = $1; }
 914     | WithStatement { $$ = $1; }
 915     | LabelledStatement { $$ = $1; }
 916     | SwitchStatement { $$ = $1; }
 917     | ThrowStatement { $$ = $1; }
 918     | TryStatement { $$ = $1; }
 919     ;
 920
 921 Block
 922     : "{" StatementListOpt "}" { $$ = $2 ?: new(driver.pool_) CYEmpty(); }
 923     ;
 924
 925 StatementList
 926     : Statement StatementListOpt { $1->SetNext($2); $$ = $1; }
 927     ;
 928
 929 StatementListOpt
 930     : StatementList { $$ = $1; }
 931     | { $$ = NULL; }
 932     ;
 933
 934 VariableStatement
 935     : "var" VariableDeclarationList Terminator { $$ = $2; }
 936     ;
 937
 938 VariableDeclarationList_
 939     : "," VariableDeclarationList { $$ = $2; }
 940     | { $$ = NULL; }
 941     ;
 942
 943 VariableDeclarationListNoIn_
 944     : "," VariableDeclarationListNoIn { $$ = $2; }
 945     | { $$ = NULL; }
 946     ;
 947
 948 VariableDeclarationList
 949     : VariableDeclaration VariableDeclarationList_ { $$ = new(driver.pool_) CYDeclarations($1, $2); }
 950     ;
 951
 952 VariableDeclarationListNoIn
 953     : VariableDeclarationNoIn VariableDeclarationListNoIn_ { $$ = new(driver.pool_) CYDeclarations($1, $2); }
 954     ;
 955
 956 VariableDeclaration
 957     : Identifier InitialiserOpt { $$ = new(driver.pool_) CYDeclaration($1, $2); }
 958     ;
 959
 960 VariableDeclarationNoIn
 961     : Identifier InitialiserNoInOpt { $$ = new(driver.pool_) CYDeclaration($1, $2); }
 962     ;
 963
 964 InitialiserOpt
 965     : Initialiser { $$ = $1; }
 966     | { $$ = NULL; }
 967     ;
 968
 969 InitialiserNoInOpt
 970     : InitialiserNoIn { $$ = $1; }
 971     | { $$ = NULL; }
 972     ;
 973
 974 Initialiser
 975     : "=" AssignmentExpression { $$ = $2; }
 976     ;
 977
 978 InitialiserNoIn
 979     : "=" AssignmentExpressionNoIn { $$ = $2; }
 980     ;
 981
 982 EmptyStatement
 983     : ";" { $$ = new(driver.pool_) CYEmpty(); }
 984     ;
 985
 986 ExpressionStatement
 987     : ExpressionNoBF Terminator { $$ = new(driver.pool_) CYExpress($1); }
 988     ;
 989
 990 ElseStatementOpt
 991     : "else" Statement { $$ = $2; }
 992     | %prec "if" { $$ = NULL; }
 993     ;
 994
 995 IfStatement
 996     : "if" "(" Expression ")" Statement ElseStatementOpt { $$ = new(driver.pool_) CYIf($3, $5, $6); }
 997     ;
 998
 999 IterationStatement
1000     : DoWhileStatement { $$ = $1; }
1001     | WhileStatement { $$ = $1; }
1002     | ForStatement { $$ = $1; }
1003     | ForInStatement { $$ = $1; }
1004     ;
1005
1006 DoWhileStatement
1007     : "do" Statement "while" "(" Expression ")" TerminatorOpt { $$ = new(driver.pool_) CYDoWhile($5, $2); }
1008     ;
1009
1010 WhileStatement
1011     : "while" "(" Expression ")" Statement { $$ = new(driver.pool_) CYWhile($3, $5); }
1012     ;
1013
1014 ForStatement
1015     : "for" "(" ForStatementInitialiser ";" ExpressionOpt ";" ExpressionOpt ")" Statement { $$ = new(driver.pool_) CYFor($3, $5, $7, $9); }
1016     ;
1017
1018 ForStatementInitialiser
1019     : ExpressionNoInOpt { $$ = $1; }
1020     | "var" VariableDeclarationListNoIn { $$ = $2; }
1021     ;
1022
1023 ForInStatement
1024     : "for" "(" ForInStatementInitialiser "in" Expression ")" Statement { $$ = new(driver.pool_) CYForIn($3, $5, $7); }
1025     ;
1026
1027 ForInStatementInitialiser
1028     : LeftHandSideExpression { $$ = $1; }
1029     | "var" VariableDeclarationNoIn { $$ = $2; }
1030     ;
1031
1032 ContinueStatement
1033     : "continue" IdentifierOpt Terminator { $$ = new(driver.pool_) CYContinue($2); }
1034     ;
1035
1036 BreakStatement
1037     : "break" IdentifierOpt Terminator { $$ = new(driver.pool_) CYBreak($2); }
1038     ;
1039
1040 ReturnStatement
1041     : "return" ExpressionOpt Terminator { $$ = new(driver.pool_) CYReturn($2); }
1042     ;
1043
1044 WithStatement
1045     : "with" "(" Expression ")" Statement { $$ = new(driver.pool_) CYWith($3, $5); }
1046     ;
1047
1048 SwitchStatement
1049     : "switch" "(" Expression ")" CaseBlock { $$ = new(driver.pool_) CYSwitch($3, $5); }
1050     ;
1051
1052 CaseBlock
1053     : "{" CaseClausesOpt "}" { $$ = $2; }
1054     ;
1055
1056 CaseClausesOpt
1057     : CaseClause CaseClausesOpt { $1->SetNext($2); $$ = $1; }
1058     | DefaultClause CaseClausesOpt { $1->SetNext($2); $$ = $1; }
1059     | { $$ = NULL; }
1060     ;
1061
1062 CaseClause
1063     : "case" Expression ":" StatementListOpt { $$ = new(driver.pool_) CYClause($2, $4); }
1064     ;
1065
1066 DefaultClause
1067     : "default" ":" StatementListOpt { $$ = new(driver.pool_) CYClause(NULL, $3); }
1068     ;
1069
1070 LabelledStatement
1071     : Identifier ":" Statement { $3->AddLabel($1); $$ = $3; }
1072     ;
1073
1074 ThrowStatement
1075     : "throw" Expression Terminator { $$ = new(driver.pool_) CYThrow($2); }
1076     ;
1077
1078 TryStatement
1079     : "try" Block CatchOpt FinallyOpt { $$ = new(driver.pool_) CYTry($2, $3, $4); }
1080     ;
1081
1082 CatchOpt
1083     : "catch" "(" Identifier ")" Block { $$ = new(driver.pool_) CYCatch($3, $5); }
1084     | { $$ = NULL; }
1085     ;
1086
1087 FinallyOpt
1088     : "finally" Block { $$ = $2; }
1089     | { $$ = NULL; }
1090     ;
1091
1092 FunctionDeclaration
1093     : "function" Identifier "(" FormalParameterList ")" "{" FunctionBody "}" { $$ = new(driver.pool_) CYFunction($2, $4, $7); }
1094     ;
1095
1096 FunctionExpression
1097     : "function" IdentifierOpt "(" FormalParameterList ")" "{" FunctionBody "}" { $$ = new(driver.pool_) CYLambda($2, $4, $7); }
1098     ;
1099
1100 FormalParameterList_
1101     : "," FormalParameterList { $$ = $2; }
1102     | { $$ = NULL; }
1103     ;
1104
1105 FormalParameterList
1106     : Identifier FormalParameterList_ { $$ = new(driver.pool_) CYParameter($1, $2); }
1107     | { $$ = NULL; }
1108     ;
1109
1110 FunctionBody
1111     : SourceElements { $$ = $1; }
1112     ;
1113
1114 Program
1115     : SourceElements { driver.source_ = $1; }
1116     ;
1117
1118 SourceElements
1119     : SourceElement SourceElements { $1->SetNext($2); $$ = $1; }
1120     | { $$ = NULL; }
1121     ;
1122
1123 SourceElement
1124     : Statement { $$ = $1; }
1125     | FunctionDeclaration { $$ = $1; }
1126     ;
1127
1128 /* Objective-C Extensions {{{ */
1129 VariadicCall
1130     : "," AssignmentExpression VariadicCall { $$ = new(driver.pool_) CYArgument(NULL, $2, $3); }
1131     | { $$ = NULL; }
1132     ;
1133
1134 SelectorCall_
1135     : SelectorCall { $$ = $1; }
1136     | VariadicCall { $$ = $1; }
1137     ;
1138
1139 SelectorCall
1140     : WordOpt ":" AssignmentExpression SelectorCall_ { $$ = new(driver.pool_) CYArgument($1 ?: new(driver.pool_) CYBlank(), $3, $4); }
1141     ;
1142
1143 SelectorList
1144     : SelectorCall { $$ = $1; }
1145     | Word { $$ = new(driver.pool_) CYArgument($1, NULL); }
1146     ;
1147
1148 MessageExpression
1149     : "[" AssignmentExpression SelectorList "]" { $$ = new(driver.pool_) CYMessage($2, $3); }
1150     ;
1151
1152 SelectorExpressionOpt
1153     : SelectorExpression_ { $$ = $1; }
1154     | { $$ = NULL; }
1155     ;
1156
1157 SelectorExpression_
1158     : WordOpt ":" SelectorExpressionOpt { $$ = new(driver.pool_) CYSelectorPart($1, true, $3); }
1159     ;
1160
1161 SelectorExpression
1162     : SelectorExpression_ { $$ = $1; }
1163     | Word { $$ = new(driver.pool_) CYSelectorPart($1, false, NULL); }
1164     ;
1165
1166 PrimaryExpression_
1167     : MessageExpression { $$ = $1; }
1168     | "@selector" "(" SelectorExpression ")" { $$ = new CYSelector($3); }
1169     ;
1170 /* }}} */
1171
1172 LeftHandSideExpression_
1173     : "*" LeftHandSideExpression { $$ = new(driver.pool_) CYIndirect($2); }
1174     ;
1175
1176 UnaryExpression_
1177     : "&" UnaryExpression { $$ = new(driver.pool_) CYAddressOf($2); }
1178     ;
1179
1180 %%