Cycript.yy.in

   1 /* Cycript - Optimizing JavaScript Compiler/Runtime
   2  * Copyright (C) 2009-2012  Jay Freeman (saurik)
   3 */
   4
   5 /* GNU Lesser General Public License, Version 3 {{{ */
   6 /*
   7  * Cycript is free software: you can redistribute it and/or modify it under
   8  * the terms of the GNU Lesser General Public License as published by the
   9  * Free Software Foundation, either version 3 of the License, or (at your
  10  * option) any later version.
  11  *
  12  * Cycript is distributed in the hope that it will be useful, but WITHOUT
  13  * ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  14  * FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  15  * License for more details.
  16  *
  17  * You should have received a copy of the GNU Lesser General Public License
  18  * along with Cycript.  If not, see <http://www.gnu.org/licenses/>.
  19 **/
  20 /* }}} */
  21
  22 @if Bison23 %{
  23
  24 @if Bison24 %code top {
  25 #define cyscanner driver.scanner_
  26 #define YYSTACKEXPANDABLE 1
  27 @if Bison23 #define yyerrok (yyerrstatus_ = 0)
  28 @if Bison24 }
  29
  30 @if Bison24 %code requires {
  31 #include "Parser.hpp"
  32 #define CYNew new($pool)
  33
  34 @begin ObjectiveC
  35 #include "ObjectiveC/Syntax.hpp"
  36 @end
  37
  38 @begin E4X
  39 #include "E4X/Syntax.hpp"
  40 @end
  41
  42 #include "Highlight.hpp"
  43
  44 typedef struct {
  45     bool newline_;
  46     hi::Value highlight_;
  47
  48     union {
  49         bool bool_;
  50
  51         CYDriver::Condition condition_;
  52
  53         CYArgument *argument_;
  54         CYAssignment *assignment_;
  55         CYBoolean *boolean_;
  56         CYClause *clause_;
  57         cy::Syntax::Catch *catch_;
  58         CYComment *comment_;
  59         CYComprehension *comprehension_;
  60         CYCompound *compound_;
  61         CYDeclaration *declaration_;
  62         CYDeclarations *declarations_;
  63         CYElement *element_;
  64         CYExpression *expression_;
  65         CYFalse *false_;
  66         CYFinally *finally_;
  67         CYForInitialiser *for_;
  68         CYForInInitialiser *forin_;
  69         CYFunctionParameter *functionParameter_;
  70         CYIdentifier *identifier_;
  71         CYInfix *infix_;
  72         CYLiteral *literal_;
  73         CYMember *member_;
  74         CYNull *null_;
  75         CYNumber *number_;
  76         CYProgram *program_;
  77         CYProperty *property_;
  78         CYPropertyName *propertyName_;
  79         CYRubyProc *rubyProc_;
  80         CYStatement *statement_;
  81         CYString *string_;
  82         CYThis *this_;
  83         CYTrue *true_;
  84         CYTypeModifier *type_;
  85         CYTypedIdentifier *typedIdentifier_;
  86         CYTypedParameter *typedParameter_;
  87         CYWord *word_;
  88
  89 @begin ObjectiveC
  90         CYClassName *className_;
  91         CYField *field_;
  92         CYMessage *message_;
  93         CYMessageParameter *messageParameter_;
  94         CYProtocol *protocol_;
  95         CYSelectorPart *selector_;
  96 @end
  97
  98 @begin E4X
  99         CYAttribute *attribute_;
 100         CYPropertyIdentifier *propertyIdentifier_;
 101         CYSelector *selector_;
 102 @end
 103     };
 104 } YYSTYPE;
 105
 106 #define YYSTYPE YYSTYPE
 107 @if Bison24 }
 108
 109 @if Bison24 %code provides {
 110 int cylex(YYSTYPE *, cy::location *, void *);
 111 @if Bison24 }
 112
 113 @if Bison23 %}
 114
 115 %name-prefix="cy"
 116
 117 @if Bison23 %skeleton "lalr1.cc"
 118 @if Bison24 %language "C++"
 119
 120 %initial-action {
 121     @$.begin.filename = @$.end.filename = &driver.filename_;
 122 };
 123
 124 %locations
 125 %defines
 126
 127 //%glr-parser
 128 //%expect 1
 129
 130 %error-verbose
 131
 132 %parse-param { CYDriver &driver }
 133 %lex-param { void *cyscanner }
 134
 135 /* Token Declarations {{{ */
 136 @begin E4X
 137 %token XMLCDATA
 138 %token XMLComment
 139 %token XMLPI
 140
 141 %token XMLAttributeValue
 142 %token XMLName
 143 %token XMLTagCharacters
 144 %token XMLText
 145 %token XMLWhitespace
 146 @end
 147
 148 @begin E4X
 149 %token LeftRight "<>"
 150 %token LeftSlashRight "</>"
 151
 152 %token SlashRight "/>"
 153 %token LeftSlash "</"
 154
 155 %token ColonColon "::"
 156 %token PeriodPeriod ".."
 157 @end
 158
 159 @begin E4X ObjectiveC
 160 %token At "@"
 161 @end
 162
 163 %token Ampersand "&"
 164 %token AmpersandAmpersand "&&"
 165 %token AmpersandEqual "&="
 166 %token Carrot "^"
 167 %token CarrotEqual "^="
 168 %token Equal "="
 169 %token EqualEqual "=="
 170 %token EqualEqualEqual "==="
 171 %token EqualRight "=>"
 172 %token Exclamation "!"
 173 %token ExclamationEqual "!="
 174 %token ExclamationEqualEqual "!=="
 175 %token Hyphen "-"
 176 %token HyphenEqual "-="
 177 %token HyphenHyphen "--"
 178 %token HyphenHyphen_ "\n--"
 179 %token HyphenRight "->"
 180 %token Left "<"
 181 %token LeftEqual "<="
 182 %token LeftLeft "<<"
 183 %token LeftLeftEqual "<<="
 184 %token Percent "%"
 185 %token PercentEqual "%="
 186 %token Period "."
 187 %token PeriodPeriodPeriod "..."
 188 %token Pipe "|"
 189 %token PipeEqual "|="
 190 %token PipePipe "||"
 191 %token Plus "+"
 192 %token PlusEqual "+="
 193 %token PlusPlus "++"
 194 %token PlusPlus_ "\n++"
 195 %token Right ">"
 196 %token RightEqual ">="
 197 %token RightRight ">>"
 198 %token RightRightEqual ">>="
 199 %token RightRightRight ">>>"
 200 %token RightRightRightEqual ">>>="
 201 %token Slash "/"
 202 %token SlashEqual "/="
 203 %token Star "*"
 204 %token StarEqual "*="
 205 %token Tilde "~"
 206
 207 %token Colon ":"
 208 %token Comma ","
 209 %token Question "?"
 210 %token SemiColon ";"
 211 %token NewLine "\n"
 212
 213 %token <comment_> Comment
 214
 215 %token OpenParen "("
 216 %token CloseParen ")"
 217
 218 %token OpenBrace "{"
 219 %token OpenBrace_ "\n{"
 220 %token OpenBrace__ ";{"
 221 %token CloseBrace "}"
 222
 223 %token OpenBracket "["
 224 %token CloseBracket "]"
 225
 226 @begin Java
 227 %token AtClass "@class"
 228 @end
 229
 230 @begin ObjectiveC
 231 %token AtImplementation "@implementation"
 232 %token AtImplementation_ ";@implementation"
 233 %token AtImport "@import"
 234 %token AtEncode "@encode"
 235 %token AtEnd "@end"
 236 %token AtSelector "@selector"
 237 @end
 238
 239 %token <false_> False "false"
 240 %token <null_> Null "null"
 241 %token <true_> True "true"
 242
 243 // ES3/ES5/WIE/JSC Reserved
 244 %token <word_> Auto "auto"
 245 %token <word_> Break "break"
 246 %token <word_> Case "case"
 247 %token <word_> Catch "catch"
 248 %token <word_> Continue "continue"
 249 %token <word_> Default "default"
 250 %token <word_> Delete "delete"
 251 %token <word_> Do "do"
 252 %token <word_> Else "else"
 253 %token <word_> Finally "finally"
 254 %token <word_> For "for"
 255 %token <word_> Function "function"
 256 %token <word_> Function_ ";function"
 257 %token <word_> If "if"
 258 %token <word_> In "in"
 259 %token <word_> In_ "!in"
 260 %token <word_> InstanceOf "instanceof"
 261 %token <word_> New "new"
 262 %token <word_> Return "return"
 263 %token <word_> Switch "switch"
 264 %token <this_> This "this"
 265 %token <word_> Throw "throw"
 266 %token <word_> Try "try"
 267 %token <word_> TypeOf "typeof"
 268 %token <word_> Var "var"
 269 %token <word_> Void "void"
 270 %token <word_> While "while"
 271 %token <word_> With "with"
 272
 273 // ES3/IE6 Future, ES5/JSC Reserved
 274 %token <word_> Debugger "debugger"
 275
 276 // ES3/ES5/IE6 Future, JSC Reserved
 277 %token <word_> Const "const"
 278
 279 // ES3/ES5/IE6/JSC Future
 280 %token <word_> Class "class"
 281 %token <word_> Enum "enum"
 282 %token <word_> Export "export"
 283 %token <word_> Extends "extends"
 284 %token <word_> Import "import"
 285 %token <word_> Super "super"
 286
 287 // ES3 Future, ES5 Strict Future
 288 %token <identifier_> Implements "implements"
 289 %token <identifier_> Interface "interface"
 290 %token <identifier_> Package "package"
 291 %token <identifier_> Private "private"
 292 %token <identifier_> Protected "protected"
 293 %token <identifier_> Public "public"
 294 %token <identifier_> Static "static"
 295
 296 // ES3 Future
 297 %token <identifier_> Abstract "abstract"
 298 %token <identifier_> Boolean "boolean"
 299 %token <identifier_> Byte "byte"
 300 %token <identifier_> Char "char"
 301 %token <identifier_> Double "double"
 302 %token <identifier_> Final "final"
 303 %token <identifier_> Float "float"
 304 %token <identifier_> Goto "goto"
 305 %token <identifier_> Int "int"
 306 %token <identifier_> Long "long"
 307 %token <identifier_> Native "native"
 308 %token <identifier_> Short "short"
 309 %token <identifier_> Synchronized "synchronized"
 310 %token <identifier_> Throws "throws"
 311 %token <identifier_> Transient "transient"
 312 %token <identifier_> Volatile "volatile"
 313
 314 // ES5 Strict
 315 %token <identifier_> Let "let"
 316 %token <identifier_> Yield "yield"
 317
 318 // Woah?!
 319 %token <identifier_> Each "each"
 320 %token <identifier_> Of "of"
 321
 322 @begin E4X
 323 // E4X Conditional
 324 %token <identifier_> Namespace "namespace"
 325 %token <identifier_> XML "xml"
 326 @end
 327
 328 %token AutoComplete
 329
 330 %token <identifier_> Identifier_
 331 %token <number_> NumericLiteral
 332 %token <string_> StringLiteral
 333 %token <literal_> RegularExpressionLiteral
 334
 335 %type <expression_> AdditiveExpression
 336 %type <argument_> ArgumentList_
 337 %type <argument_> ArgumentList
 338 %type <argument_> ArgumentListOpt
 339 %type <argument_> Arguments
 340 %type <literal_> ArrayLiteral
 341 %type <expression_> ArrowFunction
 342 %type <functionParameter_> ArrowParameters
 343 %type <expression_> AssignmentExpression
 344 %type <identifier_> Binding
 345 %type <identifier_> BindingIdentifier
 346 %type <expression_> BitwiseANDExpression
 347 %type <statement_> Block_
 348 %type <statement_> Block
 349 %type <boolean_> BooleanLiteral
 350 %type <declaration_> BindingElement
 351 %type <expression_> BitwiseORExpression
 352 %type <expression_> BitwiseXORExpression
 353 %type <statement_> BreakStatement
 354 %type <statement_> BreakableStatement
 355 %type <expression_> CallExpression_
 356 %type <expression_> CallExpression
 357 %type <clause_> CaseBlock
 358 %type <clause_> CaseClause
 359 %type <clause_> CaseClausesOpt
 360 %type <catch_> CatchOpt
 361 %type <comprehension_> ComprehensionForList
 362 %type <comprehension_> ComprehensionForListOpt
 363 %type <comprehension_> ComprehensionList
 364 %type <comprehension_> ComprehensionListOpt
 365 %type <expression_> ConditionalExpression
 366 %type <statement_> ContinueStatement
 367 %type <statement_> ConciseBody
 368 %type <statement_> DebuggerStatement
 369 %type <statement_> Declaration__
 370 %type <statement_> Declaration_
 371 %type <statement_> Declaration
 372 %type <clause_> DefaultClause
 373 %type <expression_> Element
 374 %type <expression_> ElementOpt
 375 %type <element_> ElementList
 376 %type <element_> ElementListOpt
 377 %type <statement_> ElseStatementOpt
 378 %type <statement_> EmptyStatement
 379 %type <expression_> EqualityExpression
 380 %type <compound_> Expression_
 381 %type <compound_> Expression
 382 %type <expression_> ExpressionOpt
 383 %type <statement_> ExpressionStatement
 384 %type <finally_> FinallyOpt
 385 %type <comprehension_> ForComprehension
 386 %type <for_> ForStatementInitialiser
 387 %type <forin_> ForInStatementInitialiser
 388 %type <declaration_> FormalParameter
 389 %type <functionParameter_> FormalParameterList_
 390 %type <functionParameter_> FormalParameterList
 391 %type <functionParameter_> FormalParameterListOpt
 392 %type <statement_> FunctionBody
 393 %type <statement_> FunctionDeclaration
 394 %type <expression_> FunctionExpression
 395 %type <identifier_> Identifier
 396 %type <identifier_> IdentifierOpt
 397 %type <word_> IdentifierName
 398 %type <comprehension_> IfComprehension
 399 %type <statement_> IfStatement
 400 %type <expression_> Initialiser
 401 %type <expression_> InitialiserOpt
 402 %type <statement_> IterationStatement
 403 %type <statement_> LabelledStatement
 404 %type <expression_> LeftHandSideExpression
 405 %type <statement_> LetStatement
 406 %type <statement_> LexicalDeclaration
 407 %type <literal_> Literal
 408 %type <literal_> ValueLiteral
 409 %type <expression_> LogicalANDExpression
 410 %type <expression_> LogicalORExpression
 411 %type <member_> MemberAccess
 412 %type <expression_> MemberExpression_
 413 %type <expression_> MemberExpression
 414 %type <expression_> MultiplicativeExpression
 415 %type <expression_> NewExpression
 416 %type <null_> NullLiteral
 417 %type <literal_> ObjectLiteral
 418 %type <compound_> Parenthetical
 419 %type <compound_> ParentheticalOpt
 420 %type <expression_> PostfixExpression
 421 %type <expression_> PrimaryExpression
 422 %type <statement_> Program
 423 %type <statement_> ProgramBody
 424 %type <statement_> ProgramBodyOpt
 425 %type <propertyName_> PropertyName_
 426 %type <propertyName_> PropertyName
 427 %type <property_> PropertyDefinition
 428 %type <property_> PropertyDefinitionList_
 429 %type <property_> PropertyDefinitionList
 430 %type <property_> PropertyDefinitionListOpt
 431 %type <expression_> RelationalExpression
 432 %type <statement_> ReturnStatement
 433 %type <rubyProc_> RubyProcExpression
 434 %type <functionParameter_> RubyProcParameterList_
 435 %type <functionParameter_> RubyProcParameterList
 436 %type <functionParameter_> RubyProcParameters
 437 %type <functionParameter_> RubyProcParametersOpt
 438 %type <expression_> ShiftExpression
 439 %type <declaration_> SingleNameBinding
 440 %type <statement_> Statement__
 441 %type <statement_> Statement_
 442 %type <statement_> Statement
 443 %type <statement_> StatementList
 444 %type <statement_> StatementListOpt
 445 %type <statement_> StatementListItem
 446 %type <statement_> SwitchStatement
 447 %type <statement_> ThrowStatement
 448 %type <statement_> TryStatement
 449 %type <expression_> UnaryExpression_
 450 %type <expression_> UnaryExpression
 451 %type <declaration_> VariableDeclaration
 452 %type <declarations_> VariableDeclarationList_
 453 %type <declarations_> VariableDeclarationList
 454 %type <statement_> VariableStatement
 455 %type <statement_> WithStatement
 456 %type <word_> Word
 457 %type <word_> WordOpt
 458 %type <expression_> Variable
 459
 460 @begin ObjectiveC
 461 %type <expression_> BoxableExpression
 462 %type <statement_> CategoryStatement
 463 %type <expression_> ClassExpression
 464 %type <field_> ClassFieldListOpt
 465 %type <field_> ClassFields
 466 %type <statement_> ClassStatement
 467 %type <expression_> ClassSuperOpt
 468 %type <message_> ClassMessageDeclaration
 469 %type <message_> ClassMessageDeclarationListOpt
 470 %type <className_> ClassName
 471 %type <className_> ClassNameOpt
 472 %type <protocol_> ClassProtocolListOpt
 473 %type <protocol_> ClassProtocols
 474 %type <protocol_> ClassProtocolsOpt
 475 %type <expression_> EncodedType
 476 %type <expression_> MessageExpression
 477 %type <messageParameter_> MessageParameter
 478 %type <messageParameter_> MessageParameters
 479 %type <messageParameter_> MessageParameterList
 480 %type <messageParameter_> MessageParameterListOpt
 481 %type <bool_> MessageScope
 482 %type <type_> ModifiedType
 483 %type <typedIdentifier_> PrefixedType
 484 %type <type_> QualifiedType
 485 %type <argument_> SelectorCall_
 486 %type <argument_> SelectorCall
 487 %type <selector_> SelectorExpression_
 488 %type <selector_> SelectorExpression
 489 %type <selector_> SelectorExpressionOpt
 490 %type <argument_> SelectorList
 491 %type <word_> SelectorWordOpt
 492 %type <typedIdentifier_> SuffixedType
 493 %type <expression_> TypeOpt
 494 %type <typedIdentifier_> TypedIdentifier
 495 %type <typedParameter_> TypedParameterList_
 496 %type <typedParameter_> TypedParameterList
 497 %type <typedParameter_> TypedParameterListOpt
 498 %type <argument_> VariadicCall
 499 @end
 500
 501 @begin E4X
 502 %type <propertyIdentifier_> PropertyIdentifier_
 503 %type <selector_> PropertySelector_
 504 %type <selector_> PropertySelector
 505 %type <identifier_> QualifiedIdentifier_
 506 %type <identifier_> QualifiedIdentifier
 507 %type <identifier_> WildcardIdentifier
 508 %type <identifier_> XMLComment
 509 %type <identifier_> XMLCDATA
 510 %type <identifier_> XMLElement
 511 %type <identifier_> XMLElementContent
 512 %type <identifier_> XMLMarkup
 513 %type <identifier_> XMLPI
 514
 515 %type <attribute_> AttributeIdentifier
 516 /* XXX: %type <statement_> DefaultXMLNamespaceStatement */
 517 %type <expression_> PropertyIdentifier
 518 %type <expression_> XMLListInitialiser
 519 %type <expression_> XMLInitialiser
 520 @end
 521 /* }}} */
 522 /* Token Priorities {{{ */
 523 %nonassoc ""
 524 %left "++" "--"
 525
 526 %nonassoc "if"
 527 %nonassoc "else"
 528 /* }}} */
 529
 530 %start Program
 531
 532 %%
 533
 534 /* Lexer State {{{ */
 535 LexPushInOn
 536     : { driver.in_.push(true); }
 537     ;
 538
 539 LexPushInOff
 540     : { driver.in_.push(false); }
 541     ;
 542
 543 LexPopIn
 544     : { driver.in_.pop(); }
 545     ;
 546
 547 LexSetRegExp
 548     : { driver.SetCondition(CYDriver::RegExpCondition); }
 549     ;
 550
 551 LexNoBrace
 552     : { if (yychar == yyempty_) driver.no_.OpenBrace = true; else if (yychar == token::OpenBrace || yychar == token::OpenBrace_) yychar = token::OpenBrace__; }
 553     ;
 554
 555 LexNoFunction
 556     : { if (yychar == yyempty_) driver.no_.Function = true; else if (yychar == token::Function) yychar = token::Function_; }
 557     ;
 558
 559 LexNoAtImplementation
 560     : { if (yychar == yyempty_) driver.no_.AtImplementation = true; else if (yychar == token::AtImplementation) yychar = token::AtImplementation_; }
 561     ;
 562
 563 LexSetStatement
 564     : LexNoBrace LexNoFunction LexNoAtImplementation
 565     ;
 566 /* }}} */
 567 /* Virtual Tokens {{{ */
 568 BRACE
 569     : "{"
 570     | "\n{"
 571     ;
 572
 573 Var_
 574     : "var"
 575     ;
 576 /* }}} */
 577
 578 /* 7.6 Identifier Names and Identifiers {{{ */
 579 IdentifierName
 580     : Word { $$ = $1; }
 581     ;
 582
 583 NewLineOpt
 584     : "\n"
 585     |
 586     ;
 587
 588 Word
 589     : Identifier { $$ = $1; }
 590     | "auto" { $$ = $1; }
 591     | "break" NewLineOpt { $$ = $1; }
 592     | "case" { $$ = $1; }
 593     | "catch" { $$ = $1; }
 594     | "class" { $$ = $1; }
 595     | "const" { $$ = $1; }
 596     | "continue" NewLineOpt { $$ = $1; }
 597     | "debugger" { $$ = $1; }
 598     | "default" { $$ = $1; }
 599     | "delete" { $$ = $1; }
 600     | "do" { $$ = $1; }
 601     | "else" { $$ = $1; }
 602     | "enum" { $$ = $1; }
 603     | "export" { $$ = $1; }
 604     | "extends" { $$ = $1; }
 605     | "false" { $$ = $1; }
 606     | "finally" { $$ = $1; }
 607     /* XXX: | "for" { $$ = $1; } */
 608     | "function" { $$ = $1; }
 609     | "if" { $$ = $1; }
 610     | "import" { $$ = $1; }
 611     /* XXX: | "in" { $$ = $1; } */
 612     | "!in" { $$ = $1; }
 613     /* XXX: | "instanceof" { $$ = $1; } */
 614
 615     // XXX: as it currently is not an Identifier
 616     | "let" { $$ = $1; }
 617
 618     | "new" { $$ = $1; }
 619     | "null" { $$ = $1; }
 620     | "return" NewLineOpt { $$ = $1; }
 621     | "super" { $$ = $1; }
 622     | "switch" { $$ = $1; }
 623     | "this" { $$ = $1; }
 624     | "throw" NewLineOpt { $$ = $1; }
 625     | "true" { $$ = $1; }
 626     | "try" { $$ = $1; }
 627     | "typeof" { $$ = $1; }
 628     | "var" { $$ = $1; }
 629     | "void" { $$ = $1; }
 630     | "while" { $$ = $1; }
 631     | "with" { $$ = $1; }
 632     ;
 633
 634 WordOpt
 635     : Word { $$ = $1; }
 636     | { $$ = NULL; }
 637     ;
 638
 639 Identifier
 640     : Identifier_ { $$ = $1; }
 641
 642     | "implements" { $$ = $1; }
 643     | "interface" { $$ = $1; }
 644     | "package" { $$ = $1; }
 645     | "private" { $$ = $1; }
 646     | "protected" { $$ = $1; }
 647     | "public" { $$ = $1; }
 648     | "static" { $$ = $1; }
 649
 650     | "abstract" { $$ = $1; }
 651     | "boolean" { $$ = $1; }
 652     | "byte" { $$ = $1; }
 653     | "char" { $$ = $1; }
 654     | "double" { $$ = $1; }
 655     | "final" { $$ = $1; }
 656     | "float" { $$ = $1; }
 657     | "goto" { $$ = $1; }
 658     | "int" { $$ = $1; }
 659     | "long" { $$ = $1; }
 660     | "native" { $$ = $1; }
 661     | "short" { $$ = $1; }
 662     | "synchronized" { $$ = $1; }
 663     | "throws" { $$ = $1; }
 664     | "transient" { $$ = $1; }
 665     | "volatile" { $$ = $1; }
 666
 667     // XXX: currently I only have this as Word
 668     // | "let" { $$ = $1; }
 669
 670     | "yield" { $$ = $1; }
 671
 672     | "each" { $$ = $1; }
 673     | "of" { $$ = $1; }
 674     ;
 675
 676 IdentifierOpt
 677     : Identifier { $$ = $1; }
 678     | { $$ = NULL; }
 679     ;
 680 /* }}} */
 681
 682 /* 7.8 Literals {{{ */
 683 Literal
 684     : NullLiteral { $$ = $1; }
 685     | ValueLiteral { $$ = $1; }
 686     ;
 687
 688 ValueLiteral
 689     : BooleanLiteral { $$ = $1; }
 690     | NumericLiteral { $$ = $1; }
 691     | StringLiteral { $$ = $1; }
 692     | RegularExpressionLiteral { $$ = $1; }
 693     ;
 694 /* }}} */
 695 /* 7.8.1 Null Literals {{{ */
 696 NullLiteral
 697     : "null" { $$ = $1; }
 698     ;
 699 /* }}} */
 700 /* 7.8.2 Boolean Literals {{{ */
 701 BooleanLiteral
 702     : "true" { $$ = $1; }
 703     | "false" { $$ = $1; }
 704     ;
 705 /* }}} */
 706
 707 /* 7.9 Automatic Semicolon Insertion {{{ */
 708 StrictSemi
 709     : { driver.Warning(yylloc, "warning, automatic semi-colon insertion required"); }
 710     ;
 711
 712 Terminator
 713     : ";"
 714     | error { if (yychar != yyeof_ && yychar != token::CloseBrace && !yylval.newline_) YYABORT; else { yyerrok; driver.errors_.pop_back(); } } StrictSemi
 715     ;
 716
 717 TerminatorOpt
 718     : ";"
 719     | error { yyerrok; driver.errors_.pop_back(); } StrictSemi
 720     ;
 721 /* }}} */
 722
 723 /* 11.1 Primary Expressions {{{ */
 724 Parenthetical
 725     : "(" LexPushInOff Expression LexPopIn ")" { $$ = $3; }
 726     ;
 727
 728 ParentheticalOpt
 729     : Parenthetical { $$ = $1; }
 730     | { $$ = NULL; }
 731     ;
 732
 733 Variable
 734     : Identifier { $$ = CYNew CYVariable($1); }
 735     ;
 736
 737 PrimaryExpression
 738     : "this" { $$ = $1; }
 739     | Variable { $$ = $1; }
 740     | Literal { $$ = $1; }
 741     | ArrayLiteral { $$ = $1; }
 742     | ObjectLiteral { $$ = $1; }
 743     | FunctionExpression { $$ = $1; }
 744     | Parenthetical { $$ = $1; }
 745     | AutoComplete { driver.mode_ = CYDriver::AutoPrimary; YYACCEPT; }
 746     ;
 747 /* }}} */
 748 /* 11.1.4.1 Array Initialiser {{{ */
 749 ArrayLiteral
 750     : "[" LexPushInOff ElementListOpt LexPopIn "]" { $$ = CYNew CYArray($3); }
 751     ;
 752
 753 Element
 754     : AssignmentExpression { $$ = $1; }
 755     ;
 756
 757 ElementOpt
 758     : Element { $$ = $1; }
 759     | LexSetRegExp { $$ = NULL; }
 760     ;
 761
 762 ElementList
 763     : ElementOpt "," ElementListOpt { $$ = CYNew CYElement($1, $3); }
 764     | Element { $$ = CYNew CYElement($1, NULL); }
 765     ;
 766
 767 ElementListOpt
 768     : ElementList { $$ = $1; }
 769     | LexSetRegExp { $$ = NULL; }
 770     ;
 771 /* }}} */
 772 /* 11.1.4.2 Array Comprehension {{{ */
 773 PrimaryExpression
 774     : "[" LexPushInOff AssignmentExpression ComprehensionForList LexPopIn "]" { $$ = CYNew CYArrayComprehension($3, $4); }
 775     ;
 776
 777 ComprehensionForList
 778     : "for" Binding "in" Expression ComprehensionForListOpt { $$ = CYNew CYForInComprehension($2, $4, $5); }
 779     | "for" Binding "of" Expression ComprehensionForListOpt { $$ = CYNew CYForOfComprehension($2, $4, $5); }
 780     ;
 781
 782 ComprehensionForListOpt
 783     : ComprehensionForList { $$ = $1; }
 784     | "if" Expression { $$ = CYNew CYIfComprehension($2); }
 785     | { $$ = NULL; }
 786     ;
 787 /* }}} */
 788 /* 11.1.5 Object Initialiser {{{ */
 789 ObjectLiteral
 790     : BRACE LexPushInOff PropertyDefinitionListOpt LexPopIn "}" { $$ = CYNew CYObject($3); }
 791     ;
 792
 793 PropertyDefinitionList_
 794     : "," PropertyDefinitionList { $$ = $2; }
 795     | "," { $$ = NULL; }
 796     | { $$ = NULL; }
 797     ;
 798
 799 PropertyDefinitionList
 800     : PropertyDefinition PropertyDefinitionList_ { $1->SetNext($2); $$ = $1; }
 801     ;
 802
 803 PropertyDefinitionListOpt
 804     : PropertyDefinitionList { $$ = $1; }
 805     | { $$ = NULL; }
 806     ;
 807
 808 PropertyDefinition
 809     // XXX: this should be IdentifierName
 810     : LexSetRegExp Identifier { $$ = CYNew CYProperty($2, CYNew CYVariable($2)); }
 811     | PropertyName ":" AssignmentExpression { $$ = CYNew CYProperty($1, $3); }
 812     //| MethodDefinition
 813     ;
 814
 815 PropertyName_
 816     : IdentifierName { $$ = $1; }
 817     | StringLiteral { $$ = $1; }
 818     | NumericLiteral { $$ = $1; }
 819     ;
 820
 821 PropertyName
 822     : LexSetRegExp PropertyName_ { $$ = $2; }
 823     ;
 824 /* }}} */
 825
 826 /* 11.2 Left-Hand-Side Expressions {{{ */
 827 MemberAccess
 828     : "[" LexPushInOff Expression LexPopIn "]" { $$ = CYNew CYDirectMember(NULL, $3); }
 829     | "." IdentifierName { $$ = CYNew CYDirectMember(NULL, CYNew CYString($2)); }
 830     | "." AutoComplete { driver.mode_ = CYDriver::AutoDirect; YYACCEPT; }
 831     ;
 832
 833 MemberExpression_
 834     : MemberExpression { $$ = $1; }
 835     //| "super" { $$ = $1; }
 836     ;
 837
 838 MemberExpression
 839     : LexSetRegExp PrimaryExpression { $$ = $2; }
 840     | MemberExpression_ { driver.context_ = $1; } MemberAccess { $3->SetLeft($1); $$ = $3; }
 841     | LexSetRegExp "new" MemberExpression Arguments { $$ = CYNew cy::Syntax::New($3, $4); }
 842     ;
 843
 844 NewExpression
 845     : MemberExpression { $$ = $1; }
 846     | LexSetRegExp "new" NewExpression { $$ = CYNew cy::Syntax::New($3, NULL); }
 847     ;
 848
 849 CallExpression_
 850     : MemberExpression_
 851     | CallExpression
 852     ;
 853
 854 CallExpression
 855     : CallExpression_ Arguments { $$ = CYNew CYCall($1, $2); }
 856     | CallExpression { driver.context_ = $1; } MemberAccess { $3->SetLeft($1); $$ = $3; }
 857     ;
 858
 859 Arguments
 860     : "(" LexPushInOff ArgumentListOpt LexPopIn ")" { $$ = $3; }
 861     ;
 862
 863 ArgumentList_
 864     : "," ArgumentList { $$ = $2; }
 865     | { $$ = NULL; }
 866     ;
 867
 868 ArgumentList
 869     : AssignmentExpression ArgumentList_ { $$ = CYNew CYArgument(NULL, $1, $2); }
 870     ;
 871
 872 ArgumentListOpt
 873     : ArgumentList { $$ = $1; }
 874     | LexSetRegExp { $$ = NULL; }
 875     ;
 876
 877 LeftHandSideExpression
 878     : NewExpression { $$ = $1; }
 879     | CallExpression { $$ = $1; }
 880     ;
 881 /* }}} */
 882 /* 11.3 Postfix Expressions {{{ */
 883 PostfixExpression
 884     : %prec "" LeftHandSideExpression { $$ = $1; }
 885     | LeftHandSideExpression "++" { $$ = CYNew CYPostIncrement($1); }
 886     | LeftHandSideExpression "--" { $$ = CYNew CYPostDecrement($1); }
 887     ;
 888 /* }}} */
 889 /* 11.4 Unary Operators {{{ */
 890 UnaryExpression_
 891     : "delete" UnaryExpression { $$ = CYNew CYDelete($2); }
 892     | "void" UnaryExpression { $$ = CYNew CYVoid($2); }
 893     | "typeof" UnaryExpression { $$ = CYNew CYTypeOf($2); }
 894     | "++" UnaryExpression { $$ = CYNew CYPreIncrement($2); }
 895     | "\n++" UnaryExpression { $$ = CYNew CYPreIncrement($2); }
 896     | "--" UnaryExpression { $$ = CYNew CYPreDecrement($2); }
 897     | "\n--" UnaryExpression { $$ = CYNew CYPreDecrement($2); }
 898     | "+" UnaryExpression { $$ = CYNew CYAffirm($2); }
 899     | "-" UnaryExpression { $$ = CYNew CYNegate($2); }
 900     | "~" UnaryExpression { $$ = CYNew CYBitwiseNot($2); }
 901     | "!" UnaryExpression { $$ = CYNew CYLogicalNot($2); }
 902     ;
 903
 904 UnaryExpression
 905     : PostfixExpression { $$ = $1; }
 906     | LexSetRegExp UnaryExpression_ { $$ = $2; }
 907     ;
 908 /* }}} */
 909 /* 11.5 Multiplicative Operators {{{ */
 910 MultiplicativeExpression
 911     : UnaryExpression { $$ = $1; }
 912     | MultiplicativeExpression "*" UnaryExpression { $$ = CYNew CYMultiply($1, $3); }
 913     | MultiplicativeExpression "/" UnaryExpression { $$ = CYNew CYDivide($1, $3); }
 914     | MultiplicativeExpression "%" UnaryExpression { $$ = CYNew CYModulus($1, $3); }
 915     ;
 916 /* }}} */
 917 /* 11.6 Additive Operators {{{ */
 918 AdditiveExpression
 919     : MultiplicativeExpression { $$ = $1; }
 920     | AdditiveExpression "+" MultiplicativeExpression { $$ = CYNew CYAdd($1, $3); }
 921     | AdditiveExpression "-" MultiplicativeExpression { $$ = CYNew CYSubtract($1, $3); }
 922     ;
 923 /* }}} */
 924 /* 11.7 Bitwise Shift Operators {{{ */
 925 ShiftExpression
 926     : AdditiveExpression { $$ = $1; }
 927     | ShiftExpression "<<" AdditiveExpression { $$ = CYNew CYShiftLeft($1, $3); }
 928     | ShiftExpression ">>" AdditiveExpression { $$ = CYNew CYShiftRightSigned($1, $3); }
 929     | ShiftExpression ">>>" AdditiveExpression { $$ = CYNew CYShiftRightUnsigned($1, $3); }
 930     ;
 931 /* }}} */
 932 /* 11.8 Relational Operators {{{ */
 933 RelationalExpression
 934     : ShiftExpression { $$ = $1; }
 935     | RelationalExpression "<" ShiftExpression { $$ = CYNew CYLess($1, $3); }
 936     | RelationalExpression ">" ShiftExpression { $$ = CYNew CYGreater($1, $3); }
 937     | RelationalExpression "<=" ShiftExpression { $$ = CYNew CYLessOrEqual($1, $3); }
 938     | RelationalExpression ">=" ShiftExpression { $$ = CYNew CYGreaterOrEqual($1, $3); }
 939     | RelationalExpression "instanceof" ShiftExpression { $$ = CYNew CYInstanceOf($1, $3); }
 940     | RelationalExpression "in" ShiftExpression { $$ = CYNew CYIn($1, $3); }
 941     ;
 942 /* }}} */
 943 /* 11.9 Equality Operators {{{ */
 944 EqualityExpression
 945     : RelationalExpression { $$ = $1; }
 946     | EqualityExpression "==" RelationalExpression { $$ = CYNew CYEqual($1, $3); }
 947     | EqualityExpression "!=" RelationalExpression { $$ = CYNew CYNotEqual($1, $3); }
 948     | EqualityExpression "===" RelationalExpression { $$ = CYNew CYIdentical($1, $3); }
 949     | EqualityExpression "!==" RelationalExpression { $$ = CYNew CYNotIdentical($1, $3); }
 950     ;
 951 /* }}} */
 952 /* 11.10 Binary Bitwise Operators {{{ */
 953 BitwiseANDExpression
 954     : EqualityExpression { $$ = $1; }
 955     | BitwiseANDExpression "&" EqualityExpression { $$ = CYNew CYBitwiseAnd($1, $3); }
 956     ;
 957
 958 BitwiseXORExpression
 959     : BitwiseANDExpression { $$ = $1; }
 960     | BitwiseXORExpression "^" BitwiseANDExpression { $$ = CYNew CYBitwiseXOr($1, $3); }
 961     ;
 962
 963 BitwiseORExpression
 964     : BitwiseXORExpression { $$ = $1; }
 965     | BitwiseORExpression "|" BitwiseXORExpression { $$ = CYNew CYBitwiseOr($1, $3); }
 966     ;
 967 /* }}} */
 968 /* 11.11 Binary Logical Operators {{{ */
 969 LogicalANDExpression
 970     : BitwiseORExpression { $$ = $1; }
 971     | LogicalANDExpression "&&" BitwiseORExpression { $$ = CYNew CYLogicalAnd($1, $3); }
 972     ;
 973
 974 LogicalORExpression
 975     : LogicalANDExpression { $$ = $1; }
 976     | LogicalORExpression "||" LogicalANDExpression { $$ = CYNew CYLogicalOr($1, $3); }
 977     ;
 978 /* }}} */
 979 /* 11.12 Conditional Operator ( ? : ) {{{ */
 980 ConditionalExpression
 981     : LogicalORExpression { $$ = $1; }
 982     | LogicalORExpression "?" LexPushInOff AssignmentExpression LexPopIn ":" AssignmentExpression { $$ = CYNew CYCondition($1, $4, $7); }
 983     ;
 984 /* }}} */
 985 /* 11.13 Assignment Operators {{{ */
 986 AssignmentExpression
 987     : ConditionalExpression { $$ = $1; }
 988     | ArrowFunction { $$ = $1; }
 989     | LeftHandSideExpression "=" AssignmentExpression { $$ = CYNew CYAssign($1, $3); }
 990     | LeftHandSideExpression "*=" AssignmentExpression { $$ = CYNew CYMultiplyAssign($1, $3); }
 991     | LeftHandSideExpression "/=" AssignmentExpression { $$ = CYNew CYDivideAssign($1, $3); }
 992     | LeftHandSideExpression "%=" AssignmentExpression { $$ = CYNew CYModulusAssign($1, $3); }
 993     | LeftHandSideExpression "+=" AssignmentExpression { $$ = CYNew CYAddAssign($1, $3); }
 994     | LeftHandSideExpression "-=" AssignmentExpression { $$ = CYNew CYSubtractAssign($1, $3); }
 995     | LeftHandSideExpression "<<=" AssignmentExpression { $$ = CYNew CYShiftLeftAssign($1, $3); }
 996     | LeftHandSideExpression ">>=" AssignmentExpression { $$ = CYNew CYShiftRightSignedAssign($1, $3); }
 997     | LeftHandSideExpression ">>>=" AssignmentExpression { $$ = CYNew CYShiftRightUnsignedAssign($1, $3); }
 998     | LeftHandSideExpression "&=" AssignmentExpression { $$ = CYNew CYBitwiseAndAssign($1, $3); }
 999     | LeftHandSideExpression "^=" AssignmentExpression { $$ = CYNew CYBitwiseXOrAssign($1, $3); }
1000     | LeftHandSideExpression "|=" AssignmentExpression { $$ = CYNew CYBitwiseOrAssign($1, $3); }
1001     ;
1002 /* }}} */
1003 /* 11.14 Comma Operator {{{ */
1004 Expression_
1005     : "," Expression { $$ = $2; }
1006     | { $$ = CYNew CYCompound(); }
1007     ;
1008
1009 Expression
1010     : AssignmentExpression Expression_ { $2->AddPrev($1); $$ = $2; }
1011     ;
1012
1013 ExpressionOpt
1014     : Expression { $$ = $1; }
1015     | LexSetRegExp { $$ = NULL; }
1016     ;
1017 /* }}} */
1018
1019 /* 12 Statements {{{ */
1020 Statement__
1021     : Block { $$ = $1; }
1022     | VariableStatement { $$ = $1; }
1023     | EmptyStatement { $$ = $1; }
1024     | IfStatement { $$ = $1; }
1025     | BreakableStatement { $$ = $1; }
1026     | ContinueStatement { $$ = $1; }
1027     | BreakStatement { $$ = $1; }
1028     | ReturnStatement { $$ = $1; }
1029     | WithStatement { $$ = $1; }
1030     | LabelledStatement { $$ = $1; }
1031     | ThrowStatement { $$ = $1; }
1032     | TryStatement { $$ = $1; }
1033     | DebuggerStatement { $$ = $1; }
1034     ;
1035
1036 Statement_
1037     : LexSetRegExp Statement__ { $$ = $2; }
1038     | ExpressionStatement { $$ = $1; }
1039     ;
1040
1041 Statement
1042     : LexSetStatement Statement_ { $$ = $2; }
1043     ;
1044
1045 Declaration__
1046     : FunctionDeclaration { $$ = $1; }
1047     | LexicalDeclaration { $$ = $1; }
1048     ;
1049
1050 Declaration_
1051     : LexSetRegExp Declaration__ { $$ = $2; }
1052     ;
1053
1054 Declaration
1055     : LexSetStatement Declaration_ { $$ = $2; }
1056     ;
1057
1058 BreakableStatement
1059     : IterationStatement { $$ = $1; }
1060     | SwitchStatement { $$ = $1; }
1061     ;
1062 /* }}} */
1063 /* 12.1 Block {{{ */
1064 Block_
1065     : BRACE StatementListOpt "}" { $$ = $2; }
1066     ;
1067
1068 Block
1069     : ";{" StatementListOpt "}" { $$ = CYNew CYBlock($2); }
1070     ;
1071
1072 StatementList
1073     : StatementListItem StatementListOpt { $1->SetNext($2); $$ = $1; }
1074     ;
1075
1076 StatementListOpt
1077     : StatementList { $$ = $1; }
1078     | LexSetStatement LexSetRegExp { $$ = NULL; }
1079     ;
1080
1081 StatementListItem
1082     : Statement { $$ = $1; }
1083     | Declaration { $$ = $1; }
1084     ;
1085 /* }}} */
1086
1087 /* 12.2 Declarations {{{ */
1088 BindingIdentifier
1089     : Identifier { $$ = $1; }
1090     ;
1091
1092 Binding
1093     : BindingIdentifier
1094     ;
1095
1096 // XXX: BindingPattern
1097 /* }}} */
1098 /* 12.2.1 Let and Const Declarations {{{ */
1099 LexicalDeclaration
1100     : LetOrConst VariableDeclarationList Terminator { $$ = CYNew CYVar($2); }
1101     ;
1102
1103 LetOrConst
1104     : "let"
1105     | "const"
1106     ;
1107 /* }}} */
1108 /* 12.2.2 Variable Statement {{{ */
1109 VariableStatement
1110     : Var_ VariableDeclarationList Terminator { $$ = CYNew CYVar($2); }
1111     ;
1112
1113 VariableDeclarationList_
1114     : "," VariableDeclarationList { $$ = $2; }
1115     | { $$ = NULL; }
1116     ;
1117
1118 VariableDeclarationList
1119     : VariableDeclaration VariableDeclarationList_ { $$ = CYNew CYDeclarations($1, $2); }
1120     ;
1121
1122 VariableDeclaration
1123     : BindingIdentifier InitialiserOpt { $$ = CYNew CYDeclaration($1, $2); }
1124     // XXX: | BindingPattern Initialiser { $$ = CYNew CYDeclaration($1, $2); }
1125     ;
1126
1127 Initialiser
1128     : "=" AssignmentExpression { $$ = $2; }
1129     ;
1130
1131 InitialiserOpt
1132     : Initialiser { $$ = $1; }
1133     | { $$ = NULL; }
1134     ;
1135 /* }}} */
1136 /* 12.2.4 Destructuring Binding Patterns {{{ */
1137 // XXX: *
1138
1139 BindingElement
1140     : SingleNameBinding { $$ = $1; }
1141     ;
1142
1143 SingleNameBinding
1144     : BindingIdentifier InitialiserOpt { $$ = CYNew CYDeclaration($1, $2); }
1145     ;
1146 /* }}} */
1147
1148 /* 12.3 Empty Statement {{{ */
1149 EmptyStatement
1150     : ";" { $$ = CYNew CYEmpty(); }
1151     ;
1152 /* }}} */
1153 /* 12.4 Expression Statement {{{ */
1154 ExpressionStatement
1155     : Expression Terminator { $$ = CYNew CYExpress($1); }
1156     ;
1157 /* }}} */
1158 /* 12.5 The if Statement {{{ */
1159 ElseStatementOpt
1160     : "else" Statement { $$ = $2; }
1161     | %prec "if" { $$ = NULL; }
1162     ;
1163
1164 IfStatement
1165     : "if" "(" Expression ")" Statement ElseStatementOpt { $$ = CYNew CYIf($3, $5, $6); }
1166     ;
1167 /* }}} */
1168
1169 /* 12.6.1 The do-while Statement {{{ */
1170 IterationStatement
1171     : "do" Statement "while" "(" Expression ")" TerminatorOpt { $$ = CYNew CYDoWhile($5, $2); }
1172     ;
1173 /* }}} */
1174 /* 12.6.2 The while Statement {{{ */
1175 IterationStatement
1176     : "while" "(" Expression ")" Statement { $$ = CYNew CYWhile($3, $5); }
1177     ;
1178 /* }}} */
1179 /* 12.6.3 The for Statement {{{ */
1180 IterationStatement
1181     : "for" "(" LexPushInOn ForStatementInitialiser LexPopIn ";" ExpressionOpt ";" ExpressionOpt ")" Statement { $$ = CYNew CYFor($4, $7, $9, $11); }
1182     ;
1183
1184 ForStatementInitialiser
1185     : ExpressionOpt { $$ = $1; }
1186     | LexSetRegExp Var_ VariableDeclarationList { $$ = CYNew CYForDeclarations($3); }
1187     ;
1188 /* }}} */
1189 /* 12.6.4 The for-in and for-of Statements {{{ */
1190 IterationStatement
1191     : "for" "(" LexPushInOn ForInStatementInitialiser LexPopIn "!in" Expression ")" Statement { $$ = CYNew CYForIn($4, $7, $9); }
1192     | "for" "(" LexPushInOn ForInStatementInitialiser LexPopIn "of" Expression ")" Statement { $$ = CYNew CYForOf($4, $7, $9); }
1193     ;
1194
1195 ForInStatementInitialiser
1196     : LeftHandSideExpression { $$ = $1; }
1197     | LexSetRegExp Var_ VariableDeclaration { $$ = $3; }
1198     ;
1199 /* }}} */
1200
1201 /* 12.7 The continue Statement {{{ */
1202 ContinueStatement
1203     : "continue" "\n" StrictSemi { $$ = CYNew CYContinue(NULL); }
1204     | "continue" IdentifierOpt Terminator { $$ = CYNew CYContinue($2); }
1205     ;
1206 /* }}} */
1207 /* 12.8 The break Statement {{{ */
1208 BreakStatement
1209     : "break" "\n" StrictSemi { $$ = CYNew CYBreak(NULL); }
1210     | "break" IdentifierOpt Terminator { $$ = CYNew CYBreak($2); }
1211     ;
1212 /* }}} */
1213 /* 12.9 The return Statement {{{ */
1214 ReturnStatement
1215     : "return" "\n" StrictSemi { $$ = CYNew CYReturn(NULL); }
1216     | "return" ExpressionOpt Terminator { $$ = CYNew CYReturn($2); }
1217     ;
1218 /* }}} */
1219 /* 12.10 The with Statement {{{ */
1220 WithStatement
1221     : "with" "(" Expression ")" Statement { $$ = CYNew CYWith($3, $5); }
1222     ;
1223 /* }}} */
1224
1225 /* 12.11 The switch Statement {{{ */
1226 SwitchStatement
1227     : "switch" "(" Expression ")" CaseBlock { $$ = CYNew CYSwitch($3, $5); }
1228     ;
1229
1230 CaseBlock
1231     : BRACE CaseClausesOpt "}" { $$ = $2; }
1232     ;
1233
1234 CaseClause
1235     : "case" Expression ":" StatementListOpt { $$ = CYNew CYClause($2, $4); }
1236     ;
1237
1238 CaseClausesOpt
1239     : CaseClause CaseClausesOpt { $1->SetNext($2); $$ = $1; }
1240     | DefaultClause CaseClausesOpt { $1->SetNext($2); $$ = $1; }
1241     | { $$ = NULL; }
1242     ;
1243
1244 DefaultClause
1245     : "default" ":" StatementListOpt { $$ = CYNew CYClause(NULL, $3); }
1246     ;
1247 /* }}} */
1248 /* 12.12 Labelled Statements {{{ */
1249 LabelledStatement
1250     : Identifier ":" Statement { $$ = CYNew CYLabel($1, $3); }
1251     ;
1252 /* }}} */
1253 /* 12.13 The throw Statement {{{ */
1254 ThrowStatement
1255     : "throw" "\n" StrictSemi { YYABORT; }
1256     | "throw" Expression Terminator { $$ = CYNew cy::Syntax::Throw($2); }
1257     ;
1258 /* }}} */
1259 /* 12.14 The try Statement {{{ */
1260 TryStatement
1261     : "try" Block_ CatchOpt FinallyOpt { $$ = CYNew cy::Syntax::Try($2, $3, $4); }
1262     ;
1263
1264 CatchOpt
1265     : "catch" "(" Identifier ")" Block_ { $$ = CYNew cy::Syntax::Catch($3, $5); }
1266     | { $$ = NULL; }
1267     ;
1268
1269 FinallyOpt
1270     : "finally" Block_ { $$ = CYNew CYFinally($2); }
1271     | { $$ = NULL; }
1272     ;
1273 /* }}} */
1274 /* 12.14 The debugger Statement {{{ */
1275 DebuggerStatement
1276     : "debugger" Terminator { $$ = CYNew CYDebugger(); }
1277     ;
1278 /* }}} */
1279
1280 /* 13.1 Function Definitions {{{ */
1281 FunctionDeclaration
1282     : ";function" Identifier "(" FormalParameterListOpt ")" BRACE FunctionBody "}" { $$ = CYNew CYFunctionStatement($2, $4, $7); }
1283     ;
1284
1285 FunctionExpression
1286     : "function" IdentifierOpt "(" LexPushInOff FormalParameterListOpt LexPopIn ")" BRACE LexPushInOff FunctionBody LexPopIn "}" { $$ = CYNew CYFunctionExpression($2, $5, $10); }
1287     ;
1288
1289 FormalParameterList_
1290     : "," FormalParameterList { $$ = $2; }
1291     | { $$ = NULL; }
1292     ;
1293
1294 FormalParameterList
1295     // XXX: : FunctionRestParameter { $$ = $1; }
1296     : FormalParameter FormalParameterList_ { $$ = CYNew CYFunctionParameter($1, $2); }
1297     ;
1298
1299 FormalParameterListOpt
1300     : FormalParameterList
1301     | { $$ = NULL; }
1302     ;
1303
1304 /* XXX: FunctionRestParameter
1305     : "..." BindingIdentifier { $$ = CYNew CYFunctionRestParameter($2); }
1306     ;*/
1307
1308 FormalParameter
1309     : BindingElement { $$ = $1; }
1310     ;
1311
1312 FunctionBody
1313     : StatementListOpt { $$ = $1; }
1314     ;
1315 /* }}} */
1316 /* 13.2 Arrow Function Definitions {{{ */
1317 ArrowFunction
1318     : LexSetRegExp ArrowParameters "=>" LexNoBrace ConciseBody { $$ = CYNew CYFatArrow($2, $5); }
1319     ;
1320
1321 ArrowParameters
1322     : BindingIdentifier { $$ = CYNew CYFunctionParameter(CYNew CYDeclaration($1)); }
1323     //| ParentheticalOpt { $$ = $1; }
1324     ;
1325
1326 ConciseBody
1327     : AssignmentExpression { $$ = CYNew CYReturn($1); }
1328     | ";{" LexPushInOff FunctionBody LexPopIn "}" { $$ = $3; }
1329     ;
1330 /* }}} */
1331 /* 14 Program {{{ */
1332 Program
1333     : ProgramBodyOpt { driver.program_ = CYNew CYProgram($1); }
1334     ;
1335
1336 ProgramBody
1337     : StatementList { $$ = $1; }
1338     ;
1339
1340 ProgramBodyOpt
1341     : ProgramBody { $$ = $1; }
1342     | LexSetStatement LexSetRegExp { $$ = NULL; }
1343     ;
1344 /* }}} */
1345
1346 @begin ObjectiveC
1347 /* Cycript (Objective-C): Type Encoding {{{ */
1348 SuffixedType
1349     : IdentifierOpt { $$ = CYNew CYTypedIdentifier($1); }
1350     | "(" LexPushInOff PrefixedType LexPopIn ")" { $$ = $3; }
1351     | SuffixedType "[" NumericLiteral "]" { CYSetLast($1->type_) = CYNew CYTypeArrayOf($3->Value()); $$ = $1; }
1352     ;
1353
1354 PrefixedType
1355     : SuffixedType { $$ = $1; }
1356     | "const" PrefixedType { CYSetLast($2->type_) = CYNew CYTypeConstant(); $$ = $2; }
1357     | "*" PrefixedType { CYSetLast($2->type_) = CYNew CYTypePointerTo(); $$ = $2; }
1358     ;
1359
1360 QualifiedType
1361     : Variable { $$ = CYNew CYTypeVariable($1); }
1362     | "const" QualifiedType { $$ = CYNew CYTypeConstant($2); }
1363     ;
1364
1365 ModifiedType
1366     : QualifiedType { $$ = $1; }
1367     | QualifiedType "*" { $$ = CYNew CYTypePointerTo($1); }
1368     | QualifiedType "const" { $$ = CYNew CYTypeConstant($1); }
1369     ;
1370
1371 TypedIdentifier
1372     : QualifiedType PrefixedType { CYSetLast($2->type_) = $1; $$ = $2;}
1373     ;
1374
1375 EncodedType
1376     : TypedIdentifier { $$ = CYNew CYEncodedType($1->type_); }
1377     ;
1378
1379 PrimaryExpression
1380     : AtEncode "(" EncodedType ")" { $$ = $3; }
1381     ;
1382 /* }}} */
1383 /* Cycript (Objective-C): @class Declaration {{{ */
1384 ClassSuperOpt
1385     /* XXX: why the hell did I choose MemberExpression? */
1386     : ":" LexSetRegExp MemberExpression { $$ = $3; }
1387     | { $$ = NULL; }
1388     ;
1389
1390 ClassFieldListOpt
1391     : Expression Identifier ";" ClassFieldListOpt { $$ = CYNew CYField($1, $2, $4); }
1392     | { $$ = NULL; }
1393     ;
1394
1395 ClassFields
1396     : BRACE ClassFieldListOpt "}" { $$ = $2; }
1397     ;
1398
1399 MessageScope
1400     : "+" { $$ = false; }
1401     | "-" { $$ = true; }
1402     ;
1403
1404 TypeOpt
1405     : "(" LexSetRegExp EncodedType ")" { $$ = $3; }
1406     | "(" LexSetRegExp "void" ")" { $$ = CYNew CYString("v"); }
1407     | { $$ = NULL; }
1408     ;
1409
1410 MessageParameter
1411     : Word ":" TypeOpt Identifier { $$ = CYNew CYMessageParameter($1, $3, $4); }
1412     ;
1413
1414 MessageParameterList
1415     : MessageParameter MessageParameterListOpt { $1->SetNext($2); $$ = $1; }
1416     ;
1417
1418 MessageParameterListOpt
1419     : MessageParameterList { $$ = $1; }
1420     | { $$ = NULL; }
1421     ;
1422
1423 MessageParameters
1424     : MessageParameterList { $$ = $1; }
1425     | Word { $$ = CYNew CYMessageParameter($1, NULL, NULL); }
1426     ;
1427
1428 ClassMessageDeclaration
1429     : MessageScope TypeOpt MessageParameters BRACE FunctionBody "}" { $$ = CYNew CYMessage($1, $2, $3, $5); }
1430     ;
1431
1432 ClassMessageDeclarationListOpt
1433     : ClassMessageDeclarationListOpt ClassMessageDeclaration { $2->SetNext($1); $$ = $2; }
1434     | ClassMessageDeclarationListOpt Comment { $$ = $1; }
1435     | { $$ = NULL; }
1436     ;
1437
1438 ClassName
1439     : Identifier { $$ = $1; }
1440     | "(" AssignmentExpression ")" { $$ = $2; }
1441     ;
1442
1443 ClassNameOpt
1444     : ClassName { $$ = $1; }
1445     | { $$ = NULL; }
1446     ;
1447
1448 // XXX: this should be AssignmentExpressionNoRight
1449 ClassProtocols
1450     : ShiftExpression ClassProtocolsOpt { $$ = CYNew CYProtocol($1, $2); }
1451     ;
1452
1453 ClassProtocolsOpt
1454     : "," ClassProtocols { $$ = $2; }
1455     | { $$ = NULL; }
1456     ;
1457
1458 ClassProtocolListOpt
1459     : "<" ClassProtocols ">" { $$ = $2; }
1460     | { $$ = NULL; }
1461     ;
1462
1463 ClassExpression
1464     : "@implementation" LexPushInOff ClassNameOpt ClassSuperOpt ClassProtocolListOpt ClassFields ClassMessageDeclarationListOpt LexPopIn "@end" { $$ = CYNew CYClassExpression($3, $4, $5, $6, $7); }
1465     ;
1466
1467 ClassStatement
1468     : ";@implementation" ClassName ClassSuperOpt ClassProtocolListOpt ClassFields ClassMessageDeclarationListOpt "@end" { $$ = CYNew CYClassStatement($2, $3, $4, $5, $6); }
1469     ;
1470
1471 CategoryName
1472     : "(" WordOpt ")"
1473     ;
1474
1475 CategoryStatement
1476     : ";@implementation" ClassName CategoryName ClassMessageDeclarationListOpt "@end" { $$ = CYNew CYCategory($2, $4); }
1477     ;
1478
1479 PrimaryExpression
1480     : ClassExpression { $$ = $1; }
1481     ;
1482
1483 Statement__
1484     : ClassStatement { $$ = $1; }
1485     | CategoryStatement { $$ = $1; }
1486     ;
1487 /* }}} */
1488 /* Cycript (Objective-C): Send Message {{{ */
1489 VariadicCall
1490     : "," AssignmentExpression VariadicCall { $$ = CYNew CYArgument(NULL, $2, $3); }
1491     | { $$ = NULL; }
1492     ;
1493
1494 SelectorWordOpt
1495     : WordOpt { driver.contexts_.back().words_.push_back($1); } { $$ = $1; }
1496     | AutoComplete { driver.mode_ = CYDriver::AutoMessage; YYACCEPT; }
1497     ;
1498
1499 SelectorCall_
1500     : SelectorCall { $$ = $1; }
1501     | VariadicCall { $$ = $1; }
1502     ;
1503
1504 SelectorCall
1505     : SelectorWordOpt ":" AssignmentExpression SelectorCall_ { $$ = CYNew CYArgument($1 ?: CYNew CYBlank(), $3, $4); }
1506     ;
1507
1508 SelectorList
1509     : SelectorCall { $$ = $1; }
1510     | Word { $$ = CYNew CYArgument($1, NULL); }
1511     ;
1512
1513 MessageExpression
1514     : "[" LexPushInOff AssignmentExpression { driver.contexts_.push_back($3); } SelectorList LexPopIn "]" { driver.contexts_.pop_back(); } { $$ = CYNew CYSendDirect($3, $5); }
1515     | "[" LexPushInOff LexSetRegExp "super" { driver.context_ = NULL; } SelectorList LexPopIn "]" { $$ = CYNew CYSendSuper($6); }
1516     ;
1517
1518 SelectorExpression_
1519     : WordOpt ":" SelectorExpressionOpt { $$ = CYNew CYSelectorPart($1, true, $3); }
1520     ;
1521
1522 SelectorExpression
1523     : SelectorExpression_ { $$ = $1; }
1524     | Word { $$ = CYNew CYSelectorPart($1, false, NULL); }
1525     ;
1526
1527 SelectorExpressionOpt
1528     : SelectorExpression_ { $$ = $1; }
1529     | { $$ = NULL; }
1530     ;
1531
1532 PrimaryExpression
1533     : MessageExpression { $$ = $1; }
1534     | "@selector" "(" LexPushInOff SelectorExpression LexPopIn ")" { $$ = CYNew CYSelector($4); }
1535     ;
1536 /* }}} */
1537 /* Cycript (Objective-C): @import Directive {{{ */
1538 PathName
1539     : "/" PathName
1540     | "." PathName
1541     | Word PathName
1542     |
1543     ;
1544
1545 ImportPath
1546     : "<" PathName ">"
1547     | StringLiteral
1548     ;
1549
1550 StatementListItem
1551     : LexSetStatement LexSetRegExp "@import" ImportPath { $$ = CYNew CYImport(); }
1552     ;
1553 /* }}} */
1554 /* Cycript (Objective-C): Boxed Expressions {{{ */
1555 BoxableExpression
1556     : NullLiteral { $$ = $1; }
1557     | BooleanLiteral { $$ = $1; }
1558     | NumericLiteral { $$ = $1; }
1559     | StringLiteral { $$ = $1; }
1560     | ArrayLiteral { $$ = $1; }
1561     | ObjectLiteral { $$ = $1; }
1562     | Parenthetical { $$ = $1; }
1563     ;
1564
1565 PrimaryExpression
1566     : "@" BoxableExpression { $$ = CYNew CYBox($2); }
1567     ;
1568 /* }}} */
1569 /* Cycript (Objective-C): Block Expressions {{{ */
1570 TypedParameterList_
1571     : "," TypedParameterList { $$ = $2; }
1572     | { $$ = NULL; }
1573     ;
1574
1575 TypedParameterList
1576     : TypedIdentifier TypedParameterList_ { $$ = CYNew CYTypedParameter($1, $2); }
1577     ;
1578
1579 TypedParameterListOpt
1580     : TypedParameterList { $$ = $1; }
1581     | { $$ = NULL; }
1582     ;
1583
1584 PrimaryExpression
1585     : "^" ModifiedType "(" LexPushInOff TypedParameterListOpt LexPopIn ")" BRACE LexPushInOff FunctionBody LexPopIn "}" { $$ = CYNew CYObjCBlock($2, $5, $10); }
1586     ;
1587 /* }}} */
1588 @end
1589
1590 @begin C
1591 /* Cycript (C): Pointer Indirection/Addressing {{{ */
1592 LeftHandSideExpression
1593     : LexSetRegExp "*" UnaryExpression { $$ = CYNew CYIndirect($3); }
1594     ;
1595
1596 UnaryExpression_
1597     : "&" UnaryExpression { $$ = CYNew CYAddressOf($2); }
1598     ;
1599
1600 MemberAccess
1601     : "->" "[" Expression "]" { $$ = CYNew CYIndirectMember(NULL, $3); }
1602     | "->" IdentifierName { $$ = CYNew CYIndirectMember(NULL, CYNew CYString($2)); }
1603     | "->" AutoComplete { driver.mode_ = CYDriver::AutoIndirect; YYACCEPT; }
1604     ;
1605 /* }}} */
1606 /* Cycript (C): auto Compatibility {{{ */
1607 Var_
1608     : "auto"
1609     ;
1610 /* }}} */
1611 @end
1612
1613 /* YUI: Documentation Comments {{{ */
1614 Statement__
1615     : Comment { $$ = $1; }
1616     ;
1617 /* }}} */
1618
1619 @begin E4X
1620 /* Lexer State {{{ */
1621 LexPushRegExp
1622     : { driver.PushCondition(CYDriver::RegExpCondition); }
1623     ;
1624
1625 LexPushXMLContent
1626     : { driver.PushCondition(CYDriver::XMLContentCondition); }
1627     ;
1628
1629 LexPushXMLTag
1630     : { driver.PushCondition(CYDriver::XMLTagCondition); }
1631     ;
1632
1633 LexPop
1634     : { driver.PopCondition(); }
1635     ;
1636
1637 LexSetXMLContent
1638     : { driver.SetCondition(CYDriver::XMLContentCondition); }
1639     ;
1640
1641 LexSetXMLTag
1642     : { driver.SetCondition(CYDriver::XMLTagCondition); }
1643     ;
1644 /* }}} */
1645 /* Virtual Tokens {{{ */
1646 XMLWhitespaceOpt
1647     : XMLWhitespace
1648     |
1649     ;
1650 /* }}} */
1651
1652 /* 8.1 Context Keywords {{{ */
1653 Identifier
1654     : "namespace" { $$ = $1; }
1655     | "xml" { $$ = $1; }
1656     ;
1657 /* }}} */
1658 /* 8.3 XML Initialiser Input Elements {{{ */
1659 XMLMarkup
1660     : XMLComment { $$ = $1; }
1661     | XMLCDATA { $$ = $1; }
1662     | XMLPI { $$ = $1; }
1663     ;
1664 /* }}} */
1665
1666 /* 11.1 Primary Expressions {{{ */
1667 PrimaryExpression
1668     : PropertyIdentifier { $$ = CYNew CYPropertyVariable($1); }
1669     | XMLInitialiser { $$ = $1; }
1670     | XMLListInitialiser { $$ = $1; }
1671     ;
1672
1673 PropertyIdentifier
1674     : AttributeIdentifier { $$ = $1; }
1675     | QualifiedIdentifier { $$ = $1; }
1676     | WildcardIdentifier { $$ = $1; }
1677     ;
1678 /* }}} */
1679 /* 11.1.1 Attribute Identifiers {{{ */
1680 AttributeIdentifier
1681     : "@" QualifiedIdentifier_ { $$ = CYNew CYAttribute($2); }
1682     ;
1683
1684 PropertySelector_
1685     : PropertySelector { $$ = $1; }
1686     | "[" LexPushInOff Expression LexPopIn "]" { $$ = CYNew CYSelector($3); }
1687     ;
1688
1689 PropertySelector
1690     : Identifier { $$ = CYNew CYSelector($1); }
1691     | WildcardIdentifier { $$ = $1; }
1692     ;
1693 /* }}} */
1694 /* 11.1.2 Qualified Identifiers {{{ */
1695 QualifiedIdentifier_
1696     : PropertySelector_ { $$ = CYNew CYQualified(NULL, $1); }
1697     | QualifiedIdentifier { $$ = $1; }
1698     ;
1699
1700 QualifiedIdentifier
1701     : PropertySelector "::" PropertySelector_ { $$ = CYNew CYQualified($1, $3); }
1702     ;
1703 /* }}} */
1704 /* 11.1.3 Wildcard Identifiers {{{ */
1705 WildcardIdentifier
1706     : "*" { $$ = CYNew CYWildcard(); }
1707     ;
1708 /* }}} */
1709 /* 11.1.4 XML Initialiser {{{ */
1710 XMLInitialiser
1711     : XMLMarkup { $$ = $1; }
1712     | XMLElement { $$ = $1; }
1713     ;
1714
1715 XMLElement
1716     : "<" LexPushInOff XMLTagContent LexPop LexPopIn "/>"
1717     | "<" LexPushInOff XMLTagContent ">" LexSetXMLContent XMLElementContentOpt "</" LexSetXMLTag XMLTagName XMLWhitespaceOpt LexPop LexPopIn ">"
1718     ;
1719
1720 XMLTagContent
1721     : LexPushXMLTag XMLTagName XMLAttributes
1722     ;
1723
1724 XMLExpression
1725     : BRACE LexPushRegExp Expression LexPop "}"
1726     ;
1727
1728 XMLTagName
1729     : XMLExpression
1730     | XMLName
1731     ;
1732
1733 XMLAttributes_
1734     : XMLAttributes_ XMLAttribute
1735     |
1736     ;
1737
1738 XMLAttributes
1739     : XMLAttributes_ XMLWhitespace XMLExpression XMLWhitespaceOpt
1740     | XMLAttributes_ XMLWhitespaceOpt
1741     ;
1742
1743 XMLAttributeValue_
1744     : XMLExpression
1745     | XMLAttributeValue
1746     ;
1747
1748 XMLAttribute
1749     : XMLWhitespace XMLName XMLWhitespaceOpt "=" XMLWhitespaceOpt XMLAttributeValue_
1750     ;
1751
1752 XMLElementContent
1753     : XMLExpression XMLElementContentOpt
1754     | XMLMarkup XMLElementContentOpt
1755     | XMLText XMLElementContentOpt
1756     | XMLElement XMLElementContentOpt
1757     ;
1758
1759 XMLElementContentOpt
1760     : XMLElementContent
1761     |
1762     ;
1763 /* }}} */
1764 /* 11.1.5 XMLList Initialiser {{{ */
1765 XMLListInitialiser
1766     : "<>" LexPushInOff LexPushXMLContent XMLElementContent LexPop LexPopIn "</>" { $$ = CYNew CYXMLList($4); }
1767     ;
1768 /* }}} */
1769
1770 /* 11.2 Left-Hand-Side Expressions {{{ */
1771 PropertyIdentifier_
1772     : Identifier { $$ = $1; }
1773     | PropertyIdentifier { $$ = $1; }
1774     ;
1775
1776 MemberAccess
1777     : "." PropertyIdentifier { $$ = CYNew CYPropertyMember(NULL, $2); }
1778     | ".." PropertyIdentifier_ { $$ = CYNew CYDescendantMember(NULL, $2); }
1779     | "." "(" Expression ")" { $$ = CYNew CYFilteringPredicate(NULL, $3); }
1780     ;
1781 /* }}} */
1782 /* 12.1 The default xml namespace Statement {{{ */
1783 /* XXX: DefaultXMLNamespaceStatement
1784     : "default" "xml" "namespace" "=" Expression Terminator { $$ = CYNew CYDefaultXMLNamespace($5); }
1785     ;
1786
1787 Statement__
1788     : DefaultXMLNamespaceStatement { $$ = $1; }
1789     ; */
1790 /* }}} */
1791 @end
1792
1793 /* JavaScript 1.7: Array Comprehensions {{{ */
1794 IfComprehension
1795     : "if" "(" Expression ")" { $$ = CYNew CYIfComprehension($3); }
1796     ;
1797
1798 ForComprehension
1799     : "for" "(" Identifier "in" Expression ")" { $$ = CYNew CYForInComprehension($3, $5); }
1800     | "for" "each" "(" Identifier "in" Expression ")" { $$ = CYNew CYForOfComprehension($4, $6); }
1801     ;
1802
1803 ComprehensionList
1804     : ForComprehension ComprehensionListOpt { $1->SetNext($2); $$ = $1; }
1805     ;
1806
1807 ComprehensionListOpt
1808     : ComprehensionList { $$ = $1; }
1809     | IfComprehension { $$ = $1; }
1810     | { $$ = NULL; }
1811     ;
1812
1813 PrimaryExpression
1814     : "[" LexPushInOff AssignmentExpression ComprehensionList LexPopIn "]" { $$ = CYNew CYArrayComprehension($3, $4); }
1815     ;
1816 /* }}} */
1817 /* JavaScript 1.7: for each {{{ */
1818 IterationStatement
1819     : "for" "each" "(" LexPushInOn ForInStatementInitialiser LexPopIn "!in" Expression ")" Statement { $$ = CYNew CYForOf($5, $8, $10); }
1820     ;
1821 /* }}} */
1822 /* JavaScript 1.7: let Statements {{{ */
1823 LetStatement
1824     : "let" "(" VariableDeclarationList ")" Statement { $$ = CYNew CYLetStatement($3, $5); }
1825     ;
1826
1827 Statement__
1828     : LetStatement
1829     ;
1830 /* }}} */
1831
1832 /* JavaScript FTW: Ruby Blocks {{{ */
1833 RubyProcParameterList_
1834     : "," RubyProcParameterList { $$ = $2; }
1835     | { $$ = NULL; }
1836     ;
1837
1838 RubyProcParameterList
1839     : Identifier RubyProcParameterList_ { $$ = CYNew CYFunctionParameter(CYNew CYDeclaration($1), $2); }
1840     | { $$ = NULL; }
1841     ;
1842
1843 RubyProcParameters
1844     : "|" RubyProcParameterList "|" { $$ = $2; }
1845     | "||" { $$ = NULL; }
1846     ;
1847
1848 RubyProcParametersOpt
1849     : RubyProcParameters
1850     | { $$ = NULL; }
1851     ;
1852
1853 RubyProcExpression
1854     : "{" RubyProcParametersOpt StatementListOpt "}" { $$ = CYNew CYRubyProc($2, $3); }
1855     ;
1856
1857 PrimaryExpression
1858     : "{" LexPushInOff RubyProcParameters StatementListOpt LexPopIn "}" { $$ = CYNew CYRubyProc($3, $4); }
1859     ;
1860
1861 CallExpression
1862     : CallExpression_ RubyProcExpression { $$ = CYNew CYRubyBlock($1, $2); }
1863     ;
1864 /* }}} */
1865
1866 %%