src/osx/cocoa/filedlg.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/cocoa/filedlg.mm
   3 // Purpose:     wxFileDialog for wxCocoa
   4 // Author:      Ryan Norton
   5 // Modified by:
   6 // Created:     2004-10-02
   7 // RCS-ID:      $Id: filedlg.mm 40007 2006-07-05 13:10:46Z SC $
   8 // Copyright:   (c) Ryan Norton
   9 // Licence:     wxWindows licence
  10 /////////////////////////////////////////////////////////////////////////////
  11
  12 // ============================================================================
  13 // declarations
  14 // ============================================================================
  15
  16 // ----------------------------------------------------------------------------
  17 // headers
  18 // ----------------------------------------------------------------------------
  19
  20 // For compilers that support precompilation, includes "wx.h".
  21 #include "wx/wxprec.h"
  22
  23 #if wxUSE_FILEDLG
  24
  25 #include "wx/filedlg.h"
  26
  27 #ifndef WX_PRECOMP
  28     #include "wx/msgdlg.h"
  29     #include "wx/app.h"
  30 #endif
  31
  32 #include "wx/filename.h"
  33 #include "wx/tokenzr.h"
  34
  35 #include "wx/osx/private.h"
  36
  37 // ============================================================================
  38 // implementation
  39 // ============================================================================
  40
  41 // Open Items:
  42 // - support for old style MacOS creator / type combos
  43 // - parameter support for descending into packages as directories (setTreatsFilePackagesAsDirectories)
  44
  45 IMPLEMENT_CLASS(wxFileDialog, wxFileDialogBase)
  46
  47 wxFileDialog::wxFileDialog(
  48     wxWindow *parent, const wxString& message,
  49     const wxString& defaultDir, const wxString& defaultFileName, const wxString& wildCard,
  50     long style, const wxPoint& pos, const wxSize& sz, const wxString& name)
  51     : wxFileDialogBase(parent, message, defaultDir, defaultFileName, wildCard, style, pos, sz, name)
  52 {
  53 }
  54
  55 bool wxFileDialog::SupportsExtraControl() const
  56 {
  57     return true;
  58 }
  59
  60 NSArray* GetTypesFromFilter( const wxString filter )
  61 {
  62     NSMutableArray* types = nil;
  63     if ( !filter.empty() )
  64     {
  65         wxArrayString names ;
  66         wxArrayString extensions;
  67
  68         wxString filter2(filter) ;
  69         int filterIndex = 0;
  70         bool isName = true ;
  71         wxString current ;
  72
  73         for ( unsigned int i = 0; i < filter2.length() ; i++ )
  74         {
  75             if ( filter2.GetChar(i) == wxT('|') )
  76             {
  77                 if ( isName )
  78                 {
  79                     names.Add( current ) ;
  80                 }
  81                 else
  82                 {
  83                     extensions.Add( current ) ;
  84                     ++filterIndex ;
  85                 }
  86
  87                 isName = !isName ;
  88                 current = wxEmptyString ;
  89             }
  90             else
  91             {
  92                 current += filter2.GetChar(i) ;
  93             }
  94         }
  95         // we allow for compatibility reason to have a single filter expression (like *.*) without
  96         // an explanatory text, in that case the first part is name and extension at the same time
  97
  98         wxASSERT_MSG( filterIndex == 0 || !isName , wxT("incorrect format of format string") ) ;
  99         if ( current.empty() )
 100             extensions.Add( names[filterIndex] ) ;
 101         else
 102             extensions.Add( current ) ;
 103         if ( filterIndex == 0 || isName )
 104             names.Add( current ) ;
 105
 106         ++filterIndex ;
 107
 108         const size_t extCount = extensions.GetCount();
 109         for ( size_t i = 0 ; i < extCount; i++ )
 110         {
 111             wxString extensiongroup = extensions[i];
 112             wxStringTokenizer tokenizer( extensiongroup , wxT(";") ) ;
 113             while ( tokenizer.HasMoreTokens() )
 114             {
 115                 wxString extension = tokenizer.GetNextToken() ;
 116                 // Remove leading '*'
 117                 if (extension.length() && (extension.GetChar(0) == '*'))
 118                     extension = extension.Mid( 1 );
 119
 120                 // Remove leading '.'
 121                 if (extension.length() && (extension.GetChar(0) == '.'))
 122                     extension = extension.Mid( 1 );
 123
 124                 // Remove leading '*', this is for handling *.*
 125                 if (extension.length() && (extension.GetChar(0) == '*'))
 126                     extension = extension.Mid( 1 );
 127
 128                 if ( extension.IsEmpty() )
 129                 {
 130                     if ( types != nil )
 131                         [types release];
 132                     return nil;
 133                 }
 134
 135                 if ( types == nil )
 136                     types = [[NSMutableArray alloc] init];
 137
 138                 wxCFStringRef cfext(extension);
 139                 [types addObject: (NSString*)cfext.AsNSString()  ];
 140 #if 0
 141                 // add support for classic fileType / creator here
 142                 wxUint32 fileType, creator;
 143                 // extension -> mactypes
 144 #endif
 145             }
 146
 147         }
 148     }
 149     return types;
 150 }
 151
 152 void wxFileDialog::ShowWindowModal()
 153 {
 154     wxCFStringRef cf( m_message );
 155     wxCFStringRef dir( m_dir );
 156     wxCFStringRef file( m_fileName );
 157
 158     wxNonOwnedWindow* parentWindow = NULL;
 159
 160     m_modality = wxDIALOG_MODALITY_WINDOW_MODAL;
 161
 162     if (GetParent())
 163         parentWindow = dynamic_cast<wxNonOwnedWindow*>(wxGetTopLevelParent(GetParent()));
 164
 165     wxASSERT_MSG(parentWindow, "Window modal display requires parent.");
 166
 167     if (HasFlag(wxFD_SAVE))
 168     {
 169         NSSavePanel* sPanel = [NSSavePanel savePanel];
 170
 171         SetupExtraControls(sPanel);
 172
 173         // makes things more convenient:
 174         [sPanel setCanCreateDirectories:YES];
 175         [sPanel setMessage:cf.AsNSString()];
 176         // if we should be able to descend into pacakges we must somehow
 177         // be able to pass this in
 178         [sPanel setTreatsFilePackagesAsDirectories:NO];
 179         [sPanel setCanSelectHiddenExtension:YES];
 180
 181         NSWindow* nativeParent = parentWindow->GetWXWindow();
 182         ModalDialogDelegate* sheetDelegate = [[ModalDialogDelegate alloc] init];
 183         [sheetDelegate setImplementation: this];
 184         [sPanel beginSheetForDirectory:dir.AsNSString() file:file.AsNSString()
 185             modalForWindow: nativeParent modalDelegate: sheetDelegate
 186             didEndSelector: @selector(sheetDidEnd:returnCode:contextInfo:)
 187             contextInfo: nil];
 188     }
 189     else
 190     {
 191         NSArray* types = GetTypesFromFilter( m_wildCard ) ;
 192         NSOpenPanel* oPanel = [NSOpenPanel openPanel];
 193
 194         SetupExtraControls(oPanel);
 195
 196         [oPanel setTreatsFilePackagesAsDirectories:NO];
 197         [oPanel setCanChooseDirectories:NO];
 198         [oPanel setResolvesAliases:YES];
 199         [oPanel setCanChooseFiles:YES];
 200         [oPanel setMessage:cf.AsNSString()];
 201
 202         NSWindow* nativeParent = parentWindow->GetWXWindow();
 203         ModalDialogDelegate* sheetDelegate = [[ModalDialogDelegate alloc] init];
 204         [sheetDelegate setImplementation: this];
 205         [oPanel beginSheetForDirectory:dir.AsNSString() file:file.AsNSString()
 206             types: types modalForWindow: nativeParent
 207             modalDelegate: sheetDelegate
 208             didEndSelector: @selector(sheetDidEnd:returnCode:contextInfo:)
 209             contextInfo: nil];
 210     }
 211 }
 212
 213 void wxFileDialog::SetupExtraControls(WXWindow nativeWindow)
 214 {
 215     NSSavePanel* panel = (NSSavePanel*) nativeWindow;
 216
 217     wxNonOwnedWindow::Create( GetParent(), nativeWindow );
 218
 219     if (HasExtraControlCreator())
 220     {
 221         CreateExtraControl();
 222         wxWindow* control = GetExtraControl();
 223         if ( control )
 224         {
 225             NSView* accView = control->GetHandle();
 226             [accView removeFromSuperview];
 227             [panel setAccessoryView:accView];
 228         }
 229         else
 230         {
 231             [panel setAccessoryView:nil];
 232         }
 233     }
 234 }
 235
 236 int wxFileDialog::ShowModal()
 237 {
 238     wxCFStringRef cf( m_message );
 239
 240     wxCFStringRef dir( m_dir );
 241     wxCFStringRef file( m_fileName );
 242
 243     m_path = wxEmptyString;
 244     m_fileNames.Clear();
 245     m_paths.Clear();
 246     // since we don't support retrieving the matching filter
 247     m_filterIndex = -1;
 248
 249     wxNonOwnedWindow* parentWindow = NULL;
 250     int returnCode = -1;
 251
 252     if (GetParent())
 253     {
 254         parentWindow = dynamic_cast<wxNonOwnedWindow*>(wxGetTopLevelParent(GetParent()));
 255     }
 256
 257     if (HasFlag(wxFD_SAVE))
 258     {
 259         NSSavePanel* sPanel = [NSSavePanel savePanel];
 260
 261         SetupExtraControls(sPanel);
 262
 263         // makes things more convenient:
 264         [sPanel setCanCreateDirectories:YES];
 265         [sPanel setMessage:cf.AsNSString()];
 266         // if we should be able to descend into pacakges we must somehow
 267         // be able to pass this in
 268         [sPanel setTreatsFilePackagesAsDirectories:NO];
 269         [sPanel setCanSelectHiddenExtension:YES];
 270
 271         if ( HasFlag(wxFD_OVERWRITE_PROMPT) )
 272         {
 273         }
 274
 275         returnCode = [sPanel runModalForDirectory:dir.AsNSString() file:file.AsNSString() ];
 276         ModalFinishedCallback(sPanel, returnCode);
 277
 278         [sPanel setAccessoryView:nil];
 279     }
 280     else
 281     {
 282         NSArray* types = GetTypesFromFilter( m_wildCard ) ;
 283         NSOpenPanel* oPanel = [NSOpenPanel openPanel];
 284
 285         SetupExtraControls(oPanel);
 286
 287         [oPanel setTreatsFilePackagesAsDirectories:NO];
 288         [oPanel setCanChooseDirectories:NO];
 289         [oPanel setResolvesAliases:YES];
 290         [oPanel setCanChooseFiles:YES];
 291         [oPanel setMessage:cf.AsNSString()];
 292
 293         returnCode = [oPanel runModalForDirectory:dir.AsNSString()
 294                         file:file.AsNSString() types:types];
 295
 296         ModalFinishedCallback(oPanel, returnCode);
 297
 298         [oPanel setAccessoryView:nil];
 299
 300         if ( types != nil )
 301             [types release];
 302     }
 303
 304     return GetReturnCode();
 305 }
 306
 307 void wxFileDialog::ModalFinishedCallback(void* panel, int returnCode)
 308 {
 309     int result = wxID_CANCEL;
 310     if (HasFlag(wxFD_SAVE))
 311     {
 312         if (returnCode == NSOKButton )
 313         {
 314             NSSavePanel* sPanel = (NSSavePanel*)panel;
 315             result = wxID_OK;
 316
 317             m_path = wxCFStringRef::AsString([sPanel filename]);
 318             m_fileName = wxFileNameFromPath(m_path);
 319             m_dir = wxPathOnly( m_path );
 320         }
 321     }
 322     else
 323     {
 324         NSOpenPanel* oPanel = (NSOpenPanel*)panel;
 325         if (returnCode == NSOKButton )
 326         {
 327             panel = oPanel;
 328             result = wxID_OK;
 329             NSArray* filenames = [oPanel filenames];
 330             for ( size_t i = 0 ; i < [filenames count] ; ++ i )
 331             {
 332                 wxString fnstr = wxCFStringRef::AsString([filenames objectAtIndex:i]);
 333                 m_paths.Add( fnstr );
 334                 m_fileNames.Add( wxFileNameFromPath(fnstr) );
 335                 if ( i == 0 )
 336                 {
 337                     m_path = fnstr;
 338                     m_fileName = wxFileNameFromPath(fnstr);
 339                     m_dir = wxPathOnly( fnstr );
 340                 }
 341             }
 342         }
 343     }
 344     SetReturnCode(result);
 345
 346     if (GetModality() == wxDIALOG_MODALITY_WINDOW_MODAL)
 347         SendWindowModalDialogEvent ( wxEVT_WINDOW_MODAL_DIALOG_CLOSED  );
 348
 349     [(NSSavePanel*) panel setAccessoryView:nil];
 350 }
 351
 352 #endif // wxUSE_FILEDLG