Library.mm

   1 /* Cycript - Remove Execution Server and Disassembler
   2  * Copyright (C) 2009  Jay Freeman (saurik)
   3 */
   4
   5 /* Modified BSD License {{{ */
   6 /*
   7  *        Redistribution and use in source and binary
   8  * forms, with or without modification, are permitted
   9  * provided that the following conditions are met:
  10  *
  11  * 1. Redistributions of source code must retain the
  12  *    above copyright notice, this list of conditions
  13  *    and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the
  15  *    above copyright notice, this list of conditions
  16  *    and the following disclaimer in the documentation
  17  *    and/or other materials provided with the
  18  *    distribution.
  19  * 3. The name of the author may not be used to endorse
  20  *    or promote products derived from this software
  21  *    without specific prior written permission.
  22  *
  23  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS''
  24  * AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING,
  25  * BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
  26  * MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  27  * ARE DISCLAIMED. IN NO EVENT SHALL THE AUTHOR BE
  28  * LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  29  * EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  30  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
  31  * SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  32  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
  33  * LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR
  34  * TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
  35  * ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
  36  * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  37 */
  38 /* }}} */
  39
  40 #define _GNU_SOURCE
  41
  42 #include <substrate.h>
  43 #include "cycript.hpp"
  44
  45 #include "sig/parse.hpp"
  46 #include "sig/ffi_type.hpp"
  47
  48 #include "Pooling.hpp"
  49 #include "Struct.hpp"
  50
  51 #include <unistd.h>
  52
  53 #include <CoreFoundation/CoreFoundation.h>
  54 #include <CoreFoundation/CFLogUtilities.h>
  55
  56 #include <WebKit/WebScriptObject.h>
  57
  58 #include <sys/types.h>
  59 #include <sys/socket.h>
  60 #include <netinet/in.h>
  61 #include <sys/un.h>
  62
  63 #include <sys/mman.h>
  64
  65 #include <iostream>
  66 #include <ext/stdio_filebuf.h>
  67 #include <set>
  68 #include <map>
  69
  70 #include <sstream>
  71 #include <cmath>
  72
  73 #include "Parser.hpp"
  74 #include "Cycript.tab.hh"
  75
  76 #include <fcntl.h>
  77
  78 #include <apr-1/apr_thread_proc.h>
  79
  80 #undef _assert
  81 #undef _trace
  82
  83 #define _assert(test) do { \
  84     if (!(test)) \
  85         @throw [NSException exceptionWithName:NSInternalInconsistencyException reason:[NSString stringWithFormat:@"_assert(%s):%s(%u):%s", #test, __FILE__, __LINE__, __FUNCTION__] userInfo:nil]; \
  86 } while (false)
  87
  88 #define _trace() do { \
  89     CFLog(kCFLogLevelNotice, CFSTR("_trace():%u"), __LINE__); \
  90 } while (false)
  91
  92 #define CYPoolTry { \
  93     id _saved(nil); \
  94     NSAutoreleasePool *_pool([[NSAutoreleasePool alloc] init]); \
  95     @try
  96 #define CYPoolCatch(value) \
  97     @catch (NSException *error) { \
  98         _saved = [error retain]; \
  99         @throw; \
 100         return value; \
 101     } @finally { \
 102         [_pool release]; \
 103         if (_saved != nil) \
 104             [_saved autorelease]; \
 105     } \
 106 }
 107
 108 static JSGlobalContextRef Context_;
 109 static JSObjectRef System_;
 110 static JSObjectRef ObjectiveC_;
 111
 112 static JSClassRef Functor_;
 113 static JSClassRef Instance_;
 114 static JSClassRef Internal_;
 115 static JSClassRef Pointer_;
 116 static JSClassRef Runtime_;
 117 static JSClassRef Selector_;
 118 static JSClassRef Struct_;
 119 static JSClassRef Type_;
 120
 121 static JSClassRef ObjectiveC_Classes_;
 122 static JSClassRef ObjectiveC_Image_Classes_;
 123 static JSClassRef ObjectiveC_Images_;
 124 static JSClassRef ObjectiveC_Protocols_;
 125
 126 static JSObjectRef Array_;
 127 static JSObjectRef Function_;
 128
 129 static JSStringRef Result_;
 130
 131 static JSStringRef length_;
 132 static JSStringRef message_;
 133 static JSStringRef name_;
 134 static JSStringRef toCYON_;
 135 static JSStringRef toJSON_;
 136
 137 static Class NSCFBoolean_;
 138 static Class NSCFType_;
 139 static Class NSMessageBuilder_;
 140 static Class NSZombie_;
 141 static Class Object_;
 142
 143 static NSArray *Bridge_;
 144
 145 struct CYData {
 146     apr_pool_t *pool_;
 147
 148     virtual ~CYData() {
 149     }
 150
 151     static void *operator new(size_t size, apr_pool_t *pool) {
 152         void *data(apr_palloc(pool, size));
 153         reinterpret_cast<CYData *>(data)->pool_ = pool;
 154         return data;
 155     }
 156
 157     static void *operator new(size_t size) {
 158         apr_pool_t *pool;
 159         apr_pool_create(&pool, NULL);
 160         return operator new(size, pool);
 161     }
 162
 163     static void operator delete(void *data) {
 164         apr_pool_destroy(reinterpret_cast<CYData *>(data)->pool_);
 165     }
 166
 167     static void Finalize(JSObjectRef object) {
 168         delete reinterpret_cast<CYData *>(JSObjectGetPrivate(object));
 169     }
 170 };
 171
 172 struct CYValue :
 173     CYData
 174 {
 175     void *value_;
 176
 177     CYValue() {
 178     }
 179
 180     CYValue(void *value) :
 181         value_(value)
 182     {
 183     }
 184
 185     CYValue(const CYValue &rhs) :
 186         value_(rhs.value_)
 187     {
 188     }
 189 };
 190
 191 struct Selector_privateData :
 192     CYValue
 193 {
 194     Selector_privateData(SEL value) :
 195         CYValue(value)
 196     {
 197     }
 198
 199     SEL GetValue() const {
 200         return reinterpret_cast<SEL>(value_);
 201     }
 202 };
 203
 204 struct Instance :
 205     CYValue
 206 {
 207     enum Flags {
 208         None          = 0,
 209         Transient     = (1 << 0),
 210         Uninitialized = (1 << 1),
 211     };
 212
 213     Flags flags_;
 214
 215     Instance(id value, Flags flags) :
 216         CYValue(value),
 217         flags_(flags)
 218     {
 219     }
 220
 221     virtual ~Instance() {
 222         if ((flags_ & Transient) == 0)
 223             // XXX: does this handle background threads correctly?
 224             [GetValue() performSelector:@selector(release) withObject:nil afterDelay:0];
 225     }
 226
 227     static JSObjectRef Make(JSContextRef context, id object, Flags flags) {
 228         return JSObjectMake(context, Instance_, new Instance(object, flags));
 229     }
 230
 231     id GetValue() const {
 232         return reinterpret_cast<id>(value_);
 233     }
 234
 235     bool IsUninitialized() const {
 236         return (flags_ & Uninitialized) != 0;
 237     }
 238 };
 239
 240 struct Internal :
 241     CYValue
 242 {
 243     JSObjectRef owner_;
 244
 245     Internal(id value, JSObjectRef owner) :
 246         CYValue(value),
 247         owner_(owner)
 248     {
 249     }
 250
 251     static JSObjectRef Make(JSContextRef context, id object, JSObjectRef owner) {
 252         return JSObjectMake(context, Internal_, new Internal(object, owner));
 253     }
 254
 255     id GetValue() const {
 256         return reinterpret_cast<id>(value_);
 257     }
 258 };
 259
 260 namespace sig {
 261
 262 void Copy(apr_pool_t *pool, Type &lhs, Type &rhs);
 263
 264 void Copy(apr_pool_t *pool, Element &lhs, Element &rhs) {
 265     lhs.name = apr_pstrdup(pool, rhs.name);
 266     if (rhs.type == NULL)
 267         lhs.type = NULL;
 268     else {
 269         lhs.type = new(pool) Type;
 270         Copy(pool, *lhs.type, *rhs.type);
 271     }
 272     lhs.offset = rhs.offset;
 273 }
 274
 275 void Copy(apr_pool_t *pool, Signature &lhs, Signature &rhs) {
 276     size_t count(rhs.count);
 277     lhs.count = count;
 278     lhs.elements = new(pool) Element[count];
 279     for (size_t index(0); index != count; ++index)
 280         Copy(pool, lhs.elements[index], rhs.elements[index]);
 281 }
 282
 283 void Copy(apr_pool_t *pool, Type &lhs, Type &rhs) {
 284     lhs.primitive = rhs.primitive;
 285     lhs.name = apr_pstrdup(pool, rhs.name);
 286     lhs.flags = rhs.flags;
 287
 288     if (sig::IsAggregate(rhs.primitive))
 289         Copy(pool, lhs.data.signature, rhs.data.signature);
 290     else {
 291         if (rhs.data.data.type != NULL) {
 292             lhs.data.data.type = new(pool) Type;
 293             Copy(pool, *lhs.data.data.type, *rhs.data.data.type);
 294         }
 295
 296         lhs.data.data.size = rhs.data.data.size;
 297     }
 298 }
 299
 300 void Copy(apr_pool_t *pool, ffi_type &lhs, ffi_type &rhs) {
 301     lhs.size = rhs.size;
 302     lhs.alignment = rhs.alignment;
 303     lhs.type = rhs.type;
 304     if (rhs.elements == NULL)
 305         lhs.elements = NULL;
 306     else {
 307         size_t count(0);
 308         while (rhs.elements[count] != NULL)
 309             ++count;
 310
 311         lhs.elements = new(pool) ffi_type *[count + 1];
 312         lhs.elements[count] = NULL;
 313
 314         for (size_t index(0); index != count; ++index) {
 315             // XXX: if these are libffi native then you can just take them
 316             ffi_type *ffi(new(pool) ffi_type);
 317             lhs.elements[index] = ffi;
 318             sig::Copy(pool, *ffi, *rhs.elements[index]);
 319         }
 320     }
 321 }
 322
 323 }
 324
 325 struct CStringMapLess :
 326     std::binary_function<const char *, const char *, bool>
 327 {
 328     _finline bool operator ()(const char *lhs, const char *rhs) const {
 329         return strcmp(lhs, rhs) < 0;
 330     }
 331 };
 332
 333 void Structor_(apr_pool_t *pool, const char *name, const char *types, sig::Type *&type) {
 334     if (name == NULL)
 335         return;
 336
 337     CYPoolTry {
 338         if (NSMutableArray *entry = [[Bridge_ objectAtIndex:2] objectForKey:[NSString stringWithUTF8String:name]])
 339             switch ([[entry objectAtIndex:0] intValue]) {
 340                 case 0: {
 341                     sig::Parse(pool, &type->data.signature, [[entry objectAtIndex:1] UTF8String], &Structor_);
 342                 } break;
 343
 344                 case 1: {
 345                     sig::Signature signature;
 346                     sig::Parse(pool, &signature, [[entry objectAtIndex:1] UTF8String], &Structor_);
 347                     type = signature.elements[0].type;
 348                 } break;
 349             }
 350     } CYPoolCatch()
 351 }
 352
 353 struct Type_privateData :
 354     CYData
 355 {
 356     ffi_type *ffi_;
 357     sig::Type *type_;
 358
 359     void Set(sig::Type *type) {
 360         type_ = new(pool_) sig::Type;
 361         sig::Copy(pool_, *type_, *type);
 362     }
 363
 364     Type_privateData(apr_pool_t *pool, const char *type) :
 365         ffi_(NULL)
 366     {
 367         if (pool != NULL)
 368             pool_ = pool;
 369
 370         sig::Signature signature;
 371         sig::Parse(pool_, &signature, type, &Structor_);
 372         type_ = signature.elements[0].type;
 373     }
 374
 375     Type_privateData(sig::Type *type) :
 376         ffi_(NULL)
 377     {
 378         if (type != NULL)
 379             Set(type);
 380     }
 381
 382     Type_privateData(sig::Type *type, ffi_type *ffi) {
 383         ffi_ = new(pool_) ffi_type;
 384         sig::Copy(pool_, *ffi_, *ffi);
 385         Set(type);
 386     }
 387
 388     ffi_type *GetFFI() {
 389         if (ffi_ == NULL) {
 390             ffi_ = new(pool_) ffi_type;
 391
 392             sig::Element element;
 393             element.name = NULL;
 394             element.type = type_;
 395             element.offset = 0;
 396
 397             sig::Signature signature;
 398             signature.elements = &element;
 399             signature.count = 1;
 400
 401             ffi_cif cif;
 402             sig::sig_ffi_cif(pool_, &sig::ObjectiveC, &signature, &cif);
 403             *ffi_ = *cif.rtype;
 404         }
 405
 406         return ffi_;
 407     }
 408 };
 409
 410 struct Pointer :
 411     CYValue
 412 {
 413     JSObjectRef owner_;
 414     Type_privateData *type_;
 415
 416     Pointer(void *value, sig::Type *type, JSObjectRef owner) :
 417         CYValue(value),
 418         owner_(owner),
 419         type_(new(pool_) Type_privateData(type))
 420     {
 421     }
 422 };
 423
 424 struct Struct_privateData :
 425     CYValue
 426 {
 427     JSObjectRef owner_;
 428     Type_privateData *type_;
 429
 430     Struct_privateData(JSObjectRef owner) :
 431         owner_(owner)
 432     {
 433     }
 434 };
 435
 436 typedef std::map<const char *, Type_privateData *, CStringMapLess> TypeMap;
 437 static TypeMap Types_;
 438
 439 JSObjectRef CYMakeStruct(JSContextRef context, void *data, sig::Type *type, ffi_type *ffi, JSObjectRef owner) {
 440     Struct_privateData *internal(new Struct_privateData(owner));
 441     apr_pool_t *pool(internal->pool_);
 442     Type_privateData *typical(new(pool) Type_privateData(type, ffi));
 443     internal->type_ = typical;
 444
 445     if (owner != NULL)
 446         internal->value_ = data;
 447     else {
 448         size_t size(typical->GetFFI()->size);
 449         void *copy(apr_palloc(internal->pool_, size));
 450         memcpy(copy, data, size);
 451         internal->value_ = copy;
 452     }
 453
 454     return JSObjectMake(context, Struct_, internal);
 455 }
 456
 457 struct Functor_privateData :
 458     CYValue
 459 {
 460     sig::Signature signature_;
 461     ffi_cif cif_;
 462
 463     Functor_privateData(const char *type, void (*value)()) :
 464         CYValue(reinterpret_cast<void *>(value))
 465     {
 466         sig::Parse(pool_, &signature_, type, &Structor_);
 467         sig::sig_ffi_cif(pool_, &sig::ObjectiveC, &signature_, &cif_);
 468     }
 469 };
 470
 471 struct ffoData :
 472     Functor_privateData
 473 {
 474     JSContextRef context_;
 475     JSObjectRef function_;
 476
 477     ffoData(const char *type) :
 478         Functor_privateData(type, NULL)
 479     {
 480     }
 481 };
 482
 483 JSObjectRef CYMakeInstance(JSContextRef context, id object, bool transient) {
 484     Instance::Flags flags;
 485
 486     if (transient)
 487         flags = Instance::Transient;
 488     else {
 489         flags = Instance::None;
 490         object = [object retain];
 491     }
 492
 493     return Instance::Make(context, object, flags);
 494 }
 495
 496 const char *CYPoolCString(apr_pool_t *pool, NSString *value) {
 497     if (pool == NULL)
 498         return [value UTF8String];
 499     else {
 500         size_t size([value maximumLengthOfBytesUsingEncoding:NSUTF8StringEncoding] + 1);
 501         char *string(new(pool) char[size]);
 502         if (![value getCString:string maxLength:size encoding:NSUTF8StringEncoding])
 503             @throw [NSException exceptionWithName:NSInternalInconsistencyException reason:@"[NSString getCString:maxLength:encoding:] == NO" userInfo:nil];
 504         return string;
 505     }
 506 }
 507
 508 JSValueRef CYCastJSValue(JSContextRef context, bool value) {
 509     return JSValueMakeBoolean(context, value);
 510 }
 511
 512 JSValueRef CYCastJSValue(JSContextRef context, double value) {
 513     return JSValueMakeNumber(context, value);
 514 }
 515
 516 #define CYCastJSValue_(Type_) \
 517     JSValueRef CYCastJSValue(JSContextRef context, Type_ value) { \
 518         return JSValueMakeNumber(context, static_cast<double>(value)); \
 519     }
 520
 521 CYCastJSValue_(int)
 522 CYCastJSValue_(unsigned int)
 523 CYCastJSValue_(long int)
 524 CYCastJSValue_(long unsigned int)
 525 CYCastJSValue_(long long int)
 526 CYCastJSValue_(long long unsigned int)
 527
 528 JSValueRef CYJSUndefined(JSContextRef context) {
 529     return JSValueMakeUndefined(context);
 530 }
 531
 532 bool CYGetIndex(const char *value, ssize_t &index) {
 533     if (value[0] != '0') {
 534         char *end;
 535         index = strtol(value, &end, 10);
 536         if (value + strlen(value) == end)
 537             return true;
 538     } else if (value[1] == '\0') {
 539         index = 0;
 540         return true;
 541     }
 542
 543     return false;
 544 }
 545
 546 bool CYGetIndex(apr_pool_t *pool, NSString *value, ssize_t &index) {
 547     return CYGetIndex(CYPoolCString(pool, value), index);
 548 }
 549
 550 NSString *CYPoolNSCYON(apr_pool_t *pool, id value);
 551
 552 @interface NSMethodSignature (Cycript)
 553 - (NSString *) _typeString;
 554 @end
 555
 556 @interface NSObject (Cycript)
 557
 558 - (JSValueRef) cy$JSValueInContext:(JSContextRef)context;
 559 - (JSType) cy$JSType;
 560
 561 - (NSObject *) cy$toJSON:(NSString *)key;
 562 - (NSString *) cy$toCYON;
 563 - (NSString *) cy$toKey;
 564
 565 - (NSObject *) cy$getProperty:(NSString *)name;
 566 - (bool) cy$setProperty:(NSString *)name to:(NSObject *)value;
 567 - (bool) cy$deleteProperty:(NSString *)name;
 568
 569 @end
 570
 571 @protocol Cycript
 572 - (JSValueRef) cy$JSValueInContext:(JSContextRef)context;
 573 @end
 574
 575 @interface NSString (Cycript)
 576 - (void *) cy$symbol;
 577 @end
 578
 579 struct PropertyAttributes {
 580     CYPool pool_;
 581
 582     const char *name;
 583
 584     const char *variable;
 585
 586     const char *getter_;
 587     const char *setter_;
 588
 589     bool readonly;
 590     bool copy;
 591     bool retain;
 592     bool nonatomic;
 593     bool dynamic;
 594     bool weak;
 595     bool garbage;
 596
 597     PropertyAttributes(objc_property_t property) :
 598         variable(NULL),
 599         getter_(NULL),
 600         setter_(NULL),
 601         readonly(false),
 602         copy(false),
 603         retain(false),
 604         nonatomic(false),
 605         dynamic(false),
 606         weak(false),
 607         garbage(false)
 608     {
 609         name = property_getName(property);
 610         const char *attributes(property_getAttributes(property));
 611
 612         for (char *state, *token(apr_strtok(apr_pstrdup(pool_, attributes), ",", &state)); token != NULL; token = apr_strtok(NULL, ",", &state)) {
 613             switch (*token) {
 614                 case 'R': readonly = true; break;
 615                 case 'C': copy = true; break;
 616                 case '&': retain = true; break;
 617                 case 'N': nonatomic = true; break;
 618                 case 'G': getter_ = token + 1; break;
 619                 case 'S': setter_ = token + 1; break;
 620                 case 'V': variable = token + 1; break;
 621             }
 622         }
 623
 624         /*if (variable == NULL) {
 625             variable = property_getName(property);
 626             size_t size(strlen(variable));
 627             char *name(new(pool_) char[size + 2]);
 628             name[0] = '_';
 629             memcpy(name + 1, variable, size);
 630             name[size + 1] = '\0';
 631             variable = name;
 632         }*/
 633     }
 634
 635     const char *Getter() {
 636         if (getter_ == NULL)
 637             getter_ = apr_pstrdup(pool_, name);
 638         return getter_;
 639     }
 640
 641     const char *Setter() {
 642         if (setter_ == NULL && !readonly) {
 643             size_t length(strlen(name));
 644
 645             char *temp(new(pool_) char[length + 5]);
 646             temp[0] = 's';
 647             temp[1] = 'e';
 648             temp[2] = 't';
 649
 650             if (length != 0) {
 651                 temp[3] = toupper(name[0]);
 652                 memcpy(temp + 4, name + 1, length - 1);
 653             }
 654
 655             temp[length + 3] = ':';
 656             temp[length + 4] = '\0';
 657             setter_ = temp;
 658         }
 659
 660         return setter_;
 661     }
 662
 663 };
 664
 665 @implementation NSProxy (Cycript)
 666
 667 - (NSObject *) cy$toJSON:(NSString *)key {
 668     return [self description];
 669 }
 670
 671 - (NSString *) cy$toCYON {
 672     return [[self cy$toJSON:@""] cy$toCYON];
 673 }
 674
 675 @end
 676
 677 @implementation NSObject (Cycript)
 678
 679 - (JSValueRef) cy$JSValueInContext:(JSContextRef)context {
 680     return CYMakeInstance(context, self, false);
 681 }
 682
 683 - (JSType) cy$JSType {
 684     return kJSTypeObject;
 685 }
 686
 687 - (NSObject *) cy$toJSON:(NSString *)key {
 688     return [self description];
 689 }
 690
 691 - (NSString *) cy$toCYON {
 692     return [[self cy$toJSON:@""] cy$toCYON];
 693 }
 694
 695 - (NSString *) cy$toKey {
 696     return [self cy$toCYON];
 697 }
 698
 699 - (NSObject *) cy$getProperty:(NSString *)name {
 700     /*if (![name isEqualToString:@"prototype"])
 701         NSLog(@"get:%@", name);*/
 702     return nil;
 703 }
 704
 705 - (bool) cy$setProperty:(NSString *)name to:(NSObject *)value {
 706     //NSLog(@"set:%@", name);
 707     return false;
 708 }
 709
 710 - (bool) cy$deleteProperty:(NSString *)name {
 711     //NSLog(@"delete:%@", name);
 712     return false;
 713 }
 714
 715 @end
 716
 717 NSString *NSCFType$cy$toJSON(id self, SEL sel, NSString *key) {
 718     return [(NSString *) CFCopyDescription((CFTypeRef) self) autorelease];
 719 }
 720
 721 @implementation WebUndefined (Cycript)
 722
 723 - (JSType) cy$JSType {
 724     return kJSTypeUndefined;
 725 }
 726
 727 - (NSObject *) cy$toJSON:(NSString *)key {
 728     return self;
 729 }
 730
 731 - (NSString *) cy$toCYON {
 732     return @"undefined";
 733 }
 734
 735 - (JSValueRef) cy$JSValueInContext:(JSContextRef)context {
 736     return CYJSUndefined(context);
 737 }
 738
 739 @end
 740
 741 @implementation NSNull (Cycript)
 742
 743 - (JSType) cy$JSType {
 744     return kJSTypeNull;
 745 }
 746
 747 - (NSObject *) cy$toJSON:(NSString *)key {
 748     return self;
 749 }
 750
 751 - (NSString *) cy$toCYON {
 752     return @"null";
 753 }
 754
 755 @end
 756
 757 @implementation NSArray (Cycript)
 758
 759 - (NSString *) cy$toCYON {
 760     NSMutableString *json([[[NSMutableString alloc] init] autorelease]);
 761     [json appendString:@"["];
 762
 763     bool comma(false);
 764     for (id object in self) {
 765         if (comma)
 766             [json appendString:@","];
 767         else
 768             comma = true;
 769         if ([object cy$JSType] != kJSTypeUndefined)
 770             [json appendString:CYPoolNSCYON(NULL, object)];
 771         else {
 772             [json appendString:@","];
 773             comma = false;
 774         }
 775     }
 776
 777     [json appendString:@"]"];
 778     return json;
 779 }
 780
 781 - (NSObject *) cy$getProperty:(NSString *)name {
 782     if ([name isEqualToString:@"length"])
 783         return [NSNumber numberWithUnsignedInteger:[self count]];
 784
 785     ssize_t index;
 786     if (!CYGetIndex(NULL, name, index) || index < 0 || index >= static_cast<ssize_t>([self count]))
 787         return [super cy$getProperty:name];
 788     else
 789         return [self objectAtIndex:index];
 790 }
 791
 792 @end
 793
 794 @implementation NSMutableArray (Cycript)
 795
 796 - (bool) cy$setProperty:(NSString *)name to:(NSObject *)value {
 797     ssize_t index;
 798     if (!CYGetIndex(NULL, name, index) || index < 0 || index >= static_cast<ssize_t>([self count]))
 799         return [super cy$setProperty:name to:value];
 800     else {
 801         [self replaceObjectAtIndex:index withObject:(value ?: [NSNull null])];
 802         return true;
 803     }
 804 }
 805
 806 - (bool) cy$deleteProperty:(NSString *)name {
 807     ssize_t index;
 808     if (!CYGetIndex(NULL, name, index) || index < 0 || index >= static_cast<ssize_t>([self count]))
 809         return [super cy$deleteProperty:name];
 810     else {
 811         [self removeObjectAtIndex:index];
 812         return true;
 813     }
 814 }
 815
 816 @end
 817
 818 @implementation NSDictionary (Cycript)
 819
 820 - (NSString *) cy$toCYON {
 821     NSMutableString *json([[[NSMutableString alloc] init] autorelease]);
 822     [json appendString:@"{"];
 823
 824     bool comma(false);
 825     for (id key in self) {
 826         if (comma)
 827             [json appendString:@","];
 828         else
 829             comma = true;
 830         [json appendString:[key cy$toKey]];
 831         [json appendString:@":"];
 832         NSObject *object([self objectForKey:key]);
 833         [json appendString:CYPoolNSCYON(NULL, object)];
 834     }
 835
 836     [json appendString:@"}"];
 837     return json;
 838 }
 839
 840 - (NSObject *) cy$getProperty:(NSString *)name {
 841     return [self objectForKey:name];
 842 }
 843
 844 @end
 845
 846 @implementation NSMutableDictionary (Cycript)
 847
 848 - (bool) cy$setProperty:(NSString *)name to:(NSObject *)value {
 849     [self setObject:(value ?: [NSNull null]) forKey:name];
 850     return true;
 851 }
 852
 853 - (bool) cy$deleteProperty:(NSString *)name {
 854     if ([self objectForKey:name] == nil)
 855         return false;
 856     else {
 857         [self removeObjectForKey:name];
 858         return true;
 859     }
 860 }
 861
 862 @end
 863
 864 @implementation NSNumber (Cycript)
 865
 866 - (JSType) cy$JSType {
 867     // XXX: this just seems stupid
 868     return [self class] == NSCFBoolean_ ? kJSTypeBoolean : kJSTypeNumber;
 869 }
 870
 871 - (NSObject *) cy$toJSON:(NSString *)key {
 872     return self;
 873 }
 874
 875 - (NSString *) cy$toCYON {
 876     return [self cy$JSType] != kJSTypeBoolean ? [self stringValue] : [self boolValue] ? @"true" : @"false";
 877 }
 878
 879 - (JSValueRef) cy$JSValueInContext:(JSContextRef)context {
 880     return [self cy$JSType] != kJSTypeBoolean ? CYCastJSValue(context, [self doubleValue]) : CYCastJSValue(context, [self boolValue]);
 881 }
 882
 883 @end
 884
 885 @implementation NSString (Cycript)
 886
 887 - (JSType) cy$JSType {
 888     return kJSTypeString;
 889 }
 890
 891 - (NSObject *) cy$toJSON:(NSString *)key {
 892     return self;
 893 }
 894
 895 - (NSString *) cy$toCYON {
 896     // XXX: this should use the better code from Output.cpp
 897     CFMutableStringRef json(CFStringCreateMutableCopy(kCFAllocatorDefault, 0, (CFStringRef) self));
 898
 899     CFStringFindAndReplace(json, CFSTR("\\"), CFSTR("\\\\"), CFRangeMake(0, CFStringGetLength(json)), 0);
 900     CFStringFindAndReplace(json, CFSTR("\""), CFSTR("\\\""), CFRangeMake(0, CFStringGetLength(json)), 0);
 901     CFStringFindAndReplace(json, CFSTR("\t"), CFSTR("\\t"), CFRangeMake(0, CFStringGetLength(json)), 0);
 902     CFStringFindAndReplace(json, CFSTR("\r"), CFSTR("\\r"), CFRangeMake(0, CFStringGetLength(json)), 0);
 903     CFStringFindAndReplace(json, CFSTR("\n"), CFSTR("\\n"), CFRangeMake(0, CFStringGetLength(json)), 0);
 904
 905     CFStringInsert(json, 0, CFSTR("\""));
 906     CFStringAppend(json, CFSTR("\""));
 907
 908     return [reinterpret_cast<const NSString *>(json) autorelease];
 909 }
 910
 911 - (NSString *) cy$toKey {
 912     const char *value([self UTF8String]);
 913     size_t size(strlen(value));
 914
 915     if (size == 0)
 916         goto cyon;
 917
 918     if (DigitRange_[value[0]]) {
 919         ssize_t index;
 920         if (!CYGetIndex(NULL, self, index) || index < 0)
 921             goto cyon;
 922     } else {
 923         if (!WordStartRange_[value[0]])
 924             goto cyon;
 925         for (size_t i(1); i != size; ++i)
 926             if (!WordEndRange_[value[i]])
 927                 goto cyon;
 928     }
 929
 930     return self;
 931
 932   cyon:
 933     return [self cy$toCYON];
 934 }
 935
 936 - (void *) cy$symbol {
 937     CYPool pool;
 938     return dlsym(RTLD_DEFAULT, CYPoolCString(pool, self));
 939 }
 940
 941 @end
 942
 943 @interface CYJSObject : NSDictionary {
 944     JSObjectRef object_;
 945     JSContextRef context_;
 946 }
 947
 948 - (id) initWithJSObject:(JSObjectRef)object inContext:(JSContextRef)context;
 949
 950 - (NSString *) cy$toJSON:(NSString *)key;
 951
 952 - (NSUInteger) count;
 953 - (id) objectForKey:(id)key;
 954 - (NSEnumerator *) keyEnumerator;
 955 - (void) setObject:(id)object forKey:(id)key;
 956 - (void) removeObjectForKey:(id)key;
 957
 958 @end
 959
 960 @interface CYJSArray : NSArray {
 961     JSObjectRef object_;
 962     JSContextRef context_;
 963 }
 964
 965 - (id) initWithJSObject:(JSObjectRef)object inContext:(JSContextRef)context;
 966
 967 - (NSUInteger) count;
 968 - (id) objectAtIndex:(NSUInteger)index;
 969
 970 @end
 971
 972 CYRange DigitRange_    (0x3ff000000000000LLU, 0x000000000000000LLU); // 0-9
 973 CYRange WordStartRange_(0x000001000000000LLU, 0x7fffffe87fffffeLLU); // A-Za-z_$
 974 CYRange WordEndRange_  (0x3ff001000000000LLU, 0x7fffffe87fffffeLLU); // A-Za-z_$0-9
 975
 976 #define CYTry \
 977     @try
 978 #define CYCatch \
 979     @catch (id error) { \
 980         CYThrow(context, error, exception); \
 981         return NULL; \
 982     }
 983
 984 void CYThrow(JSContextRef context, JSValueRef value);
 985
 986 apr_status_t CYPoolRelease_(void *data) {
 987     id object(reinterpret_cast<id>(data));
 988     [object release];
 989     return APR_SUCCESS;
 990 }
 991
 992 id CYPoolRelease(apr_pool_t *pool, id object) {
 993     if (object == nil)
 994         return nil;
 995     else if (pool == NULL)
 996         return [object autorelease];
 997     else {
 998         apr_pool_cleanup_register(pool, object, &CYPoolRelease_, &apr_pool_cleanup_null);
 999         return object;
1000     }
1001 }
1002
1003 CFTypeRef CYPoolRelease(apr_pool_t *pool, CFTypeRef object) {
1004     return (CFTypeRef) CYPoolRelease(pool, (id) object);
1005 }
1006
1007 id CYCastNSObject_(apr_pool_t *pool, JSContextRef context, JSObjectRef object) {
1008     JSValueRef exception(NULL);
1009     bool array(JSValueIsInstanceOfConstructor(context, object, Array_, &exception));
1010     CYThrow(context, exception);
1011     id value(array ? [CYJSArray alloc] : [CYJSObject alloc]);
1012     return CYPoolRelease(pool, [value initWithJSObject:object inContext:context]);
1013 }
1014
1015 id CYCastNSObject(apr_pool_t *pool, JSContextRef context, JSObjectRef object) {
1016     if (!JSValueIsObjectOfClass(context, object, Instance_))
1017         return CYCastNSObject_(pool, context, object);
1018     else {
1019         Instance *data(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
1020         return data->GetValue();
1021     }
1022 }
1023
1024 JSStringRef CYCopyJSString(id value) {
1025     return value == NULL ? NULL : JSStringCreateWithCFString(reinterpret_cast<CFStringRef>([value description]));
1026 }
1027
1028 JSStringRef CYCopyJSString(const char *value) {
1029     return value == NULL ? NULL : JSStringCreateWithUTF8CString(value);
1030 }
1031
1032 JSStringRef CYCopyJSString(JSStringRef value) {
1033     return value == NULL ? NULL : JSStringRetain(value);
1034 }
1035
1036 JSStringRef CYCopyJSString(JSContextRef context, JSValueRef value) {
1037     if (JSValueIsNull(context, value))
1038         return NULL;
1039     JSValueRef exception(NULL);
1040     JSStringRef string(JSValueToStringCopy(context, value, &exception));
1041     CYThrow(context, exception);
1042     return string;
1043 }
1044
1045 class CYJSString {
1046   private:
1047     JSStringRef string_;
1048
1049     void Clear_() {
1050         if (string_ != NULL)
1051             JSStringRelease(string_);
1052     }
1053
1054   public:
1055     CYJSString(const CYJSString &rhs) :
1056         string_(CYCopyJSString(rhs.string_))
1057     {
1058     }
1059
1060     template <typename Arg0_>
1061     CYJSString(Arg0_ arg0) :
1062         string_(CYCopyJSString(arg0))
1063     {
1064     }
1065
1066     template <typename Arg0_, typename Arg1_>
1067     CYJSString(Arg0_ arg0, Arg1_ arg1) :
1068         string_(CYCopyJSString(arg0, arg1))
1069     {
1070     }
1071
1072     CYJSString &operator =(const CYJSString &rhs) {
1073         Clear_();
1074         string_ = CYCopyJSString(rhs.string_);
1075         return *this;
1076     }
1077
1078     ~CYJSString() {
1079         Clear_();
1080     }
1081
1082     void Clear() {
1083         Clear_();
1084         string_ = NULL;
1085     }
1086
1087     operator JSStringRef() const {
1088         return string_;
1089     }
1090 };
1091
1092 CFStringRef CYCopyCFString(JSStringRef value) {
1093     return JSStringCopyCFString(kCFAllocatorDefault, value);
1094 }
1095
1096 CFStringRef CYCopyCFString(JSContextRef context, JSValueRef value) {
1097     return CYCopyCFString(CYJSString(context, value));
1098 }
1099
1100 double CYCastDouble(const char *value, size_t size) {
1101     char *end;
1102     double number(strtod(value, &end));
1103     if (end != value + size)
1104         return NAN;
1105     return number;
1106 }
1107
1108 double CYCastDouble(const char *value) {
1109     return CYCastDouble(value, strlen(value));
1110 }
1111
1112 double CYCastDouble(JSContextRef context, JSValueRef value) {
1113     JSValueRef exception(NULL);
1114     double number(JSValueToNumber(context, value, &exception));
1115     CYThrow(context, exception);
1116     return number;
1117 }
1118
1119 CFNumberRef CYCopyCFNumber(JSContextRef context, JSValueRef value) {
1120     double number(CYCastDouble(context, value));
1121     return CFNumberCreate(kCFAllocatorDefault, kCFNumberDoubleType, &number);
1122 }
1123
1124 CFStringRef CYCopyCFString(const char *value) {
1125     return CFStringCreateWithCString(kCFAllocatorDefault, value, kCFStringEncodingUTF8);
1126 }
1127
1128 NSString *CYCastNSString(apr_pool_t *pool, const char *value) {
1129     return (NSString *) CYPoolRelease(pool, CYCopyCFString(value));
1130 }
1131
1132 NSString *CYCastNSString(apr_pool_t *pool, JSStringRef value) {
1133     return (NSString *) CYPoolRelease(pool, CYCopyCFString(value));
1134 }
1135
1136 bool CYCastBool(JSContextRef context, JSValueRef value) {
1137     return JSValueToBoolean(context, value);
1138 }
1139
1140 CFTypeRef CYCFType(apr_pool_t *pool, JSContextRef context, JSValueRef value, bool cast) {
1141     CFTypeRef object;
1142     bool copy;
1143
1144     switch (JSType type = JSValueGetType(context, value)) {
1145         case kJSTypeUndefined:
1146             object = [WebUndefined undefined];
1147             copy = false;
1148         break;
1149
1150         case kJSTypeNull:
1151             return NULL;
1152         break;
1153
1154         case kJSTypeBoolean:
1155             object = CYCastBool(context, value) ? kCFBooleanTrue : kCFBooleanFalse;
1156             copy = false;
1157         break;
1158
1159         case kJSTypeNumber:
1160             object = CYCopyCFNumber(context, value);
1161             copy = true;
1162         break;
1163
1164         case kJSTypeString:
1165             object = CYCopyCFString(context, value);
1166             copy = true;
1167         break;
1168
1169         case kJSTypeObject:
1170             // XXX: this might could be more efficient
1171             object = (CFTypeRef) CYCastNSObject(pool, context, (JSObjectRef) value);
1172             copy = false;
1173         break;
1174
1175         default:
1176             @throw [NSException exceptionWithName:NSInternalInconsistencyException reason:[NSString stringWithFormat:@"JSValueGetType() == 0x%x", type] userInfo:nil];
1177         break;
1178     }
1179
1180     if (cast != copy)
1181         return object;
1182     else if (copy)
1183         return CYPoolRelease(pool, object);
1184     else
1185         return CFRetain(object);
1186 }
1187
1188 CFTypeRef CYCastCFType(apr_pool_t *pool, JSContextRef context, JSValueRef value) {
1189     return CYCFType(pool, context, value, true);
1190 }
1191
1192 CFTypeRef CYCopyCFType(apr_pool_t *pool, JSContextRef context, JSValueRef value) {
1193     return CYCFType(pool, context, value, false);
1194 }
1195
1196 NSArray *CYCastNSArray(JSPropertyNameArrayRef names) {
1197     CYPool pool;
1198     size_t size(JSPropertyNameArrayGetCount(names));
1199     NSMutableArray *array([NSMutableArray arrayWithCapacity:size]);
1200     for (size_t index(0); index != size; ++index)
1201         [array addObject:CYCastNSString(pool, JSPropertyNameArrayGetNameAtIndex(names, index))];
1202     return array;
1203 }
1204
1205 id CYCastNSObject(apr_pool_t *pool, JSContextRef context, JSValueRef value) {
1206     return reinterpret_cast<const NSObject *>(CYCastCFType(pool, context, value));
1207 }
1208
1209 void CYThrow(JSContextRef context, JSValueRef value) {
1210     if (value == NULL)
1211         return;
1212     @throw CYCastNSObject(NULL, context, value);
1213 }
1214
1215 JSValueRef CYJSNull(JSContextRef context) {
1216     return JSValueMakeNull(context);
1217 }
1218
1219 JSValueRef CYCastJSValue(JSContextRef context, JSStringRef value) {
1220     return value == NULL ? CYJSNull(context) : JSValueMakeString(context, value);
1221 }
1222
1223 JSValueRef CYCastJSValue(JSContextRef context, const char *value) {
1224     return CYCastJSValue(context, CYJSString(value));
1225 }
1226
1227 JSValueRef CYCastJSValue(JSContextRef context, id value) {
1228     if (value == nil)
1229         return CYJSNull(context);
1230     else if ([value respondsToSelector:@selector(cy$JSValueInContext:)])
1231         return [value cy$JSValueInContext:context];
1232     else
1233         return CYMakeInstance(context, value, false);
1234 }
1235
1236 JSObjectRef CYCastJSObject(JSContextRef context, JSValueRef value) {
1237     JSValueRef exception(NULL);
1238     JSObjectRef object(JSValueToObject(context, value, &exception));
1239     CYThrow(context, exception);
1240     return object;
1241 }
1242
1243 JSValueRef CYGetProperty(JSContextRef context, JSObjectRef object, size_t index) {
1244     JSValueRef exception(NULL);
1245     JSValueRef value(JSObjectGetPropertyAtIndex(context, object, index, &exception));
1246     CYThrow(context, exception);
1247     return value;
1248 }
1249
1250 JSValueRef CYGetProperty(JSContextRef context, JSObjectRef object, JSStringRef name) {
1251     JSValueRef exception(NULL);
1252     JSValueRef value(JSObjectGetProperty(context, object, name, &exception));
1253     CYThrow(context, exception);
1254     return value;
1255 }
1256
1257 void CYSetProperty(JSContextRef context, JSObjectRef object, JSStringRef name, JSValueRef value) {
1258     JSValueRef exception(NULL);
1259     JSObjectSetProperty(context, object, name, value, kJSPropertyAttributeNone, &exception);
1260     CYThrow(context, exception);
1261 }
1262
1263 void CYThrow(JSContextRef context, id error, JSValueRef *exception) {
1264     if (exception == NULL)
1265         throw error;
1266     *exception = CYCastJSValue(context, error);
1267 }
1268
1269 JSValueRef CYCallAsFunction(JSContextRef context, JSObjectRef function, JSObjectRef _this, size_t count, JSValueRef arguments[]) {
1270     JSValueRef exception(NULL);
1271     JSValueRef value(JSObjectCallAsFunction(context, function, _this, count, arguments, &exception));
1272     CYThrow(context, exception);
1273     return value;
1274 }
1275
1276 bool CYIsCallable(JSContextRef context, JSValueRef value) {
1277     // XXX: this isn't actually correct
1278     return value != NULL && JSValueIsObject(context, value);
1279 }
1280
1281 @implementation CYJSObject
1282
1283 - (id) initWithJSObject:(JSObjectRef)object inContext:(JSContextRef)context {
1284     if ((self = [super init]) != nil) {
1285         object_ = object;
1286         context_ = context;
1287     } return self;
1288 }
1289
1290 - (NSObject *) cy$toJSON:(NSString *)key {
1291     JSValueRef toJSON(CYGetProperty(context_, object_, toJSON_));
1292     if (!CYIsCallable(context_, toJSON))
1293         return [super cy$toJSON:key];
1294     else {
1295         JSValueRef arguments[1] = {CYCastJSValue(context_, key)};
1296         JSValueRef value(CYCallAsFunction(context_, (JSObjectRef) toJSON, object_, 1, arguments));
1297         // XXX: do I really want an NSNull here?!
1298         return CYCastNSObject(NULL, context_, value) ?: [NSNull null];
1299     }
1300 }
1301
1302 - (NSString *) cy$toCYON {
1303     JSValueRef toCYON(CYGetProperty(context_, object_, toCYON_));
1304     if (!CYIsCallable(context_, toCYON))
1305         return [super cy$toCYON];
1306     else {
1307         JSValueRef value(CYCallAsFunction(context_, (JSObjectRef) toCYON, object_, 0, NULL));
1308         return CYCastNSString(NULL, CYJSString(context_, value));
1309     }
1310 }
1311
1312 - (NSUInteger) count {
1313     JSPropertyNameArrayRef names(JSObjectCopyPropertyNames(context_, object_));
1314     size_t size(JSPropertyNameArrayGetCount(names));
1315     JSPropertyNameArrayRelease(names);
1316     return size;
1317 }
1318
1319 - (id) objectForKey:(id)key {
1320     return CYCastNSObject(NULL, context_, CYGetProperty(context_, object_, CYJSString(key))) ?: [NSNull null];
1321 }
1322
1323 - (NSEnumerator *) keyEnumerator {
1324     JSPropertyNameArrayRef names(JSObjectCopyPropertyNames(context_, object_));
1325     NSEnumerator *enumerator([CYCastNSArray(names) objectEnumerator]);
1326     JSPropertyNameArrayRelease(names);
1327     return enumerator;
1328 }
1329
1330 - (void) setObject:(id)object forKey:(id)key {
1331     CYSetProperty(context_, object_, CYJSString(key), CYCastJSValue(context_, object));
1332 }
1333
1334 - (void) removeObjectForKey:(id)key {
1335     JSValueRef exception(NULL);
1336     (void) JSObjectDeleteProperty(context_, object_, CYJSString(key), &exception);
1337     CYThrow(context_, exception);
1338 }
1339
1340 @end
1341
1342 @implementation CYJSArray
1343
1344 - (id) initWithJSObject:(JSObjectRef)object inContext:(JSContextRef)context {
1345     if ((self = [super init]) != nil) {
1346         object_ = object;
1347         context_ = context;
1348     } return self;
1349 }
1350
1351 - (NSUInteger) count {
1352     return CYCastDouble(context_, CYGetProperty(context_, object_, length_));
1353 }
1354
1355 - (id) objectAtIndex:(NSUInteger)index {
1356     JSValueRef exception(NULL);
1357     JSValueRef value(JSObjectGetPropertyAtIndex(context_, object_, index, &exception));
1358     CYThrow(context_, exception);
1359     return CYCastNSObject(NULL, context_, value) ?: [NSNull null];
1360 }
1361
1362 @end
1363
1364 NSString *CYCopyNSCYON(id value) {
1365     Class _class(object_getClass(value));
1366     SEL sel(@selector(cy$toCYON));
1367
1368     NSString *string;
1369
1370     if (Method toCYON = class_getInstanceMethod(_class, sel))
1371         string = reinterpret_cast<NSString *(*)(id, SEL)>(method_getImplementation(toCYON))(value, sel);
1372     else if (Method methodSignatureForSelector = class_getInstanceMethod(_class, @selector(methodSignatureForSelector:))) {
1373         if (reinterpret_cast<NSMethodSignature *(*)(id, SEL, SEL)>(method_getImplementation(methodSignatureForSelector))(value, @selector(methodSignatureForSelector:), sel) != nil)
1374             string = [value cy$toCYON];
1375         else goto fail;
1376     } else fail: {
1377         if (value == NSZombie_)
1378             string = @"_NSZombie_";
1379         else if (_class == NSZombie_)
1380             string = [NSString stringWithFormat:@"<_NSZombie_: %p>", value];
1381         else if (value == NSMessageBuilder_ || value == Object_)
1382             string = nil;
1383         else
1384             string = [NSString stringWithFormat:@"%@", value];
1385     }
1386
1387     // XXX: frowny pants
1388     if (string == nil)
1389         string = @"undefined";
1390     return [string retain];
1391 }
1392
1393 NSString *CYCopyNSCYON(JSContextRef context, JSValueRef value, JSValueRef *exception) {
1394     CYTry {
1395         CYPoolTry {
1396             return CYCopyNSCYON(CYCastNSObject(NULL, context, value) ?: [NSNull null]);
1397         } CYPoolCatch(NULL)
1398     } CYCatch
1399 }
1400
1401 NSString *CYPoolNSCYON(apr_pool_t *pool, id value) {
1402     return CYPoolRelease(pool, static_cast<id>(CYCopyNSCYON(value)));
1403 }
1404
1405 const char *CYPoolCCYON(apr_pool_t *pool, JSContextRef context, JSValueRef value, JSValueRef *exception) {
1406     if (NSString *json = CYCopyNSCYON(context, value, exception)) {
1407         const char *string(CYPoolCString(pool, json));
1408         [json release];
1409         return string;
1410     } else return NULL;
1411 }
1412
1413 // XXX: use objc_getAssociatedObject and objc_setAssociatedObject on 10.6
1414 struct CYInternal :
1415     CYData
1416 {
1417     JSObjectRef object_;
1418
1419     CYInternal() :
1420         object_(NULL)
1421     {
1422     }
1423
1424     ~CYInternal() {
1425         // XXX: delete object_? ;(
1426     }
1427
1428     static CYInternal *Get(id self) {
1429         CYInternal *internal(NULL);
1430         if (object_getInstanceVariable(self, "cy$internal_", reinterpret_cast<void **>(&internal)) == NULL) {
1431             // XXX: do something epic? ;P
1432         }
1433
1434         return internal;
1435     }
1436
1437     static CYInternal *Set(id self) {
1438         CYInternal *internal(NULL);
1439         if (Ivar ivar = object_getInstanceVariable(self, "cy$internal_", reinterpret_cast<void **>(&internal))) {
1440             if (internal == NULL) {
1441                 internal = new CYInternal();
1442                 object_setIvar(self, ivar, reinterpret_cast<id>(internal));
1443             }
1444         } else {
1445             // XXX: do something epic? ;P
1446         }
1447
1448         return internal;
1449     }
1450
1451     JSValueRef GetProperty(JSContextRef context, JSStringRef name) {
1452         if (object_ == NULL)
1453             return NULL;
1454         return CYGetProperty(context, object_, name);
1455     }
1456
1457     void SetProperty(JSContextRef context, JSStringRef name, JSValueRef value) {
1458         if (object_ == NULL)
1459             object_ = JSObjectMake(context, NULL, NULL);
1460         CYSetProperty(context, object_, name, value);
1461     }
1462 };
1463
1464 JSObjectRef CYMakeSelector(JSContextRef context, SEL sel) {
1465     Selector_privateData *data(new Selector_privateData(sel));
1466     return JSObjectMake(context, Selector_, data);
1467 }
1468
1469 JSObjectRef CYMakePointer(JSContextRef context, void *pointer, sig::Type *type, ffi_type *ffi, JSObjectRef owner) {
1470     Pointer *data(new Pointer(pointer, type, owner));
1471     return JSObjectMake(context, Pointer_, data);
1472 }
1473
1474 JSObjectRef CYMakeFunctor(JSContextRef context, void (*function)(), const char *type) {
1475     Functor_privateData *data(new Functor_privateData(type, function));
1476     return JSObjectMake(context, Functor_, data);
1477 }
1478
1479 const char *CYPoolCString(apr_pool_t *pool, JSStringRef value) {
1480     if (pool == NULL) {
1481         const char *string([CYCastNSString(NULL, value) UTF8String]);
1482         return string;
1483     } else {
1484         size_t size(JSStringGetMaximumUTF8CStringSize(value));
1485         char *string(new(pool) char[size]);
1486         JSStringGetUTF8CString(value, string, size);
1487         return string;
1488     }
1489 }
1490
1491 const char *CYPoolCString(apr_pool_t *pool, JSContextRef context, JSValueRef value) {
1492     return JSValueIsNull(context, value) ? NULL : CYPoolCString(pool, CYJSString(context, value));
1493 }
1494
1495 bool CYGetIndex(apr_pool_t *pool, JSStringRef value, ssize_t &index) {
1496     return CYGetIndex(CYPoolCString(pool, value), index);
1497 }
1498
1499 // XXX: this macro is unhygenic
1500 #define CYCastCString(context, value) ({ \
1501     char *utf8; \
1502     if (value == NULL) \
1503         utf8 = NULL; \
1504     else if (JSStringRef string = CYCopyJSString(context, value)) { \
1505         size_t size(JSStringGetMaximumUTF8CStringSize(string)); \
1506         utf8 = reinterpret_cast<char *>(alloca(size)); \
1507         JSStringGetUTF8CString(string, utf8, size); \
1508         JSStringRelease(string); \
1509     } else \
1510         utf8 = NULL; \
1511     utf8; \
1512 })
1513
1514 void *CYCastPointer_(JSContextRef context, JSValueRef value) {
1515     switch (JSValueGetType(context, value)) {
1516         case kJSTypeNull:
1517             return NULL;
1518         /*case kJSTypeString:
1519             return dlsym(RTLD_DEFAULT, CYCastCString(context, value));
1520         case kJSTypeObject:
1521             if (JSValueIsObjectOfClass(context, value, Pointer_)) {
1522                 Pointer *data(reinterpret_cast<Pointer *>(JSObjectGetPrivate((JSObjectRef) value)));
1523                 return data->value_;
1524             }*/
1525         default:
1526             double number(CYCastDouble(context, value));
1527             if (std::isnan(number))
1528                 @throw [NSException exceptionWithName:NSInvalidArgumentException reason:@"cannot convert value to pointer" userInfo:nil];
1529             return reinterpret_cast<void *>(static_cast<uintptr_t>(static_cast<long long>(number)));
1530     }
1531 }
1532
1533 template <typename Type_>
1534 _finline Type_ CYCastPointer(JSContextRef context, JSValueRef value) {
1535     return reinterpret_cast<Type_>(CYCastPointer_(context, value));
1536 }
1537
1538 SEL CYCastSEL(JSContextRef context, JSValueRef value) {
1539     if (JSValueIsObjectOfClass(context, value, Selector_)) {
1540         Selector_privateData *data(reinterpret_cast<Selector_privateData *>(JSObjectGetPrivate((JSObjectRef) value)));
1541         return reinterpret_cast<SEL>(data->value_);
1542     } else
1543         return CYCastPointer<SEL>(context, value);
1544 }
1545
1546 void CYPoolFFI(apr_pool_t *pool, JSContextRef context, sig::Type *type, ffi_type *ffi, void *data, JSValueRef value) {
1547     switch (type->primitive) {
1548         case sig::boolean_P:
1549             *reinterpret_cast<bool *>(data) = JSValueToBoolean(context, value);
1550         break;
1551
1552 #define CYPoolFFI_(primitive, native) \
1553         case sig::primitive ## _P: \
1554             *reinterpret_cast<native *>(data) = CYCastDouble(context, value); \
1555         break;
1556
1557         CYPoolFFI_(uchar, unsigned char)
1558         CYPoolFFI_(char, char)
1559         CYPoolFFI_(ushort, unsigned short)
1560         CYPoolFFI_(short, short)
1561         CYPoolFFI_(ulong, unsigned long)
1562         CYPoolFFI_(long, long)
1563         CYPoolFFI_(uint, unsigned int)
1564         CYPoolFFI_(int, int)
1565         CYPoolFFI_(ulonglong, unsigned long long)
1566         CYPoolFFI_(longlong, long long)
1567         CYPoolFFI_(float, float)
1568         CYPoolFFI_(double, double)
1569
1570         case sig::object_P:
1571         case sig::typename_P:
1572             *reinterpret_cast<id *>(data) = CYCastNSObject(pool, context, value);
1573         break;
1574
1575         case sig::selector_P:
1576             *reinterpret_cast<SEL *>(data) = CYCastSEL(context, value);
1577         break;
1578
1579         case sig::pointer_P:
1580             *reinterpret_cast<void **>(data) = CYCastPointer<void *>(context, value);
1581         break;
1582
1583         case sig::string_P:
1584             *reinterpret_cast<const char **>(data) = CYPoolCString(pool, context, value);
1585         break;
1586
1587         case sig::struct_P: {
1588             uint8_t *base(reinterpret_cast<uint8_t *>(data));
1589             JSObjectRef aggregate(JSValueIsObject(context, value) ? (JSObjectRef) value : NULL);
1590             for (size_t index(0); index != type->data.signature.count; ++index) {
1591                 sig::Element *element(&type->data.signature.elements[index]);
1592                 ffi_type *field(ffi->elements[index]);
1593
1594                 JSValueRef rhs;
1595                 if (aggregate == NULL)
1596                     rhs = value;
1597                 else {
1598                     rhs = CYGetProperty(context, aggregate, index);
1599                     if (JSValueIsUndefined(context, rhs)) {
1600                         if (element->name != NULL)
1601                             rhs = CYGetProperty(context, aggregate, CYJSString(element->name));
1602                         else
1603                             goto undefined;
1604                         if (JSValueIsUndefined(context, rhs)) undefined:
1605                             @throw [NSException exceptionWithName:NSInvalidArgumentException reason:@"unable to extract structure value" userInfo:nil];
1606                     }
1607                 }
1608
1609                 CYPoolFFI(pool, context, element->type, field, base, rhs);
1610                 // XXX: alignment?
1611                 base += field->size;
1612             }
1613         } break;
1614
1615         case sig::void_P:
1616         break;
1617
1618         default:
1619             NSLog(@"CYPoolFFI(%c)\n", type->primitive);
1620             _assert(false);
1621     }
1622 }
1623
1624 JSValueRef CYFromFFI(JSContextRef context, sig::Type *type, ffi_type *ffi, void *data, bool initialize = false, JSObjectRef owner = NULL) {
1625     JSValueRef value;
1626
1627     switch (type->primitive) {
1628         case sig::boolean_P:
1629             value = CYCastJSValue(context, *reinterpret_cast<bool *>(data));
1630         break;
1631
1632 #define CYFromFFI_(primitive, native) \
1633         case sig::primitive ## _P: \
1634             value = CYCastJSValue(context, *reinterpret_cast<native *>(data)); \
1635         break;
1636
1637         CYFromFFI_(uchar, unsigned char)
1638         CYFromFFI_(char, char)
1639         CYFromFFI_(ushort, unsigned short)
1640         CYFromFFI_(short, short)
1641         CYFromFFI_(ulong, unsigned long)
1642         CYFromFFI_(long, long)
1643         CYFromFFI_(uint, unsigned int)
1644         CYFromFFI_(int, int)
1645         CYFromFFI_(ulonglong, unsigned long long)
1646         CYFromFFI_(longlong, long long)
1647         CYFromFFI_(float, float)
1648         CYFromFFI_(double, double)
1649
1650         case sig::object_P: {
1651             if (id object = *reinterpret_cast<id *>(data)) {
1652                 value = CYCastJSValue(context, object);
1653                 if (initialize)
1654                     [object release];
1655             } else goto null;
1656         } break;
1657
1658         case sig::typename_P:
1659             value = CYMakeInstance(context, *reinterpret_cast<Class *>(data), true);
1660         break;
1661
1662         case sig::selector_P:
1663             if (SEL sel = *reinterpret_cast<SEL *>(data))
1664                 value = CYMakeSelector(context, sel);
1665             else goto null;
1666         break;
1667
1668         case sig::pointer_P:
1669             if (void *pointer = *reinterpret_cast<void **>(data))
1670                 value = CYMakePointer(context, pointer, type->data.data.type, ffi, owner);
1671             else goto null;
1672         break;
1673
1674         case sig::string_P:
1675             if (char *utf8 = *reinterpret_cast<char **>(data))
1676                 value = CYCastJSValue(context, utf8);
1677             else goto null;
1678         break;
1679
1680         case sig::struct_P:
1681             value = CYMakeStruct(context, data, type, ffi, owner);
1682         break;
1683
1684         case sig::void_P:
1685             value = CYJSUndefined(context);
1686         break;
1687
1688         null:
1689             value = CYJSNull(context);
1690         break;
1691
1692         default:
1693             NSLog(@"CYFromFFI(%c)\n", type->primitive);
1694             _assert(false);
1695     }
1696
1697     return value;
1698 }
1699
1700 static JSValueRef Instance_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
1701     CYPool pool;
1702
1703     CYTry {
1704         id self(CYCastNSObject(pool, context, object));
1705         NSString *name(CYCastNSString(pool, property));
1706
1707         if (CYInternal *internal = CYInternal::Get(self))
1708             if (JSValueRef value = internal->GetProperty(context, property))
1709                 return value;
1710
1711         CYPoolTry {
1712             if (NSObject *data = [self cy$getProperty:name])
1713                 return CYCastJSValue(context, data);
1714         } CYPoolCatch(NULL)
1715
1716         const char *string(CYPoolCString(pool, name));
1717         Class _class(object_getClass(self));
1718
1719         if (objc_property_t property = class_getProperty(_class, string)) {
1720             PropertyAttributes attributes(property);
1721             SEL sel(sel_registerName(attributes.Getter()));
1722             return CYSendMessage(pool, context, self, sel, 0, NULL, false, exception);
1723         }
1724
1725         if (SEL sel = sel_getUid(string))
1726             // XXX: possibly use a more "awesome" check?
1727             if (class_getInstanceMethod(_class, sel) != NULL)
1728                 return CYSendMessage(pool, context, self, sel, 0, NULL, false, exception);
1729
1730         return NULL;
1731     } CYCatch
1732 }
1733
1734 static JSValueRef Instance_getProperty_$cyi(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
1735     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
1736     return Internal::Make(context, internal->GetValue(), object);
1737 }
1738
1739 static bool Instance_setProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef value, JSValueRef *exception) {
1740     CYPool pool;
1741
1742     CYTry {
1743         id self(CYCastNSObject(pool, context, object));
1744         NSString *name(CYCastNSString(pool, property));
1745         NSString *data(CYCastNSObject(pool, context, value));
1746
1747         CYPoolTry {
1748             if ([self cy$setProperty:name to:data])
1749                 return true;
1750         } CYPoolCatch(NULL)
1751
1752         const char *string(CYPoolCString(pool, name));
1753         Class _class(object_getClass(self));
1754
1755         if (objc_property_t property = class_getProperty(_class, string)) {
1756             PropertyAttributes attributes(property);
1757             if (const char *setter = attributes.Setter()) {
1758                 SEL sel(sel_registerName(setter));
1759                 JSValueRef arguments[1] = {value};
1760                 CYSendMessage(pool, context, self, sel, 1, arguments, false, exception);
1761                 return true;
1762             }
1763         }
1764
1765         size_t length(strlen(string));
1766
1767         char set[length + 5];
1768
1769         set[0] = 's';
1770         set[1] = 'e';
1771         set[2] = 't';
1772
1773         if (string[0] != '\0') {
1774             set[3] = toupper(string[0]);
1775             memcpy(set + 4, string + 1, length - 1);
1776         }
1777
1778         set[length + 3] = ':';
1779         set[length + 4] = '\0';
1780
1781         if (SEL sel = sel_getUid(set))
1782             // XXX: possibly use a more "awesome" check?
1783             if (class_getInstanceMethod(_class, sel) != NULL) {
1784                 JSValueRef arguments[1] = {value};
1785                 CYSendMessage(pool, context, self, sel, 1, arguments, false, exception);
1786             }
1787
1788         if (CYInternal *internal = CYInternal::Set(self)) {
1789             internal->SetProperty(context, property, value);
1790             return true;
1791         }
1792
1793         return false;
1794     } CYCatch
1795 }
1796
1797 static bool Instance_deleteProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
1798     CYTry {
1799         CYPoolTry {
1800             id self(CYCastNSObject(NULL, context, object));
1801             NSString *name(CYCastNSString(NULL, property));
1802             return [self cy$deleteProperty:name];
1803         } CYPoolCatch(NULL)
1804     } CYCatch
1805 }
1806
1807 static void Instance_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
1808     CYPool pool;
1809     NSString *self(CYCastNSObject(pool, context, object));
1810     Class _class(object_getClass(self));
1811
1812     {
1813         unsigned int size;
1814         objc_property_t *data(class_copyPropertyList(_class, &size));
1815         for (size_t i(0); i != size; ++i)
1816             JSPropertyNameAccumulatorAddName(names, CYJSString(property_getName(data[i])));
1817         free(data);
1818     }
1819 }
1820
1821 static JSObjectRef Instance_callAsConstructor(JSContextRef context, JSObjectRef object, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
1822     CYTry {
1823         Instance *data(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
1824         JSObjectRef value(Instance::Make(context, [data->GetValue() alloc], Instance::Uninitialized));
1825         return value;
1826     } CYCatch
1827 }
1828
1829 static JSValueRef Internal_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
1830     Internal *internal(reinterpret_cast<Internal *>(JSObjectGetPrivate(object)));
1831     CYPool pool;
1832
1833     CYTry {
1834         id self(internal->GetValue());
1835         const char *name(CYPoolCString(pool, property));
1836
1837         if (Ivar ivar = object_getInstanceVariable(self, name, NULL)) {
1838             Type_privateData type(pool, ivar_getTypeEncoding(ivar));
1839             return CYFromFFI(context, type.type_, type.GetFFI(), reinterpret_cast<uint8_t *>(self) + ivar_getOffset(ivar));
1840         }
1841
1842         return NULL;
1843     } CYCatch
1844 }
1845
1846 static bool Internal_setProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef value, JSValueRef *exception) {
1847     Internal *internal(reinterpret_cast<Internal *>(JSObjectGetPrivate(object)));
1848     CYPool pool;
1849
1850     CYTry {
1851         id self(internal->GetValue());
1852         const char *name(CYPoolCString(pool, property));
1853
1854         if (Ivar ivar = object_getInstanceVariable(self, name, NULL)) {
1855             Type_privateData type(pool, ivar_getTypeEncoding(ivar));
1856             CYPoolFFI(pool, context, type.type_, type.GetFFI(), reinterpret_cast<uint8_t *>(self) + ivar_getOffset(ivar), value);
1857             return true;
1858         }
1859
1860         return false;
1861     } CYCatch
1862 }
1863
1864 static void Internal_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
1865     Internal *internal(reinterpret_cast<Internal *>(JSObjectGetPrivate(object)));
1866     CYPool pool;
1867
1868     id self(internal->GetValue());
1869     Class _class(object_getClass(self));
1870
1871     for (Class super(_class); super != NULL; super = class_getSuperclass(super)) {
1872         unsigned int size;
1873         Ivar *data(class_copyIvarList(super, &size));
1874         for (size_t i(0); i != size; ++i)
1875             JSPropertyNameAccumulatorAddName(names, CYJSString(ivar_getName(data[i])));
1876         free(data);
1877     }
1878 }
1879
1880 static JSValueRef Internal_callAsFunction_$cya(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
1881     Internal *internal(reinterpret_cast<Internal *>(JSObjectGetPrivate(object)));
1882     return internal->owner_;
1883 }
1884
1885 bool Index_(apr_pool_t *pool, Struct_privateData *internal, JSStringRef property, ssize_t &index, uint8_t *&base) {
1886     Type_privateData *typical(internal->type_);
1887     sig::Type *type(typical->type_);
1888     if (type == NULL)
1889         return false;
1890
1891     const char *name(CYPoolCString(pool, property));
1892     size_t length(strlen(name));
1893     double number(CYCastDouble(name, length));
1894
1895     size_t count(type->data.signature.count);
1896
1897     if (std::isnan(number)) {
1898         if (property == NULL)
1899             return false;
1900
1901         sig::Element *elements(type->data.signature.elements);
1902
1903         for (size_t local(0); local != count; ++local) {
1904             sig::Element *element(&elements[local]);
1905             if (element->name != NULL && strcmp(name, element->name) == 0) {
1906                 index = local;
1907                 goto base;
1908             }
1909         }
1910
1911         return false;
1912     } else {
1913         index = static_cast<ssize_t>(number);
1914         if (index != number || index < 0 || static_cast<size_t>(index) >= count)
1915             return false;
1916     }
1917
1918   base:
1919     ffi_type **elements(typical->GetFFI()->elements);
1920
1921     base = reinterpret_cast<uint8_t *>(internal->value_);
1922     for (ssize_t local(0); local != index; ++local)
1923         base += elements[local]->size;
1924
1925     return true;
1926 }
1927
1928 static JSValueRef Pointer_getIndex(JSContextRef context, JSObjectRef object, size_t index, JSValueRef *exception) {
1929     Pointer *internal(reinterpret_cast<Pointer *>(JSObjectGetPrivate(object)));
1930     Type_privateData *typical(internal->type_);
1931
1932     ffi_type *ffi(typical->GetFFI());
1933
1934     uint8_t *base(reinterpret_cast<uint8_t *>(internal->value_));
1935     base += ffi->size * index;
1936
1937     JSObjectRef owner(internal->owner_ ?: object);
1938
1939     CYTry {
1940         return CYFromFFI(context, typical->type_, ffi, base, false, owner);
1941     } CYCatch
1942 }
1943
1944 static JSValueRef Pointer_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
1945     CYPool pool;
1946     Pointer *internal(reinterpret_cast<Pointer *>(JSObjectGetPrivate(object)));
1947     Type_privateData *typical(internal->type_);
1948
1949     if (typical->type_ == NULL)
1950         return NULL;
1951
1952     ssize_t index;
1953     if (!CYGetIndex(pool, property, index))
1954         return NULL;
1955
1956     return Pointer_getIndex(context, object, index, exception);
1957 }
1958
1959 static JSValueRef Pointer_getProperty_$cyi(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
1960     return Pointer_getIndex(context, object, 0, exception);
1961 }
1962
1963 static bool Pointer_setIndex(JSContextRef context, JSObjectRef object, size_t index, JSValueRef value, JSValueRef *exception) {
1964     Pointer *internal(reinterpret_cast<Pointer *>(JSObjectGetPrivate(object)));
1965     Type_privateData *typical(internal->type_);
1966
1967     ffi_type *ffi(typical->GetFFI());
1968
1969     uint8_t *base(reinterpret_cast<uint8_t *>(internal->value_));
1970     base += ffi->size * index;
1971
1972     CYTry {
1973         CYPoolFFI(NULL, context, typical->type_, ffi, base, value);
1974         return true;
1975     } CYCatch
1976 }
1977
1978 static bool Pointer_setProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef value, JSValueRef *exception) {
1979     CYPool pool;
1980     Pointer *internal(reinterpret_cast<Pointer *>(JSObjectGetPrivate(object)));
1981     Type_privateData *typical(internal->type_);
1982
1983     if (typical->type_ == NULL)
1984         return NULL;
1985
1986     ssize_t index;
1987     if (!CYGetIndex(pool, property, index))
1988         return NULL;
1989
1990     return Pointer_setIndex(context, object, 0, value, exception);
1991 }
1992
1993 static bool Pointer_setProperty_$cyi(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef value, JSValueRef *exception) {
1994     return Pointer_setIndex(context, object, 0, value, exception);
1995 }
1996
1997 static JSValueRef Struct_callAsFunction_$cya(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
1998     Struct_privateData *internal(reinterpret_cast<Struct_privateData *>(JSObjectGetPrivate(_this)));
1999     Type_privateData *typical(internal->type_);
2000     return CYMakePointer(context, internal->value_, typical->type_, typical->ffi_, _this);
2001 }
2002
2003 static JSValueRef Struct_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
2004     CYPool pool;
2005     Struct_privateData *internal(reinterpret_cast<Struct_privateData *>(JSObjectGetPrivate(object)));
2006     Type_privateData *typical(internal->type_);
2007
2008     ssize_t index;
2009     uint8_t *base;
2010
2011     if (!Index_(pool, internal, property, index, base))
2012         return NULL;
2013
2014     JSObjectRef owner(internal->owner_ ?: object);
2015
2016     CYTry {
2017         return CYFromFFI(context, typical->type_->data.signature.elements[index].type, typical->GetFFI()->elements[index], base, false, owner);
2018     } CYCatch
2019 }
2020
2021 static bool Struct_setProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef value, JSValueRef *exception) {
2022     CYPool pool;
2023     Struct_privateData *internal(reinterpret_cast<Struct_privateData *>(JSObjectGetPrivate(object)));
2024     Type_privateData *typical(internal->type_);
2025
2026     ssize_t index;
2027     uint8_t *base;
2028
2029     if (!Index_(pool, internal, property, index, base))
2030         return false;
2031
2032     CYTry {
2033         CYPoolFFI(NULL, context, typical->type_->data.signature.elements[index].type, typical->GetFFI()->elements[index], base, value);
2034         return true;
2035     } CYCatch
2036 }
2037
2038 static void Struct_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
2039     Struct_privateData *internal(reinterpret_cast<Struct_privateData *>(JSObjectGetPrivate(object)));
2040     Type_privateData *typical(internal->type_);
2041     sig::Type *type(typical->type_);
2042
2043     if (type == NULL)
2044         return;
2045
2046     size_t count(type->data.signature.count);
2047     sig::Element *elements(type->data.signature.elements);
2048
2049     char number[32];
2050
2051     for (size_t index(0); index != count; ++index) {
2052         const char *name;
2053         name = elements[index].name;
2054
2055         if (name == NULL) {
2056             sprintf(number, "%lu", index);
2057             name = number;
2058         }
2059
2060         JSPropertyNameAccumulatorAddName(names, CYJSString(name));
2061     }
2062 }
2063
2064 JSValueRef CYCallFunction(apr_pool_t *pool, JSContextRef context, size_t setups, void *setup[], size_t count, const JSValueRef arguments[], bool initialize, JSValueRef *exception, sig::Signature *signature, ffi_cif *cif, void (*function)()) {
2065     CYTry {
2066         if (setups + count != signature->count - 1)
2067             @throw [NSException exceptionWithName:NSInvalidArgumentException reason:@"incorrect number of arguments to ffi function" userInfo:nil];
2068
2069         size_t size(setups + count);
2070         void *values[size];
2071         memcpy(values, setup, sizeof(void *) * setups);
2072
2073         for (size_t index(setups); index != size; ++index) {
2074             sig::Element *element(&signature->elements[index + 1]);
2075             ffi_type *ffi(cif->arg_types[index]);
2076             // XXX: alignment?
2077             values[index] = new(pool) uint8_t[ffi->size];
2078             CYPoolFFI(pool, context, element->type, ffi, values[index], arguments[index - setups]);
2079         }
2080
2081         uint8_t value[cif->rtype->size];
2082         ffi_call(cif, function, value, values);
2083
2084         return CYFromFFI(context, signature->elements[0].type, cif->rtype, value, initialize);
2085     } CYCatch
2086 }
2087
2088 void Closure_(ffi_cif *cif, void *result, void **arguments, void *arg) {
2089     ffoData *data(reinterpret_cast<ffoData *>(arg));
2090
2091     JSContextRef context(data->context_);
2092
2093     size_t count(data->cif_.nargs);
2094     JSValueRef values[count];
2095
2096     for (size_t index(0); index != count; ++index)
2097         values[index] = CYFromFFI(context, data->signature_.elements[1 + index].type, data->cif_.arg_types[index], arguments[index]);
2098
2099     JSValueRef value(CYCallAsFunction(context, data->function_, NULL, count, values));
2100     CYPoolFFI(NULL, context, data->signature_.elements[0].type, data->cif_.rtype, result, value);
2101 }
2102
2103 JSObjectRef CYMakeFunctor(JSContextRef context, JSObjectRef function, const char *type) {
2104     // XXX: in case of exceptions this will leak
2105     ffoData *data(new ffoData(type));
2106
2107     ffi_closure *closure((ffi_closure *) _syscall(mmap(
2108         NULL, sizeof(ffi_closure),
2109         PROT_READ | PROT_WRITE, MAP_ANON | MAP_PRIVATE,
2110         -1, 0
2111     )));
2112
2113     ffi_status status(ffi_prep_closure(closure, &data->cif_, &Closure_, data));
2114     _assert(status == FFI_OK);
2115
2116     _syscall(mprotect(closure, sizeof(*closure), PROT_READ | PROT_EXEC));
2117
2118     data->value_ = closure;
2119
2120     data->context_ = CYGetJSContext();
2121     data->function_ = function;
2122
2123     return JSObjectMake(context, Functor_, data);
2124 }
2125
2126 static JSValueRef ObjectiveC_Classes_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
2127     CYTry {
2128         CYPool pool;
2129         NSString *name(CYCastNSString(pool, property));
2130         if (Class _class = NSClassFromString(name))
2131             return CYMakeInstance(context, _class, true);
2132         return NULL;
2133     } CYCatch
2134 }
2135
2136 static void ObjectiveC_Classes_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
2137     size_t size(objc_getClassList(NULL, 0));
2138     Class *data(reinterpret_cast<Class *>(malloc(sizeof(Class) * size)));
2139
2140   get:
2141     size_t writ(objc_getClassList(data, size));
2142     if (size < writ) {
2143         size = writ;
2144         if (Class *copy = reinterpret_cast<Class *>(realloc(data, sizeof(Class) * writ))) {
2145             data = copy;
2146             goto get;
2147         } else goto done;
2148     }
2149
2150     for (size_t i(0); i != writ; ++i)
2151         JSPropertyNameAccumulatorAddName(names, CYJSString(class_getName(data[i])));
2152
2153   done:
2154     free(data);
2155 }
2156
2157 static JSValueRef ObjectiveC_Image_Classes_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
2158     const char *internal(reinterpret_cast<const char *>(JSObjectGetPrivate(object)));
2159
2160     CYTry {
2161         CYPool pool;
2162         const char *name(CYPoolCString(pool, property));
2163         unsigned int size;
2164         const char **data(objc_copyClassNamesForImage(internal, &size));
2165         JSValueRef value;
2166         for (size_t i(0); i != size; ++i)
2167             if (strcmp(name, data[i]) == 0) {
2168                 if (Class _class = objc_getClass(name)) {
2169                     value = CYMakeInstance(context, _class, true);
2170                     goto free;
2171                 } else
2172                     break;
2173             }
2174         value = NULL;
2175       free:
2176         free(data);
2177         return value;
2178     } CYCatch
2179 }
2180
2181 static void ObjectiveC_Image_Classes_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
2182     const char *internal(reinterpret_cast<const char *>(JSObjectGetPrivate(object)));
2183     unsigned int size;
2184     const char **data(objc_copyClassNamesForImage(internal, &size));
2185     for (size_t i(0); i != size; ++i)
2186         JSPropertyNameAccumulatorAddName(names, CYJSString(data[i]));
2187     free(data);
2188 }
2189
2190 static JSValueRef ObjectiveC_Images_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
2191     CYTry {
2192         CYPool pool;
2193         const char *name(CYPoolCString(pool, property));
2194         unsigned int size;
2195         const char **data(objc_copyImageNames(&size));
2196         for (size_t i(0); i != size; ++i)
2197             if (strcmp(name, data[i]) == 0) {
2198                 name = data[i];
2199                 goto free;
2200             }
2201         name = NULL;
2202       free:
2203         free(data);
2204         if (name == NULL)
2205             return NULL;
2206         JSObjectRef value(JSObjectMake(context, NULL, NULL));
2207         CYSetProperty(context, value, CYJSString("classes"), JSObjectMake(context, ObjectiveC_Image_Classes_, const_cast<char *>(name)));
2208         return value;
2209     } CYCatch
2210 }
2211
2212 static void ObjectiveC_Images_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
2213     unsigned int size;
2214     const char **data(objc_copyImageNames(&size));
2215     for (size_t i(0); i != size; ++i)
2216         JSPropertyNameAccumulatorAddName(names, CYJSString(data[i]));
2217     free(data);
2218 }
2219
2220 static JSValueRef ObjectiveC_Protocols_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
2221     CYTry {
2222         CYPool pool;
2223         NSString *name(CYCastNSString(pool, property));
2224         if (Protocol *protocol = NSProtocolFromString(name))
2225             return CYMakeInstance(context, protocol, true);
2226         return NULL;
2227     } CYCatch
2228 }
2229
2230 static void ObjectiveC_Protocols_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
2231     unsigned int size;
2232     Protocol **data(objc_copyProtocolList(&size));
2233     for (size_t i(0); i != size; ++i)
2234         JSPropertyNameAccumulatorAddName(names, CYJSString(protocol_getName(data[i])));
2235     free(data);
2236 }
2237
2238 static JSValueRef Runtime_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
2239     CYTry {
2240         CYPool pool;
2241         NSString *name(CYCastNSString(pool, property));
2242         if (Class _class = NSClassFromString(name))
2243             return CYMakeInstance(context, _class, true);
2244         if (NSMutableArray *entry = [[Bridge_ objectAtIndex:0] objectForKey:name])
2245             switch ([[entry objectAtIndex:0] intValue]) {
2246                 case 0:
2247                     return JSEvaluateScript(CYGetJSContext(), CYJSString([entry objectAtIndex:1]), NULL, NULL, 0, NULL);
2248                 case 1:
2249                     return CYMakeFunctor(context, reinterpret_cast<void (*)()>([name cy$symbol]), CYPoolCString(pool, [entry objectAtIndex:1]));
2250                 case 2:
2251                     // XXX: this is horrendously inefficient
2252                     sig::Signature signature;
2253                     sig::Parse(pool, &signature, CYPoolCString(pool, [entry objectAtIndex:1]), &Structor_);
2254                     ffi_cif cif;
2255                     sig::sig_ffi_cif(pool, &sig::ObjectiveC, &signature, &cif);
2256                     return CYFromFFI(context, signature.elements[0].type, cif.rtype, [name cy$symbol]);
2257             }
2258         return NULL;
2259     } CYCatch
2260 }
2261
2262 bool stret(ffi_type *ffi_type) {
2263     return ffi_type->type == FFI_TYPE_STRUCT && (
2264         ffi_type->size > OBJC_MAX_STRUCT_BY_VALUE ||
2265         struct_forward_array[ffi_type->size] != 0
2266     );
2267 }
2268
2269 extern "C" {
2270     int *_NSGetArgc(void);
2271     char ***_NSGetArgv(void);
2272     int UIApplicationMain(int argc, char *argv[], NSString *principalClassName, NSString *delegateClassName);
2273 }
2274
2275 static JSValueRef System_print(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2276     CYTry {
2277         NSLog(@"%s", CYCastCString(context, arguments[0]));
2278         return CYJSUndefined(context);
2279     } CYCatch
2280 }
2281
2282 JSValueRef CYSendMessage(apr_pool_t *pool, JSContextRef context, id self, SEL _cmd, size_t count, const JSValueRef arguments[], bool initialize, JSValueRef *exception) {
2283     const char *type;
2284
2285     Class _class(object_getClass(self));
2286     if (Method method = class_getInstanceMethod(_class, _cmd))
2287         type = method_getTypeEncoding(method);
2288     else {
2289         CYTry {
2290             CYPoolTry {
2291                 NSMethodSignature *method([self methodSignatureForSelector:_cmd]);
2292                 if (method == nil)
2293                     @throw [NSException exceptionWithName:NSInvalidArgumentException reason:[NSString stringWithFormat:@"unrecognized selector %s sent to object %p", sel_getName(_cmd), self] userInfo:nil];
2294                 type = CYPoolCString(pool, [method _typeString]);
2295             } CYPoolCatch(NULL)
2296         } CYCatch
2297     }
2298
2299     void *setup[2];
2300     setup[0] = &self;
2301     setup[1] = &_cmd;
2302
2303     sig::Signature signature;
2304     sig::Parse(pool, &signature, type, &Structor_);
2305
2306     ffi_cif cif;
2307     sig::sig_ffi_cif(pool, &sig::ObjectiveC, &signature, &cif);
2308
2309     void (*function)() = stret(cif.rtype) ? reinterpret_cast<void (*)()>(&objc_msgSend_stret) : reinterpret_cast<void (*)()>(&objc_msgSend);
2310     return CYCallFunction(pool, context, 2, setup, count, arguments, initialize, exception, &signature, &cif, function);
2311 }
2312
2313 static JSValueRef $objc_msgSend(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2314     CYPool pool;
2315
2316     bool uninitialized;
2317
2318     id self;
2319     SEL _cmd;
2320
2321     CYTry {
2322         if (count < 2)
2323             @throw [NSException exceptionWithName:NSInvalidArgumentException reason:@"too few arguments to objc_msgSend" userInfo:nil];
2324
2325         if (JSValueIsObjectOfClass(context, arguments[0], Instance_)) {
2326             Instance *data(reinterpret_cast<Instance *>(JSObjectGetPrivate((JSObjectRef) arguments[0])));
2327             self = data->GetValue();
2328             uninitialized = data->IsUninitialized();
2329             if (uninitialized)
2330                 data->value_ = nil;
2331         } else {
2332             self = CYCastNSObject(pool, context, arguments[0]);
2333             uninitialized = false;
2334         }
2335
2336         if (self == nil)
2337             return CYJSNull(context);
2338
2339         _cmd = CYCastSEL(context, arguments[1]);
2340     } CYCatch
2341
2342     return CYSendMessage(pool, context, self, _cmd, count - 2, arguments + 2, uninitialized, exception);
2343 }
2344
2345 MSHook(void, CYDealloc, id self, SEL sel) {
2346     CYInternal *internal;
2347     object_getInstanceVariable(self, "cy$internal_", reinterpret_cast<void **>(&internal));
2348     if (internal != NULL)
2349         delete internal;
2350     _CYDealloc(self, sel);
2351 }
2352
2353 MSHook(void, objc_registerClassPair, Class _class) {
2354     Class super(class_getSuperclass(_class));
2355     if (super == NULL || class_getInstanceVariable(super, "cy$internal_") == NULL) {
2356         class_addIvar(_class, "cy$internal_", sizeof(CYInternal *), log2(sizeof(CYInternal *)), "^{CYInternal}");
2357         MSHookMessage(_class, @selector(dealloc), MSHake(CYDealloc));
2358     }
2359
2360     _objc_registerClassPair(_class);
2361 }
2362
2363 static JSValueRef objc_registerClassPair_(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2364     CYTry {
2365         if (count != 1)
2366             @throw [NSException exceptionWithName:NSInvalidArgumentException reason:@"incorrect number of arguments to objc_registerClassPair" userInfo:nil];
2367         CYPool pool;
2368         Class _class(CYCastNSObject(pool, context, arguments[0]));
2369         $objc_registerClassPair(_class);
2370         return CYJSUndefined(context);
2371     } CYCatch
2372 }
2373
2374 static JSValueRef Selector_callAsFunction(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2375     JSValueRef setup[count + 2];
2376     setup[0] = _this;
2377     setup[1] = object;
2378     memcpy(setup + 2, arguments, sizeof(JSValueRef) * count);
2379     return $objc_msgSend(context, NULL, NULL, count + 2, setup, exception);
2380 }
2381
2382 static JSValueRef Functor_callAsFunction(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2383     CYPool pool;
2384     Functor_privateData *data(reinterpret_cast<Functor_privateData *>(JSObjectGetPrivate(object)));
2385     return CYCallFunction(pool, context, 0, NULL, count, arguments, false, exception, &data->signature_, &data->cif_, reinterpret_cast<void (*)()>(data->value_));
2386 }
2387
2388 JSObjectRef Selector_new(JSContextRef context, JSObjectRef object, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2389     CYTry {
2390         if (count != 1)
2391             @throw [NSException exceptionWithName:NSInvalidArgumentException reason:@"incorrect number of arguments to Selector constructor" userInfo:nil];
2392         const char *name(CYCastCString(context, arguments[0]));
2393         return CYMakeSelector(context, sel_registerName(name));
2394     } CYCatch
2395 }
2396
2397 JSObjectRef Pointer_new(JSContextRef context, JSObjectRef object, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2398     CYTry {
2399         if (count != 2)
2400             @throw [NSException exceptionWithName:NSInvalidArgumentException reason:@"incorrect number of arguments to Functor constructor" userInfo:nil];
2401
2402         void *value(CYCastPointer<void *>(context, arguments[0]));
2403         const char *type(CYCastCString(context, arguments[1]));
2404
2405         CYPool pool;
2406
2407         sig::Signature signature;
2408         sig::Parse(pool, &signature, type, &Structor_);
2409
2410         return CYMakePointer(context, value, signature.elements[0].type, NULL, NULL);
2411     } CYCatch
2412 }
2413
2414 JSObjectRef CYMakeType(JSContextRef context, JSObjectRef object, const char *type) {
2415     Type_privateData *internal(new Type_privateData(NULL, type));
2416     return JSObjectMake(context, Type_, internal);
2417 }
2418
2419 JSObjectRef Type_new(JSContextRef context, JSObjectRef object, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2420     CYTry {
2421         if (count != 1)
2422             @throw [NSException exceptionWithName:NSInvalidArgumentException reason:@"incorrect number of arguments to Type constructor" userInfo:nil];
2423         const char *type(CYCastCString(context, arguments[0]));
2424         return CYMakeType(context, object, type);
2425     } CYCatch
2426 }
2427
2428 static JSValueRef Type_callAsFunction(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2429     CYTry {
2430         if (count != 1)
2431             @throw [NSException exceptionWithName:NSInvalidArgumentException reason:@"incorrect number of arguments to type cast function" userInfo:nil];
2432         Type_privateData *internal(reinterpret_cast<Type_privateData *>(JSObjectGetPrivate(object)));
2433         sig::Type *type(internal->type_);
2434         ffi_type *ffi(internal->GetFFI());
2435         // XXX: alignment?
2436         uint8_t value[ffi->size];
2437         CYPool pool;
2438         CYPoolFFI(pool, context, type, ffi, value, arguments[0]);
2439         return CYFromFFI(context, type, ffi, value);
2440     } CYCatch
2441 }
2442
2443 static JSObjectRef Type_callAsConstructor(JSContextRef context, JSObjectRef object, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2444     CYTry {
2445         if (count > 1)
2446             @throw [NSException exceptionWithName:NSInvalidArgumentException reason:@"incorrect number of arguments to type cast function" userInfo:nil];
2447         Type_privateData *internal(reinterpret_cast<Type_privateData *>(JSObjectGetPrivate(object)));
2448         size_t size(count == 0 ? 0 : CYCastDouble(context, arguments[0]));
2449         // XXX: alignment?
2450         void *value(malloc(internal->GetFFI()->size * size));
2451         return CYMakePointer(context, value, internal->type_, internal->ffi_, NULL);
2452     } CYCatch
2453 }
2454
2455 JSObjectRef Functor_new(JSContextRef context, JSObjectRef object, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2456     CYTry {
2457         if (count != 2)
2458             @throw [NSException exceptionWithName:NSInvalidArgumentException reason:@"incorrect number of arguments to Functor constructor" userInfo:nil];
2459         const char *type(CYCastCString(context, arguments[1]));
2460         JSValueRef exception(NULL);
2461         if (JSValueIsInstanceOfConstructor(context, arguments[0], Function_, &exception)) {
2462             JSObjectRef function(CYCastJSObject(context, arguments[0]));
2463             return CYMakeFunctor(context, function, type);
2464         } else if (exception != NULL) {
2465             return NULL;
2466         } else {
2467             void (*function)()(CYCastPointer<void (*)()>(context, arguments[0]));
2468             return CYMakeFunctor(context, function, type);
2469         }
2470     } CYCatch
2471 }
2472
2473 JSValueRef CYValue_getProperty_value(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
2474     CYValue *internal(reinterpret_cast<CYValue *>(JSObjectGetPrivate(object)));
2475     return CYCastJSValue(context, reinterpret_cast<uintptr_t>(internal->value_));
2476 }
2477
2478 JSValueRef Selector_getProperty_prototype(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
2479     return Function_;
2480 }
2481
2482 static JSValueRef CYValue_callAsFunction_valueOf(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2483     CYTry {
2484         CYValue *internal(reinterpret_cast<CYValue *>(JSObjectGetPrivate(_this)));
2485         return CYCastJSValue(context, reinterpret_cast<uintptr_t>(internal->value_));
2486     } CYCatch
2487 }
2488
2489 static JSValueRef CYValue_callAsFunction_toJSON(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2490     return CYValue_callAsFunction_valueOf(context, object, _this, count, arguments, exception);
2491 }
2492
2493 static JSValueRef CYValue_callAsFunction_toCYON(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2494     CYTry {
2495         CYValue *internal(reinterpret_cast<CYValue *>(JSObjectGetPrivate(_this)));
2496         char string[32];
2497         sprintf(string, "%p", internal->value_);
2498         return CYCastJSValue(context, string);
2499     } CYCatch
2500 }
2501
2502 static JSValueRef Instance_callAsFunction_toCYON(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2503     CYTry {
2504         Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(_this)));
2505         CYPoolTry {
2506             return CYCastJSValue(context, CYJSString([internal->GetValue() cy$toCYON]));
2507         } CYPoolCatch(NULL)
2508     } CYCatch
2509 }
2510
2511 static JSValueRef Instance_callAsFunction_toJSON(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2512     CYTry {
2513         Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(_this)));
2514         CYPoolTry {
2515             NSString *key(count == 0 ? nil : CYCastNSString(NULL, CYJSString(context, arguments[0])));
2516             return CYCastJSValue(context, CYJSString([internal->GetValue() cy$toJSON:key]));
2517         } CYPoolCatch(NULL)
2518     } CYCatch
2519 }
2520
2521 static JSValueRef Instance_callAsFunction_toString(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2522     CYTry {
2523         Instance *data(reinterpret_cast<Instance *>(JSObjectGetPrivate(_this)));
2524         CYPoolTry {
2525             return CYCastJSValue(context, CYJSString([data->GetValue() description]));
2526         } CYPoolCatch(NULL)
2527     } CYCatch
2528 }
2529
2530 static JSValueRef Selector_callAsFunction_toString(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2531     CYTry {
2532         Selector_privateData *data(reinterpret_cast<Selector_privateData *>(JSObjectGetPrivate(_this)));
2533         return CYCastJSValue(context, sel_getName(data->GetValue()));
2534     } CYCatch
2535 }
2536
2537 static JSValueRef Selector_callAsFunction_toJSON(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2538     return Selector_callAsFunction_toString(context, object, _this, count, arguments, exception);
2539 }
2540
2541 static JSValueRef Selector_callAsFunction_toCYON(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2542     CYTry {
2543         Selector_privateData *internal(reinterpret_cast<Selector_privateData *>(JSObjectGetPrivate(_this)));
2544         const char *name(sel_getName(internal->GetValue()));
2545         CYPoolTry {
2546             return CYCastJSValue(context, CYJSString([NSString stringWithFormat:@"@selector(%s)", name]));
2547         } CYPoolCatch(NULL)
2548     } CYCatch
2549 }
2550
2551 static JSValueRef Selector_callAsFunction_type(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2552     CYTry {
2553         if (count != 1)
2554             @throw [NSException exceptionWithName:NSInvalidArgumentException reason:@"incorrect number of arguments to Selector.type" userInfo:nil];
2555         CYPool pool;
2556         Selector_privateData *internal(reinterpret_cast<Selector_privateData *>(JSObjectGetPrivate(_this)));
2557         Class _class(CYCastNSObject(pool, context, arguments[0]));
2558         SEL sel(internal->GetValue());
2559         if (Method method = class_getInstanceMethod(_class, sel))
2560             return CYCastJSValue(context, method_getTypeEncoding(method));
2561         else if (NSString *type = [[Bridge_ objectAtIndex:1] objectForKey:CYCastNSString(pool, sel_getName(sel))])
2562             return CYCastJSValue(context, CYJSString(type));
2563         else
2564             return CYJSNull(context);
2565     } CYCatch
2566 }
2567
2568 static JSValueRef Type_callAsFunction_toString(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2569     CYTry {
2570         Type_privateData *internal(reinterpret_cast<Type_privateData *>(JSObjectGetPrivate(_this)));
2571         CYPool pool;
2572         const char *type(sig::Unparse(pool, internal->type_));
2573         CYPoolTry {
2574             return CYCastJSValue(context, CYJSString(type));
2575         } CYPoolCatch(NULL)
2576     } CYCatch
2577 }
2578
2579 static JSValueRef Type_callAsFunction_toCYON(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2580     CYTry {
2581         Type_privateData *internal(reinterpret_cast<Type_privateData *>(JSObjectGetPrivate(_this)));
2582         CYPool pool;
2583         const char *type(sig::Unparse(pool, internal->type_));
2584         CYPoolTry {
2585             return CYCastJSValue(context, CYJSString([NSString stringWithFormat:@"new Type(%@)", [[NSString stringWithUTF8String:type] cy$toCYON]]));
2586         } CYPoolCatch(NULL)
2587     } CYCatch
2588 }
2589
2590 static JSValueRef Type_callAsFunction_toJSON(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2591     return Type_callAsFunction_toString(context, object, _this, count, arguments, exception);
2592 }
2593
2594 static JSStaticValue CYValue_staticValues[2] = {
2595     {"value", &CYValue_getProperty_value, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontDelete},
2596     {NULL, NULL, NULL, 0}
2597 };
2598
2599 static JSStaticValue Pointer_staticValues[2] = {
2600     {"$cyi", &Pointer_getProperty_$cyi, &Pointer_setProperty_$cyi, kJSPropertyAttributeDontDelete},
2601     {NULL, NULL, NULL, 0}
2602 };
2603
2604 static JSStaticFunction Pointer_staticFunctions[4] = {
2605     {"toCYON", &CYValue_callAsFunction_toCYON, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2606     {"toJSON", &CYValue_callAsFunction_toJSON, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2607     {"valueOf", &CYValue_callAsFunction_valueOf, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2608     {NULL, NULL, 0}
2609 };
2610
2611 static JSStaticFunction Struct_staticFunctions[2] = {
2612     {"$cya", &Struct_callAsFunction_$cya, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2613     {NULL, NULL, 0}
2614 };
2615
2616 static JSStaticFunction Functor_staticFunctions[4] = {
2617     {"toCYON", &CYValue_callAsFunction_toCYON, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2618     {"toJSON", &CYValue_callAsFunction_toJSON, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2619     {"valueOf", &CYValue_callAsFunction_valueOf, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2620     {NULL, NULL, 0}
2621 };
2622
2623 /*static JSStaticValue Selector_staticValues[2] = {
2624     {"prototype", &Selector_getProperty_prototype, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontDelete},
2625     {NULL, NULL, NULL, 0}
2626 };*/
2627
2628 static JSStaticValue Instance_staticValues[3] = {
2629     {"value", &CYValue_getProperty_value, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontDelete},
2630     {"$cyi", &Instance_getProperty_$cyi, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontDelete},
2631     {NULL, NULL, NULL, 0}
2632 };
2633
2634 static JSStaticFunction Instance_staticFunctions[4] = {
2635     {"toCYON", &Instance_callAsFunction_toCYON, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2636     {"toJSON", &Instance_callAsFunction_toJSON, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2637     {"toString", &Instance_callAsFunction_toString, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2638     {NULL, NULL, 0}
2639 };
2640
2641 static JSStaticFunction Internal_staticFunctions[2] = {
2642     {"$cya", &Internal_callAsFunction_$cya, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2643     {NULL, NULL, 0}
2644 };
2645
2646 static JSStaticFunction Selector_staticFunctions[5] = {
2647     {"toCYON", &Selector_callAsFunction_toCYON, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2648     {"toJSON", &Selector_callAsFunction_toJSON, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2649     {"toString", &Selector_callAsFunction_toString, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2650     {"type", &Selector_callAsFunction_type, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2651     {NULL, NULL, 0}
2652 };
2653
2654 static JSStaticFunction Type_staticFunctions[4] = {
2655     {"toCYON", &Type_callAsFunction_toCYON, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2656     {"toJSON", &Type_callAsFunction_toJSON, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2657     {"toString", &Type_callAsFunction_toString, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2658     {NULL, NULL, 0}
2659 };
2660
2661 CYDriver::CYDriver(const std::string &filename) :
2662     state_(CYClear),
2663     data_(NULL),
2664     size_(0),
2665     filename_(filename),
2666     source_(NULL)
2667 {
2668     ScannerInit();
2669 }
2670
2671 CYDriver::~CYDriver() {
2672     ScannerDestroy();
2673 }
2674
2675 void cy::parser::error(const cy::parser::location_type &location, const std::string &message) {
2676     CYDriver::Error error;
2677     error.location_ = location;
2678     error.message_ = message;
2679     driver.errors_.push_back(error);
2680 }
2681
2682 void CYSetArgs(int argc, const char *argv[]) {
2683     JSContextRef context(CYGetJSContext());
2684     JSValueRef args[argc];
2685     for (int i(0); i != argc; ++i)
2686         args[i] = CYCastJSValue(context, argv[i]);
2687     JSValueRef exception(NULL);
2688     JSObjectRef array(JSObjectMakeArray(context, argc, args, &exception));
2689     CYThrow(context, exception);
2690     CYSetProperty(context, System_, CYJSString("args"), array);
2691 }
2692
2693 JSObjectRef CYGetGlobalObject(JSContextRef context) {
2694     return JSContextGetGlobalObject(context);
2695 }
2696
2697 const char *CYExecute(apr_pool_t *pool, const char *code) { _pooled
2698     JSContextRef context(CYGetJSContext());
2699     JSValueRef exception(NULL), result;
2700
2701     try {
2702         result = JSEvaluateScript(context, CYJSString(code), NULL, NULL, 0, &exception);
2703     } catch (const char *error) {
2704         return error;
2705     }
2706
2707     if (exception != NULL) { error:
2708         result = exception;
2709         exception = NULL;
2710     }
2711
2712     if (JSValueIsUndefined(context, result))
2713         return NULL;
2714
2715     const char *json(CYPoolCCYON(pool, context, result, &exception));
2716     if (exception != NULL)
2717         goto error;
2718
2719     CYSetProperty(context, CYGetGlobalObject(context), Result_, result);
2720     return json;
2721 }
2722
2723 bool CYRecvAll_(int socket, uint8_t *data, size_t size) {
2724     while (size != 0) if (size_t writ = _syscall(recv(socket, data, size, 0))) {
2725         data += writ;
2726         size -= writ;
2727     } else
2728         return false;
2729     return true;
2730 }
2731
2732 bool CYSendAll_(int socket, const uint8_t *data, size_t size) {
2733     while (size != 0) if (size_t writ = _syscall(send(socket, data, size, 0))) {
2734         data += writ;
2735         size -= writ;
2736     } else
2737         return false;
2738     return true;
2739 }
2740
2741 static int Socket_;
2742 apr_pool_t *Pool_;
2743
2744 struct CYExecute_ {
2745     apr_pool_t *pool_;
2746     const char * volatile data_;
2747 };
2748
2749 // XXX: this is "tre lame"
2750 @interface CYClient_ : NSObject {
2751 }
2752
2753 - (void) execute:(NSValue *)value;
2754
2755 @end
2756
2757 @implementation CYClient_
2758
2759 - (void) execute:(NSValue *)value {
2760     CYExecute_ *execute(reinterpret_cast<CYExecute_ *>([value pointerValue]));
2761     const char *data(execute->data_);
2762     execute->data_ = NULL;
2763     execute->data_ = CYExecute(execute->pool_, data);
2764 }
2765
2766 @end
2767
2768 struct CYClient :
2769     CYData
2770 {
2771     int socket_;
2772     apr_thread_t *thread_;
2773
2774     CYClient(int socket) :
2775         socket_(socket)
2776     {
2777     }
2778
2779     ~CYClient() {
2780         _syscall(close(socket_));
2781     }
2782
2783     void Handle() { _pooled
2784         CYClient_ *client = [[[CYClient_ alloc] init] autorelease];
2785
2786         for (;;) {
2787             size_t size;
2788             if (!CYRecvAll(socket_, &size, sizeof(size)))
2789                 return;
2790
2791             CYPool pool;
2792             char *data(new(pool) char[size + 1]);
2793             if (!CYRecvAll(socket_, data, size))
2794                 return;
2795             data[size] = '\0';
2796
2797             CYDriver driver("");
2798             cy::parser parser(driver);
2799
2800             driver.data_ = data;
2801             driver.size_ = size;
2802
2803             const char *json;
2804             if (parser.parse() != 0 || !driver.errors_.empty()) {
2805                 json = NULL;
2806                 size = _not(size_t);
2807             } else {
2808                 std::ostringstream str;
2809                 driver.source_->Show(str);
2810                 std::string code(str.str());
2811                 CYExecute_ execute = {pool, code.c_str()};
2812                 [client performSelectorOnMainThread:@selector(execute:) withObject:[NSValue valueWithPointer:&execute] waitUntilDone:YES];
2813                 json = execute.data_;
2814                 size = json == NULL ? _not(size_t) : strlen(json);
2815             }
2816
2817             if (!CYSendAll(socket_, &size, sizeof(size)))
2818                 return;
2819             if (json != NULL)
2820                 if (!CYSendAll(socket_, json, size))
2821                     return;
2822         }
2823     }
2824 };
2825
2826 static void * APR_THREAD_FUNC OnClient(apr_thread_t *thread, void *data) {
2827     CYClient *client(reinterpret_cast<CYClient *>(data));
2828     client->Handle();
2829     delete client;
2830     return NULL;
2831 }
2832
2833 static void * APR_THREAD_FUNC Cyrver(apr_thread_t *thread, void *data) {
2834     for (;;) {
2835         int socket(_syscall(accept(Socket_, NULL, NULL)));
2836         CYClient *client(new CYClient(socket));
2837         apr_threadattr_t *attr;
2838         _aprcall(apr_threadattr_create(&attr, Pool_));
2839         _aprcall(apr_thread_create(&client->thread_, attr, &OnClient, client, client->pool_));
2840     }
2841
2842     return NULL;
2843 }
2844
2845 void Unlink() {
2846     pid_t pid(getpid());
2847     char path[104];
2848     sprintf(path, "/tmp/.s.cy.%u", pid);
2849     unlink(path);
2850 }
2851
2852 MSInitialize { _pooled
2853     _aprcall(apr_initialize());
2854     _aprcall(apr_pool_create(&Pool_, NULL));
2855
2856     Bridge_ = [[NSMutableArray arrayWithContentsOfFile:@"/usr/lib/libcycript.plist"] retain];
2857
2858     NSCFBoolean_ = objc_getClass("NSCFBoolean");
2859     NSCFType_ = objc_getClass("NSCFType");
2860     NSMessageBuilder_ = objc_getClass("NSMessageBuilder");
2861     NSZombie_ = objc_getClass("_NSZombie_");
2862     Object_ = objc_getClass("Object");
2863
2864     Socket_ = _syscall(socket(PF_UNIX, SOCK_STREAM, 0));
2865
2866     struct sockaddr_un address;
2867     memset(&address, 0, sizeof(address));
2868     address.sun_family = AF_UNIX;
2869
2870     pid_t pid(getpid());
2871     sprintf(address.sun_path, "/tmp/.s.cy.%u", pid);
2872
2873     try {
2874         _syscall(bind(Socket_, reinterpret_cast<sockaddr *>(&address), SUN_LEN(&address)));
2875         atexit(&Unlink);
2876         _syscall(listen(Socket_, 0));
2877
2878         apr_threadattr_t *attr;
2879         _aprcall(apr_threadattr_create(&attr, Pool_));
2880
2881         apr_thread_t *thread;
2882         _aprcall(apr_thread_create(&thread, attr, &Cyrver, NULL, Pool_));
2883     } catch (...) {
2884         NSLog(@"failed to setup Cyrver");
2885     }
2886 }
2887
2888 JSGlobalContextRef CYGetJSContext() {
2889     if (Context_ == NULL) {
2890         JSClassDefinition definition;
2891
2892         definition = kJSClassDefinitionEmpty;
2893         definition.className = "Functor";
2894         definition.staticFunctions = Functor_staticFunctions;
2895         definition.callAsFunction = &Functor_callAsFunction;
2896         definition.finalize = &CYData::Finalize;
2897         Functor_ = JSClassCreate(&definition);
2898
2899         definition = kJSClassDefinitionEmpty;
2900         definition.className = "Instance";
2901         definition.staticValues = Instance_staticValues;
2902         definition.staticFunctions = Instance_staticFunctions;
2903         definition.getProperty = &Instance_getProperty;
2904         definition.setProperty = &Instance_setProperty;
2905         definition.deleteProperty = &Instance_deleteProperty;
2906         definition.getPropertyNames = &Instance_getPropertyNames;
2907         definition.callAsConstructor = &Instance_callAsConstructor;
2908         definition.finalize = &CYData::Finalize;
2909         Instance_ = JSClassCreate(&definition);
2910
2911         definition = kJSClassDefinitionEmpty;
2912         definition.className = "Internal";
2913         definition.staticFunctions = Internal_staticFunctions;
2914         definition.getProperty = &Internal_getProperty;
2915         definition.setProperty = &Internal_setProperty;
2916         definition.getPropertyNames = &Internal_getPropertyNames;
2917         definition.finalize = &CYData::Finalize;
2918         Internal_ = JSClassCreate(&definition);
2919
2920         definition = kJSClassDefinitionEmpty;
2921         definition.className = "Pointer";
2922         definition.staticValues = Pointer_staticValues;
2923         definition.staticFunctions = Pointer_staticFunctions;
2924         definition.getProperty = &Pointer_getProperty;
2925         definition.setProperty = &Pointer_setProperty;
2926         definition.finalize = &CYData::Finalize;
2927         Pointer_ = JSClassCreate(&definition);
2928
2929         definition = kJSClassDefinitionEmpty;
2930         definition.className = "Selector";
2931         definition.staticValues = CYValue_staticValues;
2932         //definition.staticValues = Selector_staticValues;
2933         definition.staticFunctions = Selector_staticFunctions;
2934         definition.callAsFunction = &Selector_callAsFunction;
2935         definition.finalize = &CYData::Finalize;
2936         Selector_ = JSClassCreate(&definition);
2937
2938         definition = kJSClassDefinitionEmpty;
2939         definition.className = "Struct";
2940         definition.staticFunctions = Struct_staticFunctions;
2941         definition.getProperty = &Struct_getProperty;
2942         definition.setProperty = &Struct_setProperty;
2943         definition.getPropertyNames = &Struct_getPropertyNames;
2944         definition.finalize = &CYData::Finalize;
2945         Struct_ = JSClassCreate(&definition);
2946
2947         definition = kJSClassDefinitionEmpty;
2948         definition.className = "Type";
2949         definition.staticFunctions = Type_staticFunctions;
2950         //definition.getProperty = &Type_getProperty;
2951         definition.callAsFunction = &Type_callAsFunction;
2952         definition.callAsConstructor = &Type_callAsConstructor;
2953         definition.finalize = &CYData::Finalize;
2954         Type_ = JSClassCreate(&definition);
2955
2956         definition = kJSClassDefinitionEmpty;
2957         definition.className = "Runtime";
2958         definition.getProperty = &Runtime_getProperty;
2959         Runtime_ = JSClassCreate(&definition);
2960
2961         definition = kJSClassDefinitionEmpty;
2962         definition.className = "ObjectiveC::Classes";
2963         definition.getProperty = &ObjectiveC_Classes_getProperty;
2964         definition.getPropertyNames = &ObjectiveC_Classes_getPropertyNames;
2965         ObjectiveC_Classes_ = JSClassCreate(&definition);
2966
2967         definition = kJSClassDefinitionEmpty;
2968         definition.className = "ObjectiveC::Images";
2969         definition.getProperty = &ObjectiveC_Images_getProperty;
2970         definition.getPropertyNames = &ObjectiveC_Images_getPropertyNames;
2971         ObjectiveC_Images_ = JSClassCreate(&definition);
2972
2973         definition = kJSClassDefinitionEmpty;
2974         definition.className = "ObjectiveC::Image::Classes";
2975         definition.getProperty = &ObjectiveC_Image_Classes_getProperty;
2976         definition.getPropertyNames = &ObjectiveC_Image_Classes_getPropertyNames;
2977         definition.finalize = &CYData::Finalize;
2978         ObjectiveC_Image_Classes_ = JSClassCreate(&definition);
2979
2980         definition = kJSClassDefinitionEmpty;
2981         definition.className = "ObjectiveC::Protocols";
2982         definition.getProperty = &ObjectiveC_Protocols_getProperty;
2983         definition.getPropertyNames = &ObjectiveC_Protocols_getPropertyNames;
2984         ObjectiveC_Protocols_ = JSClassCreate(&definition);
2985
2986         definition = kJSClassDefinitionEmpty;
2987         //definition.getProperty = &Global_getProperty;
2988         JSClassRef Global(JSClassCreate(&definition));
2989
2990         JSGlobalContextRef context(JSGlobalContextCreate(Global));
2991         Context_ = context;
2992
2993         JSObjectRef global(CYGetGlobalObject(context));
2994
2995         JSObjectSetPrototype(context, global, JSObjectMake(context, Runtime_, NULL));
2996         ObjectiveC_ = JSObjectMake(context, NULL, NULL);
2997         CYSetProperty(context, global, CYJSString("ObjectiveC"), ObjectiveC_);
2998
2999         CYSetProperty(context, ObjectiveC_, CYJSString("classes"), JSObjectMake(context, ObjectiveC_Classes_, NULL));
3000         CYSetProperty(context, ObjectiveC_, CYJSString("images"), JSObjectMake(context, ObjectiveC_Images_, NULL));
3001         CYSetProperty(context, ObjectiveC_, CYJSString("protocols"), JSObjectMake(context, ObjectiveC_Protocols_, NULL));
3002
3003         CYSetProperty(context, global, CYJSString("Functor"), JSObjectMakeConstructor(context, Functor_, &Functor_new));
3004         CYSetProperty(context, global, CYJSString("Instance"), JSObjectMakeConstructor(context, Instance_, NULL));
3005         CYSetProperty(context, global, CYJSString("Pointer"), JSObjectMakeConstructor(context, Pointer_, &Pointer_new));
3006         CYSetProperty(context, global, CYJSString("Selector"), JSObjectMakeConstructor(context, Selector_, &Selector_new));
3007         CYSetProperty(context, global, CYJSString("Type"), JSObjectMakeConstructor(context, Type_, &Type_new));
3008
3009         MSHookFunction(&objc_registerClassPair, MSHake(objc_registerClassPair));
3010
3011         class_addMethod(NSCFType_, @selector(cy$toJSON:), reinterpret_cast<IMP>(&NSCFType$cy$toJSON), "@12@0:4@8");
3012
3013         CYSetProperty(context, global, CYJSString("objc_registerClassPair"), JSObjectMakeFunctionWithCallback(context, CYJSString("objc_registerClassPair"), &objc_registerClassPair_));
3014         CYSetProperty(context, global, CYJSString("objc_msgSend"), JSObjectMakeFunctionWithCallback(context, CYJSString("objc_msgSend"), &$objc_msgSend));
3015
3016         System_ = JSObjectMake(context, NULL, NULL);
3017         CYSetProperty(context, global, CYJSString("system"), System_);
3018         CYSetProperty(context, System_, CYJSString("args"), CYJSNull(context));
3019         //CYSetProperty(context, System_, CYJSString("global"), global);
3020
3021         CYSetProperty(context, System_, CYJSString("print"), JSObjectMakeFunctionWithCallback(context, CYJSString("print"), &System_print));
3022
3023         Result_ = JSStringCreateWithUTF8CString("_");
3024
3025         length_ = JSStringCreateWithUTF8CString("length");
3026         message_ = JSStringCreateWithUTF8CString("message");
3027         name_ = JSStringCreateWithUTF8CString("name");
3028         toCYON_ = JSStringCreateWithUTF8CString("toCYON");
3029         toJSON_ = JSStringCreateWithUTF8CString("toJSON");
3030
3031         Array_ = CYCastJSObject(context, CYGetProperty(context, global, CYJSString("Array")));
3032         Function_ = CYCastJSObject(context, CYGetProperty(context, global, CYJSString("Function")));
3033     }
3034
3035     return Context_;
3036 }