configure.ac

   1 dnl Cycript - Optimizing JavaScript Compiler/Runtime
   2 dnl Copyright (C) 2009-2014  Jay Freeman (saurik)
   3
   4 dnl GNU Affero General Public License, Version 3 {{{
   5 dnl
   6 dnl This program is free software: you can redistribute it and/or modify
   7 dnl it under the terms of the GNU Affero General Public License as published by
   8 dnl the Free Software Foundation, either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU Affero General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU Affero General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18 dnl }}}
  19
  20 AC_PREREQ([2.65])
  21 AC_INIT([Cycript], [0.9], [saurik@saurik.com], [cycript], [http://www.cycript.org/])
  22 AC_COPYRIGHT([Copyright (C) 2009-2014  Jay Freeman (saurik)])
  23
  24 AC_CONFIG_SRCDIR([Console.cpp])
  25 AC_CONFIG_AUX_DIR([.])
  26 AC_CONFIG_MACRO_DIR([m4])
  27 AC_CONFIG_HEADERS([config.h])
  28
  29 AM_INIT_AUTOMAKE([-Wall -Werror foreign])
  30 AM_MAINTAINER_MODE([disable])
  31
  32 AC_PROG_CC
  33 AC_PROG_CXX
  34 AC_PROG_OBJCXX
  35
  36 AM_PROG_AR
  37 AC_PROG_INSTALL
  38
  39 LT_INIT([disable-static])
  40
  41 AC_LANG([C++])
  42
  43 AX_CXX_COMPILE_STDCXX_11([ext], [mandatory])
  44 OBJCXXFLAGS="${OBJCXXFLAGS} ${CXXFLAGS##*' '}"
  45
  46 PKG_PROG_PKG_CONFIG([0.22])
  47
  48 AC_PATH_PROG([GIT], [git])
  49 AC_PATH_PROG([TIME], [time])
  50
  51 dnl CY_CHECK_PROGS_VERSION {{{
  52 AC_DEFUN([CY_CHECK_PROGS_VERSION], [
  53     AC_ARG_VAR(]$1[, ]$3[)
  54
  55     AC_MSG_CHECKING(for ]$2[ >= ]$5[)
  56     AC_PATH_PROGS_FEATURE_CHECK(]$1[, ]$2[,
  57         AS_VAR_SET(version, [`$ac_path_]$1[ ]$4[`])
  58         AS_VAR_IF(version, [], ,
  59             AS_VERSION_COMPARE($version, ]$5[, ,
  60                 ac_cv_path_]$1[=$ac_path_]$1[,
  61                 ac_cv_path_]$1[=$ac_path_]$1[))
  62     , AC_MSG_RESULT(no))
  63
  64     AS_IF([true], [
  65         AC_SUBST(]$1[, $ac_cv_path_]$1[)
  66         AC_MSG_RESULT($]$1[)
  67     ], AS_IF([true], [
  68         AC_MSG_ERROR(You need ]$2[ ]$5[ or greater)
  69     ], [
  70         AC_SUBST(]$1[, [:])
  71         AC_MSG_RESULT([no])
  72     ]))
  73 ]) dnl }}}
  74
  75 CY_CHECK_PROGS_VERSION([BISON], [bison], [GNU Project parser generator (yacc replacement)],
  76     [-V | $SED -e '1 s/^bison (GNU Bison) \(.*\)$/\1/p;d'], [3.0])
  77 CY_CHECK_PROGS_VERSION([FLEX], [flex], [the fast lexical analyser generator],
  78     [--version | $SED -e '1 s/^@<:@^0-9.@:>@* \(@<:@0-9.@:>@*\).*$/\1/p;d'], [2.5.33])
  79 CY_CHECK_PROGS_VERSION([GPERF], [gperf], [perfect hash function generator],
  80     [--version | $SED -e '1 s/^.* \(@<:@0-9.@:>@*\)$/\1/p;d'], [3.0.3])
  81 CY_CHECK_PROGS_VERSION([GNUTAR], [tar gtar gnutar], [a very sticky lump of files],
  82     [--version | $SED -e '1 s/^tar (GNU tar) \(.*\)$/\1/p;d'], [1.19])
  83
  84 dnl CY_TRY {{{
  85 AC_DEFUN([CY_SUCCESS], [cy_good=1])
  86 AC_DEFUN([CY_FAILURE], [cy_good=0])
  87
  88 AC_DEFUN([CY_TRY], [
  89     cy_save=$]$1[
  90         AC_LIB_APPENDTOVAR(]$1[, ]$2[)
  91         ]$3[
  92     ]$1[=$cy_save
  93     AS_IF([test "x$cy_good" = x1], ]$4[, ]$5[)
  94 ]) dnl }}}
  95
  96 AC_DEFUN([CY_TEST_FLAG_], [
  97     AC_LANG_PUSH(]$2[)
  98     AC_MSG_CHECKING([for ]]$4[[ ]]$1[)
  99     CY_TRY(]$3[, $1, [
 100         AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
 101             [CY_SUCCESS], [CY_FAILURE])
 102     ], [
 103         AC_MSG_RESULT([yes])
 104         AC_LIB_APPENDTOVAR(]$3[, ]$1[)
 105     ], [AC_MSG_RESULT([no])])
 106     AC_LANG_POP(]$2[)
 107 ])
 108
 109 AC_DEFUN([CY_TEST_FLAG], [
 110     CY_TEST_FLAG_(]$1[, [C], [CFLAGS], [cc])
 111     CY_TEST_FLAG_(]$1[, [C++], [CXXFLAGS], [c++])
 112     CY_TEST_FLAG_(]$1[, [Objective C++], [OBJCXXFLAGS], [c++ -ObjC])
 113 ])
 114
 115 AX_CFLAGS_WARN_ALL
 116 AX_CXXFLAGS_WARN_ALL
 117 AX_FLAGS_WARN_ALL
 118
 119 CY_TEST_FLAG([-Werror])
 120
 121 dnl XXX: this is used to support GNU Objective-C struct objc_method
 122 CY_TEST_FLAG([-Wno-deprecated-declarations])
 123
 124 CY_TEST_FLAG([-Wno-dangling-else])
 125 CY_TEST_FLAG([-Wno-overloaded-virtual])
 126 CY_TEST_FLAG([-Wno-parentheses])
 127 CY_TEST_FLAG([-Wno-unneeded-internal-declaration])
 128
 129 AX_PTHREAD
 130
 131 AC_DEFUN([CY_LT_LIB], [
 132     cy_save=$LIBS
 133     LIBS=
 134     ]$2[
 135     ]$1[=$LIBS
 136     LIBS=$cy_save
 137     AC_SUBST(]$1[)
 138 ])
 139
 140 dnl -arch * {{{
 141 for cy_arch in ppc ppc64 i386 x86_64 armv6 arm64; do
 142     AC_MSG_CHECKING([for -arch $cy_arch])
 143     CY_TRY([CXXFLAGS], ["-arch $cy_arch"], [
 144         AC_TRY_LINK([], [], [CY_SUCCESS], [CY_FAILURE])
 145     ], [
 146         AC_MSG_RESULT([yes])
 147         AC_LIB_APPENDTOVAR([CY_ARCH], ["-arch $cy_arch"])
 148     ], [AC_MSG_RESULT([no])])
 149 done
 150 AC_SUBST([CY_ARCH])
 151 dnl }}}
 152
 153 dnl --enable-javascript {{{
 154 AC_DEFUN([CY_CHECK_JAVASCRIPTCORE], [
 155     CY_LT_LIB([LTJAVASCRIPTCORE], [AC_SEARCH_LIBS([JSEvaluateScript], [JavaScriptCore], [
 156         AC_SUBST([CY_EXECUTE], [1])
 157     ], [AC_CHECK_FRAMEWORK([JavaScriptCore], [
 158         #include <JavaScriptCore/JSBase.h>
 159     ], [
 160         JSEvaluateScript(0, 0, 0, 0, 0, 0);
 161     ], [
 162         AC_SUBST([CY_EXECUTE], [1])
 163     ], [
 164         for cy_webkit_pkg in "webkit-1.0" "WebKitGtk"; do
 165             PKG_CHECK_MODULES([WEBKIT], [$cy_webkit_pkg], [
 166                 AC_SUBST([CY_EXECUTE], [1])
 167                 AC_LIB_APPENDTOVAR([CPPFLAGS], [`$PKG_CONFIG --cflags $cy_webkit_pkg`])
 168                 AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs $cy_webkit_pkg`])
 169             ], [:]); if test "x$CY_EXECUTE" = x1; then break; fi
 170         done
 171     ])])])
 172 ])
 173
 174 AC_DEFUN([CY_CHECK_JAVASCRIPT], [
 175     CY_CHECK_JAVASCRIPTCORE])
 176
 177 AC_ARG_ENABLE([javascript], [AS_HELP_STRING(
 178     [--enable-javascript@<:@=ENGINE@:>@],
 179     [use a JavaScript runtime (currently the only available option for ENGINE is JavaScriptCore) @<:@default=yes@:>@]
 180 )], [
 181     AS_CASE([$enableval],
 182         [yes], [
 183             CY_CHECK_JAVASCRIPT],
 184         [no], [
 185             AC_SUBST([CY_EXECUTE], [0])],
 186         [JavaScriptCore], [
 187             CY_CHECK_JAVASCRIPTCORE],
 188         [AC_MSG_ERROR([Unknown JavaScript engine: $enableval])])
 189 ], [CY_CHECK_JAVASCRIPT])
 190 dnl }}}
 191
 192 AC_ARG_ENABLE([console], AS_HELP_STRING([--disable-console], [disable console]))
 193 AM_CONDITIONAL([CY_CONSOLE], [test "x$enable_console" != "xno"])
 194
 195 AC_DEFUN([CY_CHECK_PKG_CONFIG_LIBFFI], [
 196     PKG_CHECK_MODULES([LIBFFI], [libffi], [
 197         AC_LIB_APPENDTOVAR([CPPFLAGS], [`$PKG_CONFIG --cflags libffi`])
 198         AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs libffi`])
 199     ], [AC_MSG_ERROR([missing "libffi"])])])
 200
 201 AM_CONDITIONAL([CY_EXECUTE], [test "x$CY_EXECUTE" = x1])
 202
 203 AS_CASE([$CY_EXECUTE], [1], [
 204     AC_CHECK_HEADERS([ffi.h ffi/ffi.h], [break])
 205
 206     CY_LT_LIB([LTLIBFFI], AS_IF([test "x$ac_cv_header_ffi_h" = xno && test "x$ac_cv_header_ffi_ffi_h" = xno], [
 207         CY_CHECK_PKG_CONFIG_LIBFFI
 208     ], [
 209         AC_SEARCH_LIBS([ffi_call], [ffi])
 210         AS_CASE([$ac_cv_search_ffi_call], [no], [CY_CHECK_PKG_CONFIG_LIBFFI])
 211     ]))
 212
 213     AC_CHECK_HEADER([jni.h], [
 214         AC_SUBST([CY_JAVA], [1])
 215         CY_LT_LIB([LTJAVA], [AC_SEARCH_LIBS([JNI_GetCreatedJavaVMs], [dvm], [
 216         ])])
 217     ], [
 218         AC_SUBST([CY_JAVA], [0])
 219     ])
 220
 221     AC_LANG_PUSH([Objective C++])
 222
 223     AC_MSG_CHECKING([if we really have Objective C++])
 224     AC_COMPILE_IFELSE([AC_LANG_SOURCE([])], [
 225         CY_OBJECTIVEC=1
 226         AC_MSG_RESULT([yes])
 227     ], [AC_MSG_RESULT([no])])
 228
 229     AS_IF([test "x$CY_OBJECTIVEC" = x1], [
 230         CY_LT_LIB([LTOBJECTIVEC], [AC_CHECK_FRAMEWORK([CoreFoundation], [
 231             #include <CoreFoundation/CFBase.h>
 232         ], [CFAllocatorGetDefault();], [
 233             AC_SUBST([CY_OBJECTIVEC])
 234
 235             AC_CHECK_FRAMEWORK([Foundation], [
 236                 #include <Foundation/NSObject.h>
 237             ], [[[[NSObject alloc] init];]])
 238         ], [
 239             AC_ARG_VAR([GNUSTEP_CONFIG], [prints information about the current gnustep installation])
 240             AC_CHECK_PROGS([GNUSTEP_CONFIG], [gnustep-config])
 241
 242             AS_IF([test "x$GNUSTEP_CONFIG" != x], [
 243                 AC_SUBST([CY_OBJECTIVEC])
 244                 AC_LIB_APPENDTOVAR([OBJCXXFLAGS], [`$GNUSTEP_CONFIG --objc-flags`])
 245                 AC_LIB_APPENDTOVAR([LIBS], [`$GNUSTEP_CONFIG --base-libs`])
 246             ], [AC_SUBST([CY_OBJECTIVEC], [0])])
 247         ])])
 248     ])
 249
 250     AC_LANG_POP([Objective C++])
 251 ])
 252
 253 AM_CONDITIONAL([CY_JAVA], [test "x$CY_JAVA" = x1])
 254 AM_CONDITIONAL([CY_OBJECTIVEC], [test "x$CY_OBJECTIVEC" = x1])
 255
 256 CY_LT_LIB([LTLIBREADLINE], [AX_LIB_READLINE])
 257 AS_CASE([$ax_cv_lib_readline], [no], [AC_MSG_ERROR([missing "libreadline"])])
 258
 259 CY_LT_LIB([LTLIBTERMCAP], [AC_SEARCH_LIBS([cur_term], [termcap ncurses])])
 260
 261 AC_SUBST([LTLIBGCC])
 262
 263 AC_SUBST([LTFLAGS])
 264 AC_SUBST([SO], [$acl_shlibext])
 265
 266 AS_IF([test "x$CY_EXECUTE" = x1], [
 267     AC_CHECK_HEADER([mach/mach.h], [
 268         AC_CHECK_TOOLS([_LIPO], [lipo], [AC_MSG_ERROR([missing "lipo"])])
 269         AC_CHECK_TOOLS([_NM], [nm], [AC_MSG_ERROR([missing "nm"])])
 270         AC_CHECK_TOOLS([_OTOOL], [otool], [AC_MSG_ERROR([missing "otool"])])
 271         AC_SUBST([CY_ATTACH_GROUP], [procmod])
 272         AC_SUBST([CY_MACH], [1])])])
 273 AM_CONDITIONAL([CY_MACH], [test "x$CY_MACH" = x1])
 274
 275 AC_CONFIG_FILES([Makefile])
 276 AC_OUTPUT