Cycript.l.in

   1 /* Cycript - Inlining/Optimizing JavaScript Compiler
   2  * Copyright (C) 2009  Jay Freeman (saurik)
   3 */
   4
   5 /* Modified BSD License {{{ */
   6 /*
   7  *        Redistribution and use in source and binary
   8  * forms, with or without modification, are permitted
   9  * provided that the following conditions are met:
  10  *
  11  * 1. Redistributions of source code must retain the
  12  *    above copyright notice, this list of conditions
  13  *    and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the
  15  *    above copyright notice, this list of conditions
  16  *    and the following disclaimer in the documentation
  17  *    and/or other materials provided with the
  18  *    distribution.
  19  * 3. The name of the author may not be used to endorse
  20  *    or promote products derived from this software
  21  *    without specific prior written permission.
  22  *
  23  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS''
  24  * AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING,
  25  * BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
  26  * MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  27  * ARE DISCLAIMED. IN NO EVENT SHALL THE AUTHOR BE
  28  * LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  29  * EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  30  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
  31  * SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  32  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
  33  * LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR
  34  * TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
  35  * ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
  36  * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  37 */
  38 /* }}} */
  39
  40 /* XXX: supposedly I will be screwed on very very long multi-line comments and need to replace these with a manual lexer. http://websrv.cs.fsu.edu/~engelen/courses/COP5621/Pr2.pdf */
  41
  42 %{
  43 #define YYLTYPE cy::location
  44 #include "Cycript.tab.hh"
  45 typedef cy::parser::token tk;
  46
  47 #define YY_EXTRA_TYPE CYDriver *
  48
  49 #define T yylval->newline_ = yyextra->state_ == CYNewLine; BEGIN(Div);
  50 #define C T yyextra->state_ = CYClear;
  51 #define R T yyextra->state_ = CYRestricted;
  52
  53 #define E(prefix) L C { \
  54     char *value(reinterpret_cast<char *>(apr_palloc(yyextra->pool_, yyleng + sizeof(prefix)))); \
  55     memcpy(value, prefix, sizeof(prefix) - 1); \
  56     memcpy(value + sizeof(prefix) - 1, yytext, yyleng); \
  57     value[yyleng + sizeof(prefix) - 1] = '\0'; \
  58     yylval->literal_ = new(yyextra->pool_) CYRegEx(value); \
  59     return tk::RegularExpressionLiteral; \
  60 }
  61
  62 #define N \
  63     if (yyextra->state_ != CYNewLine) { \
  64         bool restricted(yyextra->state_ == CYRestricted); \
  65         if (restricted) { \
  66             yyextra->state_ = CYClear; \
  67             return tk::NewLine; \
  68         } else \
  69             yyextra->state_ = CYNewLine; \
  70     }
  71
  72 #define V(more) { \
  73     if (const char *nl = reinterpret_cast<const char *>(memchr(yytext, '\n', yyleng))) { \
  74         unsigned lines(0); \
  75         size_t left; \
  76         do { \
  77             ++lines; \
  78             left = yyleng - (nl - yytext) - 1; \
  79             nl = reinterpret_cast<const char *>(memchr(nl + 1, '\n', left)); \
  80         } while (nl != NULL); \
  81         yylloc->end.lines(lines); \
  82         yylloc->end.columns(left); \
  83         yylloc->step(); \
  84         more \
  85     } else L \
  86 }
  87
  88 #define L { \
  89     yylloc->step(); \
  90     yylloc->columns(yyleng); \
  91 }
  92
  93 int H(char c) {
  94     if (c >= '0' && c <= '9')
  95         return c - '0';
  96     if (c >= 'a' && c <= 'f')
  97         return c - 'a' + 10;
  98     if (c >= 'A' && c <= 'F')
  99         return c - 'A' + 10;
 100     return -1;
 101 }
 102
 103 #define YY_INPUT(data, value, size) { \
 104     if (yyextra->file_ != NULL) { \
 105         size_t copy(fread(data, 1, size, yyextra->file_)); \
 106         value = copy == 0 ? YY_NULL : copy; \
 107     } else if (yyextra->size_ == 0) \
 108         value = YY_NULL; \
 109     else { \
 110         size_t copy(size); \
 111         copy = (std::min(copy, yyextra->size_)); \
 112         memcpy(data, yyextra->data_, copy); \
 113         yyextra->data_ += copy; \
 114         yyextra->size_ -= copy; \
 115         value = copy; \
 116     } \
 117 }
 118
 119 %}
 120
 121 %option prefix="cy"
 122 %option bison-bridge
 123 %option bison-locations
 124 %option noyywrap
 125 %option yylineno
 126 %option nounput
 127 %option interactive
 128 %option reentrant
 129 %option stack
 130
 131 Exponent [eE][+-]?[0-9]+
 132 Escape   \\[\\'"bfnrtv]|\\0|\\x[0-9a-fA-F]{2}|\\u[0-9a-fA-F]{4}|\\\n
 133
 134 IdentifierStart [a-zA-Z$_]
 135 IdentifierPart  [a-zA-Z$_0-9]
 136
 137 NonTerminator [^\n]
 138 BackslashSequence \\{NonTerminator}
 139 RegularExpressionFirstChar [^\n*\\/]|{BackslashSequence}
 140 RegularExpressionChar [^\n\\/]|{BackslashSequence}
 141 RegularExpressionFlags {IdentifierPart}*
 142 RegularExpressionChars {RegularExpressionChar}*
 143 RegularExpressionBody {RegularExpressionFirstChar}{RegularExpressionChars}
 144
 145 @begin E4X
 146 XMLNameStart [a-zA-Z_:]
 147 XMLNamePart [a-zA-Z0-9.-_:]
 148 XMLName {XMLNameStart}{XMLNamePart}*
 149 @end
 150
 151 %s Div
 152 %s RegExp
 153
 154 @begin E4X
 155 %x XMLContent
 156 %x XMLTag
 157 @end
 158
 159 %%
 160
 161 <RegExp>\/{RegularExpressionBody}\/{RegularExpressionFlags} E("")
 162
 163 \/\/[^\n]* L
 164
 165         /* http://ostermiller.org/findcomment.html */
 166         /* XXX: unify these two rules using !? */
 167 \/\*!([^*]|[\r\n]|(\*+([^*/]|[\r\n])))*\*+\/ V() C yylval->comment_ = new(yyextra->pool_) CYComment(apr_pstrmemdup(yyextra->pool_, yytext, yyleng)); return tk::Comment;
 168 \/\*([^*]|[\r\n]|(\*+([^*/]|[\r\n])))*\*+\/ V(N)
 169
 170 @begin E4X
 171 <RegExp>"<>"      L return tk::LeftRight;
 172 <XMLContent>"</>" L return tk::LeftSlashRight;
 173
 174 <RegExp,XMLContent>\<!\[CDATA\[(\n|[^[]|\[[^[]|\[\[[^>])*]]> V() return tk::XMLCDATA;
 175 <RegExp,XMLContent>\<!--(\n|[^-]|-[^-])*--> V() return tk::XMLComment;
 176 <RegExp,XMLContent>\<?(\n|[^?]|\?[^>])*?> V() return tk::XMLPI;
 177
 178 <XMLTag>"="  L return tk::Equal;
 179 <XMLTag>">"  L return tk::Right;
 180 <XMLTag>"/>" L return tk::SlashRight;
 181 <XMLTag>"{"  L return tk::OpenBrace;
 182
 183 <XMLTag>\"(\n|[^"])*\"|'(\n|[^'])*' V() {
 184     return tk::XMLAttributeValue;
 185 }
 186
 187 <XMLTag>{XMLName} L return tk::XMLName;
 188 <XMLTag>[ \t\r\n] V() return tk::XMLWhitespace;
 189
 190 <XMLContent>"{"  L return tk::OpenBrace;
 191 <XMLContent>"<"  L return tk::Left;
 192 <XMLContent>"</" L return tk::LeftSlash;
 193 @end
 194
 195 @begin E4X
 196 "::"   L C return tk::ColonColon;
 197 ".."   L C return tk::PeriodPeriod;
 198 @end
 199
 200 @begin E4X ObjectiveC
 201 "@"    L C return tk::At;
 202 @end
 203
 204 "&"    L C return tk::Ampersand;
 205 "&&"   L C return tk::AmpersandAmpersand;
 206 "&="   L C return tk::AmpersandEqual;
 207 "^"    L C return tk::Carrot;
 208 "^="   L C return tk::CarrotEqual;
 209 "="    L C return tk::Equal;
 210 "=="   L C return tk::EqualEqual;
 211 "==="  L C return tk::EqualEqualEqual;
 212 "!"    L C return tk::Exclamation;
 213 "!="   L C return tk::ExclamationEqual;
 214 "!=="  L C return tk::ExclamationEqualEqual;
 215 "-"    L C return tk::Hyphen;
 216 "-="   L C return tk::HyphenEqual;
 217 "--"   L C return yylval->newline_ ? tk::HyphenHyphen_ : tk::HyphenHyphen;
 218 "->"   L C return tk::HyphenRight;
 219 "<"    L C return tk::Left;
 220 "<="   L C return tk::LeftEqual;
 221 "<<"   L C return tk::LeftLeft;
 222 "<<="  L C return tk::LeftLeftEqual;
 223 "%"    L C return tk::Percent;
 224 "%="   L C return tk::PercentEqual;
 225 "."    L C return tk::Period;
 226 "|"    L C return tk::Pipe;
 227 "|="   L C return tk::PipeEqual;
 228 "||"   L C return tk::PipePipe;
 229 "+"    L C return tk::Plus;
 230 "+="   L C return tk::PlusEqual;
 231 "++"   L C return yylval->newline_ ? tk::PlusPlus_ : tk::PlusPlus;
 232 ">"    L C return tk::Right;
 233 ">="   L C return tk::RightEqual;
 234 ">>"   L C return tk::RightRight;
 235 ">>="  L C return tk::RightRightEqual;
 236 ">>>"  L C return tk::RightRightRight;
 237 ">>>=" L C return tk::RightRightRightEqual;
 238 "*"    L C return tk::Star;
 239 "*="   L C return tk::StarEqual;
 240 "~"    L C return tk::Tilde;
 241
 242 <Div>"/"  L C return tk::Slash;
 243 <Div>"/=" L C return tk::SlashEqual;
 244
 245 ":"    L C return tk::Colon;
 246 ","    L C return tk::Comma;
 247 "?"    L C return tk::Question;
 248 ";"    L C return tk::SemiColon;
 249
 250 "("    L C return tk::OpenParen;
 251 ")"    L C return tk::CloseParen;
 252
 253 "{"    L C return tk::OpenBrace;
 254 "}"    L C return tk::CloseBrace;
 255
 256 "["    L C return tk::OpenBracket;
 257 "]"    L C return tk::CloseBracket;
 258
 259 @begin ObjectiveC
 260 "@class"       L C return tk::AtClass;
 261 "@end"         L C return tk::AtEnd;
 262 "@selector"    L C return tk::AtSelector;
 263 @end
 264
 265 "false"        L C yylval->false_ = new(yyextra->pool_) CYFalse(); return tk::False;
 266 "null"         L C yylval->null_ = new(yyextra->pool_) CYNull(); return tk::Null;
 267 "true"         L C yylval->true_ = new(yyextra->pool_) CYTrue(); return tk::True;
 268
 269 "break"        L R yylval->word_ = new(yyextra->pool_) CYWord("break"); return tk::Break;
 270 "case"         L C yylval->word_ = new(yyextra->pool_) CYWord("case"); return tk::Case;
 271 "catch"        L C yylval->word_ = new(yyextra->pool_) CYWord("catch"); return tk::Catch;
 272 "continue"     L R yylval->word_ = new(yyextra->pool_) CYWord("continue"); return tk::Continue;
 273 "default"      L C yylval->word_ = new(yyextra->pool_) CYWord("default"); return tk::Default;
 274 "delete"       L C yylval->word_ = new(yyextra->pool_) CYWord("delete"); return tk::Delete;
 275 "do"           L C yylval->word_ = new(yyextra->pool_) CYWord("do"); return tk::Do;
 276 "else"         L C yylval->word_ = new(yyextra->pool_) CYWord("else"); return tk::Else;
 277 "finally"      L C yylval->word_ = new(yyextra->pool_) CYWord("finally"); return tk::Finally;
 278 "for"          L C yylval->word_ = new(yyextra->pool_) CYWord("for"); return tk::For;
 279 "function"     L C yylval->word_ = new(yyextra->pool_) CYWord("function"); return tk::Function;
 280 "if"           L C yylval->word_ = new(yyextra->pool_) CYWord("if"); return tk::If;
 281 "in"           L C yylval->word_ = new(yyextra->pool_) CYWord("in"); return tk::In;
 282 "instanceof"   L C yylval->word_ = new(yyextra->pool_) CYWord("instanceof"); return tk::InstanceOf;
 283 "new"          L C yylval->word_ = new(yyextra->pool_) CYWord("new"); return tk::New;
 284 "return"       L R yylval->word_ = new(yyextra->pool_) CYWord("return"); return tk::Return;
 285 "switch"       L C yylval->word_ = new(yyextra->pool_) CYWord("switch"); return tk::Switch;
 286 "this"         L C yylval->this_ = new(yyextra->pool_) CYThis(); return tk::This;
 287 "throw"        L R yylval->word_ = new(yyextra->pool_) CYWord("throw"); return tk::Throw;
 288 "try"          L C yylval->word_ = new(yyextra->pool_) CYWord("try"); return tk::Try;
 289 "typeof"       L C yylval->word_ = new(yyextra->pool_) CYWord("typeof"); return tk::TypeOf;
 290 "var"          L C yylval->word_ = new(yyextra->pool_) CYWord("var"); return tk::Var;
 291 "void"         L C yylval->word_ = new(yyextra->pool_) CYWord("void"); return tk::Void;
 292 "while"        L C yylval->word_ = new(yyextra->pool_) CYWord("while"); return tk::While;
 293 "with"         L C yylval->word_ = new(yyextra->pool_) CYWord("with"); return tk::With;
 294
 295 "debugger"     L C yylval->word_ = new(yyextra->pool_) CYWord("debugger"); return tk::Debugger;
 296
 297 "const"        L C yylval->word_ = new(yyextra->pool_) CYWord("const"); return tk::Const;
 298
 299 "class"        L C yylval->word_ = new(yyextra->pool_) CYWord("class"); return tk::Class;
 300 "enum"         L C yylval->word_ = new(yyextra->pool_) CYWord("enum"); return tk::Enum;
 301 "export"       L C yylval->word_ = new(yyextra->pool_) CYWord("export"); return tk::Export;
 302 "extends"      L C yylval->word_ = new(yyextra->pool_) CYWord("extends"); return tk::Extends;
 303 "import"       L C yylval->word_ = new(yyextra->pool_) CYWord("import"); return tk::Import;
 304 "super"        L C yylval->word_ = new(yyextra->pool_) CYWord("super"); return tk::Super;
 305
 306 "implements"   L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("implements"); return tk::Implements;
 307 "interface"    L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("interface"); return tk::Interface;
 308 "package"      L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("package"); return tk::Package;
 309 "private"      L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("private"); return tk::Private;
 310 "protected"    L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("protected"); return tk::Protected;
 311 "public"       L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("public"); return tk::Public;
 312 "static"       L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("static"); return tk::Static;
 313
 314 "abstract"     L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("abstract"); return tk::Abstract;
 315 "boolean"      L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("boolean"); return tk::Boolean;
 316 "byte"         L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("byte"); return tk::Byte;
 317 "char"         L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("char"); return tk::Char;
 318 "double"       L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("double"); return tk::Double;
 319 "final"        L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("final"); return tk::Final;
 320 "float"        L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("float"); return tk::Float;
 321 "goto"         L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("goto"); return tk::Goto;
 322 "int"          L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("int"); return tk::Int;
 323 "long"         L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("long"); return tk::Long;
 324 "native"       L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("native"); return tk::Native;
 325 "short"        L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("short"); return tk::Short;
 326 "synchronized" L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("synchronized"); return tk::Synchronized;
 327 "throws"       L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("throws"); return tk::Throws;
 328 "transient"    L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("transient"); return tk::Transient;
 329 "volatile"     L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("volatile"); return tk::Volatile;
 330
 331 "let"          L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("let"); return tk::Let;
 332 "yield"        L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("yield"); return tk::Yield;
 333
 334 "each"         L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("each"); return tk::Each;
 335
 336 @begin E4X
 337 "namespace"    L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("namespace"); return tk::Namespace;
 338 "xml"          L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier("xml"); return tk::XML;
 339 @end
 340
 341 {IdentifierStart}{IdentifierPart}* L C yylval->identifier_ = new(yyextra->pool_) CYIdentifier(apr_pstrmemdup(yyextra->pool_, yytext, yyleng)); return tk::Identifier_;
 342
 343 (\.[0-9]+|(0|[1-9][0-9]*)(\.[0-9]*)?){Exponent}? L C yylval->number_ = new(yyextra->pool_) CYNumber(strtod(yytext, NULL)); return tk::NumericLiteral;
 344
 345 0[xX][0-9a-fA-F]+ L C yylval->number_ = new(yyextra->pool_) CYNumber(strtoull(yytext + 2, NULL, 16)); return tk::NumericLiteral;
 346 0[0-7]+ L C yylval->number_ = new(yyextra->pool_) CYNumber(strtoull(yytext + 1, NULL, 8)); return tk::NumericLiteral;
 347 0[bB][0-1]+ L C yylval->number_ = new(yyextra->pool_) CYNumber(strtoull(yytext + 2, NULL, 2)); return tk::NumericLiteral;
 348
 349 \"([^"\\\n]|{Escape})*\"|'([^'\\\n]|{Escape})*' L C {
 350     char *value(reinterpret_cast<char *>(apr_palloc(yyextra->pool_, yyleng)));
 351     char *local(value);
 352
 353     for (yy_size_t i(1), e(yyleng - 1); i != e; ++i) {
 354         char next(yytext[i]);
 355
 356         if (yytext[i] == '\\')
 357             switch (next = yytext[++i]) {
 358                 case '\n': continue;
 359                 case '\\': next = '\\'; break;
 360                 case '\'': next = '\''; break;
 361                 case '"': next = '"'; break;
 362                 case 'b': next = '\b'; break;
 363                 case 'f': next = '\f'; break;
 364                 case 'n': next = '\n'; break;
 365                 case 'r': next = '\r'; break;
 366                 case 't': next = '\t'; break;
 367                 case 'v': next = '\v'; break;
 368                 case '0': next = '\0'; break;
 369
 370                 case 'x':
 371                     next = H(yytext[i + 1]) << 4 | H(yytext[i + 2]);
 372                     i += 2;
 373                 break;
 374             }
 375
 376         *local++ = next;
 377     }
 378
 379     *local = '\0';
 380     yylval->string_ = new(yyextra->pool_) CYString(value, local - value);
 381     return tk::StringLiteral;
 382 }
 383
 384 \r?\n yylloc->end.lines(); yylloc->step(); N
 385
 386 [ \t] L
 387
 388 <<EOF>> if (yyextra->auto_) { yyextra->auto_ = false; return tk::AutoComplete_; } L yyterminate();
 389
 390 . L {
 391     CYDriver::Error error;
 392     error.location_ = *yylloc;
 393     error.message_ = "syntax error, unknown token";
 394     yyextra->errors_.push_back(error);
 395     yyterminate();
 396 }
 397
 398 %%
 399
 400 void CYDriver::ScannerInit() {
 401     cylex_init(&scanner_);
 402     cyset_extra(this, scanner_);
 403 }
 404
 405 void CYDriver::ScannerDestroy() {
 406     cylex_destroy(scanner_);
 407 }
 408
 409 CYDriver::Condition CYDriver::GetCondition() {
 410     switch (yy_top_state(scanner_)) {
 411         case RegExp:
 412             return RegExpCondition;
 413 @begin E4X
 414         case XMLContent:
 415             return XMLContentCondition;
 416         case XMLTag:
 417             return XMLTagCondition;
 418 @end
 419         default:
 420             _assert(false);
 421     }
 422 }
 423
 424 void CYDriver::SetCondition(Condition condition) {
 425     struct yyguts_t *yyg(reinterpret_cast<struct yyguts_t *>(scanner_));
 426
 427     switch (condition) {
 428         case RegExpCondition:
 429             BEGIN(RegExp);
 430             break;
 431 @begin E4X
 432         case XMLContentCondition:
 433             BEGIN(XMLContent);
 434             break;
 435         case XMLTagCondition:
 436             BEGIN(XMLTag);
 437             break;
 438 @end
 439         default:
 440             _assert(false);
 441     }
 442 }
 443
 444 void CYDriver::PushCondition(Condition condition) {
 445     switch (condition) {
 446         case RegExpCondition:
 447             yy_push_state(RegExp, scanner_);
 448             break;
 449 @begin E4X
 450         case XMLContentCondition:
 451             yy_push_state(XMLContent, scanner_);
 452             break;
 453         case XMLTagCondition:
 454             yy_push_state(XMLTag, scanner_);
 455             break;
 456 @end
 457         default:
 458             _assert(false);
 459     }
 460 }
 461
 462 void CYDriver::PopCondition() {
 463     yy_pop_state(scanner_);
 464 }