src/osx/cocoa/dataview.mm

   1 ///////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/osx/cocoa/dataview.mm
   3 // Purpose:     wxDataView
   4 // Author:
   5 // Modified by:
   6 // Created:     2009-01-31
   7 // RCS-ID:      $Id: dataview.mm$
   8 // Copyright:
   9 // Licence:     wxWindows licence
  10 ///////////////////////////////////////////////////////////////////////////////
  11
  12 #include "wx/wxprec.h"
  13
  14 #if (wxUSE_DATAVIEWCTRL == 1) && !defined(wxUSE_GENERICDATAVIEWCTRL)
  15
  16 #ifndef WX_PRECOMP
  17     #include "wx/app.h"
  18     #include "wx/toplevel.h"
  19     #include "wx/font.h"
  20     #include "wx/settings.h"
  21     #include "wx/utils.h"
  22 #endif
  23
  24 #include "wx/osx/private.h"
  25 #include "wx/osx/cocoa/dataview.h"
  26 #include "wx/renderer.h"
  27
  28 // ============================================================================
  29 // Constants used locally
  30 // ============================================================================
  31
  32 #define DataViewPboardType @"OutlineViewItem"
  33
  34 // ============================================================================
  35 // Classes used locally in dataview.mm
  36 // ============================================================================
  37
  38 // ============================================================================
  39 // wxPointerObject
  40 // ============================================================================
  41
  42 @implementation wxPointerObject
  43
  44 -(id) init
  45 {
  46     self = [super init];
  47     if (self != nil)
  48         self->pointer = NULL;
  49     return self;
  50 }
  51
  52 -(id) initWithPointer:(void*) initPointer
  53 {
  54     self = [super init];
  55     if (self != nil)
  56         self->pointer = initPointer;
  57     return self;
  58 }
  59
  60 //
  61 // inherited methods from NSObject
  62 //
  63 -(BOOL) isEqual:(id)object
  64 {
  65     return (object != nil) &&
  66              ([object isKindOfClass:[wxPointerObject class]]) &&
  67                  (pointer == [((wxPointerObject*) object) pointer]);
  68 }
  69
  70 -(NSUInteger) hash
  71 {
  72     return (NSUInteger) pointer;
  73 }
  74
  75 -(void*) pointer
  76 {
  77     return pointer;
  78 }
  79
  80 -(void) setPointer:(void*) newPointer
  81 {
  82     pointer = newPointer;
  83 }
  84
  85 @end
  86
  87 namespace
  88 {
  89
  90 inline wxDataViewItem wxDataViewItemFromItem(id item)
  91 {
  92     return wxDataViewItem([static_cast<wxPointerObject *>(item) pointer]);
  93 }
  94
  95 inline wxDataViewItem wxDataViewItemFromMaybeNilItem(id item)
  96 {
  97     return item == nil ? wxDataViewItem() : wxDataViewItemFromItem(item);
  98 }
  99
 100 } // anonymous namespace
 101
 102 // ----------------------------------------------------------------------------
 103 // wxCustomRendererObject
 104 // ----------------------------------------------------------------------------
 105
 106 @interface wxCustomRendererObject : NSObject <NSCopying>
 107 {
 108 @public
 109     wxDataViewCustomRenderer* customRenderer; // not owned by the class
 110 }
 111
 112     -(id) init;
 113     -(id) initWithRenderer:(wxDataViewCustomRenderer*)renderer;
 114 @end
 115
 116 @implementation wxCustomRendererObject
 117
 118 -(id) init
 119 {
 120     self = [super init];
 121     if (self != nil)
 122     {
 123         customRenderer = NULL;
 124     }
 125     return self;
 126 }
 127
 128 -(id) initWithRenderer:(wxDataViewCustomRenderer*)renderer
 129 {
 130     self = [super init];
 131     if (self != nil)
 132     {
 133         customRenderer = renderer;
 134     }
 135     return self;
 136 }
 137
 138 -(id) copyWithZone:(NSZone*)zone
 139 {
 140     wxCustomRendererObject* copy;
 141
 142     copy = [[[self class] allocWithZone:zone] init];
 143     copy->customRenderer = customRenderer;
 144
 145     return copy;
 146 }
 147 @end
 148
 149 // ----------------------------------------------------------------------------
 150 // wxDVCNSTableColumn: exists only to override NSTableColumn:dataCellForRow:
 151 // ----------------------------------------------------------------------------
 152
 153 @interface wxDVCNSTableColumn : NSTableColumn
 154 {
 155 }
 156
 157     -(id) dataCellForRow:(NSInteger)row;
 158 @end
 159
 160 @implementation wxDVCNSTableColumn
 161
 162 -(id) dataCellForRow:(NSInteger)row
 163 {
 164     // what we want to do here is to simply return nil for the cells which
 165     // shouldn't show anything as otherwise we would show e.g. empty combo box
 166     // or progress cells in the columns using the corresponding types even for
 167     // the container rows which is wrong
 168
 169     // half of the problem is just finding the objects we need from the column
 170     // pointer which is itself stashed inside wxPointerObject which we use as
 171     // our identifier
 172     const wxDataViewColumn * const
 173         dvCol = static_cast<wxDataViewColumn *>(
 174                     [(wxPointerObject *)[self identifier] pointer]
 175                 );
 176
 177     const wxDataViewCtrl * const dvc = dvCol->GetOwner();
 178     const wxCocoaDataViewControl * const
 179         peer = static_cast<wxCocoaDataViewControl *>(dvc->GetPeer());
 180
 181
 182     // once we do have everything, simply ask NSOutlineView for the item...
 183     const id item = peer->GetItemAtRow(row);
 184     if ( item )
 185     {
 186         // ... and if it succeeded, ask the model whether it has any value
 187         wxDataViewItem dvItem(wxDataViewItemFromItem(item));
 188
 189         if ( !dvc->GetModel()->HasValue(dvItem, dvCol->GetModelColumn()) )
 190             return nil;
 191     }
 192
 193     return [super dataCellForRow:row];
 194 }
 195
 196 @end
 197
 198 // ============================================================================
 199 // local helpers
 200 // ============================================================================
 201
 202 namespace
 203 {
 204
 205 // convert from NSObject to different C++ types: all these functions check
 206 // that the conversion really makes sense and assert if it doesn't
 207 wxString ObjectToString(NSObject *object)
 208 {
 209     wxCHECK_MSG( [object isKindOfClass:[NSString class]], "",
 210                  wxString::Format
 211                  (
 212                     "string expected but got %s",
 213                     wxCFStringRef::AsString([object className])
 214                  ));
 215
 216     return wxCFStringRef([((NSString*) object) retain]).AsString();
 217 }
 218
 219 bool ObjectToBool(NSObject *object)
 220 {
 221     // actually the value must be of NSCFBoolean class but it's private so we
 222     // can't check for it directly
 223     wxCHECK_MSG( [object isKindOfClass:[NSNumber class]], false,
 224                  wxString::Format
 225                  (
 226                     "number expected but got %s",
 227                     wxCFStringRef::AsString([object className])
 228                  ));
 229
 230     return [(NSNumber *)object boolValue];
 231 }
 232
 233 long ObjectToLong(NSObject *object)
 234 {
 235     wxCHECK_MSG( [object isKindOfClass:[NSNumber class]], -1,
 236                  wxString::Format
 237                  (
 238                     "number expected but got %s",
 239                     wxCFStringRef::AsString([object className])
 240                  ));
 241
 242     return [(NSNumber *)object longValue];
 243 }
 244
 245 wxDateTime ObjectToDate(NSObject *object)
 246 {
 247     wxCHECK_MSG( [object isKindOfClass:[NSDate class]], wxInvalidDateTime,
 248                  wxString::Format
 249                  (
 250                     "date expected but got %s",
 251                     wxCFStringRef::AsString([object className])
 252                  ));
 253
 254     // get the number of seconds since 1970-01-01 UTC and this is the only
 255     // way to convert a double to a wxLongLong
 256     const wxLongLong seconds = [((NSDate*) object) timeIntervalSince1970];
 257
 258     wxDateTime dt(1, wxDateTime::Jan, 1970);
 259     dt.Add(wxTimeSpan(0,0,seconds));
 260
 261     // the user has entered a date in the local timezone but seconds
 262     // contains the number of seconds from date in the local timezone
 263     // since 1970-01-01 UTC; therefore, the timezone information has to be
 264     // transferred to wxWidgets, too:
 265     dt.MakeFromTimezone(wxDateTime::UTC);
 266
 267     return dt;
 268 }
 269
 270 NSInteger CompareItems(id item1, id item2, void* context)
 271 {
 272     NSArray* const sortDescriptors = (NSArray*) context;
 273
 274     NSUInteger const count = [sortDescriptors count];
 275
 276     NSInteger result = NSOrderedSame;
 277     for ( NSUInteger i = 0; i < count && result == NSOrderedSame; ++i )
 278     {
 279         wxSortDescriptorObject* const
 280             sortDescriptor = (wxSortDescriptorObject*)
 281                 [sortDescriptors objectAtIndex:i];
 282
 283         int rc = [sortDescriptor modelPtr]->Compare
 284                  (
 285                      wxDataViewItemFromItem(item1),
 286                      wxDataViewItemFromItem(item2),
 287                      [sortDescriptor columnPtr]->GetModelColumn(),
 288                      [sortDescriptor ascending] == YES
 289                  );
 290
 291         if ( rc < 0 )
 292             result = NSOrderedAscending;
 293         else if ( rc > 0 )
 294             result = NSOrderedDescending;
 295     }
 296
 297     return result;
 298 }
 299
 300 NSTextAlignment ConvertToNativeHorizontalTextAlignment(int alignment)
 301 {
 302     if (alignment & wxALIGN_CENTER_HORIZONTAL)
 303         return NSCenterTextAlignment;
 304     else if (alignment & wxALIGN_RIGHT)
 305         return NSRightTextAlignment;
 306     else
 307         return NSLeftTextAlignment;
 308 }
 309
 310 NSTableColumn* CreateNativeColumn(const wxDataViewColumn *column)
 311 {
 312     wxDataViewRenderer * const renderer = column->GetRenderer();
 313
 314     wxCHECK_MSG( renderer, NULL, "column should have a renderer" );
 315
 316     wxDVCNSTableColumn * const nativeColumn(
 317         [[wxDVCNSTableColumn alloc] initWithIdentifier:
 318             [[[wxPointerObject alloc] initWithPointer:
 319                 const_cast<wxDataViewColumn*>(column)]
 320              autorelease]]
 321     );
 322
 323     // setting the size related parameters:
 324     const int width = column->GetWidthVariable();
 325     int resizingMask;
 326     if (column->IsResizeable())
 327     {
 328         resizingMask = NSTableColumnUserResizingMask;
 329         [nativeColumn setMinWidth:column->GetMinWidth()];
 330         [nativeColumn setMaxWidth:column->GetMaxWidth()];
 331     }
 332     else // column is not resizeable [by user]
 333     {
 334         // if the control doesn't show a header, make the columns resize
 335         // automatically, this is particularly important for the single column
 336         // controls (such as wxDataViewTreeCtrl) as their unique column should
 337         // always take up all the available splace
 338         resizingMask = column->GetOwner()->HasFlag(wxDV_NO_HEADER)
 339                             ? NSTableColumnAutoresizingMask
 340                             : NSTableColumnNoResizing;
 341     }
 342     [nativeColumn setResizingMask:resizingMask];
 343     [nativeColumn setWidth:width];
 344
 345 #if MAC_OS_X_VERSION_MAX_ALLOWED >= MAC_OS_X_VERSION_10_5
 346     // setting the visibility:
 347     [nativeColumn setHidden:static_cast<BOOL>(column->IsHidden())];
 348 #endif
 349
 350     wxDataViewRendererNativeData * const renderData = renderer->GetNativeData();
 351
 352     // setting the header:
 353     [[nativeColumn headerCell] setAlignment:
 354         ConvertToNativeHorizontalTextAlignment(column->GetAlignment())];
 355     [[nativeColumn headerCell] setStringValue:
 356         [[wxCFStringRef(column->GetTitle()).AsNSString() retain] autorelease]];
 357     renderData->ApplyLineBreakMode([nativeColumn headerCell]);
 358
 359     // setting data cell's properties:
 360     [[nativeColumn dataCell] setWraps:NO];
 361     // setting the default data cell:
 362     [nativeColumn setDataCell:renderData->GetColumnCell()];
 363     // setting the editablility:
 364     const bool isEditable = renderer->GetMode() == wxDATAVIEW_CELL_EDITABLE;
 365
 366     [nativeColumn setEditable:isEditable];
 367     [[nativeColumn dataCell] setEditable:isEditable];
 368
 369     return nativeColumn;
 370 }
 371
 372 } // anonymous namespace
 373
 374 // ============================================================================
 375 // Public helper functions for dataview implementation on OSX
 376 // ============================================================================
 377
 378 wxWidgetImplType* CreateDataView(wxWindowMac* wxpeer,
 379                                  wxWindowMac* WXUNUSED(parent),
 380                                  wxWindowID WXUNUSED(id),
 381                                  const wxPoint& pos,
 382                                  const wxSize& size,
 383                                  long style,
 384                                  long WXUNUSED(extraStyle))
 385 {
 386     return new wxCocoaDataViewControl(wxpeer,pos,size,style);
 387 }
 388
 389 // ============================================================================
 390 // wxSortDescriptorObject
 391 // ============================================================================
 392
 393 @implementation wxSortDescriptorObject
 394 -(id) init
 395 {
 396     self = [super init];
 397     if (self != nil)
 398     {
 399         columnPtr = NULL;
 400         modelPtr  = NULL;
 401     }
 402     return self;
 403 }
 404
 405 -(id)
 406 initWithModelPtr:(wxDataViewModel*)initModelPtr
 407     sortingColumnPtr:(wxDataViewColumn*)initColumnPtr
 408     ascending:(BOOL)sortAscending
 409 {
 410     self = [super initWithKey:@"dummy" ascending:sortAscending];
 411     if (self != nil)
 412     {
 413         columnPtr = initColumnPtr;
 414         modelPtr  = initModelPtr;
 415     }
 416     return self;
 417 }
 418
 419 -(id) copyWithZone:(NSZone*)zone
 420 {
 421     wxSortDescriptorObject* copy;
 422
 423
 424     copy = [super copyWithZone:zone];
 425     copy->columnPtr = columnPtr;
 426     copy->modelPtr  = modelPtr;
 427
 428     return copy;
 429 }
 430
 431 //
 432 // access to model column's index
 433 //
 434 -(wxDataViewColumn*) columnPtr
 435 {
 436     return columnPtr;
 437 }
 438
 439 -(wxDataViewModel*) modelPtr
 440 {
 441     return modelPtr;
 442 }
 443
 444 -(void) setColumnPtr:(wxDataViewColumn*)newColumnPtr
 445 {
 446     columnPtr = newColumnPtr;
 447 }
 448
 449 -(void) setModelPtr:(wxDataViewModel*)newModelPtr
 450 {
 451     modelPtr = newModelPtr;
 452 }
 453
 454 @end
 455
 456 // ============================================================================
 457 // wxCocoaOutlineDataSource
 458 // ============================================================================
 459 @implementation wxCocoaOutlineDataSource
 460
 461 //
 462 // constructors / destructor
 463 //
 464 -(id) init
 465 {
 466     self = [super init];
 467     if (self != nil)
 468     {
 469         implementation = NULL;
 470         model          = NULL;
 471
 472         currentParentItem = nil;
 473
 474         children = [[NSMutableArray alloc] init];
 475         items    = [[NSMutableSet   alloc] init];
 476     }
 477     return self;
 478 }
 479
 480 -(void) dealloc
 481 {
 482     [currentParentItem release];
 483
 484     [children release];
 485     [items    release];
 486
 487     [super dealloc];
 488 }
 489
 490 //
 491 // methods of informal protocol:
 492 //
 493 -(BOOL)
 494 outlineView:(NSOutlineView*)outlineView
 495     acceptDrop:(id<NSDraggingInfo>)info
 496     item:(id)item childIndex:(NSInteger)index
 497 {
 498     NSArray* supportedTypes(
 499         [NSArray arrayWithObjects:DataViewPboardType,NSStringPboardType,nil]
 500     );
 501
 502     NSPasteboard* pasteboard([info draggingPasteboard]);
 503
 504     NSString* bestType([pasteboard availableTypeFromArray:supportedTypes]);
 505
 506     if ( bestType == nil )
 507         return FALSE;
 508
 509     wxDataViewCtrl * const dvc(implementation->GetDataViewCtrl());
 510
 511     wxCHECK_MSG( dvc, false,
 512                      "Pointer to data view control not set correctly." );
 513     wxCHECK_MSG( dvc->GetModel(), false,
 514                     "Pointer to model not set correctly." );
 515
 516     wxDataViewEvent event(wxEVT_COMMAND_DATAVIEW_ITEM_DROP, dvc->GetId());
 517     event.SetEventObject(dvc);
 518     event.SetItem(wxDataViewItemFromItem(item));
 519     event.SetModel(dvc->GetModel());
 520
 521     BOOL dragSuccessful;
 522     if ( [bestType compare:DataViewPboardType] == NSOrderedSame )
 523     {
 524         NSArray* dataArray((NSArray*)
 525                       [pasteboard propertyListForType:DataViewPboardType]);
 526         NSUInteger indexDraggedItem, noOfDraggedItems([dataArray count]);
 527
 528         indexDraggedItem = 0;
 529         while (indexDraggedItem < noOfDraggedItems)
 530         {
 531             wxDataObjectComposite* dataObjects(
 532                 implementation->GetDnDDataObjects((NSData*)
 533                     [dataArray objectAtIndex:indexDraggedItem]));
 534
 535             if (dataObjects && (dataObjects->GetFormatCount() > 0))
 536             {
 537                 wxMemoryBuffer buffer;
 538
 539                 // copy data into data object:
 540                 event.SetDataObject(dataObjects);
 541                 event.SetDataFormat(
 542                     implementation->GetDnDDataFormat(dataObjects));
 543                 // copy data into buffer:
 544                 dataObjects->GetDataHere(
 545                     event.GetDataFormat().GetType(),
 546                     buffer.GetWriteBuf(event.GetDataSize()));
 547                 buffer.UngetWriteBuf(event.GetDataSize());
 548                 event.SetDataBuffer(buffer.GetData());
 549                 // finally, send event:
 550                 if (dvc->HandleWindowEvent(event) && event.IsAllowed())
 551                 {
 552                     dragSuccessful = true;
 553                     ++indexDraggedItem;
 554                 }
 555                 else
 556                 {
 557                     dragSuccessful   = true;
 558                     indexDraggedItem = noOfDraggedItems; // stop loop
 559                 }
 560             }
 561             else
 562             {
 563                 dragSuccessful   = false;
 564                 indexDraggedItem = noOfDraggedItems; // stop loop
 565             }
 566             // clean-up:
 567             delete dataObjects;
 568         }
 569     }
 570     else
 571     {
 572         // needed to convert internally used UTF-16 representation to a UTF-8
 573         // representation
 574         CFDataRef              osxData;
 575         wxDataObjectComposite* dataObjects   (new wxDataObjectComposite());
 576         wxTextDataObject*      textDataObject(new wxTextDataObject());
 577
 578         osxData = ::CFStringCreateExternalRepresentation
 579                     (
 580                      kCFAllocatorDefault,
 581                      (CFStringRef)[pasteboard stringForType:NSStringPboardType],
 582                      kCFStringEncodingUTF8,
 583                      32
 584                     );
 585         if (textDataObject->SetData(::CFDataGetLength(osxData),
 586                                     ::CFDataGetBytePtr(osxData)))
 587             dataObjects->Add(textDataObject);
 588         else
 589             delete textDataObject;
 590         // send event if data could be copied:
 591         if (dataObjects->GetFormatCount() > 0)
 592         {
 593             event.SetDataObject(dataObjects);
 594             event.SetDataFormat(implementation->GetDnDDataFormat(dataObjects));
 595             if (dvc->HandleWindowEvent(event) && event.IsAllowed())
 596                 dragSuccessful = true;
 597             else
 598                 dragSuccessful = false;
 599         }
 600         else
 601             dragSuccessful = false;
 602         // clean up:
 603         ::CFRelease(osxData);
 604         delete dataObjects;
 605     }
 606     return dragSuccessful;
 607 }
 608
 609 -(id) outlineView:(NSOutlineView*)outlineView
 610     child:(NSInteger)index
 611     ofItem:(id)item
 612 {
 613     if ((item == currentParentItem) &&
 614             (index < ((NSInteger) [self getChildCount])))
 615         return [self getChild:index];
 616
 617     wxDataViewItemArray dataViewChildren;
 618
 619     wxCHECK_MSG( model, 0, "Valid model in data source does not exist." );
 620     model->GetChildren(wxDataViewItemFromMaybeNilItem(item), dataViewChildren);
 621     [self bufferItem:item withChildren:&dataViewChildren];
 622     if ([sortDescriptors count] > 0)
 623         [children sortUsingFunction:CompareItems context:sortDescriptors];
 624     return [self getChild:index];
 625 }
 626
 627 -(BOOL) outlineView:(NSOutlineView*)outlineView isItemExpandable:(id)item
 628 {
 629     wxCHECK_MSG( model, 0, "Valid model in data source does not exist." );
 630     return model->IsContainer(wxDataViewItemFromItem(item));
 631 }
 632
 633 -(NSInteger) outlineView:(NSOutlineView*)outlineView numberOfChildrenOfItem:(id)item
 634 {
 635     NSInteger noOfChildren;
 636
 637     wxDataViewItemArray dataViewChildren;
 638
 639
 640     wxCHECK_MSG( model, 0, "Valid model in data source does not exist." );
 641     noOfChildren = model->GetChildren(wxDataViewItemFromMaybeNilItem(item),
 642                                       dataViewChildren);
 643     [self bufferItem:item withChildren:&dataViewChildren];
 644     if ([sortDescriptors count] > 0)
 645         [children sortUsingFunction:CompareItems context:sortDescriptors];
 646     return noOfChildren;
 647 }
 648
 649 -(id)
 650 outlineView:(NSOutlineView*)outlineView
 651     objectValueForTableColumn:(NSTableColumn*)tableColumn
 652     byItem:(id)item
 653 {
 654     wxCHECK_MSG( model, nil, "Valid model in data source does not exist." );
 655
 656     wxDataViewColumn* col(static_cast<wxDataViewColumn*>([[tableColumn identifier] pointer]));
 657     const unsigned colIdx = col->GetModelColumn();
 658
 659     wxDataViewItem dataViewItem(wxDataViewItemFromItem(item));
 660
 661     if ( model->HasValue(dataViewItem, colIdx) )
 662     {
 663         wxVariant value;
 664         model->GetValue(value,dataViewItem, colIdx);
 665         col->GetRenderer()->SetValue(value);
 666     }
 667
 668     return nil;
 669 }
 670
 671 -(void)
 672 outlineView:(NSOutlineView*)outlineView
 673     setObjectValue:(id)object
 674     forTableColumn:(NSTableColumn*)tableColumn
 675     byItem:(id)item
 676 {
 677     wxDataViewColumn* col(static_cast<wxDataViewColumn*>([[tableColumn identifier] pointer]));
 678
 679     col->GetRenderer()->
 680         OSXOnCellChanged(object, wxDataViewItemFromItem(item), col->GetModelColumn());
 681 }
 682
 683 -(void) outlineView:(NSOutlineView*)outlineView sortDescriptorsDidChange:(NSArray*)oldDescriptors
 684 {
 685     // Warning: the new sort descriptors are guaranteed to be only of type
 686     // NSSortDescriptor! Therefore, the sort descriptors for the data source
 687     // have to be converted.
 688     NSArray* newDescriptors;
 689
 690     NSMutableArray* wxSortDescriptors;
 691
 692     NSUInteger noOfDescriptors;
 693
 694     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
 695
 696
 697     // convert NSSortDescriptors to wxSortDescriptorObjects:
 698     newDescriptors    = [outlineView sortDescriptors];
 699     noOfDescriptors   = [newDescriptors count];
 700     wxSortDescriptors = [NSMutableArray arrayWithCapacity:noOfDescriptors];
 701     for (NSUInteger i=0; i<noOfDescriptors; ++i)
 702     {
 703         NSSortDescriptor* const newDescriptor = [newDescriptors objectAtIndex:i];
 704
 705         [wxSortDescriptors addObject:[[[wxSortDescriptorObject alloc] initWithModelPtr:model
 706             sortingColumnPtr:dvc->GetColumn([[newDescriptor key] intValue])
 707             ascending:[newDescriptor ascending]] autorelease]];
 708     }
 709     [(wxCocoaOutlineDataSource*)[outlineView dataSource] setSortDescriptors:wxSortDescriptors];
 710
 711     // send first the event to wxWidgets that the sorting has changed so that
 712     // the program can do special actions before the sorting actually starts:
 713     wxDataViewEvent event(wxEVT_COMMAND_DATAVIEW_COLUMN_SORTED,dvc->GetId()); // variable defintion
 714
 715     event.SetEventObject(dvc);
 716     if (noOfDescriptors > 0)
 717     {
 718         wxDataViewColumn* const col = [[wxSortDescriptors objectAtIndex:0] columnPtr];
 719
 720         event.SetColumn(dvc->GetColumnPosition(col));
 721         event.SetDataViewColumn(col);
 722     }
 723     dvc->GetEventHandler()->ProcessEvent(event);
 724
 725     // start re-ordering the data;
 726     // children's buffer must be cleared first because it contains the old order:
 727     [self clearChildren];
 728     // sorting is done while reloading the data:
 729     [outlineView reloadData];
 730 }
 731
 732 -(NSDragOperation) outlineView:(NSOutlineView*)outlineView validateDrop:(id<NSDraggingInfo>)info proposedItem:(id)item proposedChildIndex:(NSInteger)index
 733 {
 734     NSArray* supportedTypes([NSArray arrayWithObjects:DataViewPboardType,NSStringPboardType,nil]);
 735
 736     NSPasteboard* pasteboard([info draggingPasteboard]);
 737
 738     NSString* bestType([pasteboard availableTypeFromArray:supportedTypes]);
 739     if (bestType == nil)
 740         return NSDragOperationNone;
 741
 742     NSDragOperation dragOperation;
 743     wxDataViewCtrl* const dvc(implementation->GetDataViewCtrl());
 744
 745     wxCHECK_MSG(dvc, false, "Pointer to data view control not set correctly.");
 746     wxCHECK_MSG(dvc->GetModel(), false, "Pointer to model not set correctly.");
 747
 748     wxDataViewEvent
 749         event(wxEVT_COMMAND_DATAVIEW_ITEM_DROP_POSSIBLE,dvc->GetId());
 750
 751     event.SetEventObject(dvc);
 752     event.SetItem(wxDataViewItemFromItem(item));
 753     event.SetModel(dvc->GetModel());
 754     if ([bestType compare:DataViewPboardType] == NSOrderedSame)
 755     {
 756         NSArray*               dataArray((NSArray*)[pasteboard propertyListForType:DataViewPboardType]);
 757         NSUInteger             indexDraggedItem, noOfDraggedItems([dataArray count]);
 758
 759         indexDraggedItem = 0;
 760         while (indexDraggedItem < noOfDraggedItems)
 761         {
 762             wxDataObjectComposite* dataObjects(implementation->GetDnDDataObjects((NSData*)[dataArray objectAtIndex:indexDraggedItem]));
 763
 764             if (dataObjects && (dataObjects->GetFormatCount() > 0))
 765             {
 766                 wxMemoryBuffer buffer;
 767
 768                 // copy data into data object:
 769                 event.SetDataObject(dataObjects);
 770                 event.SetDataFormat(implementation->GetDnDDataFormat(dataObjects));
 771                 // copy data into buffer:
 772                 dataObjects->GetDataHere(event.GetDataFormat().GetType(),buffer.GetWriteBuf(event.GetDataSize()));
 773                 buffer.UngetWriteBuf(event.GetDataSize());
 774                 event.SetDataBuffer(buffer.GetData());
 775                 // finally, send event:
 776                 if (dvc->HandleWindowEvent(event) && event.IsAllowed())
 777                 {
 778                     dragOperation = NSDragOperationEvery;
 779                     ++indexDraggedItem;
 780                 }
 781                 else
 782                 {
 783                     dragOperation    = NSDragOperationNone;
 784                     indexDraggedItem = noOfDraggedItems; // stop loop
 785                 }
 786             }
 787             else
 788             {
 789                 dragOperation    = NSDragOperationNone;
 790                 indexDraggedItem = noOfDraggedItems; // stop loop
 791             }
 792             // clean-up:
 793             delete dataObjects;
 794         }
 795     }
 796     else
 797     {
 798         // needed to convert internally used UTF-16 representation to a UTF-8
 799         // representation
 800         CFDataRef              osxData;
 801         wxDataObjectComposite* dataObjects   (new wxDataObjectComposite());
 802         wxTextDataObject*      textDataObject(new wxTextDataObject());
 803
 804         osxData = ::CFStringCreateExternalRepresentation(kCFAllocatorDefault,(CFStringRef)[pasteboard stringForType:NSStringPboardType],kCFStringEncodingUTF8,32);
 805         if (textDataObject->SetData(::CFDataGetLength(osxData),::CFDataGetBytePtr(osxData)))
 806             dataObjects->Add(textDataObject);
 807         else
 808             delete textDataObject;
 809         // send event if data could be copied:
 810         if (dataObjects->GetFormatCount() > 0)
 811         {
 812             event.SetDataObject(dataObjects);
 813             event.SetDataFormat(implementation->GetDnDDataFormat(dataObjects));
 814             if (dvc->HandleWindowEvent(event) && event.IsAllowed())
 815                 dragOperation = NSDragOperationEvery;
 816             else
 817                 dragOperation = NSDragOperationNone;
 818         }
 819         else
 820             dragOperation = NSDragOperationNone;
 821         // clean up:
 822         ::CFRelease(osxData);
 823         delete dataObjects;
 824     }
 825
 826     return dragOperation;
 827 }
 828
 829 -(BOOL) outlineView:(NSOutlineView*)outlineView writeItems:(NSArray*)writeItems toPasteboard:(NSPasteboard*)pasteboard
 830 {
 831     // the pasteboard will be filled up with an array containing the data as
 832     // returned by the events (including the data type) and a concatenation of
 833     // text (string) data; the text data will only be put onto the pasteboard
 834     // if for all items a string representation exists
 835     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
 836
 837     wxDataViewItemArray dataViewItems;
 838
 839
 840     wxCHECK_MSG(dvc, false,"Pointer to data view control not set correctly.");
 841     wxCHECK_MSG(dvc->GetModel(),false,"Pointer to model not set correctly.");
 842
 843     if ([writeItems count] > 0)
 844     {
 845         bool            dataStringAvailable(true); // a flag indicating if for all items a data string is available
 846         NSMutableArray* dataArray = [[NSMutableArray arrayWithCapacity:[writeItems count]] retain]; // data of all items
 847         wxString        dataString; // contains the string data of all items
 848
 849         // send a begin drag event for all selected items and proceed with
 850         // dragging unless the event is vetoed:
 851         wxDataViewEvent
 852             event(wxEVT_COMMAND_DATAVIEW_ITEM_BEGIN_DRAG,dvc->GetId());
 853
 854         event.SetEventObject(dvc);
 855         event.SetModel(dvc->GetModel());
 856         for (size_t itemCounter=0; itemCounter<[writeItems count]; ++itemCounter)
 857         {
 858             bool                   itemStringAvailable(false);              // a flag indicating if for the current item a string is available
 859             wxDataObjectComposite* itemObject(new wxDataObjectComposite()); // data object for current item
 860             wxString               itemString;                              // contains the TAB concatenated data of an item
 861
 862             event.SetItem(
 863                 wxDataViewItemFromItem([writeItems objectAtIndex:itemCounter]));
 864             itemString = ::ConcatenateDataViewItemValues(dvc,event.GetItem());
 865             itemObject->Add(new wxTextDataObject(itemString));
 866             event.SetDataObject(itemObject);
 867             // check if event has not been vetoed:
 868             if (dvc->HandleWindowEvent(event) && event.IsAllowed() && (event.GetDataObject()->GetFormatCount() > 0))
 869             {
 870                 size_t const noOfFormats = event.GetDataObject()->GetFormatCount();
 871                 wxDataFormat* dataFormats(new wxDataFormat[noOfFormats]);
 872
 873                 event.GetDataObject()->GetAllFormats(dataFormats,wxDataObject::Get);
 874                 for (size_t formatCounter=0; formatCounter<noOfFormats; ++formatCounter)
 875                 {
 876                     // constant definitions for abbreviational purposes:
 877                     wxDataFormatId const idDataFormat = dataFormats[formatCounter].GetType();
 878                     size_t const dataSize       = event.GetDataObject()->GetDataSize(idDataFormat);
 879                     size_t const dataBufferSize = sizeof(wxDataFormatId)+dataSize;
 880                     // variable definitions (used in all case statements):
 881                     wxMemoryBuffer dataBuffer(dataBufferSize);
 882
 883                     dataBuffer.AppendData(&idDataFormat,sizeof(wxDataFormatId));
 884                     switch (idDataFormat)
 885                     {
 886                         case wxDF_TEXT:
 887                             // otherwise wxDF_UNICODETEXT already filled up
 888                             // the string; and the UNICODE representation has
 889                             // priority
 890                             if (!itemStringAvailable)
 891                             {
 892                                 event.GetDataObject()->GetDataHere(wxDF_TEXT,dataBuffer.GetAppendBuf(dataSize));
 893                                 dataBuffer.UngetAppendBuf(dataSize);
 894                                 [dataArray addObject:[NSData dataWithBytes:dataBuffer.GetData() length:dataBufferSize]];
 895                                 itemString = wxString(static_cast<char const*>(dataBuffer.GetData())+sizeof(wxDataFormatId),wxConvLocal);
 896                                 itemStringAvailable = true;
 897                             }
 898                             break;
 899                         case wxDF_UNICODETEXT:
 900                             {
 901                                 event.GetDataObject()->GetDataHere(wxDF_UNICODETEXT,dataBuffer.GetAppendBuf(dataSize));
 902                                 dataBuffer.UngetAppendBuf(dataSize);
 903                                 if (itemStringAvailable) // does an object already exist as an ASCII text (see wxDF_TEXT case statement)?
 904                                     [dataArray replaceObjectAtIndex:itemCounter withObject:[NSData dataWithBytes:dataBuffer.GetData() length:dataBufferSize]];
 905                                 else
 906                                     [dataArray addObject:[NSData dataWithBytes:dataBuffer.GetData() length:dataBufferSize]];
 907                                 itemString = wxString::FromUTF8(static_cast<char const*>(dataBuffer.GetData())+sizeof(wxDataFormatId),dataSize);
 908                                 itemStringAvailable = true;
 909                             } /* block */
 910                             break;
 911                         default:
 912                             wxFAIL_MSG("Data object has invalid or unsupported data format");
 913                             [dataArray release];
 914                             return NO;
 915                     }
 916                 }
 917                 delete[] dataFormats;
 918                 delete itemObject;
 919                 if (dataStringAvailable)
 920                     if (itemStringAvailable)
 921                     {
 922                         if (itemCounter > 0)
 923                             dataString << wxT('\n');
 924                         dataString << itemString;
 925                     }
 926                     else
 927                         dataStringAvailable = false;
 928             }
 929             else
 930             {
 931                 [dataArray release];
 932                 delete itemObject;
 933                 return NO; // dragging was vetoed or no data available
 934             }
 935         }
 936         if (dataStringAvailable)
 937         {
 938             wxCFStringRef osxString(dataString);
 939
 940             [pasteboard declareTypes:[NSArray arrayWithObjects:DataViewPboardType,NSStringPboardType,nil] owner:nil];
 941             [pasteboard setPropertyList:dataArray forType:DataViewPboardType];
 942             [pasteboard setString:osxString.AsNSString() forType:NSStringPboardType];
 943         }
 944         else
 945         {
 946             [pasteboard declareTypes:[NSArray arrayWithObject:DataViewPboardType] owner:nil];
 947             [pasteboard setPropertyList:dataArray forType:DataViewPboardType];
 948         }
 949         return YES;
 950     }
 951     else
 952         return NO; // no items to drag (should never occur)
 953 }
 954
 955 //
 956 // buffer handling
 957 //
 958 -(void) addToBuffer:(wxPointerObject*)item
 959 {
 960     [items addObject:item];
 961 }
 962
 963 -(void) clearBuffer
 964 {
 965     [items removeAllObjects];
 966 }
 967
 968 -(wxPointerObject*) getDataViewItemFromBuffer:(const wxDataViewItem&)item
 969 {
 970     return [items member:[[[wxPointerObject alloc] initWithPointer:item.GetID()] autorelease]];
 971 }
 972
 973 -(wxPointerObject*) getItemFromBuffer:(wxPointerObject*)item
 974 {
 975     return [items member:item];
 976 }
 977
 978 -(BOOL) isInBuffer:(wxPointerObject*)item
 979 {
 980     return [items containsObject:item];
 981 }
 982
 983 -(void) removeFromBuffer:(wxPointerObject*)item
 984 {
 985     [items removeObject:item];
 986 }
 987
 988 //
 989 // children handling
 990 //
 991 -(void) appendChild:(wxPointerObject*)item
 992 {
 993     [children addObject:item];
 994 }
 995
 996 -(void) clearChildren
 997 {
 998     [children removeAllObjects];
 999 }
1000
1001 -(wxPointerObject*) getChild:(NSUInteger)index
1002 {
1003     return [children objectAtIndex:index];
1004 }
1005
1006 -(NSUInteger) getChildCount
1007 {
1008     return [children count];
1009 }
1010
1011 -(void) removeChild:(NSUInteger)index
1012 {
1013     [children removeObjectAtIndex:index];
1014 }
1015
1016 //
1017 // buffer handling
1018 //
1019 -(void) clearBuffers
1020 {
1021     [self clearBuffer];
1022     [self clearChildren];
1023     [self setCurrentParentItem:nil];
1024 }
1025
1026 //
1027 // sorting
1028 //
1029 -(NSArray*) sortDescriptors
1030 {
1031     return sortDescriptors;
1032 }
1033
1034 -(void) setSortDescriptors:(NSArray*)newSortDescriptors
1035 {
1036     [newSortDescriptors retain];
1037     [sortDescriptors release];
1038     sortDescriptors = newSortDescriptors;
1039 }
1040
1041 //
1042 // access to wxWidget's implementation
1043 //
1044 -(wxPointerObject*) currentParentItem
1045 {
1046     return currentParentItem;
1047 }
1048
1049 -(wxCocoaDataViewControl*) implementation
1050 {
1051     return implementation;
1052 }
1053
1054 -(wxDataViewModel*) model
1055 {
1056     return model;
1057 }
1058
1059 -(void) setCurrentParentItem:(wxPointerObject*)newCurrentParentItem
1060 {
1061     [newCurrentParentItem retain];
1062     [currentParentItem release];
1063     currentParentItem = newCurrentParentItem;
1064 }
1065
1066 -(void) setImplementation:(wxCocoaDataViewControl*) newImplementation
1067 {
1068     implementation = newImplementation;
1069 }
1070
1071 -(void) setModel:(wxDataViewModel*) newModel
1072 {
1073     model = newModel;
1074 }
1075
1076 //
1077 // other methods
1078 //
1079 -(void) bufferItem:(wxPointerObject*)parentItem withChildren:(wxDataViewItemArray*)dataViewChildrenPtr
1080 {
1081     NSInteger const noOfChildren = (*dataViewChildrenPtr).GetCount();
1082
1083     [self setCurrentParentItem:parentItem];
1084     [self clearChildren];
1085     for (NSInteger indexChild=0; indexChild<noOfChildren; ++indexChild)
1086     {
1087         wxPointerObject* bufferedPointerObject;
1088         wxPointerObject* newPointerObject([[wxPointerObject alloc] initWithPointer:(*dataViewChildrenPtr)[indexChild].GetID()]);
1089
1090         // The next statement and test looks strange but there is
1091         // unfortunately no workaround: due to the fact that two pointer
1092         // objects are identical if their pointers are identical - because the
1093         // method isEqual has been overloaded - the set operation will only
1094         // add a new pointer object if there is not already one in the set
1095         // having the same pointer. On the other side the children's array
1096         // would always add the new pointer object. This means that different
1097         // pointer objects are stored in the set and array. This will finally
1098         // lead to a crash as objects diverge. To solve this issue it is first
1099         // tested if the child already exists in the set and if it is the case
1100         // the sets object is going to be appended to the array, otheriwse the
1101         // new pointer object is added to the set and array:
1102         bufferedPointerObject = [self getItemFromBuffer:newPointerObject];
1103         if (bufferedPointerObject == nil)
1104         {
1105             [items    addObject:newPointerObject];
1106             [children addObject:newPointerObject];
1107         }
1108         else
1109             [children addObject:bufferedPointerObject];
1110         [newPointerObject release];
1111     }
1112 }
1113
1114 @end
1115
1116 // ============================================================================
1117 // wxCustomCell
1118 // ============================================================================
1119
1120 @implementation wxCustomCell
1121
1122 -(NSSize) cellSize
1123 {
1124     wxCustomRendererObject * const
1125         obj = static_cast<wxCustomRendererObject *>([self objectValue]);
1126
1127
1128     const wxSize size = obj->customRenderer->GetSize();
1129     return NSMakeSize(size.x, size.y);
1130 }
1131
1132 //
1133 // implementations
1134 //
1135 -(void) drawWithFrame:(NSRect)cellFrame inView:(NSView*)controlView
1136 {
1137     wxCustomRendererObject * const
1138         obj = static_cast<wxCustomRendererObject *>([self objectValue]);
1139     if ( !obj )
1140     {
1141         // this may happen for the custom cells in container rows: they don't
1142         // have any values
1143         return;
1144     }
1145
1146     wxDataViewCustomRenderer * const renderer = obj->customRenderer;
1147
1148     wxDC * const dc = renderer->GetDC();
1149     renderer->WXCallRender(wxFromNSRect(controlView, cellFrame), dc, 0);
1150     renderer->SetDC(NULL);
1151 }
1152
1153 -(NSRect) imageRectForBounds:(NSRect)cellFrame
1154 {
1155     return cellFrame;
1156 }
1157
1158 -(NSRect) titleRectForBounds:(NSRect)cellFrame
1159 {
1160     return cellFrame;
1161 }
1162
1163 @end
1164
1165 // ============================================================================
1166 // wxImageTextCell
1167 // ============================================================================
1168 @implementation wxImageTextCell
1169 //
1170 // initialization
1171 //
1172 -(id) init
1173 {
1174     self = [super init];
1175     if (self != nil)
1176     {
1177         // initializing the text part:
1178         [self setSelectable:YES];
1179         // initializing the image part:
1180         image       = nil;
1181         imageSize   = NSMakeSize(16,16);
1182         spaceImageText = 5.0;
1183         xImageShift    = 5.0;
1184     }
1185     return self;
1186 }
1187
1188 -(id) copyWithZone:(NSZone*)zone
1189 {
1190     wxImageTextCell* cell;
1191
1192
1193     cell = (wxImageTextCell*) [super copyWithZone:zone];
1194     cell->image          = [image retain];
1195     cell->imageSize      = imageSize;
1196     cell->spaceImageText = spaceImageText;
1197     cell->xImageShift    = xImageShift;
1198
1199     return cell;
1200 }
1201
1202 -(void) dealloc
1203 {
1204     [image release];
1205
1206     [super dealloc];
1207 }
1208
1209 //
1210 // alignment
1211 //
1212 -(NSTextAlignment) alignment
1213 {
1214     return cellAlignment;
1215 }
1216
1217 -(void) setAlignment:(NSTextAlignment)newAlignment
1218 {
1219     cellAlignment = newAlignment;
1220     switch (newAlignment)
1221     {
1222         case NSCenterTextAlignment:
1223         case NSLeftTextAlignment:
1224         case NSJustifiedTextAlignment:
1225         case NSNaturalTextAlignment:
1226             [super setAlignment:NSLeftTextAlignment];
1227             break;
1228         case NSRightTextAlignment:
1229             [super setAlignment:NSRightTextAlignment];
1230             break;
1231         default:
1232             wxFAIL_MSG("Unknown alignment type.");
1233     }
1234 }
1235
1236 //
1237 // image access
1238 //
1239 -(NSImage*) image
1240 {
1241     return image;
1242 }
1243
1244 -(void) setImage:(NSImage*)newImage
1245 {
1246     [newImage retain];
1247     [image release];
1248     image = newImage;
1249 }
1250
1251 -(NSSize) imageSize
1252 {
1253     return imageSize;
1254 }
1255
1256 -(void) setImageSize:(NSSize) newImageSize
1257 {
1258     imageSize = newImageSize;
1259 }
1260
1261 //
1262 // other methods
1263 //
1264 -(NSSize) cellImageSize
1265 {
1266     return NSMakeSize(imageSize.width+xImageShift+spaceImageText,imageSize.height);
1267 }
1268
1269 -(NSSize) cellSize
1270 {
1271     NSSize cellSize([super cellSize]);
1272
1273
1274     if (imageSize.height > cellSize.height)
1275         cellSize.height = imageSize.height;
1276     cellSize.width += imageSize.width+xImageShift+spaceImageText;
1277
1278     return cellSize;
1279 }
1280
1281 -(NSSize) cellTextSize
1282 {
1283     return [super cellSize];
1284 }
1285
1286 //
1287 // implementations
1288 //
1289 -(void) determineCellParts:(NSRect)cellFrame imagePart:(NSRect*)imageFrame textPart:(NSRect*)textFrame
1290 {
1291     switch (cellAlignment)
1292     {
1293         case NSCenterTextAlignment:
1294             {
1295                 CGFloat const cellSpace = cellFrame.size.width-[self cellSize].width;
1296
1297                 // if the cell's frame is smaller than its contents (at least
1298                 // in x-direction) make sure that the image is visible:
1299                 if (cellSpace <= 0)
1300                     NSDivideRect(cellFrame,imageFrame,textFrame,xImageShift+imageSize.width+spaceImageText,NSMinXEdge);
1301                 else // otherwise center the image and text in the cell's frame
1302                     NSDivideRect(cellFrame,imageFrame,textFrame,xImageShift+imageSize.width+spaceImageText+0.5*cellSpace,NSMinXEdge);
1303             }
1304             break;
1305         case NSJustifiedTextAlignment:
1306         case NSLeftTextAlignment:
1307         case NSNaturalTextAlignment: // how to determine the natural writing direction? TODO
1308             NSDivideRect(cellFrame,imageFrame,textFrame,xImageShift+imageSize.width+spaceImageText,NSMinXEdge);
1309             break;
1310         case NSRightTextAlignment:
1311             {
1312                 CGFloat const cellSpace = cellFrame.size.width-[self cellSize].width;
1313
1314                 // if the cell's frame is smaller than its contents (at least
1315                 // in x-direction) make sure that the image is visible:
1316                 if (cellSpace <= 0)
1317                     NSDivideRect(cellFrame,imageFrame,textFrame,xImageShift+imageSize.width+spaceImageText,NSMinXEdge);
1318                 else // otherwise right align the image and text in the cell's frame
1319                     NSDivideRect(cellFrame,imageFrame,textFrame,xImageShift+imageSize.width+spaceImageText+cellSpace,NSMinXEdge);
1320             }
1321             break;
1322         default:
1323             *imageFrame = NSZeroRect;
1324             *textFrame  = NSZeroRect;
1325             wxFAIL_MSG("Unhandled alignment type.");
1326     }
1327 }
1328
1329 -(void) drawWithFrame:(NSRect)cellFrame inView:(NSView*)controlView
1330 {
1331     NSRect textFrame, imageFrame;
1332
1333
1334     [self determineCellParts:cellFrame imagePart:&imageFrame textPart:&textFrame];
1335     // draw the image part by ourselves;
1336     // check if the cell has to draw its own background (checking is done by
1337     // the parameter of the textfield's cell):
1338     if ([self drawsBackground])
1339     {
1340         [[self backgroundColor] set];
1341         NSRectFill(imageFrame);
1342     }
1343     if (image != nil)
1344     {
1345         // the image is slightly shifted (xImageShift) and has a fixed size
1346         // but the image's frame might be larger and starts currently on the
1347         // left side of the cell's frame; therefore, the origin and the
1348         // image's frame size have to be adjusted:
1349         if (imageFrame.size.width >= xImageShift+imageSize.width+spaceImageText)
1350         {
1351             imageFrame.origin.x += imageFrame.size.width-imageSize.width-spaceImageText;
1352             imageFrame.size.width = imageSize.width;
1353         }
1354         else
1355         {
1356             imageFrame.origin.x   += xImageShift;
1357             imageFrame.size.width -= xImageShift+spaceImageText;
1358         }
1359         // ...and the image has to be centered in the y-direction:
1360         if (imageFrame.size.height > imageSize.height)
1361             imageFrame.size.height = imageSize.height;
1362         imageFrame.origin.y += ceil(0.5*(cellFrame.size.height-imageFrame.size.height));
1363
1364         // according to the documentation the coordinate system should be
1365         // flipped for NSTableViews (y-coordinate goes from top to bottom); to
1366         // draw an image correctly the coordinate system has to be transformed
1367         // to a bottom-top coordinate system, otherwise the image's
1368         // content is flipped:
1369         NSAffineTransform* coordinateTransform([NSAffineTransform transform]);
1370
1371         if ([controlView isFlipped])
1372         {
1373             [coordinateTransform scaleXBy: 1.0 yBy:-1.0]; // first the coordinate system is brought back to bottom-top orientation
1374             [coordinateTransform translateXBy:0.0 yBy:(-2.0)*imageFrame.origin.y-imageFrame.size.height]; // the coordinate system has to be moved to compensate for the
1375             [coordinateTransform concat];                                                                 // other orientation and the position of the image's frame
1376         }
1377         [image drawInRect:imageFrame fromRect:NSZeroRect operation:NSCompositeSourceOver fraction:1.0]; // suggested method to draw the image
1378         // instead of compositeToPoint:operation:
1379         // take back previous transformation (if the view is not flipped the
1380         // coordinate transformation matrix contains the identity matrix and
1381         // the next two operations do not change the content's transformation
1382         // matrix):
1383         [coordinateTransform invert];
1384         [coordinateTransform concat];
1385     }
1386     // let the textfield cell draw the text part:
1387     if (textFrame.size.width > [self cellTextSize].width)
1388     {
1389         // for unknown reasons the alignment of the text cell is ignored;
1390         // therefore change the size so that alignment does not influence the
1391         // visualization anymore
1392         textFrame.size.width = [self cellTextSize].width;
1393     }
1394     [super drawWithFrame:textFrame inView:controlView];
1395 }
1396
1397 -(void) editWithFrame:(NSRect)aRect inView:(NSView*)controlView editor:(NSText*)textObj delegate:(id)anObject event:(NSEvent*)theEvent
1398 {
1399     NSRect textFrame, imageFrame;
1400
1401
1402     [self determineCellParts:aRect imagePart:&imageFrame textPart:&textFrame];
1403     [super editWithFrame:textFrame inView:controlView editor:textObj delegate:anObject event:theEvent];
1404 }
1405
1406 #if MAC_OS_X_VERSION_MAX_ALLOWED >= MAC_OS_X_VERSION_10_5
1407 -(NSUInteger) hitTestForEvent:(NSEvent*)event inRect:(NSRect)cellFrame ofView:(NSView*)controlView
1408 {
1409     NSPoint point = [controlView convertPoint:[event locationInWindow] fromView:nil];
1410
1411     NSRect imageFrame, textFrame;
1412
1413
1414     [self determineCellParts:cellFrame imagePart:&imageFrame textPart:&textFrame];
1415     if (image != nil)
1416     {
1417         // the image is shifted...
1418         if (imageFrame.size.width >= xImageShift+imageSize.width+spaceImageText)
1419         {
1420             imageFrame.origin.x += imageFrame.size.width-imageSize.width-spaceImageText;
1421             imageFrame.size.width = imageSize.width;
1422         }
1423         else
1424         {
1425             imageFrame.origin.x   += xImageShift;
1426             imageFrame.size.width -= xImageShift+spaceImageText;
1427         }
1428         // ...and centered:
1429         if (imageFrame.size.height > imageSize.height)
1430             imageFrame.size.height = imageSize.height;
1431         imageFrame.origin.y += ceil(0.5*(cellFrame.size.height-imageFrame.size.height));
1432         // If the point is in the image rect, then it is a content hit (see
1433         // documentation for hitTestForEvent:inRect:ofView):
1434         if (NSMouseInRect(point, imageFrame, [controlView isFlipped]))
1435             return NSCellHitContentArea;
1436     }
1437     // if the image was not hit let's try the text part:
1438     if (textFrame.size.width > [self cellTextSize].width)
1439     {
1440         // for unknown reasons the alignment of the text cell is ignored;
1441         // therefore change the size so that alignment does not influence the
1442         // visualization anymore
1443         textFrame.size.width = [self cellTextSize].width;
1444     }
1445
1446     return [super hitTestForEvent:event inRect:textFrame ofView:controlView];
1447 }
1448 #endif
1449
1450 -(NSRect) imageRectForBounds:(NSRect)cellFrame
1451 {
1452     NSRect textFrame, imageFrame;
1453
1454
1455     [self determineCellParts:cellFrame imagePart:&imageFrame textPart:&textFrame];
1456     if (imageFrame.size.width >= xImageShift+imageSize.width+spaceImageText)
1457     {
1458         imageFrame.origin.x += imageFrame.size.width-imageSize.width-spaceImageText;
1459         imageFrame.size.width = imageSize.width;
1460     }
1461     else
1462     {
1463         imageFrame.origin.x   += xImageShift;
1464         imageFrame.size.width -= xImageShift+spaceImageText;
1465     }
1466     // ...and centered:
1467     if (imageFrame.size.height > imageSize.height)
1468         imageFrame.size.height = imageSize.height;
1469     imageFrame.origin.y += ceil(0.5*(cellFrame.size.height-imageFrame.size.height));
1470
1471     return imageFrame;
1472 }
1473
1474 -(void) selectWithFrame:(NSRect)aRect inView:(NSView*)controlView editor:(NSText*)textObj delegate:(id)anObject start:(NSInteger)selStart length:(NSInteger)selLength
1475 {
1476     NSRect textFrame, imageFrame;
1477
1478
1479     [self determineCellParts:aRect imagePart:&imageFrame textPart:&textFrame];
1480     [super selectWithFrame:textFrame inView:controlView editor:textObj delegate:anObject start:selStart length:selLength];
1481 }
1482
1483 -(NSRect) titleRectForBounds:(NSRect)cellFrame
1484 {
1485     NSRect textFrame, imageFrame;
1486
1487
1488     [self determineCellParts:cellFrame imagePart:&imageFrame textPart:&textFrame];
1489     return textFrame;
1490 }
1491
1492 @end
1493
1494 // ============================================================================
1495 // wxCocoaOutlineView
1496 // ============================================================================
1497 @implementation wxCocoaOutlineView
1498
1499 //
1500 // initializers / destructor
1501 //
1502 -(id) init
1503 {
1504     self = [super init];
1505     if (self != nil)
1506     {
1507         currentlyEditedColumn =
1508             currentlyEditedRow = -1;
1509
1510         [self registerForDraggedTypes:[NSArray arrayWithObjects:DataViewPboardType,NSStringPboardType,nil]];
1511         [self setDelegate:self];
1512         [self setDoubleAction:@selector(actionDoubleClick:)];
1513         [self setDraggingSourceOperationMask:NSDragOperationEvery forLocal:NO];
1514         [self setDraggingSourceOperationMask:NSDragOperationEvery forLocal:YES];
1515         [self setTarget:self];
1516     }
1517     return self;
1518 }
1519
1520 //
1521 // access to wxWidget's implementation
1522 //
1523 -(wxCocoaDataViewControl*) implementation
1524 {
1525     return implementation;
1526 }
1527
1528 -(void) setImplementation:(wxCocoaDataViewControl*) newImplementation
1529 {
1530     implementation = newImplementation;
1531 }
1532
1533 //
1534 // actions
1535 //
1536 -(void) actionDoubleClick:(id)sender
1537 {
1538     // actually the documentation (NSTableView 2007-10-31) for doubleAction:
1539     // and setDoubleAction: seems to be wrong as this action message is always
1540     // sent whether the cell is editable or not
1541     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
1542
1543     wxDataViewEvent event(wxEVT_COMMAND_DATAVIEW_ITEM_ACTIVATED,dvc->GetId());
1544
1545
1546     event.SetEventObject(dvc);
1547     event.SetItem(wxDataViewItemFromItem([self itemAtRow:[self clickedRow]]));
1548     dvc->GetEventHandler()->ProcessEvent(event);
1549 }
1550
1551
1552 //
1553 // contextual menus
1554 //
1555 -(NSMenu*) menuForEvent:(NSEvent*)theEvent
1556 {
1557     // this method does not do any special menu event handling but only sends
1558     // an event message; therefore, the user has full control if a context
1559     // menu should be shown or not
1560     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
1561
1562     wxDataViewEvent event(wxEVT_COMMAND_DATAVIEW_ITEM_CONTEXT_MENU,dvc->GetId());
1563
1564     wxDataViewItemArray selectedItems;
1565
1566
1567     event.SetEventObject(dvc);
1568     event.SetModel(dvc->GetModel());
1569     // get the item information;
1570     // theoretically more than one ID can be returned but the event can only
1571     // handle one item, therefore only the first item of the array is
1572     // returned:
1573     if (dvc->GetSelections(selectedItems) > 0)
1574         event.SetItem(selectedItems[0]);
1575     dvc->GetEventHandler()->ProcessEvent(event);
1576     // nothing is done:
1577     return nil;
1578 }
1579
1580 //
1581 // delegate methods
1582 //
1583 -(void) outlineView:(NSOutlineView*)outlineView mouseDownInHeaderOfTableColumn:(NSTableColumn*)tableColumn
1584 {
1585     wxDataViewColumn* const col(static_cast<wxDataViewColumn*>([[tableColumn identifier] pointer]));
1586
1587     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
1588
1589     wxDataViewEvent
1590         event(wxEVT_COMMAND_DATAVIEW_COLUMN_HEADER_CLICK,dvc->GetId());
1591
1592
1593     // first, send an event that the user clicked into a column's header:
1594     event.SetEventObject(dvc);
1595     event.SetColumn(dvc->GetColumnPosition(col));
1596     event.SetDataViewColumn(col);
1597     dvc->HandleWindowEvent(event);
1598
1599     // now, check if the click may have had an influence on sorting, too;
1600     // the sorting setup has to be done only if the clicked table column is
1601     // sortable and has not been used for sorting before the click; if the
1602     // column is already responsible for sorting the native control changes
1603     // the sorting direction automatically and informs the data source via
1604     // outlineView:sortDescriptorsDidChange:
1605     if (col->IsSortable() && ([tableColumn sortDescriptorPrototype] == nil))
1606     {
1607         // remove the sort order from the previously sorted column table (it
1608         // can also be that no sorted column table exists):
1609         UInt32 const noOfColumns = [outlineView numberOfColumns];
1610
1611         for (UInt32 i=0; i<noOfColumns; ++i)
1612             [[[outlineView tableColumns] objectAtIndex:i] setSortDescriptorPrototype:nil];
1613         // make column table sortable:
1614         NSArray*          sortDescriptors;
1615         NSSortDescriptor* sortDescriptor;
1616
1617         sortDescriptor = [[NSSortDescriptor alloc] initWithKey:[NSString stringWithFormat:@"%d",[outlineView columnWithIdentifier:[tableColumn identifier]]]
1618             ascending:YES];
1619         sortDescriptors = [NSArray arrayWithObject:sortDescriptor];
1620         [tableColumn setSortDescriptorPrototype:sortDescriptor];
1621         [outlineView setSortDescriptors:sortDescriptors];
1622         [sortDescriptor release];
1623     }
1624 }
1625
1626 -(BOOL) outlineView:(NSOutlineView*)outlineView shouldCollapseItem:(id)item
1627 {
1628     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
1629
1630     wxDataViewEvent event(wxEVT_COMMAND_DATAVIEW_ITEM_COLLAPSING,dvc->GetId());
1631
1632
1633     event.SetEventObject(dvc);
1634     event.SetItem       (wxDataViewItemFromItem(item));
1635     event.SetModel      (dvc->GetModel());
1636     // finally send the equivalent wxWidget event:
1637     dvc->GetEventHandler()->ProcessEvent(event);
1638     // opening the container is allowed if not vetoed:
1639     return event.IsAllowed();
1640 }
1641
1642 -(BOOL) outlineView:(NSOutlineView*)outlineView shouldExpandItem:(id)item
1643 {
1644     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
1645
1646     wxDataViewEvent event(wxEVT_COMMAND_DATAVIEW_ITEM_EXPANDING,dvc->GetId());
1647
1648
1649     event.SetEventObject(dvc);
1650     event.SetItem       (wxDataViewItemFromItem(item));
1651     event.SetModel      (dvc->GetModel());
1652     // finally send the equivalent wxWidget event:
1653     dvc->GetEventHandler()->ProcessEvent(event);
1654     // opening the container is allowed if not vetoed:
1655     return event.IsAllowed();
1656 }
1657
1658 -(BOOL) outlineView:(NSOutlineView*)outlineView shouldSelectTableColumn:(NSTableColumn*)tableColumn
1659 {
1660     return NO;
1661 }
1662
1663 -(void) outlineView:(wxCocoaOutlineView*)outlineView
1664     willDisplayCell:(id)cell
1665     forTableColumn:(NSTableColumn*)tableColumn
1666     item:(id)item
1667 {
1668     wxDataViewCtrl * const dvc = implementation->GetDataViewCtrl();
1669     wxDataViewModel * const model = dvc->GetModel();
1670
1671     wxDataViewColumn * const
1672         dvCol(static_cast<wxDataViewColumn*>(
1673                     [[tableColumn identifier] pointer]
1674                     )
1675              );
1676     const unsigned colIdx = dvCol->GetModelColumn();
1677
1678     wxDataViewItem dvItem(wxDataViewItemFromItem(item));
1679
1680     if ( !model->HasValue(dvItem, colIdx) )
1681         return;
1682
1683     wxDataViewRenderer * const renderer = dvCol->GetRenderer();
1684     wxDataViewRendererNativeData * const data = renderer->GetNativeData();
1685
1686     // let the renderer know about what it's going to render next
1687     data->SetColumnPtr(tableColumn);
1688     data->SetItem(item);
1689     data->SetItemCell(cell);
1690
1691     // use the attributes: notice that we need to do this whether we have them
1692     // or not as even if this cell doesn't have any attributes, the previous
1693     // one might have had some and then we need to reset them back to default
1694     wxDataViewItemAttr attr;
1695     model->GetAttr(dvItem, colIdx, attr);
1696     renderer->OSXApplyAttr(attr);
1697
1698     // and finally do draw it
1699     renderer->MacRender();
1700 }
1701
1702 //
1703 // notifications
1704 //
1705 -(void) outlineViewColumnDidMove:(NSNotification*)notification
1706 {
1707     int const newColumnPosition = [[[notification userInfo] objectForKey:@"NSNewColumn"] intValue];
1708
1709     wxDataViewColumn* const col(static_cast<wxDataViewColumn*>([[[[self tableColumns] objectAtIndex:newColumnPosition] identifier] pointer]));
1710
1711     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
1712
1713     wxDataViewEvent event(wxEVT_COMMAND_DATAVIEW_COLUMN_REORDERED,dvc->GetId());
1714
1715
1716     event.SetEventObject(dvc);
1717     event.SetColumn(dvc->GetColumnPosition(col));
1718     event.SetDataViewColumn(col);
1719     dvc->GetEventHandler()->ProcessEvent(event);
1720 }
1721
1722 -(void) outlineViewItemDidCollapse:(NSNotification*)notification
1723 {
1724     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
1725
1726     wxDataViewEvent event(wxEVT_COMMAND_DATAVIEW_ITEM_COLLAPSED,dvc->GetId());
1727
1728
1729     event.SetEventObject(dvc);
1730     event.SetItem(wxDataViewItemFromItem(
1731                     [[notification userInfo] objectForKey:@"NSObject"]));
1732     dvc->GetEventHandler()->ProcessEvent(event);
1733 }
1734
1735 -(void) outlineViewItemDidExpand:(NSNotification*)notification
1736 {
1737     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
1738
1739     wxDataViewEvent event(wxEVT_COMMAND_DATAVIEW_ITEM_EXPANDED,dvc->GetId());
1740
1741
1742     event.SetEventObject(dvc);
1743     event.SetItem(wxDataViewItemFromItem(
1744                     [[notification userInfo] objectForKey:@"NSObject"]));
1745     dvc->GetEventHandler()->ProcessEvent(event);
1746 }
1747
1748 -(void) outlineViewSelectionDidChange:(NSNotification*)notification
1749 {
1750     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
1751
1752     wxDataViewEvent event(wxEVT_COMMAND_DATAVIEW_SELECTION_CHANGED,dvc->GetId());
1753
1754     event.SetEventObject(dvc);
1755     event.SetModel(dvc->GetModel());
1756     event.SetItem(dvc->GetSelection());
1757     dvc->GetEventHandler()->ProcessEvent(event);
1758 }
1759
1760 -(void) textDidBeginEditing:(NSNotification*)notification
1761 {
1762     // this notification is only sent if the user started modifying the cell
1763     // (not when the user clicked into the cell and the cell's editor is
1764     // called!)
1765
1766     // call method of superclass (otherwise editing does not work correctly -
1767     // the outline data source class is not informed about a change of data):
1768     [super textDidBeginEditing:notification];
1769
1770     // remember the column being edited, it will be used in textDidEndEditing:
1771     currentlyEditedColumn = [self editedColumn];
1772     currentlyEditedRow = [self editedRow];
1773
1774     wxDataViewColumn* const col =
1775         static_cast<wxDataViewColumn*>(
1776                 [[[[self tableColumns] objectAtIndex:currentlyEditedColumn] identifier] pointer]);
1777
1778     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
1779
1780
1781     // stop editing of a custom item first (if necessary)
1782     dvc->FinishCustomItemEditing();
1783
1784     // now, send the event:
1785     wxDataViewEvent
1786         event(wxEVT_COMMAND_DATAVIEW_ITEM_EDITING_STARTED,dvc->GetId());
1787
1788     event.SetEventObject(dvc);
1789     event.SetItem(
1790             wxDataViewItemFromItem([self itemAtRow:currentlyEditedRow]));
1791     event.SetColumn(dvc->GetColumnPosition(col));
1792     event.SetDataViewColumn(col);
1793     dvc->GetEventHandler()->ProcessEvent(event);
1794 }
1795
1796 -(void) textDidEndEditing:(NSNotification*)notification
1797 {
1798     // call method of superclass (otherwise editing does not work correctly -
1799     // the outline data source class is not informed about a change of data):
1800     [super textDidEndEditing:notification];
1801
1802     // under OSX an event indicating the end of an editing session can be sent
1803     // even if no event indicating a start of an editing session has been sent
1804     // (see Documentation for NSControl controlTextDidEndEditing:); this is
1805     // not expected by a user of the wxWidgets library and therefore an
1806     // wxEVT_COMMAND_DATAVIEW_ITEM_EDITING_DONE event is only sent if a
1807     // corresponding wxEVT_COMMAND_DATAVIEW_ITEM_EDITING_STARTED has been sent
1808     // before; to check if a wxEVT_COMMAND_DATAVIEW_ITEM_EDITING_STARTED has
1809     // been sent the last edited column/row are valid:
1810     if ( currentlyEditedColumn != -1 && currentlyEditedRow != -1 )
1811     {
1812         wxDataViewColumn* const col =
1813             static_cast<wxDataViewColumn*>(
1814                     [[[[self tableColumns] objectAtIndex:currentlyEditedColumn] identifier] pointer]);
1815
1816         wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
1817
1818         // send event to wxWidgets:
1819         wxDataViewEvent
1820             event(wxEVT_COMMAND_DATAVIEW_ITEM_EDITING_DONE,dvc->GetId());
1821
1822         event.SetEventObject(dvc);
1823         event.SetItem(
1824                 wxDataViewItemFromItem([self itemAtRow:currentlyEditedRow]));
1825         event.SetColumn(dvc->GetColumnPosition(col));
1826         event.SetDataViewColumn(col);
1827         dvc->GetEventHandler()->ProcessEvent(event);
1828
1829
1830         // we're not editing any more
1831         currentlyEditedColumn =
1832             currentlyEditedRow = -1;
1833     }
1834 }
1835
1836 @end
1837
1838 // ============================================================================
1839 // wxCocoaDataViewControl
1840 // ============================================================================
1841
1842 wxCocoaDataViewControl::wxCocoaDataViewControl(wxWindow* peer,
1843                                                const wxPoint& pos,
1844                                                const wxSize& size,
1845                                                long style)
1846     : wxWidgetCocoaImpl
1847       (
1848         peer,
1849         [[NSScrollView alloc] initWithFrame:wxOSXGetFrameForControl(peer,pos,size)]
1850       ),
1851       m_DataSource(NULL),
1852       m_OutlineView([[wxCocoaOutlineView alloc] init])
1853 {
1854     // initialize scrollview (the outline view is part of a scrollview):
1855     NSScrollView* scrollview = (NSScrollView*) GetWXWidget();
1856
1857     [scrollview setAutoresizingMask:NSViewWidthSizable | NSViewHeightSizable];
1858     [scrollview setBorderType:NSNoBorder];
1859     [scrollview setHasVerticalScroller:YES];
1860     [scrollview setHasHorizontalScroller:YES];
1861     [scrollview setAutohidesScrollers:YES];
1862     [scrollview setDocumentView:m_OutlineView];
1863
1864     // initialize the native control itself too
1865     InitOutlineView(style);
1866 }
1867
1868 void wxCocoaDataViewControl::InitOutlineView(long style)
1869 {
1870     [m_OutlineView setImplementation:this];
1871     [m_OutlineView setColumnAutoresizingStyle:NSTableViewSequentialColumnAutoresizingStyle];
1872     [m_OutlineView setIndentationPerLevel:GetDataViewCtrl()->GetIndent()];
1873     NSUInteger maskGridStyle(NSTableViewGridNone);
1874     if (style & wxDV_HORIZ_RULES)
1875         maskGridStyle |= NSTableViewSolidHorizontalGridLineMask;
1876     if (style & wxDV_VERT_RULES)
1877         maskGridStyle |= NSTableViewSolidVerticalGridLineMask;
1878     [m_OutlineView setGridStyleMask:maskGridStyle];
1879     [m_OutlineView setAllowsMultipleSelection:           (style & wxDV_MULTIPLE)  != 0];
1880     [m_OutlineView setUsesAlternatingRowBackgroundColors:(style & wxDV_ROW_LINES) != 0];
1881
1882     if ( style & wxDV_NO_HEADER )
1883         [m_OutlineView setHeaderView:nil];
1884 }
1885
1886 wxCocoaDataViewControl::~wxCocoaDataViewControl()
1887 {
1888     [m_DataSource  release];
1889     [m_OutlineView release];
1890 }
1891
1892 //
1893 // column related methods (inherited from wxDataViewWidgetImpl)
1894 //
1895 bool wxCocoaDataViewControl::ClearColumns()
1896 {
1897     // as there is a bug in NSOutlineView version (OSX 10.5.6 #6555162) the
1898     // columns cannot be deleted if there is an outline column in the view;
1899     // therefore, the whole view is deleted and newly constructed:
1900     [m_OutlineView release];
1901     m_OutlineView = [[wxCocoaOutlineView alloc] init];
1902     [((NSScrollView*) GetWXWidget()) setDocumentView:m_OutlineView];
1903     [m_OutlineView setDataSource:m_DataSource];
1904
1905     InitOutlineView(GetDataViewCtrl()->GetWindowStyle());
1906
1907     return true;
1908 }
1909
1910 bool wxCocoaDataViewControl::DeleteColumn(wxDataViewColumn* columnPtr)
1911 {
1912     if ([m_OutlineView outlineTableColumn] == columnPtr->GetNativeData()->GetNativeColumnPtr())
1913         [m_OutlineView setOutlineTableColumn:nil]; // due to a bug this does not work
1914     [m_OutlineView removeTableColumn:columnPtr->GetNativeData()->GetNativeColumnPtr()]; // due to a confirmed bug #6555162 the deletion does not work for
1915     // outline table columns (... and there is no workaround)
1916     return (([m_OutlineView columnWithIdentifier:[[[wxPointerObject alloc] initWithPointer:columnPtr] autorelease]]) == -1);
1917 }
1918
1919 void wxCocoaDataViewControl::DoSetExpanderColumn(const wxDataViewColumn *columnPtr)
1920 {
1921     [m_OutlineView setOutlineTableColumn:columnPtr->GetNativeData()->GetNativeColumnPtr()];
1922 }
1923
1924 wxDataViewColumn* wxCocoaDataViewControl::GetColumn(unsigned int pos) const
1925 {
1926     return static_cast<wxDataViewColumn*>([[[[m_OutlineView tableColumns] objectAtIndex:pos] identifier] pointer]);
1927 }
1928
1929 int wxCocoaDataViewControl::GetColumnPosition(const wxDataViewColumn *columnPtr) const
1930 {
1931     return [m_OutlineView columnWithIdentifier:[[[wxPointerObject alloc] initWithPointer:const_cast<wxDataViewColumn*>(columnPtr)] autorelease]];
1932 }
1933
1934 bool wxCocoaDataViewControl::InsertColumn(unsigned int pos, wxDataViewColumn* columnPtr)
1935 {
1936     // create column and set the native data of the dataview column:
1937     NSTableColumn *nativeColumn = ::CreateNativeColumn(columnPtr);
1938     columnPtr->GetNativeData()->SetNativeColumnPtr(nativeColumn);
1939     // as the native control does not allow the insertion of a column at a
1940     // specified position the column is first appended and - if necessary -
1941     // moved to its final position:
1942     [m_OutlineView addTableColumn:nativeColumn];
1943     if (pos != static_cast<unsigned int>([m_OutlineView numberOfColumns]-1))
1944         [m_OutlineView moveColumn:[m_OutlineView numberOfColumns]-1 toColumn:pos];
1945     // done:
1946     return true;
1947 }
1948
1949 //
1950 // item related methods (inherited from wxDataViewWidgetImpl)
1951 //
1952 bool wxCocoaDataViewControl::Add(const wxDataViewItem& parent, const wxDataViewItem& WXUNUSED(item))
1953 {
1954     if (parent.IsOk())
1955         [m_OutlineView reloadItem:[m_DataSource getDataViewItemFromBuffer:parent] reloadChildren:YES];
1956     else
1957         [m_OutlineView reloadData];
1958     return true;
1959 }
1960
1961 bool wxCocoaDataViewControl::Add(const wxDataViewItem& parent, const wxDataViewItemArray& WXUNUSED(items))
1962 {
1963     if (parent.IsOk())
1964         [m_OutlineView reloadItem:[m_DataSource getDataViewItemFromBuffer:parent] reloadChildren:YES];
1965     else
1966         [m_OutlineView reloadData];
1967     return true;
1968 }
1969
1970 void wxCocoaDataViewControl::Collapse(const wxDataViewItem& item)
1971 {
1972     [m_OutlineView collapseItem:[m_DataSource getDataViewItemFromBuffer:item]];
1973 }
1974
1975 void wxCocoaDataViewControl::EnsureVisible(const wxDataViewItem& item, const wxDataViewColumn *columnPtr)
1976 {
1977     if (item.IsOk())
1978     {
1979         [m_OutlineView scrollRowToVisible:[m_OutlineView rowForItem:[m_DataSource getDataViewItemFromBuffer:item]]];
1980         if (columnPtr)
1981             [m_OutlineView scrollColumnToVisible:GetColumnPosition(columnPtr)];
1982     }
1983 }
1984
1985 void wxCocoaDataViewControl::Expand(const wxDataViewItem& item)
1986 {
1987     [m_OutlineView expandItem:[m_DataSource getDataViewItemFromBuffer:item]];
1988 }
1989
1990 unsigned int wxCocoaDataViewControl::GetCount() const
1991 {
1992     return [m_OutlineView numberOfRows];
1993 }
1994
1995 wxRect wxCocoaDataViewControl::GetRectangle(const wxDataViewItem& item, const wxDataViewColumn *columnPtr)
1996 {
1997     return wxFromNSRect([m_osxView superview],[m_OutlineView frameOfCellAtColumn:GetColumnPosition(columnPtr)
1998             row:[m_OutlineView rowForItem:[m_DataSource getDataViewItemFromBuffer:item]]]);
1999 }
2000
2001 bool wxCocoaDataViewControl::IsExpanded(const wxDataViewItem& item) const
2002 {
2003     return [m_OutlineView isItemExpanded:[m_DataSource getDataViewItemFromBuffer:item]];
2004 }
2005
2006 bool wxCocoaDataViewControl::Reload()
2007 {
2008     [m_DataSource clearBuffers];
2009     [m_OutlineView scrollColumnToVisible:0];
2010     [m_OutlineView scrollRowToVisible:0];
2011     [m_OutlineView reloadData];
2012     return true;
2013 }
2014
2015 bool wxCocoaDataViewControl::Remove(const wxDataViewItem& parent, const wxDataViewItem& WXUNUSED(item))
2016 {
2017     if (parent.IsOk())
2018         [m_OutlineView reloadItem:[m_DataSource getDataViewItemFromBuffer:parent] reloadChildren:YES];
2019     else
2020         [m_OutlineView reloadData];
2021     return true;
2022 }
2023
2024 bool wxCocoaDataViewControl::Remove(const wxDataViewItem& parent, const wxDataViewItemArray& WXUNUSED(item))
2025 {
2026     if (parent.IsOk())
2027         [m_OutlineView reloadItem:[m_DataSource getDataViewItemFromBuffer:parent] reloadChildren:YES];
2028     else
2029         [m_OutlineView reloadData];
2030     return true;
2031 }
2032
2033 bool wxCocoaDataViewControl::Update(const wxDataViewColumn *columnPtr)
2034 {
2035     return false;
2036 }
2037
2038 bool wxCocoaDataViewControl::Update(const wxDataViewItem& WXUNUSED(parent), const wxDataViewItem& item)
2039 {
2040     [m_OutlineView reloadItem:[m_DataSource getDataViewItemFromBuffer:item]];
2041     return true;
2042 }
2043
2044 bool wxCocoaDataViewControl::Update(const wxDataViewItem& WXUNUSED(parent), const wxDataViewItemArray& items)
2045 {
2046     for (size_t i=0; i<items.GetCount(); ++i)
2047         [m_OutlineView reloadItem:[m_DataSource getDataViewItemFromBuffer:items[i]]];
2048     return true;
2049 }
2050
2051 //
2052 // model related methods
2053 //
2054 bool wxCocoaDataViewControl::AssociateModel(wxDataViewModel* model)
2055 {
2056     [m_DataSource release];
2057     if (model)
2058     {
2059         m_DataSource = [[wxCocoaOutlineDataSource alloc] init];
2060         [m_DataSource setImplementation:this];
2061         [m_DataSource setModel:model];
2062     }
2063     else
2064         m_DataSource = NULL;
2065     [m_OutlineView setDataSource:m_DataSource]; // if there is a data source the data is immediately going to be requested
2066     return true;
2067 }
2068
2069 //
2070 // selection related methods (inherited from wxDataViewWidgetImpl)
2071 //
2072 int wxCocoaDataViewControl::GetSelections(wxDataViewItemArray& sel) const
2073 {
2074     NSIndexSet* selectedRowIndexes([m_OutlineView selectedRowIndexes]);
2075
2076     NSUInteger indexRow;
2077
2078
2079     sel.Empty();
2080     sel.Alloc([selectedRowIndexes count]);
2081     indexRow = [selectedRowIndexes firstIndex];
2082     while (indexRow != NSNotFound)
2083     {
2084         sel.Add(wxDataViewItem([[m_OutlineView itemAtRow:indexRow] pointer]));
2085         indexRow = [selectedRowIndexes indexGreaterThanIndex:indexRow];
2086     }
2087     return sel.GetCount();
2088 }
2089
2090 bool wxCocoaDataViewControl::IsSelected(const wxDataViewItem& item) const
2091 {
2092     return [m_OutlineView isRowSelected:[m_OutlineView rowForItem:[m_DataSource getDataViewItemFromBuffer:item]]];
2093 }
2094
2095 void wxCocoaDataViewControl::Select(const wxDataViewItem& item)
2096 {
2097     if (item.IsOk())
2098         [m_OutlineView selectRowIndexes:[NSIndexSet indexSetWithIndex:[m_OutlineView rowForItem:[m_DataSource getDataViewItemFromBuffer:item]]]
2099             byExtendingSelection:NO];
2100 }
2101
2102 void wxCocoaDataViewControl::SelectAll()
2103 {
2104     [m_OutlineView selectAll:m_OutlineView];
2105 }
2106
2107 void wxCocoaDataViewControl::Unselect(const wxDataViewItem& item)
2108 {
2109     if (item.IsOk())
2110         [m_OutlineView deselectRow:[m_OutlineView rowForItem:[m_DataSource getDataViewItemFromBuffer:item]]];
2111 }
2112
2113 void wxCocoaDataViewControl::UnselectAll()
2114 {
2115     [m_OutlineView deselectAll:m_OutlineView];
2116 }
2117
2118 //
2119 // sorting related methods
2120 //
2121 wxDataViewColumn* wxCocoaDataViewControl::GetSortingColumn() const
2122 {
2123     NSArray* const columns = [m_OutlineView tableColumns];
2124
2125     UInt32 const noOfColumns = [columns count];
2126
2127
2128     for (UInt32 i=0; i<noOfColumns; ++i)
2129         if ([[columns objectAtIndex:i] sortDescriptorPrototype] != nil)
2130             return static_cast<wxDataViewColumn*>([[[columns objectAtIndex:i] identifier] pointer]);
2131     return NULL;
2132 }
2133
2134 void wxCocoaDataViewControl::Resort()
2135 {
2136     [m_DataSource clearChildren];
2137     [m_OutlineView reloadData];
2138 }
2139
2140 //
2141 // other methods (inherited from wxDataViewWidgetImpl)
2142 //
2143 void wxCocoaDataViewControl::DoSetIndent(int indent)
2144 {
2145     [m_OutlineView setIndentationPerLevel:static_cast<CGFloat>(indent)];
2146 }
2147
2148 void wxCocoaDataViewControl::HitTest(const wxPoint& point, wxDataViewItem& item, wxDataViewColumn*& columnPtr) const
2149 {
2150     NSPoint const nativePoint = wxToNSPoint((NSScrollView*) GetWXWidget(),point);
2151
2152     int indexColumn;
2153     int indexRow;
2154
2155
2156     indexColumn = [m_OutlineView columnAtPoint:nativePoint];
2157     indexRow    = [m_OutlineView rowAtPoint:   nativePoint];
2158     if ((indexColumn >= 0) && (indexRow >= 0))
2159     {
2160         columnPtr = static_cast<wxDataViewColumn*>([[[[m_OutlineView tableColumns] objectAtIndex:indexColumn] identifier] pointer]);
2161         item      = wxDataViewItem([[m_OutlineView itemAtRow:indexRow] pointer]);
2162     }
2163     else
2164     {
2165         columnPtr = NULL;
2166         item      = wxDataViewItem();
2167     }
2168 }
2169
2170 void wxCocoaDataViewControl::SetRowHeight(const wxDataViewItem& WXUNUSED(item), unsigned int WXUNUSED(height))
2171     // Not supported by the native control
2172 {
2173 }
2174
2175 void wxCocoaDataViewControl::OnSize()
2176 {
2177     if ([m_OutlineView numberOfColumns] == 1)
2178         [m_OutlineView sizeLastColumnToFit];
2179 }
2180
2181 //
2182 // drag & drop helper methods
2183 //
2184 wxDataFormat wxCocoaDataViewControl::GetDnDDataFormat(wxDataObjectComposite* dataObjects)
2185 {
2186     wxDataFormat resultFormat;
2187     if ( !dataObjects )
2188         return resultFormat;
2189
2190     bool compatible(true);
2191
2192     size_t const noOfFormats = dataObjects->GetFormatCount();
2193     size_t       indexFormat;
2194
2195     wxDataFormat* formats;
2196
2197     // get all formats and check afterwards if the formats are compatible; if
2198     // they are compatible the preferred format is returned otherwise
2199     // wxDF_INVALID is returned;
2200     // currently compatible types (ordered by priority are):
2201     //  - wxDF_UNICODETEXT - wxDF_TEXT
2202     formats = new wxDataFormat[noOfFormats];
2203     dataObjects->GetAllFormats(formats);
2204     indexFormat = 0;
2205     while ((indexFormat < noOfFormats) && compatible)
2206     {
2207         switch (resultFormat.GetType())
2208         {
2209             case wxDF_INVALID:
2210                 resultFormat.SetType(formats[indexFormat].GetType()); // first format (should only be reached if indexFormat == 0)
2211                 break;
2212             case wxDF_TEXT:
2213                 if (formats[indexFormat].GetType() == wxDF_UNICODETEXT)
2214                     resultFormat.SetType(wxDF_UNICODETEXT);
2215                 else // incompatible
2216                 {
2217                     resultFormat.SetType(wxDF_INVALID);
2218                     compatible = false;
2219                 }
2220                 break;
2221             case wxDF_UNICODETEXT:
2222                 if (formats[indexFormat].GetType() != wxDF_TEXT)
2223                 {
2224                     resultFormat.SetType(wxDF_INVALID);
2225                     compatible = false;
2226                 }
2227                 break;
2228             default:
2229                 resultFormat.SetType(wxDF_INVALID); // not (yet) supported format
2230                 compatible = false;
2231         }
2232         ++indexFormat;
2233     }
2234
2235     delete[] formats;
2236
2237     return resultFormat;
2238 }
2239
2240 wxDataObjectComposite* wxCocoaDataViewControl::GetDnDDataObjects(NSData* dataObject) const
2241 {
2242     wxDataFormatId dataFormatID;
2243
2244
2245     [dataObject getBytes:&dataFormatID length:sizeof(wxDataFormatId)];
2246     switch (dataFormatID)
2247     {
2248         case wxDF_TEXT:
2249         case wxDF_UNICODETEXT:
2250             {
2251                 wxTextDataObject* textDataObject(new wxTextDataObject());
2252
2253                 if (textDataObject->SetData(wxDataFormat(dataFormatID),[dataObject length]-sizeof(wxDataFormatId),static_cast<char const*>([dataObject bytes])+sizeof(wxDataFormatId)))
2254                 {
2255                     wxDataObjectComposite* dataObjectComposite(new wxDataObjectComposite());
2256
2257                     dataObjectComposite->Add(textDataObject);
2258                     return dataObjectComposite;
2259                 }
2260                 else
2261                 {
2262                     delete textDataObject;
2263                     return NULL;
2264                 }
2265             }
2266             break;
2267         default:
2268             return NULL;
2269     }
2270 }
2271
2272 id wxCocoaDataViewControl::GetItemAtRow(int row) const
2273 {
2274     return [m_OutlineView itemAtRow:row];
2275 }
2276
2277 // ----------------------------------------------------------------------------
2278 // wxDataViewRendererNativeData
2279 // ----------------------------------------------------------------------------
2280
2281 void wxDataViewRendererNativeData::Init()
2282 {
2283     m_origFont = NULL;
2284     m_origTextColour = NULL;
2285     m_ellipsizeMode = wxELLIPSIZE_MIDDLE;
2286
2287     if ( m_ColumnCell )
2288         ApplyLineBreakMode(m_ColumnCell);
2289 }
2290
2291 void wxDataViewRendererNativeData::ApplyLineBreakMode(NSCell *cell)
2292 {
2293     NSLineBreakMode nsMode = NSLineBreakByWordWrapping;
2294     switch ( m_ellipsizeMode )
2295     {
2296         case wxELLIPSIZE_NONE:
2297             nsMode = NSLineBreakByClipping;
2298             break;
2299
2300         case wxELLIPSIZE_START:
2301             nsMode = NSLineBreakByTruncatingHead;
2302             break;
2303
2304         case wxELLIPSIZE_MIDDLE:
2305             nsMode = NSLineBreakByTruncatingMiddle;
2306             break;
2307
2308         case wxELLIPSIZE_END:
2309             nsMode = NSLineBreakByTruncatingTail;
2310             break;
2311     }
2312
2313     wxASSERT_MSG( nsMode != NSLineBreakByWordWrapping, "unknown wxEllipsizeMode" );
2314
2315     [cell setLineBreakMode: nsMode];
2316 }
2317
2318 // ---------------------------------------------------------
2319 // wxDataViewRenderer
2320 // ---------------------------------------------------------
2321
2322 wxDataViewRenderer::wxDataViewRenderer(const wxString& varianttype,
2323                                        wxDataViewCellMode mode,
2324                                        int align)
2325     : wxDataViewRendererBase(varianttype, mode, align),
2326       m_alignment(align),
2327       m_mode(mode),
2328       m_NativeDataPtr(NULL)
2329 {
2330 }
2331
2332 wxDataViewRenderer::~wxDataViewRenderer()
2333 {
2334     delete m_NativeDataPtr;
2335 }
2336
2337 void wxDataViewRenderer::SetAlignment(int align)
2338 {
2339     m_alignment = align;
2340     [GetNativeData()->GetColumnCell() setAlignment:ConvertToNativeHorizontalTextAlignment(align)];
2341 }
2342
2343 void wxDataViewRenderer::SetMode(wxDataViewCellMode mode)
2344 {
2345     m_mode = mode;
2346     if ( GetOwner() )
2347         [GetOwner()->GetNativeData()->GetNativeColumnPtr() setEditable:(mode == wxDATAVIEW_CELL_EDITABLE)];
2348 }
2349
2350 void wxDataViewRenderer::SetNativeData(wxDataViewRendererNativeData* newNativeDataPtr)
2351 {
2352     delete m_NativeDataPtr;
2353     m_NativeDataPtr = newNativeDataPtr;
2354 }
2355
2356 void wxDataViewRenderer::EnableEllipsize(wxEllipsizeMode mode)
2357 {
2358     // we need to store this value to apply it to the columns headerCell in
2359     // CreateNativeColumn()
2360     GetNativeData()->SetEllipsizeMode(mode);
2361
2362     // but we may already apply it to the column cell which will be used for
2363     // this column
2364     GetNativeData()->ApplyLineBreakMode(GetNativeData()->GetColumnCell());
2365 }
2366
2367 wxEllipsizeMode wxDataViewRenderer::GetEllipsizeMode() const
2368 {
2369     return GetNativeData()->GetEllipsizeMode();
2370 }
2371
2372 void
2373 wxDataViewRenderer::OSXOnCellChanged(NSObject *object,
2374                                      const wxDataViewItem& item,
2375                                      unsigned col)
2376 {
2377     // TODO: we probably should get rid of this code entirely and make this
2378     //       function pure virtual, but currently we still have some native
2379     //       renderers (wxDataViewChoiceRenderer) which don't override it and
2380     //       there is also wxDataViewCustomRenderer for which it's not obvious
2381     //       how it should be implemented so keep this "auto-deduction" of
2382     //       variant type from NSObject for now
2383
2384     wxVariant value;
2385     if ( [object isKindOfClass:[NSString class]] )
2386         value = ObjectToString(object);
2387     else if ( [object isKindOfClass:[NSNumber class]] )
2388         value = ObjectToLong(object);
2389     else if ( [object isKindOfClass:[NSDate class]] )
2390         value = ObjectToDate(object);
2391     else
2392     {
2393         wxFAIL_MSG( wxString::Format
2394                     (
2395                      "unknown value type %s",
2396                      wxCFStringRef::AsString([object className])
2397                     ));
2398         return;
2399     }
2400
2401     wxDataViewModel *model = GetOwner()->GetOwner()->GetModel();
2402     model->ChangeValue(value, item, col);
2403 }
2404
2405 void wxDataViewRenderer::OSXApplyAttr(const wxDataViewItemAttr& attr)
2406 {
2407     wxDataViewRendererNativeData * const data = GetNativeData();
2408     NSCell * const cell = data->GetItemCell();
2409
2410     // set the font and text colour to use: we need to do it if we had ever
2411     // changed them before, even if this item itself doesn't have any special
2412     // attributes as otherwise it would reuse the attributes from the previous
2413     // cell rendered using the same renderer
2414     NSFont *font = NULL;
2415     NSColor *colText = NULL;
2416
2417     if ( attr.HasFont() )
2418     {
2419         font = data->GetOriginalFont();
2420         if ( !font )
2421         {
2422             // this is the first time we're setting the font, remember the
2423             // original one before changing it
2424             font = [cell font];
2425             data->SaveOriginalFont(font);
2426         }
2427
2428         if ( font )
2429         {
2430             // FIXME: using wxFont methods here doesn't work for some reason
2431             NSFontManager * const fm = [NSFontManager sharedFontManager];
2432             if ( attr.GetBold() )
2433                 font = [fm convertFont:font toHaveTrait:NSBoldFontMask];
2434             if ( attr.GetItalic() )
2435                 font = [fm convertFont:font toHaveTrait:NSItalicFontMask];
2436         }
2437         //else: can't change font if the cell doesn't have any
2438     }
2439
2440     if ( attr.HasColour() )
2441     {
2442         // we can set font for any cell but only NSTextFieldCell provides
2443         // a method for setting text colour so check that this method is
2444         // available before using it
2445         if ( [cell respondsToSelector:@selector(setTextColor:)] &&
2446                 [cell respondsToSelector:@selector(textColor)] )
2447         {
2448             if ( !data->GetOriginalTextColour() )
2449             {
2450                 // the cast to (untyped) id is safe because of the check above
2451                 data->SaveOriginalTextColour([(id)cell textColor]);
2452             }
2453
2454             const wxColour& c = attr.GetColour();
2455             colText = [NSColor colorWithDeviceRed:c.Red() / 255.
2456                 green:c.Green() / 255.
2457                 blue:c.Blue() / 255.
2458                 alpha:c.Alpha() / 255.];
2459         }
2460     }
2461
2462     if ( !font )
2463         font = data->GetOriginalFont();
2464     if ( !colText )
2465         colText = data->GetOriginalTextColour();
2466
2467     if ( font )
2468         [cell setFont:font];
2469
2470     if ( colText )
2471         [(id)cell setTextColor:colText];
2472 }
2473
2474 IMPLEMENT_ABSTRACT_CLASS(wxDataViewRenderer,wxDataViewRendererBase)
2475
2476 // ---------------------------------------------------------
2477 // wxDataViewCustomRenderer
2478 // ---------------------------------------------------------
2479 wxDataViewCustomRenderer::wxDataViewCustomRenderer(const wxString& varianttype,
2480                                                    wxDataViewCellMode mode,
2481                                                    int align)
2482     : wxDataViewCustomRendererBase(varianttype, mode, align),
2483       m_editorCtrlPtr(NULL),
2484       m_DCPtr(NULL)
2485 {
2486     SetNativeData(new wxDataViewRendererNativeData([[wxCustomCell alloc] init]));
2487 }
2488
2489 bool wxDataViewCustomRenderer::MacRender()
2490 {
2491     [GetNativeData()->GetItemCell() setObjectValue:[[[wxCustomRendererObject alloc] initWithRenderer:this] autorelease]];
2492     return true;
2493 }
2494
2495 void wxDataViewCustomRenderer::OSXApplyAttr(const wxDataViewItemAttr& attr)
2496 {
2497     // simply save the attribute so that it could be reused from our Render()
2498     SetAttr(attr);
2499
2500     // it's not necessary to call the base class version which sets the cell
2501     // properties to correspond to this attribute because we currently don't
2502     // use any NSCell methods in custom renderers anyhow but if we ever start
2503     // doing this (e.g. override RenderText() here to use NSTextFieldCell
2504     // methods), then we should pass it on to wxDataViewRenderer here
2505 }
2506
2507 IMPLEMENT_ABSTRACT_CLASS(wxDataViewCustomRenderer, wxDataViewRenderer)
2508
2509 // ---------------------------------------------------------
2510 // wxDataViewTextRenderer
2511 // ---------------------------------------------------------
2512 wxDataViewTextRenderer::wxDataViewTextRenderer(const wxString& varianttype,
2513                                                wxDataViewCellMode mode,
2514                                                int align)
2515     : wxDataViewRenderer(varianttype,mode,align)
2516 {
2517     NSTextFieldCell* cell;
2518
2519
2520     cell = [[NSTextFieldCell alloc] init];
2521     [cell setAlignment:ConvertToNativeHorizontalTextAlignment(align)];
2522     SetNativeData(new wxDataViewRendererNativeData(cell));
2523     [cell release];
2524 }
2525
2526 bool wxDataViewTextRenderer::MacRender()
2527 {
2528     if (GetValue().GetType() == GetVariantType())
2529     {
2530         [GetNativeData()->GetItemCell() setObjectValue:wxCFStringRef(GetValue().GetString()).AsNSString()];
2531         return true;
2532     }
2533     else
2534     {
2535         wxFAIL_MSG(wxString("Text renderer cannot render value because of wrong value type; value type: ") << GetValue().GetType());
2536         return false;
2537     }
2538 }
2539
2540 void
2541 wxDataViewTextRenderer::OSXOnCellChanged(NSObject *value,
2542                                          const wxDataViewItem& item,
2543                                          unsigned col)
2544 {
2545     wxDataViewModel *model = GetOwner()->GetOwner()->GetModel();
2546     model->ChangeValue(ObjectToString(value), item, col);
2547 }
2548
2549 IMPLEMENT_CLASS(wxDataViewTextRenderer,wxDataViewRenderer)
2550
2551 // ---------------------------------------------------------
2552 // wxDataViewBitmapRenderer
2553 // ---------------------------------------------------------
2554 wxDataViewBitmapRenderer::wxDataViewBitmapRenderer(const wxString& varianttype,
2555                                                    wxDataViewCellMode mode,
2556                                                    int align)
2557     : wxDataViewRenderer(varianttype,mode,align)
2558 {
2559     NSImageCell* cell;
2560
2561
2562     cell = [[NSImageCell alloc] init];
2563     SetNativeData(new wxDataViewRendererNativeData(cell));
2564     [cell release];
2565 }
2566
2567 // This method returns 'true' if
2568 //  - the passed bitmap is valid and it could be assigned to the native data
2569 //  browser;
2570 //  - the passed bitmap is invalid (or is not initialized); this case
2571 //  simulates a non-existing bitmap.
2572 // In all other cases the method returns 'false'.
2573 bool wxDataViewBitmapRenderer::MacRender()
2574 {
2575     wxCHECK_MSG(GetValue().GetType() == GetVariantType(),false,wxString("Bitmap renderer cannot render value; value type: ") << GetValue().GetType());
2576
2577     wxBitmap bitmap;
2578
2579     bitmap << GetValue();
2580     if (bitmap.IsOk())
2581         [GetNativeData()->GetItemCell() setObjectValue:[[bitmap.GetNSImage() retain] autorelease]];
2582     return true;
2583 }
2584
2585 IMPLEMENT_CLASS(wxDataViewBitmapRenderer,wxDataViewRenderer)
2586
2587 // -------------------------------------
2588 // wxDataViewChoiceRenderer
2589 // -------------------------------------
2590 wxDataViewChoiceRenderer::wxDataViewChoiceRenderer(const wxArrayString& choices,
2591                                                    wxDataViewCellMode mode,
2592                                                    int alignment)
2593     : wxDataViewRenderer(wxT("string"), mode, alignment),
2594       m_choices(choices)
2595 {
2596     NSPopUpButtonCell* cell;
2597
2598
2599     cell = [[NSPopUpButtonCell alloc] init];
2600     [cell setControlSize:NSMiniControlSize];
2601     [cell setFont:[[NSFont fontWithName:[[cell font] fontName] size:[NSFont systemFontSizeForControlSize:NSMiniControlSize]] autorelease]];
2602     for (size_t i=0; i<choices.GetCount(); ++i)
2603         [cell addItemWithTitle:[[wxCFStringRef(choices[i]).AsNSString() retain] autorelease]];
2604     SetNativeData(new wxDataViewRendererNativeData(cell));
2605     [cell release];
2606 }
2607
2608 bool wxDataViewChoiceRenderer::MacRender()
2609 {
2610     if (GetValue().GetType() == GetVariantType())
2611     {
2612         [((NSPopUpButtonCell*) GetNativeData()->GetItemCell()) selectItemWithTitle:[[wxCFStringRef(GetValue().GetString()).AsNSString() retain] autorelease]];
2613         return true;
2614     }
2615     else
2616     {
2617         wxFAIL_MSG(wxString("Choice renderer cannot render value because of wrong value type; value type: ") << GetValue().GetType());
2618         return false;
2619     }
2620 }
2621
2622 IMPLEMENT_CLASS(wxDataViewChoiceRenderer,wxDataViewRenderer)
2623
2624 // ---------------------------------------------------------
2625 // wxDataViewDateRenderer
2626 // ---------------------------------------------------------
2627
2628 wxDataViewDateRenderer::wxDataViewDateRenderer(const wxString& varianttype,
2629                                                wxDataViewCellMode mode,
2630                                                int align)
2631     : wxDataViewRenderer(varianttype,mode,align)
2632 {
2633     NSTextFieldCell* cell;
2634
2635     NSDateFormatter* dateFormatter;
2636
2637
2638     dateFormatter = [[NSDateFormatter alloc] init];
2639     [dateFormatter setFormatterBehavior:NSDateFormatterBehavior10_4];
2640     [dateFormatter setDateStyle:NSDateFormatterShortStyle];
2641     cell = [[NSTextFieldCell alloc] init];
2642     [cell setFormatter:dateFormatter];
2643     SetNativeData(new wxDataViewRendererNativeData(cell,[NSDate dateWithString:@"2000-12-30 20:00:00 +0000"]));
2644     [cell          release];
2645     [dateFormatter release];
2646 }
2647
2648 bool wxDataViewDateRenderer::MacRender()
2649 {
2650     if (GetValue().GetType() == GetVariantType())
2651     {
2652         if (GetValue().GetDateTime().IsValid())
2653         {
2654             // -- find best fitting style to show the date --
2655             // as the style should be identical for all cells a reference date
2656             // instead of the actual cell's date value is used for all cells;
2657             // this reference date is stored in the renderer's native data
2658             // section for speed purposes; otherwise, the reference date's
2659             // string has to be recalculated for each item that may become
2660             // timewise long if a lot of rows using dates exist; the algorithm
2661             // has the preference to display as much information as possible
2662             // in the first instance; but as this is often impossible due to
2663             // space restrictions the style is shortened per loop; finally, if
2664             // the shortest time and date format does not fit into the cell
2665             // the time part is dropped; remark: the time part itself is not
2666             // modified per iteration loop and only uses the short style,
2667             // means that only the hours and minutes are being shown
2668
2669             // GetObject() returns a date for testing the size of a date object
2670             [GetNativeData()->GetItemCell() setObjectValue:GetNativeData()->GetObject()];
2671             [[GetNativeData()->GetItemCell() formatter] setTimeStyle:NSDateFormatterShortStyle];
2672             for (int dateFormatterStyle=4; dateFormatterStyle>0; --dateFormatterStyle)
2673             {
2674                 [[GetNativeData()->GetItemCell() formatter] setDateStyle:(NSDateFormatterStyle)dateFormatterStyle];
2675                 if (dateFormatterStyle == 1)
2676                 {
2677                     // if the shortest style for displaying the date and time
2678                     // is too long to be fully visible remove the time part of
2679                     // the date:
2680                     if ([GetNativeData()->GetItemCell() cellSize].width > [GetNativeData()->GetColumnPtr() width])
2681                         [[GetNativeData()->GetItemCell() formatter] setTimeStyle:NSDateFormatterNoStyle];
2682                     {
2683                         // basically not necessary as the loop would end anyway
2684                         // but let's save the last comparison
2685                         break;
2686                     }
2687                 }
2688                 else if ([GetNativeData()->GetItemCell() cellSize].width <= [GetNativeData()->GetColumnPtr() width])
2689                     break;
2690             }
2691             // set data (the style is set by the previous loop); on OSX the
2692             // date has to be specified with respect to UTC; in wxWidgets the
2693             // date is always entered in the local timezone; so, we have to do
2694             // a conversion from the local to UTC timezone when adding the
2695             // seconds to 1970-01-01 UTC:
2696             [GetNativeData()->GetItemCell() setObjectValue:[NSDate dateWithTimeIntervalSince1970:GetValue().GetDateTime().ToUTC().Subtract(wxDateTime(1,wxDateTime::Jan,1970)).GetSeconds().ToDouble()]];
2697         }
2698         return true;
2699     }
2700     else
2701     {
2702         wxFAIL_MSG(wxString("Date renderer cannot render value because of wrong value type; value type: ") << GetValue().GetType());
2703         return false;
2704     }
2705 }
2706
2707 void
2708 wxDataViewDateRenderer::OSXOnCellChanged(NSObject *value,
2709                                          const wxDataViewItem& item,
2710                                          unsigned col)
2711 {
2712     wxDataViewModel *model = GetOwner()->GetOwner()->GetModel();
2713     model->ChangeValue(ObjectToDate(value), item, col);
2714 }
2715
2716 IMPLEMENT_ABSTRACT_CLASS(wxDataViewDateRenderer,wxDataViewRenderer)
2717
2718 // ---------------------------------------------------------
2719 // wxDataViewIconTextRenderer
2720 // ---------------------------------------------------------
2721 wxDataViewIconTextRenderer::wxDataViewIconTextRenderer(const wxString& varianttype,
2722                                                        wxDataViewCellMode mode,
2723                                                        int align)
2724      : wxDataViewRenderer(varianttype,mode)
2725 {
2726     wxImageTextCell* cell;
2727
2728
2729     cell = [[wxImageTextCell alloc] init];
2730     [cell setAlignment:ConvertToNativeHorizontalTextAlignment(align)];
2731     SetNativeData(new wxDataViewRendererNativeData(cell));
2732     [cell release];
2733 }
2734
2735 bool wxDataViewIconTextRenderer::MacRender()
2736 {
2737     if (GetValue().GetType() == GetVariantType())
2738     {
2739         wxDataViewIconText iconText;
2740
2741         wxImageTextCell* cell;
2742
2743         cell = (wxImageTextCell*) GetNativeData()->GetItemCell();
2744         iconText << GetValue();
2745         if (iconText.GetIcon().IsOk())
2746             [cell setImage:[[wxBitmap(iconText.GetIcon()).GetNSImage() retain] autorelease]];
2747         [cell setStringValue:[[wxCFStringRef(iconText.GetText()).AsNSString() retain] autorelease]];
2748         return true;
2749     }
2750     else
2751     {
2752         wxFAIL_MSG(wxString("Icon & text renderer cannot render value because of wrong value type; value type: ") << GetValue().GetType());
2753         return false;
2754     }
2755 }
2756
2757 void
2758 wxDataViewIconTextRenderer::OSXOnCellChanged(NSObject *value,
2759                                              const wxDataViewItem& item,
2760                                              unsigned col)
2761 {
2762     wxVariant valueIconText;
2763     valueIconText << wxDataViewIconText(ObjectToString(value));
2764
2765     wxDataViewModel *model = GetOwner()->GetOwner()->GetModel();
2766     model->ChangeValue(valueIconText, item, col);
2767 }
2768
2769 IMPLEMENT_ABSTRACT_CLASS(wxDataViewIconTextRenderer,wxDataViewRenderer)
2770
2771 // ---------------------------------------------------------
2772 // wxDataViewToggleRenderer
2773 // ---------------------------------------------------------
2774 wxDataViewToggleRenderer::wxDataViewToggleRenderer(const wxString& varianttype,
2775                                                    wxDataViewCellMode mode,
2776                                                    int align)
2777     : wxDataViewRenderer(varianttype,mode)
2778 {
2779     NSButtonCell* cell;
2780
2781
2782     cell = [[NSButtonCell alloc] init];
2783     [cell setAlignment:ConvertToNativeHorizontalTextAlignment(align)];
2784     [cell setButtonType:NSSwitchButton];
2785     [cell setImagePosition:NSImageOnly];
2786     SetNativeData(new wxDataViewRendererNativeData(cell));
2787     [cell release];
2788 }
2789
2790 bool wxDataViewToggleRenderer::MacRender()
2791 {
2792     if (GetValue().GetType() == GetVariantType())
2793     {
2794         [GetNativeData()->GetItemCell() setIntValue:GetValue().GetLong()];
2795         return true;
2796     }
2797     else
2798     {
2799         wxFAIL_MSG(wxString("Toggle renderer cannot render value because of wrong value type; value type: ") << GetValue().GetType());
2800         return false;
2801     }
2802 }
2803
2804 void
2805 wxDataViewToggleRenderer::OSXOnCellChanged(NSObject *value,
2806                                            const wxDataViewItem& item,
2807                                            unsigned col)
2808 {
2809     wxDataViewModel *model = GetOwner()->GetOwner()->GetModel();
2810     model->ChangeValue(ObjectToBool(value), item, col);
2811 }
2812
2813 IMPLEMENT_ABSTRACT_CLASS(wxDataViewToggleRenderer,wxDataViewRenderer)
2814
2815 // ---------------------------------------------------------
2816 // wxDataViewProgressRenderer
2817 // ---------------------------------------------------------
2818 wxDataViewProgressRenderer::wxDataViewProgressRenderer(const wxString& label,
2819                                                        const wxString& varianttype,
2820                                                        wxDataViewCellMode mode,
2821                                                        int align)
2822     : wxDataViewRenderer(varianttype,mode,align)
2823 {
2824     NSLevelIndicatorCell* cell;
2825
2826     cell = [[NSLevelIndicatorCell alloc] initWithLevelIndicatorStyle:NSContinuousCapacityLevelIndicatorStyle];
2827     [cell setMinValue:0];
2828     [cell setMaxValue:100];
2829     SetNativeData(new wxDataViewRendererNativeData(cell));
2830     [cell release];
2831 }
2832
2833 bool wxDataViewProgressRenderer::MacRender()
2834 {
2835     if (GetValue().GetType() == GetVariantType())
2836     {
2837         [GetNativeData()->GetItemCell() setIntValue:GetValue().GetLong()];
2838         return true;
2839     }
2840     else
2841     {
2842         wxFAIL_MSG(wxString("Progress renderer cannot render value because of wrong value type; value type: ") << GetValue().GetType());
2843         return false;
2844     }
2845 }
2846
2847 void
2848 wxDataViewProgressRenderer::OSXOnCellChanged(NSObject *value,
2849                                              const wxDataViewItem& item,
2850                                              unsigned col)
2851 {
2852     wxDataViewModel *model = GetOwner()->GetOwner()->GetModel();
2853     model->ChangeValue(ObjectToLong(value), item, col);
2854 }
2855
2856 IMPLEMENT_ABSTRACT_CLASS(wxDataViewProgressRenderer,wxDataViewRenderer)
2857
2858 // ---------------------------------------------------------
2859 // wxDataViewColumn
2860 // ---------------------------------------------------------
2861
2862 wxDataViewColumn::wxDataViewColumn(const wxString& title,
2863                                    wxDataViewRenderer* renderer,
2864                                    unsigned int model_column,
2865                                    int width,
2866                                    wxAlignment align,
2867                                    int flags)
2868      : wxDataViewColumnBase(renderer, model_column),
2869        m_NativeDataPtr(new wxDataViewColumnNativeData()),
2870        m_title(title)
2871 {
2872     InitCommon(width, align, flags);
2873     if (renderer && (renderer->GetAlignment() == wxDVR_DEFAULT_ALIGNMENT))
2874         renderer->SetAlignment(align);
2875 }
2876
2877 wxDataViewColumn::wxDataViewColumn(const wxBitmap& bitmap,
2878                                    wxDataViewRenderer* renderer,
2879                                    unsigned int model_column,
2880                                    int width,
2881                                    wxAlignment align,
2882                                    int flags)
2883     : wxDataViewColumnBase(bitmap, renderer, model_column),
2884       m_NativeDataPtr(new wxDataViewColumnNativeData())
2885 {
2886     InitCommon(width, align, flags);
2887     if (renderer && (renderer->GetAlignment() == wxDVR_DEFAULT_ALIGNMENT))
2888         renderer->SetAlignment(align);
2889 }
2890
2891 wxDataViewColumn::~wxDataViewColumn()
2892 {
2893     delete m_NativeDataPtr;
2894 }
2895
2896 int wxDataViewColumn::GetWidth() const
2897 {
2898     return [m_NativeDataPtr->GetNativeColumnPtr() width];
2899 }
2900
2901 bool wxDataViewColumn::IsSortKey() const
2902 {
2903     NSTableColumn *nsCol = GetNativeData()->GetNativeColumnPtr();
2904     return nsCol && ([nsCol sortDescriptorPrototype] != nil);
2905 }
2906
2907 void wxDataViewColumn::SetAlignment(wxAlignment align)
2908 {
2909     m_alignment = align;
2910     [[m_NativeDataPtr->GetNativeColumnPtr() headerCell] setAlignment:ConvertToNativeHorizontalTextAlignment(align)];
2911     if (m_renderer && (m_renderer->GetAlignment() == wxDVR_DEFAULT_ALIGNMENT))
2912         m_renderer->SetAlignment(align);
2913 }
2914
2915 void wxDataViewColumn::SetBitmap(const wxBitmap& bitmap)
2916 {
2917     // bitmaps and titles cannot exist at the same time - if the bitmap is set
2918     // the title is removed:
2919     m_title = wxEmptyString;
2920     wxDataViewColumnBase::SetBitmap(bitmap);
2921     [[m_NativeDataPtr->GetNativeColumnPtr() headerCell] setImage:[[bitmap.GetNSImage() retain] autorelease]];
2922 }
2923
2924 void wxDataViewColumn::SetMaxWidth(int maxWidth)
2925 {
2926     m_maxWidth = maxWidth;
2927     [m_NativeDataPtr->GetNativeColumnPtr() setMaxWidth:maxWidth];
2928 }
2929
2930 void wxDataViewColumn::SetMinWidth(int minWidth)
2931 {
2932     m_minWidth = minWidth;
2933     [m_NativeDataPtr->GetNativeColumnPtr() setMinWidth:minWidth];
2934 }
2935
2936 void wxDataViewColumn::SetReorderable(bool reorderable)
2937 {
2938 }
2939
2940 void wxDataViewColumn::SetHidden(bool hidden)
2941 {
2942     // How to set flag here?
2943
2944     [m_NativeDataPtr->GetNativeColumnPtr() setHidden:hidden];
2945 }
2946
2947 bool wxDataViewColumn::IsHidden() const
2948 {
2949     return [m_NativeDataPtr->GetNativeColumnPtr() isHidden];
2950 }
2951
2952 void wxDataViewColumn::SetResizeable(bool resizeable)
2953 {
2954     wxDataViewColumnBase::SetResizeable(resizeable);
2955     if (resizeable)
2956         [m_NativeDataPtr->GetNativeColumnPtr() setResizingMask:NSTableColumnUserResizingMask];
2957     else
2958         [m_NativeDataPtr->GetNativeColumnPtr() setResizingMask:NSTableColumnNoResizing];
2959 }
2960
2961 void wxDataViewColumn::SetSortable(bool sortable)
2962 {
2963     wxDataViewColumnBase::SetSortable(sortable);
2964 }
2965
2966 void wxDataViewColumn::SetSortOrder(bool ascending)
2967 {
2968     if (m_ascending != ascending)
2969     {
2970         m_ascending = ascending;
2971         if (IsSortKey())
2972         {
2973             // change sorting order:
2974             NSArray*          sortDescriptors;
2975             NSSortDescriptor* sortDescriptor;
2976             NSTableColumn*    tableColumn;
2977
2978             tableColumn     = m_NativeDataPtr->GetNativeColumnPtr();
2979             sortDescriptor  = [[NSSortDescriptor alloc] initWithKey:[[tableColumn sortDescriptorPrototype] key] ascending:m_ascending];
2980             sortDescriptors = [NSArray arrayWithObject:sortDescriptor];
2981             [tableColumn setSortDescriptorPrototype:sortDescriptor];
2982             [[tableColumn tableView] setSortDescriptors:sortDescriptors];
2983             [sortDescriptor release];
2984         }
2985     }
2986 }
2987
2988 void wxDataViewColumn::SetTitle(const wxString& title)
2989 {
2990     // bitmaps and titles cannot exist at the same time - if the title is set
2991     // the bitmap is removed:
2992     wxDataViewColumnBase::SetBitmap(wxBitmap());
2993     m_title = title;
2994     [[m_NativeDataPtr->GetNativeColumnPtr() headerCell] setStringValue:[[wxCFStringRef(title).AsNSString() retain] autorelease]];
2995 }
2996
2997 void wxDataViewColumn::SetWidth(int width)
2998 {
2999     [m_NativeDataPtr->GetNativeColumnPtr() setWidth:width];
3000     m_width = width;
3001 }
3002
3003 void wxDataViewColumn::SetAsSortKey(bool WXUNUSED(sort))
3004 {
3005     // see wxGTK native wxDataViewColumn implementation
3006     wxFAIL_MSG("not implemented");
3007 }
3008
3009 void wxDataViewColumn::SetNativeData(wxDataViewColumnNativeData* newNativeDataPtr)
3010 {
3011     delete m_NativeDataPtr;
3012     m_NativeDataPtr = newNativeDataPtr;
3013 }
3014
3015 #endif // (wxUSE_DATAVIEWCTRL == 1) && !defined(wxUSE_GENERICDATAVIEWCTRL)