configure.ac

   1 dnl Cycript - Optimizing JavaScript Compiler/Runtime
   2 dnl Copyright (C) 2009-2013  Jay Freeman (saurik)
   3
   4 dnl GNU General Public License, Version 3 {{{
   5 dnl
   6 dnl Cycript is free software: you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published
   8 dnl by the Free Software Foundation, either version 3 of the License,
   9 dnl or (at your option) any later version.
  10 dnl
  11 dnl Cycript is distributed in the hope that it will be useful, but
  12 dnl WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with Cycript.  If not, see <http://www.gnu.org/licenses/>.
  18 dnl }}}
  19
  20 AC_PREREQ([2.65])
  21 AC_INIT([Cycript], [0.9], [saurik@saurik.com], [cycript], [http://www.cycript.org/])
  22 AC_COPYRIGHT([Copyright (C) 2009-2012  Jay Freeman (saurik)])
  23
  24 AC_CONFIG_SRCDIR([Console.cpp])
  25 AC_CONFIG_AUX_DIR([.])
  26 AC_CONFIG_MACRO_DIR([m4])
  27 AC_CONFIG_HEADERS([config.h])
  28
  29 AM_INIT_AUTOMAKE([-Wall -Werror foreign])
  30
  31 AC_PROG_CXX
  32 AC_PROG_OBJCXX
  33 AM_PROG_AR
  34 AC_PROG_INSTALL
  35
  36 LT_INIT([disable-static])
  37
  38 AC_LANG([C++])
  39
  40 PKG_PROG_PKG_CONFIG([0.22])
  41
  42 AC_PATH_PROG([_BASH], [bash], [AC_MSG_ERROR([missing "bash"])])
  43 AC_PATH_PROG([GIT], [git])
  44 AC_PATH_PROG([TIME], [time])
  45
  46 dnl CY_CHECK_PROGS_VERSION {{{
  47 AC_DEFUN([CY_CHECK_PROGS_VERSION], [
  48     AC_ARG_VAR(]$1[, ]$3[)
  49
  50     AC_MSG_CHECKING(for ]$2[ >= ]$5[)
  51     AC_PATH_PROGS_FEATURE_CHECK(]$1[, ]$2[,
  52         AS_VAR_SET(version, [`$ac_path_]$1[ ]$4[`])
  53         AS_VAR_IF(version, [], ,
  54             AS_VERSION_COMPARE($version, ]$5[, ,
  55                 ac_cv_path_]$1[=$ac_path_]$1[,
  56                 ac_cv_path_]$1[=$ac_path_]$1[))
  57     , AC_MSG_RESULT(no))
  58
  59     AS_IF([true], [
  60         AC_SUBST(]$1[, $ac_cv_path_]$1[)
  61         AC_MSG_RESULT($]$1[)
  62     ], AS_IF([true], [
  63         AC_MSG_ERROR(You need ]$2[ ]$5[ or greater)
  64     ], [
  65         AC_SUBST(]$1[, [:])
  66         AC_MSG_RESULT([no])
  67     ]))
  68 ]) dnl }}}
  69
  70 CY_CHECK_PROGS_VERSION([BISON], [bison], [GNU Project parser generator (yacc replacement)],
  71     [-V | $SED -e '1 s/^bison (GNU Bison) \(.*\)$/\1/p;d'], [2.3])
  72 CY_CHECK_PROGS_VERSION([FLEX], [flex], [the fast lexical analyser generator],
  73     [--version | $SED -e '1 s/^@<:@^0-9.@:>@* \(@<:@0-9.@:>@*\).*$/\1/p;d'], [2.5.33])
  74 CY_CHECK_PROGS_VERSION([GPERF], [gperf], [perfect hash function generator],
  75     [--version | $SED -e '1 s/^.* \(@<:@0-9.@:>@*\)$/\1/p;d'], [3.0.3])
  76 CY_CHECK_PROGS_VERSION([GNUTAR], [tar gtar gnutar], [a very sticky lump of files],
  77     [--version | $SED -e '1 s/^tar (GNU tar) \(.*\)$/\1/p;d'], [1.19])
  78
  79 AC_MSG_CHECKING([bison for %code{}])
  80 echo '%code{}%%_:' >conftest.y
  81 if $BISON conftest.y -o/dev/null 2>/dev/null; then
  82     AC_LIB_APPENDTOVAR([CY_FILTERS], [Bison24])
  83     AC_MSG_RESULT([yes])
  84 else
  85     AC_LIB_APPENDTOVAR([CY_FILTERS], [Bison23])
  86     AC_MSG_RESULT([no])
  87 fi
  88
  89 rm -f conftest.y
  90 AC_SUBST([CY_FILTERS])
  91
  92 dnl CY_TRY {{{
  93 AC_DEFUN([CY_SUCCESS], [cy_good=1])
  94 AC_DEFUN([CY_FAILURE], [cy_good=0])
  95
  96 AC_DEFUN([CY_TRY], [
  97     cy_save=$]$1[
  98         AC_LIB_APPENDTOVAR(]$1[, ]$2[)
  99         ]$3[
 100     ]$1[=$cy_save
 101     AS_IF([test "x$cy_good" = x1], ]$4[, ]$5[)
 102 ]) dnl }}}
 103
 104 AC_DEFUN([CY_COMPILE_FLAG], [
 105     AC_LIB_APPENDTOVAR([CFLAGS], ]$1[)
 106     AC_LIB_APPENDTOVAR([CXXFLAGS], ]$1[)
 107     AC_LIB_APPENDTOVAR([OBJCXXFLAGS], ]$1[)
 108 ])
 109
 110 AC_DEFUN([CY_TEST_FLAG_], [
 111     AC_LANG_PUSH(]$2[)
 112     AC_MSG_CHECKING([for ]]$4[[ ]]$1[)
 113     CY_TRY(]$3[, $1, [
 114         AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
 115             [CY_SUCCESS], [CY_FAILURE])
 116     ], [
 117         AC_MSG_RESULT([yes])
 118         AC_LIB_APPENDTOVAR(]$3[, ]$1[)
 119     ], [AC_MSG_RESULT([no])])
 120     AC_LANG_POP(]$2[)
 121 ])
 122
 123 AC_DEFUN([CY_TEST_FLAG], [
 124     CY_TEST_FLAG_(]$1[, [C], [CFLAGS], [cc])
 125     CY_TEST_FLAG_(]$1[, [C++], [CXXFLAGS], [c++])
 126     CY_TEST_FLAG_(]$1[, [Objective C++], [OBJCXXFLAGS], [c++ -ObjC])
 127 ])
 128
 129 AX_CFLAGS_WARN_ALL
 130 AX_CXXFLAGS_WARN_ALL
 131
 132 CY_TEST_FLAG([-Wno-dangling-else])
 133 CY_TEST_FLAG([-Wno-overloaded-virtual])
 134 CY_TEST_FLAG([-Wno-parentheses])
 135 CY_TEST_FLAG([-Wno-unneeded-internal-declaration])
 136
 137 dnl -arch * {{{
 138 for cy_arch in ppc ppc64 i386 x86_64 armv6; do
 139     AC_MSG_CHECKING([for -arch $cy_arch])
 140     CY_TRY([CXXFLAGS], ["-arch $cy_arch"], [
 141         AC_TRY_LINK([], [], [CY_SUCCESS], [CY_FAILURE])
 142     ], [
 143         AC_MSG_RESULT([yes])
 144         AC_LIB_APPENDTOVAR([CY_ARCH], ["-arch $cy_arch"])
 145     ], [AC_MSG_RESULT([no])])
 146 done
 147 AC_SUBST([CY_ARCH])
 148 dnl }}}
 149
 150 AC_DEFUN([CY_LT_LIB], [
 151     cy_save=$LIBS
 152     LIBS=
 153     ]$2[
 154     ]$1[=$LIBS
 155     LIBS=$cy_save
 156     AC_SUBST(]$1[)
 157 ])
 158
 159 dnl --with-frameworks {{{
 160 AC_ARG_WITH([frameworks], [AS_HELP_STRING(
 161     [--with-frameworks=DIRS],
 162     [add to DIRS (space separated) to the Darwin include path for frameworks with -F]
 163 )], [
 164     for cy_framework in $withval; do
 165         CY_COMPILE_FLAG([-F$cy_framework])
 166     done
 167 ]) dnl }}}
 168 dnl --enable-javascript {{{
 169 AC_DEFUN([CY_CHECK_JAVASCRIPTCORE], [
 170     AC_CHECK_FRAMEWORK([JavaScriptCore], [
 171         #include <JavaScriptCore/JSBase.h>
 172     ], [
 173         JSEvaluateScript(0, 0, 0, 0, 0, 0);
 174     ], [
 175         AC_SUBST([CY_EXECUTE], [1])
 176     ], [
 177         for cy_webkit_pkg in "webkit-1.0" "WebKitGtk"; do
 178             PKG_CHECK_MODULES([WEBKIT], [$cy_webkit_pkg], [
 179                 AC_SUBST([CY_EXECUTE], [1])
 180                 CY_COMPILE_FLAG([`$PKG_CONFIG --cflags $cy_webkit_pkg`])
 181                 AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs $cy_webkit_pkg`])
 182             ], [:]); if test "x$CY_EXECUTE" = x1; then break; fi
 183         done
 184     ])
 185 ])
 186
 187 AC_DEFUN([CY_CHECK_JAVASCRIPT], [
 188     CY_CHECK_JAVASCRIPTCORE])
 189
 190 AC_ARG_ENABLE([javascript], [AS_HELP_STRING(
 191     [--enable-javascript@<:@=ENGINE@:>@],
 192     [use a JavaScript runtime (currently the only available option for ENGINE is JavaScriptCore) @<:@default=yes@:>@]
 193 )], [
 194     AS_CASE([$enableval],
 195         [yes], [
 196             CY_CHECK_JAVASCRIPT],
 197         [no], [
 198             AC_SUBST([CY_EXECUTE], [0])],
 199         [JavaScriptCore], [
 200             CY_CHECK_JAVASCRIPTCORE],
 201         [AC_MSG_ERROR([Unknown JavaScript engine: $enableval])])
 202 ], [CY_CHECK_JAVASCRIPT])
 203 dnl }}}
 204
 205 dnl APR_FIND_APR {{{
 206 APR_FIND_APR([], [], [1], [1])
 207 AS_CASE([$apr_found], [yes], [
 208     AC_LIB_APPENDTOVAR([CPPFLAGS], [`$apr_config --includes`])
 209     AC_LIB_APPENDTOVAR([LTLIBAPR], [`$apr_config --link-libtool`])
 210     AC_SUBST([LTLIBAPR])
 211 ], [AC_MSG_ERROR([missing "libapr"])])
 212 dnl }}}
 213
 214 AC_DEFUN([CY_CHECK_PKG_CONFIG_LIBFFI], [
 215     PKG_CHECK_MODULES([LIBFFI], [libffi], [
 216         CY_COMPILE_FLAG([`$PKG_CONFIG --cflags libffi`])
 217         AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs libffi`])
 218     ], [AC_MSG_ERROR([missing "libffi"])])])
 219
 220 AM_CONDITIONAL([CY_EXECUTE], [test "x$CY_EXECUTE" = x1])
 221
 222 AS_CASE([$CY_EXECUTE], [1], [
 223     AC_CHECK_HEADERS([ffi.h ffi/ffi.h], [break])
 224
 225     CY_LT_LIB([LTLIBFFI], AS_IF([test "x$ac_cv_header_ffi_h" = xno && test "x$ac_cv_header_ffi_ffi_h" = xno], [
 226         CY_CHECK_PKG_CONFIG_LIBFFI
 227     ], [
 228         AC_SEARCH_LIBS([ffi_call], [ffi])
 229         AS_CASE([$ac_cv_search_ffi_call], [no], [CY_CHECK_PKG_CONFIG_LIBFFI])
 230     ]))
 231
 232     AC_LANG_PUSH([Objective C++])
 233
 234     AC_MSG_CHECKING([if we really have Objective C++])
 235     AC_COMPILE_IFELSE([AC_LANG_SOURCE([])], [
 236         CY_OBJECTIVEC=1
 237         AC_MSG_RESULT([yes])
 238     ], [AC_MSG_RESULT([no])])
 239
 240     AS_IF([test "x$CY_OBJECTIVEC" = x1], [
 241         AC_CHECK_FRAMEWORK([CoreFoundation], [
 242             #include <CoreFoundation/CFBase.h>
 243         ], [CFAllocatorGetDefault();], [
 244             AC_SUBST([CY_OBJECTIVEC])
 245
 246             AC_CHECK_FRAMEWORK([Foundation], [
 247                 #include <Foundation/NSObject.h>
 248             ], [[[[NSObject alloc] init];]])
 249
 250             AC_CHECK_FRAMEWORK([WebKit], [
 251                 #include <WebKit/WebScriptObject.h>
 252             ], [[[[WebScriptObject alloc] init];]])
 253         ], [
 254             AC_ARG_VAR([GNUSTEP_CONFIG], [prints information about the current gnustep installation])
 255             AC_CHECK_PROGS([GNUSTEP_CONFIG], [gnustep-config])
 256
 257             AS_IF([test "x$GNUSTEP_CONFIG" != x], [
 258                 AC_SUBST([CY_OBJECTIVEC])
 259                 AC_LIB_APPENDTOVAR([OBJCXXFLAGS], [`$GNUSTEP_CONFIG --objc-flags`])
 260                 AC_LIB_APPENDTOVAR([LIBS], [`$GNUSTEP_CONFIG --base-libs`])
 261             ], [AC_SUBST([CY_OBJECTIVEC], [0])])
 262         ])
 263     ])
 264
 265     AC_LANG_POP([Objective C++])
 266 ])
 267
 268 AM_CONDITIONAL([CY_OBJECTIVEC], [test "x$CY_OBJECTIVEC" = x1])
 269
 270 CY_LT_LIB([LTLIBREADLINE], [AX_LIB_READLINE])
 271 AS_CASE([$ax_cv_lib_readline], [no], [AC_MSG_ERROR([missing "libreadline"])])
 272
 273 CY_LT_LIB([LTLIBTERMCAP], [AC_SEARCH_LIBS([cur_term], [termcap])])
 274
 275 AC_LANG_PUSH([C])
 276 AM_ICONV
 277 AS_CASE([$am_cv_func_iconv], [yes], [], [AC_MSG_ERROR([missing "libiconv"])])
 278 AC_LANG_POP([C])
 279
 280 AC_SUBST([LTFLAGS])
 281 AC_SUBST([SO], [$acl_shlibext])
 282
 283 AS_IF([test "x$CY_EXECUTE" = x1], [
 284     AC_CHECK_HEADER([mach/mach.h], [
 285         AC_CHECK_TOOLS([_LIPO], [lipo], [AC_MSG_ERROR([missing "lipo"])])
 286         AC_CHECK_TOOLS([_NM], [nm], [AC_MSG_ERROR([missing "nm"])])
 287         AC_CHECK_TOOLS([_OTOOL], [otool], [AC_MSG_ERROR([missing "otool"])])
 288         AC_SUBST([CY_ATTACH_GROUP], [procmod])
 289         AC_SUBST([CY_MACH], [1])])])
 290 AM_CONDITIONAL([CY_MACH], [test "x$CY_MACH" = x1])
 291
 292 AC_CONFIG_FILES([Makefile])
 293 AC_OUTPUT