src/osx/cocoa/listbox.mm

   1 ///////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/osx/cocoa/listbox.mm
   3 // Purpose:     wxListBox
   4 // Author:      Stefan Csomor
   5 // Modified by:
   6 // Created:     1998-01-01
   7 // RCS-ID:      $Id: listbox.cpp 54820 2008-07-29 20:04:11Z SC $
   8 // Copyright:   (c) Stefan Csomor
   9 // Licence:     wxWindows licence
  10 ///////////////////////////////////////////////////////////////////////////////
  11
  12 #include "wx/wxprec.h"
  13
  14 #if wxUSE_LISTBOX
  15
  16 #include "wx/listbox.h"
  17 #include "wx/dnd.h"
  18
  19 #ifndef WX_PRECOMP
  20     #include "wx/log.h"
  21     #include "wx/intl.h"
  22     #include "wx/utils.h"
  23     #include "wx/settings.h"
  24     #include "wx/arrstr.h"
  25     #include "wx/dcclient.h"
  26 #endif
  27
  28 #include "wx/osx/private.h"
  29
  30 #include <vector>
  31
  32 // forward decls
  33
  34 class wxListWidgetCocoaImpl;
  35
  36 @interface wxNSTableDataSource : NSObject wxOSX_10_6_AND_LATER(<NSTableViewDataSource>)
  37 {
  38     wxListWidgetCocoaImpl* impl;
  39 }
  40
  41 - (id)tableView:(NSTableView *)aTableView
  42         objectValueForTableColumn:(NSTableColumn *)aTableColumn
  43         row:(NSInteger)rowIndex;
  44
  45 - (void)tableView:(NSTableView *)aTableView
  46         setObjectValue:(id)value forTableColumn:(NSTableColumn *)aTableColumn
  47         row:(NSInteger)rowIndex;
  48
  49 - (NSInteger)numberOfRowsInTableView:(NSTableView *)aTableView;
  50
  51 - (void)setImplementation: (wxListWidgetCocoaImpl *) theImplementation;
  52 - (wxListWidgetCocoaImpl*) implementation;
  53
  54 @end
  55
  56 @interface wxNSTableView : NSTableView wxOSX_10_6_AND_LATER(<NSTableViewDelegate>)
  57 {
  58 }
  59
  60 @end
  61
  62 //
  63 // table column
  64 //
  65
  66 class wxCocoaTableColumn;
  67
  68 @interface wxNSTableColumn : NSTableColumn
  69 {
  70     wxCocoaTableColumn* column;
  71 }
  72
  73 - (void) setColumn: (wxCocoaTableColumn*) col;
  74
  75 - (wxCocoaTableColumn*) column;
  76
  77 @end
  78
  79 class WXDLLIMPEXP_CORE wxCocoaTableColumn : public wxListWidgetColumn
  80 {
  81 public :
  82     wxCocoaTableColumn( wxNSTableColumn* column, bool editable )
  83         : m_column( column ), m_editable(editable)
  84     {
  85     }
  86
  87     ~wxCocoaTableColumn()
  88     {
  89     }
  90
  91     wxNSTableColumn* GetNSTableColumn() const { return m_column ; }
  92
  93     bool IsEditable() const { return m_editable; }
  94
  95 protected :
  96     wxNSTableColumn* m_column;
  97     bool m_editable;
  98 } ;
  99
 100 NSString* column1 = @"1";
 101
 102 class wxListWidgetCocoaImpl : public wxWidgetCocoaImpl, public wxListWidgetImpl
 103 {
 104 public :
 105     wxListWidgetCocoaImpl( wxWindowMac* peer, NSScrollView* view, wxNSTableView* tableview, wxNSTableDataSource* data );
 106
 107     ~wxListWidgetCocoaImpl();
 108
 109     virtual wxListWidgetColumn*     InsertTextColumn( unsigned pos, const wxString& title, bool editable = false,
 110                                 wxAlignment just = wxALIGN_LEFT , int defaultWidth = -1)  ;
 111     virtual wxListWidgetColumn*     InsertCheckColumn( unsigned pos , const wxString& title, bool editable = false,
 112                                 wxAlignment just = wxALIGN_LEFT , int defaultWidth =  -1)  ;
 113
 114     // add and remove
 115
 116     virtual void            ListDelete( unsigned int n ) ;
 117     virtual void            ListInsert( unsigned int n ) ;
 118     virtual void            ListClear() ;
 119
 120     // selecting
 121
 122     virtual void            ListDeselectAll();
 123
 124     virtual void            ListSetSelection( unsigned int n, bool select, bool multi ) ;
 125     virtual int             ListGetSelection() const ;
 126
 127     virtual int             ListGetSelections( wxArrayInt& aSelections ) const ;
 128
 129     virtual bool            ListIsSelected( unsigned int n ) const ;
 130
 131     // display
 132
 133     virtual void            ListScrollTo( unsigned int n ) ;
 134
 135     // accessing content
 136
 137     virtual unsigned int    ListGetCount() const ;
 138     virtual int             DoListHitTest( const wxPoint& inpoint ) const;
 139
 140     int                     ListGetColumnType( int col )
 141     {
 142         return col;
 143     }
 144     virtual void            UpdateLine( unsigned int n, wxListWidgetColumn* col = NULL ) ;
 145     virtual void            UpdateLineToEnd( unsigned int n);
 146
 147     virtual void            controlDoubleAction(WXWidget slf, void* _cmd, void *sender);
 148
 149
 150 protected :
 151     wxNSTableView*          m_tableView ;
 152
 153     wxNSTableDataSource*    m_dataSource;
 154 } ;
 155
 156 //
 157 // implementations
 158 //
 159
 160 @implementation wxNSTableColumn
 161
 162 - (id) init
 163 {
 164     [super init];
 165     column = nil;
 166     return self;
 167 }
 168
 169 - (void) setColumn: (wxCocoaTableColumn*) col
 170 {
 171     column = col;
 172 }
 173
 174 - (wxCocoaTableColumn*) column
 175 {
 176     return column;
 177 }
 178
 179 @end
 180
 181 class wxNSTableViewCellValue : public wxListWidgetCellValue
 182 {
 183 public :
 184     wxNSTableViewCellValue( id &v ) : value(v)
 185     {
 186     }
 187
 188     virtual ~wxNSTableViewCellValue() {}
 189
 190     virtual void Set( CFStringRef v )
 191     {
 192         value = [[(NSString*)v retain] autorelease];
 193     }
 194     virtual void Set( const wxString& value )
 195     {
 196         Set( (CFStringRef) wxCFStringRef( value ) );
 197     }
 198     virtual void Set( int v )
 199     {
 200         value = [NSNumber numberWithInt:v];
 201     }
 202
 203     virtual int GetIntValue() const
 204     {
 205         if ( [value isKindOfClass:[NSNumber class]] )
 206             return [ (NSNumber*) value intValue ];
 207
 208         return 0;
 209     }
 210
 211     virtual wxString GetStringValue() const
 212     {
 213         if ( [value isKindOfClass:[NSString class]] )
 214             return wxCFStringRef::AsString( (NSString*) value );
 215
 216         return wxEmptyString;
 217     }
 218
 219 protected:
 220     id& value;
 221 } ;
 222
 223 @implementation wxNSTableDataSource
 224
 225 - (id) init
 226 {
 227     [super init];
 228     impl = nil;
 229     return self;
 230 }
 231
 232 - (void)setImplementation: (wxListWidgetCocoaImpl *) theImplementation
 233 {
 234     impl = theImplementation;
 235 }
 236
 237 - (wxListWidgetCocoaImpl*) implementation
 238 {
 239     return impl;
 240 }
 241
 242 - (NSInteger)numberOfRowsInTableView:(NSTableView *)aTableView
 243 {
 244     wxUnusedVar(aTableView);
 245     if ( impl )
 246         return impl->ListGetCount();
 247     return 0;
 248 }
 249
 250 - (id)tableView:(NSTableView *)aTableView
 251         objectValueForTableColumn:(NSTableColumn *)aTableColumn
 252         row:(NSInteger)rowIndex
 253 {
 254     wxUnusedVar(aTableView);
 255     wxNSTableColumn* tablecol = (wxNSTableColumn *)aTableColumn;
 256     wxListBox* lb = dynamic_cast<wxListBox*>(impl->GetWXPeer());
 257     wxCocoaTableColumn* col = [tablecol column];
 258     id value = nil;
 259     wxNSTableViewCellValue cellvalue(value);
 260     lb->GetValueCallback(rowIndex, col, cellvalue);
 261     return value;
 262 }
 263
 264 - (void)tableView:(NSTableView *)aTableView
 265         setObjectValue:(id)value forTableColumn:(NSTableColumn *)aTableColumn
 266         row:(NSInteger)rowIndex
 267 {
 268     wxUnusedVar(aTableView);
 269     wxNSTableColumn* tablecol = (wxNSTableColumn *)aTableColumn;
 270     wxListBox* lb = dynamic_cast<wxListBox*>(impl->GetWXPeer());
 271     wxCocoaTableColumn* col = [tablecol column];
 272     wxNSTableViewCellValue cellvalue(value);
 273     lb->SetValueCallback(rowIndex, col, cellvalue);
 274 }
 275
 276 @end
 277
 278 @implementation wxNSTableView
 279
 280 + (void)initialize
 281 {
 282     static BOOL initialized = NO;
 283     if (!initialized)
 284     {
 285         initialized = YES;
 286         wxOSXCocoaClassAddWXMethods( self );
 287     }
 288 }
 289
 290 - (void) tableViewSelectionDidChange: (NSNotification *) notification
 291 {
 292     wxUnusedVar(notification);
 293
 294     int row = [self selectedRow];
 295
 296     if (row == -1)
 297     {
 298         // no row selected
 299     }
 300     else
 301     {
 302         wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 303         wxListBox *list = static_cast<wxListBox*> ( impl->GetWXPeer());
 304         wxCHECK_RET( list != NULL , wxT("Listbox expected"));
 305
 306         wxCommandEvent event( wxEVT_COMMAND_LISTBOX_SELECTED, list->GetId() );
 307
 308         if ((row < 0) || (row > (int) list->GetCount()))  // OS X can select an item below the last item
 309             return;
 310
 311         if ( !list->MacGetBlockEvents() )
 312             list->HandleLineEvent( row, false );
 313     }
 314
 315 }
 316
 317 @end
 318
 319 //
 320 //
 321 //
 322
 323 wxListWidgetCocoaImpl::wxListWidgetCocoaImpl( wxWindowMac* peer, NSScrollView* view, wxNSTableView* tableview, wxNSTableDataSource* data ) :
 324     wxWidgetCocoaImpl( peer, view ), m_tableView(tableview), m_dataSource(data)
 325 {
 326     InstallEventHandler( tableview );
 327 }
 328
 329 wxListWidgetCocoaImpl::~wxListWidgetCocoaImpl()
 330 {
 331     [m_dataSource release];
 332 }
 333
 334 unsigned int wxListWidgetCocoaImpl::ListGetCount() const
 335 {
 336     wxListBox* lb = dynamic_cast<wxListBox*> ( GetWXPeer() );
 337     return lb->GetCount();
 338 }
 339
 340 //
 341 // columns
 342 //
 343
 344 wxListWidgetColumn* wxListWidgetCocoaImpl::InsertTextColumn( unsigned pos, const wxString& WXUNUSED(title), bool editable,
 345                                 wxAlignment WXUNUSED(just), int defaultWidth)
 346 {
 347     wxNSTableColumn* col1 = [[wxNSTableColumn alloc] init];
 348     [col1 setEditable:editable];
 349
 350     unsigned formerColCount = [m_tableView numberOfColumns];
 351
 352     // there's apparently no way to insert at a specific position
 353     [m_tableView addTableColumn:col1 ];
 354     if ( pos < formerColCount )
 355         [m_tableView moveColumn:formerColCount toColumn:pos];
 356
 357     if ( defaultWidth >= 0 )
 358     {
 359         [col1 setMaxWidth:defaultWidth];
 360         [col1 setMinWidth:defaultWidth];
 361         [col1 setWidth:defaultWidth];
 362     }
 363     else
 364     {
 365         [col1 setMaxWidth:1000];
 366         [col1 setMinWidth:10];
 367         // temporary hack, because I cannot get the automatic column resizing
 368         // to work properly
 369         [col1 setWidth:1000];
 370     }
 371     [col1 setResizingMask: NSTableColumnAutoresizingMask];
 372     wxCocoaTableColumn* wxcol = new wxCocoaTableColumn( col1, editable );
 373     [col1 setColumn:wxcol];
 374
 375     // owned by the tableview
 376     [col1 release];
 377     return wxcol;
 378 }
 379
 380 wxListWidgetColumn* wxListWidgetCocoaImpl::InsertCheckColumn( unsigned pos , const wxString& WXUNUSED(title), bool editable,
 381                                 wxAlignment WXUNUSED(just), int defaultWidth )
 382 {
 383    wxNSTableColumn* col1 = [[wxNSTableColumn alloc] init];
 384     [col1 setEditable:editable];
 385
 386     // set your custom cell & set it up
 387     NSButtonCell* checkbox = [[NSButtonCell alloc] init];
 388     [checkbox setTitle:@""];
 389     [checkbox setButtonType:NSSwitchButton];
 390     [col1 setDataCell:checkbox] ;
 391     [checkbox release];
 392
 393     unsigned formerColCount = [m_tableView numberOfColumns];
 394
 395     // there's apparently no way to insert at a specific position
 396     [m_tableView addTableColumn:col1 ];
 397     if ( pos < formerColCount )
 398         [m_tableView moveColumn:formerColCount toColumn:pos];
 399
 400     if ( defaultWidth >= 0 )
 401     {
 402         [col1 setMaxWidth:defaultWidth];
 403         [col1 setMinWidth:defaultWidth];
 404         [col1 setWidth:defaultWidth];
 405     }
 406
 407     [col1 setResizingMask: NSTableColumnNoResizing];
 408     wxCocoaTableColumn* wxcol = new wxCocoaTableColumn( col1, editable );
 409     [col1 setColumn:wxcol];
 410
 411     // owned by the tableview
 412     [col1 release];
 413     return wxcol;
 414 }
 415
 416
 417 //
 418 // inserting / removing lines
 419 //
 420
 421 void wxListWidgetCocoaImpl::ListInsert( unsigned int WXUNUSED(n) )
 422 {
 423     [m_tableView reloadData];
 424 }
 425
 426 void wxListWidgetCocoaImpl::ListDelete( unsigned int WXUNUSED(n) )
 427 {
 428     [m_tableView reloadData];
 429 }
 430
 431 void wxListWidgetCocoaImpl::ListClear()
 432 {
 433     [m_tableView reloadData];
 434 }
 435
 436 // selecting
 437
 438 void wxListWidgetCocoaImpl::ListDeselectAll()
 439 {
 440     [m_tableView deselectAll:nil];
 441 }
 442
 443 void wxListWidgetCocoaImpl::ListSetSelection( unsigned int n, bool select, bool multi )
 444 {
 445     // TODO
 446     if ( select )
 447         [m_tableView selectRow: n byExtendingSelection:multi];
 448     else
 449         [m_tableView deselectRow: n];
 450
 451 }
 452
 453 int wxListWidgetCocoaImpl::ListGetSelection() const
 454 {
 455     return [m_tableView selectedRow];
 456 }
 457
 458 int wxListWidgetCocoaImpl::ListGetSelections( wxArrayInt& aSelections ) const
 459 {
 460     aSelections.Empty();
 461
 462     int count = ListGetCount();
 463
 464     for ( int i = 0; i < count; ++i)
 465     {
 466         if ([m_tableView isRowSelected:i])
 467         aSelections.Add(i);
 468     }
 469
 470     return aSelections.Count();
 471 }
 472
 473 bool wxListWidgetCocoaImpl::ListIsSelected( unsigned int n ) const
 474 {
 475     return [m_tableView isRowSelected:n];
 476 }
 477
 478 // display
 479
 480 void wxListWidgetCocoaImpl::ListScrollTo( unsigned int n )
 481 {
 482     [m_tableView scrollRowToVisible:n];
 483 }
 484
 485
 486 void wxListWidgetCocoaImpl::UpdateLine( unsigned int WXUNUSED(n), wxListWidgetColumn* WXUNUSED(col) )
 487 {
 488     // TODO optimize
 489     [m_tableView reloadData];
 490 }
 491
 492 void wxListWidgetCocoaImpl::UpdateLineToEnd( unsigned int WXUNUSED(n))
 493 {
 494     // TODO optimize
 495     [m_tableView reloadData];
 496 }
 497
 498 void wxListWidgetCocoaImpl::controlDoubleAction(WXWidget WXUNUSED(slf),void* WXUNUSED(_cmd), void *WXUNUSED(sender))
 499 {
 500     wxListBox *list = static_cast<wxListBox*> ( GetWXPeer());
 501     wxCHECK_RET( list != NULL , wxT("Listbox expected"));
 502
 503     int sel = [m_tableView clickedRow];
 504     if ((sel < 0) || (sel > (int) list->GetCount()))  // OS X can select an item below the last item (why?)
 505        return;
 506
 507     list->HandleLineEvent( sel, true );
 508 }
 509
 510 // accessing content
 511
 512
 513 wxWidgetImplType* wxWidgetImpl::CreateListBox( wxWindowMac* wxpeer,
 514                                     wxWindowMac* WXUNUSED(parent),
 515                                     wxWindowID WXUNUSED(id),
 516                                     const wxPoint& pos,
 517                                     const wxSize& size,
 518                                     long style,
 519                                     long WXUNUSED(extraStyle))
 520 {
 521     NSRect r = wxOSXGetFrameForControl( wxpeer, pos , size ) ;
 522     NSScrollView* scrollview = [[NSScrollView alloc] initWithFrame:r];
 523
 524     // use same scroll flags logic as msw
 525
 526     [scrollview setHasVerticalScroller:YES];
 527
 528     if ( style & wxLB_HSCROLL )
 529         [scrollview setHasHorizontalScroller:YES];
 530
 531     [scrollview setAutohidesScrollers: ((style & wxLB_ALWAYS_SB) ? NO : YES)];
 532
 533     // setting up the true table
 534
 535     wxNSTableView* tableview = [[wxNSTableView alloc] init];
 536     [tableview setDelegate:tableview];
 537     // only one multi-select mode available
 538     if ( (style & wxLB_EXTENDED) || (style & wxLB_MULTIPLE) )
 539         [tableview setAllowsMultipleSelection:YES];
 540
 541     // simple listboxes have no header row
 542     [tableview setHeaderView:nil];
 543
 544     if ( style & wxLB_HSCROLL )
 545         [tableview setColumnAutoresizingStyle:NSTableViewNoColumnAutoresizing];
 546     else
 547         [tableview setColumnAutoresizingStyle:NSTableViewLastColumnOnlyAutoresizingStyle];
 548
 549     wxNSTableDataSource* ds = [[ wxNSTableDataSource alloc] init];
 550     [tableview setDataSource:ds];
 551     [scrollview setDocumentView:tableview];
 552     [tableview release];
 553
 554     wxListWidgetCocoaImpl* c = new wxListWidgetCocoaImpl( wxpeer, scrollview, tableview, ds );
 555
 556     // temporary hook for dnd
 557     [tableview registerForDraggedTypes:[NSArray arrayWithObjects:
 558         NSStringPboardType, NSFilenamesPboardType, NSTIFFPboardType, NSPICTPboardType, NSPDFPboardType, nil]];
 559
 560     [ds setImplementation:c];
 561     return c;
 562 }
 563
 564 int wxListWidgetCocoaImpl::DoListHitTest(const wxPoint& inpoint) const
 565 {
 566     // translate inpoint to listpoint via scrollview
 567     NSPoint p = wxToNSPoint( m_osxView, inpoint );
 568     p = [m_osxView convertPoint:p toView:m_tableView];
 569     // hittest using new point
 570     NSInteger i = [m_tableView rowAtPoint:p];
 571     return i;
 572 }
 573
 574 #endif // wxUSE_LISTBOX