Cycript.yy.in

   1 /* Cycript - Optimizing JavaScript Compiler/Runtime
   2  * Copyright (C) 2009-2010  Jay Freeman (saurik)
   3 */
   4
   5 /* GNU Lesser General Public License, Version 3 {{{ */
   6 /*
   7  * Cycript is free software: you can redistribute it and/or modify it under
   8  * the terms of the GNU Lesser General Public License as published by the
   9  * Free Software Foundation, either version 3 of the License, or (at your
  10  * option) any later version.
  11  *
  12  * Cycript is distributed in the hope that it will be useful, but WITHOUT
  13  * ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  14  * FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  15  * License for more details.
  16  *
  17  * You should have received a copy of the GNU Lesser General Public License
  18  * along with Cycript.  If not, see <http://www.gnu.org/licenses/>.
  19 **/
  20 /* }}} */
  21
  22 @if Bison23 %{
  23
  24 @if Bison24 %code top {
  25 #define cyscanner driver.scanner_
  26 #define YYSTACKEXPANDABLE 1
  27 @if Bison23 #define yyerrok (yyerrstatus_ = 0)
  28 @if Bison24 }
  29
  30 @if Bison24 %code requires {
  31 #include "Parser.hpp"
  32 #define CYNew new($pool)
  33
  34 @begin ObjectiveC
  35 #include "ObjectiveC/Syntax.hpp"
  36 @end
  37
  38 @begin E4X
  39 #include "E4X/Syntax.hpp"
  40 @end
  41
  42 typedef struct {
  43     bool newline_;
  44
  45     union {
  46         bool bool_;
  47
  48         CYDriver::Condition condition_;
  49
  50         CYArgument *argument_;
  51         CYAssignment *assignment_;
  52         CYBoolean *boolean_;
  53         CYClause *clause_;
  54         cy::Syntax::Catch *catch_;
  55         CYComment *comment_;
  56         CYComprehension *comprehension_;
  57         CYCompound *compound_;
  58         CYDeclaration *declaration_;
  59         CYDeclarations *declarations_;
  60         CYElement *element_;
  61         CYExpression *expression_;
  62         CYFalse *false_;
  63         CYFinally *finally_;
  64         CYForInitialiser *for_;
  65         CYForInInitialiser *forin_;
  66         CYFunctionParameter *functionParameter_;
  67         CYIdentifier *identifier_;
  68         CYInfix *infix_;
  69         CYLiteral *literal_;
  70         CYMember *member_;
  71         CYNull *null_;
  72         CYNumber *number_;
  73         CYProgram *program_;
  74         CYProperty *property_;
  75         CYPropertyName *propertyName_;
  76         CYRubyProc *rubyProc_;
  77         CYStatement *statement_;
  78         CYString *string_;
  79         CYThis *this_;
  80         CYTrue *true_;
  81         CYWord *word_;
  82
  83 @begin ObjectiveC
  84         CYClassName *className_;
  85         CYField *field_;
  86         CYMessage *message_;
  87         CYMessageParameter *messageParameter_;
  88         CYProtocol *protocol_;
  89         CYSelectorPart *selector_;
  90 @end
  91
  92 @begin E4X
  93         CYAttribute *attribute_;
  94         CYPropertyIdentifier *propertyIdentifier_;
  95         CYSelector *selector_;
  96 @end
  97     };
  98 } YYSTYPE;
  99
 100 #define YYSTYPE YYSTYPE
 101 @if Bison24 }
 102
 103 @if Bison24 %code provides {
 104 int cylex(YYSTYPE *, cy::location *, void *);
 105 @if Bison24 }
 106
 107 @if Bison23 %}
 108
 109 %name-prefix="cy"
 110
 111 @if Bison23 %skeleton "lalr1.cc"
 112 @if Bison24 %language "C++"
 113
 114 %initial-action {
 115     @$.begin.filename = @$.end.filename = &driver.filename_;
 116 };
 117
 118 %locations
 119 %defines
 120
 121 //%glr-parser
 122 //%expect 1
 123
 124 %error-verbose
 125
 126 %parse-param { CYDriver &driver }
 127 %lex-param { void *cyscanner }
 128
 129 @begin E4X
 130 %token XMLCDATA
 131 %token XMLComment
 132 %token XMLPI
 133
 134 %token XMLAttributeValue
 135 %token XMLName
 136 %token XMLTagCharacters
 137 %token XMLText
 138 %token XMLWhitespace
 139 @end
 140
 141 @begin E4X
 142 %token LeftRight "<>"
 143 %token LeftSlashRight "</>"
 144
 145 %token SlashRight "/>"
 146 %token LeftSlash "</"
 147
 148 %token ColonColon "::"
 149 %token PeriodPeriod ".."
 150 @end
 151
 152 @begin E4X ObjectiveC
 153 %token At "@"
 154 @end
 155
 156 %token Ampersand "&"
 157 %token AmpersandAmpersand "&&"
 158 %token AmpersandEqual "&="
 159 %token Carrot "^"
 160 %token CarrotEqual "^="
 161 %token Equal "="
 162 %token EqualEqual "=="
 163 %token EqualEqualEqual "==="
 164 %token Exclamation "!"
 165 %token ExclamationEqual "!="
 166 %token ExclamationEqualEqual "!=="
 167 %token Hyphen "-"
 168 %token HyphenEqual "-="
 169 %token HyphenHyphen "--"
 170 %token HyphenHyphen_ "\n--"
 171 %token HyphenRight "->"
 172 %token Left "<"
 173 %token LeftEqual "<="
 174 %token LeftLeft "<<"
 175 %token LeftLeftEqual "<<="
 176 %token Percent "%"
 177 %token PercentEqual "%="
 178 %token Period "."
 179 %token Pipe "|"
 180 %token PipeEqual "|="
 181 %token PipePipe "||"
 182 %token Plus "+"
 183 %token PlusEqual "+="
 184 %token PlusPlus "++"
 185 %token PlusPlus_ "\n++"
 186 %token Right ">"
 187 %token RightEqual ">="
 188 %token RightRight ">>"
 189 %token RightRightEqual ">>="
 190 %token RightRightRight ">>>"
 191 %token RightRightRightEqual ">>>="
 192 %token Slash "/"
 193 %token SlashEqual "/="
 194 %token Star "*"
 195 %token StarEqual "*="
 196 %token Tilde "~"
 197
 198 %token Colon ":"
 199 %token Comma ","
 200 %token Question "?"
 201 %token SemiColon ";"
 202 %token NewLine "\n"
 203
 204 %token <comment_> Comment
 205
 206 %token OpenParen "("
 207 %token CloseParen ")"
 208
 209 %token OpenBrace "{"
 210 %token OpenBrace_ "\n{"
 211 %token CloseBrace "}"
 212
 213 %token OpenBracket "["
 214 %token CloseBracket "]"
 215
 216 @begin Java
 217 %token AtClass "@class"
 218 @end
 219
 220 @begin ObjectiveC
 221 %token AtImplementation "@implementation"
 222 %token AtImport "@import"
 223 %token AtEnd "@end"
 224 %token AtSelector "@selector"
 225 @end
 226
 227 %token <false_> False "false"
 228 %token <null_> Null "null"
 229 %token <true_> True "true"
 230
 231 // ES3/ES5/WIE/JSC Reserved
 232 %token <word_> Break "break"
 233 %token <word_> Case "case"
 234 %token <word_> Catch "catch"
 235 %token <word_> Continue "continue"
 236 %token <word_> Default "default"
 237 %token <word_> Delete "delete"
 238 %token <word_> Do "do"
 239 %token <word_> Else "else"
 240 %token <word_> Finally "finally"
 241 %token <word_> For "for"
 242 %token <word_> Function "function"
 243 %token <word_> If "if"
 244 %token <word_> In "in"
 245 %token <word_> InstanceOf "instanceof"
 246 %token <word_> New "new"
 247 %token <word_> Return "return"
 248 %token <word_> Switch "switch"
 249 %token <this_> This "this"
 250 %token <word_> Throw "throw"
 251 %token <word_> Try "try"
 252 %token <word_> TypeOf "typeof"
 253 %token <word_> Var "var"
 254 %token <word_> Void "void"
 255 %token <word_> While "while"
 256 %token <word_> With "with"
 257
 258 // ES3/IE6 Future, ES5/JSC Reserved
 259 %token <word_> Debugger "debugger"
 260
 261 // ES3/ES5/IE6 Future, JSC Reserved
 262 %token <word_> Const "const"
 263
 264 // ES3/ES5/IE6/JSC Future
 265 %token <word_> Class "class"
 266 %token <word_> Enum "enum"
 267 %token <word_> Export "export"
 268 %token <word_> Extends "extends"
 269 %token <word_> Import "import"
 270 %token <word_> Super "super"
 271
 272 // ES3 Future, ES5 Strict Future
 273 %token <identifier_> Implements "implements"
 274 %token <identifier_> Interface "interface"
 275 %token <identifier_> Package "package"
 276 %token <identifier_> Private "private"
 277 %token <identifier_> Protected "protected"
 278 %token <identifier_> Public "public"
 279 %token <identifier_> Static "static"
 280
 281 // ES3 Future
 282 %token <identifier_> Abstract "abstract"
 283 %token <identifier_> Boolean "boolean"
 284 %token <identifier_> Byte "byte"
 285 %token <identifier_> Char "char"
 286 %token <identifier_> Double "double"
 287 %token <identifier_> Final "final"
 288 %token <identifier_> Float "float"
 289 %token <identifier_> Goto "goto"
 290 %token <identifier_> Int "int"
 291 %token <identifier_> Long "long"
 292 %token <identifier_> Native "native"
 293 %token <identifier_> Short "short"
 294 %token <identifier_> Synchronized "synchronized"
 295 %token <identifier_> Throws "throws"
 296 %token <identifier_> Transient "transient"
 297 %token <identifier_> Volatile "volatile"
 298
 299 // ES5 Strict
 300 %token <identifier_> Let "let"
 301 %token <identifier_> Yield "yield"
 302
 303 // Woah?!
 304 %token <identifier_> Each "each"
 305
 306 @begin E4X
 307 // E4X Conditional
 308 %token <identifier_> Namespace "namespace"
 309 %token <identifier_> XML "xml"
 310 @end
 311
 312 %token AutoComplete
 313
 314 %token <identifier_> Identifier_
 315 %token <number_> NumericLiteral
 316 %token <string_> StringLiteral
 317 %token <literal_> RegularExpressionLiteral
 318
 319 %type <expression_> AdditiveExpression
 320 %type <expression_> AdditiveExpressionNoBF
 321 %type <argument_> ArgumentList
 322 %type <argument_> ArgumentList_
 323 %type <argument_> ArgumentListOpt
 324 %type <argument_> Arguments
 325 %type <literal_> ArrayLiteral
 326 %type <expression_> AssigneeExpression
 327 %type <expression_> AssigneeExpressionNoBF
 328 %type <expression_> AssignmentExpression
 329 %type <assignment_> AssignmentExpression_
 330 %type <expression_> AssignmentExpressionNoBF
 331 %type <expression_> AssignmentExpressionNoIn
 332 %type <expression_> BitwiseANDExpression
 333 %type <expression_> BitwiseANDExpressionNoBF
 334 %type <expression_> BitwiseANDExpressionNoIn
 335 %type <statement_> Block
 336 %type <statement_> Block_
 337 %type <boolean_> BooleanLiteral
 338 %type <expression_> BitwiseORExpression
 339 %type <expression_> BitwiseORExpressionNoBF
 340 %type <expression_> BitwiseORExpressionNoIn
 341 %type <expression_> BitwiseXORExpression
 342 %type <expression_> BitwiseXORExpressionNoBF
 343 %type <expression_> BitwiseXORExpressionNoIn
 344 %type <statement_> BreakStatement
 345 %type <expression_> CallExpression
 346 %type <expression_> CallExpressionNoBF
 347 %type <clause_> CaseBlock
 348 %type <clause_> CaseClause
 349 %type <clause_> CaseClausesOpt
 350 %type <catch_> CatchOpt
 351 %type <comprehension_> ComprehensionList
 352 %type <comprehension_> ComprehensionListOpt
 353 %type <expression_> ConditionalExpression
 354 %type <expression_> ConditionalExpressionNoBF
 355 %type <expression_> ConditionalExpressionNoIn
 356 %type <statement_> ContinueStatement
 357 %type <clause_> DefaultClause
 358 %type <statement_> DoWhileStatement
 359 %type <expression_> Element
 360 %type <expression_> ElementOpt
 361 %type <element_> ElementList
 362 %type <element_> ElementListOpt
 363 %type <statement_> ElseStatementOpt
 364 %type <statement_> EmptyStatement
 365 %type <expression_> EqualityExpression
 366 %type <expression_> EqualityExpressionNoBF
 367 %type <expression_> EqualityExpressionNoIn
 368 %type <expression_> Expression
 369 %type <expression_> ExpressionOpt
 370 %type <compound_> Expression_
 371 %type <expression_> ExpressionNoBF
 372 %type <expression_> ExpressionNoIn
 373 %type <compound_> ExpressionNoIn_
 374 %type <expression_> ExpressionNoInOpt
 375 %type <statement_> ExpressionStatement
 376 %type <finally_> FinallyOpt
 377 %type <comprehension_> ForComprehension
 378 %type <statement_> ForStatement
 379 %type <for_> ForStatementInitialiser
 380 %type <statement_> ForInStatement
 381 %type <forin_> ForInStatementInitialiser
 382 %type <functionParameter_> FormalParameterList
 383 %type <functionParameter_> FormalParameterList_
 384 %type <statement_> FunctionBody
 385 %type <statement_> FunctionDeclaration
 386 %type <expression_> FunctionExpression
 387 %type <identifier_> Identifier
 388 %type <identifier_> IdentifierOpt
 389 %type <comprehension_> IfComprehension
 390 %type <statement_> IfStatement
 391 %type <expression_> Initialiser
 392 %type <expression_> InitialiserOpt
 393 %type <expression_> InitialiserNoIn
 394 %type <expression_> InitialiserNoInOpt
 395 %type <statement_> IterationStatement
 396 %type <statement_> LabelledStatement
 397 %type <expression_> LeftHandSideExpression
 398 %type <expression_> LeftHandSideExpressionNoBF
 399 //%type <statement_> LetStatement
 400 %type <literal_> Literal
 401 %type <literal_> LiteralNoRE
 402 %type <literal_> LiteralRE
 403 %type <expression_> LogicalANDExpression
 404 %type <expression_> LogicalANDExpressionNoBF
 405 %type <expression_> LogicalANDExpressionNoIn
 406 %type <expression_> LogicalORExpression
 407 %type <expression_> LogicalORExpressionNoBF
 408 %type <expression_> LogicalORExpressionNoIn
 409 %type <member_> MemberAccess
 410 %type <expression_> MemberExpression
 411 %type <expression_> MemberExpression_
 412 %type <expression_> MemberExpressionNoBF
 413 %type <expression_> MultiplicativeExpression
 414 %type <expression_> MultiplicativeExpressionNoBF
 415 %type <expression_> NewExpression
 416 %type <expression_> NewExpression_
 417 %type <expression_> NewExpressionNoBF
 418 %type <null_> NullLiteral
 419 %type <literal_> ObjectLiteral
 420 %type <expression_> PostfixExpression
 421 %type <expression_> PostfixExpressionNoBF
 422 %type <expression_> PrimaryExpression
 423 %type <expression_> PrimaryExpressionNo
 424 %type <expression_> PrimaryExpressionNoBF
 425 %type <expression_> PrimaryExpressionNoRE
 426 %type <expression_> PrimaryExpressionBF
 427 %type <statement_> Program
 428 %type <propertyName_> PropertyName
 429 %type <propertyName_> PropertyName_
 430 %type <property_> PropertyNameAndValueList
 431 %type <property_> PropertyNameAndValueList_
 432 %type <property_> PropertyNameAndValueListOpt
 433 %type <expression_> RelationalExpression
 434 %type <infix_> RelationalExpression_
 435 %type <expression_> RelationalExpressionNoBF
 436 %type <expression_> RelationalExpressionNoIn
 437 %type <infix_> RelationalExpressionNoIn_
 438 %type <statement_> ReturnStatement
 439 %type <rubyProc_> RubyProcExpression
 440 %type <functionParameter_> RubyProcParameterList
 441 %type <functionParameter_> RubyProcParameterList_
 442 %type <functionParameter_> RubyProcParametersOpt
 443 %type <expression_> ShiftExpression
 444 %type <expression_> ShiftExpressionNoBF
 445 %type <statement_> SourceElement
 446 %type <statement_> SourceElement_
 447 %type <statement_> SourceElements
 448 %type <statement_> Statement
 449 %type <statement_> Statement_
 450 %type <statement_> StatementList
 451 %type <statement_> StatementListOpt
 452 %type <statement_> SwitchStatement
 453 %type <statement_> ThrowStatement
 454 %type <statement_> TryStatement
 455 %type <expression_> UnaryExpression
 456 %type <expression_> UnaryExpression_
 457 %type <expression_> UnaryExpressionNoBF
 458 %type <declaration_> VariableDeclaration
 459 %type <declaration_> VariableDeclarationNoIn
 460 %type <declarations_> VariableDeclarationList
 461 %type <declarations_> VariableDeclarationList_
 462 %type <declarations_> VariableDeclarationListNoIn
 463 %type <declarations_> VariableDeclarationListNoIn_
 464 %type <statement_> VariableStatement
 465 %type <statement_> WhileStatement
 466 %type <statement_> WithStatement
 467
 468 @begin C
 469 %type <expression_> AssigneeExpressionNoRE
 470 %type <expression_> CallExpressionNoRE
 471 %type <expression_> LeftHandSideExpressionNoRE
 472 %type <expression_> MemberExpressionNoRE
 473 %type <expression_> NewExpressionNoRE
 474 %type <expression_> PostfixExpressionNoRE
 475 %type <expression_> UnaryAssigneeExpression
 476 %type <expression_> UnaryExpressionNoRE
 477 @end
 478
 479 @begin ObjectiveC
 480 %type <statement_> CategoryStatement
 481 %type <expression_> ClassExpression
 482 %type <statement_> ClassStatement
 483 %type <expression_> ClassSuperOpt
 484 %type <field_> ClassFieldList
 485 %type <message_> ClassMessageDeclaration
 486 %type <message_> ClassMessageDeclarationListOpt
 487 %type <className_> ClassName
 488 %type <className_> ClassNameOpt
 489 %type <protocol_> ClassProtocolListOpt
 490 %type <protocol_> ClassProtocols
 491 %type <protocol_> ClassProtocolsOpt
 492 %type <expression_> MessageExpression
 493 %type <messageParameter_> MessageParameter
 494 %type <messageParameter_> MessageParameters
 495 %type <messageParameter_> MessageParameterList
 496 %type <messageParameter_> MessageParameterListOpt
 497 %type <bool_> MessageScope
 498 %type <argument_> SelectorCall
 499 %type <argument_> SelectorCall_
 500 %type <selector_> SelectorExpression
 501 %type <selector_> SelectorExpression_
 502 %type <selector_> SelectorExpressionOpt
 503 %type <argument_> SelectorList
 504 %type <word_> SelectorWordOpt
 505 %type <expression_> TypeOpt
 506 %type <argument_> VariadicCall
 507 %type <word_> Word
 508 %type <word_> WordOpt
 509 @end
 510
 511 @begin E4X
 512 %type <propertyIdentifier_> PropertyIdentifier_
 513 %type <selector_> PropertySelector
 514 %type <selector_> PropertySelector_
 515 %type <identifier_> QualifiedIdentifier
 516 %type <identifier_> QualifiedIdentifier_
 517 %type <identifier_> WildcardIdentifier
 518 %type <identifier_> XMLComment
 519 %type <identifier_> XMLCDATA
 520 %type <identifier_> XMLElement
 521 %type <identifier_> XMLElementContent
 522 %type <identifier_> XMLMarkup
 523 %type <identifier_> XMLPI
 524
 525 %type <attribute_> AttributeIdentifier
 526 /* XXX: %type <statement_> DefaultXMLNamespaceStatement */
 527 %type <expression_> PropertyIdentifier
 528 %type <expression_> XMLListInitialiser
 529 %type <expression_> XMLInitialiser
 530 @end
 531
 532 %nonassoc Identifier_ "abstract" "boolean" "break" "byte" "case" "catch" "char" "class" "const" "continue" "debugger" "default" "delete" "do" "double" "each" "enum" "export" "extends" "false" "final" "finally" "float" /*"for"*/ "function" "goto" "implements" "import" /*"in"*/ /*"instanceof"*/ "int" "interface" "let" "long" "namespace" "native" "new" "null" "package" "private" "protected" "public" "return" "short" "super" "static" "switch" "synchronized" "this" "throw" "throws" "transient" "true" "try" "typeof" "var" "void" "volatile" "while" "with" "xml" "yield"
 533
 534 %nonassoc "if"
 535 %nonassoc "else"
 536
 537 %nonassoc "++" "--"
 538 %nonassoc "(" "["
 539
 540 %left "*" "/" "%"
 541 %left "+" "-"
 542 %left "<<" ">>" ">>>"
 543 %left "<" ">" "<=" ">=" "instanceof" "in"
 544 %left "==" "!=" "===" "!=="
 545 %left "&"
 546 %left "^"
 547 %left "|"
 548 %left "&&"
 549 %left "||"
 550
 551 %right "=" "*=" "/=" "%=" "+=" "-=" "<<=" ">>=" ">>>=" "&=" "^=" "|="
 552
 553 %start Program
 554
 555 %%
 556
 557 /* Lexer State {{{ */
 558 LexSetRegExp
 559     : { driver.SetCondition(CYDriver::RegExpCondition); }
 560     ;
 561 /* }}} */
 562
 563 Brace
 564     : "{"
 565     | "\n{"
 566     ;
 567
 568 StrictSemi
 569     : { driver.Warning(yylloc, "warning, automatic semi-colon insertion required"); }
 570     ;
 571
 572 Terminator_
 573     : ";"
 574     | "\n" StrictSemi
 575     ;
 576
 577 TerminatorOpt
 578     : Terminator_
 579     | error { yyerrok; driver.errors_.pop_back(); } StrictSemi
 580     ;
 581
 582 Terminator
 583     : Terminator_
 584     | error { if (yychar != 0 && yychar != cy::parser::token::CloseBrace && !yylval.newline_) YYABORT; else { yyerrok; driver.errors_.pop_back(); } } StrictSemi
 585     ;
 586
 587 /*CommaOpt
 588     : ","
 589     |
 590     ;*/
 591
 592 @begin ObjectiveC
 593 NewLineOpt
 594     : "\n"
 595     |
 596     ;
 597
 598 WordOpt
 599     : Word { $$ = $1; }
 600     | { $$ = NULL; }
 601     ;
 602
 603 Word
 604     : Identifier { $$ = $1; }
 605     | "break" NewLineOpt { $$ = $1; }
 606     | "case" { $$ = $1; }
 607     | "catch" { $$ = $1; }
 608     | "class" { $$ = $1; }
 609     | "const" { $$ = $1; }
 610     | "continue" NewLineOpt { $$ = $1; }
 611     | "debugger" { $$ = $1; }
 612     | "default" { $$ = $1; }
 613     | "delete" { $$ = $1; }
 614     | "do" { $$ = $1; }
 615     | "else" { $$ = $1; }
 616     | "enum" { $$ = $1; }
 617     | "export" { $$ = $1; }
 618     | "extends" { $$ = $1; }
 619     | "false" { $$ = $1; }
 620     | "finally" { $$ = $1; }
 621     /* XXX: | "for" { $$ = $1; } */
 622     | "function" { $$ = $1; }
 623     | "if" { $$ = $1; }
 624     | "import" { $$ = $1; }
 625     /* XXX: | "in" { $$ = $1; } */
 626     /* XXX: | "instanceof" { $$ = $1; } */
 627     | "new" { $$ = $1; }
 628     | "null" { $$ = $1; }
 629     | "return" NewLineOpt { $$ = $1; }
 630     | "super" { $$ = $1; }
 631     | "switch" { $$ = $1; }
 632     | "this" { $$ = $1; }
 633     | "throw" NewLineOpt { $$ = $1; }
 634     | "true" { $$ = $1; }
 635     | "try" { $$ = $1; }
 636     | "typeof" { $$ = $1; }
 637     | "var" { $$ = $1; }
 638     | "void" { $$ = $1; }
 639     | "while" { $$ = $1; }
 640     | "with" { $$ = $1; }
 641     ;
 642 @end
 643
 644 Identifier
 645     : Identifier_ { $$ = $1; }
 646
 647     | "implements" { $$ = $1; }
 648     | "interface" { $$ = $1; }
 649     | "package" { $$ = $1; }
 650     | "private" { $$ = $1; }
 651     | "protected" { $$ = $1; }
 652     | "public" { $$ = $1; }
 653     | "static" { $$ = $1; }
 654
 655     | "abstract" { $$ = $1; }
 656     | "boolean" { $$ = $1; }
 657     | "byte" { $$ = $1; }
 658     | "char" { $$ = $1; }
 659     | "double" { $$ = $1; }
 660     | "final" { $$ = $1; }
 661     | "float" { $$ = $1; }
 662     | "goto" { $$ = $1; }
 663     | "int" { $$ = $1; }
 664     | "long" { $$ = $1; }
 665     | "native" { $$ = $1; }
 666     | "short" { $$ = $1; }
 667     | "synchronized" { $$ = $1; }
 668     | "throws" { $$ = $1; }
 669     | "transient" { $$ = $1; }
 670     | "volatile" { $$ = $1; }
 671
 672     | "let" { $$ = $1; }
 673     | "yield" { $$ = $1; }
 674
 675     | "each" { $$ = $1; }
 676     ;
 677
 678 IdentifierOpt
 679     : Identifier { $$ = $1; }
 680     | { $$ = NULL; }
 681     ;
 682
 683 LiteralNoRE
 684     : NullLiteral { $$ = $1; }
 685     | BooleanLiteral { $$ = $1; }
 686     | NumericLiteral { $$ = $1; }
 687     | StringLiteral { $$ = $1; }
 688     | "@" StringLiteral { $$ = $2; }
 689     ;
 690
 691 LiteralRE
 692     : RegularExpressionLiteral { $$ = $1; }
 693     ;
 694
 695 Literal
 696     : LiteralNoRE { $$ = $1; }
 697     | LiteralRE { $$ = $1; }
 698     ;
 699
 700 NullLiteral
 701     : "null" { $$ = $1; }
 702     ;
 703
 704 BooleanLiteral
 705     : "true" { $$ = $1; }
 706     | "false" { $$ = $1; }
 707     ;
 708
 709 /* 11.1 Primary Expressions {{{ */
 710 PrimaryExpression
 711     : LexSetRegExp PrimaryExpressionNoRE { $$ = $2; }
 712     ;
 713
 714 PrimaryExpressionNoBF
 715     : PrimaryExpressionNo { $$ = $1; }
 716     ;
 717
 718 PrimaryExpressionNoRE
 719     : PrimaryExpressionBF { $$ = $1; }
 720     | PrimaryExpressionNo { $$ = $1; }
 721     ;
 722
 723 PrimaryExpressionNo
 724     : "this" { $$ = $1; }
 725     | Identifier { $$ = CYNew CYVariable($1); }
 726     | AutoComplete { driver.mode_ = CYDriver::AutoPrimary; YYACCEPT; }
 727     | Literal { $$ = $1; }
 728     | ArrayLiteral { $$ = $1; }
 729     | "(" Expression ")" { $$ = $2; }
 730     ;
 731
 732 PrimaryExpressionBF
 733     : ObjectLiteral { $$ = $1; }
 734     ;
 735 /* }}} */
 736 /* 11.1.4 Array Initialiser {{{ */
 737 ArrayLiteral
 738     : "[" ElementListOpt "]" { $$ = CYNew CYArray($2); }
 739     ;
 740
 741 Element
 742     : AssignmentExpression { $$ = $1; }
 743     ;
 744
 745 ElementOpt
 746     : Element { $$ = $1; }
 747     | LexSetRegExp { $$ = NULL; }
 748     ;
 749
 750 ElementListOpt
 751     : ElementList { $$ = $1; }
 752     | LexSetRegExp { $$ = NULL; }
 753     ;
 754
 755 ElementList
 756     : ElementOpt "," ElementListOpt { $$ = CYNew CYElement($1, $3); }
 757     | Element { $$ = CYNew CYElement($1, NULL); }
 758     ;
 759 /* }}} */
 760 /* 11.1.5 Object Initialiser {{{ */
 761 ObjectLiteral
 762     : OpenBrace PropertyNameAndValueListOpt "}" { $$ = CYNew CYObject($2); }
 763     ;
 764
 765 PropertyNameAndValueList_
 766     : "," PropertyNameAndValueList { $$ = $2; }
 767     | { $$ = NULL; }
 768     ;
 769
 770 PropertyNameAndValueListOpt
 771     : PropertyNameAndValueList { $$ = $1; }
 772     | { $$ = NULL; }
 773     ;
 774
 775 PropertyNameAndValueList
 776     : PropertyName ":" AssignmentExpression PropertyNameAndValueList_ { $$ = CYNew CYProperty($1, $3, $4); }
 777     ;
 778
 779 PropertyName_
 780     : Identifier { $$ = $1; }
 781     | StringLiteral { $$ = $1; }
 782     | NumericLiteral { $$ = $1; }
 783     ;
 784
 785 PropertyName
 786     : LexSetRegExp PropertyName_ { $$ = $2; }
 787     ;
 788 /* }}} */
 789
 790 /* 11.2 Left-Hand-Side Expressions {{{ */
 791 MemberExpression_
 792     : "new" MemberExpression Arguments { $$ = CYNew cy::Syntax::New($2, $3); }
 793     ;
 794
 795 MemberAccess
 796     : "[" Expression "]" { $$ = CYNew CYDirectMember(NULL, $2); }
 797     | "." Identifier { $$ = CYNew CYDirectMember(NULL, CYNew CYString($2)); }
 798     | "." AutoComplete { driver.mode_ = CYDriver::AutoDirect; YYACCEPT; }
 799     ;
 800
 801 MemberExpression
 802     : PrimaryExpression { $$ = $1; }
 803     | LexSetRegExp FunctionExpression { $$ = $2; }
 804     | MemberExpression { driver.context_ = $1; } MemberAccess { $3->SetLeft($1); $$ = $3; }
 805     | LexSetRegExp MemberExpression_ { $$ = $2; }
 806     ;
 807
 808 MemberExpressionNoBF
 809     : PrimaryExpressionNoBF { $$ = $1; }
 810     | MemberExpressionNoBF { driver.context_ = $1; } MemberAccess { $3->SetLeft($1); $$ = $3; }
 811     | MemberExpression_ { $$ = $1; }
 812     ;
 813
 814 @begin C
 815 MemberExpressionNoRE
 816     : PrimaryExpressionNoRE { $$ = $1; }
 817     | FunctionExpression { $$ = $1; }
 818     | MemberExpressionNoRE { driver.context_ = $1; } MemberAccess { $3->SetLeft($1); $$ = $3; }
 819     | MemberExpression_ { $$ = $1; }
 820     ;
 821 @end
 822
 823 NewExpression_
 824     : "new" NewExpression { $$ = CYNew cy::Syntax::New($2, NULL); }
 825     ;
 826
 827 NewExpression
 828     : MemberExpression { $$ = $1; }
 829     | LexSetRegExp NewExpression_ { $$ = $2; }
 830     ;
 831
 832 NewExpressionNoBF
 833     : MemberExpressionNoBF { $$ = $1; }
 834     | NewExpression_ { $$ = $1; }
 835     ;
 836
 837 @begin C
 838 NewExpressionNoRE
 839     : MemberExpressionNoRE { $$ = $1; }
 840     | NewExpression_ { $$ = $1; }
 841     ;
 842 @end
 843
 844 CallExpression
 845     : MemberExpression Arguments { $$ = CYNew CYCall($1, $2); }
 846     | CallExpression Arguments { $$ = CYNew CYCall($1, $2); }
 847     | CallExpression { driver.context_ = $1; } MemberAccess { $3->SetLeft($1); $$ = $3; }
 848     ;
 849
 850 CallExpressionNoBF
 851     : MemberExpressionNoBF Arguments { $$ = CYNew CYCall($1, $2); }
 852     | CallExpressionNoBF Arguments { $$ = CYNew CYCall($1, $2); }
 853     | CallExpressionNoBF { driver.context_ = $1; } MemberAccess { $3->SetLeft($1); $$ = $3; }
 854     ;
 855
 856 @begin C
 857 CallExpressionNoRE
 858     : MemberExpressionNoRE Arguments { $$ = CYNew CYCall($1, $2); }
 859     | CallExpressionNoRE Arguments { $$ = CYNew CYCall($1, $2); }
 860     | CallExpressionNoRE { driver.context_ = $1; } MemberAccess { $3->SetLeft($1); $$ = $3; }
 861     ;
 862 @end
 863
 864 ArgumentList_
 865     : "," ArgumentList { $$ = $2; }
 866     | { $$ = NULL; }
 867     ;
 868
 869 ArgumentListOpt
 870     : ArgumentList { $$ = $1; }
 871     | LexSetRegExp { $$ = NULL; }
 872     ;
 873
 874 ArgumentList
 875     : AssignmentExpression ArgumentList_ { $$ = CYNew CYArgument(NULL, $1, $2); }
 876     ;
 877
 878 Arguments
 879     : "(" ArgumentListOpt ")" { $$ = $2; }
 880     ;
 881
 882 LeftHandSideExpression
 883     : NewExpression { $$ = $1; }
 884     | CallExpression { $$ = $1; }
 885     ;
 886
 887 LeftHandSideExpressionNoBF
 888     : NewExpressionNoBF { $$ = $1; }
 889     | CallExpressionNoBF { $$ = $1; }
 890     ;
 891
 892 @begin C
 893 LeftHandSideExpressionNoRE
 894     : NewExpressionNoRE { $$ = $1; }
 895     | CallExpressionNoRE { $$ = $1; }
 896     ;
 897 @end
 898 /* }}} */
 899 /* 11.3 Postfix Expressions {{{ */
 900 PostfixExpression
 901     : AssigneeExpression { $$ = $1; }
 902     | LeftHandSideExpression "++" { $$ = CYNew CYPostIncrement($1); }
 903     | LeftHandSideExpression "--" { $$ = CYNew CYPostDecrement($1); }
 904     ;
 905
 906 PostfixExpressionNoBF
 907     : AssigneeExpressionNoBF { $$ = $1; }
 908     | LeftHandSideExpressionNoBF "++" { $$ = CYNew CYPostIncrement($1); }
 909     | LeftHandSideExpressionNoBF "--" { $$ = CYNew CYPostDecrement($1); }
 910     ;
 911
 912 @begin C
 913 PostfixExpressionNoRE
 914     : AssigneeExpressionNoRE { $$ = $1; }
 915     | LeftHandSideExpressionNoRE "++" { $$ = CYNew CYPostIncrement($1); }
 916     | LeftHandSideExpressionNoRE "--" { $$ = CYNew CYPostDecrement($1); }
 917     ;
 918 @end
 919 /* }}} */
 920 /* 11.4 Unary Operators {{{ */
 921 UnaryExpression_
 922     : "delete" UnaryExpression { $$ = CYNew CYDelete($2); }
 923     | "void" UnaryExpression { $$ = CYNew CYVoid($2); }
 924     | "typeof" UnaryExpression { $$ = CYNew CYTypeOf($2); }
 925     | "++" UnaryExpression { $$ = CYNew CYPreIncrement($2); }
 926     | "\n++" UnaryExpression { $$ = CYNew CYPreIncrement($2); }
 927     | "--" UnaryExpression { $$ = CYNew CYPreDecrement($2); }
 928     | "\n--" UnaryExpression { $$ = CYNew CYPreDecrement($2); }
 929     | "+" UnaryExpression { $$ = CYNew CYAffirm($2); }
 930     | "-" UnaryExpression { $$ = CYNew CYNegate($2); }
 931     | "~" UnaryExpression { $$ = CYNew CYBitwiseNot($2); }
 932     | "!" UnaryExpression { $$ = CYNew CYLogicalNot($2); }
 933     ;
 934
 935 UnaryExpression
 936     : PostfixExpression { $$ = $1; }
 937     | LexSetRegExp UnaryExpression_ { $$ = $2; }
 938     ;
 939
 940 UnaryExpressionNoBF
 941     : PostfixExpressionNoBF { $$ = $1; }
 942     | UnaryExpression_ { $$ = $1; }
 943     ;
 944
 945 @begin C
 946 UnaryExpressionNoRE
 947     : PostfixExpressionNoRE { $$ = $1; }
 948     | UnaryExpression_ { $$ = $1; }
 949     ;
 950 @end
 951 /* }}} */
 952 /* 11.5 Multiplicative Operators {{{ */
 953 MultiplicativeExpression
 954     : UnaryExpression { $$ = $1; }
 955     | MultiplicativeExpression "*" UnaryExpression { $$ = CYNew CYMultiply($1, $3); }
 956     | MultiplicativeExpression "/" UnaryExpression { $$ = CYNew CYDivide($1, $3); }
 957     | MultiplicativeExpression "%" UnaryExpression { $$ = CYNew CYModulus($1, $3); }
 958     ;
 959
 960 MultiplicativeExpressionNoBF
 961     : UnaryExpressionNoBF { $$ = $1; }
 962     | MultiplicativeExpressionNoBF "*" UnaryExpression { $$ = CYNew CYMultiply($1, $3); }
 963     | MultiplicativeExpressionNoBF "/" UnaryExpression { $$ = CYNew CYDivide($1, $3); }
 964     | MultiplicativeExpressionNoBF "%" UnaryExpression { $$ = CYNew CYModulus($1, $3); }
 965     ;
 966 /* }}} */
 967 /* 11.6 Additive Operators {{{ */
 968 AdditiveExpression
 969     : MultiplicativeExpression { $$ = $1; }
 970     | AdditiveExpression "+" MultiplicativeExpression { $$ = CYNew CYAdd($1, $3); }
 971     | AdditiveExpression "-" MultiplicativeExpression { $$ = CYNew CYSubtract($1, $3); }
 972     ;
 973
 974 AdditiveExpressionNoBF
 975     : MultiplicativeExpressionNoBF { $$ = $1; }
 976     | AdditiveExpressionNoBF "+" MultiplicativeExpression { $$ = CYNew CYAdd($1, $3); }
 977     | AdditiveExpressionNoBF "-" MultiplicativeExpression { $$ = CYNew CYSubtract($1, $3); }
 978     ;
 979 /* }}} */
 980 /* 11.7 Bitwise Shift Operators {{{ */
 981 ShiftExpression
 982     : AdditiveExpression { $$ = $1; }
 983     | ShiftExpression "<<" AdditiveExpression { $$ = CYNew CYShiftLeft($1, $3); }
 984     | ShiftExpression ">>" AdditiveExpression { $$ = CYNew CYShiftRightSigned($1, $3); }
 985     | ShiftExpression ">>>" AdditiveExpression { $$ = CYNew CYShiftRightUnsigned($1, $3); }
 986     ;
 987
 988 ShiftExpressionNoBF
 989     : AdditiveExpressionNoBF { $$ = $1; }
 990     | ShiftExpressionNoBF "<<" AdditiveExpression { $$ = CYNew CYShiftLeft($1, $3); }
 991     | ShiftExpressionNoBF ">>" AdditiveExpression { $$ = CYNew CYShiftRightSigned($1, $3); }
 992     | ShiftExpressionNoBF ">>>" AdditiveExpression { $$ = CYNew CYShiftRightUnsigned($1, $3); }
 993     ;
 994 /* }}} */
 995 /* 11.8 Relational Operators {{{ */
 996 RelationalExpressionNoIn_
 997     : "<" ShiftExpression { $$ = CYNew CYLess(NULL, $2); }
 998     | ">" ShiftExpression { $$ = CYNew CYGreater(NULL, $2); }
 999     | "<=" ShiftExpression { $$ = CYNew CYLessOrEqual(NULL, $2); }
1000     | ">=" ShiftExpression { $$ = CYNew CYGreaterOrEqual(NULL, $2); }
1001     | "instanceof" ShiftExpression { $$ = CYNew CYInstanceOf(NULL, $2); }
1002     ;
1003
1004 RelationalExpression_
1005     : RelationalExpressionNoIn_ { $$ = $1; }
1006     | "in" ShiftExpression { $$ = CYNew CYIn(NULL, $2); }
1007     ;
1008
1009 RelationalExpression
1010     : ShiftExpression { $$ = $1; }
1011     | RelationalExpression RelationalExpression_ { $2->SetLeft($1); $$ = $2; }
1012     ;
1013
1014 RelationalExpressionNoIn
1015     : ShiftExpression { $$ = $1; }
1016     | RelationalExpressionNoIn RelationalExpressionNoIn_ { $2->SetLeft($1); $$ = $2; }
1017     ;
1018
1019 RelationalExpressionNoBF
1020     : ShiftExpressionNoBF { $$ = $1; }
1021     | RelationalExpressionNoBF RelationalExpression_ { $2->SetLeft($1); $$ = $2; }
1022     ;
1023 /* }}} */
1024 /* 11.9 Equality Operators {{{ */
1025 EqualityExpression
1026     : RelationalExpression { $$ = $1; }
1027     | EqualityExpression "==" RelationalExpression { $$ = CYNew CYEqual($1, $3); }
1028     | EqualityExpression "!=" RelationalExpression { $$ = CYNew CYNotEqual($1, $3); }
1029     | EqualityExpression "===" RelationalExpression { $$ = CYNew CYIdentical($1, $3); }
1030     | EqualityExpression "!==" RelationalExpression { $$ = CYNew CYNotIdentical($1, $3); }
1031     ;
1032
1033 EqualityExpressionNoIn
1034     : RelationalExpressionNoIn { $$ = $1; }
1035     | EqualityExpressionNoIn "==" RelationalExpressionNoIn { $$ = CYNew CYEqual($1, $3); }
1036     | EqualityExpressionNoIn "!=" RelationalExpressionNoIn { $$ = CYNew CYNotEqual($1, $3); }
1037     | EqualityExpressionNoIn "===" RelationalExpressionNoIn { $$ = CYNew CYIdentical($1, $3); }
1038     | EqualityExpressionNoIn "!==" RelationalExpressionNoIn { $$ = CYNew CYNotIdentical($1, $3); }
1039     ;
1040
1041 EqualityExpressionNoBF
1042     : RelationalExpressionNoBF { $$ = $1; }
1043     | EqualityExpressionNoBF "==" RelationalExpression { $$ = CYNew CYEqual($1, $3); }
1044     | EqualityExpressionNoBF "!=" RelationalExpression { $$ = CYNew CYNotEqual($1, $3); }
1045     | EqualityExpressionNoBF "===" RelationalExpression { $$ = CYNew CYIdentical($1, $3); }
1046     | EqualityExpressionNoBF "!==" RelationalExpression { $$ = CYNew CYNotIdentical($1, $3); }
1047     ;
1048 /* }}} */
1049 /* 11.10 Binary Bitwise Operators {{{ */
1050 BitwiseANDExpression
1051     : EqualityExpression { $$ = $1; }
1052     | BitwiseANDExpression "&" EqualityExpression { $$ = CYNew CYBitwiseAnd($1, $3); }
1053     ;
1054
1055 BitwiseANDExpressionNoIn
1056     : EqualityExpressionNoIn { $$ = $1; }
1057     | BitwiseANDExpressionNoIn "&" EqualityExpressionNoIn { $$ = CYNew CYBitwiseAnd($1, $3); }
1058     ;
1059
1060 BitwiseANDExpressionNoBF
1061     : EqualityExpressionNoBF { $$ = $1; }
1062     | BitwiseANDExpressionNoBF "&" EqualityExpression { $$ = CYNew CYBitwiseAnd($1, $3); }
1063     ;
1064
1065 BitwiseXORExpression
1066     : BitwiseANDExpression { $$ = $1; }
1067     | BitwiseXORExpression "^" BitwiseANDExpression { $$ = CYNew CYBitwiseXOr($1, $3); }
1068     ;
1069
1070 BitwiseXORExpressionNoIn
1071     : BitwiseANDExpressionNoIn { $$ = $1; }
1072     | BitwiseXORExpressionNoIn "^" BitwiseANDExpressionNoIn { $$ = CYNew CYBitwiseXOr($1, $3); }
1073     ;
1074
1075 BitwiseXORExpressionNoBF
1076     : BitwiseANDExpressionNoBF { $$ = $1; }
1077     | BitwiseXORExpressionNoBF "^" BitwiseANDExpression { $$ = CYNew CYBitwiseXOr($1, $3); }
1078     ;
1079
1080 BitwiseORExpression
1081     : BitwiseXORExpression { $$ = $1; }
1082     | BitwiseORExpression "|" BitwiseXORExpression { $$ = CYNew CYBitwiseOr($1, $3); }
1083     ;
1084
1085 BitwiseORExpressionNoIn
1086     : BitwiseXORExpressionNoIn { $$ = $1; }
1087     | BitwiseORExpressionNoIn "|" BitwiseXORExpressionNoIn { $$ = CYNew CYBitwiseOr($1, $3); }
1088     ;
1089
1090 BitwiseORExpressionNoBF
1091     : BitwiseXORExpressionNoBF { $$ = $1; }
1092     | BitwiseORExpressionNoBF "|" BitwiseXORExpression { $$ = CYNew CYBitwiseOr($1, $3); }
1093     ;
1094 /* }}} */
1095 /* 11.11 Binary Logical Operators {{{ */
1096 LogicalANDExpression
1097     : BitwiseORExpression { $$ = $1; }
1098     | LogicalANDExpression "&&" BitwiseORExpression { $$ = CYNew CYLogicalAnd($1, $3); }
1099     ;
1100
1101 LogicalANDExpressionNoIn
1102     : BitwiseORExpressionNoIn { $$ = $1; }
1103     | LogicalANDExpressionNoIn "&&" BitwiseORExpressionNoIn { $$ = CYNew CYLogicalAnd($1, $3); }
1104     ;
1105
1106 LogicalANDExpressionNoBF
1107     : BitwiseORExpressionNoBF { $$ = $1; }
1108     | LogicalANDExpressionNoBF "&&" BitwiseORExpression { $$ = CYNew CYLogicalAnd($1, $3); }
1109     ;
1110
1111 LogicalORExpression
1112     : LogicalANDExpression { $$ = $1; }
1113     | LogicalORExpression "||" LogicalANDExpression { $$ = CYNew CYLogicalOr($1, $3); }
1114     ;
1115
1116 LogicalORExpressionNoIn
1117     : LogicalANDExpressionNoIn { $$ = $1; }
1118     | LogicalORExpressionNoIn "||" LogicalANDExpressionNoIn { $$ = CYNew CYLogicalOr($1, $3); }
1119     ;
1120
1121 LogicalORExpressionNoBF
1122     : LogicalANDExpressionNoBF { $$ = $1; }
1123     | LogicalORExpressionNoBF "||" LogicalANDExpression { $$ = CYNew CYLogicalOr($1, $3); }
1124     ;
1125 /* }}} */
1126 /* 11.12 Conditional Operator ( ? : ) {{{ */
1127 ConditionalExpression
1128     : LogicalORExpression { $$ = $1; }
1129     | LogicalORExpression "?" AssignmentExpression ":" AssignmentExpression { $$ = CYNew CYCondition($1, $3, $5); }
1130     ;
1131
1132 ConditionalExpressionNoIn
1133     : LogicalORExpressionNoIn { $$ = $1; }
1134     | LogicalORExpressionNoIn "?" AssignmentExpression ":" AssignmentExpressionNoIn { $$ = CYNew CYCondition($1, $3, $5); }
1135     ;
1136
1137 ConditionalExpressionNoBF
1138     : LogicalORExpressionNoBF { $$ = $1; }
1139     | LogicalORExpressionNoBF "?" AssignmentExpression ":" AssignmentExpression { $$ = CYNew CYCondition($1, $3, $5); }
1140     ;
1141 /* }}} */
1142 /* 11.13 Assignment Operators {{{ */
1143 AssignmentExpression_
1144     : "=" AssignmentExpression { $$ = CYNew CYAssign(NULL, $2); }
1145     | "*=" AssignmentExpression { $$ = CYNew CYMultiplyAssign(NULL, $2); }
1146     | "/=" AssignmentExpression { $$ = CYNew CYDivideAssign(NULL, $2); }
1147     | "%=" AssignmentExpression { $$ = CYNew CYModulusAssign(NULL, $2); }
1148     | "+=" AssignmentExpression { $$ = CYNew CYAddAssign(NULL, $2); }
1149     | "-=" AssignmentExpression { $$ = CYNew CYSubtractAssign(NULL, $2); }
1150     | "<<=" AssignmentExpression { $$ = CYNew CYShiftLeftAssign(NULL, $2); }
1151     | ">>=" AssignmentExpression { $$ = CYNew CYShiftRightSignedAssign(NULL, $2); }
1152     | ">>>=" AssignmentExpression { $$ = CYNew CYShiftRightUnsignedAssign(NULL, $2); }
1153     | "&=" AssignmentExpression { $$ = CYNew CYBitwiseAndAssign(NULL, $2); }
1154     | "^=" AssignmentExpression { $$ = CYNew CYBitwiseXOrAssign(NULL, $2); }
1155     | "|=" AssignmentExpression { $$ = CYNew CYBitwiseOrAssign(NULL, $2); }
1156     ;
1157
1158 AssigneeExpression
1159     : LeftHandSideExpression { $$ = $1; }
1160 @begin C
1161     | LexSetRegExp UnaryAssigneeExpression { $$ = $2; }
1162 @end
1163     ;
1164
1165 AssigneeExpressionNoBF
1166     : LeftHandSideExpressionNoBF { $$ = $1; }
1167 @begin C
1168     | UnaryAssigneeExpression { $$ = $1; }
1169 @end
1170     ;
1171
1172 @begin C
1173 AssigneeExpressionNoRE
1174     : LeftHandSideExpressionNoRE { $$ = $1; }
1175     | UnaryAssigneeExpression { $$ = $1; }
1176     ;
1177 @end
1178
1179 AssignmentExpression
1180     : ConditionalExpression { $$ = $1; }
1181     | AssigneeExpression AssignmentExpression_ { $2->SetLeft($1); $$ = $2; }
1182     ;
1183
1184 AssignmentExpressionNoIn
1185     : ConditionalExpressionNoIn { $$ = $1; }
1186     | AssigneeExpression "=" AssignmentExpressionNoIn { $$ = CYNew CYAssign($1, $3); }
1187     | AssigneeExpression "*=" AssignmentExpressionNoIn { $$ = CYNew CYMultiplyAssign($1, $3); }
1188     | AssigneeExpression "/=" AssignmentExpressionNoIn { $$ = CYNew CYDivideAssign($1, $3); }
1189     | AssigneeExpression "%=" AssignmentExpressionNoIn { $$ = CYNew CYModulusAssign($1, $3); }
1190     | AssigneeExpression "+=" AssignmentExpressionNoIn { $$ = CYNew CYAddAssign($1, $3); }
1191     | AssigneeExpression "-=" AssignmentExpressionNoIn { $$ = CYNew CYSubtractAssign($1, $3); }
1192     | AssigneeExpression "<<=" AssignmentExpressionNoIn { $$ = CYNew CYShiftLeftAssign($1, $3); }
1193     | AssigneeExpression ">>=" AssignmentExpressionNoIn { $$ = CYNew CYShiftRightSignedAssign($1, $3); }
1194     | AssigneeExpression ">>>=" AssignmentExpressionNoIn { $$ = CYNew CYShiftRightUnsignedAssign($1, $3); }
1195     | AssigneeExpression "&=" AssignmentExpressionNoIn { $$ = CYNew CYBitwiseAndAssign($1, $3); }
1196     | AssigneeExpression "^=" AssignmentExpressionNoIn { $$ = CYNew CYBitwiseXOrAssign($1, $3); }
1197     | AssigneeExpression "|=" AssignmentExpressionNoIn { $$ = CYNew CYBitwiseOrAssign($1, $3); }
1198     ;
1199
1200 AssignmentExpressionNoBF
1201     : ConditionalExpressionNoBF { $$ = $1; }
1202     | AssigneeExpressionNoBF AssignmentExpression_ { $2->SetLeft($1); $$ = $2; }
1203     ;
1204 /* }}} */
1205 /* 11.14 Comma Operator {{{ */
1206 Expression_
1207     : "," Expression { $$ = CYNew CYCompound($2); }
1208     | { $$ = NULL; }
1209     ;
1210
1211 ExpressionNoIn_
1212     : "," ExpressionNoIn { $$ = CYNew CYCompound($2); }
1213     | { $$ = NULL; }
1214     ;
1215
1216 ExpressionOpt
1217     : Expression { $$ = $1; }
1218     | LexSetRegExp { $$ = NULL; }
1219     ;
1220
1221 ExpressionNoInOpt
1222     : ExpressionNoIn { $$ = $1; }
1223     | LexSetRegExp { $$ = NULL; }
1224     ;
1225
1226 Expression
1227     : AssignmentExpression Expression_ { if ($2) { $2->AddPrev($1); $$ = $2; } else $$ = $1; }
1228     ;
1229
1230 ExpressionNoIn
1231     : AssignmentExpressionNoIn ExpressionNoIn_ { if ($2) { $2->AddPrev($1); $$ = $2; } else $$ = $1; }
1232     ;
1233
1234 ExpressionNoBF
1235     : AssignmentExpressionNoBF Expression_ { if ($2) { $2->AddPrev($1); $$ = $2; } else $$ = $1; }
1236     ;
1237 /* }}} */
1238
1239 /* 12 Statements {{{ */
1240 Statement_
1241     : Block { $$ = $1; }
1242     | VariableStatement { $$ = $1; }
1243     | EmptyStatement { $$ = $1; }
1244     | ExpressionStatement { $$ = $1; }
1245     | IfStatement { $$ = $1; }
1246     | IterationStatement { $$ = $1; }
1247     | ContinueStatement { $$ = $1; }
1248     | BreakStatement { $$ = $1; }
1249     | ReturnStatement { $$ = $1; }
1250     | WithStatement { $$ = $1; }
1251     | LabelledStatement { $$ = $1; }
1252     | SwitchStatement { $$ = $1; }
1253     | ThrowStatement { $$ = $1; }
1254     | TryStatement { $$ = $1; }
1255     ;
1256
1257 Statement
1258     : LexSetRegExp Statement_ { $$ = $2; }
1259     ;
1260 /* }}} */
1261 /* 12.1 Block {{{ */
1262 Block_
1263     : Brace StatementListOpt "}" { $$ = $2; }
1264     ;
1265
1266 Block
1267     : Block_ { if ($1) $$ = CYNew CYBlock($1); else $$ = CYNew CYEmpty(); }
1268     ;
1269
1270 StatementList
1271     : Statement StatementListOpt { $1->SetNext($2); $$ = $1; }
1272     ;
1273
1274 StatementListOpt
1275     : StatementList { $$ = $1; }
1276     | LexSetRegExp { $$ = NULL; }
1277     ;
1278 /* }}} */
1279 /* 12.2 Variable Statement {{{ */
1280 VariableStatement
1281     : "var" VariableDeclarationList Terminator { $$ = CYNew CYVar($2); }
1282     ;
1283
1284 VariableDeclarationList_
1285     : "," VariableDeclarationList { $$ = $2; }
1286     | { $$ = NULL; }
1287     ;
1288
1289 VariableDeclarationListNoIn_
1290     : "," VariableDeclarationListNoIn { $$ = $2; }
1291     | { $$ = NULL; }
1292     ;
1293
1294 VariableDeclarationList
1295     : VariableDeclaration VariableDeclarationList_ { $$ = CYNew CYDeclarations($1, $2); }
1296     ;
1297
1298 VariableDeclarationListNoIn
1299     : VariableDeclarationNoIn VariableDeclarationListNoIn_ { $$ = CYNew CYDeclarations($1, $2); }
1300     ;
1301
1302 VariableDeclaration
1303     : Identifier InitialiserOpt { $$ = CYNew CYDeclaration($1, $2); }
1304     ;
1305
1306 VariableDeclarationNoIn
1307     : Identifier InitialiserNoInOpt { $$ = CYNew CYDeclaration($1, $2); }
1308     ;
1309
1310 InitialiserOpt
1311     : Initialiser { $$ = $1; }
1312     | { $$ = NULL; }
1313     ;
1314
1315 InitialiserNoInOpt
1316     : InitialiserNoIn { $$ = $1; }
1317     | { $$ = NULL; }
1318     ;
1319
1320 Initialiser
1321     : "=" AssignmentExpression { $$ = $2; }
1322     ;
1323
1324 InitialiserNoIn
1325     : "=" AssignmentExpressionNoIn { $$ = $2; }
1326     ;
1327 /* }}} */
1328 /* 12.3 Empty Statement {{{ */
1329 EmptyStatement
1330     : ";" { $$ = CYNew CYEmpty(); }
1331     ;
1332 /* }}} */
1333 /* 12.4 Expression Statement {{{ */
1334 ExpressionStatement
1335     : ExpressionNoBF Terminator { $$ = CYNew CYExpress($1); }
1336     ;
1337 /* }}} */
1338 /* 12.5 The if Statement {{{ */
1339 ElseStatementOpt
1340     : "else" Statement { $$ = $2; }
1341     | %prec "if" { $$ = NULL; }
1342     ;
1343
1344 IfStatement
1345     : "if" "(" Expression ")" Statement ElseStatementOpt { $$ = CYNew CYIf($3, $5, $6); }
1346     ;
1347 /* }}} */
1348
1349 /* 12.6 Iteration Statements {{{ */
1350 IterationStatement
1351     : DoWhileStatement { $$ = $1; }
1352     | WhileStatement { $$ = $1; }
1353     | ForStatement { $$ = $1; }
1354     | ForInStatement { $$ = $1; }
1355     ;
1356 /* }}} */
1357 /* 12.6.1 The do-while Statement {{{ */
1358 DoWhileStatement
1359     : "do" Statement "while" "(" Expression ")" TerminatorOpt { $$ = CYNew CYDoWhile($5, $2); }
1360     ;
1361 /* }}} */
1362 /* 12.6.2 The while Statement {{{ */
1363 WhileStatement
1364     : "while" "(" Expression ")" Statement { $$ = CYNew CYWhile($3, $5); }
1365     ;
1366 /* }}} */
1367 /* 12.6.3 The for Statement {{{ */
1368 ForStatement
1369     : "for" "(" ForStatementInitialiser ";" ExpressionOpt ";" ExpressionOpt ")" Statement { $$ = CYNew CYFor($3, $5, $7, $9); }
1370     ;
1371
1372 ForStatementInitialiser
1373     : ExpressionNoInOpt { $$ = $1; }
1374     | LexSetRegExp "var" VariableDeclarationListNoIn { $$ = $3; }
1375     ;
1376 /* }}} */
1377 /* 12.6.4 The for-in Statement {{{ */
1378 ForInStatement
1379     : "for" "(" ForInStatementInitialiser "in" Expression ")" Statement { $$ = CYNew CYForIn($3, $5, $7); }
1380     ;
1381
1382 ForInStatementInitialiser
1383     : LeftHandSideExpression { $$ = $1; }
1384     | LexSetRegExp "var" VariableDeclarationNoIn { $$ = $3; }
1385     ;
1386 /* }}} */
1387
1388 /* 12.7 The continue Statement {{{ */
1389 ContinueStatement
1390     : "continue" IdentifierOpt Terminator { $$ = CYNew CYContinue($2); }
1391     ;
1392 /* }}} */
1393 /* 12.8 The break Statement {{{ */
1394 BreakStatement
1395     : "break" IdentifierOpt Terminator { $$ = CYNew CYBreak($2); }
1396     ;
1397 /* }}} */
1398 /* 12.9 The return Statement {{{ */
1399 ReturnStatement
1400     : "return" ExpressionOpt Terminator { $$ = CYNew CYReturn($2); }
1401     ;
1402 /* }}} */
1403 /* 12.10 The with Statement {{{ */
1404 WithStatement
1405     : "with" "(" Expression ")" Statement { $$ = CYNew CYWith($3, $5); }
1406     ;
1407 /* }}} */
1408
1409 /* 12.11 The switch Statement {{{ */
1410 SwitchStatement
1411     : "switch" "(" Expression ")" CaseBlock { $$ = CYNew CYSwitch($3, $5); }
1412     ;
1413
1414 CaseBlock
1415     : Brace CaseClausesOpt "}" { $$ = $2; }
1416     ;
1417
1418 CaseClausesOpt
1419     : CaseClause CaseClausesOpt { $1->SetNext($2); $$ = $1; }
1420     | DefaultClause CaseClausesOpt { $1->SetNext($2); $$ = $1; }
1421     | { $$ = NULL; }
1422     ;
1423
1424 CaseClause
1425     : "case" Expression ":" StatementListOpt { $$ = CYNew CYClause($2, $4); }
1426     ;
1427
1428 DefaultClause
1429     : "default" ":" StatementListOpt { $$ = CYNew CYClause(NULL, $3); }
1430     ;
1431 /* }}} */
1432 /* 12.12 Labelled Statements {{{ */
1433 LabelledStatement
1434     : Identifier ":" Statement { $$ = CYNew CYLabel($1, $3); }
1435     ;
1436 /* }}} */
1437 /* 12.13 The throw Statement {{{ */
1438 ThrowStatement
1439     : "throw" Expression Terminator { $$ = CYNew cy::Syntax::Throw($2); }
1440     ;
1441 /* }}} */
1442 /* 12.14 The try Statement {{{ */
1443 TryStatement
1444     : "try" Block_ CatchOpt FinallyOpt { $$ = CYNew cy::Syntax::Try($2, $3, $4); }
1445     ;
1446
1447 CatchOpt
1448     : "catch" "(" Identifier ")" Block_ { $$ = CYNew cy::Syntax::Catch($3, $5); }
1449     | { $$ = NULL; }
1450     ;
1451
1452 FinallyOpt
1453     : "finally" Block_ { $$ = CYNew CYFinally($2); }
1454     | { $$ = NULL; }
1455     ;
1456 /* }}} */
1457
1458 /* 13 Function Definition {{{ */
1459 FunctionDeclaration
1460     : "function" Identifier "(" FormalParameterList ")" Brace FunctionBody "}" { $$ = CYNew CYFunctionStatement($2, $4, $7); }
1461     ;
1462
1463 FunctionExpression
1464     : "function" IdentifierOpt "(" FormalParameterList ")" Brace FunctionBody "}" { $$ = CYNew CYFunctionExpression($2, $4, $7); }
1465     ;
1466
1467 FormalParameterList_
1468     : "," FormalParameterList { $$ = $2; }
1469     | { $$ = NULL; }
1470     ;
1471
1472 FormalParameterList
1473     : Identifier FormalParameterList_ { $$ = CYNew CYFunctionParameter($1, $2); }
1474     | { $$ = NULL; }
1475     ;
1476
1477 FunctionBody
1478     : SourceElements { $$ = $1; }
1479     ;
1480 /* }}} */
1481 /* 14 Program {{{ */
1482 Program
1483     : SourceElements { driver.program_ = CYNew CYProgram($1); }
1484     ;
1485
1486 SourceElements
1487     : SourceElement SourceElements { $1->SetNext($2); $$ = $1; }
1488     | LexSetRegExp { $$ = NULL; }
1489     ;
1490
1491 SourceElement_
1492     : Statement_ { $$ = $1; }
1493     | FunctionDeclaration { $$ = $1; }
1494     ;
1495
1496 SourceElement
1497     : LexSetRegExp SourceElement_ { $$ = $2; }
1498     ;
1499 /* }}} */
1500
1501 @begin ObjectiveC
1502 /* Cycript (Objective-C): @class Declaration {{{ */
1503 ClassSuperOpt
1504     /* XXX: why the hell did I choose MemberExpressionNoBF? */
1505     : ":" LexSetRegExp MemberExpressionNoBF { $$ = $3; }
1506     | { $$ = NULL; }
1507     ;
1508
1509 ClassField
1510     : Expression Identifier ";"
1511     ;
1512
1513 ClassFieldListOpt
1514     : ClassFieldListOpt ClassField
1515     |
1516     ;
1517
1518 ClassFieldList
1519     : Brace ClassFieldListOpt "}" { $$ = NULL; }
1520     ;
1521
1522 MessageScope
1523     : "+" { $$ = false; }
1524     | "-" { $$ = true; }
1525     ;
1526
1527 TypeOpt
1528     : "(" Expression ")" { $$ = $2; }
1529     | "(" LexSetRegExp "void" ")" { $$ = NULL; }
1530     | { $$ = NULL; }
1531     ;
1532
1533 MessageParameter
1534     : Word ":" TypeOpt Identifier { $$ = CYNew CYMessageParameter($1, $3, $4); }
1535     ;
1536
1537 MessageParameterListOpt
1538     : MessageParameterList { $$ = $1; }
1539     | { $$ = NULL; }
1540     ;
1541
1542 MessageParameterList
1543     : MessageParameter MessageParameterListOpt { $1->SetNext($2); $$ = $1; }
1544     ;
1545
1546 MessageParameters
1547     : MessageParameterList { $$ = $1; }
1548     | Word { $$ = CYNew CYMessageParameter($1, NULL, NULL); }
1549     ;
1550
1551 ClassMessageDeclaration
1552     : MessageScope TypeOpt MessageParameters Brace FunctionBody "}" { $$ = CYNew CYMessage($1, $2, $3, $5); }
1553     ;
1554
1555 ClassMessageDeclarationListOpt
1556     : ClassMessageDeclarationListOpt ClassMessageDeclaration { $2->SetNext($1); $$ = $2; }
1557     | ClassMessageDeclarationListOpt Comment { $$ = $1; }
1558     | { $$ = NULL; }
1559     ;
1560
1561 ClassName
1562     : Identifier { $$ = $1; }
1563     | "(" AssignmentExpression ")" { $$ = $2; }
1564     ;
1565
1566 ClassNameOpt
1567     : ClassName { $$ = $1; }
1568     | { $$ = NULL; }
1569     ;
1570
1571 // XXX: this should be AssignmentExpressionNoRight
1572 ClassProtocols
1573     : ShiftExpression ClassProtocolsOpt { $$ = CYNew CYProtocol($1, $2); }
1574     ;
1575
1576 ClassProtocolsOpt
1577     : "," ClassProtocols { $$ = $2; }
1578     | { $$ = NULL; }
1579     ;
1580
1581 ClassProtocolListOpt
1582     : "<" ClassProtocols ">" { $$ = $2; }
1583     | { $$ = NULL; }
1584     ;
1585
1586 ClassExpression
1587     : "@implementation" ClassNameOpt ClassSuperOpt ClassProtocolListOpt ClassFieldList ClassMessageDeclarationListOpt "@end" { $$ = CYNew CYClassExpression($2, $3, $4, $5, $6); }
1588     ;
1589
1590 ClassStatement
1591     : "@implementation" ClassName ClassSuperOpt ClassProtocolListOpt ClassFieldList ClassMessageDeclarationListOpt "@end" { $$ = CYNew CYClassStatement($2, $3, $4, $5, $6); }
1592     ;
1593
1594 CategoryName
1595     : "(" Word ")"
1596     ;
1597
1598 CategoryStatement
1599     : "@implementation" ClassName CategoryName ClassMessageDeclarationListOpt "@end" { $$ = CYNew CYCategory($2, $4); }
1600     ;
1601
1602 PrimaryExpressionBF
1603     : ClassExpression { $$ = $1; }
1604     ;
1605
1606 Statement_
1607     : ClassStatement { $$ = $1; }
1608     | CategoryStatement { $$ = $1; }
1609     ;
1610 /* }}} */
1611 /* Cycript (Objective-C): Send Message {{{ */
1612 VariadicCall
1613     : "," AssignmentExpression VariadicCall { $$ = CYNew CYArgument(NULL, $2, $3); }
1614     | { $$ = NULL; }
1615     ;
1616
1617 SelectorCall_
1618     : SelectorCall { $$ = $1; }
1619     | VariadicCall { $$ = $1; }
1620     ;
1621
1622 SelectorWordOpt
1623     : WordOpt { driver.contexts_.back().words_.push_back($1); } { $$ = $1; }
1624     | AutoComplete { driver.mode_ = CYDriver::AutoMessage; YYACCEPT; }
1625     ;
1626
1627 SelectorCall
1628     : SelectorWordOpt ":" AssignmentExpression SelectorCall_ { $$ = CYNew CYArgument($1 ?: CYNew CYBlank(), $3, $4); }
1629     ;
1630
1631 SelectorList
1632     : SelectorCall { $$ = $1; }
1633     | Word { $$ = CYNew CYArgument($1, NULL); }
1634     ;
1635
1636 MessageExpression
1637     : "[" AssignmentExpression { driver.contexts_.push_back($2); } SelectorList "]" { driver.contexts_.pop_back(); } { $$ = CYNew CYSendDirect($2, $4); }
1638     | "[" LexSetRegExp "super" { driver.context_ = NULL; } SelectorList "]" { $$ = CYNew CYSendSuper($5); }
1639     ;
1640
1641 SelectorExpressionOpt
1642     : SelectorExpression_ { $$ = $1; }
1643     | { $$ = NULL; }
1644     ;
1645
1646 SelectorExpression_
1647     : WordOpt ":" SelectorExpressionOpt { $$ = CYNew CYSelectorPart($1, true, $3); }
1648     ;
1649
1650 SelectorExpression
1651     : SelectorExpression_ { $$ = $1; }
1652     | Word { $$ = CYNew CYSelectorPart($1, false, NULL); }
1653     ;
1654
1655 PrimaryExpressionNo
1656     : MessageExpression { $$ = $1; }
1657     | "@selector" "(" SelectorExpression ")" { $$ = CYNew CYSelector($3); }
1658     ;
1659 /* }}} */
1660 /* Cycript (Objective-C): @import Directive {{{ */
1661 PathName
1662     : "/" PathName
1663     | "." PathName
1664     | Word PathName
1665     |
1666     ;
1667
1668 ImportPath
1669     : "<" PathName ">"
1670     | StringLiteral
1671     ;
1672
1673 SourceElement_
1674     : "@import" ImportPath { $$ = CYNew CYImport(); }
1675     ;
1676 /* }}} */
1677 @end
1678
1679 @begin C
1680 /* Cycript (C): Pointer Indirection/Addressing {{{ */
1681 UnaryAssigneeExpression
1682     : "*" UnaryExpressionNoRE { $$ = CYNew CYIndirect($2); }
1683     ;
1684
1685 UnaryExpression_
1686     : "&" UnaryExpression { $$ = CYNew CYAddressOf($2); }
1687     ;
1688
1689 MemberAccess
1690     : "->" "[" Expression "]" { $$ = CYNew CYIndirectMember(NULL, $3); }
1691     | "->" Identifier { $$ = CYNew CYIndirectMember(NULL, CYNew CYString($2)); }
1692     | "->" AutoComplete { driver.mode_ = CYDriver::AutoIndirect; YYACCEPT; }
1693     ;
1694 /* }}} */
1695 @end
1696
1697 /* YUI: Documentation Comments {{{ */
1698 Statement_
1699     : Comment { $$ = $1; }
1700     ;
1701 /* }}} */
1702
1703 @begin E4X
1704 /* Lexer State {{{ */
1705 LexPushRegExp
1706     : { driver.PushCondition(CYDriver::RegExpCondition); }
1707     ;
1708
1709 LexPushXMLContent
1710     : { driver.PushCondition(CYDriver::XMLContentCondition); }
1711     ;
1712
1713 LexPushXMLTag
1714     : { driver.PushCondition(CYDriver::XMLTagCondition); }
1715     ;
1716
1717 LexPop
1718     : { driver.PopCondition(); }
1719     ;
1720
1721 LexSetXMLContent
1722     : { driver.SetCondition(CYDriver::XMLContentCondition); }
1723     ;
1724
1725 LexSetXMLTag
1726     : { driver.SetCondition(CYDriver::XMLTagCondition); }
1727     ;
1728 /* }}} */
1729
1730 XMLWhitespaceOpt
1731     : XMLWhitespace
1732     |
1733     ;
1734
1735 /* 8.1 Context Keywords {{{ */
1736 Identifier
1737     : "namespace" { $$ = $1; }
1738     | "xml" { $$ = $1; }
1739     ;
1740 /* }}} */
1741 /* 8.3 XML Initialiser Input Elements {{{ */
1742 XMLMarkup
1743     : XMLComment { $$ = $1; }
1744     | XMLCDATA { $$ = $1; }
1745     | XMLPI { $$ = $1; }
1746     ;
1747 /* }}} */
1748 /* 11.1 Primary Expressions {{{ */
1749 PrimaryExpressionNo
1750     : PropertyIdentifier { $$ = CYNew CYPropertyVariable($1); }
1751     | XMLInitialiser { $$ = $1; }
1752     | XMLListInitialiser { $$ = $1; }
1753     ;
1754
1755 PropertyIdentifier
1756     : AttributeIdentifier { $$ = $1; }
1757     | QualifiedIdentifier { $$ = $1; }
1758     | WildcardIdentifier { $$ = $1; }
1759     ;
1760 /* }}} */
1761 /* 11.1.1 Attribute Identifiers {{{ */
1762 AttributeIdentifier
1763     : "@" QualifiedIdentifier_ { $$ = CYNew CYAttribute($2); }
1764     ;
1765
1766 PropertySelector_
1767     : PropertySelector { $$ = $1; }
1768     | "[" Expression "]" { $$ = CYNew CYSelector($2); }
1769     ;
1770
1771 PropertySelector
1772     : Identifier { $$ = CYNew CYSelector($1); }
1773     | WildcardIdentifier { $$ = $1; }
1774     ;
1775 /* }}} */
1776 /* 11.1.2 Qualified Identifiers {{{ */
1777 QualifiedIdentifier_
1778     : PropertySelector_ { $$ = CYNew CYQualified(NULL, $1); }
1779     | QualifiedIdentifier { $$ = $1; }
1780     ;
1781
1782 QualifiedIdentifier
1783     : PropertySelector "::" PropertySelector_ { $$ = CYNew CYQualified($1, $3); }
1784     ;
1785 /* }}} */
1786 /* 11.1.3 Wildcard Identifiers {{{ */
1787 WildcardIdentifier
1788     : "*" { $$ = CYNew CYWildcard(); }
1789     ;
1790 /* }}} */
1791 /* 11.1.4 XML Initialiser {{{ */
1792 XMLInitialiser
1793     : XMLMarkup { $$ = $1; }
1794     | XMLElement { $$ = $1; }
1795     ;
1796
1797 XMLElement
1798     : "<" XMLTagContent "/>" LexPop
1799     | "<" XMLTagContent ">" LexSetXMLContent XMLElementContentOpt "</" LexSetXMLTag XMLTagName XMLWhitespaceOpt ">" LexPop
1800     ;
1801
1802 XMLTagContent
1803     : LexPushXMLTag XMLTagName XMLAttributes
1804     ;
1805
1806 XMLExpression
1807     : Brace LexPushRegExp Expression "}" LexPop
1808     ;
1809
1810 XMLTagName
1811     : XMLExpression
1812     | XMLName
1813     ;
1814
1815 XMLAttributes_
1816     : XMLAttributes_ XMLAttribute
1817     |
1818     ;
1819
1820 XMLAttributes
1821     : XMLAttributes_ XMLWhitespace XMLExpression XMLWhitespaceOpt
1822     | XMLAttributes_ XMLWhitespaceOpt
1823     ;
1824
1825 XMLAttributeValue_
1826     : XMLExpression
1827     | XMLAttributeValue
1828     ;
1829
1830 XMLAttribute
1831     : XMLWhitespace XMLName XMLWhitespaceOpt "=" XMLWhitespaceOpt XMLAttributeValue_
1832     ;
1833
1834 XMLElementContent
1835     : XMLExpression XMLElementContentOpt
1836     | XMLMarkup XMLElementContentOpt
1837     | XMLText XMLElementContentOpt
1838     | XMLElement XMLElementContentOpt
1839     ;
1840
1841 XMLElementContentOpt
1842     : XMLElementContent
1843     |
1844     ;
1845 /* }}} */
1846 /* 11.1.5 XMLList Initialiser {{{ */
1847 XMLListInitialiser
1848     : "<>" LexPushXMLContent XMLElementContent "</>" LexPop { $$ = CYNew CYXMLList($3); }
1849     ;
1850 /* }}} */
1851 /* 11.2 Left-Hand-Side Expressions {{{ */
1852 PropertyIdentifier_
1853     : Identifier { $$ = $1; }
1854     | PropertyIdentifier { $$ = $1; }
1855     ;
1856
1857 MemberAccess
1858     : "." PropertyIdentifier { $$ = CYNew CYPropertyMember(NULL, $2); }
1859     | ".." PropertyIdentifier_ { $$ = CYNew CYDescendantMember(NULL, $2); }
1860     | "." "(" Expression ")" { $$ = CYNew CYFilteringPredicate(NULL, $3); }
1861     ;
1862 /* }}} */
1863 /* 12.1 The default xml namespace Statement {{{ */
1864 /* XXX: DefaultXMLNamespaceStatement
1865     : "default" "xml" "namespace" "=" Expression Terminator { $$ = CYNew CYDefaultXMLNamespace($5); }
1866     ;
1867
1868 Statement_
1869     : DefaultXMLNamespaceStatement { $$ = $1; }
1870     ; */
1871 /* }}} */
1872 @end
1873
1874 /* ECMAScript5: Object Literal Trailing Comma {{{ */
1875 PropertyNameAndValueList_
1876     : "," { $$ = NULL; }
1877     ;
1878 /* }}} */
1879
1880 /* JavaScript 1.7: Array Comprehensions {{{ */
1881 IfComprehension
1882     : "if" "(" Expression ")" { $$ = CYNew CYIfComprehension($3); }
1883     ;
1884
1885 ForComprehension
1886     : "for" "(" Identifier "in" Expression ")" { $$ = CYNew CYForInComprehension($3, $5); }
1887     | "for" "each" "(" Identifier "in" Expression ")" { $$ = CYNew CYForEachInComprehension($4, $6); }
1888     ;
1889
1890 ComprehensionListOpt
1891     : ComprehensionList { $$ = $1; }
1892     | IfComprehension { $$ = $1; }
1893     | { $$ = NULL; }
1894     ;
1895
1896 ComprehensionList
1897     : ForComprehension ComprehensionListOpt { $1->SetNext($2); $$ = $1; }
1898     ;
1899
1900 PrimaryExpressionNo
1901     : "[" AssignmentExpression ComprehensionList "]" { $$ = CYNew CYArrayComprehension($2, $3); }
1902     ;
1903 /* }}} */
1904 /* JavaScript 1.7: for each {{{ */
1905 ForInStatement
1906     : "for" "each" "(" ForInStatementInitialiser "in" Expression ")" Statement { $$ = CYNew CYForEachIn($4, $6, $8); }
1907     ;
1908 /* }}} */
1909 /* JavaScript 1.7: let Statements {{{ *//*
1910 LetStatement
1911     : "let" "(" VariableDeclarationList ")" Block_ { $$ = CYNew CYLet($3, $5); }
1912     ;
1913
1914 Statement_
1915     : LetStatement
1916     ;
1917 *//* }}} */
1918
1919 /* JavaScript FTW: Function Statements {{{ */
1920 Statement
1921     : LexSetRegExp FunctionDeclaration { driver.Warning(yylloc, "warning, FunctionDeclaration is a SourceElement, not a Statement"); } { $$ = $2; }
1922     ;
1923 /* }}} */
1924 /* JavaScript FTW: Optional Arguments {{{ */
1925 FormalParameterList
1926     : Identifier "=" AssignmentExpression FormalParameterList_ { $$ = CYNew CYOptionalFunctionParameter($1, $3, $4); }
1927     ;
1928 /* }}} */
1929 /* JavaScript FTW: Ruby Blocks {{{ */
1930 RubyProcParameterList_
1931     : "," RubyProcParameterList { $$ = $2; }
1932     | { $$ = NULL; }
1933     ;
1934
1935 RubyProcParameterList
1936     : Identifier RubyProcParameterList_ { $$ = CYNew CYFunctionParameter($1, $2); }
1937     | { $$ = NULL; }
1938     ;
1939
1940 RubyProcParametersOpt
1941     : "|" RubyProcParameterList "|" { $$ = $2; }
1942     | { $$ = NULL; }
1943     ;
1944
1945 RubyProcExpression
1946     : "{" RubyProcParametersOpt StatementListOpt "}" { $$ = CYNew CYRubyProc($2, $3); }
1947     ;
1948
1949 LeftHandSideExpression
1950     : LeftHandSideExpression RubyProcExpression { $$ = CYNew CYRubyBlock($1, $2); }
1951     ;
1952
1953 LeftHandSideExpressionNoBF
1954     : LeftHandSideExpressionNoBF RubyProcExpression { $$ = CYNew CYRubyBlock($1, $2); }
1955     ;
1956
1957 @begin C
1958 LeftHandSideExpressionNoRE
1959     : LeftHandSideExpressionNoRE RubyProcExpression { $$ = CYNew CYRubyBlock($1, $2); }
1960     ;
1961 @end
1962 /* }}} */
1963
1964 %%