configure.ac

   1 dnl Cycript - Optimizing JavaScript Compiler/Runtime
   2 dnl Copyright (C) 2009-2014  Jay Freeman (saurik)
   3
   4 dnl GNU Affero General Public License, Version 3 {{{
   5 dnl
   6 dnl This program is free software: you can redistribute it and/or modify
   7 dnl it under the terms of the GNU Affero General Public License as published by
   8 dnl the Free Software Foundation, either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU Affero General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU Affero General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18 dnl }}}
  19
  20 AC_PREREQ([2.65])
  21 AC_INIT([Cycript], [0.9], [saurik@saurik.com], [cycript], [http://www.cycript.org/])
  22 AC_COPYRIGHT([Copyright (C) 2009-2014  Jay Freeman (saurik)])
  23
  24 AC_CONFIG_SRCDIR([Console.cpp])
  25 AC_CONFIG_AUX_DIR([.])
  26 AC_CONFIG_MACRO_DIR([m4])
  27 AC_CONFIG_HEADERS([config.h])
  28
  29 AM_INIT_AUTOMAKE([-Wall -Werror foreign])
  30 AM_MAINTAINER_MODE([disable])
  31
  32 AC_PROG_CC
  33 AC_PROG_CXX
  34 AC_PROG_OBJCXX
  35
  36 AM_PROG_AR
  37 AC_PROG_INSTALL
  38
  39 LT_INIT([disable-static])
  40
  41 AC_LANG([C++])
  42
  43 AX_CXX_COMPILE_STDCXX_11([ext], [mandatory])
  44 OBJCXXFLAGS="${OBJCXXFLAGS} ${CXXFLAGS##*' '}"
  45
  46 PKG_PROG_PKG_CONFIG([0.22])
  47
  48 AC_PATH_PROG([GIT], [git])
  49 AC_PATH_PROG([TIME], [time])
  50
  51 dnl CY_CHECK_PROGS_VERSION {{{
  52 AC_DEFUN([CY_CHECK_PROGS_VERSION], [
  53     AC_ARG_VAR(]$1[, ]$3[)
  54
  55     AC_MSG_CHECKING(for ]$2[ >= ]$5[)
  56     AC_PATH_PROGS_FEATURE_CHECK(]$1[, ]$2[,
  57         AS_VAR_SET(version, [`$ac_path_]$1[ ]$4[`])
  58         AS_VAR_IF(version, [], ,
  59             AS_VERSION_COMPARE($version, ]$5[, ,
  60                 ac_cv_path_]$1[=$ac_path_]$1[,
  61                 ac_cv_path_]$1[=$ac_path_]$1[))
  62     , AC_MSG_RESULT(no))
  63
  64     AS_IF([true], [
  65         AC_SUBST(]$1[, $ac_cv_path_]$1[)
  66         AC_MSG_RESULT($]$1[)
  67     ], AS_IF([true], [
  68         AC_MSG_ERROR(You need ]$2[ ]$5[ or greater)
  69     ], [
  70         AC_SUBST(]$1[, [:])
  71         AC_MSG_RESULT([no])
  72     ]))
  73 ]) dnl }}}
  74
  75 CY_CHECK_PROGS_VERSION([BISON], [bison], [GNU Project parser generator (yacc replacement)],
  76     [-V | $SED -e '1 s/^bison (GNU Bison) \(.*\)$/\1/p;d'], [2.3])
  77 CY_CHECK_PROGS_VERSION([FLEX], [flex], [the fast lexical analyser generator],
  78     [--version | $SED -e '1 s/^@<:@^0-9.@:>@* \(@<:@0-9.@:>@*\).*$/\1/p;d'], [2.5.33])
  79 CY_CHECK_PROGS_VERSION([GPERF], [gperf], [perfect hash function generator],
  80     [--version | $SED -e '1 s/^.* \(@<:@0-9.@:>@*\)$/\1/p;d'], [3.0.3])
  81 CY_CHECK_PROGS_VERSION([GNUTAR], [tar gtar gnutar], [a very sticky lump of files],
  82     [--version | $SED -e '1 s/^tar (GNU tar) \(.*\)$/\1/p;d'], [1.19])
  83
  84 AC_MSG_CHECKING([bison for %code{}])
  85 echo '%code{}%%_:' >conftest.y
  86 if $BISON conftest.y -o/dev/null 2>/dev/null; then
  87     AC_LIB_APPENDTOVAR([CY_FILTERS], [Bison24])
  88     AC_MSG_RESULT([yes])
  89 else
  90     AC_LIB_APPENDTOVAR([CY_FILTERS], [Bison23])
  91     AC_MSG_RESULT([no])
  92 fi
  93
  94 rm -f conftest.y
  95 AC_SUBST([CY_FILTERS])
  96
  97 dnl CY_TRY {{{
  98 AC_DEFUN([CY_SUCCESS], [cy_good=1])
  99 AC_DEFUN([CY_FAILURE], [cy_good=0])
 100
 101 AC_DEFUN([CY_TRY], [
 102     cy_save=$]$1[
 103         AC_LIB_APPENDTOVAR(]$1[, ]$2[)
 104         ]$3[
 105     ]$1[=$cy_save
 106     AS_IF([test "x$cy_good" = x1], ]$4[, ]$5[)
 107 ]) dnl }}}
 108
 109 AC_DEFUN([CY_TEST_FLAG_], [
 110     AC_LANG_PUSH(]$2[)
 111     AC_MSG_CHECKING([for ]]$4[[ ]]$1[)
 112     CY_TRY(]$3[, $1, [
 113         AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
 114             [CY_SUCCESS], [CY_FAILURE])
 115     ], [
 116         AC_MSG_RESULT([yes])
 117         AC_LIB_APPENDTOVAR(]$3[, ]$1[)
 118     ], [AC_MSG_RESULT([no])])
 119     AC_LANG_POP(]$2[)
 120 ])
 121
 122 AC_DEFUN([CY_TEST_FLAG], [
 123     CY_TEST_FLAG_(]$1[, [C], [CFLAGS], [cc])
 124     CY_TEST_FLAG_(]$1[, [C++], [CXXFLAGS], [c++])
 125     CY_TEST_FLAG_(]$1[, [Objective C++], [OBJCXXFLAGS], [c++ -ObjC])
 126 ])
 127
 128 AX_CFLAGS_WARN_ALL
 129 AX_CXXFLAGS_WARN_ALL
 130 AX_FLAGS_WARN_ALL
 131
 132 CY_TEST_FLAG([-Werror])
 133
 134 dnl XXX: this is used to support GNU Objective-C struct objc_method
 135 CY_TEST_FLAG([-Wno-deprecated-declarations])
 136
 137 CY_TEST_FLAG([-Wno-dangling-else])
 138 CY_TEST_FLAG([-Wno-overloaded-virtual])
 139 CY_TEST_FLAG([-Wno-parentheses])
 140 CY_TEST_FLAG([-Wno-unneeded-internal-declaration])
 141
 142 AC_DEFUN([CY_LT_LIB], [
 143     cy_save=$LIBS
 144     LIBS=
 145     ]$2[
 146     ]$1[=$LIBS
 147     LIBS=$cy_save
 148     AC_SUBST(]$1[)
 149 ])
 150
 151 dnl -arch * {{{
 152 for cy_arch in ppc ppc64 i386 x86_64 armv6 arm64; do
 153     AC_MSG_CHECKING([for -arch $cy_arch])
 154     CY_TRY([CXXFLAGS], ["-arch $cy_arch"], [
 155         AC_TRY_LINK([], [], [CY_SUCCESS], [CY_FAILURE])
 156     ], [
 157         AC_MSG_RESULT([yes])
 158         AC_LIB_APPENDTOVAR([CY_ARCH], ["-arch $cy_arch"])
 159     ], [AC_MSG_RESULT([no])])
 160 done
 161 AC_SUBST([CY_ARCH])
 162 dnl }}}
 163
 164 dnl --enable-javascript {{{
 165 AC_DEFUN([CY_CHECK_JAVASCRIPTCORE], [
 166     CY_LT_LIB([LTJAVASCRIPTCORE], [AC_SEARCH_LIBS([JSEvaluateScript], [JavaScriptCore], [
 167         AC_SUBST([CY_EXECUTE], [1])
 168     ], [AC_CHECK_FRAMEWORK([JavaScriptCore], [
 169         #include <JavaScriptCore/JSBase.h>
 170     ], [
 171         JSEvaluateScript(0, 0, 0, 0, 0, 0);
 172     ], [
 173         AC_SUBST([CY_EXECUTE], [1])
 174     ], [
 175         for cy_webkit_pkg in "webkit-1.0" "WebKitGtk"; do
 176             PKG_CHECK_MODULES([WEBKIT], [$cy_webkit_pkg], [
 177                 AC_SUBST([CY_EXECUTE], [1])
 178                 AC_LIB_APPENDTOVAR([CPPFLAGS], [`$PKG_CONFIG --cflags $cy_webkit_pkg`])
 179                 AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs $cy_webkit_pkg`])
 180             ], [:]); if test "x$CY_EXECUTE" = x1; then break; fi
 181         done
 182     ])])])
 183 ])
 184
 185 AC_DEFUN([CY_CHECK_JAVASCRIPT], [
 186     CY_CHECK_JAVASCRIPTCORE])
 187
 188 AC_ARG_ENABLE([javascript], [AS_HELP_STRING(
 189     [--enable-javascript@<:@=ENGINE@:>@],
 190     [use a JavaScript runtime (currently the only available option for ENGINE is JavaScriptCore) @<:@default=yes@:>@]
 191 )], [
 192     AS_CASE([$enableval],
 193         [yes], [
 194             CY_CHECK_JAVASCRIPT],
 195         [no], [
 196             AC_SUBST([CY_EXECUTE], [0])],
 197         [JavaScriptCore], [
 198             CY_CHECK_JAVASCRIPTCORE],
 199         [AC_MSG_ERROR([Unknown JavaScript engine: $enableval])])
 200 ], [CY_CHECK_JAVASCRIPT])
 201 dnl }}}
 202
 203 AC_ARG_ENABLE([console], AS_HELP_STRING([--disable-console], [disable console]))
 204 AM_CONDITIONAL([CY_CONSOLE], [test "x$enable_console" != "xno"])
 205
 206 AC_DEFUN([CY_CHECK_PKG_CONFIG_LIBFFI], [
 207     PKG_CHECK_MODULES([LIBFFI], [libffi], [
 208         AC_LIB_APPENDTOVAR([CPPFLAGS], [`$PKG_CONFIG --cflags libffi`])
 209         AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs libffi`])
 210     ], [AC_MSG_ERROR([missing "libffi"])])])
 211
 212 AM_CONDITIONAL([CY_EXECUTE], [test "x$CY_EXECUTE" = x1])
 213
 214 AS_CASE([$CY_EXECUTE], [1], [
 215     AC_CHECK_HEADERS([ffi.h ffi/ffi.h], [break])
 216
 217     CY_LT_LIB([LTLIBFFI], AS_IF([test "x$ac_cv_header_ffi_h" = xno && test "x$ac_cv_header_ffi_ffi_h" = xno], [
 218         CY_CHECK_PKG_CONFIG_LIBFFI
 219     ], [
 220         AC_SEARCH_LIBS([ffi_call], [ffi])
 221         AS_CASE([$ac_cv_search_ffi_call], [no], [CY_CHECK_PKG_CONFIG_LIBFFI])
 222     ]))
 223
 224     AC_CHECK_HEADER([jni.h], [
 225         AC_SUBST([CY_JAVA], [1])
 226         CY_LT_LIB([LTJAVA], [AC_SEARCH_LIBS([JNI_GetCreatedJavaVMs], [dvm], [
 227         ])])
 228     ], [
 229         AC_SUBST([CY_JAVA], [0])
 230     ])
 231
 232     AC_LANG_PUSH([Objective C++])
 233
 234     AC_MSG_CHECKING([if we really have Objective C++])
 235     AC_COMPILE_IFELSE([AC_LANG_SOURCE([])], [
 236         CY_OBJECTIVEC=1
 237         AC_MSG_RESULT([yes])
 238     ], [AC_MSG_RESULT([no])])
 239
 240     AS_IF([test "x$CY_OBJECTIVEC" = x1], [
 241         CY_LT_LIB([LTOBJECTIVEC], [AC_CHECK_FRAMEWORK([CoreFoundation], [
 242             #include <CoreFoundation/CFBase.h>
 243         ], [CFAllocatorGetDefault();], [
 244             AC_SUBST([CY_OBJECTIVEC])
 245
 246             AC_CHECK_FRAMEWORK([Foundation], [
 247                 #include <Foundation/NSObject.h>
 248             ], [[[[NSObject alloc] init];]])
 249         ], [
 250             AC_ARG_VAR([GNUSTEP_CONFIG], [prints information about the current gnustep installation])
 251             AC_CHECK_PROGS([GNUSTEP_CONFIG], [gnustep-config])
 252
 253             AS_IF([test "x$GNUSTEP_CONFIG" != x], [
 254                 AC_SUBST([CY_OBJECTIVEC])
 255                 AC_LIB_APPENDTOVAR([OBJCXXFLAGS], [`$GNUSTEP_CONFIG --objc-flags`])
 256                 AC_LIB_APPENDTOVAR([LIBS], [`$GNUSTEP_CONFIG --base-libs`])
 257             ], [AC_SUBST([CY_OBJECTIVEC], [0])])
 258         ])])
 259     ])
 260
 261     AC_LANG_POP([Objective C++])
 262 ])
 263
 264 AM_CONDITIONAL([CY_JAVA], [test "x$CY_JAVA" = x1])
 265 AM_CONDITIONAL([CY_OBJECTIVEC], [test "x$CY_OBJECTIVEC" = x1])
 266
 267 CY_LT_LIB([LTLIBREADLINE], [AX_LIB_READLINE])
 268 AS_CASE([$ax_cv_lib_readline], [no], [AC_MSG_ERROR([missing "libreadline"])])
 269
 270 CY_LT_LIB([LTLIBTERMCAP], [AC_SEARCH_LIBS([cur_term], [termcap ncurses])])
 271
 272 AC_SUBST([LTLIBGCC])
 273
 274 AC_SUBST([LTFLAGS])
 275 AC_SUBST([SO], [$acl_shlibext])
 276
 277 AS_IF([test "x$CY_EXECUTE" = x1], [
 278     AC_CHECK_HEADER([mach/mach.h], [
 279         AC_CHECK_TOOLS([_LIPO], [lipo], [AC_MSG_ERROR([missing "lipo"])])
 280         AC_CHECK_TOOLS([_NM], [nm], [AC_MSG_ERROR([missing "nm"])])
 281         AC_CHECK_TOOLS([_OTOOL], [otool], [AC_MSG_ERROR([missing "otool"])])
 282         AC_SUBST([CY_ATTACH_GROUP], [procmod])
 283         AC_SUBST([CY_MACH], [1])])])
 284 AM_CONDITIONAL([CY_MACH], [test "x$CY_MACH" = x1])
 285
 286 AC_CONFIG_FILES([Makefile])
 287 AC_OUTPUT