Handler.mm

   1 /* Cycript - Remote Execution Server and Disassembler
   2  * Copyright (C) 2009  Jay Freeman (saurik)
   3 */
   4
   5 /* Modified BSD License {{{ */
   6 /*
   7  *        Redistribution and use in source and binary
   8  * forms, with or without modification, are permitted
   9  * provided that the following conditions are met:
  10  *
  11  * 1. Redistributions of source code must retain the
  12  *    above copyright notice, this list of conditions
  13  *    and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the
  15  *    above copyright notice, this list of conditions
  16  *    and the following disclaimer in the documentation
  17  *    and/or other materials provided with the
  18  *    distribution.
  19  * 3. The name of the author may not be used to endorse
  20  *    or promote products derived from this software
  21  *    without specific prior written permission.
  22  *
  23  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS''
  24  * AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING,
  25  * BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
  26  * MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  27  * ARE DISCLAIMED. IN NO EVENT SHALL THE AUTHOR BE
  28  * LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  29  * EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  30  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
  31  * SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  32  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
  33  * LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR
  34  * TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
  35  * ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
  36  * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  37 */
  38 /* }}} */
  39
  40 #include "substrate.h"
  41 #include "cycript.hpp"
  42
  43 #include "Pooling.hpp"
  44 #include "Parser.hpp"
  45
  46 #include "Cycript.tab.hh"
  47
  48 #include <Foundation/Foundation.h>
  49 #include <apr_thread_proc.h>
  50 #include <unistd.h>
  51 #include <sstream>
  52
  53 struct CYExecute_ {
  54     apr_pool_t *pool_;
  55     const char * volatile data_;
  56 };
  57
  58 // XXX: this is "tre lame"
  59 @interface CYClient_ : NSObject {
  60 }
  61
  62 - (void) execute:(NSValue *)value;
  63
  64 @end
  65
  66 @implementation CYClient_
  67
  68 - (void) execute:(NSValue *)value {
  69     CYExecute_ *execute(reinterpret_cast<CYExecute_ *>([value pointerValue]));
  70     const char *data(execute->data_);
  71     execute->data_ = NULL;
  72     execute->data_ = CYExecute(execute->pool_, data);
  73 }
  74
  75 @end
  76
  77 struct CYClient :
  78     CYData
  79 {
  80     int socket_;
  81     apr_thread_t *thread_;
  82
  83     CYClient(int socket) :
  84         socket_(socket)
  85     {
  86     }
  87
  88     ~CYClient() {
  89         _syscall(close(socket_));
  90     }
  91
  92     void Handle() { _pooled
  93         CYClient_ *client = [[[CYClient_ alloc] init] autorelease];
  94
  95         for (;;) {
  96             size_t size;
  97             if (!CYRecvAll(socket_, &size, sizeof(size)))
  98                 return;
  99
 100             CYPool pool;
 101             char *data(new(pool) char[size + 1]);
 102             if (!CYRecvAll(socket_, data, size))
 103                 return;
 104             data[size] = '\0';
 105
 106             CYDriver driver("");
 107             cy::parser parser(driver);
 108
 109             driver.data_ = data;
 110             driver.size_ = size;
 111
 112             const char *json;
 113             if (parser.parse() != 0 || !driver.errors_.empty()) {
 114                 json = NULL;
 115                 size = _not(size_t);
 116             } else {
 117                 CYContext context(driver.pool_);
 118                 driver.program_->Replace(context);
 119                 std::ostringstream str;
 120                 CYOutput out(str);
 121                 out << *driver.program_;
 122                 std::string code(str.str());
 123                 CYExecute_ execute = {pool, code.c_str()};
 124                 [client performSelectorOnMainThread:@selector(execute:) withObject:[NSValue valueWithPointer:&execute] waitUntilDone:YES];
 125                 json = execute.data_;
 126                 size = json == NULL ? _not(size_t) : strlen(json);
 127             }
 128
 129             if (!CYSendAll(socket_, &size, sizeof(size)))
 130                 return;
 131             if (json != NULL)
 132                 if (!CYSendAll(socket_, json, size))
 133                     return;
 134         }
 135     }
 136 };
 137
 138 static void * APR_THREAD_FUNC OnClient(apr_thread_t *thread, void *data) {
 139     CYClient *client(reinterpret_cast<CYClient *>(data));
 140     client->Handle();
 141     delete client;
 142     return NULL;
 143 }
 144
 145 extern "C" void CYHandleClient(apr_pool_t *pool, int socket) {
 146     CYClient *client(new(pool) CYClient(socket));
 147     apr_threadattr_t *attr;
 148     _aprcall(apr_threadattr_create(&attr, client->pool_));
 149     _aprcall(apr_thread_create(&client->thread_, attr, &OnClient, client, client->pool_));
 150 }