Parser.ypp.in

   1 /* Cycript - Optimizing JavaScript Compiler/Runtime
   2  * Copyright (C) 2009-2015  Jay Freeman (saurik)
   3 */
   4
   5 /* GNU Affero General Public License, Version 3 {{{ */
   6 /*
   7  * This program is free software: you can redistribute it and/or modify
   8  * it under the terms of the GNU Affero General Public License as published by
   9  * the Free Software Foundation, either version 3 of the License, or
  10  * (at your option) any later version.
  11
  12  * This program is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU Affero General Public License for more details.
  16
  17  * You should have received a copy of the GNU Affero General Public License
  18  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 **/
  20 /* }}} */
  21
  22 %code top {
  23 #define YYSTACKEXPANDABLE 1
  24 }
  25
  26 %code requires {
  27 #include "Driver.hpp"
  28 #include "Parser.hpp"
  29 #include "Stack.hpp"
  30 #define CYNew new(driver.pool_)
  31
  32 @begin ObjectiveC
  33 #include "ObjectiveC/Syntax.hpp"
  34 @end
  35
  36 @begin E4X
  37 #include "E4X/Syntax.hpp"
  38 @end
  39
  40 #include "Highlight.hpp"
  41 }
  42
  43 %union { bool bool_; }
  44
  45 %union { CYMember *access_; }
  46 %union { CYArgument *argument_; }
  47 %union { CYAssignment *assignment_; }
  48 %union { CYBoolean *boolean_; }
  49 %union { CYClause *clause_; }
  50 %union { cy::Syntax::Catch *catch_; }
  51 %union { CYClassTail *classTail_; }
  52 %union { CYComprehension *comprehension_; }
  53 %union { CYDeclaration *declaration_; }
  54 %union { CYDeclarations *declarations_; }
  55 %union { CYElement *element_; }
  56 %union { CYExpression *expression_; }
  57 %union { CYFalse *false_; }
  58 %union { CYVariable *variable_; }
  59 %union { CYFinally *finally_; }
  60 %union { CYForInitializer *for_; }
  61 %union { CYForInInitializer *forin_; }
  62 %union { CYFunctionParameter *functionParameter_; }
  63 %union { CYIdentifier *identifier_; }
  64 %union { CYInfix *infix_; }
  65 %union { CYLiteral *literal_; }
  66 %union { CYMethod *method_; }
  67 %union { CYModule *module_; }
  68 %union { CYNull *null_; }
  69 %union { CYNumber *number_; }
  70 %union { CYParenthetical *parenthetical_; }
  71 %union { CYProperty *property_; }
  72 %union { CYPropertyName *propertyName_; }
  73 %union { CYRubyProc *rubyProc_; }
  74 %union { CYSpan *span_; }
  75 %union { CYStatement *statement_; }
  76 %union { CYString *string_; }
  77 %union { CYTarget *target_; }
  78 %union { CYThis *this_; }
  79 %union { CYTrue *true_; }
  80 %union { CYWord *word_; }
  81
  82 @begin C
  83 %union { CYTypeModifier *modifier_; }
  84 %union { CYTypeSpecifier *specifier_; }
  85 %union { CYTypedIdentifier *typedIdentifier_; }
  86 %union { CYTypedParameter *typedParameter_; }
  87 @end
  88
  89 @begin ObjectiveC
  90 %union { CYMessage *message_; }
  91 %union { CYMessageParameter *messageParameter_; }
  92 %union { CYImplementationField *implementationField_; }
  93 %union { CYProtocol *protocol_; }
  94 %union { CYSelectorPart *selector_; }
  95 @end
  96
  97 @begin E4X
  98 %union { CYAttribute *attribute_; }
  99 %union { CYPropertyIdentifier *propertyIdentifier_; }
 100 %union { CYSelector *selector_; }
 101 @end
 102
 103 %code provides {
 104
 105 struct YYSTYPE {
 106     cy::parser::semantic_type semantic_;
 107     hi::Value highlight_;
 108 };
 109
 110 int cylex(YYSTYPE *, CYLocation *, void *);
 111
 112 }
 113
 114 %code {
 115
 116 #undef yylex
 117 _finline int yylex(cy::parser::semantic_type *semantic, CYLocation *location, CYDriver &driver) {
 118     if (driver.mark_ == CYMarkIgnore);
 119     else if (driver.mark_ == CYMarkScript) {
 120         driver.mark_ = CYMarkIgnore;
 121         return cy::parser::token::MarkScript;
 122     } else if (driver.mark_ == CYMarkModule) {
 123         driver.mark_ = CYMarkIgnore;
 124         return cy::parser::token::MarkModule;
 125     }
 126
 127     YYSTYPE data;
 128     int token(cylex(&data, location, driver.scanner_));
 129     *semantic = data.semantic_;
 130     return token;
 131 }
 132
 133 #define CYLEX() do if (yyla.empty()) { \
 134     YYCDEBUG << "Mapping a token: "; \
 135     yyla.type = yytranslate_(yylex(&yyla.value, &yyla.location, driver)); \
 136     YY_SYMBOL_PRINT("Next token is", yyla); \
 137 } while (false)
 138
 139 #define CYMAP(to, from) do { \
 140     CYLEX(); \
 141     if (yyla.type == yytranslate_(token::from)) \
 142         yyla.type = yytranslate_(token::to); \
 143 } while (false)
 144
 145 #define CYERR(location, message) do { \
 146     error(location, message); \
 147     YYABORT; \
 148 } while (false)
 149
 150 #define CYNOT(location) \
 151     CYERR(location, "unimplemented feature")
 152
 153 }
 154
 155 %name-prefix "cy"
 156
 157 %language "C++"
 158
 159 %initial-action {
 160     @$.begin.filename = @$.end.filename = &driver.filename_;
 161 };
 162
 163 %locations
 164 %defines
 165
 166 %define api.location.type { CYLocation }
 167
 168 //%glr-parser
 169 //%expect 1
 170
 171 %error-verbose
 172
 173 %param { CYDriver &driver }
 174
 175 /* Token Declarations {{{ */
 176 @begin E4X
 177 %token XMLCDATA
 178 %token XMLComment
 179 %token XMLPI
 180
 181 %token XMLAttributeValue
 182 %token XMLName
 183 %token XMLTagCharacters
 184 %token XMLText
 185 %token XMLWhitespace
 186 @end
 187
 188 @begin E4X
 189 %token LeftRight "<>"
 190 %token LeftSlashRight "</>"
 191
 192 %token SlashRight "/>"
 193 %token LeftSlash "</"
 194
 195 %token ColonColon "::"
 196 %token PeriodPeriod ".."
 197 @end
 198
 199 @begin E4X ObjectiveC
 200 %token At "@"
 201 %token Pound "#"
 202 @end
 203
 204 %token Ampersand "&"
 205 %token AmpersandAmpersand "&&"
 206 %token AmpersandEqual "&="
 207 %token Carrot "^"
 208 %token CarrotEqual "^="
 209 %token Equal "="
 210 %token EqualEqual "=="
 211 %token EqualEqualEqual "==="
 212 %token EqualRight "=>"
 213 %token EqualRight_ "\n=>"
 214 %token Exclamation "!"
 215 %token ExclamationEqual "!="
 216 %token ExclamationEqualEqual "!=="
 217 %token Hyphen "-"
 218 %token HyphenEqual "-="
 219 %token HyphenHyphen "--"
 220 %token HyphenHyphen_ "\n--"
 221 %token HyphenRight "->"
 222 %token Left "<"
 223 %token LeftEqual "<="
 224 %token LeftLeft "<<"
 225 %token LeftLeftEqual "<<="
 226 %token Percent "%"
 227 %token PercentEqual "%="
 228 %token Period "."
 229 %token PeriodPeriodPeriod "..."
 230 %token Pipe "|"
 231 %token PipeEqual "|="
 232 %token PipePipe "||"
 233 %token Plus "+"
 234 %token PlusEqual "+="
 235 %token PlusPlus "++"
 236 %token PlusPlus_ "\n++"
 237 %token Right ">"
 238 %token RightEqual ">="
 239 %token RightRight ">>"
 240 %token RightRightEqual ">>="
 241 %token RightRightRight ">>>"
 242 %token RightRightRightEqual ">>>="
 243 %token Slash "/"
 244 %token SlashEqual "/="
 245 %token Star "*"
 246 %token StarEqual "*="
 247 %token Tilde "~"
 248
 249 %token Colon ":"
 250 %token Comma ","
 251 %token Question "?"
 252 %token SemiColon ";"
 253 %token NewLine "\n"
 254
 255 %token Comment
 256
 257 %token OpenParen "("
 258 %token CloseParen ")"
 259
 260 %token OpenBrace "{"
 261 %token OpenBrace_ "\n{"
 262 %token OpenBrace__ ";{"
 263 %token CloseBrace "}"
 264
 265 %token OpenBracket "["
 266 %token CloseBracket "]"
 267
 268 %token At_error_ "@error"
 269
 270 @begin Java
 271 %token At_class_ "@class"
 272 @end
 273
 274 @begin C
 275 %token _typedef_ "typedef"
 276 %token _unsigned_ "unsigned"
 277 %token _signed_ "signed"
 278 %token _extern_ "extern"
 279 @end
 280
 281 @begin C
 282 %token At_encode_ "@encode"
 283 @end
 284
 285 @begin ObjectiveC
 286 %token At_implementation_ "@implementation"
 287 %token At_import_ "@import"
 288 %token At_end_ "@end"
 289 %token At_selector_ "@selector"
 290 %token At_null_ "@null"
 291 %token At_YES_ "@YES"
 292 %token At_NO_ "@NO"
 293 %token At_true_ "@true"
 294 %token At_false_ "@false"
 295 %token _YES_ "YES"
 296 %token _NO_ "NO"
 297 @end
 298
 299 %token _false_ "false"
 300 %token _null_ "null"
 301 %token _true_ "true"
 302
 303 %token _break_ "break"
 304 %token _case_ "case"
 305 %token _catch_ "catch"
 306 %token _class_ "class"
 307 %token _class__ ";class"
 308 %token _const_ "const"
 309 %token _continue_ "continue"
 310 %token _debugger_ "debugger"
 311 %token _default_ "default"
 312 %token _delete_ "delete"
 313 %token _do_ "do"
 314 %token _else_ "else"
 315 %token _enum_ "enum"
 316 %token _export_ "export"
 317 %token _extends_ "extends"
 318 %token _finally_ "finally"
 319 %token _for_ "for"
 320 %token _function_ "function"
 321 %token _function__ ";function"
 322 %token _if_ "if"
 323 %token _import_ "import"
 324 %token _in_ "in"
 325 %token _in__ "!in"
 326 %token _Infinity_ "Infinity"
 327 %token _instanceof_ "instanceof"
 328 %token _new_ "new"
 329 %token _return_ "return"
 330 %token _return__ "!return"
 331 %token _super_ "super"
 332 %token _super__ "!super"
 333 %token _switch_ "switch"
 334 %token _this_ "this"
 335 %token _throw_ "throw"
 336 %token _try_ "try"
 337 %token _typeof_ "typeof"
 338 %token _var_ "var"
 339 %token _void_ "void"
 340 %token _while_ "while"
 341 %token _with_ "with"
 342
 343 %token _abstract_ "abstract"
 344 %token _await_ "await"
 345 %token _boolean_ "boolean"
 346 %token _byte_ "byte"
 347 %token _char_ "char"
 348 %token _constructor_ "constructor"
 349 %token _double_ "double"
 350 %token _eval_ "eval"
 351 %token _final_ "final"
 352 %token _float_ "float"
 353 %token _from_ "from"
 354 %token _get_ "get"
 355 %token _goto_ "goto"
 356 %token _implements_ "implements"
 357 %token _int_ "int"
 358 %token _interface_ "interface"
 359 %token _let_ "let"
 360 %token _long_ "long"
 361 %token _native_ "native"
 362 %token _package_ "package"
 363 %token _private_ "private"
 364 %token _protected_ "protected"
 365 %token _prototype_ "prototype"
 366 %token _public_ "public"
 367 %token _set_ "set"
 368 %token _short_ "short"
 369 %token _static_ "static"
 370 %token _synchronized_ "synchronized"
 371 %token _throws_ "throws"
 372 %token _transient_ "transient"
 373 %token _volatile_ "volatile"
 374 %token _yield_ "yield"
 375 %token _yield__ "!yield"
 376
 377 %token _undefined_ "undefined"
 378
 379 @begin ObjectiveC
 380 %token _bool_ "bool"
 381 %token _BOOL_ "BOOL"
 382 %token _id_ "id"
 383 %token _nil_ "nil"
 384 %token _NULL_ "NULL"
 385 %token _SEL_ "SEL"
 386 @end
 387
 388 %token _auto_ "auto"
 389 %token _each_ "each"
 390 %token _of_ "of"
 391
 392 @begin E4X
 393 %token _namespace_ "namespace"
 394 %token _xml_ "xml"
 395 @end
 396
 397 %token AutoComplete
 398 %token YieldStar
 399
 400 %token <identifier_> Identifier_
 401 %token <number_> NumericLiteral
 402 %token <string_> StringLiteral
 403 %token <literal_> RegularExpressionLiteral
 404
 405 %token <string_> NoSubstitutionTemplate
 406 %token <string_> TemplateHead
 407 %token <string_> TemplateMiddle
 408 %token <string_> TemplateTail
 409
 410 %type <expression_> AdditiveExpression
 411 %type <argument_> ArgumentList_
 412 %type <argument_> ArgumentList
 413 %type <argument_> ArgumentListOpt
 414 %type <argument_> Arguments
 415 %type <target_> ArrayComprehension
 416 %type <literal_> ArrayLiteral
 417 %type <expression_> ArrowFunction
 418 %type <functionParameter_> ArrowParameters
 419 %type <expression_> AssignmentExpression
 420 %type <expression_> AssignmentExpressionOpt
 421 %type <identifier_> BindingIdentifier
 422 %type <identifier_> BindingIdentifierOpt
 423 %type <declarations_> BindingList_
 424 %type <declarations_> BindingList
 425 %type <expression_> BitwiseANDExpression
 426 %type <statement_> Block
 427 %type <statement_> BlockStatement
 428 %type <boolean_> BooleanLiteral
 429 %type <declaration_> BindingElement
 430 %type <expression_> BitwiseORExpression
 431 %type <expression_> BitwiseXORExpression
 432 %type <statement_> BreakStatement
 433 %type <statement_> BreakableStatement
 434 %type <expression_> CallExpression_
 435 %type <target_> CallExpression
 436 %type <clause_> CaseBlock
 437 %type <clause_> CaseClause
 438 %type <clause_> CaseClausesOpt
 439 %type <catch_> Catch
 440 %type <identifier_> CatchParameter
 441 %type <statement_> ClassDeclaration
 442 %type <target_> ClassExpression
 443 %type <classTail_> ClassHeritage
 444 %type <classTail_> ClassHeritageOpt
 445 %type <classTail_> ClassTail
 446 %type <target_> Comprehension
 447 %type <comprehension_> ComprehensionFor
 448 %type <comprehension_> ComprehensionIf
 449 %type <comprehension_> ComprehensionTail
 450 %type <propertyName_> ComputedPropertyName
 451 %type <expression_> ConditionalExpression
 452 %type <statement_> ContinueStatement
 453 %type <statement_> ConciseBody
 454 %type <parenthetical_> CoverParenthesizedExpressionAndArrowParameterList
 455 %type <statement_> DebuggerStatement
 456 %type <statement_> Declaration__
 457 %type <statement_> Declaration_
 458 %type <statement_> Declaration
 459 %type <clause_> DefaultClause
 460 %type <element_> ElementList
 461 %type <element_> ElementListOpt
 462 %type <statement_> ElseStatementOpt
 463 %type <for_> EmptyStatement
 464 %type <expression_> EqualityExpression
 465 %type <expression_> Expression
 466 %type <expression_> ExpressionOpt
 467 %type <for_> ExpressionStatement_
 468 %type <statement_> ExpressionStatement
 469 %type <finally_> Finally
 470 %type <declaration_> ForBinding
 471 %type <forin_> ForDeclaration
 472 %type <forin_> ForInStatementInitializer
 473 %type <for_> ForStatementInitializer
 474 %type <declaration_> FormalParameter
 475 %type <functionParameter_> FormalParameterList_
 476 %type <functionParameter_> FormalParameterList
 477 %type <functionParameter_> FormalParameters
 478 %type <statement_> FunctionBody
 479 %type <statement_> FunctionDeclaration
 480 %type <target_> FunctionExpression
 481 %type <statement_> FunctionStatementList
 482 %type <statement_> GeneratorBody
 483 %type <statement_> GeneratorDeclaration
 484 %type <target_> GeneratorExpression
 485 %type <method_> GeneratorMethod
 486 %type <statement_> HoistableDeclaration
 487 %type <identifier_> Identifier
 488 %type <identifier_> IdentifierType
 489 %type <word_> IdentifierName
 490 %type <variable_> IdentifierReference
 491 %type <statement_> IfStatement
 492 %type <expression_> Initializer
 493 %type <expression_> InitializerOpt
 494 %type <statement_> IterationStatement
 495 %type <identifier_> LabelIdentifier
 496 %type <statement_> LabelledItem
 497 %type <statement_> LabelledStatement
 498 %type <target_> LeftHandSideExpression
 499 %type <bool_> LetOrConst
 500 %type <declaration_> LexicalBinding
 501 %type <for_> LexicalDeclaration_
 502 %type <statement_> LexicalDeclaration
 503 %type <literal_> Literal
 504 %type <propertyName_> LiteralPropertyName
 505 %type <expression_> LogicalANDExpression
 506 %type <expression_> LogicalORExpression
 507 %type <access_> MemberAccess
 508 %type <target_> MemberExpression
 509 %type <method_> MethodDefinition
 510 %type <module_> ModulePath
 511 %type <expression_> MultiplicativeExpression
 512 %type <target_> NewExpression
 513 %type <null_> NullLiteral
 514 %type <literal_> ObjectLiteral
 515 %type <expression_> PostfixExpression
 516 %type <target_> PrimaryExpression
 517 %type <propertyName_> PropertyName
 518 %type <property_> PropertyDefinition
 519 %type <property_> PropertyDefinitionList_
 520 %type <property_> PropertyDefinitionList
 521 %type <property_> PropertyDefinitionListOpt
 522 %type <declaration_> PropertySetParameterList
 523 %type <expression_> RelationalExpression
 524 %type <statement_> ReturnStatement
 525 %type <rubyProc_> RubyProcExpression
 526 %type <functionParameter_> RubyProcParameterList_
 527 %type <functionParameter_> RubyProcParameterList
 528 %type <functionParameter_> RubyProcParameters
 529 %type <functionParameter_> RubyProcParametersOpt
 530 %type <statement_> Script
 531 %type <statement_> ScriptBody
 532 %type <statement_> ScriptBodyOpt
 533 %type <expression_> ShiftExpression
 534 %type <declaration_> SingleNameBinding
 535 %type <statement_> Statement__
 536 %type <statement_> Statement_
 537 %type <statement_> Statement
 538 %type <statement_> StatementList
 539 %type <statement_> StatementListOpt
 540 %type <statement_> StatementListItem
 541 %type <functionParameter_> StrictFormalParameters
 542 %type <target_> SuperCall
 543 %type <target_> SuperProperty
 544 %type <statement_> SwitchStatement
 545 %type <target_> TemplateLiteral
 546 %type <span_> TemplateSpans
 547 %type <statement_> ThrowStatement
 548 %type <statement_> TryStatement
 549 %type <expression_> UnaryExpression_
 550 %type <expression_> UnaryExpression
 551 %type <declaration_> VariableDeclaration
 552 %type <declarations_> VariableDeclarationList_
 553 %type <declarations_> VariableDeclarationList
 554 %type <for_> VariableStatement_
 555 %type <statement_> VariableStatement
 556 %type <statement_> WithStatement
 557 %type <word_> Word
 558 @begin ObjectiveC
 559 %type <word_> WordOpt
 560 @end
 561 %type <expression_> YieldExpression
 562
 563 @begin C
 564 %type <specifier_> IntegerType
 565 %type <specifier_> IntegerTypeOpt
 566 %type <typedIdentifier_> PrefixedType
 567 %type <specifier_> PrimitiveType
 568 %type <typedIdentifier_> SuffixedType
 569 %type <typedIdentifier_> TypeSignifier
 570 %type <modifier_> TypeQualifierLeft
 571 %type <typedIdentifier_> TypeQualifierRight
 572 %type <typedIdentifier_> TypedIdentifier
 573 %type <typedParameter_> TypedParameterList_
 574 %type <typedParameter_> TypedParameterList
 575 %type <typedParameter_> TypedParameterListOpt
 576 @end
 577
 578 @begin ObjectiveC
 579 %type <expression_> BoxableExpression
 580 %type <statement_> CategoryStatement
 581 %type <expression_> ClassSuperOpt
 582 %type <implementationField_> ImplementationFieldListOpt
 583 %type <implementationField_> ImplementationFields
 584 %type <message_> ClassMessageDeclaration
 585 %type <message_> ClassMessageDeclarationListOpt
 586 %type <protocol_> ClassProtocolListOpt
 587 %type <protocol_> ClassProtocols
 588 %type <protocol_> ClassProtocolsOpt
 589 %type <statement_> ImplementationStatement
 590 %type <target_> MessageExpression
 591 %type <messageParameter_> MessageParameter
 592 %type <messageParameter_> MessageParameters
 593 %type <messageParameter_> MessageParameterList
 594 %type <messageParameter_> MessageParameterListOpt
 595 %type <bool_> MessageScope
 596 %type <argument_> SelectorCall_
 597 %type <argument_> SelectorCall
 598 %type <selector_> SelectorExpression_
 599 %type <selector_> SelectorExpression
 600 %type <selector_> SelectorExpressionOpt
 601 %type <argument_> SelectorList
 602 %type <word_> SelectorWordOpt
 603 %type <typedIdentifier_> TypeOpt
 604 %type <argument_> VariadicCall
 605 @end
 606
 607 @begin E4X
 608 %type <propertyIdentifier_> PropertyIdentifier_
 609 %type <selector_> PropertySelector_
 610 %type <selector_> PropertySelector
 611 %type <identifier_> QualifiedIdentifier_
 612 %type <identifier_> QualifiedIdentifier
 613 %type <identifier_> WildcardIdentifier
 614 %type <identifier_> XMLComment
 615 %type <identifier_> XMLCDATA
 616 %type <identifier_> XMLElement
 617 %type <identifier_> XMLElementContent
 618 %type <identifier_> XMLMarkup
 619 %type <identifier_> XMLPI
 620
 621 %type <attribute_> AttributeIdentifier
 622 /* XXX: %type <statement_> DefaultXMLNamespaceStatement */
 623 %type <expression_> PropertyIdentifier
 624 %type <expression_> XMLListInitialiser
 625 %type <expression_> XMLInitialiser
 626 @end
 627 /* }}} */
 628 /* Token Priorities {{{ */
 629 %nonassoc ""
 630 %left "++" "--" "{"
 631
 632 %nonassoc "if"
 633 %nonassoc "else"
 634 /* }}} */
 635
 636 %start Program
 637 %token MarkModule
 638 %token MarkScript
 639
 640 %%
 641
 642 Program
 643     : MarkScript Script
 644     | MarkModule Module
 645     ;
 646
 647 /* Lexer State {{{ */
 648 LexPushInOn: { driver.in_.push(true); };
 649 LexPushInOff: { driver.in_.push(false); };
 650 LexPopIn: { driver.in_.pop(); };
 651
 652 LexPushReturnOn: { driver.return_.push(true); };
 653 LexPopReturn: { driver.return_.pop(); };
 654
 655 LexPushSuperOn: { driver.super_.push(true); };
 656 LexPushSuperOff: { driver.super_.push(false); };
 657 LexPopSuper: { driver.super_.pop(); };
 658
 659 LexPushYieldOn: { driver.yield_.push(true); };
 660 LexPushYieldOff: { driver.yield_.push(false); };
 661 LexPopYield: { driver.yield_.pop(); };
 662
 663 LexSetRegExp
 664     : { CYLEX(); if (yyla.type == yytranslate_(token::Slash)) { yyla.clear(); driver.SetRegEx(false); } else if (yyla.type == yytranslate_(token::SlashEqual)) { yyla.clear(); driver.SetRegEx(true); } }
 665     ;
 666
 667 LexNewLine
 668     : { if (!yyla.empty() && yyla.type_get() != yyeof_) CYERR(@$, "unexpected lookahead"); driver.next_ = true; }
 669     ;
 670
 671 LexNoStar
 672     : { CYMAP(YieldStar, Star); }
 673     ;
 674
 675 LexNoBrace
 676     : { CYMAP(OpenBrace__, OpenBrace); CYMAP(OpenBrace__, OpenBrace_); }
 677     ;
 678
 679 LexNoClass
 680     : { CYMAP(_class__, _class_); }
 681     ;
 682
 683 LexNoFunction
 684     : { CYMAP(_function__, _function_); }
 685     ;
 686
 687 LexSetStatement
 688     : LexNoBrace LexNoClass LexNoFunction
 689     ;
 690 /* }}} */
 691 /* Virtual Tokens {{{ */
 692 BRACE
 693     : "{"
 694     | "\n{"
 695     ;
 696
 697 Var_
 698     : "var"
 699     ;
 700 /* }}} */
 701
 702 /* 11.6 Names and Keywords {{{ */
 703 IdentifierName
 704     : Word { $$ = $1; }
 705     | "for" { $$ = CYNew CYWord("for"); }
 706     | "in" { $$ = CYNew CYWord("in"); }
 707     | "Infinity" { $$ = CYNew CYIdentifier("Infinity"); }
 708     | "instanceof" { $$ = CYNew CYWord("instanceof"); }
 709     ;
 710
 711 NewLineOpt
 712     : "\n"
 713     |
 714     ;
 715
 716 Word
 717     : Identifier { $$ = $1; }
 718     | "auto" { $$ = CYNew CYWord("auto"); }
 719     | "break" { $$ = CYNew CYWord("break"); }
 720     | "case" { $$ = CYNew CYWord("case"); }
 721     | "catch" { $$ = CYNew CYWord("catch"); }
 722     | "class" { $$ = CYNew CYWord("class"); }
 723     | ";class" { $$ = CYNew CYWord("class"); }
 724     | "const" { $$ = CYNew CYWord("const"); }
 725     | "continue" { $$ = CYNew CYWord("continue"); }
 726     | "debugger" { $$ = CYNew CYWord("debugger"); }
 727     | "default" { $$ = CYNew CYWord("default"); }
 728     | "delete" LexSetRegExp { $$ = CYNew CYWord("delete"); }
 729     | "do" { $$ = CYNew CYWord("do"); }
 730     | "else" { $$ = CYNew CYWord("else"); }
 731     | "enum" { $$ = CYNew CYWord("enum"); }
 732     | "export" { $$ = CYNew CYWord("export"); }
 733     | "extends" { $$ = CYNew CYWord("extends"); }
 734     | "false" { $$ = CYNew CYWord("false"); }
 735     | "finally" { $$ = CYNew CYWord("finally"); }
 736     | "function" { $$ = CYNew CYWord("function"); }
 737     | "if" { $$ = CYNew CYWord("if"); }
 738     | "import" { $$ = CYNew CYWord("import"); }
 739     | "!in" { $$ = CYNew CYWord("in"); }
 740     | "new" LexSetRegExp { $$ = CYNew CYWord("new"); }
 741     | "null" { $$ = CYNew CYWord("null"); }
 742     | "return" { $$ = CYNew CYWord("return"); }
 743     | "!return" { $$ = CYNew CYWord("return"); }
 744     | "super" { $$ = CYNew CYWord("super"); }
 745     | "!super" { $$ = CYNew CYWord("super"); }
 746     | "switch" { $$ = CYNew CYWord("switch"); }
 747     | "this" { $$ = CYNew CYWord("this"); }
 748     | "throw" { $$ = CYNew CYWord("throw"); }
 749     | "true" { $$ = CYNew CYWord("true"); }
 750     | "try" { $$ = CYNew CYWord("try"); }
 751     | "typeof" LexSetRegExp { $$ = CYNew CYWord("typeof"); }
 752     | "var" { $$ = CYNew CYWord("var"); }
 753     | "void" LexSetRegExp { $$ = CYNew CYWord("void"); }
 754     | "while" { $$ = CYNew CYWord("while"); }
 755     | "with" { $$ = CYNew CYWord("with"); }
 756     | "yield" { $$ = CYNew CYIdentifier("yield"); }
 757
 758     | Yield LexSetRegExp NewLineOpt { $$ = CYNew CYIdentifier("yield"); }
 759
 760     // XXX: should be Identifier
 761     | "let" { $$ = CYNew CYIdentifier("let"); }
 762     ;
 763
 764 @begin ObjectiveC
 765 WordOpt
 766     : Word { $$ = $1; }
 767     | { $$ = NULL; }
 768     ;
 769 @end
 770 /* }}} */
 771 /* 11.8.1 Null Literals {{{ */
 772 NullLiteral
 773     : "null" { $$ = CYNew CYNull(); }
 774     ;
 775 /* }}} */
 776 /* 11.8.2 Boolean Literals {{{ */
 777 BooleanLiteral
 778     : "true" { $$ = CYNew CYTrue(); }
 779     | "false" { $$ = CYNew CYFalse(); }
 780     ;
 781 /* }}} */
 782
 783 /* 11.9 Automatic Semicolon Insertion {{{ */
 784 StrictSemi
 785     : { driver.Warning(@$, "warning, automatic semi-colon insertion required"); }
 786     ;
 787
 788 TerminatorSoft
 789     : ";"
 790     | "\n" StrictSemi
 791     ;
 792
 793 Terminator
 794     : ";"
 795     | error { if (yyla.type_get() != yyeof_ && yyla.type != yytranslate_(token::CloseBrace) && !driver.newline_) { CYERR(@1, "required semi-colon"); } else { yyerrok; driver.errors_.pop_back(); } } StrictSemi
 796     ;
 797
 798 TerminatorOpt
 799     : ";"
 800     | error { yyerrok; driver.errors_.pop_back(); } StrictSemi
 801     ;
 802 /* }}} */
 803
 804 /* 12.1 Identifiers {{{ */
 805 IdentifierReference
 806     : Identifier { $$ = CYNew CYVariable($1); }
 807     | "yield" { $$ = CYNew CYVariable(CYNew CYIdentifier("yield")); }
 808     ;
 809
 810 BindingIdentifier
 811     : Identifier { $$ = $1; }
 812     | "yield" { $$ = CYNew CYIdentifier("yield"); }
 813     ;
 814
 815 BindingIdentifierOpt
 816     : BindingIdentifier { $$ = $1; }
 817     | { $$ = NULL; }
 818     ;
 819
 820 LabelIdentifier
 821     : Identifier { $$ = $1; }
 822     | "yield" { $$ = CYNew CYIdentifier("yield"); }
 823     ;
 824
 825 IdentifierType
 826     : Identifier_ { $$ = $1; }
 827     | "abstract" { $$ = CYNew CYIdentifier("abstract"); }
 828     | "await" { $$ = CYNew CYIdentifier("await"); }
 829     | "boolean" { $$ = CYNew CYIdentifier("boolean"); }
 830     | "byte" { $$ = CYNew CYIdentifier("byte"); }
 831     | "constructor" { $$ = CYNew CYIdentifier("constructor"); }
 832     | "double" { $$ = CYNew CYIdentifier("double"); }
 833     | "each" { $$ = CYNew CYIdentifier("each"); }
 834     | "eval" { $$ = CYNew CYIdentifier("eval"); }
 835     | "final" { $$ = CYNew CYIdentifier("final"); }
 836     | "float" { $$ = CYNew CYIdentifier("float"); }
 837     | "from" { $$ = CYNew CYIdentifier("from"); }
 838     | "get" { $$ = CYNew CYIdentifier("get"); }
 839     | "goto" { $$ = CYNew CYIdentifier("goto"); }
 840     | "implements" { $$ = CYNew CYIdentifier("implements"); }
 841     | "interface" { $$ = CYNew CYIdentifier("interface"); }
 842     | "native" { $$ = CYNew CYIdentifier("native"); }
 843     | "of" { $$ = CYNew CYIdentifier("of"); }
 844     | "package" { $$ = CYNew CYIdentifier("package"); }
 845     | "private" { $$ = CYNew CYIdentifier("private"); }
 846     | "protected" { $$ = CYNew CYIdentifier("protected"); }
 847     | "prototype" { $$ = CYNew CYIdentifier("prototype"); }
 848     | "public" { $$ = CYNew CYIdentifier("public"); }
 849     | "set" { $$ = CYNew CYIdentifier("set"); }
 850     | "synchronized" { $$ = CYNew CYIdentifier("synchronized"); }
 851     | "throws" { $$ = CYNew CYIdentifier("throws"); }
 852     | "transient" { $$ = CYNew CYIdentifier("transient"); }
 853     | "undefined" { $$ = CYNew CYIdentifier("undefined"); }
 854 @begin ObjectiveC
 855     | "bool" { $$ = CYNew CYIdentifier("bool"); }
 856     | "BOOL" { $$ = CYNew CYIdentifier("BOOL"); }
 857     | "id" { $$ = CYNew CYIdentifier("id"); }
 858     | "SEL" { $$ = CYNew CYIdentifier("SEL"); }
 859 @end
 860     ;
 861
 862 Identifier
 863     : IdentifierType
 864     | "char" { $$ = CYNew CYIdentifier("char"); }
 865     | "int" { $$ = CYNew CYIdentifier("int"); }
 866     | "long" { $$ = CYNew CYIdentifier("long"); }
 867     | "short" { $$ = CYNew CYIdentifier("short"); }
 868     | "static" { $$ = CYNew CYIdentifier("static"); }
 869     | "volatile" { $$ = CYNew CYIdentifier("volatile"); }
 870 @begin C
 871     | "extern" { $$ = CYNew CYIdentifier("extern"); }
 872     | "signed" { $$ = CYNew CYIdentifier("signed"); }
 873     | "typedef" { $$ = CYNew CYIdentifier("typedef"); }
 874     | "unsigned" { $$ = CYNew CYIdentifier("unsigned"); }
 875 @end
 876 @begin ObjectiveC
 877     | "nil" { $$ = CYNew CYIdentifier("nil"); }
 878     | "NO" { $$ = CYNew CYIdentifier("NO"); }
 879     | "NULL" { $$ = CYNew CYIdentifier("NULL"); }
 880     | "YES" { $$ = CYNew CYIdentifier("YES"); }
 881 @end
 882     ;
 883 /* }}} */
 884 /* 12.2 Primary Expression {{{ */
 885 PrimaryExpression
 886     : "this" { $$ = CYNew CYThis(); }
 887     | IdentifierReference { $$ = $1; }
 888     | Literal { $$ = $1; }
 889     | ArrayLiteral { $$ = $1; }
 890     | ObjectLiteral { $$ = $1; }
 891     | FunctionExpression { $$ = $1; }
 892     | ClassExpression { $$ = $1; }
 893     | GeneratorExpression { $$ = $1; }
 894     | RegularExpressionLiteral { $$ = $1; }
 895     | TemplateLiteral { $$ = $1; }
 896     | CoverParenthesizedExpressionAndArrowParameterList { if ($1 == NULL) CYERR(@1, "invalid parenthetical"); $$ = $1; }
 897     | AutoComplete { driver.mode_ = CYDriver::AutoPrimary; YYACCEPT; }
 898     ;
 899
 900 CoverParenthesizedExpressionAndArrowParameterList
 901     : "(" LexPushInOff Expression ")" LexPopIn { $$ = CYNew CYParenthetical($3); }
 902     | "(" LexPushInOff LexSetRegExp ")" LexPopIn { $$ = NULL; }
 903     | "(" LexPushInOff LexSetRegExp "..." BindingIdentifier ")" LexPopIn { CYNOT(@$); }
 904     | "(" LexPushInOff Expression "," LexSetRegExp "..." BindingIdentifier ")" LexPopIn { CYNOT(@$); }
 905     ;
 906 /* }}} */
 907 /* 12.2.4 Literals {{{ */
 908 Literal
 909     : NullLiteral { $$ = $1; }
 910     | BooleanLiteral { $$ = $1; }
 911     | NumericLiteral { $$ = $1; }
 912     | "Infinity" { $$ = CYNew CYNumber(std::numeric_limits<double>::infinity()); }
 913     | StringLiteral { $$ = $1; }
 914     ;
 915 /* }}} */
 916 /* 12.2.5 Array Initializer {{{ */
 917 ArrayLiteral
 918     : "[" LexPushInOff ElementListOpt "]" LexPopIn { $$ = CYNew CYArray($3); }
 919     ;
 920
 921 ElementList
 922     : AssignmentExpressionOpt "," ElementListOpt { $$ = CYNew CYElementValue($1, $3); }
 923     | LexSetRegExp "..." AssignmentExpression { $$ = CYNew CYElementSpread($3); }
 924     | AssignmentExpression { $$ = CYNew CYElementValue($1, NULL); }
 925     ;
 926
 927 ElementListOpt
 928     : ElementList { $$ = $1; }
 929     | LexSetRegExp { $$ = NULL; }
 930     ;
 931 /* }}} */
 932 /* 12.2.6 Object Initializer {{{ */
 933 ObjectLiteral
 934     : BRACE LexPushInOff PropertyDefinitionListOpt "}" LexPopIn { $$ = CYNew CYObject($3); }
 935     ;
 936
 937 PropertyDefinitionList_
 938     : "," PropertyDefinitionListOpt { $$ = $2; }
 939     | { $$ = NULL; }
 940     ;
 941
 942 PropertyDefinitionList
 943     : PropertyDefinition PropertyDefinitionList_ { $1->SetNext($2); $$ = $1; }
 944     ;
 945
 946 PropertyDefinitionListOpt
 947     : LexSetRegExp PropertyDefinitionList { $$ = $2; }
 948     | LexSetRegExp { $$ = NULL; }
 949     ;
 950
 951 PropertyDefinition
 952     : IdentifierReference { $$ = CYNew CYPropertyValue($1->name_, $1); }
 953     | CoverInitializedName { CYNOT(@$); }
 954     | PropertyName ":" AssignmentExpression { $$ = CYNew CYPropertyValue($1, $3); }
 955     | MethodDefinition { $$ = $1; }
 956     ;
 957
 958 PropertyName
 959     : LiteralPropertyName { $$ = $1; }
 960     | ComputedPropertyName { $$ = $1; }
 961     ;
 962
 963 LiteralPropertyName
 964     : IdentifierName { $$ = $1; }
 965     | StringLiteral { $$ = $1; }
 966     | NumericLiteral { $$ = $1; }
 967     ;
 968
 969 ComputedPropertyName
 970     : "[" AssignmentExpression "]" { $$ = CYNew CYComputed($2); }
 971     ;
 972
 973 CoverInitializedName
 974     : IdentifierReference Initializer
 975     ;
 976
 977 Initializer
 978     : "=" AssignmentExpression { $$ = $2; }
 979     ;
 980
 981 InitializerOpt
 982     : Initializer { $$ = $1; }
 983     | { $$ = NULL; }
 984     ;
 985 /* }}} */
 986 /* 12.2.9 Template Literals {{{ */
 987 TemplateLiteral
 988     : NoSubstitutionTemplate { $$ = CYNew CYTemplate($1, NULL); }
 989     | TemplateHead TemplateSpans { $$ = CYNew CYTemplate($1, $2); }
 990     ;
 991
 992 TemplateSpans
 993     : Expression TemplateMiddle TemplateSpans { $$ = CYNew CYSpan($1, $2, $3); }
 994     | Expression TemplateTail { $$ = CYNew CYSpan($1, $2, NULL); }
 995     ;
 996 /* }}} */
 997
 998 /* 12.3 Left-Hand-Side Expressions {{{ */
 999 MemberAccess
1000     : "[" LexPushInOff Expression "]" LexPopIn { $$ = CYNew CYDirectMember(NULL, $3); }
1001     | "." IdentifierName { $$ = CYNew CYDirectMember(NULL, CYNew CYString($2)); }
1002     | "." AutoComplete { driver.mode_ = CYDriver::AutoDirect; YYACCEPT; }
1003     | TemplateLiteral { CYNOT(@$); }
1004     ;
1005
1006 MemberExpression
1007     : LexSetRegExp PrimaryExpression { $$ = $2; }
1008     | MemberExpression { driver.context_ = $1; } MemberAccess { $3->SetLeft($1); $$ = $3; }
1009     | SuperProperty { $$ = $1; }
1010     | MetaProperty { CYNOT(@$); }
1011     | LexSetRegExp "new" MemberExpression Arguments { $$ = CYNew cy::Syntax::New($3, $4); }
1012     ;
1013
1014 SuperProperty
1015     : LexSetRegExp "!super" "[" Expression "]" { $$ = CYNew CYSuperAccess($4); }
1016     | LexSetRegExp "!super" "." IdentifierName { $$ = CYNew CYSuperAccess(CYNew CYString($4)); }
1017     ;
1018
1019 MetaProperty
1020     : NewTarget
1021     ;
1022
1023 NewTarget
1024     : LexSetRegExp "new" LexSetRegExp "." "target"
1025     ;
1026
1027 NewExpression
1028     : MemberExpression { $$ = $1; }
1029     | LexSetRegExp "new" NewExpression { $$ = CYNew cy::Syntax::New($3, NULL); }
1030     ;
1031
1032 CallExpression_
1033     : MemberExpression { $$ = $1; }
1034     | CallExpression { $$ = $1; }
1035     ;
1036
1037 CallExpression
1038     : CallExpression_ Arguments { if (!$1->Eval()) $$ = CYNew CYCall($1, $2); else $$ = CYNew CYEval($2); }
1039     | SuperCall { $$ = $1; }
1040     | CallExpression { driver.context_ = $1; } MemberAccess { $3->SetLeft($1); $$ = $3; }
1041     ;
1042
1043 SuperCall
1044     : LexSetRegExp "!super" Arguments { $$ = CYNew CYSuperCall($3); }
1045     ;
1046
1047 Arguments
1048     : "(" LexPushInOff ArgumentListOpt ")" LexPopIn { $$ = $3; }
1049     ;
1050
1051 ArgumentList_
1052     : "," ArgumentList { $$ = $2; }
1053     | { $$ = NULL; }
1054     ;
1055
1056 ArgumentList
1057     : AssignmentExpression ArgumentList_ { $$ = CYNew CYArgument(NULL, $1, $2); }
1058     | LexSetRegExp "..." AssignmentExpression { CYNOT(@$); }
1059     ;
1060
1061 ArgumentListOpt
1062     : ArgumentList { $$ = $1; }
1063     | LexSetRegExp { $$ = NULL; }
1064     ;
1065
1066 LeftHandSideExpression
1067     : NewExpression { $$ = $1; }
1068     | CallExpression { $$ = $1; }
1069     ;
1070 /* }}} */
1071 /* 12.4 Postfix Expressions {{{ */
1072 PostfixExpression
1073     : %prec "" LeftHandSideExpression { $$ = $1; }
1074     | LeftHandSideExpression "++" { $$ = CYNew CYPostIncrement($1); }
1075     | LeftHandSideExpression "--" { $$ = CYNew CYPostDecrement($1); }
1076     ;
1077 /* }}} */
1078 /* 12.5 Unary Operators {{{ */
1079 UnaryExpression_
1080     : "delete" UnaryExpression { $$ = CYNew CYDelete($2); }
1081     | "void" UnaryExpression { $$ = CYNew CYVoid($2); }
1082     | "typeof" UnaryExpression { $$ = CYNew CYTypeOf($2); }
1083     | "++" UnaryExpression { $$ = CYNew CYPreIncrement($2); }
1084     | "\n++" UnaryExpression { $$ = CYNew CYPreIncrement($2); }
1085     | "--" UnaryExpression { $$ = CYNew CYPreDecrement($2); }
1086     | "\n--" UnaryExpression { $$ = CYNew CYPreDecrement($2); }
1087     | "+" UnaryExpression { $$ = CYNew CYAffirm($2); }
1088     | "-" UnaryExpression { $$ = CYNew CYNegate($2); }
1089     | "~" UnaryExpression { $$ = CYNew CYBitwiseNot($2); }
1090     | "!" UnaryExpression { $$ = CYNew CYLogicalNot($2); }
1091     ;
1092
1093 UnaryExpression
1094     : %prec "" PostfixExpression { $$ = $1; }
1095     | LexSetRegExp UnaryExpression_ { $$ = $2; }
1096     ;
1097 /* }}} */
1098 /* 12.6 Multiplicative Operators {{{ */
1099 MultiplicativeExpression
1100     : UnaryExpression { $$ = $1; }
1101     | MultiplicativeExpression "*" UnaryExpression { $$ = CYNew CYMultiply($1, $3); }
1102     | MultiplicativeExpression "/" UnaryExpression { $$ = CYNew CYDivide($1, $3); }
1103     | MultiplicativeExpression "%" UnaryExpression { $$ = CYNew CYModulus($1, $3); }
1104     ;
1105 /* }}} */
1106 /* 12.7 Additive Operators {{{ */
1107 AdditiveExpression
1108     : MultiplicativeExpression { $$ = $1; }
1109     | AdditiveExpression "+" MultiplicativeExpression { $$ = CYNew CYAdd($1, $3); }
1110     | AdditiveExpression "-" MultiplicativeExpression { $$ = CYNew CYSubtract($1, $3); }
1111     ;
1112 /* }}} */
1113 /* 12.8 Bitwise Shift Operators {{{ */
1114 ShiftExpression
1115     : AdditiveExpression { $$ = $1; }
1116     | ShiftExpression "<<" AdditiveExpression { $$ = CYNew CYShiftLeft($1, $3); }
1117     | ShiftExpression ">>" AdditiveExpression { $$ = CYNew CYShiftRightSigned($1, $3); }
1118     | ShiftExpression ">>>" AdditiveExpression { $$ = CYNew CYShiftRightUnsigned($1, $3); }
1119     ;
1120 /* }}} */
1121 /* 12.9 Relational Operators {{{ */
1122 RelationalExpression
1123     : ShiftExpression { $$ = $1; }
1124     | RelationalExpression "<" ShiftExpression { $$ = CYNew CYLess($1, $3); }
1125     | RelationalExpression ">" ShiftExpression { $$ = CYNew CYGreater($1, $3); }
1126     | RelationalExpression "<=" ShiftExpression { $$ = CYNew CYLessOrEqual($1, $3); }
1127     | RelationalExpression ">=" ShiftExpression { $$ = CYNew CYGreaterOrEqual($1, $3); }
1128     | RelationalExpression "instanceof" ShiftExpression { $$ = CYNew CYInstanceOf($1, $3); }
1129     | RelationalExpression "in" ShiftExpression { $$ = CYNew CYIn($1, $3); }
1130     ;
1131 /* }}} */
1132 /* 12.10 Equality Operators {{{ */
1133 EqualityExpression
1134     : RelationalExpression { $$ = $1; }
1135     | EqualityExpression "==" RelationalExpression { $$ = CYNew CYEqual($1, $3); }
1136     | EqualityExpression "!=" RelationalExpression { $$ = CYNew CYNotEqual($1, $3); }
1137     | EqualityExpression "===" RelationalExpression { $$ = CYNew CYIdentical($1, $3); }
1138     | EqualityExpression "!==" RelationalExpression { $$ = CYNew CYNotIdentical($1, $3); }
1139     ;
1140 /* }}} */
1141 /* 12.11 Binary Bitwise Operators {{{ */
1142 BitwiseANDExpression
1143     : EqualityExpression { $$ = $1; }
1144     | BitwiseANDExpression "&" EqualityExpression { $$ = CYNew CYBitwiseAnd($1, $3); }
1145     ;
1146
1147 BitwiseXORExpression
1148     : BitwiseANDExpression { $$ = $1; }
1149     | BitwiseXORExpression "^" BitwiseANDExpression { $$ = CYNew CYBitwiseXOr($1, $3); }
1150     ;
1151
1152 BitwiseORExpression
1153     : BitwiseXORExpression { $$ = $1; }
1154     | BitwiseORExpression "|" BitwiseXORExpression { $$ = CYNew CYBitwiseOr($1, $3); }
1155     ;
1156 /* }}} */
1157 /* 12.12 Binary Logical Operators {{{ */
1158 LogicalANDExpression
1159     : BitwiseORExpression { $$ = $1; }
1160     | LogicalANDExpression "&&" BitwiseORExpression { $$ = CYNew CYLogicalAnd($1, $3); }
1161     ;
1162
1163 LogicalORExpression
1164     : LogicalANDExpression { $$ = $1; }
1165     | LogicalORExpression "||" LogicalANDExpression { $$ = CYNew CYLogicalOr($1, $3); }
1166     ;
1167 /* }}} */
1168 /* 12.13 Conditional Operator ( ? : ) {{{ */
1169 ConditionalExpression
1170     : LogicalORExpression { $$ = $1; }
1171     | LogicalORExpression "?" LexPushInOff AssignmentExpression ":" LexPopIn AssignmentExpression { $$ = CYNew CYCondition($1, $4, $7); }
1172     ;
1173 /* }}} */
1174 /* 12.14 Assignment Operators {{{ */
1175 AssignmentExpression
1176     : ConditionalExpression { $$ = $1; }
1177     | LexSetRegExp YieldExpression { $$ = $2; }
1178     | ArrowFunction { $$ = $1; }
1179     | LeftHandSideExpression "=" AssignmentExpression { $$ = CYNew CYAssign($1, $3); }
1180     | LeftHandSideExpression "*=" AssignmentExpression { $$ = CYNew CYMultiplyAssign($1, $3); }
1181     | LeftHandSideExpression "/=" AssignmentExpression { $$ = CYNew CYDivideAssign($1, $3); }
1182     | LeftHandSideExpression "%=" AssignmentExpression { $$ = CYNew CYModulusAssign($1, $3); }
1183     | LeftHandSideExpression "+=" AssignmentExpression { $$ = CYNew CYAddAssign($1, $3); }
1184     | LeftHandSideExpression "-=" AssignmentExpression { $$ = CYNew CYSubtractAssign($1, $3); }
1185     | LeftHandSideExpression "<<=" AssignmentExpression { $$ = CYNew CYShiftLeftAssign($1, $3); }
1186     | LeftHandSideExpression ">>=" AssignmentExpression { $$ = CYNew CYShiftRightSignedAssign($1, $3); }
1187     | LeftHandSideExpression ">>>=" AssignmentExpression { $$ = CYNew CYShiftRightUnsignedAssign($1, $3); }
1188     | LeftHandSideExpression "&=" AssignmentExpression { $$ = CYNew CYBitwiseAndAssign($1, $3); }
1189     | LeftHandSideExpression "^=" AssignmentExpression { $$ = CYNew CYBitwiseXOrAssign($1, $3); }
1190     | LeftHandSideExpression "|=" AssignmentExpression { $$ = CYNew CYBitwiseOrAssign($1, $3); }
1191     ;
1192
1193 AssignmentExpressionOpt
1194     : AssignmentExpression { $$ = $1; }
1195     | LexSetRegExp { $$ = NULL; }
1196     ;
1197 /* }}} */
1198 /* 12.15 Comma Operator ( , ) {{{ */
1199 Expression
1200     : AssignmentExpression { $$ = $1; }
1201     | Expression "," AssignmentExpression { $$ = CYNew CYCompound($1, $3); }
1202     ;
1203
1204 ExpressionOpt
1205     : Expression { $$ = $1; }
1206     | LexSetRegExp { $$ = NULL; }
1207     ;
1208 /* }}} */
1209
1210 /* 13 Statements and Declarations {{{ */
1211 Statement__
1212     : BlockStatement { $$ = $1; }
1213     | VariableStatement { $$ = $1; }
1214     | EmptyStatement { $$ = $1; }
1215     | IfStatement { $$ = $1; }
1216     | BreakableStatement { $$ = $1; }
1217     | ContinueStatement { $$ = $1; }
1218     | BreakStatement { $$ = $1; }
1219     | ReturnStatement { $$ = $1; }
1220     | WithStatement { $$ = $1; }
1221     | LabelledStatement { $$ = $1; }
1222     | ThrowStatement { $$ = $1; }
1223     | TryStatement { $$ = $1; }
1224     | DebuggerStatement { $$ = $1; }
1225     ;
1226
1227 Statement_
1228     : LexSetRegExp Statement__ { $$ = $2; }
1229     | ExpressionStatement { $$ = $1; }
1230     ;
1231
1232 Statement
1233     : LexSetStatement Statement_ { $$ = $2; }
1234     ;
1235
1236 Declaration__
1237     : HoistableDeclaration { $$ = $1; }
1238     | ClassDeclaration { $$ = $1; }
1239     | LexicalDeclaration { $$ = $1; }
1240     ;
1241
1242 Declaration_
1243     : LexSetRegExp Declaration__ { $$ = $2; }
1244     ;
1245
1246 Declaration
1247     : LexSetStatement Declaration_ { $$ = $2; }
1248     ;
1249
1250 HoistableDeclaration
1251     : FunctionDeclaration { $$ = $1; }
1252     | GeneratorDeclaration { $$ = $1; }
1253     ;
1254
1255 BreakableStatement
1256     : IterationStatement { $$ = $1; }
1257     | SwitchStatement { $$ = $1; }
1258     ;
1259 /* }}} */
1260 /* 13.2 Block {{{ */
1261 BlockStatement
1262     : ";{" StatementListOpt "}" { $$ = CYNew CYBlock($2); }
1263     ;
1264
1265 Block
1266     : BRACE StatementListOpt "}" { $$ = $2; }
1267     ;
1268
1269 StatementList
1270     : StatementListItem StatementListOpt { $1->SetNext($2); $$ = $1; }
1271     ;
1272
1273 StatementListOpt
1274     : StatementList { $$ = $1; }
1275     | LexSetStatement LexSetRegExp { $$ = NULL; }
1276     ;
1277
1278 StatementListItem
1279     : Statement { $$ = $1; }
1280     | Declaration { $$ = $1; }
1281     ;
1282 /* }}} */
1283 /* 13.3 Let and Const Declarations {{{ */
1284 LexicalDeclaration_
1285     : LetOrConst BindingList { $$ = CYNew CYLet($1, $2); }
1286     ;
1287
1288 LexicalDeclaration
1289     : LexicalDeclaration_ Terminator { $$ = $1; }
1290     ;
1291
1292 LetOrConst
1293     : "let" { $$ = false; }
1294     | "const" { $$ = true; }
1295     ;
1296
1297 BindingList_
1298     : "," BindingList { $$ = $2; }
1299     | { $$ = NULL; }
1300     ;
1301
1302 BindingList
1303     : LexicalBinding BindingList_ { $$ = CYNew CYDeclarations($1, $2); }
1304     ;
1305
1306 LexicalBinding
1307     : BindingIdentifier InitializerOpt { $$ = CYNew CYDeclaration($1, $2); }
1308     | BindingPattern Initializer { CYNOT(@1); }
1309     ;
1310 /* }}} */
1311 /* 13.3.2 Variable Statement {{{ */
1312 VariableStatement_
1313     : Var_ VariableDeclarationList { $$ = CYNew CYVar($2); }
1314     ;
1315
1316 VariableStatement
1317     : VariableStatement_ Terminator { $$ = $1; }
1318     ;
1319
1320 VariableDeclarationList_
1321     : "," VariableDeclarationList { $$ = $2; }
1322     | { $$ = NULL; }
1323     ;
1324
1325 VariableDeclarationList
1326     : VariableDeclaration VariableDeclarationList_ { $$ = CYNew CYDeclarations($1, $2); }
1327     ;
1328
1329 VariableDeclaration
1330     : BindingIdentifier InitializerOpt { $$ = CYNew CYDeclaration($1, $2); }
1331     | BindingPattern Initializer { CYNOT(@1); }
1332     ;
1333 /* }}} */
1334 /* 13.3.3 Destructuring Binding Patterns {{{ */
1335 BindingPattern
1336     : ObjectBindingPattern
1337     | ArrayBindingPattern
1338     ;
1339
1340 ObjectBindingPattern
1341     : BRACE BindingPropertyListOpt "}"
1342     ;
1343
1344 ArrayBindingPattern
1345     : "[" { CYNOT(@$); }
1346     ;
1347
1348 BindingPropertyList_
1349     : "," BindingPropertyListOpt
1350     |
1351     ;
1352
1353 BindingPropertyList
1354     : BindingProperty BindingPropertyList_
1355     ;
1356
1357 BindingPropertyListOpt
1358     : BindingPropertyList
1359     |
1360     ;
1361
1362 BindingProperty
1363     : SingleNameBinding
1364     | PropertyName ":" BindingElement
1365     ;
1366
1367 BindingElement
1368     : SingleNameBinding { $$ = $1; }
1369     | BindingPattern InitializerOpt { CYNOT(@$); }
1370     ;
1371
1372 SingleNameBinding
1373     : BindingIdentifier InitializerOpt { $$ = CYNew CYDeclaration($1, $2); }
1374     ;
1375
1376 BindingRestElement
1377     : "..." BindingIdentifier
1378     ;
1379 /* }}} */
1380 /* 13.4 Empty Statement {{{ */
1381 EmptyStatement
1382     : ";" { $$ = CYNew CYEmpty(); }
1383     ;
1384 /* }}} */
1385 /* 13.5 Expression Statement {{{ */
1386 ExpressionStatement_
1387     : Expression { $$ = CYNew CYExpress($1); }
1388
1389 ExpressionStatement
1390     : ExpressionStatement_ Terminator { $$ = $1; }
1391     ;
1392 /* }}} */
1393 /* 13.6 The if Statement {{{ */
1394 ElseStatementOpt
1395     : "else" Statement { $$ = $2; }
1396     | %prec "if" { $$ = NULL; }
1397     ;
1398
1399 IfStatement
1400     : "if" "(" Expression ")" Statement ElseStatementOpt { $$ = CYNew CYIf($3, $5, $6); }
1401     ;
1402 /* }}} */
1403 /* 13.7 Iteration Statements {{{ */
1404 IterationStatement
1405     : "do" Statement "while" "(" Expression ")" TerminatorOpt { $$ = CYNew CYDoWhile($5, $2); }
1406     | "while" "(" Expression ")" Statement { $$ = CYNew CYWhile($3, $5); }
1407     | "for" "(" LexPushInOn ForStatementInitializer LexPopIn ExpressionOpt ";" ExpressionOpt ")" Statement { $$ = CYNew CYFor($4, $6, $8, $10); }
1408     | "for" "(" LexPushInOn LexSetRegExp Var_ BindingIdentifier Initializer "!in" LexPopIn Expression ")" Statement { $$ = CYNew CYForInitialized(CYNew CYDeclaration($6, $7), $10, $12); }
1409     | "for" "(" LexPushInOn ForInStatementInitializer "!in" LexPopIn Expression ")" Statement { $$ = CYNew CYForIn($4, $7, $9); }
1410     | "for" "(" LexPushInOn ForInStatementInitializer "of" LexPopIn AssignmentExpression ")" Statement { $$ = CYNew CYForOf($4, $7, $9); }
1411     ;
1412
1413 ForStatementInitializer
1414     : LexSetRegExp EmptyStatement { $$ = $2; }
1415     | ExpressionStatement_ ";" { $$ = $1; }
1416     | LexSetRegExp VariableStatement_ ";" { $$ = $2; }
1417     | LexSetRegExp LexicalDeclaration_ ";" { $$ = $2; }
1418     ;
1419
1420 ForInStatementInitializer
1421     : LeftHandSideExpression { $$ = $1; }
1422     | LexSetRegExp Var_ ForBinding { $$ = CYNew CYForVariable($3); }
1423     | LexSetRegExp ForDeclaration { $$ = $2; }
1424     ;
1425
1426 ForDeclaration
1427     : LetOrConst ForBinding { $$ = CYNew CYForLexical($1, $2); }
1428     ;
1429
1430 ForBinding
1431     : BindingIdentifier { $$ = CYNew CYDeclaration($1, NULL); }
1432     | BindingPattern { CYNOT(@1); }
1433     ;
1434 /* }}} */
1435 /* 13.8 The continue Statement {{{ */
1436 Continue
1437     : "continue" LexNewLine
1438     ;
1439
1440 ContinueStatement
1441     : Continue TerminatorSoft { $$ = CYNew CYContinue(NULL); }
1442     | Continue Identifier Terminator { $$ = CYNew CYContinue($2); }
1443     ;
1444 /* }}} */
1445 /* 13.9 The break Statement {{{ */
1446 Break
1447     : "break" LexNewLine
1448     ;
1449
1450 BreakStatement
1451     : Break TerminatorSoft { $$ = CYNew CYBreak(NULL); }
1452     | Break Identifier Terminator { $$ = CYNew CYBreak($2); }
1453     ;
1454 /* }}} */
1455 /* 13.10 The return Statement {{{ */
1456 Return
1457     : "!return" LexNewLine
1458     ;
1459
1460 ReturnStatement
1461     : Return LexSetRegExp TerminatorSoft { $$ = CYNew CYReturn(NULL); }
1462     | Return Expression Terminator { $$ = CYNew CYReturn($2); }
1463     ;
1464 /* }}} */
1465 /* 13.11 The with Statement {{{ */
1466 WithStatement
1467     : "with" "(" Expression ")" Statement { $$ = CYNew CYWith($3, $5); }
1468     ;
1469 /* }}} */
1470 /* 13.12 The switch Statement {{{ */
1471 SwitchStatement
1472     : "switch" "(" Expression ")" CaseBlock { $$ = CYNew CYSwitch($3, $5); }
1473     ;
1474
1475 CaseBlock
1476     : BRACE CaseClausesOpt "}" { $$ = $2; }
1477     ;
1478
1479 CaseClause
1480     : "case" Expression ":" StatementListOpt { $$ = CYNew CYClause($2, $4); }
1481     ;
1482
1483 CaseClausesOpt
1484     : CaseClause CaseClausesOpt { $1->SetNext($2); $$ = $1; }
1485     | DefaultClause CaseClausesOpt { $1->SetNext($2); $$ = $1; }
1486     | { $$ = NULL; }
1487     ;
1488
1489 // XXX: the standard makes certain you can only have one of these
1490 DefaultClause
1491     : "default" ":" StatementListOpt { $$ = CYNew CYClause(NULL, $3); }
1492     ;
1493 /* }}} */
1494 /* 13.13 Labelled Statements {{{ */
1495 LabelledStatement
1496     : LabelIdentifier ":" LabelledItem { $$ = CYNew CYLabel($1, $3); }
1497     ;
1498
1499 LabelledItem
1500     : Statement { $$ = $1; }
1501     | LexSetStatement LexSetRegExp FunctionDeclaration { $$ = $3; }
1502     ;
1503 /* }}} */
1504 /* 13.14 The throw Statement {{{ */
1505 Throw
1506     : "throw" LexNewLine
1507     ;
1508
1509 ThrowStatement
1510     : Throw LexSetRegExp TerminatorSoft { CYERR(@1, "throw without exception"); }
1511     | Throw Expression Terminator { $$ = CYNew cy::Syntax::Throw($2); }
1512     ;
1513 /* }}} */
1514 /* 13.15 The try Statement {{{ */
1515 TryStatement
1516     : "try" Block Catch { $$ = CYNew cy::Syntax::Try($2, $3, NULL); }
1517     | "try" Block Finally { $$ = CYNew cy::Syntax::Try($2, NULL, $3); }
1518     | "try" Block Catch Finally { $$ = CYNew cy::Syntax::Try($2, $3, $4); }
1519     ;
1520
1521 Catch
1522     : "catch" "(" CatchParameter ")" Block { $$ = CYNew cy::Syntax::Catch($3, $5); }
1523     ;
1524
1525 Finally
1526     : "finally" Block { $$ = CYNew CYFinally($2); }
1527     ;
1528
1529 CatchParameter
1530     : BindingIdentifier { $$ = $1; }
1531     | BindingPattern { CYNOT(@$); }
1532     ;
1533 /* }}} */
1534 /* 13.16 The debugger Statement {{{ */
1535 DebuggerStatement
1536     : "debugger" Terminator { $$ = CYNew CYDebugger(); }
1537     ;
1538 /* }}} */
1539
1540 /* 14.1 Function Definitions {{{ */
1541 FunctionDeclaration
1542     : ";function" BindingIdentifier "(" FormalParameters ")" BRACE LexPushSuperOff FunctionBody "}" LexPopSuper { $$ = CYNew CYFunctionStatement($2, $4, $8); }
1543     ;
1544
1545 FunctionExpression
1546     : "function" BindingIdentifierOpt "(" LexPushInOff FormalParameters ")" LexPopIn BRACE LexPushSuperOff LexPushInOff FunctionBody "}" LexPopIn LexPopSuper { $$ = CYNew CYFunctionExpression($2, $5, $11); }
1547     ;
1548
1549 StrictFormalParameters
1550     : FormalParameters { $$ = $1; }
1551     ;
1552
1553 FormalParameters
1554     : { $$ = NULL; }
1555     | FormalParameterList
1556     ;
1557
1558 FormalParameterList_
1559     : "," FormalParameterList { $$ = $2; }
1560     | { $$ = NULL; }
1561     ;
1562
1563 FormalParameterList
1564     : FunctionRestParameter { CYNOT(@$); }
1565     | FormalParameter FormalParameterList_ { $$ = CYNew CYFunctionParameter($1, $2); }
1566     ;
1567
1568 FunctionRestParameter
1569     : BindingRestElement
1570     ;
1571
1572 FormalParameter
1573     : BindingElement { $$ = $1; }
1574     ;
1575
1576 FunctionBody
1577     : LexPushYieldOff FunctionStatementList LexPopYield { $$ = $2; }
1578     ;
1579
1580 FunctionStatementList
1581     : LexPushReturnOn StatementListOpt LexPopReturn { $$ = $2; }
1582     ;
1583 /* }}} */
1584 /* 14.2 Arrow Function Definitions {{{ */
1585 ArrowFunction
1586     : LexSetRegExp ArrowParameters "=>" LexNoBrace ConciseBody { $$ = CYNew CYFatArrow($2, $5); }
1587     ;
1588
1589 ArrowParameters
1590     : BindingIdentifier { $$ = CYNew CYFunctionParameter(CYNew CYDeclaration($1)); }
1591     | CoverParenthesizedExpressionAndArrowParameterList { if ($1 == NULL) $$ = NULL; else { $$ = $1->expression_->Parameter(); if ($$ == NULL) CYERR(@1, "invalid parameter list"); } }
1592     ;
1593
1594 ConciseBody
1595     : AssignmentExpression { $$ = CYNew CYReturn($1); }
1596     | LexSetRegExp ";{" LexPushInOff FunctionBody "}" LexPopIn { $$ = $4; }
1597     ;
1598 /* }}} */
1599 /* 14.3 Method Definitions {{{ */
1600 MethodDefinition
1601     : PropertyName "(" StrictFormalParameters ")" BRACE FunctionBody "}" { $$ = CYNew CYPropertyMethod($1, $3, $6); }
1602     | GeneratorMethod { $$ = $1; }
1603     | "get" PropertyName "(" ")" BRACE FunctionBody "}" { $$ = CYNew CYPropertyGetter($2, $6); }
1604     | "set" PropertyName "(" PropertySetParameterList ")" BRACE FunctionBody "}" { $$ = CYNew CYPropertySetter($2, CYNew CYFunctionParameter($4), $7); }
1605     ;
1606
1607 PropertySetParameterList
1608     : FormalParameter { $$ = $1; }
1609     ;
1610 /* }}} */
1611 /* 14.4 Generator Function Definitions {{{ */
1612 GeneratorMethod
1613     : "*" PropertyName "(" StrictFormalParameters ")" BRACE GeneratorBody "}" { CYNOT(@$); /* $$ = CYNew CYGeneratorMethod($2, $4, $7); */ }
1614     ;
1615
1616 GeneratorDeclaration
1617     : ";function" "*" BindingIdentifier "(" FormalParameters ")" BRACE GeneratorBody "}" { CYNOT(@$); /* $$ = CYNew CYGeneratorStatement($3, $5, $8); */ }
1618     ;
1619
1620 GeneratorExpression
1621     : "function" "*" BindingIdentifierOpt "(" FormalParameters ")" BRACE GeneratorBody "}" { CYNOT(@$); /* $$ = CYNew CYGeneratorExpression($3, $5, $8); */ }
1622     ;
1623
1624 GeneratorBody
1625     : LexPushYieldOn FunctionStatementList LexPopYield { $$ = $2; }
1626     ;
1627
1628 Yield
1629     : "!yield" LexNewLine LexNoStar
1630     ;
1631
1632 YieldExpression
1633     : Yield LexSetRegExp "\n" { CYNOT(@$); /* $$ = CYNew CYYieldValue(NULL); */ }
1634     | Yield AssignmentExpression { CYNOT(@$); /* $$ = CYNew CYYieldValue($2); */ }
1635     | Yield LexSetRegExp YieldStar AssignmentExpression { CYNOT(@$); /* $$ = CYNew CYYieldGenerator($4); */ }
1636     ;
1637 /* }}} */
1638 /* 14.5 Class Definitions {{{ */
1639 ClassDeclaration
1640     : ";class" BindingIdentifier ClassTail { $$ = CYNew CYClassStatement($2, $3); }
1641     ;
1642
1643 ClassExpression
1644     : "class" BindingIdentifierOpt ClassTail { $$ = CYNew CYClassExpression($2, $3); }
1645     ;
1646
1647 ClassTail
1648     : ClassHeritageOpt { driver.class_.push($1); } BRACE LexPushSuperOn ClassBodyOpt "}" LexPopSuper { driver.class_.pop(); $$ = $1; }
1649     ;
1650
1651 ClassHeritage
1652     : "extends" LeftHandSideExpression { $$ = CYNew CYClassTail($2); }
1653     ;
1654
1655 ClassHeritageOpt
1656     : ClassHeritage { $$ = $1; }
1657     | { $$ = CYNew CYClassTail(NULL); }
1658     ;
1659
1660 ClassBody
1661     : ClassElementList
1662     ;
1663
1664 ClassBodyOpt
1665     : ClassBody
1666     |
1667     ;
1668
1669 ClassElementList
1670     : ClassElementListOpt ClassElement
1671     ;
1672
1673 ClassElementListOpt
1674     : ClassElementList
1675     |
1676     ;
1677
1678 ClassElement
1679     : MethodDefinition { if (CYFunctionExpression *constructor = $1->Constructor()) driver.class_.top()->constructor_ = constructor; else driver.class_.top()->instance_->*$1; }
1680     | "static" MethodDefinition { driver.class_.top()->static_->*$2; }
1681     | ";"
1682     ;
1683 /* }}} */
1684
1685 /* 15.1 Scripts {{{ */
1686 Script
1687     : ScriptBodyOpt { driver.script_ = CYNew CYScript($1); }
1688     ;
1689
1690 ScriptBody
1691     : StatementList { $$ = $1; }
1692     ;
1693
1694 ScriptBodyOpt
1695     : ScriptBody { $$ = $1; }
1696     | LexSetStatement LexSetRegExp { $$ = NULL; }
1697     ;
1698 /* }}} */
1699 /* 15.2 Modules {{{ */
1700 Module
1701     : ModuleBodyOpt
1702     ;
1703
1704 ModuleBody
1705     : ModuleItemList
1706     ;
1707
1708 ModuleBodyOpt
1709     : ModuleBody
1710     |
1711     ;
1712
1713 ModuleItemList
1714     : ModuleItemListOpt ModuleItem
1715     ;
1716
1717 ModuleItemListOpt
1718     : ModuleItemList
1719     |
1720     ;
1721
1722 ModuleItem
1723     : LexSetStatement LexSetRegExp ImportDeclaration
1724     | LexSetStatement LexSetRegExp ExportDeclaration
1725     | StatementListItem
1726     ;
1727 /* }}} */
1728 /* 15.2.2 Imports {{{ */
1729 ImportDeclaration
1730     : "import" ImportClause FromClause Terminator
1731     | "import" ModuleSpecifier Terminator
1732     ;
1733
1734 ImportClause
1735     : ImportedDefaultBinding
1736     | NameSpaceImport
1737     | NamedImports
1738     | ImportedDefaultBinding "," NameSpaceImport
1739     | ImportedDefaultBinding "," NamedImports
1740     ;
1741
1742 ImportedDefaultBinding
1743     : ImportedBinding
1744     ;
1745
1746 NameSpaceImport
1747     : "*" "as" ImportedBinding
1748     ;
1749
1750 NamedImports
1751     : BRACE ImportsListOpt "}"
1752     ;
1753
1754 FromClause
1755     : "from" ModuleSpecifier
1756     ;
1757
1758 ImportsList_
1759     : "," ImportsListOpt
1760     |
1761     ;
1762
1763 ImportsList
1764     : ImportSpecifier ImportsList_
1765     ;
1766
1767 ImportsListOpt
1768     : ImportsList
1769     |
1770     ;
1771
1772 ImportSpecifier
1773     : ImportedBinding
1774     | IdentifierName "as" ImportedBinding
1775     ;
1776
1777 ModuleSpecifier
1778     : StringLiteral
1779     ;
1780
1781 ImportedBinding
1782     : BindingIdentifier
1783     ;
1784 /* }}} */
1785 /* 15.2.3 Exports {{{ */
1786 ExportDeclaration_
1787     : "*" FromClause Terminator
1788     | ExportClause FromClause Terminator
1789     | ExportClause Terminator
1790     | VariableStatement
1791     | "default" LexSetStatement LexSetRegExp HoistableDeclaration
1792     | "default" LexSetStatement LexSetRegExp ClassDeclaration
1793     | "default" LexSetStatement AssignmentExpression Terminator
1794     ;
1795
1796 ExportDeclaration
1797     : "export" LexSetStatement LexSetRegExp ExportDeclaration_
1798     | "export" Declaration
1799     ;
1800
1801 ExportClause
1802     : ";{" ExportsListOpt "}"
1803     ;
1804
1805 ExportsList_
1806     : "," ExportsListOpt
1807     |
1808     ;
1809
1810 ExportsList
1811     : ExportSpecifier ExportsList_
1812     ;
1813
1814 ExportsListOpt
1815     : ExportsList
1816     |
1817     ;
1818
1819 ExportSpecifier
1820     : IdentifierName
1821     | IdentifierName "as" IdentifierName
1822     ;
1823 /* }}} */
1824
1825 @begin C
1826 /* Cycript (C): Type Encoding {{{ */
1827 TypeSignifier
1828     : IdentifierType { $$ = CYNew CYTypedIdentifier(@1, $1); }
1829     | "(" LexPushInOff "*" TypeQualifierRight ")" LexPopIn { $$ = $4; }
1830     ;
1831
1832 SuffixedType
1833     : SuffixedType "[" NumericLiteral "]" { $$ = $1; $$->modifier_ = CYNew CYTypeArrayOf($3, $$->modifier_); }
1834     | "(" LexPushInOff "^" TypeQualifierRight ")" LexPopIn "(" LexPushInOff TypedParameterListOpt ")" LexPopIn { $$ = $4; $$->modifier_ = CYNew CYTypeBlockWith($9, $$->modifier_); }
1835     | TypeSignifier "(" LexPushInOff TypedParameterListOpt ")" LexPopIn { $$ = $1; $$->modifier_ = CYNew CYTypeFunctionWith($4, $$->modifier_); }
1836     | "(" LexPushInOff TypedParameterListOpt ")" LexPopIn { $$ = CYNew CYTypedIdentifier(@1); $$->modifier_ = CYNew CYTypeFunctionWith($3, $$->modifier_); }
1837     | TypeSignifier { $$ = $1; }
1838     | { $$ = CYNew CYTypedIdentifier(@$); }
1839     ;
1840
1841 PrefixedType
1842     : "*" TypeQualifierRight { $$ = $2; $$->modifier_ = CYNew CYTypePointerTo($$->modifier_); }
1843     ;
1844
1845 TypeQualifierLeft
1846     : { $$ = NULL; }
1847     | "const" TypeQualifierLeft { $$ = $2; CYSetLast($$) = CYNew CYTypeConstant(); }
1848     | "volatile" TypeQualifierLeft { $$ = $2; CYSetLast($$) = CYNew CYTypeVolatile(); }
1849     ;
1850
1851 TypeQualifierRight
1852     : PrefixedType { $$ = $1; }
1853     | SuffixedType { $$ = $1; }
1854     | "const" TypeQualifierRight { $$ = $2; $$->modifier_ = CYNew CYTypeConstant($$->modifier_); }
1855     | "volatile" TypeQualifierRight { $$ = $2; $$->modifier_ = CYNew CYTypeVolatile($$->modifier_); }
1856     ;
1857
1858 IntegerType
1859     : "int" { $$ = CYNew CYTypeVariable("int"); }
1860     | "unsigned" IntegerTypeOpt { $$ = CYNew CYTypeUnsigned($2); }
1861     | "signed" IntegerTypeOpt { $$ = CYNew CYTypeSigned($2); }
1862     | "long" IntegerTypeOpt { $$ = CYNew CYTypeLong($2); }
1863     | "short" IntegerTypeOpt { $$ = CYNew CYTypeShort($2); }
1864     ;
1865
1866 IntegerTypeOpt
1867     : IntegerType { $$ = $1; }
1868     | { $$ = CYNew CYTypeVariable("int"); }
1869     ;
1870
1871 PrimitiveType
1872     : IdentifierType { $$ = CYNew CYTypeVariable($1); }
1873     | IntegerType { $$ = $1; }
1874     | "void" { $$ = CYNew CYTypeVoid(); }
1875     | "char" { $$ = CYNew CYTypeVariable("char"); }
1876     | "signed" "char" { $$ = CYNew CYTypeSigned(CYNew CYTypeVariable("char")); }
1877     | "unsigned" "char" { $$ = CYNew CYTypeUnsigned(CYNew CYTypeVariable("char")); }
1878     ;
1879
1880 TypedIdentifier
1881     : TypeQualifierLeft PrimitiveType TypeQualifierRight { $$ = $3; $$->specifier_ = $2; CYSetLast($1) = $$->modifier_; $$->modifier_ = $1; }
1882     ;
1883
1884 PrimaryExpression
1885     : "@encode" "(" TypedIdentifier ")" { $$ = CYNew CYEncodedType($3); }
1886     ;
1887 /* }}} */
1888 @end
1889
1890 @begin ObjectiveC
1891 /* Cycript (Objective-C): @class Declaration {{{ */
1892 ClassSuperOpt
1893     /* XXX: why the hell did I choose MemberExpression? */
1894     : ":" LexSetRegExp MemberExpression { $$ = $3; }
1895     | { $$ = NULL; }
1896     ;
1897
1898 ImplementationFieldListOpt
1899     : TypedIdentifier ";" ImplementationFieldListOpt { $$ = CYNew CYImplementationField($1, $3); }
1900     | LexSetRegExp { $$ = NULL; }
1901     ;
1902
1903 ImplementationFields
1904     : BRACE ImplementationFieldListOpt "}" { $$ = $2; }
1905     ;
1906
1907 MessageScope
1908     : "+" { $$ = false; }
1909     | "-" { $$ = true; }
1910     ;
1911
1912 TypeOpt
1913     : "(" LexSetRegExp TypedIdentifier ")" { if ($3->identifier_ != NULL) CYERR($3->location_, "unexpected identifier"); $$ = $3; }
1914     | { $$ = CYNew CYTypedIdentifier(CYNew CYTypeVariable("id")); }
1915     ;
1916
1917 MessageParameter
1918     : Word ":" TypeOpt Identifier { $3->identifier_ = $4; $$ = CYNew CYMessageParameter($1, $3); }
1919     ;
1920
1921 MessageParameterList
1922     : MessageParameter MessageParameterListOpt { $1->SetNext($2); $$ = $1; }
1923     ;
1924
1925 MessageParameterListOpt
1926     : MessageParameterList { $$ = $1; }
1927     | { $$ = NULL; }
1928     ;
1929
1930 MessageParameters
1931     : MessageParameterList { $$ = $1; }
1932     | Word { $$ = CYNew CYMessageParameter($1, NULL); }
1933     ;
1934
1935 ClassMessageDeclaration
1936     : MessageScope TypeOpt MessageParameters BRACE LexPushSuperOn FunctionBody "}" LexPopSuper { $$ = CYNew CYMessage($1, $2, $3, $6); }
1937     ;
1938
1939 ClassMessageDeclarationListOpt
1940     : ClassMessageDeclarationListOpt ClassMessageDeclaration { $2->SetNext($1); $$ = $2; }
1941     | { $$ = NULL; }
1942     ;
1943
1944 // XXX: this should be AssignmentExpressionNoRight
1945 ClassProtocols
1946     : ShiftExpression ClassProtocolsOpt { $$ = CYNew CYProtocol($1, $2); }
1947     ;
1948
1949 ClassProtocolsOpt
1950     : "," ClassProtocols { $$ = $2; }
1951     | { $$ = NULL; }
1952     ;
1953
1954 ClassProtocolListOpt
1955     : "<" ClassProtocols ">" { $$ = $2; }
1956     | { $$ = NULL; }
1957     ;
1958
1959 ImplementationStatement
1960     : "@implementation" Identifier ClassSuperOpt ClassProtocolListOpt ImplementationFields ClassMessageDeclarationListOpt "@end" { $$ = CYNew CYImplementation($2, $3, $4, $5, $6); }
1961     ;
1962
1963 CategoryName
1964     : "(" WordOpt ")"
1965     ;
1966
1967 CategoryStatement
1968     : "@implementation" Identifier CategoryName ClassMessageDeclarationListOpt "@end" { $$ = CYNew CYCategory($2, $4); }
1969     ;
1970
1971 Statement__
1972     : ImplementationStatement { $$ = $1; }
1973     | CategoryStatement { $$ = $1; }
1974     ;
1975 /* }}} */
1976 /* Cycript (Objective-C): Send Message {{{ */
1977 VariadicCall
1978     : "," AssignmentExpression VariadicCall { $$ = CYNew CYArgument(NULL, $2, $3); }
1979     | { $$ = NULL; }
1980     ;
1981
1982 SelectorWordOpt
1983     : WordOpt { driver.contexts_.back().words_.push_back($1); } { $$ = $1; }
1984     | AutoComplete { driver.mode_ = CYDriver::AutoMessage; YYACCEPT; }
1985     ;
1986
1987 SelectorCall_
1988     : SelectorCall { $$ = $1; }
1989     | VariadicCall { $$ = $1; }
1990     ;
1991
1992 SelectorCall
1993     : SelectorWordOpt ":" AssignmentExpression SelectorCall_ { $$ = CYNew CYArgument($1 ?: CYNew CYWord(""), $3, $4); }
1994     ;
1995
1996 SelectorList
1997     : SelectorCall { $$ = $1; }
1998     | Word { $$ = CYNew CYArgument($1, NULL); }
1999     ;
2000
2001 MessageExpression
2002     : "[" LexPushInOff AssignmentExpression { driver.contexts_.push_back($3); } SelectorList "]" LexPopIn { driver.contexts_.pop_back(); } { $$ = CYNew CYSendDirect($3, $5); }
2003     | "[" LexPushInOff LexSetRegExp "!super" { driver.context_ = NULL; } SelectorList "]" LexPopIn { $$ = CYNew CYSendSuper($6); }
2004     ;
2005
2006 SelectorExpression_
2007     : WordOpt ":" SelectorExpressionOpt { $$ = CYNew CYSelectorPart($1, true, $3); }
2008     ;
2009
2010 SelectorExpression
2011     : SelectorExpression_ { $$ = $1; }
2012     | Word { $$ = CYNew CYSelectorPart($1, false, NULL); }
2013     ;
2014
2015 SelectorExpressionOpt
2016     : SelectorExpression_ { $$ = $1; }
2017     | { $$ = NULL; }
2018     ;
2019
2020 PrimaryExpression
2021     : MessageExpression { $$ = $1; }
2022     | "@selector" "(" LexPushInOff SelectorExpression ")" LexPopIn { $$ = CYNew CYSelector($4); }
2023     ;
2024 /* }}} */
2025 @end
2026
2027 /* Cycript: @import Directive {{{ */
2028 ModulePath
2029     : ModulePath "." Word { $$ = CYNew CYModule($3, $1); }
2030     | Word { $$ = CYNew CYModule($1); }
2031     ;
2032
2033 Declaration__
2034     : "@import" ModulePath { $$ = CYNew CYImport($2); }
2035     ;
2036 /* }}} */
2037
2038 @begin ObjectiveC
2039 /* Cycript (Objective-C): Boxed Expressions {{{ */
2040 BoxableExpression
2041     : NullLiteral { $$ = $1; }
2042     | BooleanLiteral { $$ = $1; }
2043     | NumericLiteral { $$ = $1; }
2044     | StringLiteral { $$ = $1; }
2045     | ArrayLiteral { $$ = $1; }
2046     | ObjectLiteral { $$ = $1; }
2047     | CoverParenthesizedExpressionAndArrowParameterList { $$ = $1; }
2048     | "YES" { $$ = CYNew CYTrue(); }
2049     | "NO" { $$ = CYNew CYFalse(); }
2050     ;
2051
2052 PrimaryExpression
2053     : "@" BoxableExpression { $$ = CYNew CYBox($2); }
2054     | "@YES" { $$ = CYNew CYBox(CYNew CYTrue()); }
2055     | "@NO" { $$ = CYNew CYBox(CYNew CYFalse()); }
2056     | "@true" { $$ = CYNew CYBox(CYNew CYTrue()); }
2057     | "@false" { $$ = CYNew CYBox(CYNew CYFalse()); }
2058     | "@null" { $$ = CYNew CYBox(CYNew CYNull()); }
2059     ;
2060 /* }}} */
2061 /* Cycript (Objective-C): Block Expressions {{{ */
2062 PrimaryExpression
2063     : "^" TypedIdentifier { if ($2->identifier_ != NULL) CYERR($2->location_, "unexpected identifier"); } BRACE LexPushInOff FunctionBody "}" LexPopIn { if (CYTypeFunctionWith *function = $2->Function()) $$ = CYNew CYObjCBlock($2, function->parameters_, $6); else CYERR($2->location_, "expected parameters"); }
2064     ;
2065 /* }}} */
2066 /* Cycript (Objective-C): Instance Literals {{{ */
2067 PrimaryExpression
2068     : "#" NumericLiteral { $$ = CYNew CYInstanceLiteral($2); }
2069     ;
2070 /* }}} */
2071 @end
2072
2073 @begin C
2074 /* Cycript (C): Pointer Indirection/Addressing {{{ */
2075 LeftHandSideExpression
2076     : LexSetRegExp "*" UnaryExpression { $$ = CYNew CYIndirect($3); }
2077     ;
2078
2079 UnaryExpression_
2080     : "&" UnaryExpression { $$ = CYNew CYAddressOf($2); }
2081     ;
2082
2083 MemberAccess
2084     : "->" "[" Expression "]" { $$ = CYNew CYIndirectMember(NULL, $3); }
2085     | "->" IdentifierName { $$ = CYNew CYIndirectMember(NULL, CYNew CYString($2)); }
2086     | "->" AutoComplete { driver.mode_ = CYDriver::AutoIndirect; YYACCEPT; }
2087     ;
2088 /* }}} */
2089 /* Cycript (C): auto Compatibility {{{ */
2090 Var_
2091     : "auto"
2092     ;
2093 /* }}} */
2094 /* Cycript (C): Lambda Expressions {{{ */
2095 TypedParameterList_
2096     : "," TypedParameterList { $$ = $2; }
2097     | { $$ = NULL; }
2098     ;
2099
2100 TypedParameterList
2101     : TypedIdentifier TypedParameterList_ { $$ = CYNew CYTypedParameter($1, $2); }
2102     ;
2103
2104 TypedParameterListOpt
2105     : TypedParameterList { $$ = $1; }
2106     | { $$ = NULL; }
2107     ;
2108
2109 PrimaryExpression
2110     : "[" LexPushInOff LexSetRegExp "&" LexSetRegExp "]" LexPopIn "(" LexPushInOff TypedParameterListOpt ")" LexPopIn "->" TypedIdentifier BRACE LexPushInOff FunctionBody "}" LexPopIn { $$ = CYNew CYLambda($14, $10, $17); }
2111     ;
2112 /* }}} */
2113 /* Cycript (C): Type Definitions {{{ */
2114 Statement__
2115     : "typedef" TypedIdentifier { if ($2->identifier_ == NULL) CYERR($2->location_, "expected identifier"); } Terminator { $$ = CYNew CYTypeDefinition($2); }
2116     ;
2117 /* }}} */
2118 /* Cycript (C): extern "C" {{{ */
2119 Statement__
2120     : "extern" StringLiteral { if (strcmp($2->Value(), "C") != 0) CYERR(@2, "unknown extern binding"); } TypedIdentifier { if ($4->identifier_ == NULL) CYERR($4->location_, "expected identifier"); } Terminator { $$ = CYNew CYExternal($2, $4); }
2121     ;
2122 /* }}} */
2123
2124 @end
2125
2126 @begin E4X
2127 /* Lexer State {{{ */
2128 LexPushRegExp
2129     : { driver.PushCondition(CYDriver::RegExpCondition); }
2130     ;
2131
2132 LexPushXMLContent
2133     : { driver.PushCondition(CYDriver::XMLContentCondition); }
2134     ;
2135
2136 LexPushXMLTag
2137     : { driver.PushCondition(CYDriver::XMLTagCondition); }
2138     ;
2139
2140 LexPop
2141     : { driver.PopCondition(); }
2142     ;
2143
2144 LexSetXMLContent
2145     : { driver.SetCondition(CYDriver::XMLContentCondition); }
2146     ;
2147
2148 LexSetXMLTag
2149     : { driver.SetCondition(CYDriver::XMLTagCondition); }
2150     ;
2151 /* }}} */
2152 /* Virtual Tokens {{{ */
2153 XMLWhitespaceOpt
2154     : XMLWhitespace
2155     |
2156     ;
2157 /* }}} */
2158
2159 /* 8.1 Context Keywords {{{ */
2160 Identifier
2161     : "namespace" { $$ = CYNew CYIdentifier("namespace"); }
2162     | "xml" { $$ = CYNew CYIdentifier("xml"); }
2163     ;
2164 /* }}} */
2165 /* 8.3 XML Initializer Input Elements {{{ */
2166 XMLMarkup
2167     : XMLComment { $$ = $1; }
2168     | XMLCDATA { $$ = $1; }
2169     | XMLPI { $$ = $1; }
2170     ;
2171 /* }}} */
2172
2173 /* 11.1 Primary Expressions {{{ */
2174 PrimaryExpression
2175     : PropertyIdentifier { $$ = CYNew CYPropertyVariable($1); }
2176     | XMLInitialiser { $$ = $1; }
2177     | XMLListInitialiser { $$ = $1; }
2178     ;
2179
2180 PropertyIdentifier
2181     : AttributeIdentifier { $$ = $1; }
2182     | QualifiedIdentifier { $$ = $1; }
2183     | WildcardIdentifier { $$ = $1; }
2184     ;
2185 /* }}} */
2186 /* 11.1.1 Attribute Identifiers {{{ */
2187 AttributeIdentifier
2188     : "@" QualifiedIdentifier_ { $$ = CYNew CYAttribute($2); }
2189     ;
2190
2191 PropertySelector_
2192     : PropertySelector { $$ = $1; }
2193     | "[" LexPushInOff Expression "]" LexPopIn { $$ = CYNew CYSelector($3); }
2194     ;
2195
2196 PropertySelector
2197     : Identifier { $$ = CYNew CYSelector($1); }
2198     | WildcardIdentifier { $$ = $1; }
2199     ;
2200 /* }}} */
2201 /* 11.1.2 Qualified Identifiers {{{ */
2202 QualifiedIdentifier_
2203     : PropertySelector_ { $$ = CYNew CYQualified(NULL, $1); }
2204     | QualifiedIdentifier { $$ = $1; }
2205     ;
2206
2207 QualifiedIdentifier
2208     : PropertySelector "::" PropertySelector_ { $$ = CYNew CYQualified($1, $3); }
2209     ;
2210 /* }}} */
2211 /* 11.1.3 Wildcard Identifiers {{{ */
2212 WildcardIdentifier
2213     : "*" { $$ = CYNew CYWildcard(); }
2214     ;
2215 /* }}} */
2216 /* 11.1.4 XML Initializer {{{ */
2217 XMLInitialiser
2218     : XMLMarkup { $$ = $1; }
2219     | XMLElement { $$ = $1; }
2220     ;
2221
2222 XMLElement
2223     : "<" LexPushInOff XMLTagContent LexPop "/>" LexPopIn
2224     | "<" LexPushInOff XMLTagContent ">" LexSetXMLContent XMLElementContentOpt "</" LexSetXMLTag XMLTagName XMLWhitespaceOpt LexPop ">" LexPopIn
2225     ;
2226
2227 XMLTagContent
2228     : LexPushXMLTag XMLTagName XMLAttributes
2229     ;
2230
2231 XMLExpression
2232     : BRACE LexPushRegExp Expression LexPop "}"
2233     ;
2234
2235 XMLTagName
2236     : XMLExpression
2237     | XMLName
2238     ;
2239
2240 XMLAttributes_
2241     : XMLAttributes_ XMLAttribute
2242     |
2243     ;
2244
2245 XMLAttributes
2246     : XMLAttributes_ XMLWhitespace XMLExpression XMLWhitespaceOpt
2247     | XMLAttributes_ XMLWhitespaceOpt
2248     ;
2249
2250 XMLAttributeValue_
2251     : XMLExpression
2252     | XMLAttributeValue
2253     ;
2254
2255 XMLAttribute
2256     : XMLWhitespace XMLName XMLWhitespaceOpt "=" XMLWhitespaceOpt XMLAttributeValue_
2257     ;
2258
2259 XMLElementContent
2260     : XMLExpression XMLElementContentOpt
2261     | XMLMarkup XMLElementContentOpt
2262     | XMLText XMLElementContentOpt
2263     | XMLElement XMLElementContentOpt
2264     ;
2265
2266 XMLElementContentOpt
2267     : XMLElementContent
2268     |
2269     ;
2270 /* }}} */
2271 /* 11.1.5 XMLList Initializer {{{ */
2272 XMLListInitialiser
2273     : "<>" LexPushInOff LexPushXMLContent XMLElementContent LexPop "</>" LexPopIn { $$ = CYNew CYXMLList($4); }
2274     ;
2275 /* }}} */
2276
2277 /* 11.2 Left-Hand-Side Expressions {{{ */
2278 PropertyIdentifier_
2279     : Identifier { $$ = $1; }
2280     | PropertyIdentifier { $$ = $1; }
2281     ;
2282
2283 MemberAccess
2284     : "." PropertyIdentifier { $$ = CYNew CYPropertyMember(NULL, $2); }
2285     | ".." PropertyIdentifier_ { $$ = CYNew CYDescendantMember(NULL, $2); }
2286     | "." "(" Expression ")" { $$ = CYNew CYFilteringPredicate(NULL, $3); }
2287     ;
2288 /* }}} */
2289 /* 12.1 The default xml namespace Statement {{{ */
2290 /* XXX: DefaultXMLNamespaceStatement
2291     : "default" "xml" "namespace" "=" Expression Terminator { $$ = CYNew CYDefaultXMLNamespace($5); }
2292     ;
2293
2294 Statement__
2295     : DefaultXMLNamespaceStatement { $$ = $1; }
2296     ; */
2297 /* }}} */
2298 @end
2299
2300 /* JavaScript FTL: Array Comprehensions {{{ */
2301 Comprehension
2302     : AssignmentExpression ComprehensionFor ComprehensionTail { $$ = CYNew CYArrayComprehension($1, $2->Modify($3)); }
2303     ;
2304
2305 ComprehensionFor
2306     : "for" "each" "(" LexPushInOn LexicalBinding "!in" LexPopIn Expression ")" { $$ = CYNew CYForOfComprehension($5, $8); }
2307     ;
2308 /* }}} */
2309 /* JavaScript FTL: for each {{{ */
2310 IterationStatement
2311     : "for" "each" "(" LexPushInOn ForInStatementInitializer "!in" LexPopIn Expression ")" Statement { $$ = CYNew CYForOf($5, $8, $10); }
2312     ;
2313 /* }}} */
2314
2315 /* JavaScript FTW: Array Comprehensions {{{ */
2316 PrimaryExpression
2317     : ArrayComprehension
2318     ;
2319
2320 ArrayComprehension
2321     : "[" LexPushInOff Comprehension "]" LexPopIn { $$ = $3; }
2322     ;
2323
2324 Comprehension
2325     : LexSetRegExp ComprehensionFor ComprehensionTail AssignmentExpression { $$ = CYNew CYArrayComprehension($4, $2->Modify($3)); }
2326     ;
2327
2328 ComprehensionTail
2329     : { $$ = NULL; }
2330     | ComprehensionFor ComprehensionTail { $$ = $1->Modify($2); }
2331     | ComprehensionIf ComprehensionTail { $$ = $1->Modify($2); }
2332     ;
2333
2334 ComprehensionFor
2335     : "for" "(" LexPushInOn LexicalBinding "!in" LexPopIn Expression ")" { $$ = CYNew CYForInComprehension($4, $7); }
2336     | "for" "(" LexPushInOn LexicalBinding "of" LexPopIn Expression ")" { $$ = CYNew CYForOfComprehension($4, $7); }
2337     ;
2338
2339 ComprehensionIf
2340     : "if" "(" AssignmentExpression ")" { $$ = CYNew CYIfComprehension($3); }
2341     ;
2342 /* }}} */
2343 /* JavaScript FTW: Coalesce Operator {{{ */
2344 ConditionalExpression
2345     : LogicalORExpression "?" LexPushInOff LexSetRegExp ":" LexPopIn AssignmentExpression { $$ = CYNew CYCondition($1, $1, $7); }
2346     ;
2347 /* }}} */
2348 /* JavaScript FTW: Named Arguments {{{ */
2349 ArgumentList
2350     : LexSetRegExp Word ":" AssignmentExpression ArgumentList_ { $$ = CYNew CYArgument($2, $4, $5); }
2351     ;
2352 /* }}} */
2353 /* JavaScript FTW: Ruby Blocks {{{ */
2354 RubyProcParameterList_
2355     : "," RubyProcParameterList { $$ = $2; }
2356     | { $$ = NULL; }
2357     ;
2358
2359 RubyProcParameterList
2360     : Identifier RubyProcParameterList_ { $$ = CYNew CYFunctionParameter(CYNew CYDeclaration($1), $2); }
2361     | { $$ = NULL; }
2362     ;
2363
2364 RubyProcParameters
2365     : LexSetRegExp "|" RubyProcParameterList "|" { $$ = $3; }
2366     | LexSetRegExp "||" { $$ = NULL; }
2367     ;
2368
2369 RubyProcParametersOpt
2370     : RubyProcParameters { $$ = $1; }
2371     | { $$ = NULL; }
2372     ;
2373
2374 RubyProcExpression
2375     : "{" RubyProcParametersOpt StatementListOpt "}" { $$ = CYNew CYRubyProc($2, $3); }
2376     ;
2377
2378 PrimaryExpression
2379     : BRACE LexPushInOff RubyProcParameters StatementListOpt "}" LexPopIn { $$ = CYNew CYRubyProc($3, $4); }
2380     ;
2381
2382 PostfixExpression
2383     : PostfixExpression RubyProcExpression { $$ = CYNew CYRubyBlock($1, $2); }
2384     ;
2385 /* }}} */
2386
2387 %%
2388
2389 bool CYDriver::Parse(CYMark mark) {
2390     mark_ = mark;
2391     CYLocal<CYPool> local(&pool_);
2392     cy::parser parser(*this);
2393 #ifdef YYDEBUG
2394     parser.set_debug_level(debug_);
2395 #endif
2396     return parser.parse() != 0;
2397 }
2398
2399 void CYDriver::Warning(const cy::parser::location_type &location, const char *message) {
2400     if (!strict_)
2401         return;
2402
2403     CYDriver::Error error;
2404     error.warning_ = true;
2405     error.location_ = location;
2406     error.message_ = message;
2407     errors_.push_back(error);
2408 }
2409
2410 void cy::parser::error(const cy::parser::location_type &location, const std::string &message) {
2411     CYDriver::Error error;
2412     error.warning_ = false;
2413     error.location_ = location;
2414     error.message_ = message;
2415     driver.errors_.push_back(error);
2416 }