configure.in

   1 ad
   2 dnl Process this file with autoconf to produce a configure script.
   3 dnl The ONLY thing this is used for is to configure for different
   4 dnl linux architectures and configurations, it is not used to make the
   5 dnl code more portable
   6
   7 dnl You MUST have an environment that has all the POSIX functions and
   8 dnl some of the more populare bsd/sysv ones (like select). You'll also
   9 dnl need a C++ compiler that is semi-standard conformant, exceptions are
  10 dnl not used but STL is.
  11
  12 dnl 'make -f Makefile startup' will generate the configure file from
  13 dnl configure.in correctly and can be run at any time
  14
  15 AC_INIT(configure.in)
  16 AC_CONFIG_AUX_DIR(buildlib)
  17 AC_CONFIG_HEADER(include/config.h:buildlib/config.h.in include/apti18n.h:buildlib/apti18n.h.in)
  18
  19 dnl -- SET THIS TO THE RELEASE VERSION --
  20 AC_DEFINE_UNQUOTED(VERSION,"0.5.5.1")
  21 PACKAGE="apt"
  22 AC_DEFINE_UNQUOTED(PACKAGE,"$PACKAGE")
  23 AC_SUBST(PACKAGE)
  24
  25 dnl Check the archs, we want the target type.
  26 AC_CANONICAL_SYSTEM
  27
  28 dnl Check our C compiler
  29 AC_CHECK_TOOL_PREFIX
  30 AC_PROG_CC
  31 AC_ISC_POSIX
  32
  33 dnl Check for other programs
  34 AC_PROG_CXX
  35 AC_PROG_CPP
  36 AC_PROG_RANLIB
  37 AC_CHECK_TOOL(AR,ar,"ar")
  38
  39 dnl Checks for sockets
  40 SAVE_LIBS="$LIBS"
  41 LIBS=""
  42 AC_SEARCH_LIBS(gethostbyname,nsl)
  43 AC_SEARCH_LIBS(connect,socket)
  44 SOCKETLIBS="$LIBS"
  45 AC_SUBST(SOCKETLIBS)
  46 LIBS="$SAVE_LIBS"
  47
  48 dnl Checks for pthread -- disabled due to glibc bugs jgg
  49 dnl AC_CHECK_LIB(pthread, pthread_create,[AC_DEFINE(HAVE_PTHREAD) PTHREADLIB="-lpthread"])
  50 AC_SUBST(PTHREADLIB)
  51 dnl if test "$PTHREADLIB" != "-lpthread"; then
  52 dnl   AC_MSG_ERROR(failed: I need posix threads, pthread)
  53 dnl fi
  54
  55 dnl Check for DB2
  56 AC_CHECK_HEADER(db2/db.h,
  57      [AC_CHECK_LIB(db2,db_open,
  58         [AC_DEFINE(HAVE_DB2) DB2LIB="-ldb2"])])
  59 AC_SUBST(DB2LIB)
  60
  61 dnl Converts the ARCH to be something singular for this general CPU family
  62 dnl This is often the dpkg architecture string.
  63 AC_MSG_CHECKING(system architecture)
  64 archset="`awk \" ! /^#|^\\\$/ { if(match(\\\"$target_cpu\\\",\\\"^\\\"\\\$1\\\"\\\$\\\")) {print \\\$2; exit}}\" $srcdir/buildlib/archtable`"
  65 if test "x$archset" = "x"; then
  66   AC_MSG_ERROR(failed: use --host=)
  67 fi
  68 AC_MSG_RESULT($archset)
  69 AC_DEFINE_UNQUOTED(COMMON_CPU,"$archset")
  70
  71 dnl Get a common name for the host OS - this is primarily only for HURD and is
  72 dnl non fatal if it fails
  73 AC_MSG_CHECKING(system OS)
  74 osset="`awk \" ! /^#|^\\\$/ {if (match(\\\"$target_vendor-$target_os\\\",\\\$1)) {print \\\$2; exit}}\" $srcdir/buildlib/ostable`"
  75 AC_MSG_RESULT($osset)
  76 AC_DEFINE_UNQUOTED(COMMON_OS,"$osset")
  77
  78 dnl We use C99 types if at all possible
  79 AC_CACHE_CHECK([for C99 integer types],c9x_ints,[
  80     AC_TRY_COMPILE([#include <inttypes.h>],
  81                    [uint8_t Foo1;uint16_t Foo2;uint32_t Foo3;],
  82                    c9x_ints=yes,c9x_ints=no)])
  83
  84 dnl Single Unix Spec statvfs
  85 AC_CHECK_FUNC(statvfs,[HAVE_STATVFS=yes])
  86 AC_SUBST(HAVE_STATVFS)
  87
  88 dnl Arg, linux and bsd put their statfs function in different places
  89 if test x"$HAVE_STATVFS" != x"yes"; then
  90    AC_EGREP_HEADER(statfs,sys/vfs.h,[AC_DEFINE(HAVE_VFS_H)],[
  91    AC_EGREP_HEADER(statfs,sys/mount.h,[AC_DEFINE(HAVE_MOUNT_H)],[AC_MSG_ERROR(failed: Need statvfs)])
  92    ])
  93 fi
  94
  95 dnl We should use the real timegm function if we have it.
  96 AC_CHECK_FUNC(timegm,AC_DEFINE(HAVE_TIMEGM))
  97 AC_SUBST(HAVE_TIMEGM)
  98
  99 dnl Check the sizes etc. of the architecture
 100 dnl This is stupid, it should just use the AC macros like it does below
 101 dnl Cross compilers can either get a real C library or preload the cache
 102 dnl with their size values.
 103 changequote(,)
 104 archline="`awk \" ! /^#|^\\\$/ {if (match(\\\"$archset\\\",\\\$1)) {print; exit}}\" $srcdir/buildlib/sizetable | cut -f 2- -d ' '`"
 105 if test "x$archline" != "x"; then
 106    changequote([,])
 107    set $archline
 108    if test "$1" = "little"; then
 109       ac_cv_c_bigendian=no
 110    else
 111       ac_cv_c_bigendian=yes
 112    fi
 113    size_char=$2
 114    size_int=$3
 115    size_short=$4
 116    size_long=$5
 117 fi
 118
 119 dnl I wonder what AC_C_BIGENDIAN does if you cross compile...
 120 dnl This is probably bogus, as above we only care if we have to build our own
 121 dnl C9x types.
 122 if test "$cross_compiling" = "yes" -a "x$archline" = "x"; then
 123   AC_MSG_ERROR(When cross compiling, architecture must be present in sizetable)
 124 fi
 125 AC_C_BIGENDIAN
 126
 127 dnl We do not need this if we have inttypes!
 128 HAVE_C9X=yes
 129 if test x"$c9x_ints" = x"no"; then
 130    AC_CHECK_SIZEOF(char,$size_char)
 131    AC_CHECK_SIZEOF(int,$size_int)
 132    AC_CHECK_SIZEOF(short,$size_short)
 133    AC_CHECK_SIZEOF(long,$size_long)
 134
 135    HAVE_C9X=
 136    AC_SUBST(HAVE_C9X)
 137 fi
 138
 139 dnl HP-UX sux..
 140 AC_MSG_CHECKING(for missing socklen_t)
 141 AC_EGREP_HEADER(socklen_t, sys/socket.h,[AC_MSG_RESULT(no)],[
 142         AC_DEFINE(NEED_SOCKLEN_T_DEFINE)
 143         NEED_SOCKLEN_T_DEFINE=yes
 144         AC_MSG_RESULT(missing.)])
 145 AC_SUBST(NEED_SOCKLEN_T_DEFINE)
 146
 147 dnl HP-UX needs -d_XOPEN_SOURCE_EXTENDED for h_errno
 148 AC_MSG_CHECKING(for h_errno)
 149 AC_EGREP_HEADER(h_errno, netdb.h, [AC_MSG_RESULT(normal)],
 150    [CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE_EXTENDED"
 151     AC_EGREP_HEADER(h_errno, netdb.h,
 152        [AC_MSG_RESULT(needs _XOPEN_SOURCE_EXTENDED)],
 153        [AC_MSG_ERROR("not found.")])
 154    ])
 155
 156 dnl Check for debiandoc
 157 AC_PATH_PROG(DEBIANDOC_HTML,debiandoc2html)
 158 AC_PATH_PROG(DEBIANDOC_TEXT,debiandoc2text)
 159
 160 dnl Check for the SGML tools needed to build man pages
 161 AC_PATH_PROG(DOCBOOK2MAN,docbook2man)
 162
 163 dnl Check for YODL
 164 dnl AC_CHECK_PROG(YODL_MAN,yodl2man,"yes","")
 165
 166 ah_NUM_PROCS
 167 rc_GLIBC_VER
 168 rc_LIBSTDCPP_VER
 169 ah_GCC3DEP
 170
 171 dnl It used to be that the user could select translations and that could get
 172 dnl passed to the makefiles, but now that can only work if you use special
 173 dnl gettext approved makefiles, so this feature is unsupported by this.
 174 ALL_LINGUAS="da de en_GB es fr hu it nl no_NO pl pt_BR ru sv zh_TW"
 175 AM_GNU_GETTEXT(external)
 176 if test x"$USE_NLS" = "xyes"; then
 177    AC_DEFINE(USE_NLS)
 178 fi
 179 AC_SUBST(USE_NLS)
 180 AC_PATH_PROG(BASH, bash)
 181
 182 AC_OUTPUT(environment.mak:buildlib/environment.mak.in makefile:buildlib/makefile.in,make -s dirs)