configure.ac

   1 dnl Cycript - Optimizing JavaScript Compiler/Runtime
   2 dnl Copyright (C) 2009-2013  Jay Freeman (saurik)
   3
   4 dnl GNU General Public License, Version 3 {{{
   5 dnl
   6 dnl Cycript is free software: you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published
   8 dnl by the Free Software Foundation, either version 3 of the License,
   9 dnl or (at your option) any later version.
  10 dnl
  11 dnl Cycript is distributed in the hope that it will be useful, but
  12 dnl WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with Cycript.  If not, see <http://www.gnu.org/licenses/>.
  18 dnl }}}
  19
  20 AC_PREREQ([2.65])
  21 AC_INIT([Cycript], [0.9], [saurik@saurik.com], [cycript], [http://www.cycript.org/])
  22 AC_COPYRIGHT([Copyright (C) 2009-2012  Jay Freeman (saurik)])
  23
  24 AC_CONFIG_SRCDIR([Console.cpp])
  25 AC_CONFIG_AUX_DIR([.])
  26 AC_CONFIG_MACRO_DIR([m4])
  27
  28 AM_INIT_AUTOMAKE([-Wall -Werror foreign])
  29
  30 AC_PROG_CXX
  31 AC_PROG_OBJCXX
  32 AM_PROG_AR
  33 AC_PROG_INSTALL
  34
  35 LT_INIT([disable-static])
  36
  37 AC_LANG([C++])
  38
  39 PKG_PROG_PKG_CONFIG([0.22])
  40
  41 AX_CHECK_GNU_MAKE
  42 AC_SUBST([GMAKE], [$_cv_gnu_make_command])
  43 AS_IF([test "x$GMAKE" = x], [AC_MSG_ERROR([You need GNU make])])
  44
  45 AC_PATH_PROG([_BASH], [bash], [AC_MSG_ERROR([missing "bash"])])
  46 AC_PATH_PROG([GIT], [git])
  47 AC_PATH_PROG([TIME], [time])
  48
  49 dnl CY_CHECK_PROGS_VERSION {{{
  50 AC_DEFUN([CY_CHECK_PROGS_VERSION], [
  51     AC_ARG_VAR(]$1[, ]$3[)
  52
  53     AC_MSG_CHECKING(for ]$2[ >= ]$5[)
  54     AC_PATH_PROGS_FEATURE_CHECK(]$1[, ]$2[,
  55         AS_VAR_SET(version, [`$ac_path_]$1[ ]$4[`])
  56         AS_VAR_IF(version, [], ,
  57             AS_VERSION_COMPARE($version, ]$5[, ,
  58                 ac_cv_path_]$1[=$ac_path_]$1[,
  59                 ac_cv_path_]$1[=$ac_path_]$1[))
  60     , AC_MSG_RESULT(no))
  61
  62     AS_IF([true], [
  63         AC_SUBST(]$1[, $ac_cv_path_]$1[)
  64         AC_MSG_RESULT($]$1[)
  65     ], AS_IF([true], [
  66         AC_MSG_ERROR(You need ]$2[ ]$5[ or greater)
  67     ], [
  68         AC_SUBST(]$1[, [:])
  69         AC_MSG_RESULT([no])
  70     ]))
  71 ]) dnl }}}
  72
  73 CY_CHECK_PROGS_VERSION([BISON], [bison], [GNU Project parser generator (yacc replacement)],
  74     [-V | $SED -e '1 s/^bison (GNU Bison) \(.*\)$/\1/p;d'], [2.3])
  75 CY_CHECK_PROGS_VERSION([FLEX], [flex], [the fast lexical analyser generator],
  76     [--version | $SED -e '1 s/^@<:@^0-9.@:>@* \(@<:@0-9.@:>@*\).*$/\1/p;d'], [2.5.33])
  77 CY_CHECK_PROGS_VERSION([GPERF], [gperf], [perfect hash function generator],
  78     [--version | $SED -e '1 s/^.* \(@<:@0-9.@:>@*\)$/\1/p;d'], [3.0.3])
  79 CY_CHECK_PROGS_VERSION([GNUTAR], [tar gtar gnutar], [a very sticky lump of files],
  80     [--version | $SED -e '1 s/^tar (GNU tar) \(.*\)$/\1/p;d'], [1.19])
  81
  82 AC_MSG_CHECKING([bison for %code{}])
  83 echo '%code{}%%_:' >conftest.y
  84 if $BISON conftest.y -o/dev/null 2>/dev/null; then
  85     AC_LIB_APPENDTOVAR([CY_FILTERS], [Bison24])
  86     AC_MSG_RESULT([yes])
  87 else
  88     AC_LIB_APPENDTOVAR([CY_FILTERS], [Bison23])
  89     AC_MSG_RESULT([no])
  90 fi
  91
  92 rm -f conftest.y
  93 AC_SUBST([CY_FILTERS])
  94
  95 dnl CY_TRY {{{
  96 AC_DEFUN([CY_SUCCESS], [cy_good=1])
  97 AC_DEFUN([CY_FAILURE], [cy_good=0])
  98
  99 AC_DEFUN([CY_TRY], [
 100     cy_save=$]$1[
 101         AC_LIB_APPENDTOVAR(]$1[, ]$2[)
 102         ]$3[
 103     ]$1[=$cy_save
 104     AS_IF([test "x$cy_good" = x1], ]$4[, ]$5[)
 105 ]) dnl }}}
 106
 107 AC_DEFUN([CY_COMPILE_FLAG], [
 108     AC_LIB_APPENDTOVAR([CFLAGS], ]$1[)
 109     AC_LIB_APPENDTOVAR([CXXFLAGS], ]$1[)
 110     AC_LIB_APPENDTOVAR([OBJCCXXFLAGS], ]$1[)
 111 ])
 112
 113 AC_DEFUN([CY_TEST_FLAG], [
 114     AC_MSG_CHECKING([for ]]$1[)
 115     CY_TRY([CXXFLAGS], $1, [
 116         AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
 117             [CY_SUCCESS], [CY_FAILURE])
 118     ], [
 119         AC_MSG_RESULT([yes])
 120         CY_COMPILE_FLAG($1)
 121     ], [AC_MSG_RESULT([no])])
 122 ])
 123
 124 AX_CFLAGS_WARN_ALL
 125 AX_CXXFLAGS_WARN_ALL
 126
 127 CY_TEST_FLAG([-Wno-overloaded-virtual])
 128 CY_TEST_FLAG([-Wno-parentheses])
 129 CY_TEST_FLAG([-Wno-unneeded-internal-declaration])
 130
 131 dnl -arch * {{{
 132 for cy_arch in ppc ppc64 i386 x86_64 armv6; do
 133     AC_MSG_CHECKING([for -arch $cy_arch])
 134     CY_TRY([CXXFLAGS], ["-arch $cy_arch"], [
 135         AC_TRY_LINK([], [], [CY_SUCCESS], [CY_FAILURE])
 136     ], [
 137         AC_MSG_RESULT([yes])
 138         AC_LIB_APPENDTOVAR([CY_ARCH], ["-arch $cy_arch"])
 139     ], [AC_MSG_RESULT([no])])
 140 done
 141 AC_SUBST([CY_ARCH])
 142 dnl }}}
 143
 144 dnl --with-frameworks {{{
 145 AC_ARG_WITH([frameworks], [AS_HELP_STRING(
 146     [--with-frameworks=DIRS],
 147     [add to DIRS (space separated) to the Darwin include path for frameworks with -F]
 148 )], [
 149     for cy_framework in $withval; do
 150         CY_COMPILE_FLAG([-F$cy_framework])
 151     done
 152 ]) dnl }}}
 153 dnl --enable-javascript {{{
 154 AC_DEFUN([CY_CHECK_JAVASCRIPTCORE], [
 155     PKG_CHECK_MODULES([WEBKIT], [webkit-1.0], [
 156         AC_SUBST([CY_EXECUTE], [1])
 157         AC_LIB_APPENDTOVAR([CXXFLAGS], [`$PKG_CONFIG --cflags webkit-1.0`])
 158         AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs webkit-1.0`])
 159     ], [
 160         PKG_CHECK_MODULES([WEBKIT], [WebKitGtk], [
 161             AC_SUBST([CY_EXECUTE], [1])
 162             AC_LIB_APPENDTOVAR([CXXFLAGS], [`$PKG_CONFIG --cflags WebKitGtk`])
 163             AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs WebKitGtk`])
 164         ], [
 165             AC_CHECK_FRAMEWORK([JavaScriptCore], [
 166                 #include <JavaScriptCore/JSBase.h>
 167             ], [
 168                 JSEvaluateScript(0, 0, 0, 0, 0, 0);
 169             ], [
 170                 AC_SUBST([CY_EXECUTE], [1])
 171             ])
 172         ])
 173     ])
 174 ])
 175
 176 AC_DEFUN([CY_CHECK_JAVASCRIPT], [
 177     CY_CHECK_JAVASCRIPTCORE])
 178
 179 AC_ARG_ENABLE([javascript], [AS_HELP_STRING(
 180     [--enable-javascript@<:@=ENGINE@:>@],
 181     [use a JavaScript runtime (currently the only available option for ENGINE is JavaScriptCore) @<:@default=yes@:>@]
 182 )], [
 183     AS_CASE([$enableval],
 184         [yes], [
 185             CY_CHECK_JAVASCRIPT],
 186         [no], [
 187             AC_SUBST([CY_EXECUTE], [0])],
 188         [JavaScriptCore], [
 189             CY_CHECK_JAVASCRIPTCORE],
 190         [AC_MSG_ERROR([Unknown JavaScript engine: $enableval])])
 191 ], [CY_CHECK_JAVASCRIPT])
 192 dnl }}}
 193
 194 dnl APR_FIND_APR {{{
 195 APR_FIND_APR([], [], [1], [1])
 196 AS_CASE([$apr_found], [yes], [
 197     AC_LIB_APPENDTOVAR([CPPFLAGS], [`$apr_config --includes`])
 198     AC_LIB_APPENDTOVAR([LTLIBAPR], [`$apr_config --link-libtool`])
 199     AC_SUBST([LTLIBAPR])
 200 ], [AC_MSG_ERROR([missing "libapr"])])
 201 dnl }}}
 202
 203 AC_DEFUN([CY_CHECK_PKG_CONFIG_LIBFFI], [
 204     PKG_CHECK_MODULES([LIBFFI], [libffi], [
 205         AC_LIB_APPENDTOVAR([CXXFLAGS], [`$PKG_CONFIG --cflags libffi`])
 206         AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs libffi`])
 207     ], [AC_MSG_ERROR([missing "libffi"])])])
 208
 209 AM_CONDITIONAL([CY_EXECUTE], [test "x$CY_EXECUTE" = x1])
 210
 211 AS_CASE([$CY_EXECUTE], [1], [
 212     AC_CHECK_HEADERS([ffi.h ffi/ffi.h], [break])
 213     AS_IF([test "x$ac_cv_header_ffi_h" = xno && test "x$ac_cv_header_ffi_ffi_h" = xno], [
 214         CY_CHECK_PKG_CONFIG_LIBFFI
 215     ], [
 216         AC_SEARCH_LIBS([ffi_call], [ffi])
 217         AS_CASE([$ac_cv_search_ffi_call], [no], [CY_CHECK_PKG_CONFIG_LIBFFI])
 218     ])
 219
 220     AC_LANG_PUSH([Objective C++])
 221
 222     AC_MSG_CHECKING([if we really have Objective C++])
 223     AC_COMPILE_IFELSE([AC_LANG_SOURCE([])], [
 224         CY_OBJECTIVEC=1
 225         AC_MSG_RESULT([yes])
 226     ], [AC_MSG_RESULT([no])])
 227
 228     AS_IF([test "x$CY_OBJECTIVEC" = x1], [
 229         AC_CHECK_FRAMEWORK([CoreFoundation], [
 230             #include <CoreFoundation/CFBase.h>
 231         ], [CFAllocatorGetDefault();], [
 232             AC_SUBST([CY_OBJECTIVEC])
 233
 234             AC_CHECK_FRAMEWORK([Foundation], [
 235                 #include <Foundation/NSObject.h>
 236             ], [[[[NSObject alloc] init];]])
 237
 238             AC_CHECK_FRAMEWORK([WebKit], [
 239                 #include <WebKit/WebScriptObject.h>
 240             ], [[[[WebScriptObject alloc] init];]])
 241         ], [
 242             AC_ARG_VAR([GNUSTEP_CONFIG], [prints information about the current gnustep installation])
 243             AC_CHECK_PROGS([GNUSTEP_CONFIG], [gnustep-config])
 244
 245             AS_IF([test "x$GNUSTEP_CONFIG" != x], [
 246                 AC_SUBST([CY_OBJECTIVEC])
 247                 AC_LIB_APPENDTOVAR([OBJCXXFLAGS], [`$GNUSTEP_CONFIG --objc-flags`])
 248                 AC_LIB_APPENDTOVAR([LIBS], [`$GNUSTEP_CONFIG --base-libs`])
 249             ], [AC_SUBST([CY_OBJECTIVEC], [0])])
 250         ])
 251     ])
 252
 253     AC_LANG_POP([Objective C++])
 254 ])
 255
 256 AM_CONDITIONAL([CY_OBJECTIVEC], [test "x$CY_OBJECTIVEC" = x1])
 257
 258 AC_DEFUN([CY_LT_LIB], [
 259     cy_save=$LIBS
 260     LIBS=
 261     ]$2[
 262     ]$1[=$LIBS
 263     LIBS=$cy_save
 264     AC_SUBST(]$1[)
 265 ])
 266
 267 CY_LT_LIB([LTLIBREADLINE], [AX_LIB_READLINE])
 268 AS_CASE([$ax_cv_lib_readline], [no], [AC_MSG_ERROR([missing "libreadline"])])
 269
 270 CY_LT_LIB([LTLIBTERMCAP], [AC_SEARCH_LIBS([cur_term], [termcap])])
 271
 272 dnl XXX: saurik doesn't understand what this does
 273 dnl AM_ICONV {{{
 274 AC_LANG_PUSH([C])
 275 AM_ICONV
 276 AS_CASE([$am_cv_func_iconv], [yes], [], [
 277     for cy_iconv_prefix_arg in $CFLAGS $CXXFLAGS $OBJCXXFLAGS $LDFLAGS $LIBS; do
 278         AS_CASE([$cy_iconv_prefix_arg], [-I*], [
 279             AC_LIB_APPENDTOVAR([cy_iconv_prefixes], [`echo $cy_iconv_prefix_arg | sed -e 's/^-I//;s|/include$||'`])
 280         ], [-L*], [
 281             AC_LIB_APPENDTOVAR([cy_iconv_prefixes], [`echo $cy_iconv_prefix_arg | sed -e 's/^-L//;s|/lib$||'`])
 282         ])
 283     done
 284     for with_libiconv_prefix in $cy_iconv_prefixes; do
 285         AS_UNSET([am_cv_func_iconv])
 286         AM_ICONV_LINKFLAGS_BODY
 287         AM_ICONV
 288     done
 289 ])
 290 AS_CASE([$am_cv_func_iconv], [yes], [], [AC_MSG_ERROR([missing "libiconv"])])
 291 AC_LANG_POP([C])
 292 dnl }}}
 293
 294 AC_SUBST([LTFLAGS])
 295 AC_SUBST([SO], [$acl_shlibext])
 296
 297 AC_CHECK_HEADER([mach/mach.h], [
 298     AC_CHECK_TOOLS([_LIPO], [lipo], [AC_MSG_ERROR([missing "lipo"])])
 299     AC_CHECK_TOOLS([_NM], [nm], [AC_MSG_ERROR([missing "nm"])])
 300     AC_CHECK_TOOLS([_OTOOL], [otool], [AC_MSG_ERROR([missing "otool"])])
 301     AC_SUBST([CY_MACH], [1])
 302     AC_SUBST([CY_ATTACH_GROUP], [procmod])
 303 ])
 304
 305 AM_CONDITIONAL([CY_MACH], [test "x$CY_MACH" = x1])
 306
 307 AC_CONFIG_FILES([Makefile])
 308 AC_OUTPUT