configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl The ONLY thing this is used for is to configure for different
   3 dnl linux architectures and configurations, it is not used to make the
   4 dnl code more portable
   5
   6 dnl You MUST have an environment that has all the POSIX functions and
   7 dnl some of the more populare bsd/sysv ones (like select). You'll also
   8 dnl need a C++ compiler that is semi-standard conformant, exceptions are
   9 dnl not used but STL is.
  10
  11 AC_INIT(configure.in)
  12 AC_CONFIG_AUX_DIR(buildlib)
  13 AC_CONFIG_HEADER(include/config.h:buildlib/config.h.in)
  14
  15 dnl Tom's host stuff
  16 tl_CHECK_TOOL_PREFIX    dnl Initial guess
  17
  18 dnl Check our C compiler
  19 tl_PROG_CC
  20 AC_ISC_POSIX
  21
  22 dnl Check the host arch (build+target not needed... yet)
  23 tl_CANONICAL_HOST
  24 tl_CHECK_TOOL_PREFIX    dnl recheck, in case the initial guess was wrong
  25
  26 dnl Check for other programs
  27 tl_PROG_CXX
  28 AC_LANG_CPLUSPLUS
  29
  30 dnl Checks for X11
  31 AC_PATH_X
  32 AC_PATH_XTRA
  33 AC_SUBST(X11LIB)
  34 X11LIB=
  35 if test "$no_x" != "yes"; then
  36   X11LIB="-lx11"
  37   AC_DEFINE(HAVE_X11)
  38 fi
  39
  40 dnl Checks for Slang
  41 AC_CHECK_LIB(slang, init_SLang,[AC_DEFINE(HAVE_LIBSLANG) SLANGLIB="-lslang"])
  42 AC_SUBST(SLANGLIB)
  43
  44 dnl Checks for GPM
  45 AC_ARG_WITH(gpm,[  --without-gpm                  do not use GPM mouse support])
  46 if test "$with_gpm" != "no"; then
  47   AC_CHECK_LIB(gpm, Gpm_Open,[AC_DEFINE(HAVE_LIBGPM) GPMLIB="-lgpm"])
  48   AC_SUBST(GPMLIB)
  49 fi
  50
  51 dnl Converts the ARCH to be the same as dpkg
  52 AC_MSG_CHECKING(system architecture)
  53 archset="`awk '$1 == "'$host_cpu'" { print $2 }' $srcdir/buildlib/archtable`"
  54 if test "x$archset" = "x"; then
  55   AC_MSG_ERROR(failed: use --host=)
  56 fi
  57 AC_MSG_RESULT($archset)
  58 AC_DEFINE_UNQUOTED(PKG_DEB_ARCH,"$archset")
  59
  60 dnl Check the sizes etc. of the architecture
  61 changequote(,)
  62 if archline="`sed -ne 's/^'$archset':[  ]\+\(.*\)/\1/gp' $srcdir/buildlib/sizetable`"; then
  63 changequote([,])
  64   set $archline
  65   if test "$1" = "little"; then
  66     ac_cv_c_bigendian=no
  67   else
  68     ac_cv_c_bigendian=yes
  69   fi
  70   size_char=$2
  71   size_int=$3
  72   size_short=$4
  73   size_long=$5
  74 fi
  75 if test "$cross_compiling" = "yes" -a "$archline" = ""; then
  76   AC_MSG_ERROR(When cross compiling, architecture must be present in sizetable)
  77 fi
  78 AC_C_BIGENDIAN
  79 AC_CHECK_SIZEOF(char,$size_char)
  80 AC_CHECK_SIZEOF(int,$size_int)
  81 AC_CHECK_SIZEOF(short,$size_short)
  82 AC_CHECK_SIZEOF(long,$size_long)
  83
  84 dnl Check for debiandoc
  85 AC_CHECK_PROG(DEBIANDOC_HTML,debiandoc2html,"yes","")
  86 AC_CHECK_PROG(DEBIANDOC_TEXT,debiandoc2text,"yes","")
  87
  88 AC_OUTPUT(environment.mak:buildlib/environment.mak.in makefile:buildlib/makefile.in,make dirs)