Cycript.y.in

   1 /* Cycript - Remove Execution Server and Disassembler
   2  * Copyright (C) 2009  Jay Freeman (saurik)
   3 */
   4
   5 /* Modified BSD License {{{ */
   6 /*
   7  *        Redistribution and use in source and binary
   8  * forms, with or without modification, are permitted
   9  * provided that the following conditions are met:
  10  *
  11  * 1. Redistributions of source code must retain the
  12  *    above copyright notice, this list of conditions
  13  *    and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the
  15  *    above copyright notice, this list of conditions
  16  *    and the following disclaimer in the documentation
  17  *    and/or other materials provided with the
  18  *    distribution.
  19  * 3. The name of the author may not be used to endorse
  20  *    or promote products derived from this software
  21  *    without specific prior written permission.
  22  *
  23  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS''
  24  * AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING,
  25  * BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
  26  * MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  27  * ARE DISCLAIMED. IN NO EVENT SHALL THE AUTHOR BE
  28  * LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  29  * EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  30  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
  31  * SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  32  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
  33  * LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR
  34  * TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
  35  * ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
  36  * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  37 */
  38 /* }}} */
  39
  40 %code top {
  41 #include "Cycript.tab.hh"
  42 #define scanner driver.scanner_
  43 #define YYSTACKEXPANDABLE 1
  44 }
  45
  46 %code requires {
  47 #include "Parser.hpp"
  48
  49 @begin ObjC
  50 #include "ObjectiveC.hpp"
  51 @end
  52
  53 typedef struct {
  54     bool newline_;
  55
  56     union {
  57         bool bool_;
  58
  59         CYDriver::Condition condition_;
  60
  61         CYArgument *argument_;
  62         CYAssignment *assignment_;
  63         CYBoolean *boolean_;
  64         CYClause *clause_;
  65         CYCatch *catch_;
  66         CYClassName *className_;
  67         CYComprehension *comprehension_;
  68         CYCompound *compound_;
  69         CYDeclaration *declaration_;
  70         CYDeclarations *declarations_;
  71         CYElement *element_;
  72         CYExpression *expression_;
  73         CYFalse *false_;
  74         CYField *field_;
  75         CYFinally *finally_;
  76         CYForInitialiser *for_;
  77         CYForInInitialiser *forin_;
  78         CYFunctionParameter *functionParameter_;
  79         CYIdentifier *identifier_;
  80         CYInfix *infix_;
  81         CYLiteral *literal_;
  82         CYMember *member_;
  83         CYNull *null_;
  84         CYNumber *number_;
  85         CYProgram *program_;
  86         CYProperty *property_;
  87         CYPropertyName *propertyName_;
  88         CYStatement *statement_;
  89         CYString *string_;
  90         CYThis *this_;
  91         CYTrue *true_;
  92         CYWord *word_;
  93
  94 @begin ObjC
  95         CYMessage *message_;
  96         CYMessageParameter *messageParameter_;
  97         CYSelectorPart *selector_;
  98 @end
  99     };
 100 } YYSTYPE;
 101
 102 }
 103
 104 %code provides {
 105 int cylex(YYSTYPE *lvalp, cy::location *llocp, void *scanner);
 106 }
 107
 108 %name-prefix "cy"
 109
 110 %language "C++"
 111 %locations
 112
 113 %initial-action {
 114     @$.begin.filename = @$.end.filename = &driver.filename_;
 115 };
 116
 117 %defines
 118
 119 //%glr-parser
 120 //%expect 1
 121
 122 %error-verbose
 123
 124 %parse-param { CYDriver &driver }
 125 %lex-param { void *scanner }
 126
 127 %token At "@"
 128
 129 %token Ampersand "&"
 130 %token AmpersandAmpersand "&&"
 131 %token AmpersandEqual "&="
 132 %token Carrot "^"
 133 %token CarrotEqual "^="
 134 %token Equal "="
 135 %token EqualEqual "=="
 136 %token EqualEqualEqual "==="
 137 %token Exclamation "!"
 138 %token ExclamationEqual "!="
 139 %token ExclamationEqualEqual "!=="
 140 %token Hyphen "-"
 141 %token HyphenEqual "-="
 142 %token HyphenHyphen "--"
 143 %token HyphenHyphen_ "\n--"
 144 %token HyphenRight "->"
 145 %token Left "<"
 146 %token LeftEqual "<="
 147 %token LeftLeft "<<"
 148 %token LeftLeftEqual "<<="
 149 %token Percent "%"
 150 %token PercentEqual "%="
 151 %token Period "."
 152 %token Pipe "|"
 153 %token PipeEqual "|="
 154 %token PipePipe "||"
 155 %token Plus "+"
 156 %token PlusEqual "+="
 157 %token PlusPlus "++"
 158 %token PlusPlus_ "\n++"
 159 %token Right ">"
 160 %token RightEqual ">="
 161 %token RightRight ">>"
 162 %token RightRightEqual ">>="
 163 %token RightRightRight ">>>"
 164 %token RightRightRightEqual ">>>="
 165 %token Slash "/"
 166 %token SlashEqual "/="
 167 %token Star "*"
 168 %token StarEqual "*="
 169 %token Tilde "~"
 170
 171 %token Colon ":"
 172 %token Comma ","
 173 %token Question "?"
 174 %token SemiColon ";"
 175 %token NewLine "\n"
 176
 177 %token OpenParen "("
 178 %token CloseParen ")"
 179
 180 %token OpenBrace "{"
 181 %token CloseBrace "}"
 182
 183 %token OpenBracket "["
 184 %token CloseBracket "]"
 185
 186 %token AtClass "@class"
 187 %token AtSelector "@selector"
 188 %token AtEnd "@end"
 189
 190 %token <false_> False "false"
 191 %token <null_> Null "null"
 192 %token <true_> True "true"
 193
 194 // ES3/ES5/WIE/JSC Reserved
 195 %token <word_> Break "break"
 196 %token <word_> Case "case"
 197 %token <word_> Catch "catch"
 198 %token <word_> Continue "continue"
 199 %token <word_> Default "default"
 200 %token <word_> Delete "delete"
 201 %token <word_> Do "do"
 202 %token <word_> Else "else"
 203 %token <word_> Finally "finally"
 204 %token <word_> For "for"
 205 %token <word_> Function "function"
 206 %token <word_> If "if"
 207 %token <word_> In "in"
 208 %token <word_> InstanceOf "instanceof"
 209 %token <word_> New "new"
 210 %token <word_> Return "return"
 211 %token <word_> Switch "switch"
 212 %token <this_> This "this"
 213 %token <word_> Throw "throw"
 214 %token <word_> Try "try"
 215 %token <word_> TypeOf "typeof"
 216 %token <word_> Var "var"
 217 %token <word_> Void "void"
 218 %token <word_> While "while"
 219 %token <word_> With "with"
 220
 221 // ES3/IE6 Future, ES5/JSC Reserved
 222 %token <word_> Debugger "debugger"
 223
 224 // ES3/ES5/IE6 Future, JSC Reserved
 225 %token <word_> Const "const"
 226
 227 // ES3/ES5/IE6/JSC Future
 228 %token <word_> Class "class"
 229 %token <word_> Enum "enum"
 230 %token <word_> Export "export"
 231 %token <word_> Extends "extends"
 232 %token <word_> Import "import"
 233 %token <word_> Super "super"
 234
 235 // ES3 Future, ES5 Strict Future
 236 %token <identifier_> Implements "implements"
 237 %token <identifier_> Interface "interface"
 238 %token <identifier_> Package "package"
 239 %token <identifier_> Private "private"
 240 %token <identifier_> Protected "protected"
 241 %token <identifier_> Public "public"
 242 %token <identifier_> Static "static"
 243
 244 // ES3 Future
 245 %token <identifier_> Abstract "abstract"
 246 %token <identifier_> Boolean "boolean"
 247 %token <identifier_> Byte "byte"
 248 %token <identifier_> Char "char"
 249 %token <identifier_> Double "double"
 250 %token <identifier_> Final "final"
 251 %token <identifier_> Float "float"
 252 %token <identifier_> Goto "goto"
 253 %token <identifier_> Int "int"
 254 %token <identifier_> Long "long"
 255 %token <identifier_> Native "native"
 256 %token <identifier_> Short "short"
 257 %token <identifier_> Synchronized "synchronized"
 258 %token <identifier_> Throws "throws"
 259 %token <identifier_> Transient "transient"
 260 %token <identifier_> Volatile "volatile"
 261
 262 // ES5 Strict
 263 %token <identifier_> Let "let"
 264 %token <identifier_> Yield "yield"
 265
 266 // Woah?!
 267 %token <identifier_> Each "each"
 268
 269 %token <identifier_> Identifier_
 270 %token <number_> NumericLiteral
 271 %token <string_> StringLiteral
 272 %token <literal_> RegularExpressionLiteral
 273
 274 %type <expression_> AdditiveExpression
 275 %type <expression_> AdditiveExpressionNoBF
 276 %type <argument_> ArgumentList
 277 %type <argument_> ArgumentList_
 278 %type <argument_> ArgumentListOpt
 279 %type <argument_> Arguments
 280 %type <literal_> ArrayLiteral
 281 %type <expression_> AssigneeExpression
 282 %type <expression_> AssigneeExpression_
 283 %type <expression_> AssigneeExpressionNoBF
 284 %type <expression_> AssignmentExpression
 285 %type <assignment_> AssignmentExpression_
 286 %type <expression_> AssignmentExpressionNoBF
 287 %type <expression_> AssignmentExpressionNoIn
 288 %type <expression_> BitwiseANDExpression
 289 %type <expression_> BitwiseANDExpressionNoBF
 290 %type <expression_> BitwiseANDExpressionNoIn
 291 %type <statement_> Block
 292 %type <statement_> Block_
 293 %type <boolean_> BooleanLiteral
 294 %type <expression_> BitwiseORExpression
 295 %type <expression_> BitwiseORExpressionNoBF
 296 %type <expression_> BitwiseORExpressionNoIn
 297 %type <expression_> BitwiseXORExpression
 298 %type <expression_> BitwiseXORExpressionNoBF
 299 %type <expression_> BitwiseXORExpressionNoIn
 300 %type <statement_> BreakStatement
 301 %type <expression_> CallExpression
 302 %type <expression_> CallExpressionNoBF
 303 %type <clause_> CaseBlock
 304 %type <clause_> CaseClause
 305 %type <clause_> CaseClausesOpt
 306 %type <catch_> CatchOpt
 307 %type <statement_> CategoryStatement
 308 %type <expression_> ClassExpression
 309 %type <message_> ClassMessageDeclaration
 310 %type <message_> ClassMessageDeclarationListOpt
 311 %type <className_> ClassName
 312 %type <className_> ClassNameOpt
 313 %type <statement_> ClassStatement
 314 %type <expression_> ClassSuperOpt
 315 %type <field_> ClassFieldList
 316 %type <comprehension_> ComprehensionList
 317 %type <comprehension_> ComprehensionListOpt
 318 %type <expression_> ConditionalExpression
 319 %type <expression_> ConditionalExpressionNoBF
 320 %type <expression_> ConditionalExpressionNoIn
 321 %type <statement_> ContinueStatement
 322 %type <clause_> DefaultClause
 323 %type <statement_> DoWhileStatement
 324 %type <expression_> Element
 325 %type <expression_> ElementOpt
 326 %type <element_> ElementList
 327 %type <element_> ElementListOpt
 328 %type <statement_> ElseStatementOpt
 329 %type <statement_> EmptyStatement
 330 %type <expression_> EqualityExpression
 331 %type <expression_> EqualityExpressionNoBF
 332 %type <expression_> EqualityExpressionNoIn
 333 %type <expression_> Expression
 334 %type <expression_> ExpressionOpt
 335 %type <compound_> Expression_
 336 %type <expression_> ExpressionNoBF
 337 %type <expression_> ExpressionNoIn
 338 %type <compound_> ExpressionNoIn_
 339 %type <expression_> ExpressionNoInOpt
 340 %type <statement_> ExpressionStatement
 341 %type <finally_> FinallyOpt
 342 %type <comprehension_> ForComprehension
 343 %type <statement_> ForStatement
 344 %type <for_> ForStatementInitialiser
 345 %type <statement_> ForInStatement
 346 %type <forin_> ForInStatementInitialiser
 347 %type <functionParameter_> FormalParameterList
 348 %type <functionParameter_> FormalParameterList_
 349 %type <statement_> FunctionBody
 350 %type <statement_> FunctionDeclaration
 351 %type <expression_> FunctionExpression
 352 %type <identifier_> Identifier
 353 %type <identifier_> IdentifierOpt
 354 %type <comprehension_> IfComprehension
 355 %type <statement_> IfStatement
 356 %type <expression_> Initialiser
 357 %type <expression_> InitialiserOpt
 358 %type <expression_> InitialiserNoIn
 359 %type <expression_> InitialiserNoInOpt
 360 %type <statement_> IterationStatement
 361 %type <statement_> LabelledStatement
 362 %type <expression_> LeftHandSideExpression
 363 %type <expression_> LeftHandSideExpressionNoBF
 364 //%type <statement_> LetStatement
 365 %type <literal_> Literal
 366 %type <expression_> LogicalANDExpression
 367 %type <expression_> LogicalANDExpressionNoBF
 368 %type <expression_> LogicalANDExpressionNoIn
 369 %type <expression_> LogicalORExpression
 370 %type <expression_> LogicalORExpressionNoBF
 371 %type <expression_> LogicalORExpressionNoIn
 372 %type <member_> MemberAccess
 373 %type <expression_> MemberExpression
 374 %type <expression_> MemberExpression_
 375 %type <expression_> MemberExpressionNoBF
 376 %type <messageParameter_> MessageParameter
 377 %type <messageParameter_> MessageParameters
 378 %type <messageParameter_> MessageParameterList
 379 %type <messageParameter_> MessageParameterListOpt
 380 %type <bool_> MessageScope
 381 %type <expression_> MultiplicativeExpression
 382 %type <expression_> MultiplicativeExpressionNoBF
 383 %type <expression_> NewExpression
 384 %type <expression_> NewExpression_
 385 %type <expression_> NewExpressionNoBF
 386 %type <null_> NullLiteral
 387 %type <literal_> ObjectLiteral
 388 %type <expression_> PostfixExpression
 389 %type <expression_> PostfixExpressionNoBF
 390 %type <expression_> PrimaryExpression
 391 %type <expression_> PrimaryExpression_
 392 %type <expression_> PrimaryExpressionNoBF
 393 %type <statement_> Program
 394 %type <propertyName_> PropertyName
 395 %type <property_> PropertyNameAndValueList
 396 %type <property_> PropertyNameAndValueList_
 397 %type <property_> PropertyNameAndValueListOpt
 398 %type <literal_> RegularExpressionLiteral_
 399 %type <condition_> RegularExpressionToken
 400 %type <expression_> RelationalExpression
 401 %type <infix_> RelationalExpression_
 402 %type <expression_> RelationalExpressionNoBF
 403 %type <expression_> RelationalExpressionNoIn
 404 %type <infix_> RelationalExpressionNoIn_
 405 %type <statement_> ReturnStatement
 406 %type <selector_> SelectorExpression
 407 %type <selector_> SelectorExpression_
 408 %type <selector_> SelectorExpressionOpt
 409 %type <expression_> ShiftExpression
 410 %type <expression_> ShiftExpressionNoBF
 411 %type <statement_> SourceElement
 412 %type <statement_> SourceElements
 413 %type <statement_> Statement
 414 %type <statement_> Statement_
 415 %type <statement_> StatementList
 416 %type <statement_> StatementListOpt
 417 %type <statement_> SwitchStatement
 418 %type <statement_> ThrowStatement
 419 %type <statement_> TryStatement
 420 %type <expression_> TypeOpt
 421 %type <expression_> UnaryExpression
 422 %type <expression_> UnaryExpression_
 423 %type <expression_> UnaryExpressionNoBF
 424 %type <declaration_> VariableDeclaration
 425 %type <declaration_> VariableDeclarationNoIn
 426 %type <declarations_> VariableDeclarationList
 427 %type <declarations_> VariableDeclarationList_
 428 %type <declarations_> VariableDeclarationListNoIn
 429 %type <declarations_> VariableDeclarationListNoIn_
 430 %type <statement_> VariableStatement
 431 %type <statement_> WhileStatement
 432 %type <statement_> WithStatement
 433 %type <word_> Word
 434 %type <word_> WordOpt
 435
 436 %type <expression_> MessageExpression
 437 %type <argument_> SelectorCall
 438 %type <argument_> SelectorCall_
 439 %type <argument_> SelectorList
 440 %type <argument_> VariadicCall
 441
 442 %left "*" "/" "%"
 443 %left "+" "-"
 444 %left "<<" ">>" ">>>"
 445 %left "<" ">" "<=" ">=" "instanceof" "in"
 446 %left "==" "!=" "===" "!=="
 447 %left "&"
 448 %left "^"
 449 %left "|"
 450 %left "&&"
 451 %left "||"
 452
 453 %right "=" "*=" "/=" "%=" "+=" "-=" "<<=" ">>=" ">>>=" "&=" "^=" "|="
 454
 455 %nonassoc "if"
 456 %nonassoc "else"
 457
 458 %start Program
 459
 460 %%
 461
 462 StrictSemi
 463     : { driver.Warning(yylloc, "warning, automatic semi-colon insertion required"); }
 464     ;
 465
 466 Terminator_
 467     : ";"
 468     | "\n" StrictSemi
 469     ;
 470
 471 TerminatorOpt
 472     : Terminator_
 473     | error { yyerrok; driver.errors_.pop_back(); } StrictSemi
 474     ;
 475
 476 Terminator
 477     : Terminator_
 478     | error { if (yychar != 0 && yychar != cy::parser::token::CloseBrace && !yylval.newline_) YYABORT; else { yyerrok; driver.errors_.pop_back(); } } StrictSemi
 479     ;
 480
 481 /*CommaOpt
 482     : ","
 483     |
 484     ;*/
 485
 486 NewLineOpt
 487     : "\n"
 488     |
 489     ;
 490
 491 WordOpt
 492     : Word { $$ = $1; }
 493     | { $$ = NULL; }
 494     ;
 495
 496 Word
 497     : Identifier { $$ = $1; }
 498     | "break" NewLineOpt { $$ = $1; }
 499     | "case" { $$ = $1; }
 500     | "catch" { $$ = $1; }
 501     | "class" { $$ = $1; }
 502     | "const" { $$ = $1; }
 503     | "continue" NewLineOpt { $$ = $1; }
 504     | "debugger" { $$ = $1; }
 505     | "default" { $$ = $1; }
 506     | "delete" { $$ = $1; }
 507     | "do" { $$ = $1; }
 508     | "else" { $$ = $1; }
 509     | "enum" { $$ = $1; }
 510     | "export" { $$ = $1; }
 511     | "extends" { $$ = $1; }
 512     | "false" { $$ = $1; }
 513     | "finally" { $$ = $1; }
 514     | "for" { $$ = $1; }
 515     | "function" { $$ = $1; }
 516     | "if" { $$ = $1; }
 517     | "import" { $$ = $1; }
 518     /* XXX: | "in" { $$ = $1; } */
 519     /* XXX: | "instanceof" { $$ = $1; } */
 520     | "new" { $$ = $1; }
 521     | "null" { $$ = $1; }
 522     | "return" NewLineOpt { $$ = $1; }
 523     | "super" { $$ = $1; }
 524     | "switch" { $$ = $1; }
 525     | "this" { $$ = $1; }
 526     | "throw" NewLineOpt { $$ = $1; }
 527     | "true" { $$ = $1; }
 528     | "try" { $$ = $1; }
 529     | "typeof" { $$ = $1; }
 530     | "var" { $$ = $1; }
 531     | "void" { $$ = $1; }
 532     | "while" { $$ = $1; }
 533     | "with" { $$ = $1; }
 534     ;
 535
 536 Identifier
 537     : Identifier_ { $$ = $1; }
 538
 539     | "implements" { $$ = $1; }
 540     | "interface" { $$ = $1; }
 541     | "package" { $$ = $1; }
 542     | "private" { $$ = $1; }
 543     | "protected" { $$ = $1; }
 544     | "public" { $$ = $1; }
 545     | "static" { $$ = $1; }
 546
 547     | "abstract" { $$ = $1; }
 548     | "boolean" { $$ = $1; }
 549     | "byte" { $$ = $1; }
 550     | "char" { $$ = $1; }
 551     | "double" { $$ = $1; }
 552     | "final" { $$ = $1; }
 553     | "float" { $$ = $1; }
 554     | "goto" { $$ = $1; }
 555     | "int" { $$ = $1; }
 556     | "long" { $$ = $1; }
 557     | "native" { $$ = $1; }
 558     | "short" { $$ = $1; }
 559     | "synchronized" { $$ = $1; }
 560     | "throws" { $$ = $1; }
 561     | "transient" { $$ = $1; }
 562     | "volatile" { $$ = $1; }
 563
 564     | "let" { $$ = $1; }
 565     | "yield" { $$ = $1; }
 566
 567     | "each" { $$ = $1; }
 568     ;
 569
 570 IdentifierOpt
 571     : Identifier { $$ = $1; }
 572     | { $$ = NULL; }
 573     ;
 574
 575 RegularExpressionToken
 576     : "/" { $$ = CYDriver::RegExStart; }
 577     | "/=" { $$ = CYDriver::RegExRest; }
 578     ;
 579
 580 RegularExpressionLiteral_
 581     : RegularExpressionToken { driver.SetCondition($1); } RegularExpressionLiteral { $$ = $3; }
 582     ;
 583
 584 Literal
 585     : NullLiteral { $$ = $1; }
 586     | BooleanLiteral { $$ = $1; }
 587     | NumericLiteral { $$ = $1; }
 588     | StringLiteral { $$ = $1; }
 589     | RegularExpressionLiteral_ { $$ = $1; }
 590     ;
 591
 592 NullLiteral
 593     : "null" { $$ = $1; }
 594     ;
 595
 596 BooleanLiteral
 597     : "true" { $$ = $1; }
 598     | "false" { $$ = $1; }
 599     ;
 600
 601 /* 11.1 Primary Expressions {{{ */
 602 PrimaryExpression_
 603     : "this" { $$ = $1; }
 604     | Identifier { $$ = new(driver.pool_) CYVariable($1); }
 605     | Literal { $$ = $1; }
 606     | ArrayLiteral { $$ = $1; }
 607     | "(" Expression ")" { $$ = $2; }
 608     ;
 609
 610 PrimaryExpression
 611     : ObjectLiteral { $$ = $1; }
 612     | PrimaryExpression_ { $$ = $1; }
 613     ;
 614
 615 PrimaryExpressionNoBF
 616     : PrimaryExpression_ { $$ = $1; }
 617     ;
 618 /* }}} */
 619 /* 11.1.4 Array Initialiser {{{ */
 620 ArrayLiteral
 621     : "[" ElementListOpt "]" { $$ = new(driver.pool_) CYArray($2); }
 622     ;
 623
 624 Element
 625     : AssignmentExpression { $$ = $1; }
 626     ;
 627
 628 ElementOpt
 629     : Element { $$ = $1; }
 630     | { $$ = NULL; }
 631     ;
 632
 633 ElementListOpt
 634     : ElementList { $$ = $1; }
 635     | { $$ = NULL; }
 636     ;
 637
 638 ElementList
 639     : ElementOpt "," ElementListOpt { $$ = new(driver.pool_) CYElement($1, $3); }
 640     | Element { $$ = new(driver.pool_) CYElement($1, NULL); }
 641     ;
 642 /* }}} */
 643 /* 11.1.5 Object Initialiser {{{ */
 644 ObjectLiteral
 645     : "{" PropertyNameAndValueListOpt "}" { $$ = new(driver.pool_) CYObject($2); }
 646     ;
 647
 648 PropertyNameAndValueList_
 649     : "," PropertyNameAndValueList { $$ = $2; }
 650     | { $$ = NULL; }
 651     ;
 652
 653 PropertyNameAndValueListOpt
 654     : PropertyNameAndValueList { $$ = $1; }
 655     | { $$ = NULL; }
 656     ;
 657
 658 PropertyNameAndValueList
 659     : PropertyName ":" AssignmentExpression PropertyNameAndValueList_ { $$ = new(driver.pool_) CYProperty($1, $3, $4); }
 660     ;
 661
 662 PropertyName
 663     : Identifier { $$ = $1; }
 664     | StringLiteral { $$ = $1; }
 665     | NumericLiteral { $$ = $1; }
 666     ;
 667 /* }}} */
 668
 669 /* 11.2 Left-Hand-Side Expressions {{{ */
 670 MemberExpression_
 671     : "new" MemberExpression Arguments { $$ = new(driver.pool_) CYNew($2, $3); }
 672     ;
 673
 674 MemberAccess
 675     : "[" Expression "]" { $$ = new(driver.pool_) CYDirectMember(NULL, $2); }
 676     | "." Identifier { $$ = new(driver.pool_) CYDirectMember(NULL, new(driver.pool_) CYString($2)); }
 677     ;
 678
 679 MemberExpression
 680     : PrimaryExpression { $$ = $1; }
 681     | FunctionExpression { $$ = $1; }
 682     | MemberExpression MemberAccess { $2->SetLeft($1); $$ = $2; }
 683     | MemberExpression_ { $$ = $1; }
 684     ;
 685
 686 MemberExpressionNoBF
 687     : PrimaryExpressionNoBF { $$ = $1; }
 688     | MemberExpressionNoBF MemberAccess { $2->SetLeft($1); $$ = $2; }
 689     | MemberExpression_ { $$ = $1; }
 690     ;
 691
 692 NewExpression_
 693     : "new" NewExpression { $$ = new(driver.pool_) CYNew($2, NULL); }
 694     ;
 695
 696 NewExpression
 697     : MemberExpression { $$ = $1; }
 698     | NewExpression_ { $$ = $1; }
 699     ;
 700
 701 NewExpressionNoBF
 702     : MemberExpressionNoBF { $$ = $1; }
 703     | NewExpression_ { $$ = $1; }
 704     ;
 705
 706 CallExpression
 707     : MemberExpression Arguments { $$ = new(driver.pool_) CYCall($1, $2); }
 708     | CallExpression Arguments { $$ = new(driver.pool_) CYCall($1, $2); }
 709     | CallExpression MemberAccess { $2->SetLeft($1); $$ = $2; }
 710     ;
 711
 712 CallExpressionNoBF
 713     : MemberExpressionNoBF Arguments { $$ = new(driver.pool_) CYCall($1, $2); }
 714     | CallExpressionNoBF Arguments { $$ = new(driver.pool_) CYCall($1, $2); }
 715     | CallExpressionNoBF MemberAccess { $2->SetLeft($1); $$ = $2; }
 716     ;
 717
 718 ArgumentList_
 719     : "," ArgumentList { $$ = $2; }
 720     | { $$ = NULL; }
 721     ;
 722
 723 ArgumentListOpt
 724     : ArgumentList { $$ = $1; }
 725     | { $$ = NULL; }
 726     ;
 727
 728 ArgumentList
 729     : AssignmentExpression ArgumentList_ { $$ = new(driver.pool_) CYArgument(NULL, $1, $2); }
 730     ;
 731
 732 Arguments
 733     : "(" ArgumentListOpt ")" { $$ = $2; }
 734     ;
 735
 736 LeftHandSideExpression
 737     : NewExpression { $$ = $1; }
 738     | CallExpression { $$ = $1; }
 739     ;
 740
 741 LeftHandSideExpressionNoBF
 742     : NewExpressionNoBF { $$ = $1; }
 743     | CallExpressionNoBF { $$ = $1; }
 744     ;
 745 /* }}} */
 746 /* 11.3 Postfix Expressions {{{ */
 747 PostfixExpression
 748     : AssigneeExpression { $$ = $1; }
 749     | LeftHandSideExpression "++" { $$ = new(driver.pool_) CYPostIncrement($1); }
 750     | LeftHandSideExpression "--" { $$ = new(driver.pool_) CYPostDecrement($1); }
 751     ;
 752
 753 PostfixExpressionNoBF
 754     : AssigneeExpressionNoBF { $$ = $1; }
 755     | LeftHandSideExpressionNoBF "++" { $$ = new(driver.pool_) CYPostIncrement($1); }
 756     | LeftHandSideExpressionNoBF "--" { $$ = new(driver.pool_) CYPostDecrement($1); }
 757     ;
 758 /* }}} */
 759 /* 11.4 Unary Operators {{{ */
 760 UnaryExpression_
 761     : "delete" UnaryExpression { $$ = new(driver.pool_) CYDelete($2); }
 762     | "void" UnaryExpression { $$ = new(driver.pool_) CYVoid($2); }
 763     | "typeof" UnaryExpression { $$ = new(driver.pool_) CYTypeOf($2); }
 764     | "++" UnaryExpression { $$ = new(driver.pool_) CYPreIncrement($2); }
 765     | "\n++" UnaryExpression { $$ = new(driver.pool_) CYPreIncrement($2); }
 766     | "--" UnaryExpression { $$ = new(driver.pool_) CYPreDecrement($2); }
 767     | "\n--" UnaryExpression { $$ = new(driver.pool_) CYPreDecrement($2); }
 768     | "+" UnaryExpression { $$ = new(driver.pool_) CYAffirm($2); }
 769     | "-" UnaryExpression { $$ = new(driver.pool_) CYNegate($2); }
 770     | "~" UnaryExpression { $$ = new(driver.pool_) CYBitwiseNot($2); }
 771     | "!" UnaryExpression { $$ = new(driver.pool_) CYLogicalNot($2); }
 772     ;
 773
 774 UnaryExpression
 775     : PostfixExpression { $$ = $1; }
 776     | UnaryExpression_ { $$ = $1; }
 777     ;
 778
 779 UnaryExpressionNoBF
 780     : PostfixExpressionNoBF { $$ = $1; }
 781     | UnaryExpression_ { $$ = $1; }
 782     ;
 783 /* }}} */
 784 /* 11.5 Multiplicative Operators {{{ */
 785 MultiplicativeExpression
 786     : UnaryExpression { $$ = $1; }
 787     | MultiplicativeExpression "*" UnaryExpression { $$ = new(driver.pool_) CYMultiply($1, $3); }
 788     | MultiplicativeExpression "/" UnaryExpression { $$ = new(driver.pool_) CYDivide($1, $3); }
 789     | MultiplicativeExpression "%" UnaryExpression { $$ = new(driver.pool_) CYModulus($1, $3); }
 790     ;
 791
 792 MultiplicativeExpressionNoBF
 793     : UnaryExpressionNoBF { $$ = $1; }
 794     | MultiplicativeExpressionNoBF "*" UnaryExpression { $$ = new(driver.pool_) CYMultiply($1, $3); }
 795     | MultiplicativeExpressionNoBF "/" UnaryExpression { $$ = new(driver.pool_) CYDivide($1, $3); }
 796     | MultiplicativeExpressionNoBF "%" UnaryExpression { $$ = new(driver.pool_) CYModulus($1, $3); }
 797     ;
 798 /* }}} */
 799 /* 11.6 Additive Operators {{{ */
 800 AdditiveExpression
 801     : MultiplicativeExpression { $$ = $1; }
 802     | AdditiveExpression "+" MultiplicativeExpression { $$ = new(driver.pool_) CYAdd($1, $3); }
 803     | AdditiveExpression "-" MultiplicativeExpression { $$ = new(driver.pool_) CYSubtract($1, $3); }
 804     ;
 805
 806 AdditiveExpressionNoBF
 807     : MultiplicativeExpressionNoBF { $$ = $1; }
 808     | AdditiveExpressionNoBF "+" MultiplicativeExpression { $$ = new(driver.pool_) CYAdd($1, $3); }
 809     | AdditiveExpressionNoBF "-" MultiplicativeExpression { $$ = new(driver.pool_) CYSubtract($1, $3); }
 810     ;
 811 /* }}} */
 812 /* 11.7 Bitwise Shift Operators {{{ */
 813 ShiftExpression
 814     : AdditiveExpression { $$ = $1; }
 815     | ShiftExpression "<<" AdditiveExpression { $$ = new(driver.pool_) CYShiftLeft($1, $3); }
 816     | ShiftExpression ">>" AdditiveExpression { $$ = new(driver.pool_) CYShiftRightSigned($1, $3); }
 817     | ShiftExpression ">>>" AdditiveExpression { $$ = new(driver.pool_) CYShiftRightUnsigned($1, $3); }
 818     ;
 819
 820 ShiftExpressionNoBF
 821     : AdditiveExpressionNoBF { $$ = $1; }
 822     | ShiftExpressionNoBF "<<" AdditiveExpression { $$ = new(driver.pool_) CYShiftLeft($1, $3); }
 823     | ShiftExpressionNoBF ">>" AdditiveExpression { $$ = new(driver.pool_) CYShiftRightSigned($1, $3); }
 824     | ShiftExpressionNoBF ">>>" AdditiveExpression { $$ = new(driver.pool_) CYShiftRightUnsigned($1, $3); }
 825     ;
 826 /* }}} */
 827 /* 11.8 Relational Operators {{{ */
 828 RelationalExpressionNoIn_
 829     : "<" ShiftExpression { $$ = new(driver.pool_) CYLess(NULL, $2); }
 830     | ">" ShiftExpression { $$ = new(driver.pool_) CYGreater(NULL, $2); }
 831     | "<=" ShiftExpression { $$ = new(driver.pool_) CYLessOrEqual(NULL, $2); }
 832     | ">=" ShiftExpression { $$ = new(driver.pool_) CYGreaterOrEqual(NULL, $2); }
 833     | "instanceof" ShiftExpression { $$ = new(driver.pool_) CYInstanceOf(NULL, $2); }
 834     ;
 835
 836 RelationalExpression_
 837     : RelationalExpressionNoIn_ { $$ = $1; }
 838     | "in" ShiftExpression { $$ = new(driver.pool_) CYIn(NULL, $2); }
 839     ;
 840
 841 RelationalExpression
 842     : ShiftExpression { $$ = $1; }
 843     | RelationalExpression RelationalExpression_ { $2->SetLeft($1); $$ = $2; }
 844     ;
 845
 846 RelationalExpressionNoIn
 847     : ShiftExpression { $$ = $1; }
 848     | RelationalExpressionNoIn RelationalExpressionNoIn_ { $2->SetLeft($1); $$ = $2; }
 849     ;
 850
 851 RelationalExpressionNoBF
 852     : ShiftExpressionNoBF { $$ = $1; }
 853     | RelationalExpressionNoBF RelationalExpression_ { $2->SetLeft($1); $$ = $2; }
 854     ;
 855 /* }}} */
 856 /* 11.9 Equality Operators {{{ */
 857 EqualityExpression
 858     : RelationalExpression { $$ = $1; }
 859     | EqualityExpression "==" RelationalExpression { $$ = new(driver.pool_) CYEqual($1, $3); }
 860     | EqualityExpression "!=" RelationalExpression { $$ = new(driver.pool_) CYNotEqual($1, $3); }
 861     | EqualityExpression "===" RelationalExpression { $$ = new(driver.pool_) CYIdentical($1, $3); }
 862     | EqualityExpression "!==" RelationalExpression { $$ = new(driver.pool_) CYNotIdentical($1, $3); }
 863     ;
 864
 865 EqualityExpressionNoIn
 866     : RelationalExpressionNoIn { $$ = $1; }
 867     | EqualityExpressionNoIn "==" RelationalExpressionNoIn { $$ = new(driver.pool_) CYEqual($1, $3); }
 868     | EqualityExpressionNoIn "!=" RelationalExpressionNoIn { $$ = new(driver.pool_) CYNotEqual($1, $3); }
 869     | EqualityExpressionNoIn "===" RelationalExpressionNoIn { $$ = new(driver.pool_) CYIdentical($1, $3); }
 870     | EqualityExpressionNoIn "!==" RelationalExpressionNoIn { $$ = new(driver.pool_) CYNotIdentical($1, $3); }
 871     ;
 872
 873 EqualityExpressionNoBF
 874     : RelationalExpressionNoBF { $$ = $1; }
 875     | EqualityExpressionNoBF "==" RelationalExpression { $$ = new(driver.pool_) CYEqual($1, $3); }
 876     | EqualityExpressionNoBF "!=" RelationalExpression { $$ = new(driver.pool_) CYNotEqual($1, $3); }
 877     | EqualityExpressionNoBF "===" RelationalExpression { $$ = new(driver.pool_) CYIdentical($1, $3); }
 878     | EqualityExpressionNoBF "!==" RelationalExpression { $$ = new(driver.pool_) CYNotIdentical($1, $3); }
 879     ;
 880 /* }}} */
 881 /* 11.10 Binary Bitwise Operators {{{ */
 882 BitwiseANDExpression
 883     : EqualityExpression { $$ = $1; }
 884     | BitwiseANDExpression "&" EqualityExpression { $$ = new(driver.pool_) CYBitwiseAnd($1, $3); }
 885     ;
 886
 887 BitwiseANDExpressionNoIn
 888     : EqualityExpressionNoIn { $$ = $1; }
 889     | BitwiseANDExpressionNoIn "&" EqualityExpressionNoIn { $$ = new(driver.pool_) CYBitwiseAnd($1, $3); }
 890     ;
 891
 892 BitwiseANDExpressionNoBF
 893     : EqualityExpressionNoBF { $$ = $1; }
 894     | BitwiseANDExpressionNoBF "&" EqualityExpression { $$ = new(driver.pool_) CYBitwiseAnd($1, $3); }
 895     ;
 896
 897 BitwiseXORExpression
 898     : BitwiseANDExpression { $$ = $1; }
 899     | BitwiseXORExpression "^" BitwiseANDExpression { $$ = new(driver.pool_) CYBitwiseXOr($1, $3); }
 900     ;
 901
 902 BitwiseXORExpressionNoIn
 903     : BitwiseANDExpressionNoIn { $$ = $1; }
 904     | BitwiseXORExpressionNoIn "^" BitwiseANDExpressionNoIn { $$ = new(driver.pool_) CYBitwiseXOr($1, $3); }
 905     ;
 906
 907 BitwiseXORExpressionNoBF
 908     : BitwiseANDExpressionNoBF { $$ = $1; }
 909     | BitwiseXORExpressionNoBF "^" BitwiseANDExpression { $$ = new(driver.pool_) CYBitwiseXOr($1, $3); }
 910     ;
 911
 912 BitwiseORExpression
 913     : BitwiseXORExpression { $$ = $1; }
 914     | BitwiseORExpression "|" BitwiseXORExpression { $$ = new(driver.pool_) CYBitwiseOr($1, $3); }
 915     ;
 916
 917 BitwiseORExpressionNoIn
 918     : BitwiseXORExpressionNoIn { $$ = $1; }
 919     | BitwiseORExpressionNoIn "|" BitwiseXORExpressionNoIn { $$ = new(driver.pool_) CYBitwiseOr($1, $3); }
 920     ;
 921
 922 BitwiseORExpressionNoBF
 923     : BitwiseXORExpressionNoBF { $$ = $1; }
 924     | BitwiseORExpressionNoBF "|" BitwiseXORExpression { $$ = new(driver.pool_) CYBitwiseOr($1, $3); }
 925     ;
 926 /* }}} */
 927 /* 11.11 Binary Logical Operators {{{ */
 928 LogicalANDExpression
 929     : BitwiseORExpression { $$ = $1; }
 930     | LogicalANDExpression "&&" BitwiseORExpression { $$ = new(driver.pool_) CYLogicalAnd($1, $3); }
 931     ;
 932
 933 LogicalANDExpressionNoIn
 934     : BitwiseORExpressionNoIn { $$ = $1; }
 935     | LogicalANDExpressionNoIn "&&" BitwiseORExpressionNoIn { $$ = new(driver.pool_) CYLogicalAnd($1, $3); }
 936     ;
 937
 938 LogicalANDExpressionNoBF
 939     : BitwiseORExpressionNoBF { $$ = $1; }
 940     | LogicalANDExpressionNoBF "&&" BitwiseORExpression { $$ = new(driver.pool_) CYLogicalAnd($1, $3); }
 941     ;
 942
 943 LogicalORExpression
 944     : LogicalANDExpression { $$ = $1; }
 945     | LogicalORExpression "||" LogicalANDExpression { $$ = new(driver.pool_) CYLogicalOr($1, $3); }
 946     ;
 947
 948 LogicalORExpressionNoIn
 949     : LogicalANDExpressionNoIn { $$ = $1; }
 950     | LogicalORExpressionNoIn "||" LogicalANDExpressionNoIn { $$ = new(driver.pool_) CYLogicalOr($1, $3); }
 951     ;
 952
 953 LogicalORExpressionNoBF
 954     : LogicalANDExpressionNoBF { $$ = $1; }
 955     | LogicalORExpressionNoBF "||" LogicalANDExpression { $$ = new(driver.pool_) CYLogicalOr($1, $3); }
 956     ;
 957 /* }}} */
 958 /* 11.12 Conditional Operator ( ? : ) {{{ */
 959 ConditionalExpression
 960     : LogicalORExpression { $$ = $1; }
 961     | LogicalORExpression "?" AssignmentExpression ":" AssignmentExpression { $$ = new(driver.pool_) CYCondition($1, $3, $5); }
 962     ;
 963
 964 ConditionalExpressionNoIn
 965     : LogicalORExpressionNoIn { $$ = $1; }
 966     | LogicalORExpressionNoIn "?" AssignmentExpression ":" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYCondition($1, $3, $5); }
 967     ;
 968
 969 ConditionalExpressionNoBF
 970     : LogicalORExpressionNoBF { $$ = $1; }
 971     | LogicalORExpressionNoBF "?" AssignmentExpression ":" AssignmentExpression { $$ = new(driver.pool_) CYCondition($1, $3, $5); }
 972     ;
 973 /* }}} */
 974 /* 11.13 Assignment Operators {{{ */
 975 AssignmentExpression_
 976     : "=" AssignmentExpression { $$ = new(driver.pool_) CYAssign(NULL, $2); }
 977     | "*=" AssignmentExpression { $$ = new(driver.pool_) CYMultiplyAssign(NULL, $2); }
 978     | "/=" AssignmentExpression { $$ = new(driver.pool_) CYDivideAssign(NULL, $2); }
 979     | "%=" AssignmentExpression { $$ = new(driver.pool_) CYModulusAssign(NULL, $2); }
 980     | "+=" AssignmentExpression { $$ = new(driver.pool_) CYAddAssign(NULL, $2); }
 981     | "-=" AssignmentExpression { $$ = new(driver.pool_) CYSubtractAssign(NULL, $2); }
 982     | "<<=" AssignmentExpression { $$ = new(driver.pool_) CYShiftLeftAssign(NULL, $2); }
 983     | ">>=" AssignmentExpression { $$ = new(driver.pool_) CYShiftRightSignedAssign(NULL, $2); }
 984     | ">>>=" AssignmentExpression { $$ = new(driver.pool_) CYShiftRightUnsignedAssign(NULL, $2); }
 985     | "&=" AssignmentExpression { $$ = new(driver.pool_) CYBitwiseAndAssign(NULL, $2); }
 986     | "^=" AssignmentExpression { $$ = new(driver.pool_) CYBitwiseXOrAssign(NULL, $2); }
 987     | "|=" AssignmentExpression { $$ = new(driver.pool_) CYBitwiseOrAssign(NULL, $2); }
 988     ;
 989
 990 AssigneeExpression
 991     : LeftHandSideExpression { $$ = $1; }
 992     | AssigneeExpression_ { $$ = $1; }
 993     ;
 994
 995 AssigneeExpressionNoBF
 996     : LeftHandSideExpressionNoBF { $$ = $1; }
 997     | AssigneeExpression_ { $$ = $1; }
 998     ;
 999
1000 AssignmentExpression
1001     : ConditionalExpression { $$ = $1; }
1002     | AssigneeExpression AssignmentExpression_ { $2->SetLeft($1); $$ = $2; }
1003     ;
1004
1005 AssignmentExpressionNoIn
1006     : ConditionalExpressionNoIn { $$ = $1; }
1007     | AssigneeExpression "=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYAssign($1, $3); }
1008     | AssigneeExpression "*=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYMultiplyAssign($1, $3); }
1009     | AssigneeExpression "/=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYDivideAssign($1, $3); }
1010     | AssigneeExpression "%=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYModulusAssign($1, $3); }
1011     | AssigneeExpression "+=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYAddAssign($1, $3); }
1012     | AssigneeExpression "-=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYSubtractAssign($1, $3); }
1013     | AssigneeExpression "<<=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYShiftLeftAssign($1, $3); }
1014     | AssigneeExpression ">>=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYShiftRightSignedAssign($1, $3); }
1015     | AssigneeExpression ">>>=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYShiftRightUnsignedAssign($1, $3); }
1016     | AssigneeExpression "&=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYBitwiseAndAssign($1, $3); }
1017     | AssigneeExpression "^=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYBitwiseXOrAssign($1, $3); }
1018     | AssigneeExpression "|=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYBitwiseOrAssign($1, $3); }
1019     ;
1020
1021 AssignmentExpressionNoBF
1022     : ConditionalExpressionNoBF { $$ = $1; }
1023     | AssigneeExpressionNoBF AssignmentExpression_ { $2->SetLeft($1); $$ = $2; }
1024     ;
1025 /* }}} */
1026 /* 11.14 Comma Operator {{{ */
1027 Expression_
1028     : "," Expression { $$ = new(driver.pool_) CYCompound($2); }
1029     | { $$ = NULL; }
1030     ;
1031
1032 ExpressionNoIn_
1033     : "," ExpressionNoIn { $$ = new(driver.pool_) CYCompound($2); }
1034     | { $$ = NULL; }
1035     ;
1036
1037 ExpressionOpt
1038     : Expression { $$ = $1; }
1039     | { $$ = NULL; }
1040     ;
1041
1042 ExpressionNoInOpt
1043     : ExpressionNoIn { $$ = $1; }
1044     | { $$ = NULL; }
1045     ;
1046
1047 Expression
1048     : AssignmentExpression Expression_ { if ($2) { $2->AddPrev($1); $$ = $2; } else $$ = $1; }
1049     ;
1050
1051 ExpressionNoIn
1052     : AssignmentExpressionNoIn ExpressionNoIn_ { if ($2) { $2->AddPrev($1); $$ = $2; } else $$ = $1; }
1053     ;
1054
1055 ExpressionNoBF
1056     : AssignmentExpressionNoBF Expression_ { if ($2) { $2->AddPrev($1); $$ = $2; } else $$ = $1; }
1057     ;
1058 /* }}} */
1059
1060 /* 12 Statements {{{ */
1061 Statement_
1062     : Block { $$ = $1; }
1063     | VariableStatement { $$ = $1; }
1064     | EmptyStatement { $$ = $1; }
1065     | ExpressionStatement { $$ = $1; }
1066     | IfStatement { $$ = $1; }
1067     | IterationStatement { $$ = $1; }
1068     | ContinueStatement { $$ = $1; }
1069     | BreakStatement { $$ = $1; }
1070     | ReturnStatement { $$ = $1; }
1071     | WithStatement { $$ = $1; }
1072     | LabelledStatement { $$ = $1; }
1073     | SwitchStatement { $$ = $1; }
1074     | ThrowStatement { $$ = $1; }
1075     | TryStatement { $$ = $1; }
1076     ;
1077
1078 Statement
1079     : Statement_ { $$ = $1; }
1080     ;
1081 /* }}} */
1082 /* 12.1 Block {{{ */
1083 Block_
1084     : "{" StatementListOpt "}" { $$ = $2; }
1085     ;
1086
1087 Block
1088     : Block_ { if ($1) $$ = new(driver.pool_) CYBlock($1); else $$ = new(driver.pool_) CYEmpty(); }
1089     ;
1090
1091 StatementList
1092     : Statement StatementListOpt { $1->SetNext($2); $$ = $1; }
1093     ;
1094
1095 StatementListOpt
1096     : StatementList { $$ = $1; }
1097     | { $$ = NULL; }
1098     ;
1099 /* }}} */
1100 /* 12.2 Variable Statement {{{ */
1101 VariableStatement
1102     : "var" VariableDeclarationList Terminator { $$ = new(driver.pool_) CYVar($2); }
1103     ;
1104
1105 VariableDeclarationList_
1106     : "," VariableDeclarationList { $$ = $2; }
1107     | { $$ = NULL; }
1108     ;
1109
1110 VariableDeclarationListNoIn_
1111     : "," VariableDeclarationListNoIn { $$ = $2; }
1112     | { $$ = NULL; }
1113     ;
1114
1115 VariableDeclarationList
1116     : VariableDeclaration VariableDeclarationList_ { $$ = new(driver.pool_) CYDeclarations($1, $2); }
1117     ;
1118
1119 VariableDeclarationListNoIn
1120     : VariableDeclarationNoIn VariableDeclarationListNoIn_ { $$ = new(driver.pool_) CYDeclarations($1, $2); }
1121     ;
1122
1123 VariableDeclaration
1124     : Identifier InitialiserOpt { $$ = new(driver.pool_) CYDeclaration($1, $2); }
1125     ;
1126
1127 VariableDeclarationNoIn
1128     : Identifier InitialiserNoInOpt { $$ = new(driver.pool_) CYDeclaration($1, $2); }
1129     ;
1130
1131 InitialiserOpt
1132     : Initialiser { $$ = $1; }
1133     | { $$ = NULL; }
1134     ;
1135
1136 InitialiserNoInOpt
1137     : InitialiserNoIn { $$ = $1; }
1138     | { $$ = NULL; }
1139     ;
1140
1141 Initialiser
1142     : "=" AssignmentExpression { $$ = $2; }
1143     ;
1144
1145 InitialiserNoIn
1146     : "=" AssignmentExpressionNoIn { $$ = $2; }
1147     ;
1148 /* }}} */
1149 /* 12.3 Empty Statement {{{ */
1150 EmptyStatement
1151     : ";" { $$ = new(driver.pool_) CYEmpty(); }
1152     ;
1153 /* }}} */
1154 /* 12.4 Expression Statement {{{ */
1155 ExpressionStatement
1156     : ExpressionNoBF Terminator { $$ = new(driver.pool_) CYExpress($1); }
1157     ;
1158 /* }}} */
1159 /* 12.5 The if Statement {{{ */
1160 ElseStatementOpt
1161     : "else" Statement { $$ = $2; }
1162     | %prec "if" { $$ = NULL; }
1163     ;
1164
1165 IfStatement
1166     : "if" "(" Expression ")" Statement ElseStatementOpt { $$ = new(driver.pool_) CYIf($3, $5, $6); }
1167     ;
1168 /* }}} */
1169
1170 /* 12.6 Iteration Statements {{{ */
1171 IterationStatement
1172     : DoWhileStatement { $$ = $1; }
1173     | WhileStatement { $$ = $1; }
1174     | ForStatement { $$ = $1; }
1175     | ForInStatement { $$ = $1; }
1176     ;
1177 /* }}} */
1178 /* 12.6.1 The do-while Statement {{{ */
1179 DoWhileStatement
1180     : "do" Statement "while" "(" Expression ")" TerminatorOpt { $$ = new(driver.pool_) CYDoWhile($5, $2); }
1181     ;
1182 /* }}} */
1183 /* 12.6.2 The while Statement {{{ */
1184 WhileStatement
1185     : "while" "(" Expression ")" Statement { $$ = new(driver.pool_) CYWhile($3, $5); }
1186     ;
1187 /* }}} */
1188 /* 12.6.3 The for Statement {{{ */
1189 ForStatement
1190     : "for" "(" ForStatementInitialiser ";" ExpressionOpt ";" ExpressionOpt ")" Statement { $$ = new(driver.pool_) CYFor($3, $5, $7, $9); }
1191     ;
1192
1193 ForStatementInitialiser
1194     : ExpressionNoInOpt { $$ = $1; }
1195     | "var" VariableDeclarationListNoIn { $$ = $2; }
1196     ;
1197 /* }}} */
1198 /* 12.6.4 The for-in Statement {{{ */
1199 ForInStatement
1200     : "for" "(" ForInStatementInitialiser "in" Expression ")" Statement { $$ = new(driver.pool_) CYForIn($3, $5, $7); }
1201     ;
1202
1203 ForInStatementInitialiser
1204     : LeftHandSideExpression { $$ = $1; }
1205     | "var" VariableDeclarationNoIn { $$ = $2; }
1206     ;
1207 /* }}} */
1208
1209 /* 12.7 The continue Statement {{{ */
1210 ContinueStatement
1211     : "continue" IdentifierOpt Terminator { $$ = new(driver.pool_) CYContinue($2); }
1212     ;
1213 /* }}} */
1214 /* 12.8 The break Statement {{{ */
1215 BreakStatement
1216     : "break" IdentifierOpt Terminator { $$ = new(driver.pool_) CYBreak($2); }
1217     ;
1218 /* }}} */
1219 /* 12.9 The return Statement {{{ */
1220 ReturnStatement
1221     : "return" ExpressionOpt Terminator { $$ = new(driver.pool_) CYReturn($2); }
1222     ;
1223 /* }}} */
1224 /* 12.10 The with Statement {{{ */
1225 WithStatement
1226     : "with" "(" Expression ")" Statement { $$ = new(driver.pool_) CYWith($3, $5); }
1227     ;
1228 /* }}} */
1229
1230 /* 12.11 The switch Statement {{{ */
1231 SwitchStatement
1232     : "switch" "(" Expression ")" CaseBlock { $$ = new(driver.pool_) CYSwitch($3, $5); }
1233     ;
1234
1235 CaseBlock
1236     : "{" CaseClausesOpt "}" { $$ = $2; }
1237     ;
1238
1239 CaseClausesOpt
1240     : CaseClause CaseClausesOpt { $1->SetNext($2); $$ = $1; }
1241     | DefaultClause CaseClausesOpt { $1->SetNext($2); $$ = $1; }
1242     | { $$ = NULL; }
1243     ;
1244
1245 CaseClause
1246     : "case" Expression ":" StatementListOpt { $$ = new(driver.pool_) CYClause($2, $4); }
1247     ;
1248
1249 DefaultClause
1250     : "default" ":" StatementListOpt { $$ = new(driver.pool_) CYClause(NULL, $3); }
1251     ;
1252 /* }}} */
1253 /* 12.12 Labelled Statements {{{ */
1254 LabelledStatement
1255     : Identifier ":" Statement { $$ = new(driver.pool_) CYLabel($1, $3); }
1256     ;
1257 /* }}} */
1258 /* 12.13 The throw Statement {{{ */
1259 ThrowStatement
1260     : "throw" Expression Terminator { $$ = new(driver.pool_) CYThrow($2); }
1261     ;
1262 /* }}} */
1263 /* 12.14 The try Statement {{{ */
1264 TryStatement
1265     : "try" Block_ CatchOpt FinallyOpt { $$ = new(driver.pool_) CYTry($2, $3, $4); }
1266     ;
1267
1268 CatchOpt
1269     : "catch" "(" Identifier ")" Block_ { $$ = new(driver.pool_) CYCatch($3, $5); }
1270     | { $$ = NULL; }
1271     ;
1272
1273 FinallyOpt
1274     : "finally" Block_ { $$ = new(driver.pool_) CYFinally($2); }
1275     | { $$ = NULL; }
1276     ;
1277 /* }}} */
1278
1279 /* 13 Function Definition {{{ */
1280 FunctionDeclaration
1281     : "function" Identifier "(" FormalParameterList ")" "{" FunctionBody "}" { $$ = new(driver.pool_) CYFunctionStatement($2, $4, $7); }
1282     ;
1283
1284 FunctionExpression
1285     : "function" IdentifierOpt "(" FormalParameterList ")" "{" FunctionBody "}" { $$ = new(driver.pool_) CYFunctionExpression($2, $4, $7); }
1286     ;
1287
1288 FormalParameterList_
1289     : "," FormalParameterList { $$ = $2; }
1290     | { $$ = NULL; }
1291     ;
1292
1293 FormalParameterList
1294     : Identifier FormalParameterList_ { $$ = new(driver.pool_) CYFunctionParameter($1, $2); }
1295     | { $$ = NULL; }
1296     ;
1297
1298 FunctionBody
1299     : SourceElements { $$ = $1; }
1300     ;
1301 /* }}} */
1302 /* 14 Program {{{ */
1303 Program
1304     : SourceElements { driver.program_ = new(driver.pool_) CYProgram($1); }
1305     ;
1306
1307 SourceElements
1308     : SourceElement SourceElements { $1->SetNext($2); $$ = $1; }
1309     | { $$ = NULL; }
1310     ;
1311
1312 SourceElement
1313     : Statement_ { $$ = $1; }
1314     | FunctionDeclaration { $$ = $1; }
1315     ;
1316 /* }}} */
1317
1318 @begin ObjC
1319 /* Cycript (Objective-C): @class Declaration {{{ */
1320 ClassSuperOpt
1321     : ":" MemberExpressionNoBF { $$ = $2; }
1322     | { $$ = NULL; }
1323     ;
1324
1325 ClassFieldList
1326     : "{" "}" { $$ = NULL; }
1327     ;
1328
1329 MessageScope
1330     : "+" { $$ = false; }
1331     | "-" { $$ = true; }
1332     ;
1333
1334 TypeOpt
1335     : "(" Expression ")" { $$ = $2; }
1336     | { $$ = NULL; }
1337     ;
1338
1339 MessageParameter
1340     : Word ":" TypeOpt Identifier { $$ = new(driver.pool_) CYMessageParameter($1, $3, $4); }
1341     ;
1342
1343 MessageParameterListOpt
1344     : MessageParameterList { $$ = $1; }
1345     | { $$ = NULL; }
1346     ;
1347
1348 MessageParameterList
1349     : MessageParameter MessageParameterListOpt { $1->SetNext($2); $$ = $1; }
1350     ;
1351
1352 MessageParameters
1353     : MessageParameterList { $$ = $1; }
1354     | Word { $$ = new(driver.pool_) CYMessageParameter($1, NULL, NULL); }
1355     ;
1356
1357 ClassMessageDeclaration
1358     : MessageScope TypeOpt MessageParameters "{" FunctionBody "}" { $$ = new(driver.pool_) CYMessage($1, $2, $3, $5); }
1359     ;
1360
1361 ClassMessageDeclarationListOpt
1362     : ClassMessageDeclarationListOpt ClassMessageDeclaration { $2->SetNext($1); $$ = $2; }
1363     | { $$ = NULL; }
1364     ;
1365
1366 ClassName
1367     : Identifier { $$ = $1; }
1368     | "(" AssignmentExpression ")" { $$ = $2; }
1369     ;
1370
1371 ClassNameOpt
1372     : ClassName { $$ = $1; }
1373     | { $$ = NULL; }
1374     ;
1375
1376 ClassExpression
1377     : "@class" ClassNameOpt ClassSuperOpt ClassFieldList ClassMessageDeclarationListOpt "@end" { $$ = new(driver.pool_) CYClassExpression($2, $3, $4, $5); }
1378     ;
1379
1380 ClassStatement
1381     : "@class" ClassName ClassSuperOpt ClassFieldList ClassMessageDeclarationListOpt "@end" { $$ = new(driver.pool_) CYClassStatement($2, $3, $4, $5); }
1382     ;
1383
1384 CategoryStatement
1385     : "@class" ClassName ClassMessageDeclarationListOpt "@end" { $$ = new(driver.pool_) CYCategory($2, $3); }
1386     ;
1387
1388 PrimaryExpression
1389     : ClassExpression { $$ = $1; }
1390     ;
1391
1392 Statement_
1393     : ClassStatement { $$ = $1; }
1394     | CategoryStatement { $$ = $1; }
1395     ;
1396 /* }}} */
1397 /* Cycript (Objective-C): Send Message {{{ */
1398 VariadicCall
1399     : "," AssignmentExpression VariadicCall { $$ = new(driver.pool_) CYArgument(NULL, $2, $3); }
1400     | { $$ = NULL; }
1401     ;
1402
1403 SelectorCall_
1404     : SelectorCall { $$ = $1; }
1405     | VariadicCall { $$ = $1; }
1406     ;
1407
1408 SelectorCall
1409     : WordOpt ":" AssignmentExpression SelectorCall_ { $$ = new(driver.pool_) CYArgument($1 ?: new(driver.pool_) CYBlank(), $3, $4); }
1410     ;
1411
1412 SelectorList
1413     : SelectorCall { $$ = $1; }
1414     | Word { $$ = new(driver.pool_) CYArgument($1, NULL); }
1415     ;
1416
1417 MessageExpression
1418     : "[" AssignmentExpression SelectorList "]" { $$ = new(driver.pool_) CYSend($2, $3); }
1419     ;
1420
1421 SelectorExpressionOpt
1422     : SelectorExpression_ { $$ = $1; }
1423     | { $$ = NULL; }
1424     ;
1425
1426 SelectorExpression_
1427     : WordOpt ":" SelectorExpressionOpt { $$ = new(driver.pool_) CYSelectorPart($1, true, $3); }
1428     ;
1429
1430 SelectorExpression
1431     : SelectorExpression_ { $$ = $1; }
1432     | Word { $$ = new(driver.pool_) CYSelectorPart($1, false, NULL); }
1433     ;
1434
1435 PrimaryExpression_
1436     : MessageExpression { $$ = $1; }
1437     | "@selector" "(" SelectorExpression ")" { $$ = new(driver.pool_) CYSelector($3); }
1438     ;
1439 /* }}} */
1440 @end
1441
1442 @begin C
1443 /* Cycript (C): Pointer Indirection/Addressing {{{ */
1444 AssigneeExpression_
1445     : "*" UnaryExpression { $$ = new(driver.pool_) CYIndirect($2); }
1446     ;
1447
1448 UnaryExpression_
1449     : "&" UnaryExpression { $$ = new(driver.pool_) CYAddressOf($2); }
1450     ;
1451
1452 MemberAccess
1453     : "->" "[" Expression "]" { $$ = new(driver.pool_) CYIndirectMember(NULL, $3); }
1454     | "->" Identifier { $$ = new(driver.pool_) CYIndirectMember(NULL, new(driver.pool_) CYString($2)); }
1455     ;
1456 /* }}} */
1457 @end
1458
1459 /* ECMAScript5: Object Literal Trailing Comma {{{ */
1460 PropertyNameAndValueList_
1461     : "," { $$ = NULL; }
1462     ;
1463 /* }}} */
1464 /* JavaScript 1.7: Array Comprehensions {{{ */
1465 IfComprehension
1466     : "if" "(" Expression ")" { $$ = new(driver.pool_) CYIfComprehension($3); }
1467     ;
1468
1469 ForComprehension
1470     : "for" "(" Identifier "in" Expression ")" { $$ = new(driver.pool_) CYForInComprehension($3, $5); }
1471     | "for" "each" "(" Identifier "in" Expression ")" { $$ = new(driver.pool_) CYForEachInComprehension($4, $6); }
1472     ;
1473
1474 ComprehensionListOpt
1475     : ComprehensionList { $$ = $1; }
1476     | IfComprehension { $$ = $1; }
1477     | { $$ = NULL; }
1478     ;
1479
1480 ComprehensionList
1481     : ForComprehension ComprehensionListOpt { $1->SetNext($2); $$ = $1; }
1482     ;
1483
1484 PrimaryExpression_
1485     : "[" AssignmentExpression ComprehensionList "]" { $$ = new(driver.pool_) CYArrayComprehension($2, $3); }
1486     ;
1487 /* }}} */
1488 /* JavaScript 1.7: for each {{{ */
1489 ForInStatement
1490     : "for" "each" "(" ForInStatementInitialiser "in" Expression ")" Statement { $$ = new(driver.pool_) CYForEachIn($4, $6, $8); }
1491     ;
1492 /* }}} */
1493 /* JavaScript 1.7: let Statements {{{ *//*
1494 LetStatement
1495     : "let" "(" VariableDeclarationList ")" Block_ { $$ = new(driver.pool_) CYLet($3, $5); }
1496     ;
1497
1498 Statement
1499     : LetStatement
1500     ;
1501 *//* }}} */
1502 /* JavaScript FTW: Function Statements {{{ */
1503 Statement
1504     : FunctionDeclaration { driver.Warning(yylloc, "warning, FunctionDeclaration is a SourceElement, not a Statement"); } { $$ = $1; }
1505     ;
1506 /* }}} */
1507
1508 %%