Cycript.l.in

   1 /* Cycript - Inlining/Optimizing JavaScript Compiler
   2  * Copyright (C) 2009  Jay Freeman (saurik)
   3 */
   4
   5 /* Modified BSD License {{{ */
   6 /*
   7  *        Redistribution and use in source and binary
   8  * forms, with or without modification, are permitted
   9  * provided that the following conditions are met:
  10  *
  11  * 1. Redistributions of source code must retain the
  12  *    above copyright notice, this list of conditions
  13  *    and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the
  15  *    above copyright notice, this list of conditions
  16  *    and the following disclaimer in the documentation
  17  *    and/or other materials provided with the
  18  *    distribution.
  19  * 3. The name of the author may not be used to endorse
  20  *    or promote products derived from this software
  21  *    without specific prior written permission.
  22  *
  23  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS''
  24  * AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING,
  25  * BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
  26  * MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  27  * ARE DISCLAIMED. IN NO EVENT SHALL THE AUTHOR BE
  28  * LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  29  * EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  30  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
  31  * SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  32  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
  33  * LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR
  34  * TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
  35  * ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
  36  * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  37 */
  38 /* }}} */
  39
  40 /* XXX: supposedly I will be screwed on very very long multi-line comments and need to replace these with a manual lexer. http://websrv.cs.fsu.edu/~engelen/courses/COP5621/Pr2.pdf */
  41
  42 %{
  43 #define YYLTYPE cy::location
  44 #include "Cycript.tab.hh"
  45 typedef cy::parser::token tk;
  46
  47 #define YY_EXTRA_TYPE CYDriver *
  48
  49 #define T yylval->newline_ = yyextra->state_ == CYNewLine; BEGIN(Div);
  50 #define C T yyextra->state_ = CYClear;
  51 #define R T yyextra->state_ = CYRestricted;
  52
  53 #define E(prefix) L C { \
  54     char *value(reinterpret_cast<char *>(apr_palloc(yyextra->pool_, yyleng + sizeof(prefix)))); \
  55     memcpy(value, prefix, sizeof(prefix) - 1); \
  56     memcpy(value + sizeof(prefix) - 1, yytext, yyleng); \
  57     value[yyleng + sizeof(prefix) - 1] = '\0'; \
  58     yylval->literal_ = new(yyextra->pool_) CYRegEx(value); \
  59     return tk::RegularExpressionLiteral; \
  60 }
  61
  62 #define N \
  63     if (yyextra->state_ != CYNewLine) { \
  64         bool restricted(yyextra->state_ == CYRestricted); \
  65         if (restricted) { \
  66             yyextra->state_ = CYClear; \
  67             return tk::NewLine; \
  68         } else \
  69             yyextra->state_ = CYNewLine; \
  70     }
  71
  72 #define V(more) { \
  73     if (const char *nl = reinterpret_cast<const char *>(memchr(yytext, '\n', yyleng))) { \
  74         unsigned lines(0); \
  75         size_t left; \
  76         do { \
  77             ++lines; \
  78             left = yyleng - (nl - yytext) - 1; \
  79             nl = reinterpret_cast<const char *>(memchr(nl + 1, '\n', left)); \
  80         } while (nl != NULL); \
  81         yylloc->end.lines(lines); \
  82         yylloc->end.columns(left); \
  83         yylloc->step(); \
  84         more \
  85     } else L \
  86 }
  87
  88 #define L { \
  89     yylloc->step(); \
  90     yylloc->columns(yyleng); \
  91 }
  92
  93 int H(char c) {
  94     if (c >= '0' && c <= '9')
  95         return c - '0';
  96     if (c >= 'a' && c <= 'f')
  97         return c - 'a' + 10;
  98     if (c >= 'A' && c <= 'F')
  99         return c - 'A' + 10;
 100     return -1;
 101 }
 102
 103 #define YY_INPUT(data, value, size) { \
 104     if (yyextra->file_ != NULL) { \
 105         size_t copy(fread(data, 1, size, yyextra->file_)); \
 106         value = copy == 0 ? YY_NULL : copy; \
 107     } else if (yyextra->size_ == 0) \
 108         value = YY_NULL; \
 109     else { \
 110         size_t copy(size); \
 111         copy = (std::min(copy, yyextra->size_)); \
 112         memcpy(data, yyextra->data_, copy); \
 113         yyextra->data_ += copy; \
 114         yyextra->size_ -= copy; \
 115         value = copy; \
 116     } \
 117 }
 118
 119 %}
 120
 121 %option prefix="cy"
 122 %option bison-bridge
 123 %option bison-locations
 124 %option noyywrap
 125 %option yylineno
 126 %option nounput
 127 %option interactive
 128 %option reentrant
 129 %option stack
 130
 131 Exponent [eE][+-]?[0-9]+
 132 Escape   \\[\\'"bfnrtv]|\\0|\\x[0-9a-fA-F]{2}|\\u[0-9a-fA-F]{4}|\\\n
 133
 134 IdentifierStart [a-zA-Z$_]
 135 IdentifierPart  [a-zA-Z$_0-9]
 136
 137 NonTerminator [^\n]
 138 BackslashSequence \\{NonTerminator}
 139 RegularExpressionFirstChar [^\n*\\/]|{BackslashSequence}
 140 RegularExpressionChar [^\n\\/]|{BackslashSequence}
 141 RegularExpressionFlags {IdentifierPart}*
 142 RegularExpressionChars {RegularExpressionChar}*
 143 RegularExpressionBody {RegularExpressionFirstChar}{RegularExpressionChars}
 144
 145 @begin E4X
 146 XMLNameStart [a-zA-Z_:]
 147 XMLNamePart [a-zA-Z0-9.-_:]
 148 XMLName {XMLNameStart}{XMLNamePart}*
 149 @end
 150
 151 %s Div
 152 %s RegExp
 153
 154 @begin E4X
 155 %x XMLContent
 156 %x XMLTag
 157 @end
 158
 159 %%
 160
 161 <RegExp>\/{RegularExpressionBody}\/{RegularExpressionFlags} E("")
 162
 163 \/\/[^\n]* L
 164 \/\*(\n|[^\*]|\*[^/])*\*\/ V(N)
 165
 166 @begin E4X
 167 <RegExp>"<>"      L return tk::LeftRight;
 168 <XMLContent>"</>" L return tk::LeftSlashRight;
 169
 170 <RegExp,XMLContent>\<!\[CDATA\[(\n|[^[]|\[[^[]|\[\[[^>])*]]> V() return tk::XMLCDATA;
 171 <RegExp,XMLContent>\<!--(\n|[^-]|-[^-])*--> V() return tk::XMLComment;
 172 <RegExp,XMLContent>\<?(\n|[^?]|\?[^>])*?> V() return tk::XMLPI;
 173
 174 <XMLTag>"="  L return tk::Equal;
 175 <XMLTag>">"  L return tk::Right;
 176 <XMLTag>"/>" L return tk::SlashRight;
 177 <XMLTag>"{"  L return tk::OpenBrace;
 178
 179 <XMLTag>\"(\n|[^"])*\"|'(\n|[^'])*' V() {
 180     return tk::XMLAttributeValue;
 181 }
 182
 183 <XMLTag>{XMLName} L return tk::XMLName;
 184 <XMLTag>[ \t\r\n] V() return tk::XMLWhitespace;
 185
 186 <XMLContent>"{"  L return tk::OpenBrace;
 187 <XMLContent>"<"  L return tk::Left;
 188 <XMLContent>"</" L return tk::LeftSlash;
 189 @end
 190
 191 @begin E4X
 192 "::"   L C return tk::ColonColon;
 193 ".."   L C return tk::PeriodPeriod;
 194 @end
 195
 196 @begin E4X ObjectiveC
 197 "@"    L C return tk::At;
 198 @end
 199
 200 "&"    L C return tk::Ampersand;
 201 "&&"   L C return tk::AmpersandAmpersand;
 202 "&="   L C return tk::AmpersandEqual;
 203 "^"    L C return tk::Carrot;
 204 "^="   L C return tk::CarrotEqual;
 205 "="    L C return tk::Equal;
 206 "=="   L C return tk::EqualEqual;
 207 "==="  L C return tk::EqualEqualEqual;
 208 "!"    L C return tk::Exclamation;
 209 "!="   L C return tk::ExclamationEqual;
 210 "!=="  L C return tk::ExclamationEqualEqual;
 211 "-"    L C return tk::Hyphen;
 212 "-="   L C return tk::HyphenEqual;
 213 "--"   L C return yylval->newline_ ? tk::HyphenHyphen_ : tk::HyphenHyphen;
 214 "->"   L C return tk::HyphenRight;
 215 "<"    L C return tk::Left;
 216 "<="   L C return tk::LeftEqual;
 217 "<<"   L C return tk::LeftLeft;
 218 "<<="  L C return tk::LeftLeftEqual;
 219 "%"    L C return tk::Percent;
 220 "%="   L C return tk::PercentEqual;
 221 "."    L C return tk::Period;
 222 "|"    L C return tk::Pipe;
 223 "|="   L C return tk::PipeEqual;
 224 "||"   L C return tk::PipePipe;
 225 "+"    L C return tk::Plus;
 226 "+="   L C return tk::PlusEqual;
 227 "++"   L C return yylval->newline_ ? tk::PlusPlus_ : tk::PlusPlus;
 228 ">"    L C return tk::Right;
 229 ">="   L C return tk::RightEqual;
 230 ">>"   L C return tk::RightRight;
 231 ">>="  L C return tk::RightRightEqual;
 232 ">>>"  L C return tk::RightRightRight;
 233 ">>>=" L C return tk::RightRightRightEqual;
 234 "*"    L C return tk::Star;
 235 "*="   L C return tk::StarEqual;
 236 "~"    L C return tk::Tilde;
 237
 238 <Div>"/"  L C return tk::Slash;
 239 <Div>"/=" L C return tk::SlashEqual;
 240
 241 ":"    L C return tk::Colon;
 242 ","    L C return tk::Comma;
 243 "?"    L C return tk::Question;
 244 ";"    L C return tk::SemiColon;
 245
 246 "("    L C return tk::OpenParen;
 247 ")"    L C return tk::CloseParen;
 248
 249 "{"    L C return tk::OpenBrace;
 250 "}"    L C return tk::CloseBrace;
 251
 252 "["    L C return tk::OpenBracket;
 253 "]"    L C return tk::CloseBracket;
 254
 255 @begin ObjectiveC
 256 "@class"       L C return tk::AtClass;
 257 "@end"         L C return tk::AtEnd;
 258 "@selector"    L C return tk::AtSelector;
 259 @end
 260
 261 "false"        L C yylval->false_ = new(yyextra->pool_) CYFalse(); return tk::False;
 262 "null"         L C yylval->null_ = new(yyextra->pool_) CYNull(); return tk::Null;
 263 "true"         L C yylval->true_ = new(yyextra->pool_) CYTrue(); return tk::True;
 264
 265 "break"        L R yylval->word_ = new(yyextra->pool_) CYWord("break"); return tk::Break;
 266 "case"         L C yylval->word_ = new(yyextra->pool_) CYWord("case"); return tk::Case;
 267 "catch"        L C yylval->word_ = new(yyextra->pool_) CYWord("catch"); return tk::Catch;
 268 "continue"     L R yylval->word_ = new(yyextra->pool_) CYWord("continue"); return tk::Continue;
 269 "default"      L C yylval->word_ = new(yyextra->pool_) CYWord("default"); return tk::Default;
 270 "delete"       L C yylval->word_ = new(yyextra->pool_) CYWord("delete"); return tk::Delete;
 271 "do"           L C yylval->word_ = new(yyextra->pool_) CYWord("do"); return tk::Do;
 272 "else"         L C yylval->word_ = new(yyextra->pool_) CYWord("else"); return tk::Else;
 273 "finally"      L C yylval->word_ = new(yyextra->pool_) CYWord("finally"); return tk::Finally;
 274 "for"          L C yylval->word_ = new(yyextra->pool_) CYWord("for"); return tk::For;
 275 "function"     L C yylval->word_ = new(yyextra->pool_) CYWord("function"); return tk::Function;
 276 "if"           L C yylval->word_ = new(yyextra->pool_) CYWord("if"); return tk::If;
 277 "in"           L C yylval->word_ = new(yyextra->pool_) CYWord("in"); return tk::In;
 278 "instanceof"   L C yylval->word_ = new(yyextra->pool_) CYWord("instanceof"); return tk::InstanceOf;
 279 "new"          L C yylval->word_ = new(yyextra->pool_) CYWord("new"); return tk::New;
 280 "return"       L R yylval->word_ = new(yyextra->pool_) CYWord("return"); return tk::Return;
 281 "switch"       L C yylval->word_ = new(yyextra->pool_) CYWord("switch"); return tk::Switch;
 282 "this"         L C yylval->this_ = new(yyextra->pool_) CYThis(); return tk::This;
 283 "throw"        L R yylval->word_ = new(yyextra->pool_) CYWord("throw"); return tk::Throw;
 284 "try"          L C yylval->word_ = new(yyextra->pool_) CYWord("try"); return tk::Try;
 285 "typeof"       L C yylval->word_ = new(yyextra->pool_) CYWord("typeof"); return tk::TypeOf;
 286 "var"          L C yylval->word_ = new(yyextra->pool_) CYWord("var"); return tk::Var;
 287 "void"         L C yylval->word_ = new(yyextra->pool_) CYWord("void"); return tk::Void;
 288 "while"        L C yylval->word_ = new(yyextra->pool_) CYWord("while"); return tk::While;
 289 "with"         L C yylval->word_ = new(yyextra->pool_) CYWord("with"); return tk::With;
 290
 291 "debugger"     L C yylval->word_ = new(yyextra->pool_) CYWord("debugger"); return tk::Debugger;
 292
 293 "const"        L C yylval->word_ = new(yyextra->pool_) CYWord("const"); return tk::Const;
 294
 295 "class"        L C yylval->word_ = new(yyextra->pool_) CYWord("class"); return tk::Class;
 296 "enum"         L C yylval->word_ = new(yyextra->pool_) CYWord("enum"); return tk::Enum;
 297 "export"       L C yylval->word_ = new(yyextra->pool_) CYWord("export"); return tk::Export;
 298 "extends"      L C yylval->word_ = new(yyextra->pool_) CYWord("extends"); return tk::Extends;
 299 "import"       L C yylval->word_ = new(yyextra->pool_) CYWord("import"); return tk::Import;
 300 "super"        L C yylval->word_ = new(yyextra->pool_) CYWord("super"); return tk::Super;
 301
 302 "implements"   L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("implements"); return tk::Implements;
 303 "interface"    L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("interface"); return tk::Interface;
 304 "package"      L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("package"); return tk::Package;
 305 "private"      L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("private"); return tk::Private;
 306 "protected"    L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("protected"); return tk::Protected;
 307 "public"       L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("public"); return tk::Public;
 308 "static"       L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("static"); return tk::Static;
 309
 310 "abstract"     L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("abstract"); return tk::Abstract;
 311 "boolean"      L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("boolean"); return tk::Boolean;
 312 "byte"         L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("byte"); return tk::Byte;
 313 "char"         L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("char"); return tk::Char;
 314 "double"       L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("double"); return tk::Double;
 315 "final"        L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("final"); return tk::Final;
 316 "float"        L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("float"); return tk::Float;
 317 "goto"         L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("goto"); return tk::Goto;
 318 "int"          L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("int"); return tk::Int;
 319 "long"         L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("long"); return tk::Long;
 320 "native"       L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("native"); return tk::Native;
 321 "short"        L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("short"); return tk::Short;
 322 "synchronized" L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("synchronized"); return tk::Synchronized;
 323 "throws"       L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("throws"); return tk::Throws;
 324 "transient"    L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("transient"); return tk::Transient;
 325 "volatile"     L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("volatile"); return tk::Volatile;
 326
 327 "let"          L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("let"); return tk::Let;
 328 "yield"        L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("yield"); return tk::Yield;
 329
 330 "each"         L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("each"); return tk::Each;
 331
 332 @begin E4X
 333 "namespace"    L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("namespace"); return tk::Namespace;
 334 "xml"          L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("xml"); return tk::XML;
 335 @end
 336
 337 {IdentifierStart}{IdentifierPart}* L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier(apr_pstrmemdup(yyextra->pool_, yytext, yyleng)); return tk::Identifier_;
 338
 339 (\.[0-9]+|(0|[1-9][0-9]*)(\.[0-9]*)?){Exponent}? L C yylval->number_ = new(yyextra->pool_) CYNumber(strtod(yytext, NULL)); return tk::NumericLiteral;
 340
 341 0[xX][0-9a-fA-F]+ L C yylval->number_ = new(yyextra->pool_) CYNumber(strtoull(yytext + 2, NULL, 16)); return tk::NumericLiteral;
 342
 343 0[bB][0-1]+ L C yylval->number_ = new(yyextra->pool_) CYNumber(strtoull(yytext + 2, NULL, 2)); return tk::NumericLiteral;
 344
 345 \"([^"\\\n]|{Escape})*\"|'([^'\\\n]|{Escape})*' L C {
 346     char *value(reinterpret_cast<char *>(apr_palloc(yyextra->pool_, yyleng)));
 347     char *local(value);
 348
 349     for (int i(1); i != yyleng - 1; ++i) {
 350         char next(yytext[i]);
 351
 352         if (yytext[i] == '\\')
 353             switch (next = yytext[++i]) {
 354                 case '\n': continue;
 355                 case '\\': next = '\\'; break;
 356                 case '\'': next = '\''; break;
 357                 case '"': next = '"'; break;
 358                 case 'b': next = '\b'; break;
 359                 case 'f': next = '\f'; break;
 360                 case 'n': next = '\n'; break;
 361                 case 'r': next = '\r'; break;
 362                 case 't': next = '\t'; break;
 363                 case 'v': next = '\v'; break;
 364                 case '0': next = '\0'; break;
 365
 366                 case 'x':
 367                     next = H(yytext[i + 1]) << 4 | H(yytext[i + 2]);
 368                     i += 2;
 369                 break;
 370             }
 371
 372         *local++ = next;
 373     }
 374
 375     *local = '\0';
 376     yylval->string_ = new(yyextra->pool_) CYString(value, local - value);
 377     return tk::StringLiteral;
 378 }
 379
 380 \r?\n yylloc->end.lines(); yylloc->step(); N
 381
 382 [ \t] L
 383 <<EOF>> L yyterminate();
 384
 385 . L {
 386     CYDriver::Error error;
 387     error.location_ = *yylloc;
 388     error.message_ = "syntax error, unknown token";
 389     yyextra->errors_.push_back(error);
 390     yyterminate();
 391 }
 392
 393 %%
 394
 395 void CYDriver::ScannerInit() {
 396     cylex_init(&scanner_);
 397     cyset_extra(this, scanner_);
 398 }
 399
 400 void CYDriver::ScannerDestroy() {
 401     cylex_destroy(scanner_);
 402 }
 403
 404 CYDriver::Condition CYDriver::GetCondition() {
 405     switch (yy_top_state(scanner_)) {
 406         case RegExp:
 407             return RegExpCondition;
 408 @begin E4X
 409         case XMLContent:
 410             return XMLContentCondition;
 411         case XMLTag:
 412             return XMLTagCondition;
 413 @end
 414         default:
 415             _assert(false);
 416     }
 417 }
 418
 419 void CYDriver::SetCondition(Condition condition) {
 420     struct yyguts_t *yyg(reinterpret_cast<struct yyguts_t *>(scanner_));
 421
 422     switch (condition) {
 423         case RegExpCondition:
 424             BEGIN(RegExp);
 425             break;
 426 @begin E4X
 427         case XMLContentCondition:
 428             BEGIN(XMLContent);
 429             break;
 430         case XMLTagCondition:
 431             BEGIN(XMLTag);
 432             break;
 433 @end
 434         default:
 435             _assert(false);
 436     }
 437 }
 438
 439 void CYDriver::PushCondition(Condition condition) {
 440     switch (condition) {
 441         case RegExpCondition:
 442             yy_push_state(RegExp, scanner_);
 443             break;
 444 @begin E4X
 445         case XMLContentCondition:
 446             yy_push_state(XMLContent, scanner_);
 447             break;
 448         case XMLTagCondition:
 449             yy_push_state(XMLTag, scanner_);
 450             break;
 451 @end
 452         default:
 453             _assert(false);
 454     }
 455 }
 456
 457 void CYDriver::PopCondition() {
 458     yy_pop_state(scanner_);
 459 }