Cycript.y

   1 /* Cycript - Remove Execution Server and Disassembler
   2  * Copyright (C) 2009  Jay Freeman (saurik)
   3 */
   4
   5 /* Modified BSD License {{{ */
   6 /*
   7  *        Redistribution and use in source and binary
   8  * forms, with or without modification, are permitted
   9  * provided that the following conditions are met:
  10  *
  11  * 1. Redistributions of source code must retain the
  12  *    above copyright notice, this list of conditions
  13  *    and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the
  15  *    above copyright notice, this list of conditions
  16  *    and the following disclaimer in the documentation
  17  *    and/or other materials provided with the
  18  *    distribution.
  19  * 3. The name of the author may not be used to endorse
  20  *    or promote products derived from this software
  21  *    without specific prior written permission.
  22  *
  23  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS''
  24  * AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING,
  25  * BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
  26  * MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  27  * ARE DISCLAIMED. IN NO EVENT SHALL THE AUTHOR BE
  28  * LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  29  * EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  30  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
  31  * SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  32  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
  33  * LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR
  34  * TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
  35  * ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
  36  * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  37 */
  38 /* }}} */
  39
  40 %code top {
  41 #include "Cycript.tab.hh"
  42 #define scanner driver.scanner_
  43 #define YYSTACKEXPANDABLE 1
  44 }
  45
  46 %code requires {
  47 #include "Parser.hpp"
  48
  49 typedef struct {
  50     bool newline_;
  51
  52     union {
  53         bool bool_;
  54
  55         CYDriver::Condition condition_;
  56
  57         CYArgument *argument_;
  58         CYAssignment *assignment_;
  59         CYBoolean *boolean_;
  60         CYClause *clause_;
  61         CYCatch *catch_;
  62         CYClass *class_;
  63         CYClassName *className_;
  64         CYComprehension *comprehension_;
  65         CYCompound *compound_;
  66         CYDeclaration *declaration_;
  67         CYDeclarations *declarations_;
  68         CYElement *element_;
  69         CYExpression *expression_;
  70         CYFalse *false_;
  71         CYField *field_;
  72         CYForInitialiser *for_;
  73         CYForInInitialiser *forin_;
  74         CYFunctionParameter *functionParameter_;
  75         CYIdentifier *identifier_;
  76         CYInfix *infix_;
  77         CYLiteral *literal_;
  78         CYMember *member_;
  79         CYMessage *message_;
  80         CYMessageParameter *messageParameter_;
  81         CYNull *null_;
  82         CYNumber *number_;
  83         CYProperty *property_;
  84         CYPropertyName *propertyName_;
  85         CYSelectorPart *selector_;
  86         CYSource *source_;
  87         CYStatement *statement_;
  88         CYString *string_;
  89         CYThis *this_;
  90         CYTrue *true_;
  91         CYWord *word_;
  92     };
  93 } YYSTYPE;
  94
  95 }
  96
  97 %code provides {
  98 int cylex(YYSTYPE *lvalp, cy::location *llocp, void *scanner);
  99 }
 100
 101 %name-prefix "cy"
 102
 103 %language "C++"
 104 %locations
 105
 106 %initial-action {
 107     @$.begin.filename = @$.end.filename = &driver.filename_;
 108 };
 109
 110 %defines
 111
 112 //%glr-parser
 113 //%expect 1
 114
 115 %error-verbose
 116
 117 %parse-param { CYDriver &driver }
 118 %lex-param { void *scanner }
 119
 120 %token Ampersand "&"
 121 %token AmpersandAmpersand "&&"
 122 %token AmpersandEqual "&="
 123 %token Carrot "^"
 124 %token CarrotEqual "^="
 125 %token Equal "="
 126 %token EqualEqual "=="
 127 %token EqualEqualEqual "==="
 128 %token Exclamation "!"
 129 %token ExclamationEqual "!="
 130 %token ExclamationEqualEqual "!=="
 131 %token Hyphen "-"
 132 %token HyphenEqual "-="
 133 %token HyphenHyphen "--"
 134 %token HyphenHyphen_ "\n--"
 135 %token HyphenRight "->"
 136 %token Left "<"
 137 %token LeftEqual "<="
 138 %token LeftLeft "<<"
 139 %token LeftLeftEqual "<<="
 140 %token Percent "%"
 141 %token PercentEqual "%="
 142 %token Period "."
 143 %token Pipe "|"
 144 %token PipeEqual "|="
 145 %token PipePipe "||"
 146 %token Plus "+"
 147 %token PlusEqual "+="
 148 %token PlusPlus "++"
 149 %token PlusPlus_ "\n++"
 150 %token Right ">"
 151 %token RightEqual ">="
 152 %token RightRight ">>"
 153 %token RightRightEqual ">>="
 154 %token RightRightRight ">>>"
 155 %token RightRightRightEqual ">>>="
 156 %token Slash "/"
 157 %token SlashEqual "/="
 158 %token Star "*"
 159 %token StarEqual "*="
 160 %token Tilde "~"
 161
 162 %token Colon ":"
 163 %token Comma ","
 164 %token Question "?"
 165 %token SemiColon ";"
 166 %token NewLine "\n"
 167
 168 %token OpenParen "("
 169 %token CloseParen ")"
 170
 171 %token OpenBrace "{"
 172 %token CloseBrace "}"
 173
 174 %token OpenBracket "["
 175 %token CloseBracket "]"
 176
 177 %token AtClass "@class"
 178 %token AtSelector "@selector"
 179 %token AtEnd "@end"
 180
 181 %token <false_> False "false"
 182 %token <null_> Null "null"
 183 %token <true_> True "true"
 184
 185 // ES3/ES5/WIE/JSC Reserved
 186 %token <word_> Break "break"
 187 %token <word_> Case "case"
 188 %token <word_> Catch "catch"
 189 %token <word_> Continue "continue"
 190 %token <word_> Default "default"
 191 %token <word_> Delete "delete"
 192 %token <word_> Do "do"
 193 %token <word_> Else "else"
 194 %token <word_> Finally "finally"
 195 %token <word_> For "for"
 196 %token <word_> Function "function"
 197 %token <word_> If "if"
 198 %token <word_> In "in"
 199 %token <word_> InstanceOf "instanceof"
 200 %token <word_> New "new"
 201 %token <word_> Return "return"
 202 %token <word_> Switch "switch"
 203 %token <this_> This "this"
 204 %token <word_> Throw "throw"
 205 %token <word_> Try "try"
 206 %token <word_> TypeOf "typeof"
 207 %token <word_> Var "var"
 208 %token <word_> Void "void"
 209 %token <word_> While "while"
 210 %token <word_> With "with"
 211
 212 // ES3/IE6 Future, ES5/JSC Reserved
 213 %token <word_> Debugger "debugger"
 214
 215 // ES3/ES5/IE6 Future, JSC Reserved
 216 %token <word_> Const "const"
 217
 218 // ES3/ES5/IE6/JSC Future
 219 %token <word_> Class "class"
 220 %token <word_> Enum "enum"
 221 %token <word_> Export "export"
 222 %token <word_> Extends "extends"
 223 %token <word_> Import "import"
 224 %token <word_> Super "super"
 225
 226 // ES3 Future, ES5 Strict Future
 227 %token <identifier_> Implements "implements"
 228 %token <identifier_> Interface "interface"
 229 %token <identifier_> Package "package"
 230 %token <identifier_> Private "private"
 231 %token <identifier_> Protected "protected"
 232 %token <identifier_> Public "public"
 233 %token <identifier_> Static "static"
 234
 235 // ES3 Future
 236 %token <identifier_> Abstract "abstract"
 237 %token <identifier_> Boolean "boolean"
 238 %token <identifier_> Byte "byte"
 239 %token <identifier_> Char "char"
 240 %token <identifier_> Double "double"
 241 %token <identifier_> Final "final"
 242 %token <identifier_> Float "float"
 243 %token <identifier_> Goto "goto"
 244 %token <identifier_> Int "int"
 245 %token <identifier_> Long "long"
 246 %token <identifier_> Native "native"
 247 %token <identifier_> Short "short"
 248 %token <identifier_> Synchronized "synchronized"
 249 %token <identifier_> Throws "throws"
 250 %token <identifier_> Transient "transient"
 251 %token <identifier_> Volatile "volatile"
 252
 253 // ES5 Strict
 254 %token <identifier_> Let "let"
 255 %token <identifier_> Yield "yield"
 256
 257 // Woah?!
 258 %token <identifier_> Each "each"
 259
 260 %token <identifier_> Identifier_
 261 %token <number_> NumericLiteral
 262 %token <string_> StringLiteral
 263 %token <literal_> RegularExpressionLiteral
 264
 265 %type <expression_> AdditiveExpression
 266 %type <expression_> AdditiveExpressionNoBF
 267 %type <argument_> ArgumentList
 268 %type <argument_> ArgumentList_
 269 %type <argument_> ArgumentListOpt
 270 %type <argument_> Arguments
 271 %type <literal_> ArrayLiteral
 272 %type <expression_> AssigneeExpression
 273 %type <expression_> AssigneeExpression_
 274 %type <expression_> AssigneeExpressionNoBF
 275 %type <expression_> AssignmentExpression
 276 %type <assignment_> AssignmentExpression_
 277 %type <expression_> AssignmentExpressionNoBF
 278 %type <expression_> AssignmentExpressionNoIn
 279 %type <expression_> BitwiseANDExpression
 280 %type <expression_> BitwiseANDExpressionNoBF
 281 %type <expression_> BitwiseANDExpressionNoIn
 282 %type <statement_> Block
 283 %type <statement_> Block_
 284 %type <boolean_> BooleanLiteral
 285 %type <expression_> BitwiseORExpression
 286 %type <expression_> BitwiseORExpressionNoBF
 287 %type <expression_> BitwiseORExpressionNoIn
 288 %type <expression_> BitwiseXORExpression
 289 %type <expression_> BitwiseXORExpressionNoBF
 290 %type <expression_> BitwiseXORExpressionNoIn
 291 %type <statement_> BreakStatement
 292 %type <expression_> CallExpression
 293 %type <expression_> CallExpressionNoBF
 294 %type <clause_> CaseBlock
 295 %type <clause_> CaseClause
 296 %type <clause_> CaseClausesOpt
 297 %type <catch_> CatchOpt
 298 %type <statement_> CategoryStatement
 299 %type <class_> ClassDefinition
 300 %type <message_> ClassMessageDeclaration
 301 %type <message_> ClassMessageDeclarationListOpt
 302 %type <className_> ClassName
 303 %type <className_> ClassNameOpt
 304 %type <expression_> ClassSuperOpt
 305 %type <field_> ClassFieldList
 306 %type <comprehension_> ComprehensionList
 307 %type <comprehension_> ComprehensionListOpt
 308 %type <expression_> ConditionalExpression
 309 %type <expression_> ConditionalExpressionNoBF
 310 %type <expression_> ConditionalExpressionNoIn
 311 %type <statement_> ContinueStatement
 312 %type <clause_> DefaultClause
 313 %type <statement_> DoWhileStatement
 314 %type <expression_> Element
 315 %type <expression_> ElementOpt
 316 %type <element_> ElementList
 317 %type <element_> ElementListOpt
 318 %type <statement_> ElseStatementOpt
 319 %type <statement_> EmptyStatement
 320 %type <expression_> EqualityExpression
 321 %type <expression_> EqualityExpressionNoBF
 322 %type <expression_> EqualityExpressionNoIn
 323 %type <expression_> Expression
 324 %type <expression_> ExpressionOpt
 325 %type <compound_> Expression_
 326 %type <expression_> ExpressionNoBF
 327 %type <expression_> ExpressionNoIn
 328 %type <compound_> ExpressionNoIn_
 329 %type <expression_> ExpressionNoInOpt
 330 %type <statement_> ExpressionStatement
 331 %type <statement_> FinallyOpt
 332 %type <comprehension_> ForComprehension
 333 %type <statement_> ForStatement
 334 %type <for_> ForStatementInitialiser
 335 %type <statement_> ForInStatement
 336 %type <forin_> ForInStatementInitialiser
 337 %type <functionParameter_> FormalParameterList
 338 %type <functionParameter_> FormalParameterList_
 339 %type <source_> FunctionBody
 340 %type <source_> FunctionDeclaration
 341 %type <expression_> FunctionExpression
 342 %type <identifier_> Identifier
 343 %type <identifier_> IdentifierOpt
 344 %type <comprehension_> IfComprehension
 345 %type <statement_> IfStatement
 346 %type <expression_> Initialiser
 347 %type <expression_> InitialiserOpt
 348 %type <expression_> InitialiserNoIn
 349 %type <expression_> InitialiserNoInOpt
 350 %type <statement_> IterationStatement
 351 %type <statement_> LabelledStatement
 352 %type <expression_> LeftHandSideExpression
 353 %type <expression_> LeftHandSideExpressionNoBF
 354 //%type <statement_> LetStatement
 355 %type <literal_> Literal
 356 %type <expression_> LogicalANDExpression
 357 %type <expression_> LogicalANDExpressionNoBF
 358 %type <expression_> LogicalANDExpressionNoIn
 359 %type <expression_> LogicalORExpression
 360 %type <expression_> LogicalORExpressionNoBF
 361 %type <expression_> LogicalORExpressionNoIn
 362 %type <member_> MemberAccess
 363 %type <expression_> MemberExpression
 364 %type <expression_> MemberExpression_
 365 %type <expression_> MemberExpressionNoBF
 366 %type <messageParameter_> MessageParameter
 367 %type <messageParameter_> MessageParameters
 368 %type <messageParameter_> MessageParameterList
 369 %type <messageParameter_> MessageParameterListOpt
 370 %type <bool_> MessageScope
 371 %type <expression_> MultiplicativeExpression
 372 %type <expression_> MultiplicativeExpressionNoBF
 373 %type <expression_> NewExpression
 374 %type <expression_> NewExpression_
 375 %type <expression_> NewExpressionNoBF
 376 %type <null_> NullLiteral
 377 %type <literal_> ObjectLiteral
 378 %type <expression_> PostfixExpression
 379 %type <expression_> PostfixExpressionNoBF
 380 %type <expression_> PrimaryExpression
 381 %type <expression_> PrimaryExpression_
 382 %type <expression_> PrimaryExpressionNoBF
 383 %type <source_> Program
 384 %type <propertyName_> PropertyName
 385 %type <property_> PropertyNameAndValueList
 386 %type <property_> PropertyNameAndValueList_
 387 %type <property_> PropertyNameAndValueListOpt
 388 %type <literal_> RegularExpressionLiteral_
 389 %type <condition_> RegularExpressionToken
 390 %type <expression_> RelationalExpression
 391 %type <infix_> RelationalExpression_
 392 %type <expression_> RelationalExpressionNoBF
 393 %type <expression_> RelationalExpressionNoIn
 394 %type <infix_> RelationalExpressionNoIn_
 395 %type <statement_> ReturnStatement
 396 %type <selector_> SelectorExpression
 397 %type <selector_> SelectorExpression_
 398 %type <selector_> SelectorExpressionOpt
 399 %type <expression_> ShiftExpression
 400 %type <expression_> ShiftExpressionNoBF
 401 %type <source_> SourceElement
 402 %type <source_> SourceElements
 403 %type <statement_> Statement
 404 %type <statement_> StatementList
 405 %type <statement_> StatementListOpt
 406 %type <statement_> SwitchStatement
 407 %type <statement_> ThrowStatement
 408 %type <statement_> TryStatement
 409 %type <expression_> TypeOpt
 410 %type <expression_> UnaryExpression
 411 %type <expression_> UnaryExpression_
 412 %type <expression_> UnaryExpressionNoBF
 413 %type <declaration_> VariableDeclaration
 414 %type <declaration_> VariableDeclarationNoIn
 415 %type <declarations_> VariableDeclarationList
 416 %type <declarations_> VariableDeclarationList_
 417 %type <declarations_> VariableDeclarationListNoIn
 418 %type <declarations_> VariableDeclarationListNoIn_
 419 %type <statement_> VariableStatement
 420 %type <statement_> WhileStatement
 421 %type <statement_> WithStatement
 422 %type <word_> Word
 423 %type <word_> WordOpt
 424
 425 %type <expression_> MessageExpression
 426 %type <argument_> SelectorCall
 427 %type <argument_> SelectorCall_
 428 %type <argument_> SelectorList
 429 %type <argument_> VariadicCall
 430
 431 %left "*" "/" "%"
 432 %left "+" "-"
 433 %left "<<" ">>" ">>>"
 434 %left "<" ">" "<=" ">=" "instanceof" "in"
 435 %left "==" "!=" "===" "!=="
 436 %left "&"
 437 %left "^"
 438 %left "|"
 439 %left "&&"
 440 %left "||"
 441
 442 %right "=" "*=" "/=" "%=" "+=" "-=" "<<=" ">>=" ">>>=" "&=" "^=" "|="
 443
 444 %nonassoc "if"
 445 %nonassoc "else"
 446
 447 %start Program
 448
 449 %%
 450
 451 TerminatorOpt
 452     : ";"
 453     | "\n"
 454     | error { yyerrok; driver.errors_.pop_back(); }
 455     ;
 456
 457 Terminator
 458     : ";"
 459     | "\n"
 460     | error { if (yychar != 0 && yychar != cy::parser::token::CloseBrace && !yylval.newline_) YYABORT; else { yyerrok; driver.errors_.pop_back(); } }
 461     ;
 462
 463 /*CommaOpt
 464     : ","
 465     |
 466     ;*/
 467
 468 NewLineOpt
 469     : "\n"
 470     |
 471     ;
 472
 473 WordOpt
 474     : Word { $$ = $1; }
 475     | { $$ = NULL; }
 476     ;
 477
 478 Word
 479     : Identifier { $$ = $1; }
 480     | "break" NewLineOpt { $$ = $1; }
 481     | "case" { $$ = $1; }
 482     | "catch" { $$ = $1; }
 483     | "class" { $$ = $1; }
 484     | "const" { $$ = $1; }
 485     | "continue" NewLineOpt { $$ = $1; }
 486     | "debugger" { $$ = $1; }
 487     | "default" { $$ = $1; }
 488     | "delete" { $$ = $1; }
 489     | "do" { $$ = $1; }
 490     | "else" { $$ = $1; }
 491     | "enum" { $$ = $1; }
 492     | "export" { $$ = $1; }
 493     | "extends" { $$ = $1; }
 494     | "false" { $$ = $1; }
 495     | "finally" { $$ = $1; }
 496     | "for" { $$ = $1; }
 497     | "function" { $$ = $1; }
 498     | "if" { $$ = $1; }
 499     | "import" { $$ = $1; }
 500     /* XXX: | "in" { $$ = $1; } */
 501     /* XXX: | "instanceof" { $$ = $1; } */
 502     | "new" { $$ = $1; }
 503     | "null" { $$ = $1; }
 504     | "return" NewLineOpt { $$ = $1; }
 505     | "super" { $$ = $1; }
 506     | "switch" { $$ = $1; }
 507     | "this" { $$ = $1; }
 508     | "throw" NewLineOpt { $$ = $1; }
 509     | "true" { $$ = $1; }
 510     | "try" { $$ = $1; }
 511     | "typeof" { $$ = $1; }
 512     | "var" { $$ = $1; }
 513     | "void" { $$ = $1; }
 514     | "while" { $$ = $1; }
 515     | "with" { $$ = $1; }
 516     ;
 517
 518 Identifier
 519     : Identifier_ { $$ = $1; }
 520
 521     | "implements" { $$ = $1; }
 522     | "interface" { $$ = $1; }
 523     | "package" { $$ = $1; }
 524     | "private" { $$ = $1; }
 525     | "protected" { $$ = $1; }
 526     | "public" { $$ = $1; }
 527     | "static" { $$ = $1; }
 528
 529     | "abstract" { $$ = $1; }
 530     | "boolean" { $$ = $1; }
 531     | "byte" { $$ = $1; }
 532     | "char" { $$ = $1; }
 533     | "double" { $$ = $1; }
 534     | "final" { $$ = $1; }
 535     | "float" { $$ = $1; }
 536     | "goto" { $$ = $1; }
 537     | "int" { $$ = $1; }
 538     | "long" { $$ = $1; }
 539     | "native" { $$ = $1; }
 540     | "short" { $$ = $1; }
 541     | "synchronized" { $$ = $1; }
 542     | "throws" { $$ = $1; }
 543     | "transient" { $$ = $1; }
 544     | "volatile" { $$ = $1; }
 545
 546     | "let" { $$ = $1; }
 547     | "yield" { $$ = $1; }
 548
 549     | "each" { $$ = $1; }
 550     ;
 551
 552 IdentifierOpt
 553     : Identifier { $$ = $1; }
 554     | { $$ = NULL; }
 555     ;
 556
 557 RegularExpressionToken
 558     : "/" { $$ = CYDriver::RegExStart; }
 559     | "/=" { $$ = CYDriver::RegExRest; }
 560     ;
 561
 562 RegularExpressionLiteral_
 563     : RegularExpressionToken { driver.SetCondition($1); } RegularExpressionLiteral { $$ = $3; }
 564     ;
 565
 566 Literal
 567     : NullLiteral { $$ = $1; }
 568     | BooleanLiteral { $$ = $1; }
 569     | NumericLiteral { $$ = $1; }
 570     | StringLiteral { $$ = $1; }
 571     | RegularExpressionLiteral_ { $$ = $1; }
 572     ;
 573
 574 NullLiteral
 575     : "null" { $$ = $1; }
 576     ;
 577
 578 BooleanLiteral
 579     : "true" { $$ = $1; }
 580     | "false" { $$ = $1; }
 581     ;
 582
 583 /* 11.1 Primary Expressions {{{ */
 584 PrimaryExpression_
 585     : "this" { $$ = $1; }
 586     | Identifier { $$ = new(driver.pool_) CYVariable($1); }
 587     | Literal { $$ = $1; }
 588     | ArrayLiteral { $$ = $1; }
 589     | "(" Expression ")" { $$ = $2; }
 590     ;
 591
 592 PrimaryExpression
 593     : ObjectLiteral { $$ = $1; }
 594     | PrimaryExpression_ { $$ = $1; }
 595     ;
 596
 597 PrimaryExpressionNoBF
 598     : PrimaryExpression_ { $$ = $1; }
 599     ;
 600 /* }}} */
 601 /* 11.1.4 Array Initialiser {{{ */
 602 ArrayLiteral
 603     : "[" ElementListOpt "]" { $$ = new(driver.pool_) CYArray($2); }
 604     ;
 605
 606 Element
 607     : AssignmentExpression { $$ = $1; }
 608     ;
 609
 610 ElementOpt
 611     : Element { $$ = $1; }
 612     | { $$ = NULL; }
 613     ;
 614
 615 ElementListOpt
 616     : ElementList { $$ = $1; }
 617     | { $$ = NULL; }
 618     ;
 619
 620 ElementList
 621     : ElementOpt "," ElementListOpt { $$ = new(driver.pool_) CYElement($1, $3); }
 622     | Element { $$ = new(driver.pool_) CYElement($1, NULL); }
 623     ;
 624 /* }}} */
 625 /* 11.1.5 Object Initialiser {{{ */
 626 ObjectLiteral
 627     : "{" PropertyNameAndValueListOpt "}" { $$ = new(driver.pool_) CYObject($2); }
 628     ;
 629
 630 PropertyNameAndValueList_
 631     : "," PropertyNameAndValueList { $$ = $2; }
 632     | { $$ = NULL; }
 633     ;
 634
 635 PropertyNameAndValueListOpt
 636     : PropertyNameAndValueList { $$ = $1; }
 637     | { $$ = NULL; }
 638     ;
 639
 640 PropertyNameAndValueList
 641     : PropertyName ":" AssignmentExpression PropertyNameAndValueList_ { $$ = new(driver.pool_) CYProperty($1, $3, $4); }
 642     ;
 643
 644 PropertyName
 645     : Identifier { $$ = $1; }
 646     | StringLiteral { $$ = $1; }
 647     | NumericLiteral { $$ = $1; }
 648     ;
 649 /* }}} */
 650
 651 /* 11.2 Left-Hand-Side Expressions {{{ */
 652 MemberExpression_
 653     : "new" MemberExpression Arguments { $$ = new(driver.pool_) CYNew($2, $3); }
 654     ;
 655
 656 MemberAccess
 657     : "[" Expression "]" { $$ = new(driver.pool_) CYDirectMember(NULL, $2); }
 658     | "." Identifier { $$ = new(driver.pool_) CYDirectMember(NULL, new(driver.pool_) CYString($2)); }
 659     ;
 660
 661 MemberExpression
 662     : PrimaryExpression { $$ = $1; }
 663     | FunctionExpression { $$ = $1; }
 664     | MemberExpression MemberAccess { $2->SetLeft($1); $$ = $2; }
 665     | MemberExpression_ { $$ = $1; }
 666     ;
 667
 668 MemberExpressionNoBF
 669     : PrimaryExpressionNoBF { $$ = $1; }
 670     | MemberExpressionNoBF MemberAccess { $2->SetLeft($1); $$ = $2; }
 671     | MemberExpression_ { $$ = $1; }
 672     ;
 673
 674 NewExpression_
 675     : "new" NewExpression { $$ = new(driver.pool_) CYNew($2, NULL); }
 676     ;
 677
 678 NewExpression
 679     : MemberExpression { $$ = $1; }
 680     | NewExpression_ { $$ = $1; }
 681     ;
 682
 683 NewExpressionNoBF
 684     : MemberExpressionNoBF { $$ = $1; }
 685     | NewExpression_ { $$ = $1; }
 686     ;
 687
 688 CallExpression
 689     : MemberExpression Arguments { $$ = new(driver.pool_) CYCall($1, $2); }
 690     | CallExpression Arguments { $$ = new(driver.pool_) CYCall($1, $2); }
 691     | CallExpression MemberAccess { $2->SetLeft($1); $$ = $2; }
 692     ;
 693
 694 CallExpressionNoBF
 695     : MemberExpressionNoBF Arguments { $$ = new(driver.pool_) CYCall($1, $2); }
 696     | CallExpressionNoBF Arguments { $$ = new(driver.pool_) CYCall($1, $2); }
 697     | CallExpressionNoBF MemberAccess { $2->SetLeft($1); $$ = $2; }
 698     ;
 699
 700 ArgumentList_
 701     : "," ArgumentList { $$ = $2; }
 702     | { $$ = NULL; }
 703     ;
 704
 705 ArgumentListOpt
 706     : ArgumentList { $$ = $1; }
 707     | { $$ = NULL; }
 708     ;
 709
 710 ArgumentList
 711     : AssignmentExpression ArgumentList_ { $$ = new(driver.pool_) CYArgument(NULL, $1, $2); }
 712     ;
 713
 714 Arguments
 715     : "(" ArgumentListOpt ")" { $$ = $2; }
 716     ;
 717
 718 LeftHandSideExpression
 719     : NewExpression { $$ = $1; }
 720     | CallExpression { $$ = $1; }
 721     ;
 722
 723 LeftHandSideExpressionNoBF
 724     : NewExpressionNoBF { $$ = $1; }
 725     | CallExpressionNoBF { $$ = $1; }
 726     ;
 727 /* }}} */
 728 /* 11.3 Postfix Expressions {{{ */
 729 PostfixExpression
 730     : AssigneeExpression { $$ = $1; }
 731     | LeftHandSideExpression "++" { $$ = new(driver.pool_) CYPostIncrement($1); }
 732     | LeftHandSideExpression "--" { $$ = new(driver.pool_) CYPostDecrement($1); }
 733     ;
 734
 735 PostfixExpressionNoBF
 736     : AssigneeExpressionNoBF { $$ = $1; }
 737     | LeftHandSideExpressionNoBF "++" { $$ = new(driver.pool_) CYPostIncrement($1); }
 738     | LeftHandSideExpressionNoBF "--" { $$ = new(driver.pool_) CYPostDecrement($1); }
 739     ;
 740 /* }}} */
 741 /* 11.4 Unary Operators {{{ */
 742 UnaryExpression_
 743     : "delete" UnaryExpression { $$ = new(driver.pool_) CYDelete($2); }
 744     | "void" UnaryExpression { $$ = new(driver.pool_) CYVoid($2); }
 745     | "typeof" UnaryExpression { $$ = new(driver.pool_) CYTypeOf($2); }
 746     | "++" UnaryExpression { $$ = new(driver.pool_) CYPreIncrement($2); }
 747     | "\n++" UnaryExpression { $$ = new(driver.pool_) CYPreIncrement($2); }
 748     | "--" UnaryExpression { $$ = new(driver.pool_) CYPreDecrement($2); }
 749     | "\n--" UnaryExpression { $$ = new(driver.pool_) CYPreDecrement($2); }
 750     | "+" UnaryExpression { $$ = $2; }
 751     | "-" UnaryExpression { $$ = new(driver.pool_) CYNegate($2); }
 752     | "~" UnaryExpression { $$ = new(driver.pool_) CYBitwiseNot($2); }
 753     | "!" UnaryExpression { $$ = new(driver.pool_) CYLogicalNot($2); }
 754     ;
 755
 756 UnaryExpression
 757     : PostfixExpression { $$ = $1; }
 758     | UnaryExpression_ { $$ = $1; }
 759     ;
 760
 761 UnaryExpressionNoBF
 762     : PostfixExpressionNoBF { $$ = $1; }
 763     | UnaryExpression_ { $$ = $1; }
 764     ;
 765 /* }}} */
 766 /* 11.5 Multiplicative Operators {{{ */
 767 MultiplicativeExpression
 768     : UnaryExpression { $$ = $1; }
 769     | MultiplicativeExpression "*" UnaryExpression { $$ = new(driver.pool_) CYMultiply($1, $3); }
 770     | MultiplicativeExpression "/" UnaryExpression { $$ = new(driver.pool_) CYDivide($1, $3); }
 771     | MultiplicativeExpression "%" UnaryExpression { $$ = new(driver.pool_) CYModulus($1, $3); }
 772     ;
 773
 774 MultiplicativeExpressionNoBF
 775     : UnaryExpressionNoBF { $$ = $1; }
 776     | MultiplicativeExpressionNoBF "*" UnaryExpression { $$ = new(driver.pool_) CYMultiply($1, $3); }
 777     | MultiplicativeExpressionNoBF "/" UnaryExpression { $$ = new(driver.pool_) CYDivide($1, $3); }
 778     | MultiplicativeExpressionNoBF "%" UnaryExpression { $$ = new(driver.pool_) CYModulus($1, $3); }
 779     ;
 780 /* }}} */
 781 /* 11.6 Additive Operators {{{ */
 782 AdditiveExpression
 783     : MultiplicativeExpression { $$ = $1; }
 784     | AdditiveExpression "+" MultiplicativeExpression { $$ = new(driver.pool_) CYAdd($1, $3); }
 785     | AdditiveExpression "-" MultiplicativeExpression { $$ = new(driver.pool_) CYSubtract($1, $3); }
 786     ;
 787
 788 AdditiveExpressionNoBF
 789     : MultiplicativeExpressionNoBF { $$ = $1; }
 790     | AdditiveExpressionNoBF "+" MultiplicativeExpression { $$ = new(driver.pool_) CYAdd($1, $3); }
 791     | AdditiveExpressionNoBF "-" MultiplicativeExpression { $$ = new(driver.pool_) CYSubtract($1, $3); }
 792     ;
 793 /* }}} */
 794 /* 11.7 Bitwise Shift Operators {{{ */
 795 ShiftExpression
 796     : AdditiveExpression { $$ = $1; }
 797     | ShiftExpression "<<" AdditiveExpression { $$ = new(driver.pool_) CYShiftLeft($1, $3); }
 798     | ShiftExpression ">>" AdditiveExpression { $$ = new(driver.pool_) CYShiftRightSigned($1, $3); }
 799     | ShiftExpression ">>>" AdditiveExpression { $$ = new(driver.pool_) CYShiftRightUnsigned($1, $3); }
 800     ;
 801
 802 ShiftExpressionNoBF
 803     : AdditiveExpressionNoBF { $$ = $1; }
 804     | ShiftExpressionNoBF "<<" AdditiveExpression { $$ = new(driver.pool_) CYShiftLeft($1, $3); }
 805     | ShiftExpressionNoBF ">>" AdditiveExpression { $$ = new(driver.pool_) CYShiftRightSigned($1, $3); }
 806     | ShiftExpressionNoBF ">>>" AdditiveExpression { $$ = new(driver.pool_) CYShiftRightUnsigned($1, $3); }
 807     ;
 808 /* }}} */
 809 /* 11.8 Relational Operators {{{ */
 810 RelationalExpressionNoIn_
 811     : "<" ShiftExpression { $$ = new(driver.pool_) CYLess(NULL, $2); }
 812     | ">" ShiftExpression { $$ = new(driver.pool_) CYGreater(NULL, $2); }
 813     | "<=" ShiftExpression { $$ = new(driver.pool_) CYLessOrEqual(NULL, $2); }
 814     | ">=" ShiftExpression { $$ = new(driver.pool_) CYGreaterOrEqual(NULL, $2); }
 815     | "instanceof" ShiftExpression { $$ = new(driver.pool_) CYInstanceOf(NULL, $2); }
 816     ;
 817
 818 RelationalExpression_
 819     : RelationalExpressionNoIn_ { $$ = $1; }
 820     | "in" ShiftExpression { $$ = new(driver.pool_) CYIn(NULL, $2); }
 821     ;
 822
 823 RelationalExpression
 824     : ShiftExpression { $$ = $1; }
 825     | RelationalExpression RelationalExpression_ { $2->SetLeft($1); $$ = $2; }
 826     ;
 827
 828 RelationalExpressionNoIn
 829     : ShiftExpression { $$ = $1; }
 830     | RelationalExpressionNoIn RelationalExpressionNoIn_ { $2->SetLeft($1); $$ = $2; }
 831     ;
 832
 833 RelationalExpressionNoBF
 834     : ShiftExpressionNoBF { $$ = $1; }
 835     | RelationalExpressionNoBF RelationalExpression_ { $2->SetLeft($1); $$ = $2; }
 836     ;
 837 /* }}} */
 838 /* 11.9 Equality Operators {{{ */
 839 EqualityExpression
 840     : RelationalExpression { $$ = $1; }
 841     | EqualityExpression "==" RelationalExpression { $$ = new(driver.pool_) CYEqual($1, $3); }
 842     | EqualityExpression "!=" RelationalExpression { $$ = new(driver.pool_) CYNotEqual($1, $3); }
 843     | EqualityExpression "===" RelationalExpression { $$ = new(driver.pool_) CYIdentical($1, $3); }
 844     | EqualityExpression "!==" RelationalExpression { $$ = new(driver.pool_) CYNotIdentical($1, $3); }
 845     ;
 846
 847 EqualityExpressionNoIn
 848     : RelationalExpressionNoIn { $$ = $1; }
 849     | EqualityExpressionNoIn "==" RelationalExpressionNoIn { $$ = new(driver.pool_) CYEqual($1, $3); }
 850     | EqualityExpressionNoIn "!=" RelationalExpressionNoIn { $$ = new(driver.pool_) CYNotEqual($1, $3); }
 851     | EqualityExpressionNoIn "===" RelationalExpressionNoIn { $$ = new(driver.pool_) CYIdentical($1, $3); }
 852     | EqualityExpressionNoIn "!==" RelationalExpressionNoIn { $$ = new(driver.pool_) CYNotIdentical($1, $3); }
 853     ;
 854
 855 EqualityExpressionNoBF
 856     : RelationalExpressionNoBF { $$ = $1; }
 857     | EqualityExpressionNoBF "==" RelationalExpression { $$ = new(driver.pool_) CYEqual($1, $3); }
 858     | EqualityExpressionNoBF "!=" RelationalExpression { $$ = new(driver.pool_) CYNotEqual($1, $3); }
 859     | EqualityExpressionNoBF "===" RelationalExpression { $$ = new(driver.pool_) CYIdentical($1, $3); }
 860     | EqualityExpressionNoBF "!==" RelationalExpression { $$ = new(driver.pool_) CYNotIdentical($1, $3); }
 861     ;
 862 /* }}} */
 863 /* 11.10 Binary Bitwise Operators {{{ */
 864 BitwiseANDExpression
 865     : EqualityExpression { $$ = $1; }
 866     | BitwiseANDExpression "&" EqualityExpression { $$ = new(driver.pool_) CYBitwiseAnd($1, $3); }
 867     ;
 868
 869 BitwiseANDExpressionNoIn
 870     : EqualityExpressionNoIn { $$ = $1; }
 871     | BitwiseANDExpressionNoIn "&" EqualityExpressionNoIn { $$ = new(driver.pool_) CYBitwiseAnd($1, $3); }
 872     ;
 873
 874 BitwiseANDExpressionNoBF
 875     : EqualityExpressionNoBF { $$ = $1; }
 876     | BitwiseANDExpressionNoBF "&" EqualityExpression { $$ = new(driver.pool_) CYBitwiseAnd($1, $3); }
 877     ;
 878
 879 BitwiseXORExpression
 880     : BitwiseANDExpression { $$ = $1; }
 881     | BitwiseXORExpression "^" BitwiseANDExpression { $$ = new(driver.pool_) CYBitwiseXOr($1, $3); }
 882     ;
 883
 884 BitwiseXORExpressionNoIn
 885     : BitwiseANDExpressionNoIn { $$ = $1; }
 886     | BitwiseXORExpressionNoIn "^" BitwiseANDExpressionNoIn { $$ = new(driver.pool_) CYBitwiseXOr($1, $3); }
 887     ;
 888
 889 BitwiseXORExpressionNoBF
 890     : BitwiseANDExpressionNoBF { $$ = $1; }
 891     | BitwiseXORExpressionNoBF "^" BitwiseANDExpression { $$ = new(driver.pool_) CYBitwiseXOr($1, $3); }
 892     ;
 893
 894 BitwiseORExpression
 895     : BitwiseXORExpression { $$ = $1; }
 896     | BitwiseORExpression "|" BitwiseXORExpression { $$ = new(driver.pool_) CYBitwiseOr($1, $3); }
 897     ;
 898
 899 BitwiseORExpressionNoIn
 900     : BitwiseXORExpressionNoIn { $$ = $1; }
 901     | BitwiseORExpressionNoIn "|" BitwiseXORExpressionNoIn { $$ = new(driver.pool_) CYBitwiseOr($1, $3); }
 902     ;
 903
 904 BitwiseORExpressionNoBF
 905     : BitwiseXORExpressionNoBF { $$ = $1; }
 906     | BitwiseORExpressionNoBF "|" BitwiseXORExpression { $$ = new(driver.pool_) CYBitwiseOr($1, $3); }
 907     ;
 908 /* }}} */
 909 /* 11.11 Binary Logical Operators {{{ */
 910 LogicalANDExpression
 911     : BitwiseORExpression { $$ = $1; }
 912     | LogicalANDExpression "&&" BitwiseORExpression { $$ = new(driver.pool_) CYLogicalAnd($1, $3); }
 913     ;
 914
 915 LogicalANDExpressionNoIn
 916     : BitwiseORExpressionNoIn { $$ = $1; }
 917     | LogicalANDExpressionNoIn "&&" BitwiseORExpressionNoIn { $$ = new(driver.pool_) CYLogicalAnd($1, $3); }
 918     ;
 919
 920 LogicalANDExpressionNoBF
 921     : BitwiseORExpressionNoBF { $$ = $1; }
 922     | LogicalANDExpressionNoBF "&&" BitwiseORExpression { $$ = new(driver.pool_) CYLogicalAnd($1, $3); }
 923     ;
 924
 925 LogicalORExpression
 926     : LogicalANDExpression { $$ = $1; }
 927     | LogicalORExpression "||" LogicalANDExpression { $$ = new(driver.pool_) CYLogicalOr($1, $3); }
 928     ;
 929
 930 LogicalORExpressionNoIn
 931     : LogicalANDExpressionNoIn { $$ = $1; }
 932     | LogicalORExpressionNoIn "||" LogicalANDExpressionNoIn { $$ = new(driver.pool_) CYLogicalOr($1, $3); }
 933     ;
 934
 935 LogicalORExpressionNoBF
 936     : LogicalANDExpressionNoBF { $$ = $1; }
 937     | LogicalORExpressionNoBF "||" LogicalANDExpression { $$ = new(driver.pool_) CYLogicalOr($1, $3); }
 938     ;
 939 /* }}} */
 940 /* 11.12 Conditional Operator ( ? : ) {{{ */
 941 ConditionalExpression
 942     : LogicalORExpression { $$ = $1; }
 943     | LogicalORExpression "?" AssignmentExpression ":" AssignmentExpression { $$ = new(driver.pool_) CYCondition($1, $3, $5); }
 944     ;
 945
 946 ConditionalExpressionNoIn
 947     : LogicalORExpressionNoIn { $$ = $1; }
 948     | LogicalORExpressionNoIn "?" AssignmentExpression ":" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYCondition($1, $3, $5); }
 949     ;
 950
 951 ConditionalExpressionNoBF
 952     : LogicalORExpressionNoBF { $$ = $1; }
 953     | LogicalORExpressionNoBF "?" AssignmentExpression ":" AssignmentExpression { $$ = new(driver.pool_) CYCondition($1, $3, $5); }
 954     ;
 955 /* }}} */
 956 /* 11.13 Assignment Operators {{{ */
 957 AssignmentExpression_
 958     : "=" AssignmentExpression { $$ = new(driver.pool_) CYAssign(NULL, $2); }
 959     | "*=" AssignmentExpression { $$ = new(driver.pool_) CYMultiplyAssign(NULL, $2); }
 960     | "/=" AssignmentExpression { $$ = new(driver.pool_) CYDivideAssign(NULL, $2); }
 961     | "%=" AssignmentExpression { $$ = new(driver.pool_) CYModulusAssign(NULL, $2); }
 962     | "+=" AssignmentExpression { $$ = new(driver.pool_) CYAddAssign(NULL, $2); }
 963     | "-=" AssignmentExpression { $$ = new(driver.pool_) CYSubtractAssign(NULL, $2); }
 964     | "<<=" AssignmentExpression { $$ = new(driver.pool_) CYShiftLeftAssign(NULL, $2); }
 965     | ">>=" AssignmentExpression { $$ = new(driver.pool_) CYShiftRightSignedAssign(NULL, $2); }
 966     | ">>>=" AssignmentExpression { $$ = new(driver.pool_) CYShiftRightUnsignedAssign(NULL, $2); }
 967     | "&=" AssignmentExpression { $$ = new(driver.pool_) CYBitwiseAndAssign(NULL, $2); }
 968     | "^=" AssignmentExpression { $$ = new(driver.pool_) CYBitwiseXOrAssign(NULL, $2); }
 969     | "|=" AssignmentExpression { $$ = new(driver.pool_) CYBitwiseOrAssign(NULL, $2); }
 970     ;
 971
 972 AssigneeExpression
 973     : LeftHandSideExpression { $$ = $1; }
 974     | AssigneeExpression_ { $$ = $1; }
 975     ;
 976
 977 AssigneeExpressionNoBF
 978     : LeftHandSideExpressionNoBF { $$ = $1; }
 979     | AssigneeExpression_ { $$ = $1; }
 980     ;
 981
 982 AssignmentExpression
 983     : ConditionalExpression { $$ = $1; }
 984     | AssigneeExpression AssignmentExpression_ { $2->SetLeft($1); $$ = $2; }
 985     ;
 986
 987 AssignmentExpressionNoIn
 988     : ConditionalExpressionNoIn { $$ = $1; }
 989     | AssigneeExpression "=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYAssign($1, $3); }
 990     | AssigneeExpression "*=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYMultiplyAssign($1, $3); }
 991     | AssigneeExpression "/=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYDivideAssign($1, $3); }
 992     | AssigneeExpression "%=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYModulusAssign($1, $3); }
 993     | AssigneeExpression "+=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYAddAssign($1, $3); }
 994     | AssigneeExpression "-=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYSubtractAssign($1, $3); }
 995     | AssigneeExpression "<<=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYShiftLeftAssign($1, $3); }
 996     | AssigneeExpression ">>=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYShiftRightSignedAssign($1, $3); }
 997     | AssigneeExpression ">>>=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYShiftRightUnsignedAssign($1, $3); }
 998     | AssigneeExpression "&=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYBitwiseAndAssign($1, $3); }
 999     | AssigneeExpression "^=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYBitwiseXOrAssign($1, $3); }
1000     | AssigneeExpression "|=" AssignmentExpressionNoIn { $$ = new(driver.pool_) CYBitwiseOrAssign($1, $3); }
1001     ;
1002
1003 AssignmentExpressionNoBF
1004     : ConditionalExpressionNoBF { $$ = $1; }
1005     | AssigneeExpressionNoBF AssignmentExpression_ { $2->SetLeft($1); $$ = $2; }
1006     ;
1007 /* }}} */
1008 /* 11.14 Comma Operator {{{ */
1009 Expression_
1010     : "," Expression { $$ = new(driver.pool_) CYCompound($2); }
1011     | { $$ = NULL; }
1012     ;
1013
1014 ExpressionNoIn_
1015     : "," ExpressionNoIn { $$ = new(driver.pool_) CYCompound($2); }
1016     | { $$ = NULL; }
1017     ;
1018
1019 ExpressionOpt
1020     : Expression { $$ = $1; }
1021     | { $$ = NULL; }
1022     ;
1023
1024 ExpressionNoInOpt
1025     : ExpressionNoIn { $$ = $1; }
1026     | { $$ = NULL; }
1027     ;
1028
1029 Expression
1030     : AssignmentExpression Expression_ { if ($2) { $2->AddPrev($1); $$ = $2; } else $$ = $1; }
1031     ;
1032
1033 ExpressionNoIn
1034     : AssignmentExpressionNoIn ExpressionNoIn_ { if ($2) { $2->AddPrev($1); $$ = $2; } else $$ = $1; }
1035     ;
1036
1037 ExpressionNoBF
1038     : AssignmentExpressionNoBF Expression_ { if ($2) { $2->AddPrev($1); $$ = $2; } else $$ = $1; }
1039     ;
1040 /* }}} */
1041
1042 /* 12 Statements {{{ */
1043 Statement
1044     : Block { $$ = $1; }
1045     | VariableStatement { $$ = $1; }
1046     | EmptyStatement { $$ = $1; }
1047     | ExpressionStatement { $$ = $1; }
1048     | IfStatement { $$ = $1; }
1049     | IterationStatement { $$ = $1; }
1050     | ContinueStatement { $$ = $1; }
1051     | BreakStatement { $$ = $1; }
1052     | ReturnStatement { $$ = $1; }
1053     | WithStatement { $$ = $1; }
1054     | LabelledStatement { $$ = $1; }
1055     | SwitchStatement { $$ = $1; }
1056     | ThrowStatement { $$ = $1; }
1057     | TryStatement { $$ = $1; }
1058     ;
1059 /* }}} */
1060 /* 12.1 Block {{{ */
1061 Block_
1062     : "{" StatementListOpt "}" { $$ = $2; }
1063     ;
1064
1065 Block
1066     : Block_ { if ($1) $$ = new(driver.pool_) CYBlock($1); else $$ = new(driver.pool_) CYEmpty(); }
1067     ;
1068
1069 StatementList
1070     : Statement StatementListOpt { $1->SetNext($2); $$ = $1; }
1071     ;
1072
1073 StatementListOpt
1074     : StatementList { $$ = $1; }
1075     | { $$ = NULL; }
1076     ;
1077 /* }}} */
1078 /* 12.2 Variable Statement {{{ */
1079 VariableStatement
1080     : "var" VariableDeclarationList Terminator { $$ = new(driver.pool_) CYVar($2); }
1081     ;
1082
1083 VariableDeclarationList_
1084     : "," VariableDeclarationList { $$ = $2; }
1085     | { $$ = NULL; }
1086     ;
1087
1088 VariableDeclarationListNoIn_
1089     : "," VariableDeclarationListNoIn { $$ = $2; }
1090     | { $$ = NULL; }
1091     ;
1092
1093 VariableDeclarationList
1094     : VariableDeclaration VariableDeclarationList_ { $$ = new(driver.pool_) CYDeclarations($1, $2); }
1095     ;
1096
1097 VariableDeclarationListNoIn
1098     : VariableDeclarationNoIn VariableDeclarationListNoIn_ { $$ = new(driver.pool_) CYDeclarations($1, $2); }
1099     ;
1100
1101 VariableDeclaration
1102     : Identifier InitialiserOpt { $$ = new(driver.pool_) CYDeclaration($1, $2); }
1103     ;
1104
1105 VariableDeclarationNoIn
1106     : Identifier InitialiserNoInOpt { $$ = new(driver.pool_) CYDeclaration($1, $2); }
1107     ;
1108
1109 InitialiserOpt
1110     : Initialiser { $$ = $1; }
1111     | { $$ = NULL; }
1112     ;
1113
1114 InitialiserNoInOpt
1115     : InitialiserNoIn { $$ = $1; }
1116     | { $$ = NULL; }
1117     ;
1118
1119 Initialiser
1120     : "=" AssignmentExpression { $$ = $2; }
1121     ;
1122
1123 InitialiserNoIn
1124     : "=" AssignmentExpressionNoIn { $$ = $2; }
1125     ;
1126 /* }}} */
1127 /* 12.3 Empty Statement {{{ */
1128 EmptyStatement
1129     : ";" { $$ = new(driver.pool_) CYEmpty(); }
1130     ;
1131 /* }}} */
1132 /* 12.4 Expression Statement {{{ */
1133 ExpressionStatement
1134     : ExpressionNoBF Terminator { $$ = new(driver.pool_) CYExpress($1); }
1135     ;
1136 /* }}} */
1137 /* 12.5 The if Statement {{{ */
1138 ElseStatementOpt
1139     : "else" Statement { $$ = $2; }
1140     | %prec "if" { $$ = NULL; }
1141     ;
1142
1143 IfStatement
1144     : "if" "(" Expression ")" Statement ElseStatementOpt { $$ = new(driver.pool_) CYIf($3, $5, $6); }
1145     ;
1146 /* }}} */
1147
1148 /* 12.6 Iteration Statements {{{ */
1149 IterationStatement
1150     : DoWhileStatement { $$ = $1; }
1151     | WhileStatement { $$ = $1; }
1152     | ForStatement { $$ = $1; }
1153     | ForInStatement { $$ = $1; }
1154     ;
1155 /* }}} */
1156 /* 12.6.1 The do-while Statement {{{ */
1157 DoWhileStatement
1158     : "do" Statement "while" "(" Expression ")" TerminatorOpt { $$ = new(driver.pool_) CYDoWhile($5, $2); }
1159     ;
1160 /* }}} */
1161 /* 12.6.2 The while Statement {{{ */
1162 WhileStatement
1163     : "while" "(" Expression ")" Statement { $$ = new(driver.pool_) CYWhile($3, $5); }
1164     ;
1165 /* }}} */
1166 /* 12.6.3 The for Statement {{{ */
1167 ForStatement
1168     : "for" "(" ForStatementInitialiser ";" ExpressionOpt ";" ExpressionOpt ")" Statement { $$ = new(driver.pool_) CYFor($3, $5, $7, $9); }
1169     ;
1170
1171 ForStatementInitialiser
1172     : ExpressionNoInOpt { $$ = $1; }
1173     | "var" VariableDeclarationListNoIn { $$ = $2; }
1174     ;
1175 /* }}} */
1176 /* 12.6.4 The for-in Statement {{{ */
1177 ForInStatement
1178     : "for" "(" ForInStatementInitialiser "in" Expression ")" Statement { $$ = new(driver.pool_) CYForIn($3, $5, $7); }
1179     ;
1180
1181 ForInStatementInitialiser
1182     : LeftHandSideExpression { $$ = $1; }
1183     | "var" VariableDeclarationNoIn { $$ = $2; }
1184     ;
1185 /* }}} */
1186
1187 /* 12.7 The continue Statement {{{ */
1188 ContinueStatement
1189     : "continue" IdentifierOpt Terminator { $$ = new(driver.pool_) CYContinue($2); }
1190     ;
1191 /* }}} */
1192 /* 12.8 The break Statement {{{ */
1193 BreakStatement
1194     : "break" IdentifierOpt Terminator { $$ = new(driver.pool_) CYBreak($2); }
1195     ;
1196 /* }}} */
1197 /* 12.9 The return Statement {{{ */
1198 ReturnStatement
1199     : "return" ExpressionOpt Terminator { $$ = new(driver.pool_) CYReturn($2); }
1200     ;
1201 /* }}} */
1202 /* 12.10 The with Statement {{{ */
1203 WithStatement
1204     : "with" "(" Expression ")" Statement { $$ = new(driver.pool_) CYWith($3, $5); }
1205     ;
1206 /* }}} */
1207
1208 /* 12.11 The switch Statement {{{ */
1209 SwitchStatement
1210     : "switch" "(" Expression ")" CaseBlock { $$ = new(driver.pool_) CYSwitch($3, $5); }
1211     ;
1212
1213 CaseBlock
1214     : "{" CaseClausesOpt "}" { $$ = $2; }
1215     ;
1216
1217 CaseClausesOpt
1218     : CaseClause CaseClausesOpt { $1->SetNext($2); $$ = $1; }
1219     | DefaultClause CaseClausesOpt { $1->SetNext($2); $$ = $1; }
1220     | { $$ = NULL; }
1221     ;
1222
1223 CaseClause
1224     : "case" Expression ":" StatementListOpt { $$ = new(driver.pool_) CYClause($2, $4); }
1225     ;
1226
1227 DefaultClause
1228     : "default" ":" StatementListOpt { $$ = new(driver.pool_) CYClause(NULL, $3); }
1229     ;
1230 /* }}} */
1231 /* 12.12 Labelled Statements {{{ */
1232 LabelledStatement
1233     : Identifier ":" Statement { $3->AddLabel($1); $$ = $3; }
1234     ;
1235 /* }}} */
1236 /* 12.13 The throw Statement {{{ */
1237 ThrowStatement
1238     : "throw" Expression Terminator { $$ = new(driver.pool_) CYThrow($2); }
1239     ;
1240 /* }}} */
1241 /* 12.14 The try Statement {{{ */
1242 TryStatement
1243     : "try" Block_ CatchOpt FinallyOpt { $$ = new(driver.pool_) CYTry($2, $3, $4); }
1244     ;
1245
1246 CatchOpt
1247     : "catch" "(" Identifier ")" Block_ { $$ = new(driver.pool_) CYCatch($3, $5); }
1248     | { $$ = NULL; }
1249     ;
1250
1251 FinallyOpt
1252     : "finally" Block_ { $$ = $2; }
1253     | { $$ = NULL; }
1254     ;
1255 /* }}} */
1256
1257 /* 13 Function Definition {{{ */
1258 FunctionDeclaration
1259     : "function" Identifier "(" FormalParameterList ")" "{" FunctionBody "}" { $$ = new(driver.pool_) CYFunction($2, $4, $7); }
1260     ;
1261
1262 FunctionExpression
1263     : "function" IdentifierOpt "(" FormalParameterList ")" "{" FunctionBody "}" { $$ = new(driver.pool_) CYLambda($2, $4, $7); }
1264     ;
1265
1266 FormalParameterList_
1267     : "," FormalParameterList { $$ = $2; }
1268     | { $$ = NULL; }
1269     ;
1270
1271 FormalParameterList
1272     : Identifier FormalParameterList_ { $$ = new(driver.pool_) CYFunctionParameter($1, $2); }
1273     | { $$ = NULL; }
1274     ;
1275
1276 FunctionBody
1277     : SourceElements { $$ = $1; }
1278     ;
1279 /* }}} */
1280 /* 14 Program {{{ */
1281 Program
1282     : SourceElements { driver.source_ = $1; }
1283     ;
1284
1285 SourceElements
1286     : SourceElement SourceElements { $1->SetNext($2); $$ = $1; }
1287     | { $$ = NULL; }
1288     ;
1289
1290 SourceElement
1291     : Statement { $$ = $1; }
1292     | FunctionDeclaration { $$ = $1; }
1293     ;
1294 /* }}} */
1295
1296 /* Cycript: @class Declaration {{{ */
1297 ClassSuperOpt
1298     : ":" MemberExpressionNoBF { $$ = $2; }
1299     | { $$ = NULL; }
1300     ;
1301
1302 ClassFieldList
1303     : "{" "}" { $$ = NULL; }
1304     ;
1305
1306 MessageScope
1307     : "+" { $$ = false; }
1308     | "-" { $$ = true; }
1309     ;
1310
1311 TypeOpt
1312     : "(" Expression ")" { $$ = $2; }
1313     | { $$ = NULL; }
1314     ;
1315
1316 MessageParameter
1317     : Word ":" TypeOpt Identifier { $$ = new(driver.pool_) CYMessageParameter($1, $3, $4); }
1318     ;
1319
1320 MessageParameterListOpt
1321     : MessageParameterList { $$ = $1; }
1322     | { $$ = NULL; }
1323     ;
1324
1325 MessageParameterList
1326     : MessageParameter MessageParameterListOpt { $1->SetNext($2); $$ = $1; }
1327     ;
1328
1329 MessageParameters
1330     : MessageParameterList { $$ = $1; }
1331     | Word { $$ = new(driver.pool_) CYMessageParameter($1, NULL, NULL); }
1332     ;
1333
1334 ClassMessageDeclaration
1335     : MessageScope TypeOpt MessageParameters "{" FunctionBody "}" { $$ = new(driver.pool_) CYMessage($1, $2, $3, $5); }
1336     ;
1337
1338 ClassMessageDeclarationListOpt
1339     : ClassMessageDeclarationListOpt ClassMessageDeclaration { $2->SetNext($1); $$ = $2; }
1340     | { $$ = NULL; }
1341     ;
1342
1343 ClassName
1344     : Identifier { $$ = $1; }
1345     | "(" AssignmentExpression ")" { $$ = $2; }
1346     ;
1347
1348 ClassNameOpt
1349     : ClassName { $$ = $1; }
1350     | { $$ = NULL; }
1351     ;
1352
1353 ClassDefinition
1354     : "@class" ClassNameOpt ClassSuperOpt ClassFieldList ClassMessageDeclarationListOpt "@end" { $$ = new(driver.pool_) CYClass($2, $3, $4, $5); }
1355     ;
1356
1357 CategoryStatement
1358     : "@class" ClassName ClassMessageDeclarationListOpt "@end" { $$ = new(driver.pool_) CYCategory($2, $3); }
1359     ;
1360
1361 PrimaryExpression
1362     : ClassDefinition { $$ = $1; }
1363     ;
1364
1365 Statement
1366     : ClassDefinition { $$ = $1; }
1367     | CategoryStatement { $$ = $1; }
1368     ;
1369 /* }}} */
1370 /* Cycript: Send Message {{{ */
1371 VariadicCall
1372     : "," AssignmentExpression VariadicCall { $$ = new(driver.pool_) CYArgument(NULL, $2, $3); }
1373     | { $$ = NULL; }
1374     ;
1375
1376 SelectorCall_
1377     : SelectorCall { $$ = $1; }
1378     | VariadicCall { $$ = $1; }
1379     ;
1380
1381 SelectorCall
1382     : WordOpt ":" AssignmentExpression SelectorCall_ { $$ = new(driver.pool_) CYArgument($1 ?: new(driver.pool_) CYBlank(), $3, $4); }
1383     ;
1384
1385 SelectorList
1386     : SelectorCall { $$ = $1; }
1387     | Word { $$ = new(driver.pool_) CYArgument($1, NULL); }
1388     ;
1389
1390 MessageExpression
1391     : "[" AssignmentExpression SelectorList "]" { $$ = new(driver.pool_) CYSend($2, $3); }
1392     ;
1393
1394 SelectorExpressionOpt
1395     : SelectorExpression_ { $$ = $1; }
1396     | { $$ = NULL; }
1397     ;
1398
1399 SelectorExpression_
1400     : WordOpt ":" SelectorExpressionOpt { $$ = new(driver.pool_) CYSelectorPart($1, true, $3); }
1401     ;
1402
1403 SelectorExpression
1404     : SelectorExpression_ { $$ = $1; }
1405     | Word { $$ = new(driver.pool_) CYSelectorPart($1, false, NULL); }
1406     ;
1407
1408 PrimaryExpression_
1409     : MessageExpression { $$ = $1; }
1410     | "@selector" "(" SelectorExpression ")" { $$ = new(driver.pool_) CYSelector($3); }
1411     ;
1412 /* }}} */
1413 /* Cycript: Pointer Indirection/Addressing {{{ */
1414 AssigneeExpression_
1415     : "*" UnaryExpression { $$ = new(driver.pool_) CYIndirect($2); }
1416     ;
1417
1418 UnaryExpression_
1419     : "&" UnaryExpression { $$ = new(driver.pool_) CYAddressOf($2); }
1420     ;
1421
1422 MemberAccess
1423     : "->" Identifier { $$ = new(driver.pool_) CYIndirectMember(NULL, new(driver.pool_) CYString($2)); }
1424     ;
1425 /* }}} */
1426 /* ECMAScript5: Object Literal Trailing Comma {{{ */
1427 PropertyNameAndValueList_
1428     : "," { $$ = NULL; }
1429     ;
1430 /* }}} */
1431 /* JavaScript 1.7: Array Comprehensions {{{ */
1432 IfComprehension
1433     : "if" "(" Expression ")" { $$ = new(driver.pool_) CYIfComprehension($3); }
1434     ;
1435
1436 ForComprehension
1437     : "for" "(" Identifier "in" Expression ")" { $$ = new(driver.pool_) CYForInComprehension($3, $5); }
1438     | "for" "each" "(" Identifier "in" Expression ")" { $$ = new(driver.pool_) CYForEachInComprehension($4, $6); }
1439     ;
1440
1441 ComprehensionListOpt
1442     : ComprehensionList { $$ = $1; }
1443     | IfComprehension { $$ = $1; }
1444     | { $$ = NULL; }
1445     ;
1446
1447 ComprehensionList
1448     : ForComprehension ComprehensionListOpt { $1->SetNext($2); $$ = $1; }
1449     ;
1450
1451 PrimaryExpression_
1452     : "[" AssignmentExpression ComprehensionList "]" { $$ = new(driver.pool_) CYArrayComprehension($2, $3); }
1453     ;
1454 /* }}} */
1455 /* JavaScript 1.7: for each {{{ */
1456 ForInStatement
1457     : "for" "each" "(" ForInStatementInitialiser "in" Expression ")" Statement { $$ = new(driver.pool_) CYForEachIn($4, $6, $8); }
1458     ;
1459 /* }}} */
1460 /* JavaScript 1.7: Let Statements {{{ *//*
1461 LetStatement
1462     : "let" "(" VariableDeclarationList ")" Block_ { $$ = new(driver.pool_) CYLet($3, $5); }
1463     ;
1464
1465 Statement
1466     : LetStatement
1467     ;
1468 *//* }}} */
1469
1470 %%