ObjectiveC/Library.mm

   1 /* Cycript - Optimizing JavaScript Compiler/Runtime
   2  * Copyright (C) 2009-2013  Jay Freeman (saurik)
   3 */
   4
   5 /* GNU General Public License, Version 3 {{{ */
   6 /*
   7  * Cycript is free software: you can redistribute it and/or modify
   8  * it under the terms of the GNU General Public License as published
   9  * by the Free Software Foundation, either version 3 of the License,
  10  * or (at your option) any later version.
  11  *
  12  * Cycript is distributed in the hope that it will be useful, but
  13  * WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with Cycript.  If not, see <http://www.gnu.org/licenses/>.
  19 **/
  20 /* }}} */
  21
  22 #include <Foundation/Foundation.h>
  23
  24 #include "ObjectiveC/Internal.hpp"
  25
  26 #include <objc/objc-api.h>
  27
  28 #include "cycript.hpp"
  29
  30 #include "ObjectiveC/Internal.hpp"
  31
  32 #ifdef __APPLE__
  33 #include <CoreFoundation/CoreFoundation.h>
  34 #include <JavaScriptCore/JSStringRefCF.h>
  35 #include <objc/runtime.h>
  36 #endif
  37
  38 #include "Error.hpp"
  39 #include "JavaScript.hpp"
  40 #include "String.hpp"
  41 #include "Execute.hpp"
  42
  43 #include <cmath>
  44 #include <map>
  45
  46 #include <dlfcn.h>
  47
  48 #define CYObjectiveTry_(context) { \
  49     JSContextRef context_(context); \
  50     try
  51 #define CYObjectiveTry { \
  52     try
  53 #define CYObjectiveCatch \
  54     catch (const CYException &error) { \
  55         @throw CYCastNSObject(NULL, context_, error.CastJSValue(context_)); \
  56     } \
  57 }
  58
  59 #define CYPoolTry { \
  60     id _saved(nil); \
  61     NSAutoreleasePool *_pool([[NSAutoreleasePool alloc] init]); \
  62     @try
  63 #define CYPoolCatch(value) \
  64     @catch (NSException *error) { \
  65         _saved = [error retain]; \
  66         throw CYJSError(context, CYCastJSValue(context, error)); \
  67         return value; \
  68     } @finally { \
  69         [_pool release]; \
  70         if (_saved != nil) \
  71             [_saved autorelease]; \
  72     } \
  73 }
  74
  75 #define CYSadTry { \
  76     @try
  77 #define CYSadCatch(value) \
  78     @catch (NSException *error ) { \
  79         throw CYJSError(context, CYCastJSValue(context, error)); \
  80     } return value; \
  81 }
  82
  83 #ifndef __APPLE__
  84 #define class_getSuperclass GSObjCSuper
  85 #define class_getInstanceVariable GSCGetInstanceVariableDefinition
  86 #define class_getName GSNameFromClass
  87
  88 #define class_removeMethods(cls, list) GSRemoveMethodList(cls, list, YES)
  89
  90 #define ivar_getName(ivar) ((ivar)->ivar_name)
  91 #define ivar_getOffset(ivar) ((ivar)->ivar_offset)
  92 #define ivar_getTypeEncoding(ivar) ((ivar)->ivar_type)
  93
  94 #define method_getName(method) ((method)->method_name)
  95 #define method_getImplementation(method) ((method)->method_imp)
  96 #define method_getTypeEncoding(method) ((method)->method_types)
  97 #define method_setImplementation(method, imp) ((void) ((method)->method_imp = (imp)))
  98
  99 #undef objc_getClass
 100 #define objc_getClass GSClassFromName
 101
 102 #define objc_getProtocol GSProtocolFromName
 103
 104 #define object_getClass GSObjCClass
 105
 106 #define object_getInstanceVariable(object, name, value) ({ \
 107     objc_ivar *ivar(class_getInstanceVariable(object_getClass(object), name)); \
 108     _assert(value != NULL); \
 109     if (ivar != NULL) \
 110         GSObjCGetVariable(object, ivar_getOffset(ivar), sizeof(void *), value); \
 111     ivar; \
 112 })
 113
 114 #define object_setIvar(object, ivar, value) ({ \
 115     void *data = (value); \
 116     GSObjCSetVariable(object, ivar_getOffset(ivar), sizeof(void *), &data); \
 117 })
 118
 119 #define protocol_getName(protocol) [(protocol) name]
 120 #endif
 121
 122 static void (*$objc_setAssociatedObject)(id object, void *key, id value, objc_AssociationPolicy policy);
 123 static id (*$objc_getAssociatedObject)(id object, void *key);
 124 static void (*$objc_removeAssociatedObjects)(id object);
 125
 126 struct BlockLiteral {
 127     Class isa;
 128     int flags;
 129     int reserved;
 130     void (*invoke)(void *, ...);
 131     void *descriptor;
 132 };
 133
 134 struct BlockDescriptor1 {
 135     unsigned long int reserved;
 136     unsigned long int size;
 137 };
 138
 139 struct BlockDescriptor2 {
 140     void (*copy_helper)(BlockLiteral *dst, BlockLiteral *src);
 141     void (*dispose_helper)(BlockLiteral *src);
 142 };
 143
 144 struct BlockDescriptor3 {
 145     const char *signature;
 146     const char *layout;
 147 };
 148
 149 enum {
 150     BLOCK_DEALLOCATING = 0x0001,
 151     BLOCK_REFCOUNT_MASK = 0xfffe,
 152     BLOCK_NEEDS_FREE = 1 << 24,
 153     BLOCK_HAS_COPY_DISPOSE = 1 << 25,
 154     BLOCK_HAS_CTOR = 1 << 26,
 155     BLOCK_IS_GC = 1 << 27,
 156     BLOCK_IS_GLOBAL = 1 << 28,
 157     BLOCK_HAS_STRET = 1 << 29,
 158     BLOCK_HAS_SIGNATURE = 1 << 30,
 159 };
 160
 161 JSValueRef CYSendMessage(CYPool &pool, JSContextRef context, id self, Class super, SEL _cmd, size_t count, const JSValueRef arguments[], bool initialize, JSValueRef *exception);
 162
 163 /* Objective-C Pool Release {{{ */
 164 void CYPoolRelease_(void *data) {
 165     id object(reinterpret_cast<id>(data));
 166     [object release];
 167 }
 168
 169 id CYPoolRelease_(CYPool *pool, id object) {
 170     if (object == nil)
 171         return nil;
 172     else if (pool == NULL)
 173         return [object autorelease];
 174     else {
 175         pool->atexit(CYPoolRelease_);
 176         return object;
 177     }
 178 }
 179
 180 template <typename Type_>
 181 Type_ CYPoolRelease(CYPool *pool, Type_ object) {
 182     return (Type_) CYPoolRelease_(pool, (id) object);
 183 }
 184 /* }}} */
 185 /* Objective-C Strings {{{ */
 186 const char *CYPoolCString(CYPool &pool, JSContextRef context, NSString *value) {
 187     size_t size([value maximumLengthOfBytesUsingEncoding:NSUTF8StringEncoding] + 1);
 188     char *string(new(pool) char[size]);
 189     if (![value getCString:string maxLength:size encoding:NSUTF8StringEncoding])
 190         throw CYJSError(context, "[NSString getCString:maxLength:encoding:] == NO");
 191     return string;
 192 }
 193
 194 JSStringRef CYCopyJSString(JSContextRef context, NSString *value) {
 195 #ifdef __APPLE__
 196     return JSStringCreateWithCFString(reinterpret_cast<CFStringRef>(value));
 197 #else
 198     CYPool pool;
 199     return CYCopyJSString(CYPoolCString(pool, context, value));
 200 #endif
 201 }
 202
 203 JSStringRef CYCopyJSString(JSContextRef context, NSObject *value) {
 204     if (value == nil)
 205         return NULL;
 206     // XXX: this definition scares me; is anyone using this?!
 207     NSString *string([value description]);
 208     return CYCopyJSString(context, string);
 209 }
 210
 211 NSString *CYCopyNSString(const CYUTF8String &value) {
 212 #ifdef __APPLE__
 213     return (NSString *) CFStringCreateWithBytes(kCFAllocatorDefault, reinterpret_cast<const UInt8 *>(value.data), value.size, kCFStringEncodingUTF8, true);
 214 #else
 215     return [[NSString alloc] initWithBytes:value.data length:value.size encoding:NSUTF8StringEncoding];
 216 #endif
 217 }
 218
 219 NSString *CYCopyNSString(JSContextRef context, JSStringRef value) {
 220 #ifdef __APPLE__
 221     return (NSString *) JSStringCopyCFString(kCFAllocatorDefault, value);
 222 #else
 223     CYPool pool;
 224     return CYCopyNSString(CYPoolUTF8String(pool, context, value));
 225 #endif
 226 }
 227
 228 NSString *CYCopyNSString(JSContextRef context, JSValueRef value) {
 229     return CYCopyNSString(context, CYJSString(context, value));
 230 }
 231
 232 NSString *CYCastNSString(CYPool *pool, const CYUTF8String &value) {
 233     return CYPoolRelease(pool, CYCopyNSString(value));
 234 }
 235
 236 NSString *CYCastNSString(CYPool *pool, SEL sel) {
 237     const char *name(sel_getName(sel));
 238     return CYPoolRelease(pool, CYCopyNSString(CYUTF8String(name, strlen(name))));
 239 }
 240
 241 NSString *CYCastNSString(CYPool *pool, JSContextRef context, JSStringRef value) {
 242     return CYPoolRelease(pool, CYCopyNSString(context, value));
 243 }
 244
 245 CYUTF8String CYCastUTF8String(NSString *value) {
 246     NSData *data([value dataUsingEncoding:NSUTF8StringEncoding allowLossyConversion:NO]);
 247     return CYUTF8String(reinterpret_cast<const char *>([data bytes]), [data length]);
 248 }
 249 /* }}} */
 250
 251 JSValueRef CYCastJSValue(JSContextRef context, NSObject *value);
 252
 253 void CYThrow(JSContextRef context, NSException *error, JSValueRef *exception) {
 254     if (exception == NULL)
 255         throw error;
 256     *exception = CYCastJSValue(context, error);
 257 }
 258
 259 size_t CYGetIndex(NSString *value) {
 260     return CYGetIndex(CYCastUTF8String(value));
 261 }
 262
 263 bool CYGetOffset(CYPool &pool, JSContextRef context, NSString *value, ssize_t &index) {
 264     return CYGetOffset(CYPoolCString(pool, context, value), index);
 265 }
 266
 267 static JSClassRef Instance_;
 268
 269 static JSClassRef ArrayInstance_;
 270 static JSClassRef FunctionInstance_;
 271 static JSClassRef ObjectInstance_;
 272 static JSClassRef StringInstance_;
 273
 274 static JSClassRef Class_;
 275 static JSClassRef Internal_;
 276 static JSClassRef Message_;
 277 static JSClassRef Messages_;
 278 static JSClassRef Selector_;
 279 static JSClassRef Super_;
 280
 281 static JSClassRef ObjectiveC_Classes_;
 282 static JSClassRef ObjectiveC_Constants_;
 283 static JSClassRef ObjectiveC_Protocols_;
 284
 285 #ifdef __APPLE__
 286 static JSClassRef ObjectiveC_Image_Classes_;
 287 static JSClassRef ObjectiveC_Images_;
 288 #endif
 289
 290 #ifdef __APPLE__
 291 static Class NSCFBoolean_;
 292 static Class NSCFType_;
 293 static Class NSGenericDeallocHandler_;
 294 static Class NSMessageBuilder_;
 295 static Class NSZombie_;
 296 #else
 297 static Class NSBoolNumber_;
 298 #endif
 299
 300 static Class NSArray_;
 301 static Class NSBlock_;
 302 static Class NSDictionary_;
 303 static Class NSString_;
 304 static Class Object_;
 305
 306 static Type_privateData *Object_type;
 307 static Type_privateData *Selector_type;
 308
 309 Type_privateData *Instance::GetType() const {
 310     return Object_type;
 311 }
 312
 313 Type_privateData *Selector_privateData::GetType() const {
 314     return Selector_type;
 315 }
 316
 317 static JSValueRef Instance_callAsFunction_toString(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception);
 318
 319 JSValueRef CYGetClassPrototype(JSContextRef context, Class self, bool meta) {
 320     if (self == nil)
 321         return CYGetCachedObject(context, CYJSString("Instance_prototype"));
 322     else if (meta && !class_isMetaClass(self))
 323         return CYGetCachedObject(context, CYJSString("Class_prototype"));
 324
 325     JSObjectRef global(CYGetGlobalObject(context));
 326     JSObjectRef cy(CYCastJSObject(context, CYGetProperty(context, global, cy_s)));
 327
 328     char label[32];
 329     sprintf(label, "i%p", self);
 330     CYJSString name(label);
 331
 332     JSValueRef value(CYGetProperty(context, cy, name));
 333     if (!JSValueIsUndefined(context, value))
 334         return value;
 335
 336     JSClassRef _class(NULL);
 337     JSValueRef prototype;
 338
 339     if (self == NSArray_)
 340         prototype = CYGetCachedObject(context, CYJSString("ArrayInstance_prototype"));
 341     else if (self == NSBlock_)
 342         prototype = CYGetCachedObject(context, CYJSString("FunctionInstance_prototype"));
 343     else if (self == NSDictionary_)
 344         prototype = CYGetCachedObject(context, CYJSString("ObjectInstance_prototype"));
 345     else if (self == NSString_)
 346         prototype = CYGetCachedObject(context, CYJSString("StringInstance_prototype"));
 347     else
 348         prototype = CYGetClassPrototype(context, class_getSuperclass(self), meta);
 349
 350     JSObjectRef object(JSObjectMake(context, _class, NULL));
 351     JSObjectSetPrototype(context, object, prototype);
 352     CYSetProperty(context, cy, name, object);
 353
 354     return object;
 355 }
 356
 357 _finline JSValueRef CYGetClassPrototype(JSContextRef context, Class self) {
 358     return CYGetClassPrototype(context, self, class_isMetaClass(self));
 359 }
 360
 361 JSObjectRef Messages::Make(JSContextRef context, Class _class) {
 362     JSObjectRef value(JSObjectMake(context, Messages_, new Messages(_class)));
 363     if (Class super = class_getSuperclass(_class))
 364         JSObjectSetPrototype(context, value, Messages::Make(context, super));
 365     return value;
 366 }
 367
 368 JSObjectRef Internal::Make(JSContextRef context, id object, JSObjectRef owner) {
 369     return JSObjectMake(context, Internal_, new Internal(object, context, owner));
 370 }
 371
 372 namespace cy {
 373 JSObjectRef Super::Make(JSContextRef context, id object, Class _class) {
 374     JSObjectRef value(JSObjectMake(context, Super_, new Super(object, _class)));
 375     return value;
 376 } }
 377
 378 JSObjectRef Instance::Make(JSContextRef context, id object, Flags flags) {
 379     JSObjectRef value(JSObjectMake(context, Instance_, new Instance(object, flags)));
 380     JSObjectSetPrototype(context, value, CYGetClassPrototype(context, object_getClass(object)));
 381     return value;
 382 }
 383
 384 Instance::~Instance() {
 385     if ((flags_ & Transient) == 0)
 386         // XXX: does this handle background threads correctly?
 387         // XXX: this simply does not work on the console because I'm stupid
 388         [GetValue() performSelector:@selector(release) withObject:nil afterDelay:0];
 389 }
 390
 391 struct Message_privateData :
 392     cy::Functor
 393 {
 394     SEL sel_;
 395
 396     Message_privateData(SEL sel, const char *type, IMP value = NULL) :
 397         cy::Functor(type, reinterpret_cast<void (*)()>(value)),
 398         sel_(sel)
 399     {
 400     }
 401 };
 402
 403 JSObjectRef CYMakeInstance(JSContextRef context, id object, bool transient) {
 404     Instance::Flags flags;
 405
 406     if (transient)
 407         flags = Instance::Transient;
 408     else {
 409         flags = Instance::None;
 410         object = [object retain];
 411     }
 412
 413     return Instance::Make(context, object, flags);
 414 }
 415
 416 @interface NSMethodSignature (Cycript)
 417 - (NSString *) _typeString;
 418 @end
 419
 420 @interface NSObject (Cycript)
 421
 422 - (JSValueRef) cy$valueOfInContext:(JSContextRef)context;
 423 - (JSType) cy$JSType;
 424
 425 - (JSValueRef) cy$toJSON:(NSString *)key inContext:(JSContextRef)context;
 426 - (NSString *) cy$toCYON:(bool)objective;
 427
 428 - (bool) cy$hasProperty:(NSString *)name;
 429 - (NSObject *) cy$getProperty:(NSString *)name;
 430 - (JSValueRef) cy$getProperty:(NSString *)name inContext:(JSContextRef)context;
 431 - (bool) cy$setProperty:(NSString *)name to:(NSObject *)value;
 432 - (bool) cy$deleteProperty:(NSString *)name;
 433 - (void) cy$getPropertyNames:(JSPropertyNameAccumulatorRef)names inContext:(JSContextRef)context;
 434
 435 + (bool) cy$hasImplicitProperties;
 436
 437 @end
 438
 439 @protocol Cycript
 440 - (id) cy$box;
 441 - (JSValueRef) cy$valueOfInContext:(JSContextRef)context;
 442 @end
 443
 444 NSString *CYCastNSCYON(id value, bool objective) {
 445     NSString *string;
 446
 447     if (value == nil)
 448         string = @"nil";
 449     else {
 450         Class _class(object_getClass(value));
 451         SEL sel(@selector(cy$toCYON:));
 452
 453         if (objc_method *toCYON = class_getInstanceMethod(_class, sel))
 454             string = reinterpret_cast<NSString *(*)(id, SEL, bool)>(method_getImplementation(toCYON))(value, sel, objective);
 455         else if (objc_method *methodSignatureForSelector = class_getInstanceMethod(_class, @selector(methodSignatureForSelector:))) {
 456             if (reinterpret_cast<NSMethodSignature *(*)(id, SEL, SEL)>(method_getImplementation(methodSignatureForSelector))(value, @selector(methodSignatureForSelector:), sel) != nil)
 457                 string = [value cy$toCYON:objective];
 458             else goto fail;
 459         } else fail: {
 460             if (false);
 461 #ifdef __APPLE__
 462             else if (value == NSZombie_)
 463                 string = @"_NSZombie_";
 464             else if (_class == NSZombie_)
 465                 string = [NSString stringWithFormat:@"<_NSZombie_: %p>", value];
 466             // XXX: frowny /in/ the pants
 467             else if (value == NSGenericDeallocHandler_ || value == NSMessageBuilder_ || value == Object_)
 468                 string = nil;
 469 #endif
 470             else
 471                 string = [NSString stringWithFormat:@"%@", value];
 472         }
 473
 474         // XXX: frowny pants
 475         if (string == nil)
 476             string = @"undefined";
 477     }
 478
 479     return string;
 480 }
 481
 482 #ifdef __APPLE__
 483 struct PropertyAttributes {
 484     CYPool pool_;
 485
 486     const char *name;
 487
 488     const char *variable;
 489
 490     const char *getter_;
 491     const char *setter_;
 492
 493     bool readonly;
 494     bool copy;
 495     bool retain;
 496     bool nonatomic;
 497     bool dynamic;
 498     bool weak;
 499     bool garbage;
 500
 501     PropertyAttributes(objc_property_t property) :
 502         variable(NULL),
 503         getter_(NULL),
 504         setter_(NULL),
 505         readonly(false),
 506         copy(false),
 507         retain(false),
 508         nonatomic(false),
 509         dynamic(false),
 510         weak(false),
 511         garbage(false)
 512     {
 513         name = property_getName(property);
 514         const char *attributes(property_getAttributes(property));
 515
 516         for (char *token(pool_.strdup(attributes)), *next; token != NULL; token = next) {
 517             if ((next = strchr(token, ',')) != NULL)
 518                 *next++ = '\0';
 519             switch (*token) {
 520                 case 'R': readonly = true; break;
 521                 case 'C': copy = true; break;
 522                 case '&': retain = true; break;
 523                 case 'N': nonatomic = true; break;
 524                 case 'G': getter_ = token + 1; break;
 525                 case 'S': setter_ = token + 1; break;
 526                 case 'V': variable = token + 1; break;
 527             }
 528         }
 529
 530         /*if (variable == NULL) {
 531             variable = property_getName(property);
 532             size_t size(strlen(variable));
 533             char *name(new(pool_) char[size + 2]);
 534             name[0] = '_';
 535             memcpy(name + 1, variable, size);
 536             name[size + 1] = '\0';
 537             variable = name;
 538         }*/
 539     }
 540
 541     const char *Getter() {
 542         if (getter_ == NULL)
 543             getter_ = pool_.strdup(name);
 544         return getter_;
 545     }
 546
 547     const char *Setter() {
 548         if (setter_ == NULL && !readonly) {
 549             size_t length(strlen(name));
 550
 551             char *temp(new(pool_) char[length + 5]);
 552             temp[0] = 's';
 553             temp[1] = 'e';
 554             temp[2] = 't';
 555
 556             if (length != 0) {
 557                 temp[3] = toupper(name[0]);
 558                 memcpy(temp + 4, name + 1, length - 1);
 559             }
 560
 561             temp[length + 3] = ':';
 562             temp[length + 4] = '\0';
 563             setter_ = temp;
 564         }
 565
 566         return setter_;
 567     }
 568
 569 };
 570 #endif
 571
 572 @interface CYWebUndefined : NSObject {
 573 }
 574
 575 + (CYWebUndefined *) undefined;
 576
 577 @end
 578
 579 @implementation CYWebUndefined
 580
 581 + (CYWebUndefined *) undefined {
 582     static CYWebUndefined *instance_([[CYWebUndefined alloc] init]);
 583     return instance_;
 584 }
 585
 586 @end
 587
 588 #define WebUndefined CYWebUndefined
 589
 590 /* Bridge: CYJSObject {{{ */
 591 @interface CYJSObject : NSMutableDictionary {
 592     JSObjectRef object_;
 593     JSGlobalContextRef context_;
 594 }
 595
 596 - (id) initWithJSObject:(JSObjectRef)object inContext:(JSContextRef)context;
 597
 598 - (NSUInteger) count;
 599 - (id) objectForKey:(id)key;
 600 - (NSEnumerator *) keyEnumerator;
 601 - (void) setObject:(id)object forKey:(id)key;
 602 - (void) removeObjectForKey:(id)key;
 603
 604 @end
 605 /* }}} */
 606 /* Bridge: CYJSArray {{{ */
 607 @interface CYJSArray : NSMutableArray {
 608     JSObjectRef object_;
 609     JSGlobalContextRef context_;
 610 }
 611
 612 - (id) initWithJSObject:(JSObjectRef)object inContext:(JSContextRef)context;
 613
 614 - (NSUInteger) count;
 615 - (id) objectAtIndex:(NSUInteger)index;
 616
 617 - (void) addObject:(id)anObject;
 618 - (void) insertObject:(id)anObject atIndex:(NSUInteger)index;
 619 - (void) removeLastObject;
 620 - (void) removeObjectAtIndex:(NSUInteger)index;
 621 - (void) replaceObjectAtIndex:(NSUInteger)index withObject:(id)anObject;
 622
 623 @end
 624 /* }}} */
 625
 626 _finline bool CYJSValueIsNSObject(JSContextRef context, JSValueRef value) {
 627     return JSValueIsObjectOfClass(context, value, Instance_);
 628 }
 629
 630 _finline bool CYJSValueIsInstanceOfCachedConstructor(JSContextRef context, JSValueRef value, JSStringRef cache) {
 631     JSValueRef exception(NULL);
 632     JSObjectRef constructor(CYGetCachedObject(context, cache));
 633     bool is(JSValueIsInstanceOfConstructor(context, value, constructor, &exception));
 634     CYThrow(context, exception);
 635     return is;
 636 }
 637
 638 NSObject *CYMakeBlock(void (*invoke)(), sig::Signature &signature) {
 639     BlockLiteral *literal(reinterpret_cast<BlockLiteral *>(malloc(sizeof(BlockLiteral))));
 640
 641     struct Descriptor {
 642         struct {
 643             BlockDescriptor1 one_;
 644             BlockDescriptor2 two_;
 645             BlockDescriptor3 three_;
 646         } d_;
 647
 648         CYPool pool_;
 649     };
 650
 651     Descriptor *descriptor(new Descriptor);
 652     memset(&descriptor->d_, 0, sizeof(descriptor->d_));
 653
 654     literal->isa = objc_getClass("__NSGlobalBlock__");
 655     literal->flags = BLOCK_HAS_SIGNATURE | BLOCK_HAS_COPY_DISPOSE | BLOCK_IS_GLOBAL;
 656     literal->reserved = 0;
 657     literal->invoke = reinterpret_cast<void (*)(void *, ...)>(invoke);
 658     literal->descriptor = descriptor;
 659
 660     descriptor->d_.one_.size = sizeof(descriptor->d_);
 661     descriptor->d_.three_.signature = sig::Unparse(descriptor->pool_, &signature);
 662
 663     return reinterpret_cast<NSObject *>(literal);
 664 }
 665
 666 NSObject *CYCastNSObject(CYPool *pool, JSContextRef context, JSObjectRef object) {
 667     if (CYJSValueIsNSObject(context, object)) {
 668         Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
 669         return internal->GetValue();
 670     }
 671
 672     if (JSValueIsObjectOfClass(context, object, Functor_)) {
 673         cy::Functor *internal(reinterpret_cast<cy::Functor *>(JSObjectGetPrivate(object)));
 674         return CYMakeBlock(internal->GetValue(), internal->signature_);
 675     }
 676
 677     bool array(CYJSValueIsInstanceOfCachedConstructor(context, object, Array_s));
 678     id value(array ? [CYJSArray alloc] : [CYJSObject alloc]);
 679     return CYPoolRelease(pool, [value initWithJSObject:object inContext:context]);
 680 }
 681
 682 NSNumber *CYCopyNSNumber(JSContextRef context, JSValueRef value) {
 683     return [[NSNumber alloc] initWithDouble:CYCastDouble(context, value)];
 684 }
 685
 686 #ifndef __APPLE__
 687 @interface NSBoolNumber : NSNumber {
 688 }
 689 @end
 690 #endif
 691
 692 id CYNSObject(CYPool *pool, JSContextRef context, JSValueRef value, bool cast) {
 693     id object;
 694     bool copy;
 695
 696     switch (JSType type = JSValueGetType(context, value)) {
 697         case kJSTypeUndefined:
 698             object = [WebUndefined undefined];
 699             copy = false;
 700         break;
 701
 702         case kJSTypeNull:
 703             return NULL;
 704         break;
 705
 706         case kJSTypeBoolean:
 707 #ifdef __APPLE__
 708             object = (id) (CYCastBool(context, value) ? kCFBooleanTrue : kCFBooleanFalse);
 709             copy = false;
 710 #else
 711             object = [[NSBoolNumber alloc] initWithBool:CYCastBool(context, value)];
 712             copy = true;
 713 #endif
 714         break;
 715
 716         case kJSTypeNumber:
 717             object = CYCopyNSNumber(context, value);
 718             copy = true;
 719         break;
 720
 721         case kJSTypeString:
 722             object = CYCopyNSString(context, value);
 723             copy = true;
 724         break;
 725
 726         case kJSTypeObject:
 727             // XXX: this might could be more efficient
 728             object = CYCastNSObject(pool, context, (JSObjectRef) value);
 729             copy = false;
 730         break;
 731
 732         default:
 733             throw CYJSError(context, "JSValueGetType() == 0x%x", type);
 734         break;
 735     }
 736
 737     if (cast != copy)
 738         return object;
 739     else if (copy)
 740         return CYPoolRelease(pool, object);
 741     else
 742         return [object retain];
 743 }
 744
 745 NSObject *CYCastNSObject(CYPool *pool, JSContextRef context, JSValueRef value) {
 746     return CYNSObject(pool, context, value, true);
 747 }
 748
 749 NSObject *CYCopyNSObject(CYPool &pool, JSContextRef context, JSValueRef value) {
 750     return CYNSObject(&pool, context, value, false);
 751 }
 752
 753 /* Bridge: NSArray {{{ */
 754 @implementation NSArray (Cycript)
 755
 756 - (id) cy$box {
 757     return [[self mutableCopy] autorelease];
 758 }
 759
 760 - (NSString *) cy$toCYON:(bool)objective {
 761     NSMutableString *json([[[NSMutableString alloc] init] autorelease]);
 762     [json appendString:@"@["];
 763
 764     bool comma(false);
 765 #ifdef __APPLE__
 766     for (id object in self) {
 767 #else
 768     for (size_t index(0), count([self count]); index != count; ++index) {
 769         id object([self objectAtIndex:index]);
 770 #endif
 771         if (comma)
 772             [json appendString:@","];
 773         else
 774             comma = true;
 775         if (object == nil || [object cy$JSType] != kJSTypeUndefined)
 776             [json appendString:CYCastNSCYON(object, true)];
 777         else {
 778             [json appendString:@","];
 779             comma = false;
 780         }
 781     }
 782
 783     [json appendString:@"]"];
 784     return json;
 785 }
 786
 787 - (bool) cy$hasProperty:(NSString *)name {
 788     if ([name isEqualToString:@"length"])
 789         return true;
 790
 791     size_t index(CYGetIndex(name));
 792     if (index == _not(size_t) || index >= [self count])
 793         return [super cy$hasProperty:name];
 794     else
 795         return true;
 796 }
 797
 798 - (NSObject *) cy$getProperty:(NSString *)name {
 799     size_t index(CYGetIndex(name));
 800     if (index == _not(size_t) || index >= [self count])
 801         return [super cy$getProperty:name];
 802     else
 803         return [self objectAtIndex:index];
 804 }
 805
 806 - (JSValueRef) cy$getProperty:(NSString *)name inContext:(JSContextRef)context {
 807     CYObjectiveTry_(context) {
 808         if ([name isEqualToString:@"length"])
 809             return CYCastJSValue(context, [self count]);
 810     } CYObjectiveCatch
 811
 812     return [super cy$getProperty:name inContext:context];
 813 }
 814
 815 - (void) cy$getPropertyNames:(JSPropertyNameAccumulatorRef)names inContext:(JSContextRef)context {
 816     [super cy$getPropertyNames:names inContext:context];
 817
 818     for (size_t index(0), count([self count]); index != count; ++index) {
 819         id object([self objectAtIndex:index]);
 820         if (object == nil || [object cy$JSType] != kJSTypeUndefined) {
 821             char name[32];
 822             sprintf(name, "%zu", index);
 823             JSPropertyNameAccumulatorAddName(names, CYJSString(name));
 824         }
 825     }
 826 }
 827
 828 + (bool) cy$hasImplicitProperties {
 829     return false;
 830 }
 831
 832 @end
 833 /* }}} */
 834 /* Bridge: NSBlock {{{ */
 835 #ifdef __APPLE__
 836 @interface NSBlock
 837 - (void) invoke;
 838 @end
 839 #endif
 840 /* }}} */
 841 /* Bridge: NSBoolNumber {{{ */
 842 #ifndef __APPLE__
 843 @implementation NSBoolNumber (Cycript)
 844
 845 - (JSType) cy$JSType {
 846     return kJSTypeBoolean;
 847 }
 848
 849 - (NSString *) cy$toCYON:(bool)objective {
 850     NSString *value([self boolValue] ? @"true" : @"false");
 851     return objective ? value : [NSString stringWithFormat:@"@%@", value];
 852 }
 853
 854 - (JSValueRef) cy$valueOfInContext:(JSContextRef)context { CYObjectiveTry_(context) {
 855     return CYCastJSValue(context, (bool) [self boolValue]);
 856 } CYObjectiveCatch }
 857
 858 @end
 859 #endif
 860 /* }}} */
 861 /* Bridge: NSDictionary {{{ */
 862 @implementation NSDictionary (Cycript)
 863
 864 - (id) cy$box {
 865     return [[self mutableCopy] autorelease];
 866 }
 867
 868 - (NSString *) cy$toCYON:(bool)objective {
 869     NSMutableString *json([[[NSMutableString alloc] init] autorelease]);
 870     [json appendString:@"@{"];
 871
 872     bool comma(false);
 873 #ifdef __APPLE__
 874     for (NSObject *key in self) {
 875 #else
 876     NSEnumerator *keys([self keyEnumerator]);
 877     while (NSObject *key = [keys nextObject]) {
 878 #endif
 879         if (comma)
 880             [json appendString:@","];
 881         else
 882             comma = true;
 883         [json appendString:CYCastNSCYON(key, true)];
 884         [json appendString:@":"];
 885         NSObject *object([self objectForKey:key]);
 886         [json appendString:CYCastNSCYON(object, true)];
 887     }
 888
 889     [json appendString:@"}"];
 890     return json;
 891 }
 892
 893 - (bool) cy$hasProperty:(NSString *)name {
 894     return [self objectForKey:name] != nil;
 895 }
 896
 897 - (NSObject *) cy$getProperty:(NSString *)name {
 898     return [self objectForKey:name];
 899 }
 900
 901 - (void) cy$getPropertyNames:(JSPropertyNameAccumulatorRef)names inContext:(JSContextRef)context {
 902     [super cy$getPropertyNames:names inContext:context];
 903
 904 #ifdef __APPLE__
 905     for (NSObject *key in self) {
 906 #else
 907     NSEnumerator *keys([self keyEnumerator]);
 908     while (NSObject *key = [keys nextObject]) {
 909 #endif
 910         JSPropertyNameAccumulatorAddName(names, CYJSString(context, key));
 911     }
 912 }
 913
 914 + (bool) cy$hasImplicitProperties {
 915     return false;
 916 }
 917
 918 @end
 919 /* }}} */
 920 /* Bridge: NSMutableArray {{{ */
 921 @implementation NSMutableArray (Cycript)
 922
 923 - (bool) cy$setProperty:(NSString *)name to:(NSObject *)value {
 924     if ([name isEqualToString:@"length"]) {
 925         // XXX: is this not intelligent?
 926         NSNumber *number(reinterpret_cast<NSNumber *>(value));
 927 #ifdef __APPLE__
 928         NSUInteger size([number unsignedIntegerValue]);
 929 #else
 930         NSUInteger size([number unsignedIntValue]);
 931 #endif
 932         NSUInteger count([self count]);
 933         if (size < count)
 934             [self removeObjectsInRange:NSMakeRange(size, count - size)];
 935         else if (size != count) {
 936             WebUndefined *undefined([WebUndefined undefined]);
 937             for (size_t i(count); i != size; ++i)
 938                 [self addObject:undefined];
 939         }
 940         return true;
 941     }
 942
 943     size_t index(CYGetIndex(name));
 944     if (index == _not(size_t))
 945         return [super cy$setProperty:name to:value];
 946
 947     id object(value ?: [NSNull null]);
 948
 949     size_t count([self count]);
 950     if (index < count)
 951         [self replaceObjectAtIndex:index withObject:object];
 952     else {
 953         if (index != count) {
 954             WebUndefined *undefined([WebUndefined undefined]);
 955             for (size_t i(count); i != index; ++i)
 956                 [self addObject:undefined];
 957         }
 958
 959         [self addObject:object];
 960     }
 961
 962     return true;
 963 }
 964
 965 - (bool) cy$deleteProperty:(NSString *)name {
 966     size_t index(CYGetIndex(name));
 967     if (index == _not(size_t) || index >= [self count])
 968         return [super cy$deleteProperty:name];
 969     [self replaceObjectAtIndex:index withObject:[WebUndefined undefined]];
 970     return true;
 971 }
 972
 973 @end
 974 /* }}} */
 975 /* Bridge: NSMutableDictionary {{{ */
 976 @implementation NSMutableDictionary (Cycript)
 977
 978 - (bool) cy$setProperty:(NSString *)name to:(NSObject *)value {
 979     [self setObject:(value ?: [NSNull null]) forKey:name];
 980     return true;
 981 }
 982
 983 - (bool) cy$deleteProperty:(NSString *)name {
 984     if ([self objectForKey:name] == nil)
 985         return false;
 986     else {
 987         [self removeObjectForKey:name];
 988         return true;
 989     }
 990 }
 991
 992 @end
 993 /* }}} */
 994 /* Bridge: NSNumber {{{ */
 995 @implementation NSNumber (Cycript)
 996
 997 - (JSType) cy$JSType {
 998 #ifdef __APPLE__
 999     // XXX: this just seems stupid
1000     if ([self class] == NSCFBoolean_)
1001         return kJSTypeBoolean;
1002 #endif
1003     return kJSTypeNumber;
1004 }
1005
1006 - (NSString *) cy$toCYON:(bool)objective {
1007     NSString *value([self cy$JSType] != kJSTypeBoolean ? [self stringValue] : [self boolValue] ? @"true" : @"false");
1008     return objective ? value : [NSString stringWithFormat:@"@%@", value];
1009 }
1010
1011 - (JSValueRef) cy$valueOfInContext:(JSContextRef)context { CYObjectiveTry_(context) {
1012     return [self cy$JSType] != kJSTypeBoolean ? CYCastJSValue(context, [self doubleValue]) : CYCastJSValue(context, static_cast<bool>([self boolValue]));
1013 } CYObjectiveCatch }
1014
1015 @end
1016 /* }}} */
1017 /* Bridge: NSNull {{{ */
1018 @implementation NSNull (Cycript)
1019
1020 - (JSType) cy$JSType {
1021     return kJSTypeNull;
1022 }
1023
1024 - (NSString *) cy$toCYON:(bool)objective {
1025     NSString *value(@"null");
1026     return objective ? value : [NSString stringWithFormat:@"@%@", value];
1027 }
1028
1029 - (JSValueRef) cy$valueOfInContext:(JSContextRef)context { CYObjectiveTry_(context) {
1030     return CYJSNull(context);
1031 } CYObjectiveCatch }
1032
1033 @end
1034 /* }}} */
1035 /* Bridge: NSObject {{{ */
1036 @implementation NSObject (Cycript)
1037
1038 - (id) cy$box {
1039     return self;
1040 }
1041
1042 - (JSValueRef) cy$toJSON:(NSString *)key inContext:(JSContextRef)context {
1043     return [self cy$valueOfInContext:context];
1044 }
1045
1046 - (JSValueRef) cy$valueOfInContext:(JSContextRef)context { CYObjectiveTry_(context) {
1047     return NULL;
1048 } CYObjectiveCatch }
1049
1050 - (JSType) cy$JSType {
1051     return kJSTypeObject;
1052 }
1053
1054 - (NSString *) cy$toCYON:(bool)objective {
1055     return [[self description] cy$toCYON:objective];
1056 }
1057
1058 - (bool) cy$hasProperty:(NSString *)name {
1059     return false;
1060 }
1061
1062 - (NSObject *) cy$getProperty:(NSString *)name {
1063     return nil;
1064 }
1065
1066 - (JSValueRef) cy$getProperty:(NSString *)name inContext:(JSContextRef)context { CYObjectiveTry_(context) {
1067     if (NSObject *value = [self cy$getProperty:name])
1068         return CYCastJSValue(context, value);
1069     return NULL;
1070 } CYObjectiveCatch }
1071
1072 - (bool) cy$setProperty:(NSString *)name to:(NSObject *)value {
1073     return false;
1074 }
1075
1076 - (bool) cy$deleteProperty:(NSString *)name {
1077     return false;
1078 }
1079
1080 - (void) cy$getPropertyNames:(JSPropertyNameAccumulatorRef)names inContext:(JSContextRef)context {
1081 }
1082
1083 + (bool) cy$hasImplicitProperties {
1084     return true;
1085 }
1086
1087 @end
1088 /* }}} */
1089 /* Bridge: NSProxy {{{ */
1090 @implementation NSProxy (Cycript)
1091
1092 - (NSString *) cy$toCYON:(bool)objective {
1093     return [[self description] cy$toCYON:objective];
1094 }
1095
1096 @end
1097 /* }}} */
1098 /* Bridge: NSString {{{ */
1099 @implementation NSString (Cycript)
1100
1101 - (id) cy$box {
1102     return [[self copy] autorelease];
1103 }
1104
1105 - (JSType) cy$JSType {
1106     return kJSTypeString;
1107 }
1108
1109 - (NSString *) cy$toCYON:(bool)objective {
1110     std::ostringstream str;
1111     if (!objective)
1112         str << '@';
1113     CYUTF8String string(CYCastUTF8String(self));
1114     CYStringify(str, string.data, string.size);
1115     std::string value(str.str());
1116     return CYCastNSString(NULL, CYUTF8String(value.c_str(), value.size()));
1117 }
1118
1119 - (bool) cy$hasProperty:(NSString *)name {
1120     size_t index(CYGetIndex(name));
1121     if (index == _not(size_t) || index >= [self length])
1122         return [super cy$hasProperty:name];
1123     else
1124         return true;
1125 }
1126
1127 - (NSObject *) cy$getProperty:(NSString *)name {
1128     size_t index(CYGetIndex(name));
1129     if (index == _not(size_t) || index >= [self length])
1130         return [super cy$getProperty:name];
1131     else
1132         return [self substringWithRange:NSMakeRange(index, 1)];
1133 }
1134
1135 - (void) cy$getPropertyNames:(JSPropertyNameAccumulatorRef)names inContext:(JSContextRef)context {
1136     [super cy$getPropertyNames:names inContext:context];
1137
1138     for (size_t index(0), length([self length]); index != length; ++index) {
1139         char name[32];
1140         sprintf(name, "%zu", index);
1141         JSPropertyNameAccumulatorAddName(names, CYJSString(name));
1142     }
1143 }
1144
1145 - (JSValueRef) cy$valueOfInContext:(JSContextRef)context { CYObjectiveTry_(context) {
1146     return CYCastJSValue(context, CYJSString(context, self));
1147 } CYObjectiveCatch }
1148
1149 @end
1150 /* }}} */
1151 /* Bridge: WebUndefined {{{ */
1152 @implementation WebUndefined (Cycript)
1153
1154 - (JSType) cy$JSType {
1155     return kJSTypeUndefined;
1156 }
1157
1158 - (NSString *) cy$toCYON:(bool)objective {
1159     NSString *value(@"undefined");
1160     return value; // XXX: maybe use the below code, adding @undefined?
1161     //return objective ? value : [NSString stringWithFormat:@"@%@", value];
1162 }
1163
1164 - (JSValueRef) cy$valueOfInContext:(JSContextRef)context { CYObjectiveTry_(context) {
1165     return CYJSUndefined(context);
1166 } CYObjectiveCatch }
1167
1168 @end
1169 /* }}} */
1170
1171 static bool CYIsClass(id self) {
1172 #ifdef __APPLE__
1173     return class_isMetaClass(object_getClass(self));
1174 #else
1175     return GSObjCIsClass(self);
1176 #endif
1177 }
1178
1179 Class CYCastClass(CYPool &pool, JSContextRef context, JSValueRef value) {
1180     id self(CYCastNSObject(&pool, context, value));
1181     if (CYIsClass(self))
1182         return (Class) self;
1183     throw CYJSError(context, "got something that is not a Class");
1184     return NULL;
1185 }
1186
1187 NSArray *CYCastNSArray(JSContextRef context, JSPropertyNameArrayRef names) {
1188     CYPool pool;
1189     size_t size(JSPropertyNameArrayGetCount(names));
1190     NSMutableArray *array([NSMutableArray arrayWithCapacity:size]);
1191     for (size_t index(0); index != size; ++index)
1192         [array addObject:CYCastNSString(&pool, context, JSPropertyNameArrayGetNameAtIndex(names, index))];
1193     return array;
1194 }
1195
1196 JSValueRef CYCastJSValue(JSContextRef context, NSObject *value) { CYPoolTry {
1197     if (value == nil)
1198         return CYJSNull(context);
1199     else
1200         return CYMakeInstance(context, value, false);
1201 } CYPoolCatch(NULL) return /*XXX*/ NULL; }
1202
1203 @implementation CYJSObject
1204
1205 - (id) initWithJSObject:(JSObjectRef)object inContext:(JSContextRef)context { CYObjectiveTry {
1206     if ((self = [super init]) != nil) {
1207         object_ = object;
1208         context_ = CYGetJSContext(context);
1209         JSGlobalContextRetain(context_);
1210         JSValueProtect(context_, object_);
1211     } return self;
1212 } CYObjectiveCatch }
1213
1214 - (void) dealloc { CYObjectiveTry {
1215     JSValueUnprotect(context_, object_);
1216     JSGlobalContextRelease(context_);
1217     [super dealloc];
1218 } CYObjectiveCatch }
1219
1220 - (NSString *) cy$toCYON:(bool)objective { CYObjectiveTry {
1221     CYPool pool;
1222     JSValueRef exception(NULL);
1223     const char *cyon(CYPoolCCYON(pool, context_, object_));
1224     CYThrow(context_, exception);
1225     if (cyon == NULL)
1226         return [super cy$toCYON:objective];
1227     else
1228         return [NSString stringWithUTF8String:cyon];
1229 } CYObjectiveCatch }
1230
1231 - (NSUInteger) count { CYObjectiveTry {
1232     JSPropertyNameArrayRef names(JSObjectCopyPropertyNames(context_, object_));
1233     size_t size(JSPropertyNameArrayGetCount(names));
1234     JSPropertyNameArrayRelease(names);
1235     return size;
1236 } CYObjectiveCatch }
1237
1238 - (id) objectForKey:(id)key { CYObjectiveTry {
1239     JSValueRef value(CYGetProperty(context_, object_, CYJSString(context_, (NSObject *) key)));
1240     if (JSValueIsUndefined(context_, value))
1241         return nil;
1242     return CYCastNSObject(NULL, context_, value) ?: [NSNull null];
1243 } CYObjectiveCatch }
1244
1245 - (NSEnumerator *) keyEnumerator { CYObjectiveTry {
1246     JSPropertyNameArrayRef names(JSObjectCopyPropertyNames(context_, object_));
1247     NSEnumerator *enumerator([CYCastNSArray(context_, names) objectEnumerator]);
1248     JSPropertyNameArrayRelease(names);
1249     return enumerator;
1250 } CYObjectiveCatch }
1251
1252 - (void) setObject:(id)object forKey:(id)key { CYObjectiveTry {
1253     CYSetProperty(context_, object_, CYJSString(context_, (NSObject *) key), CYCastJSValue(context_, (NSString *) object));
1254 } CYObjectiveCatch }
1255
1256 - (void) removeObjectForKey:(id)key { CYObjectiveTry {
1257     JSValueRef exception(NULL);
1258     (void) JSObjectDeleteProperty(context_, object_, CYJSString(context_, (NSObject *) key), &exception);
1259     CYThrow(context_, exception);
1260 } CYObjectiveCatch }
1261
1262 @end
1263
1264 @implementation CYJSArray
1265
1266 - (NSString *) cy$toCYON:(bool)objective {
1267     CYPool pool;
1268     return [NSString stringWithUTF8String:CYPoolCCYON(pool, context_, object_)];
1269 }
1270
1271 - (id) initWithJSObject:(JSObjectRef)object inContext:(JSContextRef)context { CYObjectiveTry {
1272     if ((self = [super init]) != nil) {
1273         object_ = object;
1274         context_ = CYGetJSContext(context);
1275         JSGlobalContextRetain(context_);
1276         JSValueProtect(context_, object_);
1277     } return self;
1278 } CYObjectiveCatch }
1279
1280 - (void) dealloc { CYObjectiveTry {
1281     JSValueUnprotect(context_, object_);
1282     JSGlobalContextRelease(context_);
1283     [super dealloc];
1284 } CYObjectiveCatch }
1285
1286 - (NSUInteger) count { CYObjectiveTry {
1287     return CYArrayLength(context_, object_);
1288 } CYObjectiveCatch }
1289
1290 - (id) objectAtIndex:(NSUInteger)index { CYObjectiveTry {
1291     size_t bounds([self count]);
1292     if (index >= bounds)
1293         @throw [NSException exceptionWithName:NSRangeException reason:[NSString stringWithFormat:@"*** -[CYJSArray objectAtIndex:]: index (%zu) beyond bounds (%zu)", static_cast<size_t>(index), bounds] userInfo:nil];
1294     JSValueRef exception(NULL);
1295     JSValueRef value(JSObjectGetPropertyAtIndex(context_, object_, index, &exception));
1296     CYThrow(context_, exception);
1297     return CYCastNSObject(NULL, context_, value) ?: [NSNull null];
1298 } CYObjectiveCatch }
1299
1300 - (void) addObject:(id)object { CYObjectiveTry {
1301     CYArrayPush(context_, object_, CYCastJSValue(context_, (NSObject *) object));
1302 } CYObjectiveCatch }
1303
1304 - (void) insertObject:(id)object atIndex:(NSUInteger)index { CYObjectiveTry {
1305     size_t bounds([self count] + 1);
1306     if (index >= bounds)
1307         @throw [NSException exceptionWithName:NSRangeException reason:[NSString stringWithFormat:@"*** -[CYJSArray insertObject:atIndex:]: index (%zu) beyond bounds (%zu)", static_cast<size_t>(index), bounds] userInfo:nil];
1308     JSValueRef exception(NULL);
1309     JSValueRef arguments[3];
1310     arguments[0] = CYCastJSValue(context_, index);
1311     arguments[1] = CYCastJSValue(context_, 0);
1312     arguments[2] = CYCastJSValue(context_, (NSObject *) object);
1313     JSObjectRef Array(CYGetCachedObject(context_, CYJSString("Array_prototype")));
1314     JSObjectCallAsFunction(context_, CYCastJSObject(context_, CYGetProperty(context_, Array, splice_s)), object_, 3, arguments, &exception);
1315     CYThrow(context_, exception);
1316 } CYObjectiveCatch }
1317
1318 - (void) removeLastObject { CYObjectiveTry {
1319     JSValueRef exception(NULL);
1320     JSObjectRef Array(CYGetCachedObject(context_, CYJSString("Array_prototype")));
1321     JSObjectCallAsFunction(context_, CYCastJSObject(context_, CYGetProperty(context_, Array, pop_s)), object_, 0, NULL, &exception);
1322     CYThrow(context_, exception);
1323 } CYObjectiveCatch }
1324
1325 - (void) removeObjectAtIndex:(NSUInteger)index { CYObjectiveTry {
1326     size_t bounds([self count]);
1327     if (index >= bounds)
1328         @throw [NSException exceptionWithName:NSRangeException reason:[NSString stringWithFormat:@"*** -[CYJSArray removeObjectAtIndex:]: index (%zu) beyond bounds (%zu)", static_cast<size_t>(index), bounds] userInfo:nil];
1329     JSValueRef exception(NULL);
1330     JSValueRef arguments[2];
1331     arguments[0] = CYCastJSValue(context_, index);
1332     arguments[1] = CYCastJSValue(context_, 1);
1333     JSObjectRef Array(CYGetCachedObject(context_, CYJSString("Array_prototype")));
1334     JSObjectCallAsFunction(context_, CYCastJSObject(context_, CYGetProperty(context_, Array, splice_s)), object_, 2, arguments, &exception);
1335     CYThrow(context_, exception);
1336 } CYObjectiveCatch }
1337
1338 - (void) replaceObjectAtIndex:(NSUInteger)index withObject:(id)object { CYObjectiveTry {
1339     size_t bounds([self count]);
1340     if (index >= bounds)
1341         @throw [NSException exceptionWithName:NSRangeException reason:[NSString stringWithFormat:@"*** -[CYJSArray replaceObjectAtIndex:withObject:]: index (%zu) beyond bounds (%zu)", static_cast<size_t>(index), bounds] userInfo:nil];
1342     CYSetProperty(context_, object_, index, CYCastJSValue(context_, (NSObject *) object));
1343 } CYObjectiveCatch }
1344
1345 @end
1346
1347 // XXX: inherit from or replace with CYJSObject
1348 @interface CYInternal : NSObject {
1349     JSGlobalContextRef context_;
1350     JSObjectRef object_;
1351 }
1352
1353 @end
1354
1355 @implementation CYInternal
1356
1357 - (void) dealloc {
1358     JSValueUnprotect(context_, object_);
1359     JSGlobalContextRelease(context_);
1360     [super dealloc];
1361 }
1362
1363 - (id) initInContext:(JSContextRef)context {
1364     if ((self = [super init]) != nil) {
1365         context_ = CYGetJSContext(context);
1366         JSGlobalContextRetain(context_);
1367     } return self;
1368 }
1369
1370 - (bool) hasProperty:(JSStringRef)name inContext:(JSContextRef)context {
1371     if (object_ == NULL)
1372         return false;
1373
1374     return JSObjectHasProperty(context, object_, name);
1375 }
1376
1377 - (JSValueRef) getProperty:(JSStringRef)name inContext:(JSContextRef)context {
1378     if (object_ == NULL)
1379         return NULL;
1380
1381     return CYGetProperty(context, object_, name);
1382 }
1383
1384 - (void) setProperty:(JSStringRef)name toValue:(JSValueRef)value inContext:(JSContextRef)context {
1385     @synchronized (self) {
1386         if (object_ == NULL) {
1387             object_ = JSObjectMake(context, NULL, NULL);
1388             JSValueProtect(context, object_);
1389         }
1390     }
1391
1392     CYSetProperty(context, object_, name, value);
1393 }
1394
1395 + (CYInternal *) get:(id)object {
1396     if ($objc_getAssociatedObject == NULL)
1397         return nil;
1398
1399     @synchronized (object) {
1400         if (CYInternal *internal = $objc_getAssociatedObject(object, @selector(cy$internal)))
1401             return internal;
1402     }
1403
1404     return nil;
1405 }
1406
1407 + (CYInternal *) set:(id)object inContext:(JSContextRef)context {
1408     if ($objc_getAssociatedObject == NULL)
1409         return nil;
1410
1411     @synchronized (object) {
1412         if (CYInternal *internal = $objc_getAssociatedObject(object, @selector(cy$internal)))
1413             return internal;
1414
1415         if ($objc_setAssociatedObject == NULL)
1416             return nil;
1417
1418         CYInternal *internal([[[CYInternal alloc] initInContext:context] autorelease]);
1419         objc_setAssociatedObject(object, @selector(cy$internal), internal, OBJC_ASSOCIATION_RETAIN_NONATOMIC);
1420         return internal;
1421     }
1422
1423     return nil;
1424 }
1425
1426 @end
1427
1428 static JSObjectRef CYMakeSelector(JSContextRef context, SEL sel) {
1429     Selector_privateData *internal(new Selector_privateData(sel));
1430     return JSObjectMake(context, Selector_, internal);
1431 }
1432
1433 static SEL CYCastSEL(JSContextRef context, JSValueRef value) {
1434     if (JSValueIsObjectOfClass(context, value, Selector_)) {
1435         Selector_privateData *internal(reinterpret_cast<Selector_privateData *>(JSObjectGetPrivate((JSObjectRef) value)));
1436         return reinterpret_cast<SEL>(internal->value_);
1437     } else
1438         return CYCastPointer<SEL>(context, value);
1439 }
1440
1441 void *CYObjectiveC_ExecuteStart(JSContextRef context) { CYSadTry {
1442     return (void *) [[NSAutoreleasePool alloc] init];
1443 } CYSadCatch(NULL) }
1444
1445 void CYObjectiveC_ExecuteEnd(JSContextRef context, void *handle) { CYSadTry {
1446     return [(NSAutoreleasePool *) handle release];
1447 } CYSadCatch() }
1448
1449 JSValueRef CYObjectiveC_RuntimeProperty(JSContextRef context, CYUTF8String name) { CYPoolTry {
1450     if (name == "nil")
1451         return Instance::Make(context, nil);
1452     if (Class _class = objc_getClass(name.data))
1453         return CYMakeInstance(context, _class, true);
1454     if (Protocol *protocol = objc_getProtocol(name.data))
1455         return CYMakeInstance(context, protocol, true);
1456     return NULL;
1457 } CYPoolCatch(NULL) return /*XXX*/ NULL; }
1458
1459 static void CYObjectiveC_CallFunction(JSContextRef context, ffi_cif *cif, void (*function)(), uint8_t *value, void **values) { CYSadTry {
1460     ffi_call(cif, function, value, values);
1461 } CYSadCatch() }
1462
1463 static bool CYObjectiveC_PoolFFI(CYPool *pool, JSContextRef context, sig::Type *type, ffi_type *ffi, void *data, JSValueRef value) { CYSadTry {
1464     switch (type->primitive) {
1465         // XXX: do something epic about blocks
1466         case sig::block_P:
1467         case sig::object_P:
1468         case sig::typename_P:
1469             // XXX: this works for return values, but not for properties and fields
1470             *reinterpret_cast<id *>(data) = CYCastNSObject(pool, context, value);
1471         break;
1472
1473         case sig::selector_P:
1474             *reinterpret_cast<SEL *>(data) = CYCastSEL(context, value);
1475         break;
1476
1477         default:
1478             return false;
1479     }
1480
1481     return true;
1482 } CYSadCatch(false) }
1483
1484 static JSValueRef CYObjectiveC_FromFFI(JSContextRef context, sig::Type *type, ffi_type *ffi, void *data, bool initialize, JSObjectRef owner) { CYPoolTry {
1485     switch (type->primitive) {
1486         // XXX: do something epic about blocks
1487         case sig::block_P:
1488         case sig::object_P:
1489             if (NSObject *object = *reinterpret_cast<NSObject **>(data)) {
1490                 JSValueRef value(CYCastJSValue(context, object));
1491                 if (initialize)
1492                     [object release];
1493                 return value;
1494             } else goto null;
1495
1496         case sig::typename_P:
1497             return CYMakeInstance(context, *reinterpret_cast<Class *>(data), true);
1498
1499         case sig::selector_P:
1500             if (SEL sel = *reinterpret_cast<SEL *>(data))
1501                 return CYMakeSelector(context, sel);
1502             else goto null;
1503
1504         null:
1505             return CYJSNull(context);
1506         default:
1507             return NULL;
1508     }
1509 } CYPoolCatch(NULL) return /*XXX*/ NULL; }
1510
1511 static bool CYImplements(id object, Class _class, SEL selector, bool devoid = false) {
1512     if (objc_method *method = class_getInstanceMethod(_class, selector)) {
1513         if (!devoid)
1514             return true;
1515 #if OBJC_API_VERSION >= 2
1516         char type[16];
1517         method_getReturnType(method, type, sizeof(type));
1518 #else
1519         const char *type(method_getTypeEncoding(method));
1520 #endif
1521         if (type[0] != 'v')
1522             return true;
1523     }
1524
1525     // XXX: possibly use a more "awesome" check?
1526     return false;
1527 }
1528
1529 static const char *CYPoolTypeEncoding(CYPool &pool, JSContextRef context, SEL sel, objc_method *method) {
1530     if (method != NULL)
1531         return method_getTypeEncoding(method);
1532
1533     const char *name(sel_getName(sel));
1534     size_t length(strlen(name));
1535
1536     char keyed[length + 2];
1537     keyed[0] = '6';
1538     keyed[length + 1] = '\0';
1539     memcpy(keyed + 1, name, length);
1540
1541     if (CYBridgeEntry *entry = CYBridgeHash(keyed, length + 1))
1542         return entry->value_;
1543
1544     return NULL;
1545 }
1546
1547 static JSValueRef MessageAdapter_(JSContextRef context, size_t count, JSValueRef values[], JSObjectRef function) {
1548     JSObjectRef _this(CYCastJSObject(context, values[0]));
1549     return CYCallAsFunction(context, function, _this, count - 2, values + 2);
1550 }
1551
1552 static void MessageClosure_(ffi_cif *cif, void *result, void **arguments, void *arg) {
1553     CYExecuteClosure(cif, result, arguments, arg, &MessageAdapter_);
1554 }
1555
1556 static JSObjectRef CYMakeMessage(JSContextRef context, SEL sel, IMP imp, const char *type) {
1557     Message_privateData *internal(new Message_privateData(sel, type, imp));
1558     return JSObjectMake(context, Message_, internal);
1559 }
1560
1561 static IMP CYMakeMessage(JSContextRef context, JSValueRef value, const char *type) {
1562     JSObjectRef function(CYCastJSObject(context, value));
1563     Closure_privateData *internal(CYMakeFunctor_(context, function, type, &MessageClosure_));
1564     // XXX: see notes in Library.cpp about needing to leak
1565     return reinterpret_cast<IMP>(internal->GetValue());
1566 }
1567
1568 static bool Messages_hasProperty(JSContextRef context, JSObjectRef object, JSStringRef property) {
1569     Messages *internal(reinterpret_cast<Messages *>(JSObjectGetPrivate(object)));
1570     Class _class(internal->GetValue());
1571
1572     CYPool pool;
1573     const char *name(CYPoolCString(pool, context, property));
1574
1575     if (SEL sel = sel_getUid(name))
1576         if (class_getInstanceMethod(_class, sel) != NULL)
1577             return true;
1578
1579     return false;
1580 }
1581
1582 static JSValueRef Messages_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
1583     Messages *internal(reinterpret_cast<Messages *>(JSObjectGetPrivate(object)));
1584     Class _class(internal->GetValue());
1585
1586     CYPool pool;
1587     const char *name(CYPoolCString(pool, context, property));
1588
1589     if (SEL sel = sel_getUid(name))
1590         if (objc_method *method = class_getInstanceMethod(_class, sel))
1591             return CYMakeMessage(context, sel, method_getImplementation(method), method_getTypeEncoding(method));
1592
1593     return NULL;
1594 }
1595
1596 static bool Messages_setProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef value, JSValueRef *exception) {
1597     Messages *internal(reinterpret_cast<Messages *>(JSObjectGetPrivate(object)));
1598     Class _class(internal->GetValue());
1599
1600     CYPool pool;
1601     const char *name(CYPoolCString(pool, context, property));
1602
1603     SEL sel(sel_registerName(name));
1604
1605     objc_method *method(class_getInstanceMethod(_class, sel));
1606
1607     const char *type;
1608     IMP imp;
1609
1610     if (JSValueIsObjectOfClass(context, value, Message_)) {
1611         Message_privateData *message(reinterpret_cast<Message_privateData *>(JSObjectGetPrivate((JSObjectRef) value)));
1612         type = sig::Unparse(pool, &message->signature_);
1613         imp = reinterpret_cast<IMP>(message->GetValue());
1614     } else {
1615         type = CYPoolTypeEncoding(pool, context, sel, method);
1616         imp = CYMakeMessage(context, value, type);
1617     }
1618
1619     if (method != NULL)
1620         method_setImplementation(method, imp);
1621     else {
1622 #ifdef GNU_RUNTIME
1623         GSMethodList list(GSAllocMethodList(1));
1624         GSAppendMethodToList(list, sel, type, imp, YES);
1625         GSAddMethodList(_class, list, YES);
1626         GSFlushMethodCacheForClass(_class);
1627 #else
1628         class_addMethod(_class, sel, imp, type);
1629 #endif
1630     }
1631
1632     return true;
1633 }
1634
1635 #if 0 && OBJC_API_VERSION < 2
1636 static bool Messages_deleteProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
1637     Messages *internal(reinterpret_cast<Messages *>(JSObjectGetPrivate(object)));
1638     Class _class(internal->GetValue());
1639
1640     CYPool pool;
1641     const char *name(CYPoolCString(pool, context, property));
1642
1643     if (SEL sel = sel_getUid(name))
1644         if (objc_method *method = class_getInstanceMethod(_class, sel)) {
1645             objc_method_list list = {NULL, 1, {method}};
1646             class_removeMethods(_class, &list);
1647             return true;
1648         }
1649
1650     return false;
1651 }
1652 #endif
1653
1654 static void Messages_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
1655     Messages *internal(reinterpret_cast<Messages *>(JSObjectGetPrivate(object)));
1656     Class _class(internal->GetValue());
1657
1658 #if OBJC_API_VERSION >= 2
1659     unsigned int size;
1660     objc_method **data(class_copyMethodList(_class, &size));
1661     for (size_t i(0); i != size; ++i)
1662         JSPropertyNameAccumulatorAddName(names, CYJSString(sel_getName(method_getName(data[i]))));
1663     free(data);
1664 #else
1665     for (objc_method_list *methods(_class->methods); methods != NULL; methods = methods->method_next)
1666         for (int i(0); i != methods->method_count; ++i)
1667             JSPropertyNameAccumulatorAddName(names, CYJSString(sel_getName(method_getName(&methods->method_list[i]))));
1668 #endif
1669 }
1670
1671 static bool CYHasImplicitProperties(Class _class) {
1672     // XXX: this is an evil hack to deal with NSProxy; fix elsewhere
1673     if (!CYImplements(_class, object_getClass(_class), @selector(cy$hasImplicitProperties)))
1674         return true;
1675     return [_class cy$hasImplicitProperties];
1676 }
1677
1678 static bool Instance_hasProperty(JSContextRef context, JSObjectRef object, JSStringRef property) {
1679     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
1680     id self(internal->GetValue());
1681
1682     if (JSStringIsEqualToUTF8CString(property, "$cyi"))
1683         return true;
1684
1685     CYPool pool;
1686     NSString *name(CYCastNSString(&pool, context, property));
1687
1688     if (CYInternal *internal = [CYInternal get:self])
1689         if ([internal hasProperty:property inContext:context])
1690             return true;
1691
1692     Class _class(object_getClass(self));
1693
1694     CYPoolTry {
1695         // XXX: this is an evil hack to deal with NSProxy; fix elsewhere
1696         if (CYImplements(self, _class, @selector(cy$hasProperty:)))
1697             if ([self cy$hasProperty:name])
1698                 return true;
1699     } CYPoolCatch(false)
1700
1701     const char *string(CYPoolCString(pool, context, name));
1702
1703 #ifdef __APPLE__
1704     if (class_getProperty(_class, string) != NULL)
1705         return true;
1706 #endif
1707
1708     if (CYHasImplicitProperties(_class))
1709         if (SEL sel = sel_getUid(string))
1710             if (CYImplements(self, _class, sel, true))
1711                 return true;
1712
1713     return false;
1714 }
1715
1716 static JSValueRef Instance_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
1717     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
1718     id self(internal->GetValue());
1719
1720     if (JSStringIsEqualToUTF8CString(property, "$cyi"))
1721         return Internal::Make(context, self, object);
1722
1723     CYPool pool;
1724     NSString *name(CYCastNSString(&pool, context, property));
1725
1726     if (CYInternal *internal = [CYInternal get:self])
1727         if (JSValueRef value = [internal getProperty:property inContext:context])
1728             return value;
1729
1730     CYPoolTry {
1731         if (JSValueRef value = [self cy$getProperty:name inContext:context])
1732             return value;
1733     } CYPoolCatch(NULL)
1734
1735     const char *string(CYPoolCString(pool, context, name));
1736     Class _class(object_getClass(self));
1737
1738 #ifdef __APPLE__
1739     if (objc_property_t property = class_getProperty(_class, string)) {
1740         PropertyAttributes attributes(property);
1741         SEL sel(sel_registerName(attributes.Getter()));
1742         return CYSendMessage(pool, context, self, NULL, sel, 0, NULL, false, exception);
1743     }
1744 #endif
1745
1746     if (CYHasImplicitProperties(_class))
1747         if (SEL sel = sel_getUid(string))
1748             if (CYImplements(self, _class, sel, true))
1749                 return CYSendMessage(pool, context, self, NULL, sel, 0, NULL, false, exception);
1750
1751     return NULL;
1752 } CYCatch(NULL) }
1753
1754 static bool Instance_setProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef value, JSValueRef *exception) { CYTry {
1755     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
1756     id self(internal->GetValue());
1757
1758     CYPool pool;
1759
1760     NSString *name(CYCastNSString(&pool, context, property));
1761     NSObject *data(CYCastNSObject(&pool, context, value));
1762
1763     CYPoolTry {
1764         if ([self cy$setProperty:name to:data])
1765             return true;
1766     } CYPoolCatch(false)
1767
1768     const char *string(CYPoolCString(pool, context, name));
1769     Class _class(object_getClass(self));
1770
1771 #ifdef __APPLE__
1772     if (objc_property_t property = class_getProperty(_class, string)) {
1773         PropertyAttributes attributes(property);
1774         if (const char *setter = attributes.Setter()) {
1775             SEL sel(sel_registerName(setter));
1776             JSValueRef arguments[1] = {value};
1777             CYSendMessage(pool, context, self, NULL, sel, 1, arguments, false, exception);
1778             return true;
1779         }
1780     }
1781 #endif
1782
1783     size_t length(strlen(string));
1784
1785     char set[length + 5];
1786
1787     set[0] = 's';
1788     set[1] = 'e';
1789     set[2] = 't';
1790
1791     if (string[0] != '\0') {
1792         set[3] = toupper(string[0]);
1793         memcpy(set + 4, string + 1, length - 1);
1794     }
1795
1796     set[length + 3] = ':';
1797     set[length + 4] = '\0';
1798
1799     if (SEL sel = sel_getUid(set))
1800         if (CYImplements(self, _class, sel)) {
1801             JSValueRef arguments[1] = {value};
1802             CYSendMessage(pool, context, self, NULL, sel, 1, arguments, false, exception);
1803             return true;
1804         }
1805
1806     if (CYInternal *internal = [CYInternal set:self inContext:context]) {
1807         [internal setProperty:property toValue:value inContext:context];
1808         return true;
1809     }
1810
1811     return false;
1812 } CYCatch(false) }
1813
1814 static bool Instance_deleteProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
1815     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
1816     id self(internal->GetValue());
1817
1818     CYPoolTry {
1819         NSString *name(CYCastNSString(NULL, context, property));
1820         return [self cy$deleteProperty:name];
1821     } CYPoolCatch(false)
1822 } CYCatch(false) return /*XXX*/ false; }
1823
1824 static void Instance_getPropertyNames_message(JSPropertyNameAccumulatorRef names, objc_method *method) {
1825     const char *name(sel_getName(method_getName(method)));
1826     if (strchr(name, ':') != NULL)
1827         return;
1828
1829     const char *type(method_getTypeEncoding(method));
1830     if (type == NULL || *type == '\0' || *type == 'v')
1831         return;
1832
1833     JSPropertyNameAccumulatorAddName(names, CYJSString(name));
1834 }
1835
1836 static void Instance_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
1837     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
1838     id self(internal->GetValue());
1839
1840     CYPool pool;
1841     Class _class(object_getClass(self));
1842
1843 #ifdef __APPLE__
1844     {
1845         unsigned int size;
1846         objc_property_t *data(class_copyPropertyList(_class, &size));
1847         for (size_t i(0); i != size; ++i)
1848             JSPropertyNameAccumulatorAddName(names, CYJSString(property_getName(data[i])));
1849         free(data);
1850     }
1851 #endif
1852
1853     if (CYHasImplicitProperties(_class))
1854         for (Class current(_class); current != nil; current = class_getSuperclass(current)) {
1855 #if OBJC_API_VERSION >= 2
1856             unsigned int size;
1857             objc_method **data(class_copyMethodList(current, &size));
1858             for (size_t i(0); i != size; ++i)
1859                 Instance_getPropertyNames_message(names, data[i]);
1860             free(data);
1861 #else
1862             for (objc_method_list *methods(current->methods); methods != NULL; methods = methods->method_next)
1863                 for (int i(0); i != methods->method_count; ++i)
1864                     Instance_getPropertyNames_message(names, &methods->method_list[i]);
1865 #endif
1866         }
1867
1868     CYPoolTry {
1869         // XXX: this is an evil hack to deal with NSProxy; fix elsewhere
1870         if (CYImplements(self, _class, @selector(cy$getPropertyNames:inContext:)))
1871             [self cy$getPropertyNames:names inContext:context];
1872     } CYPoolCatch()
1873 }
1874
1875 static JSObjectRef Instance_callAsConstructor(JSContextRef context, JSObjectRef object, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
1876     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
1877     JSObjectRef value(Instance::Make(context, [internal->GetValue() alloc], Instance::Uninitialized));
1878     return value;
1879 } CYCatch(NULL) }
1880
1881 static JSValueRef Instance_callAsFunction(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
1882     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
1883     id self(internal->GetValue());
1884
1885     if (![self isKindOfClass:NSBlock_])
1886         CYThrow("non-NSBlock object is not a function");
1887     // XXX: replace above logic with the following assertion
1888     //_assert([self isKindOfClass:NSBlock_]);
1889     // to do this, make it so FunctionInstance_ is the class of blocks
1890     // to do /that/, generalize the various "is exactly Instance_" checks
1891     // then, move Instance_callAsFunction to only be on FunctionInstance
1892
1893     BlockLiteral *literal(reinterpret_cast<BlockLiteral *>(self));
1894
1895     if ((literal->flags & BLOCK_HAS_SIGNATURE) != 0) {
1896         uint8_t *descriptor(reinterpret_cast<uint8_t *>(literal->descriptor));
1897         descriptor += sizeof(BlockDescriptor1);
1898         if ((literal->flags & BLOCK_HAS_COPY_DISPOSE) != 0)
1899             descriptor += sizeof(BlockDescriptor2);
1900         BlockDescriptor3 *descriptor3(reinterpret_cast<BlockDescriptor3 *>(descriptor));
1901
1902         if (const char *type = descriptor3->signature) {
1903             CYPool pool;
1904
1905             void *setup[1];
1906             setup[0] = &self;
1907
1908             sig::Signature signature;
1909             sig::Parse(pool, &signature, type, &Structor_);
1910
1911             ffi_cif cif;
1912             sig::sig_ffi_cif(pool, &sig::ObjectiveC, &signature, &cif);
1913
1914             void (*function)() = reinterpret_cast<void (*)()>(literal->invoke);
1915             return CYCallFunction(pool, context, 1, setup, count, arguments, false, exception, &signature, &cif, function);
1916         }
1917     }
1918
1919     if (count != 0)
1920         CYThrow("NSBlock without signature field passed arguments");
1921
1922     CYPoolTry {
1923         [self invoke];
1924     } CYPoolCatch(NULL);
1925
1926     return NULL;
1927 } CYCatch(NULL) }
1928
1929 static bool Instance_hasInstance(JSContextRef context, JSObjectRef constructor, JSValueRef instance, JSValueRef *exception) { CYTry {
1930     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate((JSObjectRef) constructor)));
1931     Class _class(internal->GetValue());
1932     if (!CYIsClass(_class))
1933         return false;
1934
1935     if (CYJSValueIsNSObject(context, instance)) {
1936         Instance *linternal(reinterpret_cast<Instance *>(JSObjectGetPrivate((JSObjectRef) instance)));
1937         // XXX: this isn't always safe
1938         return [linternal->GetValue() isKindOfClass:_class];
1939     }
1940
1941     return false;
1942 } CYCatch(false) }
1943
1944 static JSValueRef Instance_box_callAsFunction(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
1945     if (count == 0)
1946         throw CYJSError(context, "incorrect number of arguments to Instance");
1947     CYPool pool;
1948     id value(CYCastNSObject(&pool, context, arguments[0]));
1949     if (value == nil)
1950         value = [NSNull null];
1951     return CYCastJSValue(context, [value cy$box]);
1952 } CYCatch(NULL) }
1953
1954 static bool Internal_hasProperty(JSContextRef context, JSObjectRef object, JSStringRef property) {
1955     Internal *internal(reinterpret_cast<Internal *>(JSObjectGetPrivate(object)));
1956     CYPool pool;
1957
1958     id self(internal->GetValue());
1959     const char *name(CYPoolCString(pool, context, property));
1960
1961     if (object_getInstanceVariable(self, name, NULL) != NULL)
1962         return true;
1963
1964     return false;
1965 }
1966
1967 static JSValueRef Internal_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
1968     Internal *internal(reinterpret_cast<Internal *>(JSObjectGetPrivate(object)));
1969     CYPool pool;
1970
1971     id self(internal->GetValue());
1972     const char *name(CYPoolCString(pool, context, property));
1973
1974     if (objc_ivar *ivar = object_getInstanceVariable(self, name, NULL)) {
1975         Type_privateData type(pool, ivar_getTypeEncoding(ivar));
1976         // XXX: if this fails and throws an exception the person we are throwing it to gets the wrong exception
1977         return CYFromFFI(context, type.type_, type.GetFFI(), reinterpret_cast<uint8_t *>(self) + ivar_getOffset(ivar));
1978     }
1979
1980     return NULL;
1981 } CYCatch(NULL) }
1982
1983 static bool Internal_setProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef value, JSValueRef *exception) { CYTry {
1984     Internal *internal(reinterpret_cast<Internal *>(JSObjectGetPrivate(object)));
1985     CYPool pool;
1986
1987     id self(internal->GetValue());
1988     const char *name(CYPoolCString(pool, context, property));
1989
1990     if (objc_ivar *ivar = object_getInstanceVariable(self, name, NULL)) {
1991         Type_privateData type(pool, ivar_getTypeEncoding(ivar));
1992         CYPoolFFI(&pool, context, type.type_, type.GetFFI(), reinterpret_cast<uint8_t *>(self) + ivar_getOffset(ivar), value);
1993         return true;
1994     }
1995
1996     return false;
1997 } CYCatch(false) }
1998
1999 static void Internal_getPropertyNames_(Class _class, JSPropertyNameAccumulatorRef names) {
2000     if (Class super = class_getSuperclass(_class))
2001         Internal_getPropertyNames_(super, names);
2002
2003 #if OBJC_API_VERSION >= 2
2004     unsigned int size;
2005     objc_ivar **data(class_copyIvarList(_class, &size));
2006     for (size_t i(0); i != size; ++i)
2007         JSPropertyNameAccumulatorAddName(names, CYJSString(ivar_getName(data[i])));
2008     free(data);
2009 #else
2010     if (objc_ivar_list *ivars = _class->ivars)
2011         for (int i(0); i != ivars->ivar_count; ++i)
2012             JSPropertyNameAccumulatorAddName(names, CYJSString(ivar_getName(&ivars->ivar_list[i])));
2013 #endif
2014 }
2015
2016 static void Internal_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
2017     Internal *internal(reinterpret_cast<Internal *>(JSObjectGetPrivate(object)));
2018     CYPool pool;
2019
2020     id self(internal->GetValue());
2021     Class _class(object_getClass(self));
2022
2023     Internal_getPropertyNames_(_class, names);
2024 }
2025
2026 static JSValueRef Internal_callAsFunction_$cya(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2027     Internal *internal(reinterpret_cast<Internal *>(JSObjectGetPrivate(object)));
2028     return internal->GetOwner();
2029 }
2030
2031 static JSValueRef ObjectiveC_Classes_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
2032     CYPool pool;
2033     NSString *name(CYCastNSString(&pool, context, property));
2034     if (Class _class = NSClassFromString(name))
2035         return CYMakeInstance(context, _class, true);
2036     return NULL;
2037 } CYCatch(NULL) }
2038
2039 static void ObjectiveC_Classes_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
2040 #ifdef __APPLE__
2041     size_t size(objc_getClassList(NULL, 0));
2042     Class *data(reinterpret_cast<Class *>(malloc(sizeof(Class) * size)));
2043
2044   get:
2045     size_t writ(objc_getClassList(data, size));
2046     if (size < writ) {
2047         size = writ;
2048         if (Class *copy = reinterpret_cast<Class *>(realloc(data, sizeof(Class) * writ))) {
2049             data = copy;
2050             goto get;
2051         } else goto done;
2052     }
2053
2054     for (size_t i(0); i != writ; ++i)
2055         JSPropertyNameAccumulatorAddName(names, CYJSString(class_getName(data[i])));
2056
2057   done:
2058     free(data);
2059 #else
2060     void *state(NULL);
2061     while (Class _class = objc_next_class(&state))
2062         JSPropertyNameAccumulatorAddName(names, CYJSString(class_getName(_class)));
2063 #endif
2064 }
2065
2066 #if OBJC_API_VERSION >= 2
2067 static JSValueRef ObjectiveC_Image_Classes_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
2068     const char *internal(reinterpret_cast<const char *>(JSObjectGetPrivate(object)));
2069
2070     CYPool pool;
2071     const char *name(CYPoolCString(pool, context, property));
2072     unsigned int size;
2073     const char **data(objc_copyClassNamesForImage(internal, &size));
2074     JSValueRef value;
2075     for (size_t i(0); i != size; ++i)
2076         if (strcmp(name, data[i]) == 0) {
2077             if (Class _class = objc_getClass(name)) {
2078                 value = CYMakeInstance(context, _class, true);
2079                 goto free;
2080             } else
2081                 break;
2082         }
2083     value = NULL;
2084   free:
2085     free(data);
2086     return value;
2087 } CYCatch(NULL) }
2088
2089 static void ObjectiveC_Image_Classes_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
2090     const char *internal(reinterpret_cast<const char *>(JSObjectGetPrivate(object)));
2091     unsigned int size;
2092     const char **data(objc_copyClassNamesForImage(internal, &size));
2093     for (size_t i(0); i != size; ++i)
2094         JSPropertyNameAccumulatorAddName(names, CYJSString(data[i]));
2095     free(data);
2096 }
2097
2098 static JSValueRef ObjectiveC_Images_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
2099     CYPool pool;
2100     const char *name(CYPoolCString(pool, context, property));
2101     unsigned int size;
2102     const char **data(objc_copyImageNames(&size));
2103     for (size_t i(0); i != size; ++i)
2104         if (strcmp(name, data[i]) == 0) {
2105             name = data[i];
2106             goto free;
2107         }
2108     name = NULL;
2109   free:
2110     free(data);
2111     if (name == NULL)
2112         return NULL;
2113     JSObjectRef value(JSObjectMake(context, NULL, NULL));
2114     CYSetProperty(context, value, CYJSString("classes"), JSObjectMake(context, ObjectiveC_Image_Classes_, const_cast<char *>(name)));
2115     return value;
2116 } CYCatch(NULL) }
2117
2118 static void ObjectiveC_Images_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
2119     unsigned int size;
2120     const char **data(objc_copyImageNames(&size));
2121     for (size_t i(0); i != size; ++i)
2122         JSPropertyNameAccumulatorAddName(names, CYJSString(data[i]));
2123     free(data);
2124 }
2125 #endif
2126
2127 static JSValueRef ObjectiveC_Protocols_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
2128     CYPool pool;
2129     const char *name(CYPoolCString(pool, context, property));
2130     if (Protocol *protocol = objc_getProtocol(name))
2131         return CYMakeInstance(context, protocol, true);
2132     return NULL;
2133 } CYCatch(NULL) }
2134
2135 static void ObjectiveC_Protocols_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
2136 #if OBJC_API_VERSION >= 2
2137     unsigned int size;
2138     Protocol **data(objc_copyProtocolList(&size));
2139     for (size_t i(0); i != size; ++i)
2140         JSPropertyNameAccumulatorAddName(names, CYJSString(protocol_getName(data[i])));
2141     free(data);
2142 #else
2143     // XXX: fix this!
2144 #endif
2145 }
2146
2147 static JSValueRef ObjectiveC_Constants_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
2148     CYPool pool;
2149     CYUTF8String name(CYPoolUTF8String(pool, context, property));
2150     if (name == "nil")
2151         return Instance::Make(context, nil);
2152     return NULL;
2153 } CYCatch(NULL) }
2154
2155 static void ObjectiveC_Constants_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
2156     JSPropertyNameAccumulatorAddName(names, CYJSString("nil"));
2157 }
2158
2159 #ifdef __APPLE__
2160 #if defined(__i386__) || defined(__x86_64__)
2161 #define OBJC_MAX_STRUCT_BY_VALUE 8
2162 static int struct_forward_array[] = {
2163     0, 0, 0, 1, 0, 1, 1, 1, 0 };
2164 #elif defined(__arm__)
2165 #define OBJC_MAX_STRUCT_BY_VALUE 1
2166 static int struct_forward_array[] = {
2167     0, 0 };
2168 #else
2169 #error missing objc-runtime-info
2170 #endif
2171
2172 static bool stret(ffi_type *ffi_type) {
2173     return ffi_type->type == FFI_TYPE_STRUCT && (
2174         ffi_type->size > OBJC_MAX_STRUCT_BY_VALUE ||
2175         struct_forward_array[ffi_type->size] != 0
2176     );
2177 }
2178 #endif
2179
2180 JSValueRef CYSendMessage(CYPool &pool, JSContextRef context, id self, Class _class, SEL _cmd, size_t count, const JSValueRef arguments[], bool initialize, JSValueRef *exception) { CYTry {
2181     const char *type;
2182
2183     if (_class == NULL)
2184         _class = object_getClass(self);
2185
2186     IMP imp;
2187
2188     if (objc_method *method = class_getInstanceMethod(_class, _cmd)) {
2189         imp = method_getImplementation(method);
2190         type = method_getTypeEncoding(method);
2191     } else {
2192         imp = NULL;
2193
2194         CYPoolTry {
2195             NSMethodSignature *method([self methodSignatureForSelector:_cmd]);
2196             if (method == nil)
2197                 throw CYJSError(context, "unrecognized selector %s sent to object %p", sel_getName(_cmd), self);
2198             type = CYPoolCString(pool, context, [method _typeString]);
2199         } CYPoolCatch(NULL)
2200     }
2201
2202     void *setup[2];
2203     setup[0] = &self;
2204     setup[1] = &_cmd;
2205
2206     sig::Signature signature;
2207     sig::Parse(pool, &signature, type, &Structor_);
2208
2209     size_t used(count + 3);
2210     if (used > signature.count) {
2211         sig::Element *elements(new (pool) sig::Element[used]);
2212         memcpy(elements, signature.elements, used * sizeof(sig::Element));
2213
2214         for (size_t index(signature.count); index != used; ++index) {
2215             sig::Element *element(&elements[index]);
2216             element->name = NULL;
2217             element->offset = _not(size_t);
2218
2219             sig::Type *type(new (pool) sig::Type);
2220             memset(type, 0, sizeof(*type));
2221             type->primitive = sig::object_P;
2222             element->type = type;
2223         }
2224
2225         signature.elements = elements;
2226         signature.count = used;
2227     }
2228
2229     ffi_cif cif;
2230     sig::sig_ffi_cif(pool, &sig::ObjectiveC, &signature, &cif);
2231
2232     if (imp == NULL) {
2233 #ifdef __APPLE__
2234         if (stret(cif.rtype))
2235             imp = class_getMethodImplementation_stret(_class, _cmd);
2236         else
2237             imp = class_getMethodImplementation(_class, _cmd);
2238 #else
2239         objc_super super = {self, _class};
2240         imp = objc_msg_lookup_super(&super, _cmd);
2241 #endif
2242     }
2243
2244     void (*function)() = reinterpret_cast<void (*)()>(imp);
2245     return CYCallFunction(pool, context, 2, setup, count, arguments, initialize, exception, &signature, &cif, function);
2246 } CYCatch(NULL) }
2247
2248 static JSValueRef $objc_msgSend(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2249     if (count < 2)
2250         throw CYJSError(context, "too few arguments to objc_msgSend");
2251
2252     CYPool pool;
2253
2254     bool uninitialized;
2255
2256     id self;
2257     SEL _cmd;
2258     Class _class;
2259
2260     if (JSValueIsObjectOfClass(context, arguments[0], Super_)) {
2261         cy::Super *internal(reinterpret_cast<cy::Super *>(JSObjectGetPrivate((JSObjectRef) arguments[0])));
2262         self = internal->GetValue();
2263         _class = internal->class_;;
2264         uninitialized = false;
2265     } else if (CYJSValueIsNSObject(context, arguments[0])) {
2266         Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate((JSObjectRef) arguments[0])));
2267         self = internal->GetValue();
2268         _class = nil;
2269         uninitialized = internal->IsUninitialized();
2270         if (uninitialized)
2271             internal->value_ = nil;
2272     } else {
2273         self = CYCastNSObject(&pool, context, arguments[0]);
2274         _class = nil;
2275         uninitialized = false;
2276     }
2277
2278     if (self == nil)
2279         return CYJSNull(context);
2280
2281     _cmd = CYCastSEL(context, arguments[1]);
2282
2283     return CYSendMessage(pool, context, self, _class, _cmd, count - 2, arguments + 2, uninitialized, exception);
2284 } CYCatch(NULL) }
2285
2286 static JSValueRef Selector_callAsFunction(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2287     JSValueRef setup[count + 2];
2288     setup[0] = _this;
2289     setup[1] = object;
2290     memcpy(setup + 2, arguments, sizeof(JSValueRef) * count);
2291     return $objc_msgSend(context, NULL, NULL, count + 2, setup, exception);
2292 }
2293
2294 static JSValueRef Message_callAsFunction(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2295     CYPool pool;
2296     Message_privateData *internal(reinterpret_cast<Message_privateData *>(JSObjectGetPrivate(object)));
2297
2298     // XXX: handle Instance::Uninitialized?
2299     id self(CYCastNSObject(&pool, context, _this));
2300
2301     void *setup[2];
2302     setup[0] = &self;
2303     setup[1] = &internal->sel_;
2304
2305     return CYCallFunction(pool, context, 2, setup, count, arguments, false, exception, &internal->signature_, &internal->cif_, internal->GetValue());
2306 }
2307
2308 static JSObjectRef Super_new(JSContextRef context, JSObjectRef object, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2309     if (count != 2)
2310         throw CYJSError(context, "incorrect number of arguments to Super constructor");
2311     CYPool pool;
2312     id self(CYCastNSObject(&pool, context, arguments[0]));
2313     Class _class(CYCastClass(pool, context, arguments[1]));
2314     return cy::Super::Make(context, self, _class);
2315 } CYCatch(NULL) }
2316
2317 static JSObjectRef Selector_new(JSContextRef context, JSObjectRef object, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2318     if (count != 1)
2319         throw CYJSError(context, "incorrect number of arguments to Selector constructor");
2320     CYPool pool;
2321     const char *name(CYPoolCString(pool, context, arguments[0]));
2322     return CYMakeSelector(context, sel_registerName(name));
2323 } CYCatch(NULL) }
2324
2325 static JSObjectRef Instance_new(JSContextRef context, JSObjectRef object, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2326     if (count > 1)
2327         throw CYJSError(context, "incorrect number of arguments to Instance constructor");
2328     id self(count == 0 ? nil : CYCastPointer<id>(context, arguments[0]));
2329     return CYMakeInstance(context, self, false);
2330 } CYCatch(NULL) }
2331
2332 static JSValueRef CYValue_getProperty_value(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
2333     CYValue *internal(reinterpret_cast<CYValue *>(JSObjectGetPrivate(object)));
2334     return CYCastJSValue(context, reinterpret_cast<uintptr_t>(internal->value_));
2335 }
2336
2337 static JSValueRef CYValue_callAsFunction_$cya(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2338     CYValue *internal(reinterpret_cast<CYValue *>(JSObjectGetPrivate(_this)));
2339     Type_privateData *typical(internal->GetType());
2340
2341     sig::Type *type;
2342     ffi_type *ffi;
2343
2344     if (typical == NULL) {
2345         type = NULL;
2346         ffi = NULL;
2347     } else {
2348         type = typical->type_;
2349         ffi = typical->ffi_;
2350     }
2351
2352     return CYMakePointer(context, &internal->value_, _not(size_t), type, ffi, object);
2353 }
2354
2355 static JSValueRef Instance_getProperty_constructor(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
2356     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
2357     return Instance::Make(context, (id) object_getClass(internal->GetValue()));
2358 }
2359
2360 static JSValueRef Instance_getProperty_prototype(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
2361     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
2362     id self(internal->GetValue());
2363     if (!CYIsClass(self))
2364         return CYJSUndefined(context);
2365     return CYGetClassPrototype(context, self);
2366 } CYCatch(NULL) }
2367
2368 static JSValueRef Instance_getProperty_messages(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
2369     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
2370     id self(internal->GetValue());
2371     if (!CYIsClass(self))
2372         return CYJSUndefined(context);
2373     return Messages::Make(context, (Class) self);
2374 }
2375
2376 static JSValueRef Instance_callAsFunction_toCYON(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2377     if (!CYJSValueIsNSObject(context, _this))
2378         return NULL;
2379
2380     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(_this)));
2381     return CYCastJSValue(context, CYJSString(context, CYCastNSCYON(internal->GetValue(), false)));
2382 } CYCatch(NULL) }
2383
2384 static JSValueRef Instance_callAsFunction_toJSON(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2385     if (!CYJSValueIsNSObject(context, _this))
2386         return NULL;
2387
2388     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(_this)));
2389     id value(internal->GetValue());
2390
2391     CYPoolTry {
2392         NSString *key;
2393         if (count == 0)
2394             key = nil;
2395         else
2396             key = CYCastNSString(NULL, context, CYJSString(context, arguments[0]));
2397
2398         if (!CYImplements(value, object_getClass(value), @selector(cy$toJSON:inContext:)))
2399             return CYJSUndefined(context);
2400         else if (JSValueRef json = [value cy$toJSON:key inContext:context])
2401             return json;
2402         else
2403             return CYCastJSValue(context, CYJSString(context, [value description]));
2404     } CYPoolCatch(NULL)
2405 } CYCatch(NULL) return /*XXX*/ NULL; }
2406
2407 static JSValueRef Instance_callAsFunction_valueOf(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2408     if (!CYJSValueIsNSObject(context, _this))
2409         return NULL;
2410
2411     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(_this)));
2412     id value(internal->GetValue());
2413
2414     if (![value respondsToSelector:@selector(cy$valueOfInContext:)])
2415         return _this;
2416
2417     if (JSValueRef result = [value cy$valueOfInContext:context])
2418         return result;
2419
2420     return _this;
2421 } CYCatch(NULL) return /*XXX*/ NULL; }
2422
2423 static JSValueRef Instance_callAsFunction_toPointer(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2424     if (!CYJSValueIsNSObject(context, _this))
2425         return NULL;
2426
2427     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(_this)));
2428     // XXX: but... but... THIS ISN'T A POINTER! :(
2429     return CYCastJSValue(context, reinterpret_cast<uintptr_t>(internal->GetValue()));
2430 } CYCatch(NULL) return /*XXX*/ NULL; }
2431
2432 static JSValueRef Instance_callAsFunction_toString(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2433     if (!CYJSValueIsNSObject(context, _this))
2434         return NULL;
2435
2436     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(_this)));
2437     id value(internal->GetValue());
2438
2439     CYPoolTry {
2440         // XXX: this seems like a stupid implementation; what if it crashes? why not use the CYONifier backend?
2441         return CYCastJSValue(context, CYJSString(context, [value description]));
2442     } CYPoolCatch(NULL)
2443 } CYCatch(NULL) return /*XXX*/ NULL; }
2444
2445 static JSValueRef Class_callAsFunction_pointerTo(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2446     if (!CYJSValueIsNSObject(context, _this))
2447         return NULL;
2448
2449     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(_this)));
2450     id value(internal->GetValue());
2451
2452     if (!CYIsClass(value))
2453         CYThrow("non-Class object cannot be used as Type");
2454
2455     // XXX: this is a very silly implementation
2456
2457     std::ostringstream type;
2458     type << "@\"";
2459     type << class_getName(value);
2460     type << "\"";
2461
2462     CYPoolTry {
2463         return CYMakeType(context, type.str().c_str());
2464     } CYPoolCatch(NULL)
2465 } CYCatch(NULL) return /*XXX*/ NULL; }
2466
2467 static JSValueRef Selector_callAsFunction_toString(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2468     Selector_privateData *internal(reinterpret_cast<Selector_privateData *>(JSObjectGetPrivate(_this)));
2469     return CYCastJSValue(context, sel_getName(internal->GetValue()));
2470 } CYCatch(NULL) }
2471
2472 static JSValueRef Selector_callAsFunction_toJSON(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2473     return Selector_callAsFunction_toString(context, object, _this, count, arguments, exception);
2474 }
2475
2476 static JSValueRef Selector_callAsFunction_toCYON(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2477     Selector_privateData *internal(reinterpret_cast<Selector_privateData *>(JSObjectGetPrivate(_this)));
2478     const char *name(sel_getName(internal->GetValue()));
2479
2480     CYPoolTry {
2481         NSString *string([NSString stringWithFormat:@"@selector(%s)", name]);
2482         return CYCastJSValue(context, CYJSString(context, string));
2483     } CYPoolCatch(NULL)
2484 } CYCatch(NULL) return /*XXX*/ NULL; }
2485
2486 static JSValueRef Selector_callAsFunction_type(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2487     if (count != 1)
2488         throw CYJSError(context, "incorrect number of arguments to Selector.type");
2489
2490     CYPool pool;
2491     Selector_privateData *internal(reinterpret_cast<Selector_privateData *>(JSObjectGetPrivate(_this)));
2492     SEL sel(internal->GetValue());
2493
2494     objc_method *method;
2495     if (Class _class = CYCastClass(pool, context, arguments[0]))
2496         method = class_getInstanceMethod(_class, sel);
2497     else
2498         method = NULL;
2499
2500     if (const char *type = CYPoolTypeEncoding(pool, context, sel, method))
2501         return CYCastJSValue(context, CYJSString(type));
2502
2503     return CYJSNull(context);
2504 } CYCatch(NULL) }
2505
2506 static JSStaticValue Selector_staticValues[2] = {
2507     {"value", &CYValue_getProperty_value, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontDelete},
2508     {NULL, NULL, NULL, 0}
2509 };
2510
2511 static JSStaticValue Instance_staticValues[5] = {
2512     {"constructor", &Instance_getProperty_constructor, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2513     {"messages", &Instance_getProperty_messages, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2514     {"prototype", &Instance_getProperty_prototype, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2515     {"value", &CYValue_getProperty_value, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2516     {NULL, NULL, NULL, 0}
2517 };
2518
2519 static JSStaticFunction Instance_staticFunctions[7] = {
2520     {"$cya", &CYValue_callAsFunction_$cya, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2521     {"toCYON", &Instance_callAsFunction_toCYON, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2522     {"toJSON", &Instance_callAsFunction_toJSON, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2523     {"valueOf", &Instance_callAsFunction_valueOf, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2524     {"toPointer", &Instance_callAsFunction_toPointer, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2525     {"toString", &Instance_callAsFunction_toString, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2526     {NULL, NULL, 0}
2527 };
2528
2529 static JSStaticFunction Class_staticFunctions[2] = {
2530     {"pointerTo", &Class_callAsFunction_pointerTo, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2531     {NULL, NULL, 0}
2532 };
2533
2534 static JSStaticFunction Internal_staticFunctions[2] = {
2535     {"$cya", &Internal_callAsFunction_$cya, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2536     {NULL, NULL, 0}
2537 };
2538
2539 static JSStaticFunction Selector_staticFunctions[5] = {
2540     {"toCYON", &Selector_callAsFunction_toCYON, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2541     {"toJSON", &Selector_callAsFunction_toJSON, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2542     {"toString", &Selector_callAsFunction_toString, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2543     {"type", &Selector_callAsFunction_type, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2544     {NULL, NULL, 0}
2545 };
2546
2547 #ifdef __APPLE__
2548 JSValueRef NSCFType$cy$toJSON$inContext$(id self, SEL sel, JSValueRef key, JSContextRef context) { CYObjectiveTry_(context) {
2549     return CYCastJSValue(context, [(NSString *) CFCopyDescription((CFTypeRef) self) autorelease]);
2550 } CYObjectiveCatch }
2551 #endif
2552
2553 void CYObjectiveC_Initialize() { /*XXX*/ JSContextRef context(NULL); CYPoolTry {
2554     $objc_setAssociatedObject = reinterpret_cast<void (*)(id, void *, id value, objc_AssociationPolicy)>(dlsym(RTLD_DEFAULT, "objc_setAssociatedObject"));
2555     $objc_getAssociatedObject = reinterpret_cast<id (*)(id, void *)>(dlsym(RTLD_DEFAULT, "objc_getAssociatedObject"));
2556     $objc_removeAssociatedObjects = reinterpret_cast<void (*)(id)>(dlsym(RTLD_DEFAULT, "objc_removeAssociatedObjects"));
2557
2558     CYPool &pool(CYGetGlobalPool());
2559
2560     Object_type = new(pool) Type_privateData("@");
2561     Selector_type = new(pool) Type_privateData(":");
2562
2563 #ifdef __APPLE__
2564     // XXX: apparently, iOS now has both of these
2565     NSCFBoolean_ = objc_getClass("__NSCFBoolean");
2566     if (NSCFBoolean_ == nil)
2567         NSCFBoolean_ = objc_getClass("NSCFBoolean");
2568
2569     NSCFType_ = objc_getClass("NSCFType");
2570     NSGenericDeallocHandler_ = objc_getClass("__NSGenericDeallocHandler");
2571     NSMessageBuilder_ = objc_getClass("NSMessageBuilder");
2572     NSZombie_ = objc_getClass("_NSZombie_");
2573 #else
2574     NSBoolNumber_ = objc_getClass("NSBoolNumber");
2575 #endif
2576
2577     NSArray_ = objc_getClass("NSArray");
2578     NSBlock_ = objc_getClass("NSBlock");
2579     NSDictionary_ = objc_getClass("NSDictionary");
2580     NSString_ = objc_getClass("NSString");
2581     Object_ = objc_getClass("Object");
2582
2583     JSClassDefinition definition;
2584
2585     definition = kJSClassDefinitionEmpty;
2586     definition.className = "Instance";
2587     definition.staticValues = Instance_staticValues;
2588     definition.staticFunctions = Instance_staticFunctions;
2589     definition.hasProperty = &Instance_hasProperty;
2590     definition.getProperty = &Instance_getProperty;
2591     definition.setProperty = &Instance_setProperty;
2592     definition.deleteProperty = &Instance_deleteProperty;
2593     definition.getPropertyNames = &Instance_getPropertyNames;
2594     definition.callAsConstructor = &Instance_callAsConstructor;
2595     definition.callAsFunction = &Instance_callAsFunction;
2596     definition.hasInstance = &Instance_hasInstance;
2597     definition.finalize = &CYFinalize;
2598     Instance_ = JSClassCreate(&definition);
2599
2600     definition.className = "ArrayInstance";
2601     ArrayInstance_ = JSClassCreate(&definition);
2602
2603     definition.className = "FunctionInstance";
2604     FunctionInstance_ = JSClassCreate(&definition);
2605
2606     definition.className = "ObjectInstance";
2607     ObjectInstance_ = JSClassCreate(&definition);
2608
2609     definition.className = "StringInstance";
2610     StringInstance_ = JSClassCreate(&definition);
2611
2612     definition = kJSClassDefinitionEmpty;
2613     definition.className = "Class";
2614     definition.staticFunctions = Class_staticFunctions;
2615     Class_ = JSClassCreate(&definition);
2616
2617     definition = kJSClassDefinitionEmpty;
2618     definition.className = "Internal";
2619     definition.staticFunctions = Internal_staticFunctions;
2620     definition.hasProperty = &Internal_hasProperty;
2621     definition.getProperty = &Internal_getProperty;
2622     definition.setProperty = &Internal_setProperty;
2623     definition.getPropertyNames = &Internal_getPropertyNames;
2624     definition.finalize = &CYFinalize;
2625     Internal_ = JSClassCreate(&definition);
2626
2627     definition = kJSClassDefinitionEmpty;
2628     definition.className = "Message";
2629     definition.staticFunctions = cy::Functor::StaticFunctions;
2630     definition.callAsFunction = &Message_callAsFunction;
2631     definition.finalize = &CYFinalize;
2632     Message_ = JSClassCreate(&definition);
2633
2634     definition = kJSClassDefinitionEmpty;
2635     definition.className = "Messages";
2636     definition.hasProperty = &Messages_hasProperty;
2637     definition.getProperty = &Messages_getProperty;
2638     definition.setProperty = &Messages_setProperty;
2639 #if 0 && OBJC_API_VERSION < 2
2640     definition.deleteProperty = &Messages_deleteProperty;
2641 #endif
2642     definition.getPropertyNames = &Messages_getPropertyNames;
2643     definition.finalize = &CYFinalize;
2644     Messages_ = JSClassCreate(&definition);
2645
2646     definition = kJSClassDefinitionEmpty;
2647     definition.className = "Selector";
2648     definition.staticValues = Selector_staticValues;
2649     definition.staticFunctions = Selector_staticFunctions;
2650     definition.callAsFunction = &Selector_callAsFunction;
2651     definition.finalize = &CYFinalize;
2652     Selector_ = JSClassCreate(&definition);
2653
2654     definition = kJSClassDefinitionEmpty;
2655     definition.className = "Super";
2656     definition.staticFunctions = Internal_staticFunctions;
2657     definition.finalize = &CYFinalize;
2658     Super_ = JSClassCreate(&definition);
2659
2660     definition = kJSClassDefinitionEmpty;
2661     definition.className = "ObjectiveC::Classes";
2662     definition.getProperty = &ObjectiveC_Classes_getProperty;
2663     definition.getPropertyNames = &ObjectiveC_Classes_getPropertyNames;
2664     ObjectiveC_Classes_ = JSClassCreate(&definition);
2665
2666     definition = kJSClassDefinitionEmpty;
2667     definition.className = "ObjectiveC::Constants";
2668     definition.getProperty = &ObjectiveC_Constants_getProperty;
2669     definition.getPropertyNames = &ObjectiveC_Constants_getPropertyNames;
2670     ObjectiveC_Constants_ = JSClassCreate(&definition);
2671
2672 #if OBJC_API_VERSION >= 2
2673     definition = kJSClassDefinitionEmpty;
2674     definition.className = "ObjectiveC::Images";
2675     definition.getProperty = &ObjectiveC_Images_getProperty;
2676     definition.getPropertyNames = &ObjectiveC_Images_getPropertyNames;
2677     ObjectiveC_Images_ = JSClassCreate(&definition);
2678
2679     definition = kJSClassDefinitionEmpty;
2680     definition.className = "ObjectiveC::Image::Classes";
2681     definition.getProperty = &ObjectiveC_Image_Classes_getProperty;
2682     definition.getPropertyNames = &ObjectiveC_Image_Classes_getPropertyNames;
2683     ObjectiveC_Image_Classes_ = JSClassCreate(&definition);
2684 #endif
2685
2686     definition = kJSClassDefinitionEmpty;
2687     definition.className = "ObjectiveC::Protocols";
2688     definition.getProperty = &ObjectiveC_Protocols_getProperty;
2689     definition.getPropertyNames = &ObjectiveC_Protocols_getPropertyNames;
2690     ObjectiveC_Protocols_ = JSClassCreate(&definition);
2691
2692 #ifdef __APPLE__
2693     class_addMethod(NSCFType_, @selector(cy$toJSON:inContext:), reinterpret_cast<IMP>(&NSCFType$cy$toJSON$inContext$), "^{OpaqueJSValue=}16@0:4@8^{OpaqueJSContext=}12");
2694 #endif
2695 } CYPoolCatch() }
2696
2697 void CYObjectiveC_SetupContext(JSContextRef context) { CYPoolTry {
2698     JSObjectRef global(CYGetGlobalObject(context));
2699     JSObjectRef cy(CYCastJSObject(context, CYGetProperty(context, global, cy_s)));
2700     JSObjectRef cycript(CYCastJSObject(context, CYGetProperty(context, global, CYJSString("Cycript"))));
2701     JSObjectRef all(CYCastJSObject(context, CYGetProperty(context, cycript, CYJSString("all"))));
2702     JSObjectRef alls(CYCastJSObject(context, CYGetProperty(context, cycript, CYJSString("alls"))));
2703
2704     JSObjectRef ObjectiveC(JSObjectMake(context, NULL, NULL));
2705     CYSetProperty(context, cycript, CYJSString("ObjectiveC"), ObjectiveC);
2706
2707     JSObjectRef protocols(JSObjectMake(context, ObjectiveC_Protocols_, NULL));
2708     CYSetProperty(context, ObjectiveC, CYJSString("protocols"), protocols);
2709     CYArrayPush(context, alls, protocols);
2710
2711     JSObjectRef classes(JSObjectMake(context, ObjectiveC_Classes_, NULL));
2712     CYSetProperty(context, ObjectiveC, CYJSString("classes"), classes);
2713     CYArrayPush(context, alls, classes);
2714
2715     JSObjectRef constants(JSObjectMake(context, ObjectiveC_Constants_, NULL));
2716     CYSetProperty(context, ObjectiveC, CYJSString("constants"), constants);
2717     CYArrayPush(context, alls, constants);
2718
2719 #if OBJC_API_VERSION >= 2
2720     CYSetProperty(context, ObjectiveC, CYJSString("images"), JSObjectMake(context, ObjectiveC_Images_, NULL));
2721 #endif
2722
2723     JSObjectRef Class(JSObjectMakeConstructor(context, Class_, NULL));
2724     JSObjectRef Instance(JSObjectMakeConstructor(context, Instance_, &Instance_new));
2725     JSObjectRef Message(JSObjectMakeConstructor(context, Message_, NULL));
2726     JSObjectRef Selector(JSObjectMakeConstructor(context, Selector_, &Selector_new));
2727     JSObjectRef Super(JSObjectMakeConstructor(context, Super_, &Super_new));
2728
2729     JSObjectRef Instance_prototype(CYCastJSObject(context, CYGetProperty(context, Instance, prototype_s)));
2730     CYSetProperty(context, cy, CYJSString("Instance_prototype"), Instance_prototype);
2731
2732     JSObjectRef ArrayInstance(JSObjectMakeConstructor(context, ArrayInstance_, NULL));
2733     JSObjectRef ArrayInstance_prototype(CYCastJSObject(context, CYGetProperty(context, ArrayInstance, prototype_s)));
2734     CYSetProperty(context, cy, CYJSString("ArrayInstance_prototype"), ArrayInstance_prototype);
2735     JSObjectRef Array_prototype(CYGetCachedObject(context, CYJSString("Array_prototype")));
2736     JSObjectSetPrototype(context, ArrayInstance_prototype, Array_prototype);
2737
2738     JSObjectRef FunctionInstance(JSObjectMakeConstructor(context, FunctionInstance_, NULL));
2739     JSObjectRef FunctionInstance_prototype(CYCastJSObject(context, CYGetProperty(context, FunctionInstance, prototype_s)));
2740     CYSetProperty(context, cy, CYJSString("FunctionInstance_prototype"), FunctionInstance_prototype);
2741     JSObjectRef Function_prototype(CYGetCachedObject(context, CYJSString("Function_prototype")));
2742     JSObjectSetPrototype(context, FunctionInstance_prototype, Function_prototype);
2743
2744     JSObjectRef ObjectInstance(JSObjectMakeConstructor(context, ObjectInstance_, NULL));
2745     JSObjectRef ObjectInstance_prototype(CYCastJSObject(context, CYGetProperty(context, ObjectInstance, prototype_s)));
2746     CYSetProperty(context, cy, CYJSString("ObjectInstance_prototype"), ObjectInstance_prototype);
2747     JSObjectRef Object_prototype(CYGetCachedObject(context, CYJSString("Object_prototype")));
2748     JSObjectSetPrototype(context, ObjectInstance_prototype, Object_prototype);
2749
2750     JSObjectRef StringInstance(JSObjectMakeConstructor(context, StringInstance_, NULL));
2751     JSObjectRef StringInstance_prototype(CYCastJSObject(context, CYGetProperty(context, StringInstance, prototype_s)));
2752     CYSetProperty(context, cy, CYJSString("StringInstance_prototype"), StringInstance_prototype);
2753     JSObjectRef String_prototype(CYGetCachedObject(context, CYJSString("String_prototype")));
2754     JSObjectSetPrototype(context, StringInstance_prototype, String_prototype);
2755
2756     JSObjectRef Class_prototype(CYCastJSObject(context, CYGetProperty(context, Class, prototype_s)));
2757     CYSetProperty(context, cy, CYJSString("Class_prototype"), Class_prototype);
2758     JSObjectSetPrototype(context, Class_prototype, Instance_prototype);
2759
2760     CYSetProperty(context, cycript, CYJSString("Instance"), Instance);
2761     CYSetProperty(context, cycript, CYJSString("Selector"), Selector);
2762     CYSetProperty(context, cycript, CYJSString("Super"), Super);
2763
2764     JSObjectRef box(JSObjectMakeFunctionWithCallback(context, CYJSString("box"), &Instance_box_callAsFunction));
2765     CYSetProperty(context, Instance, CYJSString("box"), box);
2766
2767 #if defined(__APPLE__) && defined(__arm__) && 0
2768     CYSetProperty(context, all, CYJSString("objc_registerClassPair"), &objc_registerClassPair_, kJSPropertyAttributeDontEnum);
2769 #endif
2770
2771     CYSetProperty(context, all, CYJSString("objc_msgSend"), &$objc_msgSend, kJSPropertyAttributeDontEnum);
2772
2773     JSObjectSetPrototype(context, CYCastJSObject(context, CYGetProperty(context, Message, prototype_s)), Function_prototype);
2774     JSObjectSetPrototype(context, CYCastJSObject(context, CYGetProperty(context, Selector, prototype_s)), Function_prototype);
2775 } CYPoolCatch() }
2776
2777 static CYHooks CYObjectiveCHooks = {
2778     &CYObjectiveC_ExecuteStart,
2779     &CYObjectiveC_ExecuteEnd,
2780     &CYObjectiveC_CallFunction,
2781     &CYObjectiveC_Initialize,
2782     &CYObjectiveC_SetupContext,
2783     &CYObjectiveC_PoolFFI,
2784     &CYObjectiveC_FromFFI,
2785 };
2786
2787 struct CYObjectiveC {
2788     CYObjectiveC() {
2789         hooks_ = &CYObjectiveCHooks;
2790         // XXX: evil magic juju to make this actually take effect on a Mac when compiled with autoconf/libtool doom!
2791         _assert(hooks_ != NULL);
2792     }
2793 } CYObjectiveC;