Cycript.yy.in

   1 /* Cycript - Optimizing JavaScript Compiler/Runtime
   2  * Copyright (C) 2009-2015  Jay Freeman (saurik)
   3 */
   4
   5 /* GNU Affero General Public License, Version 3 {{{ */
   6 /*
   7  * This program is free software: you can redistribute it and/or modify
   8  * it under the terms of the GNU Affero General Public License as published by
   9  * the Free Software Foundation, either version 3 of the License, or
  10  * (at your option) any later version.
  11
  12  * This program is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU Affero General Public License for more details.
  16
  17  * You should have received a copy of the GNU Affero General Public License
  18  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 **/
  20 /* }}} */
  21
  22 %code top {
  23 #define cyscanner driver.scanner_
  24 #define YYSTACKEXPANDABLE 1
  25 }
  26
  27 %code requires {
  28 #include "Driver.hpp"
  29 #include "Parser.hpp"
  30 #define CYNew new($pool)
  31
  32 @begin ObjectiveC
  33 #include "ObjectiveC/Syntax.hpp"
  34 @end
  35
  36 @begin E4X
  37 #include "E4X/Syntax.hpp"
  38 @end
  39
  40 #include "Highlight.hpp"
  41
  42 typedef struct {
  43     bool newline_;
  44     hi::Value highlight_;
  45
  46     union {
  47         bool bool_;
  48
  49         CYDriver::Condition condition_;
  50
  51         CYArgument *argument_;
  52         CYAssignment *assignment_;
  53         CYBoolean *boolean_;
  54         CYClause *clause_;
  55         cy::Syntax::Catch *catch_;
  56         CYComment *comment_;
  57         CYComprehension *comprehension_;
  58         CYCompound *compound_;
  59         CYDeclaration *declaration_;
  60         CYDeclarations *declarations_;
  61         CYElement *element_;
  62         CYExpression *expression_;
  63         CYFalse *false_;
  64         CYFinally *finally_;
  65         CYForInitialiser *for_;
  66         CYForInInitialiser *forin_;
  67         CYFunctionParameter *functionParameter_;
  68         CYIdentifier *identifier_;
  69         CYInfix *infix_;
  70         CYLiteral *literal_;
  71         CYMember *member_;
  72         CYModule *module_;
  73         CYNull *null_;
  74         CYNumber *number_;
  75         CYProgram *program_;
  76         CYProperty *property_;
  77         CYPropertyName *propertyName_;
  78         CYRubyProc *rubyProc_;
  79         CYStatement *statement_;
  80         CYString *string_;
  81         CYThis *this_;
  82         CYTrue *true_;
  83         CYWord *word_;
  84
  85 @begin C
  86         CYTypeModifier *modifier_;
  87         CYTypeSpecifier *specifier_;
  88         CYTypedIdentifier *typedIdentifier_;
  89         CYTypedParameter *typedParameter_;
  90 @end
  91
  92 @begin ObjectiveC
  93         CYClassName *className_;
  94         CYClassField *classField_;
  95         CYMessage *message_;
  96         CYMessageParameter *messageParameter_;
  97         CYProtocol *protocol_;
  98         CYSelectorPart *selector_;
  99 @end
 100
 101 @begin E4X
 102         CYAttribute *attribute_;
 103         CYPropertyIdentifier *propertyIdentifier_;
 104         CYSelector *selector_;
 105 @end
 106     };
 107 } YYSTYPE;
 108
 109 #define YYSTYPE YYSTYPE
 110 }
 111
 112 %code provides {
 113 int cylex(YYSTYPE *, CYLocation *, void *);
 114 }
 115
 116 %name-prefix "cy"
 117
 118 %language "C++"
 119
 120 %initial-action {
 121     @$.begin.filename = @$.end.filename = &driver.filename_;
 122 };
 123
 124 %locations
 125 %defines
 126
 127 %define api.location.type { CYLocation }
 128
 129 //%glr-parser
 130 //%expect 1
 131
 132 %error-verbose
 133
 134 %parse-param { CYDriver &driver }
 135 %lex-param { void *cyscanner }
 136
 137 /* Token Declarations {{{ */
 138 @begin E4X
 139 %token XMLCDATA
 140 %token XMLComment
 141 %token XMLPI
 142
 143 %token XMLAttributeValue
 144 %token XMLName
 145 %token XMLTagCharacters
 146 %token XMLText
 147 %token XMLWhitespace
 148 @end
 149
 150 @begin E4X
 151 %token LeftRight "<>"
 152 %token LeftSlashRight "</>"
 153
 154 %token SlashRight "/>"
 155 %token LeftSlash "</"
 156
 157 %token ColonColon "::"
 158 %token PeriodPeriod ".."
 159 @end
 160
 161 @begin E4X ObjectiveC
 162 %token At "@"
 163 %token Pound "#"
 164 @end
 165
 166 %token Ampersand "&"
 167 %token AmpersandAmpersand "&&"
 168 %token AmpersandEqual "&="
 169 %token Carrot "^"
 170 %token CarrotEqual "^="
 171 %token Equal "="
 172 %token EqualEqual "=="
 173 %token EqualEqualEqual "==="
 174 %token EqualRight "=>"
 175 %token Exclamation "!"
 176 %token ExclamationEqual "!="
 177 %token ExclamationEqualEqual "!=="
 178 %token Hyphen "-"
 179 %token HyphenEqual "-="
 180 %token HyphenHyphen "--"
 181 %token HyphenHyphen_ "\n--"
 182 %token HyphenRight "->"
 183 %token Left "<"
 184 %token LeftEqual "<="
 185 %token LeftLeft "<<"
 186 %token LeftLeftEqual "<<="
 187 %token Percent "%"
 188 %token PercentEqual "%="
 189 %token Period "."
 190 %token PeriodPeriodPeriod "..."
 191 %token Pipe "|"
 192 %token PipeEqual "|="
 193 %token PipePipe "||"
 194 %token Plus "+"
 195 %token PlusEqual "+="
 196 %token PlusPlus "++"
 197 %token PlusPlus_ "\n++"
 198 %token Right ">"
 199 %token RightEqual ">="
 200 %token RightRight ">>"
 201 %token RightRightEqual ">>="
 202 %token RightRightRight ">>>"
 203 %token RightRightRightEqual ">>>="
 204 %token Slash "/"
 205 %token SlashEqual "/="
 206 %token Star "*"
 207 %token StarEqual "*="
 208 %token Tilde "~"
 209
 210 %token Colon ":"
 211 %token Comma ","
 212 %token Question "?"
 213 %token SemiColon ";"
 214 %token NewLine "\n"
 215
 216 %token <comment_> Comment
 217
 218 %token OpenParen "("
 219 %token CloseParen ")"
 220
 221 %token OpenBrace "{"
 222 %token OpenBrace_ "\n{"
 223 %token OpenBrace__ ";{"
 224 %token CloseBrace "}"
 225
 226 %token OpenBracket "["
 227 %token CloseBracket "]"
 228
 229 %token AtError "@error"
 230
 231 @begin Java
 232 %token AtClass "@class"
 233 @end
 234
 235 @begin C
 236 %token <identifier_> Typedef "typedef"
 237 %token <identifier_> Unsigned "unsigned"
 238 %token <identifier_> Signed "signed"
 239 %token <identifier_> Extern "extern"
 240 @end
 241
 242 @begin C
 243 %token AtEncode "@encode"
 244 @end
 245
 246 @begin ObjectiveC
 247 %token AtImplementation "@implementation"
 248 %token AtImplementation_ ";@implementation"
 249 %token AtImport "@import"
 250 %token AtEnd "@end"
 251 %token AtSelector "@selector"
 252 %token <identifier_> Yes "YES"
 253 %token <identifier_> No "NO"
 254 @end
 255
 256 %token <false_> False "false"
 257 %token <null_> Null "null"
 258 %token <true_> True "true"
 259
 260 // ES3/ES5/WIE/JSC Reserved
 261 %token <word_> Auto "auto"
 262 %token <word_> Break "break"
 263 %token <word_> Case "case"
 264 %token <word_> Catch "catch"
 265 %token <word_> Continue "continue"
 266 %token <word_> Default "default"
 267 %token <word_> Delete "delete"
 268 %token <word_> Do "do"
 269 %token <word_> Else "else"
 270 %token <word_> Finally "finally"
 271 %token <word_> For "for"
 272 %token <word_> Function "function"
 273 %token <word_> Function_ ";function"
 274 %token <word_> If "if"
 275 %token <word_> In "in"
 276 %token <word_> In_ "!in"
 277 %token <word_> InstanceOf "instanceof"
 278 %token <word_> New "new"
 279 %token <word_> Return "return"
 280 %token <word_> Switch "switch"
 281 %token <this_> This "this"
 282 %token <word_> Throw "throw"
 283 %token <word_> Try "try"
 284 %token <word_> TypeOf "typeof"
 285 %token <word_> Var "var"
 286 %token <word_> Void "void"
 287 %token <word_> While "while"
 288 %token <word_> With "with"
 289
 290 // ES3/IE6 Future, ES5/JSC Reserved
 291 %token <word_> Debugger "debugger"
 292
 293 // ES3/ES5/IE6 Future, JSC Reserved
 294 %token <word_> Const "const"
 295
 296 // ES3/ES5/IE6/JSC Future
 297 %token <word_> Class "class"
 298 %token <word_> Enum "enum"
 299 %token <word_> Export "export"
 300 %token <word_> Extends "extends"
 301 %token <word_> Import "import"
 302 %token <word_> Super "super"
 303
 304 // ES3 Future, ES5 Strict Future
 305 %token <identifier_> Implements "implements"
 306 %token <identifier_> Interface "interface"
 307 %token <identifier_> Package "package"
 308 %token <identifier_> Private "private"
 309 %token <identifier_> Protected "protected"
 310 %token <identifier_> Public "public"
 311 %token <identifier_> Static "static"
 312
 313 // ES3 Future
 314 %token <identifier_> Abstract "abstract"
 315 %token <identifier_> Boolean "boolean"
 316 %token <identifier_> Byte "byte"
 317 %token <identifier_> Char "char"
 318 %token <identifier_> Double "double"
 319 %token <identifier_> Final "final"
 320 %token <identifier_> Float "float"
 321 %token <identifier_> Goto "goto"
 322 %token <identifier_> Int "int"
 323 %token <identifier_> Long "long"
 324 %token <identifier_> Native "native"
 325 %token <identifier_> Short "short"
 326 %token <identifier_> Synchronized "synchronized"
 327 %token <identifier_> Throws "throws"
 328 %token <identifier_> Transient "transient"
 329 %token <identifier_> Volatile "volatile"
 330
 331 // ES5 Strict
 332 %token <identifier_> Let "let"
 333 %token <identifier_> Yield "yield"
 334
 335 // Woah?!
 336 %token <identifier_> Each "each"
 337 %token <identifier_> Of "of"
 338
 339 @begin E4X
 340 // E4X Conditional
 341 %token <identifier_> Namespace "namespace"
 342 %token <identifier_> XML "xml"
 343 @end
 344
 345 %token AutoComplete
 346
 347 %token <identifier_> Identifier_
 348 %token <number_> NumericLiteral
 349 %token <string_> StringLiteral
 350 %token <literal_> RegularExpressionLiteral
 351
 352 %type <expression_> AdditiveExpression
 353 %type <argument_> ArgumentList_
 354 %type <argument_> ArgumentList
 355 %type <argument_> ArgumentListOpt
 356 %type <argument_> Arguments
 357 %type <expression_> ArrayComprehension
 358 %type <expression_> ArrayInitialiser
 359 %type <literal_> ArrayLiteral
 360 %type <expression_> ArrowFunction
 361 %type <functionParameter_> ArrowParameters
 362 %type <expression_> AssignmentExpression
 363 %type <identifier_> Binding
 364 %type <identifier_> BindingIdentifier
 365 %type <expression_> BitwiseANDExpression
 366 %type <statement_> Block_
 367 %type <statement_> Block
 368 %type <boolean_> BooleanLiteral
 369 %type <declaration_> BindingElement
 370 %type <expression_> BitwiseORExpression
 371 %type <expression_> BitwiseXORExpression
 372 %type <statement_> BreakStatement
 373 %type <statement_> BreakableStatement
 374 %type <expression_> CallExpression_
 375 %type <expression_> CallExpression
 376 %type <clause_> CaseBlock
 377 %type <clause_> CaseClause
 378 %type <clause_> CaseClausesOpt
 379 %type <catch_> CatchOpt
 380 %type <expression_> Comprehension
 381 %type <comprehension_> ComprehensionFor
 382 %type <comprehension_> ComprehensionIf
 383 %type <comprehension_> ComprehensionTail
 384 %type <expression_> ConditionalExpression
 385 %type <statement_> ContinueStatement
 386 %type <statement_> ConciseBody
 387 %type <statement_> DebuggerStatement
 388 %type <statement_> Declaration__
 389 %type <statement_> Declaration_
 390 %type <statement_> Declaration
 391 %type <clause_> DefaultClause
 392 %type <expression_> Element
 393 %type <expression_> ElementOpt
 394 %type <element_> ElementList
 395 %type <element_> ElementListOpt
 396 %type <statement_> ElseStatementOpt
 397 %type <statement_> EmptyStatement
 398 %type <expression_> EqualityExpression
 399 %type <compound_> Expression_
 400 %type <compound_> Expression
 401 %type <expression_> ExpressionOpt
 402 %type <statement_> ExpressionStatement
 403 %type <finally_> FinallyOpt
 404 %type <for_> ForStatementInitialiser
 405 %type <forin_> ForInStatementInitialiser
 406 %type <declaration_> FormalParameter
 407 %type <functionParameter_> FormalParameterList_
 408 %type <functionParameter_> FormalParameterList
 409 %type <functionParameter_> FormalParameterListOpt
 410 %type <statement_> FunctionBody
 411 %type <statement_> FunctionDeclaration
 412 %type <expression_> FunctionExpression
 413 %type <identifier_> Identifier
 414 %type <identifier_> IdentifierOpt
 415 %type <identifier_> IdentifierType
 416 %type <word_> IdentifierName
 417 %type <statement_> IfStatement
 418 %type <expression_> Initialiser
 419 %type <expression_> InitialiserOpt
 420 %type <statement_> IterationStatement
 421 %type <statement_> LabelledStatement
 422 %type <expression_> LeftHandSideExpression
 423 %type <statement_> LetStatement
 424 %type <statement_> LexicalDeclaration
 425 %type <literal_> Literal
 426 %type <literal_> ValueLiteral
 427 %type <expression_> LogicalANDExpression
 428 %type <expression_> LogicalORExpression
 429 %type <member_> MemberAccess
 430 %type <expression_> MemberExpression_
 431 %type <expression_> MemberExpression
 432 %type <module_> Module
 433 %type <expression_> MultiplicativeExpression
 434 %type <expression_> NewExpression
 435 %type <null_> NullLiteral
 436 %type <literal_> ObjectLiteral
 437 %type <compound_> Parenthetical
 438 %type <expression_> PostfixExpression
 439 %type <expression_> PrimaryExpression
 440 %type <statement_> Program
 441 %type <statement_> ProgramBody
 442 %type <statement_> ProgramBodyOpt
 443 %type <propertyName_> PropertyName_
 444 %type <propertyName_> PropertyName
 445 %type <property_> PropertyDefinition
 446 %type <property_> PropertyDefinitionList_
 447 %type <property_> PropertyDefinitionList
 448 %type <property_> PropertyDefinitionListOpt
 449 %type <expression_> RelationalExpression
 450 %type <statement_> ReturnStatement
 451 %type <rubyProc_> RubyProcExpression
 452 %type <functionParameter_> RubyProcParameterList_
 453 %type <functionParameter_> RubyProcParameterList
 454 %type <functionParameter_> RubyProcParameters
 455 %type <functionParameter_> RubyProcParametersOpt
 456 %type <expression_> ShiftExpression
 457 %type <declaration_> SingleNameBinding
 458 %type <statement_> Statement__
 459 %type <statement_> Statement_
 460 %type <statement_> Statement
 461 %type <statement_> StatementList
 462 %type <statement_> StatementListOpt
 463 %type <statement_> StatementListItem
 464 %type <statement_> SwitchStatement
 465 %type <statement_> ThrowStatement
 466 %type <statement_> TryStatement
 467 %type <expression_> UnaryExpression_
 468 %type <expression_> UnaryExpression
 469 %type <declaration_> VariableDeclaration
 470 %type <declarations_> VariableDeclarationList_
 471 %type <declarations_> VariableDeclarationList
 472 %type <statement_> VariableStatement
 473 %type <statement_> WithStatement
 474 %type <word_> Word
 475 @begin ObjectiveC
 476 %type <word_> WordOpt
 477 @end
 478 %type <expression_> Variable
 479
 480 @begin C
 481 %type <specifier_> IntegerType
 482 %type <specifier_> IntegerTypeOpt
 483 %type <typedIdentifier_> PrefixedType
 484 %type <specifier_> PrimitiveType
 485 %type <typedIdentifier_> SuffixedType
 486 %type <typedIdentifier_> TypeSignifier
 487 %type <modifier_> TypeQualifierLeft
 488 %type <typedIdentifier_> TypeQualifierRight
 489 %type <typedIdentifier_> TypedIdentifier
 490 %type <typedParameter_> TypedParameterList_
 491 %type <typedParameter_> TypedParameterList
 492 %type <typedParameter_> TypedParameterListOpt
 493 @end
 494
 495 @begin ObjectiveC
 496 %type <expression_> BoxableExpression
 497 %type <statement_> CategoryStatement
 498 %type <expression_> ClassExpression
 499 %type <classField_> ClassFieldListOpt
 500 %type <classField_> ClassFields
 501 %type <statement_> ClassStatement
 502 %type <expression_> ClassSuperOpt
 503 %type <message_> ClassMessageDeclaration
 504 %type <message_> ClassMessageDeclarationListOpt
 505 %type <className_> ClassName
 506 %type <className_> ClassNameOpt
 507 %type <protocol_> ClassProtocolListOpt
 508 %type <protocol_> ClassProtocols
 509 %type <protocol_> ClassProtocolsOpt
 510 %type <expression_> MessageExpression
 511 %type <messageParameter_> MessageParameter
 512 %type <messageParameter_> MessageParameters
 513 %type <messageParameter_> MessageParameterList
 514 %type <messageParameter_> MessageParameterListOpt
 515 %type <bool_> MessageScope
 516 %type <argument_> SelectorCall_
 517 %type <argument_> SelectorCall
 518 %type <selector_> SelectorExpression_
 519 %type <selector_> SelectorExpression
 520 %type <selector_> SelectorExpressionOpt
 521 %type <argument_> SelectorList
 522 %type <word_> SelectorWordOpt
 523 %type <typedIdentifier_> TypeOpt
 524 %type <argument_> VariadicCall
 525 @end
 526
 527 @begin E4X
 528 %type <propertyIdentifier_> PropertyIdentifier_
 529 %type <selector_> PropertySelector_
 530 %type <selector_> PropertySelector
 531 %type <identifier_> QualifiedIdentifier_
 532 %type <identifier_> QualifiedIdentifier
 533 %type <identifier_> WildcardIdentifier
 534 %type <identifier_> XMLComment
 535 %type <identifier_> XMLCDATA
 536 %type <identifier_> XMLElement
 537 %type <identifier_> XMLElementContent
 538 %type <identifier_> XMLMarkup
 539 %type <identifier_> XMLPI
 540
 541 %type <attribute_> AttributeIdentifier
 542 /* XXX: %type <statement_> DefaultXMLNamespaceStatement */
 543 %type <expression_> PropertyIdentifier
 544 %type <expression_> XMLListInitialiser
 545 %type <expression_> XMLInitialiser
 546 @end
 547 /* }}} */
 548 /* Token Priorities {{{ */
 549 %nonassoc ""
 550 %left "++" "--"
 551
 552 %nonassoc "if"
 553 %nonassoc "else"
 554 /* }}} */
 555
 556 %start Program
 557
 558 %%
 559
 560 /* Lexer State {{{ */
 561 LexPushInOn
 562     : { driver.in_.push(true); }
 563     ;
 564
 565 LexPushInOff
 566     : { driver.in_.push(false); }
 567     ;
 568
 569 LexPopIn
 570     : { driver.in_.pop(); }
 571     ;
 572
 573 LexSetRegExp
 574     : { driver.SetCondition(CYDriver::RegExpCondition); }
 575     ;
 576
 577 LexNoBrace
 578     : { if (yyla.empty()) driver.no_.OpenBrace = true; else if (yyla.type == yytranslate_(token::OpenBrace) || yyla.type == yytranslate_(token::OpenBrace_)) yyla.type = yytranslate_(token::OpenBrace__); }
 579     ;
 580
 581 LexNoFunction
 582     : { if (yyla.empty()) driver.no_.Function = true; else if (yyla.type == yytranslate_(token::Function)) yyla.type = yytranslate_(token::Function_); }
 583     ;
 584
 585 LexNoAtImplementation :
 586 @begin ObjectiveC
 587     { if (yyla.empty()) driver.no_.AtImplementation = true; else if (yyla.type == yytranslate_(token::AtImplementation)) yyla.type = yytranslate_(token::AtImplementation_); }
 588 @end
 589     ;
 590
 591 LexSetStatement
 592     : LexNoBrace LexNoFunction LexNoAtImplementation
 593     ;
 594 /* }}} */
 595 /* Virtual Tokens {{{ */
 596 BRACE
 597     : "{"
 598     | "\n{"
 599     ;
 600
 601 Var_
 602     : "var"
 603     ;
 604 /* }}} */
 605
 606 /* 7.6 Identifier Names and Identifiers {{{ */
 607 IdentifierName
 608     : Word { $$ = $1; }
 609     ;
 610
 611 NewLineOpt
 612     : "\n"
 613     |
 614     ;
 615
 616 Word
 617     : Identifier { $$ = $1; }
 618     | "auto" { $$ = $1; }
 619     | "break" NewLineOpt { $$ = $1; }
 620     | "case" { $$ = $1; }
 621     | "catch" { $$ = $1; }
 622     | "class" { $$ = $1; }
 623     | "const" { $$ = $1; }
 624     | "continue" NewLineOpt { $$ = $1; }
 625     | "debugger" { $$ = $1; }
 626     | "default" { $$ = $1; }
 627     | "delete" LexSetRegExp { $$ = $1; }
 628     | "do" { $$ = $1; }
 629     | "else" { $$ = $1; }
 630     | "enum" { $$ = $1; }
 631     | "export" { $$ = $1; }
 632     | "extends" { $$ = $1; }
 633     | "false" { $$ = $1; }
 634     | "finally" { $$ = $1; }
 635     /* XXX: | "for" { $$ = $1; } */
 636     | "function" { $$ = $1; }
 637     | "if" { $$ = $1; }
 638     | "import" { $$ = $1; }
 639     /* XXX: | "in" { $$ = $1; } */
 640     | "!in" { $$ = $1; }
 641     /* XXX: | "instanceof" { $$ = $1; } */
 642
 643     // XXX: as it currently is not an Identifier
 644     | "let" { $$ = $1; }
 645
 646     | "new" LexSetRegExp { $$ = $1; }
 647     | "null" { $$ = $1; }
 648     | "return" NewLineOpt { $$ = $1; }
 649     | "super" { $$ = $1; }
 650     | "switch" { $$ = $1; }
 651     | "this" { $$ = $1; }
 652     | "throw" NewLineOpt { $$ = $1; }
 653     | "true" { $$ = $1; }
 654     | "try" { $$ = $1; }
 655     | "typeof" LexSetRegExp { $$ = $1; }
 656     | "var" { $$ = $1; }
 657     | "void" LexSetRegExp { $$ = $1; }
 658     | "while" { $$ = $1; }
 659     | "with" { $$ = $1; }
 660     ;
 661
 662 @begin ObjectiveC
 663 WordOpt
 664     : Word { $$ = $1; }
 665     | { $$ = NULL; }
 666     ;
 667 @end
 668
 669 IdentifierType
 670     : Identifier_ { $$ = $1; }
 671
 672     | "implements" { $$ = $1; }
 673     | "interface" { $$ = $1; }
 674     | "package" { $$ = $1; }
 675     | "private" { $$ = $1; }
 676     | "protected" { $$ = $1; }
 677     | "public" { $$ = $1; }
 678     | "static" { $$ = $1; }
 679
 680     | "abstract" { $$ = $1; }
 681     | "boolean" { $$ = $1; }
 682     | "byte" { $$ = $1; }
 683     | "double" { $$ = $1; }
 684     | "final" { $$ = $1; }
 685     | "float" { $$ = $1; }
 686     | "goto" { $$ = $1; }
 687     | "native" { $$ = $1; }
 688     | "synchronized" { $$ = $1; }
 689     | "throws" { $$ = $1; }
 690     | "transient" { $$ = $1; }
 691
 692     // XXX: currently I only have this as Word
 693     // | "let" { $$ = $1; }
 694
 695     | "yield" { $$ = $1; }
 696
 697     | "each" { $$ = $1; }
 698     | "of" { $$ = $1; }
 699     ;
 700
 701 Identifier
 702     : IdentifierType
 703     | "char" { $$ = $1; }
 704     | "int" { $$ = $1; }
 705     | "long" { $$ = $1; }
 706     | "short" { $$ = $1; }
 707     | "volatile" { $$ = $1; }
 708 @begin C
 709     | "typedef" { $$ = $1; }
 710     | "unsigned" { $$ = $1; }
 711     | "signed" { $$ = $1; }
 712     | "extern" { $$ = $1; }
 713 @end
 714 @begin ObjectiveC
 715     | "YES" { $$ = $1; }
 716     | "NO" { $$ = $1; }
 717 @end
 718     ;
 719
 720 IdentifierOpt
 721     : Identifier { $$ = $1; }
 722     | { $$ = NULL; }
 723     ;
 724 /* }}} */
 725
 726 /* 7.8 Literals {{{ */
 727 Literal
 728     : NullLiteral { $$ = $1; }
 729     | ValueLiteral { $$ = $1; }
 730     ;
 731
 732 ValueLiteral
 733     : BooleanLiteral { $$ = $1; }
 734     | NumericLiteral { $$ = $1; }
 735     | StringLiteral { $$ = $1; }
 736     | RegularExpressionLiteral { $$ = $1; }
 737     ;
 738 /* }}} */
 739 /* 7.8.1 Null Literals {{{ */
 740 NullLiteral
 741     : "null" { $$ = $1; }
 742     ;
 743 /* }}} */
 744 /* 7.8.2 Boolean Literals {{{ */
 745 BooleanLiteral
 746     : "true" { $$ = $1; }
 747     | "false" { $$ = $1; }
 748     ;
 749 /* }}} */
 750
 751 /* 7.9 Automatic Semicolon Insertion {{{ */
 752 StrictSemi
 753     : { driver.Warning(@$, "warning, automatic semi-colon insertion required"); }
 754     ;
 755
 756 Terminator
 757     : ";"
 758     | error { if (yyla.type_get() != yyeof_ && yyla.type != token::CloseBrace && !yyla.value.newline_) YYABORT; else { yyerrok; driver.errors_.pop_back(); } } StrictSemi
 759     ;
 760
 761 TerminatorOpt
 762     : ";"
 763     | error { yyerrok; driver.errors_.pop_back(); } StrictSemi
 764     ;
 765 /* }}} */
 766
 767 /* 11.1 Primary Expressions {{{ */
 768 Parenthetical
 769     : "(" LexPushInOff Expression ")" LexPopIn { $$ = $3; }
 770     ;
 771
 772 Variable
 773     : Identifier { $$ = CYNew CYVariable($1); }
 774     ;
 775
 776 PrimaryExpression
 777     : "this" { $$ = $1; }
 778     | Variable { $$ = $1; }
 779     | Literal { $$ = $1; }
 780     | ArrayInitialiser { $$ = $1; }
 781     | ObjectLiteral { $$ = $1; }
 782     | Parenthetical { $$ = $1; }
 783     | AutoComplete { driver.mode_ = CYDriver::AutoPrimary; YYACCEPT; }
 784     ;
 785 /* }}} */
 786 /* 11.1.4 Array Initializer {{{ */
 787 ArrayInitialiser
 788     : ArrayLiteral { $$ = $1; }
 789     | ArrayComprehension { $$ = $1; }
 790     ;
 791 /* }}} */
 792 /* 11.1.4.1 Array Literal {{{ */
 793 ArrayLiteral
 794     : "[" LexPushInOff ElementListOpt "]" LexPopIn { $$ = CYNew CYArray($3); }
 795     ;
 796
 797 Element
 798     : AssignmentExpression { $$ = $1; }
 799     ;
 800
 801 ElementOpt
 802     : Element { $$ = $1; }
 803     | LexSetRegExp { $$ = NULL; }
 804     ;
 805
 806 ElementList
 807     : ElementOpt "," ElementListOpt { $$ = CYNew CYElement($1, $3); }
 808     | Element { $$ = CYNew CYElement($1, NULL); }
 809     ;
 810
 811 ElementListOpt
 812     : ElementList { $$ = $1; }
 813     | LexSetRegExp { $$ = NULL; }
 814     ;
 815 /* }}} */
 816 /* 11.1.4.2 Array Comprehension {{{ */
 817 ArrayComprehension
 818     : "[" LexPushInOff Comprehension "]" LexPopIn { $$ = $3; }
 819     ;
 820
 821 Comprehension
 822     : LexSetRegExp ComprehensionFor ComprehensionTail AssignmentExpression { $$ = CYNew CYArrayComprehension($4, $2->Modify($3)); }
 823     ;
 824
 825 ComprehensionTail
 826     : { $$ = NULL; }
 827     | ComprehensionFor ComprehensionTail { $$ = $1->Modify($2); }
 828     | ComprehensionIf ComprehensionTail { $$ = $1->Modify($2); }
 829     ;
 830
 831 ComprehensionFor
 832     : "for" "(" Binding "of" Expression ")" { $$ = CYNew CYForOfComprehension($3, $5); }
 833     ;
 834
 835 ComprehensionIf
 836     : "if" "(" AssignmentExpression ")" { $$ = CYNew CYIfComprehension($3); }
 837     ;
 838 /* }}} */
 839 /* 11.1.5 Object Initialiser {{{ */
 840 ObjectLiteral
 841     : BRACE LexPushInOff PropertyDefinitionListOpt "}" LexPopIn { $$ = CYNew CYObject($3); }
 842     ;
 843
 844 PropertyDefinitionList_
 845     : "," PropertyDefinitionList { $$ = $2; }
 846     | "," LexSetRegExp { $$ = NULL; }
 847     | { $$ = NULL; }
 848     ;
 849
 850 PropertyDefinitionList
 851     : PropertyDefinition PropertyDefinitionList_ { $1->SetNext($2); $$ = $1; }
 852     ;
 853
 854 PropertyDefinitionListOpt
 855     : PropertyDefinitionList { $$ = $1; }
 856     | LexSetRegExp { $$ = NULL; }
 857     ;
 858
 859 PropertyDefinition
 860     // XXX: this should be IdentifierName
 861     : LexSetRegExp Identifier { $$ = CYNew CYProperty($2, CYNew CYVariable($2)); }
 862     | PropertyName ":" AssignmentExpression { $$ = CYNew CYProperty($1, $3); }
 863     //| MethodDefinition
 864     ;
 865
 866 PropertyName_
 867     : IdentifierName { $$ = $1; }
 868     | StringLiteral { $$ = $1; }
 869     | NumericLiteral { $$ = $1; }
 870     ;
 871
 872 PropertyName
 873     : LexSetRegExp PropertyName_ { $$ = $2; }
 874     ;
 875 /* }}} */
 876
 877 /* 11.2 Left-Hand-Side Expressions {{{ */
 878 MemberAccess
 879     : "[" LexPushInOff Expression "]" LexPopIn { $$ = CYNew CYDirectMember(NULL, $3); }
 880     | "." IdentifierName { $$ = CYNew CYDirectMember(NULL, CYNew CYString($2)); }
 881     | "." AutoComplete { driver.mode_ = CYDriver::AutoDirect; YYACCEPT; }
 882     ;
 883
 884 MemberExpression_
 885     : MemberExpression { $$ = $1; }
 886     //| "super" { $$ = $1; }
 887     ;
 888
 889 MemberExpression
 890     : LexSetRegExp PrimaryExpression { $$ = $2; }
 891     | LexSetRegExp FunctionExpression { $$ = $2; }
 892     | MemberExpression_ { driver.context_ = $1; } MemberAccess { $3->SetLeft($1); $$ = $3; }
 893     | LexSetRegExp "new" MemberExpression Arguments { $$ = CYNew cy::Syntax::New($3, $4); }
 894     ;
 895
 896 NewExpression
 897     : MemberExpression { $$ = $1; }
 898     | LexSetRegExp "new" NewExpression { $$ = CYNew cy::Syntax::New($3, NULL); }
 899     ;
 900
 901 CallExpression_
 902     : MemberExpression_
 903     | CallExpression
 904     ;
 905
 906 CallExpression
 907     : CallExpression_ Arguments { $$ = CYNew CYCall($1, $2); }
 908     | CallExpression { driver.context_ = $1; } MemberAccess { $3->SetLeft($1); $$ = $3; }
 909     ;
 910
 911 Arguments
 912     : "(" LexPushInOff ArgumentListOpt ")" LexPopIn { $$ = $3; }
 913     ;
 914
 915 ArgumentList_
 916     : "," ArgumentList { $$ = $2; }
 917     | { $$ = NULL; }
 918     ;
 919
 920 ArgumentList
 921     : AssignmentExpression ArgumentList_ { $$ = CYNew CYArgument(NULL, $1, $2); }
 922     | LexSetRegExp Word ":" AssignmentExpression ArgumentList_ { $$ = CYNew CYArgument($2, $4, $5); }
 923     ;
 924
 925 ArgumentListOpt
 926     : ArgumentList { $$ = $1; }
 927     | LexSetRegExp { $$ = NULL; }
 928     ;
 929
 930 LeftHandSideExpression
 931     : NewExpression { $$ = $1; }
 932     | CallExpression { $$ = $1; }
 933     ;
 934 /* }}} */
 935 /* 11.3 Postfix Expressions {{{ */
 936 PostfixExpression
 937     : %prec "" LeftHandSideExpression { $$ = $1; }
 938     | LeftHandSideExpression "++" { $$ = CYNew CYPostIncrement($1); }
 939     | LeftHandSideExpression "--" { $$ = CYNew CYPostDecrement($1); }
 940     ;
 941 /* }}} */
 942 /* 11.4 Unary Operators {{{ */
 943 UnaryExpression_
 944     : "delete" UnaryExpression { $$ = CYNew CYDelete($2); }
 945     | "void" UnaryExpression { $$ = CYNew CYVoid($2); }
 946     | "typeof" UnaryExpression { $$ = CYNew CYTypeOf($2); }
 947     | "++" UnaryExpression { $$ = CYNew CYPreIncrement($2); }
 948     | "\n++" UnaryExpression { $$ = CYNew CYPreIncrement($2); }
 949     | "--" UnaryExpression { $$ = CYNew CYPreDecrement($2); }
 950     | "\n--" UnaryExpression { $$ = CYNew CYPreDecrement($2); }
 951     | "+" UnaryExpression { $$ = CYNew CYAffirm($2); }
 952     | "-" UnaryExpression { $$ = CYNew CYNegate($2); }
 953     | "~" UnaryExpression { $$ = CYNew CYBitwiseNot($2); }
 954     | "!" UnaryExpression { $$ = CYNew CYLogicalNot($2); }
 955     ;
 956
 957 UnaryExpression
 958     : PostfixExpression { $$ = $1; }
 959     | LexSetRegExp UnaryExpression_ { $$ = $2; }
 960     ;
 961 /* }}} */
 962 /* 11.5 Multiplicative Operators {{{ */
 963 MultiplicativeExpression
 964     : UnaryExpression { $$ = $1; }
 965     | MultiplicativeExpression "*" UnaryExpression { $$ = CYNew CYMultiply($1, $3); }
 966     | MultiplicativeExpression "/" UnaryExpression { $$ = CYNew CYDivide($1, $3); }
 967     | MultiplicativeExpression "%" UnaryExpression { $$ = CYNew CYModulus($1, $3); }
 968     ;
 969 /* }}} */
 970 /* 11.6 Additive Operators {{{ */
 971 AdditiveExpression
 972     : MultiplicativeExpression { $$ = $1; }
 973     | AdditiveExpression "+" MultiplicativeExpression { $$ = CYNew CYAdd($1, $3); }
 974     | AdditiveExpression "-" MultiplicativeExpression { $$ = CYNew CYSubtract($1, $3); }
 975     ;
 976 /* }}} */
 977 /* 11.7 Bitwise Shift Operators {{{ */
 978 ShiftExpression
 979     : AdditiveExpression { $$ = $1; }
 980     | ShiftExpression "<<" AdditiveExpression { $$ = CYNew CYShiftLeft($1, $3); }
 981     | ShiftExpression ">>" AdditiveExpression { $$ = CYNew CYShiftRightSigned($1, $3); }
 982     | ShiftExpression ">>>" AdditiveExpression { $$ = CYNew CYShiftRightUnsigned($1, $3); }
 983     ;
 984 /* }}} */
 985 /* 11.8 Relational Operators {{{ */
 986 RelationalExpression
 987     : ShiftExpression { $$ = $1; }
 988     | RelationalExpression "<" ShiftExpression { $$ = CYNew CYLess($1, $3); }
 989     | RelationalExpression ">" ShiftExpression { $$ = CYNew CYGreater($1, $3); }
 990     | RelationalExpression "<=" ShiftExpression { $$ = CYNew CYLessOrEqual($1, $3); }
 991     | RelationalExpression ">=" ShiftExpression { $$ = CYNew CYGreaterOrEqual($1, $3); }
 992     | RelationalExpression "instanceof" ShiftExpression { $$ = CYNew CYInstanceOf($1, $3); }
 993     | RelationalExpression "in" ShiftExpression { $$ = CYNew CYIn($1, $3); }
 994     ;
 995 /* }}} */
 996 /* 11.9 Equality Operators {{{ */
 997 EqualityExpression
 998     : RelationalExpression { $$ = $1; }
 999     | EqualityExpression "==" RelationalExpression { $$ = CYNew CYEqual($1, $3); }
1000     | EqualityExpression "!=" RelationalExpression { $$ = CYNew CYNotEqual($1, $3); }
1001     | EqualityExpression "===" RelationalExpression { $$ = CYNew CYIdentical($1, $3); }
1002     | EqualityExpression "!==" RelationalExpression { $$ = CYNew CYNotIdentical($1, $3); }
1003     ;
1004 /* }}} */
1005 /* 11.10 Binary Bitwise Operators {{{ */
1006 BitwiseANDExpression
1007     : EqualityExpression { $$ = $1; }
1008     | BitwiseANDExpression "&" EqualityExpression { $$ = CYNew CYBitwiseAnd($1, $3); }
1009     ;
1010
1011 BitwiseXORExpression
1012     : BitwiseANDExpression { $$ = $1; }
1013     | BitwiseXORExpression "^" BitwiseANDExpression { $$ = CYNew CYBitwiseXOr($1, $3); }
1014     ;
1015
1016 BitwiseORExpression
1017     : BitwiseXORExpression { $$ = $1; }
1018     | BitwiseORExpression "|" BitwiseXORExpression { $$ = CYNew CYBitwiseOr($1, $3); }
1019     ;
1020 /* }}} */
1021 /* 11.11 Binary Logical Operators {{{ */
1022 LogicalANDExpression
1023     : BitwiseORExpression { $$ = $1; }
1024     | LogicalANDExpression "&&" BitwiseORExpression { $$ = CYNew CYLogicalAnd($1, $3); }
1025     ;
1026
1027 LogicalORExpression
1028     : LogicalANDExpression { $$ = $1; }
1029     | LogicalORExpression "||" LogicalANDExpression { $$ = CYNew CYLogicalOr($1, $3); }
1030     ;
1031 /* }}} */
1032 /* 11.12 Conditional Operator ( ? : ) {{{ */
1033 ConditionalExpression
1034     : LogicalORExpression { $$ = $1; }
1035     | LogicalORExpression "?" LexPushInOff AssignmentExpression ":" LexPopIn AssignmentExpression { $$ = CYNew CYCondition($1, $4, $7); }
1036     | LogicalORExpression "?" LexPushInOff LexSetRegExp ":" LexPopIn AssignmentExpression { $$ = CYNew CYCondition($1, $1, $7); }
1037     ;
1038 /* }}} */
1039 /* 11.13 Assignment Operators {{{ */
1040 AssignmentExpression
1041     : ConditionalExpression { $$ = $1; }
1042     | ArrowFunction { $$ = $1; }
1043     | LeftHandSideExpression "=" AssignmentExpression { $$ = CYNew CYAssign($1, $3); }
1044     | LeftHandSideExpression "*=" AssignmentExpression { $$ = CYNew CYMultiplyAssign($1, $3); }
1045     | LeftHandSideExpression "/=" AssignmentExpression { $$ = CYNew CYDivideAssign($1, $3); }
1046     | LeftHandSideExpression "%=" AssignmentExpression { $$ = CYNew CYModulusAssign($1, $3); }
1047     | LeftHandSideExpression "+=" AssignmentExpression { $$ = CYNew CYAddAssign($1, $3); }
1048     | LeftHandSideExpression "-=" AssignmentExpression { $$ = CYNew CYSubtractAssign($1, $3); }
1049     | LeftHandSideExpression "<<=" AssignmentExpression { $$ = CYNew CYShiftLeftAssign($1, $3); }
1050     | LeftHandSideExpression ">>=" AssignmentExpression { $$ = CYNew CYShiftRightSignedAssign($1, $3); }
1051     | LeftHandSideExpression ">>>=" AssignmentExpression { $$ = CYNew CYShiftRightUnsignedAssign($1, $3); }
1052     | LeftHandSideExpression "&=" AssignmentExpression { $$ = CYNew CYBitwiseAndAssign($1, $3); }
1053     | LeftHandSideExpression "^=" AssignmentExpression { $$ = CYNew CYBitwiseXOrAssign($1, $3); }
1054     | LeftHandSideExpression "|=" AssignmentExpression { $$ = CYNew CYBitwiseOrAssign($1, $3); }
1055     ;
1056 /* }}} */
1057 /* 11.14 Comma Operator {{{ */
1058 Expression_
1059     : "," Expression { $$ = $2; }
1060     | { $$ = NULL; }
1061     ;
1062
1063 Expression
1064     : AssignmentExpression Expression_ { $$ = CYNew CYCompound($1, $2); }
1065     ;
1066
1067 ExpressionOpt
1068     : Expression { $$ = $1; }
1069     | LexSetRegExp { $$ = NULL; }
1070     ;
1071 /* }}} */
1072
1073 /* 12 Statements {{{ */
1074 Statement__
1075     : Block { $$ = $1; }
1076     | VariableStatement { $$ = $1; }
1077     | EmptyStatement { $$ = $1; }
1078     | IfStatement { $$ = $1; }
1079     | BreakableStatement { $$ = $1; }
1080     | ContinueStatement { $$ = $1; }
1081     | BreakStatement { $$ = $1; }
1082     | ReturnStatement { $$ = $1; }
1083     | WithStatement { $$ = $1; }
1084     | LabelledStatement { $$ = $1; }
1085     | ThrowStatement { $$ = $1; }
1086     | TryStatement { $$ = $1; }
1087     | DebuggerStatement { $$ = $1; }
1088     ;
1089
1090 Statement_
1091     : LexSetRegExp Statement__ { $$ = $2; }
1092     | ExpressionStatement { $$ = $1; }
1093     ;
1094
1095 Statement
1096     : LexSetStatement Statement_ { $$ = $2; }
1097     ;
1098
1099 Declaration__
1100     : FunctionDeclaration { $$ = $1; }
1101     | LexicalDeclaration { $$ = $1; }
1102     ;
1103
1104 Declaration_
1105     : LexSetRegExp Declaration__ { $$ = $2; }
1106     ;
1107
1108 Declaration
1109     : LexSetStatement Declaration_ { $$ = $2; }
1110     ;
1111
1112 BreakableStatement
1113     : IterationStatement { $$ = $1; }
1114     | SwitchStatement { $$ = $1; }
1115     ;
1116 /* }}} */
1117 /* 12.1 Block {{{ */
1118 Block_
1119     : BRACE StatementListOpt "}" { $$ = $2; }
1120     ;
1121
1122 Block
1123     : ";{" StatementListOpt "}" { $$ = CYNew CYBlock($2); }
1124     ;
1125
1126 StatementList
1127     : StatementListItem StatementListOpt { $1->SetNext($2); $$ = $1; }
1128     ;
1129
1130 StatementListOpt
1131     : StatementList { $$ = $1; }
1132     | LexSetStatement LexSetRegExp { $$ = NULL; }
1133     ;
1134
1135 StatementListItem
1136     : Statement { $$ = $1; }
1137     | Declaration { $$ = $1; }
1138     ;
1139 /* }}} */
1140
1141 /* 12.2 Declarations {{{ */
1142 BindingIdentifier
1143     : Identifier { $$ = $1; }
1144     ;
1145
1146 Binding
1147     : BindingIdentifier
1148     ;
1149
1150 // XXX: BindingPattern
1151 /* }}} */
1152 /* 12.2.1 Let and Const Declarations {{{ */
1153 LexicalDeclaration
1154     : LetOrConst VariableDeclarationList Terminator { $$ = CYNew CYVar($2); }
1155     ;
1156
1157 LetOrConst
1158     : "let"
1159     | "const"
1160     ;
1161 /* }}} */
1162 /* 12.2.2 Variable Statement {{{ */
1163 VariableStatement
1164     : Var_ VariableDeclarationList Terminator { $$ = CYNew CYVar($2); }
1165     ;
1166
1167 VariableDeclarationList_
1168     : "," VariableDeclarationList { $$ = $2; }
1169     | { $$ = NULL; }
1170     ;
1171
1172 VariableDeclarationList
1173     : VariableDeclaration VariableDeclarationList_ { $$ = CYNew CYDeclarations($1, $2); }
1174     ;
1175
1176 VariableDeclaration
1177     : BindingIdentifier InitialiserOpt { $$ = CYNew CYDeclaration($1, $2); }
1178     // XXX: | BindingPattern Initialiser { $$ = CYNew CYDeclaration($1, $2); }
1179     ;
1180
1181 Initialiser
1182     : "=" AssignmentExpression { $$ = $2; }
1183     ;
1184
1185 InitialiserOpt
1186     : Initialiser { $$ = $1; }
1187     | { $$ = NULL; }
1188     ;
1189 /* }}} */
1190 /* 12.2.4 Destructuring Binding Patterns {{{ */
1191 // XXX: *
1192
1193 BindingElement
1194     : SingleNameBinding { $$ = $1; }
1195     ;
1196
1197 SingleNameBinding
1198     : BindingIdentifier InitialiserOpt { $$ = CYNew CYDeclaration($1, $2); }
1199     ;
1200 /* }}} */
1201
1202 /* 12.3 Empty Statement {{{ */
1203 EmptyStatement
1204     : ";" { $$ = CYNew CYEmpty(); }
1205     ;
1206 /* }}} */
1207 /* 12.4 Expression Statement {{{ */
1208 ExpressionStatement
1209     : Expression Terminator { $$ = CYNew CYExpress($1); }
1210     ;
1211 /* }}} */
1212 /* 12.5 The if Statement {{{ */
1213 ElseStatementOpt
1214     : "else" Statement { $$ = $2; }
1215     | %prec "if" { $$ = NULL; }
1216     ;
1217
1218 IfStatement
1219     : "if" "(" Expression ")" Statement ElseStatementOpt { $$ = CYNew CYIf($3, $5, $6); }
1220     ;
1221 /* }}} */
1222
1223 /* 12.6.1 The do-while Statement {{{ */
1224 IterationStatement
1225     : "do" Statement "while" "(" Expression ")" TerminatorOpt { $$ = CYNew CYDoWhile($5, $2); }
1226     ;
1227 /* }}} */
1228 /* 12.6.2 The while Statement {{{ */
1229 IterationStatement
1230     : "while" "(" Expression ")" Statement { $$ = CYNew CYWhile($3, $5); }
1231     ;
1232 /* }}} */
1233 /* 12.6.3 The for Statement {{{ */
1234 IterationStatement
1235     : "for" "(" LexPushInOn ForStatementInitialiser ";" LexPopIn ExpressionOpt ";" ExpressionOpt ")" Statement { $$ = CYNew CYFor($4, $7, $9, $11); }
1236     ;
1237
1238 ForStatementInitialiser
1239     : ExpressionOpt { $$ = $1; }
1240     | LexSetRegExp Var_ VariableDeclarationList { $$ = CYNew CYForDeclarations($3); }
1241     ;
1242 /* }}} */
1243 /* 12.6.4 The for-in and for-of Statements {{{ */
1244 IterationStatement
1245     : "for" "(" LexPushInOn ForInStatementInitialiser "!in" LexPopIn Expression ")" Statement { $$ = CYNew CYForIn($4, $7, $9); }
1246     | "for" "(" LexPushInOn ForInStatementInitialiser "of" LexPopIn Expression ")" Statement { $$ = CYNew CYForOf($4, $7, $9); }
1247     ;
1248
1249 ForInStatementInitialiser
1250     : LeftHandSideExpression { $$ = $1; }
1251     | LexSetRegExp Var_ VariableDeclaration { $$ = $3; }
1252     ;
1253 /* }}} */
1254
1255 /* 12.7 The continue Statement {{{ */
1256 ContinueStatement
1257     : "continue" "\n" StrictSemi { $$ = CYNew CYContinue(NULL); }
1258     | "continue" IdentifierOpt Terminator { $$ = CYNew CYContinue($2); }
1259     ;
1260 /* }}} */
1261 /* 12.8 The break Statement {{{ */
1262 BreakStatement
1263     : "break" "\n" StrictSemi { $$ = CYNew CYBreak(NULL); }
1264     | "break" IdentifierOpt Terminator { $$ = CYNew CYBreak($2); }
1265     ;
1266 /* }}} */
1267 /* 12.9 The return Statement {{{ */
1268 ReturnStatement
1269     : "return" LexSetRegExp "\n" StrictSemi { $$ = CYNew CYReturn(NULL); }
1270     | "return" ExpressionOpt Terminator { $$ = CYNew CYReturn($2); }
1271     ;
1272 /* }}} */
1273 /* 12.10 The with Statement {{{ */
1274 WithStatement
1275     : "with" "(" Expression ")" Statement { $$ = CYNew CYWith($3, $5); }
1276     ;
1277 /* }}} */
1278
1279 /* 12.11 The switch Statement {{{ */
1280 SwitchStatement
1281     : "switch" "(" Expression ")" CaseBlock { $$ = CYNew CYSwitch($3, $5); }
1282     ;
1283
1284 CaseBlock
1285     : BRACE CaseClausesOpt "}" { $$ = $2; }
1286     ;
1287
1288 CaseClause
1289     : "case" Expression ":" StatementListOpt { $$ = CYNew CYClause($2, $4); }
1290     ;
1291
1292 CaseClausesOpt
1293     : CaseClause CaseClausesOpt { $1->SetNext($2); $$ = $1; }
1294     | DefaultClause CaseClausesOpt { $1->SetNext($2); $$ = $1; }
1295     | { $$ = NULL; }
1296     ;
1297
1298 DefaultClause
1299     : "default" ":" StatementListOpt { $$ = CYNew CYClause(NULL, $3); }
1300     ;
1301 /* }}} */
1302 /* 12.12 Labelled Statements {{{ */
1303 LabelledStatement
1304     : Identifier ":" Statement { $$ = CYNew CYLabel($1, $3); }
1305     ;
1306 /* }}} */
1307 /* 12.13 The throw Statement {{{ */
1308 ThrowStatement
1309     : "throw" LexSetRegExp "\n" StrictSemi { YYABORT; }
1310     | "throw" Expression Terminator { $$ = CYNew cy::Syntax::Throw($2); }
1311     ;
1312 /* }}} */
1313 /* 12.14 The try Statement {{{ */
1314 TryStatement
1315     : "try" Block_ CatchOpt FinallyOpt { $$ = CYNew cy::Syntax::Try($2, $3, $4); }
1316     ;
1317
1318 CatchOpt
1319     : "catch" "(" Identifier ")" Block_ { $$ = CYNew cy::Syntax::Catch($3, $5); }
1320     | { $$ = NULL; }
1321     ;
1322
1323 FinallyOpt
1324     : "finally" Block_ { $$ = CYNew CYFinally($2); }
1325     | { $$ = NULL; }
1326     ;
1327 /* }}} */
1328 /* 12.14 The debugger Statement {{{ */
1329 DebuggerStatement
1330     : "debugger" Terminator { $$ = CYNew CYDebugger(); }
1331     ;
1332 /* }}} */
1333
1334 /* 13.1 Function Definitions {{{ */
1335 FunctionDeclaration
1336     : ";function" Identifier "(" FormalParameterListOpt ")" BRACE FunctionBody "}" { $$ = CYNew CYFunctionStatement($2, $4, $7); }
1337     ;
1338
1339 FunctionExpression
1340     : "function" IdentifierOpt "(" LexPushInOff FormalParameterListOpt ")" LexPopIn BRACE LexPushInOff FunctionBody "}" LexPopIn { $$ = CYNew CYFunctionExpression($2, $5, $10); }
1341     ;
1342
1343 FormalParameterList_
1344     : "," FormalParameterList { $$ = $2; }
1345     | { $$ = NULL; }
1346     ;
1347
1348 FormalParameterList
1349     // XXX: : FunctionRestParameter { $$ = $1; }
1350     : FormalParameter FormalParameterList_ { $$ = CYNew CYFunctionParameter($1, $2); }
1351     ;
1352
1353 FormalParameterListOpt
1354     : FormalParameterList
1355     | { $$ = NULL; }
1356     ;
1357
1358 /* XXX: FunctionRestParameter
1359     : "..." BindingIdentifier { $$ = CYNew CYFunctionRestParameter($2); }
1360     ;*/
1361
1362 FormalParameter
1363     : BindingElement { $$ = $1; }
1364     ;
1365
1366 FunctionBody
1367     : StatementListOpt { $$ = $1; }
1368     ;
1369 /* }}} */
1370 /* 13.2 Arrow Function Definitions {{{ */
1371 ArrowFunction
1372     : LexSetRegExp ArrowParameters "=>" LexNoBrace ConciseBody { $$ = CYNew CYFatArrow($2, $5); }
1373     ;
1374
1375 ArrowParameters
1376     : BindingIdentifier { $$ = CYNew CYFunctionParameter(CYNew CYDeclaration($1)); }
1377     | "(" LexPushInOff LexSetRegExp ")" LexPopIn { $$ = NULL; }
1378     | Parenthetical { $$ = $1->Parameters(); if ($$ == NULL) error(@1, "invalid parameter list"); }
1379     ;
1380
1381 ConciseBody
1382     : AssignmentExpression { $$ = CYNew CYReturn($1); }
1383     | LexSetRegExp ";{" LexPushInOff FunctionBody "}" LexPopIn { $$ = $4; }
1384     ;
1385 /* }}} */
1386 /* 14 Program {{{ */
1387 Program
1388     : ProgramBodyOpt { driver.program_ = CYNew CYProgram($1); }
1389     ;
1390
1391 ProgramBody
1392     : StatementList { $$ = $1; }
1393     ;
1394
1395 ProgramBodyOpt
1396     : ProgramBody { $$ = $1; }
1397     | LexSetStatement LexSetRegExp { $$ = NULL; }
1398     ;
1399 /* }}} */
1400
1401 @begin C
1402 /* Cycript (C): Type Encoding {{{ */
1403 TypeSignifier
1404     : IdentifierType { $$ = CYNew CYTypedIdentifier(@1, $1); }
1405     | "(" LexPushInOff "*" TypeQualifierRight ")" LexPopIn { $$ = $4; }
1406     ;
1407
1408 SuffixedType
1409     : SuffixedType "[" NumericLiteral "]" { $$ = $1; $$->modifier_ = CYNew CYTypeArrayOf($3, $$->modifier_); }
1410     | "(" LexPushInOff "^" TypeQualifierRight ")" LexPopIn "(" LexPushInOff TypedParameterListOpt ")" LexPopIn { $$ = $4; $$->modifier_ = CYNew CYTypeBlockWith($9, $$->modifier_); }
1411     | TypeSignifier "(" LexPushInOff TypedParameterListOpt ")" LexPopIn { $$ = $1; $$->modifier_ = CYNew CYTypeFunctionWith($4, $$->modifier_); }
1412     | "(" LexPushInOff TypedParameterListOpt ")" LexPopIn { $$ = CYNew CYTypedIdentifier(@1); $$->modifier_ = CYNew CYTypeFunctionWith($3, $$->modifier_); }
1413     | TypeSignifier { $$ = $1; }
1414     | { $$ = CYNew CYTypedIdentifier(@$); }
1415     ;
1416
1417 PrefixedType
1418     : "*" TypeQualifierRight { $$ = $2; $$->modifier_ = CYNew CYTypePointerTo($$->modifier_); }
1419     ;
1420
1421 TypeQualifierLeft
1422     : { $$ = NULL; }
1423     | "const" TypeQualifierLeft { $$ = $2; CYSetLast($$) = CYNew CYTypeConstant(); }
1424     | "volatile" TypeQualifierLeft { $$ = $2; CYSetLast($$) = CYNew CYTypeVolatile(); }
1425     ;
1426
1427 TypeQualifierRight
1428     : PrefixedType { $$ = $1; }
1429     | SuffixedType { $$ = $1; }
1430     | "const" TypeQualifierRight { $$ = $2; $$->modifier_ = CYNew CYTypeConstant($$->modifier_); }
1431     | "volatile" TypeQualifierRight { $$ = $2; $$->modifier_ = CYNew CYTypeVolatile($$->modifier_); }
1432     ;
1433
1434 IntegerType
1435     : "int" { $$ = CYNew CYTypeVariable("int"); }
1436     | "unsigned" IntegerTypeOpt { $$ = CYNew CYTypeUnsigned($2); }
1437     | "signed" IntegerTypeOpt { $$ = CYNew CYTypeSigned($2); }
1438     | "long" IntegerTypeOpt { $$ = CYNew CYTypeLong($2); }
1439     | "short" IntegerTypeOpt { $$ = CYNew CYTypeShort($2); }
1440     ;
1441
1442 IntegerTypeOpt
1443     : IntegerType { $$ = $1; }
1444     | { $$ = CYNew CYTypeVariable("int"); }
1445     ;
1446
1447 PrimitiveType
1448     : IdentifierType { $$ = CYNew CYTypeVariable($1); }
1449     | IntegerType { $$ = $1; }
1450     | "void" { $$ = CYNew CYTypeVoid(); }
1451     | "char" { $$ = CYNew CYTypeVariable("char"); }
1452     | "signed" "char" { $$ = CYNew CYTypeSigned(CYNew CYTypeVariable("char")); }
1453     | "unsigned" "char" { $$ = CYNew CYTypeUnsigned(CYNew CYTypeVariable("char")); }
1454     ;
1455
1456 TypedIdentifier
1457     : TypeQualifierLeft PrimitiveType TypeQualifierRight { $$ = $3; $$->specifier_ = $2; CYSetLast($1) = $$->modifier_; $$->modifier_ = $1; }
1458     ;
1459
1460 PrimaryExpression
1461     : "@encode" "(" TypedIdentifier ")" { $$ = CYNew CYEncodedType($3); }
1462     ;
1463 /* }}} */
1464 @end
1465
1466 @begin ObjectiveC
1467 /* Cycript (Objective-C): @class Declaration {{{ */
1468 ClassSuperOpt
1469     /* XXX: why the hell did I choose MemberExpression? */
1470     : ":" LexSetRegExp MemberExpression { $$ = $3; }
1471     | { $$ = NULL; }
1472     ;
1473
1474 ClassFieldListOpt
1475     : TypedIdentifier ";" ClassFieldListOpt { $$ = CYNew CYClassField($1, $3); }
1476     | LexSetRegExp { $$ = NULL; }
1477     ;
1478
1479 ClassFields
1480     : BRACE ClassFieldListOpt "}" { $$ = $2; }
1481     ;
1482
1483 MessageScope
1484     : "+" { $$ = false; }
1485     | "-" { $$ = true; }
1486     ;
1487
1488 TypeOpt
1489     : "(" LexSetRegExp TypedIdentifier ")" { if ($3->identifier_ != NULL) error($3->location_, "unexpected identifier"); $$ = $3; }
1490     | { $$ = CYNew CYTypedIdentifier(CYNew CYTypeVariable("id")); }
1491     ;
1492
1493 MessageParameter
1494     : Word ":" TypeOpt Identifier { $3->identifier_ = $4; $$ = CYNew CYMessageParameter($1, $3); }
1495     ;
1496
1497 MessageParameterList
1498     : MessageParameter MessageParameterListOpt { $1->SetNext($2); $$ = $1; }
1499     ;
1500
1501 MessageParameterListOpt
1502     : MessageParameterList { $$ = $1; }
1503     | { $$ = NULL; }
1504     ;
1505
1506 MessageParameters
1507     : MessageParameterList { $$ = $1; }
1508     | Word { $$ = CYNew CYMessageParameter($1, NULL); }
1509     ;
1510
1511 ClassMessageDeclaration
1512     : MessageScope TypeOpt MessageParameters BRACE FunctionBody "}" { $$ = CYNew CYMessage($1, $2, $3, $5); }
1513     ;
1514
1515 ClassMessageDeclarationListOpt
1516     : ClassMessageDeclarationListOpt ClassMessageDeclaration { $2->SetNext($1); $$ = $2; }
1517     | ClassMessageDeclarationListOpt Comment { $$ = $1; }
1518     | { $$ = NULL; }
1519     ;
1520
1521 ClassName
1522     : Identifier { $$ = $1; }
1523     | "(" AssignmentExpression ")" { $$ = $2; }
1524     ;
1525
1526 ClassNameOpt
1527     : ClassName { $$ = $1; }
1528     | { $$ = NULL; }
1529     ;
1530
1531 // XXX: this should be AssignmentExpressionNoRight
1532 ClassProtocols
1533     : ShiftExpression ClassProtocolsOpt { $$ = CYNew CYProtocol($1, $2); }
1534     ;
1535
1536 ClassProtocolsOpt
1537     : "," ClassProtocols { $$ = $2; }
1538     | { $$ = NULL; }
1539     ;
1540
1541 ClassProtocolListOpt
1542     : "<" ClassProtocols ">" { $$ = $2; }
1543     | { $$ = NULL; }
1544     ;
1545
1546 ClassExpression
1547     : "@implementation" LexPushInOff ClassNameOpt ClassSuperOpt ClassProtocolListOpt ClassFields ClassMessageDeclarationListOpt "@end" LexPopIn { $$ = CYNew CYClassExpression($3, $4, $5, $6, $7); }
1548     ;
1549
1550 ClassStatement
1551     : ";@implementation" ClassName ClassSuperOpt ClassProtocolListOpt ClassFields ClassMessageDeclarationListOpt "@end" { $$ = CYNew CYClassStatement($2, $3, $4, $5, $6); }
1552     ;
1553
1554 CategoryName
1555     : "(" WordOpt ")"
1556     ;
1557
1558 CategoryStatement
1559     : ";@implementation" ClassName CategoryName ClassMessageDeclarationListOpt "@end" { $$ = CYNew CYCategory($2, $4); }
1560     ;
1561
1562 PrimaryExpression
1563     : ClassExpression { $$ = $1; }
1564     ;
1565
1566 Statement__
1567     : ClassStatement { $$ = $1; }
1568     | CategoryStatement { $$ = $1; }
1569     ;
1570 /* }}} */
1571 /* Cycript (Objective-C): Send Message {{{ */
1572 VariadicCall
1573     : "," AssignmentExpression VariadicCall { $$ = CYNew CYArgument(NULL, $2, $3); }
1574     | { $$ = NULL; }
1575     ;
1576
1577 SelectorWordOpt
1578     : WordOpt { driver.contexts_.back().words_.push_back($1); } { $$ = $1; }
1579     | AutoComplete { driver.mode_ = CYDriver::AutoMessage; YYACCEPT; }
1580     ;
1581
1582 SelectorCall_
1583     : SelectorCall { $$ = $1; }
1584     | VariadicCall { $$ = $1; }
1585     ;
1586
1587 SelectorCall
1588     : SelectorWordOpt ":" AssignmentExpression SelectorCall_ { $$ = CYNew CYArgument($1 ?: CYNew CYBlank(), $3, $4); }
1589     ;
1590
1591 SelectorList
1592     : SelectorCall { $$ = $1; }
1593     | Word { $$ = CYNew CYArgument($1, NULL); }
1594     ;
1595
1596 MessageExpression
1597     : "[" LexPushInOff AssignmentExpression { driver.contexts_.push_back($3); } SelectorList "]" LexPopIn { driver.contexts_.pop_back(); } { $$ = CYNew CYSendDirect($3, $5); }
1598     | "[" LexPushInOff LexSetRegExp "super" { driver.context_ = NULL; } SelectorList "]" LexPopIn { $$ = CYNew CYSendSuper($6); }
1599     ;
1600
1601 SelectorExpression_
1602     : WordOpt ":" SelectorExpressionOpt { $$ = CYNew CYSelectorPart($1, true, $3); }
1603     ;
1604
1605 SelectorExpression
1606     : SelectorExpression_ { $$ = $1; }
1607     | Word { $$ = CYNew CYSelectorPart($1, false, NULL); }
1608     ;
1609
1610 SelectorExpressionOpt
1611     : SelectorExpression_ { $$ = $1; }
1612     | { $$ = NULL; }
1613     ;
1614
1615 PrimaryExpression
1616     : MessageExpression { $$ = $1; }
1617     | "@selector" "(" LexPushInOff SelectorExpression ")" LexPopIn { $$ = CYNew CYSelector($4); }
1618     ;
1619 /* }}} */
1620 @end
1621
1622 /* Cycript: @import Directive {{{ */
1623 Module
1624     : Module "." Word { $$ = CYNew CYModule($3, $1); }
1625     | Word { $$ = CYNew CYModule($1); }
1626     ;
1627
1628 Declaration__
1629     : "@import" Module { $$ = CYNew CYImport($2); }
1630     ;
1631 /* }}} */
1632
1633 @begin ObjectiveC
1634 /* Cycript (Objective-C): Boxed Expressions {{{ */
1635 BoxableExpression
1636     : NullLiteral { $$ = $1; }
1637     | BooleanLiteral { $$ = $1; }
1638     | NumericLiteral { $$ = $1; }
1639     | StringLiteral { $$ = $1; }
1640     | ArrayLiteral { $$ = $1; }
1641     | ObjectLiteral { $$ = $1; }
1642     | Parenthetical { $$ = $1; }
1643     | "YES" { $$ = CYNew CYTrue(); }
1644     | "NO" { $$ = CYNew CYFalse(); }
1645     ;
1646
1647 PrimaryExpression
1648     : "@" BoxableExpression { $$ = CYNew CYBox($2); }
1649     ;
1650 /* }}} */
1651 /* Cycript (Objective-C): Block Expressions {{{ */
1652 PrimaryExpression
1653     : "^" TypedIdentifier { if ($2->identifier_ != NULL) error($2->location_, "unexpected identifier"); } BRACE LexPushInOff FunctionBody "}" LexPopIn { if (CYTypeFunctionWith *function = $2->Function()) $$ = CYNew CYObjCBlock($2, function->parameters_, $6); else error($2->location_, "expected parameters"); }
1654     ;
1655 /* }}} */
1656 /* Cycript (Objective-C): Instance Literals {{{ */
1657 PrimaryExpression
1658     : "#" NumericLiteral { $$ = CYNew CYInstanceLiteral($2); }
1659     ;
1660 /* }}} */
1661 @end
1662
1663 @begin C
1664 /* Cycript (C): Pointer Indirection/Addressing {{{ */
1665 LeftHandSideExpression
1666     : LexSetRegExp "*" UnaryExpression { $$ = CYNew CYIndirect($3); }
1667     ;
1668
1669 UnaryExpression_
1670     : "&" UnaryExpression { $$ = CYNew CYAddressOf($2); }
1671     ;
1672
1673 MemberAccess
1674     : "->" "[" Expression "]" { $$ = CYNew CYIndirectMember(NULL, $3); }
1675     | "->" IdentifierName { $$ = CYNew CYIndirectMember(NULL, CYNew CYString($2)); }
1676     | "->" AutoComplete { driver.mode_ = CYDriver::AutoIndirect; YYACCEPT; }
1677     ;
1678 /* }}} */
1679 /* Cycript (C): auto Compatibility {{{ */
1680 Var_
1681     : "auto"
1682     ;
1683 /* }}} */
1684 /* Cycript (C): Lambda Expressions {{{ */
1685 TypedParameterList_
1686     : "," TypedParameterList { $$ = $2; }
1687     | { $$ = NULL; }
1688     ;
1689
1690 TypedParameterList
1691     : TypedIdentifier TypedParameterList_ { $$ = CYNew CYTypedParameter($1, $2); }
1692     ;
1693
1694 TypedParameterListOpt
1695     : TypedParameterList { $$ = $1; }
1696     | { $$ = NULL; }
1697     ;
1698
1699 PrimaryExpression
1700     : "[" LexPushInOff LexSetRegExp "&" LexSetRegExp "]" LexPopIn "(" LexPushInOff TypedParameterListOpt ")" LexPopIn "->" TypedIdentifier BRACE LexPushInOff FunctionBody "}" LexPopIn { $$ = CYNew CYLambda($14, $10, $17); }
1701     ;
1702 /* }}} */
1703 /* Cycript (C): Type Definitions {{{ */
1704 Statement__
1705     : "typedef" TypedIdentifier { if ($2->identifier_ == NULL) error($2->location_, "expected identifier"); } Terminator { $$ = CYNew CYTypeDefinition($2); }
1706     ;
1707 /* }}} */
1708 /* Cycript (C): extern "C" {{{ */
1709 Statement__
1710     : "extern" StringLiteral { if (strcmp($2->Value(), "C") != 0) error(@2, "unknown extern binding"); } TypedIdentifier { if ($4->identifier_ == NULL) error($4->location_, "expected identifier"); } Terminator { $$ = CYNew CYExternal($2, $4); }
1711     ;
1712 /* }}} */
1713
1714 @end
1715
1716 /* YUI: Documentation Comments {{{ */
1717 Statement__
1718     : Comment { $$ = $1; }
1719     ;
1720 /* }}} */
1721
1722 @begin E4X
1723 /* Lexer State {{{ */
1724 LexPushRegExp
1725     : { driver.PushCondition(CYDriver::RegExpCondition); }
1726     ;
1727
1728 LexPushXMLContent
1729     : { driver.PushCondition(CYDriver::XMLContentCondition); }
1730     ;
1731
1732 LexPushXMLTag
1733     : { driver.PushCondition(CYDriver::XMLTagCondition); }
1734     ;
1735
1736 LexPop
1737     : { driver.PopCondition(); }
1738     ;
1739
1740 LexSetXMLContent
1741     : { driver.SetCondition(CYDriver::XMLContentCondition); }
1742     ;
1743
1744 LexSetXMLTag
1745     : { driver.SetCondition(CYDriver::XMLTagCondition); }
1746     ;
1747 /* }}} */
1748 /* Virtual Tokens {{{ */
1749 XMLWhitespaceOpt
1750     : XMLWhitespace
1751     |
1752     ;
1753 /* }}} */
1754
1755 /* 8.1 Context Keywords {{{ */
1756 Identifier
1757     : "namespace" { $$ = $1; }
1758     | "xml" { $$ = $1; }
1759     ;
1760 /* }}} */
1761 /* 8.3 XML Initialiser Input Elements {{{ */
1762 XMLMarkup
1763     : XMLComment { $$ = $1; }
1764     | XMLCDATA { $$ = $1; }
1765     | XMLPI { $$ = $1; }
1766     ;
1767 /* }}} */
1768
1769 /* 11.1 Primary Expressions {{{ */
1770 PrimaryExpression
1771     : PropertyIdentifier { $$ = CYNew CYPropertyVariable($1); }
1772     | XMLInitialiser { $$ = $1; }
1773     | XMLListInitialiser { $$ = $1; }
1774     ;
1775
1776 PropertyIdentifier
1777     : AttributeIdentifier { $$ = $1; }
1778     | QualifiedIdentifier { $$ = $1; }
1779     | WildcardIdentifier { $$ = $1; }
1780     ;
1781 /* }}} */
1782 /* 11.1.1 Attribute Identifiers {{{ */
1783 AttributeIdentifier
1784     : "@" QualifiedIdentifier_ { $$ = CYNew CYAttribute($2); }
1785     ;
1786
1787 PropertySelector_
1788     : PropertySelector { $$ = $1; }
1789     | "[" LexPushInOff Expression "]" LexPopIn { $$ = CYNew CYSelector($3); }
1790     ;
1791
1792 PropertySelector
1793     : Identifier { $$ = CYNew CYSelector($1); }
1794     | WildcardIdentifier { $$ = $1; }
1795     ;
1796 /* }}} */
1797 /* 11.1.2 Qualified Identifiers {{{ */
1798 QualifiedIdentifier_
1799     : PropertySelector_ { $$ = CYNew CYQualified(NULL, $1); }
1800     | QualifiedIdentifier { $$ = $1; }
1801     ;
1802
1803 QualifiedIdentifier
1804     : PropertySelector "::" PropertySelector_ { $$ = CYNew CYQualified($1, $3); }
1805     ;
1806 /* }}} */
1807 /* 11.1.3 Wildcard Identifiers {{{ */
1808 WildcardIdentifier
1809     : "*" { $$ = CYNew CYWildcard(); }
1810     ;
1811 /* }}} */
1812 /* 11.1.4 XML Initialiser {{{ */
1813 XMLInitialiser
1814     : XMLMarkup { $$ = $1; }
1815     | XMLElement { $$ = $1; }
1816     ;
1817
1818 XMLElement
1819     : "<" LexPushInOff XMLTagContent LexPop "/>" LexPopIn
1820     | "<" LexPushInOff XMLTagContent ">" LexSetXMLContent XMLElementContentOpt "</" LexSetXMLTag XMLTagName XMLWhitespaceOpt LexPop ">" LexPopIn
1821     ;
1822
1823 XMLTagContent
1824     : LexPushXMLTag XMLTagName XMLAttributes
1825     ;
1826
1827 XMLExpression
1828     : BRACE LexPushRegExp Expression LexPop "}"
1829     ;
1830
1831 XMLTagName
1832     : XMLExpression
1833     | XMLName
1834     ;
1835
1836 XMLAttributes_
1837     : XMLAttributes_ XMLAttribute
1838     |
1839     ;
1840
1841 XMLAttributes
1842     : XMLAttributes_ XMLWhitespace XMLExpression XMLWhitespaceOpt
1843     | XMLAttributes_ XMLWhitespaceOpt
1844     ;
1845
1846 XMLAttributeValue_
1847     : XMLExpression
1848     | XMLAttributeValue
1849     ;
1850
1851 XMLAttribute
1852     : XMLWhitespace XMLName XMLWhitespaceOpt "=" XMLWhitespaceOpt XMLAttributeValue_
1853     ;
1854
1855 XMLElementContent
1856     : XMLExpression XMLElementContentOpt
1857     | XMLMarkup XMLElementContentOpt
1858     | XMLText XMLElementContentOpt
1859     | XMLElement XMLElementContentOpt
1860     ;
1861
1862 XMLElementContentOpt
1863     : XMLElementContent
1864     |
1865     ;
1866 /* }}} */
1867 /* 11.1.5 XMLList Initialiser {{{ */
1868 XMLListInitialiser
1869     : "<>" LexPushInOff LexPushXMLContent XMLElementContent LexPop "</>" LexPopIn { $$ = CYNew CYXMLList($4); }
1870     ;
1871 /* }}} */
1872
1873 /* 11.2 Left-Hand-Side Expressions {{{ */
1874 PropertyIdentifier_
1875     : Identifier { $$ = $1; }
1876     | PropertyIdentifier { $$ = $1; }
1877     ;
1878
1879 MemberAccess
1880     : "." PropertyIdentifier { $$ = CYNew CYPropertyMember(NULL, $2); }
1881     | ".." PropertyIdentifier_ { $$ = CYNew CYDescendantMember(NULL, $2); }
1882     | "." "(" Expression ")" { $$ = CYNew CYFilteringPredicate(NULL, $3); }
1883     ;
1884 /* }}} */
1885 /* 12.1 The default xml namespace Statement {{{ */
1886 /* XXX: DefaultXMLNamespaceStatement
1887     : "default" "xml" "namespace" "=" Expression Terminator { $$ = CYNew CYDefaultXMLNamespace($5); }
1888     ;
1889
1890 Statement__
1891     : DefaultXMLNamespaceStatement { $$ = $1; }
1892     ; */
1893 /* }}} */
1894 @end
1895
1896 /* JavaScript 1.7: Array Comprehensions {{{ */
1897 Comprehension
1898     : AssignmentExpression ComprehensionFor ComprehensionTail { $$ = CYNew CYArrayComprehension($1, $2->Modify($3)); }
1899     ;
1900
1901 ComprehensionFor
1902     : "for" "(" Binding "in" Expression ")" { $$ = CYNew CYForInComprehension($3, $5); }
1903     | "for" "each" "(" Binding "in" Expression ")" { $$ = CYNew CYForOfComprehension($4, $6); }
1904     ;
1905 /* }}} */
1906 /* JavaScript 1.7: for each {{{ */
1907 IterationStatement
1908     : "for" "each" "(" LexPushInOn ForInStatementInitialiser "!in" LexPopIn Expression ")" Statement { $$ = CYNew CYForOf($5, $8, $10); }
1909     ;
1910 /* }}} */
1911 /* JavaScript 1.7: let Statements {{{ */
1912 LetStatement
1913     : "let" "(" VariableDeclarationList ")" Statement { $$ = CYNew CYLetStatement($3, $5); }
1914     ;
1915
1916 Statement__
1917     : LetStatement
1918     ;
1919 /* }}} */
1920
1921 /* JavaScript FTW: Ruby Blocks {{{ */
1922 RubyProcParameterList_
1923     : "," RubyProcParameterList { $$ = $2; }
1924     | { $$ = NULL; }
1925     ;
1926
1927 RubyProcParameterList
1928     : Identifier RubyProcParameterList_ { $$ = CYNew CYFunctionParameter(CYNew CYDeclaration($1), $2); }
1929     | { $$ = NULL; }
1930     ;
1931
1932 RubyProcParameters
1933     : "|" RubyProcParameterList "|" { $$ = $2; }
1934     | "||" { $$ = NULL; }
1935     ;
1936
1937 RubyProcParametersOpt
1938     : RubyProcParameters
1939     | { $$ = NULL; }
1940     ;
1941
1942 RubyProcExpression
1943     : "{" RubyProcParametersOpt StatementListOpt "}" { $$ = CYNew CYRubyProc($2, $3); }
1944     ;
1945
1946 PrimaryExpression
1947     : "{" LexPushInOff RubyProcParameters StatementListOpt "}" LexPopIn { $$ = CYNew CYRubyProc($3, $4); }
1948     ;
1949
1950 CallExpression
1951     : CallExpression_ RubyProcExpression { $$ = CYNew CYRubyBlock($1, $2); }
1952     ;
1953 /* }}} */
1954
1955 %%