ObjectiveC/Library.mm

   1 /* Cycript - Optimizing JavaScript Compiler/Runtime
   2  * Copyright (C) 2009-2015  Jay Freeman (saurik)
   3 */
   4
   5 /* GNU Affero General Public License, Version 3 {{{ */
   6 /*
   7  * This program is free software: you can redistribute it and/or modify
   8  * it under the terms of the GNU Affero General Public License as published by
   9  * the Free Software Foundation, either version 3 of the License, or
  10  * (at your option) any later version.
  11
  12  * This program is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU Affero General Public License for more details.
  16
  17  * You should have received a copy of the GNU Affero General Public License
  18  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 **/
  20 /* }}} */
  21
  22 #include "cycript.hpp"
  23
  24 #include "ObjectiveC/Internal.hpp"
  25
  26 #include <objc/message.h>
  27 #include <objc/runtime.h>
  28
  29 #include <Foundation/Foundation.h>
  30
  31 #ifdef __APPLE__
  32 #include <CoreFoundation/CoreFoundation.h>
  33 #include <JavaScriptCore/JSStringRefCF.h>
  34 #endif
  35
  36 #ifdef __APPLE__
  37 #include <malloc/malloc.h>
  38 #include <mach/mach.h>
  39 #endif
  40
  41 #include "Code.hpp"
  42 #include "Error.hpp"
  43 #include "JavaScript.hpp"
  44 #include "String.hpp"
  45 #include "Execute.hpp"
  46
  47 #include <cmath>
  48 #include <map>
  49 #include <set>
  50
  51 #include <dlfcn.h>
  52
  53 #define CYObjectiveTry_ { \
  54     try
  55 #define CYObjectiveTry { \
  56     JSContextRef context(context_); \
  57     try
  58 #define CYObjectiveCatch \
  59     catch (const CYException &error) { \
  60         @throw CYCastNSObject(NULL, context, error.CastJSValue(context)); \
  61     } \
  62 }
  63
  64 #define CYPoolTry { \
  65     id _saved(nil); \
  66     NSAutoreleasePool *_pool([[NSAutoreleasePool alloc] init]); \
  67     @try
  68 #define CYPoolCatch(value) \
  69     @catch (NSException *error) { \
  70         _saved = [error retain]; \
  71         throw CYJSError(context, CYCastJSValue(context, error)); \
  72         return value; \
  73     } @finally { \
  74         [_pool release]; \
  75         if (_saved != nil) \
  76             [_saved autorelease]; \
  77     } \
  78 }
  79
  80 #define CYSadTry { \
  81     @try
  82 #define CYSadCatch(value) \
  83     @catch (NSException *error ) { \
  84         throw CYJSError(context, CYCastJSValue(context, error)); \
  85     } return value; \
  86 }
  87
  88 #define _oassert(test) \
  89     if (!(test)) \
  90         @throw [NSException exceptionWithName:NSInternalInconsistencyException reason:@"_assert(" #test ")" userInfo:nil];
  91
  92 @class NSBlock;
  93
  94 struct BlockLiteral {
  95     Class isa;
  96     int flags;
  97     int reserved;
  98     void (*invoke)(void *, ...);
  99     void *descriptor;
 100 };
 101
 102 struct BlockDescriptor1 {
 103     unsigned long int reserved;
 104     unsigned long int size;
 105 };
 106
 107 struct BlockDescriptor2 {
 108     void (*copy_helper)(BlockLiteral *dst, BlockLiteral *src);
 109     void (*dispose_helper)(BlockLiteral *src);
 110 };
 111
 112 struct BlockDescriptor3 {
 113     const char *signature;
 114     const char *layout;
 115 };
 116
 117 enum {
 118     BLOCK_DEALLOCATING = 0x0001,
 119     BLOCK_REFCOUNT_MASK = 0xfffe,
 120     BLOCK_NEEDS_FREE = 1 << 24,
 121     BLOCK_HAS_COPY_DISPOSE = 1 << 25,
 122     BLOCK_HAS_CTOR = 1 << 26,
 123     BLOCK_IS_GC = 1 << 27,
 124     BLOCK_IS_GLOBAL = 1 << 28,
 125     BLOCK_HAS_STRET = 1 << 29,
 126     BLOCK_HAS_SIGNATURE = 1 << 30,
 127 };
 128
 129 JSValueRef CYSendMessage(CYPool &pool, JSContextRef context, id self, Class super, SEL _cmd, size_t count, const JSValueRef arguments[], bool initialize);
 130
 131 /* Objective-C Pool Release {{{ */
 132 void CYPoolRelease_(void *data) {
 133     id object(reinterpret_cast<id>(data));
 134     [object release];
 135 }
 136
 137 id CYPoolRelease_(CYPool *pool, id object) {
 138     if (object == nil)
 139         return nil;
 140     else if (pool == NULL)
 141         return [object autorelease];
 142     else {
 143         pool->atexit(CYPoolRelease_);
 144         return object;
 145     }
 146 }
 147
 148 template <typename Type_>
 149 Type_ CYPoolRelease(CYPool *pool, Type_ object) {
 150     return (Type_) CYPoolRelease_(pool, (id) object);
 151 }
 152 /* }}} */
 153 /* Objective-C Strings {{{ */
 154 const char *CYPoolCString(CYPool &pool, JSContextRef context, NSString *value) {
 155     size_t size([value maximumLengthOfBytesUsingEncoding:NSUTF8StringEncoding] + 1);
 156     char *string(new(pool) char[size]);
 157     if (![value getCString:string maxLength:size encoding:NSUTF8StringEncoding])
 158         throw CYJSError(context, "[NSString getCString:maxLength:encoding:] == NO");
 159     return string;
 160 }
 161
 162 #ifdef __APPLE__
 163 JSStringRef CYCopyJSString(JSContextRef context, NSString *value) {
 164     return JSStringCreateWithCFString(reinterpret_cast<CFStringRef>(value));
 165 }
 166 #endif
 167
 168 JSStringRef CYCopyJSString(JSContextRef context, NSObject *value) {
 169     if (value == nil)
 170         return NULL;
 171     // XXX: this definition scares me; is anyone using this?!
 172     NSString *string([value description]);
 173 #ifdef __APPLE__
 174     return CYCopyJSString(context, string);
 175 #else
 176     CYPool pool;
 177     return CYCopyJSString(CYPoolCString(pool, context, string));
 178 #endif
 179 }
 180
 181 NSString *CYCopyNSString(const CYUTF8String &value) {
 182 #ifdef __APPLE__
 183     return (NSString *) CFStringCreateWithBytes(kCFAllocatorDefault, reinterpret_cast<const UInt8 *>(value.data), value.size, kCFStringEncodingUTF8, true);
 184 #else
 185     return [[NSString alloc] initWithBytes:value.data length:value.size encoding:NSUTF8StringEncoding];
 186 #endif
 187 }
 188
 189 NSString *CYCopyNSString(JSContextRef context, JSStringRef value) {
 190 #ifdef __APPLE__
 191     return (NSString *) JSStringCopyCFString(kCFAllocatorDefault, value);
 192 #else
 193     CYPool pool;
 194     return CYCopyNSString(CYPoolUTF8String(pool, context, value));
 195 #endif
 196 }
 197
 198 NSString *CYCopyNSString(JSContextRef context, JSValueRef value) {
 199     return CYCopyNSString(context, CYJSString(context, value));
 200 }
 201
 202 NSString *CYCastNSString(CYPool *pool, const CYUTF8String &value) {
 203     return CYPoolRelease(pool, CYCopyNSString(value));
 204 }
 205
 206 NSString *CYCastNSString(CYPool *pool, SEL sel) {
 207     const char *name(sel_getName(sel));
 208     return CYPoolRelease(pool, CYCopyNSString(CYUTF8String(name, strlen(name))));
 209 }
 210
 211 NSString *CYCastNSString(CYPool *pool, JSContextRef context, JSStringRef value) {
 212     return CYPoolRelease(pool, CYCopyNSString(context, value));
 213 }
 214
 215 CYUTF8String CYCastUTF8String(NSString *value) {
 216     NSData *data([value dataUsingEncoding:NSUTF8StringEncoding allowLossyConversion:NO]);
 217     return CYUTF8String(reinterpret_cast<const char *>([data bytes]), [data length]);
 218 }
 219 /* }}} */
 220
 221 JSValueRef CYCastJSValue(JSContextRef context, NSObject *value);
 222
 223 void CYThrow(JSContextRef context, NSException *error, JSValueRef *exception) {
 224     if (exception == NULL)
 225         throw error;
 226     *exception = CYCastJSValue(context, error);
 227 }
 228
 229 size_t CYGetIndex(NSString *value) {
 230     return CYGetIndex(CYCastUTF8String(value));
 231 }
 232
 233 bool CYGetOffset(CYPool &pool, JSContextRef context, NSString *value, ssize_t &index) {
 234     return CYGetOffset(CYPoolCString(pool, context, value), index);
 235 }
 236
 237 static JSClassRef Instance_;
 238
 239 static JSClassRef ArrayInstance_;
 240 static JSClassRef BooleanInstance_;
 241 static JSClassRef FunctionInstance_;
 242 static JSClassRef NumberInstance_;
 243 static JSClassRef ObjectInstance_;
 244 static JSClassRef StringInstance_;
 245
 246 static JSClassRef Class_;
 247 static JSClassRef Internal_;
 248 static JSClassRef Message_;
 249 static JSClassRef Messages_;
 250 static JSClassRef Selector_;
 251 static JSClassRef Super_;
 252
 253 static JSClassRef ObjectiveC_Classes_;
 254 static JSClassRef ObjectiveC_Constants_;
 255 static JSClassRef ObjectiveC_Protocols_;
 256
 257 #ifdef __APPLE__
 258 static JSClassRef ObjectiveC_Image_Classes_;
 259 static JSClassRef ObjectiveC_Images_;
 260 #endif
 261
 262 #ifdef __APPLE__
 263 static Class __NSMallocBlock__;
 264 static Class NSCFBoolean_;
 265 static Class NSCFType_;
 266 static Class NSGenericDeallocHandler_;
 267 #else
 268 static Class NSBoolNumber_;
 269 #endif
 270
 271 static Class NSArray_;
 272 static Class NSBlock_;
 273 static Class NSDictionary_;
 274 static Class NSNumber_;
 275 static Class NSString_;
 276 static Class NSZombie_;
 277 static Class Object_;
 278
 279 static Type_privateData *Object_type;
 280 static Type_privateData *Selector_type;
 281
 282 Type_privateData *Instance::GetType() const {
 283     return Object_type;
 284 }
 285
 286 Type_privateData *Selector_privateData::GetType() const {
 287     return Selector_type;
 288 }
 289
 290 static JSValueRef Instance_callAsFunction_toString(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception);
 291
 292 JSValueRef CYGetClassPrototype(JSContextRef context, Class self, bool meta) {
 293     if (self == nil)
 294         return CYGetCachedObject(context, CYJSString("Instance_prototype"));
 295     else if (meta && !class_isMetaClass(self))
 296         return CYGetCachedObject(context, CYJSString("Class_prototype"));
 297
 298     JSObjectRef global(CYGetGlobalObject(context));
 299     JSObjectRef cy(CYCastJSObject(context, CYGetProperty(context, global, cy_s)));
 300
 301     char label[32];
 302     sprintf(label, "i%p", self);
 303     CYJSString name(label);
 304
 305     JSValueRef value(CYGetProperty(context, cy, name));
 306     if (!JSValueIsUndefined(context, value))
 307         return value;
 308
 309     JSClassRef _class(NULL);
 310     JSValueRef prototype;
 311
 312 #ifdef __APPLE__
 313     if (self == NSCFBoolean_)
 314 #else
 315     if (self == NSBoolNumber_)
 316 #endif
 317         prototype = CYGetCachedObject(context, CYJSString("BooleanInstance_prototype"));
 318     else if (self == NSArray_)
 319         prototype = CYGetCachedObject(context, CYJSString("ArrayInstance_prototype"));
 320     else if (self == NSBlock_)
 321         prototype = CYGetCachedObject(context, CYJSString("FunctionInstance_prototype"));
 322     else if (self == NSNumber_)
 323         prototype = CYGetCachedObject(context, CYJSString("NumberInstance_prototype"));
 324     else if (self == NSDictionary_)
 325         prototype = CYGetCachedObject(context, CYJSString("ObjectInstance_prototype"));
 326     else if (self == NSString_)
 327         prototype = CYGetCachedObject(context, CYJSString("StringInstance_prototype"));
 328     else
 329         prototype = CYGetClassPrototype(context, class_getSuperclass(self), meta);
 330
 331     JSObjectRef object(JSObjectMake(context, _class, NULL));
 332     CYSetPrototype(context, object, prototype);
 333     CYSetProperty(context, cy, name, object);
 334
 335     return object;
 336 }
 337
 338 _finline JSValueRef CYGetClassPrototype(JSContextRef context, Class self) {
 339     return CYGetClassPrototype(context, self, class_isMetaClass(self));
 340 }
 341
 342 JSObjectRef Messages::Make(JSContextRef context, Class _class) {
 343     JSObjectRef value(JSObjectMake(context, Messages_, new Messages(_class)));
 344     if (Class super = class_getSuperclass(_class))
 345         CYSetPrototype(context, value, Messages::Make(context, super));
 346     return value;
 347 }
 348
 349 JSObjectRef Internal::Make(JSContextRef context, id object, JSObjectRef owner) {
 350     return JSObjectMake(context, Internal_, new Internal(object, context, owner));
 351 }
 352
 353 namespace cy {
 354 JSObjectRef Super::Make(JSContextRef context, id object, Class _class) {
 355     JSObjectRef value(JSObjectMake(context, Super_, new Super(object, _class)));
 356     return value;
 357 } }
 358
 359 bool CYIsKindOfClass(id object, Class _class) {
 360     for (Class isa(object_getClass(object)); isa != NULL; isa = class_getSuperclass(isa))
 361         if (isa == _class)
 362             return true;
 363     return false;
 364 }
 365
 366 JSObjectRef Instance::Make(JSContextRef context, id object, Flags flags) {
 367     JSObjectRef value(JSObjectMake(context, CYIsKindOfClass(object, NSBlock_) ? FunctionInstance_ : Instance_, new Instance(object, flags)));
 368     CYSetPrototype(context, value, CYGetClassPrototype(context, object_getClass(object)));
 369     return value;
 370 }
 371
 372 Instance::~Instance() {
 373     if ((flags_ & Permanent) == 0)
 374         [GetValue() release];
 375 }
 376
 377 struct Message_privateData :
 378     cy::Functor
 379 {
 380     SEL sel_;
 381
 382     Message_privateData(SEL sel, const char *type, IMP value = NULL) :
 383         cy::Functor(type, reinterpret_cast<void (*)()>(value)),
 384         sel_(sel)
 385     {
 386     }
 387 };
 388
 389 JSObjectRef CYMakeInstance(JSContextRef context, id object, Instance::Flags flags = Instance::None) {
 390     _assert(object != nil);
 391
 392 #ifdef __APPLE__
 393     JSWeakObjectMapRef weak(CYCastPointer<JSWeakObjectMapRef>(context, CYGetCachedValue(context, weak_s)));
 394
 395     if (weak != NULL && &JSWeakObjectMapGet != NULL)
 396         if (JSObjectRef instance = JSWeakObjectMapGet(context, weak, object))
 397             return instance;
 398 #endif
 399
 400     if ((flags & Instance::Permanent) == 0)
 401         object = [object retain];
 402
 403     JSObjectRef instance(Instance::Make(context, object, flags));
 404
 405 #ifdef __APPLE__
 406     if (weak != NULL && &JSWeakObjectMapSet != NULL)
 407         JSWeakObjectMapSet(context, weak, object, instance);
 408 #endif
 409
 410     return instance;
 411 }
 412
 413 @interface NSMethodSignature (Cycript)
 414 - (NSString *) _typeString;
 415 @end
 416
 417 @interface NSObject (Cycript)
 418
 419 - (JSValueRef) cy$valueOfInContext:(JSContextRef)context;
 420 - (JSType) cy$JSType;
 421
 422 - (JSValueRef) cy$toJSON:(NSString *)key inContext:(JSContextRef)context;
 423 - (NSString *) cy$toCYON:(bool)objective inSet:(std::set<void *> &)objects;
 424
 425 - (bool) cy$hasProperty:(NSString *)name;
 426 - (NSObject *) cy$getProperty:(NSString *)name;
 427 - (JSValueRef) cy$getProperty:(NSString *)name inContext:(JSContextRef)context;
 428 - (bool) cy$setProperty:(NSString *)name to:(NSObject *)value;
 429 - (bool) cy$deleteProperty:(NSString *)name;
 430 - (void) cy$getPropertyNames:(JSPropertyNameAccumulatorRef)names inContext:(JSContextRef)context;
 431
 432 + (bool) cy$hasImplicitProperties;
 433
 434 @end
 435
 436 @protocol Cycript
 437 - (id) cy$box;
 438 - (JSValueRef) cy$valueOfInContext:(JSContextRef)context;
 439 @end
 440
 441 NSString *CYCastNSCYON(id value, bool objective, std::set<void *> &objects) {
 442     _assert(value != nil);
 443
 444     Class _class(object_getClass(value));
 445
 446     if (class_isMetaClass(_class)) {
 447         const char *name(class_getName(value));
 448         if (class_isMetaClass(value))
 449             return [NSString stringWithFormat:@"object_getClass(%s)", name];
 450         else
 451             return [NSString stringWithUTF8String:name];
 452     }
 453
 454     if (_class == NSZombie_)
 455         return [NSString stringWithFormat:@"<_NSZombie_: %p>", value];
 456
 457     SEL sel(@selector(cy$toCYON:inSet:));
 458
 459     if (objc_method *toCYON = class_getInstanceMethod(_class, sel))
 460         return reinterpret_cast<NSString *(*)(id, SEL, bool, std::set<void *> &)>(method_getImplementation(toCYON))(value, sel, objective, objects);
 461     else if (objc_method *methodSignatureForSelector = class_getInstanceMethod(_class, @selector(methodSignatureForSelector:)))
 462         if (reinterpret_cast<NSMethodSignature *(*)(id, SEL, SEL)>(method_getImplementation(methodSignatureForSelector))(value, @selector(methodSignatureForSelector:), sel) != nil)
 463             return [value cy$toCYON:objective inSet:objects];
 464
 465     return [NSString stringWithFormat:@"%@", value];
 466 }
 467
 468 NSString *CYCastNSCYON(id value, bool objective, std::set<void *> *objects) {
 469     if (objects != NULL)
 470         return CYCastNSCYON(value, objective, *objects);
 471     else {
 472         std::set<void *> objects;
 473         return CYCastNSCYON(value, objective, objects);
 474     }
 475 }
 476
 477 struct PropertyAttributes {
 478     CYPool pool_;
 479
 480     const char *name;
 481
 482     const char *variable;
 483
 484     const char *getter_;
 485     const char *setter_;
 486
 487     bool readonly;
 488     bool copy;
 489     bool retain;
 490     bool nonatomic;
 491     bool dynamic;
 492     bool weak;
 493     bool garbage;
 494
 495     PropertyAttributes(objc_property_t property) :
 496         variable(NULL),
 497         getter_(NULL),
 498         setter_(NULL),
 499         readonly(false),
 500         copy(false),
 501         retain(false),
 502         nonatomic(false),
 503         dynamic(false),
 504         weak(false),
 505         garbage(false)
 506     {
 507         name = property_getName(property);
 508         const char *attributes(property_getAttributes(property));
 509
 510         for (char *token(pool_.strdup(attributes)), *next; token != NULL; token = next) {
 511             if ((next = strchr(token, ',')) != NULL)
 512                 *next++ = '\0';
 513             switch (*token) {
 514                 case 'R': readonly = true; break;
 515                 case 'C': copy = true; break;
 516                 case '&': retain = true; break;
 517                 case 'N': nonatomic = true; break;
 518                 case 'G': getter_ = token + 1; break;
 519                 case 'S': setter_ = token + 1; break;
 520                 case 'V': variable = token + 1; break;
 521             }
 522         }
 523
 524         /*if (variable == NULL) {
 525             variable = property_getName(property);
 526             size_t size(strlen(variable));
 527             char *name(new(pool_) char[size + 2]);
 528             name[0] = '_';
 529             memcpy(name + 1, variable, size);
 530             name[size + 1] = '\0';
 531             variable = name;
 532         }*/
 533     }
 534
 535     const char *Getter() {
 536         if (getter_ == NULL)
 537             getter_ = pool_.strdup(name);
 538         return getter_;
 539     }
 540
 541     const char *Setter() {
 542         if (setter_ == NULL && !readonly) {
 543             size_t length(strlen(name));
 544
 545             char *temp(new(pool_) char[length + 5]);
 546             temp[0] = 's';
 547             temp[1] = 'e';
 548             temp[2] = 't';
 549
 550             if (length != 0) {
 551                 temp[3] = toupper(name[0]);
 552                 memcpy(temp + 4, name + 1, length - 1);
 553             }
 554
 555             temp[length + 3] = ':';
 556             temp[length + 4] = '\0';
 557             setter_ = temp;
 558         }
 559
 560         return setter_;
 561     }
 562
 563 };
 564
 565 @interface CYWebUndefined : NSObject {
 566 }
 567
 568 + (CYWebUndefined *) undefined;
 569
 570 @end
 571
 572 @implementation CYWebUndefined
 573
 574 + (CYWebUndefined *) undefined {
 575     static CYWebUndefined *instance_([[CYWebUndefined alloc] init]);
 576     return instance_;
 577 }
 578
 579 @end
 580
 581 #define WebUndefined CYWebUndefined
 582
 583 /* Bridge: CYJSObject {{{ */
 584 @interface CYJSObject : NSMutableDictionary {
 585     JSObjectRef object_;
 586     JSGlobalContextRef context_;
 587 }
 588
 589 - (id) initWithJSObject:(JSObjectRef)object inContext:(JSContextRef)context;
 590
 591 - (NSUInteger) count;
 592 - (id) objectForKey:(id)key;
 593 - (NSEnumerator *) keyEnumerator;
 594 - (void) setObject:(id)object forKey:(id)key;
 595 - (void) removeObjectForKey:(id)key;
 596
 597 @end
 598 /* }}} */
 599 /* Bridge: CYJSArray {{{ */
 600 @interface CYJSArray : NSMutableArray {
 601     JSObjectRef object_;
 602     JSGlobalContextRef context_;
 603 }
 604
 605 - (id) initWithJSObject:(JSObjectRef)object inContext:(JSContextRef)context;
 606
 607 - (NSUInteger) count;
 608 - (id) objectAtIndex:(NSUInteger)index;
 609
 610 - (void) addObject:(id)anObject;
 611 - (void) insertObject:(id)anObject atIndex:(NSUInteger)index;
 612 - (void) removeLastObject;
 613 - (void) removeObjectAtIndex:(NSUInteger)index;
 614 - (void) replaceObjectAtIndex:(NSUInteger)index withObject:(id)anObject;
 615
 616 @end
 617 /* }}} */
 618
 619 _finline bool CYJSValueIsNSObject(JSContextRef context, JSValueRef value) {
 620     return JSValueIsObjectOfClass(context, value, Instance_) || JSValueIsObjectOfClass(context, value, FunctionInstance_);
 621 }
 622
 623 _finline bool CYJSValueIsInstanceOfCachedConstructor(JSContextRef context, JSValueRef value, JSStringRef cache) {
 624     return _jsccall(JSValueIsInstanceOfConstructor, context, value, CYGetCachedObject(context, cache));
 625 }
 626
 627 #ifdef __APPLE__
 628 struct CYBlockDescriptor {
 629     struct {
 630         BlockDescriptor1 one_;
 631         BlockDescriptor2 two_;
 632         BlockDescriptor3 three_;
 633     } d_;
 634
 635     Closure_privateData *internal_;
 636 };
 637
 638 void CYDisposeBlock(BlockLiteral *literal) {
 639     delete reinterpret_cast<CYBlockDescriptor *>(literal->descriptor)->internal_;
 640 }
 641
 642 static JSValueRef BlockAdapter_(JSContextRef context, size_t count, JSValueRef values[], JSObjectRef function) {
 643     JSObjectRef _this(CYCastJSObject(context, values[0]));
 644     return CYCallAsFunction(context, function, _this, count - 1, values + 1);
 645 }
 646
 647 static void BlockClosure_(ffi_cif *cif, void *result, void **arguments, void *arg) {
 648     CYExecuteClosure(cif, result, arguments, arg, &BlockAdapter_);
 649 }
 650
 651 NSBlock *CYMakeBlock(JSContextRef context, JSObjectRef function, sig::Signature &signature) {
 652     _assert(__NSMallocBlock__ != Nil);
 653     BlockLiteral *literal(reinterpret_cast<BlockLiteral *>(malloc(sizeof(BlockLiteral))));
 654
 655     CYBlockDescriptor *descriptor(new CYBlockDescriptor);
 656     memset(&descriptor->d_, 0, sizeof(descriptor->d_));
 657
 658     descriptor->internal_ = CYMakeFunctor_(context, function, signature, &BlockClosure_);
 659     literal->invoke = reinterpret_cast<void (*)(void *, ...)>(descriptor->internal_->GetValue());
 660
 661     literal->isa = __NSMallocBlock__;
 662     literal->flags = BLOCK_HAS_SIGNATURE | BLOCK_HAS_COPY_DISPOSE | BLOCK_IS_GLOBAL;
 663     literal->reserved = 0;
 664     literal->descriptor = descriptor;
 665
 666     descriptor->d_.one_.size = sizeof(descriptor->d_);
 667     descriptor->d_.two_.dispose_helper = &CYDisposeBlock;
 668     descriptor->d_.three_.signature = sig::Unparse(*descriptor->internal_->pool_, &signature);
 669
 670     return reinterpret_cast<NSBlock *>(literal);
 671 }
 672 #endif
 673
 674 NSObject *CYCastNSObject(CYPool *pool, JSContextRef context, JSObjectRef object) {
 675     if (CYJSValueIsNSObject(context, object)) {
 676         Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
 677         return internal->GetValue();
 678     }
 679
 680     bool array(CYJSValueIsInstanceOfCachedConstructor(context, object, Array_s));
 681     id value(array ? [CYJSArray alloc] : [CYJSObject alloc]);
 682     return CYPoolRelease(pool, [value initWithJSObject:object inContext:context]);
 683 }
 684
 685 NSNumber *CYCopyNSNumber(JSContextRef context, JSValueRef value) {
 686     return [[NSNumber alloc] initWithDouble:CYCastDouble(context, value)];
 687 }
 688
 689 #ifndef __APPLE__
 690 @interface NSBoolNumber : NSNumber {
 691 }
 692 @end
 693 #endif
 694
 695 id CYNSObject(CYPool *pool, JSContextRef context, JSValueRef value, bool cast) {
 696     id object;
 697     bool copy;
 698
 699     switch (JSType type = JSValueGetType(context, value)) {
 700         case kJSTypeUndefined:
 701             object = [WebUndefined undefined];
 702             copy = false;
 703         break;
 704
 705         case kJSTypeNull:
 706             return NULL;
 707         break;
 708
 709         case kJSTypeBoolean:
 710 #ifdef __APPLE__
 711             object = (id) (CYCastBool(context, value) ? kCFBooleanTrue : kCFBooleanFalse);
 712             copy = false;
 713 #else
 714             object = [[NSBoolNumber alloc] initWithBool:CYCastBool(context, value)];
 715             copy = true;
 716 #endif
 717         break;
 718
 719         case kJSTypeNumber:
 720             object = CYCopyNSNumber(context, value);
 721             copy = true;
 722         break;
 723
 724         case kJSTypeString:
 725             object = CYCopyNSString(context, value);
 726             copy = true;
 727         break;
 728
 729         case kJSTypeObject:
 730             // XXX: this might could be more efficient
 731             object = CYCastNSObject(pool, context, (JSObjectRef) value);
 732             copy = false;
 733         break;
 734
 735         default:
 736             throw CYJSError(context, "JSValueGetType() == 0x%x", type);
 737         break;
 738     }
 739
 740     if (cast != copy)
 741         return object;
 742     else if (copy)
 743         return CYPoolRelease(pool, object);
 744     else
 745         return [object retain];
 746 }
 747
 748 NSObject *CYCastNSObject(CYPool *pool, JSContextRef context, JSValueRef value) {
 749     return CYNSObject(pool, context, value, true);
 750 }
 751
 752 NSObject *CYCopyNSObject(CYPool &pool, JSContextRef context, JSValueRef value) {
 753     return CYNSObject(&pool, context, value, false);
 754 }
 755
 756 /* Bridge: NSArray {{{ */
 757 @implementation NSArray (Cycript)
 758
 759 - (id) cy$box {
 760     return [[self mutableCopy] autorelease];
 761 }
 762
 763 - (NSString *) cy$toCYON:(bool)objective inSet:(std::set<void *> &)objects {
 764     _oassert(objects.insert(self).second);
 765
 766     NSMutableString *json([[[NSMutableString alloc] init] autorelease]);
 767     [json appendString:@"@["];
 768
 769     bool comma(false);
 770 #ifdef __APPLE__
 771     for (id object in self) {
 772 #else
 773     for (size_t index(0), count([self count]); index != count; ++index) {
 774         id object([self objectAtIndex:index]);
 775 #endif
 776         if (comma)
 777             [json appendString:@","];
 778         else
 779             comma = true;
 780         if (object != nil && [object cy$JSType] != kJSTypeUndefined)
 781             [json appendString:CYCastNSCYON(object, true, objects)];
 782         else {
 783             [json appendString:@","];
 784             comma = false;
 785         }
 786     }
 787
 788     [json appendString:@"]"];
 789     return json;
 790 }
 791
 792 - (bool) cy$hasProperty:(NSString *)name {
 793     if ([name isEqualToString:@"length"])
 794         return true;
 795
 796     size_t index(CYGetIndex(name));
 797     if (index == _not(size_t) || index >= [self count])
 798         return [super cy$hasProperty:name];
 799     else
 800         return true;
 801 }
 802
 803 - (NSObject *) cy$getProperty:(NSString *)name {
 804     size_t index(CYGetIndex(name));
 805     if (index == _not(size_t) || index >= [self count])
 806         return [super cy$getProperty:name];
 807     else
 808         return [self objectAtIndex:index];
 809 }
 810
 811 - (JSValueRef) cy$getProperty:(NSString *)name inContext:(JSContextRef)context {
 812     CYObjectiveTry_ {
 813         if ([name isEqualToString:@"length"])
 814             return CYCastJSValue(context, [self count]);
 815     } CYObjectiveCatch
 816
 817     return [super cy$getProperty:name inContext:context];
 818 }
 819
 820 - (void) cy$getPropertyNames:(JSPropertyNameAccumulatorRef)names inContext:(JSContextRef)context {
 821     [super cy$getPropertyNames:names inContext:context];
 822
 823     for (size_t index(0), count([self count]); index != count; ++index) {
 824         id object([self objectAtIndex:index]);
 825         if (object == nil || [object cy$JSType] != kJSTypeUndefined) {
 826             char name[32];
 827             sprintf(name, "%zu", index);
 828             JSPropertyNameAccumulatorAddName(names, CYJSString(name));
 829         }
 830     }
 831 }
 832
 833 + (bool) cy$hasImplicitProperties {
 834     return false;
 835 }
 836
 837 @end
 838 /* }}} */
 839 /* Bridge: NSBlock {{{ */
 840 #ifdef __APPLE__
 841 @interface NSBlock
 842 - (void) invoke;
 843 @end
 844 #endif
 845 /* }}} */
 846 /* Bridge: NSBoolNumber {{{ */
 847 #ifndef __APPLE__
 848 @implementation NSBoolNumber (Cycript)
 849
 850 - (JSType) cy$JSType {
 851     return kJSTypeBoolean;
 852 }
 853
 854 - (NSString *) cy$toCYON:(bool)objective inSet:(std::set<void *> &)objects {
 855     NSString *value([self boolValue] ? @"true" : @"false");
 856     return objective ? value : [NSString stringWithFormat:@"@%@", value];
 857 }
 858
 859 - (JSValueRef) cy$valueOfInContext:(JSContextRef)context { CYObjectiveTry_ {
 860     return CYCastJSValue(context, (bool) [self boolValue]);
 861 } CYObjectiveCatch }
 862
 863 @end
 864 #endif
 865 /* }}} */
 866 /* Bridge: NSDictionary {{{ */
 867 @implementation NSDictionary (Cycript)
 868
 869 - (id) cy$box {
 870     return [[self mutableCopy] autorelease];
 871 }
 872
 873 - (NSString *) cy$toCYON:(bool)objective inSet:(std::set<void *> &)objects {
 874     _oassert(objects.insert(self).second);
 875
 876     NSMutableString *json([[[NSMutableString alloc] init] autorelease]);
 877     [json appendString:@"@{"];
 878
 879     bool comma(false);
 880 #ifdef __APPLE__
 881     for (NSObject *key in self) {
 882 #else
 883     NSEnumerator *keys([self keyEnumerator]);
 884     while (NSObject *key = [keys nextObject]) {
 885 #endif
 886         if (comma)
 887             [json appendString:@","];
 888         else
 889             comma = true;
 890         [json appendString:CYCastNSCYON(key, true, objects)];
 891         [json appendString:@":"];
 892         NSObject *object([self objectForKey:key]);
 893         [json appendString:CYCastNSCYON(object, true, objects)];
 894     }
 895
 896     [json appendString:@"}"];
 897     return json;
 898 }
 899
 900 - (bool) cy$hasProperty:(NSString *)name {
 901     return [self objectForKey:name] != nil;
 902 }
 903
 904 - (NSObject *) cy$getProperty:(NSString *)name {
 905     return [self objectForKey:name];
 906 }
 907
 908 - (void) cy$getPropertyNames:(JSPropertyNameAccumulatorRef)names inContext:(JSContextRef)context {
 909     [super cy$getPropertyNames:names inContext:context];
 910
 911 #ifdef __APPLE__
 912     for (NSObject *key in self) {
 913 #else
 914     NSEnumerator *keys([self keyEnumerator]);
 915     while (NSObject *key = [keys nextObject]) {
 916 #endif
 917         JSPropertyNameAccumulatorAddName(names, CYJSString(context, key));
 918     }
 919 }
 920
 921 + (bool) cy$hasImplicitProperties {
 922     return false;
 923 }
 924
 925 @end
 926 /* }}} */
 927 /* Bridge: NSMutableArray {{{ */
 928 @implementation NSMutableArray (Cycript)
 929
 930 - (bool) cy$setProperty:(NSString *)name to:(NSObject *)value {
 931     if ([name isEqualToString:@"length"]) {
 932         // XXX: is this not intelligent?
 933         NSNumber *number(reinterpret_cast<NSNumber *>(value));
 934         NSUInteger size([number unsignedIntegerValue]);
 935         NSUInteger count([self count]);
 936         if (size < count)
 937             [self removeObjectsInRange:NSMakeRange(size, count - size)];
 938         else if (size != count) {
 939             WebUndefined *undefined([WebUndefined undefined]);
 940             for (size_t i(count); i != size; ++i)
 941                 [self addObject:undefined];
 942         }
 943         return true;
 944     }
 945
 946     size_t index(CYGetIndex(name));
 947     if (index == _not(size_t))
 948         return [super cy$setProperty:name to:value];
 949
 950     id object(value ?: [NSNull null]);
 951
 952     size_t count([self count]);
 953     if (index < count)
 954         [self replaceObjectAtIndex:index withObject:object];
 955     else {
 956         if (index != count) {
 957             WebUndefined *undefined([WebUndefined undefined]);
 958             for (size_t i(count); i != index; ++i)
 959                 [self addObject:undefined];
 960         }
 961
 962         [self addObject:object];
 963     }
 964
 965     return true;
 966 }
 967
 968 - (bool) cy$deleteProperty:(NSString *)name {
 969     size_t index(CYGetIndex(name));
 970     if (index == _not(size_t) || index >= [self count])
 971         return [super cy$deleteProperty:name];
 972     [self replaceObjectAtIndex:index withObject:[WebUndefined undefined]];
 973     return true;
 974 }
 975
 976 @end
 977 /* }}} */
 978 /* Bridge: NSMutableDictionary {{{ */
 979 @implementation NSMutableDictionary (Cycript)
 980
 981 - (bool) cy$setProperty:(NSString *)name to:(NSObject *)value {
 982     [self setObject:(value ?: [NSNull null]) forKey:name];
 983     return true;
 984 }
 985
 986 - (bool) cy$deleteProperty:(NSString *)name {
 987     if ([self objectForKey:name] == nil)
 988         return false;
 989     else {
 990         [self removeObjectForKey:name];
 991         return true;
 992     }
 993 }
 994
 995 @end
 996 /* }}} */
 997 /* Bridge: NSNumber {{{ */
 998 @implementation NSNumber (Cycript)
 999
1000 - (JSType) cy$JSType {
1001 #ifdef __APPLE__
1002     // XXX: this just seems stupid
1003     if ([self class] == NSCFBoolean_)
1004         return kJSTypeBoolean;
1005 #endif
1006     return kJSTypeNumber;
1007 }
1008
1009 - (NSString *) cy$toCYON:(bool)objective inSet:(std::set<void *> &)objects {
1010     NSString *value([self cy$JSType] != kJSTypeBoolean ? [self stringValue] : [self boolValue] ? @"true" : @"false");
1011     return objective ? value : [NSString stringWithFormat:@"@%@", value];
1012 }
1013
1014 - (JSValueRef) cy$valueOfInContext:(JSContextRef)context { CYObjectiveTry_ {
1015     return [self cy$JSType] != kJSTypeBoolean ? CYCastJSValue(context, [self doubleValue]) : CYCastJSValue(context, static_cast<bool>([self boolValue]));
1016 } CYObjectiveCatch }
1017
1018 @end
1019 /* }}} */
1020 /* Bridge: NSNull {{{ */
1021 @implementation NSNull (Cycript)
1022
1023 - (JSType) cy$JSType {
1024     return kJSTypeNull;
1025 }
1026
1027 - (NSString *) cy$toCYON:(bool)objective inSet:(std::set<void *> &)objects {
1028     NSString *value(@"null");
1029     return objective ? value : [NSString stringWithFormat:@"@%@", value];
1030 }
1031
1032 - (JSValueRef) cy$valueOfInContext:(JSContextRef)context { CYObjectiveTry_ {
1033     return CYJSNull(context);
1034 } CYObjectiveCatch }
1035
1036 @end
1037 /* }}} */
1038 /* Bridge: NSObject {{{ */
1039 @implementation NSObject (Cycript)
1040
1041 - (id) cy$box {
1042     return self;
1043 }
1044
1045 - (JSValueRef) cy$toJSON:(NSString *)key inContext:(JSContextRef)context {
1046     return [self cy$valueOfInContext:context];
1047 }
1048
1049 - (JSValueRef) cy$valueOfInContext:(JSContextRef)context { CYObjectiveTry_ {
1050     return NULL;
1051 } CYObjectiveCatch }
1052
1053 - (JSType) cy$JSType {
1054     return kJSTypeObject;
1055 }
1056
1057 - (NSString *) cy$toCYON:(bool)objective inSet:(std::set<void *> &)objects {
1058     return [@"#" stringByAppendingString:[[self description] cy$toCYON:true inSet:objects]];
1059 }
1060
1061 - (bool) cy$hasProperty:(NSString *)name {
1062     return false;
1063 }
1064
1065 - (NSObject *) cy$getProperty:(NSString *)name {
1066     return nil;
1067 }
1068
1069 - (JSValueRef) cy$getProperty:(NSString *)name inContext:(JSContextRef)context { CYObjectiveTry_ {
1070     if (NSObject *value = [self cy$getProperty:name])
1071         return CYCastJSValue(context, value);
1072     return NULL;
1073 } CYObjectiveCatch }
1074
1075 - (bool) cy$setProperty:(NSString *)name to:(NSObject *)value {
1076     return false;
1077 }
1078
1079 - (bool) cy$deleteProperty:(NSString *)name {
1080     return false;
1081 }
1082
1083 - (void) cy$getPropertyNames:(JSPropertyNameAccumulatorRef)names inContext:(JSContextRef)context {
1084 }
1085
1086 + (bool) cy$hasImplicitProperties {
1087     return true;
1088 }
1089
1090 @end
1091 /* }}} */
1092 /* Bridge: NSProxy {{{ */
1093 @implementation NSProxy (Cycript)
1094
1095 - (NSString *) cy$toCYON:(bool)objective inSet:(std::set<void *> &)objects {
1096     return [[self description] cy$toCYON:objective inSet:objects];
1097 }
1098
1099 @end
1100 /* }}} */
1101 /* Bridge: NSSet {{{ */
1102 @implementation NSSet (Cycript)
1103
1104 - (NSString *) cy$toCYON:(bool)objective inSet:(std::set<void *> &)objects {
1105     _oassert(objects.insert(self).second);
1106
1107     NSMutableString *json([[[NSMutableString alloc] init] autorelease]);
1108     [json appendString:@"[NSSet setWithArray:"];
1109     [json appendString:CYCastNSCYON([self allObjects], true, objects)];
1110     [json appendString:@"]]"];
1111     return json;
1112 }
1113
1114 @end
1115 /* }}} */
1116 /* Bridge: NSString {{{ */
1117 @implementation NSString (Cycript)
1118
1119 - (id) cy$box {
1120     return [[self copy] autorelease];
1121 }
1122
1123 - (JSType) cy$JSType {
1124     return kJSTypeString;
1125 }
1126
1127 - (NSString *) cy$toCYON:(bool)objective inSet:(std::set<void *> &)objects {
1128     std::ostringstream str;
1129     if (!objective)
1130         str << '@';
1131     CYUTF8String string(CYCastUTF8String(self));
1132     CYStringify(str, string.data, string.size);
1133     std::string value(str.str());
1134     return CYCastNSString(NULL, CYUTF8String(value.c_str(), value.size()));
1135 }
1136
1137 - (bool) cy$hasProperty:(NSString *)name {
1138     size_t index(CYGetIndex(name));
1139     if (index == _not(size_t) || index >= [self length])
1140         return [super cy$hasProperty:name];
1141     else
1142         return true;
1143 }
1144
1145 - (NSObject *) cy$getProperty:(NSString *)name {
1146     size_t index(CYGetIndex(name));
1147     if (index == _not(size_t) || index >= [self length])
1148         return [super cy$getProperty:name];
1149     else
1150         return [self substringWithRange:NSMakeRange(index, 1)];
1151 }
1152
1153 - (void) cy$getPropertyNames:(JSPropertyNameAccumulatorRef)names inContext:(JSContextRef)context {
1154     [super cy$getPropertyNames:names inContext:context];
1155
1156     for (size_t index(0), length([self length]); index != length; ++index) {
1157         char name[32];
1158         sprintf(name, "%zu", index);
1159         JSPropertyNameAccumulatorAddName(names, CYJSString(name));
1160     }
1161 }
1162
1163 - (JSValueRef) cy$valueOfInContext:(JSContextRef)context { CYObjectiveTry_ {
1164     return CYCastJSValue(context, CYJSString(context, self));
1165 } CYObjectiveCatch }
1166
1167 @end
1168 /* }}} */
1169 /* Bridge: WebUndefined {{{ */
1170 @implementation WebUndefined (Cycript)
1171
1172 - (JSType) cy$JSType {
1173     return kJSTypeUndefined;
1174 }
1175
1176 - (NSString *) cy$toCYON:(bool)objective inSet:(std::set<void *> &)objects {
1177     NSString *value(@"undefined");
1178     return value; // XXX: maybe use the below code, adding @undefined?
1179     //return objective ? value : [NSString stringWithFormat:@"@%@", value];
1180 }
1181
1182 - (JSValueRef) cy$valueOfInContext:(JSContextRef)context { CYObjectiveTry_ {
1183     return CYJSUndefined(context);
1184 } CYObjectiveCatch }
1185
1186 @end
1187 /* }}} */
1188
1189 static bool CYIsClass(id self) {
1190     return class_isMetaClass(object_getClass(self));
1191 }
1192
1193 Class CYCastClass(CYPool &pool, JSContextRef context, JSValueRef value) {
1194     id self(CYCastNSObject(&pool, context, value));
1195     if (CYIsClass(self))
1196         return (Class) self;
1197     throw CYJSError(context, "got something that is not a Class");
1198     return NULL;
1199 }
1200
1201 NSArray *CYCastNSArray(JSContextRef context, JSPropertyNameArrayRef names) {
1202     CYPool pool;
1203     size_t size(JSPropertyNameArrayGetCount(names));
1204     NSMutableArray *array([NSMutableArray arrayWithCapacity:size]);
1205     for (size_t index(0); index != size; ++index)
1206         [array addObject:CYCastNSString(&pool, context, JSPropertyNameArrayGetNameAtIndex(names, index))];
1207     return array;
1208 }
1209
1210 JSValueRef CYCastJSValue(JSContextRef context, NSObject *value) { CYPoolTry {
1211     if (value == nil)
1212         return CYJSNull(context);
1213     else
1214         return CYMakeInstance(context, value);
1215 } CYPoolCatch(NULL) return /*XXX*/ NULL; }
1216
1217 @implementation CYJSObject
1218
1219 - (id) initWithJSObject:(JSObjectRef)object inContext:(JSContextRef)context { CYObjectiveTry_ {
1220     if ((self = [super init]) != nil) {
1221         object_ = object;
1222         context_ = CYGetJSContext(context);
1223         JSGlobalContextRetain(context_);
1224         JSValueProtect(context_, object_);
1225     } return self;
1226 } CYObjectiveCatch }
1227
1228 - (void) dealloc { CYObjectiveTry {
1229     JSValueUnprotect(context_, object_);
1230     JSGlobalContextRelease(context_);
1231     [super dealloc];
1232 } CYObjectiveCatch }
1233
1234 - (NSString *) cy$toCYON:(bool)objective inSet:(std::set<void *> &)objects { CYObjectiveTry {
1235     CYPool pool;
1236     const char *cyon(CYPoolCCYON(pool, context, object_, objects));
1237     if (cyon == NULL)
1238         return [super cy$toCYON:objective inSet:objects];
1239     else
1240         return [NSString stringWithUTF8String:cyon];
1241 } CYObjectiveCatch }
1242
1243 - (NSUInteger) count { CYObjectiveTry {
1244     JSPropertyNameArrayRef names(JSObjectCopyPropertyNames(context, object_));
1245     size_t size(JSPropertyNameArrayGetCount(names));
1246     JSPropertyNameArrayRelease(names);
1247     return size;
1248 } CYObjectiveCatch }
1249
1250 - (id) objectForKey:(id)key { CYObjectiveTry {
1251     JSValueRef value(CYGetProperty(context, object_, CYJSString(context, (NSObject *) key)));
1252     if (JSValueIsUndefined(context, value))
1253         return nil;
1254     return CYCastNSObject(NULL, context, value) ?: [NSNull null];
1255 } CYObjectiveCatch }
1256
1257 - (NSEnumerator *) keyEnumerator { CYObjectiveTry {
1258     JSPropertyNameArrayRef names(JSObjectCopyPropertyNames(context, object_));
1259     NSEnumerator *enumerator([CYCastNSArray(context, names) objectEnumerator]);
1260     JSPropertyNameArrayRelease(names);
1261     return enumerator;
1262 } CYObjectiveCatch }
1263
1264 - (void) setObject:(id)object forKey:(id)key { CYObjectiveTry {
1265     CYSetProperty(context, object_, CYJSString(context, (NSObject *) key), CYCastJSValue(context, (NSString *) object));
1266 } CYObjectiveCatch }
1267
1268 - (void) removeObjectForKey:(id)key { CYObjectiveTry {
1269     (void) _jsccall(JSObjectDeleteProperty, context, object_, CYJSString(context, (NSObject *) key));
1270 } CYObjectiveCatch }
1271
1272 @end
1273
1274 @implementation CYJSArray
1275
1276 - (NSString *) cy$toCYON:(bool)objective inSet:(std::set<void *> &)objects { CYObjectiveTry {
1277     CYPool pool;
1278     return [NSString stringWithUTF8String:CYPoolCCYON(pool, context, object_, objects)];
1279 } CYObjectiveCatch }
1280
1281 - (id) initWithJSObject:(JSObjectRef)object inContext:(JSContextRef)context { CYObjectiveTry_ {
1282     if ((self = [super init]) != nil) {
1283         object_ = object;
1284         context_ = CYGetJSContext(context);
1285         JSGlobalContextRetain(context_);
1286         JSValueProtect(context_, object_);
1287     } return self;
1288 } CYObjectiveCatch }
1289
1290 - (void) dealloc { CYObjectiveTry {
1291     JSValueUnprotect(context_, object_);
1292     JSGlobalContextRelease(context_);
1293     [super dealloc];
1294 } CYObjectiveCatch }
1295
1296 - (NSUInteger) count { CYObjectiveTry {
1297     return CYArrayLength(context, object_);
1298 } CYObjectiveCatch }
1299
1300 - (id) objectAtIndex:(NSUInteger)index { CYObjectiveTry {
1301     size_t bounds([self count]);
1302     if (index >= bounds)
1303         @throw [NSException exceptionWithName:NSRangeException reason:[NSString stringWithFormat:@"*** -[CYJSArray objectAtIndex:]: index (%zu) beyond bounds (%zu)", static_cast<size_t>(index), bounds] userInfo:nil];
1304     JSValueRef value(_jsccall(JSObjectGetPropertyAtIndex, context, object_, index));
1305     return CYCastNSObject(NULL, context, value) ?: [NSNull null];
1306 } CYObjectiveCatch }
1307
1308 - (void) addObject:(id)object { CYObjectiveTry {
1309     CYArrayPush(context, object_, CYCastJSValue(context, (NSObject *) object));
1310 } CYObjectiveCatch }
1311
1312 - (void) insertObject:(id)object atIndex:(NSUInteger)index { CYObjectiveTry {
1313     size_t bounds([self count] + 1);
1314     if (index >= bounds)
1315         @throw [NSException exceptionWithName:NSRangeException reason:[NSString stringWithFormat:@"*** -[CYJSArray insertObject:atIndex:]: index (%zu) beyond bounds (%zu)", static_cast<size_t>(index), bounds] userInfo:nil];
1316     JSValueRef arguments[3];
1317     arguments[0] = CYCastJSValue(context, index);
1318     arguments[1] = CYCastJSValue(context, 0);
1319     arguments[2] = CYCastJSValue(context, (NSObject *) object);
1320     JSObjectRef Array(CYGetCachedObject(context, CYJSString("Array_prototype")));
1321     _jsccall(JSObjectCallAsFunction, context, CYCastJSObject(context, CYGetProperty(context, Array, splice_s)), object_, 3, arguments);
1322 } CYObjectiveCatch }
1323
1324 - (void) removeLastObject { CYObjectiveTry {
1325     JSObjectRef Array(CYGetCachedObject(context, CYJSString("Array_prototype")));
1326     _jsccall(JSObjectCallAsFunction, context, CYCastJSObject(context, CYGetProperty(context, Array, pop_s)), object_, 0, NULL);
1327 } CYObjectiveCatch }
1328
1329 - (void) removeObjectAtIndex:(NSUInteger)index { CYObjectiveTry {
1330     size_t bounds([self count]);
1331     if (index >= bounds)
1332         @throw [NSException exceptionWithName:NSRangeException reason:[NSString stringWithFormat:@"*** -[CYJSArray removeObjectAtIndex:]: index (%zu) beyond bounds (%zu)", static_cast<size_t>(index), bounds] userInfo:nil];
1333     JSValueRef arguments[2];
1334     arguments[0] = CYCastJSValue(context, index);
1335     arguments[1] = CYCastJSValue(context, 1);
1336     JSObjectRef Array(CYGetCachedObject(context, CYJSString("Array_prototype")));
1337     _jsccall(JSObjectCallAsFunction, context, CYCastJSObject(context, CYGetProperty(context, Array, splice_s)), object_, 2, arguments);
1338 } CYObjectiveCatch }
1339
1340 - (void) replaceObjectAtIndex:(NSUInteger)index withObject:(id)object { CYObjectiveTry {
1341     size_t bounds([self count]);
1342     if (index >= bounds)
1343         @throw [NSException exceptionWithName:NSRangeException reason:[NSString stringWithFormat:@"*** -[CYJSArray replaceObjectAtIndex:withObject:]: index (%zu) beyond bounds (%zu)", static_cast<size_t>(index), bounds] userInfo:nil];
1344     CYSetProperty(context, object_, index, CYCastJSValue(context, (NSObject *) object));
1345 } CYObjectiveCatch }
1346
1347 @end
1348
1349 // XXX: inherit from or replace with CYJSObject
1350 @interface CYInternal : NSObject {
1351     JSGlobalContextRef context_;
1352     JSObjectRef object_;
1353 }
1354
1355 @end
1356
1357 @implementation CYInternal
1358
1359 - (void) dealloc { CYObjectiveTry {
1360     JSValueUnprotect(context_, object_);
1361     JSGlobalContextRelease(context_);
1362     [super dealloc];
1363 } CYObjectiveCatch }
1364
1365 - (id) initInContext:(JSContextRef)context { CYObjectiveTry_ {
1366     if ((self = [super init]) != nil) {
1367         context_ = CYGetJSContext(context);
1368         JSGlobalContextRetain(context_);
1369     } return self;
1370 } CYObjectiveCatch }
1371
1372 - (bool) hasProperty:(JSStringRef)name inContext:(JSContextRef)context {
1373     if (object_ == NULL)
1374         return false;
1375
1376     return JSObjectHasProperty(context, object_, name);
1377 }
1378
1379 - (JSValueRef) getProperty:(JSStringRef)name inContext:(JSContextRef)context {
1380     if (object_ == NULL)
1381         return NULL;
1382
1383     return CYGetProperty(context, object_, name);
1384 }
1385
1386 - (void) setProperty:(JSStringRef)name toValue:(JSValueRef)value inContext:(JSContextRef)context {
1387     @synchronized (self) {
1388         if (object_ == NULL) {
1389             object_ = JSObjectMake(context, NULL, NULL);
1390             JSValueProtect(context, object_);
1391         }
1392     }
1393
1394     CYSetProperty(context, object_, name, value);
1395 }
1396
1397 + (CYInternal *) get:(id)object {
1398 #ifdef __APPLE__
1399     if (&objc_getAssociatedObject == NULL)
1400         return nil;
1401
1402     @synchronized (object) {
1403         if (CYInternal *internal = objc_getAssociatedObject(object, @selector(cy$internal)))
1404             return internal;
1405     }
1406 #endif
1407
1408     return nil;
1409 }
1410
1411 + (CYInternal *) set:(id)object inContext:(JSContextRef)context {
1412 #ifdef __APPLE__
1413     if (&objc_getAssociatedObject == NULL)
1414         return nil;
1415
1416     @synchronized (object) {
1417         if (CYInternal *internal = objc_getAssociatedObject(object, @selector(cy$internal)))
1418             return internal;
1419
1420         if (&objc_setAssociatedObject == NULL)
1421             return nil;
1422
1423         CYInternal *internal([[[CYInternal alloc] initInContext:context] autorelease]);
1424         objc_setAssociatedObject(object, @selector(cy$internal), internal, OBJC_ASSOCIATION_RETAIN_NONATOMIC);
1425         return internal;
1426     }
1427 #endif
1428
1429     return nil;
1430 }
1431
1432 @end
1433
1434 static JSObjectRef CYMakeSelector(JSContextRef context, SEL sel) {
1435     Selector_privateData *internal(new Selector_privateData(sel));
1436     return JSObjectMake(context, Selector_, internal);
1437 }
1438
1439 static SEL CYCastSEL(JSContextRef context, JSValueRef value) {
1440     if (JSValueIsObjectOfClass(context, value, Selector_)) {
1441         Selector_privateData *internal(reinterpret_cast<Selector_privateData *>(JSObjectGetPrivate((JSObjectRef) value)));
1442         return reinterpret_cast<SEL>(internal->value_);
1443     } else {
1444         CYPool pool;
1445         return sel_registerName(CYPoolCString(pool, context, value));
1446     }
1447 }
1448
1449 void *CYObjectiveC_ExecuteStart(JSContextRef context) { CYSadTry {
1450     return (void *) [[NSAutoreleasePool alloc] init];
1451 } CYSadCatch(NULL) }
1452
1453 void CYObjectiveC_ExecuteEnd(JSContextRef context, void *handle) { CYSadTry {
1454     return [(NSAutoreleasePool *) handle release];
1455 } CYSadCatch() }
1456
1457 static void CYObjectiveC_CallFunction(JSContextRef context, ffi_cif *cif, void (*function)(), uint8_t *value, void **values) { CYSadTry {
1458     ffi_call(cif, function, value, values);
1459 } CYSadCatch() }
1460
1461 #ifdef __APPLE__
1462 static NSBlock *CYCastNSBlock(CYPool &pool, JSContextRef context, JSValueRef value, sig::Signature *signature) {
1463     if (JSValueIsNull(context, value))
1464         return nil;
1465     JSObjectRef object(CYCastJSObject(context, value));
1466
1467     if (JSValueIsObjectOfClass(context, object, FunctionInstance_))
1468         return reinterpret_cast<Instance *>(JSObjectGetPrivate(object))->GetValue();
1469
1470     if (JSValueIsObjectOfClass(context, object, Instance_)) {
1471         _assert(reinterpret_cast<Instance *>(JSObjectGetPrivate(object))->GetValue() == nil);
1472         return nil;
1473     }
1474
1475     _assert(JSObjectIsFunction(context, object));
1476
1477     _assert(signature != NULL);
1478     _assert(signature->count != 0);
1479
1480     sig::Signature modified;
1481     modified.count = signature->count + 1;
1482     modified.elements = new(pool) sig::Element[modified.count];
1483
1484     modified.elements[0] = signature->elements[0];
1485     memcpy(modified.elements + 2, signature->elements + 1, sizeof(sig::Element) * (signature->count - 1));
1486
1487     modified.elements[1].name = NULL;
1488     modified.elements[1].type = new(pool) sig::Type();
1489     modified.elements[1].offset = _not(size_t);
1490
1491     memset(modified.elements[1].type, 0, sizeof(sig::Type));
1492     modified.elements[1].type->primitive = sig::object_P;
1493
1494     return CYMakeBlock(context, object, modified);
1495 }
1496 #endif
1497
1498 static bool CYObjectiveC_PoolFFI(CYPool *pool, JSContextRef context, sig::Type *type, ffi_type *ffi, void *data, JSValueRef value) { CYSadTry {
1499     // XXX: assigning to an indirect id * works for return values, but not for properties and fields
1500
1501     switch (type->primitive) {
1502 #ifdef __APPLE__
1503         case sig::block_P:
1504             // XXX: this function might not handle the idea of a null pool
1505             *reinterpret_cast<id *>(data) = CYCastNSBlock(*pool, context, value, &type->data.signature);
1506         break;
1507 #endif
1508
1509         case sig::object_P:
1510         case sig::typename_P:
1511             *reinterpret_cast<id *>(data) = CYCastNSObject(pool, context, value);
1512         break;
1513
1514         case sig::selector_P:
1515             *reinterpret_cast<SEL *>(data) = CYCastSEL(context, value);
1516         break;
1517
1518         default:
1519             return false;
1520     }
1521
1522     return true;
1523 } CYSadCatch(false) }
1524
1525 static JSValueRef CYObjectiveC_FromFFI(JSContextRef context, sig::Type *type, ffi_type *ffi, void *data, bool initialize, JSObjectRef owner) { CYPoolTry {
1526     switch (type->primitive) {
1527         // XXX: do something epic about blocks
1528         case sig::block_P:
1529         case sig::object_P:
1530             if (NSObject *value = *reinterpret_cast<NSObject **>(data)) {
1531                 JSObjectRef object(CYMakeInstance(context, value));
1532
1533                 if (initialize) {
1534                     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
1535
1536                     if ((internal->flags_ & Instance::Uninitialized) != 0) {
1537                         internal->flags_ = static_cast<Instance::Flags>(internal->flags_ & ~Instance::Uninitialized);
1538                         _assert(internal->value_ == nil);
1539                         internal->value_ = value;
1540                     }
1541
1542                     [value release];
1543                 }
1544
1545                 return object;
1546             } else goto null;
1547
1548         case sig::typename_P:
1549             if (Class value = *reinterpret_cast<Class *>(data))
1550                 return CYMakeInstance(context, value, Instance::Permanent);
1551             else goto null;
1552
1553         case sig::selector_P:
1554             if (SEL value = *reinterpret_cast<SEL *>(data))
1555                 return CYMakeSelector(context, value);
1556             else goto null;
1557
1558         null:
1559             return CYJSNull(context);
1560         default:
1561             return NULL;
1562     }
1563 } CYPoolCatch(NULL) return /*XXX*/ NULL; }
1564
1565 static bool CYImplements(id object, Class _class, SEL selector, bool devoid = false) {
1566     if (objc_method *method = class_getInstanceMethod(_class, selector)) {
1567         if (!devoid)
1568             return true;
1569         char type[16];
1570         method_getReturnType(method, type, sizeof(type));
1571         if (type[0] != 'v')
1572             return true;
1573     }
1574
1575     // XXX: possibly use a more "awesome" check?
1576     return false;
1577 }
1578
1579 static JSValueRef MessageAdapter_(JSContextRef context, size_t count, JSValueRef values[], JSObjectRef function) {
1580     JSObjectRef _this(CYCastJSObject(context, values[0]));
1581     return CYCallAsFunction(context, function, _this, count - 2, values + 2);
1582 }
1583
1584 static void MessageClosure_(ffi_cif *cif, void *result, void **arguments, void *arg) {
1585     CYExecuteClosure(cif, result, arguments, arg, &MessageAdapter_);
1586 }
1587
1588 static JSObjectRef CYMakeMessage(JSContextRef context, SEL sel, IMP imp, const char *type) {
1589     Message_privateData *internal(new Message_privateData(sel, type, imp));
1590     return JSObjectMake(context, Message_, internal);
1591 }
1592
1593 static IMP CYMakeMessage(JSContextRef context, JSValueRef value, const char *encoding) {
1594     JSObjectRef function(CYCastJSObject(context, value));
1595     CYPool pool;
1596     sig::Signature signature;
1597     sig::Parse(pool, &signature, encoding, &Structor_);
1598     Closure_privateData *internal(CYMakeFunctor_(context, function, signature, &MessageClosure_));
1599     // XXX: see notes in Library.cpp about needing to leak
1600     return reinterpret_cast<IMP>(internal->GetValue());
1601 }
1602
1603 static bool Messages_hasProperty(JSContextRef context, JSObjectRef object, JSStringRef property) {
1604     Messages *internal(reinterpret_cast<Messages *>(JSObjectGetPrivate(object)));
1605     Class _class(internal->GetValue());
1606
1607     CYPool pool;
1608     const char *name(CYPoolCString(pool, context, property));
1609
1610     if (SEL sel = sel_getUid(name))
1611         if (class_getInstanceMethod(_class, sel) != NULL)
1612             return true;
1613
1614     return false;
1615 }
1616
1617 static JSValueRef Messages_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
1618     Messages *internal(reinterpret_cast<Messages *>(JSObjectGetPrivate(object)));
1619     Class _class(internal->GetValue());
1620
1621     CYPool pool;
1622     const char *name(CYPoolCString(pool, context, property));
1623
1624     if (SEL sel = sel_getUid(name))
1625         if (objc_method *method = class_getInstanceMethod(_class, sel))
1626             return CYMakeMessage(context, sel, method_getImplementation(method), method_getTypeEncoding(method));
1627
1628     return NULL;
1629 } CYCatch(NULL) }
1630
1631 static bool Messages_setProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef value, JSValueRef *exception) { CYTry {
1632     Messages *internal(reinterpret_cast<Messages *>(JSObjectGetPrivate(object)));
1633     Class _class(internal->GetValue());
1634
1635     CYPool pool;
1636     const char *name(CYPoolCString(pool, context, property));
1637     SEL sel(sel_registerName(name));
1638
1639     const char *type;
1640     IMP imp;
1641
1642     if (JSValueIsObjectOfClass(context, value, Message_)) {
1643         Message_privateData *message(reinterpret_cast<Message_privateData *>(JSObjectGetPrivate((JSObjectRef) value)));
1644         type = sig::Unparse(pool, &message->signature_);
1645         imp = reinterpret_cast<IMP>(message->GetValue());
1646     } else if (objc_method *method = class_getInstanceMethod(_class, sel)) {
1647         type = method_getTypeEncoding(method);
1648         imp = CYMakeMessage(context, value, type);
1649     } else _assert(false);
1650
1651     objc_method *method(NULL);
1652     unsigned int size;
1653     objc_method **methods(class_copyMethodList(_class, &size));
1654     for (size_t i(0); i != size; ++i)
1655         if (sel_isEqual(method_getName(methods[i]), sel)) {
1656             method = methods[i];
1657             break;
1658         }
1659     free(methods);
1660
1661     if (method != NULL)
1662         method_setImplementation(method, imp);
1663     else
1664         class_addMethod(_class, sel, imp, type);
1665
1666     return true;
1667 } CYCatch(false) }
1668
1669 static void Messages_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
1670     Messages *internal(reinterpret_cast<Messages *>(JSObjectGetPrivate(object)));
1671     Class _class(internal->GetValue());
1672
1673     unsigned int size;
1674     objc_method **data(class_copyMethodList(_class, &size));
1675     for (size_t i(0); i != size; ++i)
1676         JSPropertyNameAccumulatorAddName(names, CYJSString(sel_getName(method_getName(data[i]))));
1677     free(data);
1678 }
1679
1680 static bool CYHasImplicitProperties(Class _class) {
1681     // XXX: this is an evil hack to deal with NSProxy; fix elsewhere
1682     if (!CYImplements(_class, object_getClass(_class), @selector(cy$hasImplicitProperties)))
1683         return true;
1684     return [_class cy$hasImplicitProperties];
1685 }
1686
1687 static bool Instance_hasProperty(JSContextRef context, JSObjectRef object, JSStringRef property) {
1688     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
1689     id self(internal->GetValue());
1690
1691     if (JSStringIsEqualToUTF8CString(property, "$cyi"))
1692         return true;
1693
1694     CYPool pool;
1695     NSString *name(CYCastNSString(&pool, context, property));
1696
1697     if (CYInternal *internal = [CYInternal get:self])
1698         if ([internal hasProperty:property inContext:context])
1699             return true;
1700
1701     Class _class(object_getClass(self));
1702
1703     CYPoolTry {
1704         // XXX: this is an evil hack to deal with NSProxy; fix elsewhere
1705         if (CYImplements(self, _class, @selector(cy$hasProperty:)))
1706             if ([self cy$hasProperty:name])
1707                 return true;
1708     } CYPoolCatch(false)
1709
1710     const char *string(CYPoolCString(pool, context, name));
1711
1712     if (class_getProperty(_class, string) != NULL)
1713         return true;
1714
1715     if (CYHasImplicitProperties(_class))
1716         if (SEL sel = sel_getUid(string))
1717             if (CYImplements(self, _class, sel, true))
1718                 return true;
1719
1720     return false;
1721 }
1722
1723 static JSValueRef Instance_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
1724     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
1725     id self(internal->GetValue());
1726
1727     if (JSStringIsEqualToUTF8CString(property, "$cyi"))
1728         return Internal::Make(context, self, object);
1729
1730     CYPool pool;
1731     NSString *name(CYCastNSString(&pool, context, property));
1732
1733     if (CYInternal *internal = [CYInternal get:self])
1734         if (JSValueRef value = [internal getProperty:property inContext:context])
1735             return value;
1736
1737     CYPoolTry {
1738         if (JSValueRef value = [self cy$getProperty:name inContext:context])
1739             return value;
1740     } CYPoolCatch(NULL)
1741
1742     const char *string(CYPoolCString(pool, context, name));
1743     Class _class(object_getClass(self));
1744
1745     if (objc_property_t property = class_getProperty(_class, string)) {
1746         PropertyAttributes attributes(property);
1747         SEL sel(sel_registerName(attributes.Getter()));
1748         return CYSendMessage(pool, context, self, NULL, sel, 0, NULL, false);
1749     }
1750
1751     if (CYHasImplicitProperties(_class))
1752         if (SEL sel = sel_getUid(string))
1753             if (CYImplements(self, _class, sel, true))
1754                 return CYSendMessage(pool, context, self, NULL, sel, 0, NULL, false);
1755
1756     return NULL;
1757 } CYCatch(NULL) }
1758
1759 static bool Instance_setProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef value, JSValueRef *exception) { CYTry {
1760     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
1761     id self(internal->GetValue());
1762
1763     CYPool pool;
1764
1765     NSString *name(CYCastNSString(&pool, context, property));
1766     NSObject *data(CYCastNSObject(&pool, context, value));
1767
1768     CYPoolTry {
1769         if ([self cy$setProperty:name to:data])
1770             return true;
1771     } CYPoolCatch(false)
1772
1773     const char *string(CYPoolCString(pool, context, name));
1774     Class _class(object_getClass(self));
1775
1776     if (objc_property_t property = class_getProperty(_class, string)) {
1777         PropertyAttributes attributes(property);
1778         if (const char *setter = attributes.Setter()) {
1779             SEL sel(sel_registerName(setter));
1780             JSValueRef arguments[1] = {value};
1781             CYSendMessage(pool, context, self, NULL, sel, 1, arguments, false);
1782             return true;
1783         }
1784     }
1785
1786     size_t length(strlen(string));
1787
1788     char set[length + 5];
1789
1790     set[0] = 's';
1791     set[1] = 'e';
1792     set[2] = 't';
1793
1794     if (string[0] != '\0') {
1795         set[3] = toupper(string[0]);
1796         memcpy(set + 4, string + 1, length - 1);
1797     }
1798
1799     set[length + 3] = ':';
1800     set[length + 4] = '\0';
1801
1802     if (SEL sel = sel_getUid(set))
1803         if (CYImplements(self, _class, sel)) {
1804             JSValueRef arguments[1] = {value};
1805             CYSendMessage(pool, context, self, NULL, sel, 1, arguments, false);
1806             return true;
1807         }
1808
1809     if (CYInternal *internal = [CYInternal set:self inContext:context]) {
1810         [internal setProperty:property toValue:value inContext:context];
1811         return true;
1812     }
1813
1814     return false;
1815 } CYCatch(false) }
1816
1817 static bool Instance_deleteProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
1818     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
1819     id self(internal->GetValue());
1820
1821     CYPoolTry {
1822         NSString *name(CYCastNSString(NULL, context, property));
1823         return [self cy$deleteProperty:name];
1824     } CYPoolCatch(false)
1825 } CYCatch(false) return /*XXX*/ false; }
1826
1827 static void Instance_getPropertyNames_message(JSPropertyNameAccumulatorRef names, objc_method *method) {
1828     const char *name(sel_getName(method_getName(method)));
1829     if (strchr(name, ':') != NULL)
1830         return;
1831
1832     const char *type(method_getTypeEncoding(method));
1833     if (type == NULL || *type == '\0' || *type == 'v')
1834         return;
1835
1836     JSPropertyNameAccumulatorAddName(names, CYJSString(name));
1837 }
1838
1839 static void Instance_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
1840     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
1841     id self(internal->GetValue());
1842
1843     CYPool pool;
1844     Class _class(object_getClass(self));
1845
1846     {
1847         unsigned int size;
1848         objc_property_t *data(class_copyPropertyList(_class, &size));
1849         for (size_t i(0); i != size; ++i)
1850             JSPropertyNameAccumulatorAddName(names, CYJSString(property_getName(data[i])));
1851         free(data);
1852     }
1853
1854     if (CYHasImplicitProperties(_class))
1855         for (Class current(_class); current != nil; current = class_getSuperclass(current)) {
1856             unsigned int size;
1857             objc_method **data(class_copyMethodList(current, &size));
1858             for (size_t i(0); i != size; ++i)
1859                 Instance_getPropertyNames_message(names, data[i]);
1860             free(data);
1861         }
1862
1863     CYPoolTry {
1864         // XXX: this is an evil hack to deal with NSProxy; fix elsewhere
1865         if (CYImplements(self, _class, @selector(cy$getPropertyNames:inContext:)))
1866             [self cy$getPropertyNames:names inContext:context];
1867     } CYPoolCatch()
1868 }
1869
1870 static JSObjectRef Instance_callAsConstructor(JSContextRef context, JSObjectRef object, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
1871     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
1872     JSObjectRef value(CYMakeInstance(context, [internal->GetValue() alloc], Instance::Uninitialized));
1873     return value;
1874 } CYCatch(NULL) }
1875
1876 static const char *CYBlockEncoding(NSBlock *self) {
1877     BlockLiteral *literal(reinterpret_cast<BlockLiteral *>(self));
1878     if ((literal->flags & BLOCK_HAS_SIGNATURE) == 0)
1879         return NULL;
1880     uint8_t *descriptor(reinterpret_cast<uint8_t *>(literal->descriptor));
1881     descriptor += sizeof(BlockDescriptor1);
1882     if ((literal->flags & BLOCK_HAS_COPY_DISPOSE) != 0)
1883         descriptor += sizeof(BlockDescriptor2);
1884     BlockDescriptor3 *descriptor3(reinterpret_cast<BlockDescriptor3 *>(descriptor));
1885     return descriptor3->signature;
1886 }
1887
1888 static JSValueRef FunctionInstance_callAsFunction(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
1889     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
1890     id self(internal->GetValue());
1891
1892     if (const char *encoding = CYBlockEncoding(self)) {
1893         CYPool pool;
1894
1895         void *setup[1];
1896         setup[0] = &self;
1897
1898         sig::Signature signature;
1899         sig::Parse(pool, &signature, encoding, &Structor_);
1900
1901         ffi_cif cif;
1902         sig::sig_ffi_cif(pool, &sig::ObjectiveC, &signature, &cif);
1903
1904         BlockLiteral *literal(reinterpret_cast<BlockLiteral *>(self));
1905         void (*function)() = reinterpret_cast<void (*)()>(literal->invoke);
1906         return CYCallFunction(pool, context, 1, setup, count, arguments, false, &signature, &cif, function);
1907     }
1908
1909     if (count != 0)
1910         CYThrow("NSBlock without signature field passed arguments");
1911
1912     CYPoolTry {
1913         [self invoke];
1914     } CYPoolCatch(NULL);
1915
1916     return NULL;
1917 } CYCatch(NULL) }
1918
1919 static bool Instance_hasInstance(JSContextRef context, JSObjectRef constructor, JSValueRef instance, JSValueRef *exception) { CYTry {
1920     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate((JSObjectRef) constructor)));
1921     Class _class(internal->GetValue());
1922     if (!CYIsClass(_class))
1923         return false;
1924
1925     if (CYJSValueIsNSObject(context, instance)) {
1926         Instance *linternal(reinterpret_cast<Instance *>(JSObjectGetPrivate((JSObjectRef) instance)));
1927         // XXX: this isn't always safe
1928         return [linternal->GetValue() isKindOfClass:_class];
1929     }
1930
1931     return false;
1932 } CYCatch(false) }
1933
1934 static JSValueRef Instance_box_callAsFunction(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
1935     if (count == 0)
1936         throw CYJSError(context, "incorrect number of arguments to Instance");
1937     CYPool pool;
1938     id value(CYCastNSObject(&pool, context, arguments[0]));
1939     if (value == nil)
1940         value = [NSNull null];
1941     return CYCastJSValue(context, [value cy$box]);
1942 } CYCatch(NULL) }
1943
1944 static bool Internal_hasProperty(JSContextRef context, JSObjectRef object, JSStringRef property) {
1945     Internal *internal(reinterpret_cast<Internal *>(JSObjectGetPrivate(object)));
1946     CYPool pool;
1947
1948     id self(internal->GetValue());
1949     const char *name(CYPoolCString(pool, context, property));
1950
1951     if (object_getInstanceVariable(self, name, NULL) != NULL)
1952         return true;
1953
1954     return false;
1955 }
1956
1957 static void CYBitField(unsigned &length, unsigned &shift, id self, Ivar ivar, const char *encoding, unsigned offset) {
1958     length = CYCastDouble(encoding + 1);
1959     shift = 0;
1960
1961     unsigned int size;
1962     objc_ivar **ivars(class_copyIvarList(object_getClass(self), &size));
1963     for (size_t i(0); i != size; ++i)
1964         if (ivars[i] == ivar)
1965             break;
1966         else if (ivar_getOffset(ivars[i]) == offset) {
1967             const char *encoding(ivar_getTypeEncoding(ivars[i]));
1968             _assert(encoding != NULL);
1969             _assert(encoding[0] == 'b');
1970             shift += CYCastDouble(encoding + 1);
1971         }
1972     free(ivars);
1973 }
1974
1975 static JSValueRef Internal_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
1976     Internal *internal(reinterpret_cast<Internal *>(JSObjectGetPrivate(object)));
1977     CYPool pool;
1978
1979     id self(internal->GetValue());
1980     const char *name(CYPoolCString(pool, context, property));
1981
1982 #ifdef __arm64__
1983     if (strcmp(name, "isa") == 0)
1984         return CYCastJSValue(context, object_getClass(self));
1985 #endif
1986
1987     if (objc_ivar *ivar = object_getInstanceVariable(self, name, NULL)) {
1988         ptrdiff_t offset(ivar_getOffset(ivar));
1989         void *data(reinterpret_cast<uint8_t *>(self) + offset);
1990
1991         const char *encoding(ivar_getTypeEncoding(ivar));
1992         _assert(encoding != NULL);
1993         _assert(encoding[0] != '\0');
1994         if (encoding[0] == 'b') {
1995             unsigned length, shift;
1996             CYBitField(length, shift, self, ivar, encoding, offset);
1997             _assert(shift + length <= sizeof(uintptr_t) * 8);
1998             uintptr_t &field(*reinterpret_cast<uintptr_t *>(data));
1999             uintptr_t mask((1 << length) - 1);
2000             return CYCastJSValue(context, (field >> shift) & mask);
2001         } else {
2002             auto type(new(pool) Type_privateData(encoding));
2003             return CYFromFFI(context, type->type_, type->GetFFI(), data);
2004         }
2005     }
2006
2007     return NULL;
2008 } CYCatch(NULL) }
2009
2010 static bool Internal_setProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef value, JSValueRef *exception) { CYTry {
2011     Internal *internal(reinterpret_cast<Internal *>(JSObjectGetPrivate(object)));
2012     CYPool pool;
2013
2014     id self(internal->GetValue());
2015     const char *name(CYPoolCString(pool, context, property));
2016
2017     if (objc_ivar *ivar = object_getInstanceVariable(self, name, NULL)) {
2018         ptrdiff_t offset(ivar_getOffset(ivar));
2019         void *data(reinterpret_cast<uint8_t *>(self) + offset);
2020
2021         const char *encoding(ivar_getTypeEncoding(ivar));
2022         _assert(encoding != NULL);
2023         if (encoding[0] == 'b') {
2024             unsigned length, shift;
2025             CYBitField(length, shift, self, ivar, encoding, offset);
2026             _assert(shift + length <= sizeof(uintptr_t) * 8);
2027             uintptr_t &field(*reinterpret_cast<uintptr_t *>(data));
2028             uintptr_t mask((1 << length) - 1);
2029             field = field & ~(mask << shift) | (uintptr_t(CYCastDouble(context, value)) & mask) << shift;
2030         } else {
2031             auto type(new(pool) Type_privateData(ivar_getTypeEncoding(ivar)));
2032             CYPoolFFI(&pool, context, type->type_, type->GetFFI(), reinterpret_cast<uint8_t *>(self) + ivar_getOffset(ivar), value);
2033             return true;
2034         }
2035     }
2036
2037     return false;
2038 } CYCatch(false) }
2039
2040 static void Internal_getPropertyNames_(Class _class, JSPropertyNameAccumulatorRef names) {
2041     if (Class super = class_getSuperclass(_class))
2042         Internal_getPropertyNames_(super, names);
2043
2044     unsigned int size;
2045     objc_ivar **data(class_copyIvarList(_class, &size));
2046     for (size_t i(0); i != size; ++i)
2047         JSPropertyNameAccumulatorAddName(names, CYJSString(ivar_getName(data[i])));
2048     free(data);
2049 }
2050
2051 static void Internal_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
2052     Internal *internal(reinterpret_cast<Internal *>(JSObjectGetPrivate(object)));
2053     CYPool pool;
2054
2055     id self(internal->GetValue());
2056     Class _class(object_getClass(self));
2057
2058     Internal_getPropertyNames_(_class, names);
2059 }
2060
2061 static JSValueRef Internal_callAsFunction_$cya(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2062     Internal *internal(reinterpret_cast<Internal *>(JSObjectGetPrivate(object)));
2063     return internal->GetOwner();
2064 } CYCatch(NULL) }
2065
2066 static bool ObjectiveC_Classes_hasProperty(JSContextRef context, JSObjectRef object, JSStringRef property) {
2067     CYPool pool;
2068     return objc_getClass(CYPoolCString(pool, context, property)) != Nil;
2069 }
2070
2071 static JSValueRef ObjectiveC_Classes_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
2072     CYPool pool;
2073     NSString *name(CYCastNSString(&pool, context, property));
2074     if (Class _class = NSClassFromString(name))
2075         return CYMakeInstance(context, _class, Instance::Permanent);
2076     return NULL;
2077 } CYCatch(NULL) }
2078
2079 static Class *CYCopyClassList(size_t &size) {
2080     size = objc_getClassList(NULL, 0);
2081     Class *data(reinterpret_cast<Class *>(malloc(sizeof(Class) * size)));
2082
2083     for (;;) {
2084         size_t writ(objc_getClassList(data, size));
2085         if (writ <= size) {
2086             size = writ;
2087             return data;
2088         }
2089
2090         Class *copy(reinterpret_cast<Class *>(realloc(data, sizeof(Class) * writ)));
2091         if (copy == NULL) {
2092             free(data);
2093             return NULL;
2094         }
2095
2096         data = copy;
2097         size = writ;
2098     }
2099 }
2100
2101 static void ObjectiveC_Classes_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
2102     size_t size;
2103     if (Class *data = CYCopyClassList(size)) {
2104         for (size_t i(0); i != size; ++i)
2105             JSPropertyNameAccumulatorAddName(names, CYJSString(class_getName(data[i])));
2106         free(data);
2107     }
2108 }
2109
2110 #ifdef __APPLE__
2111 static JSValueRef ObjectiveC_Image_Classes_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
2112     const char *internal(reinterpret_cast<const char *>(JSObjectGetPrivate(object)));
2113
2114     CYPool pool;
2115     const char *name(CYPoolCString(pool, context, property));
2116     unsigned int size;
2117     const char **data(objc_copyClassNamesForImage(internal, &size));
2118     JSValueRef value;
2119     for (size_t i(0); i != size; ++i)
2120         if (strcmp(name, data[i]) == 0) {
2121             if (Class _class = objc_getClass(name)) {
2122                 value = CYMakeInstance(context, _class, Instance::Permanent);
2123                 goto free;
2124             } else
2125                 break;
2126         }
2127     value = NULL;
2128   free:
2129     free(data);
2130     return value;
2131 } CYCatch(NULL) }
2132
2133 static void ObjectiveC_Image_Classes_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
2134     const char *internal(reinterpret_cast<const char *>(JSObjectGetPrivate(object)));
2135     unsigned int size;
2136     const char **data(objc_copyClassNamesForImage(internal, &size));
2137     for (size_t i(0); i != size; ++i)
2138         JSPropertyNameAccumulatorAddName(names, CYJSString(data[i]));
2139     free(data);
2140 }
2141
2142 static JSValueRef ObjectiveC_Images_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
2143     CYPool pool;
2144     const char *name(CYPoolCString(pool, context, property));
2145     unsigned int size;
2146     const char **data(objc_copyImageNames(&size));
2147     for (size_t i(0); i != size; ++i)
2148         if (strcmp(name, data[i]) == 0) {
2149             name = data[i];
2150             goto free;
2151         }
2152     name = NULL;
2153   free:
2154     free(data);
2155     if (name == NULL)
2156         return NULL;
2157     JSObjectRef value(JSObjectMake(context, NULL, NULL));
2158     CYSetProperty(context, value, CYJSString("classes"), JSObjectMake(context, ObjectiveC_Image_Classes_, const_cast<char *>(name)));
2159     return value;
2160 } CYCatch(NULL) }
2161
2162 static void ObjectiveC_Images_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
2163     unsigned int size;
2164     const char **data(objc_copyImageNames(&size));
2165     for (size_t i(0); i != size; ++i)
2166         JSPropertyNameAccumulatorAddName(names, CYJSString(data[i]));
2167     free(data);
2168 }
2169 #endif
2170
2171 static JSValueRef ObjectiveC_Protocols_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
2172     CYPool pool;
2173     const char *name(CYPoolCString(pool, context, property));
2174     if (Protocol *protocol = objc_getProtocol(name))
2175         return CYMakeInstance(context, protocol, Instance::Permanent);
2176     return NULL;
2177 } CYCatch(NULL) }
2178
2179 static void ObjectiveC_Protocols_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
2180     unsigned int size;
2181     Protocol **data(objc_copyProtocolList(&size));
2182     for (size_t i(0); i != size; ++i)
2183         JSPropertyNameAccumulatorAddName(names, CYJSString(protocol_getName(data[i])));
2184     free(data);
2185 }
2186
2187 static JSValueRef ObjectiveC_Constants_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
2188     CYPool pool;
2189     CYUTF8String name(CYPoolUTF8String(pool, context, property));
2190     if (name == "nil")
2191         return CYJSNull(context);
2192     return NULL;
2193 } CYCatch(NULL) }
2194
2195 static void ObjectiveC_Constants_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
2196     JSPropertyNameAccumulatorAddName(names, CYJSString("nil"));
2197 }
2198
2199 #ifdef __APPLE__
2200 static kern_return_t CYReadMemory(task_t task, vm_address_t address, vm_size_t size, void **data) {
2201     *data = reinterpret_cast<void *>(address);
2202     return KERN_SUCCESS;
2203 }
2204
2205 struct CYChoice {
2206     std::set<Class> query_;
2207     JSContextRef context_;
2208     JSObjectRef results_;
2209 };
2210
2211 struct CYObjectStruct {
2212     Class isa_;
2213 };
2214
2215 static void choose_(task_t task, void *baton, unsigned type, vm_range_t *ranges, unsigned count) {
2216     CYChoice *choice(reinterpret_cast<CYChoice *>(baton));
2217     JSContextRef context(choice->context_);
2218
2219     for (unsigned i(0); i != count; ++i) {
2220         vm_range_t &range(ranges[i]);
2221         void *data(reinterpret_cast<void *>(range.address));
2222         size_t size(range.size);
2223
2224         if (size < sizeof(CYObjectStruct))
2225             continue;
2226
2227         uintptr_t *pointers(reinterpret_cast<uintptr_t *>(data));
2228 #ifdef __arm64__
2229         Class isa(reinterpret_cast<Class>(pointers[0] & 0x1fffffff8));
2230 #else
2231         Class isa(reinterpret_cast<Class>(pointers[0]));
2232 #endif
2233
2234         std::set<Class>::const_iterator result(choice->query_.find(isa));
2235         if (result == choice->query_.end())
2236             continue;
2237
2238         size_t needed(class_getInstanceSize(*result));
2239         // XXX: if (size < needed)
2240
2241         size_t boundary(496);
2242 #ifdef __LP64__
2243         boundary *= 2;
2244 #endif
2245         if (needed <= boundary && (needed + 15) / 16 * 16 != size || needed > boundary && (needed + 511) / 512 * 512 != size)
2246             continue;
2247         CYArrayPush(context, choice->results_, CYCastJSValue(context, reinterpret_cast<id>(data)));
2248     }
2249 }
2250
2251 static JSValueRef choose(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2252     if (count != 1)
2253         throw CYJSError(context, "choose() takes a class argument");
2254
2255     CYGarbageCollect(context);
2256
2257     CYPool pool;
2258     Class _class(CYCastNSObject(&pool, context, arguments[0]));
2259
2260     vm_address_t *zones(NULL);
2261     unsigned size(0);
2262     kern_return_t error(malloc_get_all_zones(0, &CYReadMemory, &zones, &size));
2263     _assert(error == KERN_SUCCESS);
2264
2265     JSObjectRef Array(CYGetCachedObject(context, CYJSString("Array")));
2266     JSObjectRef results(_jsccall(JSObjectCallAsConstructor, context, Array, 0, NULL));
2267
2268     CYChoice choice;
2269     choice.context_ = context;
2270     choice.results_ = results;
2271
2272     size_t number;
2273     Class *classes(CYCopyClassList(number));
2274     _assert(classes != NULL);
2275
2276     for (size_t i(0); i != number; ++i)
2277         for (Class current(classes[i]); current != Nil; current = class_getSuperclass(current))
2278             if (current == _class) {
2279                 choice.query_.insert(classes[i]);
2280                 break;
2281             }
2282
2283     free(classes);
2284
2285     for (unsigned i(0); i != size; ++i) {
2286         const malloc_zone_t *zone(reinterpret_cast<const malloc_zone_t *>(zones[i]));
2287         if (zone == NULL || zone->introspect == NULL)
2288             continue;
2289
2290         zone->introspect->enumerator(mach_task_self(), &choice, MALLOC_PTR_IN_USE_RANGE_TYPE, zones[i], &CYReadMemory, &choose_);
2291     }
2292
2293     return results;
2294 } CYCatch(NULL) }
2295 #endif
2296
2297 #ifdef __APPLE__
2298 #if defined(__i386__) || defined(__x86_64__)
2299 #define OBJC_MAX_STRUCT_BY_VALUE 8
2300 static int struct_forward_array[] = {
2301     0, 0, 0, 1, 0, 1, 1, 1, 0 };
2302 #elif defined(__arm__)
2303 #define OBJC_MAX_STRUCT_BY_VALUE 1
2304 static int struct_forward_array[] = {
2305     0, 0 };
2306 #elif defined(__arm64__)
2307 #define CY_NO_STRET
2308 #else
2309 #error missing objc-runtime-info
2310 #endif
2311
2312 #ifndef CY_NO_STRET
2313 static bool stret(ffi_type *ffi_type) {
2314     return ffi_type->type == FFI_TYPE_STRUCT && (
2315         ffi_type->size > OBJC_MAX_STRUCT_BY_VALUE ||
2316         struct_forward_array[ffi_type->size] != 0
2317     );
2318 }
2319 #endif
2320 #else
2321 #define CY_NO_STRET
2322 #endif
2323
2324 JSValueRef CYSendMessage(CYPool &pool, JSContextRef context, id self, Class _class, SEL _cmd, size_t count, const JSValueRef arguments[], bool initialize) {
2325     const char *type;
2326
2327     if (_class == NULL)
2328         _class = object_getClass(self);
2329
2330     IMP imp;
2331
2332     if (objc_method *method = class_getInstanceMethod(_class, _cmd)) {
2333         imp = method_getImplementation(method);
2334         type = method_getTypeEncoding(method);
2335     } else {
2336         imp = NULL;
2337
2338         CYPoolTry {
2339             if (NSMethodSignature *method = [self methodSignatureForSelector:_cmd])
2340                 type = CYPoolCString(pool, context, [method _typeString]);
2341             else
2342                 type = NULL;
2343         } CYPoolCatch(NULL)
2344
2345         if (type == NULL)
2346             throw CYJSError(context, "unrecognized selector %s sent to object %p", sel_getName(_cmd), self);
2347     }
2348
2349     void *setup[2];
2350     setup[0] = &self;
2351     setup[1] = &_cmd;
2352
2353     sig::Signature signature;
2354     sig::Parse(pool, &signature, type, &Structor_);
2355
2356     size_t used(count + 3);
2357     if (used > signature.count) {
2358         sig::Element *elements(new (pool) sig::Element[used]);
2359         memcpy(elements, signature.elements, used * sizeof(sig::Element));
2360
2361         for (size_t index(signature.count); index != used; ++index) {
2362             sig::Element *element(&elements[index]);
2363             element->name = NULL;
2364             element->offset = _not(size_t);
2365
2366             sig::Type *type(new (pool) sig::Type);
2367             memset(type, 0, sizeof(*type));
2368             type->primitive = sig::object_P;
2369             element->type = type;
2370         }
2371
2372         signature.elements = elements;
2373         signature.count = used;
2374     }
2375
2376     ffi_cif cif;
2377     sig::sig_ffi_cif(pool, &sig::ObjectiveC, &signature, &cif);
2378
2379     if (imp == NULL) {
2380 #ifndef CY_NO_STRET
2381         if (stret(cif.rtype))
2382             imp = class_getMethodImplementation_stret(_class, _cmd);
2383         else
2384 #endif
2385             imp = class_getMethodImplementation(_class, _cmd);
2386     }
2387
2388     void (*function)() = reinterpret_cast<void (*)()>(imp);
2389     return CYCallFunction(pool, context, 2, setup, count, arguments, initialize, &signature, &cif, function);
2390 }
2391
2392 static JSValueRef $objc_msgSend(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[]) {
2393     if (count < 2)
2394         throw CYJSError(context, "too few arguments to objc_msgSend");
2395
2396     CYPool pool;
2397
2398     bool uninitialized;
2399
2400     id self;
2401     SEL _cmd;
2402     Class _class;
2403
2404     if (JSValueIsObjectOfClass(context, arguments[0], Super_)) {
2405         cy::Super *internal(reinterpret_cast<cy::Super *>(JSObjectGetPrivate((JSObjectRef) arguments[0])));
2406         self = internal->GetValue();
2407         _class = internal->class_;;
2408         uninitialized = false;
2409     } else if (CYJSValueIsNSObject(context, arguments[0])) {
2410         Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate((JSObjectRef) arguments[0])));
2411         self = internal->GetValue();
2412         _class = nil;
2413         uninitialized = internal->IsUninitialized();
2414         if (uninitialized)
2415             internal->value_ = nil;
2416     } else {
2417         self = CYCastNSObject(&pool, context, arguments[0]);
2418         _class = nil;
2419         uninitialized = false;
2420     }
2421
2422     if (self == nil)
2423         return CYJSNull(context);
2424
2425     _cmd = CYCastSEL(context, arguments[1]);
2426
2427     return CYSendMessage(pool, context, self, _class, _cmd, count - 2, arguments + 2, uninitialized);
2428 }
2429
2430 static JSValueRef $objc_msgSend(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2431     return $objc_msgSend(context, object, _this, count, arguments);
2432 } CYCatch(NULL) }
2433
2434 static JSValueRef Selector_callAsFunction(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2435     JSValueRef setup[count + 2];
2436     setup[0] = _this;
2437     setup[1] = object;
2438     memcpy(setup + 2, arguments, sizeof(JSValueRef) * count);
2439     return $objc_msgSend(context, NULL, NULL, count + 2, setup);
2440 } CYCatch(NULL) }
2441
2442 static JSValueRef Message_callAsFunction(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2443     CYPool pool;
2444     Message_privateData *internal(reinterpret_cast<Message_privateData *>(JSObjectGetPrivate(object)));
2445
2446     // XXX: handle Instance::Uninitialized?
2447     id self(CYCastNSObject(&pool, context, _this));
2448
2449     void *setup[2];
2450     setup[0] = &self;
2451     setup[1] = &internal->sel_;
2452
2453     return CYCallFunction(pool, context, 2, setup, count, arguments, false, &internal->signature_, &internal->cif_, internal->GetValue());
2454 } CYCatch(NULL) }
2455
2456 static JSObjectRef Super_new(JSContextRef context, JSObjectRef object, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2457     if (count != 2)
2458         throw CYJSError(context, "incorrect number of arguments to objc_super constructor");
2459     CYPool pool;
2460     id self(CYCastNSObject(&pool, context, arguments[0]));
2461     Class _class(CYCastClass(pool, context, arguments[1]));
2462     return cy::Super::Make(context, self, _class);
2463 } CYCatch(NULL) }
2464
2465 static JSObjectRef Selector_new(JSContextRef context, JSObjectRef object, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2466     if (count != 1)
2467         throw CYJSError(context, "incorrect number of arguments to Selector constructor");
2468     CYPool pool;
2469     const char *name(CYPoolCString(pool, context, arguments[0]));
2470     return CYMakeSelector(context, sel_registerName(name));
2471 } CYCatch(NULL) }
2472
2473 static JSObjectRef Instance_new(JSContextRef context, JSObjectRef object, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2474     if (count > 1)
2475         throw CYJSError(context, "incorrect number of arguments to Instance constructor");
2476     id self(count == 0 ? nil : CYCastPointer<id>(context, arguments[0]));
2477     return CYMakeInstance(context, self);
2478 } CYCatch(NULL) }
2479
2480 static JSValueRef CYValue_getProperty_value(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
2481     CYValue *internal(reinterpret_cast<CYValue *>(JSObjectGetPrivate(object)));
2482     return CYCastJSValue(context, reinterpret_cast<uintptr_t>(internal->value_));
2483 } CYCatch(NULL) }
2484
2485 static JSValueRef CYValue_callAsFunction_$cya(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2486     CYValue *internal(reinterpret_cast<CYValue *>(JSObjectGetPrivate(_this)));
2487     Type_privateData *typical(internal->GetType());
2488
2489     sig::Type *type;
2490     ffi_type *ffi;
2491
2492     if (typical == NULL) {
2493         type = NULL;
2494         ffi = NULL;
2495     } else {
2496         type = typical->type_;
2497         ffi = typical->ffi_;
2498     }
2499
2500     return CYMakePointer(context, &internal->value_, _not(size_t), type, ffi, object);
2501 } CYCatch(NULL) }
2502
2503 static JSValueRef FunctionInstance_getProperty_type(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
2504     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
2505     const char *encoding(CYBlockEncoding(internal->GetValue()));
2506     if (encoding == NULL)
2507         return CYJSNull(context);
2508     // XXX: this should be stored on a FunctionInstance private value subclass
2509     CYPool pool;
2510     sig::Signature signature;
2511     sig::Parse(pool, &signature, encoding, &Structor_);
2512     return CYMakeType(context, &signature);
2513 } CYCatch(NULL) }
2514
2515 static JSValueRef Instance_getProperty_constructor(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
2516     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
2517     return CYMakeInstance(context, object_getClass(internal->GetValue()), Instance::Permanent);
2518 } CYCatch(NULL) }
2519
2520 static JSValueRef Instance_getProperty_prototype(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
2521     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
2522     id self(internal->GetValue());
2523     if (!CYIsClass(self))
2524         return CYJSUndefined(context);
2525     return CYGetClassPrototype(context, self);
2526 } CYCatch(NULL) }
2527
2528 static JSValueRef Instance_getProperty_messages(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
2529     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
2530     id self(internal->GetValue());
2531     if (!CYIsClass(self))
2532         return CYJSUndefined(context);
2533     return Messages::Make(context, (Class) self);
2534 } CYCatch(NULL) }
2535
2536 static JSValueRef Instance_callAsFunction_toCYON(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2537     std::set<void *> *objects(CYCastObjects(context, _this, count, arguments));
2538
2539     if (!CYJSValueIsNSObject(context, _this))
2540         return NULL;
2541
2542     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(_this)));
2543     return CYCastJSValue(context, CYJSString(context, CYCastNSCYON(internal->GetValue(), false, objects)));
2544 } CYCatch(NULL) }
2545
2546 static JSValueRef Instance_callAsFunction_toJSON(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2547     if (!CYJSValueIsNSObject(context, _this))
2548         return NULL;
2549
2550     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(_this)));
2551     id value(internal->GetValue());
2552
2553     CYPoolTry {
2554         NSString *key;
2555         if (count == 0)
2556             key = nil;
2557         else
2558             key = CYCastNSString(NULL, context, CYJSString(context, arguments[0]));
2559
2560         if (!CYImplements(value, object_getClass(value), @selector(cy$toJSON:inContext:)))
2561             return CYJSUndefined(context);
2562         else if (JSValueRef json = [value cy$toJSON:key inContext:context])
2563             return json;
2564         else
2565             return CYCastJSValue(context, CYJSString(context, [value description]));
2566     } CYPoolCatch(NULL)
2567 } CYCatch(NULL) return /*XXX*/ NULL; }
2568
2569 static JSValueRef Instance_callAsFunction_valueOf(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2570     if (!CYJSValueIsNSObject(context, _this))
2571         return NULL;
2572
2573     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(_this)));
2574     id value(internal->GetValue());
2575     _assert(value != nil);
2576
2577     if (![value respondsToSelector:@selector(cy$valueOfInContext:)])
2578         return _this;
2579
2580     if (JSValueRef result = [value cy$valueOfInContext:context])
2581         return result;
2582
2583     return _this;
2584 } CYCatch(NULL) return /*XXX*/ NULL; }
2585
2586 static JSValueRef Instance_callAsFunction_toPointer(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2587     if (!CYJSValueIsNSObject(context, _this))
2588         return NULL;
2589
2590     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(_this)));
2591     // XXX: but... but... THIS ISN'T A POINTER! :(
2592     return CYCastJSValue(context, reinterpret_cast<uintptr_t>(internal->GetValue()));
2593 } CYCatch(NULL) return /*XXX*/ NULL; }
2594
2595 static JSValueRef Instance_callAsFunction_toString(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2596     if (!CYJSValueIsNSObject(context, _this))
2597         return NULL;
2598
2599     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(_this)));
2600     id value(internal->GetValue());
2601
2602     CYPoolTry {
2603         // XXX: this seems like a stupid implementation; what if it crashes? why not use the CYONifier backend?
2604         return CYCastJSValue(context, CYJSString(context, [value description]));
2605     } CYPoolCatch(NULL)
2606 } CYCatch(NULL) return /*XXX*/ NULL; }
2607
2608 static JSValueRef Class_callAsFunction_pointerTo(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2609     if (!CYJSValueIsNSObject(context, _this))
2610         return NULL;
2611
2612     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(_this)));
2613     id value(internal->GetValue());
2614
2615     if (!CYIsClass(value))
2616         CYThrow("non-Class object cannot be used as Type");
2617
2618     sig::Type type;
2619     memset(&type, 0, sizeof(type));
2620     type.primitive = sig::object_P;
2621     type.name = class_getName(value);
2622     return CYMakeType(context, &type);
2623 } CYCatch(NULL) return /*XXX*/ NULL; }
2624
2625 static JSValueRef Selector_callAsFunction_toString(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2626     Selector_privateData *internal(reinterpret_cast<Selector_privateData *>(JSObjectGetPrivate(_this)));
2627     return CYCastJSValue(context, sel_getName(internal->GetValue()));
2628 } CYCatch(NULL) }
2629
2630 static JSValueRef Selector_callAsFunction_toJSON(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2631     return Selector_callAsFunction_toString(context, object, _this, count, arguments, exception);
2632 }
2633
2634 static JSValueRef Selector_callAsFunction_toCYON(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2635     Selector_privateData *internal(reinterpret_cast<Selector_privateData *>(JSObjectGetPrivate(_this)));
2636     const char *name(sel_getName(internal->GetValue()));
2637
2638     CYPoolTry {
2639         NSString *string([NSString stringWithFormat:@"@selector(%s)", name]);
2640         return CYCastJSValue(context, CYJSString(context, string));
2641     } CYPoolCatch(NULL)
2642 } CYCatch(NULL) return /*XXX*/ NULL; }
2643
2644 static JSValueRef Selector_callAsFunction_type(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2645     if (count != 1)
2646         throw CYJSError(context, "incorrect number of arguments to Selector.type");
2647
2648     CYPool pool;
2649     Selector_privateData *internal(reinterpret_cast<Selector_privateData *>(JSObjectGetPrivate(_this)));
2650     SEL sel(internal->GetValue());
2651
2652     Class _class(_require(CYCastClass(pool, context, arguments[0])));
2653     objc_method *method(_require(class_getInstanceMethod(_class, sel)));
2654     const char *encoding(method_getTypeEncoding(method));
2655
2656     sig::Signature signature;
2657     sig::Parse(pool, &signature, encoding, &Structor_);
2658     return CYMakeType(context, &signature);
2659 } CYCatch(NULL) }
2660
2661 static JSStaticValue Selector_staticValues[2] = {
2662     {"value", &CYValue_getProperty_value, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontDelete},
2663     {NULL, NULL, NULL, 0}
2664 };
2665
2666 // XXX: this is sadly duplicated in FunctionInstance_staticValues
2667 static JSStaticValue Instance_staticValues[5] = {
2668     {"constructor", &Instance_getProperty_constructor, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2669     {"messages", &Instance_getProperty_messages, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2670     {"prototype", &Instance_getProperty_prototype, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2671     {"value", &CYValue_getProperty_value, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2672     {NULL, NULL, NULL, 0}
2673 };
2674
2675 static JSStaticValue FunctionInstance_staticValues[6] = {
2676     {"type", &FunctionInstance_getProperty_type, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2677     // XXX: this is sadly a duplicate of Instance_staticValues
2678     {"constructor", &Instance_getProperty_constructor, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2679     {"messages", &Instance_getProperty_messages, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2680     {"prototype", &Instance_getProperty_prototype, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2681     {"value", &CYValue_getProperty_value, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2682     {NULL, NULL, NULL, 0}
2683 };
2684
2685 static JSStaticFunction Instance_staticFunctions[7] = {
2686     {"$cya", &CYValue_callAsFunction_$cya, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2687     {"toCYON", &Instance_callAsFunction_toCYON, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2688     {"toJSON", &Instance_callAsFunction_toJSON, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2689     {"valueOf", &Instance_callAsFunction_valueOf, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2690     {"toPointer", &Instance_callAsFunction_toPointer, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2691     {"toString", &Instance_callAsFunction_toString, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2692     {NULL, NULL, 0}
2693 };
2694
2695 static JSStaticFunction Class_staticFunctions[2] = {
2696     {"pointerTo", &Class_callAsFunction_pointerTo, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2697     {NULL, NULL, 0}
2698 };
2699
2700 static JSStaticFunction Internal_staticFunctions[2] = {
2701     {"$cya", &Internal_callAsFunction_$cya, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2702     {NULL, NULL, 0}
2703 };
2704
2705 static JSStaticFunction Selector_staticFunctions[5] = {
2706     {"toCYON", &Selector_callAsFunction_toCYON, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2707     {"toJSON", &Selector_callAsFunction_toJSON, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2708     {"toString", &Selector_callAsFunction_toString, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2709     {"type", &Selector_callAsFunction_type, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2710     {NULL, NULL, 0}
2711 };
2712
2713 #ifdef __APPLE__
2714 JSValueRef NSCFType$cy$toJSON$inContext$(id self, SEL sel, JSValueRef key, JSContextRef context) { CYObjectiveTry_ {
2715     return CYCastJSValue(context, [(NSString *) CFCopyDescription((CFTypeRef) self) autorelease]);
2716 } CYObjectiveCatch }
2717 #endif
2718
2719 void CYObjectiveC_Initialize() { /*XXX*/ JSContextRef context(NULL); CYPoolTry {
2720     CYPool &pool(CYGetGlobalPool());
2721
2722     Object_type = new(pool) Type_privateData(sig::object_P);
2723     Selector_type = new(pool) Type_privateData(sig::selector_P);
2724
2725     NSArray_ = objc_getClass("NSArray");
2726     NSBlock_ = objc_getClass("NSBlock");
2727     NSDictionary_ = objc_getClass("NSDictionary");
2728     NSNumber_ = objc_getClass("NSNumber");
2729     NSString_ = objc_getClass("NSString");
2730     Object_ = objc_getClass("Object");
2731
2732 #ifdef __APPLE__
2733     __NSMallocBlock__ = objc_getClass("__NSMallocBlock__");
2734
2735     // XXX: apparently, iOS now has both of these
2736     NSCFBoolean_ = objc_getClass("__NSCFBoolean");
2737     if (NSCFBoolean_ == nil)
2738         NSCFBoolean_ = objc_getClass("NSCFBoolean");
2739
2740     NSCFType_ = objc_getClass("NSCFType");
2741
2742     NSZombie_ = objc_getClass("_NSZombie_");
2743 #else
2744     NSBoolNumber_ = objc_getClass("NSBoolNumber");
2745     NSZombie_ = objc_getClass("NSZombie");
2746 #endif
2747
2748     JSClassDefinition definition;
2749
2750     definition = kJSClassDefinitionEmpty;
2751     definition.className = "Instance";
2752     definition.staticValues = Instance_staticValues;
2753     definition.staticFunctions = Instance_staticFunctions;
2754     definition.hasProperty = &Instance_hasProperty;
2755     definition.getProperty = &Instance_getProperty;
2756     definition.setProperty = &Instance_setProperty;
2757     definition.deleteProperty = &Instance_deleteProperty;
2758     definition.getPropertyNames = &Instance_getPropertyNames;
2759     definition.callAsConstructor = &Instance_callAsConstructor;
2760     definition.hasInstance = &Instance_hasInstance;
2761     definition.finalize = &CYFinalize;
2762     Instance_ = JSClassCreate(&definition);
2763
2764     definition.className = "ArrayInstance";
2765     ArrayInstance_ = JSClassCreate(&definition);
2766
2767     definition.className = "BooleanInstance";
2768     BooleanInstance_ = JSClassCreate(&definition);
2769
2770     definition.className = "NumberInstance";
2771     NumberInstance_ = JSClassCreate(&definition);
2772
2773     definition.className = "ObjectInstance";
2774     ObjectInstance_ = JSClassCreate(&definition);
2775
2776     definition.className = "StringInstance";
2777     StringInstance_ = JSClassCreate(&definition);
2778
2779     definition.className = "FunctionInstance";
2780     definition.staticValues = FunctionInstance_staticValues;
2781     definition.callAsFunction = &FunctionInstance_callAsFunction;
2782     FunctionInstance_ = JSClassCreate(&definition);
2783
2784     definition = kJSClassDefinitionEmpty;
2785     definition.className = "Class";
2786     definition.staticFunctions = Class_staticFunctions;
2787     Class_ = JSClassCreate(&definition);
2788
2789     definition = kJSClassDefinitionEmpty;
2790     definition.className = "Internal";
2791     definition.staticFunctions = Internal_staticFunctions;
2792     definition.hasProperty = &Internal_hasProperty;
2793     definition.getProperty = &Internal_getProperty;
2794     definition.setProperty = &Internal_setProperty;
2795     definition.getPropertyNames = &Internal_getPropertyNames;
2796     definition.finalize = &CYFinalize;
2797     Internal_ = JSClassCreate(&definition);
2798
2799     definition = kJSClassDefinitionEmpty;
2800     definition.className = "Message";
2801     definition.staticFunctions = cy::Functor::StaticFunctions;
2802     definition.staticValues = cy::Functor::StaticValues;
2803     definition.callAsFunction = &Message_callAsFunction;
2804     definition.finalize = &CYFinalize;
2805     Message_ = JSClassCreate(&definition);
2806
2807     definition = kJSClassDefinitionEmpty;
2808     definition.className = "Messages";
2809     definition.hasProperty = &Messages_hasProperty;
2810     definition.getProperty = &Messages_getProperty;
2811     definition.setProperty = &Messages_setProperty;
2812     definition.getPropertyNames = &Messages_getPropertyNames;
2813     definition.finalize = &CYFinalize;
2814     Messages_ = JSClassCreate(&definition);
2815
2816     definition = kJSClassDefinitionEmpty;
2817     definition.className = "Selector";
2818     definition.staticValues = Selector_staticValues;
2819     definition.staticFunctions = Selector_staticFunctions;
2820     definition.callAsFunction = &Selector_callAsFunction;
2821     definition.finalize = &CYFinalize;
2822     Selector_ = JSClassCreate(&definition);
2823
2824     definition = kJSClassDefinitionEmpty;
2825     definition.className = "Super";
2826     definition.staticFunctions = Internal_staticFunctions;
2827     definition.finalize = &CYFinalize;
2828     Super_ = JSClassCreate(&definition);
2829
2830     definition = kJSClassDefinitionEmpty;
2831     definition.className = "ObjectiveC::Classes";
2832     definition.hasProperty = &ObjectiveC_Classes_hasProperty;
2833     definition.getProperty = &ObjectiveC_Classes_getProperty;
2834     definition.getPropertyNames = &ObjectiveC_Classes_getPropertyNames;
2835     ObjectiveC_Classes_ = JSClassCreate(&definition);
2836
2837     definition = kJSClassDefinitionEmpty;
2838     definition.className = "ObjectiveC::Constants";
2839     definition.getProperty = &ObjectiveC_Constants_getProperty;
2840     definition.getPropertyNames = &ObjectiveC_Constants_getPropertyNames;
2841     ObjectiveC_Constants_ = JSClassCreate(&definition);
2842
2843 #ifdef __APPLE__
2844     definition = kJSClassDefinitionEmpty;
2845     definition.className = "ObjectiveC::Images";
2846     definition.getProperty = &ObjectiveC_Images_getProperty;
2847     definition.getPropertyNames = &ObjectiveC_Images_getPropertyNames;
2848     ObjectiveC_Images_ = JSClassCreate(&definition);
2849
2850     definition = kJSClassDefinitionEmpty;
2851     definition.className = "ObjectiveC::Image::Classes";
2852     definition.getProperty = &ObjectiveC_Image_Classes_getProperty;
2853     definition.getPropertyNames = &ObjectiveC_Image_Classes_getPropertyNames;
2854     ObjectiveC_Image_Classes_ = JSClassCreate(&definition);
2855 #endif
2856
2857     definition = kJSClassDefinitionEmpty;
2858     definition.className = "ObjectiveC::Protocols";
2859     definition.getProperty = &ObjectiveC_Protocols_getProperty;
2860     definition.getPropertyNames = &ObjectiveC_Protocols_getPropertyNames;
2861     ObjectiveC_Protocols_ = JSClassCreate(&definition);
2862
2863 #ifdef __APPLE__
2864     class_addMethod(NSCFType_, @selector(cy$toJSON:inContext:), reinterpret_cast<IMP>(&NSCFType$cy$toJSON$inContext$),
2865         // XXX: this is horrible; there has to be a better way to do this
2866     #ifdef __LP64__
2867         "^{OpaqueJSValue=}32@0:8@16^{OpaqueJSContext=}24"
2868     #else
2869         "^{OpaqueJSValue=}16@0:4@8^{OpaqueJSContext=}12"
2870     #endif
2871     );
2872 #endif
2873 } CYPoolCatch() }
2874
2875 void CYObjectiveC_SetupContext(JSContextRef context) { CYPoolTry {
2876     JSObjectRef global(CYGetGlobalObject(context));
2877     JSObjectRef cy(CYCastJSObject(context, CYGetProperty(context, global, cy_s)));
2878     JSObjectRef cycript(CYCastJSObject(context, CYGetProperty(context, global, CYJSString("Cycript"))));
2879     JSObjectRef all(CYCastJSObject(context, CYGetProperty(context, cycript, CYJSString("all"))));
2880     JSObjectRef alls(CYCastJSObject(context, CYGetProperty(context, cycript, CYJSString("alls"))));
2881
2882     JSObjectRef ObjectiveC(JSObjectMake(context, NULL, NULL));
2883     CYSetProperty(context, cycript, CYJSString("ObjectiveC"), ObjectiveC);
2884
2885     JSObjectRef protocols(JSObjectMake(context, ObjectiveC_Protocols_, NULL));
2886     CYSetProperty(context, ObjectiveC, CYJSString("protocols"), protocols);
2887     CYArrayPush(context, alls, protocols);
2888
2889     JSObjectRef classes(JSObjectMake(context, ObjectiveC_Classes_, NULL));
2890     CYSetProperty(context, ObjectiveC, CYJSString("classes"), classes);
2891     CYArrayPush(context, alls, classes);
2892
2893     JSObjectRef constants(JSObjectMake(context, ObjectiveC_Constants_, NULL));
2894     CYSetProperty(context, ObjectiveC, CYJSString("constants"), constants);
2895     CYArrayPush(context, alls, constants);
2896
2897 #ifdef __APPLE__
2898     CYSetProperty(context, ObjectiveC, CYJSString("images"), JSObjectMake(context, ObjectiveC_Images_, NULL));
2899 #endif
2900
2901     JSObjectRef Class(JSObjectMakeConstructor(context, Class_, NULL));
2902     JSObjectRef Instance(JSObjectMakeConstructor(context, Instance_, &Instance_new));
2903     JSObjectRef Message(JSObjectMakeConstructor(context, Message_, NULL));
2904     JSObjectRef Selector(JSObjectMakeConstructor(context, Selector_, &Selector_new));
2905     JSObjectRef Super(JSObjectMakeConstructor(context, Super_, &Super_new));
2906
2907     JSObjectRef Instance_prototype(CYCastJSObject(context, CYGetProperty(context, Instance, prototype_s)));
2908     CYSetProperty(context, cy, CYJSString("Instance_prototype"), Instance_prototype);
2909
2910     JSObjectRef ArrayInstance(JSObjectMakeConstructor(context, ArrayInstance_, NULL));
2911     JSObjectRef ArrayInstance_prototype(CYCastJSObject(context, CYGetProperty(context, ArrayInstance, prototype_s)));
2912     CYSetProperty(context, cy, CYJSString("ArrayInstance_prototype"), ArrayInstance_prototype);
2913     JSObjectRef Array_prototype(CYGetCachedObject(context, CYJSString("Array_prototype")));
2914     CYSetPrototype(context, ArrayInstance_prototype, Array_prototype);
2915
2916     JSObjectRef BooleanInstance(JSObjectMakeConstructor(context, BooleanInstance_, NULL));
2917     JSObjectRef BooleanInstance_prototype(CYCastJSObject(context, CYGetProperty(context, BooleanInstance, prototype_s)));
2918     CYSetProperty(context, cy, CYJSString("BooleanInstance_prototype"), BooleanInstance_prototype);
2919     JSObjectRef Boolean_prototype(CYGetCachedObject(context, CYJSString("Boolean_prototype")));
2920     CYSetPrototype(context, BooleanInstance_prototype, Boolean_prototype);
2921
2922     JSObjectRef FunctionInstance(JSObjectMakeConstructor(context, FunctionInstance_, NULL));
2923     JSObjectRef FunctionInstance_prototype(CYCastJSObject(context, CYGetProperty(context, FunctionInstance, prototype_s)));
2924     CYSetProperty(context, cy, CYJSString("FunctionInstance_prototype"), FunctionInstance_prototype);
2925     JSObjectRef Function_prototype(CYGetCachedObject(context, CYJSString("Function_prototype")));
2926     CYSetPrototype(context, FunctionInstance_prototype, Function_prototype);
2927
2928     JSObjectRef NumberInstance(JSObjectMakeConstructor(context, NumberInstance_, NULL));
2929     JSObjectRef NumberInstance_prototype(CYCastJSObject(context, CYGetProperty(context, NumberInstance, prototype_s)));
2930     CYSetProperty(context, cy, CYJSString("NumberInstance_prototype"), NumberInstance_prototype);
2931     JSObjectRef Number_prototype(CYGetCachedObject(context, CYJSString("Number_prototype")));
2932     CYSetPrototype(context, NumberInstance_prototype, Number_prototype);
2933
2934     JSObjectRef ObjectInstance(JSObjectMakeConstructor(context, ObjectInstance_, NULL));
2935     JSObjectRef ObjectInstance_prototype(CYCastJSObject(context, CYGetProperty(context, ObjectInstance, prototype_s)));
2936     CYSetProperty(context, cy, CYJSString("ObjectInstance_prototype"), ObjectInstance_prototype);
2937     JSObjectRef Object_prototype(CYGetCachedObject(context, CYJSString("Object_prototype")));
2938     CYSetPrototype(context, ObjectInstance_prototype, Object_prototype);
2939
2940     JSObjectRef StringInstance(JSObjectMakeConstructor(context, StringInstance_, NULL));
2941     JSObjectRef StringInstance_prototype(CYCastJSObject(context, CYGetProperty(context, StringInstance, prototype_s)));
2942     CYSetProperty(context, cy, CYJSString("StringInstance_prototype"), StringInstance_prototype);
2943     JSObjectRef String_prototype(CYGetCachedObject(context, CYJSString("String_prototype")));
2944     CYSetPrototype(context, StringInstance_prototype, String_prototype);
2945
2946     JSObjectRef Class_prototype(CYCastJSObject(context, CYGetProperty(context, Class, prototype_s)));
2947     CYSetProperty(context, cy, CYJSString("Class_prototype"), Class_prototype);
2948     CYSetPrototype(context, Class_prototype, Instance_prototype);
2949
2950     CYSetProperty(context, cycript, CYJSString("Instance"), Instance);
2951     CYSetProperty(context, cycript, CYJSString("Selector"), Selector);
2952     CYSetProperty(context, cycript, CYJSString("objc_super"), Super);
2953
2954     JSObjectRef box(JSObjectMakeFunctionWithCallback(context, CYJSString("box"), &Instance_box_callAsFunction));
2955     CYSetProperty(context, Instance, CYJSString("box"), box, kJSPropertyAttributeDontEnum);
2956
2957 #ifdef __APPLE__
2958     CYSetProperty(context, all, CYJSString("choose"), &choose, kJSPropertyAttributeDontEnum);
2959 #endif
2960
2961     CYSetProperty(context, all, CYJSString("objc_msgSend"), &$objc_msgSend, kJSPropertyAttributeDontEnum);
2962
2963     CYSetPrototype(context, CYCastJSObject(context, CYGetProperty(context, Message, prototype_s)), Function_prototype);
2964     CYSetPrototype(context, CYCastJSObject(context, CYGetProperty(context, Selector, prototype_s)), Function_prototype);
2965 } CYPoolCatch() }
2966
2967 static void *CYObjectiveC_CastSymbol(const char *name) {
2968     if (false);
2969 #ifdef __GNU_LIBOBJC__
2970     else if (strcmp(name, "object_getClass") == 0)
2971         return reinterpret_cast<void *>(&object_getClass);
2972 #endif
2973     return NULL;
2974 }
2975
2976 static CYHook CYObjectiveCHook = {
2977     &CYObjectiveC_ExecuteStart,
2978     &CYObjectiveC_ExecuteEnd,
2979     &CYObjectiveC_CallFunction,
2980     &CYObjectiveC_Initialize,
2981     &CYObjectiveC_SetupContext,
2982     &CYObjectiveC_PoolFFI,
2983     &CYObjectiveC_FromFFI,
2984     &CYObjectiveC_CastSymbol,
2985 };
2986
2987 CYRegisterHook CYObjectiveC(&CYObjectiveCHook);
2988
2989 extern "C" void CydgetSetupContext(JSGlobalContextRef context) { CYObjectiveTry_ {
2990     CYSetupContext(context);
2991 } CYObjectiveCatch }
2992
2993 extern "C" void CydgetMemoryParse(const uint16_t **data, size_t *size) { try {
2994     CYPool pool;
2995
2996     CYUTF8String utf8(CYPoolUTF8String(pool, CYUTF16String(*data, *size)));
2997     CYStream stream(utf8.data, utf8.data + utf8.size);
2998     utf8 = CYPoolCode(pool, stream);
2999
3000     CYUTF16String utf16(CYPoolUTF16String(pool, CYUTF8String(utf8.data, utf8.size)));
3001     size_t bytes(utf16.size * sizeof(uint16_t));
3002     uint16_t *copy(reinterpret_cast<uint16_t *>(malloc(bytes)));
3003     memcpy(copy, utf16.data, bytes);
3004
3005     *data = copy;
3006     *size = utf16.size;
3007 } catch (const CYException &exception) {
3008     CYPool pool;
3009     @throw [NSException exceptionWithName:NSRangeException reason:[NSString stringWithFormat:@"%s", exception.PoolCString(pool)] userInfo:nil];
3010 } }