Cycript.yy.in

   1 /* Cycript - Optimizing JavaScript Compiler/Runtime
   2  * Copyright (C) 2009-2013  Jay Freeman (saurik)
   3 */
   4
   5 /* GNU General Public License, Version 3 {{{ */
   6 /*
   7  * Cycript is free software: you can redistribute it and/or modify
   8  * it under the terms of the GNU General Public License as published
   9  * by the Free Software Foundation, either version 3 of the License,
  10  * or (at your option) any later version.
  11  *
  12  * Cycript is distributed in the hope that it will be useful, but
  13  * WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with Cycript.  If not, see <http://www.gnu.org/licenses/>.
  19 **/
  20 /* }}} */
  21
  22 @if Bison23 %{
  23
  24 @if Bison24 %code top {
  25 #define cyscanner driver.scanner_
  26 #define YYSTACKEXPANDABLE 1
  27 @if Bison23 #define yyerrok (yyerrstatus_ = 0)
  28 @if Bison24 }
  29
  30 @if Bison24 %code requires {
  31 #include "Driver.hpp"
  32 #include "Parser.hpp"
  33 #define CYNew new($pool)
  34
  35 @begin ObjectiveC
  36 #include "ObjectiveC/Syntax.hpp"
  37 @end
  38
  39 @begin E4X
  40 #include "E4X/Syntax.hpp"
  41 @end
  42
  43 #include "Highlight.hpp"
  44
  45 typedef struct {
  46     bool newline_;
  47     hi::Value highlight_;
  48
  49     union {
  50         bool bool_;
  51
  52         CYDriver::Condition condition_;
  53
  54         CYArgument *argument_;
  55         CYAssignment *assignment_;
  56         CYBoolean *boolean_;
  57         CYClause *clause_;
  58         cy::Syntax::Catch *catch_;
  59         CYComment *comment_;
  60         CYComprehension *comprehension_;
  61         CYCompound *compound_;
  62         CYDeclaration *declaration_;
  63         CYDeclarations *declarations_;
  64         CYElement *element_;
  65         CYExpression *expression_;
  66         CYFalse *false_;
  67         CYFinally *finally_;
  68         CYForInitialiser *for_;
  69         CYForInInitialiser *forin_;
  70         CYFunctionParameter *functionParameter_;
  71         CYIdentifier *identifier_;
  72         CYInfix *infix_;
  73         CYLiteral *literal_;
  74         CYMember *member_;
  75         CYNull *null_;
  76         CYNumber *number_;
  77         CYProgram *program_;
  78         CYProperty *property_;
  79         CYPropertyName *propertyName_;
  80         CYRubyProc *rubyProc_;
  81         CYStatement *statement_;
  82         CYString *string_;
  83         CYThis *this_;
  84         CYTrue *true_;
  85         CYWord *word_;
  86
  87 @begin ObjectiveC
  88         CYClassName *className_;
  89         CYField *field_;
  90         CYMessage *message_;
  91         CYMessageParameter *messageParameter_;
  92         CYProtocol *protocol_;
  93         CYSelectorPart *selector_;
  94         CYTypeModifier *modifier_;
  95         CYTypedIdentifier *typedIdentifier_;
  96         CYTypedParameter *typedParameter_;
  97 @end
  98
  99 @begin E4X
 100         CYAttribute *attribute_;
 101         CYPropertyIdentifier *propertyIdentifier_;
 102         CYSelector *selector_;
 103 @end
 104     };
 105 } YYSTYPE;
 106
 107 #define YYSTYPE YYSTYPE
 108 @if Bison24 }
 109
 110 @if Bison24 %code provides {
 111 int cylex(YYSTYPE *, cy::location *, void *);
 112 @if Bison24 }
 113
 114 @if Bison23 %}
 115
 116 %name-prefix="cy"
 117
 118 @if Bison23 %skeleton "lalr1.cc"
 119 @if Bison24 %language "C++"
 120
 121 %initial-action {
 122     @$.begin.filename = @$.end.filename = &driver.filename_;
 123 };
 124
 125 %locations
 126 %defines
 127
 128 //%glr-parser
 129 //%expect 1
 130
 131 %error-verbose
 132
 133 %parse-param { CYDriver &driver }
 134 %lex-param { void *cyscanner }
 135
 136 /* Token Declarations {{{ */
 137 @begin E4X
 138 %token XMLCDATA
 139 %token XMLComment
 140 %token XMLPI
 141
 142 %token XMLAttributeValue
 143 %token XMLName
 144 %token XMLTagCharacters
 145 %token XMLText
 146 %token XMLWhitespace
 147 @end
 148
 149 @begin E4X
 150 %token LeftRight "<>"
 151 %token LeftSlashRight "</>"
 152
 153 %token SlashRight "/>"
 154 %token LeftSlash "</"
 155
 156 %token ColonColon "::"
 157 %token PeriodPeriod ".."
 158 @end
 159
 160 @begin E4X ObjectiveC
 161 %token At "@"
 162 @end
 163
 164 %token Ampersand "&"
 165 %token AmpersandAmpersand "&&"
 166 %token AmpersandEqual "&="
 167 %token Carrot "^"
 168 %token CarrotEqual "^="
 169 %token Equal "="
 170 %token EqualEqual "=="
 171 %token EqualEqualEqual "==="
 172 %token EqualRight "=>"
 173 %token Exclamation "!"
 174 %token ExclamationEqual "!="
 175 %token ExclamationEqualEqual "!=="
 176 %token Hyphen "-"
 177 %token HyphenEqual "-="
 178 %token HyphenHyphen "--"
 179 %token HyphenHyphen_ "\n--"
 180 %token HyphenRight "->"
 181 %token Left "<"
 182 %token LeftEqual "<="
 183 %token LeftLeft "<<"
 184 %token LeftLeftEqual "<<="
 185 %token Percent "%"
 186 %token PercentEqual "%="
 187 %token Period "."
 188 %token PeriodPeriodPeriod "..."
 189 %token Pipe "|"
 190 %token PipeEqual "|="
 191 %token PipePipe "||"
 192 %token Plus "+"
 193 %token PlusEqual "+="
 194 %token PlusPlus "++"
 195 %token PlusPlus_ "\n++"
 196 %token Right ">"
 197 %token RightEqual ">="
 198 %token RightRight ">>"
 199 %token RightRightEqual ">>="
 200 %token RightRightRight ">>>"
 201 %token RightRightRightEqual ">>>="
 202 %token Slash "/"
 203 %token SlashEqual "/="
 204 %token Star "*"
 205 %token StarEqual "*="
 206 %token Tilde "~"
 207
 208 %token Colon ":"
 209 %token Comma ","
 210 %token Question "?"
 211 %token SemiColon ";"
 212 %token NewLine "\n"
 213
 214 %token <comment_> Comment
 215
 216 %token OpenParen "("
 217 %token CloseParen ")"
 218
 219 %token OpenBrace "{"
 220 %token OpenBrace_ "\n{"
 221 %token OpenBrace__ ";{"
 222 %token CloseBrace "}"
 223
 224 %token OpenBracket "["
 225 %token CloseBracket "]"
 226
 227 %token AtError "@error"
 228
 229 @begin Java
 230 %token AtClass "@class"
 231 @end
 232
 233 @begin C
 234 %token <identifier_> Typedef "typedef"
 235 @end
 236
 237 @begin ObjectiveC
 238 %token AtImplementation "@implementation"
 239 %token AtImplementation_ ";@implementation"
 240 %token AtImport "@import"
 241 %token AtEncode "@encode"
 242 %token AtEnd "@end"
 243 %token AtSelector "@selector"
 244 %token <identifier_> Yes "YES"
 245 %token <identifier_> No "NO"
 246 @end
 247
 248 %token <false_> False "false"
 249 %token <null_> Null "null"
 250 %token <true_> True "true"
 251
 252 // ES3/ES5/WIE/JSC Reserved
 253 %token <word_> Auto "auto"
 254 %token <word_> Break "break"
 255 %token <word_> Case "case"
 256 %token <word_> Catch "catch"
 257 %token <word_> Continue "continue"
 258 %token <word_> Default "default"
 259 %token <word_> Delete "delete"
 260 %token <word_> Do "do"
 261 %token <word_> Else "else"
 262 %token <word_> Finally "finally"
 263 %token <word_> For "for"
 264 %token <word_> Function "function"
 265 %token <word_> Function_ ";function"
 266 %token <word_> If "if"
 267 %token <word_> In "in"
 268 %token <word_> In_ "!in"
 269 %token <word_> InstanceOf "instanceof"
 270 %token <word_> New "new"
 271 %token <word_> Return "return"
 272 %token <word_> Switch "switch"
 273 %token <this_> This "this"
 274 %token <word_> Throw "throw"
 275 %token <word_> Try "try"
 276 %token <word_> TypeOf "typeof"
 277 %token <word_> Var "var"
 278 %token <word_> Void "void"
 279 %token <word_> While "while"
 280 %token <word_> With "with"
 281
 282 // ES3/IE6 Future, ES5/JSC Reserved
 283 %token <word_> Debugger "debugger"
 284
 285 // ES3/ES5/IE6 Future, JSC Reserved
 286 %token <word_> Const "const"
 287
 288 // ES3/ES5/IE6/JSC Future
 289 %token <word_> Class "class"
 290 %token <word_> Enum "enum"
 291 %token <word_> Export "export"
 292 %token <word_> Extends "extends"
 293 %token <word_> Import "import"
 294 %token <word_> Super "super"
 295
 296 // ES3 Future, ES5 Strict Future
 297 %token <identifier_> Implements "implements"
 298 %token <identifier_> Interface "interface"
 299 %token <identifier_> Package "package"
 300 %token <identifier_> Private "private"
 301 %token <identifier_> Protected "protected"
 302 %token <identifier_> Public "public"
 303 %token <identifier_> Static "static"
 304
 305 // ES3 Future
 306 %token <identifier_> Abstract "abstract"
 307 %token <identifier_> Boolean "boolean"
 308 %token <identifier_> Byte "byte"
 309 %token <identifier_> Char "char"
 310 %token <identifier_> Double "double"
 311 %token <identifier_> Final "final"
 312 %token <identifier_> Float "float"
 313 %token <identifier_> Goto "goto"
 314 %token <identifier_> Int "int"
 315 %token <identifier_> Long "long"
 316 %token <identifier_> Native "native"
 317 %token <identifier_> Short "short"
 318 %token <identifier_> Synchronized "synchronized"
 319 %token <identifier_> Throws "throws"
 320 %token <identifier_> Transient "transient"
 321 %token <identifier_> Volatile "volatile"
 322
 323 // ES5 Strict
 324 %token <identifier_> Let "let"
 325 %token <identifier_> Yield "yield"
 326
 327 // Woah?!
 328 %token <identifier_> Each "each"
 329 %token <identifier_> Of "of"
 330
 331 @begin E4X
 332 // E4X Conditional
 333 %token <identifier_> Namespace "namespace"
 334 %token <identifier_> XML "xml"
 335 @end
 336
 337 %token AutoComplete
 338
 339 %token <identifier_> Identifier_
 340 %token <number_> NumericLiteral
 341 %token <string_> StringLiteral
 342 %token <literal_> RegularExpressionLiteral
 343
 344 %type <expression_> AdditiveExpression
 345 %type <argument_> ArgumentList_
 346 %type <argument_> ArgumentList
 347 %type <argument_> ArgumentListOpt
 348 %type <argument_> Arguments
 349 %type <literal_> ArrayLiteral
 350 %type <expression_> ArrowFunction
 351 %type <functionParameter_> ArrowParameters
 352 %type <expression_> AssignmentExpression
 353 %type <identifier_> Binding
 354 %type <identifier_> BindingIdentifier
 355 %type <expression_> BitwiseANDExpression
 356 %type <statement_> Block_
 357 %type <statement_> Block
 358 %type <boolean_> BooleanLiteral
 359 %type <declaration_> BindingElement
 360 %type <expression_> BitwiseORExpression
 361 %type <expression_> BitwiseXORExpression
 362 %type <statement_> BreakStatement
 363 %type <statement_> BreakableStatement
 364 %type <expression_> CallExpression_
 365 %type <expression_> CallExpression
 366 %type <clause_> CaseBlock
 367 %type <clause_> CaseClause
 368 %type <clause_> CaseClausesOpt
 369 %type <catch_> CatchOpt
 370 %type <comprehension_> ComprehensionForList
 371 %type <comprehension_> ComprehensionForListOpt
 372 %type <comprehension_> ComprehensionList
 373 %type <comprehension_> ComprehensionListOpt
 374 %type <expression_> ConditionalExpression
 375 %type <statement_> ContinueStatement
 376 %type <statement_> ConciseBody
 377 %type <statement_> DebuggerStatement
 378 %type <statement_> Declaration__
 379 %type <statement_> Declaration_
 380 %type <statement_> Declaration
 381 %type <clause_> DefaultClause
 382 %type <expression_> Element
 383 %type <expression_> ElementOpt
 384 %type <element_> ElementList
 385 %type <element_> ElementListOpt
 386 %type <statement_> ElseStatementOpt
 387 %type <statement_> EmptyStatement
 388 %type <expression_> EqualityExpression
 389 %type <compound_> Expression_
 390 %type <compound_> Expression
 391 %type <expression_> ExpressionOpt
 392 %type <statement_> ExpressionStatement
 393 %type <finally_> FinallyOpt
 394 %type <comprehension_> ForComprehension
 395 %type <for_> ForStatementInitialiser
 396 %type <forin_> ForInStatementInitialiser
 397 %type <declaration_> FormalParameter
 398 %type <functionParameter_> FormalParameterList_
 399 %type <functionParameter_> FormalParameterList
 400 %type <functionParameter_> FormalParameterListOpt
 401 %type <statement_> FunctionBody
 402 %type <statement_> FunctionDeclaration
 403 %type <expression_> FunctionExpression
 404 %type <identifier_> Identifier
 405 %type <identifier_> IdentifierOpt
 406 %type <word_> IdentifierName
 407 %type <comprehension_> IfComprehension
 408 %type <statement_> IfStatement
 409 %type <expression_> Initialiser
 410 %type <expression_> InitialiserOpt
 411 %type <statement_> IterationStatement
 412 %type <statement_> LabelledStatement
 413 %type <expression_> LeftHandSideExpression
 414 %type <statement_> LetStatement
 415 %type <statement_> LexicalDeclaration
 416 %type <literal_> Literal
 417 %type <literal_> ValueLiteral
 418 %type <expression_> LogicalANDExpression
 419 %type <expression_> LogicalORExpression
 420 %type <member_> MemberAccess
 421 %type <expression_> MemberExpression_
 422 %type <expression_> MemberExpression
 423 %type <expression_> MultiplicativeExpression
 424 %type <expression_> NewExpression
 425 %type <null_> NullLiteral
 426 %type <literal_> ObjectLiteral
 427 %type <compound_> Parenthetical
 428 %type <compound_> ParentheticalOpt
 429 %type <expression_> PostfixExpression
 430 %type <expression_> PrimaryExpression
 431 %type <statement_> Program
 432 %type <statement_> ProgramBody
 433 %type <statement_> ProgramBodyOpt
 434 %type <propertyName_> PropertyName_
 435 %type <propertyName_> PropertyName
 436 %type <property_> PropertyDefinition
 437 %type <property_> PropertyDefinitionList_
 438 %type <property_> PropertyDefinitionList
 439 %type <property_> PropertyDefinitionListOpt
 440 %type <expression_> RelationalExpression
 441 %type <statement_> ReturnStatement
 442 %type <rubyProc_> RubyProcExpression
 443 %type <functionParameter_> RubyProcParameterList_
 444 %type <functionParameter_> RubyProcParameterList
 445 %type <functionParameter_> RubyProcParameters
 446 %type <functionParameter_> RubyProcParametersOpt
 447 %type <expression_> ShiftExpression
 448 %type <declaration_> SingleNameBinding
 449 %type <statement_> Statement__
 450 %type <statement_> Statement_
 451 %type <statement_> Statement
 452 %type <statement_> StatementList
 453 %type <statement_> StatementListOpt
 454 %type <statement_> StatementListItem
 455 %type <statement_> SwitchStatement
 456 %type <statement_> ThrowStatement
 457 %type <statement_> TryStatement
 458 %type <expression_> UnaryExpression_
 459 %type <expression_> UnaryExpression
 460 %type <declaration_> VariableDeclaration
 461 %type <declarations_> VariableDeclarationList_
 462 %type <declarations_> VariableDeclarationList
 463 %type <statement_> VariableStatement
 464 %type <statement_> WithStatement
 465 %type <word_> Word
 466 %type <word_> WordOpt
 467 %type <expression_> Variable
 468
 469 @begin ObjectiveC
 470 %type <typedIdentifier_> ArrayedType
 471 %type <expression_> BoxableExpression
 472 %type <statement_> CategoryStatement
 473 %type <expression_> ClassExpression
 474 %type <field_> ClassFieldListOpt
 475 %type <field_> ClassFields
 476 %type <statement_> ClassStatement
 477 %type <expression_> ClassSuperOpt
 478 %type <message_> ClassMessageDeclaration
 479 %type <message_> ClassMessageDeclarationListOpt
 480 %type <className_> ClassName
 481 %type <className_> ClassNameOpt
 482 %type <protocol_> ClassProtocolListOpt
 483 %type <protocol_> ClassProtocols
 484 %type <protocol_> ClassProtocolsOpt
 485 %type <expression_> EncodedType
 486 %type <modifier_> FunctionedType
 487 %type <expression_> MessageExpression
 488 %type <messageParameter_> MessageParameter
 489 %type <messageParameter_> MessageParameters
 490 %type <messageParameter_> MessageParameterList
 491 %type <messageParameter_> MessageParameterListOpt
 492 %type <bool_> MessageScope
 493 %type <typedIdentifier_> ModifiedType
 494 %type <typedIdentifier_> PrefixedType
 495 %type <expression_> PrimitiveType
 496 %type <argument_> SelectorCall_
 497 %type <argument_> SelectorCall
 498 %type <selector_> SelectorExpression_
 499 %type <selector_> SelectorExpression
 500 %type <selector_> SelectorExpressionOpt
 501 %type <argument_> SelectorList
 502 %type <word_> SelectorWordOpt
 503 %type <typedIdentifier_> SuffixedType
 504 %type <expression_> TypeOpt
 505 %type <typedIdentifier_> TypeParenthetical
 506 %type <modifier_> TypeQualifierLeft
 507 %type <typedIdentifier_> TypeQualifierRight
 508 %type <typedIdentifier_> TypeSignifier
 509 %type <typedIdentifier_> TypedIdentifier
 510 %type <typedParameter_> TypedParameterList_
 511 %type <typedParameter_> TypedParameterList
 512 %type <typedParameter_> TypedParameterListOpt
 513 %type <argument_> VariadicCall
 514 @end
 515
 516 @begin E4X
 517 %type <propertyIdentifier_> PropertyIdentifier_
 518 %type <selector_> PropertySelector_
 519 %type <selector_> PropertySelector
 520 %type <identifier_> QualifiedIdentifier_
 521 %type <identifier_> QualifiedIdentifier
 522 %type <identifier_> WildcardIdentifier
 523 %type <identifier_> XMLComment
 524 %type <identifier_> XMLCDATA
 525 %type <identifier_> XMLElement
 526 %type <identifier_> XMLElementContent
 527 %type <identifier_> XMLMarkup
 528 %type <identifier_> XMLPI
 529
 530 %type <attribute_> AttributeIdentifier
 531 /* XXX: %type <statement_> DefaultXMLNamespaceStatement */
 532 %type <expression_> PropertyIdentifier
 533 %type <expression_> XMLListInitialiser
 534 %type <expression_> XMLInitialiser
 535 @end
 536 /* }}} */
 537 /* Token Priorities {{{ */
 538 %nonassoc ""
 539 %left "++" "--"
 540
 541 %nonassoc "if"
 542 %nonassoc "else"
 543 /* }}} */
 544
 545 %start Program
 546
 547 %%
 548
 549 /* Lexer State {{{ */
 550 LexPushInOn
 551     : { driver.in_.push(true); }
 552     ;
 553
 554 LexPushInOff
 555     : { driver.in_.push(false); }
 556     ;
 557
 558 LexPopIn
 559     : { driver.in_.pop(); }
 560     ;
 561
 562 LexSetRegExp
 563     : { driver.SetCondition(CYDriver::RegExpCondition); }
 564     ;
 565
 566 LexNoBrace
 567     : { if (yychar == yyempty_) driver.no_.OpenBrace = true; else if (yychar == token::OpenBrace || yychar == token::OpenBrace_) yychar = token::OpenBrace__; }
 568     ;
 569
 570 LexNoFunction
 571     : { if (yychar == yyempty_) driver.no_.Function = true; else if (yychar == token::Function) yychar = token::Function_; }
 572     ;
 573
 574 LexNoAtImplementation :
 575 @begin ObjectiveC
 576     { if (yychar == yyempty_) driver.no_.AtImplementation = true; else if (yychar == token::AtImplementation) yychar = token::AtImplementation_; }
 577 @end
 578     ;
 579
 580 LexSetStatement
 581     : LexNoBrace LexNoFunction LexNoAtImplementation
 582     ;
 583 /* }}} */
 584 /* Virtual Tokens {{{ */
 585 BRACE
 586     : "{"
 587     | "\n{"
 588     ;
 589
 590 Var_
 591     : "var"
 592     ;
 593 /* }}} */
 594
 595 /* 7.6 Identifier Names and Identifiers {{{ */
 596 IdentifierName
 597     : Word { $$ = $1; }
 598     ;
 599
 600 NewLineOpt
 601     : "\n"
 602     |
 603     ;
 604
 605 Word
 606     : Identifier { $$ = $1; }
 607     | "auto" { $$ = $1; }
 608     | "break" NewLineOpt { $$ = $1; }
 609     | "case" { $$ = $1; }
 610     | "catch" { $$ = $1; }
 611     | "class" { $$ = $1; }
 612     | "const" { $$ = $1; }
 613     | "continue" NewLineOpt { $$ = $1; }
 614     | "debugger" { $$ = $1; }
 615     | "default" { $$ = $1; }
 616     | "delete" { $$ = $1; }
 617     | "do" { $$ = $1; }
 618     | "else" { $$ = $1; }
 619     | "enum" { $$ = $1; }
 620     | "export" { $$ = $1; }
 621     | "extends" { $$ = $1; }
 622     | "false" { $$ = $1; }
 623     | "finally" { $$ = $1; }
 624     /* XXX: | "for" { $$ = $1; } */
 625     | "function" { $$ = $1; }
 626     | "if" { $$ = $1; }
 627     | "import" { $$ = $1; }
 628     /* XXX: | "in" { $$ = $1; } */
 629     | "!in" { $$ = $1; }
 630     /* XXX: | "instanceof" { $$ = $1; } */
 631
 632     // XXX: as it currently is not an Identifier
 633     | "let" { $$ = $1; }
 634
 635     | "new" { $$ = $1; }
 636     | "null" { $$ = $1; }
 637     | "return" NewLineOpt { $$ = $1; }
 638     | "super" { $$ = $1; }
 639     | "switch" { $$ = $1; }
 640     | "this" { $$ = $1; }
 641     | "throw" NewLineOpt { $$ = $1; }
 642     | "true" { $$ = $1; }
 643     | "try" { $$ = $1; }
 644     | "typeof" { $$ = $1; }
 645     | "var" { $$ = $1; }
 646     | "void" { $$ = $1; }
 647     | "while" { $$ = $1; }
 648     | "with" { $$ = $1; }
 649     ;
 650
 651 WordOpt
 652     : Word { $$ = $1; }
 653     | { $$ = NULL; }
 654     ;
 655
 656 Identifier
 657     : Identifier_ { $$ = $1; }
 658
 659 @begin C
 660     | "typedef" { $$ = $1; }
 661     | "YES" { $$ = $1; }
 662     | "NO" { $$ = $1; }
 663 @end
 664
 665     | "implements" { $$ = $1; }
 666     | "interface" { $$ = $1; }
 667     | "package" { $$ = $1; }
 668     | "private" { $$ = $1; }
 669     | "protected" { $$ = $1; }
 670     | "public" { $$ = $1; }
 671     | "static" { $$ = $1; }
 672
 673     | "abstract" { $$ = $1; }
 674     | "boolean" { $$ = $1; }
 675     | "byte" { $$ = $1; }
 676     | "char" { $$ = $1; }
 677     | "double" { $$ = $1; }
 678     | "final" { $$ = $1; }
 679     | "float" { $$ = $1; }
 680     | "goto" { $$ = $1; }
 681     | "int" { $$ = $1; }
 682     | "long" { $$ = $1; }
 683     | "native" { $$ = $1; }
 684     | "short" { $$ = $1; }
 685     | "synchronized" { $$ = $1; }
 686     | "throws" { $$ = $1; }
 687     | "transient" { $$ = $1; }
 688     | "volatile" { $$ = $1; }
 689
 690     // XXX: currently I only have this as Word
 691     // | "let" { $$ = $1; }
 692
 693     | "yield" { $$ = $1; }
 694
 695     | "each" { $$ = $1; }
 696     | "of" { $$ = $1; }
 697     ;
 698
 699 IdentifierOpt
 700     : Identifier { $$ = $1; }
 701     | { $$ = NULL; }
 702     ;
 703 /* }}} */
 704
 705 /* 7.8 Literals {{{ */
 706 Literal
 707     : NullLiteral { $$ = $1; }
 708     | ValueLiteral { $$ = $1; }
 709     ;
 710
 711 ValueLiteral
 712     : BooleanLiteral { $$ = $1; }
 713     | NumericLiteral { $$ = $1; }
 714     | StringLiteral { $$ = $1; }
 715     | RegularExpressionLiteral { $$ = $1; }
 716     ;
 717 /* }}} */
 718 /* 7.8.1 Null Literals {{{ */
 719 NullLiteral
 720     : "null" { $$ = $1; }
 721     ;
 722 /* }}} */
 723 /* 7.8.2 Boolean Literals {{{ */
 724 BooleanLiteral
 725     : "true" { $$ = $1; }
 726     | "false" { $$ = $1; }
 727     ;
 728 /* }}} */
 729
 730 /* 7.9 Automatic Semicolon Insertion {{{ */
 731 StrictSemi
 732     : { driver.Warning(yylloc, "warning, automatic semi-colon insertion required"); }
 733     ;
 734
 735 Terminator
 736     : ";"
 737     | error { if (yychar != yyeof_ && yychar != token::CloseBrace && !yylval.newline_) YYABORT; else { yyerrok; driver.errors_.pop_back(); } } StrictSemi
 738     ;
 739
 740 TerminatorOpt
 741     : ";"
 742     | error { yyerrok; driver.errors_.pop_back(); } StrictSemi
 743     ;
 744 /* }}} */
 745
 746 /* 11.1 Primary Expressions {{{ */
 747 Parenthetical
 748     : "(" LexPushInOff Expression ")" LexPopIn { $$ = $3; }
 749     ;
 750
 751 ParentheticalOpt
 752     : Parenthetical { $$ = $1; }
 753     | { $$ = NULL; }
 754     ;
 755
 756 Variable
 757     : Identifier { $$ = CYNew CYVariable($1); }
 758     ;
 759
 760 PrimaryExpression
 761     : "this" { $$ = $1; }
 762     | Variable { $$ = $1; }
 763     | Literal { $$ = $1; }
 764     | ArrayLiteral { $$ = $1; }
 765     | ObjectLiteral { $$ = $1; }
 766     | Parenthetical { $$ = $1; }
 767     | AutoComplete { driver.mode_ = CYDriver::AutoPrimary; YYACCEPT; }
 768     ;
 769 /* }}} */
 770 /* 11.1.4.1 Array Initialiser {{{ */
 771 ArrayLiteral
 772     : "[" LexPushInOff ElementListOpt "]" LexPopIn { $$ = CYNew CYArray($3); }
 773     ;
 774
 775 Element
 776     : AssignmentExpression { $$ = $1; }
 777     ;
 778
 779 ElementOpt
 780     : Element { $$ = $1; }
 781     | LexSetRegExp { $$ = NULL; }
 782     ;
 783
 784 ElementList
 785     : ElementOpt "," ElementListOpt { $$ = CYNew CYElement($1, $3); }
 786     | Element { $$ = CYNew CYElement($1, NULL); }
 787     ;
 788
 789 ElementListOpt
 790     : ElementList { $$ = $1; }
 791     | LexSetRegExp { $$ = NULL; }
 792     ;
 793 /* }}} */
 794 /* 11.1.4.2 Array Comprehension {{{ */
 795 PrimaryExpression
 796     : "[" LexPushInOff AssignmentExpression ComprehensionForList "]" LexPopIn { $$ = CYNew CYArrayComprehension($3, $4); }
 797     ;
 798
 799 ComprehensionForList
 800     : "for" Binding "in" Expression ComprehensionForListOpt { $$ = CYNew CYForInComprehension($2, $4, $5); }
 801     | "for" Binding "of" Expression ComprehensionForListOpt { $$ = CYNew CYForOfComprehension($2, $4, $5); }
 802     ;
 803
 804 ComprehensionForListOpt
 805     : ComprehensionForList { $$ = $1; }
 806     | "if" Expression { $$ = CYNew CYIfComprehension($2); }
 807     | { $$ = NULL; }
 808     ;
 809 /* }}} */
 810 /* 11.1.5 Object Initialiser {{{ */
 811 ObjectLiteral
 812     : BRACE LexPushInOff PropertyDefinitionListOpt "}" LexPopIn { $$ = CYNew CYObject($3); }
 813     ;
 814
 815 PropertyDefinitionList_
 816     : "," PropertyDefinitionList { $$ = $2; }
 817     | "," LexSetRegExp { $$ = NULL; }
 818     | { $$ = NULL; }
 819     ;
 820
 821 PropertyDefinitionList
 822     : PropertyDefinition PropertyDefinitionList_ { $1->SetNext($2); $$ = $1; }
 823     ;
 824
 825 PropertyDefinitionListOpt
 826     : PropertyDefinitionList { $$ = $1; }
 827     | LexSetRegExp { $$ = NULL; }
 828     ;
 829
 830 PropertyDefinition
 831     // XXX: this should be IdentifierName
 832     : LexSetRegExp Identifier { $$ = CYNew CYProperty($2, CYNew CYVariable($2)); }
 833     | PropertyName ":" AssignmentExpression { $$ = CYNew CYProperty($1, $3); }
 834     //| MethodDefinition
 835     ;
 836
 837 PropertyName_
 838     : IdentifierName { $$ = $1; }
 839     | StringLiteral { $$ = $1; }
 840     | NumericLiteral { $$ = $1; }
 841     ;
 842
 843 PropertyName
 844     : LexSetRegExp PropertyName_ { $$ = $2; }
 845     ;
 846 /* }}} */
 847
 848 /* 11.2 Left-Hand-Side Expressions {{{ */
 849 MemberAccess
 850     : "[" LexPushInOff Expression "]" LexPopIn { $$ = CYNew CYDirectMember(NULL, $3); }
 851     | "." IdentifierName { $$ = CYNew CYDirectMember(NULL, CYNew CYString($2)); }
 852     | "." AutoComplete { driver.mode_ = CYDriver::AutoDirect; YYACCEPT; }
 853     ;
 854
 855 MemberExpression_
 856     : MemberExpression { $$ = $1; }
 857     //| "super" { $$ = $1; }
 858     ;
 859
 860 MemberExpression
 861     : LexSetRegExp PrimaryExpression { $$ = $2; }
 862     | LexSetRegExp FunctionExpression { $$ = $2; }
 863     | MemberExpression_ { driver.context_ = $1; } MemberAccess { $3->SetLeft($1); $$ = $3; }
 864     | LexSetRegExp "new" MemberExpression Arguments { $$ = CYNew cy::Syntax::New($3, $4); }
 865     ;
 866
 867 NewExpression
 868     : MemberExpression { $$ = $1; }
 869     | LexSetRegExp "new" NewExpression { $$ = CYNew cy::Syntax::New($3, NULL); }
 870     ;
 871
 872 CallExpression_
 873     : MemberExpression_
 874     | CallExpression
 875     ;
 876
 877 CallExpression
 878     : CallExpression_ Arguments { $$ = CYNew CYCall($1, $2); }
 879     | CallExpression { driver.context_ = $1; } MemberAccess { $3->SetLeft($1); $$ = $3; }
 880     ;
 881
 882 Arguments
 883     : "(" LexPushInOff ArgumentListOpt ")" LexPopIn { $$ = $3; }
 884     ;
 885
 886 ArgumentList_
 887     : "," ArgumentList { $$ = $2; }
 888     | { $$ = NULL; }
 889     ;
 890
 891 ArgumentList
 892     : AssignmentExpression ArgumentList_ { $$ = CYNew CYArgument(NULL, $1, $2); }
 893     ;
 894
 895 ArgumentListOpt
 896     : ArgumentList { $$ = $1; }
 897     | LexSetRegExp { $$ = NULL; }
 898     ;
 899
 900 LeftHandSideExpression
 901     : NewExpression { $$ = $1; }
 902     | CallExpression { $$ = $1; }
 903     ;
 904 /* }}} */
 905 /* 11.3 Postfix Expressions {{{ */
 906 PostfixExpression
 907     : %prec "" LeftHandSideExpression { $$ = $1; }
 908     | LeftHandSideExpression "++" { $$ = CYNew CYPostIncrement($1); }
 909     | LeftHandSideExpression "--" { $$ = CYNew CYPostDecrement($1); }
 910     ;
 911 /* }}} */
 912 /* 11.4 Unary Operators {{{ */
 913 UnaryExpression_
 914     : "delete" UnaryExpression { $$ = CYNew CYDelete($2); }
 915     | "void" UnaryExpression { $$ = CYNew CYVoid($2); }
 916     | "typeof" UnaryExpression { $$ = CYNew CYTypeOf($2); }
 917     | "++" UnaryExpression { $$ = CYNew CYPreIncrement($2); }
 918     | "\n++" UnaryExpression { $$ = CYNew CYPreIncrement($2); }
 919     | "--" UnaryExpression { $$ = CYNew CYPreDecrement($2); }
 920     | "\n--" UnaryExpression { $$ = CYNew CYPreDecrement($2); }
 921     | "+" UnaryExpression { $$ = CYNew CYAffirm($2); }
 922     | "-" UnaryExpression { $$ = CYNew CYNegate($2); }
 923     | "~" UnaryExpression { $$ = CYNew CYBitwiseNot($2); }
 924     | "!" UnaryExpression { $$ = CYNew CYLogicalNot($2); }
 925     ;
 926
 927 UnaryExpression
 928     : PostfixExpression { $$ = $1; }
 929     | LexSetRegExp UnaryExpression_ { $$ = $2; }
 930     ;
 931 /* }}} */
 932 /* 11.5 Multiplicative Operators {{{ */
 933 MultiplicativeExpression
 934     : UnaryExpression { $$ = $1; }
 935     | MultiplicativeExpression "*" UnaryExpression { $$ = CYNew CYMultiply($1, $3); }
 936     | MultiplicativeExpression "/" UnaryExpression { $$ = CYNew CYDivide($1, $3); }
 937     | MultiplicativeExpression "%" UnaryExpression { $$ = CYNew CYModulus($1, $3); }
 938     ;
 939 /* }}} */
 940 /* 11.6 Additive Operators {{{ */
 941 AdditiveExpression
 942     : MultiplicativeExpression { $$ = $1; }
 943     | AdditiveExpression "+" MultiplicativeExpression { $$ = CYNew CYAdd($1, $3); }
 944     | AdditiveExpression "-" MultiplicativeExpression { $$ = CYNew CYSubtract($1, $3); }
 945     ;
 946 /* }}} */
 947 /* 11.7 Bitwise Shift Operators {{{ */
 948 ShiftExpression
 949     : AdditiveExpression { $$ = $1; }
 950     | ShiftExpression "<<" AdditiveExpression { $$ = CYNew CYShiftLeft($1, $3); }
 951     | ShiftExpression ">>" AdditiveExpression { $$ = CYNew CYShiftRightSigned($1, $3); }
 952     | ShiftExpression ">>>" AdditiveExpression { $$ = CYNew CYShiftRightUnsigned($1, $3); }
 953     ;
 954 /* }}} */
 955 /* 11.8 Relational Operators {{{ */
 956 RelationalExpression
 957     : ShiftExpression { $$ = $1; }
 958     | RelationalExpression "<" ShiftExpression { $$ = CYNew CYLess($1, $3); }
 959     | RelationalExpression ">" ShiftExpression { $$ = CYNew CYGreater($1, $3); }
 960     | RelationalExpression "<=" ShiftExpression { $$ = CYNew CYLessOrEqual($1, $3); }
 961     | RelationalExpression ">=" ShiftExpression { $$ = CYNew CYGreaterOrEqual($1, $3); }
 962     | RelationalExpression "instanceof" ShiftExpression { $$ = CYNew CYInstanceOf($1, $3); }
 963     | RelationalExpression "in" ShiftExpression { $$ = CYNew CYIn($1, $3); }
 964     ;
 965 /* }}} */
 966 /* 11.9 Equality Operators {{{ */
 967 EqualityExpression
 968     : RelationalExpression { $$ = $1; }
 969     | EqualityExpression "==" RelationalExpression { $$ = CYNew CYEqual($1, $3); }
 970     | EqualityExpression "!=" RelationalExpression { $$ = CYNew CYNotEqual($1, $3); }
 971     | EqualityExpression "===" RelationalExpression { $$ = CYNew CYIdentical($1, $3); }
 972     | EqualityExpression "!==" RelationalExpression { $$ = CYNew CYNotIdentical($1, $3); }
 973     ;
 974 /* }}} */
 975 /* 11.10 Binary Bitwise Operators {{{ */
 976 BitwiseANDExpression
 977     : EqualityExpression { $$ = $1; }
 978     | BitwiseANDExpression "&" EqualityExpression { $$ = CYNew CYBitwiseAnd($1, $3); }
 979     ;
 980
 981 BitwiseXORExpression
 982     : BitwiseANDExpression { $$ = $1; }
 983     | BitwiseXORExpression "^" BitwiseANDExpression { $$ = CYNew CYBitwiseXOr($1, $3); }
 984     ;
 985
 986 BitwiseORExpression
 987     : BitwiseXORExpression { $$ = $1; }
 988     | BitwiseORExpression "|" BitwiseXORExpression { $$ = CYNew CYBitwiseOr($1, $3); }
 989     ;
 990 /* }}} */
 991 /* 11.11 Binary Logical Operators {{{ */
 992 LogicalANDExpression
 993     : BitwiseORExpression { $$ = $1; }
 994     | LogicalANDExpression "&&" BitwiseORExpression { $$ = CYNew CYLogicalAnd($1, $3); }
 995     ;
 996
 997 LogicalORExpression
 998     : LogicalANDExpression { $$ = $1; }
 999     | LogicalORExpression "||" LogicalANDExpression { $$ = CYNew CYLogicalOr($1, $3); }
1000     ;
1001 /* }}} */
1002 /* 11.12 Conditional Operator ( ? : ) {{{ */
1003 ConditionalExpression
1004     : LogicalORExpression { $$ = $1; }
1005     | LogicalORExpression "?" LexPushInOff AssignmentExpression ":" LexPopIn AssignmentExpression { $$ = CYNew CYCondition($1, $4, $7); }
1006     ;
1007 /* }}} */
1008 /* 11.13 Assignment Operators {{{ */
1009 AssignmentExpression
1010     : ConditionalExpression { $$ = $1; }
1011     | ArrowFunction { $$ = $1; }
1012     | LeftHandSideExpression "=" AssignmentExpression { $$ = CYNew CYAssign($1, $3); }
1013     | LeftHandSideExpression "*=" AssignmentExpression { $$ = CYNew CYMultiplyAssign($1, $3); }
1014     | LeftHandSideExpression "/=" AssignmentExpression { $$ = CYNew CYDivideAssign($1, $3); }
1015     | LeftHandSideExpression "%=" AssignmentExpression { $$ = CYNew CYModulusAssign($1, $3); }
1016     | LeftHandSideExpression "+=" AssignmentExpression { $$ = CYNew CYAddAssign($1, $3); }
1017     | LeftHandSideExpression "-=" AssignmentExpression { $$ = CYNew CYSubtractAssign($1, $3); }
1018     | LeftHandSideExpression "<<=" AssignmentExpression { $$ = CYNew CYShiftLeftAssign($1, $3); }
1019     | LeftHandSideExpression ">>=" AssignmentExpression { $$ = CYNew CYShiftRightSignedAssign($1, $3); }
1020     | LeftHandSideExpression ">>>=" AssignmentExpression { $$ = CYNew CYShiftRightUnsignedAssign($1, $3); }
1021     | LeftHandSideExpression "&=" AssignmentExpression { $$ = CYNew CYBitwiseAndAssign($1, $3); }
1022     | LeftHandSideExpression "^=" AssignmentExpression { $$ = CYNew CYBitwiseXOrAssign($1, $3); }
1023     | LeftHandSideExpression "|=" AssignmentExpression { $$ = CYNew CYBitwiseOrAssign($1, $3); }
1024     ;
1025 /* }}} */
1026 /* 11.14 Comma Operator {{{ */
1027 Expression_
1028     : "," Expression { $$ = $2; }
1029     | { $$ = CYNew CYCompound(); }
1030     ;
1031
1032 Expression
1033     : AssignmentExpression Expression_ { $2->AddPrev($1); $$ = $2; }
1034     ;
1035
1036 ExpressionOpt
1037     : Expression { $$ = $1; }
1038     | LexSetRegExp { $$ = NULL; }
1039     ;
1040 /* }}} */
1041
1042 /* 12 Statements {{{ */
1043 Statement__
1044     : Block { $$ = $1; }
1045     | VariableStatement { $$ = $1; }
1046     | EmptyStatement { $$ = $1; }
1047     | IfStatement { $$ = $1; }
1048     | BreakableStatement { $$ = $1; }
1049     | ContinueStatement { $$ = $1; }
1050     | BreakStatement { $$ = $1; }
1051     | ReturnStatement { $$ = $1; }
1052     | WithStatement { $$ = $1; }
1053     | LabelledStatement { $$ = $1; }
1054     | ThrowStatement { $$ = $1; }
1055     | TryStatement { $$ = $1; }
1056     | DebuggerStatement { $$ = $1; }
1057     ;
1058
1059 Statement_
1060     : LexSetRegExp Statement__ { $$ = $2; }
1061     | ExpressionStatement { $$ = $1; }
1062     ;
1063
1064 Statement
1065     : LexSetStatement Statement_ { $$ = $2; }
1066     ;
1067
1068 Declaration__
1069     : FunctionDeclaration { $$ = $1; }
1070     | LexicalDeclaration { $$ = $1; }
1071     ;
1072
1073 Declaration_
1074     : LexSetRegExp Declaration__ { $$ = $2; }
1075     ;
1076
1077 Declaration
1078     : LexSetStatement Declaration_ { $$ = $2; }
1079     ;
1080
1081 BreakableStatement
1082     : IterationStatement { $$ = $1; }
1083     | SwitchStatement { $$ = $1; }
1084     ;
1085 /* }}} */
1086 /* 12.1 Block {{{ */
1087 Block_
1088     : BRACE StatementListOpt "}" { $$ = $2; }
1089     ;
1090
1091 Block
1092     : ";{" StatementListOpt "}" { $$ = CYNew CYBlock($2); }
1093     ;
1094
1095 StatementList
1096     : StatementListItem StatementListOpt { $1->SetNext($2); $$ = $1; }
1097     ;
1098
1099 StatementListOpt
1100     : StatementList { $$ = $1; }
1101     | LexSetStatement LexSetRegExp { $$ = NULL; }
1102     ;
1103
1104 StatementListItem
1105     : Statement { $$ = $1; }
1106     | Declaration { $$ = $1; }
1107     ;
1108 /* }}} */
1109
1110 /* 12.2 Declarations {{{ */
1111 BindingIdentifier
1112     : Identifier { $$ = $1; }
1113     ;
1114
1115 Binding
1116     : BindingIdentifier
1117     ;
1118
1119 // XXX: BindingPattern
1120 /* }}} */
1121 /* 12.2.1 Let and Const Declarations {{{ */
1122 LexicalDeclaration
1123     : LetOrConst VariableDeclarationList Terminator { $$ = CYNew CYVar($2); }
1124     ;
1125
1126 LetOrConst
1127     : "let"
1128     | "const"
1129     ;
1130 /* }}} */
1131 /* 12.2.2 Variable Statement {{{ */
1132 VariableStatement
1133     : Var_ VariableDeclarationList Terminator { $$ = CYNew CYVar($2); }
1134     ;
1135
1136 VariableDeclarationList_
1137     : "," VariableDeclarationList { $$ = $2; }
1138     | { $$ = NULL; }
1139     ;
1140
1141 VariableDeclarationList
1142     : VariableDeclaration VariableDeclarationList_ { $$ = CYNew CYDeclarations($1, $2); }
1143     ;
1144
1145 VariableDeclaration
1146     : BindingIdentifier InitialiserOpt { $$ = CYNew CYDeclaration($1, $2); }
1147     // XXX: | BindingPattern Initialiser { $$ = CYNew CYDeclaration($1, $2); }
1148     ;
1149
1150 Initialiser
1151     : "=" AssignmentExpression { $$ = $2; }
1152     ;
1153
1154 InitialiserOpt
1155     : Initialiser { $$ = $1; }
1156     | { $$ = NULL; }
1157     ;
1158 /* }}} */
1159 /* 12.2.4 Destructuring Binding Patterns {{{ */
1160 // XXX: *
1161
1162 BindingElement
1163     : SingleNameBinding { $$ = $1; }
1164     ;
1165
1166 SingleNameBinding
1167     : BindingIdentifier InitialiserOpt { $$ = CYNew CYDeclaration($1, $2); }
1168     ;
1169 /* }}} */
1170
1171 /* 12.3 Empty Statement {{{ */
1172 EmptyStatement
1173     : ";" { $$ = CYNew CYEmpty(); }
1174     ;
1175 /* }}} */
1176 /* 12.4 Expression Statement {{{ */
1177 ExpressionStatement
1178     : Expression Terminator { $$ = CYNew CYExpress($1); }
1179     ;
1180 /* }}} */
1181 /* 12.5 The if Statement {{{ */
1182 ElseStatementOpt
1183     : "else" Statement { $$ = $2; }
1184     | %prec "if" { $$ = NULL; }
1185     ;
1186
1187 IfStatement
1188     : "if" "(" Expression ")" Statement ElseStatementOpt { $$ = CYNew CYIf($3, $5, $6); }
1189     ;
1190 /* }}} */
1191
1192 /* 12.6.1 The do-while Statement {{{ */
1193 IterationStatement
1194     : "do" Statement "while" "(" Expression ")" TerminatorOpt { $$ = CYNew CYDoWhile($5, $2); }
1195     ;
1196 /* }}} */
1197 /* 12.6.2 The while Statement {{{ */
1198 IterationStatement
1199     : "while" "(" Expression ")" Statement { $$ = CYNew CYWhile($3, $5); }
1200     ;
1201 /* }}} */
1202 /* 12.6.3 The for Statement {{{ */
1203 IterationStatement
1204     : "for" "(" LexPushInOn ForStatementInitialiser ";" LexPopIn ExpressionOpt ";" ExpressionOpt ")" Statement { $$ = CYNew CYFor($4, $7, $9, $11); }
1205     ;
1206
1207 ForStatementInitialiser
1208     : ExpressionOpt { $$ = $1; }
1209     | LexSetRegExp Var_ VariableDeclarationList { $$ = CYNew CYForDeclarations($3); }
1210     ;
1211 /* }}} */
1212 /* 12.6.4 The for-in and for-of Statements {{{ */
1213 IterationStatement
1214     : "for" "(" LexPushInOn ForInStatementInitialiser "!in" LexPopIn Expression ")" Statement { $$ = CYNew CYForIn($4, $7, $9); }
1215     | "for" "(" LexPushInOn ForInStatementInitialiser "of" LexPopIn Expression ")" Statement { $$ = CYNew CYForOf($4, $7, $9); }
1216     ;
1217
1218 ForInStatementInitialiser
1219     : LeftHandSideExpression { $$ = $1; }
1220     | LexSetRegExp Var_ VariableDeclaration { $$ = $3; }
1221     ;
1222 /* }}} */
1223
1224 /* 12.7 The continue Statement {{{ */
1225 ContinueStatement
1226     : "continue" "\n" StrictSemi { $$ = CYNew CYContinue(NULL); }
1227     | "continue" IdentifierOpt Terminator { $$ = CYNew CYContinue($2); }
1228     ;
1229 /* }}} */
1230 /* 12.8 The break Statement {{{ */
1231 BreakStatement
1232     : "break" "\n" StrictSemi { $$ = CYNew CYBreak(NULL); }
1233     | "break" IdentifierOpt Terminator { $$ = CYNew CYBreak($2); }
1234     ;
1235 /* }}} */
1236 /* 12.9 The return Statement {{{ */
1237 ReturnStatement
1238     : "return" LexSetRegExp "\n" StrictSemi { $$ = CYNew CYReturn(NULL); }
1239     | "return" ExpressionOpt Terminator { $$ = CYNew CYReturn($2); }
1240     ;
1241 /* }}} */
1242 /* 12.10 The with Statement {{{ */
1243 WithStatement
1244     : "with" "(" Expression ")" Statement { $$ = CYNew CYWith($3, $5); }
1245     ;
1246 /* }}} */
1247
1248 /* 12.11 The switch Statement {{{ */
1249 SwitchStatement
1250     : "switch" "(" Expression ")" CaseBlock { $$ = CYNew CYSwitch($3, $5); }
1251     ;
1252
1253 CaseBlock
1254     : BRACE CaseClausesOpt "}" { $$ = $2; }
1255     ;
1256
1257 CaseClause
1258     : "case" Expression ":" StatementListOpt { $$ = CYNew CYClause($2, $4); }
1259     ;
1260
1261 CaseClausesOpt
1262     : CaseClause CaseClausesOpt { $1->SetNext($2); $$ = $1; }
1263     | DefaultClause CaseClausesOpt { $1->SetNext($2); $$ = $1; }
1264     | { $$ = NULL; }
1265     ;
1266
1267 DefaultClause
1268     : "default" ":" StatementListOpt { $$ = CYNew CYClause(NULL, $3); }
1269     ;
1270 /* }}} */
1271 /* 12.12 Labelled Statements {{{ */
1272 LabelledStatement
1273     : Identifier ":" Statement { $$ = CYNew CYLabel($1, $3); }
1274     ;
1275 /* }}} */
1276 /* 12.13 The throw Statement {{{ */
1277 ThrowStatement
1278     : "throw" LexSetRegExp "\n" StrictSemi { YYABORT; }
1279     | "throw" Expression Terminator { $$ = CYNew cy::Syntax::Throw($2); }
1280     ;
1281 /* }}} */
1282 /* 12.14 The try Statement {{{ */
1283 TryStatement
1284     : "try" Block_ CatchOpt FinallyOpt { $$ = CYNew cy::Syntax::Try($2, $3, $4); }
1285     ;
1286
1287 CatchOpt
1288     : "catch" "(" Identifier ")" Block_ { $$ = CYNew cy::Syntax::Catch($3, $5); }
1289     | { $$ = NULL; }
1290     ;
1291
1292 FinallyOpt
1293     : "finally" Block_ { $$ = CYNew CYFinally($2); }
1294     | { $$ = NULL; }
1295     ;
1296 /* }}} */
1297 /* 12.14 The debugger Statement {{{ */
1298 DebuggerStatement
1299     : "debugger" Terminator { $$ = CYNew CYDebugger(); }
1300     ;
1301 /* }}} */
1302
1303 /* 13.1 Function Definitions {{{ */
1304 FunctionDeclaration
1305     : ";function" Identifier "(" FormalParameterListOpt ")" BRACE FunctionBody "}" { $$ = CYNew CYFunctionStatement($2, $4, $7); }
1306     ;
1307
1308 FunctionExpression
1309     : "function" IdentifierOpt "(" LexPushInOff FormalParameterListOpt ")" LexPopIn BRACE LexPushInOff FunctionBody "}" LexPopIn { $$ = CYNew CYFunctionExpression($2, $5, $10); }
1310     ;
1311
1312 FormalParameterList_
1313     : "," FormalParameterList { $$ = $2; }
1314     | { $$ = NULL; }
1315     ;
1316
1317 FormalParameterList
1318     // XXX: : FunctionRestParameter { $$ = $1; }
1319     : FormalParameter FormalParameterList_ { $$ = CYNew CYFunctionParameter($1, $2); }
1320     ;
1321
1322 FormalParameterListOpt
1323     : FormalParameterList
1324     | { $$ = NULL; }
1325     ;
1326
1327 /* XXX: FunctionRestParameter
1328     : "..." BindingIdentifier { $$ = CYNew CYFunctionRestParameter($2); }
1329     ;*/
1330
1331 FormalParameter
1332     : BindingElement { $$ = $1; }
1333     ;
1334
1335 FunctionBody
1336     : StatementListOpt { $$ = $1; }
1337     ;
1338 /* }}} */
1339 /* 13.2 Arrow Function Definitions {{{ */
1340 ArrowFunction
1341     : LexSetRegExp ArrowParameters "=>" LexNoBrace ConciseBody { $$ = CYNew CYFatArrow($2, $5); }
1342     ;
1343
1344 ArrowParameters
1345     : BindingIdentifier { $$ = CYNew CYFunctionParameter(CYNew CYDeclaration($1)); }
1346     //| ParentheticalOpt { $$ = $1; }
1347     ;
1348
1349 ConciseBody
1350     : AssignmentExpression { $$ = CYNew CYReturn($1); }
1351     | LexSetRegExp ";{" LexPushInOff FunctionBody "}" LexPopIn { $$ = $4; }
1352     ;
1353 /* }}} */
1354 /* 14 Program {{{ */
1355 Program
1356     : ProgramBodyOpt { driver.program_ = CYNew CYProgram($1); }
1357     ;
1358
1359 ProgramBody
1360     : StatementList { $$ = $1; }
1361     ;
1362
1363 ProgramBodyOpt
1364     : ProgramBody { $$ = $1; }
1365     | LexSetStatement LexSetRegExp { $$ = NULL; }
1366     ;
1367 /* }}} */
1368
1369 @begin ObjectiveC
1370 /* Cycript (Objective-C): Type Encoding {{{ */
1371 TypeParenthetical
1372     : "(" LexPushInOff PrefixedType ")" LexPopIn { $$ = $3; }
1373     ;
1374
1375 TypeSignifier
1376     : Identifier { $$ = CYNew CYTypedIdentifier($1); }
1377     | TypeParenthetical { $$ = $1; }
1378     ;
1379
1380 ArrayedType
1381     : ArrayedType "[" NumericLiteral "]" { $$ = $1; $$->modifier_ = CYNew CYTypeArrayOf($3, $$->modifier_); }
1382     | TypeSignifier { $$ = $1; }
1383     | { $$ = CYNew CYTypedIdentifier(); }
1384     ;
1385
1386 FunctionedType
1387     : "(" LexPushInOff TypedParameterListOpt ")" LexPopIn { $$ = CYNew CYTypeFunctionWith($3); }
1388     ;
1389
1390 SuffixedType
1391     : ArrayedType { $$ = $1; }
1392     | TypeParenthetical FunctionedType { $$ = $1; CYSetLast($2) = $$->modifier_; $$->modifier_ = $2; }
1393     | FunctionedType { $$ = CYNew CYTypedIdentifier(); CYSetLast($1) = $$->modifier_; $$->modifier_ = $1; }
1394     ;
1395
1396 PrefixedType
1397     : "*" TypeQualifierRight { $$ = $2; $$->modifier_ = CYNew CYTypePointerTo($$->modifier_); }
1398     ;
1399
1400 TypeQualifierLeft
1401     : "const" TypeQualifierLeft { $$ = $2; CYSetLast($$) = CYNew CYTypeConstant(); }
1402     /* XXX: | "volatile" TypeQualifierLeft { $$ = $2; CYSetLast($$) = CYNew CYTypeVolatile(); } */
1403     | { $$ = NULL; }
1404     ;
1405
1406 TypeQualifierRight
1407     : "const" TypeQualifierRight { $$ = $2; $$->modifier_ = CYNew CYTypeConstant($$->modifier_); }
1408     | PrefixedType { $$ = $1; }
1409     | SuffixedType { $$ = $1; }
1410     ;
1411
1412 PrimitiveType
1413     : Variable { $$ = $1; }
1414     | "void" { $$  = CYNew cy::Syntax::New(CYNew CYVariable(CYNew CYIdentifier("Type")), CYNew CYArgument(CYNew CYString("v"))); }
1415     ;
1416
1417 TypedIdentifier
1418     : TypeQualifierLeft PrimitiveType TypeQualifierRight { $$ = $3; $$->type_ = $2; CYSetLast($1) = $$->modifier_; $$->modifier_ = $1; }
1419     ;
1420
1421 EncodedType
1422     : TypedIdentifier { $$ = CYNew CYEncodedType($1); }
1423     ;
1424
1425 PrimaryExpression
1426     : AtEncode "(" EncodedType ")" { $$ = $3; }
1427     ;
1428 /* }}} */
1429 /* Cycript (Objective-C): @class Declaration {{{ */
1430 ClassSuperOpt
1431     /* XXX: why the hell did I choose MemberExpression? */
1432     : ":" LexSetRegExp MemberExpression { $$ = $3; }
1433     | { $$ = NULL; }
1434     ;
1435
1436 ClassFieldListOpt
1437     : Expression Identifier ";" ClassFieldListOpt { $$ = CYNew CYField($1, $2, $4); }
1438     | LexSetRegExp { $$ = NULL; }
1439     ;
1440
1441 ClassFields
1442     : BRACE ClassFieldListOpt "}" { $$ = $2; }
1443     ;
1444
1445 MessageScope
1446     : "+" { $$ = false; }
1447     | "-" { $$ = true; }
1448     ;
1449
1450 TypeOpt
1451     : "(" LexSetRegExp EncodedType ")" { $$ = $3; }
1452     | { $$ = NULL; }
1453     ;
1454
1455 MessageParameter
1456     : Word ":" TypeOpt Identifier { $$ = CYNew CYMessageParameter($1, $3, $4); }
1457     ;
1458
1459 MessageParameterList
1460     : MessageParameter MessageParameterListOpt { $1->SetNext($2); $$ = $1; }
1461     ;
1462
1463 MessageParameterListOpt
1464     : MessageParameterList { $$ = $1; }
1465     | { $$ = NULL; }
1466     ;
1467
1468 MessageParameters
1469     : MessageParameterList { $$ = $1; }
1470     | Word { $$ = CYNew CYMessageParameter($1, NULL, NULL); }
1471     ;
1472
1473 ClassMessageDeclaration
1474     : MessageScope TypeOpt MessageParameters BRACE FunctionBody "}" { $$ = CYNew CYMessage($1, $2, $3, $5); }
1475     ;
1476
1477 ClassMessageDeclarationListOpt
1478     : ClassMessageDeclarationListOpt ClassMessageDeclaration { $2->SetNext($1); $$ = $2; }
1479     | ClassMessageDeclarationListOpt Comment { $$ = $1; }
1480     | { $$ = NULL; }
1481     ;
1482
1483 ClassName
1484     : Identifier { $$ = $1; }
1485     | "(" AssignmentExpression ")" { $$ = $2; }
1486     ;
1487
1488 ClassNameOpt
1489     : ClassName { $$ = $1; }
1490     | { $$ = NULL; }
1491     ;
1492
1493 // XXX: this should be AssignmentExpressionNoRight
1494 ClassProtocols
1495     : ShiftExpression ClassProtocolsOpt { $$ = CYNew CYProtocol($1, $2); }
1496     ;
1497
1498 ClassProtocolsOpt
1499     : "," ClassProtocols { $$ = $2; }
1500     | { $$ = NULL; }
1501     ;
1502
1503 ClassProtocolListOpt
1504     : "<" ClassProtocols ">" { $$ = $2; }
1505     | { $$ = NULL; }
1506     ;
1507
1508 ClassExpression
1509     : "@implementation" LexPushInOff ClassNameOpt ClassSuperOpt ClassProtocolListOpt ClassFields ClassMessageDeclarationListOpt "@end" LexPopIn { $$ = CYNew CYClassExpression($3, $4, $5, $6, $7); }
1510     ;
1511
1512 ClassStatement
1513     : ";@implementation" ClassName ClassSuperOpt ClassProtocolListOpt ClassFields ClassMessageDeclarationListOpt "@end" { $$ = CYNew CYClassStatement($2, $3, $4, $5, $6); }
1514     ;
1515
1516 CategoryName
1517     : "(" WordOpt ")"
1518     ;
1519
1520 CategoryStatement
1521     : ";@implementation" ClassName CategoryName ClassMessageDeclarationListOpt "@end" { $$ = CYNew CYCategory($2, $4); }
1522     ;
1523
1524 PrimaryExpression
1525     : ClassExpression { $$ = $1; }
1526     ;
1527
1528 Statement__
1529     : ClassStatement { $$ = $1; }
1530     | CategoryStatement { $$ = $1; }
1531     ;
1532 /* }}} */
1533 /* Cycript (Objective-C): Send Message {{{ */
1534 VariadicCall
1535     : "," AssignmentExpression VariadicCall { $$ = CYNew CYArgument(NULL, $2, $3); }
1536     | { $$ = NULL; }
1537     ;
1538
1539 SelectorWordOpt
1540     : WordOpt { driver.contexts_.back().words_.push_back($1); } { $$ = $1; }
1541     | AutoComplete { driver.mode_ = CYDriver::AutoMessage; YYACCEPT; }
1542     ;
1543
1544 SelectorCall_
1545     : SelectorCall { $$ = $1; }
1546     | VariadicCall { $$ = $1; }
1547     ;
1548
1549 SelectorCall
1550     : SelectorWordOpt ":" AssignmentExpression SelectorCall_ { $$ = CYNew CYArgument($1 ?: CYNew CYBlank(), $3, $4); }
1551     ;
1552
1553 SelectorList
1554     : SelectorCall { $$ = $1; }
1555     | Word { $$ = CYNew CYArgument($1, NULL); }
1556     ;
1557
1558 MessageExpression
1559     : "[" LexPushInOff AssignmentExpression { driver.contexts_.push_back($3); } SelectorList "]" LexPopIn { driver.contexts_.pop_back(); } { $$ = CYNew CYSendDirect($3, $5); }
1560     | "[" LexPushInOff LexSetRegExp "super" { driver.context_ = NULL; } SelectorList "]" LexPopIn { $$ = CYNew CYSendSuper($6); }
1561     ;
1562
1563 SelectorExpression_
1564     : WordOpt ":" SelectorExpressionOpt { $$ = CYNew CYSelectorPart($1, true, $3); }
1565     ;
1566
1567 SelectorExpression
1568     : SelectorExpression_ { $$ = $1; }
1569     | Word { $$ = CYNew CYSelectorPart($1, false, NULL); }
1570     ;
1571
1572 SelectorExpressionOpt
1573     : SelectorExpression_ { $$ = $1; }
1574     | { $$ = NULL; }
1575     ;
1576
1577 PrimaryExpression
1578     : MessageExpression { $$ = $1; }
1579     | "@selector" "(" LexPushInOff SelectorExpression ")" LexPopIn { $$ = CYNew CYSelector($4); }
1580     ;
1581 /* }}} */
1582 /* Cycript (Objective-C): @import Directive {{{ */
1583 PathName
1584     : "/" PathName
1585     | "." PathName
1586     | Word PathName
1587     |
1588     ;
1589
1590 ImportPath
1591     : "<" PathName ">"
1592     | StringLiteral
1593     ;
1594
1595 StatementListItem
1596     : LexSetStatement LexSetRegExp "@import" ImportPath { $$ = CYNew CYImport(); }
1597     ;
1598 /* }}} */
1599 /* Cycript (Objective-C): Boxed Expressions {{{ */
1600 BoxableExpression
1601     : NullLiteral { $$ = $1; }
1602     | BooleanLiteral { $$ = $1; }
1603     | NumericLiteral { $$ = $1; }
1604     | StringLiteral { $$ = $1; }
1605     | ArrayLiteral { $$ = $1; }
1606     | ObjectLiteral { $$ = $1; }
1607     | Parenthetical { $$ = $1; }
1608     | "YES" { $$ = CYNew CYTrue(); }
1609     | "NO" { $$ = CYNew CYFalse(); }
1610     ;
1611
1612 PrimaryExpression
1613     : "@" BoxableExpression { $$ = CYNew CYBox($2); }
1614     ;
1615 /* }}} */
1616 /* Cycript (Objective-C): Block Expressions {{{ */
1617 ModifiedType
1618     : TypeQualifierLeft PrimitiveType { $$ = CYNew CYTypedIdentifier(); $$->type_ = $2; $$->modifier_ = $1; }
1619     | ModifiedType "*" { $$ = $1; $$->modifier_ = CYNew CYTypePointerTo($$->modifier_); }
1620     ;
1621
1622 PrimaryExpression
1623     : "^" ModifiedType "(" LexPushInOff TypedParameterListOpt ")" LexPopIn BRACE LexPushInOff FunctionBody "}" LexPopIn { $$ = CYNew CYObjCBlock($2, $5, $10); }
1624     ;
1625 /* }}} */
1626 @end
1627
1628 @begin C
1629 /* Cycript (C): Pointer Indirection/Addressing {{{ */
1630 LeftHandSideExpression
1631     : LexSetRegExp "*" UnaryExpression { $$ = CYNew CYIndirect($3); }
1632     ;
1633
1634 UnaryExpression_
1635     : "&" UnaryExpression { $$ = CYNew CYAddressOf($2); }
1636     ;
1637
1638 MemberAccess
1639     : "->" "[" Expression "]" { $$ = CYNew CYIndirectMember(NULL, $3); }
1640     | "->" IdentifierName { $$ = CYNew CYIndirectMember(NULL, CYNew CYString($2)); }
1641     | "->" AutoComplete { driver.mode_ = CYDriver::AutoIndirect; YYACCEPT; }
1642     ;
1643 /* }}} */
1644 /* Cycript (C): auto Compatibility {{{ */
1645 Var_
1646     : "auto"
1647     ;
1648 /* }}} */
1649 /* Cycript (C): Lambda Expressions {{{ */
1650 TypedParameterList_
1651     : "," TypedParameterList { $$ = $2; }
1652     | { $$ = NULL; }
1653     ;
1654
1655 TypedParameterList
1656     : TypedIdentifier TypedParameterList_ { $$ = CYNew CYTypedParameter($1, $2); }
1657     ;
1658
1659 TypedParameterListOpt
1660     : TypedParameterList { $$ = $1; }
1661     | { $$ = NULL; }
1662     ;
1663
1664 PrimaryExpression
1665     : "[" LexPushInOff LexSetRegExp "&" LexSetRegExp "]" LexPopIn "(" LexPushInOff TypedParameterListOpt ")" LexPopIn "->" TypedIdentifier BRACE LexPushInOff FunctionBody "}" LexPopIn { $$ = CYNew CYLambda($14, $10, $17); }
1666     ;
1667 /* }}} */
1668 /* Cycript (C): Type Definitions {{{ */
1669 Statement__
1670     : "typedef" TypedIdentifier Terminator { $$ = CYNew CYTypeDefinition($2); }
1671     ;
1672 /* }}} */
1673 @end
1674
1675 /* YUI: Documentation Comments {{{ */
1676 Statement__
1677     : Comment { $$ = $1; }
1678     ;
1679 /* }}} */
1680
1681 @begin E4X
1682 /* Lexer State {{{ */
1683 LexPushRegExp
1684     : { driver.PushCondition(CYDriver::RegExpCondition); }
1685     ;
1686
1687 LexPushXMLContent
1688     : { driver.PushCondition(CYDriver::XMLContentCondition); }
1689     ;
1690
1691 LexPushXMLTag
1692     : { driver.PushCondition(CYDriver::XMLTagCondition); }
1693     ;
1694
1695 LexPop
1696     : { driver.PopCondition(); }
1697     ;
1698
1699 LexSetXMLContent
1700     : { driver.SetCondition(CYDriver::XMLContentCondition); }
1701     ;
1702
1703 LexSetXMLTag
1704     : { driver.SetCondition(CYDriver::XMLTagCondition); }
1705     ;
1706 /* }}} */
1707 /* Virtual Tokens {{{ */
1708 XMLWhitespaceOpt
1709     : XMLWhitespace
1710     |
1711     ;
1712 /* }}} */
1713
1714 /* 8.1 Context Keywords {{{ */
1715 Identifier
1716     : "namespace" { $$ = $1; }
1717     | "xml" { $$ = $1; }
1718     ;
1719 /* }}} */
1720 /* 8.3 XML Initialiser Input Elements {{{ */
1721 XMLMarkup
1722     : XMLComment { $$ = $1; }
1723     | XMLCDATA { $$ = $1; }
1724     | XMLPI { $$ = $1; }
1725     ;
1726 /* }}} */
1727
1728 /* 11.1 Primary Expressions {{{ */
1729 PrimaryExpression
1730     : PropertyIdentifier { $$ = CYNew CYPropertyVariable($1); }
1731     | XMLInitialiser { $$ = $1; }
1732     | XMLListInitialiser { $$ = $1; }
1733     ;
1734
1735 PropertyIdentifier
1736     : AttributeIdentifier { $$ = $1; }
1737     | QualifiedIdentifier { $$ = $1; }
1738     | WildcardIdentifier { $$ = $1; }
1739     ;
1740 /* }}} */
1741 /* 11.1.1 Attribute Identifiers {{{ */
1742 AttributeIdentifier
1743     : "@" QualifiedIdentifier_ { $$ = CYNew CYAttribute($2); }
1744     ;
1745
1746 PropertySelector_
1747     : PropertySelector { $$ = $1; }
1748     | "[" LexPushInOff Expression "]" LexPopIn { $$ = CYNew CYSelector($3); }
1749     ;
1750
1751 PropertySelector
1752     : Identifier { $$ = CYNew CYSelector($1); }
1753     | WildcardIdentifier { $$ = $1; }
1754     ;
1755 /* }}} */
1756 /* 11.1.2 Qualified Identifiers {{{ */
1757 QualifiedIdentifier_
1758     : PropertySelector_ { $$ = CYNew CYQualified(NULL, $1); }
1759     | QualifiedIdentifier { $$ = $1; }
1760     ;
1761
1762 QualifiedIdentifier
1763     : PropertySelector "::" PropertySelector_ { $$ = CYNew CYQualified($1, $3); }
1764     ;
1765 /* }}} */
1766 /* 11.1.3 Wildcard Identifiers {{{ */
1767 WildcardIdentifier
1768     : "*" { $$ = CYNew CYWildcard(); }
1769     ;
1770 /* }}} */
1771 /* 11.1.4 XML Initialiser {{{ */
1772 XMLInitialiser
1773     : XMLMarkup { $$ = $1; }
1774     | XMLElement { $$ = $1; }
1775     ;
1776
1777 XMLElement
1778     : "<" LexPushInOff XMLTagContent LexPop "/>" LexPopIn
1779     | "<" LexPushInOff XMLTagContent ">" LexSetXMLContent XMLElementContentOpt "</" LexSetXMLTag XMLTagName XMLWhitespaceOpt LexPop ">" LexPopIn
1780     ;
1781
1782 XMLTagContent
1783     : LexPushXMLTag XMLTagName XMLAttributes
1784     ;
1785
1786 XMLExpression
1787     : BRACE LexPushRegExp Expression LexPop "}"
1788     ;
1789
1790 XMLTagName
1791     : XMLExpression
1792     | XMLName
1793     ;
1794
1795 XMLAttributes_
1796     : XMLAttributes_ XMLAttribute
1797     |
1798     ;
1799
1800 XMLAttributes
1801     : XMLAttributes_ XMLWhitespace XMLExpression XMLWhitespaceOpt
1802     | XMLAttributes_ XMLWhitespaceOpt
1803     ;
1804
1805 XMLAttributeValue_
1806     : XMLExpression
1807     | XMLAttributeValue
1808     ;
1809
1810 XMLAttribute
1811     : XMLWhitespace XMLName XMLWhitespaceOpt "=" XMLWhitespaceOpt XMLAttributeValue_
1812     ;
1813
1814 XMLElementContent
1815     : XMLExpression XMLElementContentOpt
1816     | XMLMarkup XMLElementContentOpt
1817     | XMLText XMLElementContentOpt
1818     | XMLElement XMLElementContentOpt
1819     ;
1820
1821 XMLElementContentOpt
1822     : XMLElementContent
1823     |
1824     ;
1825 /* }}} */
1826 /* 11.1.5 XMLList Initialiser {{{ */
1827 XMLListInitialiser
1828     : "<>" LexPushInOff LexPushXMLContent XMLElementContent LexPop "</>" LexPopIn { $$ = CYNew CYXMLList($4); }
1829     ;
1830 /* }}} */
1831
1832 /* 11.2 Left-Hand-Side Expressions {{{ */
1833 PropertyIdentifier_
1834     : Identifier { $$ = $1; }
1835     | PropertyIdentifier { $$ = $1; }
1836     ;
1837
1838 MemberAccess
1839     : "." PropertyIdentifier { $$ = CYNew CYPropertyMember(NULL, $2); }
1840     | ".." PropertyIdentifier_ { $$ = CYNew CYDescendantMember(NULL, $2); }
1841     | "." "(" Expression ")" { $$ = CYNew CYFilteringPredicate(NULL, $3); }
1842     ;
1843 /* }}} */
1844 /* 12.1 The default xml namespace Statement {{{ */
1845 /* XXX: DefaultXMLNamespaceStatement
1846     : "default" "xml" "namespace" "=" Expression Terminator { $$ = CYNew CYDefaultXMLNamespace($5); }
1847     ;
1848
1849 Statement__
1850     : DefaultXMLNamespaceStatement { $$ = $1; }
1851     ; */
1852 /* }}} */
1853 @end
1854
1855 /* JavaScript 1.7: Array Comprehensions {{{ */
1856 IfComprehension
1857     : "if" "(" Expression ")" { $$ = CYNew CYIfComprehension($3); }
1858     ;
1859
1860 ForComprehension
1861     : "for" "(" Identifier "in" Expression ")" { $$ = CYNew CYForInComprehension($3, $5); }
1862     | "for" "each" "(" Identifier "in" Expression ")" { $$ = CYNew CYForOfComprehension($4, $6); }
1863     ;
1864
1865 ComprehensionList
1866     : ForComprehension ComprehensionListOpt { $1->SetNext($2); $$ = $1; }
1867     ;
1868
1869 ComprehensionListOpt
1870     : ComprehensionList { $$ = $1; }
1871     | IfComprehension { $$ = $1; }
1872     | { $$ = NULL; }
1873     ;
1874
1875 PrimaryExpression
1876     : "[" LexPushInOff AssignmentExpression ComprehensionList "]" LexPopIn { $$ = CYNew CYArrayComprehension($3, $4); }
1877     ;
1878 /* }}} */
1879 /* JavaScript 1.7: for each {{{ */
1880 IterationStatement
1881     : "for" "each" "(" LexPushInOn ForInStatementInitialiser "!in" LexPopIn Expression ")" Statement { $$ = CYNew CYForOf($5, $8, $10); }
1882     ;
1883 /* }}} */
1884 /* JavaScript 1.7: let Statements {{{ */
1885 LetStatement
1886     : "let" "(" VariableDeclarationList ")" Statement { $$ = CYNew CYLetStatement($3, $5); }
1887     ;
1888
1889 Statement__
1890     : LetStatement
1891     ;
1892 /* }}} */
1893
1894 /* JavaScript FTW: Ruby Blocks {{{ */
1895 RubyProcParameterList_
1896     : "," RubyProcParameterList { $$ = $2; }
1897     | { $$ = NULL; }
1898     ;
1899
1900 RubyProcParameterList
1901     : Identifier RubyProcParameterList_ { $$ = CYNew CYFunctionParameter(CYNew CYDeclaration($1), $2); }
1902     | { $$ = NULL; }
1903     ;
1904
1905 RubyProcParameters
1906     : "|" RubyProcParameterList "|" { $$ = $2; }
1907     | "||" { $$ = NULL; }
1908     ;
1909
1910 RubyProcParametersOpt
1911     : RubyProcParameters
1912     | { $$ = NULL; }
1913     ;
1914
1915 RubyProcExpression
1916     : "{" RubyProcParametersOpt StatementListOpt "}" { $$ = CYNew CYRubyProc($2, $3); }
1917     ;
1918
1919 PrimaryExpression
1920     : "{" LexPushInOff RubyProcParameters StatementListOpt "}" LexPopIn { $$ = CYNew CYRubyProc($3, $4); }
1921     ;
1922
1923 CallExpression
1924     : CallExpression_ RubyProcExpression { $$ = CYNew CYRubyBlock($1, $2); }
1925     ;
1926 /* }}} */
1927
1928 %%