[cycript.git] / configure.ac

AC_PREREQ([2.65])
AC_INIT([Cycript], [0.9], [saurik@saurik.com], [cycript], [http://www.cycript.org/])
AC_CONFIG_SRCDIR([Console.cpp])
AC_CONFIG_AUX_DIR([.])
LT_INIT([disable-static])
PKG_PROG_PKG_CONFIG([0.22])
CHECK_GNU_MAKE
AC_SUBST([GMAKE], [$_cv_gnu_make_command])
AS_IF([test "x$GMAKE" = x], [AC_MSG_ERROR([You need GNU make])])
AC_PATH_PROGS([_BASH], [bash])
AS_IF([test "x$_BASH" = x], [AC_MSG_ERROR([You need GNU bash])])
AC_PATH_PROGS([TIME], [time])
AC_DEFUN([CY_CHECK_PROGS_VERSION], [
	AC_MSG_CHECKING(for ]$2[ >= ]$5[)
	AC_PATH_PROGS_FEATURE_CHECK(]$1[, ]$3[,
		AS_VERSION_COMPARE(`$ac_path_]$1[ ]$4[`, ]$5[, ,
			ac_cv_path_]$1[=$ac_path_]$1[
		,
			ac_cv_path_]$1[=$ac_path_]$1[
		)
	,
		AC_MSG_RESULT(no)
		AC_MSG_ERROR(You need ]$2[ ]$5[ or greater)
	)
	AC_SUBST(]$1[, $ac_cv_path_]$1[)
	AC_MSG_RESULT($]$1[)
])
AC_ARG_VAR([BISON], [GNU Project parser generator (yacc replacement)])
CY_CHECK_PROGS_VERSION([BISON], [bison], [bison],
	[-V | $SED -e '1 s/^bison (GNU Bison) \(.*\)$/\1/p;d'], [2.3])
AC_ARG_VAR([FLEX], [the fast lexical analyser generator])
CY_CHECK_PROGS_VERSION([FLEX], [flex], [flex],
	[--version | $SED -e '1 s/^.* \(@<:@0-9.@:>@*\)$/\1/p;d'], [2.5.33])
AC_ARG_VAR([GPERF], [perfect hash function generator])
CY_CHECK_PROGS_VERSION([GPERF], [gperf], [gperf],
	[--version | $SED -e '1 s/^.* \(@<:@0-9.@:>@*\)$/\1/p;d'], [3.0.3])
AC_PROG_INSTALL
AC_MSG_CHECKING([for GNU tar >=1.19])
AC_PATH_PROGS_FEATURE_CHECK([GNUTAR], [tar gtar gnutar], [
	AS_IF([test "x`$ac_path_GNUTAR --version | $SED -e '1 s/^tar (GNU tar)/&/p;d'`" != x], [
		AS_VERSION_COMPARE([`$ac_path_GNUTAR --version | $SED -e '1 s/^tar (GNU tar) \(.*\)$/\1/p;d'`], [1.19], , [
			ac_cv_path_GNUTAR=$ac_path_GNUTAR
		], [
			ac_cv_path_GNUTAR=$ac_path_GNUTAR
		])
	])
])
AS_IF([test "x$ac_cv_path_GNUTAR" != x], [
	AC_SUBST([GNUTAR], [$ac_cv_path_GNUTAR])
	AC_MSG_RESULT([$GNUTAR])
], [
	AC_SUBST([GNUTAR], [:])
	AC_MSG_RESULT([no])
])
AC_CHECK_PROGS([SVN], [svn])
AC_CHECK_PROGS([SVNVERSION], [svnversion])
AC_PROG_CXX
AC_PROG_OBJCXX
AC_ARG_WITH([frameworks], [AS_HELP_STRING(
	[--with-frameworks=DIRS],
	[add to DIRS (space separated) to the Darwin include path for frameworks with -F]
)], [
	for framework in $withval; do
		AC_LIB_APPENDTOVAR([CFLAGS], [-F$framework])
		AC_LIB_APPENDTOVAR([CXXFLAGS], [-F$framework])
		AC_LIB_APPENDTOVAR([OBJCCXXFLAGS], [-F$framework])
	done
])
AC_LANG([C++])
APR_FIND_APR([], [], [1], [1])
AS_CASE([$apr_found], [yes], [
	AC_LIB_APPENDTOVAR([CPPFLAGS], [`$apr_config --includes`])
	AC_SUBST([LTLIBAPR], [`$apr_config --link-libtool`])
], [AC_MSG_ERROR([You need apr])])
AC_DEFUN([CY_CHECK_JAVASCRIPTCORE], [
	PKG_CHECK_MODULES([WEBKIT], [webkit-1.0], [
		CY_EXECUTE=1
		AC_LIB_APPENDTOVAR([CXXFLAGS], [`$PKG_CONFIG --cflags webkit-1.0`])
		AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs webkit-1.0`])
	], [
		PKG_CHECK_MODULES([WEBKIT], [WebKitGtk], [
			CY_EXECUTE=1
			AC_LIB_APPENDTOVAR([CXXFLAGS], [`$PKG_CONFIG --cflags WebKitGtk`])
			AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs WebKitGtk`])
		], [
			AC_CHECK_FRAMEWORK([JavaScriptCore], [
				#include <JavaScriptCore/JSBase.h>
			], [JSEvaluateScript(0, 0, 0, 0, 0, 0);], [CY_EXECUTE=1])
		])
	])
])
AC_DEFUN([CY_CHECK_JAVASCRIPT], [
	CY_CHECK_JAVASCRIPTCORE
])
AC_ARG_ENABLE([javascript], [AS_HELP_STRING(
	[--enable-javascript@<:@=ENGINE@:>@],
	[use a JavaScript runtime (currently the only available option for ENGINE is JavaScriptCore) @<:@default=yes@:>@]
)], [
	AS_CASE([$enableval], [yes], [CY_CHECK_JAVASCRIPT], [no], [
		AC_SUBST([CY_EXECUTE], [0])
	], [JavaScriptCore], [
		CY_CHECK_JAVASCRIPTCORE
	], [AC_MSG_ERROR([Unknown JavaScript engine: $enableval])])
], [CY_CHECK_JAVASCRIPT])
AC_DEFUN([CY_CHECK_PKG_CONFIG_LIBFFI], [
	PKG_CHECK_MODULES([LIBFFI], [libffi], [
		AC_LIB_APPENDTOVAR([CXXFLAGS], [`$PKG_CONFIG --cflags libffi`])
		AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs libffi`])
	], [
		AC_MSG_ERROR([You need libffi])
	])
])
AS_CASE([$CY_EXECUTE], [1], [
	AC_SUBST([CY_EXECUTE])
	AC_CHECK_HEADERS([ffi.h ffi/ffi.h], [break])
	AS_IF([test "x$ac_cv_header_ffi_h" = xno && test "x$ac_cv_header_ffi_ffi_h" = xno], [
		CY_CHECK_PKG_CONFIG_LIBFFI
	], [
		AC_SEARCH_LIBS([ffi_call], [ffi])
		AS_CASE([$ac_cv_search_ffi_call], [no], [CY_CHECK_PKG_CONFIG_LIBFFI])
	])
	AC_LANG_PUSH([Objective C++])
	AC_MSG_CHECKING([if we really have Objective C++])
	AC_COMPILE_IFELSE([
		// This space intentionally left blank
	], [
		CY_OBJECTIVEC=1
		AC_MSG_RESULT([yes])
	], [AC_MSG_RESULT([no])])
	AS_IF([test "x$CY_OBJECTIVEC" = x1], [
		AC_CHECK_FRAMEWORK([CoreFoundation], [
			#include <CoreFoundation/CFBase.h>
		], [CFAllocatorGetDefault();], [
			AC_SUBST([CY_OBJECTIVEC])
			AC_CHECK_FRAMEWORK([Foundation], [
				#include <Foundation/NSObject.h>
			], [[[[NSObject alloc] init];]])
			AC_CHECK_FRAMEWORK([WebKit], [
				#include <WebKit/WebScriptObject.h>
			], [[[[WebScriptObject alloc] init];]])
		], [
			AC_ARG_VAR([GNUSTEP_CONFIG], [prints information about the current gnustep installation])
			AC_CHECK_PROGS([GNUSTEP_CONFIG], [gnustep-config])
			AS_IF([test "x$GNUSTEP_CONFIG" != x], [
				AC_SUBST([CY_OBJECTIVEC])
				AC_LIB_APPENDTOVAR([OBJCXXFLAGS], [`$GNUSTEP_CONFIG --objc-flags`])
				AC_LIB_APPENDTOVAR([LIBS], [`$GNUSTEP_CONFIG --base-libs`])
			], [AC_SUBST([CY_OBJECTIVEC], [0])])
		])
	])
	AC_LANG_POP([Objective C++])
])
VL_LIB_READLINE
AS_CASE([$vl_cv_lib_readline], [no], [AC_MSG_ERROR([You need readline])])
AC_LANG_PUSH([C])
AM_ICONV
AS_CASE([$am_cv_func_iconv], [yes], [], [
	for cy_iconv_prefix_arg in $CFLAGS $CXXFLAGS $OBJCXXFLAGS $LDFLAGS $LIBS; do
		AS_CASE([$cy_iconv_prefix_arg], [-I*], [
			AC_LIB_APPENDTOVAR([cy_iconv_prefixes], [`echo $cy_iconv_prefix_arg | sed -e 's/^-I//;s|/include$||'`])
		], [-L*], [
			AC_LIB_APPENDTOVAR([cy_iconv_prefixes], [`echo $cy_iconv_prefix_arg | sed -e 's/^-L//;s|/lib$||'`])
		])
	done
	for with_libiconv_prefix in $cy_iconv_prefixes; do
		AS_UNSET([am_cv_func_iconv])
		AM_ICONV_LINKFLAGS_BODY
		AM_ICONV
	done
])
AS_CASE([$am_cv_func_iconv], [yes], [], [AC_MSG_ERROR([You need iconv])])
AC_LANG_POP([C])
AS_IF([test "x$CY_OBJECTIVEC" = x1], [
	AC_CHECK_HEADER([mach/mach.h], [
		AS_CASE([$OTOOL], [:], [AC_MSG_WARN([Missing otool?])], [AC_SUBST([CY_OBJECTIVEC_MACH], [1])])
	])
])
AS_IF([test "x$GMAKE" != xmake], [
	AC_CONFIG_FILES([Makefile])
])
AC_CONFIG_FILES([GNUmakefile])
AC_OUTPUT
Commit	Line	Data
9c60689e	1	AC_PREREQ([2.65])
c7aa54aa	2	AC_INIT([Cycript], [0.9], [saurik@saurik.com], [cycript], [http://www.cycript.org/])
35fa52c0	3	AC_CONFIG_SRCDIR([Console.cpp])
6b66678a	4	AC_CONFIG_AUX_DIR([.])
549f29b5	5	LT_INIT([disable-static])
3fd51f51	6	PKG_PROG_PKG_CONFIG([0.22])
632b71ea	7	CHECK_GNU_MAKE
790e5246 DWT	8	AC_SUBST([GMAKE], [$_cv_gnu_make_command])
790e5246 DWT	9	AS_IF([test "x$GMAKE" = x], [AC_MSG_ERROR([You need GNU make])])
e9c9a47c DWT	10	AC_PATH_PROGS([_BASH], [bash])
	11	AS_IF([test "x$_BASH" = x], [AC_MSG_ERROR([You need GNU bash])])
	12	AC_PATH_PROGS([TIME], [time])
	13	AC_DEFUN([CY_CHECK_PROGS_VERSION], [
	14	AC_MSG_CHECKING(for ]$2[ >= ]$5[)
	15	AC_PATH_PROGS_FEATURE_CHECK(]$1[, ]$3[,
	16	AS_VERSION_COMPARE(`$ac_path_]$1[ ]$4[`, ]$5[, ,
	17	ac_cv_path_]$1[=$ac_path_]$1[
	18	,
	19	ac_cv_path_]$1[=$ac_path_]$1[
	20	)
	21	,
b5bd4353	22	AC_MSG_RESULT(no)
e9c9a47c DWT	23	AC_MSG_ERROR(You need ]$2[ ]$5[ or greater)
	24	)
	25	AC_SUBST(]$1[, $ac_cv_path_]$1[)
	26	AC_MSG_RESULT($]$1[)
	27	])
	28	AC_ARG_VAR([BISON], [GNU Project parser generator (yacc replacement)])
	29	CY_CHECK_PROGS_VERSION([BISON], [bison], [bison],
	30	[-V \| $SED -e '1 s/^bison (GNU Bison) \(.*\)$/\1/p;d'], [2.3])
	31	AC_ARG_VAR([FLEX], [the fast lexical analyser generator])
	32	CY_CHECK_PROGS_VERSION([FLEX], [flex], [flex],
	33	[--version \| $SED -e '1 s/^.* \(@<:@0-9.@:>@*\)$/\1/p;d'], [2.5.33])
	34	AC_ARG_VAR([GPERF], [perfect hash function generator])
	35	CY_CHECK_PROGS_VERSION([GPERF], [gperf], [gperf],
	36	[--version \| $SED -e '1 s/^.* \(@<:@0-9.@:>@*\)$/\1/p;d'], [3.0.3])
	37	AC_PROG_INSTALL
b5bd4353	38	AC_MSG_CHECKING([for GNU tar >=1.19])
e9c9a47c DWT	39	AC_PATH_PROGS_FEATURE_CHECK([GNUTAR], [tar gtar gnutar], [
e9c9a47c DWT	40	AS_IF([test "x`$ac_path_GNUTAR --version \| $SED -e '1 s/^tar (GNU tar)/&/p;d'`" != x], [
b5bd4353 DWT	41	AS_VERSION_COMPARE([`$ac_path_GNUTAR --version \| $SED -e '1 s/^tar (GNU tar) \(.*\)$/\1/p;d'`], [1.19], , [
	42	ac_cv_path_GNUTAR=$ac_path_GNUTAR
	43	], [
	44	ac_cv_path_GNUTAR=$ac_path_GNUTAR
	45	])
e9c9a47c DWT	46	])
	47	])
	48	AS_IF([test "x$ac_cv_path_GNUTAR" != x], [
	49	AC_SUBST([GNUTAR], [$ac_cv_path_GNUTAR])
	50	AC_MSG_RESULT([$GNUTAR])
	51	], [
	52	AC_SUBST([GNUTAR], [:])
b5bd4353	53	AC_MSG_RESULT([no])
e9c9a47c	54	])
b65019fe DWT	55	AC_CHECK_PROGS([SVN], [svn])
b65019fe DWT	56	AC_CHECK_PROGS([SVNVERSION], [svnversion])
47aaa820	57	AC_PROG_CXX
632b71ea DWT	58	AC_PROG_OBJCXX
	59	AC_ARG_WITH([frameworks], [AS_HELP_STRING(
	60	[--with-frameworks=DIRS],
	61	[add to DIRS (space separated) to the Darwin include path for frameworks with -F]
	62	)], [
	63	for framework in $withval; do
	64	AC_LIB_APPENDTOVAR([CFLAGS], [-F$framework])
	65	AC_LIB_APPENDTOVAR([CXXFLAGS], [-F$framework])
	66	AC_LIB_APPENDTOVAR([OBJCCXXFLAGS], [-F$framework])
	67	done
	68	])
47aaa820	69	AC_LANG([C++])
309b0535 DWT	70	APR_FIND_APR([], [], [1], [1])
	71	AS_CASE([$apr_found], [yes], [
	72	AC_LIB_APPENDTOVAR([CPPFLAGS], [`$apr_config --includes`])
549f29b5	73	AC_SUBST([LTLIBAPR], [`$apr_config --link-libtool`])
309b0535	74	], [AC_MSG_ERROR([You need apr])])
b66977f1 DWT	75	AC_DEFUN([CY_CHECK_JAVASCRIPTCORE], [
b66977f1 DWT	76	PKG_CHECK_MODULES([WEBKIT], [webkit-1.0], [
a667869d	77	CY_EXECUTE=1
b66977f1 DWT	78	AC_LIB_APPENDTOVAR([CXXFLAGS], [`$PKG_CONFIG --cflags webkit-1.0`])
b66977f1 DWT	79	AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs webkit-1.0`])
b128dfee	80	], [
b66977f1 DWT	81	PKG_CHECK_MODULES([WEBKIT], [WebKitGtk], [
	82	CY_EXECUTE=1
	83	AC_LIB_APPENDTOVAR([CXXFLAGS], [`$PKG_CONFIG --cflags WebKitGtk`])
	84	AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs WebKitGtk`])
	85	], [
	86	AC_CHECK_FRAMEWORK([JavaScriptCore], [
	87	#include <JavaScriptCore/JSBase.h>
	88	], [JSEvaluateScript(0, 0, 0, 0, 0, 0);], [CY_EXECUTE=1])
	89	])
b128dfee	90	])
35fa52c0	91	])
b66977f1 DWT	92	AC_DEFUN([CY_CHECK_JAVASCRIPT], [
	93	CY_CHECK_JAVASCRIPTCORE
	94	])
	95	AC_ARG_ENABLE([javascript], [AS_HELP_STRING(
	96	[--enable-javascript@<:@=ENGINE@:>@],
	97	[use a JavaScript runtime (currently the only available option for ENGINE is JavaScriptCore) @<:@default=yes@:>@]
	98	)], [
	99	AS_CASE([$enableval], [yes], [CY_CHECK_JAVASCRIPT], [no], [
	100	AC_SUBST([CY_EXECUTE], [0])
	101	], [JavaScriptCore], [
	102	CY_CHECK_JAVASCRIPTCORE
	103	], [AC_MSG_ERROR([Unknown JavaScript engine: $enableval])])
	104	], [CY_CHECK_JAVASCRIPT])
e5cca37d	105	AC_DEFUN([CY_CHECK_PKG_CONFIG_LIBFFI], [
3fd51f51 DWT	106	PKG_CHECK_MODULES([LIBFFI], [libffi], [
	107	AC_LIB_APPENDTOVAR([CXXFLAGS], [`$PKG_CONFIG --cflags libffi`])
	108	AC_LIB_APPENDTOVAR([LIBS], [`$PKG_CONFIG --libs libffi`])
	109	], [
e5cca37d DWT	110	AC_MSG_ERROR([You need libffi])
	111	])
	112	])
	113	AS_CASE([$CY_EXECUTE], [1], [
	114	AC_SUBST([CY_EXECUTE])
	115	AC_CHECK_HEADERS([ffi.h ffi/ffi.h], [break])
	116	AS_IF([test "x$ac_cv_header_ffi_h" = xno && test "x$ac_cv_header_ffi_ffi_h" = xno], [
	117	CY_CHECK_PKG_CONFIG_LIBFFI
	118	], [
6b66678a	119	AC_SEARCH_LIBS([ffi_call], [ffi])
e5cca37d	120	AS_CASE([$ac_cv_search_ffi_call], [no], [CY_CHECK_PKG_CONFIG_LIBFFI])
6b66678a	121	])
a667869d DWT	122	AC_LANG_PUSH([Objective C++])
	123	AC_MSG_CHECKING([if we really have Objective C++])
	124	AC_COMPILE_IFELSE([
	125	// This space intentionally left blank
	126	], [
	127	CY_OBJECTIVEC=1
	128	AC_MSG_RESULT([yes])
	129	], [AC_MSG_RESULT([no])])
a667869d	130	AS_IF([test "x$CY_OBJECTIVEC" = x1], [
c823f118 DWT	131	AC_CHECK_FRAMEWORK([CoreFoundation], [
	132	#include <CoreFoundation/CFBase.h>
	133	], [CFAllocatorGetDefault();], [
a667869d	134	AC_SUBST([CY_OBJECTIVEC])
c823f118 DWT	135	AC_CHECK_FRAMEWORK([Foundation], [
	136	#include <Foundation/NSObject.h>
	137	], [[[[NSObject alloc] init];]])
	138	AC_CHECK_FRAMEWORK([WebKit], [
	139	#include <WebKit/WebScriptObject.h>
	140	], [[[[WebScriptObject alloc] init];]])
	141	], [
790e5246	142	AC_ARG_VAR([GNUSTEP_CONFIG], [prints information about the current gnustep installation])
c823f118 DWT	143	AC_CHECK_PROGS([GNUSTEP_CONFIG], [gnustep-config])
	144	AS_IF([test "x$GNUSTEP_CONFIG" != x], [
	145	AC_SUBST([CY_OBJECTIVEC])
	146	AC_LIB_APPENDTOVAR([OBJCXXFLAGS], [`$GNUSTEP_CONFIG --objc-flags`])
	147	AC_LIB_APPENDTOVAR([LIBS], [`$GNUSTEP_CONFIG --base-libs`])
	148	], [AC_SUBST([CY_OBJECTIVEC], [0])])
a667869d DWT	149	])
a667869d DWT	150	])
c823f118	151	AC_LANG_POP([Objective C++])
3fd51f51	152	])
058f1bc8 DWT	153	VL_LIB_READLINE
058f1bc8 DWT	154	AS_CASE([$vl_cv_lib_readline], [no], [AC_MSG_ERROR([You need readline])])
5053a6d1 DWT	155	AC_LANG_PUSH([C])
5053a6d1 DWT	156	AM_ICONV
058f1bc8 DWT	157	AS_CASE([$am_cv_func_iconv], [yes], [], [
	158	for cy_iconv_prefix_arg in $CFLAGS $CXXFLAGS $OBJCXXFLAGS $LDFLAGS $LIBS; do
	159	AS_CASE([$cy_iconv_prefix_arg], [-I*], [
	160	AC_LIB_APPENDTOVAR([cy_iconv_prefixes], [`echo $cy_iconv_prefix_arg \| sed -e 's/^-I//;s\|/include$\|\|'`])
	161	], [-L*], [
	162	AC_LIB_APPENDTOVAR([cy_iconv_prefixes], [`echo $cy_iconv_prefix_arg \| sed -e 's/^-L//;s\|/lib$\|\|'`])
	163	])
	164	done
	165	for with_libiconv_prefix in $cy_iconv_prefixes; do
	166	AS_UNSET([am_cv_func_iconv])
	167	AM_ICONV_LINKFLAGS_BODY
	168	AM_ICONV
	169	done
	170	])
5053a6d1	171	AS_CASE([$am_cv_func_iconv], [yes], [], [AC_MSG_ERROR([You need iconv])])
058f1bc8	172	AC_LANG_POP([C])
e1cce270 DWT	173	AS_IF([test "x$CY_OBJECTIVEC" = x1], [
	174	AC_CHECK_HEADER([mach/mach.h], [
	175	AS_CASE([$OTOOL], [:], [AC_MSG_WARN([Missing otool?])], [AC_SUBST([CY_OBJECTIVEC_MACH], [1])])
	176	])
	177	])
790e5246 DWT	178	AS_IF([test "x$GMAKE" != xmake], [
	179	AC_CONFIG_FILES([Makefile])
	180	])
9c60689e DWT	181	AC_CONFIG_FILES([GNUmakefile])
9c60689e DWT	182	AC_OUTPUT