configure.ac

   1 dnl Cycript - Optimizing JavaScript Compiler/Runtime
   2 dnl Copyright (C) 2009-2013  Jay Freeman (saurik)
   3
   4 dnl GNU General Public License, Version 3 {{{
   5 dnl
   6 dnl Cycript is free software: you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published
   8 dnl by the Free Software Foundation, either version 3 of the License,
   9 dnl or (at your option) any later version.
  10 dnl
  11 dnl Cycript is distributed in the hope that it will be useful, but
  12 dnl WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with Cycript.  If not, see <http://www.gnu.org/licenses/>.
  18 dnl }}}
  19
  20 AC_PREREQ([2.65])
  21 AC_INIT([Cycript], [0.9], [saurik@saurik.com], [cycript], [http://www.cycript.org/])
  22 AC_COPYRIGHT([Copyright (C) 2009-2012  Jay Freeman (saurik)])
  23
  24 AC_CONFIG_SRCDIR([Console.cpp])
  25 AC_CONFIG_AUX_DIR([.])
  26 AC_CONFIG_MACRO_DIR([m4])
  27 AC_CONFIG_HEADERS([config.h])
  28
  29 AM_INIT_AUTOMAKE([-Wall -Werror foreign])
  30 AM_MAINTAINER_MODE([disable])
  31
  32 dnl XXX: do this only on Mac OS X
  33 am_cv_CC_dependencies_compiler_type=none
  34 am_cv_CXX_dependencies_compiler_type=none
  35 am_cv_OBJCXX_dependencies_compiler_type=none
  36
  37 AC_PROG_CC
  38 AC_PROG_CXX
  39 AC_PROG_OBJCXX
  40
  41 AM_PROG_AR
  42 AC_PROG_INSTALL
  43
  44 LT_INIT([disable-static])
  45
  46 AC_LANG([C++])
  47
  48 PKG_PROG_PKG_CONFIG([0.22])
  49
  50 AC_PATH_PROG([GIT], [git])
  51 AC_PATH_PROG([TIME], [time])
  52
  53 dnl CY_CHECK_PROGS_VERSION {{{
  54 AC_DEFUN([CY_CHECK_PROGS_VERSION], [
  55     AC_ARG_VAR(]$1[, ]$3[)
  56
  57     AC_MSG_CHECKING(for ]$2[ >= ]$5[)
  58     AC_PATH_PROGS_FEATURE_CHECK(]$1[, ]$2[,
  59         AS_VAR_SET(version, [`$ac_path_]$1[ ]$4[`])
  60         AS_VAR_IF(version, [], ,
  61             AS_VERSION_COMPARE($version, ]$5[, ,
  62                 ac_cv_path_]$1[=$ac_path_]$1[,
  63                 ac_cv_path_]$1[=$ac_path_]$1[))
  64     , AC_MSG_RESULT(no))
  65
  66     AS_IF([true], [
  67         AC_SUBST(]$1[, $ac_cv_path_]$1[)
  68         AC_MSG_RESULT($]$1[)
  69     ], AS_IF([true], [
  70         AC_MSG_ERROR(You need ]$2[ ]$5[ or greater)
  71     ], [
  72         AC_SUBST(]$1[, [:])
  73         AC_MSG_RESULT([no])
  74     ]))
  75 ]) dnl }}}
  76
  77 CY_CHECK_PROGS_VERSION([BISON], [bison], [GNU Project parser generator (yacc replacement)],
  78     [-V | $SED -e '1 s/^bison (GNU Bison) \(.*\)$/\1/p;d'], [2.3])
  79 CY_CHECK_PROGS_VERSION([FLEX], [flex], [the fast lexical analyser generator],
  80     [--version | $SED -e '1 s/^@<:@^0-9.@:>@* \(@<:@0-9.@:>@*\).*$/\1/p;d'], [2.5.33])
  81 CY_CHECK_PROGS_VERSION([GPERF], [gperf], [perfect hash function generator],
  82     [--version | $SED -e '1 s/^.* \(@<:@0-9.@:>@*\)$/\1/p;d'], [3.0.3])
  83 CY_CHECK_PROGS_VERSION([GNUTAR], [tar gtar gnutar], [a very sticky lump of files],
  84     [--version | $SED -e '1 s/^tar (GNU tar) \(.*\)$/\1/p;d'], [1.19])
  85
  86 AC_MSG_CHECKING([bison for %code{}])
  87 echo '%code{}%%_:' >conftest.y
  88 if $BISON conftest.y -o/dev/null 2>/dev/null; then
  89     AC_LIB_APPENDTOVAR([CY_FILTERS], [Bison24])
  90     AC_MSG_RESULT([yes])
  91 else
  92     AC_LIB_APPENDTOVAR([CY_FILTERS], [Bison23])
  93     AC_MSG_RESULT([no])
  94 fi
  95
  96 rm -f conftest.y
  97 AC_SUBST([CY_FILTERS])
  98
  99 dnl CY_TRY {{{
 100 AC_DEFUN([CY_SUCCESS], [cy_good=1])
 101 AC_DEFUN([CY_FAILURE], [cy_good=0])
 102
 103 AC_DEFUN([CY_TRY], [
 104     cy_save=$]$1[
 105         AC_LIB_APPENDTOVAR(]$1[, ]$2[)
 106         ]$3[
 107     ]$1[=$cy_save
 108     AS_IF([test "x$cy_good" = x1], ]$4[, ]$5[)
 109 ]) dnl }}}
 110
 111 AC_DEFUN([CY_TEST_FLAG_], [
 112     AC_LANG_PUSH(]$2[)
 113     AC_MSG_CHECKING([for ]]$4[[ ]]$1[)
 114     CY_TRY(]$3[, $1, [
 115         AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
 116             [CY_SUCCESS], [CY_FAILURE])
 117     ], [
 118         AC_MSG_RESULT([yes])
 119         AC_LIB_APPENDTOVAR(]$3[, ]$1[)
 120     ], [AC_MSG_RESULT([no])])
 121     AC_LANG_POP(]$2[)
 122 ])
 123
 124 AC_DEFUN([CY_TEST_FLAG], [
 125     CY_TEST_FLAG_(]$1[, [C], [CFLAGS], [cc])
 126     CY_TEST_FLAG_(]$1[, [C++], [CXXFLAGS], [c++])
 127     CY_TEST_FLAG_(]$1[, [Objective C++], [OBJCXXFLAGS], [c++ -ObjC])
 128 ])
 129
 130 AX_CFLAGS_WARN_ALL
 131 AX_CXXFLAGS_WARN_ALL
 132 AX_FLAGS_WARN_ALL
 133
 134 CY_TEST_FLAG([-Werror])
 135
 136 dnl XXX: this is used to support GNU Objective-C struct objc_method
 137 CY_TEST_FLAG([-Wno-deprecated-declarations])
 138
 139 CY_TEST_FLAG([-Wno-dangling-else])
 140 CY_TEST_FLAG([-Wno-overloaded-virtual])
 141 CY_TEST_FLAG([-Wno-parentheses])
 142 CY_TEST_FLAG([-Wno-unneeded-internal-declaration])
 143
 144 dnl -arch * {{{
 145 for cy_arch in ppc ppc64 i386 x86_64 armv6; do
 146     AC_MSG_CHECKING([for -arch $cy_arch])
 147     CY_TRY([CXXFLAGS], ["-arch $cy_arch"], [
 148         AC_TRY_LINK([], [], [CY_SUCCESS], [CY_FAILURE])
 149     ], [
 150         AC_MSG_RESULT([yes])
 151         AC_LIB_APPENDTOVAR([CY_ARCH], ["-arch $cy_arch"])
 152     ], [AC_MSG_RESULT([no])])
 153 done
 154 AC_SUBST([CY_ARCH])
 155 dnl }}}
 156 dnl iOS SDK {{{
 157 AC_PATH_PROG([XCODEBUILD], [xcodebuild])
 158
 159 AS_IF([test "x$XCODEBUILD" != x], [
 160     AC_SUBST([CY_XCODE_MACOSXSDK], [`xcodebuild -sdk macosx -version Path`])
 161     AC_SUBST([CY_XCODE_IOSSIMSDK], [`xcodebuild -sdk iphonesimulator -version Path`])
 162 ])
 163
 164 AM_CONDITIONAL([CY_IOS_SIMULATOR], [test "x$CY_XCODE_IOSSIMSDK" != x])
 165 dnl }}}
 166
 167 AC_DEFUN([CY_LT_LIB], [
 168     cy_save=$LIBS
 169     LIBS=
 170     ]$2[
 171     ]$1[=$LIBS
 172     LIBS=$cy_save
 173     AC_SUBST(]$1[)
 174 ])
 175
 176 dnl --enable-javascript {{{
 177 AC_DEFUN([CY_CHECK_JAVASCRIPTCORE], [
 178     CY_LT_LIB([LTJAVASCRIPTCORE], [AC_CHECK_FRAMEWORK([JavaScriptCore], [
 179         #include <JavaScriptCore/JSBase.h>
 180     ], [
 181         JSEvaluateScript(0, 0, 0, 0, 0, 0);
 182     ], [
 183         AC_SUBST([CY_EXECUTE], [1])
 184     ], [
 185         for cy_webkit_pkg in "webkit-1.0" "WebKitGtk"; do
 186             PKG_CHECK_MODULES([WEBKIT], [$cy_webkit_pkg], [
 187                 AC_SUBST([CY_EXECUTE], [1])
 188                 AC_LIB_APPENDTOVAR([CPPFLAGS], [`$PKG_CONFIG --cflags $cy_webkit_pkg`])
 189                 AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs $cy_webkit_pkg`])
 190             ], [:]); if test "x$CY_EXECUTE" = x1; then break; fi
 191         done
 192     ])])
 193 ])
 194
 195 AC_DEFUN([CY_CHECK_JAVASCRIPT], [
 196     CY_CHECK_JAVASCRIPTCORE])
 197
 198 AC_ARG_ENABLE([javascript], [AS_HELP_STRING(
 199     [--enable-javascript@<:@=ENGINE@:>@],
 200     [use a JavaScript runtime (currently the only available option for ENGINE is JavaScriptCore) @<:@default=yes@:>@]
 201 )], [
 202     AS_CASE([$enableval],
 203         [yes], [
 204             CY_CHECK_JAVASCRIPT],
 205         [no], [
 206             AC_SUBST([CY_EXECUTE], [0])],
 207         [JavaScriptCore], [
 208             CY_CHECK_JAVASCRIPTCORE],
 209         [AC_MSG_ERROR([Unknown JavaScript engine: $enableval])])
 210 ], [CY_CHECK_JAVASCRIPT])
 211 dnl }}}
 212
 213 dnl APR_FIND_APR {{{
 214 AS_IF([test "x$LTLIBAPR" != x], [
 215     AC_SUBST([LTLIBAPR])
 216 ], [
 217     APR_FIND_APR([], [], [1], [1])
 218 AS_CASE([$apr_found], [yes], [
 219     AC_LIB_APPENDTOVAR([CPPFLAGS], [`$apr_config --includes`])
 220     AC_LIB_APPENDTOVAR([LTLIBAPR], [`$apr_config --link-libtool`])
 221     AC_SUBST([LTLIBAPR])
 222 ], [
 223     AC_MSG_ERROR([missing "libapr"])
 224 ])])
 225 dnl }}}
 226
 227 AC_DEFUN([CY_CHECK_PKG_CONFIG_LIBFFI], [
 228     PKG_CHECK_MODULES([LIBFFI], [libffi], [
 229         AC_LIB_APPENDTOVAR([CPPFLAGS], [`$PKG_CONFIG --cflags libffi`])
 230         AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs libffi`])
 231     ], [AC_MSG_ERROR([missing "libffi"])])])
 232
 233 AM_CONDITIONAL([CY_EXECUTE], [test "x$CY_EXECUTE" = x1])
 234
 235 AS_CASE([$CY_EXECUTE], [1], [
 236     AC_CHECK_HEADERS([ffi.h ffi/ffi.h], [break])
 237
 238     CY_LT_LIB([LTLIBFFI], AS_IF([test "x$ac_cv_header_ffi_h" = xno && test "x$ac_cv_header_ffi_ffi_h" = xno], [
 239         CY_CHECK_PKG_CONFIG_LIBFFI
 240     ], [
 241         AC_SEARCH_LIBS([ffi_call], [ffi])
 242         AS_CASE([$ac_cv_search_ffi_call], [no], [CY_CHECK_PKG_CONFIG_LIBFFI])
 243     ]))
 244
 245     AC_LANG_PUSH([Objective C++])
 246
 247     AC_MSG_CHECKING([if we really have Objective C++])
 248     AC_COMPILE_IFELSE([AC_LANG_SOURCE([])], [
 249         CY_OBJECTIVEC=1
 250         AC_MSG_RESULT([yes])
 251     ], [AC_MSG_RESULT([no])])
 252
 253     AS_IF([test "x$CY_OBJECTIVEC" = x1], [
 254         CY_LT_LIB([LTOBJECTIVEC], [AC_CHECK_FRAMEWORK([CoreFoundation], [
 255             #include <CoreFoundation/CFBase.h>
 256         ], [CFAllocatorGetDefault();], [
 257             AC_SUBST([CY_OBJECTIVEC])
 258
 259             AC_CHECK_FRAMEWORK([Foundation], [
 260                 #include <Foundation/NSObject.h>
 261             ], [[[[NSObject alloc] init];]])
 262         ], [
 263             AC_ARG_VAR([GNUSTEP_CONFIG], [prints information about the current gnustep installation])
 264             AC_CHECK_PROGS([GNUSTEP_CONFIG], [gnustep-config])
 265
 266             AS_IF([test "x$GNUSTEP_CONFIG" != x], [
 267                 AC_SUBST([CY_OBJECTIVEC])
 268                 AC_LIB_APPENDTOVAR([OBJCXXFLAGS], [`$GNUSTEP_CONFIG --objc-flags`])
 269                 AC_LIB_APPENDTOVAR([LIBS], [`$GNUSTEP_CONFIG --base-libs`])
 270             ], [AC_SUBST([CY_OBJECTIVEC], [0])])
 271         ])])
 272     ])
 273
 274     AC_LANG_POP([Objective C++])
 275 ])
 276
 277 AM_CONDITIONAL([CY_OBJECTIVEC], [test "x$CY_OBJECTIVEC" = x1])
 278
 279 CY_LT_LIB([LTLIBREADLINE], [AX_LIB_READLINE])
 280 AS_CASE([$ax_cv_lib_readline], [no], [AC_MSG_ERROR([missing "libreadline"])])
 281
 282 CY_LT_LIB([LTLIBTERMCAP], [AC_SEARCH_LIBS([cur_term], [termcap ncurses])])
 283
 284 AC_SUBST([LTFLAGS])
 285 AC_SUBST([SO], [$acl_shlibext])
 286
 287 AS_IF([test "x$CY_EXECUTE" = x1], [
 288     AC_CHECK_HEADER([mach/mach.h], [
 289         AC_CHECK_TOOLS([_LIPO], [lipo], [AC_MSG_ERROR([missing "lipo"])])
 290         AC_CHECK_TOOLS([_NM], [nm], [AC_MSG_ERROR([missing "nm"])])
 291         AC_CHECK_TOOLS([_OTOOL], [otool], [AC_MSG_ERROR([missing "otool"])])
 292         AC_SUBST([CY_ATTACH_GROUP], [procmod])
 293         AC_SUBST([CY_MACH], [1])])])
 294 AM_CONDITIONAL([CY_MACH], [test "x$CY_MACH" = x1])
 295
 296 AC_CONFIG_FILES([Makefile])
 297 AC_OUTPUT