configure.ac

   1 dnl Cycript - Optimizing JavaScript Compiler/Runtime
   2 dnl Copyright (C) 2009-2015  Jay Freeman (saurik)
   3
   4 dnl GNU Affero General Public License, Version 3 {{{
   5 dnl
   6 dnl This program is free software: you can redistribute it and/or modify
   7 dnl it under the terms of the GNU Affero General Public License as published by
   8 dnl the Free Software Foundation, either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU Affero General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU Affero General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18 dnl }}}
  19
  20 AC_PREREQ([2.65])
  21 AC_INIT([Cycript], [0.9], [saurik@saurik.com], [cycript], [http://www.cycript.org/])
  22 AC_COPYRIGHT([Copyright (C) 2009-2015  Jay Freeman (saurik)])
  23
  24 AC_CONFIG_SRCDIR([Console.cpp])
  25 AC_CONFIG_AUX_DIR([.])
  26 AC_CONFIG_MACRO_DIR([m4])
  27 AC_CONFIG_HEADERS([config.h])
  28
  29 AM_INIT_AUTOMAKE([-Wall -Werror foreign])
  30 AM_MAINTAINER_MODE([disable])
  31
  32 AC_PROG_CC
  33 AC_PROG_CXX
  34 AC_PROG_OBJCXX
  35
  36 AM_PROG_AR
  37 AC_PROG_INSTALL
  38
  39 LT_INIT([disable-static])
  40
  41 AC_LANG([C++])
  42
  43 AX_CXX_COMPILE_STDCXX_11([ext], [mandatory])
  44 OBJCXXFLAGS="${OBJCXXFLAGS} ${CXXFLAGS##*' '}"
  45
  46 PKG_PROG_PKG_CONFIG([0.22])
  47
  48 AC_PATH_PROG([GIT], [git])
  49 AC_PATH_PROG([TIME], [time])
  50
  51 dnl CY_CHECK_PROGS_VERSION {{{
  52 AC_DEFUN([CY_CHECK_PROGS_VERSION], [
  53     AC_ARG_VAR(]$1[, ]$3[)
  54
  55     AC_MSG_CHECKING(for ]$2[ >= ]$5[)
  56     AC_PATH_PROGS_FEATURE_CHECK(]$1[, ]$2[,
  57         AS_VAR_SET(version, [`$ac_path_]$1[ ]$4[`])
  58         AS_VAR_IF(version, [], ,
  59             AS_VERSION_COMPARE($version, ]$5[, ,
  60                 ac_cv_path_]$1[=$ac_path_]$1[,
  61                 ac_cv_path_]$1[=$ac_path_]$1[))
  62     , AC_MSG_RESULT(no))
  63
  64     AS_IF([true], [
  65         AC_SUBST(]$1[, $ac_cv_path_]$1[)
  66         AC_MSG_RESULT($]$1[)
  67     ], AS_IF([true], [
  68         AC_MSG_ERROR(You need ]$2[ ]$5[ or greater)
  69     ], [
  70         AC_SUBST(]$1[, [:])
  71         AC_MSG_RESULT([no])
  72     ]))
  73 ]) dnl }}}
  74
  75 CY_CHECK_PROGS_VERSION([BISON], [bison], [GNU Project parser generator (yacc replacement)],
  76     [-V | $SED -e '1 s/^bison (GNU Bison) \(.*\)$/\1/p;d'], [3.0])
  77 CY_CHECK_PROGS_VERSION([FLEX], [flex], [the fast lexical analyser generator],
  78     [--version | $SED -e '1 s/^@<:@^0-9.@:>@* \(@<:@0-9.@:>@*\).*$/\1/p;d'], [2.5.33])
  79 CY_CHECK_PROGS_VERSION([GPERF], [gperf], [perfect hash function generator],
  80     [--version | $SED -e '1 s/^.* \(@<:@0-9.@:>@*\)$/\1/p;d'], [3.0.3])
  81 CY_CHECK_PROGS_VERSION([GNUTAR], [tar gtar gnutar], [a very sticky lump of files],
  82     [--version | $SED -e '1 s/^tar (GNU tar) \(.*\)$/\1/p;d'], [1.19])
  83
  84 dnl CY_TRY {{{
  85 AC_DEFUN([CY_SUCCESS], [cy_good=1])
  86 AC_DEFUN([CY_FAILURE], [cy_good=0])
  87
  88 AC_DEFUN([CY_TRY], [
  89     cy_save=$]$1[
  90         AC_LIB_APPENDTOVAR(]$1[, ]$2[)
  91         ]$3[
  92     ]$1[=$cy_save
  93     AS_IF([test "x$cy_good" = x1], ]$4[, ]$5[)
  94 ]) dnl }}}
  95
  96 AC_DEFUN([CY_TEST_FLAG_], [
  97     AC_LANG_PUSH(]$2[)
  98     AC_MSG_CHECKING([for ]]$4[[ ]]$1[)
  99     CY_TRY(]$3[, $1, [
 100         AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
 101             [CY_SUCCESS], [CY_FAILURE])
 102     ], [
 103         AC_MSG_RESULT([yes])
 104         AC_LIB_APPENDTOVAR(]$3[, ]$1[)
 105     ], [AC_MSG_RESULT([no])])
 106     AC_LANG_POP(]$2[)
 107 ])
 108
 109 AC_DEFUN([CY_TEST_FLAG], [
 110     CY_TEST_FLAG_(]$1[, [C], [CFLAGS], [cc])
 111     CY_TEST_FLAG_(]$1[, [C++], [CXXFLAGS], [c++])
 112     CY_TEST_FLAG_(]$1[, [Objective C++], [OBJCXXFLAGS], [c++ -ObjC])
 113 ])
 114
 115 AX_CFLAGS_WARN_ALL
 116 AX_CXXFLAGS_WARN_ALL
 117 AX_FLAGS_WARN_ALL
 118
 119 CY_TEST_FLAG([-Werror])
 120
 121 dnl XXX: this is used to support GNU Objective-C struct objc_method
 122 CY_TEST_FLAG([-Wno-deprecated-declarations])
 123
 124 CY_TEST_FLAG([-Wno-dangling-else])
 125 CY_TEST_FLAG([-Wno-empty-body])
 126 CY_TEST_FLAG([-Wno-overloaded-virtual])
 127 CY_TEST_FLAG([-Wno-parentheses])
 128 CY_TEST_FLAG([-Wno-tautological-undefined-compare])
 129 CY_TEST_FLAG([-Wno-unneeded-internal-declaration])
 130
 131 AX_PTHREAD
 132
 133 AC_DEFUN([CY_LT_LIB], [
 134     cy_save=$LIBS
 135     LIBS=
 136     ]$2[
 137     ]$1[=$LIBS
 138     LIBS=$cy_save
 139     AC_SUBST(]$1[)
 140 ])
 141
 142 dnl --enable-javascript {{{
 143 AC_DEFUN([CY_CHECK_JAVASCRIPTCORE], [
 144     CY_LT_LIB([LTJAVASCRIPTCORE], [AC_SEARCH_LIBS([JSEvaluateScript], [JavaScriptCore], [
 145         AC_SUBST([CY_EXECUTE], [1])
 146     ], [AC_CHECK_FRAMEWORK([JavaScriptCore], [
 147         #include <JavaScriptCore/JSBase.h>
 148     ], [
 149         JSEvaluateScript(0, 0, 0, 0, 0, 0);
 150     ], [
 151         AC_SUBST([CY_EXECUTE], [1])
 152     ], [
 153         for cy_webkit_pkg in "webkit-1.0" "WebKitGtk"; do
 154             PKG_CHECK_MODULES([WEBKIT], [$cy_webkit_pkg], [
 155                 AC_SUBST([CY_EXECUTE], [1])
 156                 AC_LIB_APPENDTOVAR([CPPFLAGS], [`$PKG_CONFIG --cflags $cy_webkit_pkg`])
 157                 AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs $cy_webkit_pkg`])
 158             ], [:]); if test "x$CY_EXECUTE" = x1; then break; fi
 159         done
 160     ])])])
 161 ])
 162
 163 AC_DEFUN([CY_CHECK_JAVASCRIPT], [
 164     CY_CHECK_JAVASCRIPTCORE])
 165
 166 AC_ARG_ENABLE([javascript], [AS_HELP_STRING(
 167     [--enable-javascript@<:@=ENGINE@:>@],
 168     [use a JavaScript runtime (currently the only available option for ENGINE is JavaScriptCore) @<:@default=yes@:>@]
 169 )], [
 170     AS_CASE([$enableval],
 171         [yes], [
 172             CY_CHECK_JAVASCRIPT],
 173         [no], [
 174             AC_SUBST([CY_EXECUTE], [0])],
 175         [JavaScriptCore], [
 176             CY_CHECK_JAVASCRIPTCORE],
 177         [AC_MSG_ERROR([Unknown JavaScript engine: $enableval])])
 178 ], [CY_CHECK_JAVASCRIPT])
 179 dnl }}}
 180
 181 AC_ARG_ENABLE([console], AS_HELP_STRING([--disable-console], [disable console]))
 182 AM_CONDITIONAL([CY_CONSOLE], [test "x$enable_console" != "xno"])
 183
 184 AC_ARG_ENABLE([attach], AS_HELP_STRING([--disable-attach], [disable attach]))
 185 AM_CONDITIONAL([CY_ATTACH], [test "x$enable_attach" != "xno" -a "x$CY_EXECUTE" = x1])
 186
 187 AC_DEFUN([CY_CHECK_PKG_CONFIG_LIBFFI], [
 188     PKG_CHECK_MODULES([LIBFFI], [libffi], [
 189         AC_LIB_APPENDTOVAR([CPPFLAGS], [`$PKG_CONFIG --cflags libffi`])
 190         AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs libffi`])
 191     ], [AC_MSG_ERROR([missing "libffi"])])])
 192
 193 AM_CONDITIONAL([CY_EXECUTE], [test "x$CY_EXECUTE" = x1])
 194
 195 AS_CASE([$CY_EXECUTE], [1], [
 196     AC_CHECK_HEADERS([ffi.h ffi/ffi.h], [break])
 197
 198     CY_LT_LIB([LTLIBFFI], AS_IF([test "x$ac_cv_header_ffi_h" = xno && test "x$ac_cv_header_ffi_ffi_h" = xno], [
 199         CY_CHECK_PKG_CONFIG_LIBFFI
 200     ], [
 201         AC_SEARCH_LIBS([ffi_call], [ffi])
 202         AS_CASE([$ac_cv_search_ffi_call], [no], [CY_CHECK_PKG_CONFIG_LIBFFI])
 203     ]))
 204
 205     AC_CHECK_FRAMEWORK([JavaVM], [
 206         #include <JavaVM/jni.h>
 207     ], [JNI_GetCreatedJavaVMs(NULL, 0, NULL);], [
 208         AC_SUBST([CY_JAVA], [1])
 209     ], [AC_CHECK_HEADER([jni.h], [
 210         AC_SUBST([CY_JAVA], [1])
 211         CY_LT_LIB([LTJAVA], [AC_SEARCH_LIBS([JNI_GetCreatedJavaVMs], [dvm], [
 212         ])])
 213     ], [
 214         AC_SUBST([CY_JAVA], [0])
 215     ])])
 216
 217     AC_LANG_PUSH([Objective C++])
 218
 219     AC_MSG_CHECKING([if we really have Objective C++])
 220     AC_COMPILE_IFELSE([AC_LANG_SOURCE([])], [
 221         CY_OBJECTIVEC=1
 222         AC_MSG_RESULT([yes])
 223     ], [AC_MSG_RESULT([no])])
 224
 225     AS_IF([test "x$CY_OBJECTIVEC" = x1], [
 226         CY_LT_LIB([LTOBJECTIVEC], [AC_CHECK_FRAMEWORK([CoreFoundation], [
 227             #include <CoreFoundation/CFBase.h>
 228         ], [CFAllocatorGetDefault();], [
 229             AC_SUBST([CY_OBJECTIVEC])
 230
 231             AC_CHECK_FRAMEWORK([Foundation], [
 232                 #include <Foundation/NSObject.h>
 233             ], [[[[NSObject alloc] init];]])
 234         ], [
 235             AC_ARG_VAR([GNUSTEP_CONFIG], [prints information about the current gnustep installation])
 236             AC_CHECK_PROGS([GNUSTEP_CONFIG], [gnustep-config])
 237
 238             AS_IF([test "x$GNUSTEP_CONFIG" != x], [
 239                 AC_SUBST([CY_OBJECTIVEC])
 240                 AC_LIB_APPENDTOVAR([OBJCXXFLAGS], [`$GNUSTEP_CONFIG --objc-flags`])
 241                 AC_LIB_APPENDTOVAR([LIBS], [`$GNUSTEP_CONFIG --base-libs`])
 242             ], [AC_SUBST([CY_OBJECTIVEC], [0])])
 243         ])])
 244     ])
 245
 246     AC_LANG_POP([Objective C++])
 247 ])
 248
 249 AM_CONDITIONAL([CY_JAVA], [test "x$CY_JAVA" = x1])
 250 AM_CONDITIONAL([CY_OBJECTIVEC], [test "x$CY_OBJECTIVEC" = x1])
 251
 252 CY_LT_LIB([LTLIBREADLINE], [AX_LIB_READLINE])
 253 AS_CASE([$ax_cv_lib_readline], [no], [AC_MSG_ERROR([missing "libreadline"])])
 254
 255 CY_LT_LIB([LTLIBTERMCAP], [AC_SEARCH_LIBS([cur_term], [termcap ncurses])])
 256
 257 AC_SUBST([LTLIBGCC])
 258
 259 AC_SUBST([LTFLAGS])
 260 AC_SUBST([SO], [$acl_shlibext])
 261
 262 AC_CONFIG_FILES([Makefile])
 263 AC_OUTPUT