configure.ac

   1 dnl Cycript - Optimizing JavaScript Compiler/Runtime
   2 dnl Copyright (C) 2009-2013  Jay Freeman (saurik)
   3
   4 dnl GNU General Public License, Version 3 {{{
   5 dnl
   6 dnl Cycript is free software: you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published
   8 dnl by the Free Software Foundation, either version 3 of the License,
   9 dnl or (at your option) any later version.
  10 dnl
  11 dnl Cycript is distributed in the hope that it will be useful, but
  12 dnl WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with Cycript.  If not, see <http://www.gnu.org/licenses/>.
  18 dnl }}}
  19
  20 AC_PREREQ([2.65])
  21 AC_INIT([Cycript], [0.9], [saurik@saurik.com], [cycript], [http://www.cycript.org/])
  22 AC_COPYRIGHT([Copyright (C) 2009-2012  Jay Freeman (saurik)])
  23
  24 AC_CONFIG_SRCDIR([Console.cpp])
  25 AC_CONFIG_AUX_DIR([.])
  26 AC_CONFIG_MACRO_DIR([m4])
  27 AC_CONFIG_HEADERS([config.h])
  28
  29 AM_INIT_AUTOMAKE([-Wall -Werror foreign])
  30 AM_MAINTAINER_MODE([disable])
  31
  32 dnl XXX: do this only on Mac OS X
  33 am_cv_CC_dependencies_compiler_type=none
  34 am_cv_CXX_dependencies_compiler_type=none
  35 am_cv_OBJCXX_dependencies_compiler_type=none
  36
  37 AC_PROG_CXX
  38 AC_PROG_OBJCXX
  39
  40 AM_PROG_AR
  41 AC_PROG_INSTALL
  42
  43 LT_INIT([disable-static])
  44
  45 AC_LANG([C++])
  46
  47 PKG_PROG_PKG_CONFIG([0.22])
  48
  49 AC_PATH_PROG([GIT], [git])
  50 AC_PATH_PROG([TIME], [time])
  51
  52 dnl CY_CHECK_PROGS_VERSION {{{
  53 AC_DEFUN([CY_CHECK_PROGS_VERSION], [
  54     AC_ARG_VAR(]$1[, ]$3[)
  55
  56     AC_MSG_CHECKING(for ]$2[ >= ]$5[)
  57     AC_PATH_PROGS_FEATURE_CHECK(]$1[, ]$2[,
  58         AS_VAR_SET(version, [`$ac_path_]$1[ ]$4[`])
  59         AS_VAR_IF(version, [], ,
  60             AS_VERSION_COMPARE($version, ]$5[, ,
  61                 ac_cv_path_]$1[=$ac_path_]$1[,
  62                 ac_cv_path_]$1[=$ac_path_]$1[))
  63     , AC_MSG_RESULT(no))
  64
  65     AS_IF([true], [
  66         AC_SUBST(]$1[, $ac_cv_path_]$1[)
  67         AC_MSG_RESULT($]$1[)
  68     ], AS_IF([true], [
  69         AC_MSG_ERROR(You need ]$2[ ]$5[ or greater)
  70     ], [
  71         AC_SUBST(]$1[, [:])
  72         AC_MSG_RESULT([no])
  73     ]))
  74 ]) dnl }}}
  75
  76 CY_CHECK_PROGS_VERSION([BISON], [bison], [GNU Project parser generator (yacc replacement)],
  77     [-V | $SED -e '1 s/^bison (GNU Bison) \(.*\)$/\1/p;d'], [2.3])
  78 CY_CHECK_PROGS_VERSION([FLEX], [flex], [the fast lexical analyser generator],
  79     [--version | $SED -e '1 s/^@<:@^0-9.@:>@* \(@<:@0-9.@:>@*\).*$/\1/p;d'], [2.5.33])
  80 CY_CHECK_PROGS_VERSION([GPERF], [gperf], [perfect hash function generator],
  81     [--version | $SED -e '1 s/^.* \(@<:@0-9.@:>@*\)$/\1/p;d'], [3.0.3])
  82 CY_CHECK_PROGS_VERSION([GNUTAR], [tar gtar gnutar], [a very sticky lump of files],
  83     [--version | $SED -e '1 s/^tar (GNU tar) \(.*\)$/\1/p;d'], [1.19])
  84
  85 AC_MSG_CHECKING([bison for %code{}])
  86 echo '%code{}%%_:' >conftest.y
  87 if $BISON conftest.y -o/dev/null 2>/dev/null; then
  88     AC_LIB_APPENDTOVAR([CY_FILTERS], [Bison24])
  89     AC_MSG_RESULT([yes])
  90 else
  91     AC_LIB_APPENDTOVAR([CY_FILTERS], [Bison23])
  92     AC_MSG_RESULT([no])
  93 fi
  94
  95 rm -f conftest.y
  96 AC_SUBST([CY_FILTERS])
  97
  98 dnl CY_TRY {{{
  99 AC_DEFUN([CY_SUCCESS], [cy_good=1])
 100 AC_DEFUN([CY_FAILURE], [cy_good=0])
 101
 102 AC_DEFUN([CY_TRY], [
 103     cy_save=$]$1[
 104         AC_LIB_APPENDTOVAR(]$1[, ]$2[)
 105         ]$3[
 106     ]$1[=$cy_save
 107     AS_IF([test "x$cy_good" = x1], ]$4[, ]$5[)
 108 ]) dnl }}}
 109
 110 AC_DEFUN([CY_TEST_FLAG_], [
 111     AC_LANG_PUSH(]$2[)
 112     AC_MSG_CHECKING([for ]]$4[[ ]]$1[)
 113     CY_TRY(]$3[, $1, [
 114         AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
 115             [CY_SUCCESS], [CY_FAILURE])
 116     ], [
 117         AC_MSG_RESULT([yes])
 118         AC_LIB_APPENDTOVAR(]$3[, ]$1[)
 119     ], [AC_MSG_RESULT([no])])
 120     AC_LANG_POP(]$2[)
 121 ])
 122
 123 AC_DEFUN([CY_TEST_FLAG], [
 124     CY_TEST_FLAG_(]$1[, [C], [CFLAGS], [cc])
 125     CY_TEST_FLAG_(]$1[, [C++], [CXXFLAGS], [c++])
 126     CY_TEST_FLAG_(]$1[, [Objective C++], [OBJCXXFLAGS], [c++ -ObjC])
 127 ])
 128
 129 AX_CFLAGS_WARN_ALL
 130 AX_CXXFLAGS_WARN_ALL
 131
 132 dnl XXX: this is used to support GNU Objective-C struct objc_method
 133 CY_TEST_FLAG([-Wno-deprecated-declarations])
 134
 135 CY_TEST_FLAG([-Wno-dangling-else])
 136 CY_TEST_FLAG([-Wno-overloaded-virtual])
 137 CY_TEST_FLAG([-Wno-parentheses])
 138 CY_TEST_FLAG([-Wno-unneeded-internal-declaration])
 139
 140 dnl -arch * {{{
 141 for cy_arch in ppc ppc64 i386 x86_64 armv6; do
 142     AC_MSG_CHECKING([for -arch $cy_arch])
 143     CY_TRY([CXXFLAGS], ["-arch $cy_arch"], [
 144         AC_TRY_LINK([], [], [CY_SUCCESS], [CY_FAILURE])
 145     ], [
 146         AC_MSG_RESULT([yes])
 147         AC_LIB_APPENDTOVAR([CY_ARCH], ["-arch $cy_arch"])
 148     ], [AC_MSG_RESULT([no])])
 149 done
 150 AC_SUBST([CY_ARCH])
 151 dnl }}}
 152 dnl iOS SDK {{{
 153 AC_PATH_PROG([XCODEBUILD], [xcodebuild])
 154
 155 AS_IF([test "x$XCODEBUILD" != x], [
 156     AC_SUBST([CY_IOS_SIMULATOR], [`xcodebuild -sdk iphonesimulator -version Path`])
 157 ])
 158
 159 AM_CONDITIONAL([CY_IOS_SIMULATOR], [test "x$CY_IOS_SIMULATOR" != x])
 160 dnl }}}
 161
 162 AC_DEFUN([CY_LT_LIB], [
 163     cy_save=$LIBS
 164     LIBS=
 165     ]$2[
 166     ]$1[=$LIBS
 167     LIBS=$cy_save
 168     AC_SUBST(]$1[)
 169 ])
 170
 171 dnl --enable-javascript {{{
 172 AC_DEFUN([CY_CHECK_JAVASCRIPTCORE], [
 173     CY_LT_LIB([LTJAVASCRIPTCORE], [AC_CHECK_FRAMEWORK([JavaScriptCore], [
 174         #include <JavaScriptCore/JSBase.h>
 175     ], [
 176         JSEvaluateScript(0, 0, 0, 0, 0, 0);
 177     ], [
 178         AC_SUBST([CY_EXECUTE], [1])
 179     ], [
 180         for cy_webkit_pkg in "webkit-1.0" "WebKitGtk"; do
 181             PKG_CHECK_MODULES([WEBKIT], [$cy_webkit_pkg], [
 182                 AC_SUBST([CY_EXECUTE], [1])
 183                 AC_LIB_APPENDTOVAR([CPPFLAGS], [`$PKG_CONFIG --cflags $cy_webkit_pkg`])
 184                 AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs $cy_webkit_pkg`])
 185             ], [:]); if test "x$CY_EXECUTE" = x1; then break; fi
 186         done
 187     ])])
 188 ])
 189
 190 AC_DEFUN([CY_CHECK_JAVASCRIPT], [
 191     CY_CHECK_JAVASCRIPTCORE])
 192
 193 AC_ARG_ENABLE([javascript], [AS_HELP_STRING(
 194     [--enable-javascript@<:@=ENGINE@:>@],
 195     [use a JavaScript runtime (currently the only available option for ENGINE is JavaScriptCore) @<:@default=yes@:>@]
 196 )], [
 197     AS_CASE([$enableval],
 198         [yes], [
 199             CY_CHECK_JAVASCRIPT],
 200         [no], [
 201             AC_SUBST([CY_EXECUTE], [0])],
 202         [JavaScriptCore], [
 203             CY_CHECK_JAVASCRIPTCORE],
 204         [AC_MSG_ERROR([Unknown JavaScript engine: $enableval])])
 205 ], [CY_CHECK_JAVASCRIPT])
 206 dnl }}}
 207
 208 dnl APR_FIND_APR {{{
 209 APR_FIND_APR([], [], [1], [1])
 210 AS_CASE([$apr_found], [yes], [
 211     AC_LIB_APPENDTOVAR([CPPFLAGS], [`$apr_config --includes`])
 212     AC_LIB_APPENDTOVAR([LTLIBAPR], [`$apr_config --link-libtool`])
 213     AC_SUBST([LTLIBAPR])
 214 ], [AC_MSG_ERROR([missing "libapr"])])
 215 dnl }}}
 216
 217 AC_DEFUN([CY_CHECK_PKG_CONFIG_LIBFFI], [
 218     PKG_CHECK_MODULES([LIBFFI], [libffi], [
 219         AC_LIB_APPENDTOVAR([CPPFLAGS], [`$PKG_CONFIG --cflags libffi`])
 220         AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs libffi`])
 221     ], [AC_MSG_ERROR([missing "libffi"])])])
 222
 223 AM_CONDITIONAL([CY_EXECUTE], [test "x$CY_EXECUTE" = x1])
 224
 225 AS_CASE([$CY_EXECUTE], [1], [
 226     AC_CHECK_HEADERS([ffi.h ffi/ffi.h], [break])
 227
 228     CY_LT_LIB([LTLIBFFI], AS_IF([test "x$ac_cv_header_ffi_h" = xno && test "x$ac_cv_header_ffi_ffi_h" = xno], [
 229         CY_CHECK_PKG_CONFIG_LIBFFI
 230     ], [
 231         AC_SEARCH_LIBS([ffi_call], [ffi])
 232         AS_CASE([$ac_cv_search_ffi_call], [no], [CY_CHECK_PKG_CONFIG_LIBFFI])
 233     ]))
 234
 235     AC_LANG_PUSH([Objective C++])
 236
 237     AC_MSG_CHECKING([if we really have Objective C++])
 238     AC_COMPILE_IFELSE([AC_LANG_SOURCE([])], [
 239         CY_OBJECTIVEC=1
 240         AC_MSG_RESULT([yes])
 241     ], [AC_MSG_RESULT([no])])
 242
 243     AS_IF([test "x$CY_OBJECTIVEC" = x1], [
 244         CY_LT_LIB([LTOBJECTIVEC], [AC_CHECK_FRAMEWORK([CoreFoundation], [
 245             #include <CoreFoundation/CFBase.h>
 246         ], [CFAllocatorGetDefault();], [
 247             AC_SUBST([CY_OBJECTIVEC])
 248
 249             AC_CHECK_FRAMEWORK([Foundation], [
 250                 #include <Foundation/NSObject.h>
 251             ], [[[[NSObject alloc] init];]])
 252         ], [
 253             AC_ARG_VAR([GNUSTEP_CONFIG], [prints information about the current gnustep installation])
 254             AC_CHECK_PROGS([GNUSTEP_CONFIG], [gnustep-config])
 255
 256             AS_IF([test "x$GNUSTEP_CONFIG" != x], [
 257                 AC_SUBST([CY_OBJECTIVEC])
 258                 AC_LIB_APPENDTOVAR([OBJCXXFLAGS], [`$GNUSTEP_CONFIG --objc-flags`])
 259                 AC_LIB_APPENDTOVAR([LIBS], [`$GNUSTEP_CONFIG --base-libs`])
 260             ], [AC_SUBST([CY_OBJECTIVEC], [0])])
 261         ])])
 262     ])
 263
 264     AC_LANG_POP([Objective C++])
 265 ])
 266
 267 AM_CONDITIONAL([CY_OBJECTIVEC], [test "x$CY_OBJECTIVEC" = x1])
 268
 269 CY_LT_LIB([LTLIBREADLINE], [AX_LIB_READLINE])
 270 AS_CASE([$ax_cv_lib_readline], [no], [AC_MSG_ERROR([missing "libreadline"])])
 271
 272 CY_LT_LIB([LTLIBTERMCAP], [AC_SEARCH_LIBS([cur_term], [termcap])])
 273
 274 AC_LANG_PUSH([C])
 275 AM_ICONV
 276 AS_CASE([$am_cv_func_iconv], [yes], [], [AC_MSG_ERROR([missing "libiconv"])])
 277 AC_LANG_POP([C])
 278
 279 AC_SUBST([LTFLAGS])
 280 AC_SUBST([SO], [$acl_shlibext])
 281
 282 AS_IF([test "x$CY_EXECUTE" = x1], [
 283     AC_CHECK_HEADER([mach/mach.h], [
 284         AC_CHECK_TOOLS([_LIPO], [lipo], [AC_MSG_ERROR([missing "lipo"])])
 285         AC_CHECK_TOOLS([_NM], [nm], [AC_MSG_ERROR([missing "nm"])])
 286         AC_CHECK_TOOLS([_OTOOL], [otool], [AC_MSG_ERROR([missing "otool"])])
 287         AC_SUBST([CY_ATTACH_GROUP], [procmod])
 288         AC_SUBST([CY_MACH], [1])])])
 289 AM_CONDITIONAL([CY_MACH], [test "x$CY_MACH" = x1])
 290
 291 AC_CONFIG_FILES([Makefile])
 292 AC_OUTPUT