configure.in

   1 ad
   2 dnl Process this file with autoconf to produce a configure script.
   3 dnl The ONLY thing this is used for is to configure for different
   4 dnl linux architectures and configurations, it is not used to make the
   5 dnl code more portable
   6
   7 dnl You MUST have an environment that has all the POSIX functions and
   8 dnl some of the more populare bsd/sysv ones (like select). You'll also
   9 dnl need a C++ compiler that is semi-standard conformant, exceptions are
  10 dnl not used but STL is.
  11
  12 dnl 'make -f Makefile startup' will generate the configure file from
  13 dnl configure.in correctly and can be run at any time
  14
  15 AC_PREREQ(2.50)
  16 AC_INIT(configure.in)
  17 AC_CONFIG_AUX_DIR(buildlib)
  18 AC_CONFIG_HEADER(include/config.h:buildlib/config.h.in include/apti18n.h:buildlib/apti18n.h.in)
  19
  20 dnl -- SET THIS TO THE RELEASE VERSION --
  21 AC_DEFINE_UNQUOTED(VERSION,"0.7.2ubuntu1")
  22 PACKAGE="apt"
  23 AC_DEFINE_UNQUOTED(PACKAGE,"$PACKAGE")
  24 AC_SUBST(PACKAGE)
  25
  26 dnl Check the archs, we want the target type.
  27 AC_CANONICAL_SYSTEM
  28
  29 dnl Check our C compiler
  30 AC_CHECK_TOOL_PREFIX
  31 AC_PROG_CC
  32 AC_ISC_POSIX
  33
  34 dnl Check for other programs
  35 AC_PROG_CXX
  36 AC_PROG_CPP
  37 AC_PROG_RANLIB
  38 AC_CHECK_TOOL(AR,ar,"ar")
  39
  40 dnl Checks for sockets
  41 SAVE_LIBS="$LIBS"
  42 LIBS=""
  43 AC_SEARCH_LIBS(gethostbyname,nsl)
  44 AC_SEARCH_LIBS(connect,socket)
  45 SOCKETLIBS="$LIBS"
  46 AC_SUBST(SOCKETLIBS)
  47 LIBS="$SAVE_LIBS"
  48
  49 dnl Checks for pthread -- disabled due to glibc bugs jgg
  50 dnl AC_CHECK_LIB(pthread, pthread_create,[AC_DEFINE(HAVE_PTHREAD) PTHREADLIB="-lpthread"])
  51 AC_SUBST(PTHREADLIB)
  52 dnl if test "$PTHREADLIB" != "-lpthread"; then
  53 dnl   AC_MSG_ERROR(failed: I need posix threads, pthread)
  54 dnl fi
  55
  56 dnl Check for BDB
  57 saveLIBS="$LIBS"
  58 LIBS="$LIBS -ldb"
  59
  60 AC_CHECK_HEADER(db.h,
  61      [AC_MSG_CHECKING(if we can link against BerkeleyDB)
  62       AC_LINK_IFELSE(
  63       [AC_LANG_PROGRAM(
  64        [#include <db.h>],
  65        [int r, s, t; db_version(&r, &s, &t);]
  66       )],
  67       [AC_DEFINE(HAVE_BDB)
  68        BDBLIB="-ldb"
  69        AC_MSG_RESULT(yes)],
  70       [BDBLIB=""
  71        AC_MSG_RESULT(no)]
  72     )]
  73 )
  74
  75 LIBS="$saveLIBS"
  76
  77 AC_SUBST(BDBLIB)
  78
  79 dnl Converts the ARCH to be something singular for this general CPU family
  80 dnl This is often the dpkg architecture string.
  81 dnl First check against the full canonical canoncial-system-type in $target
  82 dnl and if that fails, just look for the cpu
  83 AC_MSG_CHECKING(system architecture)
  84 archset="`awk \" ! /^#|^\\\$/ { if(match(\\\"$target\\\",\\\"^\\\"\\\$1\\\"\\\$\\\")) {print \\\$2; exit}}\" $srcdir/buildlib/systemtable`"
  85 if test "x$archset" = "x"; then
  86  archset="`awk \" ! /^#|^\\\$/ { if(match(\\\"$target_cpu\\\",\\\"^\\\"\\\$1\\\"\\\$\\\")) {print \\\$2; exit}}\" $srcdir/buildlib/archtable`"
  87  if test "x$archset" = "x"; then
  88   AC_MSG_ERROR(failed: use --host= or check buildlib/archtable)
  89  fi
  90 fi
  91 AC_MSG_RESULT($archset)
  92 AC_DEFINE_UNQUOTED(COMMON_CPU,"$archset")
  93
  94 dnl Get a common name for the host OS - this is primarily only for HURD and is
  95 dnl non fatal if it fails
  96 AC_MSG_CHECKING(system OS)
  97 osset="`awk \" ! /^#|^\\\$/ {if (match(\\\"$target_vendor-$target_os\\\",\\\$1)) {print \\\$2; exit}}\" $srcdir/buildlib/ostable`"
  98 AC_MSG_RESULT($osset)
  99 AC_DEFINE_UNQUOTED(COMMON_OS,"$osset")
 100
 101 dnl We use C99 types if at all possible
 102 AC_CACHE_CHECK([for C99 integer types],c9x_ints,[
 103     AC_TRY_COMPILE([#include <inttypes.h>],
 104                    [uint8_t Foo1;uint16_t Foo2;uint32_t Foo3;],
 105                    c9x_ints=yes,c9x_ints=no)])
 106
 107 dnl Single Unix Spec statvfs
 108 AC_CHECK_FUNC(statvfs,[HAVE_STATVFS=yes])
 109 AC_SUBST(HAVE_STATVFS)
 110
 111 dnl Arg, linux and bsd put their statfs function in different places
 112 if test x"$HAVE_STATVFS" != x"yes"; then
 113    AC_EGREP_HEADER(statfs,sys/vfs.h,[AC_DEFINE(HAVE_VFS_H)],[
 114    AC_EGREP_HEADER(statfs,sys/mount.h,[AC_DEFINE(HAVE_MOUNT_H)],[AC_MSG_ERROR(failed: Need statvfs)])
 115    ])
 116 fi
 117
 118 dnl We should use the real timegm function if we have it.
 119 AC_CHECK_FUNC(timegm,AC_DEFINE(HAVE_TIMEGM))
 120 AC_SUBST(HAVE_TIMEGM)
 121
 122 dnl Check the sizes etc. of the architecture
 123 dnl This is stupid, it should just use the AC macros like it does below
 124 dnl Cross compilers can either get a real C library or preload the cache
 125 dnl with their size values.
 126 changequote(,)
 127 archline="`awk \" ! /^#|^\\\$/ {if (match(\\\"$archset\\\",\\\$1)) {print; exit}}\" $srcdir/buildlib/sizetable | cut -f 2- -d ' '`"
 128 if test "x$archline" != "x"; then
 129    changequote([,])
 130    set $archline
 131    if test "$1" = "little"; then
 132       ac_cv_c_bigendian=no
 133    else
 134       ac_cv_c_bigendian=yes
 135    fi
 136    size_char=$2
 137    size_int=$3
 138    size_short=$4
 139    size_long=$5
 140 fi
 141
 142 dnl I wonder what AC_C_BIGENDIAN does if you cross compile...
 143 dnl This is probably bogus, as above we only care if we have to build our own
 144 dnl C9x types.
 145 if test "$cross_compiling" = "yes" -a "x$archline" = "x"; then
 146   AC_MSG_ERROR(When cross compiling, architecture must be present in sizetable)
 147 fi
 148 AC_C_BIGENDIAN
 149
 150 dnl We do not need this if we have inttypes!
 151 HAVE_C9X=yes
 152 if test x"$c9x_ints" = x"no"; then
 153    AC_CHECK_SIZEOF(char,$size_char)
 154    AC_CHECK_SIZEOF(int,$size_int)
 155    AC_CHECK_SIZEOF(short,$size_short)
 156    AC_CHECK_SIZEOF(long,$size_long)
 157
 158    HAVE_C9X=
 159    AC_SUBST(HAVE_C9X)
 160 fi
 161
 162 dnl HP-UX sux..
 163 AC_MSG_CHECKING(for missing socklen_t)
 164 AC_EGREP_HEADER(socklen_t, sys/socket.h,[AC_MSG_RESULT(no)],[
 165         AC_DEFINE(NEED_SOCKLEN_T_DEFINE)
 166         NEED_SOCKLEN_T_DEFINE=yes
 167         AC_MSG_RESULT(missing.)])
 168 AC_SUBST(NEED_SOCKLEN_T_DEFINE)
 169
 170 dnl HP-UX needs -d_XOPEN_SOURCE_EXTENDED for h_errno
 171 AC_MSG_CHECKING(for h_errno)
 172 AC_EGREP_HEADER(h_errno, netdb.h, [AC_MSG_RESULT(normal)],
 173    [CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE_EXTENDED"
 174     AC_EGREP_HEADER(h_errno, netdb.h,
 175        [AC_MSG_RESULT(needs _XOPEN_SOURCE_EXTENDED)],
 176        [AC_MSG_ERROR("not found.")])
 177    ])
 178
 179 dnl Check for debiandoc
 180 AC_PATH_PROG(DEBIANDOC_HTML,debiandoc2html)
 181 AC_PATH_PROG(DEBIANDOC_TEXT,debiandoc2text)
 182
 183 dnl Check for doxygen
 184 AC_PATH_PROG(DOXYGEN, doxygen)
 185
 186 dnl Check for the SGML tools needed to build man pages
 187 AC_PATH_PROG(DOCBOOK2MAN,docbook2man)
 188
 189 dnl Check for the XML tools needed to build man pages
 190 AC_PATH_PROG(XMLTO,xmlto)
 191
 192 dnl Check for graphviz
 193 AC_CHECK_PROG([HAVE_DOT], [dot], [YES], [NO])
 194 AC_PATH_PROG([DOT], [dot], [])
 195 DOTDIR=$(dirname $DOT)
 196 AC_SUBST(DOTDIR)
 197
 198 dnl Check for YODL
 199 dnl AC_CHECK_PROG(YODL_MAN,yodl2man,"yes","")
 200
 201 ah_NUM_PROCS
 202 rc_GLIBC_VER
 203 rc_LIBSTDCPP_VER
 204 ah_GCC3DEP
 205
 206 dnl It used to be that the user could select translations and that could get
 207 dnl passed to the makefiles, but now that can only work if you use special
 208 dnl gettext approved makefiles, so this feature is unsupported by this.
 209 ALL_LINGUAS="bg bs ca cs cy da de dz el en_GB es eu fi fr gl hu it ja ko ku nb nl nn pl pt_BR pt ro ru sk sl sv tl uk vi zn_CN zh_TW"
 210 AM_GNU_GETTEXT(external)
 211 if test x"$USE_NLS" = "xyes"; then
 212    AC_DEFINE(USE_NLS)
 213 fi
 214 AC_SUBST(USE_NLS)
 215 AC_PATH_PROG(BASH, bash)
 216
 217 AC_OUTPUT(environment.mak:buildlib/environment.mak.in makefile:buildlib/makefile.in doc/Doxyfile,make -s dirs)