configure.ac

   1 dnl Cycript - Optimizing JavaScript Compiler/Runtime
   2 dnl Copyright (C) 2009-2013  Jay Freeman (saurik)
   3
   4 dnl GNU General Public License, Version 3 {{{
   5 dnl
   6 dnl Cycript is free software: you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published
   8 dnl by the Free Software Foundation, either version 3 of the License,
   9 dnl or (at your option) any later version.
  10 dnl
  11 dnl Cycript is distributed in the hope that it will be useful, but
  12 dnl WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with Cycript.  If not, see <http://www.gnu.org/licenses/>.
  18 dnl }}}
  19
  20 AC_PREREQ([2.65])
  21 AC_INIT([Cycript], [0.9], [saurik@saurik.com], [cycript], [http://www.cycript.org/])
  22 AC_COPYRIGHT([Copyright (C) 2009-2012  Jay Freeman (saurik)])
  23
  24 AC_CONFIG_SRCDIR([Console.cpp])
  25 AC_CONFIG_AUX_DIR([.])
  26 AC_CONFIG_MACRO_DIR([m4])
  27 AC_CONFIG_HEADERS([config.h])
  28
  29 AM_INIT_AUTOMAKE([-Wall -Werror foreign])
  30
  31 AC_PROG_CXX
  32 AC_PROG_OBJCXX
  33 AM_PROG_AR
  34 AC_PROG_INSTALL
  35
  36 LT_INIT([disable-static])
  37
  38 AC_LANG([C++])
  39
  40 PKG_PROG_PKG_CONFIG([0.22])
  41
  42 AC_PATH_PROG([GIT], [git])
  43 AC_PATH_PROG([TIME], [time])
  44
  45 dnl CY_CHECK_PROGS_VERSION {{{
  46 AC_DEFUN([CY_CHECK_PROGS_VERSION], [
  47     AC_ARG_VAR(]$1[, ]$3[)
  48
  49     AC_MSG_CHECKING(for ]$2[ >= ]$5[)
  50     AC_PATH_PROGS_FEATURE_CHECK(]$1[, ]$2[,
  51         AS_VAR_SET(version, [`$ac_path_]$1[ ]$4[`])
  52         AS_VAR_IF(version, [], ,
  53             AS_VERSION_COMPARE($version, ]$5[, ,
  54                 ac_cv_path_]$1[=$ac_path_]$1[,
  55                 ac_cv_path_]$1[=$ac_path_]$1[))
  56     , AC_MSG_RESULT(no))
  57
  58     AS_IF([true], [
  59         AC_SUBST(]$1[, $ac_cv_path_]$1[)
  60         AC_MSG_RESULT($]$1[)
  61     ], AS_IF([true], [
  62         AC_MSG_ERROR(You need ]$2[ ]$5[ or greater)
  63     ], [
  64         AC_SUBST(]$1[, [:])
  65         AC_MSG_RESULT([no])
  66     ]))
  67 ]) dnl }}}
  68
  69 CY_CHECK_PROGS_VERSION([BISON], [bison], [GNU Project parser generator (yacc replacement)],
  70     [-V | $SED -e '1 s/^bison (GNU Bison) \(.*\)$/\1/p;d'], [2.3])
  71 CY_CHECK_PROGS_VERSION([FLEX], [flex], [the fast lexical analyser generator],
  72     [--version | $SED -e '1 s/^@<:@^0-9.@:>@* \(@<:@0-9.@:>@*\).*$/\1/p;d'], [2.5.33])
  73 CY_CHECK_PROGS_VERSION([GPERF], [gperf], [perfect hash function generator],
  74     [--version | $SED -e '1 s/^.* \(@<:@0-9.@:>@*\)$/\1/p;d'], [3.0.3])
  75 CY_CHECK_PROGS_VERSION([GNUTAR], [tar gtar gnutar], [a very sticky lump of files],
  76     [--version | $SED -e '1 s/^tar (GNU tar) \(.*\)$/\1/p;d'], [1.19])
  77
  78 AC_MSG_CHECKING([bison for %code{}])
  79 echo '%code{}%%_:' >conftest.y
  80 if $BISON conftest.y -o/dev/null 2>/dev/null; then
  81     AC_LIB_APPENDTOVAR([CY_FILTERS], [Bison24])
  82     AC_MSG_RESULT([yes])
  83 else
  84     AC_LIB_APPENDTOVAR([CY_FILTERS], [Bison23])
  85     AC_MSG_RESULT([no])
  86 fi
  87
  88 rm -f conftest.y
  89 AC_SUBST([CY_FILTERS])
  90
  91 dnl CY_TRY {{{
  92 AC_DEFUN([CY_SUCCESS], [cy_good=1])
  93 AC_DEFUN([CY_FAILURE], [cy_good=0])
  94
  95 AC_DEFUN([CY_TRY], [
  96     cy_save=$]$1[
  97         AC_LIB_APPENDTOVAR(]$1[, ]$2[)
  98         ]$3[
  99     ]$1[=$cy_save
 100     AS_IF([test "x$cy_good" = x1], ]$4[, ]$5[)
 101 ]) dnl }}}
 102
 103 AC_DEFUN([CY_TEST_FLAG_], [
 104     AC_LANG_PUSH(]$2[)
 105     AC_MSG_CHECKING([for ]]$4[[ ]]$1[)
 106     CY_TRY(]$3[, $1, [
 107         AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
 108             [CY_SUCCESS], [CY_FAILURE])
 109     ], [
 110         AC_MSG_RESULT([yes])
 111         AC_LIB_APPENDTOVAR(]$3[, ]$1[)
 112     ], [AC_MSG_RESULT([no])])
 113     AC_LANG_POP(]$2[)
 114 ])
 115
 116 AC_DEFUN([CY_TEST_FLAG], [
 117     CY_TEST_FLAG_(]$1[, [C], [CFLAGS], [cc])
 118     CY_TEST_FLAG_(]$1[, [C++], [CXXFLAGS], [c++])
 119     CY_TEST_FLAG_(]$1[, [Objective C++], [OBJCXXFLAGS], [c++ -ObjC])
 120 ])
 121
 122 AX_CFLAGS_WARN_ALL
 123 AX_CXXFLAGS_WARN_ALL
 124
 125 dnl XXX: this is used to support GNU Objective-C struct objc_method
 126 CY_TEST_FLAG([-Wno-deprecated-declarations])
 127
 128 CY_TEST_FLAG([-Wno-dangling-else])
 129 CY_TEST_FLAG([-Wno-overloaded-virtual])
 130 CY_TEST_FLAG([-Wno-parentheses])
 131 CY_TEST_FLAG([-Wno-unneeded-internal-declaration])
 132
 133 dnl -arch * {{{
 134 for cy_arch in ppc ppc64 i386 x86_64 armv6; do
 135     AC_MSG_CHECKING([for -arch $cy_arch])
 136     CY_TRY([CXXFLAGS], ["-arch $cy_arch"], [
 137         AC_TRY_LINK([], [], [CY_SUCCESS], [CY_FAILURE])
 138     ], [
 139         AC_MSG_RESULT([yes])
 140         AC_LIB_APPENDTOVAR([CY_ARCH], ["-arch $cy_arch"])
 141     ], [AC_MSG_RESULT([no])])
 142 done
 143 AC_SUBST([CY_ARCH])
 144 dnl }}}
 145
 146 AC_DEFUN([CY_LT_LIB], [
 147     cy_save=$LIBS
 148     LIBS=
 149     ]$2[
 150     ]$1[=$LIBS
 151     LIBS=$cy_save
 152     AC_SUBST(]$1[)
 153 ])
 154
 155 dnl --enable-javascript {{{
 156 AC_DEFUN([CY_CHECK_JAVASCRIPTCORE], [
 157     AC_CHECK_FRAMEWORK([JavaScriptCore], [
 158         #include <JavaScriptCore/JSBase.h>
 159     ], [
 160         JSEvaluateScript(0, 0, 0, 0, 0, 0);
 161     ], [
 162         AC_SUBST([CY_EXECUTE], [1])
 163     ], [
 164         for cy_webkit_pkg in "webkit-1.0" "WebKitGtk"; do
 165             PKG_CHECK_MODULES([WEBKIT], [$cy_webkit_pkg], [
 166                 AC_SUBST([CY_EXECUTE], [1])
 167                 AC_LIB_APPENDTOVAR([CPPFLAGS], [`$PKG_CONFIG --cflags $cy_webkit_pkg`])
 168                 AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs $cy_webkit_pkg`])
 169             ], [:]); if test "x$CY_EXECUTE" = x1; then break; fi
 170         done
 171     ])
 172 ])
 173
 174 AC_DEFUN([CY_CHECK_JAVASCRIPT], [
 175     CY_CHECK_JAVASCRIPTCORE])
 176
 177 AC_ARG_ENABLE([javascript], [AS_HELP_STRING(
 178     [--enable-javascript@<:@=ENGINE@:>@],
 179     [use a JavaScript runtime (currently the only available option for ENGINE is JavaScriptCore) @<:@default=yes@:>@]
 180 )], [
 181     AS_CASE([$enableval],
 182         [yes], [
 183             CY_CHECK_JAVASCRIPT],
 184         [no], [
 185             AC_SUBST([CY_EXECUTE], [0])],
 186         [JavaScriptCore], [
 187             CY_CHECK_JAVASCRIPTCORE],
 188         [AC_MSG_ERROR([Unknown JavaScript engine: $enableval])])
 189 ], [CY_CHECK_JAVASCRIPT])
 190 dnl }}}
 191
 192 dnl APR_FIND_APR {{{
 193 APR_FIND_APR([], [], [1], [1])
 194 AS_CASE([$apr_found], [yes], [
 195     AC_LIB_APPENDTOVAR([CPPFLAGS], [`$apr_config --includes`])
 196     AC_LIB_APPENDTOVAR([LTLIBAPR], [`$apr_config --link-libtool`])
 197     AC_SUBST([LTLIBAPR])
 198 ], [AC_MSG_ERROR([missing "libapr"])])
 199 dnl }}}
 200
 201 AC_DEFUN([CY_CHECK_PKG_CONFIG_LIBFFI], [
 202     PKG_CHECK_MODULES([LIBFFI], [libffi], [
 203         AC_LIB_APPENDTOVAR([CPPFLAGS], [`$PKG_CONFIG --cflags libffi`])
 204         AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs libffi`])
 205     ], [AC_MSG_ERROR([missing "libffi"])])])
 206
 207 AM_CONDITIONAL([CY_EXECUTE], [test "x$CY_EXECUTE" = x1])
 208
 209 AS_CASE([$CY_EXECUTE], [1], [
 210     AC_CHECK_HEADERS([ffi.h ffi/ffi.h], [break])
 211
 212     CY_LT_LIB([LTLIBFFI], AS_IF([test "x$ac_cv_header_ffi_h" = xno && test "x$ac_cv_header_ffi_ffi_h" = xno], [
 213         CY_CHECK_PKG_CONFIG_LIBFFI
 214     ], [
 215         AC_SEARCH_LIBS([ffi_call], [ffi])
 216         AS_CASE([$ac_cv_search_ffi_call], [no], [CY_CHECK_PKG_CONFIG_LIBFFI])
 217     ]))
 218
 219     AC_LANG_PUSH([Objective C++])
 220
 221     AC_MSG_CHECKING([if we really have Objective C++])
 222     AC_COMPILE_IFELSE([AC_LANG_SOURCE([])], [
 223         CY_OBJECTIVEC=1
 224         AC_MSG_RESULT([yes])
 225     ], [AC_MSG_RESULT([no])])
 226
 227     AS_IF([test "x$CY_OBJECTIVEC" = x1], [
 228         AC_CHECK_FRAMEWORK([CoreFoundation], [
 229             #include <CoreFoundation/CFBase.h>
 230         ], [CFAllocatorGetDefault();], [
 231             AC_SUBST([CY_OBJECTIVEC])
 232
 233             AC_CHECK_FRAMEWORK([Foundation], [
 234                 #include <Foundation/NSObject.h>
 235             ], [[[[NSObject alloc] init];]])
 236
 237             AC_CHECK_FRAMEWORK([WebKit], [
 238                 #include <WebKit/WebScriptObject.h>
 239             ], [[[[WebScriptObject alloc] init];]])
 240         ], [
 241             AC_ARG_VAR([GNUSTEP_CONFIG], [prints information about the current gnustep installation])
 242             AC_CHECK_PROGS([GNUSTEP_CONFIG], [gnustep-config])
 243
 244             AS_IF([test "x$GNUSTEP_CONFIG" != x], [
 245                 AC_SUBST([CY_OBJECTIVEC])
 246                 AC_LIB_APPENDTOVAR([OBJCXXFLAGS], [`$GNUSTEP_CONFIG --objc-flags`])
 247                 AC_LIB_APPENDTOVAR([LIBS], [`$GNUSTEP_CONFIG --base-libs`])
 248             ], [AC_SUBST([CY_OBJECTIVEC], [0])])
 249         ])
 250     ])
 251
 252     AC_LANG_POP([Objective C++])
 253 ])
 254
 255 AM_CONDITIONAL([CY_OBJECTIVEC], [test "x$CY_OBJECTIVEC" = x1])
 256
 257 CY_LT_LIB([LTLIBREADLINE], [AX_LIB_READLINE])
 258 AS_CASE([$ax_cv_lib_readline], [no], [AC_MSG_ERROR([missing "libreadline"])])
 259
 260 CY_LT_LIB([LTLIBTERMCAP], [AC_SEARCH_LIBS([cur_term], [termcap])])
 261
 262 AC_LANG_PUSH([C])
 263 AM_ICONV
 264 AS_CASE([$am_cv_func_iconv], [yes], [], [AC_MSG_ERROR([missing "libiconv"])])
 265 AC_LANG_POP([C])
 266
 267 AC_SUBST([LTFLAGS])
 268 AC_SUBST([SO], [$acl_shlibext])
 269
 270 AS_IF([test "x$CY_EXECUTE" = x1], [
 271     AC_CHECK_HEADER([mach/mach.h], [
 272         AC_CHECK_TOOLS([_LIPO], [lipo], [AC_MSG_ERROR([missing "lipo"])])
 273         AC_CHECK_TOOLS([_NM], [nm], [AC_MSG_ERROR([missing "nm"])])
 274         AC_CHECK_TOOLS([_OTOOL], [otool], [AC_MSG_ERROR([missing "otool"])])
 275         AC_SUBST([CY_ATTACH_GROUP], [procmod])
 276         AC_SUBST([CY_MACH], [1])])])
 277 AM_CONDITIONAL([CY_MACH], [test "x$CY_MACH" = x1])
 278
 279 AC_CONFIG_FILES([Makefile])
 280 AC_OUTPUT