Cycript.yy.in

   1 /* Cycript - Optimizing JavaScript Compiler/Runtime
   2  * Copyright (C) 2009-2013  Jay Freeman (saurik)
   3 */
   4
   5 /* GNU General Public License, Version 3 {{{ */
   6 /*
   7  * Cycript is free software: you can redistribute it and/or modify
   8  * it under the terms of the GNU General Public License as published
   9  * by the Free Software Foundation, either version 3 of the License,
  10  * or (at your option) any later version.
  11  *
  12  * Cycript is distributed in the hope that it will be useful, but
  13  * WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with Cycript.  If not, see <http://www.gnu.org/licenses/>.
  19 **/
  20 /* }}} */
  21
  22 @if Bison23 %{
  23
  24 @if Bison24 %code top {
  25 #define cyscanner driver.scanner_
  26 #define YYSTACKEXPANDABLE 1
  27 @if Bison23 #define yyerrok (yyerrstatus_ = 0)
  28 @if Bison24 }
  29
  30 @if Bison24 %code requires {
  31 #include "Driver.hpp"
  32 #include "Parser.hpp"
  33 #define CYNew new($pool)
  34
  35 @begin ObjectiveC
  36 #include "ObjectiveC/Syntax.hpp"
  37 @end
  38
  39 @begin E4X
  40 #include "E4X/Syntax.hpp"
  41 @end
  42
  43 #include "Highlight.hpp"
  44
  45 typedef struct {
  46     bool newline_;
  47     hi::Value highlight_;
  48
  49     union {
  50         bool bool_;
  51
  52         CYDriver::Condition condition_;
  53
  54         CYArgument *argument_;
  55         CYAssignment *assignment_;
  56         CYBoolean *boolean_;
  57         CYClause *clause_;
  58         cy::Syntax::Catch *catch_;
  59         CYComment *comment_;
  60         CYComprehension *comprehension_;
  61         CYCompound *compound_;
  62         CYDeclaration *declaration_;
  63         CYDeclarations *declarations_;
  64         CYElement *element_;
  65         CYExpression *expression_;
  66         CYFalse *false_;
  67         CYFinally *finally_;
  68         CYForInitialiser *for_;
  69         CYForInInitialiser *forin_;
  70         CYFunctionParameter *functionParameter_;
  71         CYIdentifier *identifier_;
  72         CYInfix *infix_;
  73         CYLiteral *literal_;
  74         CYMember *member_;
  75         CYNull *null_;
  76         CYNumber *number_;
  77         CYProgram *program_;
  78         CYProperty *property_;
  79         CYPropertyName *propertyName_;
  80         CYRubyProc *rubyProc_;
  81         CYStatement *statement_;
  82         CYString *string_;
  83         CYThis *this_;
  84         CYTrue *true_;
  85         CYWord *word_;
  86
  87 @begin ObjectiveC
  88         CYClassName *className_;
  89         CYField *field_;
  90         CYMessage *message_;
  91         CYMessageParameter *messageParameter_;
  92         CYProtocol *protocol_;
  93         CYSelectorPart *selector_;
  94         CYTypeModifier *type_;
  95         CYTypedIdentifier *typedIdentifier_;
  96         CYTypedParameter *typedParameter_;
  97 @end
  98
  99 @begin E4X
 100         CYAttribute *attribute_;
 101         CYPropertyIdentifier *propertyIdentifier_;
 102         CYSelector *selector_;
 103 @end
 104     };
 105 } YYSTYPE;
 106
 107 #define YYSTYPE YYSTYPE
 108 @if Bison24 }
 109
 110 @if Bison24 %code provides {
 111 int cylex(YYSTYPE *, cy::location *, void *);
 112 @if Bison24 }
 113
 114 @if Bison23 %}
 115
 116 %name-prefix="cy"
 117
 118 @if Bison23 %skeleton "lalr1.cc"
 119 @if Bison24 %language "C++"
 120
 121 %initial-action {
 122     @$.begin.filename = @$.end.filename = &driver.filename_;
 123 };
 124
 125 %locations
 126 %defines
 127
 128 //%glr-parser
 129 //%expect 1
 130
 131 %error-verbose
 132
 133 %parse-param { CYDriver &driver }
 134 %lex-param { void *cyscanner }
 135
 136 /* Token Declarations {{{ */
 137 @begin E4X
 138 %token XMLCDATA
 139 %token XMLComment
 140 %token XMLPI
 141
 142 %token XMLAttributeValue
 143 %token XMLName
 144 %token XMLTagCharacters
 145 %token XMLText
 146 %token XMLWhitespace
 147 @end
 148
 149 @begin E4X
 150 %token LeftRight "<>"
 151 %token LeftSlashRight "</>"
 152
 153 %token SlashRight "/>"
 154 %token LeftSlash "</"
 155
 156 %token ColonColon "::"
 157 %token PeriodPeriod ".."
 158 @end
 159
 160 @begin E4X ObjectiveC
 161 %token At "@"
 162 @end
 163
 164 %token Ampersand "&"
 165 %token AmpersandAmpersand "&&"
 166 %token AmpersandEqual "&="
 167 %token Carrot "^"
 168 %token CarrotEqual "^="
 169 %token Equal "="
 170 %token EqualEqual "=="
 171 %token EqualEqualEqual "==="
 172 %token EqualRight "=>"
 173 %token Exclamation "!"
 174 %token ExclamationEqual "!="
 175 %token ExclamationEqualEqual "!=="
 176 %token Hyphen "-"
 177 %token HyphenEqual "-="
 178 %token HyphenHyphen "--"
 179 %token HyphenHyphen_ "\n--"
 180 %token HyphenRight "->"
 181 %token Left "<"
 182 %token LeftEqual "<="
 183 %token LeftLeft "<<"
 184 %token LeftLeftEqual "<<="
 185 %token Percent "%"
 186 %token PercentEqual "%="
 187 %token Period "."
 188 %token PeriodPeriodPeriod "..."
 189 %token Pipe "|"
 190 %token PipeEqual "|="
 191 %token PipePipe "||"
 192 %token Plus "+"
 193 %token PlusEqual "+="
 194 %token PlusPlus "++"
 195 %token PlusPlus_ "\n++"
 196 %token Right ">"
 197 %token RightEqual ">="
 198 %token RightRight ">>"
 199 %token RightRightEqual ">>="
 200 %token RightRightRight ">>>"
 201 %token RightRightRightEqual ">>>="
 202 %token Slash "/"
 203 %token SlashEqual "/="
 204 %token Star "*"
 205 %token StarEqual "*="
 206 %token Tilde "~"
 207
 208 %token Colon ":"
 209 %token Comma ","
 210 %token Question "?"
 211 %token SemiColon ";"
 212 %token NewLine "\n"
 213
 214 %token <comment_> Comment
 215
 216 %token OpenParen "("
 217 %token CloseParen ")"
 218
 219 %token OpenBrace "{"
 220 %token OpenBrace_ "\n{"
 221 %token OpenBrace__ ";{"
 222 %token CloseBrace "}"
 223
 224 %token OpenBracket "["
 225 %token CloseBracket "]"
 226
 227 %token AtError "@error"
 228
 229 @begin Java
 230 %token AtClass "@class"
 231 @end
 232
 233 @begin C
 234 %token <identifier_> Typedef "typedef"
 235 @end
 236
 237 @begin ObjectiveC
 238 %token AtImplementation "@implementation"
 239 %token AtImplementation_ ";@implementation"
 240 %token AtImport "@import"
 241 %token AtEncode "@encode"
 242 %token AtEnd "@end"
 243 %token AtSelector "@selector"
 244 %token <identifier_> Yes "YES"
 245 %token <identifier_> No "NO"
 246 @end
 247
 248 %token <false_> False "false"
 249 %token <null_> Null "null"
 250 %token <true_> True "true"
 251
 252 // ES3/ES5/WIE/JSC Reserved
 253 %token <word_> Auto "auto"
 254 %token <word_> Break "break"
 255 %token <word_> Case "case"
 256 %token <word_> Catch "catch"
 257 %token <word_> Continue "continue"
 258 %token <word_> Default "default"
 259 %token <word_> Delete "delete"
 260 %token <word_> Do "do"
 261 %token <word_> Else "else"
 262 %token <word_> Finally "finally"
 263 %token <word_> For "for"
 264 %token <word_> Function "function"
 265 %token <word_> Function_ ";function"
 266 %token <word_> If "if"
 267 %token <word_> In "in"
 268 %token <word_> In_ "!in"
 269 %token <word_> InstanceOf "instanceof"
 270 %token <word_> New "new"
 271 %token <word_> Return "return"
 272 %token <word_> Switch "switch"
 273 %token <this_> This "this"
 274 %token <word_> Throw "throw"
 275 %token <word_> Try "try"
 276 %token <word_> TypeOf "typeof"
 277 %token <word_> Var "var"
 278 %token <word_> Void "void"
 279 %token <word_> While "while"
 280 %token <word_> With "with"
 281
 282 // ES3/IE6 Future, ES5/JSC Reserved
 283 %token <word_> Debugger "debugger"
 284
 285 // ES3/ES5/IE6 Future, JSC Reserved
 286 %token <word_> Const "const"
 287
 288 // ES3/ES5/IE6/JSC Future
 289 %token <word_> Class "class"
 290 %token <word_> Enum "enum"
 291 %token <word_> Export "export"
 292 %token <word_> Extends "extends"
 293 %token <word_> Import "import"
 294 %token <word_> Super "super"
 295
 296 // ES3 Future, ES5 Strict Future
 297 %token <identifier_> Implements "implements"
 298 %token <identifier_> Interface "interface"
 299 %token <identifier_> Package "package"
 300 %token <identifier_> Private "private"
 301 %token <identifier_> Protected "protected"
 302 %token <identifier_> Public "public"
 303 %token <identifier_> Static "static"
 304
 305 // ES3 Future
 306 %token <identifier_> Abstract "abstract"
 307 %token <identifier_> Boolean "boolean"
 308 %token <identifier_> Byte "byte"
 309 %token <identifier_> Char "char"
 310 %token <identifier_> Double "double"
 311 %token <identifier_> Final "final"
 312 %token <identifier_> Float "float"
 313 %token <identifier_> Goto "goto"
 314 %token <identifier_> Int "int"
 315 %token <identifier_> Long "long"
 316 %token <identifier_> Native "native"
 317 %token <identifier_> Short "short"
 318 %token <identifier_> Synchronized "synchronized"
 319 %token <identifier_> Throws "throws"
 320 %token <identifier_> Transient "transient"
 321 %token <identifier_> Volatile "volatile"
 322
 323 // ES5 Strict
 324 %token <identifier_> Let "let"
 325 %token <identifier_> Yield "yield"
 326
 327 // Woah?!
 328 %token <identifier_> Each "each"
 329 %token <identifier_> Of "of"
 330
 331 @begin E4X
 332 // E4X Conditional
 333 %token <identifier_> Namespace "namespace"
 334 %token <identifier_> XML "xml"
 335 @end
 336
 337 %token AutoComplete
 338
 339 %token <identifier_> Identifier_
 340 %token <number_> NumericLiteral
 341 %token <string_> StringLiteral
 342 %token <literal_> RegularExpressionLiteral
 343
 344 %type <expression_> AdditiveExpression
 345 %type <argument_> ArgumentList_
 346 %type <argument_> ArgumentList
 347 %type <argument_> ArgumentListOpt
 348 %type <argument_> Arguments
 349 %type <literal_> ArrayLiteral
 350 %type <expression_> ArrowFunction
 351 %type <functionParameter_> ArrowParameters
 352 %type <expression_> AssignmentExpression
 353 %type <identifier_> Binding
 354 %type <identifier_> BindingIdentifier
 355 %type <expression_> BitwiseANDExpression
 356 %type <statement_> Block_
 357 %type <statement_> Block
 358 %type <boolean_> BooleanLiteral
 359 %type <declaration_> BindingElement
 360 %type <expression_> BitwiseORExpression
 361 %type <expression_> BitwiseXORExpression
 362 %type <statement_> BreakStatement
 363 %type <statement_> BreakableStatement
 364 %type <expression_> CallExpression_
 365 %type <expression_> CallExpression
 366 %type <clause_> CaseBlock
 367 %type <clause_> CaseClause
 368 %type <clause_> CaseClausesOpt
 369 %type <catch_> CatchOpt
 370 %type <comprehension_> ComprehensionForList
 371 %type <comprehension_> ComprehensionForListOpt
 372 %type <comprehension_> ComprehensionList
 373 %type <comprehension_> ComprehensionListOpt
 374 %type <expression_> ConditionalExpression
 375 %type <statement_> ContinueStatement
 376 %type <statement_> ConciseBody
 377 %type <statement_> DebuggerStatement
 378 %type <statement_> Declaration__
 379 %type <statement_> Declaration_
 380 %type <statement_> Declaration
 381 %type <clause_> DefaultClause
 382 %type <expression_> Element
 383 %type <expression_> ElementOpt
 384 %type <element_> ElementList
 385 %type <element_> ElementListOpt
 386 %type <statement_> ElseStatementOpt
 387 %type <statement_> EmptyStatement
 388 %type <expression_> EqualityExpression
 389 %type <compound_> Expression_
 390 %type <compound_> Expression
 391 %type <expression_> ExpressionOpt
 392 %type <statement_> ExpressionStatement
 393 %type <finally_> FinallyOpt
 394 %type <comprehension_> ForComprehension
 395 %type <for_> ForStatementInitialiser
 396 %type <forin_> ForInStatementInitialiser
 397 %type <declaration_> FormalParameter
 398 %type <functionParameter_> FormalParameterList_
 399 %type <functionParameter_> FormalParameterList
 400 %type <functionParameter_> FormalParameterListOpt
 401 %type <statement_> FunctionBody
 402 %type <statement_> FunctionDeclaration
 403 %type <expression_> FunctionExpression
 404 %type <identifier_> Identifier
 405 %type <identifier_> IdentifierOpt
 406 %type <word_> IdentifierName
 407 %type <comprehension_> IfComprehension
 408 %type <statement_> IfStatement
 409 %type <expression_> Initialiser
 410 %type <expression_> InitialiserOpt
 411 %type <statement_> IterationStatement
 412 %type <statement_> LabelledStatement
 413 %type <expression_> LeftHandSideExpression
 414 %type <statement_> LetStatement
 415 %type <statement_> LexicalDeclaration
 416 %type <literal_> Literal
 417 %type <literal_> ValueLiteral
 418 %type <expression_> LogicalANDExpression
 419 %type <expression_> LogicalORExpression
 420 %type <member_> MemberAccess
 421 %type <expression_> MemberExpression_
 422 %type <expression_> MemberExpression
 423 %type <expression_> MultiplicativeExpression
 424 %type <expression_> NewExpression
 425 %type <null_> NullLiteral
 426 %type <literal_> ObjectLiteral
 427 %type <compound_> Parenthetical
 428 %type <compound_> ParentheticalOpt
 429 %type <expression_> PostfixExpression
 430 %type <expression_> PrimaryExpression
 431 %type <statement_> Program
 432 %type <statement_> ProgramBody
 433 %type <statement_> ProgramBodyOpt
 434 %type <propertyName_> PropertyName_
 435 %type <propertyName_> PropertyName
 436 %type <property_> PropertyDefinition
 437 %type <property_> PropertyDefinitionList_
 438 %type <property_> PropertyDefinitionList
 439 %type <property_> PropertyDefinitionListOpt
 440 %type <expression_> RelationalExpression
 441 %type <statement_> ReturnStatement
 442 %type <rubyProc_> RubyProcExpression
 443 %type <functionParameter_> RubyProcParameterList_
 444 %type <functionParameter_> RubyProcParameterList
 445 %type <functionParameter_> RubyProcParameters
 446 %type <functionParameter_> RubyProcParametersOpt
 447 %type <expression_> ShiftExpression
 448 %type <declaration_> SingleNameBinding
 449 %type <statement_> Statement__
 450 %type <statement_> Statement_
 451 %type <statement_> Statement
 452 %type <statement_> StatementList
 453 %type <statement_> StatementListOpt
 454 %type <statement_> StatementListItem
 455 %type <statement_> SwitchStatement
 456 %type <statement_> ThrowStatement
 457 %type <statement_> TryStatement
 458 %type <expression_> UnaryExpression_
 459 %type <expression_> UnaryExpression
 460 %type <declaration_> VariableDeclaration
 461 %type <declarations_> VariableDeclarationList_
 462 %type <declarations_> VariableDeclarationList
 463 %type <statement_> VariableStatement
 464 %type <statement_> WithStatement
 465 %type <word_> Word
 466 %type <word_> WordOpt
 467 %type <expression_> Variable
 468
 469 @begin ObjectiveC
 470 %type <typedIdentifier_> ArrayedType
 471 %type <expression_> BoxableExpression
 472 %type <statement_> CategoryStatement
 473 %type <expression_> ClassExpression
 474 %type <field_> ClassFieldListOpt
 475 %type <field_> ClassFields
 476 %type <statement_> ClassStatement
 477 %type <expression_> ClassSuperOpt
 478 %type <message_> ClassMessageDeclaration
 479 %type <message_> ClassMessageDeclarationListOpt
 480 %type <className_> ClassName
 481 %type <className_> ClassNameOpt
 482 %type <protocol_> ClassProtocolListOpt
 483 %type <protocol_> ClassProtocols
 484 %type <protocol_> ClassProtocolsOpt
 485 %type <type_> ConcreteType
 486 %type <expression_> EncodedType
 487 %type <expression_> MessageExpression
 488 %type <messageParameter_> MessageParameter
 489 %type <messageParameter_> MessageParameters
 490 %type <messageParameter_> MessageParameterList
 491 %type <messageParameter_> MessageParameterListOpt
 492 %type <bool_> MessageScope
 493 %type <type_> ModifiedType_
 494 %type <type_> ModifiedType
 495 %type <typedIdentifier_> PrefixedType
 496 %type <expression_> PrimitiveType
 497 %type <argument_> SelectorCall_
 498 %type <argument_> SelectorCall
 499 %type <selector_> SelectorExpression_
 500 %type <selector_> SelectorExpression
 501 %type <selector_> SelectorExpressionOpt
 502 %type <argument_> SelectorList
 503 %type <word_> SelectorWordOpt
 504 %type <typedIdentifier_> SuffixedType
 505 %type <expression_> TypeOpt
 506 %type <typedIdentifier_> TypeParenthetical
 507 %type <type_> TypeQualifierLeft
 508 %type <type_> TypeQualifierRight
 509 %type <typedIdentifier_> TypeSignifier
 510 %type <typedIdentifier_> TypedIdentifier
 511 %type <typedParameter_> TypedParameterList_
 512 %type <typedParameter_> TypedParameterList
 513 %type <typedParameter_> TypedParameterListOpt
 514 %type <argument_> VariadicCall
 515 @end
 516
 517 @begin E4X
 518 %type <propertyIdentifier_> PropertyIdentifier_
 519 %type <selector_> PropertySelector_
 520 %type <selector_> PropertySelector
 521 %type <identifier_> QualifiedIdentifier_
 522 %type <identifier_> QualifiedIdentifier
 523 %type <identifier_> WildcardIdentifier
 524 %type <identifier_> XMLComment
 525 %type <identifier_> XMLCDATA
 526 %type <identifier_> XMLElement
 527 %type <identifier_> XMLElementContent
 528 %type <identifier_> XMLMarkup
 529 %type <identifier_> XMLPI
 530
 531 %type <attribute_> AttributeIdentifier
 532 /* XXX: %type <statement_> DefaultXMLNamespaceStatement */
 533 %type <expression_> PropertyIdentifier
 534 %type <expression_> XMLListInitialiser
 535 %type <expression_> XMLInitialiser
 536 @end
 537 /* }}} */
 538 /* Token Priorities {{{ */
 539 %nonassoc ""
 540 %left "++" "--"
 541
 542 %nonassoc "if"
 543 %nonassoc "else"
 544 /* }}} */
 545
 546 %start Program
 547
 548 %%
 549
 550 /* Lexer State {{{ */
 551 LexPushInOn
 552     : { driver.in_.push(true); }
 553     ;
 554
 555 LexPushInOff
 556     : { driver.in_.push(false); }
 557     ;
 558
 559 LexPopIn
 560     : { driver.in_.pop(); }
 561     ;
 562
 563 LexSetRegExp
 564     : { driver.SetCondition(CYDriver::RegExpCondition); }
 565     ;
 566
 567 LexNoBrace
 568     : { if (yychar == yyempty_) driver.no_.OpenBrace = true; else if (yychar == token::OpenBrace || yychar == token::OpenBrace_) yychar = token::OpenBrace__; }
 569     ;
 570
 571 LexNoFunction
 572     : { if (yychar == yyempty_) driver.no_.Function = true; else if (yychar == token::Function) yychar = token::Function_; }
 573     ;
 574
 575 LexNoAtImplementation :
 576 @begin ObjectiveC
 577     { if (yychar == yyempty_) driver.no_.AtImplementation = true; else if (yychar == token::AtImplementation) yychar = token::AtImplementation_; }
 578 @end
 579     ;
 580
 581 LexSetStatement
 582     : LexNoBrace LexNoFunction LexNoAtImplementation
 583     ;
 584 /* }}} */
 585 /* Virtual Tokens {{{ */
 586 BRACE
 587     : "{"
 588     | "\n{"
 589     ;
 590
 591 Var_
 592     : "var"
 593     ;
 594 /* }}} */
 595
 596 /* 7.6 Identifier Names and Identifiers {{{ */
 597 IdentifierName
 598     : Word { $$ = $1; }
 599     ;
 600
 601 NewLineOpt
 602     : "\n"
 603     |
 604     ;
 605
 606 Word
 607     : Identifier { $$ = $1; }
 608     | "auto" { $$ = $1; }
 609     | "break" NewLineOpt { $$ = $1; }
 610     | "case" { $$ = $1; }
 611     | "catch" { $$ = $1; }
 612     | "class" { $$ = $1; }
 613     | "const" { $$ = $1; }
 614     | "continue" NewLineOpt { $$ = $1; }
 615     | "debugger" { $$ = $1; }
 616     | "default" { $$ = $1; }
 617     | "delete" { $$ = $1; }
 618     | "do" { $$ = $1; }
 619     | "else" { $$ = $1; }
 620     | "enum" { $$ = $1; }
 621     | "export" { $$ = $1; }
 622     | "extends" { $$ = $1; }
 623     | "false" { $$ = $1; }
 624     | "finally" { $$ = $1; }
 625     /* XXX: | "for" { $$ = $1; } */
 626     | "function" { $$ = $1; }
 627     | "if" { $$ = $1; }
 628     | "import" { $$ = $1; }
 629     /* XXX: | "in" { $$ = $1; } */
 630     | "!in" { $$ = $1; }
 631     /* XXX: | "instanceof" { $$ = $1; } */
 632
 633     // XXX: as it currently is not an Identifier
 634     | "let" { $$ = $1; }
 635
 636     | "new" { $$ = $1; }
 637     | "null" { $$ = $1; }
 638     | "return" NewLineOpt { $$ = $1; }
 639     | "super" { $$ = $1; }
 640     | "switch" { $$ = $1; }
 641     | "this" { $$ = $1; }
 642     | "throw" NewLineOpt { $$ = $1; }
 643     | "true" { $$ = $1; }
 644     | "try" { $$ = $1; }
 645     | "typeof" { $$ = $1; }
 646     | "var" { $$ = $1; }
 647     | "void" { $$ = $1; }
 648     | "while" { $$ = $1; }
 649     | "with" { $$ = $1; }
 650     ;
 651
 652 WordOpt
 653     : Word { $$ = $1; }
 654     | { $$ = NULL; }
 655     ;
 656
 657 Identifier
 658     : Identifier_ { $$ = $1; }
 659
 660 @begin C
 661     | "typedef" { $$ = $1; }
 662     | "YES" { $$ = $1; }
 663     | "NO" { $$ = $1; }
 664 @end
 665
 666     | "implements" { $$ = $1; }
 667     | "interface" { $$ = $1; }
 668     | "package" { $$ = $1; }
 669     | "private" { $$ = $1; }
 670     | "protected" { $$ = $1; }
 671     | "public" { $$ = $1; }
 672     | "static" { $$ = $1; }
 673
 674     | "abstract" { $$ = $1; }
 675     | "boolean" { $$ = $1; }
 676     | "byte" { $$ = $1; }
 677     | "char" { $$ = $1; }
 678     | "double" { $$ = $1; }
 679     | "final" { $$ = $1; }
 680     | "float" { $$ = $1; }
 681     | "goto" { $$ = $1; }
 682     | "int" { $$ = $1; }
 683     | "long" { $$ = $1; }
 684     | "native" { $$ = $1; }
 685     | "short" { $$ = $1; }
 686     | "synchronized" { $$ = $1; }
 687     | "throws" { $$ = $1; }
 688     | "transient" { $$ = $1; }
 689     | "volatile" { $$ = $1; }
 690
 691     // XXX: currently I only have this as Word
 692     // | "let" { $$ = $1; }
 693
 694     | "yield" { $$ = $1; }
 695
 696     | "each" { $$ = $1; }
 697     | "of" { $$ = $1; }
 698     ;
 699
 700 IdentifierOpt
 701     : Identifier { $$ = $1; }
 702     | { $$ = NULL; }
 703     ;
 704 /* }}} */
 705
 706 /* 7.8 Literals {{{ */
 707 Literal
 708     : NullLiteral { $$ = $1; }
 709     | ValueLiteral { $$ = $1; }
 710     ;
 711
 712 ValueLiteral
 713     : BooleanLiteral { $$ = $1; }
 714     | NumericLiteral { $$ = $1; }
 715     | StringLiteral { $$ = $1; }
 716     | RegularExpressionLiteral { $$ = $1; }
 717     ;
 718 /* }}} */
 719 /* 7.8.1 Null Literals {{{ */
 720 NullLiteral
 721     : "null" { $$ = $1; }
 722     ;
 723 /* }}} */
 724 /* 7.8.2 Boolean Literals {{{ */
 725 BooleanLiteral
 726     : "true" { $$ = $1; }
 727     | "false" { $$ = $1; }
 728     ;
 729 /* }}} */
 730
 731 /* 7.9 Automatic Semicolon Insertion {{{ */
 732 StrictSemi
 733     : { driver.Warning(yylloc, "warning, automatic semi-colon insertion required"); }
 734     ;
 735
 736 Terminator
 737     : ";"
 738     | error { if (yychar != yyeof_ && yychar != token::CloseBrace && !yylval.newline_) YYABORT; else { yyerrok; driver.errors_.pop_back(); } } StrictSemi
 739     ;
 740
 741 TerminatorOpt
 742     : ";"
 743     | error { yyerrok; driver.errors_.pop_back(); } StrictSemi
 744     ;
 745 /* }}} */
 746
 747 /* 11.1 Primary Expressions {{{ */
 748 Parenthetical
 749     : "(" LexPushInOff Expression ")" LexPopIn { $$ = $3; }
 750     ;
 751
 752 ParentheticalOpt
 753     : Parenthetical { $$ = $1; }
 754     | { $$ = NULL; }
 755     ;
 756
 757 Variable
 758     : Identifier { $$ = CYNew CYVariable($1); }
 759     ;
 760
 761 PrimaryExpression
 762     : "this" { $$ = $1; }
 763     | Variable { $$ = $1; }
 764     | Literal { $$ = $1; }
 765     | ArrayLiteral { $$ = $1; }
 766     | ObjectLiteral { $$ = $1; }
 767     | Parenthetical { $$ = $1; }
 768     | AutoComplete { driver.mode_ = CYDriver::AutoPrimary; YYACCEPT; }
 769     ;
 770 /* }}} */
 771 /* 11.1.4.1 Array Initialiser {{{ */
 772 ArrayLiteral
 773     : "[" LexPushInOff ElementListOpt "]" LexPopIn { $$ = CYNew CYArray($3); }
 774     ;
 775
 776 Element
 777     : AssignmentExpression { $$ = $1; }
 778     ;
 779
 780 ElementOpt
 781     : Element { $$ = $1; }
 782     | LexSetRegExp { $$ = NULL; }
 783     ;
 784
 785 ElementList
 786     : ElementOpt "," ElementListOpt { $$ = CYNew CYElement($1, $3); }
 787     | Element { $$ = CYNew CYElement($1, NULL); }
 788     ;
 789
 790 ElementListOpt
 791     : ElementList { $$ = $1; }
 792     | LexSetRegExp { $$ = NULL; }
 793     ;
 794 /* }}} */
 795 /* 11.1.4.2 Array Comprehension {{{ */
 796 PrimaryExpression
 797     : "[" LexPushInOff AssignmentExpression ComprehensionForList "]" LexPopIn { $$ = CYNew CYArrayComprehension($3, $4); }
 798     ;
 799
 800 ComprehensionForList
 801     : "for" Binding "in" Expression ComprehensionForListOpt { $$ = CYNew CYForInComprehension($2, $4, $5); }
 802     | "for" Binding "of" Expression ComprehensionForListOpt { $$ = CYNew CYForOfComprehension($2, $4, $5); }
 803     ;
 804
 805 ComprehensionForListOpt
 806     : ComprehensionForList { $$ = $1; }
 807     | "if" Expression { $$ = CYNew CYIfComprehension($2); }
 808     | { $$ = NULL; }
 809     ;
 810 /* }}} */
 811 /* 11.1.5 Object Initialiser {{{ */
 812 ObjectLiteral
 813     : BRACE LexPushInOff PropertyDefinitionListOpt "}" LexPopIn { $$ = CYNew CYObject($3); }
 814     ;
 815
 816 PropertyDefinitionList_
 817     : "," PropertyDefinitionList { $$ = $2; }
 818     | "," LexSetRegExp { $$ = NULL; }
 819     | { $$ = NULL; }
 820     ;
 821
 822 PropertyDefinitionList
 823     : PropertyDefinition PropertyDefinitionList_ { $1->SetNext($2); $$ = $1; }
 824     ;
 825
 826 PropertyDefinitionListOpt
 827     : PropertyDefinitionList { $$ = $1; }
 828     | LexSetRegExp { $$ = NULL; }
 829     ;
 830
 831 PropertyDefinition
 832     // XXX: this should be IdentifierName
 833     : LexSetRegExp Identifier { $$ = CYNew CYProperty($2, CYNew CYVariable($2)); }
 834     | PropertyName ":" AssignmentExpression { $$ = CYNew CYProperty($1, $3); }
 835     //| MethodDefinition
 836     ;
 837
 838 PropertyName_
 839     : IdentifierName { $$ = $1; }
 840     | StringLiteral { $$ = $1; }
 841     | NumericLiteral { $$ = $1; }
 842     ;
 843
 844 PropertyName
 845     : LexSetRegExp PropertyName_ { $$ = $2; }
 846     ;
 847 /* }}} */
 848
 849 /* 11.2 Left-Hand-Side Expressions {{{ */
 850 MemberAccess
 851     : "[" LexPushInOff Expression "]" LexPopIn { $$ = CYNew CYDirectMember(NULL, $3); }
 852     | "." IdentifierName { $$ = CYNew CYDirectMember(NULL, CYNew CYString($2)); }
 853     | "." AutoComplete { driver.mode_ = CYDriver::AutoDirect; YYACCEPT; }
 854     ;
 855
 856 MemberExpression_
 857     : MemberExpression { $$ = $1; }
 858     //| "super" { $$ = $1; }
 859     ;
 860
 861 MemberExpression
 862     : LexSetRegExp PrimaryExpression { $$ = $2; }
 863     | LexSetRegExp FunctionExpression { $$ = $2; }
 864     | MemberExpression_ { driver.context_ = $1; } MemberAccess { $3->SetLeft($1); $$ = $3; }
 865     | LexSetRegExp "new" MemberExpression Arguments { $$ = CYNew cy::Syntax::New($3, $4); }
 866     ;
 867
 868 NewExpression
 869     : MemberExpression { $$ = $1; }
 870     | LexSetRegExp "new" NewExpression { $$ = CYNew cy::Syntax::New($3, NULL); }
 871     ;
 872
 873 CallExpression_
 874     : MemberExpression_
 875     | CallExpression
 876     ;
 877
 878 CallExpression
 879     : CallExpression_ Arguments { $$ = CYNew CYCall($1, $2); }
 880     | CallExpression { driver.context_ = $1; } MemberAccess { $3->SetLeft($1); $$ = $3; }
 881     ;
 882
 883 Arguments
 884     : "(" LexPushInOff ArgumentListOpt ")" LexPopIn { $$ = $3; }
 885     ;
 886
 887 ArgumentList_
 888     : "," ArgumentList { $$ = $2; }
 889     | { $$ = NULL; }
 890     ;
 891
 892 ArgumentList
 893     : AssignmentExpression ArgumentList_ { $$ = CYNew CYArgument(NULL, $1, $2); }
 894     ;
 895
 896 ArgumentListOpt
 897     : ArgumentList { $$ = $1; }
 898     | LexSetRegExp { $$ = NULL; }
 899     ;
 900
 901 LeftHandSideExpression
 902     : NewExpression { $$ = $1; }
 903     | CallExpression { $$ = $1; }
 904     ;
 905 /* }}} */
 906 /* 11.3 Postfix Expressions {{{ */
 907 PostfixExpression
 908     : %prec "" LeftHandSideExpression { $$ = $1; }
 909     | LeftHandSideExpression "++" { $$ = CYNew CYPostIncrement($1); }
 910     | LeftHandSideExpression "--" { $$ = CYNew CYPostDecrement($1); }
 911     ;
 912 /* }}} */
 913 /* 11.4 Unary Operators {{{ */
 914 UnaryExpression_
 915     : "delete" UnaryExpression { $$ = CYNew CYDelete($2); }
 916     | "void" UnaryExpression { $$ = CYNew CYVoid($2); }
 917     | "typeof" UnaryExpression { $$ = CYNew CYTypeOf($2); }
 918     | "++" UnaryExpression { $$ = CYNew CYPreIncrement($2); }
 919     | "\n++" UnaryExpression { $$ = CYNew CYPreIncrement($2); }
 920     | "--" UnaryExpression { $$ = CYNew CYPreDecrement($2); }
 921     | "\n--" UnaryExpression { $$ = CYNew CYPreDecrement($2); }
 922     | "+" UnaryExpression { $$ = CYNew CYAffirm($2); }
 923     | "-" UnaryExpression { $$ = CYNew CYNegate($2); }
 924     | "~" UnaryExpression { $$ = CYNew CYBitwiseNot($2); }
 925     | "!" UnaryExpression { $$ = CYNew CYLogicalNot($2); }
 926     ;
 927
 928 UnaryExpression
 929     : PostfixExpression { $$ = $1; }
 930     | LexSetRegExp UnaryExpression_ { $$ = $2; }
 931     ;
 932 /* }}} */
 933 /* 11.5 Multiplicative Operators {{{ */
 934 MultiplicativeExpression
 935     : UnaryExpression { $$ = $1; }
 936     | MultiplicativeExpression "*" UnaryExpression { $$ = CYNew CYMultiply($1, $3); }
 937     | MultiplicativeExpression "/" UnaryExpression { $$ = CYNew CYDivide($1, $3); }
 938     | MultiplicativeExpression "%" UnaryExpression { $$ = CYNew CYModulus($1, $3); }
 939     ;
 940 /* }}} */
 941 /* 11.6 Additive Operators {{{ */
 942 AdditiveExpression
 943     : MultiplicativeExpression { $$ = $1; }
 944     | AdditiveExpression "+" MultiplicativeExpression { $$ = CYNew CYAdd($1, $3); }
 945     | AdditiveExpression "-" MultiplicativeExpression { $$ = CYNew CYSubtract($1, $3); }
 946     ;
 947 /* }}} */
 948 /* 11.7 Bitwise Shift Operators {{{ */
 949 ShiftExpression
 950     : AdditiveExpression { $$ = $1; }
 951     | ShiftExpression "<<" AdditiveExpression { $$ = CYNew CYShiftLeft($1, $3); }
 952     | ShiftExpression ">>" AdditiveExpression { $$ = CYNew CYShiftRightSigned($1, $3); }
 953     | ShiftExpression ">>>" AdditiveExpression { $$ = CYNew CYShiftRightUnsigned($1, $3); }
 954     ;
 955 /* }}} */
 956 /* 11.8 Relational Operators {{{ */
 957 RelationalExpression
 958     : ShiftExpression { $$ = $1; }
 959     | RelationalExpression "<" ShiftExpression { $$ = CYNew CYLess($1, $3); }
 960     | RelationalExpression ">" ShiftExpression { $$ = CYNew CYGreater($1, $3); }
 961     | RelationalExpression "<=" ShiftExpression { $$ = CYNew CYLessOrEqual($1, $3); }
 962     | RelationalExpression ">=" ShiftExpression { $$ = CYNew CYGreaterOrEqual($1, $3); }
 963     | RelationalExpression "instanceof" ShiftExpression { $$ = CYNew CYInstanceOf($1, $3); }
 964     | RelationalExpression "in" ShiftExpression { $$ = CYNew CYIn($1, $3); }
 965     ;
 966 /* }}} */
 967 /* 11.9 Equality Operators {{{ */
 968 EqualityExpression
 969     : RelationalExpression { $$ = $1; }
 970     | EqualityExpression "==" RelationalExpression { $$ = CYNew CYEqual($1, $3); }
 971     | EqualityExpression "!=" RelationalExpression { $$ = CYNew CYNotEqual($1, $3); }
 972     | EqualityExpression "===" RelationalExpression { $$ = CYNew CYIdentical($1, $3); }
 973     | EqualityExpression "!==" RelationalExpression { $$ = CYNew CYNotIdentical($1, $3); }
 974     ;
 975 /* }}} */
 976 /* 11.10 Binary Bitwise Operators {{{ */
 977 BitwiseANDExpression
 978     : EqualityExpression { $$ = $1; }
 979     | BitwiseANDExpression "&" EqualityExpression { $$ = CYNew CYBitwiseAnd($1, $3); }
 980     ;
 981
 982 BitwiseXORExpression
 983     : BitwiseANDExpression { $$ = $1; }
 984     | BitwiseXORExpression "^" BitwiseANDExpression { $$ = CYNew CYBitwiseXOr($1, $3); }
 985     ;
 986
 987 BitwiseORExpression
 988     : BitwiseXORExpression { $$ = $1; }
 989     | BitwiseORExpression "|" BitwiseXORExpression { $$ = CYNew CYBitwiseOr($1, $3); }
 990     ;
 991 /* }}} */
 992 /* 11.11 Binary Logical Operators {{{ */
 993 LogicalANDExpression
 994     : BitwiseORExpression { $$ = $1; }
 995     | LogicalANDExpression "&&" BitwiseORExpression { $$ = CYNew CYLogicalAnd($1, $3); }
 996     ;
 997
 998 LogicalORExpression
 999     : LogicalANDExpression { $$ = $1; }
1000     | LogicalORExpression "||" LogicalANDExpression { $$ = CYNew CYLogicalOr($1, $3); }
1001     ;
1002 /* }}} */
1003 /* 11.12 Conditional Operator ( ? : ) {{{ */
1004 ConditionalExpression
1005     : LogicalORExpression { $$ = $1; }
1006     | LogicalORExpression "?" LexPushInOff AssignmentExpression ":" LexPopIn AssignmentExpression { $$ = CYNew CYCondition($1, $4, $7); }
1007     ;
1008 /* }}} */
1009 /* 11.13 Assignment Operators {{{ */
1010 AssignmentExpression
1011     : ConditionalExpression { $$ = $1; }
1012     | ArrowFunction { $$ = $1; }
1013     | LeftHandSideExpression "=" AssignmentExpression { $$ = CYNew CYAssign($1, $3); }
1014     | LeftHandSideExpression "*=" AssignmentExpression { $$ = CYNew CYMultiplyAssign($1, $3); }
1015     | LeftHandSideExpression "/=" AssignmentExpression { $$ = CYNew CYDivideAssign($1, $3); }
1016     | LeftHandSideExpression "%=" AssignmentExpression { $$ = CYNew CYModulusAssign($1, $3); }
1017     | LeftHandSideExpression "+=" AssignmentExpression { $$ = CYNew CYAddAssign($1, $3); }
1018     | LeftHandSideExpression "-=" AssignmentExpression { $$ = CYNew CYSubtractAssign($1, $3); }
1019     | LeftHandSideExpression "<<=" AssignmentExpression { $$ = CYNew CYShiftLeftAssign($1, $3); }
1020     | LeftHandSideExpression ">>=" AssignmentExpression { $$ = CYNew CYShiftRightSignedAssign($1, $3); }
1021     | LeftHandSideExpression ">>>=" AssignmentExpression { $$ = CYNew CYShiftRightUnsignedAssign($1, $3); }
1022     | LeftHandSideExpression "&=" AssignmentExpression { $$ = CYNew CYBitwiseAndAssign($1, $3); }
1023     | LeftHandSideExpression "^=" AssignmentExpression { $$ = CYNew CYBitwiseXOrAssign($1, $3); }
1024     | LeftHandSideExpression "|=" AssignmentExpression { $$ = CYNew CYBitwiseOrAssign($1, $3); }
1025     ;
1026 /* }}} */
1027 /* 11.14 Comma Operator {{{ */
1028 Expression_
1029     : "," Expression { $$ = $2; }
1030     | { $$ = CYNew CYCompound(); }
1031     ;
1032
1033 Expression
1034     : AssignmentExpression Expression_ { $2->AddPrev($1); $$ = $2; }
1035     ;
1036
1037 ExpressionOpt
1038     : Expression { $$ = $1; }
1039     | LexSetRegExp { $$ = NULL; }
1040     ;
1041 /* }}} */
1042
1043 /* 12 Statements {{{ */
1044 Statement__
1045     : Block { $$ = $1; }
1046     | VariableStatement { $$ = $1; }
1047     | EmptyStatement { $$ = $1; }
1048     | IfStatement { $$ = $1; }
1049     | BreakableStatement { $$ = $1; }
1050     | ContinueStatement { $$ = $1; }
1051     | BreakStatement { $$ = $1; }
1052     | ReturnStatement { $$ = $1; }
1053     | WithStatement { $$ = $1; }
1054     | LabelledStatement { $$ = $1; }
1055     | ThrowStatement { $$ = $1; }
1056     | TryStatement { $$ = $1; }
1057     | DebuggerStatement { $$ = $1; }
1058     ;
1059
1060 Statement_
1061     : LexSetRegExp Statement__ { $$ = $2; }
1062     | ExpressionStatement { $$ = $1; }
1063     ;
1064
1065 Statement
1066     : LexSetStatement Statement_ { $$ = $2; }
1067     ;
1068
1069 Declaration__
1070     : FunctionDeclaration { $$ = $1; }
1071     | LexicalDeclaration { $$ = $1; }
1072     ;
1073
1074 Declaration_
1075     : LexSetRegExp Declaration__ { $$ = $2; }
1076     ;
1077
1078 Declaration
1079     : LexSetStatement Declaration_ { $$ = $2; }
1080     ;
1081
1082 BreakableStatement
1083     : IterationStatement { $$ = $1; }
1084     | SwitchStatement { $$ = $1; }
1085     ;
1086 /* }}} */
1087 /* 12.1 Block {{{ */
1088 Block_
1089     : BRACE StatementListOpt "}" { $$ = $2; }
1090     ;
1091
1092 Block
1093     : ";{" StatementListOpt "}" { $$ = CYNew CYBlock($2); }
1094     ;
1095
1096 StatementList
1097     : StatementListItem StatementListOpt { $1->SetNext($2); $$ = $1; }
1098     ;
1099
1100 StatementListOpt
1101     : StatementList { $$ = $1; }
1102     | LexSetStatement LexSetRegExp { $$ = NULL; }
1103     ;
1104
1105 StatementListItem
1106     : Statement { $$ = $1; }
1107     | Declaration { $$ = $1; }
1108     ;
1109 /* }}} */
1110
1111 /* 12.2 Declarations {{{ */
1112 BindingIdentifier
1113     : Identifier { $$ = $1; }
1114     ;
1115
1116 Binding
1117     : BindingIdentifier
1118     ;
1119
1120 // XXX: BindingPattern
1121 /* }}} */
1122 /* 12.2.1 Let and Const Declarations {{{ */
1123 LexicalDeclaration
1124     : LetOrConst VariableDeclarationList Terminator { $$ = CYNew CYVar($2); }
1125     ;
1126
1127 LetOrConst
1128     : "let"
1129     | "const"
1130     ;
1131 /* }}} */
1132 /* 12.2.2 Variable Statement {{{ */
1133 VariableStatement
1134     : Var_ VariableDeclarationList Terminator { $$ = CYNew CYVar($2); }
1135     ;
1136
1137 VariableDeclarationList_
1138     : "," VariableDeclarationList { $$ = $2; }
1139     | { $$ = NULL; }
1140     ;
1141
1142 VariableDeclarationList
1143     : VariableDeclaration VariableDeclarationList_ { $$ = CYNew CYDeclarations($1, $2); }
1144     ;
1145
1146 VariableDeclaration
1147     : BindingIdentifier InitialiserOpt { $$ = CYNew CYDeclaration($1, $2); }
1148     // XXX: | BindingPattern Initialiser { $$ = CYNew CYDeclaration($1, $2); }
1149     ;
1150
1151 Initialiser
1152     : "=" AssignmentExpression { $$ = $2; }
1153     ;
1154
1155 InitialiserOpt
1156     : Initialiser { $$ = $1; }
1157     | { $$ = NULL; }
1158     ;
1159 /* }}} */
1160 /* 12.2.4 Destructuring Binding Patterns {{{ */
1161 // XXX: *
1162
1163 BindingElement
1164     : SingleNameBinding { $$ = $1; }
1165     ;
1166
1167 SingleNameBinding
1168     : BindingIdentifier InitialiserOpt { $$ = CYNew CYDeclaration($1, $2); }
1169     ;
1170 /* }}} */
1171
1172 /* 12.3 Empty Statement {{{ */
1173 EmptyStatement
1174     : ";" { $$ = CYNew CYEmpty(); }
1175     ;
1176 /* }}} */
1177 /* 12.4 Expression Statement {{{ */
1178 ExpressionStatement
1179     : Expression Terminator { $$ = CYNew CYExpress($1); }
1180     ;
1181 /* }}} */
1182 /* 12.5 The if Statement {{{ */
1183 ElseStatementOpt
1184     : "else" Statement { $$ = $2; }
1185     | %prec "if" { $$ = NULL; }
1186     ;
1187
1188 IfStatement
1189     : "if" "(" Expression ")" Statement ElseStatementOpt { $$ = CYNew CYIf($3, $5, $6); }
1190     ;
1191 /* }}} */
1192
1193 /* 12.6.1 The do-while Statement {{{ */
1194 IterationStatement
1195     : "do" Statement "while" "(" Expression ")" TerminatorOpt { $$ = CYNew CYDoWhile($5, $2); }
1196     ;
1197 /* }}} */
1198 /* 12.6.2 The while Statement {{{ */
1199 IterationStatement
1200     : "while" "(" Expression ")" Statement { $$ = CYNew CYWhile($3, $5); }
1201     ;
1202 /* }}} */
1203 /* 12.6.3 The for Statement {{{ */
1204 IterationStatement
1205     : "for" "(" LexPushInOn ForStatementInitialiser ";" LexPopIn ExpressionOpt ";" ExpressionOpt ")" Statement { $$ = CYNew CYFor($4, $7, $9, $11); }
1206     ;
1207
1208 ForStatementInitialiser
1209     : ExpressionOpt { $$ = $1; }
1210     | LexSetRegExp Var_ VariableDeclarationList { $$ = CYNew CYForDeclarations($3); }
1211     ;
1212 /* }}} */
1213 /* 12.6.4 The for-in and for-of Statements {{{ */
1214 IterationStatement
1215     : "for" "(" LexPushInOn ForInStatementInitialiser "!in" LexPopIn Expression ")" Statement { $$ = CYNew CYForIn($4, $7, $9); }
1216     | "for" "(" LexPushInOn ForInStatementInitialiser "of" LexPopIn Expression ")" Statement { $$ = CYNew CYForOf($4, $7, $9); }
1217     ;
1218
1219 ForInStatementInitialiser
1220     : LeftHandSideExpression { $$ = $1; }
1221     | LexSetRegExp Var_ VariableDeclaration { $$ = $3; }
1222     ;
1223 /* }}} */
1224
1225 /* 12.7 The continue Statement {{{ */
1226 ContinueStatement
1227     : "continue" "\n" StrictSemi { $$ = CYNew CYContinue(NULL); }
1228     | "continue" IdentifierOpt Terminator { $$ = CYNew CYContinue($2); }
1229     ;
1230 /* }}} */
1231 /* 12.8 The break Statement {{{ */
1232 BreakStatement
1233     : "break" "\n" StrictSemi { $$ = CYNew CYBreak(NULL); }
1234     | "break" IdentifierOpt Terminator { $$ = CYNew CYBreak($2); }
1235     ;
1236 /* }}} */
1237 /* 12.9 The return Statement {{{ */
1238 ReturnStatement
1239     : "return" LexSetRegExp "\n" StrictSemi { $$ = CYNew CYReturn(NULL); }
1240     | "return" ExpressionOpt Terminator { $$ = CYNew CYReturn($2); }
1241     ;
1242 /* }}} */
1243 /* 12.10 The with Statement {{{ */
1244 WithStatement
1245     : "with" "(" Expression ")" Statement { $$ = CYNew CYWith($3, $5); }
1246     ;
1247 /* }}} */
1248
1249 /* 12.11 The switch Statement {{{ */
1250 SwitchStatement
1251     : "switch" "(" Expression ")" CaseBlock { $$ = CYNew CYSwitch($3, $5); }
1252     ;
1253
1254 CaseBlock
1255     : BRACE CaseClausesOpt "}" { $$ = $2; }
1256     ;
1257
1258 CaseClause
1259     : "case" Expression ":" StatementListOpt { $$ = CYNew CYClause($2, $4); }
1260     ;
1261
1262 CaseClausesOpt
1263     : CaseClause CaseClausesOpt { $1->SetNext($2); $$ = $1; }
1264     | DefaultClause CaseClausesOpt { $1->SetNext($2); $$ = $1; }
1265     | { $$ = NULL; }
1266     ;
1267
1268 DefaultClause
1269     : "default" ":" StatementListOpt { $$ = CYNew CYClause(NULL, $3); }
1270     ;
1271 /* }}} */
1272 /* 12.12 Labelled Statements {{{ */
1273 LabelledStatement
1274     : Identifier ":" Statement { $$ = CYNew CYLabel($1, $3); }
1275     ;
1276 /* }}} */
1277 /* 12.13 The throw Statement {{{ */
1278 ThrowStatement
1279     : "throw" LexSetRegExp "\n" StrictSemi { YYABORT; }
1280     | "throw" Expression Terminator { $$ = CYNew cy::Syntax::Throw($2); }
1281     ;
1282 /* }}} */
1283 /* 12.14 The try Statement {{{ */
1284 TryStatement
1285     : "try" Block_ CatchOpt FinallyOpt { $$ = CYNew cy::Syntax::Try($2, $3, $4); }
1286     ;
1287
1288 CatchOpt
1289     : "catch" "(" Identifier ")" Block_ { $$ = CYNew cy::Syntax::Catch($3, $5); }
1290     | { $$ = NULL; }
1291     ;
1292
1293 FinallyOpt
1294     : "finally" Block_ { $$ = CYNew CYFinally($2); }
1295     | { $$ = NULL; }
1296     ;
1297 /* }}} */
1298 /* 12.14 The debugger Statement {{{ */
1299 DebuggerStatement
1300     : "debugger" Terminator { $$ = CYNew CYDebugger(); }
1301     ;
1302 /* }}} */
1303
1304 /* 13.1 Function Definitions {{{ */
1305 FunctionDeclaration
1306     : ";function" Identifier "(" FormalParameterListOpt ")" BRACE FunctionBody "}" { $$ = CYNew CYFunctionStatement($2, $4, $7); }
1307     ;
1308
1309 FunctionExpression
1310     : "function" IdentifierOpt "(" LexPushInOff FormalParameterListOpt ")" LexPopIn BRACE LexPushInOff FunctionBody "}" LexPopIn { $$ = CYNew CYFunctionExpression($2, $5, $10); }
1311     ;
1312
1313 FormalParameterList_
1314     : "," FormalParameterList { $$ = $2; }
1315     | { $$ = NULL; }
1316     ;
1317
1318 FormalParameterList
1319     // XXX: : FunctionRestParameter { $$ = $1; }
1320     : FormalParameter FormalParameterList_ { $$ = CYNew CYFunctionParameter($1, $2); }
1321     ;
1322
1323 FormalParameterListOpt
1324     : FormalParameterList
1325     | { $$ = NULL; }
1326     ;
1327
1328 /* XXX: FunctionRestParameter
1329     : "..." BindingIdentifier { $$ = CYNew CYFunctionRestParameter($2); }
1330     ;*/
1331
1332 FormalParameter
1333     : BindingElement { $$ = $1; }
1334     ;
1335
1336 FunctionBody
1337     : StatementListOpt { $$ = $1; }
1338     ;
1339 /* }}} */
1340 /* 13.2 Arrow Function Definitions {{{ */
1341 ArrowFunction
1342     : LexSetRegExp ArrowParameters "=>" LexNoBrace ConciseBody { $$ = CYNew CYFatArrow($2, $5); }
1343     ;
1344
1345 ArrowParameters
1346     : BindingIdentifier { $$ = CYNew CYFunctionParameter(CYNew CYDeclaration($1)); }
1347     //| ParentheticalOpt { $$ = $1; }
1348     ;
1349
1350 ConciseBody
1351     : AssignmentExpression { $$ = CYNew CYReturn($1); }
1352     | LexSetRegExp ";{" LexPushInOff FunctionBody "}" LexPopIn { $$ = $4; }
1353     ;
1354 /* }}} */
1355 /* 14 Program {{{ */
1356 Program
1357     : ProgramBodyOpt { driver.program_ = CYNew CYProgram($1); }
1358     ;
1359
1360 ProgramBody
1361     : StatementList { $$ = $1; }
1362     ;
1363
1364 ProgramBodyOpt
1365     : ProgramBody { $$ = $1; }
1366     | LexSetStatement LexSetRegExp { $$ = NULL; }
1367     ;
1368 /* }}} */
1369
1370 @begin ObjectiveC
1371 /* Cycript (Objective-C): Type Encoding {{{ */
1372 TypeParenthetical
1373     : "(" PrefixedType ")" { $$ = $2; }
1374     ;
1375
1376 TypeSignifier
1377     : Identifier { $$ = CYNew CYTypedIdentifier($1); }
1378     | TypeParenthetical
1379     ;
1380
1381 ArrayedType
1382     : ArrayedType "[" NumericLiteral "]" { $$ = $1; CYSetLast($$->type_) = CYNew CYTypeArrayOf($3); }
1383     | TypeSignifier { $$ = $1; }
1384     | { $$ = CYNew CYTypedIdentifier(NULL); }
1385     ;
1386
1387 SuffixedType
1388     : ArrayedType { $$ = $1; }
1389     | TypeParenthetical "(" LexPushInOff TypedParameterListOpt ")" LexPopIn { $$ = $1; CYSetLast($$->type_) = CYNew CYTypeFunctionWith($4); }
1390     ;
1391
1392 PrefixedType
1393     : "*" TypeQualifierRight PrefixedType { $$ = $3; CYSetLast($$->type_) = $2; CYSetLast($$->type_) = CYNew CYTypePointerTo(); }
1394     | SuffixedType { $$ = $1; }
1395     ;
1396
1397 TypeQualifierLeft
1398     : "const" TypeQualifierLeft { $$ = CYNew CYTypeConstant(); CYSetLast($$) = $2; }
1399     | { $$ = NULL; }
1400     ;
1401
1402 TypeQualifierRight
1403     : TypeQualifierRight "const" { $$ = CYNew CYTypeConstant($1); }
1404     | { $$ = NULL; }
1405     ;
1406
1407 ConcreteType
1408     : TypeQualifierLeft PrimitiveType TypeQualifierRight { $$ = $3; CYSetLast($$) = $1; CYSetLast($$) = CYNew CYTypeVariable($2); }
1409     ;
1410
1411 PrimitiveType
1412     : Variable { $$ = $1; }
1413     | "void" { $$  = CYNew cy::Syntax::New(CYNew CYVariable(CYNew CYIdentifier("Type")), CYNew CYArgument(CYNew CYString("v"))); }
1414     ;
1415
1416 TypedIdentifier
1417     : ConcreteType PrefixedType { $$ = $2; CYSetLast($$->type_) = $1; }
1418     ;
1419
1420 EncodedType
1421     : TypedIdentifier { $$ = CYNew CYEncodedType($1->type_); }
1422     ;
1423
1424 ModifiedType_
1425     : TypeQualifierLeft PrimitiveType { $$ = $1; CYSetLast($$) = CYNew CYTypeVariable($2); }
1426     | ModifiedType "*" { $$ = CYNew CYTypePointerTo($1); }
1427     ;
1428
1429 ModifiedType
1430     : ModifiedType_ TypeQualifierRight { $$ = $2; CYSetLast($$) = $1; }
1431     ;
1432
1433 PrimaryExpression
1434     : AtEncode "(" EncodedType ")" { $$ = $3; }
1435     ;
1436 /* }}} */
1437 /* Cycript (Objective-C): @class Declaration {{{ */
1438 ClassSuperOpt
1439     /* XXX: why the hell did I choose MemberExpression? */
1440     : ":" LexSetRegExp MemberExpression { $$ = $3; }
1441     | { $$ = NULL; }
1442     ;
1443
1444 ClassFieldListOpt
1445     : Expression Identifier ";" ClassFieldListOpt { $$ = CYNew CYField($1, $2, $4); }
1446     | LexSetRegExp { $$ = NULL; }
1447     ;
1448
1449 ClassFields
1450     : BRACE ClassFieldListOpt "}" { $$ = $2; }
1451     ;
1452
1453 MessageScope
1454     : "+" { $$ = false; }
1455     | "-" { $$ = true; }
1456     ;
1457
1458 TypeOpt
1459     : "(" LexSetRegExp EncodedType ")" { $$ = $3; }
1460     | { $$ = NULL; }
1461     ;
1462
1463 MessageParameter
1464     : Word ":" TypeOpt Identifier { $$ = CYNew CYMessageParameter($1, $3, $4); }
1465     ;
1466
1467 MessageParameterList
1468     : MessageParameter MessageParameterListOpt { $1->SetNext($2); $$ = $1; }
1469     ;
1470
1471 MessageParameterListOpt
1472     : MessageParameterList { $$ = $1; }
1473     | { $$ = NULL; }
1474     ;
1475
1476 MessageParameters
1477     : MessageParameterList { $$ = $1; }
1478     | Word { $$ = CYNew CYMessageParameter($1, NULL, NULL); }
1479     ;
1480
1481 ClassMessageDeclaration
1482     : MessageScope TypeOpt MessageParameters BRACE FunctionBody "}" { $$ = CYNew CYMessage($1, $2, $3, $5); }
1483     ;
1484
1485 ClassMessageDeclarationListOpt
1486     : ClassMessageDeclarationListOpt ClassMessageDeclaration { $2->SetNext($1); $$ = $2; }
1487     | ClassMessageDeclarationListOpt Comment { $$ = $1; }
1488     | { $$ = NULL; }
1489     ;
1490
1491 ClassName
1492     : Identifier { $$ = $1; }
1493     | "(" AssignmentExpression ")" { $$ = $2; }
1494     ;
1495
1496 ClassNameOpt
1497     : ClassName { $$ = $1; }
1498     | { $$ = NULL; }
1499     ;
1500
1501 // XXX: this should be AssignmentExpressionNoRight
1502 ClassProtocols
1503     : ShiftExpression ClassProtocolsOpt { $$ = CYNew CYProtocol($1, $2); }
1504     ;
1505
1506 ClassProtocolsOpt
1507     : "," ClassProtocols { $$ = $2; }
1508     | { $$ = NULL; }
1509     ;
1510
1511 ClassProtocolListOpt
1512     : "<" ClassProtocols ">" { $$ = $2; }
1513     | { $$ = NULL; }
1514     ;
1515
1516 ClassExpression
1517     : "@implementation" LexPushInOff ClassNameOpt ClassSuperOpt ClassProtocolListOpt ClassFields ClassMessageDeclarationListOpt "@end" LexPopIn { $$ = CYNew CYClassExpression($3, $4, $5, $6, $7); }
1518     ;
1519
1520 ClassStatement
1521     : ";@implementation" ClassName ClassSuperOpt ClassProtocolListOpt ClassFields ClassMessageDeclarationListOpt "@end" { $$ = CYNew CYClassStatement($2, $3, $4, $5, $6); }
1522     ;
1523
1524 CategoryName
1525     : "(" WordOpt ")"
1526     ;
1527
1528 CategoryStatement
1529     : ";@implementation" ClassName CategoryName ClassMessageDeclarationListOpt "@end" { $$ = CYNew CYCategory($2, $4); }
1530     ;
1531
1532 PrimaryExpression
1533     : ClassExpression { $$ = $1; }
1534     ;
1535
1536 Statement__
1537     : ClassStatement { $$ = $1; }
1538     | CategoryStatement { $$ = $1; }
1539     ;
1540 /* }}} */
1541 /* Cycript (Objective-C): Send Message {{{ */
1542 VariadicCall
1543     : "," AssignmentExpression VariadicCall { $$ = CYNew CYArgument(NULL, $2, $3); }
1544     | { $$ = NULL; }
1545     ;
1546
1547 SelectorWordOpt
1548     : WordOpt { driver.contexts_.back().words_.push_back($1); } { $$ = $1; }
1549     | AutoComplete { driver.mode_ = CYDriver::AutoMessage; YYACCEPT; }
1550     ;
1551
1552 SelectorCall_
1553     : SelectorCall { $$ = $1; }
1554     | VariadicCall { $$ = $1; }
1555     ;
1556
1557 SelectorCall
1558     : SelectorWordOpt ":" AssignmentExpression SelectorCall_ { $$ = CYNew CYArgument($1 ?: CYNew CYBlank(), $3, $4); }
1559     ;
1560
1561 SelectorList
1562     : SelectorCall { $$ = $1; }
1563     | Word { $$ = CYNew CYArgument($1, NULL); }
1564     ;
1565
1566 MessageExpression
1567     : "[" LexPushInOff AssignmentExpression { driver.contexts_.push_back($3); } SelectorList "]" LexPopIn { driver.contexts_.pop_back(); } { $$ = CYNew CYSendDirect($3, $5); }
1568     | "[" LexPushInOff LexSetRegExp "super" { driver.context_ = NULL; } SelectorList "]" LexPopIn { $$ = CYNew CYSendSuper($6); }
1569     ;
1570
1571 SelectorExpression_
1572     : WordOpt ":" SelectorExpressionOpt { $$ = CYNew CYSelectorPart($1, true, $3); }
1573     ;
1574
1575 SelectorExpression
1576     : SelectorExpression_ { $$ = $1; }
1577     | Word { $$ = CYNew CYSelectorPart($1, false, NULL); }
1578     ;
1579
1580 SelectorExpressionOpt
1581     : SelectorExpression_ { $$ = $1; }
1582     | { $$ = NULL; }
1583     ;
1584
1585 PrimaryExpression
1586     : MessageExpression { $$ = $1; }
1587     | "@selector" "(" LexPushInOff SelectorExpression ")" LexPopIn { $$ = CYNew CYSelector($4); }
1588     ;
1589 /* }}} */
1590 /* Cycript (Objective-C): @import Directive {{{ */
1591 PathName
1592     : "/" PathName
1593     | "." PathName
1594     | Word PathName
1595     |
1596     ;
1597
1598 ImportPath
1599     : "<" PathName ">"
1600     | StringLiteral
1601     ;
1602
1603 StatementListItem
1604     : LexSetStatement LexSetRegExp "@import" ImportPath { $$ = CYNew CYImport(); }
1605     ;
1606 /* }}} */
1607 /* Cycript (Objective-C): Boxed Expressions {{{ */
1608 BoxableExpression
1609     : NullLiteral { $$ = $1; }
1610     | BooleanLiteral { $$ = $1; }
1611     | NumericLiteral { $$ = $1; }
1612     | StringLiteral { $$ = $1; }
1613     | ArrayLiteral { $$ = $1; }
1614     | ObjectLiteral { $$ = $1; }
1615     | Parenthetical { $$ = $1; }
1616     | "YES" { $$ = CYNew CYTrue(); }
1617     | "NO" { $$ = CYNew CYFalse(); }
1618     ;
1619
1620 PrimaryExpression
1621     : "@" BoxableExpression { $$ = CYNew CYBox($2); }
1622     ;
1623 /* }}} */
1624 /* Cycript (Objective-C): Block Expressions {{{ */
1625 PrimaryExpression
1626     : "^" ModifiedType "(" LexPushInOff TypedParameterListOpt ")" LexPopIn BRACE LexPushInOff FunctionBody "}" LexPopIn { $$ = CYNew CYObjCBlock($2, $5, $10); }
1627     ;
1628 /* }}} */
1629 @end
1630
1631 @begin C
1632 /* Cycript (C): Pointer Indirection/Addressing {{{ */
1633 LeftHandSideExpression
1634     : LexSetRegExp "*" UnaryExpression { $$ = CYNew CYIndirect($3); }
1635     ;
1636
1637 UnaryExpression_
1638     : "&" UnaryExpression { $$ = CYNew CYAddressOf($2); }
1639     ;
1640
1641 MemberAccess
1642     : "->" "[" Expression "]" { $$ = CYNew CYIndirectMember(NULL, $3); }
1643     | "->" IdentifierName { $$ = CYNew CYIndirectMember(NULL, CYNew CYString($2)); }
1644     | "->" AutoComplete { driver.mode_ = CYDriver::AutoIndirect; YYACCEPT; }
1645     ;
1646 /* }}} */
1647 /* Cycript (C): auto Compatibility {{{ */
1648 Var_
1649     : "auto"
1650     ;
1651 /* }}} */
1652 /* Cycript (C): Lambda Expressions {{{ */
1653 TypedParameterList_
1654     : "," TypedParameterList { $$ = $2; }
1655     | { $$ = NULL; }
1656     ;
1657
1658 TypedParameterList
1659     : TypedIdentifier TypedParameterList_ { $$ = CYNew CYTypedParameter($1, $2); }
1660     ;
1661
1662 TypedParameterListOpt
1663     : TypedParameterList { $$ = $1; }
1664     | { $$ = NULL; }
1665     ;
1666
1667 PrimaryExpression
1668     : "[" LexPushInOff LexSetRegExp "&" LexSetRegExp "]" LexPopIn "(" LexPushInOff TypedParameterListOpt ")" LexPopIn "->" TypedIdentifier BRACE LexPushInOff FunctionBody "}" LexPopIn { $$ = CYNew CYLambda($14->type_, $10, $17); }
1669     ;
1670 /* }}} */
1671 /* Cycript (C): Type Definitions {{{ */
1672 Statement__
1673     : "typedef" TypedIdentifier Terminator { $$ = CYNew CYTypeDefinition($2); }
1674     ;
1675 /* }}} */
1676 @end
1677
1678 /* YUI: Documentation Comments {{{ */
1679 Statement__
1680     : Comment { $$ = $1; }
1681     ;
1682 /* }}} */
1683
1684 @begin E4X
1685 /* Lexer State {{{ */
1686 LexPushRegExp
1687     : { driver.PushCondition(CYDriver::RegExpCondition); }
1688     ;
1689
1690 LexPushXMLContent
1691     : { driver.PushCondition(CYDriver::XMLContentCondition); }
1692     ;
1693
1694 LexPushXMLTag
1695     : { driver.PushCondition(CYDriver::XMLTagCondition); }
1696     ;
1697
1698 LexPop
1699     : { driver.PopCondition(); }
1700     ;
1701
1702 LexSetXMLContent
1703     : { driver.SetCondition(CYDriver::XMLContentCondition); }
1704     ;
1705
1706 LexSetXMLTag
1707     : { driver.SetCondition(CYDriver::XMLTagCondition); }
1708     ;
1709 /* }}} */
1710 /* Virtual Tokens {{{ */
1711 XMLWhitespaceOpt
1712     : XMLWhitespace
1713     |
1714     ;
1715 /* }}} */
1716
1717 /* 8.1 Context Keywords {{{ */
1718 Identifier
1719     : "namespace" { $$ = $1; }
1720     | "xml" { $$ = $1; }
1721     ;
1722 /* }}} */
1723 /* 8.3 XML Initialiser Input Elements {{{ */
1724 XMLMarkup
1725     : XMLComment { $$ = $1; }
1726     | XMLCDATA { $$ = $1; }
1727     | XMLPI { $$ = $1; }
1728     ;
1729 /* }}} */
1730
1731 /* 11.1 Primary Expressions {{{ */
1732 PrimaryExpression
1733     : PropertyIdentifier { $$ = CYNew CYPropertyVariable($1); }
1734     | XMLInitialiser { $$ = $1; }
1735     | XMLListInitialiser { $$ = $1; }
1736     ;
1737
1738 PropertyIdentifier
1739     : AttributeIdentifier { $$ = $1; }
1740     | QualifiedIdentifier { $$ = $1; }
1741     | WildcardIdentifier { $$ = $1; }
1742     ;
1743 /* }}} */
1744 /* 11.1.1 Attribute Identifiers {{{ */
1745 AttributeIdentifier
1746     : "@" QualifiedIdentifier_ { $$ = CYNew CYAttribute($2); }
1747     ;
1748
1749 PropertySelector_
1750     : PropertySelector { $$ = $1; }
1751     | "[" LexPushInOff Expression "]" LexPopIn { $$ = CYNew CYSelector($3); }
1752     ;
1753
1754 PropertySelector
1755     : Identifier { $$ = CYNew CYSelector($1); }
1756     | WildcardIdentifier { $$ = $1; }
1757     ;
1758 /* }}} */
1759 /* 11.1.2 Qualified Identifiers {{{ */
1760 QualifiedIdentifier_
1761     : PropertySelector_ { $$ = CYNew CYQualified(NULL, $1); }
1762     | QualifiedIdentifier { $$ = $1; }
1763     ;
1764
1765 QualifiedIdentifier
1766     : PropertySelector "::" PropertySelector_ { $$ = CYNew CYQualified($1, $3); }
1767     ;
1768 /* }}} */
1769 /* 11.1.3 Wildcard Identifiers {{{ */
1770 WildcardIdentifier
1771     : "*" { $$ = CYNew CYWildcard(); }
1772     ;
1773 /* }}} */
1774 /* 11.1.4 XML Initialiser {{{ */
1775 XMLInitialiser
1776     : XMLMarkup { $$ = $1; }
1777     | XMLElement { $$ = $1; }
1778     ;
1779
1780 XMLElement
1781     : "<" LexPushInOff XMLTagContent LexPop "/>" LexPopIn
1782     | "<" LexPushInOff XMLTagContent ">" LexSetXMLContent XMLElementContentOpt "</" LexSetXMLTag XMLTagName XMLWhitespaceOpt LexPop ">" LexPopIn
1783     ;
1784
1785 XMLTagContent
1786     : LexPushXMLTag XMLTagName XMLAttributes
1787     ;
1788
1789 XMLExpression
1790     : BRACE LexPushRegExp Expression LexPop "}"
1791     ;
1792
1793 XMLTagName
1794     : XMLExpression
1795     | XMLName
1796     ;
1797
1798 XMLAttributes_
1799     : XMLAttributes_ XMLAttribute
1800     |
1801     ;
1802
1803 XMLAttributes
1804     : XMLAttributes_ XMLWhitespace XMLExpression XMLWhitespaceOpt
1805     | XMLAttributes_ XMLWhitespaceOpt
1806     ;
1807
1808 XMLAttributeValue_
1809     : XMLExpression
1810     | XMLAttributeValue
1811     ;
1812
1813 XMLAttribute
1814     : XMLWhitespace XMLName XMLWhitespaceOpt "=" XMLWhitespaceOpt XMLAttributeValue_
1815     ;
1816
1817 XMLElementContent
1818     : XMLExpression XMLElementContentOpt
1819     | XMLMarkup XMLElementContentOpt
1820     | XMLText XMLElementContentOpt
1821     | XMLElement XMLElementContentOpt
1822     ;
1823
1824 XMLElementContentOpt
1825     : XMLElementContent
1826     |
1827     ;
1828 /* }}} */
1829 /* 11.1.5 XMLList Initialiser {{{ */
1830 XMLListInitialiser
1831     : "<>" LexPushInOff LexPushXMLContent XMLElementContent LexPop "</>" LexPopIn { $$ = CYNew CYXMLList($4); }
1832     ;
1833 /* }}} */
1834
1835 /* 11.2 Left-Hand-Side Expressions {{{ */
1836 PropertyIdentifier_
1837     : Identifier { $$ = $1; }
1838     | PropertyIdentifier { $$ = $1; }
1839     ;
1840
1841 MemberAccess
1842     : "." PropertyIdentifier { $$ = CYNew CYPropertyMember(NULL, $2); }
1843     | ".." PropertyIdentifier_ { $$ = CYNew CYDescendantMember(NULL, $2); }
1844     | "." "(" Expression ")" { $$ = CYNew CYFilteringPredicate(NULL, $3); }
1845     ;
1846 /* }}} */
1847 /* 12.1 The default xml namespace Statement {{{ */
1848 /* XXX: DefaultXMLNamespaceStatement
1849     : "default" "xml" "namespace" "=" Expression Terminator { $$ = CYNew CYDefaultXMLNamespace($5); }
1850     ;
1851
1852 Statement__
1853     : DefaultXMLNamespaceStatement { $$ = $1; }
1854     ; */
1855 /* }}} */
1856 @end
1857
1858 /* JavaScript 1.7: Array Comprehensions {{{ */
1859 IfComprehension
1860     : "if" "(" Expression ")" { $$ = CYNew CYIfComprehension($3); }
1861     ;
1862
1863 ForComprehension
1864     : "for" "(" Identifier "in" Expression ")" { $$ = CYNew CYForInComprehension($3, $5); }
1865     | "for" "each" "(" Identifier "in" Expression ")" { $$ = CYNew CYForOfComprehension($4, $6); }
1866     ;
1867
1868 ComprehensionList
1869     : ForComprehension ComprehensionListOpt { $1->SetNext($2); $$ = $1; }
1870     ;
1871
1872 ComprehensionListOpt
1873     : ComprehensionList { $$ = $1; }
1874     | IfComprehension { $$ = $1; }
1875     | { $$ = NULL; }
1876     ;
1877
1878 PrimaryExpression
1879     : "[" LexPushInOff AssignmentExpression ComprehensionList "]" LexPopIn { $$ = CYNew CYArrayComprehension($3, $4); }
1880     ;
1881 /* }}} */
1882 /* JavaScript 1.7: for each {{{ */
1883 IterationStatement
1884     : "for" "each" "(" LexPushInOn ForInStatementInitialiser "!in" LexPopIn Expression ")" Statement { $$ = CYNew CYForOf($5, $8, $10); }
1885     ;
1886 /* }}} */
1887 /* JavaScript 1.7: let Statements {{{ */
1888 LetStatement
1889     : "let" "(" VariableDeclarationList ")" Statement { $$ = CYNew CYLetStatement($3, $5); }
1890     ;
1891
1892 Statement__
1893     : LetStatement
1894     ;
1895 /* }}} */
1896
1897 /* JavaScript FTW: Ruby Blocks {{{ */
1898 RubyProcParameterList_
1899     : "," RubyProcParameterList { $$ = $2; }
1900     | { $$ = NULL; }
1901     ;
1902
1903 RubyProcParameterList
1904     : Identifier RubyProcParameterList_ { $$ = CYNew CYFunctionParameter(CYNew CYDeclaration($1), $2); }
1905     | { $$ = NULL; }
1906     ;
1907
1908 RubyProcParameters
1909     : "|" RubyProcParameterList "|" { $$ = $2; }
1910     | "||" { $$ = NULL; }
1911     ;
1912
1913 RubyProcParametersOpt
1914     : RubyProcParameters
1915     | { $$ = NULL; }
1916     ;
1917
1918 RubyProcExpression
1919     : "{" RubyProcParametersOpt StatementListOpt "}" { $$ = CYNew CYRubyProc($2, $3); }
1920     ;
1921
1922 PrimaryExpression
1923     : "{" LexPushInOff RubyProcParameters StatementListOpt "}" LexPopIn { $$ = CYNew CYRubyProc($3, $4); }
1924     ;
1925
1926 CallExpression
1927     : CallExpression_ RubyProcExpression { $$ = CYNew CYRubyBlock($1, $2); }
1928     ;
1929 /* }}} */
1930
1931 %%