[cycript.git] / configure.ac

dnl Cycript - Optimizing JavaScript Compiler/Runtime
dnl Copyright (C) 2009-2013  Jay Freeman (saurik)

dnl GNU General Public License, Version 3 {{{
dnl
dnl Cycript is free software: you can redistribute it and/or modify
dnl it under the terms of the GNU General Public License as published
dnl by the Free Software Foundation, either version 3 of the License,
dnl or (at your option) any later version.
dnl
dnl Cycript is distributed in the hope that it will be useful, but
dnl WITHOUT ANY WARRANTY; without even the implied warranty of
dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
dnl GNU General Public License for more details.
dnl
dnl You should have received a copy of the GNU General Public License
dnl along with Cycript.  If not, see <http://www.gnu.org/licenses/>.
dnl }}}

AC_PREREQ([2.65])
AC_INIT([Cycript], [0.9], [saurik@saurik.com], [cycript], [http://www.cycript.org/])
AC_COPYRIGHT([Copyright (C) 2009-2012  Jay Freeman (saurik)])

AC_CONFIG_SRCDIR([Console.cpp])
AC_CONFIG_AUX_DIR([.])
AC_CONFIG_MACRO_DIR([m4])
AC_CONFIG_HEADERS([config.h])

AM_INIT_AUTOMAKE([-Wall -Werror foreign])

AC_PROG_CXX
AC_PROG_OBJCXX
AM_PROG_AR
AC_PROG_INSTALL

LT_INIT([disable-static])

AC_LANG([C++])

PKG_PROG_PKG_CONFIG([0.22])

AC_PATH_PROG([_BASH], [bash], [AC_MSG_ERROR([missing "bash"])])
AC_PATH_PROG([GIT], [git])
AC_PATH_PROG([TIME], [time])

dnl CY_CHECK_PROGS_VERSION {{{
AC_DEFUN([CY_CHECK_PROGS_VERSION], [
    AC_ARG_VAR(]$1[, ]$3[)

    AC_MSG_CHECKING(for ]$2[ >= ]$5[)
    AC_PATH_PROGS_FEATURE_CHECK(]$1[, ]$2[,
        AS_VAR_SET(version, [`$ac_path_]$1[ ]$4[`])
        AS_VAR_IF(version, [], ,
            AS_VERSION_COMPARE($version, ]$5[, ,
                ac_cv_path_]$1[=$ac_path_]$1[,
                ac_cv_path_]$1[=$ac_path_]$1[))
    , AC_MSG_RESULT(no))

    AS_IF([true], [
        AC_SUBST(]$1[, $ac_cv_path_]$1[)
        AC_MSG_RESULT($]$1[)
    ], AS_IF([true], [
        AC_MSG_ERROR(You need ]$2[ ]$5[ or greater)
    ], [
        AC_SUBST(]$1[, [:])
        AC_MSG_RESULT([no])
    ]))
]) dnl }}}

CY_CHECK_PROGS_VERSION([BISON], [bison], [GNU Project parser generator (yacc replacement)],
    [-V | $SED -e '1 s/^bison (GNU Bison) \(.*\)$/\1/p;d'], [2.3])
CY_CHECK_PROGS_VERSION([FLEX], [flex], [the fast lexical analyser generator],
    [--version | $SED -e '1 s/^@<:@^0-9.@:>@* \(@<:@0-9.@:>@*\).*$/\1/p;d'], [2.5.33])
CY_CHECK_PROGS_VERSION([GPERF], [gperf], [perfect hash function generator],
    [--version | $SED -e '1 s/^.* \(@<:@0-9.@:>@*\)$/\1/p;d'], [3.0.3])
CY_CHECK_PROGS_VERSION([GNUTAR], [tar gtar gnutar], [a very sticky lump of files],
    [--version | $SED -e '1 s/^tar (GNU tar) \(.*\)$/\1/p;d'], [1.19])

AC_MSG_CHECKING([bison for %code{}])
echo '%code{}%%_:' >conftest.y
if $BISON conftest.y -o/dev/null 2>/dev/null; then
    AC_LIB_APPENDTOVAR([CY_FILTERS], [Bison24])
    AC_MSG_RESULT([yes])
else
    AC_LIB_APPENDTOVAR([CY_FILTERS], [Bison23])
    AC_MSG_RESULT([no])
fi

rm -f conftest.y
AC_SUBST([CY_FILTERS])

dnl CY_TRY {{{
AC_DEFUN([CY_SUCCESS], [cy_good=1])
AC_DEFUN([CY_FAILURE], [cy_good=0])

AC_DEFUN([CY_TRY], [
    cy_save=$]$1[
        AC_LIB_APPENDTOVAR(]$1[, ]$2[)
        ]$3[
    ]$1[=$cy_save
    AS_IF([test "x$cy_good" = x1], ]$4[, ]$5[)
]) dnl }}}

AC_DEFUN([CY_COMPILE_FLAG], [
    AC_LIB_APPENDTOVAR([CFLAGS], ]$1[)
    AC_LIB_APPENDTOVAR([CXXFLAGS], ]$1[)
    AC_LIB_APPENDTOVAR([OBJCCXXFLAGS], ]$1[)
])

AC_DEFUN([CY_TEST_FLAG], [
    AC_MSG_CHECKING([for ]]$1[)
    CY_TRY([CXXFLAGS], $1, [
        AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
            [CY_SUCCESS], [CY_FAILURE])
    ], [
        AC_MSG_RESULT([yes])
        CY_COMPILE_FLAG($1)
    ], [AC_MSG_RESULT([no])])
])

AX_CFLAGS_WARN_ALL
AX_CXXFLAGS_WARN_ALL

CY_TEST_FLAG([-Wno-overloaded-virtual])
CY_TEST_FLAG([-Wno-parentheses])
CY_TEST_FLAG([-Wno-unneeded-internal-declaration])

dnl -arch * {{{
for cy_arch in ppc ppc64 i386 x86_64 armv6; do
    AC_MSG_CHECKING([for -arch $cy_arch])
    CY_TRY([CXXFLAGS], ["-arch $cy_arch"], [
        AC_TRY_LINK([], [], [CY_SUCCESS], [CY_FAILURE])
    ], [
        AC_MSG_RESULT([yes])
        AC_LIB_APPENDTOVAR([CY_ARCH], ["-arch $cy_arch"])
    ], [AC_MSG_RESULT([no])])
done
AC_SUBST([CY_ARCH])
dnl }}}

AC_DEFUN([CY_LT_LIB], [
    cy_save=$LIBS
    LIBS=
    ]$2[
    ]$1[=$LIBS
    LIBS=$cy_save
    AC_SUBST(]$1[)
])

dnl --with-frameworks {{{
AC_ARG_WITH([frameworks], [AS_HELP_STRING(
    [--with-frameworks=DIRS],
    [add to DIRS (space separated) to the Darwin include path for frameworks with -F]
)], [
    for cy_framework in $withval; do
        CY_COMPILE_FLAG([-F$cy_framework])
    done
]) dnl }}}
dnl --enable-javascript {{{
AC_DEFUN([CY_CHECK_JAVASCRIPTCORE], [
    AC_CHECK_FRAMEWORK([JavaScriptCore], [
        #include <JavaScriptCore/JSBase.h>
    ], [
        JSEvaluateScript(0, 0, 0, 0, 0, 0);
    ], [
        AC_SUBST([CY_EXECUTE], [1])
    ], [
        for cy_webkit_pkg in "webkit-1.0" "WebKitGtk"; do
            PKG_CHECK_MODULES([WEBKIT], [$cy_webkit_pkg], [
                AC_SUBST([CY_EXECUTE], [1])
                CY_COMPILE_FLAG([`$PKG_CONFIG --cflags $cy_webkit_pkg`])
                AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs $cy_webkit_pkg`])
            ], [:]); if test "x$CY_EXECUTE" = x1; then break; fi
        done
    ])
])

AC_DEFUN([CY_CHECK_JAVASCRIPT], [
    CY_CHECK_JAVASCRIPTCORE])

AC_ARG_ENABLE([javascript], [AS_HELP_STRING(
    [--enable-javascript@<:@=ENGINE@:>@],
    [use a JavaScript runtime (currently the only available option for ENGINE is JavaScriptCore) @<:@default=yes@:>@]
)], [
    AS_CASE([$enableval],
        [yes], [
            CY_CHECK_JAVASCRIPT],
        [no], [
            AC_SUBST([CY_EXECUTE], [0])],
        [JavaScriptCore], [
            CY_CHECK_JAVASCRIPTCORE],
        [AC_MSG_ERROR([Unknown JavaScript engine: $enableval])])
], [CY_CHECK_JAVASCRIPT])
dnl }}}

dnl APR_FIND_APR {{{
APR_FIND_APR([], [], [1], [1])
AS_CASE([$apr_found], [yes], [
    AC_LIB_APPENDTOVAR([CPPFLAGS], [`$apr_config --includes`])
    AC_LIB_APPENDTOVAR([LTLIBAPR], [`$apr_config --link-libtool`])
    AC_SUBST([LTLIBAPR])
], [AC_MSG_ERROR([missing "libapr"])])
dnl }}}

AC_DEFUN([CY_CHECK_PKG_CONFIG_LIBFFI], [
    PKG_CHECK_MODULES([LIBFFI], [libffi], [
        CY_COMPILE_FLAG([`$PKG_CONFIG --cflags libffi`])
        AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs libffi`])
    ], [AC_MSG_ERROR([missing "libffi"])])])

AM_CONDITIONAL([CY_EXECUTE], [test "x$CY_EXECUTE" = x1])

AS_CASE([$CY_EXECUTE], [1], [
    AC_CHECK_HEADERS([ffi.h ffi/ffi.h], [break])

    CY_LT_LIB([LTLIBFFI], AS_IF([test "x$ac_cv_header_ffi_h" = xno && test "x$ac_cv_header_ffi_ffi_h" = xno], [
        CY_CHECK_PKG_CONFIG_LIBFFI
    ], [
        AC_SEARCH_LIBS([ffi_call], [ffi])
        AS_CASE([$ac_cv_search_ffi_call], [no], [CY_CHECK_PKG_CONFIG_LIBFFI])
    ]))

    AC_LANG_PUSH([Objective C++])

    AC_MSG_CHECKING([if we really have Objective C++])
    AC_COMPILE_IFELSE([AC_LANG_SOURCE([])], [
        CY_OBJECTIVEC=1
        AC_MSG_RESULT([yes])
    ], [AC_MSG_RESULT([no])])

    AS_IF([test "x$CY_OBJECTIVEC" = x1], [
        AC_CHECK_FRAMEWORK([CoreFoundation], [
            #include <CoreFoundation/CFBase.h>
        ], [CFAllocatorGetDefault();], [
            AC_SUBST([CY_OBJECTIVEC])

            AC_CHECK_FRAMEWORK([Foundation], [
                #include <Foundation/NSObject.h>
            ], [[[[NSObject alloc] init];]])

            AC_CHECK_FRAMEWORK([WebKit], [
                #include <WebKit/WebScriptObject.h>
            ], [[[[WebScriptObject alloc] init];]])
        ], [
            AC_ARG_VAR([GNUSTEP_CONFIG], [prints information about the current gnustep installation])
            AC_CHECK_PROGS([GNUSTEP_CONFIG], [gnustep-config])

            AS_IF([test "x$GNUSTEP_CONFIG" != x], [
                AC_SUBST([CY_OBJECTIVEC])
                AC_LIB_APPENDTOVAR([OBJCXXFLAGS], [`$GNUSTEP_CONFIG --objc-flags`])
                AC_LIB_APPENDTOVAR([LIBS], [`$GNUSTEP_CONFIG --base-libs`])
            ], [AC_SUBST([CY_OBJECTIVEC], [0])])
        ])
    ])

    AC_LANG_POP([Objective C++])
])

AM_CONDITIONAL([CY_OBJECTIVEC], [test "x$CY_OBJECTIVEC" = x1])

CY_LT_LIB([LTLIBREADLINE], [AX_LIB_READLINE])
AS_CASE([$ax_cv_lib_readline], [no], [AC_MSG_ERROR([missing "libreadline"])])

CY_LT_LIB([LTLIBTERMCAP], [AC_SEARCH_LIBS([cur_term], [termcap])])

AC_LANG_PUSH([C])
AM_ICONV
AS_CASE([$am_cv_func_iconv], [yes], [], [AC_MSG_ERROR([missing "libiconv"])])
AC_LANG_POP([C])

AC_SUBST([LTFLAGS])
AC_SUBST([SO], [$acl_shlibext])

AS_IF([test "x$CY_EXECUTE" = x1], [
    AC_CHECK_HEADER([mach/mach.h], [
        AC_CHECK_TOOLS([_LIPO], [lipo], [AC_MSG_ERROR([missing "lipo"])])
        AC_CHECK_TOOLS([_NM], [nm], [AC_MSG_ERROR([missing "nm"])])
        AC_CHECK_TOOLS([_OTOOL], [otool], [AC_MSG_ERROR([missing "otool"])])
        AC_SUBST([CY_ATTACH_GROUP], [procmod])
        AC_SUBST([CY_MACH], [1])])])
AM_CONDITIONAL([CY_MACH], [test "x$CY_MACH" = x1])

AC_CONFIG_FILES([Makefile])
AC_OUTPUT
Commit	Line	Data
c15969fd JF	1	dnl Cycript - Optimizing JavaScript Compiler/Runtime
	2	dnl Copyright (C) 2009-2013 Jay Freeman (saurik)
	3
	4	dnl GNU General Public License, Version 3 {{{
	5	dnl
	6	dnl Cycript is free software: you can redistribute it and/or modify
	7	dnl it under the terms of the GNU General Public License as published
	8	dnl by the Free Software Foundation, either version 3 of the License,
	9	dnl or (at your option) any later version.
	10	dnl
	11	dnl Cycript is distributed in the hope that it will be useful, but
	12	dnl WITHOUT ANY WARRANTY; without even the implied warranty of
	13	dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	14	dnl GNU General Public License for more details.
	15	dnl
	16	dnl You should have received a copy of the GNU General Public License
	17	dnl along with Cycript. If not, see <http://www.gnu.org/licenses/>.
	18	dnl }}}
	19
9c60689e	20	AC_PREREQ([2.65])
c7aa54aa	21	AC_INIT([Cycript], [0.9], [saurik@saurik.com], [cycript], [http://www.cycript.org/])
66170b30 JF	22	AC_COPYRIGHT([Copyright (C) 2009-2012 Jay Freeman (saurik)])
66170b30 JF	23
35fa52c0	24	AC_CONFIG_SRCDIR([Console.cpp])
6b66678a	25	AC_CONFIG_AUX_DIR([.])
66170b30	26	AC_CONFIG_MACRO_DIR([m4])
e2852502	27	AC_CONFIG_HEADERS([config.h])
66170b30	28
9228a43a	29	AM_INIT_AUTOMAKE([-Wall -Werror foreign])
a243b558 JF	30
	31	AC_PROG_CXX
	32	AC_PROG_OBJCXX
	33	AM_PROG_AR
	34	AC_PROG_INSTALL
	35
549f29b5	36	LT_INIT([disable-static])
66170b30 JF	37
	38	AC_LANG([C++])
	39
3fd51f51	40	PKG_PROG_PKG_CONFIG([0.22])
66170b30	41
66170b30 JF	42	AC_PATH_PROG([_BASH], [bash], [AC_MSG_ERROR([missing "bash"])])
	43	AC_PATH_PROG([GIT], [git])
	44	AC_PATH_PROG([TIME], [time])
	45
	46	dnl CY_CHECK_PROGS_VERSION {{{
e9c9a47c	47	AC_DEFUN([CY_CHECK_PROGS_VERSION], [
66170b30 JF	48	AC_ARG_VAR(]$1[, ]$3[)
	49
	50	AC_MSG_CHECKING(for ]$2[ >= ]$5[)
	51	AC_PATH_PROGS_FEATURE_CHECK(]$1[, ]$2[,
	52	AS_VAR_SET(version, [`$ac_path_]$1[ ]$4[`])
	53	AS_VAR_IF(version, [], ,
	54	AS_VERSION_COMPARE($version, ]$5[, ,
	55	ac_cv_path_]$1[=$ac_path_]$1[,
	56	ac_cv_path_]$1[=$ac_path_]$1[))
	57	, AC_MSG_RESULT(no))
	58
	59	AS_IF([true], [
	60	AC_SUBST(]$1[, $ac_cv_path_]$1[)
	61	AC_MSG_RESULT($]$1[)
	62	], AS_IF([true], [
	63	AC_MSG_ERROR(You need ]$2[ ]$5[ or greater)
	64	], [
	65	AC_SUBST(]$1[, [:])
	66	AC_MSG_RESULT([no])
	67	]))
	68	]) dnl }}}
	69
	70	CY_CHECK_PROGS_VERSION([BISON], [bison], [GNU Project parser generator (yacc replacement)],
	71	[-V \| $SED -e '1 s/^bison (GNU Bison) \(.*\)$/\1/p;d'], [2.3])
	72	CY_CHECK_PROGS_VERSION([FLEX], [flex], [the fast lexical analyser generator],
	73	[--version \| $SED -e '1 s/^@<:@^0-9.@:>@* \(@<:@0-9.@:>@\).$/\1/p;d'], [2.5.33])
	74	CY_CHECK_PROGS_VERSION([GPERF], [gperf], [perfect hash function generator],
	75	[--version \| $SED -e '1 s/^.* \(@<:@0-9.@:>@*\)$/\1/p;d'], [3.0.3])
	76	CY_CHECK_PROGS_VERSION([GNUTAR], [tar gtar gnutar], [a very sticky lump of files],
	77	[--version \| $SED -e '1 s/^tar (GNU tar) \(.*\)$/\1/p;d'], [1.19])
	78
9228a43a JF	79	AC_MSG_CHECKING([bison for %code{}])
	80	echo '%code{}%%_:' >conftest.y
	81	if $BISON conftest.y -o/dev/null 2>/dev/null; then
	82	AC_LIB_APPENDTOVAR([CY_FILTERS], [Bison24])
	83	AC_MSG_RESULT([yes])
	84	else
	85	AC_LIB_APPENDTOVAR([CY_FILTERS], [Bison23])
	86	AC_MSG_RESULT([no])
	87	fi
	88
	89	rm -f conftest.y
	90	AC_SUBST([CY_FILTERS])
	91
66170b30 JF	92	dnl CY_TRY {{{
	93	AC_DEFUN([CY_SUCCESS], [cy_good=1])
	94	AC_DEFUN([CY_FAILURE], [cy_good=0])
	95
	96	AC_DEFUN([CY_TRY], [
	97	cy_save=$]$1[
	98	AC_LIB_APPENDTOVAR(]$1[, ]$2[)
	99	]$3[
	100	]$1[=$cy_save
	101	AS_IF([test "x$cy_good" = x1], ]$4[, ]$5[)
	102	]) dnl }}}
	103
	104	AC_DEFUN([CY_COMPILE_FLAG], [
	105	AC_LIB_APPENDTOVAR([CFLAGS], ]$1[)
	106	AC_LIB_APPENDTOVAR([CXXFLAGS], ]$1[)
	107	AC_LIB_APPENDTOVAR([OBJCCXXFLAGS], ]$1[)
1504c9b8	108	])
66170b30 JF	109
	110	AC_DEFUN([CY_TEST_FLAG], [
	111	AC_MSG_CHECKING([for ]]$1[)
	112	CY_TRY([CXXFLAGS], $1, [
	113	AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
	114	[CY_SUCCESS], [CY_FAILURE])
	115	], [
	116	AC_MSG_RESULT([yes])
	117	CY_COMPILE_FLAG($1)
	118	], [AC_MSG_RESULT([no])])
	119	])
	120
	121	AX_CFLAGS_WARN_ALL
	122	AX_CXXFLAGS_WARN_ALL
	123
	124	CY_TEST_FLAG([-Wno-overloaded-virtual])
	125	CY_TEST_FLAG([-Wno-parentheses])
	126	CY_TEST_FLAG([-Wno-unneeded-internal-declaration])
	127
	128	dnl -arch * {{{
	129	for cy_arch in ppc ppc64 i386 x86_64 armv6; do
	130	AC_MSG_CHECKING([for -arch $cy_arch])
	131	CY_TRY([CXXFLAGS], ["-arch $cy_arch"], [
	132	AC_TRY_LINK([], [], [CY_SUCCESS], [CY_FAILURE])
	133	], [
	134	AC_MSG_RESULT([yes])
a243b558	135	AC_LIB_APPENDTOVAR([CY_ARCH], ["-arch $cy_arch"])
66170b30	136	], [AC_MSG_RESULT([no])])
a243b558 JF	137	done
	138	AC_SUBST([CY_ARCH])
	139	dnl }}}
66170b30	140
e71ad079 JF	141	AC_DEFUN([CY_LT_LIB], [
	142	cy_save=$LIBS
	143	LIBS=
	144	]$2[
	145	]$1[=$LIBS
	146	LIBS=$cy_save
	147	AC_SUBST(]$1[)
	148	])
	149
66170b30	150	dnl --with-frameworks {{{
632b71ea	151	AC_ARG_WITH([frameworks], [AS_HELP_STRING(
66170b30 JF	152	[--with-frameworks=DIRS],
66170b30 JF	153	[add to DIRS (space separated) to the Darwin include path for frameworks with -F]
632b71ea	154	)], [
66170b30 JF	155	for cy_framework in $withval; do
	156	CY_COMPILE_FLAG([-F$cy_framework])
	157	done
	158	]) dnl }}}
	159	dnl --enable-javascript {{{
b66977f1	160	AC_DEFUN([CY_CHECK_JAVASCRIPTCORE], [
4a762893 JF	161	AC_CHECK_FRAMEWORK([JavaScriptCore], [
	162	#include <JavaScriptCore/JSBase.h>
	163	], [
	164	JSEvaluateScript(0, 0, 0, 0, 0, 0);
	165	], [
66170b30	166	AC_SUBST([CY_EXECUTE], [1])
66170b30	167	], [
4a762893 JF	168	for cy_webkit_pkg in "webkit-1.0" "WebKitGtk"; do
4a762893 JF	169	PKG_CHECK_MODULES([WEBKIT], [$cy_webkit_pkg], [
66170b30	170	AC_SUBST([CY_EXECUTE], [1])
4a762893 JF	171	CY_COMPILE_FLAG([`$PKG_CONFIG --cflags $cy_webkit_pkg`])
	172	AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs $cy_webkit_pkg`])
	173	], [:]); if test "x$CY_EXECUTE" = x1; then break; fi
	174	done
66170b30	175	])
35fa52c0	176	])
66170b30	177
b66977f1	178	AC_DEFUN([CY_CHECK_JAVASCRIPT], [
66170b30 JF	179	CY_CHECK_JAVASCRIPTCORE])
66170b30 JF	180
b66977f1	181	AC_ARG_ENABLE([javascript], [AS_HELP_STRING(
66170b30 JF	182	[--enable-javascript@<:@=ENGINE@:>@],
66170b30 JF	183	[use a JavaScript runtime (currently the only available option for ENGINE is JavaScriptCore) @<:@default=yes@:>@]
b66977f1	184	)], [
66170b30 JF	185	AS_CASE([$enableval],
	186	[yes], [
	187	CY_CHECK_JAVASCRIPT],
	188	[no], [
	189	AC_SUBST([CY_EXECUTE], [0])],
	190	[JavaScriptCore], [
	191	CY_CHECK_JAVASCRIPTCORE],
	192	[AC_MSG_ERROR([Unknown JavaScript engine: $enableval])])
b66977f1	193	], [CY_CHECK_JAVASCRIPT])
66170b30 JF	194	dnl }}}
	195
	196	dnl APR_FIND_APR {{{
	197	APR_FIND_APR([], [], [1], [1])
	198	AS_CASE([$apr_found], [yes], [
	199	AC_LIB_APPENDTOVAR([CPPFLAGS], [`$apr_config --includes`])
812bb90b JF	200	AC_LIB_APPENDTOVAR([LTLIBAPR], [`$apr_config --link-libtool`])
812bb90b JF	201	AC_SUBST([LTLIBAPR])
66170b30 JF	202	], [AC_MSG_ERROR([missing "libapr"])])
	203	dnl }}}
	204
e5cca37d	205	AC_DEFUN([CY_CHECK_PKG_CONFIG_LIBFFI], [
66170b30	206	PKG_CHECK_MODULES([LIBFFI], [libffi], [
012153b8	207	CY_COMPILE_FLAG([`$PKG_CONFIG --cflags libffi`])
66170b30 JF	208	AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs libffi`])
	209	], [AC_MSG_ERROR([missing "libffi"])])])
	210
a243b558 JF	211	AM_CONDITIONAL([CY_EXECUTE], [test "x$CY_EXECUTE" = x1])
a243b558 JF	212
e5cca37d	213	AS_CASE([$CY_EXECUTE], [1], [
66170b30	214	AC_CHECK_HEADERS([ffi.h ffi/ffi.h], [break])
e71ad079 JF	215
e71ad079 JF	216	CY_LT_LIB([LTLIBFFI], AS_IF([test "x$ac_cv_header_ffi_h" = xno && test "x$ac_cv_header_ffi_ffi_h" = xno], [
66170b30 JF	217	CY_CHECK_PKG_CONFIG_LIBFFI
	218	], [
	219	AC_SEARCH_LIBS([ffi_call], [ffi])
	220	AS_CASE([$ac_cv_search_ffi_call], [no], [CY_CHECK_PKG_CONFIG_LIBFFI])
e71ad079	221	]))
66170b30 JF	222
	223	AC_LANG_PUSH([Objective C++])
	224
	225	AC_MSG_CHECKING([if we really have Objective C++])
	226	AC_COMPILE_IFELSE([AC_LANG_SOURCE([])], [
	227	CY_OBJECTIVEC=1
	228	AC_MSG_RESULT([yes])
	229	], [AC_MSG_RESULT([no])])
	230
	231	AS_IF([test "x$CY_OBJECTIVEC" = x1], [
	232	AC_CHECK_FRAMEWORK([CoreFoundation], [
	233	#include <CoreFoundation/CFBase.h>
	234	], [CFAllocatorGetDefault();], [
	235	AC_SUBST([CY_OBJECTIVEC])
	236
	237	AC_CHECK_FRAMEWORK([Foundation], [
	238	#include <Foundation/NSObject.h>
	239	], [[[[NSObject alloc] init];]])
	240
	241	AC_CHECK_FRAMEWORK([WebKit], [
	242	#include <WebKit/WebScriptObject.h>
	243	], [[[[WebScriptObject alloc] init];]])
	244	], [
	245	AC_ARG_VAR([GNUSTEP_CONFIG], [prints information about the current gnustep installation])
	246	AC_CHECK_PROGS([GNUSTEP_CONFIG], [gnustep-config])
	247
	248	AS_IF([test "x$GNUSTEP_CONFIG" != x], [
	249	AC_SUBST([CY_OBJECTIVEC])
	250	AC_LIB_APPENDTOVAR([OBJCXXFLAGS], [`$GNUSTEP_CONFIG --objc-flags`])
	251	AC_LIB_APPENDTOVAR([LIBS], [`$GNUSTEP_CONFIG --base-libs`])
	252	], [AC_SUBST([CY_OBJECTIVEC], [0])])
	253	])
	254	])
	255
	256	AC_LANG_POP([Objective C++])
3fd51f51	257	])
66170b30	258
a243b558 JF	259	AM_CONDITIONAL([CY_OBJECTIVEC], [test "x$CY_OBJECTIVEC" = x1])
a243b558 JF	260
6f9aea2b JF	261	CY_LT_LIB([LTLIBREADLINE], [AX_LIB_READLINE])
6f9aea2b JF	262	AS_CASE([$ax_cv_lib_readline], [no], [AC_MSG_ERROR([missing "libreadline"])])
66170b30	263
6f9aea2b	264	CY_LT_LIB([LTLIBTERMCAP], [AC_SEARCH_LIBS([cur_term], [termcap])])
a243b558	265
5053a6d1 DWT	266	AC_LANG_PUSH([C])
5053a6d1 DWT	267	AM_ICONV
66170b30	268	AS_CASE([$am_cv_func_iconv], [yes], [], [AC_MSG_ERROR([missing "libiconv"])])
058f1bc8	269	AC_LANG_POP([C])
66170b30 JF	270
66170b30 JF	271	AC_SUBST([LTFLAGS])
9777bd50	272	AC_SUBST([SO], [$acl_shlibext])
66170b30	273
1f11d1b4 JF	274	AS_IF([test "x$CY_EXECUTE" = x1], [
	275	AC_CHECK_HEADER([mach/mach.h], [
	276	AC_CHECK_TOOLS([_LIPO], [lipo], [AC_MSG_ERROR([missing "lipo"])])
	277	AC_CHECK_TOOLS([_NM], [nm], [AC_MSG_ERROR([missing "nm"])])
	278	AC_CHECK_TOOLS([_OTOOL], [otool], [AC_MSG_ERROR([missing "otool"])])
	279	AC_SUBST([CY_ATTACH_GROUP], [procmod])
	280	AC_SUBST([CY_MACH], [1])])])
a243b558	281	AM_CONDITIONAL([CY_MACH], [test "x$CY_MACH" = x1])
66170b30	282
a243b558	283	AC_CONFIG_FILES([Makefile])
9c60689e	284	AC_OUTPUT