ObjectiveC/Library.mm

   1 #if defined(__APPLE__) && defined(__arm__)
   2 #include <substrate.h>
   3 #else
   4 #include <objc/objc-api.h>
   5 #endif
   6
   7 #ifdef __APPLE__
   8 #include "Struct.hpp"
   9 #endif
  10
  11 #include <Foundation/Foundation.h>
  12
  13 #include "ObjectiveC/Internal.hpp"
  14
  15 #include <objc/Protocol.h>
  16
  17 #include "cycript.hpp"
  18
  19 #include "ObjectiveC/Internal.hpp"
  20
  21 #ifdef __APPLE__
  22 #include <CoreFoundation/CoreFoundation.h>
  23 #include <JavaScriptCore/JSStringRefCF.h>
  24 #include <WebKit/WebScriptObject.h>
  25 #endif
  26
  27 #include "Error.hpp"
  28 #include "JavaScript.hpp"
  29 #include "String.hpp"
  30
  31 #include <cmath>
  32 #include <map>
  33
  34 #define CYObjectiveTry_(context) { \
  35     JSContextRef context_(context); \
  36     try
  37 #define CYObjectiveTry { \
  38     try
  39 #define CYObjectiveCatch \
  40     catch (const CYException &error) { \
  41         @throw CYCastNSObject(NULL, context_, error.CastJSValue(context_)); \
  42     } \
  43 }
  44
  45 #define CYPoolTry { \
  46     id _saved(nil); \
  47     NSAutoreleasePool *_pool([[NSAutoreleasePool alloc] init]); \
  48     @try
  49 #define CYPoolCatch(value) \
  50     @catch (NSException *error) { \
  51         _saved = [error retain]; \
  52         throw CYJSError(context, CYCastJSValue(context, error)); \
  53         return value; \
  54     } @finally { \
  55         [_pool release]; \
  56         if (_saved != nil) \
  57             [_saved autorelease]; \
  58     } \
  59 }
  60
  61 #ifndef __APPLE__
  62 #define class_getSuperclass GSObjCSuper
  63 #define class_getInstanceVariable GSCGetInstanceVariableDefinition
  64 #define class_getName GSNameFromClass
  65
  66 #define class_removeMethods(cls, list) GSRemoveMethodList(cls, list, YES)
  67
  68 #define ivar_getName(ivar) ((ivar)->ivar_name)
  69 #define ivar_getOffset(ivar) ((ivar)->ivar_offset)
  70 #define ivar_getTypeEncoding(ivar) ((ivar)->ivar_type)
  71
  72 #define method_getName(method) ((method)->method_name)
  73 #define method_getImplementation(method) ((method)->method_imp)
  74 #define method_getTypeEncoding(method) ((method)->method_types)
  75 #define method_setImplementation(method, imp) ((void) ((method)->method_imp = (imp)))
  76
  77 #undef objc_getClass
  78 #define objc_getClass GSClassFromName
  79
  80 #define objc_getProtocol GSProtocolFromName
  81
  82 #define object_getClass GSObjCClass
  83
  84 #define object_getInstanceVariable(object, name, value) ({ \
  85     objc_ivar *ivar(class_getInstanceVariable(object_getClass(object), name)); \
  86     if (ivar != NULL) \
  87         GSObjCGetVariable(object, ivar_getOffset(ivar), sizeof(void *), value); \
  88     ivar; \
  89 })
  90
  91 #define object_setIvar(object, ivar, value) ({ \
  92     void *data = (value); \
  93     GSObjCSetVariable(object, ivar_getOffset(ivar), sizeof(void *), &data); \
  94 })
  95
  96 #define protocol_getName(protocol) [(protocol) name]
  97 #endif
  98
  99 JSValueRef CYSendMessage(apr_pool_t *pool, JSContextRef context, id self, Class super, SEL _cmd, size_t count, const JSValueRef arguments[], bool initialize, JSValueRef *exception);
 100
 101 extern sqlite3 *Bridge_;
 102
 103 /* Objective-C Pool Release {{{ */
 104 apr_status_t CYPoolRelease_(void *data) {
 105     id object(reinterpret_cast<id>(data));
 106     [object release];
 107     return APR_SUCCESS;
 108 }
 109
 110 id CYPoolRelease_(apr_pool_t *pool, id object) {
 111     if (object == nil)
 112         return nil;
 113     else if (pool == NULL)
 114         return [object autorelease];
 115     else {
 116         apr_pool_cleanup_register(pool, object, &CYPoolRelease_, &apr_pool_cleanup_null);
 117         return object;
 118     }
 119 }
 120
 121 template <typename Type_>
 122 Type_ CYPoolRelease(apr_pool_t *pool, Type_ object) {
 123     return (Type_) CYPoolRelease_(pool, (id) object);
 124 }
 125 /* }}} */
 126 /* Objective-C Strings {{{ */
 127 const char *CYPoolCString(apr_pool_t *pool, JSContextRef context, NSString *value) {
 128     if (pool == NULL)
 129         return [value UTF8String];
 130     else {
 131         size_t size([value maximumLengthOfBytesUsingEncoding:NSUTF8StringEncoding] + 1);
 132         char *string(new(pool) char[size]);
 133         if (![value getCString:string maxLength:size encoding:NSUTF8StringEncoding])
 134             throw CYJSError(context, "[NSString getCString:maxLength:encoding:] == NO");
 135         return string;
 136     }
 137 }
 138
 139 JSStringRef CYCopyJSString(JSContextRef context, NSString *value) {
 140 #ifdef __APPLE__
 141     return JSStringCreateWithCFString(reinterpret_cast<CFStringRef>(value));
 142 #else
 143     CYPool pool;
 144     return CYCopyJSString(CYPoolCString(pool, context, value));
 145 #endif
 146 }
 147
 148 JSStringRef CYCopyJSString(JSContextRef context, NSObject *value) {
 149     if (value == nil)
 150         return NULL;
 151     // XXX: this definition scares me; is anyone using this?!
 152     NSString *string([value description]);
 153     return CYCopyJSString(context, string);
 154 }
 155
 156 NSString *CYCopyNSString(const CYUTF8String &value) {
 157 #ifdef __APPLE__
 158     return (NSString *) CFStringCreateWithBytes(kCFAllocatorDefault, reinterpret_cast<const UInt8 *>(value.data), value.size, kCFStringEncodingUTF8, true);
 159 #else
 160     return [[NSString alloc] initWithBytes:value.data length:value.size encoding:NSUTF8StringEncoding];
 161 #endif
 162 }
 163
 164 NSString *CYCopyNSString(JSContextRef context, JSStringRef value) {
 165 #ifdef __APPLE__
 166     return (NSString *) JSStringCopyCFString(kCFAllocatorDefault, value);
 167 #else
 168     CYPool pool;
 169     return CYCopyNSString(CYPoolUTF8String(pool, context, value));
 170 #endif
 171 }
 172
 173 NSString *CYCopyNSString(JSContextRef context, JSValueRef value) {
 174     return CYCopyNSString(context, CYJSString(context, value));
 175 }
 176
 177 NSString *CYCastNSString(apr_pool_t *pool, const CYUTF8String &value) {
 178     return CYPoolRelease(pool, CYCopyNSString(value));
 179 }
 180
 181 NSString *CYCastNSString(apr_pool_t *pool, SEL sel) {
 182     const char *name(sel_getName(sel));
 183     return CYPoolRelease(pool, CYCopyNSString(CYUTF8String(name, strlen(name))));
 184 }
 185
 186 NSString *CYCastNSString(apr_pool_t *pool, JSContextRef context, JSStringRef value) {
 187     return CYPoolRelease(pool, CYCopyNSString(context, value));
 188 }
 189
 190 CYUTF8String CYCastUTF8String(NSString *value) {
 191     NSData *data([value dataUsingEncoding:NSUTF8StringEncoding allowLossyConversion:NO]);
 192     return CYUTF8String(reinterpret_cast<const char *>([data bytes]), [data length]);
 193 }
 194 /* }}} */
 195
 196 JSValueRef CYCastJSValue(JSContextRef context, NSObject *value);
 197
 198 void CYThrow(JSContextRef context, NSException *error, JSValueRef *exception) {
 199     if (exception == NULL)
 200         throw error;
 201     *exception = CYCastJSValue(context, error);
 202 }
 203
 204 size_t CYGetIndex(NSString *value) {
 205     return CYGetIndex(CYCastUTF8String(value));
 206 }
 207
 208 bool CYGetOffset(apr_pool_t *pool, JSContextRef context, NSString *value, ssize_t &index) {
 209     return CYGetOffset(CYPoolCString(pool, context, value), index);
 210 }
 211
 212 static JSClassRef Instance_;
 213 static JSClassRef Internal_;
 214 static JSClassRef Message_;
 215 static JSClassRef Messages_;
 216 static JSClassRef Selector_;
 217 static JSClassRef Super_;
 218
 219 static JSClassRef ObjectiveC_Classes_;
 220 static JSClassRef ObjectiveC_Protocols_;
 221
 222 #ifdef __APPLE__
 223 static JSClassRef ObjectiveC_Image_Classes_;
 224 static JSClassRef ObjectiveC_Images_;
 225 #endif
 226
 227 #ifdef __APPLE__
 228 static Class NSCFBoolean_;
 229 static Class NSCFType_;
 230 static Class NSMessageBuilder_;
 231 static Class NSZombie_;
 232 #else
 233 static Class NSBoolNumber_;
 234 #endif
 235
 236 static Class NSArray_;
 237 static Class NSDictionary_;
 238 static Class Object_;
 239
 240 static Type_privateData *Object_type;
 241 static Type_privateData *Selector_type;
 242
 243 Type_privateData *Instance::GetType() const {
 244     return Object_type;
 245 }
 246
 247 Type_privateData *Selector_privateData::GetType() const {
 248     return Selector_type;
 249 }
 250
 251 // XXX: trick this out with associated objects!
 252 JSValueRef CYGetClassPrototype(JSContextRef context, id self) {
 253     if (self == nil)
 254         return CYGetCachedObject(context, CYJSString("Instance_prototype"));
 255
 256     // XXX: I need to think through multi-context
 257     typedef std::map<id, JSValueRef> CacheMap;
 258     static CacheMap cache_;
 259
 260     JSValueRef &value(cache_[self]);
 261     if (value != NULL)
 262         return value;
 263
 264     JSClassRef _class(NULL);
 265     JSValueRef prototype;
 266
 267     if (self == NSArray_)
 268         prototype = CYGetCachedObject(context, CYJSString("Array_prototype"));
 269     else if (self == NSDictionary_)
 270         prototype = CYGetCachedObject(context, CYJSString("Object_prototype"));
 271     else
 272         prototype = CYGetClassPrototype(context, class_getSuperclass(self));
 273
 274     JSObjectRef object(JSObjectMake(context, _class, NULL));
 275     JSObjectSetPrototype(context, object, prototype);
 276
 277     JSValueProtect(context, object);
 278     value = object;
 279     return object;
 280 }
 281
 282 JSObjectRef Messages::Make(JSContextRef context, Class _class, bool array) {
 283     JSObjectRef value(JSObjectMake(context, Messages_, new Messages(_class)));
 284     if (_class == NSArray_)
 285         array = true;
 286     if (Class super = class_getSuperclass(_class))
 287         JSObjectSetPrototype(context, value, Messages::Make(context, super, array));
 288     /*else if (array)
 289         JSObjectSetPrototype(context, value, Array_prototype_);*/
 290     return value;
 291 }
 292
 293 JSObjectRef Internal::Make(JSContextRef context, id object, JSObjectRef owner) {
 294     return JSObjectMake(context, Internal_, new Internal(object, context, owner));
 295 }
 296
 297 namespace cy {
 298 JSObjectRef Super::Make(JSContextRef context, id object, Class _class) {
 299     JSObjectRef value(JSObjectMake(context, Super_, new Super(object, _class)));
 300     return value;
 301 } }
 302
 303 JSObjectRef Instance::Make(JSContextRef context, id object, Flags flags) {
 304     JSObjectRef value(JSObjectMake(context, Instance_, new Instance(object, flags)));
 305     JSObjectSetPrototype(context, value, CYGetClassPrototype(context, object_getClass(object)));
 306     return value;
 307 }
 308
 309 Instance::~Instance() {
 310     if ((flags_ & Transient) == 0)
 311         // XXX: does this handle background threads correctly?
 312         // XXX: this simply does not work on the console because I'm stupid
 313         [GetValue() performSelector:@selector(release) withObject:nil afterDelay:0];
 314 }
 315
 316 struct Message_privateData :
 317     cy::Functor
 318 {
 319     SEL sel_;
 320
 321     Message_privateData(SEL sel, const char *type, IMP value = NULL) :
 322         cy::Functor(type, reinterpret_cast<void (*)()>(value)),
 323         sel_(sel)
 324     {
 325     }
 326 };
 327
 328 JSObjectRef CYMakeInstance(JSContextRef context, id object, bool transient) {
 329     Instance::Flags flags;
 330
 331     if (transient)
 332         flags = Instance::Transient;
 333     else {
 334         flags = Instance::None;
 335         object = [object retain];
 336     }
 337
 338     return Instance::Make(context, object, flags);
 339 }
 340
 341 @interface NSMethodSignature (Cycript)
 342 - (NSString *) _typeString;
 343 @end
 344
 345 @interface NSObject (Cycript)
 346
 347 - (JSValueRef) cy$JSValueInContext:(JSContextRef)context;
 348 - (JSType) cy$JSType;
 349
 350 - (NSObject *) cy$toJSON:(NSString *)key;
 351 - (NSString *) cy$toCYON;
 352 - (NSString *) cy$toKey;
 353
 354 - (bool) cy$hasProperty:(NSString *)name;
 355 - (NSObject *) cy$getProperty:(NSString *)name;
 356 - (bool) cy$setProperty:(NSString *)name to:(NSObject *)value;
 357 - (bool) cy$deleteProperty:(NSString *)name;
 358 - (void) cy$getPropertyNames:(JSPropertyNameAccumulatorRef)names inContext:(JSContextRef)context;
 359
 360 @end
 361
 362 @protocol Cycript
 363 - (JSValueRef) cy$JSValueInContext:(JSContextRef)context;
 364 @end
 365
 366 NSString *CYCastNSCYON(id value) {
 367     NSString *string;
 368
 369     if (value == nil)
 370         string = @"nil";
 371     else {
 372         Class _class(object_getClass(value));
 373         SEL sel(@selector(cy$toCYON));
 374
 375         if (objc_method *toCYON = class_getInstanceMethod(_class, sel))
 376             string = reinterpret_cast<NSString *(*)(id, SEL)>(method_getImplementation(toCYON))(value, sel);
 377         else if (objc_method *methodSignatureForSelector = class_getInstanceMethod(_class, @selector(methodSignatureForSelector:))) {
 378             if (reinterpret_cast<NSMethodSignature *(*)(id, SEL, SEL)>(method_getImplementation(methodSignatureForSelector))(value, @selector(methodSignatureForSelector:), sel) != nil)
 379                 string = [value cy$toCYON];
 380             else goto fail;
 381         } else fail: {
 382             if (false);
 383 #ifdef __APPLE__
 384             else if (value == NSZombie_)
 385                 string = @"_NSZombie_";
 386             else if (_class == NSZombie_)
 387                 string = [NSString stringWithFormat:@"<_NSZombie_: %p>", value];
 388             // XXX: frowny /in/ the pants
 389             else if (value == NSMessageBuilder_ || value == Object_)
 390                 string = nil;
 391 #endif
 392             else
 393                 string = [NSString stringWithFormat:@"%@", value];
 394         }
 395
 396         // XXX: frowny pants
 397         if (string == nil)
 398             string = @"undefined";
 399     }
 400
 401     return string;
 402 }
 403
 404 #ifdef __APPLE__
 405 struct PropertyAttributes {
 406     CYPool pool_;
 407
 408     const char *name;
 409
 410     const char *variable;
 411
 412     const char *getter_;
 413     const char *setter_;
 414
 415     bool readonly;
 416     bool copy;
 417     bool retain;
 418     bool nonatomic;
 419     bool dynamic;
 420     bool weak;
 421     bool garbage;
 422
 423     PropertyAttributes(objc_property_t property) :
 424         variable(NULL),
 425         getter_(NULL),
 426         setter_(NULL),
 427         readonly(false),
 428         copy(false),
 429         retain(false),
 430         nonatomic(false),
 431         dynamic(false),
 432         weak(false),
 433         garbage(false)
 434     {
 435         name = property_getName(property);
 436         const char *attributes(property_getAttributes(property));
 437
 438         for (char *state, *token(apr_strtok(apr_pstrdup(pool_, attributes), ",", &state)); token != NULL; token = apr_strtok(NULL, ",", &state)) {
 439             switch (*token) {
 440                 case 'R': readonly = true; break;
 441                 case 'C': copy = true; break;
 442                 case '&': retain = true; break;
 443                 case 'N': nonatomic = true; break;
 444                 case 'G': getter_ = token + 1; break;
 445                 case 'S': setter_ = token + 1; break;
 446                 case 'V': variable = token + 1; break;
 447             }
 448         }
 449
 450         /*if (variable == NULL) {
 451             variable = property_getName(property);
 452             size_t size(strlen(variable));
 453             char *name(new(pool_) char[size + 2]);
 454             name[0] = '_';
 455             memcpy(name + 1, variable, size);
 456             name[size + 1] = '\0';
 457             variable = name;
 458         }*/
 459     }
 460
 461     const char *Getter() {
 462         if (getter_ == NULL)
 463             getter_ = apr_pstrdup(pool_, name);
 464         return getter_;
 465     }
 466
 467     const char *Setter() {
 468         if (setter_ == NULL && !readonly) {
 469             size_t length(strlen(name));
 470
 471             char *temp(new(pool_) char[length + 5]);
 472             temp[0] = 's';
 473             temp[1] = 'e';
 474             temp[2] = 't';
 475
 476             if (length != 0) {
 477                 temp[3] = toupper(name[0]);
 478                 memcpy(temp + 4, name + 1, length - 1);
 479             }
 480
 481             temp[length + 3] = ':';
 482             temp[length + 4] = '\0';
 483             setter_ = temp;
 484         }
 485
 486         return setter_;
 487     }
 488
 489 };
 490 #endif
 491
 492 #ifdef __APPLE__
 493 NSObject *NSCFType$cy$toJSON(id self, SEL sel, NSString *key) {
 494     return [(NSString *) CFCopyDescription((CFTypeRef) self) autorelease];
 495 }
 496 #endif
 497
 498 #ifndef __APPLE__
 499 @interface CYWebUndefined : NSObject {
 500 }
 501
 502 + (CYWebUndefined *) undefined;
 503
 504 @end
 505
 506 @implementation CYWebUndefined
 507
 508 + (CYWebUndefined *) undefined {
 509     static CYWebUndefined *instance_([[CYWebUndefined alloc] init]);
 510     return instance_;
 511 }
 512
 513 @end
 514
 515 #define WebUndefined CYWebUndefined
 516 #endif
 517
 518 /* Bridge: CYJSObject {{{ */
 519 @interface CYJSObject : NSMutableDictionary {
 520     JSObjectRef object_;
 521     JSContextRef context_;
 522 }
 523
 524 - (id) initWithJSObject:(JSObjectRef)object inContext:(JSContextRef)context;
 525
 526 - (NSObject *) cy$toJSON:(NSString *)key;
 527
 528 - (NSUInteger) count;
 529 - (id) objectForKey:(id)key;
 530 - (NSEnumerator *) keyEnumerator;
 531 - (void) setObject:(id)object forKey:(id)key;
 532 - (void) removeObjectForKey:(id)key;
 533
 534 @end
 535 /* }}} */
 536 /* Bridge: CYJSArray {{{ */
 537 @interface CYJSArray : NSMutableArray {
 538     JSObjectRef object_;
 539     JSContextRef context_;
 540 }
 541
 542 - (id) initWithJSObject:(JSObjectRef)object inContext:(JSContextRef)context;
 543
 544 - (NSUInteger) count;
 545 - (id) objectAtIndex:(NSUInteger)index;
 546
 547 - (void) addObject:(id)anObject;
 548 - (void) insertObject:(id)anObject atIndex:(NSUInteger)index;
 549 - (void) removeLastObject;
 550 - (void) removeObjectAtIndex:(NSUInteger)index;
 551 - (void) replaceObjectAtIndex:(NSUInteger)index withObject:(id)anObject;
 552
 553 @end
 554 /* }}} */
 555
 556 NSObject *CYCastNSObject_(apr_pool_t *pool, JSContextRef context, JSObjectRef object) {
 557     JSObjectRef Array(CYGetCachedObject(context, Array_s));
 558     JSValueRef exception(NULL);
 559     bool array(JSValueIsInstanceOfConstructor(context, object, Array, &exception));
 560     CYThrow(context, exception);
 561     id value(array ? [CYJSArray alloc] : [CYJSObject alloc]);
 562     return CYPoolRelease(pool, [value initWithJSObject:object inContext:context]);
 563 }
 564
 565 NSObject *CYCastNSObject(apr_pool_t *pool, JSContextRef context, JSObjectRef object) {
 566     if (!JSValueIsObjectOfClass(context, object, Instance_))
 567         return CYCastNSObject_(pool, context, object);
 568     else {
 569         Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
 570         return internal->GetValue();
 571     }
 572 }
 573
 574 NSNumber *CYCopyNSNumber(JSContextRef context, JSValueRef value) {
 575     return [[NSNumber alloc] initWithDouble:CYCastDouble(context, value)];
 576 }
 577
 578 #ifndef __APPLE__
 579 @interface NSBoolNumber : NSNumber {
 580 }
 581 @end
 582 #endif
 583
 584 id CYNSObject(apr_pool_t *pool, JSContextRef context, JSValueRef value, bool cast) {
 585     id object;
 586     bool copy;
 587
 588     switch (JSType type = JSValueGetType(context, value)) {
 589         case kJSTypeUndefined:
 590             object = [WebUndefined undefined];
 591             copy = false;
 592         break;
 593
 594         case kJSTypeNull:
 595             return NULL;
 596         break;
 597
 598         case kJSTypeBoolean:
 599 #ifdef __APPLE__
 600             object = (id) (CYCastBool(context, value) ? kCFBooleanTrue : kCFBooleanFalse);
 601             copy = false;
 602 #else
 603             object = [[NSBoolNumber alloc] initWithBool:CYCastBool(context, value)];
 604             copy = true;
 605 #endif
 606         break;
 607
 608         case kJSTypeNumber:
 609             object = CYCopyNSNumber(context, value);
 610             copy = true;
 611         break;
 612
 613         case kJSTypeString:
 614             object = CYCopyNSString(context, value);
 615             copy = true;
 616         break;
 617
 618         case kJSTypeObject:
 619             // XXX: this might could be more efficient
 620             object = CYCastNSObject(pool, context, (JSObjectRef) value);
 621             copy = false;
 622         break;
 623
 624         default:
 625             throw CYJSError(context, "JSValueGetType() == 0x%x", type);
 626         break;
 627     }
 628
 629     if (cast != copy)
 630         return object;
 631     else if (copy)
 632         return CYPoolRelease(pool, object);
 633     else
 634         return [object retain];
 635 }
 636
 637 NSObject *CYCastNSObject(apr_pool_t *pool, JSContextRef context, JSValueRef value) {
 638     return CYNSObject(pool, context, value, true);
 639 }
 640
 641 NSObject *CYCopyNSObject(apr_pool_t *pool, JSContextRef context, JSValueRef value) {
 642     return CYNSObject(pool, context, value, false);
 643 }
 644
 645 /* Bridge: NSArray {{{ */
 646 @implementation NSArray (Cycript)
 647
 648 - (NSString *) cy$toCYON {
 649     NSMutableString *json([[[NSMutableString alloc] init] autorelease]);
 650     [json appendString:@"["];
 651
 652     bool comma(false);
 653 #ifdef __APPLE__
 654     for (id object in self) {
 655 #else
 656     for (size_t index(0), count([self count]); index != count; ++index) {
 657         id object([self objectAtIndex:index]);
 658 #endif
 659         if (comma)
 660             [json appendString:@","];
 661         else
 662             comma = true;
 663         if (object == nil || [object cy$JSType] != kJSTypeUndefined)
 664             [json appendString:CYCastNSCYON(object)];
 665         else {
 666             [json appendString:@","];
 667             comma = false;
 668         }
 669     }
 670
 671     [json appendString:@"]"];
 672     return json;
 673 }
 674
 675 - (bool) cy$hasProperty:(NSString *)name {
 676     if ([name isEqualToString:@"length"])
 677         return true;
 678
 679     size_t index(CYGetIndex(name));
 680     if (index == _not(size_t) || index >= [self count])
 681         return [super cy$hasProperty:name];
 682     else
 683         return true;
 684 }
 685
 686 - (NSObject *) cy$getProperty:(NSString *)name {
 687     if ([name isEqualToString:@"length"]) {
 688         NSUInteger count([self count]);
 689 #ifdef __APPLE__
 690         return [NSNumber numberWithUnsignedInteger:count];
 691 #else
 692         return [NSNumber numberWithUnsignedInt:count];
 693 #endif
 694     }
 695
 696     size_t index(CYGetIndex(name));
 697     if (index == _not(size_t) || index >= [self count])
 698         return [super cy$getProperty:name];
 699     else
 700         return [self objectAtIndex:index];
 701 }
 702
 703 - (void) cy$getPropertyNames:(JSPropertyNameAccumulatorRef)names inContext:(JSContextRef)context {
 704     [super cy$getPropertyNames:names inContext:context];
 705
 706     for (size_t index(0), count([self count]); index != count; ++index) {
 707         id object([self objectAtIndex:index]);
 708         if (object == nil || [object cy$JSType] != kJSTypeUndefined) {
 709             char name[32];
 710             sprintf(name, "%zu", index);
 711             JSPropertyNameAccumulatorAddName(names, CYJSString(name));
 712         }
 713     }
 714 }
 715
 716 @end
 717 /* }}} */
 718 /* Bridge: NSBoolNumber {{{ */
 719 #ifndef __APPLE__
 720 @implementation NSBoolNumber (Cycript)
 721
 722 - (JSType) cy$JSType {
 723     return kJSTypeBoolean;
 724 }
 725
 726 - (NSObject *) cy$toJSON:(NSString *)key {
 727     return self;
 728 }
 729
 730 - (NSString *) cy$toCYON {
 731     return [self boolValue] ? @"true" : @"false";
 732 }
 733
 734 - (JSValueRef) cy$JSValueInContext:(JSContextRef)context { CYObjectiveTry_(context) {
 735     return CYCastJSValue(context, (bool) [self boolValue]);
 736 } CYObjectiveCatch }
 737
 738 @end
 739 #endif
 740 /* }}} */
 741 /* Bridge: NSDictionary {{{ */
 742 @implementation NSDictionary (Cycript)
 743
 744 - (NSString *) cy$toCYON {
 745     NSMutableString *json([[[NSMutableString alloc] init] autorelease]);
 746     [json appendString:@"{"];
 747
 748     bool comma(false);
 749 #ifdef __APPLE__
 750     for (NSObject *key in self) {
 751 #else
 752     NSEnumerator *keys([self keyEnumerator]);
 753     while (NSObject *key = [keys nextObject]) {
 754 #endif
 755         if (comma)
 756             [json appendString:@","];
 757         else
 758             comma = true;
 759         [json appendString:[key cy$toKey]];
 760         [json appendString:@":"];
 761         NSObject *object([self objectForKey:key]);
 762         [json appendString:CYCastNSCYON(object)];
 763     }
 764
 765     [json appendString:@"}"];
 766     return json;
 767 }
 768
 769 - (bool) cy$hasProperty:(NSString *)name {
 770     return [self objectForKey:name] != nil;
 771 }
 772
 773 - (NSObject *) cy$getProperty:(NSString *)name {
 774     return [self objectForKey:name];
 775 }
 776
 777 - (void) cy$getPropertyNames:(JSPropertyNameAccumulatorRef)names inContext:(JSContextRef)context {
 778     [super cy$getPropertyNames:names inContext:context];
 779
 780 #ifdef __APPLE__
 781     for (NSObject *key in self) {
 782 #else
 783     NSEnumerator *keys([self keyEnumerator]);
 784     while (NSObject *key = [keys nextObject]) {
 785 #endif
 786         JSPropertyNameAccumulatorAddName(names, CYJSString(context, key));
 787     }
 788 }
 789
 790 @end
 791 /* }}} */
 792 /* Bridge: NSMutableArray {{{ */
 793 @implementation NSMutableArray (Cycript)
 794
 795 - (bool) cy$setProperty:(NSString *)name to:(NSObject *)value {
 796     if ([name isEqualToString:@"length"]) {
 797         // XXX: is this not intelligent?
 798         NSNumber *number(reinterpret_cast<NSNumber *>(value));
 799 #ifdef __APPLE__
 800         NSUInteger size([number unsignedIntegerValue]);
 801 #else
 802         NSUInteger size([number unsignedIntValue]);
 803 #endif
 804         NSUInteger count([self count]);
 805         if (size < count)
 806             [self removeObjectsInRange:NSMakeRange(size, count - size)];
 807         else if (size != count) {
 808             WebUndefined *undefined([WebUndefined undefined]);
 809             for (size_t i(count); i != size; ++i)
 810                 [self addObject:undefined];
 811         }
 812         return true;
 813     }
 814
 815     size_t index(CYGetIndex(name));
 816     if (index == _not(size_t))
 817         return [super cy$setProperty:name to:value];
 818
 819     id object(value ?: [NSNull null]);
 820
 821     size_t count([self count]);
 822     if (index < count)
 823         [self replaceObjectAtIndex:index withObject:object];
 824     else {
 825         if (index != count) {
 826             WebUndefined *undefined([WebUndefined undefined]);
 827             for (size_t i(count); i != index; ++i)
 828                 [self addObject:undefined];
 829         }
 830
 831         [self addObject:object];
 832     }
 833
 834     return true;
 835 }
 836
 837 - (bool) cy$deleteProperty:(NSString *)name {
 838     size_t index(CYGetIndex(name));
 839     if (index == _not(size_t) || index >= [self count])
 840         return [super cy$deleteProperty:name];
 841     [self replaceObjectAtIndex:index withObject:[WebUndefined undefined]];
 842     return true;
 843 }
 844
 845 @end
 846 /* }}} */
 847 /* Bridge: NSMutableDictionary {{{ */
 848 @implementation NSMutableDictionary (Cycript)
 849
 850 - (bool) cy$setProperty:(NSString *)name to:(NSObject *)value {
 851     [self setObject:(value ?: [NSNull null]) forKey:name];
 852     return true;
 853 }
 854
 855 - (bool) cy$deleteProperty:(NSString *)name {
 856     if ([self objectForKey:name] == nil)
 857         return false;
 858     else {
 859         [self removeObjectForKey:name];
 860         return true;
 861     }
 862 }
 863
 864 @end
 865 /* }}} */
 866 /* Bridge: NSNumber {{{ */
 867 @implementation NSNumber (Cycript)
 868
 869 - (JSType) cy$JSType {
 870 #ifdef __APPLE__
 871     // XXX: this just seems stupid
 872     if ([self class] == NSCFBoolean_)
 873         return kJSTypeBoolean;
 874 #endif
 875     return kJSTypeNumber;
 876 }
 877
 878 - (NSObject *) cy$toJSON:(NSString *)key {
 879     return self;
 880 }
 881
 882 - (NSString *) cy$toCYON {
 883     return [self cy$JSType] != kJSTypeBoolean ? [self stringValue] : [self boolValue] ? @"true" : @"false";
 884 }
 885
 886 - (JSValueRef) cy$JSValueInContext:(JSContextRef)context { CYObjectiveTry_(context) {
 887     return [self cy$JSType] != kJSTypeBoolean ? CYCastJSValue(context, [self doubleValue]) : CYCastJSValue(context, [self boolValue]);
 888 } CYObjectiveCatch }
 889
 890 @end
 891 /* }}} */
 892 /* Bridge: NSNull {{{ */
 893 @implementation NSNull (Cycript)
 894
 895 - (JSType) cy$JSType {
 896     return kJSTypeNull;
 897 }
 898
 899 - (NSObject *) cy$toJSON:(NSString *)key {
 900     return self;
 901 }
 902
 903 - (NSString *) cy$toCYON {
 904     return @"null";
 905 }
 906
 907 @end
 908 /* }}} */
 909 /* Bridge: NSObject {{{ */
 910 @implementation NSObject (Cycript)
 911
 912 - (JSValueRef) cy$JSValueInContext:(JSContextRef)context { CYObjectiveTry_(context) {
 913     return CYMakeInstance(context, self, false);
 914 } CYObjectiveCatch }
 915
 916 - (JSType) cy$JSType {
 917     return kJSTypeObject;
 918 }
 919
 920 - (NSObject *) cy$toJSON:(NSString *)key {
 921     return [self description];
 922 }
 923
 924 - (NSString *) cy$toCYON {
 925     return [[self cy$toJSON:@""] cy$toCYON];
 926 }
 927
 928 - (NSString *) cy$toKey {
 929     return [self cy$toCYON];
 930 }
 931
 932 - (bool) cy$hasProperty:(NSString *)name {
 933     return false;
 934 }
 935
 936 - (NSObject *) cy$getProperty:(NSString *)name {
 937     return nil;
 938 }
 939
 940 - (bool) cy$setProperty:(NSString *)name to:(NSObject *)value {
 941     return false;
 942 }
 943
 944 - (bool) cy$deleteProperty:(NSString *)name {
 945     return false;
 946 }
 947
 948 - (void) cy$getPropertyNames:(JSPropertyNameAccumulatorRef)names inContext:(JSContextRef)context {
 949 }
 950
 951 @end
 952 /* }}} */
 953 /* Bridge: NSProxy {{{ */
 954 @implementation NSProxy (Cycript)
 955
 956 - (NSObject *) cy$toJSON:(NSString *)key {
 957     return [self description];
 958 }
 959
 960 - (NSString *) cy$toCYON {
 961     return [[self cy$toJSON:@""] cy$toCYON];
 962 }
 963
 964 @end
 965 /* }}} */
 966 /* Bridge: NSString {{{ */
 967 @implementation NSString (Cycript)
 968
 969 - (JSType) cy$JSType {
 970     return kJSTypeString;
 971 }
 972
 973 - (NSObject *) cy$toJSON:(NSString *)key {
 974     return self;
 975 }
 976
 977 - (NSString *) cy$toCYON {
 978     std::ostringstream str;
 979     CYUTF8String string(CYCastUTF8String(self));
 980     CYStringify(str, string.data, string.size);
 981     std::string value(str.str());
 982     return CYCastNSString(NULL, CYUTF8String(value.c_str(), value.size()));
 983 }
 984
 985 - (NSString *) cy$toKey {
 986     if (CYIsKey(CYCastUTF8String(self)))
 987         return self;
 988     return [self cy$toCYON];
 989 }
 990
 991 @end
 992 /* }}} */
 993 /* Bridge: WebUndefined {{{ */
 994 @implementation WebUndefined (Cycript)
 995
 996 - (JSType) cy$JSType {
 997     return kJSTypeUndefined;
 998 }
 999
1000 - (NSObject *) cy$toJSON:(NSString *)key {
1001     return self;
1002 }
1003
1004 - (NSString *) cy$toCYON {
1005     return @"undefined";
1006 }
1007
1008 - (JSValueRef) cy$JSValueInContext:(JSContextRef)context { CYObjectiveTry_(context) {
1009     return CYJSUndefined(context);
1010 } CYObjectiveCatch }
1011
1012 @end
1013 /* }}} */
1014
1015 static bool CYIsClass(id self) {
1016 #ifdef __APPLE__
1017     // XXX: this is a lame object_isClass
1018     return class_getInstanceMethod(object_getClass(self), @selector(alloc)) != NULL;
1019 #else
1020     return GSObjCIsClass(self);
1021 #endif
1022 }
1023
1024 Class CYCastClass(apr_pool_t *pool, JSContextRef context, JSValueRef value) {
1025     id self(CYCastNSObject(pool, context, value));
1026     if (CYIsClass(self))
1027         return (Class) self;
1028     throw CYJSError(context, "got something that is not a Class");
1029     return NULL;
1030 }
1031
1032 NSArray *CYCastNSArray(JSContextRef context, JSPropertyNameArrayRef names) {
1033     CYPool pool;
1034     size_t size(JSPropertyNameArrayGetCount(names));
1035     NSMutableArray *array([NSMutableArray arrayWithCapacity:size]);
1036     for (size_t index(0); index != size; ++index)
1037         [array addObject:CYCastNSString(pool, context, JSPropertyNameArrayGetNameAtIndex(names, index))];
1038     return array;
1039 }
1040
1041 JSValueRef CYCastJSValue(JSContextRef context, NSObject *value) { CYPoolTry {
1042     if (value == nil)
1043         return CYJSNull(context);
1044     else if ([value respondsToSelector:@selector(cy$JSValueInContext:)])
1045         return [value cy$JSValueInContext:context];
1046     else
1047         return CYMakeInstance(context, value, false);
1048 } CYPoolCatch(NULL) return /*XXX*/ NULL; }
1049
1050 @implementation CYJSObject
1051
1052 - (id) initWithJSObject:(JSObjectRef)object inContext:(JSContextRef)context { CYObjectiveTry {
1053     if ((self = [super init]) != nil) {
1054         object_ = object;
1055         context_ = CYGetJSContext(context);
1056         //XXX:JSGlobalContextRetain(context_);
1057         JSValueProtect(context_, object_);
1058     } return self;
1059 } CYObjectiveCatch }
1060
1061 - (void) dealloc { CYObjectiveTry {
1062     JSValueUnprotect(context_, object_);
1063     //XXX:JSGlobalContextRelease(context_);
1064     [super dealloc];
1065 } CYObjectiveCatch }
1066
1067 - (NSObject *) cy$toJSON:(NSString *)key { CYObjectiveTry {
1068     JSValueRef toJSON(CYGetProperty(context_, object_, toJSON_s));
1069     if (!CYIsCallable(context_, toJSON))
1070         return [super cy$toJSON:key];
1071     else {
1072         JSValueRef arguments[1] = {CYCastJSValue(context_, key)};
1073         JSValueRef value(CYCallAsFunction(context_, (JSObjectRef) toJSON, object_, 1, arguments));
1074         // XXX: do I really want an NSNull here?!
1075         return CYCastNSObject(NULL, context_, value) ?: [NSNull null];
1076     }
1077 } CYObjectiveCatch }
1078
1079 - (NSString *) cy$toCYON { CYObjectiveTry {
1080     CYPool pool;
1081     JSValueRef exception(NULL);
1082     const char *cyon(CYPoolCCYON(pool, context_, object_));
1083     CYThrow(context_, exception);
1084     if (cyon == NULL)
1085         return [super cy$toCYON];
1086     else
1087         return [NSString stringWithUTF8String:cyon];
1088 } CYObjectiveCatch }
1089
1090 - (NSUInteger) count { CYObjectiveTry {
1091     JSPropertyNameArrayRef names(JSObjectCopyPropertyNames(context_, object_));
1092     size_t size(JSPropertyNameArrayGetCount(names));
1093     JSPropertyNameArrayRelease(names);
1094     return size;
1095 } CYObjectiveCatch }
1096
1097 - (id) objectForKey:(id)key { CYObjectiveTry {
1098     JSValueRef value(CYGetProperty(context_, object_, CYJSString(context_, (NSObject *) key)));
1099     if (JSValueIsUndefined(context_, value))
1100         return nil;
1101     return CYCastNSObject(NULL, context_, value) ?: [NSNull null];
1102 } CYObjectiveCatch }
1103
1104 - (NSEnumerator *) keyEnumerator { CYObjectiveTry {
1105     JSPropertyNameArrayRef names(JSObjectCopyPropertyNames(context_, object_));
1106     NSEnumerator *enumerator([CYCastNSArray(context_, names) objectEnumerator]);
1107     JSPropertyNameArrayRelease(names);
1108     return enumerator;
1109 } CYObjectiveCatch }
1110
1111 - (void) setObject:(id)object forKey:(id)key { CYObjectiveTry {
1112     CYSetProperty(context_, object_, CYJSString(context_, (NSObject *) key), CYCastJSValue(context_, (NSString *) object));
1113 } CYObjectiveCatch }
1114
1115 - (void) removeObjectForKey:(id)key { CYObjectiveTry {
1116     JSValueRef exception(NULL);
1117     (void) JSObjectDeleteProperty(context_, object_, CYJSString(context_, (NSObject *) key), &exception);
1118     CYThrow(context_, exception);
1119 } CYObjectiveCatch }
1120
1121 @end
1122
1123 @implementation CYJSArray
1124
1125 - (id) initWithJSObject:(JSObjectRef)object inContext:(JSContextRef)context { CYObjectiveTry {
1126     if ((self = [super init]) != nil) {
1127         object_ = object;
1128         context_ = CYGetJSContext(context);
1129         //XXX:JSGlobalContextRetain(context_);
1130         JSValueProtect(context_, object_);
1131     } return self;
1132 } CYObjectiveCatch }
1133
1134 - (void) dealloc { CYObjectiveTry {
1135     JSValueUnprotect(context_, object_);
1136     //XXX:JSGlobalContextRelease(context_);
1137     [super dealloc];
1138 } CYObjectiveCatch }
1139
1140 - (NSUInteger) count { CYObjectiveTry {
1141     return CYCastDouble(context_, CYGetProperty(context_, object_, length_s));
1142 } CYObjectiveCatch }
1143
1144 - (id) objectAtIndex:(NSUInteger)index { CYObjectiveTry {
1145     size_t bounds([self count]);
1146     if (index >= bounds)
1147         @throw [NSException exceptionWithName:NSRangeException reason:[NSString stringWithFormat:@"*** -[CYJSArray objectAtIndex:]: index (%zu) beyond bounds (%zu)", index, bounds] userInfo:nil];
1148     JSValueRef exception(NULL);
1149     JSValueRef value(JSObjectGetPropertyAtIndex(context_, object_, index, &exception));
1150     CYThrow(context_, exception);
1151     return CYCastNSObject(NULL, context_, value) ?: [NSNull null];
1152 } CYObjectiveCatch }
1153
1154 - (void) addObject:(id)object { CYObjectiveTry {
1155     JSValueRef exception(NULL);
1156     JSValueRef arguments[1];
1157     arguments[0] = CYCastJSValue(context_, (NSObject *) object);
1158     JSObjectRef Array(CYGetCachedObject(context_, Array_s));
1159     JSObjectCallAsFunction(context_, CYCastJSObject(context_, CYGetProperty(context_, Array, push_s)), object_, 1, arguments, &exception);
1160     CYThrow(context_, exception);
1161 } CYObjectiveCatch }
1162
1163 - (void) insertObject:(id)object atIndex:(NSUInteger)index { CYObjectiveTry {
1164     size_t bounds([self count] + 1);
1165     if (index >= bounds)
1166         @throw [NSException exceptionWithName:NSRangeException reason:[NSString stringWithFormat:@"*** -[CYJSArray insertObject:atIndex:]: index (%zu) beyond bounds (%zu)", index, bounds] userInfo:nil];
1167     JSValueRef exception(NULL);
1168     JSValueRef arguments[3];
1169     arguments[0] = CYCastJSValue(context_, index);
1170     arguments[1] = CYCastJSValue(context_, 0);
1171     arguments[2] = CYCastJSValue(context_, (NSObject *) object);
1172     JSObjectRef Array(CYGetCachedObject(context_, Array_s));
1173     JSObjectCallAsFunction(context_, CYCastJSObject(context_, CYGetProperty(context_, Array, splice_s)), object_, 3, arguments, &exception);
1174     CYThrow(context_, exception);
1175 } CYObjectiveCatch }
1176
1177 - (void) removeLastObject { CYObjectiveTry {
1178     JSValueRef exception(NULL);
1179     JSObjectRef Array(CYGetCachedObject(context_, Array_s));
1180     JSObjectCallAsFunction(context_, CYCastJSObject(context_, CYGetProperty(context_, Array, pop_s)), object_, 0, NULL, &exception);
1181     CYThrow(context_, exception);
1182 } CYObjectiveCatch }
1183
1184 - (void) removeObjectAtIndex:(NSUInteger)index { CYObjectiveTry {
1185     size_t bounds([self count]);
1186     if (index >= bounds)
1187         @throw [NSException exceptionWithName:NSRangeException reason:[NSString stringWithFormat:@"*** -[CYJSArray removeObjectAtIndex:]: index (%zu) beyond bounds (%zu)", index, bounds] userInfo:nil];
1188     JSValueRef exception(NULL);
1189     JSValueRef arguments[2];
1190     arguments[0] = CYCastJSValue(context_, index);
1191     arguments[1] = CYCastJSValue(context_, 1);
1192     JSObjectRef Array(CYGetCachedObject(context_, Array_s));
1193     JSObjectCallAsFunction(context_, CYCastJSObject(context_, CYGetProperty(context_, Array, splice_s)), object_, 2, arguments, &exception);
1194     CYThrow(context_, exception);
1195 } CYObjectiveCatch }
1196
1197 - (void) replaceObjectAtIndex:(NSUInteger)index withObject:(id)object { CYObjectiveTry {
1198     size_t bounds([self count]);
1199     if (index >= bounds)
1200         @throw [NSException exceptionWithName:NSRangeException reason:[NSString stringWithFormat:@"*** -[CYJSArray replaceObjectAtIndex:withObject:]: index (%zu) beyond bounds (%zu)", index, bounds] userInfo:nil];
1201     CYSetProperty(context_, object_, index, CYCastJSValue(context_, (NSObject *) object));
1202 } CYObjectiveCatch }
1203
1204 @end
1205
1206 // XXX: use objc_getAssociatedObject and objc_setAssociatedObject on 10.6
1207 struct CYInternal :
1208     CYData
1209 {
1210     JSObjectRef object_;
1211
1212     CYInternal() :
1213         object_(NULL)
1214     {
1215     }
1216
1217     ~CYInternal() {
1218         // XXX: delete object_? ;(
1219     }
1220
1221     static CYInternal *Get(id self) {
1222         CYInternal *internal(NULL);
1223         if (object_getInstanceVariable(self, "cy$internal_", reinterpret_cast<void **>(&internal)) == NULL) {
1224             // XXX: do something epic? ;P
1225         }
1226
1227         return internal;
1228     }
1229
1230     static CYInternal *Set(id self) {
1231         CYInternal *internal(NULL);
1232         if (objc_ivar *ivar = object_getInstanceVariable(self, "cy$internal_", reinterpret_cast<void **>(&internal))) {
1233             if (internal == NULL) {
1234                 internal = new CYInternal();
1235                 object_setIvar(self, ivar, reinterpret_cast<id>(internal));
1236             }
1237         } else {
1238             // XXX: do something epic? ;P
1239         }
1240
1241         return internal;
1242     }
1243
1244     bool HasProperty(JSContextRef context, JSStringRef name) {
1245         if (object_ == NULL)
1246             return false;
1247         return JSObjectHasProperty(context, object_, name);
1248     }
1249
1250     JSValueRef GetProperty(JSContextRef context, JSStringRef name) {
1251         if (object_ == NULL)
1252             return NULL;
1253         return CYGetProperty(context, object_, name);
1254     }
1255
1256     void SetProperty(JSContextRef context, JSStringRef name, JSValueRef value) {
1257         if (object_ == NULL)
1258             object_ = JSObjectMake(context, NULL, NULL);
1259         CYSetProperty(context, object_, name, value);
1260     }
1261 };
1262
1263 static JSObjectRef CYMakeSelector(JSContextRef context, SEL sel) {
1264     Selector_privateData *internal(new Selector_privateData(sel));
1265     return JSObjectMake(context, Selector_, internal);
1266 }
1267
1268 static SEL CYCastSEL(JSContextRef context, JSValueRef value) {
1269     if (JSValueIsObjectOfClass(context, value, Selector_)) {
1270         Selector_privateData *internal(reinterpret_cast<Selector_privateData *>(JSObjectGetPrivate((JSObjectRef) value)));
1271         return reinterpret_cast<SEL>(internal->value_);
1272     } else
1273         return CYCastPointer<SEL>(context, value);
1274 }
1275
1276 void *CYObjectiveC_ExecuteStart(JSContextRef context) {
1277     // XXX: deal with exceptions!
1278     return (void *) [[NSAutoreleasePool alloc] init];
1279 }
1280
1281 void CYObjectiveC_ExecuteEnd(JSContextRef context, void *handle) {
1282     // XXX: deal with exceptions!
1283     return [(NSAutoreleasePool *) handle release];
1284 }
1285
1286 JSValueRef CYObjectiveC_RuntimeProperty(JSContextRef context, CYUTF8String name) { CYPoolTry {
1287     if (name == "nil")
1288         return Instance::Make(context, nil);
1289     if (Class _class = objc_getClass(name.data))
1290         return CYMakeInstance(context, _class, true);
1291     return NULL;
1292 } CYPoolCatch(NULL) return /*XXX*/ NULL; }
1293
1294 static void CYObjectiveC_CallFunction(JSContextRef context, ffi_cif *cif, void (*function)(), uint8_t *value, void **values) { @try {
1295     ffi_call(cif, function, value, values);
1296 } @catch (NSException *error ) {
1297     throw CYJSError(context, CYCastJSValue(context, error));
1298 } }
1299
1300 static bool CYObjectiveC_PoolFFI(apr_pool_t *pool, JSContextRef context, sig::Type *type, ffi_type *ffi, void *data, JSValueRef value) { @try  {
1301     switch (type->primitive) {
1302         case sig::object_P:
1303         case sig::typename_P:
1304             *reinterpret_cast<id *>(data) = CYCastNSObject(pool, context, value);
1305         break;
1306
1307         case sig::selector_P:
1308             *reinterpret_cast<SEL *>(data) = CYCastSEL(context, value);
1309         break;
1310
1311         default:
1312             return false;
1313     }
1314
1315     return true;
1316 } @catch (NSException *error ) {
1317     throw CYJSError(context, CYCastJSValue(context, error));
1318 } }
1319
1320 static JSValueRef CYObjectiveC_FromFFI(JSContextRef context, sig::Type *type, ffi_type *ffi, void *data, bool initialize, JSObjectRef owner) { CYPoolTry {
1321     switch (type->primitive) {
1322         case sig::object_P:
1323             if (NSObject *object = *reinterpret_cast<NSObject **>(data)) {
1324                 JSValueRef value(CYCastJSValue(context, object));
1325                 if (initialize)
1326                     [object release];
1327                 return value;
1328             } else goto null;
1329
1330         case sig::typename_P:
1331             return CYMakeInstance(context, *reinterpret_cast<Class *>(data), true);
1332
1333         case sig::selector_P:
1334             if (SEL sel = *reinterpret_cast<SEL *>(data))
1335                 return CYMakeSelector(context, sel);
1336             else goto null;
1337
1338         null:
1339             return CYJSNull(context);
1340         default:
1341             return NULL;
1342     }
1343 } CYPoolCatch(NULL) return /*XXX*/ NULL; }
1344
1345 static bool CYImplements(id object, Class _class, SEL selector, bool devoid) {
1346     if (objc_method *method = class_getInstanceMethod(_class, selector)) {
1347         if (!devoid)
1348             return true;
1349 #if OBJC_API_VERSION >= 2
1350         char type[16];
1351         method_getReturnType(method, type, sizeof(type));
1352 #else
1353         const char *type(method_getTypeEncoding(method));
1354 #endif
1355         if (type[0] != 'v')
1356             return true;
1357     }
1358
1359     // XXX: possibly use a more "awesome" check?
1360     return false;
1361 }
1362
1363 static const char *CYPoolTypeEncoding(apr_pool_t *pool, JSContextRef context, SEL sel, objc_method *method) {
1364     if (method != NULL)
1365         return method_getTypeEncoding(method);
1366
1367     const char *name(sel_getName(sel));
1368
1369     sqlite3_stmt *statement;
1370
1371     _sqlcall(sqlite3_prepare(Bridge_,
1372         "select "
1373             "\"bridge\".\"value\" "
1374         "from \"bridge\" "
1375         "where"
1376             " \"bridge\".\"mode\" = -1 and"
1377             " \"bridge\".\"name\" = ?"
1378         " limit 1"
1379     , -1, &statement, NULL));
1380
1381     _trace();
1382     _sqlcall(sqlite3_bind_text(statement, 1, name, -1, SQLITE_STATIC));
1383
1384     const char *value;
1385     if (_sqlcall(sqlite3_step(statement)) == SQLITE_DONE) {
1386     _trace();
1387         value = NULL;}
1388     else {
1389     _trace();
1390         value = sqlite3_column_pooled(pool, statement, 0);
1391         }
1392
1393     _sqlcall(sqlite3_finalize(statement));
1394
1395     if (value != NULL)
1396         return value;
1397 _trace();
1398     return NULL;
1399 }
1400
1401 static void MessageClosure_(ffi_cif *cif, void *result, void **arguments, void *arg) {
1402     Closure_privateData *internal(reinterpret_cast<Closure_privateData *>(arg));
1403
1404     JSContextRef context(internal->context_);
1405
1406     size_t count(internal->cif_.nargs);
1407     JSValueRef values[count];
1408
1409     for (size_t index(0); index != count; ++index)
1410         values[index] = CYFromFFI(context, internal->signature_.elements[1 + index].type, internal->cif_.arg_types[index], arguments[index]);
1411
1412     JSObjectRef _this(CYCastJSObject(context, values[0]));
1413
1414     JSValueRef value(CYCallAsFunction(context, internal->function_, _this, count - 2, values + 2));
1415     CYPoolFFI(NULL, context, internal->signature_.elements[0].type, internal->cif_.rtype, result, value);
1416 }
1417
1418 static JSObjectRef CYMakeMessage(JSContextRef context, SEL sel, IMP imp, const char *type) {
1419     Message_privateData *internal(new Message_privateData(sel, type, imp));
1420     return JSObjectMake(context, Message_, internal);
1421 }
1422
1423 static IMP CYMakeMessage(JSContextRef context, JSValueRef value, const char *type) {
1424     JSObjectRef function(CYCastJSObject(context, value));
1425     Closure_privateData *internal(CYMakeFunctor_(context, function, type, &MessageClosure_));
1426     // XXX: see notes in Library.cpp about needing to leak
1427     return reinterpret_cast<IMP>(internal->GetValue());
1428 }
1429
1430 static bool Messages_hasProperty(JSContextRef context, JSObjectRef object, JSStringRef property) {
1431     Messages *internal(reinterpret_cast<Messages *>(JSObjectGetPrivate(object)));
1432     Class _class(internal->GetValue());
1433
1434     CYPool pool;
1435     const char *name(CYPoolCString(pool, context, property));
1436
1437     if (SEL sel = sel_getUid(name))
1438         if (class_getInstanceMethod(_class, sel) != NULL)
1439             return true;
1440
1441     return false;
1442 }
1443
1444 static JSValueRef Messages_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
1445     Messages *internal(reinterpret_cast<Messages *>(JSObjectGetPrivate(object)));
1446     Class _class(internal->GetValue());
1447
1448     CYPool pool;
1449     const char *name(CYPoolCString(pool, context, property));
1450
1451     if (SEL sel = sel_getUid(name))
1452         if (objc_method *method = class_getInstanceMethod(_class, sel))
1453             return CYMakeMessage(context, sel, method_getImplementation(method), method_getTypeEncoding(method));
1454
1455     return NULL;
1456 }
1457
1458 static bool Messages_setProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef value, JSValueRef *exception) {
1459     Messages *internal(reinterpret_cast<Messages *>(JSObjectGetPrivate(object)));
1460     Class _class(internal->GetValue());
1461
1462     CYPool pool;
1463     const char *name(CYPoolCString(pool, context, property));
1464
1465     SEL sel(sel_registerName(name));
1466
1467     objc_method *method(class_getInstanceMethod(_class, sel));
1468
1469     const char *type;
1470     IMP imp;
1471
1472     if (JSValueIsObjectOfClass(context, value, Message_)) {
1473         Message_privateData *message(reinterpret_cast<Message_privateData *>(JSObjectGetPrivate((JSObjectRef) value)));
1474         type = sig::Unparse(pool, &message->signature_);
1475         imp = reinterpret_cast<IMP>(message->GetValue());
1476     } else {
1477         type = CYPoolTypeEncoding(pool, context, sel, method);
1478         imp = CYMakeMessage(context, value, type);
1479     }
1480
1481     if (method != NULL)
1482         method_setImplementation(method, imp);
1483     else {
1484 #ifdef GNU_RUNTIME
1485         GSMethodList list(GSAllocMethodList(1));
1486         GSAppendMethodToList(list, sel, type, imp, YES);
1487         GSAddMethodList(_class, list, YES);
1488         GSFlushMethodCacheForClass(_class);
1489 #else
1490         class_addMethod(_class, sel, imp, type);
1491 #endif
1492     }
1493
1494     return true;
1495 }
1496
1497 #if 0 && OBJC_API_VERSION < 2
1498 static bool Messages_deleteProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
1499     Messages *internal(reinterpret_cast<Messages *>(JSObjectGetPrivate(object)));
1500     Class _class(internal->GetValue());
1501
1502     CYPool pool;
1503     const char *name(CYPoolCString(pool, context, property));
1504
1505     if (SEL sel = sel_getUid(name))
1506         if (objc_method *method = class_getInstanceMethod(_class, sel)) {
1507             objc_method_list list = {NULL, 1, {method}};
1508             class_removeMethods(_class, &list);
1509             return true;
1510         }
1511
1512     return false;
1513 }
1514 #endif
1515
1516 static void Messages_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
1517     Messages *internal(reinterpret_cast<Messages *>(JSObjectGetPrivate(object)));
1518     Class _class(internal->GetValue());
1519
1520 #if OBJC_API_VERSION >= 2
1521     unsigned int size;
1522     objc_method **data(class_copyMethodList(_class, &size));
1523     for (size_t i(0); i != size; ++i)
1524         JSPropertyNameAccumulatorAddName(names, CYJSString(sel_getName(method_getName(data[i]))));
1525     free(data);
1526 #else
1527     for (objc_method_list *methods(_class->methods); methods != NULL; methods = methods->method_next)
1528         for (int i(0); i != methods->method_count; ++i)
1529             JSPropertyNameAccumulatorAddName(names, CYJSString(sel_getName(method_getName(&methods->method_list[i]))));
1530 #endif
1531 }
1532
1533 static bool Instance_hasProperty(JSContextRef context, JSObjectRef object, JSStringRef property) {
1534     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
1535     id self(internal->GetValue());
1536
1537     if (JSStringIsEqualToUTF8CString(property, "$cyi"))
1538         return true;
1539
1540     CYPool pool;
1541     NSString *name(CYCastNSString(pool, context, property));
1542
1543     if (CYInternal *internal = CYInternal::Get(self))
1544         if (internal->HasProperty(context, property))
1545             return true;
1546
1547     Class _class(object_getClass(self));
1548
1549     CYPoolTry {
1550         // XXX: this is an evil hack to deal with NSProxy; fix elsewhere
1551         if (CYImplements(self, _class, @selector(cy$hasProperty:), false))
1552             if ([self cy$hasProperty:name])
1553                 return true;
1554     } CYPoolCatch(false)
1555
1556     const char *string(CYPoolCString(pool, context, name));
1557
1558 #ifdef __APPLE__
1559     if (class_getProperty(_class, string) != NULL)
1560         return true;
1561 #endif
1562
1563     if (SEL sel = sel_getUid(string))
1564         if (CYImplements(self, _class, sel, true))
1565             return true;
1566
1567     return false;
1568 }
1569
1570 static JSValueRef Instance_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
1571     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
1572     id self(internal->GetValue());
1573
1574     if (JSStringIsEqualToUTF8CString(property, "$cyi"))
1575         return Internal::Make(context, self, object);
1576
1577     CYPool pool;
1578     NSString *name(CYCastNSString(pool, context, property));
1579
1580     if (CYInternal *internal = CYInternal::Get(self))
1581         if (JSValueRef value = internal->GetProperty(context, property))
1582             return value;
1583
1584     CYPoolTry {
1585         if (NSObject *data = [self cy$getProperty:name])
1586             return CYCastJSValue(context, data);
1587     } CYPoolCatch(NULL)
1588
1589     const char *string(CYPoolCString(pool, context, name));
1590     Class _class(object_getClass(self));
1591
1592 #ifdef __APPLE__
1593     if (objc_property_t property = class_getProperty(_class, string)) {
1594         PropertyAttributes attributes(property);
1595         SEL sel(sel_registerName(attributes.Getter()));
1596         return CYSendMessage(pool, context, self, NULL, sel, 0, NULL, false, exception);
1597     }
1598 #endif
1599
1600     if (SEL sel = sel_getUid(string))
1601         if (CYImplements(self, _class, sel, true))
1602             return CYSendMessage(pool, context, self, NULL, sel, 0, NULL, false, exception);
1603
1604     return NULL;
1605 } CYCatch }
1606
1607 static bool Instance_setProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef value, JSValueRef *exception) { CYTry {
1608     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
1609     id self(internal->GetValue());
1610
1611     CYPool pool;
1612
1613     NSString *name(CYCastNSString(pool, context, property));
1614     NSObject *data(CYCastNSObject(pool, context, value));
1615
1616     CYPoolTry {
1617         if ([self cy$setProperty:name to:data])
1618             return true;
1619     } CYPoolCatch(NULL)
1620
1621     const char *string(CYPoolCString(pool, context, name));
1622     Class _class(object_getClass(self));
1623
1624 #ifdef __APPLE__
1625     if (objc_property_t property = class_getProperty(_class, string)) {
1626         PropertyAttributes attributes(property);
1627         if (const char *setter = attributes.Setter()) {
1628             SEL sel(sel_registerName(setter));
1629             JSValueRef arguments[1] = {value};
1630             CYSendMessage(pool, context, self, NULL, sel, 1, arguments, false, exception);
1631             return true;
1632         }
1633     }
1634 #endif
1635
1636     size_t length(strlen(string));
1637
1638     char set[length + 5];
1639
1640     set[0] = 's';
1641     set[1] = 'e';
1642     set[2] = 't';
1643
1644     if (string[0] != '\0') {
1645         set[3] = toupper(string[0]);
1646         memcpy(set + 4, string + 1, length - 1);
1647     }
1648
1649     set[length + 3] = ':';
1650     set[length + 4] = '\0';
1651
1652     if (SEL sel = sel_getUid(set))
1653         if (CYImplements(self, _class, sel, false)) {
1654             JSValueRef arguments[1] = {value};
1655             CYSendMessage(pool, context, self, NULL, sel, 1, arguments, false, exception);
1656         }
1657
1658     if (CYInternal *internal = CYInternal::Set(self)) {
1659         internal->SetProperty(context, property, value);
1660         return true;
1661     }
1662
1663     return false;
1664 } CYCatch }
1665
1666 static bool Instance_deleteProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
1667     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
1668     id self(internal->GetValue());
1669
1670     CYPoolTry {
1671         NSString *name(CYCastNSString(NULL, context, property));
1672         return [self cy$deleteProperty:name];
1673     } CYPoolCatch(NULL)
1674 } CYCatch return /*XXX*/ NULL; }
1675
1676 static void Instance_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
1677     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
1678     id self(internal->GetValue());
1679
1680     CYPool pool;
1681     Class _class(object_getClass(self));
1682
1683 #ifdef __APPLE__
1684     {
1685         unsigned int size;
1686         objc_property_t *data(class_copyPropertyList(_class, &size));
1687         for (size_t i(0); i != size; ++i)
1688             JSPropertyNameAccumulatorAddName(names, CYJSString(property_getName(data[i])));
1689         free(data);
1690     }
1691 #endif
1692
1693     CYPoolTry {
1694         // XXX: this is an evil hack to deal with NSProxy; fix elsewhere
1695         if (CYImplements(self, _class, @selector(cy$getPropertyNames:inContext:), false))
1696             [self cy$getPropertyNames:names inContext:context];
1697     } CYPoolCatch()
1698 }
1699
1700 static JSObjectRef Instance_callAsConstructor(JSContextRef context, JSObjectRef object, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
1701     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
1702     JSObjectRef value(Instance::Make(context, [internal->GetValue() alloc], Instance::Uninitialized));
1703     return value;
1704 } CYCatch }
1705
1706 static bool Instance_hasInstance(JSContextRef context, JSObjectRef constructor, JSValueRef instance, JSValueRef *exception) { CYTry {
1707     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate((JSObjectRef) constructor)));
1708     Class _class(internal->GetValue());
1709     if (!CYIsClass(_class))
1710         return false;
1711
1712     if (JSValueIsObjectOfClass(context, instance, Instance_)) {
1713         Instance *linternal(reinterpret_cast<Instance *>(JSObjectGetPrivate((JSObjectRef) instance)));
1714         // XXX: this isn't always safe
1715         return [linternal->GetValue() isKindOfClass:_class];
1716     }
1717
1718     return false;
1719 } CYCatch }
1720
1721 static bool Internal_hasProperty(JSContextRef context, JSObjectRef object, JSStringRef property) {
1722     Internal *internal(reinterpret_cast<Internal *>(JSObjectGetPrivate(object)));
1723     CYPool pool;
1724
1725     id self(internal->GetValue());
1726     const char *name(CYPoolCString(pool, context, property));
1727
1728     if (object_getInstanceVariable(self, name, NULL) != NULL)
1729         return true;
1730
1731     return false;
1732 }
1733
1734 static JSValueRef Internal_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
1735     Internal *internal(reinterpret_cast<Internal *>(JSObjectGetPrivate(object)));
1736     CYPool pool;
1737
1738     id self(internal->GetValue());
1739     const char *name(CYPoolCString(pool, context, property));
1740
1741     if (objc_ivar *ivar = object_getInstanceVariable(self, name, NULL)) {
1742         Type_privateData type(pool, ivar_getTypeEncoding(ivar));
1743         // XXX: if this fails and throws an exception the person we are throwing it to gets the wrong exception
1744         return CYFromFFI(context, type.type_, type.GetFFI(), reinterpret_cast<uint8_t *>(self) + ivar_getOffset(ivar));
1745     }
1746
1747     return NULL;
1748 } CYCatch }
1749
1750 static bool Internal_setProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef value, JSValueRef *exception) { CYTry {
1751     Internal *internal(reinterpret_cast<Internal *>(JSObjectGetPrivate(object)));
1752     CYPool pool;
1753
1754     id self(internal->GetValue());
1755     const char *name(CYPoolCString(pool, context, property));
1756
1757     if (objc_ivar *ivar = object_getInstanceVariable(self, name, NULL)) {
1758         Type_privateData type(pool, ivar_getTypeEncoding(ivar));
1759         CYPoolFFI(pool, context, type.type_, type.GetFFI(), reinterpret_cast<uint8_t *>(self) + ivar_getOffset(ivar), value);
1760         return true;
1761     }
1762
1763     return false;
1764 } CYCatch }
1765
1766 static void Internal_getPropertyNames_(Class _class, JSPropertyNameAccumulatorRef names) {
1767     if (Class super = class_getSuperclass(_class))
1768         Internal_getPropertyNames_(super, names);
1769
1770 #if OBJC_API_VERSION >= 2
1771     unsigned int size;
1772     objc_ivar **data(class_copyIvarList(_class, &size));
1773     for (size_t i(0); i != size; ++i)
1774         JSPropertyNameAccumulatorAddName(names, CYJSString(ivar_getName(data[i])));
1775     free(data);
1776 #else
1777     if (objc_ivar_list *ivars = _class->ivars)
1778         for (int i(0); i != ivars->ivar_count; ++i)
1779             JSPropertyNameAccumulatorAddName(names, CYJSString(ivar_getName(&ivars->ivar_list[i])));
1780 #endif
1781 }
1782
1783 static void Internal_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
1784     Internal *internal(reinterpret_cast<Internal *>(JSObjectGetPrivate(object)));
1785     CYPool pool;
1786
1787     id self(internal->GetValue());
1788     Class _class(object_getClass(self));
1789
1790     Internal_getPropertyNames_(_class, names);
1791 }
1792
1793 static JSValueRef Internal_callAsFunction_$cya(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
1794     Internal *internal(reinterpret_cast<Internal *>(JSObjectGetPrivate(object)));
1795     return internal->GetOwner();
1796 }
1797
1798 static JSValueRef ObjectiveC_Classes_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
1799     CYPool pool;
1800     NSString *name(CYCastNSString(pool, context, property));
1801     if (Class _class = NSClassFromString(name))
1802         return CYMakeInstance(context, _class, true);
1803     return NULL;
1804 } CYCatch }
1805
1806 static void ObjectiveC_Classes_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
1807 #ifdef __APPLE__
1808     size_t size(objc_getClassList(NULL, 0));
1809     Class *data(reinterpret_cast<Class *>(malloc(sizeof(Class) * size)));
1810
1811   get:
1812     size_t writ(objc_getClassList(data, size));
1813     if (size < writ) {
1814         size = writ;
1815         if (Class *copy = reinterpret_cast<Class *>(realloc(data, sizeof(Class) * writ))) {
1816             data = copy;
1817             goto get;
1818         } else goto done;
1819     }
1820
1821     for (size_t i(0); i != writ; ++i)
1822         JSPropertyNameAccumulatorAddName(names, CYJSString(class_getName(data[i])));
1823
1824   done:
1825     free(data);
1826 #else
1827     void *state(NULL);
1828     while (Class _class = objc_next_class(&state))
1829         JSPropertyNameAccumulatorAddName(names, CYJSString(class_getName(_class)));
1830 #endif
1831 }
1832
1833 #if OBJC_API_VERSION >= 2
1834 static JSValueRef ObjectiveC_Image_Classes_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
1835     const char *internal(reinterpret_cast<const char *>(JSObjectGetPrivate(object)));
1836
1837     CYPool pool;
1838     const char *name(CYPoolCString(pool, context, property));
1839     unsigned int size;
1840     const char **data(objc_copyClassNamesForImage(internal, &size));
1841     JSValueRef value;
1842     for (size_t i(0); i != size; ++i)
1843         if (strcmp(name, data[i]) == 0) {
1844             if (Class _class = objc_getClass(name)) {
1845                 value = CYMakeInstance(context, _class, true);
1846                 goto free;
1847             } else
1848                 break;
1849         }
1850     value = NULL;
1851   free:
1852     free(data);
1853     return value;
1854 } CYCatch }
1855
1856 static void ObjectiveC_Image_Classes_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
1857     const char *internal(reinterpret_cast<const char *>(JSObjectGetPrivate(object)));
1858     unsigned int size;
1859     const char **data(objc_copyClassNamesForImage(internal, &size));
1860     for (size_t i(0); i != size; ++i)
1861         JSPropertyNameAccumulatorAddName(names, CYJSString(data[i]));
1862     free(data);
1863 }
1864
1865 static JSValueRef ObjectiveC_Images_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
1866     CYPool pool;
1867     const char *name(CYPoolCString(pool, context, property));
1868     unsigned int size;
1869     const char **data(objc_copyImageNames(&size));
1870     for (size_t i(0); i != size; ++i)
1871         if (strcmp(name, data[i]) == 0) {
1872             name = data[i];
1873             goto free;
1874         }
1875     name = NULL;
1876   free:
1877     free(data);
1878     if (name == NULL)
1879         return NULL;
1880     JSObjectRef value(JSObjectMake(context, NULL, NULL));
1881     CYSetProperty(context, value, CYJSString("classes"), JSObjectMake(context, ObjectiveC_Image_Classes_, const_cast<char *>(name)));
1882     return value;
1883 } CYCatch }
1884
1885 static void ObjectiveC_Images_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
1886     unsigned int size;
1887     const char **data(objc_copyImageNames(&size));
1888     for (size_t i(0); i != size; ++i)
1889         JSPropertyNameAccumulatorAddName(names, CYJSString(data[i]));
1890     free(data);
1891 }
1892 #endif
1893
1894 static JSValueRef ObjectiveC_Protocols_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
1895     CYPool pool;
1896     const char *name(CYPoolCString(pool, context, property));
1897     if (Protocol *protocol = objc_getProtocol(name))
1898         return CYMakeInstance(context, protocol, true);
1899     return NULL;
1900 } CYCatch }
1901
1902 static void ObjectiveC_Protocols_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
1903 #if OBJC_API_VERSION >= 2
1904     unsigned int size;
1905     Protocol **data(objc_copyProtocolList(&size));
1906     for (size_t i(0); i != size; ++i)
1907         JSPropertyNameAccumulatorAddName(names, CYJSString(protocol_getName(data[i])));
1908     free(data);
1909 #else
1910     // XXX: fix this!
1911 #endif
1912 }
1913
1914 #ifdef __APPLE__
1915 static bool stret(ffi_type *ffi_type) {
1916     return ffi_type->type == FFI_TYPE_STRUCT && (
1917         ffi_type->size > OBJC_MAX_STRUCT_BY_VALUE ||
1918         struct_forward_array[ffi_type->size] != 0
1919     );
1920 }
1921 #endif
1922
1923 JSValueRef CYSendMessage(apr_pool_t *pool, JSContextRef context, id self, Class _class, SEL _cmd, size_t count, const JSValueRef arguments[], bool initialize, JSValueRef *exception) { CYTry {
1924     const char *type;
1925
1926     if (_class == NULL)
1927         _class = object_getClass(self);
1928
1929     IMP imp;
1930
1931     if (objc_method *method = class_getInstanceMethod(_class, _cmd)) {
1932         imp = method_getImplementation(method);
1933         type = method_getTypeEncoding(method);
1934     } else {
1935         imp = NULL;
1936
1937         CYPoolTry {
1938             NSMethodSignature *method([self methodSignatureForSelector:_cmd]);
1939             if (method == nil)
1940                 throw CYJSError(context, "unrecognized selector %s sent to object %p", sel_getName(_cmd), self);
1941             type = CYPoolCString(pool, context, [method _typeString]);
1942         } CYPoolCatch(NULL)
1943     }
1944
1945     void *setup[2];
1946     setup[0] = &self;
1947     setup[1] = &_cmd;
1948
1949     sig::Signature signature;
1950     sig::Parse(pool, &signature, type, &Structor_);
1951
1952     ffi_cif cif;
1953     sig::sig_ffi_cif(pool, &sig::ObjectiveC, &signature, &cif);
1954
1955     if (imp == NULL) {
1956 #ifdef __APPLE__
1957         if (stret(cif.rtype))
1958             imp = class_getMethodImplementation_stret(_class, _cmd);
1959         else
1960             imp = class_getMethodImplementation(_class, _cmd);
1961 #else
1962         objc_super super = {self, _class};
1963         imp = objc_msg_lookup_super(&super, _cmd);
1964 #endif
1965     }
1966
1967     void (*function)() = reinterpret_cast<void (*)()>(imp);
1968     return CYCallFunction(pool, context, 2, setup, count, arguments, initialize, exception, &signature, &cif, function);
1969 } CYCatch }
1970
1971 static JSValueRef $objc_msgSend(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
1972     if (count < 2)
1973         throw CYJSError(context, "too few arguments to objc_msgSend");
1974
1975     CYPool pool;
1976
1977     bool uninitialized;
1978
1979     id self;
1980     SEL _cmd;
1981     Class _class;
1982
1983     if (JSValueIsObjectOfClass(context, arguments[0], Super_)) {
1984         cy::Super *internal(reinterpret_cast<cy::Super *>(JSObjectGetPrivate((JSObjectRef) arguments[0])));
1985         self = internal->GetValue();
1986         _class = internal->class_;;
1987         uninitialized = false;
1988     } else if (JSValueIsObjectOfClass(context, arguments[0], Instance_)) {
1989         Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate((JSObjectRef) arguments[0])));
1990         self = internal->GetValue();
1991         _class = nil;
1992         uninitialized = internal->IsUninitialized();
1993         if (uninitialized)
1994             internal->value_ = nil;
1995     } else {
1996         self = CYCastNSObject(pool, context, arguments[0]);
1997         _class = nil;
1998         uninitialized = false;
1999     }
2000
2001     if (self == nil)
2002         return CYJSNull(context);
2003
2004     _cmd = CYCastSEL(context, arguments[1]);
2005
2006     return CYSendMessage(pool, context, self, _class, _cmd, count - 2, arguments + 2, uninitialized, exception);
2007 } CYCatch }
2008
2009 /* Hook: objc_registerClassPair {{{ */
2010 #if defined(__APPLE__) && defined(__arm__)
2011 // XXX: replace this with associated objects
2012
2013 MSHook(void, CYDealloc, id self, SEL sel) {
2014     CYInternal *internal;
2015     object_getInstanceVariable(self, "cy$internal_", reinterpret_cast<void **>(&internal));
2016     if (internal != NULL)
2017         delete internal;
2018     _CYDealloc(self, sel);
2019 }
2020
2021 MSHook(void, objc_registerClassPair, Class _class) {
2022     Class super(class_getSuperclass(_class));
2023     if (super == NULL || class_getInstanceVariable(super, "cy$internal_") == NULL) {
2024         class_addIvar(_class, "cy$internal_", sizeof(CYInternal *), log2(sizeof(CYInternal *)), "^{CYInternal}");
2025         MSHookMessage(_class, @selector(dealloc), MSHake(CYDealloc));
2026     }
2027
2028     _objc_registerClassPair(_class);
2029 }
2030
2031 static JSValueRef objc_registerClassPair_(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2032     if (count != 1)
2033         throw CYJSError(context, "incorrect number of arguments to objc_registerClassPair");
2034     CYPool pool;
2035     NSObject *value(CYCastNSObject(pool, context, arguments[0]));
2036     if (value == NULL || !CYIsClass(value))
2037         throw CYJSError(context, "incorrect number of arguments to objc_registerClassPair");
2038     Class _class((Class) value);
2039     $objc_registerClassPair(_class);
2040     return CYJSUndefined(context);
2041 } CYCatch }
2042 #endif
2043 /* }}} */
2044
2045 static JSValueRef Selector_callAsFunction(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2046     JSValueRef setup[count + 2];
2047     setup[0] = _this;
2048     setup[1] = object;
2049     memcpy(setup + 2, arguments, sizeof(JSValueRef) * count);
2050     return $objc_msgSend(context, NULL, NULL, count + 2, setup, exception);
2051 }
2052
2053 static JSValueRef Message_callAsFunction(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2054     CYPool pool;
2055     Message_privateData *internal(reinterpret_cast<Message_privateData *>(JSObjectGetPrivate(object)));
2056
2057     // XXX: handle Instance::Uninitialized?
2058     id self(CYCastNSObject(pool, context, _this));
2059
2060     void *setup[2];
2061     setup[0] = &self;
2062     setup[1] = &internal->sel_;
2063
2064     return CYCallFunction(pool, context, 2, setup, count, arguments, false, exception, &internal->signature_, &internal->cif_, internal->GetValue());
2065 }
2066
2067 static JSObjectRef Super_new(JSContextRef context, JSObjectRef object, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2068     if (count != 2)
2069         throw CYJSError(context, "incorrect number of arguments to Super constructor");
2070     CYPool pool;
2071     id self(CYCastNSObject(pool, context, arguments[0]));
2072     Class _class(CYCastClass(pool, context, arguments[1]));
2073     return cy::Super::Make(context, self, _class);
2074 } CYCatch }
2075
2076 static JSObjectRef Selector_new(JSContextRef context, JSObjectRef object, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2077     if (count != 1)
2078         throw CYJSError(context, "incorrect number of arguments to Selector constructor");
2079     CYPool pool;
2080     const char *name(CYPoolCString(pool, context, arguments[0]));
2081     return CYMakeSelector(context, sel_registerName(name));
2082 } CYCatch }
2083
2084 static JSObjectRef Instance_new(JSContextRef context, JSObjectRef object, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2085     if (count > 1)
2086         throw CYJSError(context, "incorrect number of arguments to Instance constructor");
2087     id self(count == 0 ? nil : CYCastPointer<id>(context, arguments[0]));
2088     return Instance::Make(context, self);
2089 } CYCatch }
2090
2091 static JSValueRef CYValue_getProperty_value(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
2092     CYValue *internal(reinterpret_cast<CYValue *>(JSObjectGetPrivate(object)));
2093     return CYCastJSValue(context, reinterpret_cast<uintptr_t>(internal->value_));
2094 }
2095
2096 static JSValueRef CYValue_callAsFunction_$cya(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2097     CYValue *internal(reinterpret_cast<CYValue *>(JSObjectGetPrivate(_this)));
2098     Type_privateData *typical(internal->GetType());
2099
2100     sig::Type *type;
2101     ffi_type *ffi;
2102
2103     if (typical == NULL) {
2104         type = NULL;
2105         ffi = NULL;
2106     } else {
2107         type = typical->type_;
2108         ffi = typical->ffi_;
2109     }
2110
2111     return CYMakePointer(context, &internal->value_, _not(size_t), type, ffi, object);
2112 }
2113
2114 static JSValueRef Instance_getProperty_constructor(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
2115     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
2116     return Instance::Make(context, (id) object_getClass(internal->GetValue()));
2117 }
2118
2119 static JSValueRef Instance_getProperty_protocol(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
2120     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
2121     id self(internal->GetValue());
2122     if (!CYIsClass(self))
2123         return CYJSUndefined(context);
2124     return CYGetClassPrototype(context, self);
2125 } CYCatch }
2126
2127 static JSValueRef Instance_getProperty_messages(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
2128     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
2129     id self(internal->GetValue());
2130     if (!CYIsClass(self))
2131         return CYJSUndefined(context);
2132     return Messages::Make(context, (Class) self);
2133 }
2134
2135 static JSValueRef Instance_callAsFunction_toCYON(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2136     if (!JSValueIsObjectOfClass(context, _this, Instance_))
2137         return NULL;
2138
2139     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(_this)));
2140     return CYCastJSValue(context, CYJSString(context, CYCastNSCYON(internal->GetValue())));
2141 } CYCatch }
2142
2143 static JSValueRef Instance_callAsFunction_toJSON(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2144     if (!JSValueIsObjectOfClass(context, _this, Instance_))
2145         return NULL;
2146
2147     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(_this)));
2148
2149     CYPoolTry {
2150         NSString *key;
2151         if (count == 0)
2152             key = nil;
2153         else
2154             key = CYCastNSString(NULL, context, CYJSString(context, arguments[0]));
2155         // XXX: check for support of cy$toJSON?
2156         return CYCastJSValue(context, CYJSString(context, [internal->GetValue() cy$toJSON:key]));
2157     } CYPoolCatch(NULL)
2158 } CYCatch return /*XXX*/ NULL; }
2159
2160 static JSValueRef Instance_callAsFunction_toString(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2161     if (!JSValueIsObjectOfClass(context, _this, Instance_))
2162         return NULL;
2163
2164     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(_this)));
2165
2166     CYPoolTry {
2167         // XXX: this seems like a stupid implementation; what if it crashes? why not use the CYONifier backend?
2168         return CYCastJSValue(context, CYJSString(context, [internal->GetValue() description]));
2169     } CYPoolCatch(NULL)
2170 } CYCatch return /*XXX*/ NULL; }
2171
2172 static JSValueRef Selector_callAsFunction_toString(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2173     Selector_privateData *internal(reinterpret_cast<Selector_privateData *>(JSObjectGetPrivate(_this)));
2174     return CYCastJSValue(context, sel_getName(internal->GetValue()));
2175 } CYCatch }
2176
2177 static JSValueRef Selector_callAsFunction_toJSON(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2178     return Selector_callAsFunction_toString(context, object, _this, count, arguments, exception);
2179 }
2180
2181 static JSValueRef Selector_callAsFunction_toCYON(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2182     Selector_privateData *internal(reinterpret_cast<Selector_privateData *>(JSObjectGetPrivate(_this)));
2183     const char *name(sel_getName(internal->GetValue()));
2184
2185     CYPoolTry {
2186         NSString *string([NSString stringWithFormat:@"@selector(%s)", name]);
2187         return CYCastJSValue(context, CYJSString(context, string));
2188     } CYPoolCatch(NULL)
2189 } CYCatch return /*XXX*/ NULL; }
2190
2191 static JSValueRef Selector_callAsFunction_type(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2192     if (count != 1)
2193         throw CYJSError(context, "incorrect number of arguments to Selector.type");
2194
2195     CYPool pool;
2196     Selector_privateData *internal(reinterpret_cast<Selector_privateData *>(JSObjectGetPrivate(_this)));
2197     SEL sel(internal->GetValue());
2198
2199     objc_method *method;
2200     if (Class _class = CYCastClass(pool, context, arguments[0]))
2201         method = class_getInstanceMethod(_class, sel);
2202     else
2203         method = NULL;
2204
2205     if (const char *type = CYPoolTypeEncoding(pool, context, sel, method))
2206         return CYCastJSValue(context, CYJSString(type));
2207
2208     return CYJSNull(context);
2209 } CYCatch }
2210
2211 static JSStaticValue Selector_staticValues[2] = {
2212     {"value", &CYValue_getProperty_value, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontDelete},
2213     {NULL, NULL, NULL, 0}
2214 };
2215
2216 static JSStaticValue Instance_staticValues[5] = {
2217     {"constructor", &Instance_getProperty_constructor, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2218     {"messages", &Instance_getProperty_messages, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2219     {"prototype", &Instance_getProperty_protocol, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2220     {"value", &CYValue_getProperty_value, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2221     {NULL, NULL, NULL, 0}
2222 };
2223
2224 static JSStaticFunction Instance_staticFunctions[5] = {
2225     {"$cya", &CYValue_callAsFunction_$cya, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2226     {"toCYON", &Instance_callAsFunction_toCYON, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2227     {"toJSON", &Instance_callAsFunction_toJSON, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2228     {"toString", &Instance_callAsFunction_toString, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2229     {NULL, NULL, 0}
2230 };
2231
2232 static JSStaticFunction Internal_staticFunctions[2] = {
2233     {"$cya", &Internal_callAsFunction_$cya, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2234     {NULL, NULL, 0}
2235 };
2236
2237 static JSStaticFunction Selector_staticFunctions[5] = {
2238     {"toCYON", &Selector_callAsFunction_toCYON, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2239     {"toJSON", &Selector_callAsFunction_toJSON, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2240     {"toString", &Selector_callAsFunction_toString, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2241     {"type", &Selector_callAsFunction_type, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2242     {NULL, NULL, 0}
2243 };
2244
2245 void CYObjectiveC_Initialize() { /*XXX*/ JSContextRef context(NULL); CYPoolTry {
2246     apr_pool_t *pool(CYGetGlobalPool());
2247
2248     Object_type = new(pool) Type_privateData("@");
2249     Selector_type = new(pool) Type_privateData(":");
2250
2251 #ifdef __APPLE__
2252     NSCFBoolean_ = objc_getClass("NSCFBoolean");
2253     NSCFType_ = objc_getClass("NSCFType");
2254     NSMessageBuilder_ = objc_getClass("NSMessageBuilder");
2255     NSZombie_ = objc_getClass("_NSZombie_");
2256 #else
2257     NSBoolNumber_ = objc_getClass("NSBoolNumber");
2258 #endif
2259
2260     NSArray_ = objc_getClass("NSArray");
2261     NSDictionary_ = objc_getClass("NSDictionary");
2262     Object_ = objc_getClass("Object");
2263
2264     JSClassDefinition definition;
2265
2266     definition = kJSClassDefinitionEmpty;
2267     definition.className = "Instance";
2268     definition.staticValues = Instance_staticValues;
2269     definition.staticFunctions = Instance_staticFunctions;
2270     definition.hasProperty = &Instance_hasProperty;
2271     definition.getProperty = &Instance_getProperty;
2272     definition.setProperty = &Instance_setProperty;
2273     definition.deleteProperty = &Instance_deleteProperty;
2274     definition.getPropertyNames = &Instance_getPropertyNames;
2275     definition.callAsConstructor = &Instance_callAsConstructor;
2276     definition.hasInstance = &Instance_hasInstance;
2277     definition.finalize = &CYFinalize;
2278     Instance_ = JSClassCreate(&definition);
2279
2280     definition = kJSClassDefinitionEmpty;
2281     definition.className = "Internal";
2282     definition.staticFunctions = Internal_staticFunctions;
2283     definition.hasProperty = &Internal_hasProperty;
2284     definition.getProperty = &Internal_getProperty;
2285     definition.setProperty = &Internal_setProperty;
2286     definition.getPropertyNames = &Internal_getPropertyNames;
2287     definition.finalize = &CYFinalize;
2288     Internal_ = JSClassCreate(&definition);
2289
2290     definition = kJSClassDefinitionEmpty;
2291     definition.className = "Message";
2292     definition.staticFunctions = cy::Functor::StaticFunctions;
2293     definition.callAsFunction = &Message_callAsFunction;
2294     definition.finalize = &CYFinalize;
2295     Message_ = JSClassCreate(&definition);
2296
2297     definition = kJSClassDefinitionEmpty;
2298     definition.className = "Messages";
2299     definition.hasProperty = &Messages_hasProperty;
2300     definition.getProperty = &Messages_getProperty;
2301     definition.setProperty = &Messages_setProperty;
2302 #if 0 && OBJC_API_VERSION < 2
2303     definition.deleteProperty = &Messages_deleteProperty;
2304 #endif
2305     definition.getPropertyNames = &Messages_getPropertyNames;
2306     definition.finalize = &CYFinalize;
2307     Messages_ = JSClassCreate(&definition);
2308
2309     definition = kJSClassDefinitionEmpty;
2310     definition.className = "Selector";
2311     definition.staticValues = Selector_staticValues;
2312     definition.staticFunctions = Selector_staticFunctions;
2313     definition.callAsFunction = &Selector_callAsFunction;
2314     definition.finalize = &CYFinalize;
2315     Selector_ = JSClassCreate(&definition);
2316
2317     definition = kJSClassDefinitionEmpty;
2318     definition.className = "Super";
2319     definition.staticFunctions = Internal_staticFunctions;
2320     definition.finalize = &CYFinalize;
2321     Super_ = JSClassCreate(&definition);
2322
2323     definition = kJSClassDefinitionEmpty;
2324     definition.className = "ObjectiveC::Classes";
2325     definition.getProperty = &ObjectiveC_Classes_getProperty;
2326     definition.getPropertyNames = &ObjectiveC_Classes_getPropertyNames;
2327     ObjectiveC_Classes_ = JSClassCreate(&definition);
2328
2329 #if OBJC_API_VERSION >= 2
2330     definition = kJSClassDefinitionEmpty;
2331     definition.className = "ObjectiveC::Images";
2332     definition.getProperty = &ObjectiveC_Images_getProperty;
2333     definition.getPropertyNames = &ObjectiveC_Images_getPropertyNames;
2334     ObjectiveC_Images_ = JSClassCreate(&definition);
2335
2336     definition = kJSClassDefinitionEmpty;
2337     definition.className = "ObjectiveC::Image::Classes";
2338     definition.getProperty = &ObjectiveC_Image_Classes_getProperty;
2339     definition.getPropertyNames = &ObjectiveC_Image_Classes_getPropertyNames;
2340     ObjectiveC_Image_Classes_ = JSClassCreate(&definition);
2341 #endif
2342
2343     definition = kJSClassDefinitionEmpty;
2344     definition.className = "ObjectiveC::Protocols";
2345     definition.getProperty = &ObjectiveC_Protocols_getProperty;
2346     definition.getPropertyNames = &ObjectiveC_Protocols_getPropertyNames;
2347     ObjectiveC_Protocols_ = JSClassCreate(&definition);
2348
2349 #if defined(__APPLE__) && defined(__arm__)
2350     MSHookFunction(&objc_registerClassPair, MSHake(objc_registerClassPair));
2351 #endif
2352
2353 #ifdef __APPLE__
2354     class_addMethod(NSCFType_, @selector(cy$toJSON:), reinterpret_cast<IMP>(&NSCFType$cy$toJSON), "@12@0:4@8");
2355 #endif
2356 } CYPoolCatch() }
2357
2358 void CYObjectiveC_SetupContext(JSContextRef context) { CYPoolTry {
2359     JSObjectRef global(CYGetGlobalObject(context));
2360     JSObjectRef cy(CYCastJSObject(context, CYGetProperty(context, global, cy_s)));
2361
2362     JSObjectRef ObjectiveC(JSObjectMake(context, NULL, NULL));
2363     CYSetProperty(context, global, CYJSString("ObjectiveC"), ObjectiveC);
2364
2365     CYSetProperty(context, ObjectiveC, CYJSString("classes"), JSObjectMake(context, ObjectiveC_Classes_, NULL));
2366     CYSetProperty(context, ObjectiveC, CYJSString("protocols"), JSObjectMake(context, ObjectiveC_Protocols_, NULL));
2367
2368 #if OBJC_API_VERSION >= 2
2369     CYSetProperty(context, ObjectiveC, CYJSString("images"), JSObjectMake(context, ObjectiveC_Images_, NULL));
2370 #endif
2371
2372     JSObjectRef Instance(JSObjectMakeConstructor(context, Instance_, &Instance_new));
2373     JSObjectRef Message(JSObjectMakeConstructor(context, Message_, NULL));
2374     JSObjectRef Selector(JSObjectMakeConstructor(context, Selector_, &Selector_new));
2375     JSObjectRef Super(JSObjectMakeConstructor(context, Super_, &Super_new));
2376
2377     JSObjectRef Instance_prototype(CYCastJSObject(context, CYGetProperty(context, Instance, prototype_s)));
2378     CYSetProperty(context, cy, CYJSString("Instance_prototype"), Instance_prototype);
2379
2380     CYSetProperty(context, global, CYJSString("Instance"), Instance);
2381     CYSetProperty(context, global, CYJSString("Selector"), Selector);
2382     CYSetProperty(context, global, CYJSString("Super"), Super);
2383
2384 #if defined(__APPLE__) && defined(__arm__)
2385     CYSetProperty(context, global, CYJSString("objc_registerClassPair"), JSObjectMakeFunctionWithCallback(context, CYJSString("objc_registerClassPair"), &objc_registerClassPair_));
2386 #endif
2387
2388     CYSetProperty(context, global, CYJSString("objc_msgSend"), JSObjectMakeFunctionWithCallback(context, CYJSString("objc_msgSend"), &$objc_msgSend));
2389
2390     JSObjectRef Function_prototype(CYGetCachedObject(context, CYJSString("Function_prototype")));
2391     JSObjectSetPrototype(context, CYCastJSObject(context, CYGetProperty(context, Message, prototype_s)), Function_prototype);
2392     JSObjectSetPrototype(context, CYCastJSObject(context, CYGetProperty(context, Selector, prototype_s)), Function_prototype);
2393 } CYPoolCatch() }
2394
2395 static CYHooks CYObjectiveCHooks = {
2396     &CYObjectiveC_ExecuteStart,
2397     &CYObjectiveC_ExecuteEnd,
2398     &CYObjectiveC_RuntimeProperty,
2399     &CYObjectiveC_CallFunction,
2400     &CYObjectiveC_Initialize,
2401     &CYObjectiveC_SetupContext,
2402     &CYObjectiveC_PoolFFI,
2403     &CYObjectiveC_FromFFI,
2404 };
2405
2406 struct CYObjectiveC {
2407     CYObjectiveC() {
2408         hooks_ = &CYObjectiveCHooks;
2409     }
2410 } CYObjectiveC;