configure.ac

   1 dnl Cycript - Optimizing JavaScript Compiler/Runtime
   2 dnl Copyright (C) 2009-2015  Jay Freeman (saurik)
   3
   4 dnl GNU Affero General Public License, Version 3 {{{
   5 dnl
   6 dnl This program is free software: you can redistribute it and/or modify
   7 dnl it under the terms of the GNU Affero General Public License as published by
   8 dnl the Free Software Foundation, either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU Affero General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU Affero General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18 dnl }}}
  19
  20 AC_PREREQ([2.65])
  21 AC_INIT([Cycript], [0.9], [saurik@saurik.com], [cycript], [http://www.cycript.org/])
  22 AC_COPYRIGHT([Copyright (C) 2009-2015  Jay Freeman (saurik)])
  23
  24 AC_CONFIG_SRCDIR([Console.cpp])
  25 AC_CONFIG_AUX_DIR([.])
  26 AC_CONFIG_MACRO_DIR([m4])
  27 AC_CONFIG_HEADERS([config.h])
  28
  29 AM_INIT_AUTOMAKE([-Wall -Werror foreign])
  30 AM_MAINTAINER_MODE([disable])
  31
  32 AC_PROG_CC
  33 AC_PROG_CXX
  34 AC_PROG_OBJCXX
  35
  36 AM_PROG_AR
  37 AC_PROG_INSTALL
  38
  39 LT_INIT([disable-static])
  40
  41 AC_LANG([C++])
  42
  43 AX_CXX_COMPILE_STDCXX_11([ext], [mandatory])
  44 OBJCXXFLAGS="${OBJCXXFLAGS} ${CXXFLAGS##*' '}"
  45
  46 PKG_PROG_PKG_CONFIG([0.22])
  47
  48 AC_PATH_PROG([GIT], [git])
  49 AC_PATH_PROG([TIME], [time])
  50
  51 dnl CY_CHECK_PROGS_VERSION {{{
  52 AC_DEFUN([CY_CHECK_PROGS_VERSION], [
  53     AC_ARG_VAR(]$1[, ]$3[)
  54
  55     AC_MSG_CHECKING(for ]$2[ >= ]$5[)
  56     AC_PATH_PROGS_FEATURE_CHECK(]$1[, ]$2[,
  57         AS_VAR_SET(version, [`$ac_path_]$1[ ]$4[`])
  58         AS_VAR_IF(version, [], ,
  59             AS_VERSION_COMPARE($version, ]$5[, ,
  60                 ac_cv_path_]$1[=$ac_path_]$1[,
  61                 ac_cv_path_]$1[=$ac_path_]$1[))
  62     , AC_MSG_RESULT(no))
  63
  64     AS_IF([true], [
  65         AC_SUBST(]$1[, $ac_cv_path_]$1[)
  66         AC_MSG_RESULT($]$1[)
  67     ], AS_IF([true], [
  68         AC_MSG_ERROR(You need ]$2[ ]$5[ or greater)
  69     ], [
  70         AC_SUBST(]$1[, [:])
  71         AC_MSG_RESULT([no])
  72     ]))
  73 ]) dnl }}}
  74
  75 CY_CHECK_PROGS_VERSION([BISON], [bison], [GNU Project parser generator (yacc replacement)],
  76     [-V | $SED -e '1 s/^bison (GNU Bison) \(.*\)$/\1/p;d'], [3.0])
  77 CY_CHECK_PROGS_VERSION([FLEX], [flex], [the fast lexical analyser generator],
  78     [--version | $SED -e '1 s/^@<:@^0-9.@:>@* \(@<:@0-9.@:>@*\).*$/\1/p;d'], [2.5.33])
  79 CY_CHECK_PROGS_VERSION([GPERF], [gperf], [perfect hash function generator],
  80     [--version | $SED -e '1 s/^.* \(@<:@0-9.@:>@*\)$/\1/p;d'], [3.0.3])
  81 CY_CHECK_PROGS_VERSION([GNUTAR], [tar gtar gnutar], [a very sticky lump of files],
  82     [--version | $SED -e '1 s/^tar (GNU tar) \(.*\)$/\1/p;d'], [1.19])
  83
  84 dnl CY_TRY {{{
  85 AC_DEFUN([CY_SUCCESS], [cy_good=1])
  86 AC_DEFUN([CY_FAILURE], [cy_good=0])
  87
  88 AC_DEFUN([CY_TRY], [
  89     cy_save=$]$1[
  90         AC_LIB_APPENDTOVAR(]$1[, ]$2[)
  91         ]$3[
  92     ]$1[=$cy_save
  93     AS_IF([test "x$cy_good" = x1], ]$4[, ]$5[)
  94 ]) dnl }}}
  95
  96 AC_ARG_VAR([LFLAGS], [flex flags])
  97 AS_IF([test "x$LFLAGS" = x], [LFLAGS="--full --ecs"])
  98
  99 AC_DEFUN([CY_TEST_FLAG_], [
 100     AC_LANG_PUSH(]$2[)
 101     AC_MSG_CHECKING([for ]]$4[[ ]]$1[)
 102     CY_TRY(]$3[, $1, [
 103         AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
 104             [CY_SUCCESS], [CY_FAILURE])
 105     ], [
 106         AC_MSG_RESULT([yes])
 107         AC_LIB_APPENDTOVAR(]$3[, ]$1[)
 108     ], [AC_MSG_RESULT([no])])
 109     AC_LANG_POP(]$2[)
 110 ])
 111
 112 AC_DEFUN([CY_TEST_FLAG], [
 113     CY_TEST_FLAG_(]$1[, [C], [CFLAGS], [cc])
 114     CY_TEST_FLAG_(]$1[, [C++], [CXXFLAGS], [c++])
 115     CY_TEST_FLAG_(]$1[, [Objective C++], [OBJCXXFLAGS], [c++ -ObjC])
 116 ])
 117
 118 AX_CFLAGS_WARN_ALL
 119 AX_CXXFLAGS_WARN_ALL
 120 AX_FLAGS_WARN_ALL
 121
 122 CY_TEST_FLAG([-Werror])
 123
 124 dnl XXX: this is used to support GNU Objective-C struct objc_method
 125 CY_TEST_FLAG([-Wno-deprecated-declarations])
 126
 127 CY_TEST_FLAG([-Wno-dangling-else])
 128 CY_TEST_FLAG([-Wno-empty-body])
 129 CY_TEST_FLAG([-Wno-overloaded-virtual])
 130 CY_TEST_FLAG([-Wno-parentheses])
 131 CY_TEST_FLAG([-Wno-tautological-undefined-compare])
 132 CY_TEST_FLAG([-Wno-unneeded-internal-declaration])
 133
 134 AX_PTHREAD
 135
 136 AC_DEFUN([CY_LT_LIB], [
 137     cy_save=$LIBS
 138     LIBS=
 139     ]$2[
 140     ]$1[=$LIBS
 141     LIBS=$cy_save
 142     AC_SUBST(]$1[)
 143 ])
 144
 145 dnl --enable-javascript {{{
 146 AC_DEFUN([CY_CHECK_JAVASCRIPTCORE], [
 147     CY_LT_LIB([LTJAVASCRIPTCORE], [AC_SEARCH_LIBS([JSEvaluateScript], [JavaScriptCore], [
 148         AC_SUBST([CY_EXECUTE], [1])
 149     ], [AC_CHECK_FRAMEWORK([JavaScriptCore], [
 150         #include <JavaScriptCore/JSBase.h>
 151     ], [
 152         JSEvaluateScript(0, 0, 0, 0, 0, 0);
 153     ], [
 154         AC_SUBST([CY_EXECUTE], [1])
 155     ], [
 156         for cy_webkit_pkg in "javascriptcoregtk-4.0"; do
 157             PKG_CHECK_MODULES([WEBKIT], [$cy_webkit_pkg], [
 158                 AC_SUBST([CY_EXECUTE], [1])
 159                 AC_LIB_APPENDTOVAR([CPPFLAGS], [`$PKG_CONFIG --cflags $cy_webkit_pkg`])
 160                 AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs $cy_webkit_pkg`])
 161             ], [:]); if test "x$CY_EXECUTE" = x1; then break; fi
 162         done
 163     ])])])
 164 ])
 165
 166 AC_DEFUN([CY_CHECK_JAVASCRIPT], [
 167     CY_CHECK_JAVASCRIPTCORE])
 168
 169 AC_ARG_ENABLE([javascript], [AS_HELP_STRING(
 170     [--enable-javascript@<:@=ENGINE@:>@],
 171     [use a JavaScript runtime (currently the only available option for ENGINE is JavaScriptCore) @<:@default=yes@:>@]
 172 )], [
 173     AS_CASE([$enableval],
 174         [yes], [
 175             CY_CHECK_JAVASCRIPT],
 176         [no], [
 177             AC_SUBST([CY_EXECUTE], [0])],
 178         [JavaScriptCore], [
 179             CY_CHECK_JAVASCRIPTCORE],
 180         [AC_MSG_ERROR([Unknown JavaScript engine: $enableval])])
 181 ], [CY_CHECK_JAVASCRIPT])
 182 dnl }}}
 183
 184 AC_ARG_ENABLE([console], AS_HELP_STRING([--disable-console], [disable console]))
 185 AM_CONDITIONAL([CY_CONSOLE], [test "x$enable_console" != "xno"])
 186
 187 AC_ARG_ENABLE([attach], AS_HELP_STRING([--disable-attach], [disable attach]))
 188 AM_CONDITIONAL([CY_ATTACH], [test "x$enable_attach" != "xno" -a "x$CY_EXECUTE" = x1])
 189
 190 AC_DEFUN([CY_CHECK_PKG_CONFIG_LIBFFI], [
 191     PKG_CHECK_MODULES([LIBFFI], [libffi], [
 192         AC_LIB_APPENDTOVAR([CPPFLAGS], [`$PKG_CONFIG --cflags libffi`])
 193         AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs libffi`])
 194     ], [AC_MSG_ERROR([missing "libffi"])])])
 195
 196 AM_CONDITIONAL([CY_EXECUTE], [test "x$CY_EXECUTE" = x1])
 197
 198 AS_CASE([$CY_EXECUTE], [1], [
 199     CY_LT_LIB([LTLIBUV], [AC_CHECK_HEADERS([uv.h], [
 200         AC_SEARCH_LIBS([uv_loop_init], [uv])
 201     ])])
 202
 203     AC_CHECK_HEADERS([ffi.h ffi/ffi.h], [break])
 204
 205     CY_LT_LIB([LTLIBFFI], AS_IF([test "x$ac_cv_header_ffi_h" = xno && test "x$ac_cv_header_ffi_ffi_h" = xno], [
 206         CY_CHECK_PKG_CONFIG_LIBFFI
 207     ], [
 208         AC_SEARCH_LIBS([ffi_call], [ffi])
 209         AS_CASE([$ac_cv_search_ffi_call], [no], [CY_CHECK_PKG_CONFIG_LIBFFI])
 210     ]))
 211
 212     AC_CHECK_FRAMEWORK([JavaVM], [
 213         #include <JavaVM/jni.h>
 214     ], [JNI_GetCreatedJavaVMs(NULL, 0, NULL);], [
 215         AC_SUBST([CY_JAVA], [1])
 216     ], [AC_CHECK_HEADER([jni.h], [
 217         AC_SUBST([CY_JAVA], [1])
 218         CY_LT_LIB([LTJAVA], [AC_SEARCH_LIBS([JNI_GetCreatedJavaVMs], [dvm], [
 219         ])])
 220     ], [
 221         AC_SUBST([CY_JAVA], [0])
 222     ])])
 223
 224     AC_LANG_PUSH([Objective C++])
 225
 226     AC_MSG_CHECKING([if we really have Objective C++])
 227     AC_COMPILE_IFELSE([AC_LANG_SOURCE([])], [
 228         CY_OBJECTIVEC=1
 229         AC_MSG_RESULT([yes])
 230     ], [AC_MSG_RESULT([no])])
 231
 232     AS_IF([test "x$CY_OBJECTIVEC" = x1], [
 233         CY_LT_LIB([LTOBJECTIVEC], [AC_CHECK_FRAMEWORK([CoreFoundation], [
 234             #include <CoreFoundation/CFBase.h>
 235         ], [CFAllocatorGetDefault();], [
 236             AC_SUBST([CY_OBJECTIVEC])
 237
 238             AC_CHECK_FRAMEWORK([Foundation], [
 239                 #include <Foundation/NSObject.h>
 240             ], [[[[NSObject alloc] init];]])
 241         ], [
 242             AC_ARG_VAR([GNUSTEP_CONFIG], [prints information about the current gnustep installation])
 243             AC_CHECK_PROGS([GNUSTEP_CONFIG], [gnustep-config])
 244
 245             AS_IF([test "x$GNUSTEP_CONFIG" != x], [
 246                 AC_SUBST([CY_OBJECTIVEC])
 247                 AC_LIB_APPENDTOVAR([OBJCXXFLAGS], [`$GNUSTEP_CONFIG --objc-flags`])
 248                 AC_LIB_APPENDTOVAR([LIBS], [`$GNUSTEP_CONFIG --base-libs`])
 249             ], [AC_SUBST([CY_OBJECTIVEC], [0])])
 250         ])])
 251     ])
 252
 253     AC_LANG_POP([Objective C++])
 254 ])
 255
 256 AM_CONDITIONAL([CY_JAVA], [test "x$CY_JAVA" = x1])
 257 AM_CONDITIONAL([CY_OBJECTIVEC], [test "x$CY_OBJECTIVEC" = x1])
 258
 259 CY_LT_LIB([LTLIBREADLINE], [AX_LIB_READLINE])
 260 AS_CASE([$ax_cv_lib_readline], [no], [AC_MSG_ERROR([missing "libreadline"])])
 261
 262 CY_LT_LIB([LTLIBTERMCAP], [AC_SEARCH_LIBS([cur_term], [termcap ncurses])])
 263
 264 AC_SUBST([LTLIBGCC])
 265
 266 AC_SUBST([LTFLAGS])
 267 AC_SUBST([SO], [$acl_shlibext])
 268
 269 AC_CONFIG_FILES([Makefile])
 270 AC_OUTPUT